         MACRO                                                          00020000
&NAME IOCONTRL &UNIT=,&ADDRESS=,&MODEL=,&FEATURE=,&EXPBFR=              00040016
         COPY  SGGBLPAK                                                 00060000
         LCLA  &A,&B,&C                                                 00080000
         LCLA  &K,&L                                                    00100000
         LCLC  &ID                                                      00120000
         LCLC &CHANNEL                                                  00140000
      AIF   (&SGMENTB(3)).MAX4                                          00160000
&SGMENTB(3)   SETB   1      IOCONTRL ENTRY SWITCH.                      00180000
         AIF   (&LIMIT(1)).MAX1                                         00200000
         AIF   (&LIMIT(2)).MAX2                                         00220000
         AIF (&LIMIT(3)).MAX3                                           00230018
&SGMAXA(1)  SETA  40                                                    00240000
         AGO   .MX                                                      00260000
.MAX1    ANOP                                                           00280000
&SGMAXA(1)  SETA  80                                                    00300000
         AGO   .MX                                                      00320000
.MAX2    ANOP                                                           00340000
&SGMAXA(1)  SETA  16                                                    00360000
 AGO .MX                                                                00365018
.MAX3  ANOP                                                             00370018
&SGMAXA(1) SETA 255                                                     00375018
.MX MNOTE *,'      MAXIMUM OF &SGMAXA(1) I/O CONTROL UNITS ALLOWED'     00380000
.MAX4    ANOP                                                           00400000
 AIF (NOT &SGNODEV).SETSW                                               00404016
   MNOTE 0,'* * * IEIIOC114 PREVIOUS CONTROL UNIT HAS NO DEVICES'       00408016
.SETSW ANOP                                                             00412016
&SGNODEV SETB 1              INDICATE NO DEVICE ON C.U.                 00416016
&SGCNTRA(2)    SETA &SGCNTRA(2)+1  TOTAL COUNT OF CONTROL UNITS.        00420000
&A       SETA  &SGCNTRA(2)                                              00440000
         AIF   ('&NAME' EQ '').NONAME   ANY NAME FIELD VALUE.           00460000
&ID      SETC  '&NAME'                                                  00480000
         AGO   .CHKM                                                    00500000
.NONAME  ANOP                                                           00520000
&ID      SETC  'UNIT &A'                                                00540000
.CHKM    AIF  (&A GT &SGMAXA(1)).EA                                     00560000
         AIF   (T'&UNIT EQ 'O').E1                                      00580000
&SGUNT1B(&A)   SETB  1                                                  00600000
         AIF   ('&UNIT' EQ '1051').U2                                   00640000
         AIF   ('&UNIT' EQ '2403').U3                                   00660000
         AIF   ('&UNIT' EQ '2404').U4                                   00680000
         AIF   ('&UNIT' EQ '2415').U5                                   00700000
         AIF   ('&UNIT' EQ '2803').U9                                   00740000
         AIF   ('&UNIT' EQ '2804').UA                                   00760000
&SGUNT1B(&A)   SETB  0                                                  00780000
&SGUNT2B(&A)   SETB  1                                                  00800000
         AIF   ('&UNIT' EQ '2701').U6                                   00820000
         AIF   ('&UNIT' EQ '2702').U7                                   00840000
         AIF   ('&UNIT' EQ '2820').UB                                   00860000
         AIF   ('&UNIT' EQ '2821').UC                                   00880000
         AIF   ('&UNIT' EQ '2822').UD                                   00900000
         AIF   ('&UNIT' EQ '2840').UE                                   00920000
         AIF   ('&UNIT' EQ '2841').UF                                   00940000
         AIF   ('&UNIT' EQ '2848').UG                                   00960000
&SGUNT2B(&A) SETB 0                                                     00980000
&SGUNT3B(&A) SETB 1                                                     01000000
         AIF   ('&UNIT' EQ '2703').UH                                   01020000
         AIF   ('&UNIT' EQ '3803').U9A                                  01022021
         AIF   ('&UNIT' EQ '3410').U9B                                  01024021
         AIF   ('&UNIT' EQ '3811').UJ                                   01030020
         AIF   ('&UNIT' EQ '3272').UK                                   01032021
    MNOTE 5,'* * * IEIIOC102 &ID-UNIT VALUE &UNIT INVALID'              01040000
&SGQUITB SETB  1                                                        01060000
         AGO   .ON1                                                     01080000
.U2 MNOTE *,'     1051 DATA COMMUNICATIONS CONTROL UNIT'                01260000
&SGUNU2B(&A)   SETB 1              SECOND GLOBAL UNIT SWITCH.           01280000
         AIF   (T'&MODEL EQ 'O').E2     ERROR IF NO MODEL.              01300000
         AIF   ('&MODEL' EQ '1').M1     MODELS 1   AND N1 ARE VALID.    01320000
         AIF   ('&MODEL' EQ 'N1').M2    ON 1051. IF NOT ONE OF THESE    01340000
    MNOTE 5,'* * * IEIIOC103 &ID-MODEL VALUE &MODEL INVALID'            01360000
&SGQUITB SETB  1                                                        01380000
         AGO   .NEXT1    GO CHECK FOR FEATURES.                         01400000
.E2 MNOTE 5,'* * * IEIIOC104 &ID-MODEL VALUE NOT SPECIFIED'             01420000
&SGQUITB SETB  1                                                        01440000
         AGO   .NEXT1                                                   01460000
.M1 MNOTE *,'        MODEL 1'                                           01480000
&SGUNM1B(&A)   SETB 1              FIRST GLOBAL MODEL SWITCH.           01500000
         AGO   .NEXT1              GO CHECK FOR FEATURES.               01520000
.M2 MNOTE *,'        MODEL N1'                                          01540000
&SGUNM3B(&A)   SETB 1              THIRD GLOBAL MODEL SWITCH.           01560000
.NEXT1   AIF   (T'&FEATURE EQ 'O').ON1                                  01580000
         AIF   ('&FEATURE(1)' EQ 'ALARM').F2      ONLY VALID FEATURE.   01600000
         AGO   .E4                 GO TO COMMON ERROR ROUTINE.          01620000
.F2 MNOTE *,'        AUDIBLE ALARM FEATURE'                             01640000
&SGUNF1B(&A)   SETB 1         FIRST GLOBAL FEATURE SWITCH.              01660000
         AGO   .ERRMORE       GO TO COMMON CHECK FOR MORE FEATURES RTN. 01680000
.U3 MNOTE *,'     2403 MAGNETIC TAPE CONTROL UNIT'                      01700000
&SGUNU3B(&A)   SETB 1         THIRD GLOBAL UNIT SWITCH.                 01720000
         AGO   .UP2404   GO UP TO COMMON MODEL ROUTINE.                 01740000
.U5 MNOTE *,'     2415 MAGNETIC TAPE CONTROL UNIT'                      01760000
&SGUNU8B(&A)   SETB 1                                                   01780000
         AGO   .UP2404                                                  01800000
.U4 MNOTE *,'     2404 MAGNETIC TAPE CONTROL UNIT'                      01820000
&SGUNU4B(&A)   SETB 1              FOURTH GLOBAL UNIT SWITCH.           01840000
.UP2404  AIF   (T'&MODEL EQ 'O').E3    ERROR IF NO MODEL.               01860000
         AIF   ('&MODEL' EQ '1' OR '&MODEL' EQ '2' OR '&MODEL' EQ      X01880000
               '3').O2                                                  01900000
         AIF  (('&MODEL' EQ '4' OR '&MODEL' EQ '5' OR '&MODEL' EQ '6') *01920000
               AND (&SGUNU3B(&A) OR &SGUNU8B(&A))).O2 2403-2415 MOD456  01940000
.HS MNOTE 5,'* * * IEIIOC103 &ID-MODEL VALUE &MODEL INVALID'            01960000
&SGQUITB SETB  1                                                        01980000
         AGO   .NEXT2         GO CHECK FOR FEATURES.                    02000000
.E3 MNOTE 5,'* * * IEIIOC104 &ID-MODEL VALUE NOT SPECIFIED'             02020000
&SGQUITB SETB  1                                                        02040000
         AGO   .NEXT2         GO CHECK FOR FEATURES.                    02060000
.O2 MNOTE *,'        MODEL &MODEL'                                      02080000
&SGUNM1B(&A)   SETB (&MODEL EQ 1)                                       02100000
&SGUNM2B(&A)   SETB (&MODEL EQ 2)                                       02120000
&SGUNM3B(&A)   SETB (&MODEL EQ 3)                                       02140000
&SGUNM4B(&A)   SETB (&MODEL EQ 4)                                       02160000
&SGUNM5B(&A)   SETB (&MODEL EQ 5)                                       02180000
&SGUNM6B(&A)   SETB (&MODEL EQ 6)                                       02200000
         AGO   .NEXT2         GO CHECK FOR FEATURES.                    02220000
.U9 MNOTE *,'     2803 MAGNETIC TAPE CONTROL UNIT'                      02400000
&SGUNU6B(&A)   SETB 1              SIXTH GLOBAL UNIT SWITCH.            02420000
         AGO   .MOD12                                                   02440000
.U9A     ANOP                                                           02450021
   MNOTE *,'     3803 MAGNETIC TAPE CONTROL UNIT '                      02452021
&SGUNU3B(&A)   SETB 1                   GLOBAL UNIT SWITCH              02454021
&SGUNF2B(&A)   SETB 1                   DATACONV SWITCH                 02456021
         AGO   .MOD12                                                   02458021
.U9B     ANOP                                                           02458421
   MNOTE *,'     3410 MAGNETIC TAPE CONTROL UNIT '                      02458821
&SGUNU4B(&A)   SETB 1                   GLOBAL UNIT SWITCH              02459221
         AGO   .MOD12                                                   02459621
.UA MNOTE *,'     2804 MAGNETIC TAPE CONTROL UNIT'                      02460000
&SGUNU7B(&A)   SETB 1              SEVENTH GLOBAL UNIT SWITCH.          02480000
.MOD12   AIF   (T'&MODEL EQ 'O').E3   ERROR IF NO MODEL                 02500000
         AIF   ('&MODEL' EQ '1' OR '&MODEL' EQ '2').O2                  02502000
         AIF   ('&UNIT' EQ '3803').HS   ONLY TWO MODELS VALID FOR 3803  02520000
         AIF   ('&MODEL' EQ '3').O2                                     02530000
         AGO   .HS       MODEL VAVUE INVALID                            02540000
.NEXT2   AIF   (&B EQ N'&FEATURE).ON1   CHECK FOR FEATURES.             02560000
&B       SETA  &B+1      THIS FEATURE ROUTINE IS COMMON FOR 2403,2404,  02580000
         AIF   ('&FEATURE(&B)' EQ '800BPI').FX                          02640000
         AIF   ('&FEATURE(&B)' EQ '7-TRACK').F3   2803 AND 2804         02647021
         AIF   ('&UNIT' EQ '3410').NO  NO OTHER FEATURES FOR 3410       02647421
         AIF   ('&FEATURE(&B)' EQ 'ALTCTRL').FG                         02649021
         AIF   ('&FEATURE(&B)' EQ 'DATACONV').F4                        02649421
         AIF   ('&UNIT' EQ '3803').NO  NO OTHER FEATURES FOR 3803       02649821
         AIF   ('&UNIT'(4,1) EQ '4' OR '&UNIT' EQ '2415').NO 2404,2804  02660000
  AIF ('&FEATURE(&B)' EQ '16-DRIVE').F5  AND 2415 CANNOT HAVE 16-DRIVE. 02680000
.NO MNOTE 5,'* * * IEIIOC105 &ID-FEATURE VALUE &FEATURE(&B) INVALID'    02700000
&SGQUITB SETB  1                                                        02720000
         AGO   .NEXT2         GO BACK FOR MORE FEATURES.                02740000
.F3 MNOTE *,'        7-TRACK COMPATIBILITY FEATURE'                     02774000
&SGUNF1B(&A)   SETB 1              FIRST GLOBAL FEATURE SWITCH.         02780000
         AIF   (&SGUNF4B(&A)).FX22A  800BPI FEATURE?                    02782000
         AIF   ('&UNIT' NE '3410').NEXT2  CHECK FOR 3410 7-TRK          02790021
&SGUNF2B(&A)   SETB 1              DEFAULT DATACONV FOR 3410 7-TRK      02792021
         AGO   .NEXT2         GO BACK FOR MORE FEATURES.                02800000
.F4 MNOTE *,'        DATA CONVERSION FEATURE'                           02820000
&SGUNF2B(&A)   SETB 1              SECOND GLOBAL FEATURE SWITCH.        02840000
         AGO   .NEXT2              GO BACK FOR MORE FEATURES.           02860000
.F5 MNOTE *,'        16-DRIVE ADDRESSING FEATURE'                       02880000
&SGUNF3B(&A)   SETB 1              THIRD  GLOBAL FEATURE SWITCH.        02900000
         AGO   .NEXT2              GO BACK FOR MORE FEATURES.           02920000
.FG MNOTE *,'        ALTERNATE CONTROL FEATURE'                         02924019
&SGUNF6B(&A) SETB 1                    ALTERNATE CONTROL THIS C.U.      02928019
&SGMENTB(86) SETB 1                    ALTCTRL SPECIFIED DURING SYSGEN  02932019
 AGO .NEXT2                                                             02936019
.*                                      800BPI FEATURE VALID ONLY ON    02940021
.*                                      MODEL 4,5,OR 6 OF 2403 OR 2415  02950021
.*                                      OR ON MODEL 2 OF 2803 OR 2804   02960021
.*                                      OR ON 3410                      02970021
.*                                      OR ON 3803                      02980021
.FX      AIF   ((&SGUNU3B(&A) OR &SGUNU8B(&A)) AND (&SGUNM4B(&A) OR &SG*02990021
               UNM5B(&A) OR &SGUNM6B(&A))).FX1                          02992021
         AIF   ((&SGUNU6B(&A) OR &SGUNU7B(&A)) AND &SGUNM2B(&A)).FX1    02994021
         AIF   (&SGUNU4B(&A) AND &SGUNT3B(&A)).FX1    VALID FOR 3410    02996021
         AIF   (NOT(&SGUNU3B(&A) AND &SGUNT3B(&A))).NO                  02998021
.FX1     ANOP                                                           02998800
    MNOTE *,'        800 BPI DENSITY FEATURE'                           03000000
&SGUNF4B(&A)   SETB 1                                                   03020000
         AIF   (&SGUNF1B(&A)).FX22A  7-TRACK FEATURE?                   03030000
         AGO  .NEXT2                                                    03040000
.FX2 MNOTE 5,'* * * IEIIOC115 800BPI AND 7-TRACK FEATURES ARE MUTUALLY *03052021
               EXCLUSIVE FOR THE &UNIT CONTROL UNIT'                    03054021
&SGQUITB SETB  1                                                        03056021
         AGO   .NEXT2                                                   03058021
.FX22A   AIF   ('&UNIT' EQ '3410').FX2                          SA69286 03058400
         AIF   ('&UNIT' EQ '3803' AND '&MODEL' NE '2').FX2      SA69286 03058800
         AGO   .NEXT2                                                   03059200
.U6 MNOTE *,'     2701 DATA ADAPTER UNIT'                               03060000
&SGUNU1B(&A)   SETB 1              FIRST GLOBAL UNIT SWITCH.            03080000
         AGO   .NOFEAT                                                  03100000
.U7 MNOTE *,'     2702 TRANSMISSION CONTROL UNIT'                       03120000
&SGUNU2B(&A)   SETB 1              SECOND GLOBAL UNIT SWITCH.           03140000
         AGO   .NOFEAT                                                  03160000
.UB MNOTE *,'     2820 DRUM STORAGE CONTROL UNIT'                       03180000
&SGUNU3B(&A)   SETB 1              THIRD GLOBAL UNIT SWITCH.            03200000
&SGDCLSB(40)  SETB  1                                                   03220000
&SGUNF2B(&A)  SETB  1                                                   03240000
         AIF   (T'&FEATURE EQ 'O').ON1                                  03260000
.RET2820 AIF (&B EQ N'&FEATURE).TSTFEAT                                 03267015
&B SETA &B+1                                                            03274015
 AIF ('&FEATURE(&B)' EQ '2-CHANSW').F7                                  03281015
 AIF ('&FEATURE(&B)' EQ 'SHARED').F71                                   03288015
 MNOTE 5,'* * * IEIIOC105 &ID-FEATURE VALUE &FEATURE(&B) INVALID'       03295015
&SGQUITB SETB 1                                                         03302015
 AGO .RET2820                                                           03309015
.F7 MNOTE *,'        TWO CHANNEL SWITCH'                                03320000
&SGUNF3B(&A)   SETB 1              THIRD GLOBAL FEATURE SWITCH.         03340000
 AGO .RET2820                                                           03343015
.F71 MNOTE *,'        SHARED DASD'                                      03346015
 MNOTE 0,'* * * IEIIOCW01 HARDWARE CHANNEL SWITCHING CAPABILITY MUST BE*03347016
               AVAILABLE WITH SHARED'                                   03348016
&SGUNF5B(&A) SETB 1        FIFTH GLOBAL FEATURE SWITCH                  03349015
&SGDCLSB(54) SETB 1       SHARED DASD CLASS SWITCH                      03352015
 AGO .RET2820                                                           03355015
.TSTFEAT AIF (&SGUNF5B(&A) AND NOT &SGUNF3B(&A)).INCFEAT                03358015
 AGO .ON1                                                               03361015
.INCFEAT MNOTE 5,'* * * IEIIOC113 2-CHANSW REQUIRED WITH SHARED'        03364015
&SGQUITB SETB 1                                                         03367015
 AGO .ON1                                                               03370015
.UC MNOTE *,'     2821 READ,PUNCH AND PRINTER CONTROL UNIT'             03380000
&SGUNU4B(&A)   SETB 1              FOURTH GLOBAL UNIT SWITCH.           03400000
         AIF   (T'&MODEL EQ 'O').E5    NO MODEL ERROR.                  03420000
         AIF  (('&MODEL' EQ '1') OR ('&MODEL' EQ '4') OR ('&MODEL' EQ 'X03440000
               5') OR ('&MODEL' EQ '6')).OK                    @SA79798 03460018
.*           MODELS 1,4,5 OR 6 CAN HAVE COLUMN BINARY FEATURE. @SA79798 03466018
         AIF    ('&MODEL' EQ '2' OR '&MODEL' EQ '3').K2                 03480000
    MNOTE 5,'* * * IEIIOC103 &ID-MODEL VALUE &MODEL INVALID'            03500000
&SGQUITB SETB  1                                                        03520000
         AGO   .ON1                GO CHECK ADDRESS.                    03540000
.E5 MNOTE 5,'* * * IEIIOC104 &ID-MODEL VALUE NOT SPECIFIED'             03560000
&SGQUITB SETB  1                                                        03580000
         AGO   .ON1                GO CHECK ADDRESS.                    03600000
.OK MNOTE *,'        MODEL &MODEL'                                      03620000
&SGUNM1B(&A)   SETB (&MODEL EQ 1)  GLOBAL MODEL SWITCH 1.               03640000
&SGUNM4B(&A)   SETB (&MODEL EQ 4)  GLOBAL MODEL SWITCH 4.               03660000
&SGUNM5B(&A)   SETB (&MODEL EQ 5)  GLOBAL MODEL SWITCH 5.               03680000
&SGUNM6B(&A)   SETB (&MODEL EQ 6)  GLOBAL MODEL SWITCH 6.      @SA79798 03690018
         AIF   (T'&FEATURE EQ 'O').ON1                                  03700000
         AIF   ('&FEATURE(1)' EQ 'COLBNRY').F8    ONLY VALID FEATURE.   03720000
         AGO   .E4       GO TO COMMON ERROR ROUTINE.                    03740000
.F8 MNOTE *,'        COLUMN BINARY FEATURE'                             03760000
&SGUNF1B(&A)   SETB 1                   FIRST FEATURE SWITCH.           03780000
         AGO   .ERRMORE                                                 03800000
.K2 MNOTE *,'        MODEL &MODEL'                                      03820000
&SGUNM2B(&A)  SETB  (&MODEL EQ 2)                                       03840000
&SGUNM3B(&A)   SETB (&MODEL EQ 3)  GLOBAL MODEL SWITCH 3.               03860000
         AGO   .NOFEAT   COMMON ROUTINE FOR ANY FEATURES ARE INVALID.   03880000
.UD MNOTE *,'     2822 PAPER TAPE READER CONTROL'                       03900000
&SGUNU5B(&A)   SETB 1              FIFTH GLOBAL UNIT SWITCH.            03920000
         AGO   .NOFEAT                                                  03940000
.UE MNOTE *,'     2840 DISPLAY OR FILM CONTROL'                         03960000
&SGUNU6B(&A)   SETB 1              SIXTH GLOBAL UNIT SWITCH.            03980000
 AIF (T'&MODEL EQ 'O').EC                                               04000000
 AIF (('&MODEL' NE '1') AND ('&MODEL' NE '2')).ED                       04020000
&SGUNM1B(&A) SETB  ('&MODEL' EQ '1')                                    04040000
&SGUNM2B(&A) SETB ('&MODEL' EQ '2')                                     04060000
    MNOTE *,'      MODEL &MODEL'                                        04080000
.EXPBFR AIF (T'&EXPBFR NE 'O').R1                                       04100000
&SGCUN1A(&A) SETA 4096                                                  04120000
   AGO .R2                                                              04140000
.R1  ANOP                                                               04160000
&SGCUN1A(&A)  SETA  &EXPBFR                                             04180000
.R2 MNOTE *,'      AMOUNT OF BUFFER SPACE IS &SGCUN1A(&A)'              04200000
 AIF (&SGUNM2B(&A)).NOFEAT                                              04220000
  AGO  .CHKF                                                            04240000
.EC MNOTE 5,'* * * IEIIOC104 &ID-MODEL VALUE NOT SPECIFIED'             04260000
&SGQUITB  SETB  1                                                       04280000
 AGO .EXPBFR                                                            04300000
.ED MNOTE 5,'* * * IEIIOC103 &ID-MODEL VALUE &MODEL INVALID'            04320000
&SGQUITB  SETB  1                                                       04340000
 AGO .EXPBFR                                                            04360000
.CHKF    AIF   (T'&FEATURE EQ 'O').ON1                                  04380000
.R3 AIF (&B EQ N'&FEATURE).ON1                                          04400000
&B  SETA  &B+1                                                          04420000
 AIF ('&FEATURE(&B)' EQ 'BUFFER8K').F9                                  04440000
 AIF ('&FEATURE(&B)' EQ 'ABSLTVEC').R4                                  04460000
    MNOTE 5,'* * * IEIIOC105 &ID-FEATURE VALUE &FEATURE(&B) INVALID '   04480000
&SGQUITB  SETB  1                                                       04500000
  AGO  .R3                                                              04520000
.R4 MNOTE *,'      ABSOLUTE VECTOR CONTROL'                             04540000
&SGUNF2B(&A) SETB  1                                                    04560000
 AGO .R3                                                                04580000
.F9 MNOTE *,'        8K BUFFER EXTENSION FEATURE'                       04600000
&SGUNF1B(&A)   SETB 1              FIRST GLOBAL FEATURE SWITCH.         04620000
   AGO  .R3                                                             04640000
.UF MNOTE *,'     2841 DIRECT ACCESS STORAGE CONTROL UNIT'              04660000
&SGUNU7B(&A)   SETB 1              SEVENTH GLOBAL UNIT SWITCH.          04680000
 AIF (T'&FEATURE EQ 'O').ON1   BRANCH IF NO FEATURES                    04690015
.BACK4 AIF (&B EQ N'&FEATURE).FEATST   GO TEST SHARED IF &&B            04700015
&B       SETA  &B+1                     HAS REACHED THE NUMBER OF       04720000
         AIF   ('&FEATURE(&B)' EQ 'RECOFLO').FB   THROUGH THIS ROUTINE. 04760000
         AIF   ('&FEATURE(&B)' EQ '2-CHANSW').FC                        04780000
 AIF ('&FEATURE(&B)' EQ 'ADSTORAG').FD                                  04800000
 AIF ('&FEATURE(&B)' EQ 'SHARED').FF                                    04810015
.FE  ANOP                                                               04820000
    MNOTE 5,'* * * IEIIOC105 &ID-FEATURE VALUE &FEATURE(&B) INVALID'    04840000
&SGQUITB SETB  1                                                        04860000
         AGO   .BACK4                                                   04880000
.FB MNOTE *,'        RECORD OVERFLOW FEATURE'                           04960000
&SGUNF2B(&A)   SETB 1              SECOND GLOBAL FEATURE SWITCH.        04980000
&SGDCLSB(40)  SETB  1                                                   05000000
         AGO   .BACK4              GO CHECK FOR MORE.                   05020000
.FC AIF (&SGUNF4B(&A)).FE                                               05040000
    MNOTE *,'      TWO CHANNEL SWITCH FEATURE'                          05060000
&SGUNF3B(&A)   SETB 1              THIRD FEATURE SWITCH.                05080000
         AGO   .BACK4              GO BACK FOR MORE.                    05100000
.FD AIF (&SGUNF3B(&A)).FE                                               05120000
    MNOTE *,'      ADDITIONAL STORAGE FEATURE'                          05140000
&SGUNF4B(&A)  SETB  1                                                   05160000
  AGO .BACK4                                                            05180000
.FF MNOTE *,'        SHARED DASD'                                       05182015
 MNOTE 0,'* * * IEIIOCW01 HARDWARE CHANNEL SWITCHING CAPABILITY MUST BE*05182616
               AVAILABLE WITH SHARED'                                   05183216
&SGUNF5B(&A) SETB 1        FIFTH GLOBAL FEATURE SWITCH                  05184015
&SGDCLSB(54) SETB 1      SHARED DASD CLASS SWITCH                       05186015
 AGO .BACK4                                                             05188015
.FEATST AIF (&SGUNF5B(&A) AND NOT &SGUNF3B(&A)).INCFEAT                 05190015
 AGO .ON1                                                               05192015
.UG MNOTE *,'     2848 DISPLAY CONTROL UNIT'                            05200000
&SGUNU8B(&A)   SETB 1                                                   05220000
 AIF (T'&MODEL EQ 'O').EB                                               05240000
 AIF (('&MODEL' EQ '1') OR ('&MODEL' EQ '2') OR ('&MODEL' EQ '3')).G1   05260000
 AIF (('&MODEL' EQ '21') OR ('&MODEL' EQ '22')).G1                      05265014
    MNOTE 5,'* * * IEIIOC103 &ID-MODEL VALUE &MODEL INVALID'            05280000
&SGQUITB  SETB  1                                                       05300000
   AGO  .R5                                                             05320000
.G1 MNOTE *,'      MODEL &MODEL'                                        05340000
&SGUNM1B(&A)  SETB  ('&MODEL' EQ '1')                                   05360000
&SGUNM2B(&A)  SETB  ('&MODEL' EQ '2')                                   05380000
&SGUNM3B(&A)  SETB  ('&MODEL' EQ '3')                                   05400000
&SGUNM4B(&A) SETB ('&MODEL' EQ '21')                                    05402014
&SGUNM5B(&A) SETB ('&MODEL' EQ '22')                                    05404014
   AGO  .R5                                                             05420000
.EB MNOTE 5,'* * * IEIIOC104 &ID-MODEL VALUE NOT SPECIFIED'             05440000
&SGQUITB  SETB  1                                                       05460000
.R5  AIF (&B EQ N'&FEATURE).ON1                                         05480000
&B  SETA  &B+1                                                          05500000
  AIF  ('&FEATURE(&B)' EQ 'LINEADDR').R6                                05520000
   AIF ('&FEATURE(&B)' EQ 'NODESCUR').R7                                05540000
    MNOTE 5,'* * * IEIIOC105 &ID-FEATURE VALUE &FEATURE(&B) INVALID'    05560000
&SGQUITB  SETB  1                                                       05580000
  AGO  .R5                                                              05600000
.R6 MNOTE *,'      LINE ADDRESSING FEATURE'                             05620000
&SGUNF1B(&A)  SETB  1                                                   05640000
  AGO  .R5                                                              05660000
.R7 MNOTE *,'      NON-DESTRUCTIVE CURSOR'                              05680000
&SGUNF2B(&A)  SETB  1                                                   05700000
  AGO  .R5                                                              05720000
.E4  AIF  (&B GT 0).E4X                                                 05740000
&B   SETA 1                                                             05760000
.E4X MNOTE 5,'* * * IEII0C105 &ID-FEATURE VALUE &FEATURE(&B) INVALID'   05780000
&SGQUITB SETB  1                                                        05800000
         AGO   .ON1                                                     05820000
.UH MNOTE *,'     2703 TRANSMISSION CONTROL UNIT'                       05840000
&SGUNU1B(&A) SETB 1                                                     05860000
  AGO  .NOFEAT                                                          05880000
.UJ MNOTE *,'     3811 CONTROL UNIT'                                    05885020
&SGUNU2B(&A) SETB 1                                                     05890020
  AGO  .NOFEAT                                                          05895020
.ERRMORE ANOP                                                           05900000
&B       SETA  1                                                        05920000
.NOFEAT  AIF   (&B EQ N'&FEATURE).ON1                                   05940000
&B       SETA  &B+1                                                     05960000
    MNOTE 5,'* * * IEIIOC105 &ID-FEATURE VALUE &FEATURE(&B) INVALID'    05980000
&SGQUITB SETB  1                                                        06000000
         AGO   .NOFEAT                                                  06020000
.E1 MNOTE 5,'* * * IEIIOC101 &ID-UNIT VALUE NOT SPECIFIED'              06040000
&SGQUITB SETB   1                                                       06060000
.ON1     AIF   (T'&ADDRESS EQ 'O').CHECKT ADDRESS NOT SPECIFIED         06080000
&CHANNEL SETC  '&ADDRESS'(1,1)     CHANNEL POSITION OF ADDRESS.         06100000
&SGCNTRU SETC '&ADDRESS'(2,1)  CONTROL UNIT POSITION OF ADDRESS         06120000
 AIF (NOT(('&CHANNEL' GE '0' AND '&CHANNEL' LE '9')OR('&CHANNEL' GE 'A'*06130020
                AND '&CHANNEL' LE 'F'))).CBER                           06140020
 AIF (('&SGCNTRU' GE '0' AND '&SGCNTRU' LE '9')OR('&SGCNTRU' GE 'A' AND*06150020
                '&SGCNTRU' LE 'F')).K4                                  06160020
.CBER MNOTE 5,'* * * IEIIOC107 &ID-ADDRESS VALUE &ADDRESS INVALID'      06190020
&SGQUITB SETB  1                                                        06220000
         AGO   .CHECKT                                                  06240000
.K4 MNOTE *,'        ADDRESS=&CHANNEL&SGCNTRU'                          06260000
.CHECKT AGO .MEND                                                       06360016
.UK MNOTE *,'     3272 CONTROL UNIT'                                    06410021
&SGUNU5B(&A) SETB 1                                                     06460021
         AIF (T'&MODEL EQ 'O').UKO      TEST FOR MODEL NUMBER           06510021
         AIF ('&MODEL' EQ '1').UKM      TEST FOR MODEL 1                06560021
         AIF ('&MODEL' EQ '2').UKM      TEST FOR MODEL 2                06570021
    MNOTE 5,'* * * IEIIOC103 &ID-MODEL VALUE &MODEL INVALID'            06572021
.UKQ     ANOP                                                           06574021
&SGQUITB SETB  1                                                        06576021
         AGO   .NOFEAT                  GO TEST FOR FEATURES            06578021
.UKO MNOTE 5,'* * * IEIIOC104 &ID-MODEL VALUE NOT SPECIFIED'            06578421
         AGO   .UKQ                                                     06578821
.UKM MNOTE *,'        MODEL &MODEL'                                     06579221
&SGUNM1B(&A) SETB ('&MODEL' EQ '1')     SET MODEL 1 SW                  06579621
&SGUNM2B(&A) SETB ('&MODEL' EQ '2')     SET MODEL 2 SW                  06579721
         AGO   .NOFEAT                                                  06579821
.EA MNOTE 5,'* * * IEIIOC112 &ID-MAXIMUM NUMBER OF UNITS EXCEEDED'      06580000
&SGQUITB SETB  1                                                        06600000
.MEND  MEND                                                             06620021
