./       ADD   SSI=01013305,NAME=IKDCTL,SOURCE=0
 TITLE 'IKDCTL' CONTROL ROUTINE FOR SGJP                                00200017
*STATUS: CHANGE LEVEL 0                                               * 00400017
*FUNCTION/OPERATION: PERFORM CONTROL FUNCTIONS FOR PROCESSOR ROUTINES.* 00800017
*   IT'S OPERATIONS INCLUDE:                                          * 01000017
*   1)IF ENTERED PRIOR TO LOGON, LOAD THE LOGON PROCESSOR;  IF ENTERED* 01200017
*   AFTER BEGIN JOB, GET A PROCESSOR SELECT RECORD TO DETERMINE IF THE* 01400017
*   SUBSEQUENT PROCESSOR IS TO BE LINKED TO OR LOADED                 * 01600017
*   2)LINK TO THE CANCEL JOB, BEGIN JOB, LOGOFF OR BEGIN PROCEDURE    * 01800017
*   PROCESSORS                                                        * 02000017
*   3)LOAD THE LOGON, SPECIFY JOB STEP, DESCRIBE DATA, ENTER DATA,    * 02200017
*   WRITE MESSAGE OR RECALL PROCESSORS, GET AN EXTRACT RECORD FROM THE* 02400017
*   SUBSYSTEM AND BALR TO THE PROCESSOR                               * 02600017
*   4)ANALYZE RETURN CODES FROM PROCESSORS AND PERFORM ONE OF THE     * 02800017
*         X'00' DELETE LOADED PROCESSOR, TRANSMIT MESSAGE TO THE SUB- * 03000017
*               SYSTEM AND GET ANOTHER PROCESSOR SELECT RECORD        * 03200017
*         X'04' TRANSMIT A MESSAGE TO THE SUBSYSTEM AND GET ANOTHER   * 03400017
*               EXTRACT RECORD                                        * 03600017
*         X'08' ISSUE RETURN                                          * 03800017
*         X'0C' DELETE LOADED PROCESSOR AND GET ANOTHER PROCESSOR     * 04000017
*               SELECT RECORD                                         * 04200017
*ENTRY POINTS: IKDCTL.  ENTERED VIA XCTL FROM INITIALIZATION(SGJPINIT)* 04400017
*INPUT: REGISTER 0 CONTAINS ENTRY CODE FROM SGJPINIT:                 * 04600017
*         X'04' ENTERED AT LOGON                                      * 04800017
*         X'08' ENTERED AFTER BEGIN JOB                               * 05000017
*   REGISTER 1 CONTAINS THE ADDRESS OF THE CONSOLE CONTROL TABLE FROM * 05200017
*   SGJPINIT.                                                         * 05400017
*   3)PROCESSOR SELECT RECORD RECEIVED FROM 1130 SUBSYSTEM INDICATING * 05600017
*   WHICH PROCESSOR HAS BEEN SELECTED AND IF IT IS TO BE LINKED TO OR * 05800017
*   LOADED.                                                           * 06000017
*   4)EXTRACT RECORD FROM SUBSYSTEM                                   * 06200017
*   5)RETURN CODE FROM PROCESSORS VIA REGISTER 15:                    * 06400017
*        X'00' NORMAL RETURN                                          * 06600017
*        X'04' REPEAT                                                 * 06800017
*        X'08' RETURN FROM BEGIN JOB OR LOGOFF                        * 07000017
*        X'06' CANCEL CURRENT PROCESSOR                               * 07200017
*OUTPUT: 1)  CODE FOR IKDIOR IN REGISTER 0  X'04'=READ X'08'=WRITE    * 07400017
*   2)ADDRESS OF CONSOLE CONTROL TABLE IN REGISTER 1 FOR PROCESSORS   * 07600017
*   AND IKDIOR.                                                       * 07800017
*   3)MESSAGE SENT TO SUBSYSTEM TO INDICATE PREVIOUS EXTRACT RECORD   * 08000017
*   WAS ACCEPTED BY THE PROCESSOR.                                    * 08200017
*EXTERNAL ROUTINES: IKDIOR FOR I/O OPERATIONS; PROCESSOR ROUTINES       08400017
*EXITS: 1BRANCH TO IKDIOR FOR READ/WRITE OPERATIONS                   * 08600017
*       2)LINK OR BRANCH TO PROCESSOR ROUTINES                        * 08800017
*       3)RETURN UPON RECEIPT OF AN 08 CODE                           * 09000017
*TABLES/WORKAREAS: CCT, I/O BUFFER                                    * 09200017
*ATTRIBUTES: REENTRANT                                                * 09400017
*NOTES: N/A                                                           * 09600017
         EJECT                                                          09800017
IKACCT   DSECT                                                          10000017
         SPACE                                                          10200017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         10400017
         SPACE                                                          10600017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    10800017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     11000017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       11200017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             11400017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  11600017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  11800017
*                   SET.                                                12000017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      12200017
*                   SECOND.                                             12400017
         SPACE 2                                                        12600017
         SPACE 2                                                        12800017
*                             SECTION ONE                               13000017
         SPACE                                                          13200017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     13400017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    13600017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  13800017
         SPACE                                                          14000017
         DS    0F                                                       14200017
CCTUNAME DS    5F                  USER'S NAME                          14400017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         14600017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     14800017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       15000017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    15200017
*                                       AT LAST BEGIN JOB               15400017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   15600017
*                                       LAST BEGIN JOB                  15800017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 16000017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    16200017
*                                       JOB                             16400017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    16600017
*                                       JOB                             16800017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     17000017
*                                       CESSOR                          17200017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         17400017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         17600017
CCTJCTR  DS    H                   JOB COUNTER                          17800017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                18000017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   18200017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  18400017
CCTSSTAT DS    C                   SESSION STATUS                       18600017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              18800017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              19000017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    19200017
         EJECT                                                          19400017
         SPACE 2                                                        19600017
*                             SECTION TWO                               19800017
         SPACE                                                          20000017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   20200017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  20400017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 20600017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              20800017
         SPACE                                                          21000017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     21200017
*                                       FRAME                           21400017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  21600017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     21800017
*                                       MULTIPLE DISPLAY FRAME (ENT)    22000017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   22200017
CCTDISM  DS    C                   DISPLAY MASK                         22400017
CCTCSM   DS    C                   COMMAND SELECT MASK                  22600017
CCTPSTAT DS    CL2                 GJP STATUS                           22800017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              23000017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  23200017
CCTPWKAE EQU   *                                                        23400017
         SPACE 2                                                        23600017
*                             SECTION THREE                             23800017
         SPACE                                                          24000017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    24200017
*                   INTO SECTION ONE OR TWO                             24400017
         SPACE                                                          24600017
CCTDGMP  DS    F                  POINTER TO DGM                        24800017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                25000017
CCTCSTP  DS    F                  POINTER TO CST                        25200017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                25400017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            25600017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 25800017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              26000017
CCTDIARP DS    F                  POINTER TO DIA                        26200017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      26400017
CCTACTP  DS    F                  POINTER TO ACT                        26600017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     26800017
CCTIERRP DS    F                  POINTER TO IERR                       27000017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              27200017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               27400017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                27600017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 27800017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 28000017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   28200017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                28400017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                28600017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               28800017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              29000017
CCTPECB  DS    F                  PROCESSOR'S ECB                       29200017
CCTWECB  DS    F                  WTOR ECB                              29400017
CCTDIAWA DS    CL136               DIARY WORK AREA                      29600017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    29800017
CCTCSAVE DS    CL72                CTL SAVE AREA                        30000017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                30200017
CCTASAVE DS    CL72                DAT SAVE AREA                        30400017
*                                                                       30600017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       30800017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           31000017
*                                                                       31200017
IKDCCT   EQU   IKACCT              THREE CHARACTER PREFIX IS REPLACED   31400017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             31600017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               31800017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     32000017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               32200017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           32400017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    32600017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 32700017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   32800017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   32900017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   33000017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            33100017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 33200017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       33300017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  33400017
*                                  INATION OF DATA                      33500017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    33600017
*                                  THE I/O OPERATION TO BE TESTED BY    33700017
*                                  GTCLT                                33800017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        33900017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              34000017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   34600017
CCTPWKAL EQU   CCTPWKAE-CCTPWKA                                         35200017
         EJECT                                                          35400017
IKDCTL   CSECT                                                          35600017
*                                                                       35800017
*      GENERAL REGISTERS AND EQUATES                                    36000017
*                                                                       36200017
RPAR0    EQU   0                                                        36400017
RPAR1    EQU   1                                                        36600017
RCCT     EQU   2                                                        36800017
RBAL     EQU   4                                                        37200017
RSADR    EQU   5                                                        37400017
RWKAREA  EQU   6                                                        37600017
RWKARPTR EQU   7                                                        37660017
RMSGADRS EQU   8                                                        37720017
RBUFF    EQU   9                                                        37800017
RBASE    EQU   10                                                       38000017
RWORK    EQU   11                                                       38200017
RLNTH    EQU   11                                                       38260017
RLCHAR   EQU   12                                                       38320017
RMISC    EQU   12                                                       38400017
RNUC     EQU   12                                                       38600017
RSAVE    EQU   13                                                       38800017
RRET     EQU   14                                                       39000017
RBR      EQU   15                                                       39200017
*                                                                       39400017
ZERO     EQU   0                                                        39440017
CRDCODE  EQU   0                                                        39480017
ONE      EQU   1                                                        39520017
TWO      EQU   2                                                        39560017
LMSGLNTH EQU   2                                                        39600017
THREE    EQU   3                                                        39640017
KEYLNTH  EQU   3                                                        39680017
FOUR     EQU   4                                                        39720017
PSRLNTH  EQU   4                                                        39760017
CMSGLNGT EQU   4                                                        39800017
CWRCODE  EQU   4                                                        39840017
FIVE     EQU   5                                                        39880017
DUNIT    EQU   5                   DISPLACEMENT OF UNIT IN PARAM LIST   39920017
LKLDCD   EQU   5                                                        39960017
JMSGLNTH EQU   6                                                        40000017
KEY      EQU   6                                                        40040017
SEVEN    EQU   7                                                        40080017
EIGHT    EQU   8                                                        40120017
JOBCOUNT EQU   8                                                        40160017
CTRAWCD  EQU   8                                                        40200017
TWELVE   EQU   12                                                       40240017
EXTNOTE  EQU   12                                                       40280017
MAXLNTH  EQU   12                                                       40320017
CTWAWCD  EQU   12                                                       40360017
SIXTEEN  EQU   16                                                       40400017
FBCKGRND EQU   16                                                       40440017
CRDONCD  EQU   24                                                       40480017
SGLINE   EQU   26                                                       40500017
CWRONCD  EQU   28                                                       40520017
SVNTYTWO EQU   72                                                       40560017
SVNTYTHR EQU   73                                                       40600017
SVNTYSIX EQU   76                                                       40640017
NUMBER   EQU   200                                                      40680017
SUPLIST  EQU   336                                                      40720017
HEX00    EQU   X'00'                                                    40760017
HEX01    EQU   X'01'                                                    40800017
HEX08    EQU   X'08'                                                    40840017
HEX10    EQU   X'10'                                                    40880017
HEX1C    EQU   X'1C'                                                    40900017
CENDCODE EQU   X'14'                                                    40920017
HEX21    EQU   X'21'                                                    40960017
HEX26    EQU   X'26'                                                    41040017
HEX40    EQU   X'40'                                                    41080017
HEX80    EQU   X'80'                                                    41120017
HEX83    EQU   X'83'                                                    41160017
HEXC0    EQU   X'C0'                                                    41200017
HEXC4    EQU   X'C4'                                                    41240017
HEXCF    EQU   X'CF'                                                    41280017
HEXF0    EQU   X'F0'                                                    41320017
HEXFF    EQU   X'FF'                                                    41360017
D        EQU   C'D'                                                     41400017
K        EQU   C'K'                                                     41440017
M        EQU   C'M'                                                     41480017
N        EQU   C'N'                                                     41680017
         EJECT                                                          42000017
*                                                                       42200017
*      HOUSE KEEPING                                                    42400017
*                                                                       42600017
         SAVE  (2,12)         SAVE REGISTERS                            42800017
         BALR  RBASE,0                  SET UP PROGRAM BASE             43000017
         USING *,RBASE                                                  43200017
         LR    RCCT,RPAR1               GET CONSOLE CONTROL TABLE ADDR. 43400017
         USING IKACCT,RCCT              SET UP BASE FOR CCT             43600017
         ST    RSAVE,CCTCSAVE+FOUR     SAVE CALLER'S SAVE ADDRESS       43800017
         LA    RWORK,CCTCSAVE           CHAIN                           44000017
         ST    RWORK,EIGHT(RSAVE)              SAVE                     44200017
         LR    RSAVE,RWORK                       AREAS                  44400017
         LA    RWKAREA,CCTCWKA          GET POINTER TO CONTROL WORKAREA 44600017
         MVC   ZERO(EIGHT,RWKAREA),PROMODEL   PUT MODEL INTO WORKAREA   44700017
         L     RBUFF,CCTBUFFP    SET POINTER TO BUFFER                  44900017
         CLC   CCTCCR(THREE),LOGN     DETERMINE IF LOGON TIME           45000017
         BE    CLOGN               IF SO, BRANCH                        45200017
         CLC   CCTCCR(THREE),BEG      DETERMINE IF BEGIN JOB TIME       45300017
         BE    TSTMSGBT               IF YES, BRANCH                    45400017
*                                                                       45700017
* BRANCH TO INTERNAL ERROR ROUTINE AND TERMINATE JOB                    45800017
*                                                                       45900017
         LR    RPAR1,RCCT          CCT ADDRESS                          46000017
         LA    RPAR0,IERRPAR       ERROR MSG ADDRESS                    46100017
         L     RBR,CCTIERRP        IKAIERR ADDRESS                      46200017
         BALR  RRET,RBR            GO TO IERR                           46250017
         LR    RPAR0,RBR           PUT CODE IN REG15                    46300017
         B     FASTSTOP            BRANCH TO TERMINATE                  46350017
*                                                                       46400017
*      INPUT FROM INITIALIZATION INDICATES LOGON TIME.                  46600017
*                                                                       46800017
CLOGN    MVI   CCTSTAT,D           INDICATE MODULE TO BE LOADED         47000017
         MVI   CCTPECB,HEX00       CLEAR PROCESSOR ECB                  47200017
         MVI   CCTCSM,HEX01        SET COMMAND SELECT MASK              47400017
         EJECT                                                          47600017
*                                                                       47800017
*      LOGON, DESCRIBE DATA, SPECIFY JOB STEP, ENTER DATA, WRITE        48000017
*      MESSAGE AND RECALL PROCESSORS WILL BE LOADED                     48200017
*                                                                       48400017
CLOAD    LA    RPAR0,CRDONCD      PARAMETER CODE TO READ                48460017
         LA    RWORK,CCTPWKAL     GET LENGTH OF WORKAREA                48520017
         LA    RWORK,TWO(RWORK)    ADD TWO BYTES                        48580017
         ST    RWORK,CCTRECLN     PUT LENGHT IN CCT                     48640017
         BAL   RBAL,CREQIO        GO TO PERFORM I/O                     48700017
         CLC   CCTCCR(THREE),LOF   WAS LOGOFF SELECTED                  48730017
         BE    CEXTRCD     IF YES, BRANCH TO WAIT FOR I/O               48760017
         LOAD  EPLOC=(RWKAREA)          LOAD SELECTED PROCESSOR         48800017
         LR    RSADR,RPAR0              GET AND SAVE PROCESSORS ADDRESS 49000017
*                                                                       49200017
*    IKDCTL PREPARES PARAMETERS FOR IKDIOR TO READ AN EXTRACT RECORD    49400017
*      FROM THE 1130 SUBSYSTEM.                                         49600017
*                                                                       49800017
CEXTRCD  LA    RPAR0,CTRAWCD      CODE TO TEST READ AND WAIT            50300017
         BAL   RBAL,CREQIO         GO TO PERFROM I/O                    50800017
         LR    RBR,RSADR                GET ADDRESS OF PROCESSER        51000017
         CLC   CCTCCR(THREE),LOF   WAS LOGOFF SELECTED                  51030017
         BE    LINKLOF            BRANCH TO RESET CSM                   51060017
         LR    RPAR1,RCCT                                               51100017
         BALR  RRET,RBR                 BRANCH TO THE LOADED PROCESSOR  51200017
         CH    RBR,CANC           WAS PROCESSOR CANCELLED               51260017
         BE    CCNCL              IF YES, BANCH TO HNDL RETURN CODE     51320017
         B     CKSTOP              BRANCH TO                            51400017
LINKLOF  MVI   CCTCSM,HEX00       CLEAR SELECT MASK                     51460017
         B     CLINK              BRANCH TO LINK TO LOOGOFF PROCESSOR   51520017
*                                                                       51600017
*      INPUT FROM INITIALIZATION INDICATES BEGIN JOB TIME               51800017
*                                                                     * 52000017
TSTMSGBT MVC   ZERO(FOUR,RBUFF),NONE   PUT NONE MESSAGE IN BUFFER       52004017
         LA    RWORK,FOUR          GET A COUNT OF FOUR                  52008017
         ST    RWORK,CCTRECLN     SET RECORD LENGTH                     52012017
         LA    RPAR0,CWRCODE      SET CODE TO WRITE                     52016017
         BAL   RBAL,CREQIO                                              52020017
         TM    CCTPSTAT+1,X'40'    IS THERE A MESSAGE TO BE DISPLAYED   52024017
         BZ    NOMSG               BRANCH IF NO                         52028017
TESTLOF  TM    CCTCSM,HEX08        IS ONLY LOGOFF AVAILABLE             52036017
         BZ    MSGONLY             BRANCH IF NOT                        52045017
         LA    RWORK,ZERO          GET HEADER CODE FOR LOGOFF           52054017
         STH   RWORK,ZERO(RBUFF)   PUT CODE INTO BUFFER                 52063017
         B     MSGHNDLE            GO TO PUT MESSAGES INTO BUFFER       52072017
MSGONLY  LA    RWORK,TWO           GET HEADER CODE FOR MESSAGES         52081017
         STH   RWORK,ZERO(RBUFF)   PUT CODE INTO BUFFER                 52090017
MSGHNDLE LA    RBUFF,TWO(RBUFF)    SET BUFFER POINTER TO NEXT LOCATION  52099017
         SR    RLNTH,RLNTH         CLEAR A REGISTER TO USE FOR DATA LNT 52108017
         LA    RLNTH,TWO           ADD TWO TO LENGTH                    52117017
         BAL   RBAL,PROCMSG        GO TO MOVE ANY MESSAGES FROM PWKA TO 52126017
         B     GOTOIO              BUFFER                               52135017
NOMSG    LA    RWORK,ONE           GET HEADER CODE FOR NO MESSAGE       52144017
         STH   RWORK,ZERO(RBUFF)   PUT CODE INTO BUFFER                 52153017
         LA    RLNTH,TWO           SET LENGTH OF DATA TO BE TRANSMITTED 52162017
GOTOIO   ST    RLNTH,CCTRECLN      PUT LENGTH INTO CCT                  52171017
         LA    RPAR0,CWRCODE       GET CODE TO WRITE                    52180017
         BAL   RBAL,CREQIO         BRANCH TO GO TO I/O ROUTINE          52189017
CBEGN    EQU   *                                                        52200017
         MVI   CCTPWKA,HEX40    PUT BLANK IN WORKAREA                   52250017
         MVC   CCTPWKA+1(200),CCTPWKA                                   52300017
         MVC   CCTPWKA+200(151),CCTPWKA                                 52350017
         LA    RPAR0,CRDCODE            PARAMETER CODE TO READ          52400017
         LA    RWORK,MAXLNTH      GET LENGTH OF MAXIMUM PSR             52600017
*                                  TO BE RECEIVED                       52800017
         ST    RWORK,CCTRECLN      PUT IN RECORD LENGTH FOR IKDIOR      53000017
         BAL   RBAL,CREQIO                                              53200017
         MVC   CCTCWKA+FOUR(THREE),CCTCCR  PUT COMMAND KEY INTO CTL AR. 53400017
         L     RWORK,CCTHSN        GET HISTORY SEQUENCE NUMBER          53650017
         LA    RWORK,ONE(RWORK)    INCREMENT BY ONE                     53710017
         STH   RWORK,CCTHSN+TWO    RESTORE IN CCT                       53770017
         CLI   CCTSTAT,D           DETERMINE IF PROCESSOR IS TO BE      53830017
         BNE   CLINK       LOADED.  IF NOT, BRANCH                      53900017
         B     CLOAD       BRANCH TO LOAD PROCESSOR                     54100017
         EJECT                                                          54600017
*                                                                       54800017
*      CANCEL JOB, BEGIN JOB, BEGIN PROCEDURE AND LOGOFF PROCESSORS     55000017
*      WILL BE LINKED TO                                                55200017
*                                                                       55400017
CLINK    CLC   CCTCCR(KEYLNTH),CAN  IS PROCESSOR CANCEL JOB             55480017
         BNE   CSMSET         IF NOT BRANCH                             55560017
         MVI   CCTCSM,HEX01        PUT INITIAL SELECT MASK IN CCT       55640017
CSMSET   LR    RPAR1,RCCT      ADDRESS OF CCT                           55720017
         LA    RBR,CCTPWKA+SUPLIST      LOAD ADDR OF SUPEVIS- PARM LIST 56000017
         MVI   ZERO(RBR),HEX00     CLEAR AREA                           56200017
         MVC   ONE(SEVEN,RBR),ZERO(RBR)       BEFORE LINK               56400017
         LA    RWKAREA,CCTCWKA          ADDRESS OF PROCESSOR NAME       56600017
         LINK  EPLOC=(RWKAREA),MF=(E,(1)),SF=(E,(15))  LINK TO PROCESSR 56800017
         CLC   CCTCCR(THREE),LOF   WAS PROCESSOR LOGOFF                 56801017
         BNE   BRANCHT            IF NOT, BRANCH TO BRANCH TABLE        56802017
         B     CKSTOP             IF YES, BRANCH TO CHECK STOP BITS     56803017
         EJECT                                                          56804017
*                                                                       56808017
* CHECK OCT IF OPERATOR ISSUED MEDIUM OR FAST STOP                      56812017
*                                                                       56816017
RCVT     EQU   3                                                        56820017
ROCT     EQU   4                                                        56824017
RGFXLIST EQU   7                                                        56828017
ROCTENT  EQU   8                                                        56832017
RENTCTR  EQU   12                                                       56836017
CKSTOP   L     RCVT,HEX10          GET CVT ADDRESS                      56842017
         USING CVT,RCVT                                                 56848017
         L     RGFXLIST,CVTQOCR                                         56852017
         USING GRAPLIST,RGFXLIST                                        56856017
         L     ROCT,GOCT           GET OCT ADDRESS                      56860017
         USING GFXOCTHD,ROCT                                            56864017
         LA    ROCTENT,GFXHDSZE+GFXHDSTR   GET OCT RECORD ENTRY         56868017
         USING GFXOCTEN,ROCTENT                                         56872017
         LH    RENTCTR,OCTUNBR     OCT RECORD NUMBER                    56876017
ENTSEACH CLC   CCTUNIT(THREE),OCTUNIT+ONE  IS THIS OCT ENTRY NEEDED     56880017
         BE    STOP                IF YES, BRANCH                       56884017
         LA    ROCTENT,GFXENSTR+GFXENSZE  UPDATE ENTRY                  56888017
         BCT   RENTCTR,ENTSEACH    GO BACK AND CONTINUE SEARCH          56892017
NOTFOUND LA    RPAR0,MSG11         GET MESSAGE ADDRESS                  56896017
         LR    RPAR1,RCCT                                               56900017
         L     RBR,CCTIERRP        ERROR ROUTINE ADDRESS                56904017
         BR    RBR                 GO TO IKAIERR                        56908017
STOP     TM    OCTATTR2,HEX08      IS THIS MEDIUM STOP                  56912017
         BO    MSTOP               IF SO, BRANCH                        56916017
         DROP  3,4,7,8                                                  56920017
CKFSTOP  EQU   *                                                   EXTR 56922019
         L     RWKARPTR,CCTTIME    GET COMM PARAM LIST ADDRESS     EXTR 56924019
         L     RMSGADRS,0(RWKARPTR)     POINTER TO ECB             EXTR 56926019
         TM    ZERO(RMSGADRS),HEX10 IS THIS FAST STOP                   56929017
         BZ    BRANCHT            BRANCH IF NOT                         56932017
         B     SVCLOF             IMMEDIATE TERMINATION                 56942017
MSTOP    LA    RBR,TWELVE          SET A 12 RETURN CODE                 56962017
         MVI   CCTCSM,HEX08        SET LOGOFF CODE                      56965017
         CLC   CCTCCR(THREE),LOF     WAS LOGOFF IM CONTROL              56968017
         BE    SVCLOF       IF YES, BRANCH                              56971017
BRANCHT  EQU   *                                                        56976017
         B     CRETABLE(RBR)            BRANCH TO RETURN CODE TABLE     57000017
*                                                                       57200017
*      BRANCH ON RETURN CODES FROM PROCESSORS                           57400017
*                                                                       57600017
CRETABLE EQU   *                                                        57800017
         B     CNORMRET                 NORMAL CONDITION                58000017
         B     CREPEAT                  REPEAT (ENTER DATA)             58200017
         B     CFORBCK             DETERMINE IF FOREGROUND OR BACKGRND  58400017
         B     CCNCL                    CANCEL KEY DETECTED             58800017
         B     SVCLOF     BRANCH TO ISSUE SVC80                         58900017
         B     CCNCL                                                    59100017
         DS    XL4'0'              DUMMY ENTRY                          59130017
         B     FASTSTOP            ENTERED IERR BRANCH TO TERMINATE     59160017
         EJECT                                                          59200017
CNORMRET CLI   CCTSTAT,K           WAS PROCESSOR LINKED TO              59500017
         BE    CBEGN                    IS SO, GO BACK FOR ANOTHER PSR  59800017
         DELETE EPLOC=(RWKAREA)         DELETE LOADED PROCESSOR         60000017
WRITOK   CLC   CCTCCR(KEYLNTH),SPE        WAS PROCESSOR SPECIFY JOB     60020017
         BNE   MASKSET             BRANCH IF NOT                        60040017
         MVI   CCTCSM,HEX26        UPDATE COMMAND SELECT MASK           60060017
MASKSET  EQU   *                                                        60080017
         MVC   ZERO(CMSGLNGT,RBUFF),COKMESSG  PUT MESSAGE INTO BUFFER   60100017
         CLC   CCTCCR(THREE),LOGN  WAS PROCESSOR LOGON                  60102017
         BNE   NOTLON             IF NOT, BRANCH                        60104017
         L     RWORK,CCTGEND      GET ADDRESS OF SYSGEN DATA            60106017
         MVC   FOUR(FOUR,RBUFF),SGLINE(RWORK) PUT LN CT SYS TYP IN CCT  60108017
         LA    RWORK,EIGHT        SET RECORD LENGTH TO EIGHT            60110017
         B     MSGSET                                                   60112017
NOTLON   EQU   *                                                        60114017
         LA    RWORK,CMSGLNGT     SET DATA LENGTH                       60120017
MSGSET   EQU   *                                                        60160017
         BAL   RBAL,CWRITE              GO TO WRITE MESSAGE             60200017
         B     CBEGN                    GO FOR ANOTHER PROC SELECT RCD  60400017
CREPEAT  MVC   ZERO(CMSGLNGT,RBUFF),COKMESSG  PUT MSG INTO BUFFER       60500017
         LA    RWORK,CMSGLNGT                SET DATA LENGTH            60720017
         BAL   RBAL,CWRITE              GO TO WRITE MESSAGE             60800017
         LA    RPAR0,CRDONCD      SET CODE TO READ ONLY                 60820017
         LA    RWORK,CCTPWKAL     GET LENGTH OF WORKAREA                60840017
         LA    RWORK,TWO(RWORK)    INCREMENT BY TWO                     60860017
         ST    RWORK,CCTRECLN     PUT LENGTH IN CCT                     60880017
         BAL   RBAL,CREQIO        GO TO PERFORM I/O                     60900017
         L     RWORK,CCTHSN       GET HISTORY SEQUENCE NUMBER           60920017
         LA    RWORK,ONE(RWORK)    INCREMENT BY ONE                     60940017
         STH   RWORK,CCTHSN+TWO    RESTORE IN CCT                       60960017
         B     CEXTRCD                  GET ANOTHER EXTRACT RECORD      61000017
CCNCL    DELETE  EPLOC=(RWKAREA)   DE3 ETE LOADED PROCESSOR             61020017
         TM    CCTPSTAT+ONE,HEX40  ANY MESSAGES TO BE DISPLAYED         61021017
         BO    MSGTOBED           IF YES BRANCH                         61022017
         CLI   CCTCSM,HEX08        IS CSM SET FOR LOGOFF                61032017
         BNE   TESTWRI             IF NOT, BRANCH                       61042017
         LA    RWORK,LMSGLNTH     SET LENGTH OF LOGOFF MESSAGE          61080017
         MVC   ZERO(LMSGLNTH,RBUFF),LFMSG  PUT LOGOFF MESSAGE IN BUFFER 61100017
         BAL   RBAL,CWRITE                                              61120017
         B     CBEGN              GO GET LOGOFF PSR                     61123017
TESTWRI  CLI   CCTSTAT+TWO,M       WAS END KEY FUNCTION PERFORMED       61126017
         BNE   TESTN            IF NOT, BRANCH                          61129017
         MVI   CCTSTAT+TWO,HEX00   ZERO M SWITCH                        61132017
         CLC   CCTCCR(KEYLNTH),WRI WAS KEY FOR WRITE MESSAGE            61135017
         BE    WRITOK             IF YES GO WRITE OK MESSAGE            61138017
         CLC   CCTCCR(THREE),REC        WAS RECALL IN CONTROL           61139017
         BE    CBEGN               IF YES, BRANCH                       61140017
         MVC   ZERO(JMSGLNTH,RBUFF),JLMSG  PUT JOBLIB MSG IN BUFFER     61141017
         LA    RWORK,JMSGLNTH     SET MESSAGE LENGTH                    61144017
         BAL   RBAL,CWRITE        GO FOR I/O OPERATION                  61147017
         B     CBEGN              GO GET NEXT PSR                       61150017
MSGTOBED L     RBUFF,CCTBUFFP     INITIALIZE POINTER TO BUFFER          61159017
         SR    RLNTH,RLNTH        CLEAR A LENGTH REGISTER               61162017
         BAL   RBAL,PROCMSG       GO TO HANDLE MESSAGES                 61165017
         ST    RLNTH,CCTRECLN     PUT LENGTH INTO CCT                   61168017
         LA    RPAR0,CWRCODE      SET CODE TO WRITE                     61171017
         BAL   RBAL,CREQIO        GO TO PERFORM I/O                     61174017
DECHSN   CLC   CCTCCR(THREE),REC    WAS PROCESSOR RECALL                61175017
         BE    CBEGN              IF YES, BRANCH                        61176017
         L     RWORK,CCTHSN      GET HSN                                61177017
         BCTR  RWORK,ZERO          DECREMENT BY ONE                     61180017
         STH   RWORK,CCTHSN+TWO    RESTORE INTO CCT                     61183017
         B     CBEGN              GO TO READ A PSR                      61186017
TESTN    CLI   CCTSTAT+TWO,N   WAS WTOR REQUESTES                       61186117
         BNE   DECHSN     IF NOT, BRANCH                                61186217
         MVI   CCTSTAT+TWO,HEX00   CLEAR INDICATOR                      61186317
         B     CBEGN          GO READ A PSR                             61186417
*                                                                       61186617
* INFORM GFX THAT LOGOFF HAS OCCURRED                                   61187217
*                                                                       61187817
SVCLOF   EQU   *                                                        61188417
         MVC   CCTPWKA(LPARM),SVCPARM  PUT SVC LIST INTO WORKAREA       61189017
         MVC   CCTPWKA(FOUR),PLOG  MOVE CONSTANT FOR LOGOFF INTO LIST   61189617
         MVC   CCTPWKA+DUNIT(THREE),CCTUNIT  PUT UNIT ADDRESS INTO LIST 61190217
         LR    RPAR1,RCCT        SET POINTER TO CCT                     61190417
         LA    RPAR0,CCTPWKA       GET POINTER TO LIST                  61190617
         SVC   80                 INFORM GFX                            61190817
         L     RWKARPTR,CCTTIME    GET COMM PARAM LIST ADDRESS     EXTR 61191019
         L     RMSGADRS,0(RWKARPTR)     POINTER TO ECB             EXTR 61191219
         TM    ZERO(RMSGADRS),HEX10      IS THIS FAST STOP              61191417
         BZ    CRETURN       IF NOT, BRANCH TO NORMAL RETURN            61191617
         CLC   CCTCCR(THREE),LOF    IS PROCESSOR LOGOFF                 61191817
         BE    CRETURN            IF YES, GO TO RETURN                  61192017
         CLC   CCTCCR(THREE),BEG  IS PROCESSOR BEGIN JOB                61192217
         BE    CRETURN            IF YES, GO TO RETURN                  61192417
FASTSTOP CLI   CCTSTAT,D           WAS PROCESSOR LOADED                 61193217
         BNE   GOSCH               IF NOT, BRANCH                       61193817
         DELETE EPLOC=(RWKAREA)    YES, DELETE PROCESSOR                61194417
GOSCH    MVC   CCTCWKA(EIGHT),SCHMOD  PUT SCHEDULAR NAME IN WORKAREA    61195017
         LR    RPAR1,RCCT          SET CCT ADDRESS                      61195617
         O     RPAR1,HBITON        SIGNAL LOGOFF TIME                   61196217
         LA    RPAR0,HEX1C        SET REG0 TO HEX 1C                    61196517
         LA    RBR,CCTPWKA+SUPLIST  LOAD ADDRESS OF PARAMETER LIST      61196817
         MVI   ZERO(RBR),HEX00     CLEAR AREA                           61197417
         MVC   ONE(SEVEN,RBR),ZERO(RBR)  FOR PARAMETER LIST             61198017
         LINK  EPLOC=(RWKAREA),MF=(E,(1)),SF=(E,(15))  GO TO IKASCH     61198617
         B     CRETURN             BRANCH TO RETURN                     61199217
         EJECT                                                          61200017
CFORBCK  EQU   *                                                        62200017
         MVC   CCTPWKA(LPARM),SVCPARM MOVE PARMLIST INTO WORKAREA       63400017
         MVC   CCTPWKA+DUNIT(THREE),CCTUNIT  PUT LINE ADDRSS IN LIST    63600017
         LA    RWORK,CCTPWKA+NUMBER  GET ADDRESS OF AN AREA             63800017
         N     RWORK,DOUBLE        PUT IT ON DOUBLE WORD BOUNDRY        64000017
         LH    RMISC,CCTJCTR      GET JOB COUNT                         64200017
         CVD   RMISC,ZERO(RWORK)   CONVERT IT TO DECIMAL                64300017
         UNPK  CCTPWKA+SVNTYTWO(FIVE),FIVE(THREE,RWORK)  CHANGE TO EBC  64400017
         OI    CCTPWKA+SVNTYSIX,HEXF0   CHANGE LOW ORDER ZONE           64500017
         MVC   CCTPWKA+JOBCOUNT(FOUR),CCTPWKA+SVNTYTHR  PUT IN SVC LIST 64600017
         MVC   CCTPWKA+EXTNOTE(FOUR),CCTENOTE  PUT EXT NOTE IN LIST     64700017
         TM    CCTPSTAT,HEX10      IS THIS BACKGROUND JOB               64800017
         BC    1,BACKGD           BRANCH IF YES                         65320017
         MVI   CCTPWKA+FBCKGRND,HEX00   SET FG INDICATOR                65370017
SVC80    TM    CCTSSTAT,HEX40      IS EXT1 CURRENT DATA SET             65420017
         BZ    LDCCTADD           IF NOT, BRANCH                        65480017
         OI    CCTPWKA+EXTNOTE+THREE,HEXF0  INDICATE CURRENT DATA SET   65520017
LDCCTADD EQU   *                                                        65560017
         LR    RPAR1,RCCT          ADDRESS OF CCT AND                   65600017
         LA    RPAR0,CCTPWKA       ADDRESS OF PARAM LIST FOR SVCROUTINE 65800017
         SVC   80                  ISSUE SVC ROUTINE                    66000017
         TM    CCTPSTAT,HEX10      IS THIS BACKGROUND JOB               66060017
         BC    1,BACKGRND         BRANCH IF YES                         66120017
CRETURN  L     RSAVE,CCTCSAVE+FOUR   RESTORE REGISTER 13                66220017
         LR    RPAR1,RCCT          CCT ADDRESS                          66400017
         LA    RWORK,EIGHT         SET UP REGISTER WITH 8               66500017
         SR    RPAR1,RWORK         DECREMENT CCT ADDR BY 8              66600017
         L     RPAR0,ZERO(RPAR1)   GET LENGTH OF CCT                    66700017
         FREEMAIN R,LV=(0),A=(1)   FREE CORE                            67000017
         RETURN   (14,12),RC=0     RETURN TO OS                         67400017
*                                                                       67600017
* IT IS A BACKGROUND JOB                                                67800017
*                                                                       68000017
BACKGD   MVI   CCTPWKA+FBCKGRND,HEXFF   PUT BG CODE IN SVC LIST         68060017
         B     SVC80              BRANCH TO ISSUE SVC 80                68120017
BACKGRND MVI   CCTJDCBP,HEX80      SET OPTION BYTE FOR CLOSE            68320017
         LA    RPAR1,CCTJDCBP      LOAD PARAMETER ADDRESS               68600017
         CLOSE MF=(E,(1))                                               68800017
         MVI   CCTJDCBP,HEX83      SET OPTION BYTE FOR OPEN             69000017
         LA    RPAR1,CCTJDCBP      LOAD PARAMETER ADDRESS               69200017
         OPEN  MF=(E,(1))                                               69400017
         MVI   CCTJDCBP,HEX00      CLEAR OPTION BYTE                    69600017
         LA    RPAR0,NOTE1         NOTE NUMBER ADDRESS                  69800017
         L     RPAR1,CCTEDCBP      DCB ADDRESS                          70000017
         POINT (1),(0)                                                  70200017
         LOAD  EP=IKDNUC                                                71600017
         LR    RNUC,RPAR0          GET ADDRESS OF LOADED ROUTINE        71800017
         MVC   CCTIORP(FOUR),ZERO(RNUC)    PUT ADDRESSES OF IKDIOR,     71900017
         MVC   CCTMSGP(FOUR),FOUR(RNUC)    IKDMSG,                      72000017
         MVC   CCTJCLGP(FOUR),EIGHT(RNUC)                               72100017
         MVC   CCTDIARP(FOUR),TWELVE(RNUC) IKADIA &                     72200017
         MVC   CCTGEND(FOUR),SIXTEEN(RNUC) IKASGD IN CCT                72300017
         LOAD  EP=IKAIERR         GET ERROR ROUTINE IN CORE             72840017
         ST    RPAR0,CCTIERRP      PUT ADDRESS IB CCT                   72880017
         LA    RPAR0,TWELVE       SET INIT PSWD CODE TO TWELVE          72890017
         ST    RPAR0,CCTIELST     PUT INTO CCT                          72900017
         LA    RPAR0,SIXTEEN       SET INITIALIZATION CODE              72920017
         BAL   RBAL,CREQIO        GO TO INITIALIZE PTOP                 72960017
         OI    CCTPSTAT,HEXC0      REINITIALIZE                         73160017
         NI    CCTPSTAT,HEXCF      CCTPSTAT                             73360017
         MVI   CCTDISM,HEX00       RESET DISM                           73560017
         MVI   CCTCSM,HEX21        RESET COMMAND SELECT MASK            73760017
         B     CBEGN               GET A PSR                            73960017
         EJECT                                                          74400017
*                                                                       74600017
*      THE FOLLOWING CODE SETS UP FOR AND PERFORMS THE BRANCH TO THE    74800017
*      I/O ROUTINE TO WRITE TO THE 1130 SYSTEM                          75000017
*                                                                       75200017
CWRITE   EQU   *                                                        75400017
         LA    RPAR0,CWRCODE            CODE FOR WRITE                  75600017
         ST    RWORK,CCTRECLN           UPDATE CCT WITH LENGTH          76000017
CREQIO   EQU   *                                                        76600017
         L     RBR,CCTIORP         ADDRESS OF I/O ROUTINE               76800017
         LR    RPAR1,RCCT          ADDRESS OF CCT                       77000017
         BALR  RRET,RBR            GO TO I/O ROUTINE                    77200017
         LTR   RBR,RBR             WAS IKAIERR ENTERED                  77300017
         BNE   FASTSTOP            IF YES, BRANCH TO RETURN             77400017
         BR    RBAL                RETURN TO CALLER                     77500017
         EJECT                                                          77600017
*                                                                       77604017
* THIS SUBROUTINE MOVES ANY MESSAGES FROM THE PROCESSOR WORKAREA,       77608017
* AND PLACES THEM INTO THE T/O BUFFER FROM WHICH THEY WILL BE SENT TO   77612017
* THE 1130 SUBSYSTEM TO BE DISPLAYED.                                   77616017
*                                                                       77620017
PROCMSG  LA    RWKARPTR,CCTPWKA    SET POINTER TO PROCESSOR WORKAREA    77624017
TESTLAST TM    ZERO(RWKARPTR),HEXC0  TEST FOR LAST MESSAGE              77628017
         BM    NOTLAST             NOT LAST, SO BRANCH                  77632017
         MVI   CCTPSTAT+ONE,HEX00       TURN OFF MSG SWITCH             77636017
NOTLAST  L     RMSGADRS,ZERO(RWKARPTR)  GET MESSAGE ADDRESS             77640017
         SLL   RMSGADRS,TWO             SHIFT OUT OPTION BYTE           77644017
         SRL   RMSGADRS,TWO             RESTORE POSITION                77648017
         SR    RLCHAR,RLCHAR       CLEAR LENGTH OF MESSAGE REGISTER     77652017
         IC    RLCHAR,ZERO(RMSGADRS)    GET LENGTH OF MESSAGE           77656017
         MVC   ONE(ONE,RBUFF),ZERO(RMSGADRS)  PUT LENGTH INTO BUFFER    77660017
         CLI   CCTPSTAT+ONE,HEX00   IS THIS LAST MESSAGE                77664017
         BE    SETLAST              IF YES, BRANCH                      77668017
         MVI   ZERO(RBUFF),HEX00    INDICATE NOT LAST MESSAGE           77672017
         B     MOVEMSG              BRANCH                              77676017
SETLAST  MVI   ZERO(RBUFF),HEX80    INDICATE LAST MESSAGE               77680017
MOVEMSG  LA    RBUFF,TWO(RBUFF)     SET BUFFER POINTER TO NEXT LOCATION 77684017
         LA    RLNTH,TWO(RLNTH)     INCREMENT LENGTH BY TWO             77688017
         BCTR  RLCHAR,ZERO          DECREMENT COUNT BY ONE              77692017
         EX    RLCHAR,MOVEDATA     EXECUTE MOVE TO PUT DATA INTO BUFFER 77696017
         LA    RLCHAR,ONE(RLCHAR)   INCREMENT BY ONE                    77700017
         AR    RBUFF,RLCHAR        SET BUFFER POINTER TO NEXT LOCATION  77704017
         AR    RLNTH,RLCHAR        SET CURRENT LENGTH                   77708017
         TM    ZERO(RMSGADRS),HEX01 IS COUNT ODD OR EVEN                77712017
         BZ    EVENCT              COUNT IS EVEN, BRANCH                77716017
         MVI   ZERO(RBUFF),HEX40   PUT BLANK IN BUFFER                  77720017
         LA    RBUFF,ONE(RBUFF)    INCREMENT PTR BY ONE                 77724017
         LA    RLNTH,ONE(RLNTH)    INCREMENT LENGTH BY ONE              77728017
EVENCT   CLI   CCTPSTAT+ONE,HEX00  WAS THIS LAST MESSAGE                77732017
         BE    RTRN                BRANCH TO RETRUN                     77736017
         LA    RWKARPTR,FOUR(RWKARPTR)  INCREMENT PTR TO NEXT MESSAGE   77740017
         B     TESTLAST            BRANCH TO CONTINUE                   77744017
RTRN     BR    RBAL                RETURN TO CALLER                     77748017
*                                                                       77756017
MOVEDATA MVC   ZERO(ZERO,RBUFF),ONE(RMSGADRS)  MOVE MESSAGE             77760017
*                                                                       77764017
         EJECT                                                          77768017
*                                                                       77800017
*      CONSTANTS AND DSECT FOR CONSOLE CONTROL TABLE                    78000017
*                                                                       78200017
PROMODEL DC    C'IKAPLON0'         PROCESSOR MODEL NAME                 78290017
LOGN     DC    C'LON'              LOGON KEY                            78380017
BEG      DC    C'BEG'              BEGIN JOB KEY                        78470017
SPE      DC    C'SPE'              SPECIFY JOB STEP COMMANDLKEY         78560017
PLOG     DC    C'PLOG'            SVC CODE FOR LOGOFF                   78650017
SCHMOD   DC    C'IKASCH  '         SCHEDULAR INTERFACE MODULE NAME      78740017
LOF      DC    C'LOF'       CONSTANT FOR LOGOFF PROCESSOR               78860017
CAN      DC    C'CAN'     CONSTANT FOR CANCEL JOB                       78920017
COKMESSG DC    C'EXOK'             OK MESSAGE                           78940017
LFMSG    DC    C'LF'               LOGOFF MSG                           79060017
JLMSG    DC    C'JOBLIB'          JOBLIB MESSAGE                        79120017
WRI      DC    C'WRI'              KEY FOR WRITE MSG                    79140017
REC      DC    C'REC'             RECALL COMMAND KEY                    79150017
NONE     DC    C'NONE'             NONE MESSAGE                         79160017
         DS    0F                                                       79200017
NOTE1    DC    X'00000001'         NOTE NUMBER                          79400017
HBITON   DC    X'80000000'         HI BIT MASK                          79600017
DOUBLE   DC    X'FFFFFFF8'         DOUBLE WORD BOUNDARY MASK            79800017
CANC     DC    H'12'              CANCEL RETURN CODE                    79900017
*                                                                       80000017
* PARAMETER LIST TO PASS TO SVC ROUTINE                                 80200017
*                                                                       80400017
SVCPARM  DS    0F                                                       80600017
SVCCODE  DC    C'PBEG'             CODE FOR BEGIN JOB                   80800017
SVCINFTN EQU   *                                                        81000017
SVCUNIT  DC    F'0'                LINE ADDRESS                         81200017
SVCJBCNT DC    F'0'                JOB COUNTER                          81400017
SVCENOTE DC    F'0'                NOTE NUMBER                          81600017
SVGFBCK  DC    X'00'               FORE OR BACKGROUND JOB               81800017
SVCEND   EQU   *                                                        82000017
LPARM    EQU   SVCEND-SVCPARM      LENGTH OF SVC PARAMETER LIST         82200017
*                                                                       82400017
* PARAMETER LIST TO PASS TO INTERNAL ERROR ROUTINE                      82401017
*                                                                       82402017
         DS    0F                                                       82403017
MSG11    DC    CL3'011'           MESSAGE NUMBER                        82404017
         DC    CL5'CTL  '         MODULE KEY WORD                       82405017
         DC    X'40'              CONTROL BITS                          82406017
         DC    AL3(OCTMESG)        ADDRESS OF MESSAGE                   82407017
*                                                                       82408017
OCTMESG  DC    H'4'           LENGTH OF ENTRY                           82409017
         DC    C'UNIT'        CONSTANT                                  82410017
IERRPAR  EQU   *                                                        82411017
MSGNO    DC    CL3'039'       MSG NO                                    82412017
         DC    CL5'CTL  '     IDENTIFIER                                82413017
         DC    X'00'          STATUS BIT                                82414017
         DC    XL4'00000000'  SPACE FOR POINTER                         82415017
         EJECT                                                          82416017
CVT      DSECT                                                          82417017
         CVT   SYS=VMS                                                  82418017
*                                                                       82419017
* GFX LIST POINTED TO BY CVT                                            82420017
*                                                                       82421017
GRAPLIST DSECT                                                          82422017
GOCT     DS    1F             POINTER TO OCT                            82423017
GGAPR    DS    1F             POINTER TO GAPR                           82424017
GCANC    DS    1F             POINTER TO CANCEL ROUTINE                 82425017
GFXOCTHD DSECT                                                          82426017
GFXHDSTR EQU   *                       START OF HEADER RECORD           82427017
OCTSYS   DS    CL1                     BASE SYSTEM                      82428017
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                82429017
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          82430017
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       82431017
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       82432017
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              82433017
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              82434017
         DS    0H                                                       82435017
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             82436017
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       82437017
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       82438017
         DS    0F                                                       82439017
OCTFGREG DS    CL4                      REGION SIZE GJP                 82440017
OCTFUREG DS    CL4                      REGION SIZE USER FGD            82441017
OCTBUREG DS    CL4                      REGION SIZE USER BGD            82442017
OCTHRES  DS    CL8                      RESERVED                        82443017
OCTNAME  DS    CL20                     PROGRAMMER NAME                 82444017
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  82445017
GFXHDEND EQU   *                       END OF HEADER RECORD             82446017
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        82447017
         EJECT                                                          82448017
GFXOCTEN DSECT                                                          82449017
         DS    0F                                                       82450017
GFXENSTR EQU   *                       START OF ENTRY RECORD            82451017
OCTECB   DS    CL4                      ECB                             82452017
OCTUCB   DS    CL4                      UCB ADDRESS                     82453017
OCTUNIT  DS    CL4                      UNIT ADDRESS                    82454017
OCTCOUNT DS    CL4                      JOB COUNT                       82455017
OCTNOTE  DS    CL4                      NOTE                            82456017
OCTABEND DS    A                       ABEND CODE                       82457017
OCTRESD  DS    CL8                      RESERVED                        82458017
**********************************************************************  82459017
****                          ATTRIBUTE 1                          **** 82460017
**********************************************************************  82461017
OCTATTR1 DS    CL2                      ATTRIBUTES                      82462017
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         82463017
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   82464017
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         82465017
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       82466017
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   82467017
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  82468017
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  82469017
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           82470017
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          82471017
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   82472017
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           82473017
**********************************************************************  82474017
****                          ATTRIBUTE 2                          **** 82475017
**********************************************************************  82476017
OCTATTR2 DS    CL2                      ATTRIBUTES                      82477017
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  82478017
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      82479017
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              82480017
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           82481017
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         82482017
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           82483017
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       82484017
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            82485017
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82486017
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  82487017
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        82488017
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         82489017
**********************************************************************  82490017
****                          ATTRIBUTE 3                          **** 82491017
**********************************************************************  82492017
OCTATTR3 DS    CL2                      ATTRIBUTES                      82493017
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  82494017
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      82495017
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              82496017
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           82497017
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         82498017
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           82499017
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       82500017
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            82501017
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  82502017
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  82503017
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        82504017
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         82505017
**********************************************************************  82506017
****                          ATTRIBUTE 4                          **** 82507017
**********************************************************************  82508017
OCTATTR4 DS    CL2                      ATTRIBUTES                      82509017
*                                                                       82510017
GFXENEND EQU   *                       END OF ENTRY RECORD              82511017
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             82512017
         EJECT                                                          82513017
         EJECT                                                          82600017
*                                                                       82800017
         END                                                            83000017
./       ADD   SSI=02013294,NAME=IKDINIT,SOURCE=0
IKDINIT  CSECT                                                          00100017
*3302,076800,078000                                               3052  00150000
*3302,160100-160500,168390,220200,220800,221400-221700,455480-     R001 00160018
*     455680,498400,498540                                         R001 00170018
 TITLE 'IKDINIT' INITIALIZATION ROUTINE FOR SGJP                        00200017
*STATUS: CHANGE LEVEL 0                                               * 00400017
*FUNCTION/OPERATION: PERFORMS INITIALIZATION FUNCTIONS FOR SATELLITE  * 00500017
*   GRAPHIC JOB PROCESSOR IN SYSTEM/360. IT'S OPERATIONS INCLUDE:     * 00600017
*   1)ISSUE GETMAIN FOR CONSOLE CONTROL TABLE, BTAM BUFFER AND THE JCL* 00700017
*   EXTRACT AND RECORD DCB'S                                          * 00800017
*   2)OPENS JCL AND EXTRACT DCB'S                                     * 00900017
*   3)INITIALIZES CONSOLE CONTROL TABLE                               * 01000017
*   4)LOAD ROUTINES WHICH WILL BE RESIDENT IN SGJP PARTITION.         * 01100017
*   5)IF ENTERED PRIOR TO LOGON SEND 'SESSION SYNC' MESSAGE TO 1130;  * 01200017
*   IF ENTERED AFTER BEGIN JOB, SEND JOB SYNC MESSAGE                 * 01300017
*   6)IF PREVIOUS JOB WAS PROCESSED IN THE FOREGROUND, GET THE 1130   * 01400017
*   PROGRAM NAME AND BRANCH TO IKADIA FOR ITS INCLUSION ONTO THE      * 01500017
*   RECORD DATA SET.                                                  * 01600017
*ENTRY POINTS: ENTERED AT IKDINIT FROM OPERATING SYSTEM VIA LINK      * 01700017
*   EXECUTED VIA GFX.                                                 * 01800017
*INPUT: 1)REGISTER 1 POINTS TO A PARAMETER LIST CONAINING INFORMATION * 01900017
*   NECESSARY TO INITIATE THE ADDRESS OF THE TELECOMMUNICATION LINE   * 02000017
*   (CCTUNIT), SYSOUT CLASS (CCTSOUT) AND GROUP OR PRIORITY DATA FOR  * 02100017
*   FOREGROUND OR BACKGROUND JOB(CCTFRPRI)&(CCTGRPRI); ALSO, A        * 02200017
*   PARAMETER INDICATING ENTRY PRIOR TO LOGON OR AFTER BEGIN JOB IS   * 02300017
*   RECEIVED.                                                         * 02400017
*   2)SYNCHRONIZATION MESSAGES FROM 1130 SYSTEM.                      * 02500017
*   3)1130 PROGRAM NAME IF PREVIOUS JOB WAS FOREGROUND.               * 02600017
*OUTPUT: 1)SYNCHRONIZATION MESSAGE FOR SUBSYSTEM                      * 02700017
*   2)HISTORY RECORD FOR IKADIA                                       * 02800017
*   3)CODE IN REGISTER 0 FOR IKDIOR. X'00'=INITIALIZE X'04'=READ X'08'* 02900017
*   4)CODE IN REGISTER0 FOR IKDCTL  X'04'=LOGON  X'08'=BEGIN JOB      * 03000017
*   =WRITE                                                              03100017
*   5)ADDRESS OF CCT IN REGISTER 1 FOR IKDCTL,IKDIOR OR IKADIA        * 03200017
*EXTERNAL ROUTINES: IKDIOR FOR I/O OPERATIONS,IKDIA FOR HISTORY       * 03300017
*EXITS: 1)BRANCH TO IKDIOR FOR READ/WRITE REQUESTS                    * 03500017
*       2)BRANCH TO IKADIA FOR HISTORY ENTRIES                        * 03600017
*       3)XCTL TO CONTROL UPON COMPLETION OF INITIALIZATION FUNCTIONS * 03700017
*TABLES/WORKAREAS: CCT AND I/O BUFFER.                                * 03800017
*ATTRIBUTES: TRANSIENT, REENTRANT                                     * 03900017
*NOTES: N/A                                                           * 04000017
         EJECT                                                          04200017
*                                                                       04300017
*     GENERAL REGISTERS AND EQUATES                                     04400017
*                                                                       04500017
RPAR0    EQU   0                        PARAMETER REGISTER              04600017
RPAR1    EQU   1                        PARAMETER REGISTER              04700017
RCCT     EQU   2                        BASE FOR CCT DCB ETC            04800017
RBUFF    EQU   3                                                        04900017
RWORK    EQU   4                        GENERAL PURPOSE                 05000017
ROPEN    EQU   5                        REGISTER FOR OPEN MACRO         05200017
RNUC     EQU   6                                                        05300017
RBAL     EQU   6                                                        05350017
RLENGTH  EQU   7                                                        05400017
RINCR    EQU   8                       INCREAMENT REGISTER              05500017
REND     EQU    9                      ADDRESS OS END OF GETMAIN        05600017
RBEGIN   EQU   10                       ADDRESS OF GETMAIN              05700017
RBASE    EQU   11                       BASE REGISTER                   05800017
RSAVE    EQU   13                                                       05900017
RRET     EQU   14                       RETURN REGISTER                 06000017
RBR      EQU   15                       BRANCH REGISTER                 06100017
*                                                                       06200017
ZERO     EQU   0                   ZERO                                 06240017
READCODE EQU   0                                                        06280017
ONEEQU   EQU   1                   ONE                                  06320017
TWOEQU   EQU   2                   TWO                                  06360017
EXTNOTE  EQU   2                        POINTER TO NOTE OF EXT DCB      06400017
THREE    EQU   3                   THREE                                06440017
FOUR     EQU   4                   FOUR                                 06480017
FIVE     EQU   5                   FIVE                                 06520017
NAMEL    EQU   5                                                        06560017
UNITADDR EQU   6                        POINTER TO GRAPHIC 255 ADDRESS  06600017
NAMELNTH EQU   6                                                        06640017
EIGHT    EQU   8                   EIGHT                                06680017
NINE     EQU   9                   NINE                                 06720017
SYSOUTCL EQU   9                        POINTER TO SYSOUT CLASS         06760017
TWELVE   EQU   12                  TWELVE                               06800017
CTLCHAR  EQU   12                                                       06840017
FGRPRI   EQU   13                       POINTER TO GROUP (MFT-II) OR    06880017
*                                       PRIORITY (MVT) FOR GJP AND PROG 06920017
FIFTEEN  EQU   15                  FIFTEEN                              06960017
BGRPRI   EQU   15                       POINTER TO GROUP OR PRIORITY    07000017
*                                       FOR GJP OR USER PROG BACKGROUND 07040017
SIXTEEN  EQU   16                  SIXTEEN                              07080017
INITCODE EQU   16                                                       07120017
JOBCTR   EQU   17                       JOB COUNTER                     07160017
NINETEEN EQU   19                  NINETEEN                             07200017
TERMCODE EQU   20                                                       07210017
SYS      EQU   29                                                       07220017
XX       EQU   20             DISPLACEMENT IN TCB FOR ABEND HOOK FLAG   07230017
EODADDR  EQU   33                       EOD ADDRESS IN DCB              07240017
THTYTHRE EQU   33                  THIRTY THREE                         07280017
DSREFNO  EQU   99                                                       07320017
HUNDRED  EQU   100                 HUNDRED                              07360017
ONTWSEVN EQU   127                 ONE HUNDRED TWENTY SEVEN             07400017
ONTHFIVE EQU   135                 ONE HUNDRED THIRTY FIVE              07440017
LRECORD  EQU   356                      LENGTH OF PER EXTRACT RECORD    07480017
DBLEZERO EQU   X'00'               HEX ZERO                             07520017
HEX01    EQU   X'01'               HEX ONE                              07560017
HEX08    EQU   X'08'               HEX ZERO EIGHT                       07600017
GOODOPEN EQU   X'10'          USED TO TEST OPEN                         07640017
EODAD    EQU   X'21'               END OF DATA ADDR                3052 07680000
BITTWO   EQU   X'20'               HEX TWENTY                           07720017
HEX21    EQU   X'21'               HEX TWENTY ONE                       07760017
SYNAD    EQU   X'39'               SYNCHRONOUS ERROR ADDR          3052 07800000
HEX40    EQU   X'40'               HEX FOUR ZERO                        07840017
BLANK    EQU   X'40'               BLANK                                07880017
HEX80    EQU   X'80'               HEX EIGHT ZERO                       07920017
HEXC0    EQU   X'C0'               HEX C ZERO                           07960017
HEXF0    EQU   X'F0'               HEX F ZERO                           08000017
FF       EQU   255                 EQUATE FOR BIT MANIPULATION          08050017
         EJECT                                                          08100017
*                                                                       08200017
* SAVE GENERAL REGISTERS, SET BASE, GET CORE FOR SGJP WORKAREA          08300017
*                                                                       08400017
         SAVE  (14,12)                  SAVE GENERAL REGISTERS          08500017
         BALR  RBASE,0                  SET UP BASE                     08600017
         USING *,RBASE                                                  08700017
RCVT     EQU   3                                                        08800017
ROCT     EQU   12                                                       08900017
         USING INITWKA,RCCT        DSECT FOR CCT                        09000017
         USING DCVT,RCVT           DSECT FOR CVT                        09100017
         L     RCVT,CVTPTR              SET BASE FOR CVT                09110017
         L     RWORK,CVTTCBP            GET ADDR OF TCB POINTER         09120017
         L     RWORK,FOUR(RWORK)        ADDR OF TCB                     09130017
         OI    XX(RWORK),BITTWO         FLAG BIT IN TCB                 09140017
*                                       FOR ABEND ROUTINE               09150017
         LR    RWORK,RPAR1         SAVE ADDR PARM LIST                  09200017
         GETMAIN R,LV=INITWKAE-INITWKA  GETMAIN FOR CCT                 09300017
         LR    RCCT,RPAR1              LOAD GETMAIN ADDRESS             09400017
         L     RLENGTH,LWKA             LOAD GETMAIN LENGTH             09500017
         LR    RBEGIN,RPAR1             LOAD START ADDRESS              09600017
         LA    REND,ZERO(RBEGIN,RLENGTH)  LOAD END ADDRESS              09700017
         LA    RINCR,EIGHT         SET INCREMENT                        09800017
         SR    REND,RINCR              SUBTRACT 8                       09900017
CLEAR    XC    ZERO(EIGHT,RBEGIN),ZERO(RBEGIN)   CLEAR GETMAIN AREA     10000017
         BXLE  RBEGIN,RINCR,CLEAR       CHECK IF FINISH CLEAR JOB       10100017
         ST    RLENGTH,LSAVE1           SAVE GETMAIN LENGTH AT THE      10400017
*                                       FIRST WORD OF GETMAIN AREA      10500017
         ST    RSAVE,ISAVE+FOUR    SAVE CALLING SAVE ADDRESS            10600017
         LA    RSAVE,SAVE2        ADDR SAVE AREA FOR INIT               10700017
*                                                                       10800017
MINUSONE EQU   X'FFF0'                                                  10830017
         CHAP  MINUSONE            CHANGE PRIORITY                      10860017
* GET ADDR OF OCT HEADER AND ENTRY RECORD AND SAVE THEM IN CCTWKA       10900017
*                                                                       11000017
         ST    RWORK,ADPARM        SAVE ADDR PARAMETER LIST             11100017
         LA    RWORK,ANSWAREA           ANSWER AREA ADDRESS        EXTR 11110019
         LA    RPAR1,EXTRCT             LIST FORM ADDRESS          EXTR 11120019
         EXTRACT (RWORK),FIELDS=COMM,MF=(E,(1))                    EXTR 11130019
         L     RWORK,ANSWAREA           POINTER TO COMM.PARM.LIST  EXTR 11140019
         ST    RWORK,CCTTIME                                            11150017
         L     RWORK,FOUR(RWORK)        GET CIB ADDRESS            EXTR 11220019
       LR    RINCR,RWORK          ADDR CIB                              11300017
         LA    RINCR,ONTWSEVN(RINCR)  SET ADDRESS OF END OF CIB         11400017
SCANCIB  CLC   ZERO(NINE,RWORK),ENTRYEQU  SCAN CIB FOR OCT HEADER       11500017
         BE    FOUNDADR            FOUND 'OCTENTRYE' IN CIB             11600017
         LA    RWORK,ONEEQU(RWORK)  NOT FOUND INCREMENT BY ONE          11700017
         CR    RINCR,RWORK        Q. END OF CIB                         11800017
         BE    NOTINCIB                 YES, ISSUE ERROR MESSAGE        11900017
         B     SCANCIB                  NO, CONTINUE SEARCHING          12000017
NOTINCIB MVC   ERRORMSG(EL),CIBMSG  MOVE IN BAD CIB MESSAGE             12100017
         B     ERRORRTN             ISSUE MESSAGE                       12200017
FOUNDADR L     RCVT,CVTPTR        SET BASE FOR CVT                      12300017
         L     ROCT,CVTQOCR       ADDR LIST OF POINTERS                 12400017
         LTR   ROCT,ROCT                Q. GFX RUNNING             R001 12430018
         BZ    RETURN                   EXIT IF NOT                R001 12460018
         L     ROCT,ZERO(ROCT)     ADDR OCT HEADER                      12500017
         ST    ROCT,ADOCTHD       SAVE ADDR OCT HEADER IN GETMAIN       12600017
         LA    RINCR,FIFTEEN       SET RINCR TO MAX NO OF 2250'S        12700017
         USING GFXOCTHD,ROCT                                            12800017
         TM    OCTSYS,TWOEQU            Q. MFT SYSTEM                   12820017
         BZ    MVT                      NO                              12840017
         OI    CCTDISM,GOODOPEN         TURN ON BIT                     12860017
MVT      EQU   *                                                        12880017
         LA    ROCT,GFXHDSZE(ROCT)  SET BASE FORFIRST OCT ENTRY         12900017
         MVC   CCTUNIT(THREE),NINE(RWORK)    GET DATA SUPPLIED     R001 12930000
*                                       IF NEEDE FOR MSG 059       R001 12960000
         USING GFXOCTEN,ROCT                                            13000017
SCANENT  CLC   NINE(THREE,RWORK),OCTUNIT+ONEEQU IS THIS CORRECT ENTRY   13100017
         BE    FOUNDENT            IF YES, BRANCH                       13200017
         LA    ROCT,GFXENSZE(ROCT)  A. NO    SET BASE FOR NEXT ENTRY    13300017
         BCT   RINCR,SCANENT       CONTINUE SCAN                        13400017
         B     NOTINCIB            BRANCH TO PREPARE ERROR MESSAGE      13500017
FOUNDENT ST    ROCT,ADOCTEN                                             13600017
         TM    OCTATTR1,OCTBSTOP        Q. FAST STOP ISSUED             13610017
         BO    FASTSTOP                 YES - TIMING MISS               13620017
         MVC   CCTUNIT(THREE),OCTUNIT+ONEEQU  PUT UNIT ADDR IN CCT      13630017
         OI    CCTSSTAT,BITTWO     INDICATE SGJP IN CCT                 13660017
*                                                                       13700017
*     INITIALIZE  DIARY ROUTINE WORK AREA TO BLANKS                     13800017
*                                                                       13900017
         MVI   CCTDIAWA,BLANK      PROPAGATE BLANKS THROUGH             14000017
         MVC   CCTDIAWA+ONEEQU(ONTHFIVE),CCTDIAWA  WORKAREA             14100017
*                                                                       14700017
* CREATE JCL AND EXTRACT DCB'S                                          14800017
*                                                                       14900017
         MVC   DJCLDCB(LJCLDCB),JCLDCB  MAKE JCLDCB REENTERABLE         15000017
         LA    RWORK,DJCLDCB            LOAD ITS ADDRESS AND            15100017
         ST    RWORK,CCTJDCBP           STORE IT IN CCT                 15200017
*                                                              CCTDDCBP 15300017
         MVC   DEXTDCB(LEXTDCB),EXTDCB  MAKE EXTDCB REENTERABLE         15400017
         LA    RWORK,DEXTDCB            LOAD ITS ADDRESS AND            15500017
         ST    RWORK,CCTEDCBP           STORE IT IN CCT                 15600017
*                                                              CCTEDCBP 15700017
         MVC   DEXTDCB1(LEXTDCB1),EXTDCB1 MAKE EXT DCB1 REENTERABLE     15800017
         LA    RWORK,DEXTDCB1           LOAD ITS ADDRESS AND            15900017
         ST    RWORK,CCTEDCB1           STORE ITS ADDRESS IN CCT        16000017
*                                                                       16100017
* OPEN JCL AND EXTRACT DCB'S                                            16200017
*                                                                       16300017
         MVC   DOPENDCB(LOPEN),OPENDCB  MAKE OPEN MACRO REENTERABLE     16400017
         LA    RPAR1,DOPENDCB           LOAD ITS ADDRESS                16500017
         OPEN  (DJCLDCB,(INOUT),DEXTDCB,(INOUT),                       C16600017
               DEXTDCB1,(INOUT)),MF=(E,(1))                             16700017
         EJECT                                                          16800017
         USING IHADCB,RWORK        USE RWORK AS BASE TO CHECK OPEN      16803017
*                                                                       16806017
CHECK1   LA    RWORK,DJCLDCB       CHECK JCL DCB                        16809017
         TM    DCBOFLGS,GOODOPEN   OPEN FLAGS                           16812017
         BO    CHECK2              OPEN OK                              16815017
         MVC   ERRORMSG(EL),DCBMSG  SET DCB MSG                         16818017
         MVC   ERRORDCB(EE),DCBMSG2 AS JCL DCB ERROR                    16821017
         B     ERRORRTN             GO TO ERROR EXIT                    16824017
CHECK2   LA    RWORK,DEXTDCB       CHECK EXT DCB                        16827017
         TM    DCBOFLGS,GOODOPEN   OPEN FLAGS                           16830017
         BO    CHECK4              OPEN OK                              16833017
         MVC   ERRORMSG(EL),DCBMSG  SET DCB MSG                         16836017
         MVC   ERRORDCB(EE),DCBMSG1     FOR EXT DCB ERROR          R001 16839018
         B     ERRORRTN             GO TO ERROR EXIT                    16842017
CHECK4   LA    RWORK,DEXTDCB1      CHECK RECALL MODE EXT DCB            16845017
         TM    DCBOFLGS,GOODOPEN   OPEN FLAGS                           16848017
         BO    CHECKEND            OPEN OK                              16851017
         MVC   ERRORMSG(EL),DCBMSG  SET DCB MSG                         16854017
         MVC   ERRORDCB(EE),DCBMSG4 AS RECALL DCB ERROR                 16857017
         B     ERRORRTN             GO TO ERROR EXIT                    16860017
CHECKEND EQU   *                                                        16863017
         DROP  RWORK                                                    16866017
         MVC   EODADDR+DEXTDCB1(THREE),EODRTN  PUT ADD OF END OF DATA   16869017
         MVC   SYNAD+DEXTDCB1(THREE),IORTN     PUT ADDR OF SYNCH ERROR  16872017
         EJECT                                                          16875017
*                                                                       16900017
*     LOAD RESIDENT ROUTINES AND PUT THEIR ADDRESSES IN CCT             17000017
*                                                                       17100017
         LOAD  EP=IKAIERR         LOAD IKAIERR                          17130017
         ST    RPAR0,CCTIERRP     PUT IT'S POINTER IN CCT               17160017
         LOAD  EP=IKDNUC                                                17200017
         LR    RNUC,RPAR0               GET NUCLEUS ADDRESS             17300017
         MVC   CCTIORP(FOUR),ZERO(RNUC)    PUT POINTERS TO I/O ROUTINE, 17400017
         MVC   CCTDMRP(FOUR),FOUR(RNUC)    MESSAGE ROUTINE,             17500017
         MVC   CCTJCLGP(FOUR),EIGHT(RNUC)  JCL GENERATOR,               17600017
         MVC   CCTDIARP(FOUR),TWELVE(RNUC) DIARY ROUTINE                17700017
         MVC   CCTGEND(FOUR),SIXTEEN(RNUC) AND SYSGEN DATA IN CCT       17800017
         EJECT                                                          20700017
*                                                                       20800017
*     FILL CCT WITH INFORMATION RECEIVED FROM GFX                       20900017
*                                                                       21000017
RRECNO   EQU   7                        CONTAIN THE NUMBER OF RECORDS   21100017
*                                       TO BE READ                      21200017
RDCBBASE EQU   7                        BASE FOR DIA DCB DSECT          21300017
RAREA    EQU   8                        POINTER TO READ IN AREA         21400017
RLINK    EQU   9                        INTERAL LINK REGISTER           21500017
RJOBCTR  EQU   10                       CONTAIN JOB COUNTER (BINARY)    21600017
RDECB    EQU   10                       POINTER TO READ DECB            21700017
         L     ROCT,ADOCTEN        LOAD ADDR OCT ENTRY                  21800017
         USING GFXOCTEN,ROCT       DSECT FOR OCT ENTRY RECORD           21900017
         TM    OCTATTR1+ONEEQU,OCTERR1  TEST ERROR BIT                  21910017
         BO    FILLCCT                  IF ERROR SIMULATE LOGON         21920017
         TM    OCTATTR2,OCTABND         TEST ABEND BIT                  21930017
         BO    FILLCCT                  IF ABEND SIMULATE LOGON         21940017
         TM    OCTATTR1+ONEEQU,OCTBSMBB  TEST SMB BIT                   21980017
         BO    REX                       BRANCH IF ON                   22000017
         TM    OCTATTR1,OCTBIODQ+OCTBIOGS+OCTBIOGD+OCTBIOUS        R001 22020018
*                                       ANY I/O ERROR BIT IN OCT        22040017
         BC    5,REX                    IF YES, READ EXTRACT INTO CCT   22060017
         TM    OCTATTR2,OCTBFAST+OCTBMED+OCTBSLOW                  R001 22080018
*                                       ANY STOP BITS SET IN OCT        22100017
         BC    5,REX                    IF YES, READ EXTRACT INTO CCT   22120017
         CLC   OCTATTR1(EIGHT),ZEROS8   Q. OCT ENTRY VALID         R001 22130018
         BE    BADSTART                 NO - TERMINATE             R001 22140018
         B     FILLCCT                  GO TO LOG ON               R001 22150018
*                                                                       22180017
**   END IF FAST STOP ISSUED                                            22190017
*                                                                       22200017
FASTSTOP EQU   *                                                        22210017
         MVC   ERRORMSG(EIGHT),KLOF     MOVE IN CONSTANT,               22220017
         MVC   ERRORMSG+FIVE(THREE),OCTUNIT+ONEEQU     UNITNAME         22230017
         LA    RPAR0,ERRORMSG           GET PARAMETERS                  22240017
         SR    RPAR1,RPAR1              ZERO - NO CCT                   22250017
         SVC   80                       INTERFACE                       22260017
         B     RETURN                   END SGJP                        22270017
KLOF     DC    C'PLOG UTN'              CONSTANT                        22280017
         EJECT                                                          22300017
REX      MVC   EODAD+DEXTDCB(THREE),EODRTN   SET UP EOD RTN IN          22320017
         MVC   EODAD+DEXTDCB1(THREE),EODRTN  EXT &EXT1 DCB              22340017
         MVC   SYNAD+DEXTDCB(THREE),IORTN    SET UP SYNCHRONOUS ADDR    22360017
         MVC   SYNAD+DEXTDCB1(THREE),IORTN   IN DCBS                    22380017
*                                                                       22400017
* READ FROM EXTRACT DCB TO CONSOLE CONTROL TABLE (CCT)                  22500017
*                                                                       22600017
         TM    OCTNOTE+THREE,HEXF0    IS RECALL CURRENT EXT DATA SET    22700017
         BC    1,RECALD               BRANCH IF YES                     22800017
         B     NORC                   OTHERWISE BRANCH IF NOT           22900017
RECALD   EQU   *                                                        23000017
         LA    RWORK,IPOINT                                             23100017
         ST    RWORK,CCTPWKA                                            23200017
         NI    OCTNOTE+THREE,HEX01      SET NOTE BIT                    23400017
       MVC   WKAREAD(LREAD),READ1                                       23600017
         MVC   CCTPWKA(FOUR),OCTNOTE    MOVE NOTE INTO WORKAREA         23700017
         LA    RPAR0,CCTPWKA                                            23800017
         L     RPAR1,CCTEDCB1                                           23900017
         LA    RRECNO,TWOEQU       SET A RECNO TO TWO                   24000017
         LA    RAREA,CCT                                                24100017
         POINT (1),(0)                                                  24200017
         LA    RDECB,WKAREAD                                            24300017
READCCT1 READ  (RDECB),SF,DEXTDCB1,(RAREA),,,MF=E                       24400017
         CHECK (RDECB)                                                  24500017
         LA    RAREA,LRECORD(RAREA)                                     24600017
         BCT   RRECNO,READCCT1          GO READ SECOND HALF             24670017
         B     IPOINT                   OR FINISH                       24740017
EODERR   MVC   ERRORMSG(EL),EODMSG1   MOVE END OF DATA MSG              24820017
         B     ERRORRTN               BRANCH TO ERROR EXIT              24840017
SYNCHER  MVC   ERRORMSG(EL),SYNCHM1   MOVE SYNCHRONOUS ERROR MSG        24860017
         B     ERRORRTN               BRANCH TO ERROR EXIT              24880017
NORC     EQU   *                                                        24900017
         LA    RWORK,IPOINT             * SET END OF DATA SET HANDLING  25000017
         ST    RWORK,CCTPWKA            * ROUTINE ADDRESS IN EXTRACT    25100017
         LA    RWORK,DEXTDCB            * DCB                           25200017
         MVC   EODADDR+DEXTDCB(THREE),CCTPWKA+1 PUT EOD SET ADDR IN CCT 25300017
         MVC   WKAREAD(LREAD),READ      MOVE READ IN WORKAREA           25500017
         MVC   CCTPWKA(FOUR),OCTNOTE   PUT NOTE POSITION IN CCT         25600017
         LA    RPAR0,CCTPWKA            POINTING TO NOTE NUMBER         25700017
         L     RPAR1,CCTEDCBP           EXTRACT DCB ADDRESS             25800017
         LA    RRECNO,TWOEQU           LOAD NUMBER OF RECORDS FOR READ  25900017
         LA    RAREA,CCT                LOAD AREA ADDRESS FOR READ      26000017
         POINT (1),(0)                  POINT TO WHERE TO START TO READ 26100017
         LA    RDECB,WKAREAD            LOAD DECB ADDRESS               26200017
READCCT  READ  (RDECB),SF,DEXTDCB,(RAREA),,,MF=E                        26300017
         CHECK (RDECB)                  CHECK FOR READ COMPLETE         26400017
         LA    RAREA,LRECORD(RAREA)     UPDATE AREA ENTRY               26500017
         BCT   RRECNO,READCCT           READ MORE IF NOT FINISH         26600017
IPOINT   TM    CCTSSTAT,HEX40      IS CCTEXT SWITCH ON                  26700017
         MVI   CCTPSTAT+ONEEQU,BITTWO   SET ERROR CODE TO ZERO          26800017
         BC    1,PTDCB1                 BRANCH IF YES                   26900017
         LA   RPAR0,ONE           SET TO POINT TO FIRST EXT RECORD      27000017
         L     RPAR1,CCTEDCBP           DCB ADDRESS                     27100017
         B     POINT                    BRANCH                          27200017
PTDCB1   LA   RPAR0,ONE           SET TO POINT TO FIRST EXT RECORD      27300017
         L     RPAR1,CCTEDCB1           DCB ADDRESS                     27400017
         MVC   CCTEDCB1(FOUR),CCTEDCBP  SWITCH POINTERS                 27500017
         ST    RPAR1,CCTEDCBP                       BACK TO NORMAL      27600017
POINT    POINT (1),(0)                  POINT TO LOCATION FOR READ OR   27700017
         MVC   DEXTDCB+EODADDR(THREE),DEXTDCB1+EODADDR  RESET EODAD ADD 27800017
         MVC   CCTCCR(THREE),BEGKEY    SET KEY WORD IN CCTCCR           27900017
         EJECT                                                          28000017
*                                                                       28100017
         TM    OCTATTR1,OCTBIODQ                                        28200017
         BZ    TESTSMB                  GO TEST SMB                     28300017
         TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   28400017
         BO    DEQSMSG                  YES, GO TO DEQSMSG              28500017
         B     DEQMSG                   NO, GO TO DEQMSG                28600017
TESTSMB  TM    OCTATTR1,OCTBIOUS  Q. WAS THERE AN ERROR IN USER'S SMB   28700017
         BZ    TESTDSB                  GO TEST DSB                     28800017
         TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   28900017
         BO    DSBSMSG                A.YES BRANCH DSBSMSG              29000017
         B     DSBMSG                 N.NO  BRANCH DSBMSG               29100017
TESTDSB  TM    OCTATTR1,OCTBIOGD  Q. WAS THERE AN ERROR IN DSB          29200017
         BZ    TESTMED                  NO, TEST IF MEDIUM STOP         29300017
         TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   29400017
         BO    SMBSMSG                  YES, GO TO SMBSMSG              29500017
         B     SMBMSG                   NO, GO TO SMBMSG                29600017
TESTMED  TM    OCTATTR2,OCTBMED                                         29700017
         BZ    TESTSLOW                 NO, TEST IF SLOW STOP           29760017
         NI    OCTATTR1+1,FF-OCTBSMBB   TURN OFF SMB BIT BECAUSE        29830017
*                                       MEDIUM STOP - NO DISPLAY        29860017
         B     MSTOPMSG                 GO PUT OUT MSG                  29930017
TESTSLOW TM    OCTATTR2,OCTBSLOW  Q. HAS OPERATOR REQUESTED SLOW STOP   30000017
         BO    STOPSMB                  YES, ISSUE LOGOFF REQUEST MSG   30100017
         B     FILLCCT                  RECREATE CCT                    30200017
         EJECT                                                          30500017
*                                                                       30600017
* PRAPARE NECESSARY INFORMATION FOR MESSAGE HANDLING                    30700017
*                                                                       30800017
DEQMSG   EQU   *                                                        30900017
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 31000017
         DC    H'4'                     MESSAGE POINTER DISPLACEMENT    31100017
         B     MSGMODE                  BRANCH                          31200017
DEQSMSG  EQU   *                                                        31300017
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 31400017
         DC    H'8'                     MESSAGE POINTER DISPLACEMENT    31500017
         B     MSGMODE                  BRANCH                          31600017
DSBMSG   EQU   *                                                        31700017
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 31800017
         DC    H'12'                    MESSAGE POINTER DISPLACEMENT    31900017
         B     MSGMODE                  BRANCH                          32000017
DSBSMSG  BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 32100017
         DC    H'16'                    MESSAGE POINTER DISPLACEMENT    32200017
         B     NOLOGOF            BRANCH                                32300017
SMBMSG   BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 32400017
         DC    H'20'                    MESSAGE POINTER DISPLACEMENT    32500017
         B     MSGMODE                  BRANCH                          32600017
SMBSMSG  BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 32700017
         DC    H'24'                    MESSAGE POINTER DISPLACEMENT    32800017
         B     NOLOGOF            BRANCH                                32900017
MSTOPMSG EQU   *                                                        33000017
         BAL   RLINK,INITMSG            BRANCH MESSAGE HANDLING ROUTINE 33100017
         DC    H'28'                    MESSAGE POINTER DISPLACEMENT    33200017
         B     MSGMODE                  BRANCH                          33300017
STOPSMB  EQU   *                                                        33400017
         BAL   RLINK,INITMSG           BRANCH TO MESSAGE HANDLING RTN   33500017
         DC    H'0'                                                     33600017
MSGMODE  MVI   CCTCSM,HEX08        SET SELECT MASK FOR LOGOFF           33800017
NOLOGOF  OI    CCTPSTAT+ONEEQU,HEX40     TURN ON MSG DISPLAY SWITCH     34000017
FILLCCT  EQU   *                   FILL IN CCT FROM OCT                 34200017
* MOVE OCT HEADER INTO CCT                                              34300017
*                                                                       34400017
         USING GFXOCTHD,ROCT       DSECT FOR OCT HEADER                 34500017
         L     ROCT,ADOCTHD        LOAD ADDR OCT HEADER                 34600017
         MVC   OCTHDSV(GFXHDSZE),GFXOCTHD                               34700017
*                                  MOVE OCT HEADER INTO SAVE AREA       34800017
         LA    ROCT,OCTHDSV        LOAD ADDR OCT SAVE AREA              34900017
         MVC   CCTSOUT(ONEEQU),OCTGSMB  GJPSYSOUT CLASS                 35000017
         MVC   CCTFJCLS(ONEEQU),OCTFTYPE USER'S FOREGROUND CLASS        35100017
         MVC   CCTBJCLS(ONEEQU),OCTBTYPE USER'S BACKGROUND CLASS        35200017
         MVC   CCTSOUT+ONEEQU(ONEEQU),OCTPRINT  PRINT SYSOUT CLASS      35300017
         MVC   CCTSOUT+TWOEQU(ONEEQU),OCTPUNCH  PUNCH SYSOUT CLASS      35400017
         MVC   CCTSOUT+THREE(ONEEQU),OCTBSMB  BATCH SMB SYSOUT CLASS    35500017
         MVC   CCTFRPRI(TWOEQU),OCTFPRI   FOREGROUND JOB PRIORITY       35600017
         MVC   CCTBRPRI(TWOEQU),OCTBPRI   BACKGROUND JOB PRIORITY       35700017
         MVC   CCTGRGN(FOUR),OCTFGREG     SGJP REGION SIZE              35800017
         MVC   CCTUFRGN(FOUR),OCTFUREG    USER FOREGROUND REGION SIZE   35900017
         MVC   CCTUBRGN(FOUR),OCTBUREG    USER BACKGROUND REGION SIZE   36000017
* MOVE OCT ENTRY INTO CCT                                               37100017
         L     ROCT,ADOCTEN       LOAD ADDR OCT ENTRY                   37200017
         USING GFXOCTEN,ROCT       DSECT FOR OCT ENTRY RECORD           37300017
         MVC   CCTUNIT(THREE),OCTUNIT+ONEEQU  PUT UNIT ADDR IN CCT      37400017
*                                                                       37600017
* PACK JOB COUNT NUMBER, CONVERT IT TO BINARY, AND PUT IN CCT           37700017
*                                                                       37800017
         LA    RWORK,CCTPWKA+HUNDRED    GET AN ADDRESS                  37900017
         N     RWORK,DOUBLE             INSURE ADDR IS OF DOUBLE WORD   38000017
         SR    RJOBCTR,RJOBCTR         CLEAR REG                        38100017
         ST    RJOBCTR,ZERO(RWORK)      ZERO OUT FIRST WORD             38200017
         PACK  FOUR(FOUR,RWORK),OCTCOUNT(FOUR)  PACK JOB COUNT          38300017
         CVB   RJOBCTR,ZERO(RWORK)   CONVERT EBCDIC TO BINARY           38400017
         STH   RJOBCTR,CCTJCTR         STORE BINARY NUMB IN CCT         38600017
         TM    OCTATTR1+ONEEQU,OCTERR1  TEST ERROR BIT                  38606017
         BO    LON                      IF ERROR SIMULATE LOGON         38612017
         TM    OCTATTR2,OCTABND         TEST ABEND BIT                  38618017
         BO    LON                      IF ABEND SIMULATE LOGON         38624017
         TM    OCTATTR1,OCTBIODQ+OCTBIOGS+OCTBIOGD+OCTBIOUS+OCTBSTOP    38630017
*                                       ANY I/O ERRORS                  38640017
         BC    5,DSELECT2               BRANCH IF YES                   38650017
         TM    OCTATTR2,OCTBFAST+OCTBMED+OCTBSLOW                  R001 38660000
*                             ANY STOP BITS SET                         38670017
         BC    5,DSELECT2     BRANCH IF YES                             38680017
         TM    OCTATTR1+ONEEQU,OCTBSMBB  IS THIS BEGIN JOB TIME         38690017
         BO    DSELECT        BRANCH IF YES                             38700017
         EJECT                                                          38900017
LON      TM    OCTATTR1+ONEEQU,OCTERR1  Q. RESTART FOR INTERNAL ERROR   38907017
         BZ    LONTST                   NO                              38914017
         TM    OCTATTR2,OCTABND         WAS IT ABEND                    38921017
         BZ    LONTST                   NO                              38928017
         OI    OCTATTR4,OCTBNPRO        INDICATE NO INITIAL PROCESSOR   38935017
LONTST   EQU   *                                                        38942017
         NI    OCTATTR1+ONEEQU,FF-OCTERR1    TURN OFF ERROR BIT         38949017
         NI    OCTATTR2,FF-OCTABND-OCTBIRRE  TURN OFF ABEND AND         38956017
         NI    OCTATTR3,FF-OCTABND-OCTBIRRE  INTERNAL ERROR BITS        38963017
         TM    OCTATTR4,OCTBNPRO        Q. INITIAL PROCESSOR USED       38970017
         BO    NOTUSED                  NO                              38977017
GOAGAIN  LA    RPAR0,FOUR         SET PASSWORD 01 CODE                  38990017
         ST    RPAR0,CCTIELST     PUT INTO INITIALIZATION LIST          39000017
         LA    RPAR0,INITCODE     SET CODE TO INITIALIZE                39010017
         BAL   RBAL,GODIOR        BRANCH TO GO TO IKDIOR                39020017
         MVC   CCTCCR(THREE),LONKEY  PUT LOGON KEYWORD INTO CCT         39030017
         MVI   CCTCSM,HEX01        SET COMMAND SELECT MASK              39100017
         OI    CCTPSTAT,HEXC0      TURN ON JOB AND EXEC CARD SWITCH     39200017
         LA    RPAR1,FREEABL       SET ADDR OF AREA TO FREE             39300017
         FREEMAIN   R,LV=LFREEABL,A=(1),SP=0                            39700017
         L     RPAR0,LSAVE1             GET SIZE OF SAVE AREA           39720017
         LA    RPAR1,LFREEABL           GET SIZE OF FREED AREA          39740017
         SR    RPAR0,RPAR1              FIND NEW SIZE                   39760017
         ST    RPAR0,LSAVE1             SAVE IT                         39780017
XCTLCTL  LA    RPAR1,CCT               LOAD CCT ADDRESS                 39800017
         L     RSAVE,ISAVE+FOUR    RESTORE REGISTER 13                  39900017
         XCTL  (2,12),EP=IKDCTL         TRANSFER CONTROL TO CONTROL.    40000017
NOTUSED  NI    OCTATTR4,FF-OCTBNPRO     TURN OFF INDICATOR              40004017
         LA    RPAR0,ZERO          GET CODE TO USE PASSWORD 00          40008017
         ST    RPAR0,CCTIELST     PUT INTO INITIALIZATION LIST          40014017
         LA    RPAR0,INITCODE     SET CODE TO INITIALIZE                40021017
         BAL   RBAL,GODIOR        BRANCH TO GO TO IKDIOR                40028017
         LA    RPAR0,TERMCODE     SET CODE TO TERMNATE                  40035017
         BAL   RBAL,GODIOR        BRANCH TO GO TO IKDIOR                40042017
         B     GOAGAIN            BRANCH TO REINITIALIZE                40049017
GODIOR   LA    RPAR1,CCT          SET CCT ADDRESS                       40056017
         L     RBR,CCTIORP        GET I/O ROUTINE ADDRESS               40063017
         BALR  RRET,RBR           GO TO I/O ROUTINE                     40070017
         LTR   RBR,RBR            CHECK RETURN CODE                     40077017
         BNE   RETURN             IF NOT ZERO, RETURN                   40084017
         BR    RBAL               GO BACK TO CALLER                     40091017
*                                                                       40100017
* GETMAIN FOR DIARY DCB AND OPEN DIARY DCB IF RECORD OPTION IS TAKEN    40200017
*                                                                       40300017
DSELECT  MVI   CCTCSM,HEX21        SET COMMAND SELECT MASK              40400017
DSELECT2 MVI   CCTDISM,DBLEZERO    SET DISPLAY MASK                     40500017
         LA    RPAR1,EIGHT        SET PASSWORD 02 CODE                  40520017
         ST    RPAR1,CCTIELST     PUT INTO INITIALIZATION LIST          40540017
         LA    RPAR0,INITCODE     SET CODE TO INITIALIZE                40560017
         BAL   RBAL,GODIOR        BRANCH TO GO TO IKDIOR                40580017
         LA    RPAR0,NAMELNTH     SET LENGTH OF 1130 PROGRAM NAME       40630017
         ST    RPAR0,CCTRECLN     IN CCT                                40660017
         LA    RPAR0,READCODE      GET PARAM CODE TO READ               40700017
         L     RBR,CCTIORP         ADDRESS OF I/O ROUTINE               40800017
         LA    RPAR1,CCT          GET POINTER TO CCT                    40900017
         BALR  RRET,RBR            GO TO I/O ROUTINE TO READ 1130 PROG  41000017
*                                  NAME                                 41100017
         LTR   RBR,RBR            CHECK RETURN CIDE                     41106017
         BNE   RETURN             IF NOT ZERO, BRANCH                   41112017
         MVC   CCTDIAWA+FIVE(MODLNTH),JOBMOD  PUT 1130 MODEL INTO WKAR  41120017
         L     RBUFF,CCTBUFFP     SET POINTER TO BUFFER                 41140017
         MVC   CCTDIAWA+NINETEEN(NAMEL),ZERO(RBUFF) PUT NAME INTO WKAR  41200017
         TM    CCTSSTAT,HEX80      WAS RECORD OPTION TAKEN              41260017
         BZ    BRDIARTN            BRANCH IF NOT                        41320017
         GETMAIN R,LV=DSCTEND-DCBDSECT                                  41400017
         LR    RDCBBASE,RPAR1          GETMAIN ADDRESS                  41500017
         USING DCBDSECT,RDCBBASE                                        41600017
         L     RWORK,LENGTH             GETMAIN LENGTH                  41700017
         SH    RWORK,TWO                *                               41800017
         LA    RWORK1,DCBDSECT          * CLEAR GETMAIN AREA            41900017
         MVI   ZERO(RWORK1),DBLEZERO  *                                 42000017
         EX    RWORK,MOVE              *                                42100017
         AH    RWORK,TWO                RESET GETMAIN LENGTH            42200017
         ST    RWORK,DCBDSECT           SAVE IT AT FIRST WORK           42300017
         LA    RWORK1,DIADCB            DIARY DCB ADDRESS               42400017
         ST    RWORK1,CCTRDCBP          SAVE DIARY DCB ADDRESS          42500017
         MVC   DIADCB(LDCB),DCBDIA      *                               42600017
         MVC   DOPEN(FOUR),DIAOPEN   * OPEN DIARY DCB                   42700017
         MVC   DOPEN+ONEEQU(THREE),CCTRDCBP+ONEEQU                      42800017
         LA    RPAR1,DOPEN              *                               42900017
         OPEN  ,MF=(E,(1))              *                               43000017
         LA    RPAR0,CCTRNOTE     ADDR OF PROPER RECORD IN DIARY        43100017
         LA    RWORK,DIADCB    GET DCB ADDR                             43110017
         USING IHADCB,RWORK    SET UP ADDRESSABILITY                    43120017
         TM    DCBOFLGS,GOODOPEN  GOOD OPEN                             43130017
         BO    DIAOK           IF YES, BRANCH                           43140017
         MVC   ERRORMSG(EL),DCBMSG      PUT ERROR MSG FOR               43150017
         MVC   ERRORDCB(EE),DCBMSG5     DIARY DCB INTO AREA             43160017
         B     ERRORRTN            GO TO ERROR EXIT                     43170017
         DROP  RWORK                                                    43180017
DIAOK    LA    RPAR0,CCTRNOTE    SET NOTE POSITION                      43190017
         L     RPAR1,CCTRDCBP     ADDR DIARY DCB                        43200017
         POINT (1),(0)            POINT TO PRPER RECORD                 43300017
BRDIARTN LA    RPAR1,CCT          GET POINTER TO CCT                    44100017
         L     RWORK,CCTHSN        GET HSN                              44300017
         LA    RWORK,ONEEQU(RWORK)  INCREMENT BY ONE                    44500017
         STH   RWORK,CCTHSN+TWOEQU  RESTORE                             44700017
         L     RBR,CCTDIARP        ADDRESS OF DIA                       44900017
         BALR  RRET,RBR            GO TO DIARY ROUTINE                  45000017
         CH    RBR,RCHEX1C        CHECK RETURN CODE                     45030017
         BE    RETURN             IF 28, BRANCH TO RETURN               45060017
         MVI   CCTPSTAT,HEXC0      TURN ON JOB AND EXEC SWITCH          45100017
         L     ROCT,ADOCTEN       GET OCT ENTRY ADDRESS                 45130017
         USING GFXOCTEN,ROCT      SET UP ADDRESSIBILITY                 45160017
         LA    RPAR1,FREEABL       GET ADDR OF AREA TO BE FREED         45200017
         FREEMAIN   R,LV=LFREEABL,A=(1),SP=0                            45500017
         L     RPAR0,LSAVE1             GET SIZE OF SAVE AREA           45501017
         LA    RPAR1,LFREEABL           GET SIZE OF FREED AREA          45502017
         SR    RPAR0,RPAR1              FIND NEW SIZE                   45503017
         ST    RPAR0,LSAVE1             SAVE IT                         45504017
         TM    OCTATTR1+ONEEQU,OCTBSMBB  ANY SMBS TO PROCESS            45508017
         BZ    XCTLCTL                  NO, SKIP SMB PROCESSOR          45528017
         TM    OCTATTR1,OCTBIODQ+OCTBIOGS+OCTBIOGD+OCTBIOUS             45588017
         BC    5,XCTLCTL                BRANCH IF ANY ERROR             45608017
XCTLSMB  L     RSAVE,ISAVE+FOUR    RESTORE SAVE ADDRESS                 45638017
         LA    RPAR1,CCT               LOAD CCT ADDRESS                 45700017
         XCTL  (2,12),EP=IKAPSMB0       XCTL TO SMB                     45800017
         EJECT                                                          45900017
*                                                                       46000017
* THIS IS MESSAGE HANDLING ROUTINE                                      46100017
*                                                                       46200017
RPARLIST EQU   3                        POINT TO MESSAGE PARAMETER LIST 46300017
RMSGADDR EQU   4                        POINT TO MESSAGE AREA           46400017
RMINIT   EQU   5                        POINT TO IKAMINIT               46500017
RMSGLTH  EQU   6                        MESSAGE LENGTH                  46600017
ROPTBYTE EQU   7                        MESSAGE OPTION BYTE             46700017
RWORK1   EQU   8                                                        46800017
RWORK2   EQU   12                                                       46900017
*                                                                       47000017
INITMSG  EQU   *                                                        47100017
         LA    RPARLIST,CCTPWKA         POINT TO MESSAGE PAR-LIST ADDR  47200017
         MVI   ZERO(RPARLIST),DBLEZERO   CLEAR WORK AREA                47300017
         MVC   ONEEQU(HUNDRED,RPARLIST),ZERO(RPARLIST)  FOR MESSAGE     47400017
         LA    RMSGADDR,CCTPWKA+TWELVE   POINT TO MESSAGE FIELD         47500017
         L     RMINIT,VMINIT            LOAD IKAMINIT ADDRESS           47600017
         AH    RMINIT,ZERO(RLINK)       POINT TO ADDR OF LIST           47700017
         L     RWORK1,ZERO(RMINIT)      POINT TO PARAM LIST             47800017
CONTINUE SR    ROPTBYTE,ROPTBYTE       CLEAR REGISTER                   47900017
         IC    ROPTBYTE,ZERO(RWORK1)    SAVE OPTION BYTE                48000017
         SR    RMSGLTH,RMSGLTH          ZERO REGISTER                   48100017
         STC   RMSGLTH,ZERO(RWORK1)     ZERO OPTION BYTE                48200017
         L     RWORK2,ZERO(RWORK1)      GET MESSAGE ADDRESS             48300017
         IC    RMSGLTH,ZERO(RWORK2)     GET MESSAGE LENGTH              48400017
         EX    RMSGLTH,MOVEMSG          MOVE MESSAGE IN CCTPWKA         48500017
         ST    RMSGADDR,ZERO(RPARLIST)   SET MSG PARAMETER IN CCT       48600017
         STC   ROPTBYTE,ZERO(RPARLIST)   SET OPTION BYTE                48700017
         CH    ROPTBYTE,ENTRYEND       Q.NO MORE MESSAGE                48800017
         BE    TWOEQU(RLINK)       BRANCH IF YES                        48900017
         LA    RPARLIST,FOUR(RPARLIST)   UPDATE PAR LIST POINTER        49000017
         AR    RMSGADDR,RMSGLTH         UPDATE MSG-FIELD POINTER        49100017
         LA    RMSGADDR,ONEEQU(RMSGADDR)  INCREMENT BY ONE              49200017
         LA    RWORK1,FOUR(RWORK1)        UPDATE PLIST POINTER          49300017
         B     CONTINUE                   BRANCH AND CONTINUE           49400017
         EJECT                                                          49800017
         DS    0F                                                       49802017
MSGJCL   DC    X'0005'                  DATA SIZE                       49804017
         DC    C'JCL '                  IDENTIFIER                      49806017
MSGEXT   DC    X'0005'                  DATA SIZE                       49808017
         DC    C'EXT '                  IDENTIFIER                      49810017
MSGEXT1  DC    X'0006'             MSG NO                               49812017
         DC    C'EXT1'             IDENTIFIER                           49814017
MSGDIA   DC    X'0005'                  DATA SIZE                       49816017
         DC    C'DIA '                  IDENTIFIER                      49818017
EE       EQU   3                                                        49820017
*                                                                       49822017
* INTERNAL ERROR MSG FOR IKAIERR                                        49824017
*                                                                       49826017
DCBMSG1  DC    AL3(MSGEXT)              ADCON FOR MSG              R001 49827018
DCBMSG2  DC    AL3(MSGJCL)         ADCON FOR MSG                        49828017
DCBMSG4  DC    AL3(MSGEXT1)        ADCON FOR MSG                        49830017
DCBMSG5  DC    AL3(MSGDIA)         ADCON FOR MSG                        49832017
DCBMSG   DC    C'056'              MSG NO                               49834017
         DC    C'INIT '            IDENTIFIER                           49836017
         DC    X'40'               STATUS BYTE                          49838017
         DC    C'   '                   THREE BLANKS               R001 49840018
DCBMSGE  EQU   *                                                        49842017
EL       EQU   DCBMSGE-DCBMSG                                           49844017
CIBMSG   DC    C'059'              MSG NO                               49846017
         DC    C'INIT '            IDENTIFIER                           49848017
         DC    X'00000000'         STATUS                               49850017
         DC    C'   '              BLANKS                               49852017
SYNCHM1  DC    C'062'                   MESSAGE NO.                R001 49854018
         DC    C'INIT '            IDENTIFIER                           49856017
         DC    X'40'               STATUS BYTE                          49858017
         DC    AL3(DEX)            ADCON                                49860017
         DS    0F                                                       49862017
EODMSG1  DC    C'061'              MSG NO                               49864017
         DC    C'INIT '            IDENTIFIER                           49866017
         DC    X'40'               STATUS                               49868017
         DC    AL3(DEX)            ADCON                                49870017
DEX      DC    X'0008'             MSG NO                               49872017
         DC    C'EXT'              IDENTIFIER                           49874017
         DC    C'XXX'              THREE CHARACTER SPACE                49876017
ERRORRTN LR    RPAR1,RCCT          CCT ADDRESS                          49878017
         LA    RPAR1,EIGHT(RPAR1)  INCREMENT BY 8                       49880017
         LA    RPAR0,ERRORMSG      ADDRESS OF ERROR MSG                 49882017
         O     RPAR0,HIBIT              INDICATE INITIALIZATION         49883017
         LINK  EP=IKAIERR          GO TO IKAIERR                        49884017
BADSTART EQU   *                                                        49888017
         USING IHADCB,RWORK             ADDRESSABILITY                  49892017
         LA    RPAR1,CCTJDCBP           ADDR OF JCL DCB                 49896017
         BAL   ROPEN,CLEAN              CLOSE DCB                       49900017
         LA    RPAR1,CCTEDCBP           ADDR OF EXTRACT DCB             49904017
         BAL   ROPEN,CLEAN              CLOSE DCB                       49908017
         LA    RPAR1,CCTEDCB1           ADDR OF RECALL DCB              49912017
         BAL   ROPEN,CLEAN              CLOSE DCB                       49916017
         LA    RPAR1,CCTRDCBP           ADDR OF DIARY DCB               49920017
         BAL   ROPEN,CLEAN              CLOSE DCB                       49924017
RETURN   LR    RPAR1,RCCT          GET ADDRESS OF CCT                   49928017
         L     RPAR0,LSAVE1        GET LENGTH OF CCT                    49932017
         FREEMAIN R,LV=(0),A=(1)                                        49936017
         L     RSAVE,ISAVE+FOUR         RESTORE REG 13                  49940017
         RETURN (14,12),RC=0       GO TO SYSTEM                         49944017
CLEAN    CLC   ZERO(FOUR,RPAR1),ZEROS8  IS THERE A DCB                  49948017
         BCR   8,ROPEN                  NO, RETURN                      49952017
         L     RWORK,ZERO(RPAR1)        GET ADDR OF DCB                 49956017
         TM    DCBOFLGS,GOODOPEN        IS IT OPEN                      49960017
         BCR   8,ROPEN                  NO, RETURN                      49964017
         DROP  RWORK                                                    49968017
         MVI   ZERO(RPAR1),HEX80        SET OPTION BYTE FOR CLOSE       49972017
         CLOSE MF=(E,(RPAR1))           CLOSE THE DCB                   49976017
         MVC   ZERO(FOUR,RPAR1),ZEROS8  ZERO OUT THE ADDR               49980017
         BR    ROPEN                    RETURN                          49984017
*                                                                       49988017
* DEFINE CONSTANTS AREA AND EQUATES                                     50000017
*                                                                       50100017
MOVE     MVC   ONEEQU(ZERO,RWORK1),ZERO(RWORK1)  MOVE INSTRUCTION       50200017
MOVEMSG  MVC   ZERO(ZERO,RMSGADDR),ZERO(RWORK2)  MOVE INSTRUCTION       50300017
VMINIT   DC    V(IKAMINIT)              POINT TO IKAMINIT MODULE        50400017
ENTRYEQU DC    CL9'OCTENTRY='      CONSTANT FOR OCT HEADER              50500017
         DS    0F                                                       50600017
HIBIT    DC    X'80000000'              HIGH ORDER BIT ON               50630017
ZEROS    DC    X'0000'             CONSTANT FOR 2 BYTES ZERO            50660017
ZEROS8   DC    X'0000000000000000' CONSTANT FOR 2 WORDS ZERO            50720017
         DS    0F                                                       50800017
ONE      DC    XL4'01'             CONSTANT OF ONE                      50900017
TWO      DC    H'2'                    CONSTANT TWO                     51000017
RCHEX1C  DC    H'28'              IERR RETURN CODE                      51050017
         DS    0F                                                       51100017
DOUBLE   DC    X'FFFFFFF8'         TO MAKE DOUBLE WORD BOUNDARY         51200017
MASK     DC    X'80000000'         MASK                                 51300017
LONKEY   DC    C'LON'              LON KEY                              51400017
BEGKEY   DC    C'BEG'              BEGIN KEY                            51500017
ENTRYEND DC    X'00C0'                  OPTION BYTE FOR END OF ENTRY    51600017
LWKA     DC    A(INITWKAE-INITWKA)      LENGTH OF DSECT                 51700017
LENGTH   DC    A(DSCTEND-DCBDSECT)  ADCON                               51760017
JOBMOD   DC    C'SPECIFY 1130  '    HISTORY CONSTANT                    51820017
         DC    C'XXXXX'             SPACE FOR NAME                      51880017
JOBMODE  EQU   *                                                        51910017
EODRTN   DC    AL3(EODERR)          EOD ADCON                           51940017
IORTN    DC    AL3(SYNCHER)         SYNC ADCON                          52000017
MODLNTH  EQU   JOBMODE-JOBMOD                                           52200017
*                                                                       52700017
* OPEN MACRO IN MF=L                                                    52800017
*                                                                       52900017
OPENDCB  OPEN  (JCLDCB,(INOUT),EXTDCB,(INOUT),                         C53000017
               EXTDCB1,(INOUT)),MF=L                                    53100017
OPENDCBE EQU   *                                                        53200017
DIAOPEN  OPEN  (DCBDIA,(INOUT)),MF=L                                    53300017
DIAOPENE EQU   *                                                        53400017
         EJECT                                                          53500017
*                                                                       53600017
* JCLDCB                                                                53700017
*                                                                       53800017
JCLDCB   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPJCL,DEVD=DA,RECFM=FBS, X53900017
               LRECL=80,BLKSIZE=80,SYNAD=DUMMY                          54000017
JCLDCBE  EQU   *                                                        54100017
         EJECT                                                          54200017
*                                                                       54300017
* DIARY DCB                                                             54400017
*                                                                       54500017
DCBDIA   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPDIA,DEVD=DA,RECFM=FBS, X54600017
               LRECL=120,BLKSIZE=120,SYNAD=DUMMY                        54700017
DCBDIAE  EQU   *                                                        54800017
         EJECT                                                          54900017
*                                                                       55000017
* EXTDCB                                                                55100017
*                                                                       55200017
EXTDCB   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPEXT,DEVD=DA,RECFM=FBS, X55300017
               LRECL=372,BLKSIZE=372,SYNAD=DUMMY,EODAD=DUMMY            55400017
EXTDCBE  EQU   *                                                        55500017
         EJECT                                                          55600017
*                                                                       55700017
* EXT DCB1                                                              55800017
*                                                                       55900017
EXTDCB1  DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=GJPEXT1,DEVD=DA,RECFM=FBS,X56000017
               LRECL=372,BLKSIZE=372,SYNAD=DUMMY,EODAD=DUMMY            56100017
EXTDCB1E EQU   *                                                        56200017
         EJECT                                                          56300017
*                                                                       56400017
* READ IN MF=L                                                          56500017
*                                                                       56600017
READ     READ  EXTDECB,SF,,,,,MF=L                                      56700017
READ1    READ  EXTDECB1,SF,,,,,MF=L                                     56800017
READEND  EQU   *                                                        56900017
         EJECT                                                          57000017
LJCLDCB  EQU   JCLDCBE-JCLDCB                                           57100017
LEXTDCB  EQU   EXTDCBE-EXTDCB                                           57200017
LEXTDCB1 EQU   EXTDCB1E-EXTDCB1                                         57300017
LOPEN    EQU   OPENDCBE-OPENDCB                                         57400017
LREAD    EQU   READEND-READ             READ LENGTH                     57500017
LDCB     EQU   DCBDIAE-DCBDIA           DIARY DCB LENGTH                57600017
DUMMY    EQU   *                                                        57700017
         EJECT                                                          57800017
*                                                                       57900017
*     DSECT FOR CCT, DCB'S, DECB'S AND BTAM BUFFER                      58000017
*                                                                       58100017
INITWKA  DSECT                                                          58200017
*                                                                       58300017
LSAVE1   DS    XL8                                                      58400017
CCT      EQU   *                                                        58500017
         SPACE                                                          58600017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         58700017
         SPACE                                                          58800017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    58900017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     59000017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       59100017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             59200017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  59300017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  59400017
*                   SET.                                                59500017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      59600017
*                   SECOND.                                             59700017
         SPACE 2                                                        59800017
         SPACE 2                                                        59900017
*                             SECTION ONE                               60000017
         SPACE                                                          60100017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     60200017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    60300017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  60400017
         SPACE                                                          60500017
         DS    0F                                                       60600017
CCTUNAME DS    5F                  USER'S NAME                          60700017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         60800017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     60900017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       61000017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    61100017
*                                       AT LAST BEGIN JOB               61200017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   61300017
*                                       LAST BEGIN JOB                  61400017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 61500017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    61600017
*                                       JOB                             61700017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    61800017
*                                       JOB                             61900017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     62000017
*                                       CESSOR                          62100017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         62200017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         62300017
CCTJCTR  DS    H                   JOB COUNTER                          62400017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                62500017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   62600017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  62700017
CCTSSTAT DS    C                   SESSION STATUS                       62800017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              62900017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              63000017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    63100017
         EJECT                                                          63200017
         SPACE 2                                                        63300017
*                             SECTION TWO                               63400017
         SPACE                                                          63500017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   63600017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  63700017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 63800017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              63900017
         SPACE                                                          64000017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     64100017
*                                       FRAME                           64200017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  64300017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     64400017
*                                       MULTIPLE DISPLAY FRAME (ENT)    64500017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   64600017
CCTDISM  DS    C                   DISPLAY MASK                         64700017
CCTCSM   DS    C                   COMMAND SELECT MASK                  64800017
CCTPSTAT DS    CL2                 GJP STATUS                           64900017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              65000017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  65100017
CCTPWKAE EQU   *                                                        65200017
         SPACE 2                                                        65300017
*                             SECTION THREE                             65400017
         SPACE                                                          65500017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    65600017
*                   INTO SECTION ONE OR TWO                             65700017
         SPACE                                                          65800017
CCTDGMP  DS    F                  POINTER TO DGM                        65900017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                66000017
CCTCSTP  DS    F                  POINTER TO CST                        66100017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                66200017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            66300017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 66400017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              66500017
CCTDIARP DS    F                  POINTER TO DIA                        66600017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      66700017
CCTACTP  DS    F                  POINTER TO ACT                        66800017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     66900017
CCTIERRP DS    F                  POINTER TO IERR                       67000017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              67100017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               67200017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                67300017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 67400017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 67500017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   67600017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                67700017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                67800017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               67900017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              68000017
CCTPECB  DS    F                  PROCESSOR'S ECB                       68100017
CCTWECB  DS    F                  WTOR ECB                              68200017
CCTDIAWA DS    CL136               DIARY WORK AREA                      68300017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    68400017
CCTCSAVE DS    CL72                CTL SAVE AREA                        68500017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                68600017
CCTASAVE DS    CL72                DAT SAVE AREA                        68700017
*                                                                       68800017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       68900017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           69000017
*                                                                       69100017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             69200017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               69300017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     69400017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               69500017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           69600017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    69700017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 69780017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   69860017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   69940017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   70020017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            70100017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 70180017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       70260017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  70340017
*                                  INATION OF DATA                      70420017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    70500017
*                                  THE I/O OPERATION TO BE TESTED BY    70580017
*                                  GTCLT                                70660017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        70740017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              70820017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   70910017
CCTPWKAL EQU   CCTPWKAE-CCTPWKA                                         71000017
*                                                                       71400017
*                                                                       71500017
         DS    0F                                                       71600017
DJCLDCB  DS    XL(JCLDCBE-JCLDCB)       SPACE FOR JCLDCB                71700017
         DS    0F                                                       71800017
DEXTDCB  DS    XL(EXTDCBE-EXTDCB)       SPACE FOR EXTRACTE DCB          71900017
         DS    0F                                                       72000017
DEXTDCB1 DS    XL(EXTDCB1E-EXTDCB1)     SPACE FOR EXTRACT DCB           72100017
ISAVE    DS    2F                  SAVE ADDR SYSTEM SAVE AREA           72200017
         DS    0F                                                  EXTR 72220019
EXTRCT   EXTRACT ANSWAREA,FIELDS=COMM,MF=L                         EXTR 72240019
ANSWAREA DS    1F                                                  EXTR 72260019
         DS    0D                                                       72300017
FREEABL  EQU   *                   BEGINING OF AREA IN GETMAIN NOT NEED 72400017
*                                  ED AFTER INIT                        72500017
DOPENDCB DS    XL(OPENDCBE-OPENDCB)     SPACE FOR OPEN MACRO            72600017
ERRORMSG DS    12F                 SPACE FOR ERROR MSG                  72630017
ERRORDCB EQU   ERRORMSG+9                                               72660017
SAVER13  DS    F                                                        72700017
SAVE2    DS    18F                                                      72800017
WKAREAD  DS    XL(READEND-READ)                                         72900017
ADPARM   DS    1F                                                       73000017
ADOCTHD  DS    1F                                                       73100017
ADOCTEN  DS    1F                                                       73200017
OCTHDSV  DS    XL76                                                     73300017
INITWKAE EQU   *                                                        73400017
LFREEABL EQU   INITWKAE-FREEABL    S                                    73500017
         EJECT                                                          73600017
DCVT     DSECT                                                          73700017
         CVT                                                            73800017
GFXOCTHD DSECT                                                          73900017
GFXHDSTR EQU   *                       START OF HEADER RECORD           74000017
OCTSYS   DS    CL1                     BASE SYSTEM                      74100017
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                74200017
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          74300017
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       74400017
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       74500017
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              74600017
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              74700017
         DS    0H                                                       74800017
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             74900017
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       75000017
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       75100017
OCTITYPE DS    CL1                JOBCLASS FOR SGJP  EXTERNAL           75160017
OCTITYPI DS    CL1                JOBCLASS FOR SGJP  INTERNAL           75220017
OCTFGREG DS    CL4                      REGION SIZE GJP                 75300017
OCTFUREG DS    CL4                      REGION SIZE USER FGD            75400017
OCTBUREG DS    CL4                      REGION SIZE USER BGD            75500017
OCTHRES  DS    CL8                      RESERVED                        75600017
OCTNAME  DS    CL20                     PROGRAMMER NAME                 75700017
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  75800017
GFXHDEND EQU   *                       END OF HEADER RECORD             75900017
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        76000017
         EJECT                                                          76100017
GFXOCTEN DSECT                                                          76200017
         DS    0F                                                       76300017
GFXENSTR EQU   *                       START OF ENTRY RECORD            76400017
OCTECB   DS    CL4                      ECB                             76500017
OCTUCB   DS    CL4                      UCB ADDRESS                     76600017
OCTUNIT  DS    CL4                      UNIT ADDRESS                    76700017
OCTCOUNT DS    CL4                      JOB COUNT                       76800017
OCTNOTE  DS    CL4                      NOTE                            76900017
OCTABEND DS    A                       ABEND CODE                       77000017
OCTFPART DS    CL2                                                      77050017
OCTDNOTE DS    CL3                                                      77100017
OCTIERNO DS    CL3                                                      77150017
**********************************************************************  77200017
****                          ATTRIBUTE 1                          **** 77300017
**********************************************************************  77400017
OCTATTR1 DS    CL2                      ATTRIBUTES                      77500017
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         77600017
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   77700017
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         77800017
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       77900017
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   78000017
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  78100017
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  78200017
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           78300017
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          78400017
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   78500017
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           78600017
OCTERR1  EQU   X'10'                                                    78650017
**********************************************************************  78700017
****                          ATTRIBUTE 2                          **** 78800017
**********************************************************************  78900017
OCTATTR2 DS    CL2                      ATTRIBUTES                      79000017
OCTNUSED EQU   X'80'          0-                  1-                    79100017
OCTBIRRE EQU   OCTNUSED       INTERNAL ERROR BIT                        79150017
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      79200017
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              79300017
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           79400017
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         79500017
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           79600017
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       79700017
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            79800017
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  79900017
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  80000017
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        80100017
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         80200017
**********************************************************************  80300017
****                          ATTRIBUTE 3                          **** 80400017
**********************************************************************  80500017
OCTATTR3 DS    CL2                      ATTRIBUTES                      80600017
OCTBCANM EQU   X'80'          0-                  1-                    80700017
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      80800017
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              80900017
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           81000017
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         81100017
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           81200017
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       81300017
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            81400017
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  81500017
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  81600017
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        81700017
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         81800017
**********************************************************************  81900017
****                          ATTRIBUTE 4                          **** 82000017
**********************************************************************  82100017
OCTATTR4 DS    CL2                      ATTRIBUTES                      82200017
OCTBNPRO EQU   X'40'          0-MVT     1-MFT, IF NO INIT. PROC.        82250017
GFXENEND EQU   *                       END OF ENTRY RECORD              82300017
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             82400017
         EJECT                                                          82500017
         DCBD  DSORG=PS,DEVD=DA    DSECT FOR DCB'S                      82530017
         EJECT                                                          82560017
*                                                                       82600017
* DSECT FOR DIARY DCB                                                   82700017
*                                                                       82800017
DCBDSECT DSECT                                                          82900017
         DS    D                                                        83000017
DIADCB   DS    XL(DCBDIAE-DCBDIA)                                       83100017
DIADCBE  EQU   *                                                        83200017
DOPEN    DS    F                                                        83300017
DSCTEND  EQU   *                                                        83400017
*                                                                       83500017
         END                                                            83600017
./       ADD   SSI=01011027,NAME=IKDINPRO,SOURCE=0
 TITLE 'IKDINPRO' INITIAL PROCESSOR                                     00700017
*STATUS: CHANGE LEVEL 000                                             * 01500017
*FUNCTION/OPERATION: ESTABLISH INITIAL COMMUNICATION WITH AN 1130/2250* 02500017
*   SUBSYSTEM UPON DETECTION OF A CANCEL KEY ATTENTION AT THE 2250.   * 03000017
*   IT'S OPERATIONS INCLUDE:                                          * 03500017
*   1) ISSUE GETMAIN FOR A BTAM DCB, A READ/WRITE DECB, AN I/O BUFFER * 04000017
*   AN A WORK AREA                                                    * 04500017
*   2) OPEN THE BTAM DCB                                              * 05000017
*   3) ISSUE BTAM READ INITIAL. UPON COMPLETION OF I/O, MATCH THE     * 05500017
*   PASSWORD RECEIVED FROM THE SUBSYSTEM WITH THAT OF SGJP.  IF THEY  * 06000017
*   MATCH, ISSUE BTAM READ CONTINUE TO SIGNIFY THE MATCH TO THE SUB-  * 06500017
*   SYSTEM, AND CONTINUE. IF THEY DO NOT MATCH, ISSUE BTAM WRITE RESET* 07000017
*   TO SIGNIFY THE NO-MATCH TO THE SUBSYSTEM, AND GO BACK AND READ    * 07500017
*   INITIAL.                                                          * 08000017
*   4)CLOSE BTAM DCB                                                  * 08500017
*   5)ISSUE SVC 80 TO CAUSE THE SETTING OF THE APPROPRIATE ATTRIBUTE  * 09000017
*   BITS IN GFX'S OVERALL CONTROL TABLE.                              * 09500017
*   6) ISSUE FREEMAIN TO RELEASE STORAGE                              * 10000017
*ENTRY POINTS: ENTERED AT IKDINPRO FROM OPERATING SYSTEM VIA LINK     * 10800017
*INPUT: PARAMETER LIST CONTAINING ADDRESS OF TELECOMMUNICATIONS LINE  * 11600017
*OUTPUT: ADDRESS OF PARAMETER LIST IN REGISTER 0 FOR SVC ROUTINE.     * 12500017
*   PARAMETER LIST CONTAINS:                                          * 13000017
*   +0 INPUT CODE                                                     * 13700017
*   +4 LINE ADDRESS                                                   * 14400017
*EXTERNAL ROUTINES: BTAM I/O MODULES, SVC80                           * 15100017
*EXITS-NORMAL: RETURN TO OPERATING SYSTEM VIA RETURN MACRO            * 15800017
*     -ERROR: RETURN TO OPERATING SYSTEM VIA RETURN MACRO             * 16500017
*TABLES/WORKAREAS: BUFFER                                             * 17200017
*ATTRIBUTES: REUSABLE                                                 * 17900017
*NOTES: N/A                                                           * 18600017
         EJECT                                                          19500017
IKDINPRO CSECT                                                          20000017
*3302,263200-263500,332800-333100,336400-338400,394200,775200,     R018 20100018
*     779200-783200                                                R018 20200018
*     312000-312500,729800                                         R018 20300018
* 461000-463000                                                  A40766 20350020
*                                                                       20500017
* GENERAL REGISTERS                                                     21000017
*                                                                       21500017
RPAR0    EQU   0                                                        22000017
RPAR1    EQU   1                                                        22500017
RINCR    EQU   2                                                        23000017
RCOUNT   EQU   2                                                        23200017
RWORK    EQU   3                                                        23500017
RDECB    EQU   4                                                        24000017
RBUFFER  EQU   5                                                        24500017
RDCB     EQU   6                                                        25000017
RCVT     EQU   7                                                        25100017
ROCT     EQU   8                                                        25200017
RBAL     EQU   9                                                        25270017
RCODE    EQU   10                                                       25340017
RSEC     EQU   11                                                       25410017
RBASE    EQU   12                                                       25500017
RSAVE    EQU   13                                                       26000017
RBR      EQU   15                  EQUATE                               26100017
MSGLNTH  EQU   10                                                       26200017
*                                                                       26210017
* EQUATES                                                               26220017
*                                                                       26230017
ZERO     EQU   0              EQUATE FOR ZERO                           26240017
ONE      EQU   1              EQUATE FOR ONE                            26250017
TWO      EQU   2              EQUATE FOR TWO                            26260017
THREE    EQU   3              EQUATE FOR THREE                          26270017
FOUR     EQU   4              EQUATE FOR FOUR                           26280017
FIVE     EQU   5                                                        26285017
SIX      EQU   6                                                        26290017
EIGHT    EQU   8              EQUATE FOR EIGHT                          26300017
NINE     EQU   9              EQUATE FOR NINE                           26310017
SIXTEEN  EQU   16                                                  R018 26320000
XX       EQU   20             DISPLACEMENT IN TCB FOR ABEND HOOK FLAG   26335017
ONTWSVN  EQU   127                                                      26360017
UNOPENED EQU   X'10'               ON FOR SUCCESSFUL OPEN               26370017
DBLEZERO EQU   X'00'                                                    26380017
STOPBIT  EQU   X'10'          STOP BIT MASK                             26390017
HEX20    EQU   X'20'               EQUATE                               26395017
POSTCODE EQU   X'7F'          COMPLETION CODE                           26400017
CANCEL   EQU   C'C'                                                     26410017
RETRY    EQU   C'R'                                                     26420017
         EJECT                                                          26430017
         SAVE  (14,12)             SAVE REGISTERS                       26500017
         BALR  RBASE,0             SET UP BASE                          27000017
         USING *,RBASE                                                  27500017
         ST    RSAVE,INPROSAV+FOUR   SAVE CALLERS SAVE ADDRESS          28500017
         LA    RWORK,INPROSAV      CHAIN SAVE AREAS                     30000017
         ST    RWORK,EIGHT(RSAVE)   CHAIN SAVE AREAS                    30500017
         LR    RSAVE,RWORK         SET R13 TO OUR SAVE ADDRESS          31000017
         L     RCVT,CVTPTR              GET ADDR OF CVT                 31010017
         USING DCVT,RCVT                ADDRESSABILITY                  31020017
         L     RWORK,CVTTCBP            GET ADDR OF TCB POINTER         31030017
         L     RWORK,FOUR(RWORK)        ADDR OF TCB                     31040017
         OI    XX(RWORK),HEX20     SET BIT FOR ABEND ROUTINE            31050017
         ST    RPAR1,ADPARM        SAVE ADDRESS OF PARAMETER LIST       31100017
         EXTRACT ANSWAREA,FIELDS=COMM   GET ADDR OF COMM.PARM.LIST EXTR 31150019
         L     RPAR1,ANSWAREA           POINTER TO COMM.PARM.LIST  EXTR 31200019
         L     RPAR1,FOUR(RPAR1)        GET CIB ADDRESS            EXTR 31250019
         LR    RINCR,RPAR1                                              31300017
         LA    RINCR,ONTWSVN(RINCR) SET END OF CIB ADDRESS              31400017
SCANCIB  CLC   ZERO(NINE,RPAR1),ENTRYEQU  SCAN CIB FOR OCT HEADER       31500017
         BE    FOUNDADR            FOUND OCTENTRY= IN CIB               31600017
         LA    RPAR1,ONE(RPAR1)   NOT FOUND, INCREMENT BY ONE           31700017
         CR    RINCR,RPAR1              Q. LIMIT REACHED                31800017
         BNE   SCANCIB                  NO, CONTINUE SEARCHING          31900017
         B     RETURN                   EXIT WHEN END REACHED           32000017
FOUNDADR L     RCVT,CVTPTR         SET BASE FOR CVT                     32300017
         USING DCVT,RCVT                                                32400017
         L     ROCT,CVTQOCR        ADDRESS OF LIST OF POINTERS          32500017
         LTR   ROCT,ROCT          IS REGISTER ZERO                      32530017
         BE    RETURN             IF YES BRANCH TO RETURN               32560017
         L     ROCT,ZERO(ROCT)    GET ADDRESS OF OCT HEADER             32630017
         USING GFXOCTHD,ROCT                                            32700017
         LH    RWORK,OCTUNBR       GET NUMBER OF 2250'S ATTACHED        32730017
         ST    RWORK,NUNITS                                             32760017
         LA    ROCT,GFXHDSZE(ROCT) SET BASE FOR OCT ENTRY               32800017
         USING GFXOCTEN,ROCT                                            32900017
         L     RINCR,NUNITS        GET NUMBER OF UNITS                  32950017
*    SEARCH FOR THE ENTRY IN THE OCT                                    33000017
SCANENT  CLC   NINE(THREE,RPAR1),OCTUNIT+ONE  IS THIS CORRECT ENTRY     33050017
         BE    FOUNDENT            YES, BRANCH                          33100017
         LA    ROCT,GFXENSZE(ROCT)  NO, GO TO CHECK NEXT ENTRY          33200017
         BCT   RINCR,SCANENT       CONTINUE SEARCH                      33250017
         MVC   NOTINCIB+SIXTEEN(THREE),NINE(RPAR1) ADDR NOT FOUND  R018 33270000
NOTINCIB WTO   'IKA059I XXX - INVALID UNIT ADDRESS IN CIB',ROUTCDE=2,  *33290000
               DESC=4                                              R018 33310000
         B     RETURN                                                   33340017
FOUNDENT MVC   SVCUNIT+ONE(THREE),OCTUNIT+ONE  MOVE UNIT ADDRESS INTO   33440017
         MVC   KLOFUTN+ONE(THREE),OCTUNIT+ONE  SVC PARAMETER LISTS      33540017
         MVC   WTO5+SIXTEEN(THREE),OCTUNIT+ONE  SET UP UNIT NAME   R018 33640000
*                                                     IN MESSAGE   R018 33740000
         MVC   IOMSG+XX(THREE),OCTUNIT+ONE  PUT UNIT ADDRESS IN    R018 33840000
         MVC   INITMSG+XX(THREE),OCTUNIT+ONE  TWO ERROR MSGS       R018 33940000
         CLC   OCTATTR1(8),ZEROS8       Q. OCT ENTRY VALID         R018 33990018
         BE    RETURN                   NO - TERMINATE             R018 34040018
MINUSONE EQU   X'FFF0'                                                  34100017
         CHAP  MINUSONE            CHANGE PRIORITY                      34800017
*                                                                       35500017
* OPEN BTAM DCB                                                         36000017
*                                                                       36500017
         LA    RPAR1,BTAMOPEN      SET REG 1 TO POINT TO DCB LIST       37500017
         IC    RWORK,CHAR   GET OPTION BYTE                             38000017
         STC   RWORK,BTAMOPEN     SET OPTION BYTE IN OUEN LIST          38500017
         OPEN  BTAMDCB,MF=(E,(1))                                       39000017
         TM    OPENFLAG,UNOPENED   Q. OPEN SUCCESSFUL                   39070017
         BO    SETPWD00           YES, GO TO MOVE FIRST PASSWORD        39140017
*                                                                       39210017
*    INDICATE DCB NOT OPENED                                            39280017
*                                                                       39350017
WTO5     WTO   'IKD005I XXX - DCB NOT OPENED',ROUTCDE=(2,8),DESC=4 R018 39420000
*                                                                       39490017
*    ISSUE LOGOFF'S SVC                                                 39560017
*                                                                       39630017
LOGOFF   EQU   *                   COMMON ENTRY POINT                   39700017
         LA    RPAR0,KLOF          ADDR OF PARM LIST                    39770017
         SVC   80                  NOTIFY GFX                           39840017
         B     RETURN              END PROCESSING                       39910017
SETPWD00 MVC   PASSWD(SIX),PASSWD00  PUT FIRST PASSWORD IM MODEL        39940017
         LA    RCOUNT,FIVE          SET A COUNT OF FIVE                 39970017
         EJECT                                                          40000017
*                                                                       40500017
* ISSUE BTAM READ TO GET PASSWORD FROM THE 1130. WAIT FOR I/O COMPLET-  41000017
* ION                                                                   41500017
*                                                                       42000017
ISREAD   SR    RCODE,RCODE         SET INDICATOR REGISTER TO ZERO       42500017
         LA    RDECB,BTAMREAD                                           43000017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)  CLEAR  ECB                 43500017
         LA    RBUFFER,INBUFFR     SET POINTER TO I/O AREA              44000017
         LA    RDCB,BTAMDCB       SET POINTER TO DCB                    44500017
         READ  (RDECB),TI,(RDCB),(RBUFFER),14,,1,MF=E                   45500017
         CH    RBR,KXX             Q. ENABLE COMMAND GOOD IN OPEN       45560017
         BE    WTO5                NO - EXIT                            45620017
         LA    RSEC,ONESEC         SET POINTER TO SECOND                45700017
WAITIMER STIMER WAIT,TUINTVL=(11)  SET TIMER FOR ONE SECOND             45900017
         L     RWORK,ANSWAREA      GET POINTER TO PARAMETER LIST A40766 46100020
         L     RWORK,ZERO(RWORK)    GET POINTER TO ECB           A40766 46300020
         TM    ZERO(RWORK),STOPBIT  WAS STOP COMMAND ISSUED             46500017
         BO    LOGOFF                   BRANCH TO LOGOFF                46700017
         CLI   ZERO(RDECB),DBLEZERO WAS ECB POSTED                      46900017
         BNE   TESTCOD             IF SO, CHECK COMPLETION CODE         47100017
         B     WAITIMER                                                 47300017
TESTCOD  CLI   ZERO(RDECB),POSTCODE   CHECK FOR GOOD I/O                47600017
         BNE   INIOERR             IF ERROR, BRANCH                     48000017
         CLC   INBUFFR+SIX(SIX),PASSWD  CHECK FOR PASSWORD MATCH        48500017
         BNE   PASSWDER            NO MATCH SO BRANCH                   49000017
*                                                                       49500017
* PASSWORDS MATCH                                                       50000017
*                                                                       50500017
MATCH    EQU   *                                                        50800017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)  CLEAR  ECB                 51200017
         READ  (RDECB),TT,(RDCB),(RBUFFER),14,,1,MF=E                   52000017
         WAIT  ECB=(RDECB)                                              52500017
*                                                                       53030017
* READS INDICATING SUCCESSFUL INITIALIZATION ARE COMPLETE.  NOW XMIT    53060017
* END MASSAGE TO THE 1130.                                              53090017
*                                                                       53120017
ISWRITE  LA    RCODE,ONE        SET INDICATOR TO ONE                    53150017
         MVC   INBUFFR(MSGLNTH),ENDMSG   PUT MESSAGE INTO BUFFER        53180017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)  CLEAR ECB                  53210017
         WRITE (RDECB),TIXR,(RDCB),(RBUFFER),10,,1,MF=E  WRITE MESSAGE  53240017
         WAIT  ECB=(RDECB)         WAIT FOR I/O COMPLETE                53270017
         CLI   ZERO(RDECB),POSTCODE     CHECK FOR GOOD I/O              53310017
         BNE   INIOERR             IF NOT GOOD BRANCH                   53360017
         CLC   PASSWD(SIX),PASSWD01  IS THIS SECOND PASSWORD            53380017
         BE    BTAMEND            IF YES, BRANCH TO CLOSE BTAM          53400017
         MVC   PASSWD(SIX),PASSWD01  PUT SECOND PASSWORD INTO MODEL     53420017
         LA    RCOUNT,FIVE        RESET A COUNT OF FIVE                 53440017
         B     ISREAD            GO TO ISSUE BTAM READ                  53460017
SET00    MVC   PASSWD(SIX),PASSWD00  RESET 00 IN MODEL                  53468017
         B     MATCH                 BRANCH TO READ CONTINUE            53476017
SET01    MVC   PASSWD(SIX),PASSWD01  RESET 01 IN MODEL                  53484017
         B     MATCH              BRANCH TO READ CONTINUE               53492017
         EJECT                                                          53500017
*                                                                       54000017
* I/O IS COMPLETED. CLOSE BTAM DCB                                      54500017
BTAMEND  EQU   *                                                        55200017
         IC    RWORK,CHAR                                               56000017
         STC   RWORK,BTAMOPEN                                           56500017
         LA    RPAR1,BTAMOPEN      SET POINTER TO DCB                   57000017
         CLOSE BTAMDCB,MF=(E,(1))                                       57500017
*                                                                       58500017
* SET UP FOR SVC EXIT TO POST BITS IN GFX'S OVERALL CONTROL TABLE       59000017
*                                                                       59500017
         LA    RPAR0,SVCPARM       SET POINTER TO PARAMETER LIST        60500017
         SVC   80                       ISSUE CALL TO SVC 80            61500017
*                                                                       62500017
* PROCESSING IS COMPLETED. FREE STORAGE AND RETURN TO O/S               63000017
*                                                                       63500017
RETURN   L     RSAVE,INPROSAV+FOUR      RESTORE REGISTER 13             64500017
         RETURN (14,12),RC=0                                            65500017
INIOERR  LA    RPAR1,IOMSG         SET R1 TO POINT TO MESSAGE           65800017
         BAL   RBAL,WTOR           GO WRITE MESSAGE                     66100017
         LTR   RCODE,RCODE         CHECK IF ERROR ON READ OR WRITE      66400017
         BE    ISREAD              ERROR ON READ                        66700017
         B     ISWRITE             ERROR ON WRITE                       67000017
PASSWDER EQU   *                                                        67500017
         CLC   INBUFFR+SIX(SIX),PASSWD00      WAS PASSWORD 00 RE AD     67600017
         BE    SET00                                                    67700017
         CLC   INBUFFR+SIX(SIX),PASSWD01 WAS 01 READ                    67800017
         BE    SET01              IF YES, BRANCH                        67900017
         XC    ZERO(FOUR,RDECB),ZERO(RDECB)   CLEAR ECB                 68200017
         WRITE (RDECB),TR,(RDCB),(RBUFFER),,,1,MF=E                     69000017
         WAIT  ECB=(RDECB)        WAIT FOR I/O COMPLETION               69050017
         CLI   ZERO(RDECB),POSTCODE     CHECK FOR GOOD I/O              69100017
         BNE   INIOERR             IF NOT GOOD, BRANCH                  69150017
         LTR   RCOUNT,RCOUNT     IS INITIALIZATION COUNT ZERO           69200017
         BNE   DECNT              IF NOT, BRANCH                        69250017
         LA    RPAR1,INITMSG       SET R1 TO POINT TO MESSAGE           69300017
         BAL   RBAL,WTOR           GO TO WRITE MESSAGE                  69600017
         B     ISREAD              RE-ISSUE A READ                      69700017
DECNT    BCTR  RCOUNT,0           SUBTRACT COUNT BY ONE                 69730017
         B     ISREAD             GO ISSUE A READ                       69760017
WTOR     XC    WTORECB(FOUR),WTORECB   CLEAR ECB                        69800017
         XC    WTOREPLY(FOUR),WTOREPLY CLEAR REPLY AREA                 69900017
         WTOR  ,,,,MF=(E,(1))      WTOR                                 70150017
         WAIT  ECB=WTORECB                                              70200017
         CLI   WTOREPLY,CANCEL     WAS REQUEST CANCELLED                70250017
         BE    LOGOFF              IF SO, RETURN                        70300017
         CLI   WTOREPLY,RETRY      WAS RETRY REQUESTED                  70350017
         BNE   WTOR                IF NOT, WRITE AGAIN                  70400017
         BR    RBAL                GO BACK TO RETRY                     70450017
         EJECT                                                          70500017
*                                                                       71000017
* CONSTANTS AND WORKAREAS                                               71500017
*                                                                       72000017
PASSWD   DC    C'      '          AREA FOR PASSWORD MODEL               72100017
PASSWD00 DC    C'SGJP00'          PASSWORD 00                           72200017
PASSWD01 DC    C'SGJP01'          PASSWORD 01                           72300017
ZEROS8   DC    X'0000000000000000'      EIGHT BYTES OF ZERO        R018 72400018
ENTRYEQU DC    CL9'OCTENTRY='      START OF OCT HEADER IDENTIFIER       72600017
* PARAMETERS FOR SVC ROUTINE                                            72910017
SVCPARM  DS    0F                  PARAMETER LIST ON FULL WORD BOUNDARY 72920017
SVCCODE  DC    C'NPRO'             INITIAL PROCESSOR CODE               72930017
SVCUNIT  DC    C'0XXX'             SPACE FOR UNIT NUMBER                72940017
NUNITS   DC    F'0'                WORD CONTAINING # OF UNITS           72950017
KLOF     DC    C'PLOG'             LOG OFF CODE                         72955017
KLOFUTN  DC    C' ...'             UNIT IDENTIFICATION                  72960017
WTORECB  DC    F'0'                WTOR ECB                             72965017
WTOREPLY DC    F'0'                WTOR REPLY AREA                      72970017
ONESEC   DC    F'38462'            ONE SECOND TIMER ELEMENT             72975017
KXX      DC    H'20'               X'14' CONSTANT                       72985017
INPROSAV DS    18F                 SAVE AREA                            72990017
INBUFFR  DS    10F                 BUFFER                               73000017
ANSWAREA DS    1F             ANSWER AREA FOR EXTRACT MACRO        EXTR 73050019
ADPARM   DC    F'0'                POINTER TO INPUT PARAMETER LIST      73100017
CHAR     DC    X'80'               OPTION BYTE CONSTANT                 73200017
ENDMSG   DC    X'1002'             DLE STX                              73560017
         DC    X'98'               MESSAGE IDENTIFIER                   73620017
         DC    X'69'         DATA SET REFERENCE NUMBER                  73680017
         DC    X'00'               SEQUENCE NUMBER                      73740017
         DC    X'04'               LENGTH OF HEADER                     73800017
         DC    X'0800'             EOT IDENTIFIER                       73860017
         DC    C'SP'               OPTIONAL DATA                        73920017
BTAMOPEN OPEN  BTAMDCB,MF=L                                             74120017
BTAMREAD READ  READDECB,TI,,,14,,1,MF=L                                 75020017
BTAMDCB  DCB   DSORG=CX,MACRF=(R,W),DDNAME=SUBSYS,DEVD=BS               75920017
OPENFLAG EQU   BTAMDCB+48          LOCATION OF OPEN FLAGS               76120017
*                                                                       76320017
* WTOR'S IN L-FORM                                                      76720017
*                                                                       77120017
IOMSG    WTOR  'IKD002D XXX - LINE ERROR',WTOREPLY,1,WTORECB,MF=L,     *77320000
               ROUTCDE=(2,8),DESC=4                                R018 77520000
INITMSG  WTOR  'IKD001D XXX - INITIALIZATION FAILURE',WTOREPLY,1,      *77920000
               WTORECB,MF=L,ROUTCDE=2,DESC=4                       R018 78320000
         EJECT                                                          79000017
DCVT     DSECT                                                          85050017
         CVT                                                            85100017
         EJECT                                                          85120017
GFXOCTHD DSECT                                                          85150017
GFXHDSTR EQU   *                       START OF HEADER RECORD           85200017
OCTSYS   DS    CL1                     BASE SYSTEM                      85250017
OCTGSMB  DS    CL1                      GJP SYSOUT CLASS                85300017
OCTBSMB  DS    CL1                      BATCH SMB SYSOUT CLASS          85350017
OCTFTYPE DS    CL1                      JOBCLASS FOR USER JOB FGD       85400017
OCTBTYPE DS    CL1                      JOBCLASS FOR USER JOB BGD       85450017
OCTPRINT DS    CL1                      PRINT SYSOUT CLASS              85500017
OCTPUNCH DS    CL1                      PUNCH SYSOUT CLASS              85550017
         DS    0H                                                       85600017
OCTUNBR  DS    CL2                     NO. OF SYSGENED 2250             85650017
OCTFPRI  DS    CL2                      PRIORITY FOR GJP/USER FGD       85700017
OCTBPRI  DS    CL2                      PRIORITY FOR USER JOB BGD       85750017
         DS    0F                                                       85800017
OCTFGREG DS    CL4                      REGION SIZE GJP                 85850017
OCTFUREG DS    CL4                      REGION SIZE USER FGD            85900017
OCTBUREG DS    CL4                      REGION SIZE USER BGD            85950017
OCTHRES  DS    CL8                      RESERVED                        86000017
OCTNAME  DS    CL20                     PROGRAMMER NAME                 86050017
OCTACCT  DS    CL20                     ACCOUNT NUMBER                  86100017
GFXHDEND EQU   *                       END OF HEADER RECORD             86150017
GFXHDSZE EQU   GFXHDEND-GFXHDSTR       SIZE OF OCT HEADER RECORD        86200017
         EJECT                                                          86250017
GFXOCTEN DSECT                                                          86300017
         DS    0F                                                       86350017
GFXENSTR EQU   *                       START OF ENTRY RECORD            86400017
OCTECB   DS    CL4                      ECB                             86450017
OCTUCB   DS    CL4                      UCB ADDRESS                     86500017
OCTUNIT  DS    CL4                      UNIT ADDRESS                    86550017
OCTCOUNT DS    CL4                      JOB COUNT                       86600017
OCTNOTE  DS    CL4                      NOTE                            86650017
OCTABEND DS    A                       ABEND CODE                       86700017
OCTRESD  DS    CL8                      RESERVED                        86750017
**********************************************************************  86800017
****                          ATTRIBUTE 1                          **** 86850017
**********************************************************************  86900017
OCTATTR1 DS    CL2                      ATTRIBUTES                      86950017
OCTBACTV EQU   X'80'          0-2250 NOT ACTIVE   1-2250 ACTIVE         87000017
OCTBCPGM EQU   X'40'          0-LAST JOB GJP      1-LAST JOB USER PGM   87050017
OCTBRUNN EQU   X'20'          0-JOB NOT RUNNING   1-JOB RUNNING         87100017
OCTBIODQ EQU   X'10'          0-                  1-I/O ERROR-DEQ       87150017
OCTBIOGS EQU   X'08'          0-                  1-I/O ERROR/GJP SMB   87200017
OCTBIOGD EQU   X'04'          0-                  1-I/O ERROR-USER JCL  87250017
OCTBIOUS EQU   X'02'          0-                  1-I/O ERROR-USER SMB  87300017
OCTBSTOP EQU   X'01'          0-                  1-STOP 2250           87350017
OCTBIGNR EQU   X'80'          0-                  1-IGNORE SMB          87400017
OCTBCANC EQU   X'40'          0-WAIT FOR INIT CAN 1-INIT CANCEL RECVD   87450017
OCTBSMBB EQU   X'20'          0-NO SMB INPUT      1-SMB INPUT           87500017
**********************************************************************  87550017
****                          ATTRIBUTE 2                          **** 87600017
**********************************************************************  87650017
OCTATTR2 DS    CL2                      ATTRIBUTES                      87700017
OCTBIRRE EQU   X'80'          0-                  1-GJP INTERNAL ERROR  87750017
OCTBBACK EQU   X'40'          0-                  1-BACKGROUND JOB      87800017
OCTBLOFF EQU   X'20'          0-                  1-LOGOFF              87850017
OCTBFAST EQU   X'10'          0-                  1-FAST STOP           87900017
OCTBMED  EQU   X'08'          0-                  1-MEDIUM STOP         87950017
OCTBSLOW EQU   X'04'          0-                  1-SLOW STOP           88000017
OCTABND  EQU   X'02'          0-                  1-PROGRAM ABEND       88050017
OCTBNEW  EQU   X'01'          0-                  1-NEW 2250            88100017
OCTBICAN EQU   X'80'          0-                  1-IKACKXT POST(INIT)  88150017
OCTBPCAN EQU   X'40'          0-                  1-IKACKXT POST(USER)  88200017
OCTBCMDG EQU   X'20'          0-                  1-IKAGCMD POST        88250017
OCTBSVC  EQU   X'10'          0-                  1-IKAGJP POST         88300017
**********************************************************************  88350017
****                          ATTRIBUTE 3                          **** 88400017
**********************************************************************  88450017
OCTATTR3 DS    CL2                      ATTRIBUTES                      88500017
OCTBIERR EQU   X'80'          0-                  1-GJP INTERNAL ERROR  88550017
OCTBBACM EQU   X'40'          0-                  1-BACKGROUND JOB      88600017
OCTBLOFM EQU   X'20'          0-                  1-LOGOFF              88650017
OCTBFASM EQU   X'10'          0-                  1-FAST STOP           88700017
OCTBMEDM EQU   X'08'          0-                  1-MEDIUM STOP         88750017
OCTBSLOM EQU   X'04'          0-                  1-SLOW STOP           88800017
OCTBABNM EQU   X'02'          0-                  1-PROGRAM ABEND       88850017
OCTBNEWM EQU   X'01'          0-                  1-NEW 2250            88900017
OCTBCANI EQU   X'80'          0-                  1-IKACKXT POST(INIT)  88950017
OCTBCANP EQU   X'40'          0-                  1-IKACKXT POST(USER)  89000017
OCTBGCMD EQU   X'20'          0-                  1-IKAGCMD POST        89050017
OCTBSVCP EQU   X'10'          0-                  1-IKAGJP POST         89100017
**********************************************************************  89150017
****                          ATTRIBUTE 4                          **** 89200017
**********************************************************************  89250017
OCTATTR4 DS    CL2                      ATTRIBUTES                      89300017
*                                                                       89350017
GFXENEND EQU   *                       END OF ENTRY RECORD              89400017
GFXENSZE EQU   GFXENEND-GFXENSTR       SIZE OF ENTRY RECORD             89450017
         EJECT                                                          89500017
         END                                                            90500017
./       ADD   SSI=00013302,NAME=IKDIOR,SOURCE=0
 TITLE 'IKDIOR' INPUT/OUTPUT ROUTINE                                    00200017
*STATUS: CHANGE LEVEL 000                                             * 00400017
*FUNCTION/OPERATION: REQUEST I/O FUNCTIONS OF PTOP AS DIRECTED BY     * 00600017
*   CALLING ROUTINE. ITS OPERATION INCLUDE:                           * 00700017
*   1) UPON REQUEST PREPARE FOR AND ISSUE A CALL TO IKDGTNIT. UPON    * 00800017
*   INITIALIZATION BEING COMPLETED SUCCESSFULLY, PREPARE PARAMETER    * 00900017
*   LISTS FOR REMAINING CALLS TO PTOP SUBROUTINES                     * 01000017
*   2) CALL PTOP SUBROUTINES AS DIRECTED BY CALLING ROUTINE           * 01100017
*   3) UPON COMPLETION OF A READ, EXAMINE THE DATA RECEIVED AND       * 01200017
*   PERFORM AS FOLLOWS:                                               * 01300017
*   A-IF DATA WAS A PROCESSOR SELECT RECORD, MOVE THE LINK/LOAD INDIC-* 01400017
*   ATOR INTO CCTSTAT AND PLACE THE COMMAND KEY INTO THE CCTPWKA      * 01500017
*   B-IF DATA WAS AN EXTRACT RECORD, POST THE PROCESSOR ECB WITH THE  * 01600017
*   ATTENTION TYPE CODE,AND, UPON AN END KEY ATTENTION, MOVE THE      * 01700017
*   EXTRACT RECORD FROM THE I/O BUFFER TO THE PROCESSOR WORKAREA      * 01800017
*ENTRY POINTS: IKDIOR VIA BALR BY IKDINIT, IKDCTL, IKDMSG, IKDPLOF0   * 02200017
*   AND IKDPREC0                                                      * 02300017
*INPUT: PARAMETERS FROM CALLING ROUTINE                               * 02500017
*   A-REGISTER 1 CONTAINS POINTER TO CONSOLE CONTROL TABLE            * 02560017
*   B-REGISTER 0 CONTAINS FUNCTION CODE, WHERE                        * 02620017
*   X'00' READ AND TEST                                               * 02680017
*   X'04' WRITE AND TEST                                              * 02740017
*   X'08' TEST LAST READ                                              * 02800017
*   X'0C' TEST LAST WRITE                                             * 02860017
*   X'10' INITIALIZE                                                  * 02920017
*   X'14' TERMINATE                                                   * 02980017
*   X'18' READ                                                        * 03040017
*   X'1C' WRITE                                                       * 03100017
*   X'20' WRITE ASYNCHRONOUS TO RESTART                               * 03160017
*   X'24' WRITE ASYNCHRONOUS TO TERMINATE                             * 03220017
*   2) DATA MOVED FROM I/O BUFFER TO I/O AREA BY IKDGTRED             * 03400017
*   3) RETURN CODES FROM IKDGTNIT AND IKDGTCLT INDICATING STATUS OF   * 03500017
*   PREVIOUS I/O REQUEST                                              * 03600017
*OUTPUT: CALLING SEQUENCE FOR PTOP ROUTINES                           * 03800017
*       ROUTINE              PARAMETER             SOURCE             * 03900017
*       *******              *********             ******             * 04000017
*        GTNIT-------------WRITE BUFFER-----------IKDIOR              * 04100017
*                         READ BUFFER             IKDIOR              * 04200017
*                          ASYNCHRONOUS ROUTINE    N/A                * 04300017
*                          STATUS CODE            IKDIOR              * 04400017
*                          PASSWORD               IKDIOR              * 04500017
*                          DATA SET REFERENCE     IKDIOR              * 04600017
*        GTRED-------------DATA SET REFERENCE-----IKDIOR              * 04700017
*                          TEMP ARRAY             CALLING ROUTINE     * 04800017
*                          ELEMENT COUNT          CALLING ROUTINE     * 04900017
*                          DATA TYPE              IKDIOR              * 05000017
*        GTWRT-------------DATA SET REFERENCE-----IKDIOR              * 05100017
*                          TEMP ARRAY             CALLING ROUTINE     * 05200017
*                          ELEMENT COUNT          CALLING ROUTINE     * 05300017
*                          DATA TYPE              IKDIOR              * 05400017
*                          CONTROL OPTION         IKDIOR              * 05500017
*        GTCLT-------------DATA SET REFERENCE-----IKDIOR              * 05600017
*                          TEST CODE              IKDIOR              * 05700017
*                          STATUS CODE            IKDIOR              * 05800017
*        GTEND-------------DATA SET REFERENCE-----IKDIOR              * 05900017
*   2) DATA MOVED FROM I/O AREA TO I/O BUFFER BY IKDGTWRT             * 06000017
*EXTERNAL ROUTINES: 1) GTNIT TO INITIALIZE PTOP                       * 06100017
*   2) GTRED FOR READ REQUESTS                                        * 06200017
*   3) GTWRT FOR WRITE REQUESTS                                       * 06300017
*   4) GTCLT TO TEST PREVIOUS READS OR WRITES                         * 06400017
*   5) GTEND TO TERMINATE PTOP                                        * 06500017
*EXITS: 1) CALL GTNIT TO INITIALIZE                                   * 06800017
*   2) CALL GTRED TO READ                                             * 06900017
*   3) CALL GTWRT TO WRITE                                            * 07000017
*   4) CALL GTCLT TO TEST                                             * 07100017
*   5) CALL GTEND TO TERMINATE                                        * 07200017
*   6) RETURN TO CALLER                                               * 07300017
*TABLES/WORKAREAS: CCT  BTAM I/O BUFFER                               * 07500017
*ATTRIBUTES: RESIDENT IN PARTITION DURING SGJP; REENTRANT             * 07700017
*NOTES: N/A                                                           * 07800017
         EJECT                                                          08000017
IKACCT   DSECT                                                          08100017
         SPACE                                                          08200017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         08300017
         SPACE                                                          08400017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    08500017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     08600017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       08700017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             08800017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  08900017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  09000017
*                   SET.                                                09100017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      09200017
*                   SECOND.                                             09300017
         SPACE 2                                                        09400017
         SPACE 2                                                        09500017
*                             SECTION ONE                               09600017
         SPACE                                                          09700017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     09800017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    09900017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  10000017
         SPACE                                                          10100017
         DS    0F                                                       10200017
CCTUNAME DS    5F                  USER'S NAME                          10300017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         10400017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     10500017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       10600017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    10700017
*                                       AT LAST BEGIN JOB               10800017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   10900017
*                                       LAST BEGIN JOB                  11000017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 11100017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    11200017
*                                       JOB                             11300017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    11400017
*                                       JOB                             11500017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     11600017
*                                       CESSOR                          11700017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         11800017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         11900017
CCTJCTR  DS    H                   JOB COUNTER                          12000017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                12100017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   12200017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  12300017
CCTSSTAT DS    C                   SESSION STATUS                       12400017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              12500017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              12600017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    12700017
         EJECT                                                          12800017
         SPACE 2                                                        12900017
*                             SECTION TWO                               13000017
         SPACE                                                          13100017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   13200017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  13300017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 13400017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              13500017
         SPACE                                                          13600017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     13700017
*                                       FRAME                           13800017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  13900017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     14000017
*                                       MULTIPLE DISPLAY FRAME (ENT)    14100017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   14200017
CCTDISM  DS    C                   DISPLAY MASK                         14300017
CCTCSM   DS    C                   COMMAND SELECT MASK                  14400017
CCTPSTAT DS    CL2                 GJP STATUS                           14500017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              14600017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  14700017
CCTPWKAE EQU   *                                                        14800017
         SPACE 2                                                        14900017
*                             SECTION THREE                             15000017
         SPACE                                                          15100017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    15200017
*                   INTO SECTION ONE OR TWO                             15300017
         SPACE                                                          15400017
CCTDGMP  DS    F                  POINTER TO DGM                        15500017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                15600017
CCTCSTP  DS    F                  POINTER TO CST                        15700017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                15800017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            15900017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 16000017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              16100017
CCTDIARP DS    F                  POINTER TO DIA                        16200017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      16300017
CCTACTP  DS    F                  POINTER TO ACT                        16400017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     16500017
CCTIERRP DS    F                  POINTER TO IERR                       16600017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              16700017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               16800017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                16900017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 17000017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 17100017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   17200017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                17300017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                17400017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               17500017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              17600017
CCTPECB  DS    F                  PROCESSOR'S ECB                       17700017
CCTWECB  DS    F                  WTOR ECB                              17800017
CCTDIAWA DS    CL136               DIARY WORK AREA                      17900017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    18000017
CCTCSAVE DS    CL72                CTL SAVE AREA                        18100017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                18200017
CCTASAVE DS    CL72                DAT SAVE AREA                        18300017
*                                                                       18400017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       18500017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           18600017
*                                                                       18700017
IKDCCT   EQU   IKACCT              THREE CHARACTER PREFIX IS REPLACED   18800017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             18900017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               19000017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     19100017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               19200017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           19300017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    19400017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 19480017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   19560017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   19640017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   19720017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            19800017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 19880017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       19960017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  20040017
*                                  INATION OF DATA                      20120017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    20200017
*                                  THE I/O OPERATION TO BE TESTED BY    20280017
*                                  GTCLT                                20360017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        20440017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              20520017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   20610017
CCTPWKAL EQU   CCTPWKAE-CCTPWKA                                         20700017
RMNDR    EQU   CCTPWKAL-256                                             20800017
         EJECT                                                          20900017
IKDIOR   CSECT                                                          21000017
*                                                                       21100017
* REGISTERS                                                             21200017
*                                                                       21300017
RPAR0    EQU   0                                                        21400017
RPAR1    EQU   1                                                        21500017
RBUFF    EQU   2                                                        21600017
RCCT     EQU   3                                                        21700017
RSTCODE  EQU   4                                                        21800017
RWORK    EQU   5                                                        21900017
RHOLD    EQU   6                                                        22000017
RREAD    EQU   7                                                        22100017
RWRITE   EQU   8                                                        22200017
RTEST    EQU   9                                                        22300017
RBASE    EQU   10                                                       22400017
RBAL     EQU   11                                                       22500017
R12      EQU   12                                                       22550017
RSAVE    EQU   13                                                       22600017
RRET     EQU   14                                                       22700017
RBR      EQU   15                                                       22800017
*                                                                       22900017
* EQUATES                                                               23000017
*                                                                       23100017
ZERO     EQU   0                                                        23150017
CDCHAR   EQU   0                                                        23200017
DSREF    EQU   0                                                        23300017
ONE      EQU   1                                                        23350017
PSR      EQU   1                                                        23400017
EXT      EQU   2                                                        23500017
THREE    EQU   3                                                        23550017
PSRLNTH  EQU   3                                                        23600017
TWO      EQU   2              EQUATE FOR TWO                            23630017
TSTRCODE EQU   1                   CODE TO TEST READ                    23660017
TSTWCODE EQU   2                   CODE TO TEST WRITE                   23720017
TSTRAWCD EQU   3                   CODE TO TEST READ AND WAIT           23780017
TSTWAWCD EQU   4                   CODE TO TEST WRITE AND WAIT          23840017
TESTCD   EQU   4                                                        23900017
FOUR     EQU   4                                                        23930017
FIVE     EQU   5                                                        23960017
SIX      EQU   6                                                        23980017
ADLENGTH EQU   4                                                        24000017
IOARRAY  EQU   4                                                        24100017
WRTBUF   EQU   4                                                        24200017
CTLCHAR  EQU   7                                                        24300017
EIGHT    EQU   8                                                        24350017
REDBUF   EQU   8                                                        24400017
STATCODT EQU   8                                                        24500017
ELCOUNT  EQU   8                                                        24600017
PROCLNTH EQU   8                                                        24620017
PTOP     EQU   8                                                        24650017
CBITE    EQU   8                                                        24660017
RADDR    EQU   12                                                       24670017
ASYRTN   EQU   12                                                       24700017
DATYP    EQU   12                                                       24800017
CTLOP    EQU   16                                                       24900017
PASSWD   EQU   16                                                       25000017
TWENTY   EQU   20                                                       25020017
SIXEIGHT EQU   68                                                       25040017
SIXNINE  EQU   69                                                       25060017
NINENINE EQU   99                                                       25080017
STATCODI EQU   20                                                       25100017
FIFTY2   EQU   52                  EQUATE                               25150017
TWO56    EQU   256                                                      25200017
TWO58    EQU   258                                                      25300017
TWO68    EQU   268                                                      25320017
TWO80    EQU   280                                                      25340017
TWO81    EQU   281                                                      25360017
HEX00    EQU   X'00'                                                    25620017
HEX01    EQU   X'01'                                                    25640017
HEX04    EQU   X'04'                                                    25660017
ENDKY    EQU   X'04'                                                    25700017
CANKY    EQU   X'08'                                                    25800017
HEX10    EQU   X'10'                                                    25820017
HEX1C    EQU   X'1C'                                                    25840017
HEX40    EQU   X'40'                                                    25860017
HEX7F    EQU   X'7F'                                                    25880017
POSTCODE EQU   X'7F'                                                    25900017
HEX81    EQU   X'81'                                                    25907017
HEX83    EQU   X'83'                                                    25914017
A        EQU   C'A'                                                     25921017
C        EQU   C'C'                                                     25928017
D        EQU   C'D'                                                     25935017
E        EQU   C'E'                                                     25942017
K        EQU   C'K'                                                     25949017
M        EQU   C'M'                                                     25956017
N        EQU   C'N'                                                     25963017
O        EQU   C'O'                                                     25970017
R        EQU   C'R'                                                     25977017
W        EQU   C'W'                                                     25984017
         EJECT                                                          26000017
         SAVE  (14,12)                                                  26100017
         BALR  RBASE,0             SET UP BASE                          26200017
         USING *,RBASE             ESTABLISH ADDRESSIBILITY             26300017
         LR    RCCT,RPAR1                                               26400017
         USING IKDCCT,RCCT         SET UP ADDRESSABILITY FOR CCT        26500017
         ST    RSAVE,CCTASAVE+FOUR   SAVE CALLER'S SAVE AREA ADDRESS    26530017
         LA    RWORK,CCTASAVE                                           26560017
         ST    RWORK,EIGHT(RSAVE)    CHAIN SAVE AREAS                   26590017
         LR    RSAVE,RWORK                                              26620017
         SR    R12,R12            CLEAR REGISTER 12                     26630017
*                                                                       26650017
* HOUSEKEEPING COMPLETE. BRANCH ON THE CONTENTS OF REGISTER ZERO WHICH  26700017
* CONTAINS THE FUNCTION CODE TO REQUEST THE NEEDED PTOP FUNCTION        26800017
*                                                                       26900017
         LR    RWORK,RPAR0        PUT I/O CODE IN RWORK                 26950017
         B     IOTAB(RWORK)       BRANCH ON RWORK                       27020017
IOTAB    B     CALLREAD            BRANCH TO READ AND TEST              27100017
         B     CALLWRIT            BRANCH TO WRITE AND TEST             27180017
         B     CALLTSTR            BRANCH TO TEST READ                  27260017
         B     CALLTSTW            BRANCH TO TEST WRITE                 27340017
         B     CALLINIT            BRANCH TO INITIALIZE                 27420017
         B     CALLEND             BRANCH TO TERMINATE                  27500017
         B     READONLY            BRANCH TO READ                       27580017
         B     WRITONLY            BRANCH TO WRITE                      27660017
         B     WRITRST        X'20'     RESTART CODE                    27770017
         B     WRITTRM        X'24'     TERMINATE CODE                  27780017
         EJECT                                                          27800017
*                                                                       27900017
* PARAMETER TO READ                                                     28000017
*                                                                       28100017
CALLREAD MVI   CCTSTAT+THREE,W     PUT WAIT CODE IN CCT                 28120017
         B     SETRLNTH            BRANCH TO SET READ LENGTH            28140017
READONLY MVI   CCTSTAT+THREE,O     PUT READ ONLY CODE IN CCT            28160017
SETRLNTH L     RPAR1,CCTRECLN      GET DATA LENTH                       28180017
         SRA   RPAR1,ONE           DIVIDE BY TWO                        28220017
         ST    RPAR1,CCTRECLN      PUT LENGTH BACK INTO CCT             28260017
         LA    RPAR1,CCTRDLST      GET ADDRESS OF READ PARAMETER LIST   28300017
*                                                                       28400017
* PARAMETER LIST READY, CALL GTRED                                      28500017
*                                                                       28600017
         CALL  GTRED,MF=(E,(1))                                         28700017
         B     CALLTSTR            GO TO TEST READ                      28800017
*                                                                       28900017
* PARAMETER TO WRITE.                                                   29000017
*                                                                       29100017
CALLWRIT MVI   CCTSTAT+THREE,W     PUT CODE TO WAIT IN CCT              29120017
         B     SETWLNTH            GO TO SET READ LENGTH                29140017
WRITONLY MVI   CCTSTAT+THREE,O     PUT WRITE ONLY CODE IN CCT           29160017
SETWLNTH L     RBUFF,CCTBUFFP      GET BUFFER ADDRESS                   29180017
         A     RBUFF,CCTRECLN      ADD RECORD LENGTH TO BUFFER ADDRESS  29218017
*                                                                       29227017
* RBUFF NOW POINTS TO NEXT AVAILABLE BUFFER LOCATION                    29236017
*                                                                       29245017
         L     RPAR1,CCTRECLN      GET DATA LENGTH                      29254017
         SRA   RPAR1,ONE           DIVIDE LENGTH BY TWO                 29263017
         STH   RPAR1,ZERO(RBUFF)   PUT INTO NEXT BUFFER LOCATION        29272017
         LA    RPAR1,ONE(RPAR1)    INCREMENT DATA LENGTH BY ONE         29281017
         ST    RPAR1,CCTRECLN      PUT INTO CCT AS NEW DATA LENGTH      29290017
         LA    RPAR1,CCTWRLST      GET ADDRESS OF WRITE PARAMETER LIST  29300017
*                                                                       29400017
* PARAMETER LIST READY, CALL GTWRT                                      29500017
*                                                                       29600017
         CALL  GTWRT,MF=(E,(1))                                         29700017
         B     CALLTSTW            GO TO TEST WRITE                     29800017
         EJECT                                                          29900017
*                                                                       30000017
* PARAMETER TO TEST LAST READ AND WAIT                                  30100017
*                                                                       30200017
CALLTSTR CLI   CCTSTAT+THREE,O     WAS WAIT SPECIFIED                   30250017
         BNE   WAITREAD            NO, BRANCH                           30300017
         LA    RWORK,TSTRCODE      SET CODE TO TEST READ                30350017
         B     BALREAD             GO TO TEST READ                      30400017
WAITREAD LA    RWORK,TSTRAWCD      SET CODE TO TEST READ AND WAIT       30450017
BALREAD  BAL   RBAL,CALLCLT        GO TO CALL SUBROUTINE                30500017
         LTR   RTEST,RTEST        CHECK FOR ZERO RETURN CODE            30600017
         BE    CALLREAD           IF ZERO, RETRY I/O                    30700017
         B     RDCMPLT             GO TO TEST TYPE READ COMPLETED       30800017
*                                                                       30900017
* PARAMETER TO TEST LAST WRITE AND WAIT                                 31000017
*                                                                       31100017
CALLTSTW CLI   CCTSTAT+THREE,O     WAS WAIT SPECIFIED                   31150017
         BNE   WAITWRIT            NO, BRANCH                           31200017
         LA    RWORK,TSTWCODE      SET CODE TO TEST WRITE               31250017
         B     BALWRIT             GO TO TEST WRITE                     31300017
WAITWRIT LA    RWORK,TSTWAWCD      SET CODE TO TEST WRITE AND WAIT      31350017
BALWRIT  BAL   RBAL,CALLCLT        GO TO CALL SUBROUTINE                31400017
         LTR   RTEST,RTEST        CHECK FOR ZERO RETURN CODE            31500017
         BE    CALLWRIT           IF ZERO, RETRY I/O                    31600017
         TM    CCTSSTAT,HEX10      IS EXTRACT RECORD EXPECTED           31610017
         BZ    TESTSMB             IF NOT, BRANCH TO TEST SMB BIT       31620017
         MVI   CCTPECB,POSTCODE    POST ECB COMPLETE                    31630017
         MVI   CCTPECB+THREE,ENDKY WITH END KEY                         31640017
         CLC   CCTCCR(THREE),WRICON IS WRITE MESSAGE CURRENT PROCESSOR  31650017
         BNE   DIORTRN            IF NOT, BRANCH                        31660017
         MVI   CCTSTAT+TWO,N       INDICATE REPLY WAS SENT              31670017
         B     DIORTRN             BRANCH TO RETURN                     31680017
TESTSMB  TM    CCTPSTAT+ONE,HEX01  IS SMB IN CONTROL                    31690017
         BZ    DIORTRN            IF MOT BRANCH                         31720017
         LA    RPAR1,FOUR          SET READ LENGTH IN CCT               31740017
         ST    RPAR1,CCTRECLN                                           31760017
         B     CALLREAD            GO TO READ END KEY INDICATION        31780017
*                                                                       31800017
* THIS SUBROUTINE PREPARES PARAMETERS FOR GTCLT.  UPON RETURN FROM PTOP 31900017
* IT USES A BRANCH TABLE TO RESOLVE RETURN CODES                        32000017
*                                                                       32100017
CALLCLT  MVI   CCTSTAT+THREE,HEX00  CLEAR TEST CODE IN CCT              32200017
         ST    RWORK,CCTTSTCD      PUT CODE IN CONSOLE CONTROL TABLE    32300017
         LA    RPAR1,CCTTSLST      GET ADDRESS OF TEST PARAMETER LIST   32400017
*                                                                       32500017
* PARAMETER LIST READY, CALL OTCLT                                      32600017
*                                                                       32700017
         CALL  GTCLT,MF=(E,(1))                                         32800017
         L     RTEST,CCTSTCOD      GET STATUS CODE RETURNED BY PTOP     32900017
         SLL   RTEST,TWO           SHIFT TO MAKE MULTIPLE OF FOUR       33000017
         B     RTNTAB(RTEST)       GO TO RETURN CODE TABLE              33100017
*                                                                       33200017
* BRANCH TABLE FOR POSSIBLE RETURN CODES FROM PTOP                      33300017
*                                                                       33400017
RTNTAB   B     PMSG3               BRANCH TO PREPARE ERROR MESSAGE 3    33500017
         B     REGISTER            I/O COMPLETED SUCCESSFULLY           33700017
         B     DIORTRN             I/O PENDING                          33800017
         B     DIORTRN             I/O STARTED BUT NOT COMPLETE         33900017
         B     PMSG3               BRANCH TO PREPARE ERROR MESSAGE 3    34000017
         B     PMSG3               BRANCH TO PREPARE ERROR MESSAGE 3    34100017
         B     PMSG2               BRANCH TO PREPARE ERROR MESSAGE 2    34200017
         B     REGISTER           WRONG LENGTH SPECIFIED                34300017
RETRYIO  SR    RTEST,RTEST         SET CODE TO INDICATE RETRY PREVIOUS  34450017
REGISTER BR    RBAL                OPERATION. SEND CODE TO CALLING PT   34500017
*                                  TO INDICATE THIS                     34600017
PMSG2    MVC   CCTERLST(PSRLNTH),M302  SET MSG CODE AND OPTION BYTE FOR 34620017
         MVI   CCTERLST+CBITE,HEX83  FOR IKAIERR                        34640017
         B     GOTOIERR            GO TO BRANCH TO IERR                 34660017
PMSG3    MVC   CCTERLST(PSRLNTH),M303  SET MSG CODE AND OPTION BYTE     34680017
         MVI   CCTERLST+CBITE,HEX83  FOR IKAIERR                        34700017
GOTOIERR LA    RPAR0,CCTERLST      SET ADDRESS TO PARAMETER LIST        34720017
         LR    RPAR1,RCCT          SET POINTER TO CCT                   34740017
         L     RBR,CCTIERRP        GET ADDRESS OF IKAIERR               34760017
         BALR  RRET,RBR            GO TO ERROR ROUTINE                  34780017
         LTR   RBR,RBR             TEST RETURN CODE FROM IERR           34800017
         BNZ   GTEND               TERMINATE IF NON-ZERO                34810017
         CLC   CCTERLST(PSRLNTH),M304   WAS THIS MSG ISSUED             34820017
         BE    GTEND                    YES                             34830017
         CLI   CCTREPAR,R          DID USER REQUEST RETRY               34840017
         BNE   RTSTRPLY            IF NOT, TEST AGAIN                   34860017
         B     RETRYIO             IF YES, RETURN TO RETRY I/O          34880017
RTSTRPLY CLI   CCTREPAR,C          DID USER REQUEST CANCEL              34900017
         BNE   GOTOIERR            INVALID CHARACTER. GO BACK TO IERR   34920017
         MVC   CCTERLST(PSRLNTH),M304  PUT MESSAGE CODE IN LIST         34940017
         MVI   CCTERLST+CBITE,HEX81  PUT OPTION BYTE IN LIST            34960017
         B     GOTOIERR            GO TO IKAIERR                        34980017
         EJECT                                                          35005017
*                                                                       35010017
**   INFORM SUBSYSTEM IF RESTART OR TERMINATE                           35015017
*                                                                       35020017
WRITTRM  LA    RPAR0,TERMNAT       ADDRESS OF TERMINATE CODE            35026017
         B     WRITASYN            GO TO WRITE                          35032017
WRITRST  LA    RPAR0,RESTART       ADDRESS OF RESTART CODE              35038017
WRITASYN LA    RWORK,TWO                ASYNCHRONOUS TRANSMISSION       35045017
         ST    RWORK,CCTCTLOP      PUT IN CONTROL OP OF CCT             35060017
         MVC   CCTGACBP,CCTWRLST+FOUR   SAVE CURRENT I/O AREA ADDRESS   35062017
         ST    RPAR0,CCTWRLST+FOUR      SET ADDRESS OF DATA TO BE SENT  35064017
         L     RPAR1,CCTIELST+TWENTY  GET CONTENTS OF IELST             35064517
         LTR   RPAR1,RPAR1        IS CONTENTS ZERO                      35065017
         BE    SETRC04            IF YES, BRANCH TO RETURN              35065517
         LA    RPAR1,CCTWRLST           GET ADDRESS OF LIST             35066017
         CALL  GTWRT,MF=(E,(1))         AND PASS TO PTOP                35068017
         MVC   CCTWRLST+FOUR(FOUR),CCTGACBP   RESTORE CURRENT I/O ADDR  35070017
         LH    RWORK,CTLOPT             GET CODE TO INDICATE            35072017
         ST    RWORK,CCTCTLOP           USE OF MAINLINE                 35074017
         L     RBUFF,CCTBUFFP      GET BUFFER ADDRESS                   35080017
         A     RBUFF,CCTRECLN      ADD TO IT RECORD LENGTH              35100017
         L     RPAR1,CCTRECLN      GET RECORD LENGTH                    35120017
         SRA   RPAR1,ONE           DIVIDE BY TWO                        35140017
         STH   RPAR1,ZERO(RBUFF)    PUT INTO NEXT BUFFER LOCATION       35160017
         LA    RPAR1,ONE(RPAR1)    INCREMENT BY ONE                     35180017
         ST    RPAR1,CCTRECLN      SET RECORD LENGTH                    35200017
         LA    RPAR1,CCTWRLST      GET ADDRESS OF LIST                  35220017
         CALL  GTWRT,MF=(E,(1))    CALL GTWRIT                          35240017
*                                                                       35250017
*    WAIT TO LET THE 1130 READ THE MESSAGE                              35260017
*                                                                       35270017
         LA    RPAR1,INTERVAL           ADDR OF VALUE                   35280017
         STIMER WAIT,TUINTVL=(1)        WAIT FOR COMPLETION             35290017
         LA    RWORK,TSTWCODE           GET CODE TO TEST                35300017
         ST    RWORK,CCTTSTCD           LAST WRITE                      35310017
         LA    RPAR1,CCTTSLST           ADDR OF PARAMETER LIST          35320017
         CALL  GTCLT,MF=(E,(1))                                         35330017
*                                                                       35340017
*    CLOSE THE LINE TO PREVENT I/O ERRORS                               35350017
*                                                                       35360017
GTEND    EQU   *                                                        35370017
         LA    RPAR1,CCTIELST           ADDR OF PARAMETER LIST          35380017
         CALL  GTEND,MF=(E,(1))                                         35390017
         LA    RWORK,ZERO      GET A ZERO                               35400017
         ST    RWORK,CCTIELST+TWENTY    PUT IN STATCODE POINTER         35410017
         B     SETRC04                  GO SET 'MUST TERMINATE' CODE    35420017
         EJECT                                                          35600017
*                                                                       35700017
* A READ HAS BEEN COMPLETED. DETERMINE IF THE DATA IN THE BUFFER IS     35800017
* A PROCESSOR SELECT RECORD OR AN EXTRACT RECORD                        35900017
*                                                                       36000017
RDCMPLT  EQU   *                                                        36100017
         L     RBUFF,CCTBUFFP     GET ADDRESS OF BUFFER                 36200017
         CLI   CDCHAR(RBUFF),E     IS DATA AN EXTRACT RECORD            36300017
         BE    EXTRCD              IF YES, BRANCH                       36400017
         CLI   CDCHAR(RBUFF),D     CHECK IF PSR AND PROCESSOR IS TO BE  36500017
         BE    MOVEKEY            LOADED.  IF TES, BRANCH               36600017
         CLI   CDCHAR(RBUFF),K     CHECK IF PSR AND PROCESSOR IS TO BE  36700017
         BNE   DIORTRN            LINKED TO.  IF NOT, BRANCH            36800017
MOVEKEY  EQU   *                                                        36900017
         MVC   CCTSTAT(ONE),CDCHAR(RBUFF) PUT LINK/LOAD IND INTO CCT    36950017
         MVC   CCTCCR(THREE),ONE(RBUFF)  PUT COMMAND KEY INTO CCT       36958017
         CLC   CCTCCR(PSRLNTH),CONBEGPR  WAS BEGIN PROCEDURE SELECTD    36966017
         BNE   CHEKCHAR            IF NOT BRANCH                        36974017
         MVC   CCTCCR(PSRLNTH),BEGCON  PUT BEGIN JOB KEYWORD IN CCT     36982017
         MVI   CCTPWKA,HEX40       BLANK OUT 70 BYTES IN WORK AREA      36986017
         MVC   CCTPWKA+ONE(SIXNINE),CCTPWKA                             36990017
         MVI   CCTPWKA+TWO80,HEX40 BLANK OUT 21 BYTES IN WORKAREA       36994017
         MVC   CCTPWKA+TWO81(TWENTY),CCTPWKA+TWO80                      36998017
         MVC   CCTPWKA(PSRLNTH),BEGCON   PUT BEGIN KEY INTI PWKA        37006017
         MVC   CCTPWKA+TWO68(PROCLNTH),FOUR(RBUFF)  PUT PROCEDURE NAME  37014017
         B     MOVEA               INTO WORKAREA AND BRANCH             37022017
CHEKCHAR CLC   CCTCCR(PSRLNTH),RECCON  CHECK IF RECALL WAS SELECTED     37030017
         BE    MOVED          BRANCH TO INSERT D IN PROCESSOR NAME      37038017
         CLC   CCTCCR(PSRLNTH),LOFCON  CHECK IF LOGOFF WAS SELECTED     37046017
         BNE   MOVEA          BRANCH TO PUT A IN PROCESSOR NAME         37146017
MOVED    MVI   CCTCWKA+TWO,D  PUT D IN MODULE NAME                      37246017
         B     DIORTRN        BRANCH TO RETURN                          37346017
MOVEA    MVI   CCTCWKA+TWO,A  PUT A IN MODULE NAME                      37446017
         B     DIORTRN        BRANCH TO RETURN                          37546017
         EJECT                                                          37700017
EXTRCD   MVI   CCTPECB,POSTCODE  POST PROCESSOR ECB COMPLETE            37750017
         CLC   EXT(EXT,RBUFF),CANCODE CHECK FOR CANCEL KEY FROM 1130    37800017
         BE    POSTCAN        BRANCH TO POST ECB WITH CANCEL CODE       37850017
         MVC   CCTPWKA(TWO56),EXT(RBUFF)  PUT FIRST 256 CHARACTERS OF   37900017
*                                 EXTRACT RECORD INTO CCT               38000017
         MVC   CCTPWKA+TWO56(RMNDR),TWO58(RBUFF)  PUT REMAINDER OF      38100017
*                                 EXTRACT RECORD INTO CCT               38200017
         MVI   CCTPECB+THREE,ENDKY   OTHERWISE, POST ECB WITH END       38500017
         CLC   CCTCCR(PSRLNTH),WRICON   WAS CURRENT COMMAND KEY FOR WRI 38830017
         BE    MOVEM          BRANCH TO INDICATE WRITE MESSAGE          38860017
         CLC   CCTCCR(PSRLNTH),ENTDATA CHECK FOR ENTER DATA PSR         38900017
         BNE   DIORTRN            IF NOT FOUND, BRANCH TO RETURN        39000017
MOVEM    MVI   CCTSTAT+TWO,M   INDICATE WRITE MESSAGE                   39560017
         B     DIORTRN         BRANCH TO RETURN                         39620017
POSTCAN  MVI   CCTPECB+THREE,CANKY  PUT CANCEL CODE IN ECB              39680017
         MVI   CCTSTAT+TWO,HEX00    ZERO MSG INDICATOR                  39740017
         B     DIORTRN         BRANCH TO RETURN                         39800017
         EJECT                                                          39900017
*                                                                       40000017
* PARAMETER TO INITIALIZE.                                              40100017
*                                                                       40200017
CALLINIT LA    RHOLD,FIVE          SET A COUNT                          40240017
         SR    R12,R12             SET R12 TO ZERO                      40241017
RETRY00  EQU   *                                                        40242017
         L     RPAR1,CCTIELST     GET PASSWORD CODE FROM INIT LIST      40245017
         B     PSWDTAB(RPAR1)     BRANCH ON RPAR1                       40250017
*                                                                       40255017
PSWDTAB  B     SETPWD0            BRANCH TO SET PTR TO PASSWORD 00      40260017
         B     SETPWD1            BRANCH TO SET PTR TO PASSWORD 01      40265017
         B     SETPWD2            BRANCH TO SET PTR TO PASSWORD 02      40270017
         L     RPAR1,CCTIELST+PASSWD   GET PREVIOUS PASSWORD CODE       40275017
         B     PSWDTAB(RPAR1)        BRANCH TO BRANCH TABLE             40280017
SETPWD0  LA    RPAR1,PASSWD00     GET 00 ADDRESS                        40285017
         B     STPSWD             BRANCH TO STORE IN LIST               40290017
SETPWD1  LA    RPAR1,PASSWD01     GET 00 ADDRESS                        40295017
         B     STPSWD             BRANCH TO STORE IN LIST               40300017
SETPWD2  LA    RPAR1,PASSWD02     GET 02 ADDRESS                        40305017
STPSWD   ST    RPAR1,CCTIELST+PASSWD PUT IN ITITIALIZATION LIST         40310017
PASWDSET LA    RPAR1,NINENINE     GET A NUMBER                          40315017
         ST    RPAR1,CCTDSREF     PUT AS DATA SET REFERENCE             40320017
REDOINIT LA    RPAR1,CCTIELST      SET PTR ININ LIST                    40360017
         LA    RWORK,CCTDSREF      PREPARE PARAMETERS FOR CALL TO GTNIT 40400017
         ST    RWORK,DSREF(RPAR1)  FIRST IS ADDRESS OF THE DATA SET     40500017
*                                  REFERENCE  THEN PUT ADDLESS OF THE   40600017
*                                  I/O BUFFER INTO THE SECOND AND THIRD 40700017
*                                  WORDS OF THE LIST                    40800017
         LA    RWORK,BUFFLNTH     GET BUFFER LENGTH ADDRESS             40830017
         ST    RWORK,CCTBUFFP     STORE IN CCT                          40860017
         MVC   WRTBUF(ADLENGTH,RPAR1),CCTBUFFP                          40900017
         LA    RWORK,ZEROPTR       GET POINTER TO ZERO                  40960017
         ST    RWORK,REDBUF(RPAR1)      PUT IN CCT                      41020017
* FOR THE TIME BEING, THERE IS NO ASYNCHRONOUS ROUTINE. THERE WILL BE   41100017
* NO INITIALIZATION OF THIS PARAMETER                                   41200017
*                                                                       41300017
         LA    RWORK,CCTSTCOD      PUT POINTER TO STATUS CODE IN SIXTH  41600017
         ST    RWORK,STATCODI(RPAR1) WORD OF LIST                       41700017
         MVC   CCTERLST(MLSTLNTH),MODLIST PUT MODEL PARAMETERS INTO CCT 41720017
         LA    RWORK,CCTREPAR      GET REPLY ADDRESS AND PUT IN CCT     41740017
         ST    RWORK,CCTERLST+RADDR                                     41760017
         MVI   CCTERLST+RADDR,HEX01  PUT REPLY LENGTH IN CCT            41780017
*                                                                       41800017
* PARAMETER LIST READY, CALL GTNIT                                      41900017
*                                                                       42000017
         CALL  GTNIT,MF=(E,(1))                                         42100017
*                                                                       42200017
* CHECK RETURN CODES FROM GTNIT TO DETERMINE IF ATTEMPT TO INITIALIZE   42300017
* WAS SUCCESSFUL                                                        42400017
*                                                                       42500017
         L     RSTCODE,CCTSTCOD    GET RETURN CODE FROM PTOP            42600017
         LTR   RSTCODE,RSTCODE                                          42700017
         BZ    INITCOMP            INITIALIZATION OK, SO BRANCH         42900017
         BP    DECOUNT            IF NOT, BRANCH                        42920017
         L     RWORK,CCTIELST+PASSWD   GET PASSWORD POINTER             42940017
         CLC   ZERO(SIX,RWORK),PASSWD01  WAS 01 USED                    42960017
         BNE   DECOUNT            IF NOT, BRANCH                        42980017
         SR    RWORK,RWORK        CLEAR A REGISTER                      43000017
         ST    RWORK,CCTIELST     PUT A ZERO IN CCT                     43020017
         LA    RHOLD,TWO          SET ATTEMPT COUNT TO TWO              43040017
         LA    R12,ONE            SET R12 SWITCH TO 1                   43060017
         B     RETRY00            GO TO RETRY INITIALIZATION            43080017
*                                                                       43100017
* RETURN CODE IS NEGATIVE INDICATING PASSWORDS DO NOT MATCH             43200017
* OR RETURN CODE IS POSITIVE INDICATING COMMUNICATIONS LINKAGE PROBLEM  43300017
*                                                                       43400017
DECOUNT  EQU   *                                                        43450017
         BCTR  RHOLD,ZERO          DECREMENT COUNT BY ONE               43500017
         LTR   RHOLD,RHOLD         CHECK FOR 0 COUNT                    43600017
         BNE   TESTSTOP           BRANCH TO TEST STOP BIT               43700017
         MVC   CCTERLST(PSRLNTH),M301 IF 5 RETRIES GO TO IKAIERR. SET   43800017
         MVI   CCTERLST+CBITE,HEX83   MSG CODE AND OPTION BYTE          43900017
         MVC   CCTPWKA+TWO56(FOUR),CCTBUFFP  SAVE THE CONTENTS          43920017
         LA    RBAL,CCTPWKA+FIFTY2      SET UP THE ADDRESS              43940017
         ST    RBAL,CCTBUFFP            OF AN AREA                      43960017
         BAL   RBAL,GOTOIERR       GO TO BRANCH TO IKAIERR              44000017
         MVC   CCTBUFFP(FOUR),CCTPWKA+TWO56  RESTORE THE CONTENTS       44030017
         LA    RHOLD,FIVE         RESET COUNT TO FOVE                   44060017
         B     REDOINIT           RETRY INITIALIZATILN                  44120017
TESTSTOP L     RWORK,CCTTIME      GET START PARAMETER LIST              44200017
         L     RPAR1,FOUR(RWORK)  GET ECB POINTER                       44300017
         TM    ZERO(RPAR1),HEX10  WAS FAST STOP ISSUED                  44400017
         BZ    REDOINIT           IF NOT, GO RETRY                      44500017
         MVC   CCTPWKA(EIGHT),KLOF      MOVE IN CONSTANT,               44510017
         MVC   CCTPWKA+FIVE(THREE),CCTUNIT   AND UNITNAME               44520017
         LA    RPAR0,CCTPWKA            GET PARAMETERS                  44530017
         SR    RPAR1,RPAR1              ZERO - NO CCT                   44540017
         SVC   80                       INTERFACE FOR ENDING SGJP       44550017
         B     SETRC04            GO SET A NON-ZERO RETURN CODE         44600017
*                                                                       44700017
* INITIALIZATION HAS SUCCESSFULLY COMPLETED. RETURN TO CALLER           44800017
* AFTER PREPARING PARAMETER LISTS FOR FUTURE CALLS TO PTOP ROUTINES     44900017
*                                                                       45000017
INITCOMP EQU   *                                                        45100017
         LTR   R12,R12            IS R12 EQUAL TO ZERO                  45130017
         BNE   CALLEND            IF NOT, BRANCH                        45160017
         LA    RREAD,CCTRDLST      SET POINTER TO READ PARAMETER LIST   45200017
         LA    RWRITE,CCTWRLST     SET POINTER TO WRITE PARAMETER LIST  45300017
         LA    RTEST,CCTTSLST      SET POINTER TO TEST PARAMETER LIST   45400017
         LA    RWORK,CCTDSREF      GET POINTER TO DATA SET REFERENCE    45500017
         ST    RWORK,DSREF(RREAD)  PUT DSREF PTR IN READ PARAMETER LIST 45600017
         ST    RWORK,DSREF(RWRITE)                  WRITE               45700017
         ST    RWORK,DSREF(RTEST)                   TEST                45800017
*                                                                       45900017
         LOAD  EP=IKDUATBL        GET ADDRESS OF UNIT ASSIGNMENT TABLE  45920017
         LA    RWORK,NINENINE     GET DATA SET REFERENCE NIMBER         45940017
         BCTR  RWORK,0            DECREMENT BY ONE                      45960017
         SLA   RWORK,TWO          MULTIPLY BY FOUR                      45980017
         AR    RWORK,RPAR0        GET ENTRY ADDRESS TO TABLE            46000017
         L     RWORK,ZERO(RWORK)    GET GTCB ADDRESS                    46020017
         L     RWORK,FOUR(RWORK)     GET BUFFER ADDRESS                 46040017
         LA    RWORK,SIX(RWORK)   SET POINTER TO I/O ARRAY              46060017
         ST    RWORK,IOARRAY(RREAD)  PUT POINTER INTO READ PARAM LIST   46100017
         ST    RWORK,IOARRAY(RWRITE)                  WRITE             46200017
         ST    RWORK,CCTBUFFP      RESET POINTER TO BUFFER              46250017
*                                                                       46300017
         LA    RWORK,CCTRECLN       GET POINTER TO DATA LENGTH          46400017
         ST    RWORK,ELCOUNT(RREAD)  PUT INTO READ PARAMETER LIST       46500017
         ST    RWORK,ELCOUNT(RWRITE)          WRITE                     46600017
*                                                                       46700017
         LH    RWORK,DATATYPE        GET CODE TO INDICATE TYPE OF DATA  46800017
         ST    RWORK,CCTDATYP        TO BE TRANSFERRED AND PUT INTO CCT 46900017
         LA    RWORK,CCTDATYP        GET POINTER TO THE DATA TYPE CODE  47000017
         ST    RWORK,DATYP(RREAD)    PUT INTO READ PARAMETER LIST       47100017
         ST    RWORK,DATYP(RWRITE)            WRITE                     47200017
*                                                                       47300017
         LH    RWORK,CTLOPT        GET CODE TO INDICATE DETINATION OF   47400017
*                                  DATA (1=MAIN LINE 2= ASYNCHRONOUS)   47500017
         ST    RWORK,CCTCTLOP      PUT INTO CCT                         47600017
         LA    RWORK,CCTCTLOP      GET POINTER TO CONTROL OPTION        47700017
         ST    RWORK,CTLOP(RWRITE) PUT INTO WRITE PARAMETER LIST        47800017
*                                                                       47900017
         LA    RWORK,CCTTSTCD      GET POINTER TO TEST CODE             48000017
         ST    RWORK,TESTCD(RTEST) PUT IN TEST PARAMETER LIST           48100017
         LA    RWORK,CCTSTCOD      GET POINTER TO STATUS CODE           48200017
         ST    RWORK,STATCODT(RTEST)  PUT IN TEST PARAMETER LIST        48300017
         DELETE EP=IKDUATBL                                             48350017
         B     DIORTRN             BRANCH TO RETURN                     48400017
*                                                                       48500017
* PARAMETER TO TERMINATE                                                48600017
*                                                                       48700017
CALLEND  EQU   *                                                        48800017
         L     RPAR1,CCTIELST+TWENTY  GET CONTENTS OF IELST             48820017
         LTR   RPAR1,RPAR1        IS CONTENTS ZERO                      48840017
         BE    DIORTRN            IF YES, BRANCH TO RETURN              48860017
         LA    RPAR1,CCTIELST      SET REG1 TO POINT TO PARAM LIST      48900017
*                                  TO TERMINATE                         49000017
*                                                                       49100017
* PARAMETER LIST READY, CALL GTEND                                      49200017
*                                                                       49300017
         CALL  GTEND,MF=(E,(1))                                         49400017
         LA    RWORK,ZERO      GET A ZERO                               49401017
         ST    RWORK,CCTIELST+TWENTY    PUT IN STATCODE POINTER         49402017
         LTR   R12,R12            IS R12 EQUAL TO ZERO                  49403017
         BNE   SETR120            IF NOT, BRANCH                        49404017
         L     RPAR1,CCTIELST+PASSWD   GET POINTER TO PASSWORD          49405017
         CLC   ZERO(SIX,RPAR1),PASSWD01 WAS PASSWORD 1 USED             49410017
         BE    SETFOUR            IF YES,BRANCH                         49415017
         LA    RPAR1,EIGHT        GET AN EIGHT                          49420017
         ST    RPAR1,CCTIELST+PASSWD  PUT PREVIOUS PASSWORD CODE IN CCT 49425017
         B     DIORTRN            BRANCH TO RETURN                      49430017
SETR120  LA    RPAR1,FOUR          SET PASSWORD CODE FOR 01             49431017
         ST    RPAR1,CCTIELST     PUT IN CCT                            49432017
         B     CALLINIT           GO TO ATTEMPT INITIALIZATION          49433017
SETFOUR  LA    RPAR1,FOUR         GET A FOUR                            49435017
         ST    RPAR1,CCTIELST+PASSWD  PUT PREVIOUS PASSWORD CODE IN CCT 49440017
         B     DIORTRN             BRANCH TO RETURN                     49450017
SETRC04  LA    RBR,HEX1C          SET A RETURN CODE TO TERMINATE        49500017
         ST    RBR,CCTPECB              STORE IT IN ECB                 49530017
         MVI   CCTPECB,POSTCODE         WITH COMPLETION                 49560017
         B     RCSET               GO TO RETURN                         49600017
DIORTRN  SR    RBR,RBR            SET A RETURN CODE OF ZERO             49700017
RCSET    L     RSAVE,CCTASAVE+FOUR   RESTORE REGISTER 13                49800017
         RETURN (14,12),RC=(15)       RETURN TO CALLER                  49900017
         EJECT                                                          50000017
*                                                                       50100017
* CONSTANTS                                                             50200017
*                                                                       50300017
PASSWD00 DC    C'SGJP00'          PASSWORD 00                           50320017
PASSWD01 DC    C'SGJP01'          PASSWORD 01                           50340017
PASSWD02 DC    C'SGJP02'          PASSWORD 02                           50360017
CTLOPT   EQU   *                                                        50380017
DATATYPE DC    H'1'                DATA TYPE                            50420017
ENTDATA  DC    C'ENT'              KEY FOR ENTER DATA                   50460017
CANCODE  DC    C'FF'                       CANCEL PARAMETER FRAME       50500017
WRICON   DC    C'WRI'                      WRITE MESSAGE                50540017
CONBEGPR DC    C'PRO'                      BEGIN PROCEDURE              50580017
BEGCON   DC    C'BEG'                      BEGIN JOB                    50620017
RECCON   DC    C'REC'                      RECALL                       50660017
LOFCON   DC    C'LOF'                      LOGOFF                       50700017
         DS    0H                                                       50762017
RESTART  DC    H'2'                     RESTART SGJP                    50764017
TERMNAT  DC    H'1'                     TERMINATE SGJP                  50766017
         DS    0F                                                       50770017
BUFFLNTH DC    F'1000'             LENGTH OF I/O BUFFER                 50775017
ZEROPTR  DC    F'0'               FULL WORD OF ZERO                     50777017
INTERVAL DC    F'76924'                 TWO SECONDS                     50778017
MODLIST  DC    CL3'000'            MESSAGE NUMBER                       50780017
         DC    CL5'IOR'            MODULE ID                            50790017
         DC    X'00'               CONTROL BYTE                         50800017
         DC    X'000000'           BINARY ZERO                          50810017
         DC    F'0'                LENGTH AND ADDRESS OF REPLY          50820017
MODLISTE EQU   *                                                        50830017
MLSTLNTH EQU   MODLISTE-MODLIST    LENGTH OF PARAMETER LIST             50840017
M301     DC    CL3'301'            MESSAGE NUMBER 301                   50870017
M302     DC    CL3'302'            MESSAGE NUMBER 302                   50900017
M303     DC    CL3'303'            MESSAGE NUMBER 303                   50930017
M304     DC    CL3'304'            MESSAGE NUMBER 304                   50960017
KLOF     DC    C'PLOG UTN'              CONSTANT FOR GFX INTERFACE      50980017
         END                                                            51000017
./       ADD   SSI=00011951,NAME=IKDMSG,SOURCE=0
         TITLE 'IKDMSG   DISPLAY MESSAGE ROUTINE'                       00200017
IKDMSG   START 0                                                        00400017
*                                                                       00600017
*ROUTINE NAME      IKDMSG                                               00800017
*                                                                       01000017
*CHART ID          JA                                                   01200017
*                                                                       01400017
*FUNCTION          PROVIDE AN INTERFACE TO THE 1130/2250 SUBSYSTEM IN   01600017
*                  ORDER TO PASS MESSAGES AND/OR INTENSIFICATION DATA   01800017
*                                                                       01840017
*                  AFTER WRITING THE MESSAGES TO THE SUBSYSTEM,         01880017
*                  A READ IS ISSUED TO READ BACK ANOTHER EXTRACT        01920017
*                  RECORD UNLESS A BIT IS ON IN THE 'CCTSSTAT'.         01960017
*                                                                       02000017
*ATTRIBUTES:       RESIDENT,REENTERABLE                                 02200017
*                                                                       02400017
*ENTRY POINT       IKDMSG                                               02600017
*                                                                       02800017
*EXITS           IKDIOR, RETURN TO CALLER                               03000017
*                                                                       03200017
*INPUT:            REGISTER 0 CONTAINS ADDRESS OF PARAMETER LIST        03400017
*                                                                       03600017
*                  REGISTER 1 CONTAINS ADDRESS OF CCT                   03800017
*                                                                       04000017
*                  FORMAT OF PARAMETER LIST ENTRY:                      04200017
*                                                                       04400017
*                                                                       04600017
*                  DISPL      0      1                                  04800017
*                            ***************************                05000017
*                            *      * ADDR OF MSG TEXT *                05200017
*                            * BITS *       OR         *                05400017
*                            *      *   INPUT MAPPING  *                05600017
*                            *      *       OR         *                05800017
*                            *      *    MSG NUMBER    *                06000017
*                            ***************************                06200017
*                                                                       06400017
*                  BIT 0  - 1  LAST ENTRY IN PARAMETER LIST             06600017
*                      1  - 0  PST INTENSIFICATION                      06800017
*                         - 1  MESSAGE TEXT                             07000017
*                      2       NOT USED                                 07200017
*                      3       NOT USED                                 07400017
*                      4  - 0  BASIC CHARACTER SIZE FOR MESSAGE TEXT    07600017
*                         - 1  LARGE CHARACTER SIZE FOR MESSAGE TEXT    07800017
*                      5  - 1  INTENSIFY MESSAGE LINE                   08000017
*                      6  - 0  MSG ADDRESS SUPPLIED                     08200017
*                         - 1  MSG NUMBER SUPPLIED                      08400017
*                      7       NOT USED                                 08600017
*                                                                       08800017
*                  MESSAGE TEXT FORMAT:                                 09000017
*                                                                       09200017
*                  DISPL      0       1                                 09400017
*                            **************************                 09600017
*                            *       *                *                 09800017
*                            *TEXT   *  MESSAGE TEXT  *                 10000017
*                            *LENGTH *                *                 10200017
*                            *       *                *                 10400017
*                            **************************                 10600017
*                                                                       10800017
*                  NOTE - TEXT LENGTH DOES NOT INCLUDE THE ONE BYTE     11000017
*                         FOR THE TEXT LENGTH FIELD                     11200017
*                       - TEXT MUST FIT ON ONE LINE ON SCREEN           11400017
*                       - TEXT WILL BE POSITIONED AT X=0, SO ANY        11600017
*                    DESIRED LEADING BLANKS MUST BE INCLUDED            11800017
*                                                                       12000017
*OUTPUT            REGISTER 0 CONTAINS I/O CODE FOR IKDIOR              12200017
*                                                                       12400017
*                  REGISTER 1 CONTAINS ADDR OF CONSOLE CONTROL TABLE    12600017
*                                                                       12800017
*                  I/O AREA CONTAINS DATA TO BE TRANSMITTED             13000017
*                  TO THE 1130/2250 SUBSYSTEM IN THIS FORMAT            13200017
*                                                                       13400017
*                        INTENSIFICATION          BIT 1 = 0             13600017
*                                              OR BIT 1 & BIT 6 = 1     13800017
*                  ************************                             14000017
*                  * BITS * INPUT MAPPING *                             14200017
*                  *      * OR MSG NUMBER *                             14400017
*                  ************************                             14600017
*                                                                       14800017
*                        MESSAGE TEXT             BIT 1 = 1             15000017
*                                                 AND BIT 6 = 0         15200017
*                  ***************************                          15400017
*                  * BITS *  TEXT  * MESSAGE *                          15600017
*                  *      * LENGTH *  TEXT   *                          15800017
*                  ***************************                          16000017
*                                                                       16200017
*                  BIT 7  - 0  END OF INFORMATION                       16250017
*                         - 1  MORE INFORMATION                         16300017
*                                                                       16350017
*EXTERNAL REFERENCES     NONE                                           16400017
*                                                                       16600017
*ERROR CONDITIONS:                                                      16800017
*                                                                       17000017
*TABLES AND WORKAREAS   CONSOLE CONTROL TABLE, I/O BUFFER               17200017
         EJECT                                                          17400017
*                                                                       17600017
*   REGISTER EQUATES                                                    17800017
*                                                                       18000017
RPAR0    EQU   0                                                        18200017
RPAR1    EQU   1                                                        18400017
RBASE    EQU   2                                                        18600017
RPARM    EQU   3                                                        18800017
RWRK0    EQU   4                                                        19000017
RWRK1    EQU   5                                                        19200017
RCCT     EQU   6                                                        19400017
RWKAR    EQU   7                                                        19600017
RGWRK    EQU   8                                                        19800017
RWRK2    EQU   9                                                        20000017
RBUFR    EQU   10                                                       20200017
RBUFZ    EQU   11                                                       20400017
RTRM     EQU   12                       RETURN REGISTER                 20500017
RSAVE    EQU   13                                                       20600017
RRET     EQU   14                                                       20800017
RBR      EQU   15                                                       21000017
*                                                                       21200017
*   INPUT PARAMETER DISPLACEMENTS                                       21400017
*                                                                       21600017
ENTRYBIT EQU   0                                                        21800017
ENTRYADD EQU   0                                                        22000017
ENTRYMAP EQU   2                                                        22200017
ENTRYNUM EQU   3                                                        22400017
MSGLEN   EQU   0                                                        22600017
MSGTEXT  EQU   1                                                        22800017
*                                                                       23000017
LAST     EQU   X'80'                                                    23200017
MSGENTRY EQU   X'40'                                                    23400017
MSGLGSZ  EQU   X'08'                                                    23600017
MSGINT   EQU   X'04'                                                    23800017
MSGNUMBR EQU   X'02'                                                    24000017
*                                                                       24200017
*                                                                       24400017
*   MISC EQUATES                                                        24600017
*                                                                       24800017
ENTRYLEN EQU   4                                                        25000017
IOSIZE   EQU   964                      SIZE OF BTAM BUFFER             25100017
EXTRCD   EQU   354                      SIZE OF EXTRACT RECORD          25300017
BMAXLEN  EQU   74                                                       25400017
LMAXLEN  EQU   49                                                       25600017
ZERO     EQU   0                   EQUATE                               25610017
ONE      EQU   1                   EQUATE                               25620017
TWO      EQU   2                   EQUATE                               25630017
THREE    EQU   3                   EQUATE                               25640017
FOUR     EQU   4                   EQUATE                               25650017
EIGHT    EQU   8                   EQUATE                               25660017
XTRCDSW  EQU   16                  EXTRACT RECORD SWITCH                25670017
FF       EQU   255                 X'FF' FOR BIT MANIPULATION           25680017
WRICOD   EQU   X'04'               WRITE CODE FOR IKDIOR                25690017
REDCOD   EQU   X'00'               READ CODE FOR IKDIOR                 25700017
BLANK    EQU   X'40'               EQUATE                               25710017
         SPACE 5                                                        25900017
*                                                                       26000017
*                                                                       26200017
*    WORK AREA FOR IKDMSG                                               26400017
*                                                                       26600017
MSGWORK  DSECT                                                          26800017
*                                                                       27000017
REGSAVE  DS    18F                                                      27200017
GEN14SV  DS    F                                                        27400017
*                                                                       27600017
         DS    0D                                                       27800017
MSGWAZ   EQU   *-REGSAVE                                                28000017
         EJECT                                                          28200017
IKACCT   DSECT                                                          28400017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         28600017
         SPACE                                                          28800017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    29000017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     29200017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       29400017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             29600017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  29800017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  30000017
*                   SET.                                                30200017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      30400017
*                   SECOND.                                             30600017
         SPACE 2                                                        30800017
         SPACE 2                                                        31000017
*                             SECTION ONE                               31200017
         SPACE                                                          31400017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     31600017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    31800017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  32000017
         SPACE                                                          32200017
         DS    0F                                                       32400017
CCTUNAME DS    5F                  USER'S NAME                          32600017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         32800017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     33000017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       33200017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    33400017
*                                       AT LAST BEGIN JOB               33600017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   33800017
*                                       LAST BEGIN JOB                  34000017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 34200017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    34400017
*                                       JOB                             34600017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    34800017
*                                       JOB                             35000017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     35200017
*                                       CESSOR                          35400017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         35600017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         35800017
CCTJCTR  DS    H                   JOB COUNTER                          36000017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                36200017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   36400017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  36600017
CCTSSTAT DS    C                   SESSION STATUS                       36800017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              37000017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              37200017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    37400017
         EJECT                                                          37600017
         SPACE 2                                                        37800017
*                             SECTION TWO                               38000017
         SPACE                                                          38200017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   38400017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  38600017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 38800017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              39000017
         SPACE                                                          39200017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     39400017
*                                       FRAME                           39600017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  39800017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     40000017
*                                       MULTIPLE DISPLAY FRAME (ENT)    40200017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   40400017
CCTDISM  DS    C                   DISPLAY MASK                         40600017
CCTCSM   DS    C                   COMMAND SELECT MASK                  40800017
CCTPSTAT DS    CL2                 GJP STATUS                           41000017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              41200017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  41400017
         SPACE 2                                                        41600017
*                             SECTION THREE                             41800017
         SPACE                                                          42000017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    42200017
*                   INTO SECTION ONE OR TWO                             42400017
         SPACE                                                          42600017
CCTDGMP  DS    F                  POINTER TO DGM                        42800017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                43000017
CCTCSTP  DS    F                  POINTER TO CST                        43200017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                43400017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            43600017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 43800017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              44000017
CCTDIARP DS    F                  POINTER TO DIA                        44200017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      44400017
CCTACTP  DS    F                  POINTER TO ACT                        44600017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     44800017
CCTIERRP DS    F                  POINTER TO IERR                       45000017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              45200017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               45400017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                45600017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 45800017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 46000017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   46200017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                46400017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                46600017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               46800017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              47000017
CCTPECB  DS    F                  PROCESSOR'S ECB                       47200017
CCTWECB  DS    F                  WTOR ECB                              47400017
CCTDIAWA DS    CL136               DIARY WORK AREA                      47600017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    47800017
CCTCSAVE DS    CL72                CTL SAVE AREA                        48000017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                48200017
CCTASAVE DS    CL72                DAT SAVE AREA                        48400017
*                                                                       48600017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       48800017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           49000017
*                                                                       49200017
IKDCCT   EQU   IKACCT              THREE CHARACTER PREFIX IS REPLACED   49400017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             49600017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               49800017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     50000017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               50200017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           50400017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    50600017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 50700017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   50800017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   50900017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   51000017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            51100017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 51200017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       51300017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  51400017
*                                  INATION OF DATA                      51500017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    51600017
*                                  THE I/O OPERATION TO BE TESTED BY    51700017
*                                  GTCLT                                51800017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        51900017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              52000017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   52600017
         EJECT                                                          53200017
IKDMSG   CSECT                                                          53400017
         SAVE  (14,12)                                                  53600017
         LR    RCCT,RPAR1               ADDR OF CCT                     53800017
         LR    RPARM,RPAR0              ADDR OF PARAMETER LIST          54000017
         BALR  RBASE,ZERO          SET UP BASE REGISTER                 54200017
         USING *,RBASE                                                  54400017
         USING IKACCT,RCCT                                              54600017
*                                                                       54800017
*    GET SPACE FOR WORK AREA                                            55000017
*                                                                       55200017
         GETMAIN R,SP=18,LV=MSGWAZ                                      55400017
         LR    RWKAR,RPAR1              ADDR OF WORK AREA               55600017
         USING MSGWORK,RWKAR                                            55800017
         ST    RSAVE,REGSAVE+FOUR  STORE CALLING SAVE AREA ADDRESS      56000017
         LA    RWRK0,REGSAVE                                            56200017
         ST    RWRK0,EIGHT(,RSAVE)      STORE CALLED SAVE AREA ADDRESS  56400017
         LR    RSAVE,RWRK0              ADDR OF REG SAVE AREA TO REG 13 56600017
*                                                                       56800017
*   TEST IF PARAMETER LIST IS ON FULL WORD BOUNDARY                     57000017
*                                                                       57200017
         LA    RWRK0,THREE         TURN ON 2 LOW ORDER BITS             57400017
         NR    RWRK0,RPARM                                              57600017
         BM    BADBNDRY            ZERO IF NOT ON FULL WORD BOUNDARY    57800017
         EJECT                                                          58000017
*    INITIALIZE POINTERS                                                58200017
*                                                                       58400017
         SR    RGWRK,RGWRK              ZERO FOR ARITHMETIC             58600017
INIT     EQU   *                                                        58800017
         L     RBUFR,CCTBUFFP           GET ADDR OF I/O AREA            59000017
         LA    RBUFZ,IOSIZE(,RBUFR)     GET LAST POSITION               59200017
*                                                                       59400017
INPLOOP  NI    ENTRYBIT(RPARM),FF-ONE   TURN OFF BIT SEVEN              59600017
         TM    ENTRYBIT(RPARM),MSGENTRY TEST IF ENTRY IS FOR MSG        59800017
         BO    MSGTXT                   ON FOR MESSAGE TEXT             60000017
         B     INTENS                   OFF FOR INTENSIFICATION         60200017
TESTLAST TM    ENTRYBIT(RPARM),LAST     IS THIS THE LAST ENTRY          60400017
         BO    ENDDMSG                  BRANCH IF YES                   60600017
         LA    RPARM,ENTRYLEN(RPARM)    ADDR OF NEXT ENTRY IN PARM LIST 60800017
         B     INPLOOP                  BRANCH TO SERVICE NEXT ENTRY    61000017
*                                                                       61200017
ENDDMSG  EQU   *                                                        61400017
         BAL   RRET,LINKIOW             WRITE TO SUBSYSTEM              61600017
*                                                                       61610017
*    TEST IF AN EXTRACT RECORD IS EXPECTED                              61620017
         TM    CCTSSTAT,XTRCDSW         Q. EXTRACT RECORD EXPECTED      61630017
         BO    EXIT                     NO                              61640017
*                                                                       61650017
*    READ NEW EXTRACT RECORD                                            61700017
         BAL   RRET,LINKIOR             READ FROM SUBSYSTEM             61800017
         EJECT                                                          62000017
EXIT     NI    CCTSSTAT,FF-XTRCDSW      TURN OFF EXTRACT RECORD SW.     62100017
         L     RSAVE,FOUR(RSAVE)        ADDR OF CALLING SAVE AREA       62200017
         LR    RTRM,RBR                 SAVE RETURN REGISTER            62500017
         FREEMAIN R,SP=18,A=(RWKAR),LV=MSGWAZ                           62600017
         LR    RBR,RTRM                 RESTORE RETURN REGISTER         62700017
         RETURN (14,12),RC=(15)                                         62800017
*                                                                       63000017
*    ERRONEOUS INPUT PARAMETER LIST                                     63200017
*                                                                       63400017
BADBNDRY EQU   *                                                        63600017
         LR    RPAR1,RCCT                                               63800017
         LA    RPAR0,ERR019                                             64000017
         L     RBR,CCTIERRP             GO TO IKAIERR                   64200017
         BALR  RRET,RBR                 FOR ERROR MSG                   64400017
         B     EXIT                     TERMINATE                       64600017
*                                                                       64800017
ERR019   DS    0F                       ALIGNMENT                       65000017
         DC    C'019'                   MSG NO.                         65200017
         DC    C'MSG  '                 MODULE NAME                     65400017
         DC    XL1'81'                  ATTRIBUTE                       65600017
         DC    XL3'00'                  NOT USED                        65700017
*                                                                       65810017
NOFIT    EQU   *                                                        65820017
         LR    RPAR1,RCCT               ADDR OF CCT                     65830017
         LA    RPAR0,ERR026             ADDR OF PARM LIST               65840017
         L     RBR,CCTIERRP             ADDR OF INTERNAL ERROR RTNE     65850017
         BALR  RRET,RBR                 PUT OUT ERROR MSG               65860017
         B     MSGSIZ                   CONTINUE PROCESSING             65870017
ERR026   DS    0F                       ALIGNMENT                       65890017
         DC    C'026'                   MSG NO.                         65910017
         DC    C'MSG  '                 MODULE NAME                     65930017
         DC    XL1'01'                  ATTRIBUTE                       65950017
         DC    XL3'00'                  NOT USED                        65970017
         EJECT                                                          66000017
***  MESSAGE TEXT                                                       66200017
MSGTXT   EQU   *                                                        66400017
         TM    ENTRYBIT(RPARM),MSGNUMBR IS THIS A MESSAGE NUMBER        66600017
         BO    INTENS                   YES                             66800017
         L     RWRK0,ENTRYBIT(,RPARM)   GET ADDR OF MSG                 67000017
         IC    RGWRK,MSGLEN(,RWRK0)     GET TEXT LENGTH                 67200017
**   TEXT MUST FIT ON ONE LINE ON SCREEN                                67400017
         LA    RWRK1,BMAXLEN            BASIC                           67600017
         TM    ENTRYBIT(RPARM),MSGLGSZ  IS LARGE SIZE SPECIFIED         67800017
         BZ    CMAXSIZ                  NO                              68000017
         LA    RWRK1,LMAXLEN            LARGE                           68200017
CMAXSIZ  CR    RWRK1,RGWRK              IS MAXIMUM SIZE EXCEEDED        68400017
         BH    MSGSIZ                   NO                              68600017
         LR    RGWRK,RWRK1              TRUNCATE THE MESSAGE TEXT       68800017
         B     NOFIT                    ISSUE ERROR MSG                 68900017
MSGSIZ   EQU   *                                                        69000017
         LA    RWRK1,TWO(RGWRK,RBUFR)   ADJUST FOR SIZE                 69200017
         CR    RWRK1,RBUFZ              TEST IF SPACE AVAILABLE         69400017
         BH    NOSPACE                  NO - WRITE OUT BUFFER           69600017
         MVC   ZERO(ONE,RBUFR),ENTRYBIT(RPARM)  MOVE IN FIRST BYTE      69800017
         EX    RGWRK,MVMSG              MOVE MESSAGE TO I/O AREA        70000017
         TM    MSGLEN(RWRK0),ONE        Q. EVEN NO. OF BYTES            70020017
         BZ    EVEN                     YES                             70040017
         LA    RWRK2,TWO(RGWRK,RBUFR)   GET END OF AREA                 70060017
         MVI   ZERO(RWRK2),BLANK        INSERT A BLANK                  70080017
         LA    RGWRK,ONE(,RGWRK)        INCREMENT FOR AN EVEN NO.       70100017
EVEN     EQU   *                                                        70120017
         STC   RGWRK,ONE(RBUFR)         MOVE IN TEXT LENGTH,            70220017
*                                       WHICH MAY HAVE BEEN TRUNCATED   70400017
         LA    RBUFR,TWO(RGWRK,RBUFR)   GET NEXT SPACE IN I/O BUFFER    70500017
         LA    RWRK2,TWO(,RGWRK)        SIZE OF THIS ENTRY              70600017
         B     TESTLAST                 TEST IF LAST ENTRY              70700017
*                                                                       71000017
*                                                                       71200017
***  INTENSIFICATION                                                    71400017
INTENS   EQU   *                                                        71600017
         LA    RWRK1,ENTRYLEN(,RBUFR)   ADJUST FOR SIZE                 71800017
         CR    RWRK1,RBUFZ              TEST IF SPACE AVAILABLE         72000017
         BH    NOSPACE                  NO - WRITE OUT BUFFER           72200017
         MVC   ENTRYADD(ENTRYLEN,RBUFR),ENTRYBIT(RPARM)                 72400017
*                                       MOVE THE WORD INTO I/O BUFFER   72600017
         LA    RBUFR,ENTRYLEN(,RBUFR)   GET NEXT SPACE IN I/O BUFFER    72700017
         LA    RWRK2,ENTRYLEN           SIZE OF THIS ENTRY              72900017
         B     TESTLAST                 TEST IF LAST ENTRY              73000017
         EJECT                                                          73200017
**   WRITE OUT BUFFER                                                   73400017
NOSPACE  EQU   *                                                        73600017
         SR    RBUFR,RWRK2              DECREMENT FOR LAST ENTRY        73650017
         OI    ZERO(RBUFR),ONE          INDICATE MORE INFORMATION       73700017
         AR    RBUFR,RWRK2              RE-POSITION THE POINTER         73750017
         LA    RRET,INIT                RETURN FROM LINKIOW             73800017
*                                                                       74000017
*    LINK TO IKDIOR TO WRITE TO SUBSYSTEM                               74200017
*                                                                       74400017
LINKIOW  ST    RRET,GEN14SV             SAVE RETURN ADDR                74600017
         LA    RPAR0,WRICOD             WRITE CODE                      74800017
         S     RBUFR,CCTBUFFP           GET LENGTH OF RECORD            75000017
         ST    RBUFR,CCTRECLN           TO BE TRANSMITTED               75200017
         LR    RPAR1,RCCT               ADDR OF CCT                     75400017
         L     RBR,CCTIORP              ADDR OF IKDIOR                  75600017
         BALR  RRET,RBR                 PERFORM I/O                     75800017
         L     RRET,GEN14SV             RESTORE RETURN ADDR             76000017
         CH    RBR,TRMCOD               Q. TERMINATE CODE               76100017
         BCR   7,RRET                   NO, CONTINUE                    76200017
         B     EXIT                     RETURN                          76300017
*                                                                       76400017
*    LINK TO IKDIOR TO READ FROM SUBSYSTEM                              76600017
*                                                                       76800017
LINKIOR  ST    RRET,GEN14SV             SAVE RETURN ADDR                77000017
         LA    RPAR0,REDCOD             READ CODE                       77200017
         LA    RBUFR,EXTRCD             GET LENGTH OF EXTRACT RECORD    77400017
         ST    RBUFR,CCTRECLN           TO BE RECEIVED                  77600017
         LR    RPAR1,RCCT               ADDR OF CCT                     77800017
         L     RBR,CCTIORP              ADDR OF IKDIOR                  78000017
         BALR  RRET,RBR                 PERFORM I/O                     78200017
         L     RRET,GEN14SV             RESTORE RETURN ADDR             78400017
         CH    RBR,TRMCOD               Q. TERMINATE CODE               78460017
         BCR   7,RRET                   NO, CONTINUE                    78520017
         B     EXIT                     RETURN                          78580017
         EJECT                                                          78640017
*                                                                       78700017
*    CONSTANTS                                                          78760017
*                                                                       78820017
TRMCOD   DS    H'28'                    MUST TERMINATE                  78880017
*                                                                       79000017
*                                                                       79200017
*   INSTRUCTIONS TO BE EXECUTED                                         79400017
*                                                                       79600017
MVMSG    MVC   ONE(ZERO,RBUFR),MSGLEN(RWRK0)  MOVE MSG TEXT TO I/O AREA 79800017
*                                                                       80000017
*                                                                       80200017
         CNOP  0,8                      ADJUST TO DOUBLE-WORD BOUNDARY  80400017
         END                                                            80600017
./       ADD   SSI=00013302,NAME=IKDPLOF0,SOURCE=0
         TITLE 'IKDPLOF0   LOG OFF PROCESSOR'                           00100017
IKDPLOF0 START 0                                                        00150017
*                                                                       00200017
*                                                                       00300017
*                             LOG OFF ROUTINE                           00400017
*                                                                       00500017
*  ROUTINE NAME       IKDPLOF0                                          00600017
*                                                                       00700017
*  CHART ID                                                             00800017
*                                                                       00900017
*  FUNCTION           PROCESS LOG OFF OPERATIONS FOR SGJP               01000017
*                     IN S/360 AND WITH THE SUBSYSTEM                   01100017
*                                                                       01200017
*  ATTRIBUTES:      TRANSIENT,REENTERABLE                               01300017
*                                                                       01400017
*  ENTRY POINTS:      IKDPLOF0, RETURN FROM IKAACCTG, IKDIOR            01500017
*                                                                       01600017
*  OPERATION        . GIVE CONTROL TO THE USER'S ACCOUNTING ROUTINE     01700017
*                     (IKAACCTG) AND PASS POINTERS TO INFORMATION       01800017
*                   . IF THE RECORD OPTION HAS BEEN CHOSEN THE DIARY    01900017
*                     DATA SET IS READ AND THE DATA TRANSMITTED TO      02000017
*                     THE SUBSYSTEM FOR PRINTING THERE                  02100017
*                   . CONTROL IS PASSED TO IKASCH FOR CLEAN UP          02200017
*                                                                       02400017
*                                                                       02500017
*  EXITS:             BRANCH TO IKAACCTG, IKDIOR                        02600017
*                     TRANSFER CONTROL TO IKASCH                        02700017
*                                                                       02800017
*  INPUT:           DATA IN CONSOLE CONTROL TABLE                       02900017
*                                                                       03000017
*                   REGISTER 1 POINTING TO CONSOLE CONTROL TABLE        03100017
*                                                                       03200017
*                   REGISTER 13 POINTING TO A REGISTER SAVE AREA        03300017
*                                                                       03400017
*  OUTPUT             DIARY DATA SET MAY BE SENT TO THE SUBSYSTEM       03500017
*                                                                       03600017
*                     ROUTINE      REG 0            REG 1               03700017
*                     ********  *********        ************           03800017
*                     IKAACCTG                   POINTER LIST           03900017
*                     IKDIOR    I/O CODE         CCT ADDR               04000017
*                     IKASCH                     CCT ADDR               04200017
*                                                                       04300017
*  EXTERNAL REFERENCES: USER'S ACCOUNTING ROUTINE                       04400017
*                                                                       04500017
*  ERROR CONDITIONS                                                     04600017
*                                                                       04700017
*  TABLES AND WORKAREA: CONSOLE CONTROL TABLE                           04800017
*                                                                       04900017
*  RESTRICTION:                                                         05000017
*                                                                       05100017
         EJECT                                                          05200017
*                                                                       05300017
*                                                                       05400017
*  SPECIFICATION FOR USER'S ACCOUNTING ROUTINE: THE USER'S ACCOUNTING   05500017
*                   ROUTINE IS LINK EDITED WITH LOG OFF PROCESSOR. THE  05600017
*                   ENTRY POINT OF YOUR ACCOUNTING ROUTINE MUST BE      05700017
*                   NAMED IKAACCTG AND MUST BE REENTERABLE              05800017
*                                                                       05900017
*  INPUT TO THE ACCOUNTING ROUTINE:                                     06000017
*                   REGISTER 1 CONTAINS THE STARTING ADDRESS OF A LIST  06200017
*                   OF POINTERS TO ACCOUNTING INFORMATION               06300017
*                                                                       06400017
*                                                                       06500017
*                                                                       06600017
*  PARAMETER LIST TO ACCOUNTING ROUTINE                                 06700017
*                                                                       06800017
*                                                                       06900017
*  '*****************************************************************'  07000017
*  'DISPLACEMENT'                  CONTENT                           '  07100017
*  '************'****************************************************'  07200017
*  '     0      ' ONE BYTE CODE IN HEXDICIMAL                        '  07300017
*  '************'****************************************************'  07400017
*  '     1      ' THREE BYTE UNIT NAME                               '  07460017
*  '************'****************************************************'  07520017
*  '     4      ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE USER'S  '  07580017
*  '            ' NAME IS CONTAINED                                  '  07640017
*  '************'****************************************************'  07700017
*  '     8      ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE USER'S  '  07760017
*  '            ' ACCOUNT NUMBER IS CONTAINED                        '  07820017
*  '************'****************************************************'  07880017
*  '    12      ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE USER'S  '  07940017
*  '            ' OTHER ACCOUNTING INFORMATION IS CONTAINED          '  08000017
*  '************'****************************************************'  08060017
*  '    16      ' FOUR BYTE POINTER TO A 20-BYTE FIELD WHERE THE     '  08120017
*  '            ' ACCOUNTING ROUTINE CAN STORE DATA                  '  08180017
*  '************'****************************************************'  08240017
*  '    20      ' FOUR BYTE POINTER TO A 72-BYTE FIELD WHERE THE     '  08300017
*  '            ' ACCOUNTING ROUTINE MAY PLACE A MESSAGE             '  08360017
*  '************'****************************************************'  08420017
*  '    24      ' FOUR BYTE POINTER TO A 72-BYTE FIELD WHERE USER'S  '  08480017
*  '            ' TEXT IS CONTAINED                                  '  08540017
*  '************'****************************************************'  08600017
*                                                                       08700017
*  DEFINE OF CODE :  X'00'  FIRST TIME ENTERING ACCOUNTING ROUTINE      08800017
*                    X'04'  USER CANCEL LOGOFF SELECTION                08900017
*                    X'08'  USER HAS MESSAGE TO ACCOUNTING ROUTINE      09000017
*                                                                       09100017
         EJECT                                                          09200017
*    EQUATES                                                            09260017
*                                                                       09320017
RPAR0    EQU   0                   PARAMETER REGISTER                   09400017
RPAR1    EQU   1                   PARAMETER REGISTER                   09500017
RCCT     EQU   2                   CCT ADDRESS REGISTER                 09600017
RWORK    EQU   3                   GENERAL PURPOSE REGISTER             09700017
RBUFR    EQU   4                        BUFFER STARTING ADDR            09800017
RPTR     EQU   5                        COUNTER, POINTER                09900017
RBUFZ    EQU   6                        BUFFER ENDING ADDR              10000017
RINRETN  EQU   7                       INTERNAL RETURN REGISTER         10100017
RPTR1    EQU   8                                                        10150017
RTRM     EQU   9                        RETURN REGISTER                 10170017
RDSECT   EQU   10                  DESECT DISPLACEMEN                   10200017
RBASE    EQU   11                  BASE REGISTER                        10300017
RSAVE    EQU   13                  SAVE REGISTER                        10400017
RRET     EQU   14                  RETURN REGISTER                      10500017
RBR      EQU   15                  BRANCH REGISTER                      10600017
*                                                                       10700017
EODADDR  EQU   33                  RELATIVE ADDR OF END OF DATA ROUTINE 10900017
*                                  IN DCB                               11000017
ZERO     EQU   0                   EQUATE                               11005017
ONE      EQU   1                   EQUATE                               11010017
TWO      EQU   2                   EQUATE                               11015017
THREE    EQU   3                   EQUATE                               11020017
FOUR     EQU   4                   EQUATE                               11025017
FIVE     EQU   5                   EQUATE                               11030017
SEVEN    EQU   7                   EQUATE                               11035017
EIGHT    EQU   8                   EQUATE                               11040017
TWELVE   EQU   12                  EQUATE                               11045017
XIIII    EQU   14                  EQUATE                               11050017
XX       EQU   20                  EQUATE                               11055017
TWO9     EQU   29                  EQUATE                               11060017
XXX      EQU   30                  EQUATE                               11065017
XXXVI    EQU   36                  EQUATE                               11070017
XXXXII   EQU   42                  EQUATE                               11075017
L        EQU   50                  EQUATE                               11080017
LV       EQU   55                  EQUATE                               11085017
LXVIII   EQU   68                  EQUATE                               11090017
LXVIIII  EQU   69                  EQUATE                               11095017
LXXII    EQU   72                  EQUATE                               11100017
MSGLNG   EQU   72                  EQUATE FOR MESSAGE LENGTH            11105017
ONE19    EQU   119                 EQUATE                               11110017
ONE20    EQU   120                 EQUATE                               11115017
FF       EQU   255                 X'FF' FOR BIT MANIPULATION           11120017
BLANK    EQU   X'40'               EQUATE                               11125017
HX80     EQU   X'80'               EQUATE                               11130017
ONE92    EQU   X'C0'               EQUATE                               11135017
ASTERISK EQU   C'*'                EQUATE FOR STARS                     11140017
IOSIZE   EQU   964                      SIZE OF BTAM BUFFER             11150017
LOGINPUT EQU   100                      LOGOFF INPUT MAPPING            11200017
*                                                                       11300017
* HOUSE KEEPING WORK                                                    11400017
*                                                                       11500017
         SAVE  (14,12)             SAVE GENERAL REGISTERS               11600017
         BALR  RBASE,ZERO          SET UP BASE REGISTER                 11700017
         USING *,RBASE                                                  11800017
         LR    RCCT,RPAR1          LOAD CCT ADDRESS                     11900017
         USING CCT,RCCT                                                 12000017
*                                                                       12100017
*    GET SPACE FOR WORK AREA                                            12200017
*                                                                       12300017
         GETMAIN R,LV=ENDDSECT-WORKAREA                                 12400017
         LR    RDSECT,RPAR1        LOAD GETMAIN ADDRESS                 12500017
         USING WORKAREA,RDSECT     SET UP ACCOUNTING WORKAREA BASE      12600017
         ST    RSAVE,CCTPSAVE+FOUR      STORE CALLING SAVE AREA ADDRESS 12700017
         LA    RWORK,CCTPSAVE      LOAD OUR SAVE ADDRESS AND            12800017
         ST    RWORK,EIGHT(,RSAVE)      PASS TO CALLING PROGRAM         12900017
         LR    RSAVE,RWORK         POINTER TO OUR SAVE AREA             13000017
*    TEST IF END OR CANCEL                                              13004017
         WAIT  ECB=CCTPECB              WAIT FOR SELECTION              13008017
         MVI   CCTPECB,ZERO             CLEAR PROCESSOR ECB             13012017
         LH    RTRM,CCTPECB+TWO         GET RETURN CODE                 13016017
         CH    RTRM,TRMCOD              Q. TERMINATE CODE               13020017
         BE    TRMNAT                   YES                             13024017
         TM    CCTPECB+THREE,EIGHT      Q. CANCEL KEY                   13028017
         BO    CANCEL1                  YES                             13032017
         TM    CCTPECB+THREE,FOUR       Q. END KEY                      13036017
         BO    END1                     YES                             13040017
         LA    RPAR0,MSG29              PARAMETER ADDR                  13044017
         B     IERRRN                   ISSUE ERROR MSG                 13048017
END1     OI    CCTPECB,FF-HX80          RESET FOR NEXT TEST             13052017
         MVI   UMSGAREA,BLANK           BLANK OUT THE USER'S            13060017
         MVC   UMSGAREA+ONE(LXXII-ONE),UMSGAREA   MESSAGE AREA          13120017
         SR    RPTR,RPTR                ZERO THE COUNTER                13200017
         MVI   LOGCODE,ZERO        FIRST TIME CODE                      13300017
*                                       GO TO USER ACCTING ROUTINE      13400017
         BAL   RINRETN,LKACCTG          BRANCH TO ACCTG                 13500017
         B     TESTCODE                 BRANCH                          13600017
*                                                                       13700017
*    LINK TO ACCOUNTING ROUTINE                                         13800017
*                                                                       13900017
LKACCTG  EQU   *                                                        14000017
         MVI   MSGAREA,BLANK            BLANK OUT THE                   14050017
         MVC   MSGAREA+ONE(LXXII-ONE),MSGAREA     MESSAGE AREA          14100017
         MVC   LOGUTN,CCTUNIT      IDENTIFICATION OF UNIT               14150017
         LA    RWORK,CCTUNAME           USER NAME ADDRESS               14200017
         ST    RWORK,LOGNAME            PUT IN PAR-LIST                 14300017
         LA    RWORK,CCTUACCT           USER ACCOUNT NUMBER ADDRESS     14400017
         ST    RWORK,LOGACCT            PUT IN PAR-LIST                 14500017
         LA    RWORK,UMSGAREA           USER MESSAGE AREA               14600017
         ST    RWORK,LOGTXT        POINTER TO USER'S TEXT               14630017
         LA    RWORK,CCTUOTHR      USER'S OTHER ACCT INFO               14660017
         ST    RWORK,LOGOTHR       POINTER TO USER'S OTHER              14690017
         LA    RWORK,CCTUARD       IKAACCTG'S DATA                      14720017
         ST    RWORK,LOGDATA       POINTER TO ACCT RTNE DATA            14750017
ACTMSG   LA    RWORK,MSGAREA            ACCOUNTING RTN MSG AREA         14800017
         ST    RWORK,LOGMSG             POINTER TO ACCOUNTING MSG AREA  14900017
         LA    RPAR1,LOGCODE            ACCOUNTING PARAMETER LIST ADDR  15000017
         L     RBR,VACCTG               ACCOUNTING ROUTINE ADDRESS      15200017
         BALR  RRET,RBR                 BRANCH TO ACCOUNTING ROUTINE    15300017
         BR    RINRETN                  RETURN TO CALL                  15400017
TESTCODE EQU   *                                                        15500017
         SR    RWORK,RWORK              ZERO REGISTER                   15600017
         CR    RBR,RWORK               Q. ACCOUNTING RTN HAVE MESSAGE   15700017
         BE    MOVEAMSG                 BRANCH IF YES                   15800017
         LA    RWORK,FOUR          CODE 4 - NORMAL W/O MESSAGE          15900017
         CR    RBR,RWORK               Q. NO MESSAGE DISPLAY LOGOFF     16000017
         BE    DLOGOFF                  BRANCH IF YES                   16100017
         LA    RPAR0,IERRPAR            PARAMETER ADDR                  16200017
IERRRN   LR    RPAR1,RCCT               CCT ADDR                        16300017
         L     RBR,CCTIERRP             IERR ADDR                       16400017
         BALR  RRET,RBR            PUT OUT ERROR MSG                    16470017
         BAL   RTRM,CHKTRM              CHECK RETURN CODE               16550017
         B     FINISH                   FINISH PROCESSING               16620017
DLOGOFF  EQU   *                                                        16700017
WAITECB  EQU   *                                                        16800017
         WAIT  ECB=CCTPECB              WAIT                            16900017
         MVI   CCTPECB,ZERO             CLEAR PROCESSOR ECB             16950017
         LH    RBR,CCTPECB+TWO          GET RETURN CODE                 17000017
         BAL   RTRM,CHKTRM              CHECK RETURN CODE               17060017
         TM    CCTPECB+THREE,EIGHT      Q. CANCEL KEY                   17140017
         BO    CANCEL                   YES                             17220017
         TM    CCTPECB+THREE,FOUR       Q. END KEY                      17300017
         BO    END                      YES                             17380017
         LA    RPAR0,MSG29              PARAMETER ADDR                  17500017
         B     IERRRN                   BRANCH                          17600017
CANCEL   EQU   *                                                        17700017
         MVI   LOGCODE,FOUR             SET CANCEL CODE                 17800017
         BAL   RINRETN,LKACCTG          GO TO USER ACCOUNTING ROUTINE   17900017
CANCEL1  EQU   *                                                        17950017
         FREEMAIN R,LV=ENDDSECT-WORKAREA,A=(RDSECT)                     18000017
         LA    RBR,TWELVE               CODE TO DISPLAY LAST SELECT     18100017
*                                       FRAME                           18200017
         LR    RPAR1,RCCT               CCT ADDRESS                     18300017
         L     RSAVE,CCTPSAVE+FOUR      RESTORE REGISTER                18400017
         RETURN (14,12),RC=(15)         RETURN TO CTL                   18500017
END      EQU   *                                                        18600017
         LA    RPTR,ONE(,RPTR)          UPDATE COUNTER                  18700017
         MVI   LOGCODE,EIGHT            CODE TO DISPLAY USER MSG        18800017
         LA    RWORK,CCTPWKA+LOGINPUT   INPUT ADDRESS                   18900017
         CLI   ZERO(RWORK),BLANK        Q. BLANK IN USER MSG AREA       19000017
         BNE   MOVEUMSG                 BRANCH IF NO                    19100017
         CLC   ZERO(XXXVI,RWORK),XXXVI(RWORK)     Q. ANYTHING THERE     19200017
         BE    NORMAL                   BRANCH IF NO                    19300017
MOVEUMSG EQU   *                                                        19400017
         C     RPTR,KONE                Q. FIRST TIME DATA ENTERED      19500017
         BE    MOVE                    BRANCH IF YES                    19600017
         CLC   SAVEMSG(LXXII),ZERO(RWORK)    COMPARE MESSAGES           19700017
         BE    NORMAL                  BRANCH IF YES                    19800017
MOVE     EQU   *                                                        19900017
         MVC   SAVEMSG(LXXII),ZERO(RWORK)    SAVE INPUT                 20000017
         MVC   UMSGAREA(LXXII),ZERO(RWORK)   MOVE USER'S MSG INTO LIST  20100017
         BAL   RINRETN,LKACCTG          GO TO ACCOUNTING ROUTINE        20200017
         LA    RWORK,ZERO               CODE IS NORMAL W/ MSG           20300017
         CR    RBR,RWORK              Q.ACCOUNTING HAS MSG              20400017
         BE    MOVEAMSG                 BRANCH IF YES                   20500017
         LA    RWORK,FOUR               CODE IS NORMAL W/O MSG          20600017
         CR    RBR,RWORK               Q. NO MSG                        20700017
         BE    NORMAL                   BRANCH IF YES                   20800017
         LA    RPAR0,IERRPAR            PARAMETER ADDR                  20860017
         B     IERRRN                   BRANCH                          20920017
MOVEAMSG EQU   *                                                        21000017
         MVC   CCTPWKA+8(XX),CTITLE     MOVE ACCOUNTING MESSAGE TITLE   21100017
         LA    RWORK,CCTPWKA+EIGHT      * POINTER TO THIS MESSAGE       21200017
         ST    RWORK,CCTPWKA            *                               21300017
         MVI   CCTPWKA,BLANK            SET OPTION BYTE                 21400017
         MVC   CCTPWKA+XXX(LXXII),MSGAREA  MOVE IN ACCOUNTING MSG       21500017
         MVI   CCTPWKA+TWO9,MSGLNG      SET LENGTH                      21600017
         LA    RWORK,CCTPWKA+TWO9       * POINTER TO THIS MESSAGE       21700017
         ST    RWORK,CCTPWKA+FOUR       *                               21800017
         MVI   CCTPWKA+FOUR,ONE92       CODE FOR LAST ENTRY             21900017
         LA    0,CCTPWKA               PARAMETER LIST                   22000017
         LR    RPAR1,RCCT               CCT ADDRESS                     22100017
         L     RBR,CCTDMRP              DMSG ADDR                       22200017
         BALR  RRET,RBR                 DISPLAY ACCOUNTING MSG          22400017
         BAL   RTRM,CHKTRM              CHECK RETURN CODE               22550017
         B     WAITECB                  GO TO WAIT                      22600017
         SPACE 3                                                        22620017
WTO50    EQU   *                                                        22640017
         MVC   CCTPWKA(XIIII),MSG50     MESSAGE NUMBER                  22660017
         LA    RWORK,CCTPWKA+TWELVE     ADDRESS TO INSERT DATA          22680017
         ST    RWORK,CCTPWKA+EIGHT      *                               22700017
         MVI   CCTPWKA+EIGHT,ONE92      CONTROL BITS                    22720017
         MVC   CCTPWKA+XIIII(THREE),CCTUNIT  UNIT NUMBER                22740017
         LA    RPAR0,CCTPWKA            MESSAGE PARAMETER               22760017
         LR    RPAR1,RCCT               CCT ADDRESS                     22780017
         L     RBR,CCTIERRP             IERR ADDRESS                    22800017
         BALR  RRET,RBR                 BRANCH TO IERR                  22820017
         B     TRMNAT              TERMINATE AFTER MESSAGE              22821017
         SPACE 2                                                        22822017
NORMAL   EQU   *                                                        22823017
         LA    RWORK,CCTDIAWA           DIARY WORK AREA ADDR            22824017
         MVC   5(6,RWORK),LOGOFF        PROCESSOR'S NAME                22826017
         MVC   15(20,RWORK),CCTUNAME    USER'S NAME                     22828017
         L     RBR,CCTDIARP             DIARY ROUTINE ADDR              22830017
         LR    RPAR1,RCCT               CCT ADDRESS                     22832017
         BALR  RRET,RBR                 GO TO DIARY PROCESSOR           22834017
         BAL   RTRM,CHKTRM              CHECK RETURN CODE               22837017
         EJECT                                                          22840017
FINISH   L     RPAR1,CCTBUFFP           GET ADDR OF I/O AREA            22846017
         MVC   0(4,RPAR1),EXOK          INDICATE EXTRACT RECORD OK      22852017
         LA    RPAR0,X'04'              WRITE CODE                      22858017
         ST    RPAR0,CCTRECLN           ALSO LENGTH OF RECORD           22864017
         LR    RPAR1,RCCT               ADDR OF CCT                     22870017
         L     RBR,CCTIORP              ADDR OF IKDIOR                  22876017
         BALR  RRET,RBR                                                 22882017
         BAL   RTRM,CHKTRM              CHECK RETURN CODE               22888017
         TM    CCTSSTAT,HX80            RECORD OPTION                   22958017
         BZ    FREEMAIN                 NO - GO FREEMAIN                23028017
*                                                                       23100017
*    TRANSMIT DIARY DATA SET TO THE SUBSYSTEM                           23200017
*                                                                       23300017
         MVC   READ(LREAD),FREAD        MOVE READ TO GETMAIN            23400017
*                                                                       23500017
         MVI   WKARF,HX80               TURN ON HIGH ORDER BIT          23600017
         L     RPTR,CCTRDCBP            GET ADDR OF DIARY DCB           23700017
         CLOSE ((RPTR),),MF=(E,WKARF)                                   23800017
         OPEN  ((RPTR),(INOUT)),MF=(E,WKARF)                            23900017
*                                                                       24000017
*    INITIALIZE FOR DATA TRANSMISSION                                   24100017
*                                                                       24200017
         L     RBUFR,CCTBUFFP           GET ADDR OF I/O AREA            24300017
         LA    RBUFZ,IOSIZE(,RBUFR)     GET LAST POSITION               24400017
*                                                                       24500017
         L     RPTR,CCTRDCBP          LOAD RECORD DCB ADDRESS AND       24600017
         ST    RPTR,DCBADDR        STORE IN READ FIELD                  24700017
         LA    RWORK,FCLOSE              * MOVE END OF DATA SET         24800017
         ST    RWORK,CCTPWKA             * HANDLING ROUTINE ADDRESS     24900017
         MVC   EODADDR(THREE,RPTR),CCTPWKA+ONE  INTO DIARY DCB          25000017
*    TRANSMIT FIVE RECORD HEADER TO SUBSYSTEM                           25100017
         BAL   RINRETN,CLEAR            CLEAR A LINE                    25200017
         BAL   RINRETN,STARS            MOVE IN ASTERISKS               25300017
         BAL   RINRETN,PUT              WRITE TO SUBSYSTEM              25400017
         BAL   RINRETN,CLEAR            CLEAR A LINE                    25500017
         MVC   ZERO(XXXXII,RBUFR),RECORD     MOVE IN HEADER IDENT,      25560017
         MVC   L(FIVE,RBUFR),KUNIT           MOVE IN 'UNIT=',           25620017
         MVC   LV(THREE,RBUFR),CCTUNIT       MOVE IN UNIT ADDRESS,      25680017
         MVC   LXVIII(TWO,RBUFR),RECORD      AND TWO STARS              25740017
         BAL   RINRETN,PUT              WRITE TO SUBSYSTEM              25800017
         BAL   RINRETN,CLEAR            CLEAR A LINE                    25900017
         BAL   RINRETN,STARS            MOVE IN ASTERISKS               26000017
         BAL   RINRETN,PUT              WRITE TO SUBSYSTEM              26100017
         BAL   RINRETN,CLEAR            CLEAR A LINE                    26200017
         BAL   RINRETN,PUT              WRITE TO SUBSYSTEM              26300017
         BAL   RINRETN,CLEAR            CLEAR A LINE                    26400017
         BAL   RINRETN,PUT              WRITE TO SUBSYSTEM              26500017
*                                                                       26600017
* READ AND WRITE FUNCTION                                               26700017
*                                                                       26800017
FREADEFM EQU   *                                                        26900017
         ST    RBUFR,AREAADDR           STORE ADDR IN READ AREA         27000017
         READ  ECTBLOCK,SF,MF=E                                         27100017
         CHECK READ                CHECK READ                           27200017
         BAL   RINRETN,PUT              WRITE TO SUBSYSTEM              27300017
         B     FREADEFM                 LOOP                            27400017
*                                                                       27500017
*    END OF DIARY DATA SET                                              27600017
*                                                                       27700017
FCLOSE   EQU   *                                                        27800017
         C     RBUFR,CCTBUFFP           TEST IF AT BEGINNING            27860017
         BNE   EOF                      TRAILER WILL FIT                27920017
         BAL   RINRETN,CLEAR            CLEAR A LINE                    27980017
         BAL   RINRETN,PUT              WRITE TO SUBSYSTEM              28040017
EOF      EQU   *                                                        28100017
         MVC   ZERO(FOUR,RBUFR),EOFTRLR      MOVE IN EOF TRAILER        28200017
         LA    RBUFR,FOUR(,RBUFR)            INCREMENT FOR SIZE         28300017
         BAL   RINRETN,PUTS             WRITE OUT LAST BLOCK            28400017
*                                                                       28450017
*    FREE SPACE FOR WORK AREA                                           28500017
*                                                                       28550017
FREEMAIN LR    RTRM,RBR                 SAVE RETURN REGISTER            28600017
         CH    RBR,TRMCOD               Q. TERMINATE CODE               28606017
         BNE   WTO50                    NO, ISSUE LOG OFF MSG           28612017
TRMNAT   EQU   *                                                        28620017
         FREEMAIN R,LV=ENDDSECT-WORKAREA,A=(RDSECT)                     28650017
*                                                                       28850017
**   PREPARE TO GO TO CLEAN UP MODULE                                   29050017
*                                                                       29250017
         CH    RTRM,TRMCOD              Q. TERMINATE CODE               29320017
         BNE   SCHINT                   NO - NORMAL END                 29390017
         LR    RBR,RTRM                 GET RETURN CODE FOR IKDCTL      29460017
         L     RSAVE,CCTPSAVE+FOUR      GET CALLING SAVE AREA ADDRESS   29490017
         RETURN (14,12),RC=(15)         RETURN                          29530017
         SPACE 2                                                        29600017
SCHINT   SR    RPAR0,RPAR0              SET RETURN CODE FOR IKASCH      29670017
         L     RSAVE,CCTPSAVE+FOUR      RELOAD CALLING SAVE ADDRESS     29800017
         LR    RPAR1,RCCT          LOAD CCT ADDRESS                     30000017
         O     RPAR1,HBITONE            HIGH ORDER BIT ON INDICATE      30100017
*                                       LOGOFF TIME                     30200017
         XCTL  (2,12),EP=IKASCH                                         30300017
         EJECT                                                          30350017
*                                                                       30400017
*    MISCELLANEOUS ROUTINES                                             30500017
*                                                                       30600017
CLEAR    EQU   *                        CLEAR A LINE TO BLANKS          30700017
         MVI   ZERO(RBUFR),BLANK        FIRST BLANK                     30780017
         MVC   ONE(ONE19,RBUFR),ZERO(RBUFR)  CHAINING                   30860017
         BR    RINRETN                  RETURN                          30940017
         SPACE 1                                                        31050017
STARS    EQU   *                        MOVE 70 STARS                   31100017
         MVI   ZERO(RBUFR),ASTERISK                                     31180017
         MVC   ONE(LXVIIII,RBUFR),ZERO(RBUFR)  CHAINING                 31260017
         BR    RINRETN                  RETURN                          31340017
*                                                                       31450017
*    LINK TO IKDIOR TO WRITE TO THE SUBSYSTEM                           31500017
*                                                                       31550017
PUT      EQU   *                                                        31600017
         LA    RBUFR,ONE20(,RBUFR)      INCREMENT FOR NEXT RECORD       31700017
         LA    RPTR,ONE20(,RBUFR)       Q. SPACE AVAILABLE              31800017
         CR    RBUFZ,RPTR               FOR THIS RECORD                 31900017
         BCR   TWO,RINRETN              YES - CONTINUE                  32000017
PUTS     EQU   *                                                        32100017
         LA    RPAR0,FOUR               WRITE CODE - X'04'              32200017
         S     RBUFR,CCTBUFFP           GET LENGTH OF RECORD            32300017
         ST    RBUFR,CCTRECLN           TO BE TRANSMITTED               32400017
         LR    RPAR1,RCCT               ADDR OF CCT                     32500017
         L     RBR,CCTIORP              ADDR OF IKDIOR                  32600017
         BALR  RRET,RBR                 TO I/O ROUTINE                  32670017
         BAL   RTRM,CHKTRM              CHECK RETURN CODE               32750017
         L     RBUFR,CCTBUFFP           GET ADDR OF I/O AREA            32800017
         BR    RINRETN                  RETURN                          32850017
*                                                                       32910017
*    TEST RETURN CODE FOR 'MUST TERMINATE' CONDITION                    32920017
*                                                                       32930017
CHKTRM   CH    RBR,TRMCOD               Q. TERMINATE CODE               32940017
         BCR   SEVEN,RTRM               NO - RETURN                     32960017
         B     FREEMAIN                 TERMINATE PROCESSING            32980017
         EJECT                                                          33000017
*                                                                       33100017
*                                                                       33200017
*    CONSTANTS, ETC.                                                    33300017
*                                                                       33400017
*                                                                       33500017
         DS    0F                  ALIGNMENT                            33590017
HBITONE  DC    X'80000000'         FULL WORD W/ HIGH-ORDER BIT ON       33680017
*                                                                       33770017
MSG50    EQU   *                                                        33840017
         DC    CL3'050'                 MSG NO.                         33910017
         DC    C'PLOF0'                 MODULE NAME                     33980017
         DC    X'C1'                    INSERT AND RETURN               34050017
         DC    XL3'0'                   SPACE                           34120017
         DC    H'5'                     DATA LENGTH                     34190017
         DS    0F                                                       34300017
*                                                                       34920017
**   DATA FOR TRANSMISSION TO THE SUBSYSTEM                             34940017
*                                                                       34960017
EXOK     DC    C'EXOK'                  EXTRACT RECORD OK               34980017
CTITLE   DC    AL1(19)             LENGTH OF MESSAGE                    35040017
         DC    C'ACCOUNTING MESSAGE:'   TEXT                            35100017
KONE     DC    F'1'                CONSTANT                             35160017
TRMCOD   DC    H'28'                    MUST TERMINATE                  35220017
         SPACE 1                                                        35240017
LOGOFF   DC    C'LOGOFF'                CONSTANT                        35260017
*                                                                       35300017
*    HEADER IDENTIFICATION RECORD FOR DIARY DATA SET                    35400017
*                                                                       35500017
RECORD   EQU   *                                                        35600017
         DC    CL42'**    PRINTED RECORD OF SESSION AT CONSOLE'         35700017
KUNIT    DC    C'UNIT='            CONSTANT                             35710017
*                                                                       35720017
*    TRAILER IDENTIFICATION FOR DIARY DATA SET                          35740017
*                                                                       35760017
EOFTRLR  DC    CL4' '                   EOF INDICATOR FOR SUBSYSTEM     35780017
*                                                                       35800017
* PARAMETER LIST FOR INTERNAL ERROR ROUTINE                             35900017
*                                                                       36000017
         DS    0F                  ALIGNMENT                            36100017
IERRPAR  DC    C'023'                   MESSAGE NUMBER                  36200017
         DC    C'PLOF0'                 MODULE NAME                     36300017
         DC    X'01'                    ATTRIBUTES                      36400017
         DC    X'000000'                SPACE                           36500017
*                                                                       36600017
MSG29    DC    CL3'029'                 MESSAGE NUMBER                  36620017
         DC    C'PLOF0'                 MODULE NAME                     36640017
         DC    X'01000000'              ATTRIBUTES                      36660017
*                                                                       36680017
FREAD    READ  DECBR,SF,,,120,MF=L                                      36700017
FREADE   EQU   *                                                        36800017
VACCTG   DC    V(IKAACCTG)         ADDRESS OF ACCOUNTING ROUTINE        36900017
LREAD    EQU   FREADE-FREAD        LENGTH READ EXPANSION                37000017
         CNOP  0,8                 ADJUST TO DOUBLE-WORD BOUNDARY       37100017
         EJECT                                                          37200017
*                                                                       37300017
*                                                                       37400017
* DSECT FOR ACCOUNTING ROUTINE PARAMETER LIST, READ, WRITE, OPEN        37500017
*                                                                       37600017
*                                                                       37700017
WORKAREA DSECT                                                          37800017
         DS    0F                                                       37900017
LOGCODE  DS    XL1                 PARAMETER CODE                       38000017
LOGUTN   DS    XL3                 UNIT NAME                            38100017
LOGNAME  DS    F                   ADDR OF USER'S NAME                  38200017
LOGACCT  DS    F                   ADDR OF USER'S ACCT                  38300017
LOGOTHR  DS    F                   ADDR OF OTHER INFO                   38400017
LOGDATA  DS    F                   ADDR OF DATA FROM ACCT RTNE          38500017
LOGMSG   DS    F                   ADDR OF MESSAGE FROM ACCT RTNE       38600017
LOGTXT   DS    F                   ADDR OF USER'S TEXT                  38700017
UMSGAREA DS    18F                 USER MESSAGE AREA                    38800017
MSGAREA  DS    18F                 ACCT RTNE MESSAGE                    38900017
SAVEMSG  DS    18F                 PREVIOUS USER MSG                    39000017
WKARF    DS    F                        FULL WORD WORK AREA             39100017
READ     EQU   *                                                        39200017
ECTBLOCK DC    F'0'                EVENT CONTROL BLOCK                  39300017
         DC    X'00'               TYPE FIELD                           39400017
         DC    X'80'               TYPE FIELD                           39500017
RLENGTH  DC    AL2(120)            LENGTH                               39600017
DCBADDR  DC    A(0)                DCB ADDRESS                          39700017
AREAADDR DC    A(0)                AREA ADDRESS                         39800017
         DC    A(0)                RECORD POINTER WORD                  39900017
*                                                                       40000017
         DS    0D                                                       40100017
ENDDSECT EQU   *                                                        40200017
         EJECT                                                          40300017
         SPACE                                                          40400017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         40500017
         SPACE                                                          40600017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    40700017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     40800017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       40900017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             41000017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  41100017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  41200017
*                   SET.                                                41300017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      41400017
*                   SECOND.                                             41500017
         SPACE 2                                                        41600017
CCT      DSECT                                                          41700017
         SPACE 2                                                        41800017
*                             SECTION ONE                               41900017
         SPACE                                                          42000017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     42100017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    42200017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  42300017
         SPACE                                                          42400017
         DS    0F                                                       42500017
CCTUNAME DS    5F                  USER'S NAME                          42600017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         42700017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     42800017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       42900017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    43000017
*                                       AT LAST BEGIN JOB               43100017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   43200017
*                                       LAST BEGIN JOB                  43300017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 43400017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    43500017
*                                       JOB                             43600017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    43700017
*                                       JOB                             43800017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     43900017
*                                       CESSOR                          44000017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         44100017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         44200017
CCTJCTR  DS    H                   JOB COUNTER                          44300017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                44400017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   44500017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  44600017
CCTSSTAT DS    C                   SESSION STATUS                       44700017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              44800017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              44900017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    45000017
         EJECT                                                          45100017
         SPACE 2                                                        45200017
*                             SECTION TWO                               45300017
         SPACE                                                          45400017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   45500017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  45600017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 45700017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              45800017
         SPACE                                                          45900017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     46000017
*                                       FRAME                           46100017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  46200017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     46300017
*                                       MULTIPLE DISPLAY FRAME (ENT)    46400017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   46500017
CCTDISM  DS    C                   DISPLAY MASK                         46600017
CCTCSM   DS    C                   COMMAND SELECT MASK                  46700017
CCTPSTAT DS    CL2                 GJP STATUS                           46800017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              46900017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  47000017
         SPACE 2                                                        47100017
*                             SECTION THREE                             47200017
         SPACE                                                          47300017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    47400017
*                   INTO SECTION ONE OR TWO                             47500017
         SPACE                                                          47600017
CCTDGMP  DS    F                  POINTER TO DGM                        47700017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                47800017
CCTCSTP  DS    F                  POINTER TO CST                        47900017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                48000017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            48100017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 48200017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              48300017
CCTDIARP DS    F                  POINTER TO DIA                        48400017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      48500017
CCTACTP  DS    F                  POINTER TO ACT                        48600017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     48700017
CCTIERRP DS    F                  POINTER TO IERR                       48800017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              48900017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               49000017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                49100017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 49200017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 49300017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   49400017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                49500017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                49600017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               49700017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              49800017
CCTPECB  DS    F                  PROCESSOR'S ECB                       49900017
CCTWECB  DS    F                  WTOR ECB                              50000017
CCTDIAWA DS    CL136               DIARY WORK AREA                      50100017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    50200017
CCTCSAVE DS    CL72                CTL SAVE AREA                        50300017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                50400017
CCTASAVE DS    CL72                DAT SAVE AREA                        50500017
*                                                                       50600017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       50700017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           50800017
*                                                                       50900017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             51000017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               51100017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     51200017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               51300017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           51400017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    51500017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 51580017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   51660017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   51740017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   51820017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            51900017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 51980017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       52060017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  52140017
*                                  INATION OF DATA                      52220017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    52300017
*                                  THE I/O OPERATION TO BE TESTED BY    52380017
*                                  GTCLT                                52460017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        52540017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              52620017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   52710017
         END                                                            52800017
./       ADD   SSI=00013302,NAME=IKDPREC0,SOURCE=0
         EJECT                                                          00090017
 TITLE 'IKDPREC0' RECALL PROCESSOR FOR SGJP                             00096017
*STATUS: CHANGE LEVEL 000                                             * 00102017
*FUNCTION/OPERATION: PROCESS RECALL OPTION FROM THE SELECT FRAME DIS- * 00108017
*   PLAYED AT THE 1130 SUBSYSTEM. UPON ENTRY IKDPREC0 ACQUIRES AN AREA* 00114017
*   OF STORAGE, SETS UP POINTERS TO THE EXTRACT DATA SETS AND INITIAL-* 00120017
*   IZES THE JCL DATA SET TO WRITE AT RECORD ONE. THE WORK AREA IS    * 00126017
*   THEN INITIALIZED AND THE FIRST EXTRACT RECORD IS READ INTO CORE.  * 00132017
*   A CHECK IS MADE TO DETERMINE WHICH OF THE RECALL OPTIONS ARE      * 00138017
*   AVAILABLE TO THE USER AND A CODE DENOTING THESE OPTIONS IS PLACED * 00144017
*   IN THE I/O BUFFER. THEN THE CURRENT ITEM IS PLACED INTO THE BUFFER* 00150017
*   AND THE BUFFER IS TRANSMITTED TO THE SUBSYSTEM. A READ IS THEN    * 00156017
*   REQUESTED OF IKDIOR TO RECEIVE THE USERS CHOICE.                  * 00162017
*   ACCEPT: IF ACCEPT WAS REQUESTED, THE EXTRACT RECORD IS MOVED TO   * 00168017
*   THE PROCESSOR WORKAREA AND THE APPROPRIATE PROCESSOR IS BRANCHED  * 00174017
*   TO TO PROCESS THE RECORD. IF BEGIN JOB OR BEGIN PROCEDURE IS ACC- * 00180017
*   EPTED, THE BEGIN JOB PROCESSOR IS GIVEN CONTROL VIA XCTL MACRO    * 00186017
*   REVIEW: IF REVIEW WAS ACCEPTED, THE EXTRACT RECORD AND THE PST FOR* 00192017
*   THE PROCESSOR ARE USED TO CONSTRUCT A RECORD AS THE USER PREPARED * 00198017
*   IT AT THE  1130. THIS RECORD IS THEN TRANSMITTED TO THE SUBSYSTEM * 00204017
*   FOR REDISPLAY.  A READ IS ISSUED TO RECEIEVE THE CORRECTED EXTRACT* 00210017
*   RECORD AND THE APPROPRIATE PROCESSOR IS BRANCHED TO FOR THE RECORD* 00216017
*   PROCESSING                                                        * 00222017
*   INSERT: IF INSERT IS REQUESTED, A READ IS ISSUED TO RECEIVE THE   * 00228017
*   PSR INDICATING THE USER'S CHOICE TO INSERT. THE PROCESSOR TO GAIN * 00234017
*   CONTROL IS LOADED, THE EXTRACT RECORD IS READ, AND THE PROCESSOR  * 00240017
*   IS BRANCHED TO                                                    * 00246017
*   OMIT: IF OMIT WAS SELECTED, ANOTHER EXTRACT RECORD IS READ FROM   * 00252017
*   THE DATA SET. THE CURRENT ITEM IS BUILT, AND PROCESSING CONTINUES * 00258017
*   AS DESCRIBED ABOVE UNTIL A BEGIN OPERATION IS ACCEPTED OR INSERTED* 00264017
*   UNTIL NO MORE EXTRACT RECORDS EXIST OR UNTIL A LOGOFF OR CANCEL   * 00270017
*   JOB IS INSERTED                                                   * 00276017
*ENTRY POINTS: IKDPREC0 VIA LINK FROM IKDCTL                          * 00282017
*INPUT: REGISTER ONE POINTS TO CONSOLE CONTROL TABLE                  * 00288017
*OUTPUT: EXTRACT RECORDS IN CCTPWKA FOR PROCESSORS                    * 00294017
*EXTERNAL ROUTINES: PROCESSOR ROUTINES, IKDIOR FOR I/O OPERATIONS     * 00300017
*EXITS: XCTL TO BEGIN JOB PROCESSOR, NORMAL RETURN TO IKDCTL          * 00306017
*TABLES/WORKAREAS: CCT, I/O BUFFER                                    * 00312017
*ATTRIBUTES: REENTRANT, LINKED TO BY IKDCTL                           * 00318017
*NOTES: N/A                                                           * 00324017
         EJECT                                                          00330017
*                                                                       00360017
*               CONSOLE CONTROL TABLE FOR GRAPHIC JOB PROCESSOR         00450017
         SPACE                                                          00540017
*                   THIS TABLE OF CONSTANTS, STATUS SWITCHS, STORAGE    00630017
*              AREAS AND WORKAREAS IS THE MAJOR COMMUNICATION MECH-     00720017
*              ANISM FOR GJP.  IT IS DIVIDED INTO THREE SECTIONS.       00810017
*              THE FIRST SAVED BETWEEN JOBS ON A DATA SET .             00900017
*              THE SECOND IS IN A CONSTANT AND DEPENDENT ORDER FOR THE  00990017
*                   USE OF RECALL. IT IS WRITTEN ONTO THE EXTRACT DATA  01080017
*                   SET.                                                01170017
*              THE THIRD IS ANYTHING NOT INVOLVED IN THE FIRST AND      01260017
*                   SECOND.                                             01350017
         SPACE 2                                                        01440017
CCT      DSECT                                                          01530017
         USING *,CCTR                                                   01620017
         SPACE                                                          01710017
*                             SECTION ONE                               01800017
         SPACE                                                          01890017
*                   THIS SECTION OF THE CCT IS SAVED ON DISK BY THE     01980017
*              BEGIN JOB PROCESSOR.   AFTER THE USER'S JOB HAS TERM-    02070017
*              INATED IT IS RESTORED TO THE CCT DURING INITIALIZATION.  02160017
         SPACE                                                          02250017
         DS    0F                                                       02340017
CCTUNAME DS    5F                  USER'S NAME                          02430017
CCTUACCT DS    5F                 USER'S ACCOUNTING INFORMATION         02520017
CCTUOTHR DS    5F                  USER'S ADDITIONAL ACCOUNT NUMBER     02610017
CCTUARD  DS    5F                  USER'S ACCOUNTING ROUTINE DATA       02700017
CCTENOTE DS    F                   NOTE POSITION OF EXTRACT DATA SET    02790017
*                                       AT LAST BEGIN JOB               02880017
CCTRNOTE DS    F                   NOTE POSITION OF DIARY DATA SET AT   02970017
*                                       LAST BEGIN JOB                  03060017
CCTSOUT  DS    F                   SYSOUT CLASS FOR USE WITH USER'S JOB 03150017
CCTUFRGN DS    F                   REGION SIZE FOR A USER FOREGROUND    03240017
*                                       JOB                             03330017
CCTUBRGN DS    F                   REGION SIZE FOR A USER BACKGROUND    03420017
*                                       JOB                             03510017
CCTGRGN  DS    F                   REGION SIZE FOR GRAPHIC JOB PRO-     03600017
*                                       CESSOR                          03690017
CCTFRPRI DS    H                   FOREGROUND GROUP OR PRIORITY         03780017
CCTBRPRI DS    H                   BACKGROUND GROUP OR PRIORITY         03870017
CCTJCTR  DS    H                   JOB COUNTER                          03960017
CCTHIST  DS    109F                HISTORY OF OPERATIONS                04050017
*                             THE FOLLOWING FIELDS OF SECTION ONE ARE   04140017
*                        NOT DEPENDENT ON WORD OR HALF WORD ALINEMENT.  04230017
CCTSSTAT DS    C                   SESSION STATUS                       04320017
CCTFJCLS DS    C                   JOBCLASS FOR FOREGROUND              04410017
CCTBJCLS DS    C                   JOBCLASS FOR BACKGROUND              04500017
CCTUNIT  DS    CL3                 2250 UNIT ADDRESS                    04590017
         EJECT                                                          04680017
         SPACE 2                                                        04770017
*                             SECTION TWO                               04860017
         SPACE                                                          04950017
*                   THIS SECTION OF THE CCT IS IN AN ORDER UPON WHICH   05040017
*              SOME PROGRAMS ARE DEPENDENT.  THIS ENTIRE SECTION MAKES  05130017
*              UP ONE EXTRACT RECORD WHICH IS WRITTEN BY THE JCL GENER- 05220017
*              ATOR AND READ BACK BY THE RECALL PROCESSOR.              05310017
         SPACE                                                          05400017
CCTOVRLY DS    F                   OVERLAY FIELDS GOVERNING CURRENT     05490017
*                                       FRAME                           05580017
CCTCCR   DS    XL3                 CURRENT COMMAND KEY                  05670017
CCTSCPOS DS    C                   POSITION ON SCREEN OF ENTRY OF A     05760017
*                                       MULTIPLE DISPLAY FRAME (ENT)    05850017
CCTADISM DS    C                   DISPLAY MASK OF PREVIOUS OPERATION   05940017
CCTDISM  DS    C                   DISPLAY MASK                         06030017
CCTCSM   DS    C                   COMMAND SELECT MASK                  06120017
CCTPSTAT DS    CL2                 GJP STATUS                           06210017
CCTHSN   DS    F                   HISTORY SEQUENCE NUM&ER              06300017
CCTPWKA  DS    CL352               PROCESSOR WORK AREA                  06390017
CCTPWKAE EQU   *                                                        06480017
         SPACE 2                                                        06570017
*                             SECTION THREE                             06660017
         SPACE                                                          06750017
*                   THIS SECTION IS MADE UP OF WHATEVER DOES NOT FIT    06840017
*                   INTO SECTION ONE OR TWO                             06930017
         SPACE                                                          07020017
CCTDGMP  DS    F                  POINTER TO DGM                        07110017
CCTDATAP DS    F                  POINTER TO DATA NUMBER                07200017
CCTCSTP  DS    F                  POINTER TO CST                        07290017
CCTCPSTP DS    F                  POINTER TO CURRENT PST                07380017
CCTDMRP  DS    F                  POINTER TO DISPLAY MSG RTN            07470017
CCTDORP  DS    F                  POINTER TO DOR MODULE                 07560017
CCTJCLGP DS    F                  POINTER TO JCL GENERATOR              07650017
CCTDIARP DS    F                  POINTER TO DIA                        07740017
CCTDIRP  DS    F                  POINTER TO DISPLAY INPUT ROUTINE      07830017
CCTACTP  DS    F                  POINTER TO ACT                        07920017
CCTPKYM  DS    F                  POINTER TO KYMANIP FOR PROCESSORS     08010017
CCTIERRP DS    F                  POINTER TO IERR                       08100017
CCTGWRKP DS    F                  POINTER TO DGM WORK AREA              08190017
CCTJCLWP DS    F                  POINTER TO JCL WORKAREA               08280017
CCTGEND  DS    F                  POINTER TO SYSGEN DATA                08370017
CCTJDCBP DS    F                  POINTER TO JCL DS DCB                 08460017
CCTRDCBP DS    F                  POINTER TO DIA DS DCB                 08550017
CCTDDCBP DS    F                  POINTER TO 2250 DCB                   08640017
CCTEDCBP DS    F                  POINTER TO EXTRACT DCB                08730017
CCTEDCB1 DS    F                  POINTER TO EXTRACT DCB                08820017
CCTGACBP DS    F                  POINTER TO GRAPHIC GACB               08910017
CCTTIME  DS    F                  POINTER TO TIMER FOR GJP              09000017
CCTPECB  DS    F                  PROCESSOR'S ECB                       09090017
CCTWECB  DS    F                  WTOR ECB                              09180017
CCTDIAWA DS    CL136               DIARY WORK AREA                      09270017
CCTLPWRK DS    CL184               LPMANIP WORK AREA                    09360017
CCTCSAVE DS    CL72                CTL SAVE AREA                        09450017
CCTPSAVE DS    CL72                PROCESSOR'S SAVE AREA                09540017
CCTASAVE DS    CL72                DAT SAVE AREA                        09630017
*                                                                       09720017
* THESE ARE THE CHANGES MADE TO THE CONSOLE CONTROL TABLE OF GJP.       09810017
* CONTENTS NOT NEEDED BY SGJP ARE REPLACED AS INDICATED BELOW           09900017
*                                                                       09990017
IKDCCT   EQU   CCT                                                      10080017
CCTCWKA  EQU   CCTCSTP             CONTROL ROUTINE WORKAREA             10170017
CCTBUFFP EQU   CCTGWRKP            POINTER TO BTAM BUFFER               10260017
CCTRECLN EQU   CCTDGMP             LENGTH OF DATA TO BE TRANSMITTED     10350017
CCTIORP  EQU   CCTDORP             POINTER TO I/O ROUTINE               10440017
CCTMSGP  EQU   CCTDMRP             POINTER TO MESSAGE ROUTINE           10530017
CCTSTAT  EQU   CCTACTP             SGJP STATUS BYTES                    10620017
CCTIELST EQU   CCTLPWRK+68         AREA USED FOR GTNIT/GTEND PARAM LIST 10690017
CCTRDLST EQU   CCTIELST+24         AREA USED FOR GTRED PARAMETER LIST   10760017
CCTWRLST EQU   CCTRDLST+16         AREA USED FOR GTWRT PARAMETER LIST   10830017
CCTTSLST EQU   CCTWRLST+20         AREA USED FOR GTCLT PARAMETER LIST   10900017
CCTDSREF EQU   CCTTSLST+12         DATA SET REFERENCE NUMBER            10970017
CCTSTCOD EQU   CCTDSREF+4          WORD TO CONTAIN RESULTS OF INIT,TEST 11040017
CCTDATYP EQU   CCTSTCOD+4          WORD TO CONTAIN DATA TYPE CODE       11110017
CCTCTLOP EQU   CCTDATYP+4          WORD CONTAINING CODE DENOTING DEST-  11180017
*                                  INATION OF DATA                      11250017
CCTTSTCD EQU   CCTCTLOP+4          WORD TO CONTAIN CODE REPRESENTING    11320017
*                                  THE I/O OPERATION TO BE TESTED BY    11390017
*                                  GTCLT                                11460017
CCTIOECB EQU   CCTTSTCD+4         ECB USED IN WTOR ON I/O ERRORS        11530017
CCTREPAR EQU   CCTIOECB+4         AREA USED FOR WTOR REPLY              11600017
CCTERLST EQU   CCTREPAR+4          AREA FOR IERR MODEL PARAMETER LIST   11670017
CCTDSAVE EQU   CCTASAVE           SAVE AREA USED BY IKDIOR              11790017
CCTPWKAL EQU   CCTPWKAE-CCTPWKA                                         11880017
         EJECT                                                          11970017
*                                                                       12060017
*  REGISTER EQUATES USED                                                12150017
*                                                                       12240017
         SPACE                                                          12330017
RPAR0    EQU   0                       PARAMETER REGISTER 0             12420017
RPAR1    EQU   1                       PARAMETER REGISTER 1             12510017
BASER    EQU   2                       BASE REGISTER                    12600017
CCTR     EQU   3                       CCT BASE REGISTER                12690017
GETR     EQU   4                       POINTER TO GETMAIN               12780017
EXTR     EQU   5                       POINTER TO EXTRACT RECORD        12870017
CSTR     EQU   6                       POINTER TO CST                   12960017
PNTAR    EQU   7                       A POINTER TO EXT DATA SET        13050017
RBAL    EQU    8                                                        13090017
WORKR1   EQU   9                       WORK REG 1                       13140017
RBUFF    EQU   10                                                       13180017
WORKR2   EQU   10                      WORK REG 2                       13230017
WORKR3   EQU   11                      WORK REG 3                       13320017
WORKR4   EQU   12                      WORK REG 4                       13410017
RSAVE    EQU   13                      POINTER TO SAVE AREA             13500017
RRET     EQU   14                      RETURN REGISTER                  13590017
RBR      EQU   15                      BRANCH REGISTER                  13680017
         EJECT                                                          13770017
*                                                                       13860017
*  DSECT LAYOUT OF GETMAIN WORK AREA                                    13950017
*                                                                       14040017
         SPACE                                                          14130017
GETAREA  DSECT                                                          14220017
         USING *,GETR                                                   14310017
GETSTART DS    F                       INDICATOR BYTE AND STORAGE LGT   14400017
SAVE13   DS    F                       SAVE AREA FOR REG.13             14490017
         DS    16F                     ADDRESS OF MY SAVE AREA          14580017
         SPACE                                                          14670017
*  POINTERS FOR CURRENT PROCESSORS AND SYSTEM MASKS AND POINTERS        14760017
         SPACE                                                          14850017
PNTSTRT  EQU   *                                                        14940017
CURRPROC DS    F                       ADDR OF CURRENT PROCESSOR        15030017
CPROCNM  DS    F                       CURRENT PROCESSOR NAME           15120017
PCON     DS    F                       CURRENT PROCESSOR KEY            15210017
CURRTAB  DS    F                       ADDR OF CURRENT PST              15300017
CTABNM   DS    F                       CURRENT TABLE NAME               15390017
TCON     DS    F                       CURRENT TABLE KEY                15480017
IPROCNM  DS    F                       INSERT PROCESSOR NAME            15570017
ICON     DS    F                       INSERT PROCESSOR KEY             15660017
CSMSAVP  DS    C                       COMMAND SELECT MASK PERMAMENT    15750017
CSMSAVD  DS    C                       COMMAND SELECT MASY DYNAMIC      15840017
NMSKSAV  DS    C                       NEXT MASK SAVE                   15930017
ACCREV   DS    C                  ACCEPT REVIEW SWITCH                  15970017
HISTPSAV DS    F                       POINTER TO HISTORY BEING BUILT   16020017
STATBIT  DS    C                       STATUS BITS                      16110017
BCKSW    DS    C            BACKGROUND SWITCH                           16150017
RECCSM   DS    C                       RECALL COMMAND SELECT MASK       16200017
RETSAV   DS    F                       RETURN ADDR SAVE                 16290017
DECHSN   DS    D                       PACKED DECIMAL HSN               16380017
EBDICHSN DS    D                       UNPACKED HSN                     16470017
POINTRA  DS    F                       PNTR TO END OF EXT DATA SET      16560017
HSNSAV   DS    H                       SAVE AREA FOR CURRENT HSN        16650017
KEYSAVE  DS    H                       SAVE AREA FOR EXTRACT KEY        16740017
SVPROCAD DS    F                                                        16830017
PNTEND   EQU   *                                                        16920017
         SPACE                                                          17010017
*  SPACE FOR LIST FORM OF READ MACRO                                    17100017
         SPACE                                                          17190017
READMAC  DS    F                       ECB FOR READ                     17280017
RTYPE    DS    CL2                     TYPE RECORD                      17370017
RLENGTH  DS    CL2                     LENGTH                           17460017
RDCB     DS    F                       DCB ADDR                         17550017
RAREA    DS    F                       AREA ADDR                        17640017
RSTAT    DS    3F                      STATUS                           17730017
         SPACE                                                          17820017
*  SPACE TO READ EXTRACT RECORD INTO                                    17910017
         SPACE                                                          18000017
EXTREC   EQU   *                                                        18090017
OVERLAY  DS    F                       OVERLAY MASK FOR THIS FRAME      18180017
CMDKEY   DS    CL3                     CURRENT COMMAND KEY              18270017
SPOS     DS    C                       SCREEN POSITION                  18360017
DBEF     DS    C                       BEFORE DISPLAY MASK              18450017
DAFT     DS    C                       AFTER DISPLAY MASK               18540017
COMDMSK  DS    C                       COMMAND SELECT MASK              18630017
GJPSTAT  DS    CL2                     GJP STATUS                       18720017
         DS    CL5                     UNUSED                           18810017
HSN      DS    H                       HISTORY SEQUENCE NUM.            18900017
EXTDATA  DS    88F                     EXTRACTED DATA                   18990017
         SPACE                                                          19080017
GETEND   EQU   *                                                        19170017
         EJECT                                                          19260017
*                                                                       19350017
* DSECT FOR I/O BUFFER                                                  19440017
*                                                                       19530017
         SPACE                                                          19620017
BUFFER   DSECT                                                          19710017
         USING *,WORKR1                                                 19800017
RECMASK  DS    CL2            RECALL DISPLAY MASK                       19890017
HISTSEQ  DS    CL3            HISTORY SEQUENCE NUMBER                   20070017
HSTENTRY DS    CL32           HISTORY ENTRY BEING BUILT                 20160017
         SPACE                                                          20340017
*                                                                       20430017
*  DSECT LAYOUT FOR HISTORY TABLES                                      20520017
*                                                                       20610017
         SPACE                                                          20700017
HISTAB   DSECT                                                          20790017
         USING *,WORKR3                                                 20880017
ENTLGTH  DS    H           ENTRY LENGTH                                 20970017
EXTDISP  DS    H           EXTRACT DISPLACEMENT                         21060017
NUMCHAR  DS    H           NUMBER OF CHARACTERS                         21150017
HISTDISP DS    H           HISTORY DISPLACEMENT                         21240017
CON      DS    CL8                     CONSTANT                         21330017
         SPACE                                                          21420017
*                                                                       21510017
*  DSECT LAYOUT FOR COMMAND SELECT TABLE ENTRIES                        21600017
*                                                                       21690017
         SPACE                                                          21780017
COMSTB   DSECT                                                          21870017
         USING *,CSTR                                                   21960017
TENTLGT  DS    C                       ENTRY LENGTH                     22050017
TCSMSK   DS    C                       COMMAND SELECT MASK              22140017
TTXTLGT  DS    C                       TEXT LENGTH                      22230017
         DS    C                       UNUSED                           22320017
TCMDSTAT DS    C                       COMMAND STATUS                   22410017
TNXTMULT DS    C                       POINTER TO NEXT MULTIPLE CHOICE  22500017
TNXTCMD  DS    C                       NEXT AVAILABLE COMMAND           22590017
TINLGT   DS    C                       INPUT DATA LENGTH                22680017
         DS    C                       GRID COLUMNS FOR X               22770017
         DS    C                       GRID LINES FOR Y                 22860017
TINMAP   DS    H                       INPUT MAPPING                    22950017
TKEY     DS    C                       COMMAND KEY                      23040017
         SPACE                                                          23130017
*                                                                       23220017
*  EQUATES USED                                                         23310017
*                                                                       23400017
         SPACE                                                          23490017
SELMODE  EQU   CCTPSTAT+1                                               23580017
IGNORBIT EQU   CCTPSTAT+1                                               23670017
RECMODE  EQU   CCTPSTAT+1                                               23760017
GETLEN   EQU   PNTEND-PNTSTRT                                           23850017
ZERO     EQU   0                                                        23940017
KEY      EQU   0                                                        24030017
ONE      EQU   1                                                        24120017
CHOICE   EQU   1                                                        24210017
TWO      EQU   2                                                        24300017
THREE    EQU   3                                                        24390017
CSMSK    EQU   3                                                        24480017
FOUR     EQU   4                                                        24570017
OKLNTH   EQU   4                                                        24610017
ENDCODE  EQU   4                                                        24660017
WRITCODE EQU   4                                                        24750017
SELLNTH  EQU   4                                                        24840017
PSRLNTH  EQU   6                                                        24930017
FIVE     EQU   5                                                        25020017
NEXTCMD  EQU   5                                                        25110017
SIX      EQU   6                                                        25200017
SEVEN    EQU   7                                                        25240017
EIGHT    EQU   8                                                        25290017
CANCEL   EQU   12                                                       25380017
TWELVE   EQU   12                                                       25420017
HSTENTLN EQU   36                                                       25470017
TWENTY1  EQU   21                                                       25476017
FORTY    EQU   40                                                       25482017
HUNDRED  EQU   100                                                      25488017
TWO51    EQU   251                                                      25494017
TWO68    EQU   268                                                      25500017
SUPLIST  EQU   336                                                      25510017
BFIND    EQU   340                                                      25520017
MOREDATA EQU   350                                                      25530017
HEX00    EQU   X'00'                                                    25560017
OVRLY    EQU   X'01'                                                    25650017
PSTBIT   EQU   X'01'                                                    25740017
HEX01    EQU   X'01'                                                    25830017
ENDON    EQU   X'02'                                                    25920017
RECBIT   EQU   X'02'                                                    26010017
HEX02    EQU   X'02'                                                    26100017
NOXCEPTM EQU   X'03'                                                    26140017
HEX04    EQU   X'04'                                                    26190017
ACCEPT   EQU   X'04'                                                    26280017
XCEPT    EQU   X'04'                                                    26370017
NOXCEPT  EQU   X'04'                                                    26460017
RVIEW    EQU   X'08'                                                    26550017
REVIEW   EQU   X'08'                                                    26640017
NOREV    EQU   X'08'                                                    26730017
INSERT   EQU   X'0C'                                                    26820017
HEX10    EQU X'10'                                                      26860017
OMIT     EQU   X'10'                                                    26910017
RECON    EQU   X'21'                                                    27000017
HEX37    EQU   X'37'                                                    27030017
HEX40    EQU   X'40'                                                    27060017
DCBBIT   EQU   X'40'                                                    27090017
SELTOFF  EQU   X'7F'                                                    27180017
SELTBIT  EQU   X'80'                                                    27270017
JBCRDREQ EQU   X'C0'                                                    27360017
JBLIBCRD EQU   X'CF'                                                    27450017
IGNOROFF EQU   X'DF'                                                    27540017
NOREC    EQU   X'DF'                                                    27630017
XCEPTOFF EQU   X'FB'                                                    27720017
RECOFF   EQU   X'FD'                                                    27810017
HEXFF    EQU   X'FF'                                                    27900017
SLASH    EQU   C'/'                                                     27940017
STATBYT  EQU   STATBIT                                                  27990017
D        EQU   X'C4'                                                    28030017
K        EQU   C'K'                                                     28040017
M        EQU   C'M'                                                     28050017
P        EQU   C'P'                                                     28060017
R        EQU   C'R'                                                     28070017
X        EQU   C'X'                                                     28075017
         EJECT                                                          28080017
IKDPREC0 CSECT                                                          28170017
*                                                                       28260017
*  SAVE REGISTERS AND SET UP BASE REGISTER                              28350017
*                                                                       28440017
         SPACE                                                          28530017
         SAVE  (14,12),,*              SAVE ALL REGISTERS               28620017
         SPACE                                                          28710017
         BALR  BASER,0                 ESTABLISH REG,2 AS BASE          28800017
         USING *,BASER                 USING REG 2                      28890017
         LR    CCTR,RPAR1              LOAD ADDR OF CCT INTO REG.3      28980017
         SPACE                                                          29070017
*                                                                       29160017
*  GET SPACE FOR SAVE AREA AND WORK AREA                                29250017
*                                                                       29340017
         SPACE                                                          29430017
         GETMAIN R,LV=GETEND-GETSTART  GET STORAGE                      29520017
         SPACE                                                          29610017
         LR    GETR,RPAR1              LOAD ADDR OF GETMAIN AREA        29700017
         XC    PNTSTRT(GETLEN),PNTSTRT  ZERO POINTER AREA               29790017
         ST    RPAR1,EIGHT(ZERO,RSAVE) STORE MY SAVE AREA ADDR          29880017
         ST    RSAVE,SAVE13            STORE HIGHER LEVEL SAVE AREA     29970017
         LR    RSAVE,RPAR1             LOAD ADDR OF SAVE AREA           30060017
         MVC   READMAC(RMACLEN),READB  MOVE READ MODEL                  30150017
         SPACE                                                          30240017
*                                                                       30330017
*  SET UP POINTERS TO EXTRACT DCB'S                                     30420017
*                                                                       30510017
         SPACE                                                          30600017
         MVC   RDCB(FOUR),CCTEDCBP     MOVE DCB ADDR                    30690017
         MVC   CCTEDCBP(FOUR),CCTEDCB1 MOVE POINTER TO WRITE DCB        30780017
         MVC   CCTEDCB1(FOUR),RDCB     MOVE POINTER TO READ DCB         30870017
         XI    CCTSSTAT,DCBBIT         TURN DCB INDICATOR OVER          30960017
         LA    EXTR,EXTREC             LOAD ADDR OF EXTRACT RECORD      31050017
         ST    EXTR,RAREA              STORE AREA ADDR IN READ MACRO    31140017
         LA    EXTR,EXTDATA            LOAD ADDR OF EXTRATED DATA       31230017
         OI    RECMODE,RECBIT          TURN ON RECALL MODE              31320017
         SPACE                                                          31410017
*                                                                       31500017
*  GO TO DIARY ROUTINE WITH RECALL KEYWORK                              31590017
*                                                                       31680017
         SPACE                                                          31770017
         MVC   CCTDIAWA+FIVE(SIX),RECALL     MOVE RECALL KEYWORD        31860017
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 31950017
         L     RBR,CCTDIARP            LOAD ADDR OF DIARY ROUTINE       32040017
         BALR  RRET,RBR                BRANCH TO DIARY ROUTINE          32130017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  32160017
         BE    RETURN             IF YES, RETURN                        32190017
         SPACE                                                          32220017
*                                                                       32310017
*  SAVE OLD STATUS BYTES AND INITIATE TO NEW STATUS                     32400017
*                                                                       32490017
         SPACE                                                          32580017
         MVC   CSMSAVP(ONE),CCTCSM     SAVE CURRENT CSM                 32670017
         OI    CCTPSTAT,JBCRDREQ       TURN ON JOB CARD REQ.            32760017
         NI    CCTPSTAT,JBLIBCRD       TURN OFF JOB CARD ENTERED        32850017
         MVI   CCTCSM,HEX01             INITIATE CSM TO AFTER LOGON     32940017
         MVI   CCTDISM,ZERO            INITIALIZE DISPLAY MASK TO ZEROS 33030017
         MVI    CCTADISM,ZERO          INITIALIZE BEFORE DISPLAY MASK   33120017
         MVI   BCKSW,HEX40        INITIAKIZE SWITCH                     33160017
         SPACE                                                          33210017
*                                                                       33300017
*  SET UP POINTERS TO EXTRACT DATA SET                                  33390017
*                                                                       33480017
         SPACE                                                          33570017
         L     RPAR0,CCTEDCB1          LOAD ADDR OF EXTRACT DCB FOR RD  33660017
         NOTE  (RPAR0)                 NOTE LOCATION OF LAST WRITE      33750017
         SPACE                                                          33840017
         LR    PNTAR,RPAR1             LOAD RETURNED ADDR               33930017
         C     PNTAR,ZEROS             IS A EQUAL TO ZERO               34020017
         BE    MVENOTE                 YES GO TO MOVE CCTENOTE          34110017
         A     PNTAR,ZERONE            ADD ONE TO POINTER A             34200017
         B     LDEDCB                  GO TO LOAD POINTER TO EXT DCB    34290017
         SPACE                                                          34380017
MVENOTE  L     PNTAR,CCTENOTE          LOAD ADDR OF LAST WRITE          34470017
LDEDCB   L     RPAR1,CCTEDCB1          LOAD ADDR OF EXTRACT DCB FOR RD  34560017
         POINT (RPAR1),ZERONE          POINT EXT DATA SET               34650017
         SPACE                                                          34740017
         L     RPAR1,CCTEDCBP          LOAD ADDR OF EXT DCB FOR WRITE   34830017
         POINT (RPAR1),ZERONE                                           34920017
         SPACE                                                          35010017
*                                                                       35100017
*  INITIALIZE JCL DATA SET TO WRITE AT ZERO ONE                         35190017
*                                                                       35280017
         SPACE                                                          35370017
         L     RPAR1,CCTJDCBP          LOAD ADDR OF JCL DCB             35460017
         POINT (RPAR1),ZERONE                                           35550017
         SPACE                                                          35640017
         ST    PNTAR,POINTRA           STORE POINTERS TO EXT DATA SET   35730017
         SPACE                                                          35820017
*                                                                       35910017
*  INITIALIZE PROCESSOR AND TABLE NAME CONSTANTS                        36000017
*                                                                       36090017
         SPACE                                                          36180017
         MVC   CPROCNM(EIGHT),PROCCON  MOVE PROC CONSTANT               36270017
         MVC   CTABNM(EIGHT),TABCON  MOVE TABLE CONSTANT                36360017
         MVC   IPROCNM(EIGHT),PROCCON  MOVE PROC CONSTANT               36450017
         SPACE                                                          36540017
*                                                                       36630017
*  GO TO READ FIRST EXTRACT RECORD                                      36720017
*                                                                       36810017
         SPACE                                                          36900017
TORDEXT  TM    STATBYT,ENDON           HAVE ALL RECORDS BEEN READ       36990017
         BO    EXIT                    YES GO TO EXIT                   37080017
         BAL   RRET,READEXT            BRANCH TO READ ROUTINE           37170017
*                                                                       37260017
* SCAN CSTABLE FOR ENTRIES                                              37350017
*                                                                       37440017
         SPACE                                                          37530017
SAVECSM  MVC   CSMSAVD(ONE),CCTCSM  SAVE DYNAMIC CSM                    37620017
         LA    CSTR,CSTABLE         LOAD ADDRESS OF CSTABLE             37710017
TSTENTRY CLC   ZERO(THREE,EXTR),KEY(CSTR)  ARE KEYS EQUAL               37800017
         BE    TSTBEG         YES, GO TO TEST IF BEGIN PROCEDURE        37890017
         LA    CSTR,SIX(CSTR)                                           37980017
         B     TSTENTRY             GO TO TEST NEXT ENTRY               38070017
         SPACE                                                          38160017
*                                                                       38250017
*  TEST FOR ENTRY ALLOWED NOW                                           38340017
*                                                                       38430017
         SPACE                                                          38520017
TSTBEG   CLC   ZERO(FIVE,EXTR),BEGP  IS THIS BEGIN PROCEDURE            38540017
         BNE   TSTCSMD             IF NOT, TEST COMMAND SELECT MASK     38560017
         LA    CSTR,SIX(CSTR)     SET POINTER TO PROCEDURE ENTRY        38580017
TSTCSMD  SR    RPAR1,RPAR1          ZERO REGISTER ONE                   38610017
         IC    RPAR1,CSMSK(CSTR)    INSERT COMMAND SELECT MASK          38700017
         EX    RPAR1,MSKTST             EXECUTE TEST INSTRUCTION        38790017
         BZ    NOTALWD                  ZEROS ENTRY NOT ALLOWED         38880017
         SPACE                                                          38970017
         SR    WORKR1,WORKR1           ZERO WORK REG                    39060017
         IC    WORKR1,COMDMSK          INSERT COMMAND MASK FROF EXT REC 39150017
         EX    WORKR1,MSKTST           EXECUTE TEST INSTRUCTION         39240017
         BO    ALOWALL                 ONES ALL OPTIONS ALLOWED         39330017
         CLI   COMDMSK,RECON           WAS RECALL DISPLAYED             39420017
         BE    ALOWALL                 YES ALLOW ALL APTIONS            39510017
         SPACE                                                          39600017
NOACCEPT MVI   RECCSM,NOXCEPT          MAKE RECALL SELECT MASK A HEX 4  39690017
         OI    STATBYT,RVIEW           TURN ON REVIEW BIT               39780017
         B     SAVMSK                  GO TO SAVE CMD MSK               39870017
         SPACE                                                          39960017
ALOWALL  CLC   ZERO(THREE,EXTR),CONBEG  IS IT A BEGIN JOB OR PROC       40050017
         BE    NOREVIEW                YES DO NOT ALLOW REVIEW          40140017
         OI    STATBYT,XCEPT           TURN ON ACCEPT BIT IN RECAL STAT 40230017
         OI    CCTPSTAT,XCEPT          TURN ON ACCEPT BIT IN PROC STAT  40320017
         MVI   RECCSM,HEX01            SET ON ALL OPTIONS               40410017
SAVMSK   MVC   NMSKSAV(ONE),NEXTCMD(CSTR)  SAVE NEXT AVAILABLE CMD MASK 40500017
         B     MOVEMASK           BRANCH TO PUT MASK IN BUFFER          40590017
         SPACE                                                          40680017
NOREVIEW MVI   RECCSM,NOREV            MAKE RECALL SELECT MASK A HEX 8  40770017
         OI    STATBYT,XCEPT                                            40860017
         B     MOVEMASK            BRANCH TO PUT MASK IN BUFFER         40950017
         SPACE                                                          41040017
MSKTST   TM    CCTCSM,HEX00            TEST FOR ENTRY ALLOWED           41130017
         SPACE                                                          41220017
NOTALWD  MVI   RECCSM,HEX02            SET ON OMIT OR INSERT ONLY       41310017
MOVEMASK OI    SELMODE,SELTBIT     TURN ON COMMAND MODE                 41400017
         MVC   CCTCSM(ONE),RECCSM      MOVE RECALL SELECT MASK          41490017
         OI    SELMODE,SELTBIT         TURN ON COMMAND MODE             41580017
         TM    TCMDSTAT,PSTBIT         DOES CURRENT PROC HAVE A PST     41670017
         BO    CONT                IF ON, BRANCH                        41760017
         OI    STATBYT,PSTBIT          TURN ON PST BIT                  41850017
         SPACE                                                          41940017
CONT     MVC   CCTCSM(ONE),CSMSAVD     RESTORE COMMAND SELECT MASK      42030017
*                                                                       42120017
* BUILD HISTORY ENTRY IN BUFFER                                         42210017
*                                                                       42300017
         L     WORKR1,CCTBUFFP     LOAD ADDRESS OF BUFFER               42390017
         MVI   ZERO(WORKR1),HEX40   BLANK FORTY BYTES OF BUFFER         42460017
         MVC   ONE(FORTY,WORKR1),ZERO(WORKR1)                           42530017
         MVI   RECMASK,HEX00        CLEAR RECALL MASK AREA IN BUFFER    42600017
         MVC   RECMASK+ONE(ONE),RECCSM  PUT MASK IN BUFFER              42670017
         MVC   HISTSEQ(THREE),EBDICHSN+FIVE  MOVE HSN                   42740017
         LA    WORKR3,PNTDISTB   LOAD ADDR OF POINTER TO DISP TAB       42840017
         MVC   KEYSAVE(THREE),ZERO(EXTR) SAVE EXTRACT KEY               42930017
         CLC   KEYSAVE(THREE),CONBEG    IS KEY A BEG                    43020017
         BE    TSTYPE                   YES, GO TO TEST TYPE            43110017
COMPENTY CLI   ZERO(WORKR3),HEXFF  IS THIS END OF LIST                  43200017
         BE    KEYERR              IF YES, BRANCH                       43290017
         CLC   KEYSAVE(THREE),ZERO(WORKR3)  IS THIS THE ENTRY           43380017
         BE    LDTABLE             IF YES, BRANCH                       43470017
         LA    WORKR3,EIGHT(WORKR3)    ADD 8 TO GO TO NEXT ENTRY        43560017
         B     COMPENTY                TEST NEXT ENTRY                  43650017
         SPACE                                                          43740017
TSTYPE   CLI   FOUR(EXTR),SLASH   IS FIFTH CHARACTER A SLASH            43830017
         BE    MOVEP                    YES GO MOVE A P                 43920017
         B     COMPENTY            BRANCH TO COMPLETE ENTRY             43990017
MOVEP    MVI   KEYSAVE+TWO,P       PUT P INTO KEYSAVE                   44060017
         MVI   RECMASK+ONE,X'0C'   PUT BEGIN PROC CODE IN BUFFER        44140017
         B     COMPENTY            BRANCH TO COMPLETE ENTRY             44210017
         SPACE                                                          44280017
LDTABLE  L     WORKR3,FOUR(WORKR3)      LOAD ADDRESS OF TABLE           44370017
         LA    RPAR1,HSTENTRY      GET ADDRESS OF HISTORY BEING BUILT   44460017
         ST    RPAR1,HISTPSAV      STORE ADDRESS OF HISTORY ENTRY       44550017
TSTEND   CLC   ENTLGTH(TWO),ONES        END OF TABLE                    44640017
         BE    TODIOR              GO TO I/O ROUTINE                    44730017
         L     RPAR1,HISTPSAV           LOAD ADDRESS OF HISTORY         44820017
         CLC   EXTDISP(TWO),ZEROS      ENTRY IN EXTRACT RECORD          44910017
         BE    ADDNXT              BRANCH TO ADD DISPLACEMENT           45000017
         LH    WORKR1,EXTDISP          LOAD EXTRACT DISPLACEMENT        45090017
         AR    WORKR1,EXTR             ADD BEGINNING OF EXTRACT RECORD  45180017
         AH    RPAR1,HISTDISP          ADD HISTORY DISPLACEMENT         45270017
         LH    WORKR2,NUMCHAR          GET # OF CHARACTERS TO MOVE      45360017
         EX    WORKR2,MOVE1                                             45450017
         AH    WORKR3,ENTLGTH          MOVE TO NEXT ENTRY               45540017
         B     TSTEND              GO CHECK FOR END                     45630017
         SPACE                                                          45720017
MOVE1    MVC   ZERO(ZERO,RPAR1),ZERO(WORKR1)                            45810017
MOVE2    MVC   ZERO(ZERO,RPAR1),CON                                     45900017
         SPACE                                                          45990017
ADDNXT   AH    RPAR1,HISTDISP          ADD DISPLACEMENT TO BEGIN OF HST 46080017
         LH    WORKR2,NUMCHAR          GET NUMBER OF CHAR TO MOVE       46170017
         EX    WORKR2,MOVE2                                             46260017
         AH    WORKR3,ENTLGTH          MOVE TO NEXT ENTRY               46350017
         B     TSTEND                  GO TO TEST END                   46440017
*                                                                       46530017
* HISTORY ENTRY HAS BEEN BUILT.  NO GO TO IKDIOR TO TRANSMIT TO 1130    46620017
*                                                                       46710017
TODIOR   LA    RPAR1,HSTENTLN                                           46800017
         ST    RPAR1,CCTRECLN     SET LENGTH OF DATA TO BE TRANSMITTED  46890017
         LA    RPAR0,WRITCODE     SET I/O CODE TO WRITE                 46980017
         LR    RPAR1,CCTR         SET POINTER TO CCT                    47020017
         L     RBR,CCTIORP        GET ADDRESS OF IKDIOR                 47070017
         BALR  RRET,RBR       GO TO I/O ROUTINE                         47160017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  47190017
         BE    RETURN             IF YES, RETURN                        47220017
*                                                                       47250017
*  DELETE CURRENT PROCESSOR IF ANY AND LOAD DEFAULT PROCESSOR*          47340017
*                                                                       47430017
LDPROC   CLC   CURRPROC(FOUR),ZEROS    IS THERE A PROCESSOR PRESENT     47520017
         BE    LOADDFLT                NO GO TO LOAD DEFAULT            47610017
         LA    RPAR1,CPROCNM           LOAD ADDR OF CURRENT PROCESSOR   47700017
         DELETE EPLOC=(RPAR1)          DELETE CURRENT PROCESSOR         47790017
         SPACE                                                          47880017
         XC    CURRPROC(FOUR),CURRPROC ZERO POINTER TO CURRENT PROC     47970017
LOADDFLT TM    STATBYT,XCEPT+RVIEW     IS REVIEW AND ACCEPT DISPLAYED   48060017
         BZ    DELPST                  NO GO TO DELETE CURRENT PST      48150017
         CLC   ZERO(THREE,EXTR),CONBEG  IS PROCESSOR BEGIN JOB          48240017
         BE    DELPST                  YES GO TO DELETE CURRENT PST     48330017
         MVC   PCON(THREE),ZERO(EXTR)  MOVE KEY TO CONSTANT             48420017
         SPACE                                                          48510017
         LOAD  EPLOC=CPROCNM                                            48600017
         ST    RPAR0,CURRPROC          STORE ADDR OF CURRENT PROCESSOR  48690017
*                                                                       48780017
*  DELETE CURRENT PARAMETER SELECT TABLE IF ANY AND LOAD DEFAULT        48870017
*                                                                       48960017
         SPACE                                                          49050017
DELPST   CLC   CURRTAB(FOUR),ZEROS                                      49140017
         BE    TSTFRPST            GO CHECK FOR A PST                   49230017
         SPACE                                                          49320017
         DELETE  EPLOC=CTABNM          DELETE CURRENT PST               49410017
         SPACE                                                          49500017
         XC    CURRTAB(FOUR),CURRTAB   ZERO POINTER TO CURRENT PST      49590017
TSTFRPST TM    STATBYT,PSTBIT          DOES CURR PROC HAVE A PST        49680017
         BZ    TRNIGNOF                NO GO TO TURN IGNORE ATTN OFF    49770017
         MVC   TCON(THREE),ZERO(EXTR)  MOVE KEY TO TABLE CONSTANT       49860017
         SPACE                                                          49950017
         LOAD  EPLOC=CTABNM            LOAD DEFAULT TABLE               50040017
         SPACE                                                          50130017
         ST    RPAR0,CURRTAB           STORE ADDR OF CURRENT PST        50220017
TRNIGNOF NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         50310017
         SPACE                                                          50400017
*                                                                       50490017
* POINTERS TO PROCESSOR AND PST HAVE BEEN SET IP.  NOW GO TO IKDIOR TO  50580017
* GET USERS CHOICE FROM RECALL FRAME.                                   50670017
RDCHOICE LA    RPAR1,SELLNTH                                            50760017
         ST    RPAR1,CCTRECLN      PUT DATA LENGTH IN CCT               50850017
         SR    RPAR0,RPAR0         SET CODE FOR A READ=0                50940017
         L     RBR,CCTIORP         GET POINTER TO I/O ROUTINE           51030017
         LR    RPAR1,CCTR          SET POINTER TO CCT                   51120017
         BALR  RRET,RBR            GO TO I/O ROUTINE                    51210017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  51240017
         BE    RETURN             IF YES, RETURN                        51270017
         L     WORKR4,CCTBUFFP     GET ADDRESS                          51300017
         CLI   CHOICE(WORKR4),INSERT WAS OPTION INSERT                  51390017
         BE    RSTCST              YES                                  51480017
         NI    SELMODE,SELTOFF   TURN COMMAND SELECT MODE OFF           51570017
         CLI   CHOICE(WORKR4),REVIEW  WAS OPTION REVIEW                 51660017
         BE    LOADPST             YES, GO LOAD PST                     51750017
         CLI   CHOICE(WORKR4),OMIT  WAS OPTION OMIT                     51840017
         BE    SETOFF              YES, GO SET ACCEPT OFF               51930017
         B     TSTPST              OPTION WAS ACCEPT. GO TEST FOR PST   52020017
SETOFF   NI    STATBYT,HEXFF-RVIEW-XCEPT-PSTBIT  TURN OFF STATUS BITS   52110017
         NI    CCTPSTAT,XCEPTOFF       TURN OF ACCEPT BIT FOR PROC'S    52200017
         B     TORDEXT                 GO TO READ NEXT EXTRACT RECORD   52290017
         EJECT                                                          52380017
**********************************************************************  52470017
*                                                                       52560017
*  OPTION WAS INSERT RESTORE POINTERS AND GENERATE A SELECT FRAME       52650017
*                                                                       52740017
**********************************************************************  52830017
         SPACE                                                          52920017
RSTCST   NI    CCTCSM,NOREC        ZERO RECALL BIT IN CCT               53010017
         MVC   HSNSAV(TWO),CCTHSN+TWO  SAVE CURRENT HSN                 53060017
         L     RPAR1,CCTHSN       GET HISTORY SEQUENCE NUMBER           53120017
         LA    RPAR1,ONE(RPAR1)    INCREMENT BY ONE                     53140017
         STH   RPAR1,CCTHSN+TWO    RESTORE IN CCT                       53160017
*                                                                       53190017
* GET PROCESSOR SELECT RECORD FROM THE 1130                             53280017
*                                                                       53370017
         SR    RPAR0,RPAR0         SET I/O CODE FOR READ=0              53460017
         LA    RPAR1,TWELVE       SET READ LENGTH TO TWELVE             53550017
         ST    RPAR1,CCTRECLN      PUT IN CCT                           53640017
         L     RBR,CCTIORP         GET ADDRESS OF I/O ROUTINE           53730017
         LR    RPAR1,CCTR          GET POINTER TO CCT                   53820017
         BALR  RRET,RBR            GO TO I/O ROUTINE                    53910017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  53940017
         BE    RETURN             IF YES, RETURN                        53970017
* CHECK FOR CANCEL OF COMMAND SELECT FRAME.  IF FRAME WAS CANCELLED     54000017
* GO READ ANOTHER RECORD TO DETERMINE USER'S CHOICE.                    54090017
*                                                                       54180017
         CLC   CCTCCR(THREE),CANREC  DID USER CANCEL SELECT FRAME       54270017
         BE    RDCHOICE            BRANCH TO GET ANOTHER EXTRACT RECORD 54360017
         SPACE                                                          54450017
         NI    SELMODE,SELTOFF       TURN COMMAND SELECT BIT OFF        54540017
*                                                                       54630017
* MOVE THE CCTCCR INTO THE AREA USED FOR LOADING THE PROCESSOR          54720017
*                                                                       54810017
GETPROC  MVC   ICON(THREE),CCTCCR    PUT KEY IN INSERT PROC CONSTANT    54900017
         CLC   CCTCCR(THREE),CONBEG  IS KEY BEG                         54990017
         BE    BEGINJOB             YES  BRANCH TO BEGIN JOB            55080017
         CLC   CCTCCR(THREE),LOF   IS PSR FOR LOGOFF                    55090017
         BNE   LOADPROC           IF NOT, BRANCH                        55100017
         MVI   IPROCNM+TWO,D      PUT A D IN PROCESSOR NAME             55110017
         B     RPTFRM             BRANCH TO GET EXTRACR RECORD          55115017
LOADPROC EQU   *                                                        55120017
         LA    WORKR1,IPROCNM       GET ADDRESS OF PROCESSOR NAME       55170017
         SPACE                                                          55260017
         LOAD  EPLOC=(WORKR1)       LOAD SELECTED PROCESSOR             55350017
         SPACE                                                          55440017
         ST    RPAR0,SVPROCAD                                           55530017
         XC    CCTPECB(FOUR),CCTPECB   CLEAR PROCESSOR ECB              55620017
         CLC   CCTCCR(THREE),CONCAN   WAS SELECTION CANCEL JOB          55650017
         BE    TOPROC       IF SO, BRANCH                               55680017
*                                                                       55710017
* GO TO IKDIOR TO GET EXTRACT RECORD                                    55800017
*                                                                       55890017
RPTFRM   LA    RPAR1,CCTPWKAL                                           55980017
         LA    RPAR1,TWO(RPAR1)    INCREMENT BY TWO                     56070017
         ST    RPAR1,CCTRECLN        SET LENGTH OF DATA TO BE TRANSMTED 56160017
         LR    RPAR1,CCTR            SET POINTER TO CCT                 56250017
         L     RBR,CCTIORP           GET ADDRESS OF I/O ROUTINE         56340017
         SR    RPAR0,RPAR0           SET CODE TO READ=0                 56430017
         BALR  RRET,RBR              GO TO I/O ROUTINE                  56520017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  56523017
         BE    RETURN             IF YES, RETURN                        56526017
         CLC   CCTCCR(THREE),LOF   IS PROCESSOR LOGOFF                  56529017
         BNE   TOPROC             IF NOT BRANCH                         56538017
         LR    RPAR1,CCTR         SET POINTER TO CCT                    56547017
         LA    RBR,CCTPWKA+SUPLIST  LOAD ADDR OF PARM LIST              56556017
         MVI   ZERO(RBR),HEX00    CLEAR AREA                            56565017
         MVC   ONE(SEVEN,RBR),ZERO(RBR)                                 56574017
         LA    RBAL,IPROCNM       SET POINTER TO MODULE NAME            56583017
         LINK  EPLOC=(RBAL),MF=(E,(1)),SF=(E,(15))  LINK TO PROCESSOR   56592017
         B     CODES              BRANCH TO CHECK RETURN CODES          56601017
*                                                                       56610017
* BRANCH TO PROCESSOR TO PROCESS INPUT                                  56700017
*                                                                       56790017
TOPROC   LR    RPAR1,CCTR                                               56880017
         NI    CCTPSTAT,XCEPTOFF       TURN OF ACCEPT BIT FOR PROC'S    56970017
         NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         57060017
         L     RBR,SVPROCAD       GET PROCESSOR ADDRESS                 57150017
         BALR  RRET,RBR           GO TO PROCESSOR                       57240017
         SPACE                                                          57330017
*                                                                       57420017
*  ANALIZE RETURN CODE TO DETERMINE NEXT STEP                           57510017
*                                                                       57600017
CODES    EQU   *                                                        57640017
         SPACE                                                          57690017
         MVC   CCTADISM(ONE),CCTDISM   MOVE AFTER DISPLAY MASK          57780017
         CH    RBR,CONC                WAS RETURN CODE CANCEL           57870017
         BE    HSNRST              BRANCH TO RESET HSN                  57960017
         CH    RBR,ZEROS               WAS RETURN CODE ZERO             58050017
         BE    UPDCSM                  YES GO TO UPDATE CCTCSM          58140017
         CH    RBR,CON4                WAS RETURN CODE FOUR             58230017
         BE    WRITRPT             GO TO WRITE OK AND GET ANOTHER RCD   58320017
         CH    RBR,CON8                WAS RETURN CODE EIGHT            58410017
         BE    RETURN                  YES RETURN TO IKACTL             58500017
         CH    RBR,CON10               WAS RETURN CODE HEX TEN          58590017
         BE    RETURN                  YES RETURN TO IKACTL             58680017
         CH    RBR,CON14               WAS RETURN CODE HEX 14           58770017
         BE    TESTM              BRANCH TO CHECK FOR END KEY FUNCTION  58810017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  58850017
         BE    RETURN             IF YES, RETURN                        58890017
         B     ERROR                   NO INVALID RETURN CODE ERROR     58950017
         SPACE                                                          59040017
HSNRST   EQU   *                                                        59050017
         LA    WORKR1,IPROCNM   GET ADDRESS OF PROC NAME                59060017
         DELETE  EPLOC=(WORKR1)  DELETE                                 59070017
         CLI   CCTSTAT+TWO,M  WAS END PERFORMED                         59080017
         BNE   RESETHSN           IF NOT, RESTORE HSN                   59100017
         MVI   CCTSTAT+TWO,HEX00    ZERO M SWITCH                       59110017
         BAL   RBAL,WRITOK        GO WRITE OK MEASAGE                   59130017
         B     MOVEMASK           GO TO PREPARE SAME CURRENT ITEM       59160017
RESETHSN MVC   CCTHSN+TWO(TWO),HSNSAV  RESTORE OLD HSN                  59190017
         B     MOVEMASK            GO MOVE MASK                         59250017
TESTM    CLI   CCTSTAT+TWO,M       WAS END KEY PERFORMED                59254017
         BNE   MOVEMASK           IF NOT, BRANCH                        59258017
         L     RBAL,CCTBUFFP      GET BUFFER ADDRESS                    59262017
         MVC   ZERO(SIX,RBAL),JOBLIB  PUT JOBLIB MSG INTO BUFFER        59266017
         LA    RPAR0,SIX          SET MESSAGE LENGTH                    59270017
         ST    RPAR0,CCTRECLN     IN CCT                                59274017
         LA    RPAR0,FOUR         SET CODE TO WRITE                     59278017
         BAL   RBAL,WRITJBLB      GO TO WRITE MESSAGE                   59282017
         MVI   CCTSTAT+TWO,HEX00    ZERO M SWITCH                       59286017
         LA    WORKR1,IPROCNM     GET ADDRESS OF PROCESSOR NAME         59290017
         DELETE  EPLOC=(WORKR1)    DELETE PROCESSOR                     59294017
         B     MOVEMASK           BRANCH TO MOVEMASK                    59298017
*                                                                       59310017
*  UPDATE NEXT AVAILABLE COMMAND MASK                                   59400017
*                                                                       59490017
         SPACE                                                          59580017
UPDCSM   LA    WORKR1,IPROCNM     GET ADDRESS OF PROCESSOR NAME         59590017
         DELETE EPLOC=(WORKR1)    DELETE THIS PROCESSOR                 59600017
         CLC   CCTCCR(THREE),CONCAN   WAS PROCESSOR CANCEL JOB          59610017
         BE    SETINMSK     IF YES BRANCH                               59640017
         BAL   RBAL,WRITOK                                              59670017
         LA    CSTR,CSTABLE        LOAD ADDRESS OF COMD SELET TABLE     59700017
COMPEND  CLC   CCTCCR(THREE),KEY(CSTR)  IS THIS ENTRY JUST SELECTED     59760017
         BE    MVMSK                    YES, GO MOVE NEW SELECT MASK    59850017
         LA    CSTR,SIX(CSTR)           SET POINTER TO NEXT ENTRY       59940017
         B     COMPEND             RESCAN TABLE                         60030017
         SPACE                                                          60120017
MVMSK    MVC   CCTCSM,NEXTCMD(CSTR)     SET NEW COMMAND SELECT MASK     60210017
         NI    STATBYT,XCEPTOFF         TURN OFF ACCEPT BIT             60480017
         B     SAVECSM             BRANCH TO SAVE CSM                   60540017
WRITRPT  BAL   RBAL,WRITOK         GO TO WRITE OK                       60600017
         L     WORKR1,CCTHSN      GET HSN                               60607017
         LA    WORKR1,ONE(WORKR1)   INCREMENT BY ONE                    60614017
         STH   WORKR1,CCTHSN+TWO  RESTORE IN CCT                        60621017
         B     RPTFRM              BRANCH TO GET ANOTHER EXTRACT RECORD 60630017
SETINMSK MVI   CCTCSM,HEX01       SET MASK TO AFTER LOGON               60640017
         B     RETURN             BRANCH TO RETURN                      60650017
         EJECT                                                          60660017
**********************************************************************  60750017
*                                                                       60840017
*  OPTION WAS ACCEPT IF THERE IS NO PST FOR THIS PROCESSOR BRANCH TO IT 60930017
*                                                                       61020017
**********************************************************************  61110017
         SPACE                                                          61200017
TSTPST   MVI   CCTPWKA,HEX40       BLANK WKA                            61300017
         MVC   CCTPWKA+ONE(TWO51),CCTPWKA                               61400017
         MVC   CCTPWKA+TWO51(HUNDRED),CCTPWKA                           61500017
         MVC   CCTPWKA(THREE),ZERO(EXTR)     MOVE KEY TO WORK AREA      61830017
         MVC   CCTCCR(THREE),ZERO(EXTR)    PUT KEY INTO CCTCCR          61840017
         TM    STATBYT,PSTBIT      DOES CURRENT PROC HAVE A PST         61850017
         BZ    TSTBEGIN           NO, GO TEST FOR BEGIN PROCEDURE       61870017
         L     CSTR,CURRTAB       LOAD CURRENT PST ADDRESS              61890017
         SPACE                                                          61920017
*                                                                       62010017
*  MOVE FIELDS WHICH CONTAIN DATA TO PROCESSOR WORK AREA                62100017
*                                                                       62190017
         SPACE                                                          62280017
         LA    WORKR4,CCTPWKA                                           62370017
         SR    WORKR3,WORKR3           ZERO WORK REG                    62460017
TABEND   CLC   TENTLGT(TWO),ZEROS      IS THIS END IF TABLE             62550017
         BE    POSTPROC                YES GO TO POST PROCESSOR         62640017
         TM    TINLGT,HEXFF            DOES THIS ENTRY HAVE INPUT DATA  62730017
         BZ    NEXTENT                 NO GO TO NEXT ENTRY              62820017
         LH    WORKR2,TINMAP           LOAD INPUT MAPPING               62910017
         LR    RPAR1,WORKR2            LOAD INPUT MAPPING TO PARM REG   63000017
         AR    WORKR2,EXTR             ADD BEGINNING OF EXT RECORD      63090017
         TM    ZERO(WORKR2),HEX37   IS THIS END DELIMITER               63180017
         BO    NEXTENT                 YES GO TO NEXT ENTRY             63270017
         AR    RPAR1,WORKR4            ADD BEGINNING OF WORK AREA       63360017
         IC    WORKR3,TINLGT           INSERT INPUT DATA LENGTH         63450017
         BCT   WORKR3,NEXT             SUBTRACT ONE FROM INPUT LENGTH   63540017
NEXT     EX    WORKR3,MVDATA           EXECUTE MOVE DATA FIELDS         63630017
         SPACE                                                          63720017
NEXTENT  IC    WORKR3,TENTLGT          INSERT EXTRY LENGTH              63810017
         AR    CSTR,WORKR3             ADD ENTRY LENGTH TO MOVE TO NEXT 63900017
         B     TABEND                  GO TO TEST FOR END OF TABLE      63990017
         SPACE                                                          64080017
MVDATA   MVC   ZERO(ZERO,RPAR1),ZERO(WORKR2) MOVE FIELDS TO EXT RECORD  64170017
         SPACE                                                          64260017
TSTBEGIN CLC   ZERO(FIVE,EXTR),BEGP    IS IT A BEGIN PROCEDURE          64350017
         BNE   POSTPROC                NO GO POST PROCESSOR             64440017
         MVC   CCTPWKA+TWO68(EIGHT),TWENTY1(EXTR)  PUT PROC NM IN WKA   64500017
         MVC   CCTPWKA(FIVE),BEGP  PUT PROCEDURE KEY INTO CCT           64560017
         SPACE                                                          64620017
*                                                                       64710017
*  POST PROCESSOR INCREMENT HSN AND BRANCH TO PROCESSOR                 64800017
*                                                                       64890017
         SPACE                                                          64980017
POSTPROC POST  CCTPECB,4           POST ECB WITH END CODE               65070017
         CLC   CCTPWKA(THREE),ENT  IS PROCESSOR ENTER DATA              65080017
         BNE   SKIPNSI             IF NOT, BRANCH                       65090017
         MVI   CCTPWKA+MOREDATA,HEX40   BLANK MORE DATA FOLLOWS SWITCH  65100017
SKIPNSI  EQU   *                                                        65110017
         OI    CCTPSTAT,XCEPT      TURN ON ACCEPT BIT                   65120017
         SPACE                                                          65160017
INCHSN   LH    WORKR1,CCTHSN+TWO       LOAD HISTORY SEQ. NUM.           65250017
         STH   WORKR1,HSNSAV           SAVE CURRENT HSN                 65340017
         LA    WORKR1,ONE(WORKR1)      ADD ONE                          65430017
         STH   WORKR1,CCTHSN+TWO       STORE HISTORY SEQ. NUM.          65520017
         SPACE                                                          65610017
         CLC   ZERO(THREE,EXTR),CONBEG  IS PROCESSOR BEGIN JOB          65700017
         BE    BEGINJOB                YES BRANCH TO BEGIN JOB          65790017
         L     RBR,CURRPROC            LOAD ADDR OF CURRENT PROCESSOR   65880017
         LR    RPAR1,CCTR              LOAD ADDR OF CCT                 65970017
         BALR  RRET,RBR                BRANCH TO PROCESSOR              66060017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  66063017
         BE    RETURN             IF YES, RETURN                        66066017
*                                                                       66069017
* DETERMINE IF RETURN IS FROM ACCEPT OR REVIEW OPTION                   66078017
*                                                                       66087017
         CLI   ACCREV,R            WAS REVIEW SELECTED                  66096017
         BNE   TEST               IF NOT, BRANCH                        66105017
         MVI   ACCREV,HEX40        BLANK ACC/REV SWITCH                 66114017
         CH    RBR,CON4           WAS RETURN CODE ZERO OR FOUR          66123017
         BH    TEST               IF NOT, BRANCH                        66132017
         BAL   RBAL,WRITOK        GO TO WRITE EXOK MESSAGE              66141017
         SPACE                                                          66150017
*                                                                       66240017
*  TEST RETURN CODE IF EIGHT RETURN TO CALLER  IF TWELVE REDISPLAY      66330017
*   RECALL FRAME                                                        66420017
*                                                                       66510017
         SPACE                                                          66600017
TEST     EQU   *                                                        66640017
         MVC   CCTADISM(ONE),CCTDISM   MOVE AFTER DISPLAY MASK          66690017
         CH    RBR,CON8                IS RETURN CODE EIGHT             66780017
         BE    RETURN                  YES GO TO RETURN                 66870017
         CH    RBR,CONC                IS RETURN CODE TWELVE            66960017
         BE    RSTHSN                  YES GO TO RESTORE CURRENT HSN    67050017
         CH    RBR,CON14               WAS RETURN CODE HEX 14           67140017
         BE    WJOBLIB         BRANCH TO WRITE JOBLIB MESSAGE           67230017
         CH    RBR,CON18               WAS RETURN CODE HEX 18           67320017
         BE    DISPMSG                 YES GO DISPLAY ERROR MSG         67410017
         MVC   CCTCSM(ONE),NMSKSAV     UPDATE COMMAND SELECT MASK       67500017
MOVCCTCR MVC   CCTCCR(THREE),ZERO(EXTR)   MOVE CURRENT COMMAND KEY      67590017
         NI    STATBYT,HEXFF-RVIEW-XCEPT-PSTBIT  TURN OFF STATUS BITS   67680017
         NI    CCTPSTAT,XCEPTOFF       TURN OF ACCEPT BIT FOR PROC'S    67770017
         B     TORDEXT                 GO TO READ NEXT EXTRACT RECORD   67860017
WJOBLIB  EQU   *                                                        67870017
         L     RBAL,CCTBUFFP      GET BUFFER ADDRESS                    67880017
         MVC   ZERO(SIX,RBAL),JOBLIB  PUT JOBLIB MSG INTO BUFFER        67890017
         LA    RPAR0,SIX          SET MESSAGE LENGTH                    67900017
         ST    RPAR0,CCTRECLN     IN CCT                                67910017
         LA    RPAR0,FOUR         SET CODE TO WRITE                     67920017
         BAL   RBAL,WRITJBLB      GO TO WRITE MESSAGE                   67930017
         B     MOVCCTCR         BRANCH TO MOVE KEY                      67940017
         SPACE                                                          67950017
RSTHSN   MVC   CCTHSN+TWO(TWO),HSNSAV  RESTORE OLD HSN                  68040017
         B     RDCHOICE           BRANCH TO READ CHOICE                 68130017
         SPACE                                                          68220017
BEGINJOB LA    RBR,FIVE                LOAD RETURN OF FIVE              68310017
         B     RETURN                  BRANCH TO RETURN                 68400017
         SPACE                                                          68490017
DISPMSG  OI    STATBYT,RVIEW       TURN ON REVIEW BIT                   68580017
         MVI   RECCSM,NOXCEPTM  MOVE NO ACCEPT/MSG MASK                 68620017
         LH    WORKR1,HSNSAV                                            68660017
         STH   WORKR1,CCTHSN+TWO    RESTORE OLD HSN                     68700017
         NI    STATBYT,XCEPTOFF        TURN OFF ACCEPT BIT              68760017
         NI    CCTPSTAT,XCEPTOFF       TURN OF ACCEPT BIT FOR PROC'S    68850017
         B     MOVEMASK            GO MOVE REC MASK                     68940017
         EJECT                                                          69030017
**********************************************************************  69120017
*                                                                       69210017
*  OPTION WAS REVIEW LOAD PRAMATER SELECT TABLE AND GENERATE FRAME      69300017
*                                                                       69390017
**********************************************************************  69480017
         SPACE                                                          69570017
LOADPST  MVC   CCTCCR(THREE),ZERO(EXTR)   MOVE CURRENT COMMAND KEY      69660017
         NI    CCTPSTAT,XCEPTOFF    TURN OFF ACCEPT BIT FOR PROCESSORS  69750017
         MVI   ACCREV,R            SET REVIEW CODE                      69790017
         L     WORKR1,CCTBUFFP      GET BUFFER ADDRESS                  69840017
CLRBUFF  MVI   ZERO(WORKR1),HEX40  BLANK BUFFER                         69930017
         MVC   ONE(TWO51,WORKR1),ZERO(WORKR1)                           70020017
         MVC   TWO51(HUNDRED,WORKR1),ZERO(WORKR1)                       70110017
*                                                                       70200017
* SEARCH EXTRACT RECORD AND, USING PST, PUT ENTRIES INTO I/O BUFFER     70290017
*                                                                       70380017
         L     CSTR,CURRTAB        GET ADDRESS OF CURRENT PST           70470017
         SR    WORKR3,WORKR3       ZERO WORK REGISTER                   70560017
TABLEEND CLC   TENTLGT(TWO),ZEROS  IS THIS TABLE END                    70650017
         BE    SENDDATA             YES, SET UP TO WRITE BUFFER TO 1130 70740017
         TM    TINLGT,HEXFF        DOES THIS ENTRY HAVE INPUT DATA      70830017
         BZ    NXTENTRY            NO, GO TO NEXT ENTRY                 70920017
         LH    WORKR2,TINMAP        LOAD INPUT MAPPING                  71010017
         LR    RPAR1,WORKR2        LOAD MAPPING TO PARM REG             71100017
         AR    WORKR2,EXTR         ADD BEGINNING OF EXTRACT RECORD      71190017
         TM    ZERO(WORKR2),HEX37    IS THIS END DELIMITER              71280017
         BO    NXTENTRY             YES, GO TO NEXT ENTRY               71370017
         AR    RPAR1,WORKR4        ADD BEGINNING OF WORK AREA           71460017
         IC    WORKR3,TINLGT     INSERT INPUT LENGTH                    71550017
         BCT   WORKR3,NXT        SUBTRACT ONE                           71640017
NXT      EX    WORKR3,MOVEDATA                                          71730017
         SPACE                                                          71820017
NXTENTRY IC    WORKR3,TENTLGT                                           71910017
         AR    CSTR,WORKR3       ADD ENTRY LENGTH TO NEXT TABLE ENTRY   72000017
         B     TABLEEND            GO TO CHECK FOR END OF TABLE         72090017
         SPACE                                                          72180017
MOVEDATA MVC   ZERO(ZERO,RPAR1),ZERO(WORKR2)  MOVE FIELD TO BUFFER      72270017
         SPACE                                                          72360017
*                                                                       72450017
* ALL DATA HAS BEEN MOVED INTO I/O BUFFER.  NOW SEND BUFFER TO 1130     72540017
*                                                                       72630017
SENDDATA EQU   *                                                        72640017
         L     RPAR1,CCTBUFFP     GET BUFFER ADDRESS                    72650017
         MVC   ZERO(THREE,RPAR1),CCTCCR     PUT KEY INTO BYFFER         72660017
         CLC   CCTCCR(THREE),ENT    IS KEY FOR ENTER DATA               72670017
         BNE   SENDIT             IF NOT, BRANCH                        72680017
         MVI   MOREDATA(RPAR1),HEX40    BLANK MORE DATA FOLLOIWS SW     72690017
         TM    GJPSTAT,HEX10       WAS BACKGROUND SPECIFIED             72700017
         BZ    SENDIT           IF NOT, BRANCH                          72710017
         CLI   BCKSW,X             IS SWITCH SET                        72720017
         BE    SENDIT             IF YES, BRANCH                        72730017
         TM    CCTPSTAT,X'80'     IS JOB CARD REQUIRED                  72740017
         BZ    SENDIT             IF NOT, BRANCH                        72750017
         MVI   BFIND(RPAR1),X     PUT X IN BUFFER                       72760017
         MVI   BCKSW,X             SET BACKGROUND SWITCH                72770017
SENDIT   EQU   *                                                        72780017
         LA    RPAR1,CCTPWKAL      GET LENGTH OF BUFFER                 72790017
         ST    RPAR1,CCTRECLN    PUT IN CCT AS DATA LNTH TO BE XMITTED  72810017
         LR    RPAR1,CCTR        SET POINTER TO CCT                     72900017
         LA    RPAR0,WRITCODE                                           72990017
         L     RBR,CCTIORP       GET ADDRESS OF I/O ROUTINE             73080017
         BALR  RRET,RBR          GO TO I/O ROUTINE                      73170017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  73200017
         BE    RETURN             IF YES, RETURN                        73230017
         SPACE                                                          73260017
         LA    RPAR1,CCTPWKAL      GET LENGTH OF WORKAREA               73280017
         LA    RPAR1,TWO(RPAR1)    INCREMENT BY TWO                     73300017
         ST    RPAR1,CCTRECLN      STORE IN CCT                         73320017
         SR    RPAR0,RPAR0         SET CODE TO READ                     73340017
         LR    RPAR1,CCTR         SET POINTER TO CCT                    73350017
         L     RBR,CCTIORP         GET ADDRESS OF I/O ROUTINE           73360017
         BALR  RRET,RBR            GO TO GET EXTRACT RECORD             73380017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  73400017
         BE    RETURN             IF YES, RETURN                        73420017
         B     INCHSN                  GO TO INCREMENT HSN              73440017
         EJECT                                                          73530017
*                                                                       73620017
*  THIS SUBROUTINE READS THE EXTRACT DATA SET AND MAINTAINES POINTERS   73710017
*  FOR THE NEXT READ AND NEXT WRITE                                     73800017
*                                                                       73890017
         SPACE                                                          73980017
READEXT  ST    RRET,RETSAV             SAVE RETURN ADDR                 74070017
         L     PNTAR,POINTRA           LOAD A POINTER                   74160017
         L     WORKR1,CCTEDCB1         LOAD DCB ADDR                    74250017
         SPACE                                                          74340017
*                                                                       74430017
*  READ RECORD FROM EXTRACT DATA SET                                    74520017
*                                                                       74610017
         SPACE                                                          74700017
         LA    WORKR2,READMAC          LOAD ADDR OF DECB                74790017
         READ  (WORKR2),SF,,,,,,MF=E   EXECUTE READ                     74880017
         SPACE                                                          74970017
         CHECK (WORKR2)                CHECK FOR COMPLETION             75060017
         SPACE                                                          75150017
         NOTE  (WORKR1)                NOTE POSITION OF LAST READ       75240017
         SPACE                                                          75330017
         A     RPAR1,ZERONE            ADD ONE TO NOTE POSITION         75420017
         CR    RPAR1,PNTAR             COMPARE FOR END OF DATA          75510017
         BL    CONVERT                 BRANCH IF NOT END                75600017
         OI    STATBYT,ENDON           TURN ON END OF DATA              75690017
         SPACE                                                          75780017
*                                                                       75870017
*  CONVERT HSN TO EBDIC FORM                                            75960017
*                                                                       76050017
         SPACE                                                          76140017
CONVERT  LH    WORKR3,HSN              LOAD HISTORY SEQ. NUM.           76230017
         CVD   WORKR3,DECHSN           CONVERT NUMBER TO PACKED DECIMAL 76320017
         UNPK  EBDICHSN,DECHSN         UNPACK TO EBDIC FORM             76410017
         OI    EBDICHSN+7,X'F0'        TURN ON SIGN                     76500017
         ST    PNTAR,POINTRA           SAVE END OF DATA ADDR            76590017
         L     RRET,RETSAV             LOAD RETURN ADDR                 76680017
         BR   RRET                 RETURN                               76770017
*                                                                       76860017
* INTERNAL ERROR EXIT FOR INVALID DATA FROM EXTRACT RECORD OR AN        76950017
* INVALID RETURN CODE FROM A PROCESSOR                                  77040017
*                                                                       77130017
KEYERR   LA    RPAR0,IRMSG24      LOAD ADDRESS OF ERROR MESSAGE         77220017
         L     RBR,CCTIERRP       LOAD ADDRESS OF IERR                  77310017
LDERRCCT LR    RPAR1,CCTR         LOAD ADDRESS OF CCT                   77400017
         BALR  RRET,RBR        BRANCH TO IKAIERR                        77460017
         B     RETURN           BRANCH TO RETURN                        77520017
         SPACE                                                          77580017
ERROR    LA    RPAR0,IRMSG52      LOAD ADDRESS OF ERROR MESSAGE         77670017
         B     LDERRCCT            BRANCH TO GO TO IERR                 77710017
*                                                                       77765017
* WRITE OK MESSAGE TO THE SUBSYSTEM, INCREMENT THE HSN AND RETURN TO    77770017
* CALLING ROUTINE.                                                      77775017
*                                                                       77780017
WRITOK   L     WORKR1,CCTBUFFP     GET POINTER TO BUFFER                77785017
         MVC   ZERO(OKLNTH,WORKR1),OKMSG  PUT MSG INTO BUFFER           77788017
         LA    RPAR0,FOUR         SET CODE TO WRITE                     77792017
         LA    WORKR1,FOUR         SET MSG LENGTH                       77796017
         ST    WORKR1,CCTRECLN                                          77800017
WRITJBLB EQU   *                                                        77802017
         LR    RPAR1,CCTR          SET CCT ADDRESS                      77805017
         L     RBR,CCTIORP         GET POINTER TO I/O AREA              77810017
         BALR  RRET,RBR     GOTO I/O ROUTINE                            77815017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  77821017
         BE    RETURN             IF YES, RETURN                        77827017
         BR    RBAL           RETURN TO CALLER                          77835017
         EJECT                                                          77850017
*                                                                       77940017
*  EXIT ROUTINE  INSURE THAT USER DID NOT ONLY DO OMITS ALSO DELETE ALL 78030017
*  PROCESSORS AND TABLES LOADED BY RECALL AND RETURN STATUS TO CTL AS   78120017
*  IT WAS UPON ENTERING RECALL.                                         78210017
*                                                                       78300017
         SPACE                                                          78390017
EXIT     SR    WORKR1,WORKR1       CLEAR A REGISTER                     78400017
         L     RBUFF,CCTBUFFP     GET ADDRESS OF I/O BUFFER             78405017
         STH   WORKR1,ZERO(RBUFF)  PUT ZERO IN BUFFER                   78413017
         LA    WORKR1,TWO          SET RECORD LENGTH TO TWO             78421017
         ST    WORKR1,CCTRECLN    IN CCT                                78430017
         L     RBR,CCTIORP        GET I/O ROUTINE ADDRESS               78440017
         LR    RPAR1,CCTR          AND POINTER TO CCT                   78450017
         LA    RPAR0,WRITCODE     SET CODE TO WRITE                     78460017
         BALR  RRET,RBR             GO TO I/O ROUTINE                   78470017
         CH    RBR,CON1C          IS X'1C' RETURN CODE                  78471017
         BE    RETURN             IF YES, RETURN                        78472017
         MVI   CCTSTAT,K           PUT LINK INDICATOR IN CCT            78475017
         L     WORKR1,CCTEDCBP  LOAD ADDRESS OF EXTRACT DCB             78480017
         NOTE  (WORKR1)                NOTE POSIITON OF EXT DATA SET    78570017
         SPACE                                                          78660017
         C     RPAR1,ZERONE            IS POSITION MORE THAN ZERO ONE   78750017
         BNH   LOAD0C                  NO GO TO LOAD A 0C RETURN CODE   78840017
         LA    RBR,ZERO                LOAD '00' RETURN CODE            78930017
         B     RETURN                  BRANCH TO RETURN                 79020017
         SPACE                                                          79110017
LOAD0C   LA    RBR,CANCEL              LOAD '0C' RETURN CODE            79200017
RETURN   LR    WORKR1,RBR              SAVE RETURN CODE                 79290017
         NI    IGNORBIT,IGNOROFF       TURN OFF IGNORE ATTN BIT         79380017
         SPACE                                                          79470017
         CLC   CURRPROC(FOUR),ZEROS    IS THERE A PROCESSOR PRESENT     79560017
         BE    PSTDEL                  NO GO TO TEST FOR A PST          79650017
         DELETE  EPLOC=CPROCNM         DELETE PROCESSOR                 79740017
         SPACE                                                          79830017
PSTDEL   CLC   CURRTAB(FOUR),ZEROS     IS THERE A PST PRESENT           79920017
         BE    FREECORE                                                 80010017
         DELETE  EPLOC=CTABNM          DELETE CURRENT PST               80100017
         SPACE                                                          80190017
FREECORE L     RSAVE,SAVE13            LOAD SAVE AREA ADDR              80280017
         FREEMAIN R,LV=GETEND-GETSTART,A=(4)     FREE WORK AREA         80370017
         SPACE                                                          80460017
         NI    RECMODE,RECOFF          TURN OFF RECALL MODE             80550017
         NI    CCTPSTAT,XCEPTOFF       TURN OF ACCEPT BIT FOR PROC'S    80640017
         LR    RBR,WORKR1              LOAD RETURN CODE                 80730017
         CH    RBR,CON5                                                 80820017
         BE    LDCCTADD                IS RETURN CODE FIVE              80910017
         RETURN (14,12),RC=(15)        RESTORE REGS AND RETURN          81000017
         SPACE                                                          81090017
LDCCTADD LR    RPAR1,CCTR              LOAD CCT ADDR                    81180017
         L     RRET,12(0,RSAVE)    RESTORE REGISTER 14                  81220017
         XCTL  (2,12),EP=IKAPBEG0                                       81270017
         EJECT                                                          81360017
         DS    0F                                                       81450017
ZERONE   DC    X'00000001'             STARTING ADDR FOR DATA SETS      81540017
ONES     DC    X'FFFFFFFF'             CONSTANT OF ONES                 81630017
ZEROS    DC    X'00000000'             CONSTANT OF ZEROS                81720017
PROCCON  DC    C'IKAPXXX0'        PROCESSOR CONSTANT                    81810017
TABCON   DC    C'IKATXXX0'       TABLE CONSTANT                         81900017
BLANK    DC    CL80' '                 CONSTANT OF EIGHTY BLANKS        81990017
CON4     DC    X'0004'           CONSTANT OF 4                          82080017
CON5     DC    X'0005'                 CONSTANT OF FIVE                 82170017
CON8     DC    X'0008'           CONSTANT OF 8                          82260017
CONC     DC    X'000C'           CONSTANT OF C                          82350017
CON10    DC    X'0010'                 HEX 10 CONSTANT                  82440017
CON14    DC    X'0014'                 CONSTAN HEX 14                   82530017
CON18    DC    X'0018'                 CONSTANT OF HEX 18               82620017
CON1C    DC    X'001C'            CONSTANT OF HEX 1C                    82660017
RECALL   DC    C'RECALL'               RECALL CONSTANT                  82710017
CONCAN   DC    C'CAN '                 CONSTANT OF CAN                  82800017
CONBEG   DC    C'BEG '                 CONSTANT OF BEG                  82890017
BEGP     DC    C'BEG//'                CONSTANT OF BEG//                82980017
LOF      DC    C'LOF'             LOGOFF COMMAND KEY                    83000017
ENT      DC    C'ENT'              ENTER DATA KEY                       83010017
OKMSG    DC    C'EXOK'             OK MESSAGE                           83020017
JOBLIB   DC    C'JOBLIB'          JOBLIB MESSAGE                        83040017
CANREC   DC    C'FFF'                YES, BRANCH                        83070017
IRMSG24  DC    C'024PREC0'     CALLING SEQUENCE TO IERR FOR             83160017
         DC    F'0'            ERROR MESSAGE 24                         83250017
IRMSG52  DC    C'052PREC0'     CALLING SEQUENCE TO IERR FOR             83340017
         DC    F'0'            ERROR MESSAGE 52                         83430017
         DS    0H                                                       83520017
         EJECT                                                          83610017
         SPACE                                                          83700017
         READ  READB,SF,,,,,,MF=L      READ MACRO LIST                  83790017
READEND  EQU   *                                                        83880017
         SPACE                                                          83970017
RMACLEN  EQU   READEND-READB                                            84060017
         EJECT                                                          84150017
*                                                                       84240017
*  THIS SERIES OF TABLES IS USED TO CREATE A HISTORY ENTRY TO BE        84330017
*  DISPLAYED AS CURRENT ITEM ON A RECALL SELECT FRAME                   84420017
*                                                                       84510017
*        THE PNTDISTB TABLE IS A SERIES OF POINTERS TO THE              84600017
*        INDIVIDUAL PROCESSOR TABLES. THIS TABLE IS SEARCHED USING      84690017
*        THE THREE BYTE KEY IN THE EXTRACT RECORD                       84780017
*                                                                       84870017
*        THE PROCESSOR TABLE ENTRIES HAVE THE FOLLOWING FORMAT          84960017
*                                                                       85050017
*              BYTE ONE    TOTAL LENGTH OF ENTRY                        85140017
*                   TWO    IF ZERO FIELD IS NOT IN EXTRACT RECORD       85230017
*                   THREE  THE NUMBER OF BYTES TO BE MOVED              85320017
*                   FOUR   THE DISPLACEMENT IN HISTORY RECORD           85410017
*                   FIVE   IS THE BEGINNING OF CONSTANT TO BE PLACED    85500017
*                          IN HISTORY RECORD IF FIELD IS NOT IN         85590017
*                          EXTRACT RECORD                               85680017
         SPACE                                                          85770017
         DS    0F                                                       85860017
PNTDISTB DC    C'SPE '                 SPE CONSTANT                     85950017
         DC    A(SPETABLE)             ADDR OF SPE TABLE                86040017
         DC    C'ENT '                 ENT CONSTANT                     86130017
         DC    A(ENTTABLE)             ADDR OF ENT TABLE                86220017
         DC    C'DES '                 DES CONSTANT                     86310017
         DC    A(DESTABLE)             ADDR OF DES TABLE                86400017
         DC    C'BEG '                 BEG CONSTANT                     86490017
         DC    A(BEGTABLE)             ADDR OF BEG TABLE                86580017
         DC    C'BEP '                 BEP CONSTANT                     86670017
         DC    A(BEPTABLE)             ADDR OF BEP TABLE                86760017
         DC    X'FFFF'                 END OF LIST                      86850017
         SPACE                                                          86940017
SPE1     EQU   *                                                        87030017
SPETABLE DC    AL2(SPE1E-SPE1)         LENGTH OF ENTRY                  87120017
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       87210017
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  87300017
         DC    AL2(3)             HISTORY DISPLACEMENT                  87390017
         DC    C'JOB STEP'             KEYWORD CONSTANT                 87480017
SPE1E    EQU   *                                                        87570017
*                                                                       87660017
SPE2     EQU   *                                                        87750017
         DC    AL2(SPE2E-SPE2)         LENGTH OF ENTRY                  87840017
         DC    AL2(103)                EXTRACT DISPLACEMENT             87930017
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  88020017
         DC    AL2(15)             HISTORY DISPLACEMENT                 88110017
SPE2E    EQU   *                                                        88200017
         DC    X'FFFF'                 END OF TABLE                     88290017
SPEEND   EQU   *                                                        88380017
         SPACE                                                          88470017
ENT1     EQU   *                                                        88560017
ENTTABLE DC    AL2(ENT1E-ENT1)         LENGTH OF ENTRY                  88650017
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       88740017
         DC    AL2(3)                  NUMBER OF CHAR'S TO MOVE LESS 1  88830017
         DC    AL2(3)             HISTORY DISPLACEMENT                  88920017
         DC    C'DATA'                 KEYWORD CONSTANT                 89010017
ENT1E    EQU   *                                                        89100017
*                                                                       89190017
ENT2     EQU   *                                                        89280017
         DC    AL2(ENT2E-ENT2)         LENGTH OF ENTRY                  89370017
         DC    AL2(3)                  EXTRACT DISPLACEMENT             89460017
         DC    AL2(15)                 NUMBER OF CHAR'S TO MOVE LESS 1  89550017
         DC    AL2(15)             HISTORY DISPLACEMENT                 89640017
ENT2E    EQU   *                                                        89730017
         DC    X'FFFF'                 END OF TABLE                     89820017
ENTEND   EQU   *                                                        89910017
         SPACE                                                          90000017
DES1     EQU   *                                                        90090017
DESTABLE DC    AL2(DES1E-DES1)         LENGTH OF ENTRY                  90180017
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       90270017
         DC    AL2(7)                  LENGTH OF CHAR'S TO MOVE LESS 1  90360017
         DC    AL2(3)             HISTORY DISPLACEMENT                  90450017
         DC    C'DESCRIBE'                                              90540017
DES1E    EQU   *                                                        90630017
*                                                                       90720017
DES2     EQU   *                                                        90810017
         DC    AL2(DES2E-DES2)         LENGTH OF ENTRY                  90900017
         DC    AL2(5)                  EXTRACT DISPLACEMENT             90990017
         DC    AL2(15)                 NUMBER OF CHAR'S TO MOVE LESS 1  91080017
         DC    AL2(15)             HISTORY DISPLACEMENT                 91170017
DES2E    EQU   *                                                        91260017
         DC    X'FFFF'                 END OF TABLE                     91350017
DESEND   EQU   *                                                        91440017
         SPACE                                                          91530017
BEG1     EQU   *                                                        91620017
BEGTABLE DC    AL2(BEG1E-BEG1)         LENGTH OF ENTRY                  91710017
         DC    AL2(0)                  ZERO EQUALES NOT IN EXTRACT      91800017
         DC    AL2(4)                  NUMBER OF CHAR'S TO MOVE LESS 1  91890017
         DC    AL2(3)             HISTORY DISPLACEMENT                  91980017
         DC    C'BEGIN '               CONSTANT BEGIN                   92070017
BEG1E    EQU   *                                                        92160017
         SPACE                                                          92250017
BEG2     EQU   *                                                        92340017
         DC    AL2(BEG2E-BEG2)         LENGTH OF ENTRY                  92430017
         DC    AL2(70)            EXTRACT DISPLACEMENT                  92520017
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  92610017
         DC    AL2(15)             HISTORY DISPLACEMENT                 92700017
BEG2E    EQU   *                                                        92790017
         DC    X'FFFF'                 END OF TABLE                     92880017
         SPACE                                                          92970017
BEP1     EQU   *                                                        93060017
BEPTABLE DC    AL2(BEP1E-BEP1)         LENGTH OF ENTRY                  93150017
         DC    AL2(0)                  ZERO EQUALS NOT IN EXTRACT       93240017
         DC    AL2(7)             NUMBER OF CHAR TO MOVE LESS ONE       93330017
         DC    AL2(1)             HISTORY DISPLACEMENT                  93420017
         DC    C'BEGPROC '        KEYWORD CONSTANT                      93510017
BEP1E    EQU   *                                                        93600017
         SPACE                                                          93690017
BEP2     EQU   *                                                        93780017
         DC    AL2(BEP2E-BEP2)         LENGTH OF ENTRY                  93870017
         DC    AL2(268)                EXTRACT DISPLACEMENT             93960017
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  94050017
         DC    AL2(9)             HISTORY DISPLACEMENT                  94140017
BEP2E    EQU   *                                                        94230017
         SPACE                                                          94320017
         SPACE                                                          95040017
BEP4     EQU   *                                                        95130017
         DC    AL2(BEP4E-BEP4)         LENGTH OF ENTRY                  95220017
         DC    AL2(70)                 EXTRACT DISPLACEMENT             95310017
         DC    AL2(7)                  NUMBER OF CHAR'S TO MOVE LESS 1  95400017
         DC    AL2(19)            HISTORY DISJPLACEMENT                 95490017
BEP4E    EQU   *                                                        95580017
         DC    X'FFFF'                 END OF TABLE                     95670017
BEPEND   EQU   *                                                        95760017
CSTABLE  DC    C'SPE'         KEY FOR PROCESSOR                         95850017
         DC    X'03'          COMMAND SELECT MASK                       95940017
         DC    X'A6'              COMMAND STATUS BITS                   96030017
         DC    X'26'          NEXT AVAILABLE COMMAND                    96120017
         DC    C'DES'                                                   96210017
         DC    X'02'                                                    96300017
         DC    X'A6'              COMMAND STATUS BITS                   96390017
         DC    X'26'                                                    96480017
         DC    C'ENT'                                                   96570017
         DC    X'03'                                                    96660017
         DC    X'A6'              COMMAND STATUS BITS                   96750017
         DC    X'26'                                                    96840017
         DC    C'BEG'                                                   96930017
         DC    X'02'                                                    97020017
         DC    X'A7'                                                    97110017
         DC    X'00'                                                    97200017
         DC    C'BEG'                                                   97290017
         DC    X'03'                                                    97380017
         DC    X'C7'                                                    97470017
         DC    X'00'                                                    97560017
         END                                                            97650017
./       ADD   SSI=00011656,NAME=IKDPRSJP,SOURCE=0
 TITLE 'IKDPRSJP' SGJP RESIDENT MODULE DIRECTORY                        00700017
*STATUS: CHANGE LEVEL 000                                             * 01500017
*FUNCTION/OPERATION: IKDPRSJP IS A TABLE OF ADDRESS CONSTANTS POINTING* 02500017
*   TO THE OBJECT MODULES WITHIN THE LOAD MODULE IKDNUC.  IKDNUC IS   * 03000017
*   COMPRISED OF THE ROUTINES PERMANENTLY RESIDENT IN CORE FOR THE    * 03500017
*   SATELLITE GRAPHIC JOB PROCESSOR.  WHEN IKDINIT LOADS IKDNUC. IT   * 04000017
*   USES THE ADDRESS CONSTANTS TO PARTIALLY FILL THE CONSOLE CONTROL  * 04500017
*   TABLE.  THEREFORE, WHEN THE MODULES OF IKDNUC ARE LINK EDITED,    * 05000017
*   IKDPRSJP MUST BE FIRST                                            * 05500017
*ENTRY POINTS: N/A                                                    * 06300017
*INPUT: N/A                                                           * 07100017
*OUTPUT: N/A                                                          * 07900017
*EXTERNAL ROUTINES: N/A                                               * 08700017
*EXITS: N/A                                                           * 09500017
*TABLES/WORKAREAS: N/A                                                * 10300017
*ATTRIBUTES: NON-EXECUTABLE                                           * 11100017
*NOTES: N/A                                                           * 11900017
        EJECT                                                           13000017
IKDPRSJP CSECT                                                          13500017
         EXTRN IKDIOR                                                   14000017
         EXTRN IKDMSG                                                   21000017
         EXTRN IKAJCL                                                   28000017
         EXTRN IKADIA                                                   35000017
         EXTRN IKASGD                                                   42000017
IKDTABLE DC    A(IKDIOR)           POINTER TO IRDIOR                    49000017
         DC    A(IKDMSG)           POINTER TO IKDMSG                    56000017
         DC    A(IKAJCL)           POINTER TO IKAJCL                    63000017
         DC    A(IKADIA)           POINTER TO IKADIA                    70000017
         DC    A(IKASGD)           POINTER TO IKASGD                    77000017
         END                                                            84000017
