         MACRO                                                          00020000
&NAME    SPAR  &GACB,&PRTY=,&MF=I                                       00040000
         LCLA  &LNGTH,&INC,&CNT         DEFINE WORK AREAS               00060000
         LCLC  &NAMGACB,&NAMLIST                                        00080000
         LCLC  &MNAME                                                   00100000
         LCLA  &TOTLNG,&PRTYMAC                                         00120000
         LCLC  &REGAD                                                   00140000
&CNT     SETA  0                        COUNT IS NUMBER OF GACBS        00160000
&INC     SETA  0                        NUMBER OF FULL WORDS            00180000
         AIF   (K'&PRTY EQ 0).MACSET    TEST FOR A PRIORITY             00200000
&PRTYMAC SETA  &PRTY                    IF SO, SET CONSTANT TO PRTY     00220000
         AGO   .OVSET                                                   00240000
.MACSET  ANOP                                                           00260000
&PRTYMAC SETA  0                        IF NOT, SET CONSTANT TO ZERO    00280000
.OVSET   AIF   (&PRTYMAC GT 127).ER2    TEST FOR INVALID PRIORITY       00300000
.NXTST1  AIF   ('&MF' EQ 'I').TYPESL    TEST FOR TYPE S AND             00320000
         AIF   ('&MF' EQ 'L').TYPESL    TYPE L.                         00340000
         AIF   (N'&MF NE 2).ER1         THEN A TEST IS MADE TO          00360000
         AIF   ('&MF(1)' NE 'E').ER1    CHECK PROPER MF=E FORMAT        00380000
         AIF   ('&MF(2)'(1,1) EQ '(').USEREG                            00400000
&NAME    LA    1,&MF(2)                 LOAD ADDRESS OF LIST            00420000
         AGO   .OVUSRG                  INTO REGISTER 1                 00440000
.USEREG  ANOP                           IF A REGISTER WAS SPECIFIED     00460000
&REGAD   SETC  '&MF(2)'(2,K'&MF(2)-2)   LOAD REGISTER INSTRUCTION       00480000
&NAME    LR    1,&REGAD                 LOAD PARAMETER LIST ADDRESS     00500000
.OVUSRG  AIF   (K'&PRTY NE 0).LPTY      CHECK FOR A PRIORITY            00520000
.NXTST2  AIF   (K'&GACB EQ 0).NOMOR     NO GACB IN MACRO TEST           00540000
.NEXT    AIF   (N'&GACB EQ &CNT).NOMOR    CHECK FOR END OF GACB LIST    00560000
&CNT     SETA  &CNT+1                   IF NOT, INCREMENT BOTH          00580000
&INC     SETA  &INC+4                   COUNT AND INCREMENT             00600000
         AIF   (K'&GACB(&CNT) EQ 0).NEXT    CHECK FOR BLANK ENTRY       00620000
         AIF   ('&GACB(&CNT)'(1,1) EQ '(').REGIN   CHECK FOR REG        00640000
&NAMGACB SETC  '&GACB(&CNT)'            LOAD GACB NAME INTO CONSTANT    00660000
         LA    15,&NAMGACB              LOAD GACB ADDRESS INTO          00680000
         ST    15,&INC.(1)              PARAMETER LIST                  00700000
         AGO   .NEXT                    GO TO NEXT GACB ADDRESS         00720000
.REGIN   AIF   ('&GACB(&CNT)'(K'&GACB(&CNT),1) NE ')').ER4              00740000
&NAMGACB SETC  '&GACB(&CNT)'(2,K'&GACB(&CNT)-2)   LOAD REG              00760000
         ST    &NAMGACB,&INC.(1)        STORE REG INTO PARAMETER LIST   00780000
         AGO   .NEXT                    GO TO NEXT GACB ADDRESS         00800000
.NOMOR   SVC   73                       LINK TO SPAR ROUTINE            00820000
         MEXIT                                                          00840000
.LPTY    ANOP                           IF PRIORITY,                    00860000
         MVI   0(1),&PRTYMAC            MOVE PRIORITY INTO LIST         00880000
         AGO   .NXTST2                                                  00900000
.TYPESL  AIF   (K'&GACB EQ 0).ER3       IF S OR L CHECK FOR GACBS       00920000
&LNGTH   SETA  N'&GACB+1                                                00940000
.PARFIL  AIF   (N'&MF NE 1).ER1         CHECK MF FORMAT                 00960000
         AIF   ('&MF' EQ 'I').TYPES     TEST FOR S FORMAT               00980000
         AIF   (K'&NAME EQ 0).WRNMES    CHECK FOR NAME FIELD            01000000
&MNAME   SETC  '&NAME'                  LOAD NAME INTO CONSTANT         01020000
.AFWRN   DS    0F                        ALIGN ON FULLWORD BOUNDARY     01040000
.GENPAR  ANOP                           GENERATE PARAMETER LIST         01060000
&MNAME   DC    AL1(&PRTYMAC)            PRIORITY                        01080000
         DC    AL1(0)                   RESERVED                        01100000
         DC    AL2(&LNGTH)              LENGTH OF PARAMETER LIST        01120000
         AIF   (K'&GACB EQ 0).JSTAL1    TEST FOR NO GACB ENTRY          01140000
.LOOP    ANOP                                                           01160000
&CNT     SETA  &CNT+1                   KEEP TRACK OF NUMBER OF GACBS   01180000
         AIF   (K'&GACB(&CNT) EQ 0).SETZER   TEST FOR BLANK ENTRY       01200000
         AIF   ('&GACB(&CNT)'(1,1) EQ '(').SETZER   REGISTER TEST       01220000
&NAMGACB SETC  '&GACB(&CNT)'            LOAD GACB NAME INTO CONSTANT    01240000
.PUTIN   DC    A(&NAMGACB)               GACB ADDRESS                   01260000
         AIF   (N'&GACB NE &CNT).LOOP      TEST FOR END OF GACBS        01280000
         MEXIT                                                          01300000
.SETZER  ANOP                                                           01320000
&NAMGACB SETC  '0'                      SET VALUE TO ZERO               01340000
         AGO   .PUTIN                                                   01360000
.JSTAL1  DC    A(0)                      GACB ADDRESS                   01380000
         MEXIT                                                          01400000
.TYPES   ANOP                           S TYPE MACRO                    01420000
&MNAME   SETC  'IHB&SYSNDX'             GET SYSTEM NAME                 01440000
&NAME    LA    1,&MNAME                 LOAD PARAMETER LIST ADDRESS     01460000
&TOTLNG  SETA  (&LNGTH+1)*4             GET LENGTH OF LIST AND BRANCH   01480000
         AIF   (K'&GACB EQ 0).NOSTR     TEST FOR NO STORE INSTRUCTION   01500000
.LST     AIF   (N'&GACB EQ &CNT).NOSTMR  TEST FOR END OF GACB LIST      01520000
&CNT     SETA  &CNT+1                   INCREMENT SUBLIST COUNT         01540000
&INC     SETA  &INC+4                                                   01560000
         AIF   (K'&GACB(&CNT) EQ 0).LST     CHECK FOR BLANK GACB ENTRY  01580000
         AIF   ('&GACB(&CNT)'(1,1) NE '(').LST   CHECK FOR NO REG       01600000
         AIF   ('&GACB(&CNT)'(K'&GACB(&CNT),1) NE ')').ER5  REG CHECK   01620000
&NAMGACB SETC  '&GACB(&CNT)'(2,K'&GACB(&CNT)-2)   GET REG NAME          01640000
         ST    &NAMGACB,&MNAME+&INC     STORE REG INTO PARAMETER LIST   01660000
         AGO   .LST                                                     01680000
.NOSTMR  ANOP                                                           01700000
&CNT     SETA  0                        RESET COUNT                     01720000
&INC     SETA  0                        AND INCREMENT.                  01740000
.NOSTR   SVC   73                        LINK TO SPAR ROUTINE           01760000
         CNOP  0,4                      ALIGN ON FULLWORD BOUNDARY      01780000
         B     *+&TOTLNG                BRANCH OVER PARAMETER LIST      01800000
         AGO   .GENPAR                  GO TO GENERATE PARAMETER LIST   01820000
.ER1     IHBERMAC 35,,&MF               ERROR IN MF FORMAT              01840000
         MEXIT                                                          01860000
.ER2     IHBERMAC 180,PRTY,0                                            01880000
&PRTYMAC SETA  0                                                        01900000
         AGO   .NXTST1                                                  01920000
.ER3     IHBERMAC 178,GACB,0            GACB NOT SPECIFIED              01940000
&LNGTH   SETA  2                                                        01960000
         AGO   .PARFIL                                                  01980000
.ER4     ANOP                                                           02000000
         IHBERMAC 147,REGISTER          INVALID REGISTER NOTATION       02020000
         AGO   .NEXT                                                    02040000
.ER5     ANOP                                                           02060000
         IHBERMAC 147,REGISTER          INVALID REGISTER NOTATION       02080000
         AGO   .LST                                                     02100000
.WRNMES  IHBERMAC 180,NAME,ZERO                                         02120000
         AGO   .AFWRN                                                   02140000
         MEND                                                           02160000
