         MACRO                           HEADER STATEMENT               00020000
&NAME    BUFINQ  &DCB,&TBL,&SIZE,&MF=    PROTOTYPE STATEMENT            00040000
         LCLC  &PAREN,&ALPHA             LOCALS DEFINED                 00060000
         LCLA  &ADCB,&ATBL,&ASIZE  DEFINE LOCALS                        00080000
.*0050,003400,005800,008400,009200                                 1813 00090014
         AIF   (T'&MF EQ 'O').SFORM      S-FORM ASSUMED IF MF OMITTED   00100000
         AIF   (N'&MF EQ 2).EFORM            CHECK FOR 2 OPERANDS       00120000
         AIF   ('&MF(1)' EQ 'L').LFORM       POSITIVE CHECK FOR 6       00140000
         AGO   .ERREMF                                                  00160000
.EFORM   AIF   ('&MF(1)' NE 'E').ERREMF      POSITIVE CHECK FOR E       00180000
         AIF   ('&MF(2)'(1,1) EQ '(').REGMF  CHECK NOTATION             00200000
&NAME    LA    1,&MF(2)                  PUT LSTADDR IN REG 1           00220000
.CHECK   AIF   (T'&DCB EQ 'O' AND T'&TBL EQ 'O' AND T'&SIZE EQ 'O').END 00240000
         AIF   (T'&DCB NE 'O').CHANGE1   IF DCBADDR GIVEN               00260000
         AIF   (T'&TBL NE 'O').TABAD                                    00280000
.TABSIZE AIF   ('&SIZE'(1,1) EQ '(').REGSZE                             00300000
         LA    0,&SIZE                 PUT SIZE IN PARAM LIST           00320000
         ST    0,8(1)                   PUT SIZE IN PARAM LIST     1813 00340014
.END     MVI   0(1),X'10'          REINSTATE BUFINQ REQUEST CODE        00360000
         SVC   71                  SVC TO BFR MGT CONTROL SECTION       00380000
         MEXIT   BRANCH OUT OF MACRO DEFINITION                         00400000
.CHANGE1 AIF   ('&DCB'(1,1) EQ '(').REGDCB  WITH NEW DCB ADDR           00420000
         LA    0,&DCB                  PUT DCBADDR IN PARAM LIST        00440000
         ST    0,0(1)                  PUT DCBADDR IN PARAM LIST        00460000
.GOON    AIF   (T'&TBL NE 'O').TABAD                                    00480000
         AIF   (T'&SIZE EQ 'O').END                                     00500000
         AGO   .TABSIZE                                                 00520000
.TABAD   AIF   ('&TBL'(1,1) EQ '(').REGTAB  CHECK NOTATION              00540000
         LA    0,&TBL                  PUT TABADDR IN PARAM LIST        00560000
         ST    0,4(1)                   PUT TABADDR IN PARAM LIST  1813 00580014
.CONTINU AIF   (T'&SIZE EQ 'O').END                                     00600000
         AGO   .TABSIZE                                                 00620000
.REGMF   ANOP                                                           00640000
&PAREN   SETC  '&MF(2)'(2,K'&MF(2)-2)  ISOLATE REGISTER NUMBER          00660000
&NAME    LR    1,&PAREN                  PUT LIST ADDR IN REG 1         00680000
         AGO   .CHECK                                                   00700000
.REGDCB  ANOP                                                           00720000
&PAREN   SETC  '&DCB'(2,K'&DCB-2)        ISOLATE REGISTER NUMBER        00740000
         ST    &PAREN,0(1)               PUT  DCBADR IN PARAM LIST      00760000
         AGO   .GOON                                                    00780000
.REGTAB  ANOP                                                           00800000
&PAREN   SETC  '&TBL'(2,K'&TBL-2)        ISOLATE REG NUMBER             00820000
         ST    &PAREN,4(1)              PUT TBL ADDR IN PARAM LIST 1813 00840014
         AGO   .CONTINU                                                 00860000
.REGSZE  ANOP                                                           00880000
&PAREN   SETC  '&SIZE'(2,K'&SIZE-2)                                     00900000
         ST    &PAREN,8(1)              PUT SIZE IN PARAM LIST     1813 00920014
         AGO   .END                                                     00940000
.SFORM   ANOP                                                           00960000
&NAME    LA    1,A&SYSNDX              LOAD ADR OF PARAM LST            00980000
         AIF   (T'&DCB EQ 'O').NODCB                                    01000000
&PAREN   SETC  '&DCB'(1,1)                                              01020000
         AIF   ('&PAREN' EQ '(').REGSDCB                                01040000
         AIF   ('&PAREN' LT 'A').ERRDCB  CHECK FOR SYMBOLIC FORMAT      01060000
         AIF   ('&PAREN' GT 'Z').ERRDCB  CHECK FOR SYMBOLIC FORMAT      01080000
&ADCB    SETA  1                                                        01100000
.AHEAD   AIF   (T'&TBL EQ 'O').NOTAB     GROSS ERROR IF OMITTED         01120000
&PAREN   SETC  '&TBL'(1,1)                                              01140000
         AIF   ('&PAREN' EQ '(').REGSTAB                                01160000
         AIF   ('&PAREN' LT 'A' OR '&PAREN' GT 'Z').ERRTAB              01180000
&ATBL    SETA  1                                                        01200000
.OK1     AIF   (T'&SIZE EQ 'O').NOSIZE   GROSS ERROR IF OMITTED         01220000
.FORWARD AIF   ('&SIZE'(1,1) EQ '(').REGSSZE                            01240000
&ASIZE   SETA  1                                                        01260000
.ONWARD  CNOP  2,4                       CODING TO BE GENERATED         01280000
         SVC   71                  SVC TO BFR MGT CONTROL SECTION       01300000
         B     A&SYSNDX+12         BRANCH AROUND PARAMETER LIST         01320000
         AIF   (&ADCB EQ 1).SYM1     IF 1 GO TO SYM1                    01340000
A&SYSNDX DC    A(0)                DCB-ADR AND CODE                     01360000
.CHK1    AIF   (&ATBL EQ 1).SYM2                                        01380000
         DC    AL4(0)                  TABLE-ADR                        01400000
.CHK2    AIF   (&ASIZE EQ 1).SYM3                                       01420000
         DC    AL4(0)                  SIZE                             01440000
         MEXIT                           BRANCH OUT OF MACRO DEFN       01460000
.SYM1    ANOP                                                           01480000
A&SYSNDX DC    AL1(16)             CODE                                 01500000
         DC    AL3(&DCB)          DCB-ADR                               01520000
         AGO   .CHK1                                                    01540000
.SYM2    DC    A(&TBL)             TABLE ADR                            01560000
         AGO   .CHK2                                                    01580000
.SYM3    DC    A(&SIZE)            SIZE OF TABLE                        01600000
         MEXIT                                                          01620000
.*REGISTER NOTATION                                                     01640000
.REGSDCB ANOP                                                           01660000
&PAREN   SETC  '&DCB'(2,K'&DCB-2)        ISOLATE REGISTER NUMBER        01680000
         ST    &PAREN,A&SYSNDX           PUT DCB ADDR IN PARAM LIST     01700000
         MVI   A&SYSNDX,X'10'      REINSTATE REQUEST CODE               01720000
         AGO   .AHEAD                                                   01740000
.REGSTAB ANOP                                                           01760000
&PAREN   SETC  '&TBL'(2,K'&TBL-2)        ISOLATE REGISTER NUMBER        01780000
         ST    &PAREN,A&SYSNDX+4       PUT TBL-ADR IN PARAM LIST        01800000
         AGO   .OK1                                                     01820000
.REGSSZE ANOP                                                           01840000
&PAREN   SETC  '&SIZE'(2,K'&SIZE-2)                                     01860000
         ST    &PAREN,A&SYSNDX+8       PUT SIZE IN PARAM LIST           01880000
         AGO   .ONWARD                                                  01900000
.LFORM   AIF  (T'&DCB EQ 'O' AND T'&TBL EQ 'O' AND T'&SIZE EQ 'O').FINI 01920000
         AIF   (T'&DCB NE 'O').CHK                                      01940000
         AIF   (T'&TBL NE 'O').CHKTAB                                   01960000
.SIZE    ANOP                                                           01980000
&PAREN   SETC  '&SIZE'(1,1)                                             02000000
         AIF   ('&PAREN' LT '0' OR '&PAREN' GT '9').ERRSZE              02020000
&ASIZE   SETA  1                                                        02040000
.FINI    DS    0F                        GENERATED CODING               02060000
&NAME    DC    AL1(16)             REQUEST CODE                         02080000
         AIF   (&ADCB EQ 1).FILL1                                       02100000
         DC    AL3(0)              DCB-ADR                              02120000
.CHK3    AIF   (&ATBL EQ 1).FILL2                                       02140000
         DC    A(0)                     TBLADR                          02160000
.CHK4    AIF   (&ASIZE EQ 1).FILL3                                      02180000
         DC    A(0)                     TABLE SIZE                      02200000
         MEXIT    BRANCH OUT OF MACRO DEFINITION                        02220000
.CHK     ANOP                                                           02240000
&PAREN   SETC  '&DCB'(1,1)                                              02260000
         AIF   ('&PAREN' LT 'A' OR '&PAREN' GT 'Z').ERLDCB              02280000
&ADCB    SETA  1                                                        02300000
.OK2     AIF   (T'&TBL NE 'O').CHKTAB                                   02320000
         AIF   (T'&SIZE EQ 'O').FINI                                    02340000
         AGO   .SIZE                                                    02360000
.CHKTAB  ANOP                                                           02380000
&PAREN   SETC  '&TBL'(1,1)                                              02400000
         AIF   ('&PAREN' LT 'A' OR '&PAREN' GT 'Z').ERLTAB              02420000
&ATBL    SETA  1                                                        02440000
.OK3     AIF   (T'&SIZE EQ 'O').FINI                                    02460000
         AGO   .SIZE                                                    02480000
.FILL1   ANOP                                                           02500000
         DC    AL3(&DCB)           DCB-ADR                              02520000
         AGO   .CHK3                                                    02540000
.FILL2   DC    A(&TBL)                  TBLADR                          02560000
         AGO   .CHK4                                                    02580000
.FILL3   DC    A(&SIZE)                 TABLE SIZE                      02600000
         MEXIT                                                          02620000
.ERREMF  IHBERMAC  35,,&MF         ERROR MSG FOR INVALID MF             02640000
         MEXIT                                                          02660000
.ERRDCB  IHBERMAC  36,,DCBADDR                                          02680000
         AGO   .AHEAD                                                   02700000
.ERLDCB  IHBERMAC  36,,DCBADR                                           02720000
         AGO   .OK2                                                     02740000
.NODCB   IHBERMAC  6                                                    02760000
         AGO   .AHEAD                                                   02780000
.ERRTAB  IHBERMAC  37,,TABADDR                                          02800000
         AGO   .OK1                                                     02820000
.ERLTAB  IHBERMAC  37,,TBLADR                                           02840000
         AGO   .OK3                                                     02860000
.NOTAB   IHBERMAC  3                                                    02880000
         AGO   .OK1                                                     02900000
.NOSIZE  IHBERMAC  4                                                    02920000
         AGO   .ONWARD                                                  02940000
.ERRSZE  IHBERMAC  38,,TBLSIZE                                          02960000
         AGO   .FINI                                                    02980000
         MEND                                                           03000000
