         MACRO                                                          00020000
&CNAME   CLOSE &PAR1,&MF=I,&TYPE=                                A45585 00040021
         LCLA  &ACTR,&ASUM,&CTR,&CTR1,&LGTH,&NUMBER                     00060000
         LCLB  &MFESW,&MFISW,&MFI2SW,&NULLSW,&B(4)                      00080001
         LCLC  &PARA                                                    00100000
&NUMBER  SETA  N'&PAR1                                                  00120000
&CTR     SETA  1                                                        00140000
&CTR1    SETA  2                                                        00160000
         AIF   (N'&SYSLIST LE 1).TYPE   IF ONLY 1 (PARMLIST)     A45585 00185021
         IHBERMAC 238                   EXCESSIVE POS. PARMS     A45585 00190021
.TYPE    AIF   (T'&TYPE NE 'O' AND '&TYPE' NE 'T').ERROR8        A45585 00195021
         AIF   ('&MF' EQ 'L').RTEL                                      00200000
         AIF   ('&MF' EQ 'I').TESTI                                     00220000
         AIF   (N'&MF LE 1).ERROR3                                      00240000
         AIF   ('&MF(1)' NE 'E').ERROR3                                 00260000
&CNAME   IHBINNRA &MF(2)                                                00280000
         AIF   ('&PAR1' EQ '').SVCSVC                                   00300001
.LOOPA   AIF   ('&PAR1(&NUMBER)' NE '').LOOPB                           00320001
&NUMBER  SETA  &NUMBER-1                                                00340000
         AIF   (&NUMBER EQ 0).SVCSVC                                    00360000
         AGO   .LOOPA                                                   00380000
.LOOPB   AIF   ('&PAR1(&CTR)' NE '').TESTCTR                            00400001
&NULLSW  SETB  1                                                        00420001
.TESTCTR AIF   (&CTR EQ &NUMBER).QUITNOW                                00440000
         AIF   ('&PAR1(&CTR1)' EQ '').NULLTWO                           00460001
&MFESW   SETB  1                                                        00480000
         AGO   .CLRSW                                                   00500000
.ERTRTRN AIF   (&CTR1 EQ &NUMBER).THRUNOW                               00580000
         AIF   (&NULLSW).NOFIRST                                        00600000
         AIF   ('&PAR1(&CTR)'(1,1) EQ '(').REGISTR                      00620000
         LA    14,&PAR1(&CTR)                    PICK UP DCB ADDRESS    00640000
         ST    14,&ACTR.(1,0)                    STORE INTO LIST        00660000
.NOFIRST MVI   &ACTR.(1),&ASUM                   MOVE IN OPTION BYTE    00680001
         AGO   .INCRMT                                                  00700000
.REGISTR ANOP                                                           00720000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          00740000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   00760000
         ST    &PARA,&ACTR.(1,0)                 STORE DCB ADDR IN LIST 00780000
         MVI   &ACTR.(1),&ASUM                   MOVE IN OPTION BYTE    00800000
         AGO   .INCRMT                                                  00820000
.NULLTWO AIF   (&NULLSW).INCRMT                                         00880001
         AIF   ('&PAR1(&CTR)'(1,1) EQ '(').REGSTER                      00900001
         IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       00920000
         LA    0,&PAR1(&CTR)                     PICK UP DCB ADDRESS    00940000
         ST    0,&ACTR.(1,0)                     STORE INTO LIST        00960000
         STC   14,&ACTR.(1,0)                    RESTORE OPTION BYTE    00980000
         AGO   .INCRMT                                                  01000000
.REGSTER IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       01020000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          01040000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   01060000
         ST    &PARA,&ACTR.(1,0)                 STORE DCB ADDR IN LIST 01080000
         STC   14,&ACTR.(1,0)                    RESTORE OPTION BYTE    01100000
         AGO   .INCRMT                                                  01120000
.QUITNOW IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       01140000
         AIF   ('&PAR1(&CTR)'(1,1) EQ '(').REGST                        01160000
         LA    0,&PAR1(&CTR)                     PICK UP DCB ADDRESS    01180000
         ST    0,&ACTR.(1,0)                     STORE INTO LIST        01200000
         STC   14,&ACTR.(1,0)                    RESTORE OPTION BYTE    01220000
         AGO   .SVCSVC                                                  01240000
.REGST   ANOP                                                           01260000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          01280000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   01300000
         ST    &PARA,&ACTR.(1,0)                 STORE DCB ADDR IN LIST 01320000
         STC   14,&ACTR.(1,0)                    RESTORE OPTION BYTE    01340000
         AGO   .SVCSVC                                                  01360000
.THRUNOW NI    &ACTR.(1),X'80'                   CLEAR OPTION BITS      01380001
         AIF   (&ASUM EQ 0).CONTA                                       01390001
         OI    &ACTR.(1),&ASUM                   SET OPTION BITS        01400001
.CONTA   AIF   (&NULLSW).SVCSVC                                         01420001
         AGO   .QUITNOW                                                 01440000
.INCRMT  ANOP                                                           01460000
&CTR     SETA  &CTR+2                                                   01480000
&CTR1    SETA  &CTR1+2                                                  01500000
&ACTR    SETA  &ACTR+4                                                  01520000
&NULLSW  SETB  0                                                        01540000
         AGO   .LOOPB                                                   01560000
.*--------------------------------------------------------------------- 01570001
.SVCSVC  AIF   ('&TYPE' NE 'T').ISSST                           SA51997 01580001
         SVC   23                                ISSUE TCLOSE SVC       01600000
         MEXIT                                                          01620000
.ISSST   SVC   20                                ISSUE CLOSE SVC        01640000
         MEXIT                                                          01660001
.*--------------------------------------------------------------------- 01670001
.RTEL    ANOP                                                           01680000
&CNAME   DC    0F'0'                             ALIGN LIST TO FULLWORD 01700001
         AIF   ('&PAR1' EQ '').ERROR5                                   01710001
.CLRSW   ANOP                                                           01720000
&ASUM    SETA  0                                                        01740000
         AIF   (&CTR1 GT &NUMBER).J                                     01780000
         AIF   ('&PAR1(&CTR1)' EQ '').DC1                               01800000
&B(1)    SETB  ('&PAR1(&CTR1)' EQ 'REREAD')                             01820000
&B(2)    SETB  ('&PAR1(&CTR1)' EQ 'LEAVE')                              01840000
&B(3)    SETB  ('&PAR1(&CTR1)' EQ 'DISP')                               01860001
&B(4)    SETB  ('&PAR1(&CTR1)' EQ 'REWIND')                             01870019
         AIF   (&B(1)+&B(2)+&B(3)+&B(4) NE 1).ERROR2                    01880019
         AIF   (&B(3) AND '&TYPE' EQ 'T' OR &B(4) AND '&TYPE' EQ 'T').EX01886020
               RROR2                                             A33667 01892020
&ASUM    SETA  16*&B(1)+48*&B(2)+64*&B(4)                               01900019
.DC1     AIF   (&MFESW).ERTRTRN                                         01940000
         AIF   (&CTR1 LT &NUMBER).K                                     01960001
.J       ANOP                                                           02040000
&ASUM    SETA  &ASUM+128                                                02080000
.K       AIF   (&MFI2SW).I2ROUT                                         02100001
         AIF   (&MFISW).IROUTRN                                         02120000
         DC    AL1(&ASUM)                        OPTION BYTE            02160000
         AIF   ('&PAR1(&CTR)' NE '').NOBLANK                            02180001
         DC    AL3(0)                            DCB ADDRESS            02220001
         AGO   .NOTLST                                                  02240000
.NOBLANK AIF   ('&PAR1(&CTR)'(1,1) EQ '(').ERROR6                       02280001
         DC    AL3(&PAR1(&CTR))                  DCB ADDRESS            02300001
.NOTLST  AIF   (&CTR1 GE &NUMBER).FINI                                  02320001
&CTR     SETA  &CTR+2                                                   02340000
&CTR1    SETA  &CTR1+2                                                  02360000
         AGO   .CLRSW                                                   02380001
.*--------------------------------------------------------------------- 02400001
.TESTI   CNOP  0,4                               ALIGN LIST TO FULLWORD 02420001
&LGTH    SETA  ((&NUMBER+1)/2)*4+4                                      02440001
&CNAME   BAL   1,*+&LGTH                         LOAD REG1 W/LIST ADDR  02460001
&MFISW   SETB  1                                                        02480000
.RTEYE   AIF   ('&PAR1(&CTR)' EQ '').ERROR5                             02500000
         AIF   ('&PAR1(&CTR)'(1,1) NE '(').CLRSW                        02520000
         DC    A(0)                              OPTION AND DCB ADDRESS 02540000
         AGO   .UPCTRS                                                  02560000
.IROUTRN DC    AL1(&ASUM)                        OPTION BYTE            02580000
         DC    AL3(&PAR1(&CTR))                  DCB ADDRESS            02600000
.UPCTRS  AIF   (&CTR1 GE &NUMBER).QUITS                                 02620000
&CTR     SETA  &CTR+2                                                   02640000
&CTR1    SETA  &CTR1+2                                                  02660000
         AGO   .RTEYE                                                   02680000
.QUITS   ANOP                                                           02700000
&CTR     SETA  1                                                        02720000
&CTR1    SETA  2                                                        02740000
.ILOOP2  AIF   ('&PAR1(&CTR)'(1,1) NE '(').UPCTR2                       02760000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          02780000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   02800000
         ST    &PARA,&ACTR.(1,0)                 STORE DCB ADDRESS      02820000
&MFI2SW  SETB  1                                                        02840000
         AGO   .CLRSW                                                   02860000
.I2ROUT  AIF   (&ASUM EQ 0).UPCTR2                                      02880000
         MVI   &ACTR.(1),&ASUM                   MOVE IN OPTION BYTE    02900000
.UPCTR2  AIF   (&CTR1 GE &NUMBER).SVCSVC                                02920001
&CTR     SETA  &CTR+2                                                   02940000
&CTR1    SETA  &CTR1+2                                                  02960000
&ACTR    SETA  &ACTR+4                                                  02980000
         AGO   .ILOOP2                                                  03000000
.ERROR2  IHBERMAC 49,,&PAR1(&CTR1)      INVALID OPTION OPEARND          03020001
         MEXIT                                                          03040000
.ERROR3  IHBERMAC 35,,&MF               INVALID MF OPERAND SPECIFIED    03060001
         MEXIT                                                          03080000
.ERROR5  IHBERMAC 6                     DCB MISSING                     03100001
         MEXIT                                                          03120000
.ERROR6  IHBERMAC 69                    INVALID REG NOTATION W/MF=L     03140001
         MEXIT                                                          03146020
.ERROR8  IHBERMAC 63,,&TYPE             INVALID TYPE OPERAND     M0626  03156020
.FINI    MEND                                                           03160000
