         MACRO                                                          00020000
  CENPROCS  &MODEL=40,&INSTSET=,&FEATURE=,&STORAGE=              S99247 00040021
         COPY  SGGBLPAK                                                 00060000
.*                                                                      00070021
.*       SUPPROT CODE S99235 DESIGNATES CODE CHANGES FOR                00072021
.*       FOR BOTH 158/158 CONSOLE AND 168 CPU SUPPORT.                  00074021
.*                                                                      00076021
         LCLA  &A                                                       00080000
         AIF    (&SGMENTB(1)).EB        WAS CENPROCS CALLED THIS SYSGEN 00100000
&SGMENTB(1) SETB 1                      SW ON MEAN CENPROCS CALLED ONCE 00120000
&SGCPUB(2) SETB ('&MODEL' EQ '40')      IF MOD 40,PUT GLOBAL SWT 2 ON   00160000
&SGCPUB(3) SETB ('&MODEL' EQ '50')      IF MOD 50,PUT GLOBAL SWT 3 ON   00180000
&SGCPUB(4) SETB ('&MODEL' EQ '65')      IF MOD 65,PUT GLOBAL SWT 4 ON   00200000
&SGCPUB(5) SETB ('&MODEL' EQ '75')      IF MOD 75,PUT GLOBAL SWT 5 ON   00220000
&SGCPUB(6) SETB ('&MODEL' EQ '91')                                      00230018
&SGCPUB(7) SETB ('&MODEL' EQ '85')      IF MOD=85,PUT GLOBAL SWT 7 ON   00240018
&SGCPUB(8) SETB ('&MODEL' EQ '155')     IF MOD 155,PUT GLOBAL SWT 8 ON  00244020
&SGCPUB(9) SETB ('&MODEL' EQ '195')     IF MOD 195,PUT GBL SWT 9 ON     00248019
&SGCPUB(10) SETB ('&MODEL' EQ '145')    IF MOD 145,PUT GBL SWT 10 ON    00253020
&SGCPUB(11) SETB ('&MODEL' EQ '165')    IF MOD 165,PUT GLOBAL SWT 11 ON 00258020
&SGCPUB(12) SETB ('&MODEL' EQ '135')    IF MOD 135,PUT GLOBAL SWT 12 ON 00268021
.*                                                              S99235  00268421
&SGCPUB(14) SETB ('&MODEL' EQ '158')    IF MOD 158,PUT GLOBAL SWT 14 ON 00268621
&SGCPUB(15) SETB ('&MODEL' EQ '168')    IF MOD 168,PUT GLOBAL SWT 15 ON 00269221
.* &SGCPUB(13) WILL BE SET IF FEATURE=S370 IS SPECIFIED FOR MODEL 195   00270021
.A0      AIF   (&SGCPUB(2) OR &SGCPUB(3) OR &SGCPUB(4) OR              *00272021
               &SGCPUB(5) OR &SGCPUB(6) OR &SGCPUB(7)).A1               00281021
         AIF   (&SGCPUB(8) OR &SGCPUB(9) OR &SGCPUB(10) OR             *00283021
               &SGCPUB(11) OR &SGCPUB(12) OR &SGCPUB(14) OR            *00283421
               &SGCPUB(15)).A1                                   S99235 00291421
&SGQUITB SETB  1                        MODEL NO. INVALID-PUT ENDGEN ON 00300000
    MNOTE 5,'* * * IEICEN101 MODEL VALUE &MODEL INVALID'                00320000
          AGO  .INSTEST           GO SCAN RTN FOR INST SET PARM  S99247 00340021
.A1 MNOTE *,'     MODEL &MODEL '                                        00360000
.CORTEST ANOP                           ENTER INSTSET RTN               00380000
          AIF  (T'&STORAGE EQ 'O').INSTEST IF STORAGE OMITTED, BRS99247 00440021
.*                                                               S99247 00540021
  MNOTE 0,'* * * STORAGE= &STORAGE IGNORED -- NO LONGER SUPPORTED'      00640021
.INSTEST AIF (('&INSTSET' EQ '')AND(('&MODEL' EQ '50')OR('&MODEL' EQ '6X00780000
               5')OR('&MODEL' EQ '75')OR('&MODEL' EQ '91')OR('&MODEL' E*00790018
               Q '85')OR('&MODEL' EQ '195'))).ANYFEAT                   00800019
.*                                 THE FOLLOWING THREE LINES ARE S99235 00802021
 AIF (('&INSTSET' EQ '') AND(('&MODEL' EQ '145') OR ('&MODEL' EQ '155')*00806021
               OR  ('&MODEL' EQ '158') OR ('&MODEL' EQ '165') OR       *00816021
               ('&MODEL' EQ '168') OR ('&MODEL' EQ '135'))).ANYFEAT     00826021
 AIF (('&MODEL' EQ '40') AND ('&INSTSET' EQ '')).E4                     00836000
&SGCPUB(30) SETB ('&INSTSET' EQ 'STD')  IF STD + MOD30/40,GLB SWT 30 ON 00840000
&SGCPUB(31) SETB ('&INSTSET' EQ 'COMM') IF COMMERCIAL SET,GLB SWT 31 ON 00860000
&SGCPUB(32) SETB ('&INSTSET' EQ 'SCNTF') IF SCIENTIFIC SET,GLB SWT32 ON 00880000
&SGCPUB(33) SETB ('&INSTSET' EQ 'UNIV') IF UNIVERSAL SET,GLB SWT 33 ON  00900000
     AIF (&SGCPUB(30) OR &SGCPUB(31) OR &SGCPUB(32) OR &SGCPUB(33)).A3  00920000
&SGQUITB SETB  1                        INSTSET INVALID-TURN ON SGQUITB 00940000
    MNOTE 5,'* * * IEICEN103 INSTSET VALUE &INSTSET INVALID'            00960000
         AGO   .ANYFEAT                 GO TEST IF OPT. FEATURES SPEC'D 00980000
.E4 MNOTE 5,'* * * IEICEN104 INSTSET VALUE NOT SPECIFIED'               01000000
&SGQUITB SETB  1                        MUST SPEC INSTSET FOR MOD 30/40 01020000
         AGO  .ANYFEAT                  GO TEST IF OPT. FEATURES SPEC'D 01040000
.A3 MNOTE *,'     &INSTSET INSTRUCTION SET '                            01060000
 AIF (NOT((&SGCPUB(10) OR &SGCPUB(12)) AND &SGCPUB(30))).INSDEF         01060221
&SGCPUB(30) SETB 0                                                      01060420
&SGCPUB(31) SETB 1                                                      01060620
  MNOTE 0,'* * * IEICENW01  INSTSET &INSTSET CHANGED TO COMM FOR MODEL-*01060820
               &MODEL .'                                                01061020
.INSDEF  ANOP                                                           01061220
 AIF (NOT ((&SGCPUB(8) OR &SGCPUB(9) OR &SGCPUB(11) OR &SGCPUB(14) OR  *01064421
               &SGCPUB(15)) AND (&SGCPUB(30) OR &SGCPUB(31) OR         *01064921
               &SGCPUB(32)))).ANYFEAT                            S99235 01065421
&SGCPUB(30)    SETB 0                                                   01066000
&SGCPUB(31)    SETB 0                                                   01068019
&SGCPUB(32)    SETB 0                                                   01070019
&SGCPUB(33)    SETB 1                                                   01072019
   MNOTE 0,'* * * IEICENW01  INSTSET &INSTSET CHANGED TO UNIV FOR MODELX01074019
               -&MODEL .'                                               01076019
.ANYFEAT AIF   (T'&FEATURE EQ 'O').PHASE2    GO TO STD. FEAT ROUTINE    01080000
    MNOTE *,'     FOLLOWING FEATURES SPECIFIED'                         01100000
.TESTCTR AIF (&A EQ N'&FEATURE).PHASE2  IF ALL FEAT.S SCANNED,GO PHASE2 01120000
&A       SETA  &A+1                     INCREMENT TO NEXT FEAT SUB-OPRN 01140000
 AIF ('&FEATURE(&A)' EQ 'PROTECT').F2   IF STORAGE PROTECT,GO SET SW 41 01180000
 AIF ('&FEATURE(&A)' EQ 'S370' AND '&MODEL' EQ '195').F3                01210021
&SGQUITB SETB  1                        FEATURE INVALID-TURN ON SGQUITB 01240000
    MNOTE 5,'* * * IEICEN105 FEATURE VALUE &FEATURE(&A) INVALID'        01260000
         AGO   .TESTCTR                 GO SEE IF FEAT. SUBLST EXHAUSTD 01280000
.F2 MNOTE *,'        STORAGE PROTECTION'                                01360000
&SGCPUB(41) SETB 1                      TURN ON PROTECTION SWT.         01380000
         AGO   .TESTCTR                 GO SEE IF ALL FEAT.S SCANNED    01400000
.F3 MNOTE *,'        SYSTEM 370 / MODEL 195'                            01420021
&SGCPUB(9)  SETB 0       TURN OFF S360/M195 GLOBAL                      01440021
&SGCPUB(13) SETB 1       TURN ON  S370/M195 GLOBAL                      01460021
         AGO   .TESTCTR                                                 01480021
.PHASE2  ANOP                                                           01540021
    MNOTE *,'     FOLLOWING FEATURES STANDARD ON MODEL &MODEL '         01600000
 AIF (&SGCPUB(5) OR &SGCPUB(6) OR &SGCPUB(7) OR &SGCPUB(8) OR &SGCPUB(9*01620000
               ) OR &SGCPUB(10) OR &SGCPUB(11) OR &SGCPUB(12) OR       *01630000
                &SGCPUB(13) OR &SGCPUB(14) OR &SGCPUB(15)).A6    S99235 01632021
    AIF (&SGCPUB(4) OR &SGCPUB(3)).A7   IF MOD 65/50 SET 3 STD-FEAT SWS 01660000
         AGO   .A8                      GO SET 1 STD-FEAT FOR MODEL 40  01680000
.A6 MNOTE *,'        DIRECT CONTROL '                                   01740000
.*                                 THE FOLLOWING LINE IS FOR S99235     01742021
&SGCPUB(43) SETB 1   MOD. 75/85/91/135/145/155/158/165/168/195 DEFAULTS 01750021
 AIF ('&INSTSET' EQ 'UNIV' OR '&INSTSET' EQ 'SCNTF' OR '&INSTSET' NE ''*01770013
               ).A71                                                    01780013
   AIF (NOT (&SGCPUB(10) OR &SGCPUB(12))).A7      NOT 145,135           01784021
    MNOTE *,'        COMMERCIAL INSTRUCTION SET '                       01788020
&SGCPUB(31) SETB 1            MOD. 135/145 DEFAULT                      01792021
   AGO .A71                                                             01796020
.A7 MNOTE *,'        UNIVERSAL INSTRUCTION SET '                        01800000
.*                                 THE FOLLOWING LINE IS FOR S99235     01810021
&SGCPUB(33) SETB 1         MOD. 91/75/65/50/85/155/158/165/168 DEFAULT  01820021
.A71     ANOP                                                           01840000
    MNOTE *,'        STORAGE PROTECTION  '                              01850021
&SGCPUB(41) SETB 1                                                      01860021
.A8 MNOTE *,'        INTERVAL TIMER '                                   01900018
&SGCPUB(40) SETB 1                                                      01920021
.*                               SEQ # 019270-021190 REMOVED FOR S99247 01927021
.C1A     AIF (&SGCPUB(6) OR &SGCPUB(9) OR &SGCPUB(13)).EN  MOD 91/195   02124021
.C2 AIF (NOT((&SGCPUB(3) OR &SGCPUB(4) OR &SGCPUB(5)OR &SGCPUB(7)) AND *02160018
               (&SGCPUB(30)OR &SGCPUB(31)OR &SGCPUB(32)))).EN           02180018
.T1      ANOP                                                           02200000
&SGQUITB SETB  1                                                        02220000
    MNOTE 5,'* * * IEICEN108 INSTSET VALUE &INSTSET INVALID ON MOD. &MOX02240000
               DEL'                                                     02260000
         MEXIT                                                          02280000
.*                               SEQ # 023000-023600 REMOVED FOR S99247 02300021
.EB MNOTE 5,'* * * IEICEN109 CENPROCS MACRO PREVIOUSLY USED'            02440000
&SGQUITB SETB  1                        ONLY SYSGEN ONE CPU AT A TIME   02460000
.EN      MEND                           EXIT FROM CENPROCS MACRO        02480000
