         MACRO                          HEADER STATEMENT                00020000
&NAME    ASGNBFR &DCB,&NUM,&MF=         PROTOTYPE STATEMENT             00040000
         LCLC  &PAREN,&REG,&B            LOCALS DEFINED                 00060000
         LCLA  &ADCB,&ANUM,&ASECT       DEFINE LOCALS                   00080000
         AIF   (T'&MF EQ 'O').SFORM      S-FORM ASSUMED IF MF= OMITTED  00100000
         AIF   (N'&MF EQ 2).EFORM            ARE THERE 2 OPERANDS       00120000
         AIF   ('&MF(1)' EQ 'L').LFORM  POSITIVE CHECK FOR L FORM       00140000
         AGO   .ERREMF                                                  00160000
.EFORM   AIF   ('&MF(1)' NE 'E').ERREMF      POSITIVE CHECK FOR E FORM  00180000
         AIF   ('&MF(2)'(1,1) EQ '(').REGMF  CHECK NOTATION OF LSTADDR  00200000
&NAME    LA    1,&MF(2)                  REG 1 CONTAINS LSTADDR         00220000
.CHECK   AIF   (T'&DCB EQ 'O' AND T'&NUM EQ 'O').DONE  IF OMITTED,DONE  00240000
         AIF   (T'&DCB NE 'O').CHANGE1       ONLY DCB ADR SPECIFIED     00260000
.NUMB    AIF   ('&NUM'(1,1) EQ '(').REGNUM  CHECK FOR REGISTER NOTATIN  00280000
         LA    0,&NUM                    PUT BUFPRAM-ADDR IN PARAMLIST  00300000
         ST    0,4(1)                    PUT BUFPRAM-ADDR IN PARAMLIST  00320000
         AGO   .DONE                    BRANCH TO SVC INSTRUCTION       00340000
.CHANGE1 AIF   ('&DCB'(1,1) EQ '(').REGDCB  CHECK NOTATION OF DCBADDR   00360000
         LA    0,&DCB                  PUT DCB IN PARAM LIST            00380000
         ST    0,0(1)                  PUT DCB IN PARAM LIST            00400000
.GOON    AIF   (T'&NUM NE 'O').NUMB                                     00420000
.DONE    MVI   0(1),X'04'                REINSTATE CODE ON LIST         00440000
         SVC   71                        SVC THE ASSIGN BUFFER RTN      00460000
         MEXIT                      BRANCH OUT OF MACRO DEFN            00480000
.REGMF   ANOP                            CHECK FOR REG NOTATION OF LST  00500000
&REG     SETC  '&MF(2)'(2,K'&MF(2)-2)    ISOLATE REG NUMBER             00520000
&NAME    LR    1,&REG                    PUT LSTADDR IN REG 1           00540000
         AGO   .CHECK                                                   00560000
.REGDCB  ANOP                                                           00580000
&PAREN   SETC  '&DCB'(2,K'&DCB-2)        ISOLATE REGISTER NIMBER        00600000
         ST &PAREN,0(1)                  PUT DCBADDR IN PARAM LIST      00620000
         AGO   .GOON                                                    00640000
.REGNUM  ANOP                                                           00660000
&REG     SETC  '&NUM'(2,K'&NUM-2)        ISOLATE REGISTER NUMBER        00680000
         ST    &REG,4(1)                 PUT BUFPRAM-ADDR IN PARAMLIST  00700000
         AGO   .DONE                                                    00720000
.SFORM   ANOP                                                           00740000
&NAME    LA    1,A&SYSNDX              LOAD ADR OF PARAM LST            00760000
         AIF   (T'&DCB EQ 'O').NODCB                                    00780000
         AIF   ('&DCB'(1,1) EQ '(').REGSDCB  CHECK NOTATION OF DCBADDR  00800000
&PAREN   SETC  '&DCB'(1,1)               TO CHECK 1ST CHAR OF DCBADDR   00820000
         AIF   ('&PAREN' LT 'A').ERRDCB   IF NOT ALPHA CHAR, ERROR      00840000
         AIF   ('&PAREN' GT 'Z').ERRDCB   IF NOT ALPHA CHAR, ERROR      00860000
&ADCB    SETA  1                   SET TO 1 IF SYMBOLIC                 00880000
.OK1     AIF   (T'&NUM EQ 'O').NONUM     CHECK FOR PTR OPERAND          00900000
.CONTINU AIF   ('&NUM'(1,1) EQ '(').REGSNUM  CHECK FOR REGISTER         00920000
&ANUM    SETA  1                        SET TO 1IF SYMBOLIC             00940000
.ONWARD  CNOP  2,4                                                      00960000
         SVC   71                        SVC THE ASSIGN BUFFER RTN      00980000
         B     A&SYSNDX+8                BRANCH AROUND PARAM LIST       01000000
         AIF   (&ADCB EQ 1).SYM1   IF 1 GO TO SYM1                      01020000
A&SYSNDX DC    A(0)                CODE AND DCBADR                      01040000
.CHK1    AIF   (&ANUM EQ 1).SYM2        IF 1 GO TOSYM2                  01060000
         DC    A(0)                BUFPRM                               01080000
         MEXIT                           BRANCH OUT OF  MACRO DEFN      01100000
.SYM1    ANOP                                                           01120000
A&SYSNDX DC    AL1(4)              CODE FOR ASSIGN                      01140000
         DC    AL3(&DCB)           DCBADR                               01160000
         AGO   .CHK1                                                    01180000
.SYM2    DC    A(&NUM)             BUFPRM PTR                           01200000
         MEXIT                                                          01220000
.REGSDCB ANOP                                                           01240000
&REG     SETC  '&DCB'(2,K'&DCB-2)        ISOLATE REGISTER NUMBER        01260000
         ST    &REG,A&SYSNDX             PUT  IT IN PARAM LIST          01280000
         MVI   A&SYSNDX,X'04'            REINSTATE CODE                 01300000
         AGO   .OK1                                                     01320000
.REGSNUM ANOP                                                           01340000
&REG     SETC  '&NUM'(2,K'&NUM-2)                                       01360000
         ST    &REG,A&SYSNDX+4           PUT BUFPRAM-ADDR IN PARAMLIST  01380000
         AGO   .ONWARD                                                  01400000
.LFORM   AIF   (T'&DCB EQ 'O' AND T'&NUM EQ 'O').FINI                   01420000
         AIF   (T'&DCB NE 'O').CHK                                      01440000
.NUM     ANOP                                                           01460000
&PAREN   SETC  '&NUM'(1,1)                                              01480000
         AIF   ('&PAREN' LT 'A' OR '&PAREN' GT 'Z').ERRNUM              01500000
&ANUM    SETA  1                        SET TO 1                        01520000
.FINI    DS    0F                        START GENERATED CODING         01540000
&NAME    DC    AL1(4)                    CODE FOR ASGNBF                01560000
         AIF   (&ADCB EQ 1).FILL1                                       01580000
         DC    AL3(0)                   DCBADR                          01600000
.CHK2    AIF   (&ANUM EQ 1).FILL2       IF 1 GO TO FILL2                01620000
         DC    A(0)                     BUFPARAM                        01640000
         MEXIT                                                          01660000
.CHK     ANOP                                                           01680000
&PAREN   SETC  '&DCB'(1,1)               TO CHECK 1ST CHAR OF DCBADDR   01700000
         AIF   ('&PAREN' LT 'A' OR '&PAREN' GT 'Z').ERLDCB              01720000
&ADCB    SETA  1                                                        01740000
.OK2     AIF   (T'&NUM EQ 'O').FINI                                     01760000
         AGO   .NUM                                                     01780000
.FILL1   DC    AL3(&DCB)                DCBADR                          01800000
         AGO   .CHK2                                                    01820000
.FILL2   DC    A(&NUM)                  BUFPARAM                        01840000
         MEXIT                                                          01860000
.ERREMF  IHBERMAC  35,,&MF         ERROR MSG FOR INVALID MF             01880000
         MEXIT                                                          01900000
.ERRDCB  IHBERMAC  36,,DCBADR                                           01920000
         AGO   .OK1                                                     01940000
.ERLDCB  IHBERMAC  36,,DCBADR                                           01960000
         AGO   .OK2                                                     01980000
.NODCB   IHBERMAC  6                                                    02000000
         AGO   .OK1                                                     02020000
.NONUM   IHBERMAC  3                                                    02040000
         AGO   .ONWARD                                                  02060000
.ERRNUM  IHBERMAC  37,,BUFPARAM                                         02080000
         AGO   .FINI                                                    02100000
         MEND                                                           02120000
