         MACRO                                                          00020000
&NAME    DAR   &GACB,&MF=I                                              00040000
         LCLA  &LNGTH,&INC,&CNT         DEFINE WORK AREAS               00060000
         LCLC  &NAMGACB,&NAMLIST                                        00080000
         LCLC  &MNAME                                                   00100000
         LCLA  &TOTLNG                                                  00120000
         LCLC  &REGAD                                                   00140000
&CNT     SETA  0                        COUNT IS NUMBER OF GACBS        00160000
&INC     SETA  0                        NUMBER OF FULL WORDS            00180000
.NXTST1  AIF   ('&MF' EQ 'I').TYPESL    TEST FOR TYPE S AND             00200000
         AIF   ('&MF' EQ 'L').TYPESL    TYPE L.                         00220000
         AIF   (N'&MF NE 2).ER1         THEN A TEST IS MADE TO          00240000
         AIF   ('&MF(1)' NE 'E').ER1    CHECK PROPER MF=E FORMAT        00260000
         AIF   ('&MF(2)'(1,1) EQ '(').USEREG                            00280000
&NAME    LA    1,&MF(2)                 LOAD ADDRESS OF LIST            00300000
         AGO   .OVUSRG                  INTO REGISTER 1                 00320000
.USEREG  ANOP                           IF A REGISTER WAS SPECIFIED     00340000
&REGAD   SETC  '&MF(2)'(2,K'&MF(2)-2)   LOAD REGISTER INSTRUCTION       00360000
&NAME    LR    1,&REGAD                 LOAD PARAMETER LIST ADDRESS     00380000
.OVUSRG  AIF   (K'&GACB EQ 0).NOMOR      NO GACB IN MACRO TEST          00400000
.NEXT    AIF   (N'&GACB EQ &CNT).NOMOR    CHECK FOR END OF GACB LIST    00420000
&CNT     SETA  &CNT+1                   IF NOT, INCREMENT BOTH          00440000
&INC     SETA  &INC+4                   COUNT AND INCREMENT             00460000
         AIF   (K'&GACB(&CNT) EQ 0).NEXT    CHECK FOR BLANK ENTRY       00480000
         AIF   ('&GACB(&CNT)'(1,1) EQ '(').REGIN   CHECK FOR REG        00500000
&NAMGACB SETC  '&GACB(&CNT)'            LOAD GACB NAME INTO CONSTANT    00520000
         LA    15,&NAMGACB              LOAD GACB ADDRESS INTO          00540000
         ST    15,&INC.(1)              PARAMETER LIST                  00560000
         AGO   .NEXT                    GO TO NEXT GACB ADDRESS         00580000
.REGIN   AIF   ('&GACB(&CNT)'(K'&GACB(&CNT),1) NE ')').ER4              00600000
&NAMGACB SETC  '&GACB(&CNT)'(2,K'&GACB(&CNT)-2)   LOAD REG              00620000
         ST    &NAMGACB,&INC.(1)        STORE REG INTO PARAMETER LIST   00640000
         AGO   .NEXT                    GO TO NEXT GACB ADDRESS         00660000
.NOMOR   SVC   74                       LINK TO DAR ROUTINE             00680000
         MEXIT                                                          00700000
.TYPESL  AIF   (K'&GACB EQ 0).ER3       IF S OR L CHECK FOR GACBS       00720000
&LNGTH   SETA  N'&GACB+1                                                00740000
.PARFIL  AIF   (N'&MF NE 1).ER1         CHECK MF FORMAT                 00760000
         AIF   ('&MF' EQ 'I').TYPES     TEST FOR S FORMAT               00780000
         AIF   (K'&NAME EQ 0).WRNMES    CHECK FOR NAME FIELD            00800000
&MNAME   SETC  '&NAME'                  LOAD NAME INTO CONSTANT         00820000
.AFWRN   DS    0F                        ALIGN ON FULLWORD BOUNDARY     00840000
.GENPAR  ANOP                           GENERATE PARAMETER LIST         00860000
&MNAME   DC    AL1(0)                                                   00880000
         DC    AL1(0)                   RESERVED                        00900000
         DC    AL2(&LNGTH)              LENGTH OF PARAMETER LIST        00920000
         AIF   (K'&GACB EQ 0).JSTAL1    TEST FOR NO GACB ENTRY          00940000
.LOOP    ANOP                                                           00960000
&CNT     SETA  &CNT+1                   KEEP TRACK OF NUMBER OF GACBS   00980000
         AIF   (K'&GACB(&CNT) EQ 0).SETZER   TEST FOR BLANK ENTRY       01000000
         AIF   ('&GACB(&CNT)'(1,1) EQ '(').SETZER   REGISTER TEST       01020000
&NAMGACB SETC  '&GACB(&CNT)'            LOAD GACB NAME INTO CONSTANT    01040000
.PUTIN   DC    A(&NAMGACB)               GACB ADDRESS                   01060000
         AIF   (N'&GACB NE &CNT).LOOP      TEST FOR END OF GACBS        01080000
         MEXIT                                                          01100000
.SETZER  ANOP                                                           01120000
&NAMGACB SETC  '0'                      SET VALUE TO ZERO               01140000
         AGO   .PUTIN                                                   01160000
.JSTAL1  ANOP                           JUST ONE DC STATEMENT           01180000
         DC    A(0)                     GACB ADDRESS                    01200000
         MEXIT                                                          01220000
.TYPES   ANOP                           S TYPE MACRO                    01240000
&MNAME   SETC  'IHB&SYSNDX'             GET SYSTEM NAME                 01260000
&NAME    LA    1,&MNAME                 LOAD PARAMETER LIST ADDRESS     01280000
&TOTLNG  SETA  (&LNGTH+1)*4             GET LENGTH OF LIST AND BRANCH   01300000
         AIF   (K'&GACB EQ 0).NOSTR     TEST FOR NO STORE INSTRUCTION   01320000
.LST     AIF   (N'&GACB EQ &CNT).NOSTMR  TEST FOR END OF GACB LIST      01340000
&CNT     SETA  &CNT+1                   INCREMENT SUBLIST COUNT         01360000
&INC     SETA  &INC+4                                                   01380000
         AIF   (K'&GACB(&CNT) EQ 0).LST     CHECK FOR BLANK GACB ENTRY  01400000
         AIF   ('&GACB(&CNT)'(1,1) NE '(').LST   CHECK FOR NO REG       01420000
         AIF   ('&GACB(&CNT)'(K'&GACB(&CNT),1) NE ')').ER5  REG CHECK   01440000
&NAMGACB SETC  '&GACB(&CNT)'(2,K'&GACB(&CNT)-2)   GET REG NAME          01460000
         ST    &NAMGACB,&MNAME+&INC     STORE REG INTO PARAMETER LIST   01480000
         AGO   .LST                                                     01500000
.NOSTMR  ANOP                                                           01520000
&CNT     SETA  0                        RESET COUNT                     01540000
&INC     SETA  0                        AND INCREMENT.                  01560000
.NOSTR   SVC   74                       LINK TO DAR ROUTINE             01580000
         CNOP  0,4                      ALIGN ON FULLWORD BOUNDARY      01600000
         B     *+&TOTLNG                BRANCH OVER PARAMETER LIST      01620000
         AGO   .GENPAR                  GO TO GENERATE PARAMETER LIST   01640000
.ER1     IHBERMAC 35,,&MF               ERROR IN MF FORMAT              01660000
         MEXIT                                                          01680000
.ER3     IHBERMAC 178,GACB,0            GACB NOT SPECIFIED              01700000
&LNGTH   SETA  2                                                        01720000
         AGO   .PARFIL                                                  01740000
.ER4     IHBERMAC 147,&GACB(&CNT)        INVALID REGISTER NOTATION      01760000
         AGO   .NEXT                                                    01780000
.ER5     IHBERMAC 147,&GACB(&CNT)        INVALID REGISTER NOTATION      01800000
         AGO   .LST                                                     01820000
.WRNMES  IHBERMAC 180,NAME,ZERO                                         01840000
         AGO   .AFWRN                                                   01860000
         MEND                                                           01880000
