         MACRO                                                          01000019
&NAME    TPEDIT &EDIT=EDITD,&RECFM=V,&ERROPT=IGNORE,&VERCHK=NOCHK,     X02000019
               &REPLACE=X'19',&BUFFER=NO,&MINLN=                        03000019
         LCLA  &A                                                       04000019
         LCLB  &SW(6),&B                                                05000019
         LCLC  &C                                                       06000019
&SW(1)   SETB  ('&EDIT' EQ 'EDITR')                                     07000019
         AIF   ('&EDIT' EQ 'EDITD' OR '&EDIT' EQ 'EDITR').EDITOK        08000019
&SW(1)   SETB  0                                                        09000019
         MNOTE 4,'EDIT=&EDIT INCORRECTLY SPECIFIED,DEFAULT ASSUMED'     10000019
.EDITOK  ANOP                                                           11000019
&SW(2)   SETB  ('&RECFM' EQ 'V')                                        12000019
         AIF   ('&RECFM' EQ 'V' OR '&RECFM' EQ 'U').RECFMOK             13000019
&SW(2)   SETB  0                                                        14000019
         MNOTE 4,'RECFM=&RECFM INCORRECTLY SPECIFIED,DEFAULT ASSUMED'   15000019
.RECFMOK ANOP                                                           16000019
&SW(3)   SETB  ('&ERROPT' EQ 'IGNORE')                                  17000019
&SW(4)   SETB  ('&VERCHK' EQ 'VOKCHK')                                  18000019
         AIF   ('&VERCHK' EQ 'NOCHK' OR ('&VERCHK' EQ 'VOKCHK' AND NOT X19000019
               &SW(3))).VOK                                             20000019
&SW(4)   SETB  0                                                        21000019
         MNOTE 4,'VERCHK=&VERCHK INCORRECTLY SPECIFIED,DEFAULT ASSUMED' 22000019
.VOK     ANOP                                                           23000019
&SW(5)   SETB  ('&BUFFER' EQ 'YES')                                     24000019
         AIF   ('&BUFFER' EQ 'NO' OR '&BUFFER' EQ 'YES').BUFOK          25000019
&SW(5)   SETB  0                                                        26000019
         MNOTE 4,'BUFFER=&BUFFER INCORRECTLY SPECIFIED,DEFAULT ASSUMED' 27000019
.BUFOK   AIF   (T'&REPLACE EQ 'N').TYPOK                                28000019
&SW(6)   SETB  1                                                        29000019
&C       SETC  T'&REPLACE                                               30000019
         MNOTE 4,'REPLACE=&REPLACE TYPE ATTRIBUTE=&C IMPROPER,         X31000019
               DEFAULT ASSUMED'                                         32000019
         AGO   .REPOK                                                   33000019
.TYPOK   ANOP                                                           34000019
&A       SETA  &REPLACE                                                 35000019
&B       SETB  (&A EQ 0 OR &A EQ 17 OR &A EQ 18 OR &A EQ 24 OR &A EQ   X36000019
               29 OR &A EQ 30 OR &A EQ 60 OR &A EQ 113 OR &A EQ 114)    37000019
         AIF   (&B).TEST                                                38000019
&B       SETB  (&A EQ 115 OR &A EQ 116 OR &A EQ 117 OR &A EQ 118 OR &A X39000019
               EQ 119 OR &A EQ 120)                                     40000019
.TEST    AIF   (NOT&B).REPOK                                            41000019
         MNOTE 4,'WARNING - REPLACE CHARACTER SPECIFIED IS ONE OF THE  X42000019
               SPECIAL PURPOSE 50-MDI CODES'                            43000019
.REPOK   AIF   (T'&MINLN EQ 'N' OR T'&MINLN EQ 'U').TYPMNOK             44000019
&C       SETC  T'&MINLN                                                 45000019
&A       SETA  0                                                        46000019
         MNOTE 4,'MINLN TYPE ATTRIBUTE=&C IMPROPER'                     47000019
         AGO   .BY1                                                     48000019
.TYPMNOK ANOP                                                           49000019
&A       SETA  &MINLN                                                   50000019
.BY1     ANOP                                                           51000019
         CNOP  0,4                                                      52000019
&NAME    BAL   0,IECA&SYSNDX                                            53000019
            DC B'&SW(1)&SW(2)&SW(4)&SW(5)&SW(3)000' MACRO OPTION IND    54000019
         AIF   (&SW(6)).DCX19                                           55000019
         DC    &REPLACE *          REPLACE CHARACTER                    56000019
*  IF THE ABOVE STATEMENT IS IN ERROR THE REPLACE OPERAND WAS           57000019
*   INCORRECTLY CODED                                                   58000019
         AGO   .X19                                                     59000019
.DCX19   DC    X'19' *             REPLACE CHARACTER                    60000019
.X19     DC    H'&A' *             MINIMUM RECORD LENGTH                61000019
         AIF   (&SW(3)).V0                                              62000019
         DC    V(&ERROPT)          USER ERROR EXIT ROUTINE              63000019
         AGO   .BY                                                      64000019
.V0      DC    A(0) *              NULL USER ERROR EXIT ROUTINE         65000019
.BY      ANOP                                                           66000019
IECC&SYSNDX DC V(IECTEDIT)         EDIT LOGIC MODULE                    67000019
IECA&SYSNDX L  15,IECC&SYSNDX                                           68000019
         BALR  14,15 *             LINK TO EDIT LOGIC                   69000019
         MEND                                                           70000019
