         MACRO                                                          00020000
         CUPOINT                                                        00040000
         COPY  SGGBLPAK                                                 00060000
  LCLA &T                                                               00080000
         LCLA  &M,&K,&J,&I,&A,&B                                        00100000
         ACTR  &SGACTR                                                  00110018
.L1      AIF   (&SGCNTRA(3) LT 2 OR &SGCNTRA(3) GT &SGMAXA(2)).L8       00120000
&M       SETA  &SGCNTRA(3)  GET THE NUMBER OF IO DEVICE ADDRESSES.      00140000
.L2      AIF   (&M/2 LE 0).L6  TRANSFER OUT IO DEVICE ADDRESS SORTED.   00160000
&M       SETA  &M/2  SET INDEX TO OFF SET FOR SECOND IO DEVICE ADDRESS. 00180000
&K       SETA  &SGCNTRA(3)-&M  SET VALUE TO CHECK END OF PASS.          00200000
&J       SETA  1  SET OUTER INDEX VALUE.                                00220000
.L3      ANOP    RETURN TO CONTINUE PASS AT SAME INCREMENT.             00240000
&I       SETA  &J  SET INDEX TO FIRST IO DEVICE ADDRESS.                00260000
.L4      AIF   (&SGDADRA(&I)-&SGDADRA(&I)/4096*4096 LT &SGDADRA(&I+&M)-100280000
               &SGDADRA(&I+&M)/4096*4096).L5  TRANSFER DEVICES ORDERED. 00300000
         AIF   (&SGDADRA(&I)-&SGDADRA(&I)/4096*4096 EQ &SGDADRA(&I+&M)-100320000
               &SGDADRA(&I+&M)/4096*4096).L9  ERROR DEVICES EQUAL.      00340000
.LA      ANOP                                                           00360000
&T       SETA  &SGDADRA(&I)  IO ADDRESS OUT OF ORDER.                   00380000
&SGDADRA(&I) SETA &SGDADRA(&I+&M)  SAVE FIRST ADDRESS AND PUT SECOND    00400000
&SGDADRA(&I+&M) SETA &T  ADDRESS IN FIRST. THEN PUT FIRST IN SECOND.    00420000
&I       SETA  &I-&M  RESET INNER INDEX TO MOVE ADDRESS FURTHER BACK.   00440000
         AIF   (&I GE 1).L4  TRANSFER TO MOVE ADDRESS FUTHER BACK.      00460000
.L5      AIF   (&J+1 GT &K).L2  TRANSFER FOR ANOTHER PASS.              00480000
&J       SETA  &J+1  STEP OUTER INDEX BY ONE.                           00500000
         AGO   .L3  TRANSFER TO CONTINUE PASS AT SAME INCREMENT.        00520000
.L8 MNOTE 5,'* * * IEIGEN120 INVALID NUMBER OF IO DEVICES'              00540000
&SGQUITB SETB  1                                                        00560000
         AIF  (&SGCNTRA(3)  LT  2).E2   NO. OF DEVICES LESS THAN TWO?   00580021
&SGCNTRA(3)  SETA  &SGMAXA(2)                                           00600000
         AGO   .L1                                                      00620000
.L9      ANOP                                                           00640000
&A       SETA  &SGDADRA(&I)-&SGDADRA(&I)/4096*4096                      00660000
         CONVERT TO=EBCDIC,VALUE=&A,DIGITS=3                            00680000
    MNOTE 5,'* * * IEIGEN121 TWO EQUAL IO ADDRESSES &EBCDIC'            00700000
.T1      ANOP                                                           00720000
&SGQUITB SETB  1                                                        00740000
         AGO   .LA                                                      00760000
.L6 MNOTE *,'      THE SORTED DEVICE A BOXES CONTAIN.'                  00780000
    MNOTE *,'         SEQ  ADDRESS  DEVICE POINTER C.U. POINTER'        00800000
&B       SETA  0                                                        00820000
.E1      AIF   (&B EQ &SGCNTRA(3)).E2                                   00840000
&B       SETA  &B+1                                                     00860000
&I SETA &SGDADRA(&B)/4096-&SGDADRA(&B)/1048576*256   GET CU POINTER     00880018
&J SETA &SGDADRA(&B)/1048576  GET DEVICE POINTER                        00900018
&A SETA &SGDADRA(&B)-&SGDADRA(&B)/4096*4096                             00920018
         CONVERT  TO=EBCDIC,DIGITS=3,VALUE=&A                           00940000
    MNOTE *,'         &B   &EBCDIC        &J              &I'           00960000
         AGO   .E1                                                      00980000
.E2      MEND                                                           01000000
