         MACRO                                                          00020000
&NAME    IHBRDWRK &DECB,&TYPE,&DCB,&AREA,&LENGTH,&KEYADR,&RCDREF,&MF=I  00040000
.*  THIS MACRO IS CALLED BY MACROS READ + WRITE WHEN THEIR SECOND       00046018
.*  PARAMETER STARTS WITH A K.  (BISAM)                                 00052018
         GBLB  &IHBWR,&IHBT(2),&IHBS(4)                                 00060000
         LCLB  &B1,&B2,&B3,&B4,&B5,&B6,&B7,&ISW,&SWA                    00080000
         LCLA  &CTR,&CNT                                                00100018
&SWA     SETB  ('&TYPE' EQ 'KN')                                        00120000
&CNT     SETA  88+4*&SWA                                                00160000
         AIF   ('&MF' EQ 'I').IROUT                                     00180000
         AIF   ('&MF(1)' EQ 'E').EROUT                                  00200000
         AIF   ('&MF' NE 'L').E4                                        00220000
         AIF   ('&DECB'(1,1) EQ '(').E6                                 00240000
         AIF   ('&NAME' EQ '').SETROUT  IF NAME NOT SPECIFIED           00250018
&NAME    DS    0F                                                       00260000
.SETROUT ANOP                                                           00280000
&DECB    DC    A(0)                              EVENT CONTROL BLOCK    00300000
&B1      SETB  ('&LENGTH' EQ '''S''')                                   00320000
&B2      SETB  ('&AREA' EQ '''S''')                                     00340000
         DC    BL1'&B1&B2'                       TYPE FIELD             00360000
&B3   SETB     (('&TYPE' EQ 'K' OR '&TYPE' EQ 'KC') AND NOT &IHBWR)     00370017
&B4      SETB  ('&TYPE' EQ 'KC' OR '&TYPE' EQ 'KUC'                    X00380017
               OR '&TYPE' EQ 'KNC')                                     00390017
&B5   SETB     (('&TYPE' EQ 'KU' OR '&TYPE' EQ 'KUC') AND NOT &IHBWR)   00400017
&B6   SETB     (('&TYPE' EQ 'K' OR '&TYPE' EQ 'KC') AND &IHBWR)         00410017
&B7   SETB     (('&TYPE' EQ 'KN' OR '&TYPE' EQ 'KNC') AND &IHBWR)       00420017
         AIF   (&B3+&B5+&B6+&B7 NE 1).E3                                00430017
         DC    BL1'&B3&B4&B5.0&B6&B7.00'         TYPE FIELD             00500000
         AIF   (&ISW).IRETURN                                           00520000
         AIF   ('&LENGTH' EQ '' OR &B1).NOLENG                          00540000
         AIF   ('&LENGTH'(1,1) EQ '(').E5                               00560000
         DC    AL2(&LENGTH)                      LENGTH                 00580000
         AGO   .CHKDCB                                                  00600000
.NOLENG  DC    AL2(0)                            LENGTH                 00740000
.CHKDCB  AIF   ('&DCB' EQ '').NODCB                                     00760000
         AIF   ('&DCB'(1,1) EQ '(').E5                                  00780000
         DC    A(&DCB)                           DCB ADDRESS            00800000
         AGO   .CHKAREA                                                 00820000
.NODCB   DC    A(0)                              DCB ADDRESS            00840000
.CHKAREA AIF   ('&AREA' EQ '' OR &B2).NOAREA                            00860000
         AIF   ('&AREA'(1,1) EQ '(').E5                                 00880000
         DC    A(&AREA)                          AREA ADDRESS           00900000
         AGO   .PTRWD                                                   00920000
.NOAREA  DC    A(0)                              AREA ADDRESS           00940000
.PTRWD   DC    A(0)                              RECORD POINTER WORD    00960000
         AIF   ('&KEYADR' EQ '').NOKEY                                  00980000
         AIF   ('&KEYADR'(1,1) EQ '(').E5                               01000000
         DC    A(&KEYADR)                        KEY ADDRESS            01020000
         AGO   .EXCD                                                    01040000
.NOKEY   DC    A(0)                              KEY ADDRESS            01060000
.EXCD    DC    AL2(0)                            EXCEPTION OCDE         01080000
         MEXIT                                                          01100018
.IROUT   AIF   ('&DECB'(1,1) EQ '(').E6                                 01120000
         CNOP  0,4                                                      01140000
&NAME    BAL   1,*+30                            BRANCH AROUND DECB     01160000
&ISW     SETB  1                                                        01180000
         AGO   .SETROUT                                                 01200000
.IRETURN AIF   ('&LENGTH' EQ '').ZLENGTH                                01220000
         AIF   ('&LENGTH'(1,1) EQ '(' OR &B1).ZLENGTH                   01240000
         DC    AL2(&LENGTH)                      LENGTH                 01260000
         AGO   .CKDCB                                                   01280000
.ZLENGTH DC    AL2(0)                            LENGTH                 01300000
.CKDCB   AIF   ('&DCB' EQ '').E8                                        01320000
         AIF   ('&DCB'(1,1) EQ '(').ZDCB                                01340000
         DC    A(&DCB)                           DCB ADDRESS            01360000
         AGO   .CKAREA                                                  01380000
.ZDCB    DC    A(0)                              DCB ADDRESS            01400000
.CKAREA  AIF   ('&AREA' EQ '').E9                                       01420000
         AIF   ('&AREA'(1,1) EQ '(' OR &B2).ZAREA                       01440000
         DC    A(&AREA)                          AREA ADDRESS           01460000
         AGO   .ZPTRWD                                                  01480000
.ZAREA   DC    A(0)                              AREA ADDRESS           01500000
.ZPTRWD  DC    A(0)                              RECORD POINTER WORD    01520000
         AIF   ('&KEYADR' EQ '').E10                                    01540000
         AIF   ('&KEYADR'(1,1) EQ '(').ZKEY                             01560000
         DC    A(&KEYADR)                        KEY ADDRESS            01580000
         AGO   .EXCPCD                           KEY ADDRESS            01600000
.ZKEY    DC    A(0)                              KEY ADDRESS            01620000
.EXCPCD  DC    AL2(0)                            EXCEPTION CODE         01640000
         AIF   ('&LENGTH' EQ '').TSTDCB                                 01660000
         AIF   ('&LENGTH'(1,1) NE '(').TSTDCB                           01680000
         STH   &LENGTH(1),6(1,0)                 STORE LENGTH ADDRESS   01700000
.TSTDCB  AIF   ('&DCB'(1,1) NE '(').TSTAREA                             01720000
         ST    &DCB(1),8(1,0)                    STORE DCB ADDRESS      01740000
.TSTAREA AIF   ('&AREA'(1,1) NE '(').TSTKEY                             01760000
         ST    &AREA(1),12(1,0)                  STORE AREA ADDRESS     01780000
.TSTKEY  AIF   ('&KEYADR'(1,1) NE '(').CONTA                            01800000
         ST    &KEYADR(1),20(1,0)                STORE KEY ADDRESS      01820000
.CONTA   AIF   ('&DCB' EQ '').CONTAA                                    01840000
         AIF   ('&DCB'(1,1) EQ '(').REGDCB                              01860000
&CTR     SETA  K'&DCB                                                   01880000
         AIF   ('&DCB'(&CTR,1) EQ ')').CONTAA                           01900000
         L     15,&DCB+&CNT                      LOAD RDWRT ROUT. ADDR. 01920000
.FINISH  BALR  14,15                             LINK TO RDWRT ROUTINE  01940000
         MEXIT                                                          01960018
.CONTAA  L     15,8(1,0)                         LOAD DCB ADDRESS       01980000
         L     15,&CNT.(15,0)                    LOAD RDWRT ROUT. ADDR. 02000000
         AGO   .FINISH                                                  02020000
.REGDCB  L     15,&CNT.(&DCB(1),0)               LOAD RDWRT ROUT. ADDR. 02040000
         AGO   .FINISH                                                  02060000
.EROUT   AIF   ('&DECB'(1,1) EQ '(').DECBREG                            02080000
&NAME    LA    1,&DECB                           LOAD DECB ADDRESS      02100000
         AGO   .CONTB                                                   02120000
.DECBREG AIF   ('&DECB' EQ '(1)').NAMEIT                                02140000
&NAME    LR    1,&DECB(1)                        LOAD DECB ADDRESS      02160000
         AGO   .CONTB                                                   02180000
.NAMEIT  AIF   ('&NAME' EQ '').CONTB                                    02200000
&NAME    DS    0H                                                       02220000
.CONTB   ANOP                                                           02240000
&B1      SETB  ('&LENGTH' EQ '''S''')                                   02260000
&B2      SETB  ('&AREA' EQ '''S''')                                     02280000
         AIF   ('&AREA' EQ '' OR '&LENGTH' EQ '').NOTHERE               02300000
&CTR     SETA  &B2+2*&B1                                                02320000
         MVI   4(1),&CTR                         SET TYPE FIELD         02340000
         AGO   .SETYPE                                                  02360000
.NOTHERE AIF   ('&AREA' EQ '' AND '&LENGTH' EQ '').SETYPE               02380000
         AIF   ('&LENGTH' EQ '').NIXLTH                                 02400000
         AIF   (&B1).LENGTHS                                            02420000
         NI    4(1),1                            MODIFY TYPE FIELD      02440000
         AGO   .SETYPE                                                  02460000
.LENGTHS OI    4(1),2                            MODIFY TYPE FIELD      02480000
         AGO   .SETYPE                                                  02500000
.NIXLTH  AIF   (&B2).AREAS                                              02520000
         NI    4(1),2                            MODIFY TYPE FIELD      02540000
         AGO   .SETYPE                                                  02560000
.AREAS   OI    4(1),1                            MODIFY TYPE FIELD      02580000
.SETYPE  ANOP                                                           02600000
&B3   SETB     (('&TYPE' EQ 'K' OR '&TYPE' EQ 'KC') AND NOT &IHBWR)     02610017
&B4      SETB  ('&TYPE' EQ 'KC' OR '&TYPE' EQ 'KUC'                    X02620017
               OR '&TYPE' EQ 'KNC')                                     02630017
&B5   SETB     (('&TYPE' EQ 'KU' OR '&TYPE' EQ 'KUC') AND NOT &IHBWR)   02640017
&B6   SETB     (('&TYPE' EQ 'K' OR '&TYPE' EQ 'KC') AND &IHBWR)         02650017
&B7   SETB     (('&TYPE' EQ 'KN' OR '&TYPE' EQ 'KNC') AND &IHBWR)       02660017
         AIF   (&B3+&B5+&B6+&B7 NE 1).E3                                02670017
&CTR     SETA  4*&B7+8*&B6+32*&B5+64*&B4+128*&B3                        02740000
         MVI   5(1),&CTR                         SET TYPE FIELD         02760000
         AIF   ('&LENGTH' EQ '' OR &B1).XLENGTH                         02780000
         AIF   ('&LENGTH'(1,1) NE '(').NOREGA                           02800000
         STH   &LENGTH(1),6(1,0)                 STORE LENGTH           02820000
         AGO   .XLENGTH                                                 02840000
.NOREGA  AIF   (NOT &IHBT(1)).LARGEL                                    02860000
         AIF   (&LENGTH GT 4095).LARGEL                                 02880000
         LA    14,&LENGTH.(0,0)                  PICK UP LENGTH         02900000
         STH   14,6(1,0)                         STORE LENGTH           02920000
         AGO   .XLENGTH                                                 02940000
.LARGEL  B     *+6                               BRANCH AROUND LENGTH   02960000
         DC    AL2(&LENGTH)                      LENGTH                 02980000
         MVC   6(2,1),*-2                        MOVE IN LENGTH         03000000
.XLENGTH AIF   ('&DCB' EQ '').XDCB                                      03020000
         AIF   ('&DCB'(1,1) EQ '(').DCBRG                               03040000
         LA    14,&DCB                           PICK UP DCB ADDRESS    03060000
         ST    14,8(1,0)                         STORE DCB ADDRESS      03080000
         AGO   .XDCB                                                    03100000
.DCBRG   ST    &DCB(1),8(1,0)                    STORE DCB ADDRESS      03120000
.XDCB    AIF   ('&AREA' EQ '' OR &B2).XAREA                             03140000
         AIF   ('&AREA'(1,1) EQ '(').AREARG                             03160000
         LA    14,&AREA                          PICK UP AREA ADDRESS   03180000
         ST    14,12(1,0)                        STORE AREA ADDRESS     03200000
         AGO   .XAREA                                                   03220000
.AREARG  ST    &AREA(1),12(1,0)                  STORE AREA ADDRESS     03240000
.XAREA   AIF   ('&KEYADR' EQ '').CONTA                                  03260000
         AIF   ('&KEYADR'(1,1) EQ '(').KEYREG                           03280000
         LA    14,&KEYADR                        PICK UP KEY ADDRESS    03300000
         ST    14,20(1,0)                        STORE KEY ADDRESS      03320000
         AGO   .CONTA                                                   03340000
.KEYREG  ST    &KEYADR(1),20(1,0)                                       03360000
         AGO   .CONTA                                                   03380000
.E3      IHBERMAC 48,,&TYPE             INVALID TYPE OPERAND SPECIFIED  03390018
         MEXIT                                                          03400018
.E4      IHBERMAC 35,,&MF               INVALID MF OPERAND SPECIFIED    03410018
         MEXIT                                                          03420018
.E5      IHBERMAC 69                    INVALID REG NOTATION W/MF=L     03430018
         MEXIT                                                          03440018
.E6      IHBERMAC 87                    DECB NOT SPECIFIED AS A SYMBOL  03450018
         MEXIT                                                          03460018
.E8      IHBERMAC 6                     DCB OPERAND MISSING             03470018
         MEXIT                                                          03480018
.E9      IHBERMAC 13                    AREA OPERAND MISSING            03490018
         MEXIT                                                          03500018
.E10     IHBERMAC 8                     KEY OPERAND MISSING             03510018
         MEND                                                           43510018
