         MACRO                                                          00600000
&USERNAM CRJEUSER &OPERAND                                              01200000
         GBLB  &GNOGO,&ORG                                              01800000
         GBLC  &GUSER                                                   02400000
         LCLA  &N,&LNOGO,&INDEX,&MAX,&M,&MAXG,&MAXP                     03000000
         LCLB  &SKIP                                                    03600000
         LCLC  &USER,&CHAR1,&CHAR2,&PASS                                04200000
.*       PARAMETER VALIDIZATION                                         04800000
         AIF   (N'&SYSLIST NE 0).COUNT                                  05400000
         MNOTE 1,'WARNING - NO USERIDS ARE ENTERED INTO THE SYSTEM DUE C06000000
                  TO THIS MACRO EXPANSION'                              06600000
         MEXIT                                                          07200000
.*       CHECK FOR PAIRING OF USERIDS AND PASSWORDS                     07800000
.COUNT   ANOP                                                           08400000
&N       SETA  N'&SYSLIST                                               09000000
         AIF   ((&N/2)*2 EQ &N).BEGIN                                   09600000
         MNOTE 8,'ODD NUMBER OF OPERANDS, USERID''S AND PASSWORD''S    C10200000
                     CANNOT BE PAIRED'                                  10800000
&GNOGO   SETB  1                                                        11400000
         MEXIT                                                          12000000
.*       CHECK FOR EXISTENCE AND CORRECT SPECIFICATION OF USERID        12600000
.BEGIN   ANOP                                                           13200000
&INDEX   SETA  &INDEX+1                                                 13800000
         AIF   (&INDEX GT &N).CHKEND                                    14400000
         AIF   ('&SYSLIST(&INDEX)' NE '').CHKUSR1                       15000000
         AIF   ('&SYSLIST(&INDEX+1)' EQ '').SETUP                       15600000
         MNOTE 4,'NO USERID FOR PASSWORD &SYSLIST(&INDEX+1)'            16200000
&USER    SETC  '@'                                                      16800000
&LNOGO   SETA  &LNOGO+1                                                 17400000
         AGO   .BEGIN1                                                  18000000
.SETUP   ANOP                                                           18600000
&INDEX   SETA  &INDEX+1                                                 19200000
         AGO   .BEGIN                                                   19800000
.CHKUSR1 ANOP                                                           20400000
&USER    SETC  '&SYSLIST(&INDEX)'                                       21000000
         AIF   (K'&SYSLIST(&INDEX) LE 7).CHKUSR2                        21600000
         MNOTE 4,'USERID &USER EXCEEDS SEVEN CHARACTERS IN LENGTH'      22200000
&LNOGO   SETA  &LNOGO+1                                                 22800000
&MAX     SETA  7                                                        23400000
         AGO   .CHKUSR3                                                 24000000
.CHKUSR2 ANOP                                                           24600000
&MAX     SETA  K'&SYSLIST(&INDEX)                                       25200000
.CHKUSR3 ANOP                                                           25800000
&CHAR1   SETC  '&SYSLIST(&INDEX)'(1,1)                                  26400000
         AIF   ('&CHAR1' GE 'A' AND '&CHAR1' LE 'Z').CHKUSR4            27000000
         MNOTE 4,'NON-ALPHABETIC FIRST CHARACTER ON USERID &USER'       27600000
&LNOGO   SETA  &LNOGO+1                                                 28200000
.CHKUSR4 ANOP                                                           28800000
&M       SETA  1                                                        29400000
.CHKUSR5 ANOP                                                           30000000
&M       SETA  &M+1                                                     30600000
         AIF   (&M GT &MAX).BEGIN1                                      31200000
&CHAR2   SETC  '&SYSLIST(&INDEX)'(&M,1)                                 31800000
         AIF   ('&CHAR2' GE 'A' AND '&CHAR2' LE 'Z').CHKUSR5            32400000
         AIF   ('&CHAR2' GE '0' AND '&CHAR2' LE '9').CHKUSR5            33000000
         AIF   ('&CHAR2' EQ '$').CHKUSR5                                33600000
         AIF   ('&CHAR2' EQ '#').CHKUSR5                                34200000
         AIF   ('&CHAR2' EQ '@').CHKUSR5                                34800000
         MNOTE 4,'USERID &USER CONTAINS INVALID CHARACTER(S)'           35400000
&LNOGO   SETA  &LNOGO+1                                                 36000000
.*       CHECK FOR EXISTENCE AND CORRECT SPECIFICATION OF PASSWORD      36600000
.BEGIN1  ANOP                                                           37200000
&INDEX   SETA  &INDEX+1                                                 37800000
         AIF   (&INDEX GT &N).NOPASS                                    38400000
         AIF   ('&SYSLIST(&INDEX)' NE '').CHKPAS1                       39000000
.NOPASS  MNOTE 4,'NO PASSWORD FOR USERID &SYSLIST(&INDEX-1)'            39600000
&LNOGO   SETA  &LNOGO+1                                                 40200000
         AGO   .CHKCOM                                                  40800000
.CHKPAS1 ANOP                                                           41400000
&PASS    SETC  '&SYSLIST(&INDEX)'                                       42000000
         AIF   (K'&SYSLIST(&INDEX) LE 8).CHKPAS2                        42600000
         MNOTE 4,'PASSWORD &PASS EXCEEDS EIGHT CHARACTERS IN LENGTH'    43200000
&LNOGO   SETA  &LNOGO+1                                                 43800000
&MAXP    SETA  8                                                        44400000
         AGO   .CHKPAS3                                                 45000000
.CHKPAS2 ANOP                                                           45600000
&MAXP    SETA  K'&SYSLIST(&INDEX)                                       46200000
.CHKPAS3 ANOP                                                           46800000
&CHAR1   SETC  '&SYSLIST(&INDEX)'(1,1)                                  47400000
         AIF   ('&CHAR1' GE 'A' AND '&CHAR1' LE 'Z').CHKPAS4            48000000
         MNOTE 4,'NON-ALPHABETIC FIRST CHARACTER ON PASSWORD &PASS'     48600000
&LNOGO   SETA  &LNOGO+1                                                 49200000
.CHKPAS4 ANOP                                                           49800000
&M       SETA  1                                                        50400000
.CHKPAS5 ANOP                                                           51000000
&M       SETA  &M+1                                                     51600000
         AIF   (&M GT &MAXP).CHKCOM                                     52200000
&CHAR2   SETC  '&SYSLIST(&INDEX)'(&M,1)                                 52800000
         AIF   ('&CHAR2' GE 'A' AND '&CHAR2' LE 'Z').CHKPAS5            53400000
         AIF   ('&CHAR2' GE '0' AND '&CHAR2' LE '9').CHKPAS5            54000000
         AIF   ('&CHAR2' EQ '$').CHKPAS5                                54600000
         AIF   ('&CHAR2' EQ '#').CHKPAS5                                55200000
         AIF   ('&CHAR2' EQ '@').CHKPAS5                                55800000
         MNOTE 4,'PASSWORD &PASS CONTAINS INVALID CHARACTER(S)'         56400000
&LNOGO   SETA  &LNOGO+1                                                 57000000
         AGO   .BEGIN                                                   57600000
.*       CHECK FOR UNIQUENESS AND ALPHABETICAL ORDER OF USERIDS         58200000
.CHKCOM  AIF   ('&USER' EQ '@').BEGIN                                   58800000
         AIF   ('&GUSER' EQ '').CHKPNT1                                 59400000
         AIF   ('&GUSER' NE '&USER').CHKCOM2                            60000000
         MNOTE 4,'USERID &USER IS A DUPLICATE OF A PREVIOUS USERID'     60600000
&LNOGO   SETA  &LNOGO+1                                                 61200000
         AGO   .BEGIN                                                   61800000
.CHKCOM2 ANOP                                                           62400000
&M       SETA  0                                                        63000000
.CHKCOM3 ANOP                                                           63600000
&M       SETA  &M+1                                                     64200000
         AIF   (&M LE &MAX).CHKCOM4                                     64800000
.ERROR   MNOTE 4,'USERID &USER IS NOT IN ALPHABETICAL ORDER'            65400000
&LNOGO   SETA  &LNOGO+1                                                 66000000
         AGO   .CHKPNT                                                  66600000
.CHKCOM4 AIF   (&M GT &MAXG).CHKPNT                                     67200000
         AIF   ('&GUSER'(&M,1) LT '&USER'(&M,1)).CHKPNT                 67800000
         AIF   ('&GUSER'(&M,1) EQ '&USER'(&M,1)).CHKCOM3                68400000
         AGO   .ERROR                                                   69000000
.CHKPNT1 AIF   ('&USER' EQ '').BEGIN                                    69600000
.*       GENERATION OF USER VERIFICATION RECORD                         70200000
.CHKPNT  ANOP                                                           70800000
&GUSER   SETC  '&USER'                                                  71400000
&MAXG    SETA  &MAX                                                     72000000
         AIF   (&LNOGO NE 0 OR &GNOGO).BEGIN                            72600000
         AIF   (&SKIP).GENER1                                           73200000
         SPACE 1                                                        73800000
IHKUSR   CSECT                                                          74400000
&SKIP    SETB  1                                                        75000000
.GENER1  ANOP                                                           75600000
*                                                                       76200000
*        USER TABLE ENTRY                                               76800000
*                                                                       77400000
         AIF   (NOT &ORG).GENER                                         78000000
         ORG   *-1                                                      78600000
&ORG     SETB  0                                                        79200000
.GENER   ANOP                                                           79800000
         DC    CL8'&USER' .     USERID                                  80400000
         DC    CL8'&PASS' .     PASSWORD                                81000000
         DC    7D'0' .             PADDING                              81600000
         DC    CL8'&USER' .     USERID                                  82200000
         AGO   .BEGIN                                                   82800000
.*       CHECK MACRO TERMINATION CONDITIONS                             83400000
.CHKEND  AIF   (&LNOGO EQ 0 AND NOT &GNOGO).SETEND                      84000000
         AIF   (&LNOGO EQ 0 AND &GNOGO).ERROR2                          84600000
         AIF   (&LNOGO NE 0 AND NOT &GNOGO).ERROR3                      85200000
.ERROR1  MNOTE 8,'&LNOGO TERMINATING ERROR(S) INCURRED, NO GENERATION'  85800000
         MEXIT                                                          86400000
.ERROR2  MNOTE 8,'NO TERMINATING ERRORS INCURRED, NO GENERATION DUE TO C87000000
                  PREVIOUS ERRORS'                                      87600000
         MEXIT                                                          88200000
.ERROR3  MNOTE 8,'&LNOGO TERMINATING ERROR(S) INCURRED, GENERATION     C88800000
                       TERMINATED'                                      89400000
&GNOGO   SETB  1                                                        90000000
         MEXIT                                                          90600000
.SETEND  ANOP                                                           91200000
&ORG     SETB  1                                                        91800000
         DC    X'FF' .             TERMINATOR                           92400000
         MEND                                                           93000000
