         MACRO                           HEADER STATEMENT               00020000
&NAME    RLSEBFR &DCB,&SECT,&MF=         PROTOTYPE STATEMENT            00040000
.*LOCALS DEFINED                                                        00060000
         LCLC  &PAREN,&A                 LOCALS DEFINED                 00080000
         LCLA  &ADCB,&ASECT,&ALL                                        00100000
         LCLA  &SAVCOD                                                  00120000
         AIF   (T'&MF EQ 'O').SFORM      S-FORM ASSUMED IF PMF= OMITTED 00140000
         AIF   (N'&MF EQ 2).EFORM            CHECK FOR 2 OPERANDS       00160000
         AIF   ('&MF(1)' EQ 'L').LFORM       POSITIVE CHECK FOR 6       00180000
         AGO   .ERREMF                                                  00200000
.EFORM   AIF   ('&MF(1)' NE 'E').ERREMF      POSITIVE CHECK FOR )       00220000
         AIF   ('&MF(2)'(1,1) EQ '(').REGMF  CHECK NOTATION OF LSTADDR  00240000
&NAME    LA    1,&MF(2)                  REG 1 HAS LSTADDR IN E-FORM    00260000
.CHECK   AIF   (T'&DCB EQ 'O' AND T'&SECT EQ 'O').END                   00280000
         AIF   (T'&DCB NE 'O').CHANGE1                                  00300000
.SCTION  AIF   ('&SECT' NE 'ALL').SECTAD  CHECK FOR 'ALL'               00320000
         XC    4(4,1),4(1)               CLEAR SCT ADDR AND NUMB TO 0   00340000
         MVI   0(1),X'0C'                LIST WITH GIVEN PARAMS         00360000
         AGO   .END                                                     00380000
.SECTAD  MVI   0(1),X'08'                PUT CORRECT CODE IN PARAMLST   00400000
         AIF   ('&SECT'(1,1) EQ '(').REGSCT                             00420000
         LA    0,&SECT                   PUT BUFPRAM-ADDR IN PARAMLIST  00440000
         ST    0,4(1)                    PUT BUFPRAM-ADDR IN PARAMLIST  00460000
.END     SVC   71                                                       00480000
         MEXIT     BRANCH OUT OF MACRO DEFINITION                       00500000
.CHANGE1 AIF   (T'&SECT EQ 'O').CODESV    SET SWITCH IF OMITTED         00520000
.CHANGE2 AIF   ('&DCB'(1,1) EQ '(').REGDCB    CHECK FOR REG NOTATION    00540000
         AIF   (&SAVCOD EQ 1).SYMPAIN   IF SWITCH ON,EXPAND MORE        00560000
         LA    0,&DCB                    PUT DCBADDR IN PARAM LIST      00580000
         ST    0,0(1)                    PUT DCBADDR IN PARAM LIST      00600000
.GOON    AIF   (T'&SECT NE 'O').SCTION                                  00620000
         AGO   .END                                                     00640000
.CODESV  ANOP                                                           00660000
&SAVCOD  SETA  1                  SET SWITCH                            00680000
         XC    1(3,1),1(1)        CLEAR 3 BYTE DCB FLD IN PARAMLST      00700000
         AGO   .CHANGE2                                                 00720000
.SYMPAIN LA    0,&DCB             LOAD DCB ADR                          00740000
         O     0,0(1)    OR IN REQ CODE ANDCLEARED DCB FLD              00760000
         ST    0,0(1)             STORE INTO PARLST WITH REQ CODE       00780000
         AGO   .END                                                     00800000
.REGMF   ANOP                                                           00820000
&PAREN   SETC  '&MF(2)'(2,K'&MF(2)-2)    ISOLATE REGISTER               00840000
&NAME    LR    1,&PAREN                  PUT LISTADR IN REG 1           00860000
         AGO   .CHECK                                                   00880000
.REGDCB  ANOP                                                           00900000
&PAREN   SETC  '&DCB'(2,K'&DCB-2)        ISOLATE REGISTER NUMBER        00920000
         AIF   (&SAVCOD EQ 1).REGPAIN                                   00940000
         ST    &PAREN,0(1)               PUT IN PARAM LIST              00960000
         AGO   .GOON                                                    00980000
.REGPAIN LA    0,0(&PAREN)    CLR HI-ORDER BYTE OF DCB ADR REG          01000000
         O     0,0(1)    OR REQUEST CODE AND CLEARED DCB FLD            01020000
         ST    0,0(1)    RETURN TO PARAM LST WITH CODE INTACT           01040000
         AGO   .END                                                     01060000
.REGSCT  ANOP                                                           01080000
&PAREN   SETC  '&SECT'(2,K'&SECT-2)                                     01100000
         ST    &PAREN,4(1)               PUT BUFPRAM-ADDR IN PARAMLIST  01120000
         AGO   .END                                                     01140000
.SFORM   ANOP                                                           01160000
&NAME    LA    1,A&SYSNDX              LOAD ADR OF PARAM LIST           01180000
         AIF   (T'&DCB EQ 'O').NODCB                                    01200000
&PAREN   SETC  '&DCB'(1,1)                                              01220000
         AIF   ('&PAREN' EQ '(').REGSDCB    CHECK NOTATION              01240000
         AIF   ('&PAREN' LT 'A').ERRDCB  MUST BE IN SYMBOLIC FORM       01260000
         AIF   ('&PAREN' GT 'Z').ERRDCB  MUST BE IN SYMBOLIC FORM       01280000
&ADCB    SETA  1                   SET TO 1 IF SYMBOLIC                 01300000
.OK1     AIF   (T'&SECT EQ 'O').NOSECT   IF OMITTED, GROSS ERROR        01320000
.AHEAD   AIF   ('&SECT' NE 'ALL').ADDRS  CHECK FOR 'ALL' CONDITION      01340000
         AIF   (&ADCB EQ 1).SETALL                                      01360000
         MVI   A&SYSNDX,X'0C'            INSERT PROPER CODE             01380000
.FORWRD  CNOP  2,4                                                      01400000
         SVC   71  CALL BUFFER MANAGEMENT ROUTINE VIA SVC               01420000
         B     A&SYSNDX+8                BRANCH AROUND PARAM LIST       01440000
         AIF   (&ADCB EQ 1).SYM1   IF 1 GO TO SYM1                      01460000
A&SYSNDX DC    A(0)                CODE AND DCBADR                      01480000
.CHK1    AIF   (&ASECT EQ 1).SYM2  IF 1 GO TO SYM2                      01500000
         DC    A(0)                BUFPRM                               01520000
         MEXIT   BRACCH OUT OF MACRO DEFINITION                         01540000
.SYM1    AIF   (&ALL EQ 1).ALL                                          01560000
A&SYSNDX DC    AL1(8)                   CODE FOR RLSE                   01580000
         DC    AL3(&DCB)                DCBADR                          01600000
         AGO   .CHK1                                                    01620000
.ALL     ANOP                                                           01640000
A&SYSNDX DC    AL1(12)                  CODE FOR RLSE ALL               01660000
         DC    AL3(&DCB)                DCBADR                          01680000
         AGO   .CHK1                                                    01700000
.SYM2    DC    A(&SECT)            BUFPRM PTR                           01720000
         MEXIT                                                          01740000
.ADDRS   AIF   (&ADCB EQ 1).CKON                                        01760000
         MVI   A&SYSNDX,X'08'            INSERT CORRECT CODE            01780000
.CKON    ANOP                                                           01800000
&PAREN   SETC  '&SECT'(1,1)                                             01820000
         AIF   ('&PAREN' EQ '(').REGSSCT   CHECK NOTATION               01840000
&ASECT   SETA  1                   SET TO 1 IF SYMBOLIC                 01860000
         AGO   .FORWRD                                                  01880000
.SETALL  ANOP                                                           01900000
&ALL     SETA  1                                                        01920000
         AGO   .FORWRD                                                  01940000
.REGSSCT ANOP                                                           01960000
&PAREN   SETC  '&SECT'(2,K'&SECT-2)      ISOLATE REG NUMBER             01980000
         ST    &PAREN,A&SYSNDX+4         PUT BUFPRAM-ADDR IN PARAMLIST  02000000
         AGO   .FORWRD                                                  02020000
.REGSDCB ANOP                                                           02040000
&PAREN   SETC  '&DCB'(2,K'&DCB-2)                                       02060000
         ST    &PAREN,A&SYSNDX           PUT IN PARAM LIST              02080000
         AGO   .OK1                                                     02100000
.LFORM   AIF   (T'&DCB EQ 'O' AND T'&SECT EQ 'O').FINI                  02120000
         AIF   (T'&DCB NE 'O').CHK                                      02140000
         AIF   ('&SECT' EQ 'ALL').CODE                                  02160000
.SECT    AIF   ('&SECT' EQ 'ALL').CODE                                  02180000
&PAREN   SETC  '&SECT'(1,1)                                             02200000
         AIF   ('&PAREN' LT 'A' OR '&PAREN' GT 'Z').ERRSCT              02220000
&ASECT   SETA  1                                                        02240000
.FINI    DS    0F                        GENERATED CODING               02260000
         AIF   (&ALL EQ 1).ALLCOD                                       02280000
&NAME    DC    AL1(8)                    CODE FOR RELEASE BUFFER        02300000
.CHK2    AIF   (&ADCB EQ 1).FILL1                                       02320000
         DC    AL3(0)                   DCBADR                          02340000
.CHK3    AIF   (&ASECT EQ 1).FILL2                                      02360000
.OUT     DC    A(0)                     BUFPARAM                        02380000
         MEXIT                                                          02400000
.CHK     ANOP                                                           02420000
&PAREN   SETC  '&DCB'(1,1)                                              02440000
         AIF   ('&PAREN' LT 'A' OR '&PAREN' GT 'Z').ERLDCB              02460000
&ADCB    SETA  1                                                        02480000
.OK2     AIF   (T'&SECT EQ 'O').FINI                                    02500000
         AGO   .SECT                                                    02520000
.CODE    ANOP                                                           02540000
&ALL     SETA  1                                                        02560000
         AGO   .FINI                                                    02580000
.ALLCOD  ANOP                                                           02600000
&NAME    DC    AL1(12)                  CODE FOR RLSEALL                02620000
         AGO   .CHK2                                                    02640000
.FILL1   DC    AL3(&DCB)                DCBADR                          02660000
         AGO   .CHK3                                                    02680000
.FILL2   AIF   ('&SECT' EQ 'ALL').OUT                                   02700000
         DC    A(&SECT)                 BUFPARAM                        02720000
         MEXIT                                                          02740000
.ERREMF  IHBERMAC  35,,&MF         ERROR MSG FOR INVALID MF             02760000
         MEXIT                                                          02780000
.ERRDCB  IHBERMAC  36,,DCBADDR                                          02800000
         AGO   .OK1                                                     02820000
.ERLDCB  IHBERMAC  36,,DCBADR                                           02840000
         AGO   .OK2                                                     02860000
.NODCB   IHBERMAC  6                                                    02880000
         AGO   .OK1                                                     02900000
.NOSECT  IHBERMAC  3                                                    02920000
         AGO   .FORWRD                                                  02940000
.ERRSCT  IHBERMAC  37,,BUFPARAM                                         02960000
         AGO   .FINI                                                    02980000
         MEND                                                           03000000
