         MACRO                                                          00600000
&NAME    GDULIST  &PARAMNO=,&NORGUID=,&DISPMSG=,&MSG=,&ENTRY=1,&IDENT=  01200000
         GBLA  &IECPARN,&IECNDGP(100),&IECGID                           01800000
.*             IECPARN  PARAMETER LIST NUMBER OF LAST MACRO             02400000
.*             IECGID  NUMBER OF GDU IDENTIFIERS                        03000000
         GBLB  &IECGDL,&IECTXT,&IECSW(9),&IECSEQ(10),&IECSQ(7),&IECGDSW 03600000
.*             IECGDL ON INDICATES NOT FIRST GDULIST MACRO IN THIS TRNS 04200000
.*             IECTXT  ON WHEN IMPLICIT TEXT ALREADY GENERATED          04800000
.*             IECSW(8) SET WHEN MSG TXT APPEARS.INDICATES TO FOLLOWING 05400000
.*                      TRLIST OR STEND MACRO THAT AN END OF LIST BYTE  06000000
.*                      HAS BEEN GENERATED BY THIS MACRO                06600000
         LCLA &A,&B,&C                                                  07200000
         LCLB  &NOCODE,&NORSW(16),&D,&E                                 07800000
.*             &E INDICATES MSG OPERAND IS INVALID                      08400000
.*             &D INDICATES ENTRY=M IS CODED                            09000000
.*             &NORSW(16) USED TO DEFINE 2 BYTES OF NORMAL GUIDANCE     09600000
         LCLC  &CHAR                                                    10200000
         ACTR  1000                                                     10800000
         AIF   (&IECSEQ(1) AND &IECSEQ(2) AND &IECSQ(1) AND &IECSQ(2)  X11400000
               AND &IECSEQ(4) AND NOT &IECSEQ(6)).SEQOK                 12000000
&NOCODE  SETB  1                                                        12600000
         MNOTE 12,'MACRO SEQUENCE ERROR'                                13200000
.SEQOK   ANOP                                                           13800000
         AIF   (&IECGDSW).SEQOK1                                        14400000
&NOCODE  SETB  1                                                        15000000
         MNOTE 12,'GDULIST MACRO CAN NOT BE CODED UNLESS GDU=YES IN    X15600000
               CONFIGUR MACRO'                                          16200000
.SEQOK1  ANOP                                                           16800000
         AIF   (T'&PARAMNO NE 'O').PAR1                                 17400000
&NOCODE  SETB  1                                                        18000000
         MNOTE 12,'PARAMNO OPERAND MUST BE CODED'                       18600000
         AGO   .NOR1                                                    19200000
.PAR1    ANOP                                                           19800000
         AIF   (T'&PARAMNO EQ 'N').PAR2                                 20400000
&NOCODE  SETB  1                                                        21000000
         MNOTE 12,'PARAMNO OPERAND HAS INVALID TYPE ATTRIBUTE'          21600000
         AGO   .NOR1                                                    22200000
.PAR2    ANOP                                                           22800000
         AIF   (&PARAMNO GE 1 AND &PARAMNO LE 127).PAR3                 23400000
&NOCODE  SETB  1                                                        24000000
         MNOTE 12,'PARAMNO OPERAND NOT IN VALID RANGE OF 1 TO 127'      24600000
         AGO   .NOR1                                                    25200000
.PAR3    ANOP                                                           25800000
         AIF   (&PARAMNO LE &IECPARN).NOR1                              26400000
&NOCODE  SETB  1                                                        27000000
         MNOTE 12,'PARAMNO OPERAND CAN NOT BE GREATER THAN HIGHEST     X27600000
               PLN OPERAND IN PARAMNUM MACRO'                           28200000
.NOR1    ANOP                                                           28800000
&C       SETA  N'&NORGUID                                               29400000
         AIF   (T'&NORGUID EQ 'O' AND &C EQ 0).DIS1                     30000000
         AIF   (&C LE 16).NOR2                                          30600000
&NOCODE  SETB  1                                                        31200000
         MNOTE 12,'NUMBER OF SUBOPERANDS IN NORGUID OPERAND INVALID'    31800000
.NOR2    ANOP                                                           32400000
&B       SETA  1                                                        33000000
.NOR3    ANOP                                                           33600000
         AIF   (T'&NORGUID(&B) EQ 'N').NOR4                             34200000
&NOCODE  SETB  1                                                        34800000
         MNOTE 12,'NORGUID SUBOPERAND INVALID'                          35400000
         AGO   .DIS1                                                    36000000
.NOR4    ANOP                                                           36600000
         AIF   (&NORGUID(&B) GE 1 AND &NORGUID(&B) LE 16).NOR5          37200000
&NOCODE  SETB  1                                                        37800000
         MNOTE 12,'NORGUID SUBOPERAND NOT IN VALID RANGE OF 1 TO 16'    38400000
         AGO   .NOR21                                                   39000000
.NOR5    ANOP                                                           39600000
&A       SETA  &NORGUID(&B)                                             40200000
&NORSW(&A) SETB 1                                                       40800000
.NOR21   ANOP                                                           41400000
         AIF   (&B EQ &C).DIS1   IF LAST SUBOPERAND,BRANCH              42000000
&B       SETA  &B+1                                                     42600000
         AGO   .NOR3                                                    43200000
.DIS1    ANOP                                                           43800000
         AIF   (T'&DISPMSG EQ 'O').IDEN1                                44400000
         AIF   (T'&DISPMSG EQ 'M').DIS2                                 45000000
&NOCODE  SETB  1                                                        45600000
         MNOTE 12,'D1SPMSG OPERAND HAS INVALID TYPE ATTRIBUTE'          46200000
.DIS2    ANOP                                                           46800000
         AIF   (T'&DISPMSG NE 'O' AND T'&IDENT NE 'O').DIS3             47400000
         AGO   .IDEN1                                                   48000000
.DIS3    ANOP                                                           48600000
&NOCODE  SETB  1                                                        49200000
         MNOTE 12,'D1SPMSG AND IDENT OPERANDS CAN NOT BOTH BE CODED'    49800000
.IDEN1   ANOP                                                           50400000
         AIF   (T'&IDENT EQ 'O').ENT1                                   51000000
         AIF   (T'&IDENT EQ 'N').IDEN2                                  51600000
&NOCODE  SETB  1                                                        52200000
         MNOTE 12,'IDENT OPERAND HAS INVALID TYPE ATTRIBUTE'            52800000
         AGO   .ENT1                                                    53400000
.IDEN2   ANOP                                                           54000000
         AIF   (&IDENT GE 0 AND &IDENT LE 99).IDEN3                     54600000
&NOCODE  SETB  1                                                        55200000
         MNOTE 12,'IDENT OPERAND NOT IN VALID RANGE OF 0 TO  99'        55800000
         AGO   .ENT1                                                    56400000
.IDEN3   ANOP                                                           57000000
&B       SETA  &IDENT+1                                                 57600000
         AIF   (&IDENT LE &IECGID).ENT1                                 58200000
&NOCODE  SETB  1                                                        58800000
         MNOTE 12,'IDENT OPERAND SPECIFIED IS GREATER THAN NUMBER OF   X59400000
               IDENTIFIERS SPECIFIED BY USER'                           60000000
.ENT1    ANOP                                                           60600000
         AIF   ('&ENTRY' EQ '1' OR '&ENTRY' EQ 'M').ENT2                61200000
         MNOTE 3,'ENTRY OPERAND INVALID,DEFAULT ASSUMED'                61800000
.ENT2    ANOP                                                           62400000
&D       SETB  ('&ENTRY' EQ 'M')                                        63000000
         AIF   ('&ENTRY' EQ 'M' AND &IECGDL OR '&ENTRY' EQ '1').MSG1    63600000
&D       SETB  0                                                        64200000
         MNOTE 3,'ENTRY=M ILLEGAL ON FIRST GDULIST MACRO,DEFAULT ASSUMEX64800000
               D'                                                       65400000
.MSG1    ANOP                                                           66000000
         AIF   (T'&MSG EQ 'O').CKGEN                                    66600000
         AIF   (T'&MSG NE 'O' AND &IECTXT).MSG2                         67200000
&E       SETB  1                                                        67800000
         AGO   .CKGEN                                                   68400000
.MSG2    AIF   ('&MSG'(1,1) EQ '''' AND '&MSG'(K'&MSG,1) EQ '''').MSG3  69000000
         MNOT3 3,'MSG OPERAND IN INCORRECT FORMAT,OPERAND IGNORED'      69600000
&E       SETB  1                                                        70200000
         AGO   .CKGEN                                                   70800000
.MSG3    ANOP                                                           71400000
&B       SETA  K'&MSG-2                                                 72000000
         AIF   (&B GE 0 AND &B LE 127).CKGEN                            72600000
         MNOTE 3,'MESSAGE LENGTH EXCEEDS 127,OPERAND IGNORED'           73200000
&E       SETB  1                                                        73800000
.CKGEN   ANOP                                                           74400000
         AIF   (NOT &IECSW(8)).CKGEN1                                   75000000
&NOCODE  SETB  1                                                        75600000
         MNOTE 12,'GDULIST MACRO NOT VALID FOLLOWING IMPLICIT TEXT IN  X76200000
               THIS TRANSACTION'                                        76800000
.CKGEN1  ANOP                                                           77400000
         AIF   (NOT &NOCODE).GENCODE                                    78000000
         MNOTE 12,'TEXT GENERATION SUPPRESSED'                          78600000
         AGO   .MEND                                                    79200000
.GENCODE ANOP                                                           79800000
         DC    YL1(X'80'*&D+&PARAMNO) PARAM LIST NUMBER + REPEAT REC    80400000
         DC      B'&NORSW(1)&NORSW(2)&NORSW(3)&NORSW(4)&NORSW(5)&NORSW(X81000000
               6)&NORSW(7)&NORSW(8)'  FIRST BYTE OF NORMAL GUIDANCE     81600000
         DC    B'&NORSW(9)&NORSW(10)&NORSW(11)&NORSW(12)&NORSW(13)&NORSX82200000
               W(14)&NORSW(15)&NORSW(16)' SECOND BYTE OF NORMAL GUID    82800000
         AIF   (T'&DISPMSG EQ 'O').GEN1                                 83400000
&CHAR    SETC  '&DISPMSG'                                               84000000
         DC    AL2(&CHAR-IEC15TAB)                                      84600000
         AGO   .MSG5                                                    85200000
.GEN1    AIF   (T'&IDENT EQ 'O').GEN2                                   85800000
         DC    YL2((IECIDENT-IEC15TAB)+14*&IDENT)                       86400000
         AGO   .MSG5                                                    87000000
.GEN2    DC    YL2(0)                                                   87600000
.MSG5    ANOP                                                           88200000
&B       SETA  0                                                        88800000
         AIF   (T'&MSG EQ 'O' OR &E).SET                                89400000
&IECSW(8) SETB 1                                                        90000000
         DC    YL1(0)    END OF LIST BYTE                               90600000
&B       SETA  K'&MSG-2                                                 91200000
         DC    YL1(&B)   LENGTH OF MSG TEXT                             91800000
         DC    C&MSG                                                    92400000
&B       SETA  &B+1                                                     93000000
&IECTXT  SETB  0  RESET TO PREVENT GDULIST EXPANSION FOLLOWING MSG TEXT 93600000
.SET     ANOP                                                           94200000
&IECGDL  SETB  1                                                        94800000
&IECNDGP(1) SETA &IECNDGP(1)+5+&B                                       95400000
.MEND    MEND                                                           96000000
