         MACRO                                                          00500018
         SECONSLE &CONSOLE=,&ALTCONS=,&ROUTCDE=,&VALDCMD=,&USE=,       *01000021
               &AREA=,&PFK=,&OPSTRAN=,&OPSTRNI=                         01453421
         COPY  SGGBLPAK                                                 01500018
         LCLA  &A1,&A2,&A3,&A4                                          02000018
    LCLB  &B1,&B2,&B3,&B4,&B5,&SW1,&SW2,&SW3                            02400018
         LCLC  &C1,&C2,&C3,&C4,&C5                                      02800018
&SGSCNYA(2) SETA &SGSCNYA(2)+1              NO. OF MACRO CALLS          03200018
         AIF   (&SGSCNYA(2) GT 31).M0       MAX 31 SECONDARY CONSOLES   03600018
         AIF   (T'&CONSOLE EQ 'O').M1       CONSOLE VALUE OMITTED       04500018
         AIF   (N'&CONSOLE NE 1).A6                                     05000018
&A1      SETA  &SGSCNYA(1)                                              06000018
.A2      AIF   (&A1 EQ 0).AZ                                            06500018
         AIF   ('&CONSOLE&CONSOLE' EQ '&SGSCNCC(&A1)').M3               07000018
&A1      SETA  &A1-1                                                    07500018
         AGO   .A2                                                      08000018
.AZ      ANOP                                                           08030018
&A4      SETA  1                                                        08060018
&SW1     SETB  0                                                        08090018
&SW2     SETB  0                                                        08120018
&C5      SETC  '&CONSOLE(&A4)'(1,2)                                     08150018
         AIF   ('&C5' NE 'O-').A4                                       08180018
&C4      SETC  '&CONSOLE(&A4)'(3,3)                                     08210018
&C5      SETC   'FFF'                                                   08240018
&SW1     SETB  1                                                        08270018
         MNOTE *,'      OUTPUT ONLY CONSOLE ADDRESS &C4'                08300018
&SGSCNYA(1) SETA  &SGSCNYA(1)+1                                         08330018
&SGSCNCC(&SGSCNYA(1))   SETC   '&C5&C4'                                 08360018
         AGO   .B4                                                      08390018
.A4      MNOTE *,'      CONSOLE ADDRESS &CONSOLE'                       08500018
.AX      ANOP                                                           08700018
&SGSCNYA(1) SETA &SGSCNYA(1)+1                                          09000018
&SGSCNCC(&SGSCNYA(1)) SETC '&CONSOLE&CONSOLE'                           09500018
         AGO   .B4                                                      10000018
.A6      AIF   (N'&CONSOLE NE 2).M2                                     10500018
         MNOTE *,'      COMPOSITE CONSOLE WITH FOLLOWING ADDRESSES--'   11000018
&SGSCNYA(1) SETA &SGSCNYA(1)+1                                          11500018
.A8      AIF   (&A2 EQ 2).B4                                            12000018
&A2      SETA  &A2+1                                                    12500018
&C1      SETC  '&CONSOLE(&A2)'(3,3)                                     13000018
&C2      SETC  '&CONSOLE(&A2)'(1,2)                                     13500018
         AIF   ('&C2' NE 'I-').AE                                       14000018
         AIF   (&B1).M20                                                14500018
&B1      SETB  1                                                        15000018
&A1      SETA  &SGSCNYA(1)-1                                            15500018
&C3      SETC  '&C1&C3'                                                 15700018
.AA      AIF   (&A1 EQ 0).AC                                            16000018
         AIF   ('&C3' EQ '&SGSCNCC(&A1)').M30                           16500018
&A1      SETA  &A1-1                                                    17000018
         AGO   .AA                                                      17500018
.AC      MNOTE *,'         &C1 - INPUT'                                 18000018
&SGSCNCC(&SGSCNYA(1)) SETC '&C1&SGSCNCC(&SGSCNYA(1))'  I-ADDR(O-ADDR)   18500018
         AGO   .A8                                                      19000018
.AE      AIF   ('&C2' NE 'O-').M20                                      19500018
         AIF   (&B2).M20                                                20000018
&B2      SETB  1                                                        20500018
&A1      SETA  &SGSCNYA(1)-1                                            21000018
&C3      SETC  '&C3&C1'                                                 21200018
.B0      AIF   (&A1 EQ 0).B2                                            21500018
         AIF   ('&C3' EQ '&SGSCNCC(&A1)').M30                           22000018
&A1      SETA  &A1-1                                                    22500018
         AGO   .B0                                                      23000018
.B2      MNOTE *,'         &C1 - OUTPUT'                                23500018
&SGSCNCC(&SGSCNYA(1)) SETC '&SGSCNCC(&SGSCNYA(1))&C1'  (I-ADDR)O-ADDR   24000018
         AGO   .A8                                                      24500018
.B4      AIF   (T'&ALTCONS EQ 'O').BC       OMITTED                     25000018
&A4     SETA  1                                                         25200018
         AIF   (N'&ALTCONS NE 1).B6                                     25500018
&C5      SETC  '&ALTCONS(&A4)'(1,2)                                     25600018
         AIF   ('&C5' NE 'O-').B4A                                      25700018
&C4      SETC  '&ALTCONS(&A4)'(3,3)                                     25800018
&SW2     SETB  1                                                        25900018
&C5      SETC   'FFF'                                                   26000018
         MNOTE *,'      OUTPUT ONLY ALTCONS ADDRESS &C4'                26100018
&SGSCNAC(&SGSCNYA(1))   SETC   '&C5&C4'                                 26200018
    AIF  (NOT &SW1).M9 OUTPUT ONLY ALTCONS VALID WITH O-ONLY CONSOLE    26250018
         AGO   .BC                                                      26300018
.B4A     ANOP                                                           26400018
         MNOTE *,'      ALTCONS ADDRESS &ALTCONS'                       26500018
.B4B     ANOP                                                           26700018
&SGSCNAC(&SGSCNYA(1)) SETC '&ALTCONS&ALTCONS'                           27000018
         AGO   .BC                                                      27500018
.B6      AIF   (N'&ALTCONS NE 2).M4                                     28000018
         MNOTE *,'      COMPOSITE ALTERNATE CONSOLE WITH FOLLOWING'     28500018
         MNOTE *,'       ADDRESSES--'                                   29000018
.B8      AIF   (&A3 EQ 2).BC                                            29500018
&A3      SETA  &A3+1                                                    30000018
&C1      SETC  '&ALTCONS(&A3)'(3,3)                                     30500018
&C2      SETC  '&ALTCONS(&A3)'(1,2)                                     31000018
         AIF   ('&C2' NE 'I-').BA                                       31500018
         AIF   (&B3).M40                                                32000018
&B3      SETB  1                                                        32500018
         MNOTE *,'         &C1 - INPUT'                                 33000018
&SGSCNAC(&SGSCNYA(1)) SETC '&C1&SGSCNAC(&SGSCNYA(1))'  I-ADDR(O-ADDR)   33500018
         AGO   .B8                                                      34000018
.BA      AIF   ('&C2' NE 'O-').M40                                      34500018
         AIF   (&B4).M40                                                35000018
&B4      SETB  1                                                        35500018
         MNOTE *,'         &C1 - OUTPUT'                                36000018
&SGSCNAC(&SGSCNYA(1)) SETC '&SGSCNAC(&SGSCNYA(1))&C1'  (I-ADDR)O-ADDR   36500018
         AGO   .B8                                                      37000018
.BC      AIF   (T'&ROUTCDE EQ 'O').C7          OMITTED                  37500018
         AIF   ('&ROUTCDE' EQ 'ALL').C4                                 38000018
&A1      SETA  1                                                        38500018
         MNOTE *,'      ROUTING CODES ASSIGNED TO THIS CONSOLE ARE--'   39200018
.BE      AIF   (N'&ROUTCDE LT &A1).C8       EXHAUSTED                   40000018
         AIF   (T'&ROUTCDE(&A1) NE 'N').M5  NOT NUMERIC                 40500018
         AIF   ('&ROUTCDE(&A1)' LT '1' OR '&ROUTCDE(&A1)' GT '16').M5   41000018
  AIF  (&SGRT01B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '1').M55 DUPLIC'D 41020018
  AIF  (&SGRT02B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '2').M55 DUPLIC'D 41040018
  AIF  (&SGRT03B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '3').M55 DUPLIC'D 41060018
  AIF  (&SGRT04B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '4').M55 DUPLIC'D 41080018
  AIF  (&SGRT05B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '5').M55 DUPLIC'D 41100018
  AIF  (&SGRT06B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '6').M55 DUPLIC'D 41120018
  AIF  (&SGRT07B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '7').M55 DUPLIC'D 41140018
  AIF  (&SGRT08B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '8').M55 DUPLIC'D 41160018
  AIF  (&SGRT09B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ  '9').M55 DUPLIC'D 41180018
  AIF  (&SGRT10B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ '10').M55 DUPLIC'D 41200018
  AIF  (&SGRT11B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ '11').M55 DUPLIC'D 41220018
  AIF  (&SGRT12B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ '12').M55 DUPLIC'D 41240018
  AIF  (&SGRT13B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ '13').M55 DUPLIC'D 41260018
  AIF  (&SGRT14B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ '14').M55 DUPLIC'D 41280018
  AIF  (&SGRT15B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ '15').M55 DUPLIC'D 41300018
  AIF  (&SGRT16B(&SGSCNYA(1)) AND '&ROUTCDE(&A1)' EQ '16').M55 DUPLIC'D 41320018
         MNOTE *,'         &ROUTCDE(&A1)'                               41500018
&SGRT01B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '1' OR &SGRT01B(&SGSCNY*42000018
               A(1)))                                                   42500018
&SGRT02B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '2' OR &SGRT02B(&SGSCNY*43000018
               A(1)))                                                   43500018
&SGRT03B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '3' OR &SGRT03B(&SGSCNY*44000018
               A(1)))                                                   44500018
&SGRT04B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '4' OR &SGRT04B(&SGSCNY*45000018
               A(1)))                                                   45500018
&SGRT05B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '5' OR &SGRT05B(&SGSCNY*46000018
               A(1)))                                                   46500018
&SGRT06B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '6' OR &SGRT06B(&SGSCNY*47000018
               A(1)))                                                   47500018
&SGRT07B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '7' OR &SGRT07B(&SGSCNY*48000018
               A(1)))                                                   48500018
&SGRT08B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '8' OR &SGRT08B(&SGSCNY*49000018
               A(1)))                                                   49500018
&SGRT09B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ  '9' OR &SGRT09B(&SGSCNY*50000018
               A(1)))                                                   50500018
&SGRT10B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ '10' OR &SGRT10B(&SGSCNY*51000018
               A(1)))                                                   51500018
&SGRT11B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ '11' OR &SGRT11B(&SGSCNY*52000018
               A(1)))                                                   52500018
&SGRT12B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ '12' OR &SGRT12B(&SGSCNY*53000018
               A(1)))                                                   53500018
&SGRT13B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ '13' OR &SGRT13B(&SGSCNY*54000018
               A(1)))                                                   54500018
&SGRT14B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ '14' OR &SGRT14B(&SGSCNY*55000018
               A(1)))                                                   55500018
&SGRT15B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ '15' OR &SGRT15B(&SGSCNY*56000018
               A(1)))                                                   56500018
&SGRT16B(&SGSCNYA(1)) SETB ('&ROUTCDE(&A1)' EQ '16' OR &SGRT16B(&SGSCNY*57000018
               A(1)))                                                   57500018
.C0      ANOP                                                           58000018
&A1      SETA  &A1+1                                                    58500018
         AGO   .BE                                                      59000018
.C4      MNOTE *,'      ALL ROUTING CODES ARE ASSIGNED TO THIS CONSOLE' 60000018
&SGRT01B(&SGSCNYA(1)) SETB 1                                            62000018
&SGRT02B(&SGSCNYA(1)) SETB 1                                            62500018
&SGRT03B(&SGSCNYA(1)) SETB 1                                            63000018
&SGRT04B(&SGSCNYA(1)) SETB 1                                            63500018
&SGRT05B(&SGSCNYA(1)) SETB 1                                            64000018
&SGRT06B(&SGSCNYA(1)) SETB 1                                            64500018
&SGRT07B(&SGSCNYA(1)) SETB 1                                            65000018
&SGRT08B(&SGSCNYA(1)) SETB 1                                            65500018
&SGRT09B(&SGSCNYA(1)) SETB 1                                            66000018
&SGRT10B(&SGSCNYA(1)) SETB 1                                            66500018
&SGRT12B(&SGSCNYA(1)) SETB 1                                            67000018
&SGRT11B(&SGSCNYA(1)) SETB 1                                            67500018
&SGRT13B(&SGSCNYA(1)) SETB 1                                            68000018
&SGRT14B(&SGSCNYA(1)) SETB 1                                            68500018
&SGRT15B(&SGSCNYA(1)) SETB 1                                            69000018
&SGRT16B(&SGSCNYA(1)) SETB 1                                            69500018
         AGO   .C8                                                      69800018
.C7      MNOTE *,'      NO ROUTING CODES ARE ASSIGNED THIS CONSOLE'     70100018
.C8      AIF   (T'&VALDCMD EQ 'O').CE       OMITTED                     70500018
 AIF (&SW1).M8               OUTPUT ONLY CONSOLE                        70600018
.C9      ANOP                                                           70700018
         MNOTE *,'      COMMAND CODES ASSIGNED TO THIS CONSOLE ARE--'   71000018
&A1      SETA  1                                                        71600018
.CA      AIF  (N'&VALDCMD LT &A1).D1         EXHAUSTED                  72000021
         AIF   (T'&VALDCMD(&A1) NE 'N').M6  NOT NUMERIC                 72400018
         AIF   ('&VALDCMD(&A1)' LT '1' OR '&VALDCMD(&A1)' GT '3').M6    72700018
  AIF  (&SGCMD1B(&SGSCNYA(1)) AND '&VALDCMD(&A1)' EQ '1').M7 DUPLIC'D   73100018
  AIF  (&SGCMD2B(&SGSCNYA(1)) AND '&VALDCMD(&A1)' EQ '2').M7 DUPLIC'D   73200018
  AIF  (&SGCMD3B(&SGSCNYA(1)) AND '&VALDCMD(&A1)' EQ '3').M7 DUPLIC'D   73300018
         MNOTE *,'         &VALDCMD(&A1)'                               73500018
&SGCMD1B(&SGSCNYA(1)) SETB ('&VALDCMD(&A1)' EQ '1' OR &SGCMD1B(&SGSCNYA*74000018
               (1)))                                                    74500018
&SGCMD2B(&SGSCNYA(1)) SETB ('&VALDCMD(&A1)' EQ '2' OR &SGCMD2B(&SGSCNYA*75000018
               (1)))                                                    75500018
&SGCMD3B(&SGSCNYA(1)) SETB ('&VALDCMD(&A1)' EQ '3' OR &SGCMD3B(&SGSCNYA*76000018
               (1)))                                                    76500018
.CC      ANOP                                                           78000018
&A1      SETA  &A1+1                                                    78500018
         AGO   .CA                                                      79000018
.CE MNOTE *,'      COMMANDS ''DISPLAY,LOG'' ARE ASSIGNED THIS CONSOLE'  79500018
.D1      AIF   (T'&USE EQ 'O' OR '&USE' EQ 'FC').E1                     80000021
         AIF (NOT('&USE' EQ 'MS')).D2        GO CHECK FOR SD            80453421
         MNOTE *,'      LIMITED CAPACITY CONSOLE-MESSAGE STREAM MODE'   80471521
&SGSCMSB(&SGSCNYA(1)) SETB 1                                            80489621
         AGO  .E1                                                       80493221
.D2      AIF (NOT('&USE' EQ 'SD')).MA        ANY OTHER INVALID          80496821
         MNOTE *,'      LIMITED CAPACITY CONSOLE-STATUS DISPLAY MODE'   80497521
&SGSCSDB(&SGSCNYA(1)) SETB 1                                            80498221
.E1      AIF   (T'&AREA EQ 'O').G            OMITTED                    80498921
         AIF   (&SGSCMSB(&SGSCNYA(1))).MB    ERROR IF MS CONSOLE        80499621
         AIF   (N'&AREA GT 11).MC            TOO MANY AREAS DEFINED     80499721
         MNOTE *,'      STATUS DISPLAY AREAS FOR THIS CONSOLE HAVE'     80499821
         MNOTE *,'       LENGTHS OF--'                                  80499921
&A1      SETA  1                                                        80666621
.E2      AIF   (&A1 GT N'&AREA).E4           PARAMETERS EXHAUSTED       80757221
         AIF   (T'&AREA(&A1) NE 'N').MD      NOT NUMERIC                80775321
         AIF   ('&AREA(&A1)' LT '4' OR '&AREA(&A1)' GT '47').MD         80793421
         MNOTE *,'           &AREA(&A1)'                                80811521
&SGAR12A(&SGSCNYA(1)) SETA &SGAR12A(&SGSCNYA(1))+&AREA(&A1)             80829621
.E3      ANOP                                                           80833221
&A1      SETA  &A1+1                                                    80999921
         AGO   .E2                                                      81000021
.E4      AIF (&SW3).G                   ERROR IN PARAMETER              81090621
         AIF   (N'&AREA EQ 1).F1                                        81108721
         AIF   (N'&AREA EQ 2).F2                                        81126821
         AIF   (N'&AREA EQ 3).F3                                        81144921
         AIF   (N'&AREA EQ 4).F4                                        81163021
         AIF   (N'&AREA EQ 5).F5                                        81163721
         AIF   (N'&AREA EQ 6).F6                                        81164421
         AIF   (N'&AREA EQ 7).F7                                        81165121
         AIF   (N'&AREA EQ 8).F8                                        81165821
         AIF   (N'&AREA EQ 9).F9                                        81166521
         AIF   (N'&AREA EQ 10).F10                                      81333221
&SGAR11A(&SGSCNYA(1)) SETA &AREA(11)                                    81333321
.F10     ANOP                                                           81423921
&SGAR10A(&SGSCNYA(1)) SETA &AREA(10)                                    81442021
.F9      ANOP                                                           81460121
&SGAR09A(&SGSCNYA(1)) SETA &AREA(9)                                     81478221
.F8      ANOP                                                           81496321
&SGAR08A(&SGSCNYA(1)) SETA &AREA(8)                                     81497021
.F7      ANOP                                                           81497721
&SGAR07A(&SGSCNYA(1)) SETA &AREA(7)                                     81498421
.F6      ANOP                                                           81499121
&SGAR06A(&SGSCNYA(1)) SETA &AREA(6)                                     81499821
.F5      ANOP                                                           81499921
&SGAR05A(&SGSCNYA(1)) SETA &AREA(5)                                     81666521
.F4      ANOP                                                           81666621
&SGAR04A(&SGSCNYA(1)) SETA &AREA(4)                                     81757221
.F3      ANOP                                                           81775321
&SGAR03A(&SGSCNYA(1)) SETA &AREA(3)                                     81793421
.F2      ANOP                                                           81811521
&SGAR02A(&SGSCNYA(1)) SETA &AREA(2)                                     81829621
.F1      ANOP                                                           81833221
&SGAR01A(&SGSCNYA(1)) SETA &AREA(1)                                     81833321
.G       AIF (T'&PFK EQ 'O').H               OMITTED                    81833421
         AIF (T'&PFK NE 'N').ME              NOT NUMERIC                81833521
         AIF ('&PFK' GT '12').ME             12 MAXIMUM                 81889021
&SGSCNPA(&SGSCNYA(1)) SETA &PFK                                         81979621
&SGSCHDB(30) SETB 1                                                     81989621
         MNOTE *,'      CONSOLE WILL HAVE &PFK PROGRAM FUNCTION KEYS'   81997721
.H       AIF   (T'&OPSTRAN EQ 'O').I         OMITTED                    81998421
         AIF   (T'&OPSTRAN NE 'N').MF        NOT NUMERIC                81999121
         AIF   ('&OPSTRAN' GT '64').MF       INVALID                    81999821
         AIF   (N'&CONSOLE GT 1).H1          COMPOSITE CONSOLE          81999921
         AIF   (&SW1).H1                     OUTPUT ONLY CONSOLE        82142721
    MNOTE *,'             CONSOLE ASSIGNED TO TRANSIENT GROUP &OPSTRAN' 82160821
&SGTGRIA(&SGSCNYA(1)) SETA &OPSTRAN        I/O CONSOLE - SAVED ONLY     82164421
         AGO   .I                             IN INPUT GLOBAL           82165121
.H1 MNOTE *,'             OUTPUT CONSOLE ASSIGNED TO TRANSIENT GROUP &O*82165821
               PSTRAN'                                                  82166521
&SGTGROA(&SGSCNYA(1)) SETA &OPSTRAN                                     82166621
.I       AIF   (T'&OPSTRNI EQ 'O').MEND      OMITTED                    82166721
         AIF   (N'&CONSOLE NE 2).MG          NOT COMPOSITE              82166821
         AIF   (T'&OPSTRNI NE 'N').MH        NOT NUMERIC                82257421
         AIF   ('&OPSTRNI' GT '64').MH       INVALID                    82275521
         AIF   ('&OPSTRAN' EQ '&OPSTRNI').MI                            82279121
.I0 MNOTE *,'             INPUT CONSOLE ASSIGNED TO TRANSIENT GROUP &OP*82282721
               STRNI'                                                   82283421
&SGTGRIA(&SGSCNYA(1)) SETA &OPSTRNI                                     82284121
         MEXIT                                                          82284821
.* * *    * * *       * * *        * * *        * * *       * * *       82286021
.M0 MNOTE 5,'* * * IEISCN001 MAXIMUM 31 SECONDARY CONSOLES ARE ALLOWED' 82428821
&SGQUITB SETB 1                                                         82571621
         MEXIT                                                          82714421
.M1 MNOTE 5,'* * * IEISCN002 CONSOLE VALUE NOT SPECIFIED'               82857221
&SGQUITB SETB 1                                                         83000018
         MEXIT                                                          83500018
.M20     ANOP                                                           84000018
&SGSCNCC(&SGSCNYA(1)) SETC ''                                           84500018
&SGSCNYA(1) SETA &SGSCNYA(1)-1                                          85000018
.M2 MNOTE 5,'* * * IEISCN003 CONSOLE VALUE &CONSOLE INVALID'            85500018
&SGQUITB SETB 1                                                         86000018
         MEXIT                                                          86500018
.M30     ANOP                                                           87000018
&SGSCNCC(&SGSCNYA(1)) SETC ''                                           87500018
&SGSCNYA(1) SETA &SGSCNYA(1)-1                                          88000018
.M3 MNOTE 5,'* * * IEISCN004 CONSOLE VALUE &CONSOLE PREVIOUSLY SPECIFIED88500018
               D'                                                       89000018
&SGQUITB SETB 1                                                         89500018
         MEXIT                                                          90000018
.M40     ANOP                                                           90500018
&SGSCNAC(&SGSCNYA(1)) SETC ''                                           91000018
.M4 MNOTE 5,'* * * IEISCN005 ALTCONS VALUE &ALTCONS INVALID'            91500018
&SGQUITB SETB 1                                                         92000018
         AGO   .BC                                                      92500018
.M5 MNOTE 5,'* * * IEISCN006 ROUTCDE VALUE &ROUTCDE(&A1) INVALID'       93000018
&SGQUITB SETB 1                                                         93500018
         AGO   .C0                                                      94000018
.M55 MNOTE 5,'* * * IEISCN007 ROUTCDE VALUE &ROUTCDE(&A1) DUPLICATED'   94100018
&SGQUITB SETB 1                                                         94200018
         AGO  .C0                                                       94300018
.M6  MNOTE  5,'* * * IEISCNW01 WARNING- VALDCMD VALUE &VALDCMD(&A1)    C94500018
               INVALID AND IGNORED'                                     94700018
         AGO   .CC                                                      95500018
.M7 MNOTE 5,'* * * IEISCN009 VALDCMD VALUE &VALDCMD(&A1) DUPLICATED'    95600018
&SGQUITB SETB 1                                                         95700018
         AGO  .CC                                                       95800018
.M8 MNOTE 5,'* * * IEISCN010 VALDCMD SPECIFICATION FOR OUTPUT ONLY DEVIX95840018
               CE INVALID'                                              95880018
&SGQUITB SETB  1                                                        95920018
         AGO   .CC                                                      95960018
.M9 MNOTE 5,'* * * IEISCN011 OUTPUT ONLY ALTCONS DEVICE INVALID WITH COC95968018
               NSOLE DEVICE HAVING INPUT CAPABILITY'                    95976018
&SGQUITB SETB  1                                                        95984018
         AGO  .BC                                                       95992018
.MA MNOTE 5,'* * * IEISCN012 USE VALUE &USE INVALID'                    95994021
&SGQUITB SETB  1                                                        95996021
         AGO   .E1                                                      95998021
.MB MNOTE 5,'* * * IEISCN013 AREA SPECIFICATION INVALID WITH CONSOLE   C95998421
               IN MESSAGE STREAM MODE'                                  95998821
&SGQUITB SETB  1                                                        95999221
         AGO .G                                                         95999621
.MC MNOTE 5,'* * * IEISCN014 MAXIMUM OF 11 AREAS MAY BE DEFINED'        95999721
&SGQUITB SETB  1                                                        95999821
         AGO .G                                                         95999921
.MD MNOTE 5,'* * * IEISCN015 AREA VALUE &AREA(&A1) INVALID'             96049921
&SGQUITB SETB  1                                                        96059921
&SW3     SETB  1                                                        96069921
         AGO   .E3                                                      96079921
.ME MNOTE 5,'* * * IEISCN016 PFK VALUE &PFK INVALID'                    96089921
&SGQUITB SETB  1                                                        96091921
         AGO .H                                                         96093921
.MF MNOTE 5,'* * * IEISCN017 OPSTRAN VALUE &OPSTRAN INVALID'            96095921
&SGQUITB SETB  1                                                        96097921
         AGO .I                                                         96098321
.MG MNOTE 5,'* * * IEISCN018 OPSTRNI SPECIFICATION REQUIRES COMPOSITE C*96098721
               ONSOLE'                                                  96099121
&SGQUITB SETB  1                                                        96099521
         AGO .MEND                                                      96099621
.MH MNOTE 5,'* * * IEISCN019 OPSTRNI VALUE &OPSTRNI INVALID'            96099721
&SGQUITB SETB  1                                                        96099821
         AGO .MEND                                                      96149821
.MI MNOTE 0,'* * * IEISCNW02 WARNING- BOTH HALVES OF COMPOSITE CONSOLE *96159821
               SHARE SAME TRANSIENT AREA'                               96169821
         AGO .I0                                                        96179821
.MEND    MEND                                                           96199821
