         MACRO                                                          01000000
         IDFASM                                                         02000000
         COPY  IDFGBL                   GLOBAL BOOK                     03000000
         AIF   (NOT &PIB(48)).ASM0  TRACE OFF?                          04000000
         MNOTE *,'IDF100 IN TRACE MODE ENTERING IDFASM'                 05000000
.ASM0    ANOP                                                           06000000
.* NOT ENDING A SECTOR AND NO ORGS TO PERFORM, BRANCH                   07000000
.ASM1    AIF   (&PIA(6) EQ &PIA(7)).ASM8                                08000000
.* NO BACKWARD OR FORWARD ORG REQUIRED, BRANCH                          09000000
         AIF   (&PIA(6) GE &PIA(7) AND &PIA(7) EQ &PIA(3)+&PIA(4)).ASM5 10000000
         AIF   (&PIA(6) LT &PIA(3)+&PIA(4)).ASM3 BACKWARD ORG NEEDED    11000000
.* FORWARD ORG ROUTINE                                                  12000000
.* SET NUMBER OF BYTES ASSEMBLED IN HIGHEST CSECT                       13000000
&L       SETA  &PIA(3)/486*486-&PIA(3)/&SA(1)*&SA(1)+&PIA(4)            14000000
&S       SETA  &PIA(3)/&SA(1)+1000 HIGHEST CSECT THIS ASSEMBLY          15000000
.* IF ORG WILL BE OUTSIDE THIS CSECT GEN PROPER CSECT                   16000000
         AIF   (&PIB(15)).ASM2                                          17000000
         AIF   (&PIA(3)/&SA(1) EQ &PIA(7)/&SA(1)).ASM2                  18000000
I&SC(1)&S CSECT                                                         19000000
.ASM2    ANOP                                                           20000000
&PIA(7)  SETA  &PIA(3)+&PIA(4) BRING LOC CTR TO HIGHEST BYTE ASMBLD     21000000
         AIF   (&PIB(15)).ASM1                                          22000000
         ORG   I&SC(1)&S+&L ORG TO ASM NEXT BYTE AT HIGHEST LOCATION    23000000
         AGO   .ASM1     GO ASM                                         24000000
.ASM3    ANOP            BACKWARD ORG ROUTINE                           25000000
&S       SETA  &PIA(6)/&SA(1)+1000 CSECT THAT ORG IS TO                 26000000
.*           BYTE POS IN CSECT WHERE ORG WILL GO                        27000000
&L       SETA  &PIA(6)-&PIA(6)/&SA(1)*&SA(1)                            28000000
.* IF ORG WILL BE OUTSIDE THIS CSECT, GEN PROPER CSECT                  29000000
         AIF   (&PIB(15)).ASM4                                          30000000
         AIF   (&PIA(6)/&SA(1) EQ &PIA(7)/&SA(1)).ASM4                  31000000
I&SC(1)&S CSECT                                                         32000000
.ASM4    ANOP                                                           33000000
&PIA(7)  SETA  &PIA(6) BRING LOC CTR BACK TO LOC OF DESIRED ASM         34000000
         AIF   (&PIB(15)).ASM8                                          35000000
         ORG   I&SC(1)&S+&L ORG TO DESIRED LOCATION TO ASM NEXT BYTE    36000000
         AGO   .ASM8     GO ASM                                         37000000
.ASM5    ANOP                                                           38000000
&PIA(3)  SETA  &PIA(3)+486 BUMP SECTOR COUNT BY 1                       39000000
&S       SETA  &PIA(3)/&SA(1)+1000 CALC NEXT CSECT NUMBER               40000000
         AIF   (&PIA(3)+&PIA(4) LE 0 OR &PIB(15)).ASM6  1ST CSECT       41000000
         AIF   (&PIA(3) EQ &PIA(5)).ASM5A                               42000000
         DC    3H'0'         SECTOR FLAGS                               43000000
.*    GEN NEXT SEQUENTIAL CSECT IF NEEDED, BRANCH IF NOT                44000000
.ASM5A   ANOP                                                           45000000
         AIF   ((&PIA(3)-486)/&SA(1) EQ &PIA(3)/&SA(1)).ASM7            46000000
         DC    (2+&SB(1))H'0'  CSECT FLAGS                              47000000
I&SC(1)&S CSECT                                                         48000000
         AGO   .ASM7                                                    49000000
.ASM6    AIF   (&PIB(15)).ASM6A                                         50000000
I&SC(1)&S START 0                                                       51000000
.ASM7    DC    CL8'&QC(1)' SECTOR HEADER - FORMNAME                     52000000
&L       SETA  (&PIA(3)-&PIA(5))/486 FDP RELATIVE SECTOR NUMBER         53000000
         DC    H'&L'                        SECTOR NUMBER               54000000
         DC    X'4070'                      RESERVED SECTOR CHAIN       55000000
.* ORG OUT AND BACK TO GIVE VALID LENGTH IF ABNORMAL TERM OCCURS        56000000
         ORG   *+478+&SB(1)*2    SET VALID SECTOR                       57000000
         ORG   *-478-&SB(1)*2    6ENGTH ATTRIBUTE                       58000000
.ASM6A   ANOP                                                           59000000
&PIA(4)  SETA  12   POINT AFTER HEADER                                  60000000
&PIA(7)  SETA  &PIA(3)+&PIA(4) LOC CTR TO NEXT LOC FOR ASM              61000000
.ASM8    AIF   (N'&SYSLIST EQ 0).ASM13                                  62000000
         AIF   (&PIB(15)).ASM11                                         63000000
         AIF   ('&SYSLIST(1)' NE 'A').ASM9  NOT ARITH CALL              64000000
.* CONVERT ARITHMETIC TO HEX MN AND PLUG INTO HEX 4M7N                  65000000
&L       SETA  &A(1)/16*240+&A(1)+X'4070'                               66000000
         DC    H'&L'                        GENERATED ARITHMETIC        67000000
         AGO   .ASM11    ADVANCE CTRS                                   68000000
.ASM9    AIF   ('&SYSLIST(1)' NE 'C').ASM10 NOT CHAR CALL               69000000
         DC    X'4&C(1)7&C(2)'              GENERATED CHARACTER         70000000
         AGO   .ASM11    ADVANCE CTRS                                   71000000
.ASM10   AIF   (T'&SYSLIST(1,2) EQ 'O').ASM12 NOT CONSTANT CALL         72000000
         DC    X'&SYSLIST(1,2)'             GENERATED CONSTANT          73000000
.ASM11   ANOP                                                           74000000
.* BUMP DESIRED ASM LOC PTR BY 2 PLUS CARRY IF TO NEXT SECTOR           75000000
&PIA(7)  SETA  &PIA(6)+2                                                76000000
&PIA(6)  SETA  (&PIA(6)-&PIA(6)/486*486)/478*18+&PIA(6)+2               77000000
.* IF NOT ASSEMBLING AT END, DON'T BUMP HIGHEST BYTE CTR                78000000
         AIF   (&PIA(7) LE &PIA(3)+&PIA(4)).ASM13                       79000000
&PIA(4)  SETA  &PIA(4)+2                                                80000000
         AGO   .ASM13                                                   81000000
.ASM12   MNOTE 8,'IDF999 FDM SYSTEM ERROR'                              82000000
         MNOTE 0,'       INVALID CALL OF INNER MACRO IJLFASM'           83000000
         MNOTE 0,'       CALL PARAMETER=&SYSLIST(1)'                    84000000
&PIB(15) SETB  1                                                        85000000
.ASM13   AIF   (NOT &PIB(48)).TX                                        86000000
         MNOTE *,'IDF100 IN TRACE MODE LEAVING IDFASM'                  87000000
.TX      ANOP                                                           88000000
         MEND                                                           89000000
