         MACRO                                                          00500000
         SGIFF2BM                                                       01000000
.*3211,009600,014400                                               AHD4 01500000
.*C105000                                                        A61544 01550021
         COPY  SGGBLPAK                      GET GLOBAL VARIABLES       02000000
         LCLA  &CU,&LTBLIX,&DADRIX,&NUM2840,&CUSTBL(40)                 02500000
         LCLA  &NUMMOD1,&DEV,&CUSTBLX,&BFRSIZE(96),&EXPBFR(40)          03000000
         LCLA  &A,&B,&C,&D,&E,&F,&G,&NUMSEC1(40)                        03500000
         LCLA  &NUMSEC2(40),&NUMSEC3(40),&NUMSEC4(40),&NUMSEC5(40)      04000000
         LCLA  &NUMSEC6(40),&NUMSEC7(40),&NUMSEC8(40),&NUMDEV(40)       04500000
         LCLA  &CONVCON                                            AHD4 05000000
         LCLA  &HI,&LO                                                  05500000
         LCLB  &ASMBLY                                                  06000000
         LCLC  &DEVADR,&TBLNAME(96),&CUADDR,&LSTCUNM,&X,&DVADR          06500000
&CU      SETA  1                             SET CU SWITCH SUBSCRIPT    07000000
&CUSTBLX SETA  1                             SET CU SW SUBSCPT TBL INDX 07500000
&NUM2840 SETA  0                             SET 2840 COUNTER           08000000
.BM01    AIF   (NOT &SGUNT2B(&CU)).BM02      CHK TYPE SWITCH            08500000
         AIF   (NOT &SGUNU6B(&CU)).BM02      CHK FOR 2840 CU            09000000
&CUSTBL(&CUSTBLX) SETA &CU                   SET CU SUBSCRIPT IN TABLE  09500000
         AIF   (&SGUNM2B(&CU)).BM01B         CHK FOR MOD 2              10000000
         AIF   (&SGUNF1B(&CU)).BM01A         CHK FOR 8K FEATURE         10500021
&BFRSIZE(&CUSTBLX) SETA 8192                 SET BFR SIZE IN TABLE      11000000
         AGO   .BM01C                        BRANCH TO INCREM INDEX     11500000
.BM01A   ANOP                                                           12000000
&BFRSIZE(&CUSTBLX) SETA 16384                SET BFR SIZE IN TABLE      12500000
         AGO   .BM01C                        BRANCH TO INCREM INDEX     13000000
.BM01B   ANOP                                                           13500000
&BFRSIZE(&CUSTBLX) SETA 32768                SET BFR SIZE IN TABLE      14000000
.BM01C   ANOP                                                           14500000
&CUSTBLX SETA  &CUSTBLX+1                    INCREMENT CU TABLE INDEX   15000000
&NUM2840 SETA  &NUM2840+1                    INCREMENT CU COUNTER       15500000
.BM02    ANOP                                                           16000000
         AIF   (&CU EQ &SGCNTRA(2)).BM03     CHK FOR LAST CU            16500000
&CU      SETA  &CU+1                         INCREMENT CU SW SUBSCRIPT  17000000
         AGO   .BM01                         BRANCH TO CHK NEXT CU      17500000
.BM03    ANOP                                                           18000000
&LTBLIX  SETA  41                            SET LOCAL TABLES INDEX     18500000
&NUMMOD1 SETA  0                             SET 2250 MOD 1 COUNTER     19000000
&DEV     SETA  1                             SET DEV ADR SW SUBSCRIPT   19500000
.BM04    ANOP                                                           20000000
&DADRIX  SETA  &SGDADRA(&DEV)/1048576                              000A 20500000
         AIF   (NOT &SGDT05B(&DADRIX)).BM22  CHK FOR GRAPHIC DEVICE     21000000
         AIF   (NOT &SGDU01B(&DADRIX)).BM04A  CHK FOR 2250 DEVICE       21500000
         AIF   (&SGDM01B(&DADRIX)).BM04B     CHK FOR MODEL 1            22000000
         AIF   (&SGDM02B(&DADRIX) OR &SGDM03B(&DADRIX)).BM07 CHK MOD2/3 22500000
         AGO   .BM22                         BRANCH TO CHK IF LAST DEV  23000000
.BM04A   AIF   (&SGDU04B(&DADRIX) OR &SGDU05B(&DADRIX)).BM07            23500000
         AGO   .BM22                         BRANCH TO CHK IF LAST DEV  24000000
.BM04B   ANOP                                                           24500000
&ASMBLY  SETB  1                             SET ASSEMBLY SWITCH        25000000
&CONVCON SETA  &SGDADRA(&DEV)-&SGDADRA(&DEV)/4096*4096 ISOLATE ADD AHD4 25500000
         CONVERT TO=EBCDIC,VALUE=&CONVCON,DIGITS=3 CONV DEV NAME   AHD4 26000000
&TBLNAME(&LTBLIX) SETC '&EBCDIC'             SET DEV NAME IN NAME TABLE 26500000
         AIF   (&SGDF05B(&DADRIX)).BT04C     CHK FOR BUFFER SIZE        27000000
         AIF   (&SGDF06B(&DADRIX)).BM05      CHK FOR BUFFER SIZE        27500000
&BFRSIZE(&LTBLIX) SETA 0                     SET BUF TABLE TO 0         28000000
         AGO   .BM06                         BRANCH TO INCREM CTR & IDX 28500000
.BT04C   ANOP                                                           29000000
&BFRSIZE(&LTBLIX) SETA 4096                  SET BUF TABLE TO 4096      29500000
         AGO   .BM06                         BRANCH TO INCREM CTR & IDX 30000000
.BM05    ANOP                                                           30500000
&BFRSIZE(&LTBLIX) SETA 8192                  SET BUF TABLE TO 8192      31000000
.BM06    ANOP                                                           31500000
&NUMMOD1 SETA  &NUMMOD1+1                    INCREMENT 2250 MOD 1 CTR   32000000
&LTBLIX  SETA  &LTBLIX+1                     INCREMENT LOCAL TBLES INDX 32500000
         AGO   .BM22                         BRANCH TO CHK IF LAST DEV  33000000
.BM07    ANOP                                                           33500000
&CU      SETA  &SGDADRA(&DEV)/4096-&SGDADRA(&DEV)/1048576*256      000A 34000000
&CUSTBLX SETA  1                             SET CU SW SUBSCPT TBL INDX 34500000
.BM08    AIF   (&CUSTBL(&CUSTBLX) EQ &CU).BM09  DOES CU IN TBL =DEV CU  35000000
         AIF   (&CUSTBLX EQ &NUM2840).BM22   CHK FOR LAST 2840          35500000
&CUSTBLX SETA  &CUSTBLX+1                    INC CU SW SUBSCPT TBL INDX 36000000
         AGO   .BM08                         BRANCH TO CHK NEXT CU      36500000
.BM09    ANOP                                                           37000000
&ASMBLY  SETB  1                             SET ASSEMBLY SWITCH        37500000
&CONVCON SETA  &SGDADRA(&DEV)-&SGDADRA(&DEV)/4096*4096 ISOLATE ADD AHD4 38000000
         CONVERT TO=EBCDIC,VALUE=&CONVCON,DIGITS=3 CONV DEV NAME   AHD4 38500000
&TBLNAME(&CUSTBLX) SETC '&EBCDIC'            SET CU NAME IN NAME TABLE  39000000
&EXPBFR(&CUSTBLX) SETA &SGCUN1A(&CU)         SET EXP BUF SIZE IN TABLE  39500000
         AIF   (&NUMDEV(&CUSTBLX) EQ 0).BM13  CHK FOR CORRECT TBL SLOT  40000000
         AIF   (&NUMDEV(&CUSTBLX) EQ 1).BM14  CHK FOR CORRECT TBL SLOT  40500000
         AIF   (&NUMDEV(&CUSTBLX) EQ 2).BM15  CHK FOR CORRECT TBL SLOT  41000000
         AIF   (&NUMDEV(&CUSTBLX) EQ 3).BM16  CHK FOR CORRECT TBL SLOT  41500000
         AGO   .BM22               NO SLOTS OPEN, BR TO CHK IF LAST DEV 42000000
.BM13    ANOP                                                           42500000
&NUMSEC1(&CUSTBLX) SETA &SGDNBFA(&DADRIX)    SET NUM OF SECT FOR DEV 1  43000000
         AGO   .BM21                         BRANCH TO INC DEV CTR      43500000
.BM14    ANOP                                                           44000000
&NUMSEC2(&CUSTBLX) SETA &SGDNBFA(&DADRIX)    SET NUM OF SECT FOR DEV 2  44500000
         AGO   .BM21                         BRANCH TO INC DEV CTR      45000000
.BM15    ANOP                                                           45500000
&NUMSEC3(&CUSTBLX) SETA &SGDNBFA(&DADRIX)    SET NUM OF SECT FOR DEV 3  46000000
         AGO   .BM21                         BRANCH TO INC DEV CTR      46500000
.BM16    ANOP                                                           47000000
&NUMSEC4(&CUSTBLX) SETA &SGDNBFA(&DADRIX)    SET NUM OF SECT FOR DEV 4  47500000
.BM21    ANOP                                                           48000000
&NUMDEV(&CUSTBLX) SETA &NUMDEV(&CUSTBLX)+1   INC DEV COUNT FOR THIS CU  48500000
.BM22    AIF   (&DEV EQ &SGCNTRA(3)).BM23    CHK FOR LAST DEVICE        49000000
&DEV     SETA  &DEV+1                        INCREM DEV ADR SW SUBSCRIP 49500000
         AGO   .BM04                         BRANCH TO PROCESS NEXT DEV 50000000
.BM23    AIF   (NOT &ASMBLY).BM29            CHK IF ASSEMBLY SW IS SET  50500000
&SGCTRLC(6) SETC 'IFFBDA'                    SET CSECT NAME             51000000
         COPY  SGASMPAK                      COPY ASSEMBLY MACRO        51500000
         PUNCH 'IFFBDA   CSECT'                                         52000000
         AIF   (&NUM2840 EQ 0).BM26          CHK FOR NO 2840            52500000
&LTBLIX  SETA  1                             SET LOCAL TABLE INDEX      53000000
.BM24    ANOP                                                           53500000
         AIF   ('&TBLNAME(&LTBLIX)' EQ '').BM25E NO CU IN TABLE  LI     54000000
&CUADDR  SETC  '&TBLNAME(&LTBLIX)'(1,2)  SET CU ADDRESS                 54500000
&X       SETC  ' '                 SET X BLANK                          55000000
         AIF   ('&LSTCUNM' EQ '&CUADDR').BM50     DUP ADDRESS           55500000
&HI      SETA  0                          CLEAR HI SWITCH               56000000
&LO      SETA  0                        CLEAR LO SWITCH                 56500000
.BM50    ANOP                                                           57000000
&DVADR   SETC  '&TBLNAME(&LTBLIX)'(3,1)       GET DEV ADDR              57500000
         AIF   ('&DVADR' GE '0' AND '&DVADR' LE '7').LOW                58000000
         AIF   ('&DVADR' EQ '8' OR '&DVADR' EQ '9').HIGH                58500000
         AIF   ('&DVADR' GE 'A' AND '&DVADR' LE 'F').HIGH               59000000
         AGO   .ERROR                   INVALID DEVICE                  59500000
.LOW     ANOP                                                           60000000
         AIF   (&LO GE 1).ERROR        DUP LOW DEVICE                   60500000
&LO      SETA  1                       SET LOW SWITCH ON                61000000
         AGO   .PROCESS                                                 61500000
.HIGH    ANOP                                                           62000000
&X       SETC  'X'                  SET X FOR HIGH                      62500000
         AIF   (&HI GE 1).ERROR        DUP HIGH DEVICE                  63000000
&HI      SETA  1                       SET HI SWITCH ON                 63500000
.PROCESS ANOP                                                           64000000
&A       SETA  &BFRSIZE(&LTBLIX)             SET BUFFER SIZE            64500000
&B       SETA  &EXPBFR(&LTBLIX)              SET EXP BUFF REQUIREMENT   65000000
&C       SETA  &NUMDEV(&LTBLIX)              SET DEVICE COUNT           65500000
&D       SETA  &NUMSEC1(&LTBLIX)                  SET SECTIONS VALUE    66000000
&E       SETA  &NUMSEC2(&LTBLIX)                  SET SECTIONS VALUE    66500000
&F       SETA  &NUMSEC3(&LTBLIX)                  SET SECTIONS VALUE    67000000
&G       SETA  &NUMSEC4(&LTBLIX)                  SET SECTIONS VALUE    67500000
.BM25    ANOP                                                           68000000
         PUNCH 'IFFB&CUADDR&X SGIFF0BT &A,&B,&C,&D,&E,&F,&G'            68500000
.BM25A   ANOP                                                           69000000
         AIF   (&NUM2840 EQ &LTBLIX).BM26    CHK FOR LAST 2840          69500000
&D       SETA  0                             SET SECT QTY 1 PARAMETER   70000000
&E       SETA  0                             SET SECT QTY 2 PARAMETER   70500000
&F       SETA  0                             SET SECT QTY 3 PARAMETER   71000000
&G       SETA  0                             SET SECT QTY 4 PARAMETER   71500000
.INCRNDX ANOP                                                           72000000
&LTBLIX  SETA  &LTBLIX+1               INCREMENT TABLE INDEX            72500000
&LSTCUNM SETC  '&CUADDR'                 SAVE LAST CU ADDRESS           73000000
         AGO   .BM24                         BRANCH TO PROCESS NEXT CU  73500000
.ERROR   ANOP                                                           74000000
         MNOTE 8,'****&CUADDR&DVADR IS INVALID DUPLICATE ADDRESS***'    74500000
         AGO   .BM25A                                                   75000000
.BM25E   ANOP                                                           75500000
         MNOTE 8,'INVALID CU/2250 MOD1 COMBINATION'                     76000000
         AGO   .BM25A                                                   76500000
.BM26    ANOP                                                           77000000
         AIF   (&NUMMOD1 EQ 0).BM28          CHK FOR NO MOD 1           77500000
&LTBLIX  SETA  41                            SET LOCAL TABLE INDEX      78000000
.BM27    ANOP                                                           78500000
&DEVADR  SETC  '&TBLNAME(&LTBLIX)'           SET BUFFER TABLE NAME      79000000
&A       SETA  &BFRSIZE(&LTBLIX)             SET BUFFER SIZE            79500000
         PUNCH 'IFFB&DEVADR SGIFF0BT &A'                                80000000
         AIF   (&NUMMOD1 EQ 1).BM28          CHK FOR LAST 2250          80500000
&NUMMOD1 SETA  &NUMMOD1-1                    DECREMENT 2250 MOD 1 CTR   81000000
&LTBLIX  SETA  &LTBLIX+1                     INCREM LOCAL TABLE INDEX   81500000
         AGO   .BM27                         BRANCH TO PROCESS NEXT DEV 82000000
.BM28    ANOP                                                           82500000
         PUNCH '         END'                                           83000000
         PUNCH '/*'                                                     83500000
.BM29    ANOP                                                           84000000
         MEND                                                           84500000
