         MACRO                                                          00400017
         PARTITNS                                                       00800017
         COPY  SGGBLPAK                                                 01200017
         LCLA  &M,&N,&PT,&O,&RD,&WR,&PB,&LS                             01600017
         LCLB  &C,&EO,&NOSET,&S,&HB0,&HB1,&ZER                          02000017
         LCLC  &PRT,&GV,&SZ                                             02400017
         AIF   (&SGMENTB(18)).MR             PARTITNS ENTRY SWITCH      02800017
         AIF   (N'&SYSLIST EQ 0).P3          NO PARTITNS SPECIFIED      03200017
&SGMENTB(18) SETB 1                                                     03600017
         AIF   (N'&SYSLIST GT 52).P2         TEST FOR MAX NO OF OPERAND 04000017
.BGIN    AIF   (N'&SYSLIST EQ &M).COMP       CHECKING COMPLETE?         04400017
&M       SETA  &M+1                          POINTER TO CORRECT OPERAND 04800017
.CMP2    ANOP                                                           05200017
&N       SETA  &N+1                          POINTER TO CHARACTER       05600017
         AIF   (&N GT 4).P1                  PARTITION CHECK            06000017
         AIF  (K'&SYSLIST(&M) EQ 0).P0                                  06200018
         AIF   ((&N EQ 1) AND ('&SYSLIST(&M)'(&N,1) NE 'P')).P1         06400017
         AIF   ('&SYSLIST(&M)'(&N,1) NE '(').CMP2                       06800017
&PRT     SETC  '&SYSLIST(&M)'(2,&N-2)        PARTITION VALUE SET        07200017
&PT      SETA  &PRT+1                        ADJUST VALUE FOR GLOBAL    07600017
         AIF   (&PT GT 52).P1                MUST BE LESS THAN 53       08000017
         AIF  ((&SGCPRPA(&PT) GT 0) OR (&SGCPRPA(&PT+52) GT 0)).PJ DUPE 08200021
    MNOTE *,'      PARTITION NUMBER &PRT SPECIFIED'                     08400017
.AGAIN   ANOP                                SCAN NEXT PARM             08800017
&N       SETA  &N+1                          *    INCREMENT POINTER     09200017
&O       SETA  &N                            FIRST CHAR WITHIN PAREN    09600017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ 'C').CLASS                      10000017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ 'S').SIZE                       10400017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ 'H').HI                         10800017
         AGO   .P4                               INVALID DESIGNATOR     11200017
.CLASS   ANOP                                     WHICH JOBCLASS?  **** 11600017
&N       SETA  &N+1                               *                     12000017
         AIF  (('&SYSLIST(&M)'(&N,1) EQ ',') OR ('&SYSLIST(&M)'(&N,1) EX12400017
               Q ')')).CEND                       *    END TEST         12800017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ 'R').READ *    READ CLASS       13200017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ 'W').WRITE     WRITE CLASS      13600017
         AIF   ('&SYSLIST(&M)'(&N,1) GE 'A' AND '&SYSLIST(&M)'(&N,1) LEX14000017
                'O').PROB                         *    PROBLEM CLASS    14400017
         AIF  (('&SYSLIST(&M)'(&N,1) EQ '-') AND (&N EQ (&O+1))).CLASS  14800017
         AGO   .P5                                                      15200017
.READ    ANOP                                     READER PARTITION **** 15600017
&RD      SETA  &RD+1                              * COUNTER FOR MAX     16000017
         AIF   (('&SYSLIST(&M)'(&N+1,1) NE ',') AND ('&SYSLIST(&M)'(&N+X16400017
               1,1) NE ')')).P6                    ONE CHARACTER ALLOW  16800017
.X1      AIF   (&O+2 NE &N).CLASS                 FIRST CHARACTER       17200017
&C       SETB  1                                  CLASS SWITCH          17600017
         AGO   .CLASS                             RETURN                18000017
.WRITE   ANOP                                     WRITER PARTITION **** 18400017
&WR      SETA  &WR+1                              WRITER SWITCH         18800017
         AIF   (('&SYSLIST(&M)'(&N+1,1) NE ',') AND ('&SYSLIST(&M)'(&N+X19200017
               1,1) NE ')')).P7                    ONE CHARACTER ALLOW  19600017
         AGO   .X1                                IS THIS FORST CLASS   20000017
.PROB    AIF   (&O+2 NE &N).CLASS                 PROB PROG PARTITN *** 20400017
&PB      SETA  &PB+1                              PROB PROG COUNTER     20800017
         AGO   .X1                                IS THIS FIRST CLASS   21200017
.CEND    AIF  (((&N-(&O+2)) GT 3) OR ((&N-(&O+2)) LE 0)).P8             21600017
&LS      SETA  (&N-(&O+2))                                              22000017
&GV      SETC  '&SYSLIST(&M)'(&O+2,&LS)           PLACE JOBCLASS IN     22400017
&GV      SETC  '   &GV'(&LS,4)                    * CBOX                22800017
&EO      SETB  (&PT EQ &PT/X'02'*X'02')           EVEN OR ODD PART NUMB 23200017
    MNOTE *,'           &GV IS THE JOBCLASS IDENTIFIER'                 23600017
         AIF   (&EO).EVEN                                  *S           24000017
         AIF   (&NOSET).CS                                   E          24400017
&SGCPRGC((&PT+1)/X'02') SETC '&GV&SGCPRGC((&PT+1)/X'02')'     T         24800017
.CS      AIF   ('&SYSLIST(&M)'(&N,1) EQ ',').AGAIN             *J       25200017
         AGO   .CLEN                                             O      25600017
.EVEN    AIF   (&NOSET).CS                                        B     26000017
&SGCPRGC((&PT+1)/X'02') SETC '&SGCPRGC((&PT+1)/X'02')&GV'          *C   26400017
         AGO   .CS                                                   L  26800017
.SIZE    ANOP                                    SIZE PROCESS     ****  27200017
&N       SETA  &N+1                               *    INCREMENT POINT  27600017
         AIF   (('&SYSLIST(&M)'(&N,1) EQ ',') OR ('&SYSLIST(&M)'(&N,1) X28000017
               EQ ')')).P9                        *    INVALID FIND     28400017
         AIF   ('&SYSLIST(&M)'(&N,1) LE '9' AND '&SYSLIST(&M)'(&N,1) GEX28800017
                '0').SETS                         *    SIZE CHARACTER   29200017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ 'K').SEND *    END OF PARM      29600017
         AIF  (('&SYSLIST(&M)'(&N,1) EQ '-') AND (&N EQ (&O+1))).SIZE   30000017
         AGO   .P9                                *    RETURN TO LOOP   30400017
.SETS    AIF   ((&O+2) NE &N).SIZE                FIRST CHARACTER TEST  30800017
         AIF   (&HB1 OR &HB0).SIZE                *   IF HIARCHY RETURN 31200017
&S       SETB  1                                  *   SET SIZE SWITCH   31600017
         AGO   .SIZE                              *   RETURN            32000017
.SEND    ANOP                                     SET SIZE VALUE   **** 32400017
&LS      SETA  &N-(&O+2)                          *   LENGTH            32800017
&SZ      SETC  '&SYSLIST(&M)'(&O+2,&LS)           *   *                 33200017
         AIF   (&NOSET).TEST                      *   TEST FOR VALID PT 33600017
         AIF   (&SZ LE 7).PH           *    SIZE GE 4?                  34000017
         AIF   (&HB1).H1                          *   IF H1 - BRANCH    34400017
&SGCPRPA(&PT) SETA &SZ*1024                       *   SET SIZE BOX      34800017
         AIF   (&HB0).N0                          *   IF HIARCHY 0      35200017
.SN MNOTE *,'           &SZ K BYTES ALLOCATED TO THE PARTITION'         35600017
         AGO   .CHK                               CHECK FOR ANOTHER     36000017
.N0      AIF   (&SZ EQ &SZ/X'02'*X'02').M0                              36400017
&SGCPRPA(&PT) SETA &SGCPRPA(&PT)+1024                                   36800017
.M0 MNOTE *,'           &SZ K BYTES ALLOCATED TO HIERARCHY 0'           37200017
         AGO   .CHK                               CHECK FOR ANOTHER     37600017
.H1      ANOP                                     HIERARCH 1 SET        38000017
&SGCPRPA(&PT+52) SETA &SZ*1024                    *                     38400017
         AIF   (&SZ EQ &SZ/X'02'*X'02').N1                              38800017
&SGCPRPA(&PT+52) SETA &SGCPRPA(&PT+52)+1024                             39200017
.N1 MNOTE *,'           &SZ K BYTES ALLOCATED TO HIERARCHY 1'           39600017
.CHK     AIF   ('&SYSLIST(&M)'(&N+1,1) NE ',').CLEN                     40000017
&N       SETA  &N+1                               INCREMENT POINTER     40400017
.RAG     ANOP                                                           40800017
&HB0     SETB  0                                  REINITIALIZE FOR      41200017
&HB1     SETB  0                                  *    NEXT HIERARCHY   41600017
         AGO   .AGAIN                             SCAN NEXT PARM        42000017
.CLEN    AIF   (&C AND &S).REIN                   CLASS AND SIZE SPEC   42400017
         AIF   (&C AND (&HB1 OR &HB0)).REIN       CLASS AND HIERARCHY   42800017
         AIF   (&S OR &HB1 OR &HB0).PA            NO CLASS              43200017
         AIF   (&C).PB                            NO SIZE SPECIFIED     43600017
.REIN    ANOP                                     REINITIALIZE     **** 44000017
&S       SETB  0                                  *    SIZE             44400017
&C       SETB  0                                  *    CLASS            44800017
&N       SETA  0                                  *    POINTER TO CHAR  45200017
&NOSET   SETB  0                                  *    NO SET PARTITION 45600017
&HB0     SETB  0                                  *    HIERARCHY 0      46000017
&HB1     SETB  0                                  *    HIERARCHY 1      46400017
         AGO   .BGIN                                                    46800017
.TEST    AIF   (&HB1).N1                          HIERARCHY 1           47200017
         AIF   (&HB0).N0                          HIERARCHY 0           47600017
         AIF   (&S).SN                            SIZE                  48000017
         AGO   .P9                                                      48400017
.HI ANOP                                                                48600017
&SGMENTB(54) SETB 1           HIARCHY SPECIFIED                         48800017
         AIF ('&SYSLIST(&M)'(&N+1,1) EQ '1').HI1                        49000017
         AIF   ('&SYSLIST(&M)'(&N+1,1) NE '0').PC                       49200017
&HB0     SETB  1                                  SET H0 INDICATOR      49600017
.RFS     ANOP                                     REINITIALIZE FOR SIZE 50000017
&N       SETA  &N+1                               *                     50400017
&O       SETA  &N                                 *                     50800017
&S       SETB  1                                                        51200017
         AGO   .SIZE                              *                     51600017
.HI1     ANOP                                     SET H1 INDICATOR      52000017
&HB1     SETB  1                                  *                     52400017
         AGO   .RFS                               *                     52800017
.COMP   ANOP                                                            53000019
&SGCPRNA(1) SETA &M                                                     53200019
        AIF   (&WR GT 36).PD FINAL CHECK WRITER     * *                 53400019
.CHK1         AIF  (&RD GT 3).PE                  *         READERS     53600017
.CHK2    AIF   (&PB GT 15 OR &PB LT 1).PF         *         PROBLEM PRG 54000017
.CHK3    ANOP                                     PARTITN MISSING?      54400017
&PT      SETA  0                                                        54800017
.PTCHK   AIF   (&PT EQ 52).MEND                                         55200017
&PT      SETA  &PT+1                                                    55600017
         AIF   (&ZER AND ((&SGCPRPA(&PT) NE X'00') AND (&SGCPRPA(&PT+52X56000017
               ) NE X'00'))).PG                                         56400017
         AIF   (&ZER AND ((&SGCPRPA(&PT) EQ X'00') AND (&SGCPRPA(&PT+52X56800017
               ) NE X'00'))).PG                                         57200017
         AIF   (&ZER AND ((&SGCPRPA(&PT) NE X'00') AND (&SGCPRPA(&PT+52X57600017
               ) EQ X'00'))).PG                                         58000017
         AIF  ((&SGCPRPA(&PT) NE X'00') AND (&SGCPRPA(&PT+52) NE X'00')X58400017
               ).PTCHK                                                  58800017
         AIF   ((&SGCPRPA(&PT) EQ X'00') AND (&SGCPRPA(&PT+52) NE X'00'X59200017
               )).PTCHK                                                 59600017
         AIF   ((&SGCPRPA(&PT) NE X'00') AND (&SGCPRPA(&PT+52) EQ X'00'X60000017
               )).PTCHK                                                 60400017
&ZER     SETB  1                                                        60800017
         AGO   .PTCHK                                                   61200017
.P0 MNOTE 5,'* * * IEIPTN118 THE PARTITION VALUE SPECIFIED IS BLANK OR C61280018
               INVALID'                                                 61360018
&SGQUITB  SETB  1                                                       61440018
          AGO  .MEND                                                    61520018
.P1 MNOTE 5,'* * * IEIPTN100 THE PARTITION VALUE IN &SYSLIST(&M) IS INVX61600017
               ALID - THE MAXIMUM VALUE IS 51'                          62000017
&SGQUITB SETB  1                                  QUIT SWITCH SET       62400017
         AGO  .MEND                                                     62600018
.P2 MNOTE 5,'* * * IEIPTN101 THE MAXIMUM NUMBER OF PARTITIONS ALLOWED IX65600017
               S 52'                                                    66000017
&SGQUITB SETB  1                                  QUIT SWITCH SET       66400017
         AGO   .BGIN                                                    66800017
.P3 MNOTE 5,'* * * IEIPTN102 NO PARTITIONS HAVE BEEN SPECIFIED'         67200017
&SGQUITB SETB  1                                  QUIT SWITCH SET       67600017
         AGO   .MEND                                                    68000017
.P4 MNOTE 5,'* * * IEIPTN103 &SYSLIST(&M) CONTAINS AN INVALID DESIGNATOX68400017
               R'                                                       68800017
&SGQUITB SETB  1                                  QUIT SWITCH SET       69200017
.GSLP    AIF   ('&SYSLIST(&M)'(&N,1) EQ ',').AGAIN     LOOP TO          69600017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ ')').CLEN        FIND           70000017
&N       SETA  &N+1                                          NEXT       70400017
         AGO   .GSLP                                            PARM    70800017
.P5 MNOTE 5,'* * * IEIPTN104 &SYSLIST(&M) CONTAINS AN INVALID CLASS VALX71200017
               UE OR INDICATOR'                                         71600017
&SGQUITB SETB  1                                  QUIT SWITCH SET       72000017
         AGO   .GSLP                                                    72400017
.P6 MNOTE 5,'* * * IEIPTN105 &SYSLIST(&M) CONTAINS AN INVALID READER PAX72800017
               RTITION INDICATOR'                                       73200017
&SGQUITB SETB  1                                  QUIT SWITCH SET       73600017
         AGO   .GSLP                                                    74000017
.P7 MNOTE 5,'* * * IEIPTN106 &SYSLIST(&M) CONTAINS AN INVALID WRITER PAX74400017
               RTITION INDICATOR'                                       74800017
&SGQUITB SETB  1                                  QUIT SWITCH SET       75200017
         AGO   .GSLP                                                    75600017
.P8 MNOTE 5,'* * * IEIPTN107 FROM ONE TO THREE JOBCLASS IDENTIFIERS AREX76000017
                VALID'                                                  76400017
&SGQUITB SETB  1                                  QUIT SWITCH SET       76800017
         AGO   .CS                                                      77200017
.P9 MNOTE 5,'* * * IEIPTN108 &SYSLIST(&M) CONTAINS AN INVALID SIZE VALUX77600017
               E OR INDICATOR'                                          78000017
&SGQUITB SETB  1                                  QUIT SWITCH SET       78400017
.SLP     AIF   ('&SYSLIST(&M)'(&N,1) EQ ')').REIN                       78800017
         AIF   ('&SYSLIST(&M)'(&N,1) EQ ',').RAG                        79200017
&N       SETA  &N+1                                                     79600017
         AGO   .SLP                                                     80000017
.PA MNOTE 5,'* * * IEIPTN109 &SYSLIST(&M) DOES NOT CONTAIN A JOBCLASS PX80400017
               ARAMETER OR IT HAS BEEN FOUND INVALID'                   80800017
&SGQUITB SETB  1                                  QUIT SWITCH SET       81200017
         AGO   .REIN                                                    81600017
.PB MNOTE 5,'* * * IEIPTN110 &SYSLIST(&M) DOES NOT CONTAIN A SIZE PARAMX82000017
               ETER'                                                    82400017
&SGQUITB SETB  1                                  QUIT SWITCH SET       82800017
          AGO    .REIN                                                  83200017
.PC MNOTE 5,'* * * IEIPTN111 &SYSLIST(&M) CONTAINS AN INVALID HIERARCHYX83600017
                VALUE OR INDICATOR'                                     84000017
&SGQUITB SETB  1                                  QUIT SWITCH SET       84400017
         AGO   .SLP                                                     84800017
.PD MNOTE 5,'* * * IEIPTN112 UP TO 36 WRITER PARTITIONS MAY BE SPECIFIED85200017
               D'                                                       85600017
&SGQUITB SETB  1                                  QUIT SWITCH SET       86000017
         AGO   .CHK1                                                    86400017
.PE MNOTE 5,'* * * IEIPTN113 UP TO 3 READER PARTITIONS MAY BE SPECIFIEDX86800017
               '                                                        87200017
&SGQUITB SETB  1                                  QUIT SWITCH SET       87600017
         AGO  .CHK2                                                     88000017
.PF MNOTE 5,'* * * IEIPTN114 A MAXIMUM OF 15 PROBLEM PROGRAM PARTITIONSX88400017
                ARE ALLOWABLE AND AT LEAST ONE MUST BE SPECIFIED'       88800017
&SGQUITB SETB  1                                  QUIT SWITCH SET       89200017
         AGO   .CHK3                                                    89600017
.PG MNOTE 5,'* * * IEIPTN115 ALL PARTITIONS FROM 0 THROUGH THE HIGHEST X90000017
               PARTITION SPECIFIED HAVE NOT BEEN SUPPLIED OR CONTAIN ERX90400017
               RORS'                                                    90800017
&SGQUITB SETB  1                                                        91200017
         AGO   .MEND                                                    91600017
.PH MNOTE 5,'* * * IEIPTN117 THE PARTITION SIZE IN &SYSLIST(&M) MUST EQX92000017
               UAL AT LEAST 8K'                                         92400017
&SGQUITB SETB  1                                                        92800017
         AGO   .REIN                                                    93200017
.PJ      ANOP                                                           93250021
&PT      SETA  &PT-1                                                    93300021
    MNOTE 5,'* * * IEIPTN118 DUPLICATE DEFINITION OF PARTITION &PT'     93350021
&SGQUITB SETB 1                                   QUIT SWITCH SET       93400021
&PT      SETA  &PT+1                                                    93450021
         AGO   .REIN                                                    93500021
.MR MNOTE 5,'* * * IEIPTN116 PARTITNS MACRO PREVIOUSLY USED'            93600017
&SGQUITB SETB  1                                                        94000017
.MEND    MEND                                                           94400017
