         MACRO                                                          00020000
 SUPRVSOR &OPTIONS=,&RESIDNT=,&SER=,&TIMER=,&WAIT=,&TRACE=,&USERERR=NO,*00030019
               &ALTSYS=,&ASCII=EXCLUDE,&LOAD=STANDARD                   00040021
         COPY  SGGBLPAK                                                 00060000
         LCLA  &A                                                       00080000
 LCLC &B,&C,&D                                                          00100019
         AIF  (&SGMENTB(10)).MR        SUPRVSOR ENTRY SWITCH            00120000
&SGMENTB(10)  SETB   1      SUPRVSOR ENTRY SWITCH.                      00140000
&SGSUPRB(2) SETB 1            PATCH AREA ALWAYS INCLUDED IN NUCLEUS     00150020
         AIF   (T'&OPTIONS EQ 'O').RES                                  00160000
    MNOTE *,'     SUPERVISOR OPTION(S)'                                 00180000
.BACK1 AIF (&A GE N'&OPTIONS).DDFIN                                     00200019
&A       SETA  &A+1                                                     00220000
         AIF   ('&OPTIONS(&A)' EQ 'IDENTIFY').ID                        00240000
  AIF  ('&OPTIONS(&A)' EQ 'TRSVCTBL').SV                                00280000
   AIF ('&OPTIONS(&A)' EQ 'VALIDCHK').VC                                00300000
 AIF ('&OPTIONS(&A)' EQ 'COMM').CO                                      00320000
 AIF ('&OPTIONS(&A)' EQ 'PROTECT').PR                                   00340000
 AIF ('&OPTIONS(&A)' EQ 'ONLNTEST').ONL                                 00360000
   AIF ('&OPTIONS(&A)' EQ 'DECSIM').DS                                  00380000
 AIF ('&OPTIONS(&A)' EQ 'CCH').CH                                       00390014
         AIF   ('&OPTIONS(&A)' EQ 'RER').RE                             00395017
 AIF ('&OPTIONS(&A)' EQ 'NODAV').NO                                     00395518
 AIF ('&OPTIONS(&A)' EQ 'DDR').DR                                       00396419
 AIF ('&OPTIONS(&A)' EQ 'DDRSYS').RSYS                                  00397319
 AIF ('&OPTIONS(&A)' EQ 'APR').AR                                       00398219
 AIF ('&OPTIONS(&A)' EQ 'DDRNSL').RNSL                                  00399119
 AIF  ('&OPTIONS(&A)' EQ 'ATTACH').ATCH                                 00399519
 AIF  ('&OPTIONS(&A)' EQ 'RDE').RDE                                     00399720
    MNOTE 5,'* * * IEISUP101 OPTIONS VALUE &OPTIONS(&A) INVALID'        00400000
&SGQUITB SETB  1                                                        00420000
         AGO    .BACK1                                                  00440000
.ID MNOTE *,'        IDENTIFY'                                          00460000
&SGSUPRB(1)     SETB 1                                                  00480000
         AGO   .BACK1                                                   00500000
.SV MNOTE *,'        TRANSIENT SVC TABLE'                               00580000
&SGSUPRB(3)     SETB 1                                                  00600000
         AGO   .BACK1                                                   00620000
.VC  ANOP      THIS ENTRY SETS SWITCH 27 TO SHOW ENTRY FROM VALIDCHK    00640000
&SGSUPRB(27) SETB 1                                                     00660000
.VA AIF (&SGSUPRB(4)).BACK1                                             00680000
    MNOTE *,'       EXTRA VALIDITY CHECKING'                            00700000
&SGSUPRB(4)    SETB 1                                                   00720000
         AGO   .BACK1                                                   00740000
.CO MNOTE *,'       COMMUNICATION'                                      00760000
&SGSUPRB(22) SETB  1                                                    00780000
  AGO  .BACK1                                                           00800000
.PR MNOTE *,'       STORAGE PROTECTION'                                 00820000
&SGSUPRB(23)  SETB  1                                                   00840000
  AGO  .VA                                                              00860000
.ONL MNOTE *,'       ON-LINE TESTING'                                   00880019
&SGSUPRB(26)   SETB  1                                                  00900000
  AGO    .BACK1                                                         00920000
.DS MNOTE *,'       DECIMAL SIMULATOR INCLUDED'                         00940000
&SGSUPRB(24)  SETB 1                                                    00960000
   AGO  .BACK1                                                          00965018
.NO MNOTE *,'       NO DIRECT ACCESS VOLUME SERIAL VERIFICATION'        00970018
&SGSUPRB(36)  SETB  1                                                   00975018
         AGO   .BACK1                                                   00980018
.CH MNOTE *,'       CHANNEL CHECK HANDLER'                              00985014
&SGSUPRB(29) SETB 1                                                     00990014
  AGO    .BACK1                                                         00995014
.RE MNOTE *,'       REDUCED TAPE ERROR RECOVERY'                        00996017
&SGSUPRB(32)  SETB  1                                                   00997017
         AGO   .BACK1                                                   00998017
.DR MNOTE *,'       DYNAMIC DEVICE RECONFIGURATION'                     00998819
&SGSUPRB(33) SETB 1                                                     00999619
 AGO .BACK1                                                             01000419
.RSYS MNOTE *,'       DYNAMIC DEVICE RECONFIGURATION FOR SYSTEM'        01000919
 MNOTE *,'        RESIDENCE DEVICE'                                     01001419
&SGSUPRB(34) SETB 1                                                     01002019
 AGO .BACK1                                                             01002819
.AR MNOTE *,'       ALTERNATE PATH RETRY'                               01003619
&SGSUPRB(35) SETB 1                                                     01004419
 AGO .BACK1                                                             01005219
.RNSL MNOTE *,'       DYNAMIC DEVICE RECONFIGURATION FOR NON-STANDARD'  01006019
 MNOTE *,'        LABELED TAPES'                                        01006819
&SGSUPRB(39) SETB 1                                                     01007619
 AGO .BACK1                                                             01008419
.ATCH MNOTE *,'       ASYNCHRONOUS ATTACH'                              01008519
&SGSUPRB(37)  SETB  1                                                   01008619
&SGSUPRB(16)  SETB  1                                                   01008719
&SGSUPRB(17)  SETB  1                                                   01008819
     AGO  .BACK1                                                        01008919
.RDE  MNOTE *,'            RDE'                                         01009120
&SGSUPRB(43)   SETB  1                                                  01009320
         AGO   .BACK1                                                   01009520
.DDFIN   AIF   (&SGSUPRB(33)).CKALT                                     01009720
 AIF (&SGSUPRB(34) OR &SGSUPRB(39)).SET33                               01010019
 AGO .CKALT                                                             01010819
.SET33 ANOP                                                             01011619
&SGSUPRB(33) SETB 1                                                     01012419
 MNOTE *,'       DYNAMIC DEVICE RECONFIGURATION ASSUMED'                01013219
.CKALT AIF (&SGSUPRB(34) AND T'&ALTSYS NE 'O').DAVV                     01014819
 AIF (NOT &SGSUPRB(34)).DAVV                                            01015619
 MNOTE 5,'* * * IEISUP110 OPTIONS=DDRSYS REQUIRES ALTSYS'               01016419
&SGQUITB SETB 1                                                         01017219
.DAVV AIF (NOT(&SGSUPRB(33) AND &SGSUPRB(36))).RES                      01017319
&SGSUPRB(36) SETB 0                                                     01017419
 MNOTE 0,'* * * IEISUPW01 DIRECT ACCESS VOLUME VERIFICATION REQUIRED'   01017519
 MNOTE *,'      WITH OPTIONS=DDR -- OPTIONS=NODAV IGNORED'              01017619
.RES AIF (T'&RESIDNT EQ 'O').SERR                                       01018019
    MNOTE *,'     SUPERVISOR FUNCTIONS TO BE ALWAYS RESIDENT'           01020000
&A       SETA  0                                                        01040000
.BACK2   AIF   (&A GE N'&RESIDNT).SERR                                  01060000
&A       SETA  &A+1                                                     01080000
  AIF  ('&RESIDNT(&A)' NE 'ATTACH').RES1                                01100000
&SGSUPRB(5)  SETB  1                                                    01120000
   AGO  .OK                                                             01140000
.RES1  AIF  ('&RESIDNT(&A)' NE 'EXTRACT').RES2                          01160000
&SGSUPRB(6)  SETB  1                                                    01180000
  AGO  .OK                                                              01200000
.RES2  AIF  ('&RESIDNT(&A)' NE 'IDENTIFY').RES3                         01220000
&SGSUPRB(7)  SETB  1                                                    01240000
&SGSUPRB(1)  SETB  1                                                    01260000
  AGO  .OK                                                              01280000
.RES3 AIF ('&RESIDNT(&A)' NE 'SPIE').RES4                               01300000
&SGSUPRB(8)  SETB  1                                                    01320000
  AGO  .OK                                                              01340000
.RES4 AIF ('&RESIDNT(&A)' NE 'BLDLTAB').RES5                            01360000
&SGSUPRB(20) SETB  1                                                    01380000
  AGO  .OK                                                              01400000
.RES5  AIF  ('&RESIDNT(&A)' NE 'ACSMETH').RES6                          01420000
&SGSUPRB(21)  SETB  1                                                   01440000
   AGO  .OK                                                             01460000
.RES6    AIF   ('&RESIDNT(&A)' NE 'TRSVC').RES7                         01480000
&SGSUPRB(25)  SETB  1                                                   01500000
   AGO  .OK                                                             01520000
.RES7 AIF ('&RESIDNT(&A)' NE 'RENTCODE').RES9                           01540020
&SGSUPRB(21)   SETB  1                                                  01560000
&SGSUPRB(38)  SETB  1  LINK PACK AREA SWITCH FOR MFT-II                 01570018
         AGO    .OK                                                     01580000
.RES9 AIF ('&RESIDNT(&A)' NE 'ERP').XX                                  01596019
&SGSUPRB(40) SETB 1                                                     01597019
  AGO .OK                                                               01598019
.XX MNOTE 5,'* * * IEISUP102 RESIDNT VALUE &RESIDNT(&A) INVALID'        01600000
&SGQUITB  SETB  1                                                       01620000
  AGO  .BACK2                                                           01640000
.OK MNOTE *,'         &RESIDNT(&A)'                                     01660000
  AGO  .BACK2                                                           01680000
.SERR    AIF   (T'&SER EQ 'O').WAIT                                     01700000
         AIF   ('&SER' EQ 'SER0').S0                                    01720000
         AIF   ('&SER' EQ 'SER1').S1                                    01740000
         AIF   ('&SER' EQ 'MCH').S2                                     01750015
         AIF   ('&SER' EQ 'SEREP').S3                                   01755017
    MNOTE 5,'* * * IEISUP103 SER VALUE &SER INVALID'                    01760000
&SGQUITB SETB  1                                                        01780000
         AGO   .WAIT                                                    01800000
.S0 MNOTE *,'     SER LEVEL IS ZERO'                                    01820000
&SGSUPRB(9)    SETB 1                                                   01840000
         AGO   .WAIT                                                    01860000
.S1 MNOTE *,'     SER LEVEL IS ONE'                                     01880000
&SGSUPRB(10)   SETB 1                                                   01900000
         AGO   .WAIT                                                    01905013
.S2 MNOTE *,'       MACHINE CHECK HANDLER RECOVERY REQUESTED'           01910015
&SGSUPRB(28)  SETB  1                                                   01915013
         AGO  .WAIT                                                     01916017
.S3 MNOTE *,'     SER LEVEL IS SEREP'                                   01917017
&SGSUPRB(31)  SETB  1                                                   01918017
.WAIT    AIF   (T'&WAIT EQ 'O').TIMER                                   01920000
         AIF   ('&WAIT' EQ 'SINGLE').S                                  01940000
         AIF   ('&WAIT' EQ 'MULTIPLE').M                                01960000
    MNOTE 5,'* * * IEISUP104 WAIT VALUE &WAIT INVALID'                  01980000
&SGQUITB SETB  1                                                        02000000
         AGO   .TIMER                                                   02020000
.S  MNOTE *,'     SINGLE EVENT WAIT REQUESTED'                          02040000
&SGSUPRB(11)   SETB 1                                                   02060000
         AGO   .TIMER                                                   02080000
.M  MNOTE *,'     MULTIPLE EVENT WAIT REQUESTED'                        02100000
&SGSUPRB(12)   SETB 1                                                   02120000
.TIMER   AIF   (T'&TIMER EQ 'O').TRACE                                  02140000
         AIF   ('&TIMER' EQ 'TIME').T                                   02160000
         AIF   ('&TIMER' EQ 'INTERVAL').I                               02180000
         AIF   ('&TIMER' EQ 'JOBSTEP').J                                02200000
    MNOTE 5,'* * * IEISUP105 TIMER VALUE &TIMER INVALID'                02220000
&SGQUITB SETB  1                                                        02240000
         AGO   .TRACE                                                   02260000
.J  MNOTE *,'      ''JOBSTEP TIMING'' FUNCTION REQUESTED'               02280000
&SGSUPRB(19) SETB 1                                                     02300000
&SGSUPRB(16)   SETB 1                                                   02310019
  AGO  .TRACE                                                           02320000
.T  MNOTE *,'     ''TIME'' FUNCTION REQUESTED'                          02340000
&SGSUPRB(13)   SETB 1                                                   02360000
         AGO   .TRACE                                                   02380000
.I  MNOTE *,'     ''INTERVAL TIMER'' FUNCTION REQUESTED'                02400000
&SGSUPRB(14)   SETB 1                                                   02420000
&SGSUPRB(16) SETB 1                                                     02440000
.TRACE  AIF   (T'&TRACE EQ 'O').TSKTIME                                 02460017
         AIF  (T'&TRACE NE 'N' OR '&TRACE' EQ '0').ER                   02480000
&SGSUPRA(1)    SETA &TRACE                                              02500000
    MNOTE *,'     THERE WILL BE A TRACE TABLE WITH &TRACE ENTRIES'      02520000
    AGO  .TSKTIME                                                       02540017
.ER MNOTE 5,'* * * IEISUP106 TRACE VALUE &TRACE INVALID'                02560000
&SGQUITB SETB  1                                                        02580000
.TSKTIME ANOP                                                           02590017
 AIF (T'&ALTSYS EQ 'O').USERERR                                         02593019
 AIF (K'&ALTSYS NE 3).ALTERR                                            02593119
&B SETC '&ALTSYS'(1,1)                                                  02593219
&C SETC '&ALTSYS'(2,1)                                                  02593319
&D SETC '&ALTSYS'(3,1)                                                  02593419
 AIF (NOT(('&B' GE '0' AND '&B' LE '9') OR ('&B' GE 'A' AND '&B' LE 'F'*02593519
               ))).ALTERR                                               02593619
 AIF (NOT(('&C' GE '0' AND '&C' LE '9') OR ('&C' GE 'A' AND '&C' LE 'F'*02593719
               ))).ALTERR                                               02593819
 AIF (NOT(('&D' GE '0' AND '&D' LE '9') OR ('&D' GE 'A' AND '&D' LE 'F'*02593919
               ))).ALTERR                                               02594019
 MNOTE *,'       ALTERNATE SYSTEM RESIDENCE DEVICE FOR DDR IS &ALTSYS'  02594119
 CONVERT TO=HEX,VALUE=&ALTSYS,DIGITS=3                                  02595019
&SGSUPRA(2) SETA &HEX                                                   02596019
 AGO .USERERR                                                           02597019
.ALTERR MNOTE 5,'* * * IEISUP109 ALTSYS VALUE &ALTSYS INVALID'          02598019
&SGQUITB SETB 1                                                         02599019
.USERERR AIF   ('&USERERR(1)' EQ 'NO').LOAD                             02609021
         AIF   ('&USERERR(1)' NE 'YES').EU                              02620000
    MNOTE *,'     THE USER ASYNCHRONOUS ERROR EXITS OPTION IS INCLUDED' 02640000
&SGSUPRB(18)   SETB  1                                                  02660000
.LOAD    AIF   ('&LOAD' EQ 'STANDARD').ASCII                            02662021
         AIF   ('&LOAD' EQ 'EXPLICIT').EXLOAD                           02662421
    MNOTE 5,'* * * IEISUP111 LOAD VALUE &LOAD INVALID'                  02662821
&SGQUITB SETB 1                                                         02662921
         AGO   .ASCII                                                   02666721
.EXLOAD MNOTE *,'      EXPLICIT LOAD FUNCTION REQUESTED'                02668721
&SGSUPRB(44)   SETB 1                                                   02668821
.ASCII   AIF   ('&ASCII' EQ 'EXCLUDE').EX                               02670621
         AIF   ('&ASCII' NE 'INCRES').IT                                02674421
&SGSUPRB(41)   SETB 1                                                   02678221
&SGSUPRB(42)   SETB 1                                                   02682021
    MNOTE *,'       THE ASCII TRANSLATE SVC IS INCLUDED RESIDENT.'      02685821
         AGO   .MEND                                                    02689621
.IT      AIF   ('&ASCII' NE 'INCTRAN').EY                               02693421
&SGSUPRB(41)   SETB 1                                                   02697221
    MNOTE *,'       THE ASCII TRANSLATE SVC IS INCLUDED TRANSIENT.'     02701021
         AGO   .MEND                                                    02704821
.EX MNOTE *,'       THE ASCII TRANSLATE SVC IS EXCLUDED.'               02708621
         AGO   .MEND                                                    02712421
.EU MNOTE 5,'* * * IEISUP107 USERERR VALUE &USERERR INVALID'            02716221
&SGQUITB SETB  1                                                        02720000
         MEXIT                                                          02740000
.EY MNOTE 5,'* * * IEISUP109  ASCII VALUE &ASCII IS INVALID.'           02745020
&SGQUITB SETB  1                                                        02750020
         MEXIT                                                          02755020
.MR MNOTE 5,'* * * IEISUP108 SUPRVSOR MACRO PREVIOUSLY USED'            02760000
&SGQUITB   SETB   1                                                     02780000
.MEND  ANOP                                                             02800000
   MEND                                                                 02820000
