         MACRO                                                          00020000
&NAME    CHANNEL &ADDRESS=,&TYPE=                                       00040000
         COPY  SGGBLPAK                                                 00060000
         LCLA  &A,&B,&V                                                 00080000
         LCLC  &ID                                                      00100000
&SGMENTB(2)   SETB   1       CHANNEL ENTRY SWITCH.                      00120000
&B       SETA  0                                                        00140000
&SGCNTRA(1)    SETA &SGCNTRA(1)+1                                       00160000
.BACK1   AIF   ('&NAME' EQ '').NONE  BRANCH IF NAME NOT SPECIFIED.      00180000
&ID      SETC  '&NAME'                                                  00200000
         AGO   .ON1                                                     00220000
.NONE    ANOP                                                           00240000
&ID      SETC  'CHAN. &SGCNTRA(1)'                                      00260000
.ON1     AIF   (&SGCNTRA(1) GT 14).E1                                   00280021
.BACK2   AIF   (T'&ADDRESS EQ 'O').E2      MUST BE SPECIFIED AND ONE    00300000
         AIF   (K'&ADDRESS NE 1).E3     ERROR ON NUMBER OF DIGITS       00310020
         AIF   (NOT(('&ADDRESS' GE '0' AND '&ADDRESS' LE '9')OR('&ADDRE*00320020
               SS' GE 'A' AND '&ADDRESS' LE 'D'))).E3                   00330021
         CONVERT TO=HEX,DIGITS=1,VALUE=&ADDRESS                         00340020
&B       SETA  &HEX*15                                                  00350020
         AIF   (&SGCHANB(&B+1)).E5      CHANNEL PREVIOUSLY SPECIFIED    00360020
    MNOTE *,'     CHANNEL &ADDRESS IS PRESENT'                          00400000
&SGCHANB(&B+1) SETB 1                                                   00420000
.TYPE    AIF   (T'&TYPE EQ 'O').E6                                      00440000
         AIF   (N'&TYPE EQ 1).ONE                                       00460000
         AIF   (N'&TYPE GT 2).E7   MAXIMUM OF TWO.                      00480000
.TEST    AIF   ('&TYPE(1)'  EQ 'SELECTOR').S1                           00500000
         AIF   ('&TYPE(2)'  EQ 'SELECTOR').S2                           00520000
         AGO   .E8                                                      00540000
.S1      ANOP                                                           00560000
&A       SETA  2         SECOND VALUE MUST BE STORAGE.                  00580000
         AGO   .ON2                                                     00600000
.S2      ANOP                                                           00620000
&A       SETA  1                                                        00640000
.ON2  AIF  ('&TYPE(&A)' NE 'STORAGE').E8                                00660000
    MNOTE *,'        IT IS A SELECTOR-STORAGE CHANNEL'                  00680000
&SGCHANB(&B+3) SETB 1                                                   00700000
&SGCHANB(&B+5) SETB 1                                                   00720000
         AGO   .MEND                                                    00740000
.ONE     AIF   ('&TYPE(1)' EQ 'SELECTOR').S3                            00760000
         AIF   ('&TYPE(1)' EQ 'MULTIPLEXOR').M1                         00780000
         AIF   ('&TYPE(1)' EQ 'HISPEEDMULTIPLEXOR').M2                  00800000
         AIF   ('&TYPE(1)' EQ 'HISPEED').H1                             00820000
         AIF   ('&TYPE(1)' EQ 'BLKMPXR').C1                             00830020
    AGO  .E8                                                            00840000
.C1 MNOTE *,'        IT IS A BLKMPXR CHANNEL'                           00845020
&SGCHANB(&B+6) SETB 1                                                   00850020
         AGO   .MEND                                                    00855020
.S3 MNOTE *,'        IT IS A SELECTOR CHANNEL'                          00860000
&SGCHANB(&B+3) SETB 1                                                   00880000
         AGO   .MEND                                                    00900000
.M1 MNOTE *,'        IT IS A MULTIPLEXOR CHANNEL'                       00920000
&SGCHANB(&B+2) SETB 1                                                   00940000
         AGO   .MEND                                                    00960000
.M2 MNOTE *,'        IT IS A HIGH SPEED MULTIPLEXOR CHANNEL'            00980000
&SGCHANB(&B+4) SETB 1                                                   01000000
         AGO   .MEND                                                    01020000
.H1 MNOTE *,'        IT IS A HIGH SPEED CHANNEL'                        01040000
&SGCHANB(&B+4) SETB 1                                                   01060000
         AGO   .MEND                                                    01080000
.E1 MNOTE 5,'* * * IEICHA101 &ID-MAXIMUM OF 14 CHANNELS EXCEEDED'       01100021
&SGQUITB SETB  1                                                        01120000
         AGO   .BACK2    BACK TO CHECK AS MUCH AS POSSIBLE.             01140000
.E2 MNOTE 5,'* * * IEICHA102 &ID-ADDRESS VALUE NOT SPECIFIED'           01160000
&SGQUITB SETB  1                                                        01180000
         AGO   .TYPE                                                    01200000
.E3 MNOTE 5,'* * * IEICHA103 &ID-ADDRESS VALUE &ADDRESS INVALID'        01220000
&SGQUITB SETB  1                                                        01240000
         AGO   .TYPE                                                    01260000
.E5 MNOTE 5,'* * * IEICHA104 &ID-CHANNEL &ADDRESS PREVIOUSLY SPECIFIED' 01280000
&SGQUITB SETB  1                                                        01300000
         AGO   .TYPE                                                    01320000
.E6 MNOTE 5,'* * * IEICHA105 &ID-TYPE VALUE NOT SPECIFIED'              01340000
&SGQUITB SETB  1                                                        01360000
         AGO   .MEND                                                    01380000
.E7 MNOTE 5,'* * * IEICHA106 &ID-TOO MANY TYPE VALUES'                  01400000
&SGQUITB SETB  1                                                        01420000
         AGO   .TEST                                                    01440000
.E8 MNOTE 5,'* * * IEICHA107 &ID-TYPE VALUE(S) &TYPE INVALID'           01460000
&SGQUITB SETB  1                                                        01480000
.MEND  MEND                                                             01500000
