         MACRO                                                          00020000
&NAME    OPEN  &PAR1,&MF=I,&TYPE=                                A45585 00040021
         GBLB  &IHBRDJ                  ON IF RDJFCB MACRO USED         00070018
         LCLA  &ACTR,&ASUM,&CTR,&CTR1,&LGTH,&NUMBER                     00100000
         LCLB  &MFESW,&MFISW,&MFI2SW,&B(10),&NULLSW,&OPT2SW             00120001
         LCLC  &PARA                                                    00140000
&NUMBER  SETA  N'&PAR1                                                  00220000
&CTR     SETA  1                                                        00240000
&CTR1    SETA  2                                                        00260000
         AIF   (N'&SYSLIST LE 1).TYPE   IF ONLY 1 (PARMLIST)     A45585 00285021
         IHBERMAC 238                   EXCESSIVE POS. PARMS     A45585 00290021
.TYPE    AIF   (T'&TYPE NE 'O' AND '&TYPE' NE 'J').ERROR8        A45585 00295021
         AIF   ('&MF' EQ 'L').RTEL                                      00300000
         AIF   ('&MF' EQ 'I').TESTI                                     00320000
         AIF   (N'&MF LE 1).ERROR3                                      00340000
         AIF   ('&MF(1)' NE 'E').ERROR3                                 00360000
&NAME    IHBINNRA &MF(2)                    LOAD REG 1 WITH LIST ADDR   00380000
         AGO   .ISSSVC                                                  00400000
.*--------------------------------------------------------------------- 00420001
.RTEL    ANOP                                                           00460000
&NAME    DC    0F'0'                             ALIGN LIST TO FULLWORD 00480001
         AIF   ('&PAR1' EQ '').ERROR5                                   00490001
.CLRSW   ANOP                                                           00500000
&ASUM    SETA  0                                                        00520000
         AIF   (&CTR1 GT &NUMBER).J                                     00560000
         AIF   ('&PAR1(&CTR1)' EQ '').DC1                               00580000
         AIF   ('&PAR1(&CTR1)'(1,1) NE '(').NOPAREN                     00600000
&B(1)    SETB  ('&PAR1(&CTR1)'(2,5) EQ 'INPUT')                         00620000
&B(2)    SETB  ('&PAR1(&CTR1)'(2,6) EQ 'RDBACK')                        00640000
&B(3)    SETB  ('&PAR1(&CTR1)'(2,5) EQ 'INOUT')                         00660000
&B(4)    SETB  ('&PAR1(&CTR1)'(2,5) EQ 'UPDAT')                         00680000
&B(5)    SETB  ('&PAR1(&CTR1)'(2,5) EQ 'OUTIN')                         00700000
&B(6)    SETB  ('&PAR1(&CTR1)'(2,6) EQ 'OUTPUT')                        00720000
         AIF   (K'&PAR1(&CTR1) LE 8).STOPNOW                            00740000
&B(7)    SETB  ('&PAR1(&CTR1)'(8,4) EQ 'LEAV'  OR '&PAR1(&CTR1)'(9,4) EX00760000
               Q 'LEAV')                                                00780000
&B(8)    SETB  ('&PAR1(&CTR1)'(8,4) EQ 'RERE' OR '&PAR1(&CTR1)'(9,4) EQX00800000
                'RERE')                                                 00820000
&B(9)    SETB  ('&PAR1(&CTR1)'(8,4) EQ 'DISP' OR '&PAR1(&CTR1)'(9,4) EQX00840000
                'DISP')                                                 00860000
&B(10)   SETB  ('&PAR1(&CTR1)'(8,4) EQ 'IDLE' OR '&PAR1(&CTR1)'(9,4) EQX00880000
                'IDLE')                                                 00900000
&OPT2SW  SETB  1                                                        00920000
         AIF   (&B(7)+&B(8)+&B(9)+&B(10) NE 1).ERROR1                   00940001
.STOPNOW AIF   (&B(1)+&B(2)+&B(3)+&B(4)+&B(5)+&B(6) NE 1).ERROR1        00960000
&ASUM    SETA  &B(2)+3*&B(3)+4*&B(4)+7*&B(5)+15*&B(6)+48*&B(7)+16*&B(8)X00980001
               +32*&B(10)                                               01000001
         AGO   .RESET                                                   01020000
.NOPAREN ANOP                                                           01040000
&B(1)    SETB  ('&PAR1(&CTR1)' EQ 'INPUT')                              01060000
&B(2)    SETB  ('&PAR1(&CTR1)' EQ 'RDBACK')                             01080000
&B(3)    SETB  ('&PAR1(&CTR1)' EQ 'INOUT')                              01100000
&B(4)    SETB  ('&PAR1(&CTR1)' EQ 'UPDAT')                              01120000
&B(5)    SETB  ('&PAR1(&CTR1)' EQ 'OUTIN')                              01140000
&B(6)    SETB  ('&PAR1(&CTR1)' EQ 'OUTPUT')                             01160000
         AGO   .STOPNOW                                                 01180000
.RESET   ANOP                                                           01200000
&B(7)    SETB  0                                                        01220000
&B(8)    SETB  0                                                        01240000
&B(10)   SETB  0                                                        01260000
.DC1     AIF   (&MFESW).ERTRTRN                                         01280000
         AIF   (&CTR1 LT &NUMBER).K                                     01300001
.J       ANOP                                                           01380000
&ASUM    SETA  &ASUM+128                                                01420000
.K       AIF   (&MFI2SW).I2ROUT                                         01440001
         AIF   (&MFISW).IROUTRN                                         01460000
         DC    AL1(&ASUM)                        OPTION BYTE            01500000
         AIF   ('&PAR1(&CTR)' NE '').NOBLANK                            01520001
         DC    AL3(0)                            DCB ADDRESS            01560001
         AGO   .NOTLST                                                  01580000
.NOBLANK AIF   ('&PAR1(&CTR)'(1,1) EQ '(').ERROR6                       01600000
         DC    AL3(&PAR1(&CTR))                  DCB ADDRESS            01620001
.NOTLST  AIF   (&CTR1 GE &NUMBER).FINI                                  01640001
&CTR     SETA  &CTR+2                                                   01660000
&CTR1    SETA  &CTR1+2                                                  01680000
         AGO   .CLRSW                                                   01700001
.*--------------------------------------------------------------------- 01720001
.TESTI   CNOP  0,4                               ALIGN LIST TO FULLWORD 01740001
&LGTH    SETA  ((&NUMBER+1)/2)*4+4                                      01760001
&NAME    BAL   1,*+&LGTH                         LOAD REG1 W/LIST ADDR. 01780000
&MFISW   SETB  1                                                        01800000
.RTEYE   AIF   ('&PAR1(&CTR)' EQ '').ERROR5                             01820000
         AIF   ('&PAR1(&CTR)'(1,1) NE '(').CLRSW                        01840000
         DC    A(0)                              OPT BYTE AND DCB ADDR. 01860000
         AGO   .UPCTRS                                                  01880000
.IROUTRN DC    AL1(&ASUM)                        OPTION BYTE            01900000
         DC    AL3(&PAR1(&CTR))                  DCB ADDRESS            01920000
.UPCTRS  AIF   (&CTR1 GE &NUMBER).QUITS                                 01940000
&CTR     SETA  &CTR+2                                                   01960000
&CTR1    SETA  &CTR1+2                                                  01980000
         AGO   .RTEYE                                                   02000000
.QUITS   ANOP                                                           02020000
&CTR     SETA  1                                                        02040000
&CTR1    SETA  2                                                        02060000
.ILOOP2  AIF   ('&PAR1(&CTR)'(1,1) NE '(').UPCTR2                       02080000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          02100000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   02120000
         ST    &PARA,&ACTR.(1,0)                 STORE INTO LIST        02140000
&MFI2SW  SETB  1                                                        02160000
         AGO   .CLRSW                                                   02180000
.I2ROUT  AIF   (&ASUM EQ 0).UPCTR2                                      02200000
         MVI   &ACTR.(1),&ASUM                   MOVE IN OPTION BYTE    02220000
.UPCTR2  AIF   (&CTR1 GE &NUMBER).SVCSVC                                02240000
&CTR     SETA  &CTR+2                                                   02260000
&CTR1    SETA  &CTR1+2                                                  02280000
&ACTR    SETA  &ACTR+4                                                  02300000
         AGO   .ILOOP2                                                  02320000
.*--------------------------------------------------------------------- 02340001
.ISSSVC  AIF   ('&PAR1' EQ '').SVCSVC                                   02380000
.LOOPA   AIF   ('&PAR1(&NUMBER)' NE '').LOOPB                           02400001
&NUMBER  SETA  &NUMBER-1                                                02420000
         AIF   (&NUMBER EQ 0).SVCSVC                                    02440000
         AGO   .LOOPA                                                   02460000
.LOOPB   AIF   ('&PAR1(&CTR)' NE '').TESTCTR                            02480001
&NULLSW  SETB  1                                                        02500001
.TESTCTR AIF   (&CTR EQ &NUMBER).QUITNOW                                02520000
         AIF   ('&PAR1(&CTR1)' EQ '').NULLTWO                           02540001
&MFESW   SETB  1                                                        02560000
         AGO   .CLRSW                                                   02580000
.ERTRTRN AIF   (&CTR1 EQ &NUMBER).THRUNOW                               02660000
         AIF   (&NULLSW).NOFIRST                                        02680000
         AIF   ('&PAR1(&CTR)'(1,1) EQ '(').REGISTR                      02700000
         AIF   (NOT &OPT2SW).OPTA                                       02720000
         LA    14,&PAR1(&CTR)                    PICK UP DCB ADDRESS    02740000
         ST    14,&ACTR.(1,0)                    STORE INTO LIST        02760000
.SHORTB  MVI   &ACTR.(1),&ASUM                   MOVE IN OPTION BYTE    02780000
         AGO   .INCRMT                                                  02800000
.OPTA    IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       02820000
         LA    0,&PAR1(&CTR)                     PICK UP DCB ADDRESS    02840000
         ST    0,&ACTR.(1,0)                     STORE INTO LIST        02860000
.SHORTA  STC   14,&ACTR.(1,0)                    RESTORE OPTION BYTE    02880000
.OPTC    NI    &ACTR.(1),X'F0'                   CLEAR OPT 1 BITS       02900001
         AIF   (&ASUM EQ 0).INCRMT                                      02920000
         OI    &ACTR.(1),&ASUM                   INSERT OPT 1 BITS      02940000
         AGO   .INCRMT                                                  02960000
.REGISTR ANOP                                                           02980000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          03000000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   03020000
         AIF   (NOT &OPT2SW).OPTB                                       03040000
         ST    &PARA,&ACTR.(1,0)                 STORE INTO LIST        03060000
         AGO   .SHORTB                                                  03080000
.OPTB    IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       03100000
         ST    &PARA,&ACTR.(1,0)                 STORE INTO LIST        03120000
         AGO   .SHORTA                                                  03140000
.NOFIRST AIF   (NOT &OPT2SW).OPTC                                       03160000
         AGO   .SHORTB                                                  03180000
.NULLTWO AIF   (&NULLSW).INCRMT                                         03200001
         AIF   ('&PAR1(&CTR)'(1,1) EQ '(').REGSTER                      03220001
         IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       03240000
         LA    0,&PAR1(&CTR)                     PICK UP DCB ADDRESS    03260000
         ST    0,&ACTR.(1,0)                     STORE INTO LIST        03280000
.SHORTC  STC   14,&ACTR.(1,0)                    RESTORE OPTION BYTE    03300000
         AGO   .INCRMT                                                  03320000
.REGSTER IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       03340000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          03360000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   03380000
         ST    &PARA,&ACTR.(1,0)                 STORE INTO LIST        03400000
         AGO   .SHORTC                                                  03420000
.QUITNOW IC    14,&ACTR.(1,0)                    SAVE OPTION BYTE       03440000
         AIF   ('&PAR1(&CTR)'(1,1) EQ '(').REGST                        03460000
         LA    0,&PAR1(&CTR)                     PICK UP DCB ADDRESS    03480000
         ST    0,&ACTR.(1,0)                     STORE INTO LIST        03500000
.SHORTD  STC   14,&ACTR.(1,0)                    RESTORE OPTION BYTE    03520001
         AGO   .SVCSVC                                                  03540000
.REGST   ANOP                                                           03560000
&LGTH    SETA  K'&PAR1(&CTR)-2                                          03580000
&PARA    SETC  '&PAR1(&CTR)'(2,&LGTH)                                   03600000
         ST    &PARA,&ACTR.(1,0)                 STORE INTO LIST        03620000
         AGO   .SHORTD                                                  03640000
.THRUNOW AIF   (NOT &OPT2SW).OPTD                                       03660000
         NI    &ACTR.(1),X'80'                   CLEAR OPTION BITS      03680000
.SHORTE  AIF   (&ASUM EQ 0).CONTA                                       03700000
         OI    &ACTR.(1),&ASUM                   INSERT OPTION BITS     03720000
.CONTA   AIF   (&NULLSW).SVCSVC                                         03740000
         AGO   .QUITNOW                                                 03760000
.OPTD    NI    &ACTR.(1),X'F0'                   CLEAR OPTION 1 BITS    03780001
         AGO   .SHORTE                                                  03800000
.INCRMT  ANOP                                                           03820000
&CTR     SETA  &CTR+2                                                   03840000
&CTR1    SETA  &CTR1+2                                                  03860000
&ACTR    SETA  &ACTR+4                                                  03880000
&OPT2SW  SETB  0                                                        03900000
&NULLSW  SETB  0                                                        03920000
         AGO   .LOOPB                                                   03940000
.*--------------------------------------------------------------------- 03950001
.SVCSVC  AIF   (&IHBRDJ).FINI                                   SA51997 03960001
         AIF   ('&TYPE' EQ 'J').SVC22   IF TYPE=J                       03980018
         SVC   19                                ISSUE OPEN SVC         04000000
         MEXIT                                                          04020001
.SVC22   SVC   22                                ISSUE OPENJ SVC        04040000
         MEXIT                                                          04060001
.ERROR1  IHBERMAC 49,,&PAR1(&CTR1)      INVALID OPTION OPERAND          04070018
         MEXIT                                                          04080018
.ERROR3  IHBERMAC 35,,&MF               INVALID MF OPERAND SPECIFIED    04090018
         MEXIT                                                          04100000
.ERROR5  IHBERMAC 6                     DCB MISSING                     04110018
         MEXIT                                                          04120018
.ERROR6  IHBERMAC 69                    INVALID REG NOTATION W/MF=L     04130018
         MEXIT                                                          04133020
.ERROR8  IHBERMAC 63,,&TYPE             INVALID TYPE OPERAND     M0626  04138020
.FINI    MEND                                                           04140000
