 MACRO                                                                  00600016
   GJOBCTL &UNITS=,&SYSOUT=,&PRI=,&CLASS=,&ALLOC=(20,5),&REGION=OMIT,  *01000018
               &TYPE=GJP,&LINEREF=FT99F001,                            *01400017
               &UNITREF=SYSDSPLY,&LINE=50,&DAPOOL=SYSDA                 01900017
 COPY SGGBLPAK                                                          02400016
 LCLA &B                                                                03000016
 LCLA &A                                                                03300017
 AIF (&SGMENTB(29)).E1                 HAS MACRO BEEN ENTERED BEFORE    03600016
&SGMENTB(29)  SETB  1                                                   04200016
 AIF (T'&TYPE EQ '').A1A2                    2250'S ONLY                04270017
 AIF (N'&TYPE GT 1).A1B                         BOTH SPECIFIED          04340017
 AIF ('&TYPE' EQ 'GJP').A1A2                 2250'S ONLY                04410017
 AIF ('&TYPE' EQ 'SGJP').A1A                  SATELLITE SPECIFIED       04480017
 AGO .EF                                                                04550017
.A1B AIF ('&TYPE(1)' EQ 'SGJP' OR '&TYPE(2)' EQ 'SGJP').A1A   SAT.      04620017
 AGO .EG                                                                04690017
.A1B1 AIF ('&TYPE(1)' EQ 'GJP' OR '&TYPE(2)' EQ 'GJP').A1A2   2250'S    04760017
 AGO .EH                                                                04830017
.A1A ANOP                                                               04900017
    MNOTE *,'      THE SATELLITE GRAPHIC JOB PROCESSOR IS INCLUDED'     04970017
&SGGJCB(7) SETB  1                                                      05040017
 AIF (T'&LINEREF EQ '').EI              SPECIFIED INCORRECTLY           05110017
 AIF ('&LINEREF'(1,1) LT 'A' OR '&LINEREF'(1,1) GT 'Z').EI              05180017
 AIF (K'&LINEREF GT 8).EI                     GREATER THAN 8 CHAR       05250017
&SGGJCC(11) SETC '&LINEREF'                                             05320017
    MNOTE *,'      &LINEREF IS DEFAULT OPTION FOR UNIT DDNAME'          05390017
 AIF (N'&TYPE GT 1).A1B1                                                05460017
 AGO .A1C                                                               05530017
.A1A2 ANOP                                                              05740017
    MNOTE *,'      THE GRAPHIC JOB CONTROL FUNCTION WILL BE INCLUDED'   05810017
    MNOTE *,'      2250 DISPLAY UNITS FOR GRAPHIC JOB CONTROL OPERATIONX05880017
               S ARE '                                                  05950017
&SGGJCB(6) SETB  1                                                      06020017
.A1C  ANOP                                                              06300016
 AIF (T'&UNITS EQ 'O').E2                                               06600016
 AIF (N'&UNITS GT 15).E3                                                07200016
&SGGJCA(1) SETA N'&UNITS                                                07800016
     MNOTE *,'       DEVICE ADDRESSES SPECIFIED'                        08100017
.A1  ANOP                                                               08400016
&B SETA  &B+1                                                           09000016
  AIF (&B GT N'&UNITS OR &B GT 15).A2                                   09600016
 CONVERT TO=HEX,VALUE=&UNITS(&B),DIGITS=3                               10200016
    MNOTE *,'                &UNITS(&B) '                               10800016
&SGGJUA(&B) SETA &HEX                                                   11400016
  AGO .A1                                                               12000016
.A2 AIF (T'&SYSOUT EQ 'O').E4                                           12600016
 AIF (N'&SYSOUT NE 4 OR K'&SYSOUT(1) NE 1 OR K'&SYSOUT(2) NE 1 OR K'&SYX13200016
               SOUT(3) NE 1 OR K'&SYSOUT(4) NE 1).E5                    13800016
.A21 ANOP                                                               13880017
&A  SETA &A+1                                                           13960017
 AIF (NOT('&SYSOUT(&A)' LT 'A' OR '&SYSOUT(&A)' GT '9') AND NOT('&SYSOUX14040017
               T(&A)' GT 'Z' AND '&SYSOUT(&A)' LT '0')).A22             14120017
  AGO .E4                                                               14200017
.A22 AIF (&A NE 4).A21                                                  14280017
&SGGJCC(1) SETC '&SYSOUT(1)&SYSOUT(2)&SYSOUT(3)&SYSOUT(4)'              14400016
    MNOTE *,'      SYSTEM OUTPUT CLASSES USED DURING GRAPHIC JOB CONTROX15000016
               L OPERATIONS ARE &SYSOUT(1),&SYSOUT(2),&SYSOUT(3),&SYSOUX15600016
               T(4)'                                                    16200016
.A3 AIF (T'&PRI EQ 'O').A4                                              16800016
 AIF (N'&PRI NE 2).E6                                                   17200017
 AIF (&PRI(1) LT 0 OR &PRI(1) GT 13 OR &PRI(2) LT 0 OR &PRI(2) GT 13).EX17600017
               6                                                        18000017
&SGGJCB(1)  SETB   1                                                    18600016
&SGGJCA(2) SETA &PRI(1)                                                 19200016
&SGGJCA(3) SETA &PRI(2)                                                 19800016
    MNOTE *,'      PRIORITY ASSIGNED FOR GRAPHIC JOBS IS &PRI(1)'       20400016
    MNOTE *,'      PRIORITY ASSIGNED FOR BATCH JOBS IS &PRI(2)'         21000016
.A4 AIF ('&REGION' EQ 'OMIT').A5                                        21600018
 AIF (N'&REGION NE 3).E7                                                22200016
 AIF ('&REGION(1)' EQ '').A41                                           22600018
 AIF (T'&REGION(1) NE 'N').E7                                           23000018
 AIF (&REGION(1) LT 1).E7         INVALID REGION                        23050021
&SGGJCA(4) SETA &REGION(1)                                              23400018
  MNOTE *,'      REGION SIZE FOR GRAPHIC JOB PROCESSOR IS &REGION(1) '  23800018
.A41     AIF   ('&REGION(2)' EQ '').A42                                 24000020
         AIF   (T'&REGION(2) NE 'N').E7                                 24200020
         AIF (&REGION(2) LT 1).E7  INVALID REGION                       24250021
&SGGJCA(5) SETA &REGION(2)                                              24600018
   MNOTE *,'      REGION SIZE FOR GRAPHIC JOBS IS &REGION(2)'           25000018
.A42     AIF   ('&REGION(3)' EQ '').A5                                  25200020
         AIF   (T'&REGION(3) NE 'N').E7                                 25400020
         AIF   (&REGION(3) LT 1).E7 INVALID REGION                      25450021
&SGGJCA(6) SETA &REGION(3)                                              25800018
&SGGJCB(2) SETB 1                                                       26200018
    MNOTE *,'      REGION SIZE FOR BATCH JOBS IS &REGION(3)'            27600016
.A5 AIF (T'&CLASS EQ 'O').A6                                            28200016
    AIF (N'&CLASS LT 2 OR N'&CLASS GT 3).E8  ONLY TWO OR THREE ALLOWED  28800017
     AIF (K'&CLASS(1) NE 1 OR K'&CLASS(2) NE 1).E8                      29400016
&SGGJCB(3) SETB 1                                                       30000016
&SGGJCC(2) SETC '&CLASS(1)&CLASS(2)'                                    30600016
    MNOTE *,'      JOB CLASS FOR GRAPHIC JOBS IS &CLASS(1)'             31200016
    MNOTE *,'      JOB CLASS FOR BATCH JOBS IS &CLASS(2)'               31800016
    AIF (N'&CLASS NE 3).A6                   ONLY TWO PARAMETERS        31900017
    AIF (K'&CLASS(3) NE 1).E8                                           32000017
    AIF (NOT &SGGJCB(7)).EJ             SGJP NOT SPECIFIED              32100017
&SGGJCB(8) SETB 1                                                       32200017
    MNOTE *,'      JOB CLASS FOR INITIAL PROCESSOR(SGJP) IS &CLASS(3)'  32300017
&SGGJCC(2) SETC '&CLASS(1)&CLASS(2)&CLASS(3)'                           32400017
.A6 AIF (N'&ALLOC GT 2).E9                                              33000016
&SGGJCA(7)  SETA  20                                                    33600016
&SGGJCA(8) SETA 5                                                       34200016
 AIF ('&ALLOC(1)' EQ '').A61                                            34800016
 AIF (T'&ALLOC(1) NE 'N').E9                                            35400016
 AIF ((&ALLOC(1) LT 1) OR (&ALLOC(1) GT 9999)).E9                       35450021
&SGGJCA(7)  SETA  &ALLOC(1)                                             36000016
.A61 AIF ('&ALLOC(2)' EQ '').A62                                        36600016
 AIF (T'&ALLOC(2) NE 'N').E9                                            37200016
 AIF ((&ALLOC(2) LT 1) OR (&ALLOC(2) GT 9999)).E9  INCORRECT ALLOC      37250021
&SGGJCA(8) SETA &ALLOC(2)                                               37800016
.A62 ANOP                                                               38400016
    MNOTE *,'      &SGGJCA(7) IS PRIMARY ALLOCATION FOR NEW DATA SETS'  39000016
    MNOTE *,'      &SGGJCA(8) IS SECONDARY ALLOCATION FOR NEW DATA SETSX39600016
               '                                                        40200016
.A7 AIF (K'&UNITREF GT 8).EA                                            40800016
 AIF ('&UNITREF'(1,1) LT 'A' OR '&UNITREF'(1,1) GT 'Z').EA              41100016
&SGGJCC(3) SETC '&UNITREF'                                              41400016
    MNOTE *,'      &UNITREF IS DEFAULT OPTION FOR DISPLAY UNIT REFERENCX42000016
               E'                                                       42600016
.AC AIF (T'&LINE NE 'N').ED                                             56400016
 AIF (&LINE LT 10 OR &LINE GT 99).ED                                    57000016
&SGGJCA(11) SETA &LINE                                                  57600016
    MNOTE *,'      MAXIMUM LINES PER PAGE OF PRINTED RECORD IS &LINE '  58200016
.AD AIF (K'&DAPOOL GT 8).EE                                             58800016
&SGGJCC(10) SETC '&DAPOOL'                                              59400016
    MNOTE *,'      DEFAULT OPTION FOR DIRECT ACCESS POOL IS &DAPOOL'    60000016
.AE MEXIT                    THIS IS END OF PROCESSING IN MACRO         60600016
.E1 MNOTE 5,'* * * IEIGJC100 MACRO HAS BEEN PREVIOUSLY SPECIFIED'       61200016
&SGQUITB SETB 1                                                         61800016
 AGO .END                                                               62400016
.E2 MNOTE 5,'* * * IEIGJC101 UNITS PARAMETER NOT SPECIFIED'             63000016
&SGQUITB SETB 1                                                         63600016
 AGO .A2                                                                64200016
.E3 MNOTE 5,'* * * IEIGJC102 MAXIMUM OF 15 UNITS EXCEEDED'              64800016
&SGQUITB SETB 1                                                         65400016
 AGO .A1                                                                66000016
.E4 MNOTE 5,'* * * IEIGJC103 SYSOUT PARAMETER NOT SPECIFIED'            66600016
&SGQUITB SETB 1                                                         67200016
 AGO .A3                                                                67800016
.E5 MNOTE 5,'* * * IEIGJC104 SYSOUT VALUE &SYSOUT INVALID'              68400016
&SGQUITB SETB 1                                                         69000016
 AGO .A3                                                                69600016
.E6 MNOTE 5,'* * * IEIGJC105 PRI VALUE &PRI INVALID'                    70200016
&SGQUITB SETB 1                                                         70800016
 AGO .A4                                                                71400016
.E7 MNOTE 5,'* * * IEIGJC106 REGION VALUE &REGION INVALID'              72000016
&SGQUITB SETB 1                                                         72600016
 AGO .A5                                                                73200016
.E8 MNOTE 5,'* * * IEIGJC107 CLASS VALUE &CLASS INVALID'                73800016
&SGQUITB SETB 1                                                         74400016
 AGO .A6                                                                75000016
.E9 MNOTE 5,'* * * IEIGJC108 ALLOC VALUE &ALLOC INVALID'                75600016
&SGQUITB SETB 1                                                         76200016
 AGO .A7                                                                76800016
.EA MNOTE 5,'* * * IEIGJC109 UNITREF VALUE &UNITREF INVALID'            77400016
&SGQUITB SETB 1                                                         78000016
 AGO .AC                                                                82200016
.ED MNOTE 5,'* * * IEIGJC112 LINE VALUE &LINE INVALID'                  82800016
&SGQUITB SETB 1                                                         83400016
 AGO .AD                                                                84000016
.EE MNOTE 5,'* * * IEIGJC113 DAPOOL VALUE &DAPOOL INVALID'              84600016
&SGQUITB SETB 1                                                         85200016
 AGO .AE                                                                85800016
.EF MNOTE 5,'* * * IEIGJC114 TYPE VALUE &TYPE INVALID'                  85830017
&SGQUITB SETB 1                                                         85860017
 AGO .A1A2                                                              85890017
.EG MNOTE 5,'* * * IEIGJC115 TYPE SGJP &TYPE(1) OR &TYPE(2) INVALID'    85920017
&SGQUITB SETB 1                                                         85950017
 AGO .A1B1                                                              85980017
.EH MNOTE 5,'* * * IEIGJC116 TYPE GJP &TYPE(1) OR &TYPE(2) INVALID'     86010017
&SGQUITB SETB 1                                                         86040017
 AGO .A1A2                                                              86070017
.EI MNOTE 5,'* * * IEIGJC117 LINEREF VALUE &LINEREF INVALID'            86100017
&SGQUITB SETB 1                                                         86130017
 AGO .A1C                                                               86160017
.EJ MNOTE 5,'* * * IEIGJC118 THIRD CLASS PARAMETER SPECIFIED WITHOUT   X86180017
               SGJP'                                                    86200017
&SGQUITB SETB 1                                                         86220017
 AGO .A6                                                                86310017
.END MEND                                                               86400016
