         MACRO                                                          00600000
&ANYNAME SETPRT &DCB,&UCS=,&FCB=,&MF=,&OPTCD=                           01200020
.*                                                                      01800000
.*   THE ABOVE IS MACRO PROTOTYPE                                       02400000
.*                                                                      03000000
         LCLA  &L                                                       03600000
         LCLA  &K                                                       04200000
         LCLB  &SW1                                                     04800000
         LCLC  &PAREN1                                                  05400000
         LCLC  &PAREN2                                                  06000000
         LCLC  &PAREN3                                                  06600000
         LCLC  &PAREN4                                                  07200000
         LCLC  &MFTWO                                                   07800000
&K       SETA  K'&DCB                  STORE NO. OF CHARACTERS IN DCB   08400000
&L       SETA  K'&MF(2)                LENGTH OF &MF(2)                 09000000
         AIF   ('&DCB' EQ '').CHECKL                                    09600000
&PAREN1  SETC  '&DCB'(1,1)             FIRST CHARACTER OF &DCB          10200000
&PAREN2  SETC  '&DCB'(&K,1)            LAST CHARACTER OF &DCB           10800000
         AIF   ('&DCB' NE '&DCB(1)').DCBNREG DCB IN REG                 10850000
         AGO   .CHECKL                                                  10900000
.DCBNREG ANOP                           DCB IS IN REGISTER              10950000
&K       SETA  K'&DCB(1)                LENGTH OF &DCB(1)               11000000
.CHECKL  AIF   ('&MF(2)' EQ '').TESTUCS                                 11400000
&MFTWO   SETC  '&MF(2)'                                                 12000000
&PAREN3  SETC  '&MFTWO'(1,1)           FIRST CHARACTER OF &MF(2)        12600000
&PAREN4  SETC  '&MFTWO'(&L,1)          LAST CHARACTER OF &MF(2)         13200000
.TESTUCS AIF   (N'&UCS GT 0).CHECK1    TEST IF UCS PARAMETERS PRESENT   13800000
         AGO   .TSTFCB                  GO CK FCB PARAMETERS            14400020
.CHECK1  AIF   ('&UCS(1)' EQ '').ERROR02 TEST IF UCS-ID IS MISSING      15000000
.TSTFCB  AIF   (N'&FCB GT 0).FCBCK1     TEST IF FCB PARAMETERS PRESENT  15100020
         AGO   .BYPASS                  GO CK DCB SPECIFIED             15200020
.FCBCK1  AIF   ('&FCB(1)' EQ '').ERROR06  TEST IF FCB ID MISSING        15300020
.BYPASS  AIF   ('&DCB' NE '&DCB(1)').BYPASS2                            15600000
         AIF   (K'&DCB GT 8).ERROR01    TEST IF DCB NAME GT 8           15750000
.BYPASS2 ANOP                                                           15800000
         AIF   (K'&DCB(1) GT 8).ERROR01  TEST IF REG NAME GT 8          15850000
         AIF   ('&DCB' EQ '(1)' OR '&DCB' EQ '(0)').ERROR01             16200000
         AIF   ('&MF' EQ '' OR '&MF(1)' EQ 'E' OR '&MF' EQ 'L').GOGOUCS 16800000
         AGO   .ERROR03                                                 17400000
.GOGOUCS AIF   ('&UCS(2)' EQ '' OR '&UCS(2)' EQ 'F' OR '&UCS(2)' EQ 'FOC18000000
               LD').CHECK3                                              18600000
         AGO   .ERROR02                                                 19200000
.CHECK3  AIF   ('&UCS(3)' EQ '' OR '&UCS(3)' EQ 'V' OR '&UCS(3)' EQ 'VEC19800000
               RIFY').GOGOFCB                                           20400020
         AGO   .ERROR02                                                 21000000
.GOGOFCB AIF   ('&FCB(2)' EQ '' OR '&FCB(2)' EQ 'ALIGN' OR '&FCB(2)' EQX21100020
                'VERIFY' OR '&FCB(2)' EQ 'V' OR '&FCB(2)' EQ 'A').GOGOCX21200020
               D                                                        21300020
         AGO   .ERROR06                 IF FCB PARM IN ERROR            21400020
.GOGOCD  AIF   ('&OPTCD' EQ '' OR '&OPTCD' EQ 'U' OR '&OPTCD' EQ 'B').GC21600000
               OGODCB                                                   22200000
         AIF   ('&OPTCD(1)' EQ 'B' OR '&OPTCD(1)' EQ 'U').CKOPT         22300020
         AGO   .ERROR04                 NO HAVE INVALID OPTCD PARM'S    22400020
.CKOPT   AIF   ('&OPTCD(2)' EQ '' OR '&OPTCD(2)' EQ 'FOLD' OR '&OPTCD(2X22500020
               )' EQ 'UNFOLD' OR '&OPTCD(2)' EQ 'F' OR '&OPTCD(2)' EQ 'X22600020
               U').GOGODCB                                              22700020
         AGO   .ERROR04                                                 22800000
.GOGODCB AIF   ('&DCB' EQ '').UCSERR                                    23400000
         AIF   ('&PAREN1' EQ '(' AND '&PAREN2' EQ ')').SETSW            24000000
         AGO   .UCSERR                                                  24600000
.SETSW   ANOP                                                           25200000
&SW1     SETB  (1)                           IF YES SET SW1=1           25800000
.UCSERR  AIF   (K'&UCS(1) GT 4).ERROR02      TEST IF UCS ID GT 4        26400000
         AIF   (K'&FCB(1) GT 4).ERROR06                                 26700020
         AIF   ('&MF(1)' EQ 'E').EFORMMF     TEST IF MF=E               27000000
         AIF   ('&MF' EQ 'L').LIST     TEST IF MF=L                     27600000
         AIF   ('&DCB' EQ '').ERROR01        TEST IF NO DCB SPECIFIED   28200000
         AIF   ('&UCS(1)' EQ '').TSTFCB2                                28800020
*                                                                       29400000
         AGO   .MACRGO                       IF NOT MF=L,MF=I           30000000
.TSTFCB2 AIF   ('&FCB(1)' EQ '').TSTOPCD CK IF FCB SPECIFIED            30200020
         AGO   .MACRGO                                                  30400020
.TSTOPCD AIF   ('&OPTCD' EQ '').ERROR05                                 30600000
         AGO   .MACRGO                                                  31200000
.LIST    AIF   ( &SW1 ).REGDCB               TEST IF DCB=(R)            31800000
         DS    0F                                                       32400000
         AIF   ('&DCB' NE '').SKIP                                      33000000
&ANYNAME DC    AL4(0)                  DCB ADDR                         33600000
         AGO   .SKIPGO                                                  34200000
.SKIP    ANOP                                                           34800000
&ANYNAME DC    AL4(&DCB)               DCB ADDR                         35400000
         AGO   .SKIPGO                                                  36000000
.REGDCB  ANOP                                DCB=(R)                    36600000
         CNOP  0,4                                                      37200000
&ANYNAME BAL   1,*+20                                                   37800020
         DC    AL4(0)                   DCB ADDR                        38400000
         AGO   .SKIPGO                                                  39000000
.MACRGO  AIF   ( &SW1 ).REGDCB               TEST IF DCB=(R)            39600000
         CNOP  0,4                                                      40200000
&ANYNAME BAL   1,*+20                                                   40800020
         DC    AL4(&DCB)                DCB ADDR                        41400000
.SKIPGO  AIF   ('&UCS(1)' NE '').NONULL                                 42000000
         DC    AL4(0)                   CHARACTER SET IMAGE ID          42600000
         AGO   .CONTSKP                                                 43200000
.NONULL  ANOP                                                           43800000
         DC    CL4'&UCS(1)'             CHARACTER SET IMAGE ID          44400000
.CONTSKP ANOP                                                           45000000
         AIF   ('&UCS(2)' EQ 'F' OR '&UCS(2)' EQ 'FOLD').FOLD           45600000
         DC    X'00'                    LOAD MODE = NO FOLD             46200000
         AGO   .TSTVRFY                                                 46800000
.FOLD    ANOP                           FOLD SPECIFIED                  47400000
         DC    X'40'                    LOAD MODE = FOLD                48000000
.TSTVRFY ANOP                           TEST IF VERIFY IS SPECIFIED     48600000
         AIF   ('&UCS(3)' EQ 'V' OR '&UCS(3)' EQ 'VERIFY').VERIFY       49200000
         DC    X'00'                    VERIFY = NO                     49800000
         AGO   .OPTCD                                                   50400000
.VERIFY  ANOP                           VERIFY SPECIFIED                51000000
         DC    X'10'                    VERIFY = YES                    51600000
.OPTCD   AIF   ('&OPTCD' EQ 'U').UNBLK       TEST BLOCK/UN DATA CHECK   52200000
         AIF   ('&OPTCD(1)' EQ 'U').TSTFDOP  GO CK FOR UCS OPTIONS      52500020
         AIF   ('&OPTCD' EQ 'B').BLOCK                                  52800000
         AIF   ('&OPTCD(1)' EQ 'B').TSTFLD2  GO CK UCS OPTION           53100020
         DC    X'00'                    DATA CHECK = AS DCB SPEC.       53400000
         AGO   .FCBPAR                                                  53700020
.TSTFDOP AIF   ('&OPTCD(2)' EQ 'FOLD' OR '&OPTCD(2)' EQ 'F').UNBKFD     54000020
         AIF   ('&OPTCD(2)' EQ 'UNFOLD' OR '&OPTCD(2)' EQ 'U').UNBKUFD  54300020
.UNBLK   ANOP                           OPTCD = U                       54600000
         DC    X'40'                    DATA CHECK = UNBLOCK DATA CHECK 55200000
         AGO   .FCBPAR                                                  55300020
.UNBKFD  ANOP                                                           55400020
         DC    X'44'                    UNBLOCK D.C. & FOLD UCS(3211)   55500020
         AGO   .FCBPAR                                                  55600020
.UNBKUFD ANOP                                                           55700020
         DC    X'48'                    UNBLOCD D.C. + UNFOLD UCS 3211  55800020
         AGO   .FCBPAR                                                  55900020
.TSTFLD2 AIF   ('&OPTCD(2)' EQ 'FOLD' OR '&OPTCD(2)' EQ 'F').BKFLD      56000020
         AIF   ('&OPTCD(2)' EQ 'UNFOLD' OR '&OPTCD(2)' EQ 'U').BKUFLD   56100020
.BLOCK   ANOP                           OPTCD = B                       56400000
         DC    X'80'                    DATA CHECK = BLOCK DATA CHECK   57000000
         AGO   .FCBPAR                                                  57020020
.BKFLD   ANOP                                                           57040020
         DC    X'84'                    BLOCK D.C.& FOLD UCS(3211)      57060020
         AGO   .FCBPAR                                                  57080020
.BKUFLD  ANOP                                                           57100020
         DC    X'88'                    BLOCK D.C.& UNFOLD UCS(3211)    57120020
.FCBPAR  AIF   ('&FCB(1)' NE '').FCBDC                                  57140020
         DC    AL4(0)                   NO FCB ID SPECIFIED             57160020
         DC    X'00'                    NO FCB PARAMETER OPTION BITS    57180020
         AGO   .TSTMF                                                   57200020
.FCBDC   ANOP                                                           57220020
         DC    CL4'&FCB(1)'      FCB IMAGE ID                           57240020
         AIF   ('&FCB(2)' NE '').CKVFY  CK FOR VERIFY/ALIGN PARM        57260020
         DC    X'00'        NO FCB PARAMETER OPTION BITS SPECIFIED      57280020
         AGO   .TSTMF                                                   57300020
.CKVFY   AIF   ('&FCB(2)' EQ 'VERIFY' OR '&FCB(2)' EQ 'V').STVFY        57320020
         DC    X'01'                    ALIGN FORMS SPECIFIED           57340020
         AGO   .TSTMF                                                   57360020
.STVFY   ANOP                                                           57380020
         DC    X'80'                    VERIFY FCB SPECIFIED            57400020
.TSTMF   ANOP                                                           57600000
*                                                                       58800000
         AIF   ( &SW1 ).GOSTORE                   TEST IF DCB=(R)       59400000
         AGO   .TSTEXIT                                                 60000000
.GOSTORE ANOP                                                           60600000
         ST    &DCB,0(0,1)              STORE DCB ADDR IN PARM LIST     61200019
.TSTEXIT AIF   ('&MF(1)' EQ 'L').EXIT        TEST MF=L.IF YES EXIT      61800000
         SVC   81                       ISSUE SETPRT SVC                62400000
*                                                                       63000000
.EXIT    MEXIT                          EXIT                            63600000
.EFORMMF ANOP                                MF=E                       64200000
         AIF   ('&ANYNAME' EQ '').OVER                                  64800000
&ANYNAME EQU   *                                                        65400000
.OVER    ANOP                                                           66000000
*                                                                       66600000
         AIF   ('&MF(2)' EQ '' OR '&MF(2)' EQ '(1)').TSTUCS             67200000
         AIF   ('&MF(2)' EQ '').DONTEST                                 67800000
         AIF   ('&PAREN3' EQ '(' AND '&PAREN4' EQ ')').LOADREG          68400000
.DONTEST ANOP                                                           69000000
         LA    1,&MF(2)                 LOAD PARAMETER LIST ADDR        69600000
         AGO   .TSTUCS                                                  70200000
.LOADREG ANOP                                                           70800000
         LR    1,&MF(2)                 LOAD PARAMETER LIST ADDR        71400000
.TSTUCS  AIF   ('&UCS(1)' EQ '').TSTDCB      TEST IF UCS ID SPECIFIED   72000000
         B     *+8                                                      72600019
         DC    CL4'&UCS(1)'             CHARACTER SET IMAGE ID          73200000
         MVC   4(4,1),*-4               MOVE ID TO PARAMETER LIST       73800000
.TSTDCB  AIF   ('&DCB' EQ '').TSTFLD    TEST NO DCB                     74400000
         AIF   ( &SW1 ).DCBREG          TEST DCB=(R)                    75000000
         LA    0,&DCB                   LOAD DCB ADDR                   75600000
         ST    0,0(0,1)                 STORE DCB ADDR IN PARM LIST     76200019
         AGO   .TSTFLD                                                  76800000
.DCBREG  ANOP                                                           77400000
         ST    &DCB,0(0,1)              STORE DCB ADDR IN PARM LIST     78000019
.TSTFLD  AIF   ('&UCS(1)' EQ '').CHKOPCD                                78600000
         AIF   ('&UCS(2)' EQ '').NULFOLD                                79200000
         MVI   8(1),X'40'               LOAD MODE = FOLD                79800000
        AGO   .CHKVRFY                                                  80400000
.NULFOLD ANOP                                                           81000000
         MVI   8(1),X'00'              LOAD MODE = NO FOLD              81600000
.CHKVRFY AIF   ('&UCS(3)' EQ '').NULVRFY                                82200000
         MVI   9(1),X'10'               VERIFY = YES                    82800000
         AGO   .CHKOPCD                                                 83400000
.NULVRFY ANOP                                                           84000000
         MVI   9(1),X'00'              VERIFY = NO                      84600000
.CHKOPCD AIF   ('&OPTCD' EQ 'U').GOUNBLK                                85200000
         AIF   ('&OPTCD(1)' EQ 'U').GOUNBLK                             85500020
         AIF   ('&OPTCD' EQ '').CKFCBPM                                 85900020
         MVI   10(1),X'80'              DATA CHECK = BLOCK DATA CHECK   86400000
         AGO   .CKUCSPM                                                 87300020
.GOUNBLK ANOP                                                           87600000
         MVI   10(1),X'40'              DATA CHECK = UNBLOCK DATA CHECK 88200000
.CKUCSPM AIF   ('&OPTCD(2)' EQ '').CKFCBPM                              88230020
         AIF   ('&OPTCD(2)' EQ 'FOLD' OR '&OPTCD(2)' EQ 'F').UNFLDS     88260020
         OI    10(1),X'08'              SET FOLD BIT ON                 88290020
         AGO   .CKFCBPM                                                 88320020
.UNFLDS  ANOP                                                           88350020
         OI    10(1),X'04'              SET UNFOLD BIT ON               88380020
.CKFCBPM AIF   ('&FCB(1)' EQ '').GOGOSVC                                88410020
         B     *+8                                                      88440020
         DC    CL4'&FCB(1)'             FCB IMAGE ID.                   88470020
         MVC   11(4,1),*-4              MOVE IN FCB ID TO PARM LIST     88500020
         AIF   ('&FCB(2)' EQ '').NOVFYAL                                88530020
         AIF   ('&FCB(2)' EQ 'VERIFY' OR '&FCB(2)' EQ 'V').SETVFY       88560020
         MVI   15(1),X'01'              SET ALIGN FORMS BIT IN PARM LS  88590020
         AGO   .GOGOSVC                                                 88620020
.NOVFYAL ANOP                                                           88650020
         MVI   15(1),X'00'     SET TO INDICATE NO FCB OPTIONS SPEC      88680020
         AGO   .GOGOSVC                                                 88710020
.SETVFY  ANOP                                                           88740020
         MVI   15(1),X'80'              SET VERIFY BIT IN PARM LIST     88770020
.GOGOSVC ANOP                                                           88800000
*                                                                       89400000
         SVC   81                       ISSUE SETPRT SVC                90000000
*                                                                       90600000
         MEXIT                                                          91200000
.ERROR01 IHBERMAC 190                                                   91800000
         MEXIT                                                          92400000
.ERROR02 IHBERMAC 191                                                   93000000
         MEXIT                                                          93600000
.ERROR03 IHBERMAC 192                                                   94200000
         MEXIT                                                          94800000
.ERROR04 IHBERMAC 193                                                   95400000
         MEXIT                                                          96000000
.ERROR05 IHBERMAC 194                                                   96600000
         MEXIT                                                          96800020
.ERROR06 IHBERMAC 237                                            A45586 97000021
         MEND                                                           97200000
