         MACRO                                                          01000018
         LOADER &PARM=,&SIZE=100K,&LIN=SYSLIN,&LIB=SYSLIB,             *02000018
               &PRINT=SYSLOUT                                           03000018
         COPY  SGGBLPAK                                                 04000018
         LCLA  &A                                                       05000018
         LCLB  &B,&C                                                    06000000
         LCLC  &VAL                                                     07000018
         AIF (&SGMENTB(56)).ER1         LOADER ALREADY CALLED           08000018
&SGMENTB(56)   SETB 1                                                   09000018
&A       SETA  1                                                        10000018
         AIF  (T'&PARM NE 'O').BY1                                      11000000
&SGLDRB(5)     SETB 1              SET DEFAULT OF NORES                 11050000
    AGO  .A2                       ALL DEFAULTS                         11100000
.BY1     AIF  (N'&PARM GT 5).ER2                                        12000000
    MNOTE *,'      PARM FIELD PARAMETERS ARE'                           13000018
.A AIF ('&PARM(&A)' EQ 'NCAL' OR '&PARM(&A)' EQ 'NOCALL' OR '&PARM(&A)'*14000018
                EQ 'CALL').A1                                           15000018
 AIF ('&PARM(&A)' EQ 'LET' OR '&PARM(&A)' EQ 'NOLET' OR '&PARM(&A)' EQ *16000018
               'PRINT').A1                                              17000018
 AIF ('&PARM(&A)' EQ 'NOPRINT' OR '&PARM(&A)' EQ 'MAP' OR '&PARM(&A)' E*18000018
               Q 'RES').A1                                              19000000
 AIF ('&PARM(&A)' EQ 'NOMAP' OR '&PARM(&A)' EQ 'NORES').A1              20000018
         AGO   .ER3                                                     21000018
.A1 MNOTE *,'           &PARM(&A)'                                      22000018
&SGLDRB(1)     SETB ('&PARM(&A)' EQ 'NCAL' OR '&PARM(&A)' EQ 'NOCALL' O*23000018
               R &SGLDRB(1))                                            24000018
&SGLDRB(2)     SETB ('&PARM(&A)' EQ 'LET' OR &SGLDRB(2))                25000018
&SGLDRB(3)     SETB ('&PARM(&A)' EQ 'NOPRINT' OR &SGLDRB(3))            26000018
&SGLDRB(4)     SETB ('&PARM(&A)' EQ 'MAP' OR &SGLDRB(4))                27000018
&SGLDRB(5)     SETB ('&PARM(&A)' EQ 'NORES' OR &SGLDRB(5))              28000000
&C             SETB (&SGLDRB(5))     NO RES SPECIFIED IN PARM FIELD     28050000
.A1A     ANOP                                                           29000018
&A       SETA  &A+1                                                     30000018
         AIF (N'&PARM GE &A).A          RETURN FOR NEXT OPERAND         31000018
         AIF (N'&PARM EQ 5).A8          NO DEFAULTS                     32000000
.A2      ANOP                                                           33000018
    MNOTE *,'      PARM FIELD DEFAULTS ARE '                            34000018
.A3      AIF (&SGLDRB(1)).A4            NCAL OR NOCALL SPECIFIED        35000018
    MNOTE *,'           CALL'                                           36000000
.A4      AIF (&SGLDRB(2)).A5            LET SPECIFIED                   37000018
    MNOTE *,'           NOLET'                                          38000000
.A5      AIF (&SGLDRB(3)).A6            NOPRINT SPECIFIED               39000018
    MNOTE *,'           PRINT'                                          40000000
.A6      AIF (&SGLDRB(4)).A7            MAP SPECIFIED                   41000018
    MNOTE *,'           NOMAP'                                          42000000
.A7      AIF (NOT(&SGLDRB(5)) OR &C).A8 RES SPECIFIED                   43000000
    MNOTE *,'           NORES'                                          44000000
.A8      AIF   (&SGLDRB(1) AND NOT &SGLDRB(5)).ER8  RES AND NOT CALL    44050000
.B       AIF ('&SIZE'(K'&SIZE,1) NE 'K').B1  NO IN ''K'' VALUE          45000018
&B       SETB  1                                                        46000018
&VAL     SETC  '&SIZE'(1,K'&SIZE-1)                                     46400018
&SGLDRA  SETA  &VAL                                                     46800018
&SGLDRA  SETA  &SGLDRA*1024                                             47200018
         AGO   .B2                                                      47600018
.B1      ANOP                                                           48000018
&VAL     SETC  '&SIZE'                                                  48400018
&SGLDRA  SETA  &VAL                                                     49000018
.B2      AIF   (&SGLDRA GT 8388608).ER4                                 49500018
   MNOTE *,'      SIZE VALUE &SIZE INCLUDED'                            50200018
.C       AIF (K'&LIN LT 1 OR K'&LIN GT 8).ER5                           51000018
         AIF ('&LIN'(1,1) LT 'A' OR '&LIN'(1,1) GT 'Z').ER5             52000018
&SGLDRC(1)     SETC '&LIN'                                              53000018
    MNOTE *,'      LIN VALUE &LIN INCLUDED'                             54000018
.D   AIF (K'&PRINT LT 1 OR K'&PRINT GT 8).ER6                           55000018
     AIF ('&PRINT'(1,1) LT 'A' OR '&PRINT'(1,1) GT 'Z').ER6             56000018
&SGLDRC(2)     SETC '&PRINT'                                            57000018
    MNOTE *,'      PRINT VALUE &PRINT INCLUDED'                         58000018
.E       AIF (K'&LIB LT 1 OR K'&LIB GT 8).ER7                           59000018
         AIF ('&LIB'(1,1) LT 'A' OR '&LIB'(1,1) GT 'Z').ER7             60000018
&SGLDRC(3)     SETC '&LIB'                                              61000018
    MNOTE *,'      LIB VALUE &LIB INCLUDED'                             62000018
         MEXIT                                                          63000018
.ER1 MNOTE 5,'* * * IEILDR001 LOADER MACRO PREVIOUSLY SPECIFIED'        64000018
&SGQUITB SETB  1                                                        65000018
         MEXIT                                                          66000018
.ER2 MNOTE 5,'* * * IEILDR002 PARM PARAMETER HAS TOO MANY OPERANDS'     67000018
&SGQUITB SETB  1                                                        68000018
         AGO   .A                                                       69000018
.ER3 MNOTE 5,'* * * IEILDR003 PARM(&A) VALUE &PARM(&A) INVALID'         70000018
&SGQUITB SETB  1                                                        71000018
         AGO   .A1A                                                     72000018
.ER4 MNOTE 5,'* * * IEILDR004 SIZE VALUE &SIZE INVALID'                 73000018
&SGQUITB SETB  1                                                        74000018
         AGO   .C                                                       75000018
.ER5 MNOTE 5,'* * * IEILDR005 LIN VALUE &LIN INVALID'                   76000018
&SGQUITB SETB  1                                                        77000018
         AGO   .D                                                       78000018
.ER6 MNOTE 5,'* * * IEILDR006 PRINT VALUE &PRINT INVALID'               79000018
&SGQUITB SETB  1                                                        80000018
         AGO   .E                                                       81000018
.ER7 MNOTE 5,'* * * IEILDR007 LIB VALUE &LIB INVALID'                   82000018
&SGQUITB SETB  1                                                        83000018
         MEXIT                                                          83050000
.ER8 MNOTE 5,'* * * IEILDR008 RES SPECIFIED AND CALL NOT SPECIFIED'     83100000
&SGQUITB SETB  1                                                        83150000
         AGO   .B                                                       83200000
         MEND                                                           84000018
