         MACRO                                                          00400020
    GENTSO  &UT1SDS=,&UT2SDS=,&UT3SDS=,&OBJPDS=,&RESNAME=,&RESVOL=,    *00800020
               &RESTYPE=2311,&LNKNAME=,&LNKVOL=,&LEPRT=,&ASMPRT=OFF,   *01200020
               &DIRDATA=,&GENTYPE=ALL,                         SA68152 *01600021
               &INDEX=SYS1,&UT4SDS=,&CMDVOL=,&CMDNAME=,&UTDISP=KEEP,   *02000020
               &SYOUTDV=,&LOGREC=NOPRINT,&JOBSTMT=NOTSUPPLIED           02400020
         COPY  SGGBLPAK                                                 02800020
         GBLB  &QUITONB                                                 03000020
.********************************************************************** 03200020
.*** * *  SYNCHRONIZATION OF GENTSO AND GENERATE FOR TSO SYSGENS  * * * 03600020
.*** GENTSO   *   *   *   *   *   *   *   *   *   *   *   *   *   * * * 04000020
.*** 1) IF GENERATE ENTRY SW ON--ERROR 6) IF 2ND-CALL SW ON, GOTO 11)   04400020
.*** 2) SET GENTSO ENTRY SW            7) DO TSO GROUP 2,4,5 MACROS ETC 04800020
.*** 3) DO TSO ERROR CHECKING          8) SET GENERATE 2ND CALL SW      05200020
.*** 4) SET GENERATE FIRST-CALL SW     9) BRANCH TO RE-CALL GENR        05600020
.*** 5) CALL GENERATE                  10) SET GENERATE ENTRY SW, MEND  06000020
.*** GENERATE *   *   *   *   *   *   *   *   *   *   *   *   *   * * * 06400020
.*** 1) IF GENERATE ENTRY SW ON--ERROR                                  06800020
.*** 2) ERROR IF GENTSO ENTRY SW OFF AND OPTIONS=TSO                    07200020
.*** 3) IF GENTSO 2ND-CALL SW ON DO GENR LE, COPIES,MEND                07600020
.*** 4) SET GENERATE ENTRY SW & CHECK PARMS ETC UP TO JOB CARD          08000020
.*** 5) DO GENERATE'S GROUP 2 MACROS                                    08400020
.*** 6) IF GENTSO 1ST CALL SW ON, MEXIT                                 08800020
.********************************************************************** 09200020
         AIF   (&SGMENTB(88) OR &SGMENTB(69)).DO TEST FOR PREVIOUS NTRY 09600020
&QUITONB SETB  (&SGQUITB)                                               09700020
         AIF (NOT &SGSCHDB(44)).DP  OPTIONS=TSO NOT CODED               09800020
.A00     ANOP                                                           09900020
&SGMENTB(69)   SETB 1                   SET GENTSO ENTRY SWITCH         10000020
         AIF ('&GENTYPE(1)' EQ 'ALL').A0   ALL GEN?                     10200020
         AIF ('&GENTYPE(1)' EQ 'PROCESSOR').A1 PROC GEN?                10400020
         AGO   .B22                                                     10600020
.A0      AIF (NOT &SGMENTB(61) AND NOT &SGMENTB(62)).A3  NO EDIT OR OUT 10800020
         AIF (&SGMENTB(60)).A4             CMDLIB?                      11000020
  MNOTE 5,'* * * IEITSO005 CMDLIB MUST BE SPECIFIED WITH OUTPUT OR     *11200020
                           EDIT ON SYSGEN TYPE ALL'                     11400020
&SGQUITB SETB  1                          SET QUIT SWITCH               11600020
         AGO   .A2                        SEE IF CMDVOL,NAME SPECIFIED  11800020
.A1      ANOP                                                           11850020
&GETB(2) SETB  1                                                        11900020
         AIF (&SGMENTB(60)).A4             CMDLIB?                      11950020
         AIF   (NOT &SGMENTB(61) AND NOT &SGMENTB(62)).B222 NO EDIT,OUT 12000021
         AGO   .A4                        CHECK CMDVOL,NAME PARMS       12400020
.A2      AIF (T'&CMDVOL EQ 'O' AND T'&CMDNAME EQ 'O').B8 OMITTED PARMS? 12600020
  MNOTE 0,'* * * IEITSOW10 CMDVOL/CMDNAME PARAMETERS IGNORED-          *12800020
                            CMDLIB MACRO WAS NOT SPECIFIED'             13000020
         AGO   .B8                        CALL TSGEN100                 13200020
.A3      AIF (NOT &SGMENTB(60)).A2         NO CMDLIB?                   13400020
.A4      AIF (N'&CMDVOL NE N'&CMDNAME).DM  NOT CORRECTLY SPECIFIED      13600020
         AIF ('&CMDNAME' EQ '').B6        NOT SPECIFIED-DEFAULT SYSRES  13800020
         AIF   ((K'&CMDNAME GT 8) OR (K'&CMDVOL GT 6)).DQ               13900020
&SGCTRLC(23)   SETC  '&CMDVOL'                                          14000020
&SGCTRLC(24)   SETC  '&CMDNAME'                                         14200020
   MNOTE *,'CMDLIB WILL RESIDE ON DEVICE &CMDNAME VOLUME &CMDVOL'       14300020
         AGO   .B8                        CALL TSGEN100                 14400020
.B6      ANOP                                                           14600020
&SGCTRLC(23)   SETC  '&RESVOL'                                          14800020
&SGCTRLC(24)   SETC  '&RESNAME'                                         15000020
   MNOTE *,'CMDLIB WILL RESIDE ON SYSRES'                               15100020
         AGO   .B8                        CALL TSGEN100                 15200020
.DM MNOTE 5,'* * * IEITSO015 CMDVOL/CMDNAME PARAMETERS CONTRADICTORY'   15400020
&SGQUITB SETB  1                          SET QUIT SWITCH               15600020
         AGO   .B8                        CALL TSGEN100                 15800020
.DO MNOTE 5,'* * * IEITSO020 GENERATE OR GENTSO MACRO PREVIOUSLY USED'  16000020
         MEXIT                                                          16200020
.DP MNOTE 5,'* * * IEITSO025 OPTIONS=TSO MUST BE CODED ON              *16400020
                             SCHEDULR MACRO IF GENTSO IS CODED'         16600020
&SGQUITB SETB  1                                                        16800020
         AGO   .A00                                                     16900020
.DQ MNOTE 5,'* * * IEITSO030 CMDNAME VALUE &CMDNAME INVALID OR CMDVOL  *17000020
               VALUE &CMDVOL INVALID'                                   17100020
&SGQUITB SETB  1                                                        17200020
.*  *  *  *    TSO ERROR CHECKING    *  *  *  *                         17600020
.B8      ANOP                                                           18000020
*** TSGEN100 ***                                          *** C9505 *** 18200020
         TSGEN100                                                       18400020
.B222    ANOP                                                           18450021
&SGMENTB(70)   SETB 1                   SET GENERATE 1ST CALL SWITCH    18800020
.*  *  *  *  *  CALL GENERATE FOR GROUP 2 ASSEMBLY MACROS  *  *  *  *   19200020
.* * * * * * * * * * * *                                                19600020
.B22     ANOP                                                           20000020
 GENERATE  UT1SDS=&UT1SDS,UT2SDS=&UT2SDS,UT3SDS=&UT3SDS,UT4SDS=&UT4SDS,*20400020
               OBJPDS=&OBJPDS,RESNAME=&RESNAME,RESVOL=&RESVOL,RESTYPE=&*20800020
               RESTYPE,LNKNAME=&LNKNAME,LNKVOL=&LNKVOL,GENTYPE=&GENTYPE*21200020
               ,INDEX=&INDEX,UTDISP=&UTDISP,JOBSTMT=&JOBSTMT,SYOUTDV=&S*21700020
               YOUTDV,LOGREC=&LOGREC,DIRDATA=&DIRDATA,         SA68152 *22200021
               ASMPRT=&ASMPRT,LEPRT=&LEPRT                              22700020
.* * * * * * * * * * * *                                                23200020
         AIF   (&SGMENTB(16)).OVRIDE                                    23600020
       AIF  (&SGQUITB).MEND                                             24000020
.OVRIDE  AIF   (&GETB(1) OR &GETB(3)).B52    TEST FOR I/O, NUC GENTYPES 24400020
         AIF   (&SGMENTB(71)).B52       TEST FOR 2ND RETURN - ALL DONE  24800020
         AIF (&GETB(2)).B10                PROC ONLY GEN?               25000020
*** SGIKJ2LP *** TSO SCHEDULER                            *** C5555 *** 25200020
         SGIKJ2LP                                                       25400020
.B10     AIF (NOT &GETB(2) AND NOT &SGMENTB(60)).B20 NOT ALL,NO CMDLIB  25600020
         AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(61)).B12   25800020
*** SGIKJ2EB *** TSO EDIT                                 *** UL506 *** 26000020
         SGIKJ2EB                                                       26200020
.B12     AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(62)).B20   26400020
*** SGIKJ2EF *** TSO TYPE 1 UTILITIES                     *** UN506 *** 26600020
         SGIKJ2EF                                                       26800020
.B20     ANOP                                                           27200020
.***** INSERT GROUP 4'S HERE                                            27600020
.*     INITIALIZE SWITCHES TO NULL                                      28000020
&SGCTRLC(6)    SETC ''                                                  28400020
&SGCTRLC(10)   SETC ''                                                  28800020
&SGCTRLC(11)   SETC ''                                                  29200020
&SGCTRLC(12)   SETC ''                                                  29600020
&SGCTRLC(13)   SETC ''                                                  30000020
&SGCTRLC(14)   SETC ''                                                  30400020
.*  *  *  SET LINKAGE EDIT CHARACTERISTICS  *  *  *  *  *               30800020
&SGCTRLC(4)    SETC  ''                                                 31200020
.* REMOVAL OF LBMAINT PARAMETER 31600020, 32000020,32400020     PTM0003 31600021
&SGCTRLC(1)    SETC  ''                                                 32800020
&SGCTRLC(2)    SETC  ''                                                 33200020
         AIF   (('&LEPRT(1)' EQ '') AND ('&LEPRT(2)' EQ '')).B28        33600020
         AIF   ('&LEPRT(2)' EQ '').B26                                  34000020
&SGCTRLC(2)    SETC  ',&LEPRT(2)'                                       34400020
.B26     ANOP                                                           34800020
&SGCTRLC(1)    SETC  ',&LEPRT(1)'                                       35200020
.B28     ANOP                                                           35600020
         AIF   (&GETB(2)).B30           TEST FOR PROC (NOT ALL) GENTYPE 36000020
*** SGIKJ4EA *** TSO SUPERVISOR                           *** C2555 *** 36200020
         SGIKJ4EA                                                       36400020
*** SGIKJ4EC *** TSO DATA MANAGEMENT                      *** CI555 *** 36600020
         SGIKJ4EC                                                       36800020
.B30     ANOP                                                   SA69763 36850021
*** SGIKJ445 *** TSO SCHEDULER                            *** C5555 *** 37400020
         SGIKJ445                                                       37600020
*** SGIKJ4EH *** TSO TYPE 1 UTILITIES                     *** UN506 *** 37610020
         SGIKJ4EH                                                       37620020
*** SGIKJ4IE *** TSO LINK EDIT F PROMPTER                 *** ED521 *** 37630020
         SGIKJ4IE                                                       37660020
.B31     AIF (NOT &GETB(2) AND NOT &SGMENTB(60)).B32                    37700020
         AIF (NOT &SGMENTB(60)).B31B      CMDLIB?                       37800020
*** SGIKJ4EG *** TSO TEST                                 *** UM506 *** 37900020
         SGIKJ4EG                                                       38000020
.B31B    AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(61)).B31D  38100020
*** SGIKJ4EB *** TSO EDIT                                 *** UL506 *** 38200020
         SGIKJ4EB                                                       38300020
.B31D    AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(62)).B32   38400020
*** SGIKJ4EF *** TSO TYPE 1 UTILITIES                     *** UN506 *** 38500020
         SGIKJ4EF                                                       38600020
.B32     ANOP                                                           39600020
.*  *  *  *  MOVE - COPY JCL FOR GROUP 5 MACRO CALLS  *  *  *  *        40000020
         AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(61)       X40100020
               AND NOT &SGMENTB(62) AND NOT &SGMENTB(59) AND NOT       X40200020
                &SGMENTB(65)).RXC         NO NEED FOR MOVE-COPY JCL     40300020
&SGCTRLA(1)    SETA &SGCTRLA(1)+1                                       40400020
&SGCTRLC(11)   SETC '&RESNAME'                                          40800020
&SGCTRLC(12)   SETC '&RESVOL'                                           41200020
&SGCTRLC(13)   SETC '&SGCTRLC(31)'                                      41600020
&SGCTRLC(14)   SETC '&SGCTRLC(32)'                                      42000020
*** GENTSO *** SYSGEN                                     *** C9555 *** 42400020
 PUNCH '//SG&SGCTRLA(1) EXEC PGM=IEBCOPY,COND=(8,LT)'                   42800020
 PUNCH '//SYSUT3 DD DISP=SHR,DSNAME=SYS1.&SGCTRLC(3)'                   43200020
 PUNCH '//SYSUT4 DD DISP=SHR,DSNAME=&UT4SDS'                            43600020
 PUNCH '//SYSPRINT DD SPACE=(121,(750,100),RLSE),'                      44600020
 PUNCH '//             DCB=(RECFM=FB,LRECL=121,BLKSIZE=121),           *45200020
                       X'                                               45600020
 PUNCH '//             SYSOUT=A&SGCTRLC(46)&SGCTRLC(47)&SGCTRLC(48)'    46000020
 PUNCH '//CI535 DD DISP=SHR,VOL=(,RETAIN),DSN=SYS1.CI535'               46300020
 PUNCH '//CI555 DD DISP=SHR,VOL=(,RETAIN),DSN=SYS1.CI555'               46600020
         AIF (&GETB(2) AND NOT &SGMENTB(60)).B32B   PROC, NO CMDLIB     46900020
 PUNCH '//DM508 DD DISP=SHR,VOLUME=(,RETAIN),DSN=SYS1.DM508'            46950020
 PUNCH '//CI505 DD DISP=SHR,VOL=(,RETAIN),DSN=SYS1.CI505'               47050020
.B32B    AIF (NOT &SGMENTB(59)).B35    TEST FOR TSO HELP MACRO          47300020
.B33     AIF   ('&SGCTRLC(51)' NE '').B34    TEST FOR UNIT/VOLNO SPEC'D 47600020
&SGCTRLC(51)   SETC '&RESNAME'          SET DEFAULT VALUES              48000020
&SGCTRLC(52)   SETC '&RESVOL'                                           48400020
.B34     ANOP                                                           48800020
 PUNCH '//DHELP DD DISP=SHR,VOLUME=(,RETAIN),DSNAME=SYS1.DHELP'         49200020
 PUNCH '//HELP DD DSNAME=&SGCTRLC(40)..HELP,VOLUME=(,RETAIN,SER=&SGCTRL*49600020
               C(52)),            XXXXXXXX'                             50000020
 PUNCH '//             UNIT=&SGCTRLC(51),DISP=OLD'                      50400020
.B35     AIF   (NOT &SGMENTB(65)).B37    TEST FOR TSO UADS MACRO        50800020
         AIF   ('&SGCTRLC(49)' NE '').B36    TEST FOR UNIT/VOLNO SPEC'D 51200020
&SGCTRLC(49)   SETC '&RESNAME'          SET DEFAULT VALUES              51600020
&SGCTRLC(50)   SETC '&RESVOL'                                           52000020
.B36     ANOP                                                           52400020
 PUNCH '//DUADS DD DISP=SHR,VOLUME=(,RETAIN),DSNAME=SYS1.DUADS'         52800020
 PUNCH '//UADS DD DSNAME=&SGCTRLC(40)..UADS,VOLUME=(,RETAIN,SER=&SGCTRL*53200020
               C(50)),            XXXXXXXX'                             53600020
 PUNCH '//             UNIT=&SGCTRLC(49),DISP=OLD'                      54000020
.B37     AIF (NOT &GETB(2) AND NOT &SGMENTB(60)).B39  NO DD  CARDS      54300020
         AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(61) AND   X54600020
                NOT &SGMENTB(62)).B39      NO DD  CARDS                 54900020
 PUNCH '//DCMDLIB DD DISP=SHR,VOLUME=(,RETAIN),DSNAME=SYS1.DCMDLIB'     56400020
 PUNCH '//CMDLIB DD DSN=&SGCTRLC(40)..CMDLIB,VOL=(,RETAIN,SER=&SGCTRLC(*56800020
               23)),'                                                   57200020
 PUNCH '//             UNIT=&SGCTRLC(24),DISP=OLD'                      57600020
.B39     ANOP                                                           58000020
 PUNCH '//SVCLIB DD DSNAME=&SGCTRLC(40)..SVCLIB,VOLUME=(,RETAIN,SER=&SG*58400020
               CTRLC(12)),        XXXXXXXX'                             58800020
 PUNCH '//             UNIT=&SGCTRLC(11),DISP=OLD'                      59200020
 PUNCH '//LINKLIB DD DSNAME=&SGCTRLC(40)..LINKLIB,VOLUME=(,RETAIN,SER=&*59600020
               SGCTRLC(14)),      XXXXXXXX'                             60000020
 PUNCH '//             UNIT=&SGCTRLC(13),DISP=OLD'                      60400020
 PUNCH '//SYSIN DD *'                                                   60800020
.***** INSERT GROUP 5'S HERE                                            61200020
         AIF   (NOT &SGMENTB(59)).B40A  TEST FOR HELP MACRO             62000020
 PUNCH ' COPY OUTDD=HELP,INDD=DHELP'                                    62400020
.B40A    AIF   (NOT &SGMENTB(65)).B40C  TEST FOR UADS MACRO             62800020
 PUNCH ' COPY OUTDD=UADS,INDD=DUADS'                                    63200020
.B40C    AIF   (&GETB(2)).B40E          TEST FOR PROCESSOR GENTYPE      63600020
*** SGIKJ5EA *** TSO SUPERVISOR                           *** C2555 *** 63800020
         SGIKJ5EA                                                       64000020
*** SGIKJ5EC *** TSO DATA MANAGEMENT                      *** CI555 *** 64100020
         SGIKJ5EC                                                       64200020
.B40E    AIF (NOT &GETB(2) AND NOT &SGMENTB(60)).B40F NO PROC,NO CMDLIB 64250000
         AIF (&GETB(2) AND NOT &SGMENTB(60)).B40F PROC, NO CMDLIB       64400000
*** SGIKJ5IE *** TSO LINK EDIT F PROMPTER                 *** ED521 *** 64600020
         SGIKJ5IE                                                       64800020
.B40F    AIF (NOT &GETB(2) AND NOT &SGMENTB(60)).B44 NO PROC,NO CMDLIB  65000020
         AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(61)).B42   65200020
*** SGIKJ5EB *** TSO EDIT                                 *** UL506 *** 65400020
         SGIKJ5EB                                                       65600020
.B42     AIF (&GETB(2) AND NOT &SGMENTB(60) AND NOT &SGMENTB(62)).B44   65800020
*** SGIKJ5EF *** TSO TYPE 1 UTILITIES                     *** UN506 *** 66000020
         SGIKJ5EF                                                       66200020
.B44     AIF (&GETB(2) AND NOT &SGMENTB(60)).B46 PROC, NO CMDLIB        66400020
*** SGIKJ5EG *** TSO TEST                                 *** UM506 *** 66600020
         SGIKJ5EG                                                       66800020
*** SGIKJ540 *** TSO SCHEDULER                            *** C5555 *** 67000020
         SGIKJ540                                                       67200020
.B46     AIF (NOT &SGMENTB(60)).B50       CMDLIB?                       67400020
*** SGIKJ5EH *** TSO TYPE 1 UTILITIES                     *** UN506 *** 67600020
         SGIKJ5EH                                                       67800020
.B50     ANOP                                                           68000020
 PUNCH '/*'                                                             68400020
.*  *  *  *  *  RENAME STEP FOR TSO HELP AND UADS DATA SETS  *  *  *  * 68800020
         AIF (NOT &SGMENTB(65) AND NOT &SGMENTB(59)).RXC NO HELP,UADS   69000020
         AIF   ('&INDEX' EQ 'SYS1').RXC                                 69200020
&SGCTRLA(1)    SETA &SGCTRLA(1)+1                                       69600020
 PUNCH '//SG&SGCTRLA(1) EXEC PGM=IEHPROGM,COND=(8,LT)'                  70000020
 PUNCH '//SYSPRINT DD SPACE=(121,(500,40),RLSE),'                       70600020
 PUNCH '//             DCB=(RECFM=FB,LRECL=121,BLKSIZE=121),           *71200020
                       X'                                               71600020
 PUNCH '//             SYSOUT=A&SGCTRLC(46)&SGCTRLC(47)&SGCTRLC(48)'    72000020
 PUNCH '//SYSRES DD DISP=OLD,VOLUME=(,RETAIN,SER=&RESVOL),UNIT=&RESNAME*72400020
               '                                                        72800020
.RNA     AIF   (NOT &SGMENTB(59)).RNB   TEST FOR TSO HELP DATA SET      73200020
 PUNCH '//HEL DD DISP=OLD,VOLUME=(,RETAIN,SER=&SGCTRLC(52)),UNIT=&SGCTR*73600020
               LC(51) '                                                 74000020
.RNB     AIF   (NOT &SGMENTB(65)).RNC   TEST FOR TSO UADS DATA SET      74400020
 PUNCH '//UAD DD DISP=OLD,VOLUME=(,RETAIN,SER=&SGCTRLC(50)),UNIT=&SGCTR*74800020
               LC(49) '                                                 75200020
.RNC     ANOP                                                           75600020
 PUNCH '//SYSIN DD *'                                                   76000020
.RXA     AIF   (NOT &SGMENTB(59)).RXB   TEST FOR TSO HELP DATA SET      76400020
 PUNCH ' RENAME DSNAME=&INDEX..HELP,NEWNAME=SYS1.HELP,                 *76800020
                      XXXXXXXX'                                         77200020
 PUNCH '               VOL=&SGCTRLC(51)=&SGCTRLC(52)'                   77600020
.RXB     AIF   (NOT &SGMENTB(65)).RXC   TEST FOR TSO UADS               78000020
 PUNCH ' RENAME DSNAME=&INDEX..UADS,NEWNAME=SYS1.UADS,                 *78400020
                      XXXXXXXX'                                         78800020
 PUNCH '               VOL=&SGCTRLC(49)=&SGCTRLC(50)'                   79200020
.RXC     ANOP                                                           79600020
.*  *  *  *  TSO MACRO'S ARE THROUGH - CALL GENERATE FOR REMAINING *  * 80000020
&SGMENTB(71)   SETB 1                   SET GENERATE 2ND CALL SWITCH    80400020
         AGO   .B22                     GO TO CALL GENERATE             80800020
.B52     ANOP                                                           81200020
&SGMENTB(88)   SETB 1                   SET GENERATE ENTRY SWITCH       81600020
.MEND    MEND                                                           82000020
