         MACRO                                                          00050021
         IEAAMS  &VALIDCK,&SPCHK,&LCSTORE,&SMFCORE,&ATTACH              00100021
         LCLB  &LCS,&SMF,&ATT                                           00150021
IGC010   CSECT                                                          00200021
         TITLE 'IEAAMS INTRODUCTION REL 21.7'                           00250021
* &VALIDCK AND &SPCHK PARMS ARE IGNORED,SINCE VALIDITY CHECKING IS      00300021
* ALWAYS DONE.  &VALIDCK AND &SPCHK WERE LEFT IN SO THAT  IEAAMS        00350021
* WOULD BE COMPATIBLE WITH SGIEA2MS.                                    00400021
&LCS     SETB  ('&LCSTORE' EQ 'Y')                                      00450021
&SMF     SETB  ('&SMFCORE' EQ '1')                                      00500021
&ATT     SETB  ('&ATTACH'  EQ 'Y')                                      00550021
*********************************************************************** 00600021
*              MFT  GETMAIN/FREEMAIN INTRODUCTORY COMMENTS            * 00650021
*              *******************************************            * 00700021
*                                                                     * 00750021
*                                                                     * 00800021
*                                                                     * 00850021
* STATUS:  CHANGE LEVEL 0                                             * 00900021
*                                                                     * 00950021
* FUNCTION:  IEAAMS CONTROLS THE ALLOCATION AND RELEASE OF ALL        * 01000021
*            DYNAMIC MAIN STORAGE AND OF THE SYSTEM QUEUE AREA .      * 01050021
*            IEAAMS IS A TYPE1 SVC ROUTINE WHICH GETS CONTROL AS      * 01100021
*            THE  RESULT OF SVC 4, SVC 5, OR SVC 10 BEING ISSUED.     * 01150021
         AIF   (NOT &SMF).NOSMFNX                                       01200021
*            IF SMF IS SYSGENED AND ACTIVE IN THE SYSTEM, IEAAMS      * 01250021
*            MAINTAINS THE LOW WATER MARK, THE HIGH WATER MARK,       * 01300021
*            AND THE MINIMUM DIFFERENCE IN 2K BLOCKS BETWEEN          * 01350021
*            HIGH AND LOW WATER MARKS.                                * 01400021
.NOSMFNX ANOP                                                           01450021
*                                                                     * 01500021
*                                                                     * 01550021
*            IEAAMS CONSISTS OF 3 ENTRY ROUTINES AND 5-7 SUBROUTINES  * 01600021
*            DEPENDING ON WHICH SYSGEN OPTIONS ARE PRESENT. THE       * 01650021
*            ENTRY ROUTINES ARE IGC010,IGC004 AND IGC005. THE         * 01700021
*            SUBROUTINES ARE SPGET,GETCORE,FREECORE,FQECHECK          * 01750021
*            ABTERM SETUP                                             * 01800021
         AIF   (NOT &ATT).NOATTFN                                       01850021
*            GQESRCH                                                  * 01900021
.NOATTFN ANOP                                                           01950021
         AIF   (NOT &SMF).NOSMFN2                                       02000021
*            SMFGET                                                     02050021
.NOSMFN2 ANOP                                                           02100021
*                                                                     * 02150021
*                  ***** ENTRY ROUTINES *****                         * 02200021
*                                                                     * 02250021
*            IGC010-FOR A FREEMAIN, BALR TO'SPGET'TO VALIDATE PARMS,  * 02300021
*                   AND GET ADDRESS OF THE BOUNDARY BOX. NEXT,        * 02350021
*                   BALR TO'FREECORE' AND EXIT.                       * 02400021
*                                                                     * 02450021
*                  -FOR A GETMAIN, BALR TO 'SPGET' TO VALIDATE        * 02500021
*                   PARMS, AND GET ADDRESS OF THE BOUNDARY BOX.       * 02550021
*                   NEXT, BALR TO 'GETCORE'. IF'GETCORE' WAS          * 02600021
*                   SUCCESSFUL, ZERO REG15 AND EXIT. IF 'GETCORE'     * 02650021
*                   WAS UNSUCCESSFUL, AND STEAL CORE CONDITION        * 02700021
*                   EXISTS,RETURN CODE=4 AND EXIT. IF NO STEAL        * 02750021
*                   CORE CONDITION EXISTS, GO TO'ABTERM SETUP'        * 02800021
*                   WITH 80A.                                         * 02850021
*                                                                     * 02900021
*            IGC004-BALR TO 'SPGET' TO VALIDATE PARMS AND GET THE     * 02950021
*                   ADDRESS OF THE BOUNDARY BOX.                      * 03000021
*                   BALR TO 'GETCORE'(FOR A VARIABLE REQUEST,USE      * 03050021
*                   MAXIMUM SIZE). IF GETCORE WAS SUCCESSFUL, PUT     * 03100021
*                   ADDRESS OF ALLOCATED CORE IN PARMLIST, ZERO       * 03150021
*                   RETURN CODE, AND EXIT.                            * 03200021
*                                                                     * 03250021
*                   IF GETCORE WAS UNSUCCESSFUL FOR A VARIABLE        * 03300021
*                   REQUEST AND THE LARGEST FQE IS GREATER THAN       * 03350021
*                   THE MINIMUM SIZE, BALR TO 'GETCORE' WITH LAR-     * 03400021
*                   GEST FQE SIZE. FOR A CONDITIONAL REQUEST,         * 03450021
*                   RETURN CODE=4 AND EXIT.                           * 03500021
*                   FOR AN UNCONDITIONAL'GETCORE' FAILURE AND         * 03550021
*                   A STEAL CORE CONDITION RETURN CODE=4 AND EXIT.    * 03600021
*                   IF THE UNCONDITIONAL REQUEST IS NOT FOR STEAL     * 03650021
*                   CORE, GO TO ABTERM SETUP WITH AN 804.             * 03700021
*                                                                     * 03750021
*            IGC005-BALR TO 'SPGET' TO VALIDATE PARMS AND GET         * 03800021
*                   ADDR OF THE BOUNDARY BOX. NEXT, BALR TO           * 03850021
*                   'FREECORE' AND EXIT.                              * 03900021
*                                                                     * 03950021
*                           ***** SUBROUTINES *****                   * 04000021
*                                                                     * 04050021
*            SPGET- CALLED BY IGC004,IGC005,AND IGC010                * 04100021
*                   SPGET VALIDATES THE PARAMETERS AND GETS THE       * 04150021
         AIF   (NOT &LCS).NOLCSP                                        04200021
*                   ADDR OF THE CORRECT HIERARCHY BOUNDARY BOX        * 04250021
         AGO   .SPGEND                                                  04300021
.NOLCSP  ANOP                                                           04350021
*                   ADDR OF THE JOBSTEP BOUNDARY BOX                  * 04400021
.SPGEND  ANOP                                                           04450021
*                                                                     * 04500021
*            GETCORE-CALLED BY IGC004,IGC010-GETMAIN                  * 04550021
*                   SEARCH DOWN THE FQE CHAIN FOR AN FQE TO SATISFY   * 04600021
*                   THE GETMAIN REQUEST. VALIDATE EACH FQE BY BALRS   * 04650021
*                   TO THE 'FQECHECK' SUBROUTINE. FOR A HIGH CORE     * 04700021
*                   REQUEST, USE THE 1ST FQE FOUND WHICH IS LARGE     * 04750021
*                   ENOUGH. FOR A LOW CORE REQUEST, SEARCH DOWN       * 04800021
*                   THE ENTIRE FQE CHAIN AND USE THE LOWEST FQE       * 04850021
*                   WHICH SATISFIES THE REQUEST. IF NO FQE IS         * 04900021
*                   LARGE ENOUGH, RETURN'NOT FOUND' TO CALLER.        * 04950021
*                   OTHERWISE, UPDATE THE FQE CHAIN TO ACCOUNT FOR    * 05000021
*                   THE ALLOCATED CORE.                               * 05050021
         AIF   (NOT &ATT).GTNOAT                                        05100021
*                   NEXT, IF THE REQUESTING TCB IS A SUBTASK, BUILD   * 05150021
*                   A GQE AND QUEUE IT'PUSH-DOWN' FROM THE SUBTASK    * 05200021
*                   DUMMY BOUNDARY BOX.                               * 05250021
.GTNOAT  ANOP                                                           05300021
         AIF   (NOT &SMF).GTNOSM                                        05350021
*                   BALR TO SMFGET FOR SMF CALCULATING.               * 05400021
.GTNOSM  ANOP                                                           05450021
*                   RETURN TO CALLER                                  * 05500021
*                                                                     * 05550021
*            FREECORE-CALLED BY IGC005,IGC010-FREEMAIN                * 05600021
         AIF   (NOT &ATT).NOFRAT                                        05650021
*                   WHEN A SUBTASK REQUESTS FREEING OF A SUBPOOL      * 05700021
*                   OTHER THAN SUBPOOL 240, FIND THE GQE WHICH        * 05750021
*                   DESCRIBES THE AREA TO FREE . THE GQE CHAIN        * 05800021
*                   OF THE REQUESTING SUBTASK IS 1ST SEARCHED VIA A   * 05850021
*                   BALR TO 'GQESRCH' SUBROUTINE. IF THE CORRECT      * 05900021
*                   GQE IS NOT FOUND IN THE REQUESTING TCB'S CHAIN,   * 05950021
*                   BALR TO 'GQESRCH' FOR EACH TCB IN THE JOBSTEP     * 06000021
*                   TCB FAMILY UNTIL THE GQE IS FOUND. IF THE GQE     * 06050021
*                   IS NOT FOUND (THE GETMAIN MAY HAVE BEEN ISSUED    * 06100021
*                   BY THE JOBSTEP TCB) BEGIN THE FQE SEARCH.IF       * 06150021
*                   THE GQE IS FOUND, UPDATE THE GQE CHAIN, AND       * 06200021
*                   BEGIN THE FQE SEARCH.                             * 06250021
*                                                                     * 06300021
.NOFRAT  ANOP                                                           06350021
*                   FREECORE SEARCHES DOWN THE FQE CHAIN FOR THE      * 06400021
*                   FQES ON EITHER SIDE OF THE AREA TO BE FREED.      * 06450021
*                   EACH FQE IS VALIDATED VIA BALR TO 'FQECHECK'      * 06500021
*                   ADJUST THE FQE CHAIN TO INCLUDE THE AREA          * 06550021
*                   BEING FREED AND RETURN TO CALLER.                 * 06600021
*                                                                     * 06650021
*            FQECHECK-CALLED BY GETCORE OR FREECORE                   * 06700021
*                  VALIDITY CHECK THE FQE (FQE ADDRESS IN REG7) BY    * 06750021
*                  ASSURING THAT THE FOLLOWING IS TRUE:               * 06800021
*                  1. THE HIGH ORDER BYTES OF THE FQE FORWARD PTR     * 06850021
*                     AND SIZE FIELDS ARE BOTH=0                      * 06900021
*                  2. THE FQE FORWARD POINTER AND THE FQE SIZE ARE    * 06950021
*                     BOTH MULTIPLES OF 8.                            * 07000021
*                  3. ADDRESS + SIZE OF FQE IS LESS THAN ADDRESS      * 07050021
*                     OF PREVIOUS FQE                                 * 07100021
*                  4. ADDRESS OF NEXT FQE IS LESS THAN ADDRESS OF     * 07150021
*                     THIS FQE                                        * 07200021
*                  5. FQE ADDRESS IS WITHIN BOUNDS OF BOUNDARY BOX    * 07250021
*                                                                     * 07300021
*                  IF ANY OF THE ABOVE CONDITIONS FAIL, ZERO THE      * 07350021
*                  FORWARD PTR IN THE PREVIOUS FQE TO END THE CHAIN   * 07400021
*                  BEFORE THE BAD FQE AND GO TO'ABTERM SETUP' FOR     * 07450021
*                  A 60X-2 ABEND. OTHERWISE, RETURN TO CALLER.        * 07500021
*                                                                     * 07550021
*            ABTERM SETUP-PUT PROBLEM DETERMINATION INFORMATION       * 07600021
*                  INTO A WORK BUFFER. IF AN ENTRY IS AVAILABLE       * 07650021
*                  IN IEAQMSGS, COPY THE WORK BUFFER INTO THE         * 07700021
*                  IEAQMSGS ENTRY. SET UP THE REGS FOR ABTERM         * 07750021
*                  AND GO TO ABTERM                                   * 07800021
*                                                                     * 07850021
         AIF   (NOT &ATT).NOGQ                                        * 07900021
*            GQESRCH-CALLED BY FREECORE                               * 07950021
*                   SEARCH DOWN THE CHAIN OF GQES OF THE TCB WHICH    * 08000021
*                   IS PASSED IN REG7 FOR THE GQE DESCRIBING THE      * 08050021
*                   AREA TO BE FREED. IF NO GQE IN THE CHAIN MATCHES  * 08100021
*                   THE AREA TO FREE, RETURN TO 'FREECORE' TO HAVE    * 08150021
*                   THE NEXT TCB IN THE JOBSTEP LOADED.               * 08200021
*                   IF THE GQE IS FOUND, ADJUST THE GQE CHAIN TO      * 08250021
*                   DELETE THE AREA FREED AND RETURN TO 'FREECORE'    * 08300021
*                   FOR FQE PROCESSING                                * 08350021
*                                                                     * 08400021
.NOGQ    ANOP                                                           08450021
         AIF   (NOT &SMF).NOSMF                                         08500021
*            SMFGET-CALLED BY GETCORE                                 * 08550021
*                   UPDATE THE TIMING CONTROL TABLE(TCT) STORAGE      * 08600021
*                   TABLES TO REPRESENT THE AMOUNT OF CORE USED       * 08650021
*                   BY NON-SYSTEM TASKS.                              * 08700021
*                   UPDATE THE HIGH WATER MARK WITH THE ADDRESS OF    * 08750021
*                   THE ALLOCATED AREA IF THE ADDRESS OF THE END      * 08800021
*                   OF THE ALLOCATED AREA= THE HIGH WATER MARK.       * 08850021
*                   UPDATE THE LOW WATER MARK WITH THE ADDRESS OF     * 08900021
*                   THE END OF THE ALLOCATED AREA IF THE ADDRESS      * 08950021
*                   OF THE ALLOCATED AREA= THE LOW WATER MARK.        * 09000021
*                   UPDATE THE TCTMINC  AS THE DIFFERENCE BETWEEN     * 09050021
*                   THE LOW AND HIGH MARKS BECOMES SMALLER.           * 09100021
*                                                                     * 09150021
.NOSMF   ANOP                                                           09200021
*                                                                     * 09250021
* ENTRY POINTS:                                                       * 09300021
*            IGC010- R-TYPE GETMAIN AND FREEMAIN ENTRY POINT.         * 09350021
*                    GIVEN CONTROL BY SVC FIRST LEVEL INTERRUPT       * 09400021
*                    HANDLER (FLIH) VIA LPSW IN ORDER TO PERFORM      * 09450021
*                    THE GETMAIN OR FREEMAIN FUNCTION REQUESTED       * 09500021
*                    BY THE CALLER. AN SVC 10 IS ISSUED BY THE        * 09550021
*                    CALLER.                                          * 09600021
*                                                                     * 09650021
*            IGC004- S-TYPE GETMAIN ENTRY POINT. GIVEN CONTROL BY     * 09700021
*                    SVC FLIH VIA LPSW IN ORDER TO PERFORM THE        * 09750021
*                    GETMAIN FUNCTION REQUESTED BY THE CALLER. AN     * 09800021
*                    SVC 4 IS ISSUED BY THE CALLER.                   * 09850021
*                                                                     * 09900021
*            IGC005- S-TYPE FREEMAIN ENTRY POINT. GIVEN CONTROL BY    * 09950021
*                    SVC FLIH VIA LPSW IN ORDER TO PERFORM THE        * 10000021
*                    FREEMAIN FUNCTION REQUESTED BY THE CALLER. AN    * 10050021
*                    SVC 5 IS ISSUED BY THE CALLER.                   * 10100021
*                                                                     * 10150021
* INPUT:                                                              * 10200021
*            REGISTERS 0 AND 1, DEPEND ON WHICH SVC WAS ISSUED.       * 10250021
*            SVC 10--REGISTER 0 CONTAINS THE NUMBER OF THE SUBPOOL    * 10300021
*            IN THE HIGH ORDER BYTE AND THE NUMBER OF BYTES REQUESTED * 10350021
*            IN THE LOW ORDER THREE BYTES. REGISTER 1 CONTAINS A      * 10400021
*            NEGATIVE VALUE IF THE REQUEST IS FOR GETMAIN  OR         * 10450021
*            FOR FREEMAIN, THE ADDRESS OF THE AREA TO FREE.           * 10500021
*                                                                     * 10550021
*            SVC 4 AND SVC 5-REGISTER 1 CONTAINS THE ADDRESS OF THE   * 10600021
*            PARAMETER LIST AND REGISTER 0 CONTAINS THE CONTENTS AT   * 10650021
*            THE TIME THE SVC WAS ISSUED.                             * 10700021
*                                                                     * 10750021
*            REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.              * 10800021
*            REGISTER 4 CONTAINS THE ADDRESS OF THE TCB.              * 10850021
*            REGISTER 5 CONTAINS THE ADDRESS OF THE RB.               * 10900021
*            REGISTER 14 CONTAINS THE ADDRESS OF TYPE 1 SVC EXIT      * 10950021
*            HANDLER.                                                 * 11000021
*            REGISTERS 2,6-13,AND 15 CONTAIN THE CONTENTS AT THE      * 11050021
*            TIME THE SVC WAS ISSUED.                                 * 11100021
*                                                                     * 11150021
* OUTPUT:                                                             * 11200021
*            REGISTERS 3-5,AND 14 REMAIN UNCHANGED.                   * 11250021
*            FOR SVC 10-GETMAIN,REG 1 CONTAINS THE ADDRESS OF THE     * 11300021
*            ALLOCATED CORE.                                          * 11350021
*            FOR SVC 4  THE ADDRESS OF THE ALLOCATED CORE IS          * 11400021
*            PUT AT THE ADDRESS POINTED TO BY THE SECOND WORD         * 11450021
*            IN THE PARMLIST.                                         * 11500021
*                                                                     * 11550021
*            FOR SUCCESSFUL GETMAINS, REG15 CONTAINS RETURN CODE=0.   * 11600021
*            FOR UNSUCCESSFUL GETMAINS WHICH ARE EITHER CONDITIONAL   * 11650021
*            OR 'STEAL CORE' CONDITIONS, REG15 CONTAINS A RETURN      * 11700021
*            CODE= 4.                                                 * 11750021
*                                                                     * 11800021
* EXTERNAL REFERENCES:                                                * 11850021
*            1. ABENDSUC-LABEL IN IEAATA00 FOR STEAL CORE TESTS       * 11900021
*            2. IEACVT -CVT ADDRESS                                   * 11950021
*            3. IEA04B00- ABTERM ADDRESS                              * 12000021
*            4. IEAQMSGS- ADDR PROBLEM DETERMINATION BUFFER           * 12050021
*            5. IEEMSER- ADDR MASTER SCHEDULER RESIDENT AREA          * 12100021
*                        CONTAINING ADDRESS OF SQA BOUNDARY BOX       * 12150021
*            6. SVRBPOOL- ADDRESS OF THE 1ST SVRB IN THE STEAL        * 12200021
*                        CORE SVRB POOL.                              * 12250021
*                                                                     * 12300021
* EXITS,NORMAL: BRANCH ON REGISTER 14 TO THE TYPE 1 SVC EXIT          * 12350021
*            HANDLER.                                                   12400021
*                                                                       12450021
* EXITS,ERROR: BRANCH TO ABTERM TO CAUSE THE ISSUING TASK TO BE         12500021
*            TERMINATED. REGISTER 0 CONTAINS THE TCB ADDR, REGISTER 1   12550021
*            THE COMPLETION CODE , REG12 THE CVT ADDRESS AND            12600021
*            REGISTER 15 THE ADDRESS OF ABTERM.                       * 12650021
*            PROBLEM DETERMINATION INFORMATION FOR EACH ABEND CODE    * 12700021
*            IS LOCATED AT THE TEMPORARY WORK BUFFER--PDBUFFER.       * 12750021
*            THE ABEND CODES ARE AS FOLLOWS:                            12800021
*                   604-1  PARAMETER OUTSIDE OF USER'S CORE           * 12850021
*                   605-1                                             * 12900021
*                                                                     * 12950021
*                   604-2  INVALID FQE                                * 13000021
*                   605-2                                             * 13050021
*                   60A-2                                             * 13100021
*                                                                     * 13150021
         AIF   (NOT &ATT).NO60X3                                        13200021
*                   604-3  INVALID GQE                                * 13250021
*                   605-3                                             * 13300021
*                   60A-3                                             * 13350021
*                                                                     * 13400021
.NO60X3  ANOP                                                         * 13450021
*                   704    LIST TYPE REQUEST (INVALID IN MFT)         * 13500021
*                   705                                               * 13550021
*                                                                     * 13600021
*                   804-1  MAIN STORAGE NOT AVAILABLE                 * 13650021
*                   80A-1                                             * 13700021
*                                                                     * 13750021
*                   804-2  ZERO OR NEGATIVE SIZE SPECIFIED            * 13800021
*                   80A-2                                             * 13850021
*                                                                     * 13900021
*                   905-1  AREA TO FREE NOT ON DOUBLEWORD BDY         * 13950021
*                   90A-1                                             * 14000021
*                   905-2  AREA TO FREE NOT IN USER'S BBOX            * 14050021
*                   90A-2                                             * 14100021
*                   905-3  AREA TO FREE GOES BEYOND GQE               * 14150021
*                   90A-3                                             * 14200021
*                                                                     * 14250021
*                   A05    AREA TO FREE OVERLAPSE FQE                 * 14300021
*                   A0A                                               * 14350021
*                                                                     * 14400021
*                   B04    INVALID SUBPOOL ID                         * 14450021
*                   B05                                               * 14500021
*                   B0A                                               * 14550021
*                                                                     * 14600021
* TABLES/WORK AREAS:                                                  * 14650021
*            1.'DATAWORK',AT THE BEGINNING OF IEAAMS' CONSTANT AREA,  * 14700021
*              IS A WORK AREA CONTAINING SWITCHES SUCH AS:            * 14750021
*              LOW CORE GETMAIN REQUEST SWITCH                        * 14800021
         AIF   (NOT &ATT).NOGQSW                                        14850021
*              GQE SWITCH FOR SUBTASK REQUESTORS                      * 14900021
.NOGQSW  ANOP                                                           14950021
         AIF   (NOT &LCS).NOLCSWT                                       15000021
*              LCS SWITCH FOR HIERARCHY=1 REQUEST                     * 15050021
*              DUMMY LCS SWITCH IF THE JOBSTEP DOESN'T HAVE THE       * 15100021
*              HIERARCH REQUESTED                                     * 15150021
.NOLCSWT ANOP                                                           15200021
*              DATAWORK ALSO CONTAINS SAVE AREAS FOR THE ROUNDED      * 15250021
*              SIZE, LARGEST FQE SIZE, ETC.                           * 15300021
*              DATAWORK IS ZEROD AT ENTRY TO IGC004,IGC005,IGC010.    * 15350021
*                                                                     * 15400021
*            2.'PDBUFFER',PROBLEM DETERMINATION TEMPORARY BUFFER,     * 15450021
*              CONTAINS THE ABEND INFORMATION. PDBUFFER IS            * 15500021
*              COPIED OVER TO THE IEAQMSGS BUFFER IF AN ENTRY         * 15550021
*              BUFFER IS AVAILABLE.                                   * 15600021
*                                                                     * 15650021
* CONTROL BLOCKS REFERENCED:                                          * 15700021
*            BOUNDARY BOX                                             * 15750021
*            FQE                                                      * 15800021
         AIF   (NOT &ATT).NOGQES                                        15850021
*            GQE                                                      * 15900021
.NOGQES  ANOP                                                           15950021
*            RB                                                       * 16000021
*            TCB                                                      * 16050021
         AIF   (NOT &SMF).NOTCT                                         16100021
*            TCT                                                      * 16150021
.NOTCT   ANOP                                                           16200021
*                                                                     * 16250021
* ATTRIBUTES: RE-USABLE, OPERATES IN SUPERVISOR STATE,RESIDENT,       * 16300021
*            DISABLED FOR ALL MASKABLE INTERRUPTS EXCEPT MACHINE      * 16350021
*            CHECK.TYPE 1 SVC ROUTINE.                                * 16400021
*                                                                     * 16450021
* NOTES:                                                              * 16500021
*              ..... PARAMETER LIST FORMAT .....                      * 16550021
*                                                                     * 16600021
*            ************************************************         * 16650021
*            * LENGTH REQUESTED IF SINGLE AREA REQUEST OR   *         * 16700021
*            * ADDR OF LIST OF LENGHTS FOR VARIABLE REQUEST *         * 16750021
*            ************************************************         * 16800021
         AIF   (NOT &LCS).NOLCPAR                                       16850021
*            * HIERARCHY * ADDRESS OF AREA LIST FOR ADDRESS *         * 16900021
*            *  IDENT   * OF ALLOCATED AREA INFO            *         * 16950021
         AGO   .PARMFLG                                                 17000021
.NOLCPAR ANOP                                                           17050021
*            * ADDRESS OF AREA LIST FOR THE ADDRESS OF THE  *         * 17100021
*            * ALLOCATED AREA INFORMATION.                  *         * 17150021
.PARMFLG ANOP                                                           17200021
*            ************************************************         * 17250021
*            * REQUEST  * SUBPOOL  *                        *         * 17300021
*            *  TYPE    *   ID     *                        *         * 17350021
*            ************************************************         * 17400021
*                                                                     * 17450021
*            REQUEST TYPES                                            * 17500021
*              X'00' - UNCONDITIONAL SINGLE ELEMENT REQUEST           * 17550021
*              X'20' - CONDITIONAL   SINGLE ELEMENT REQUEST           * 17600021
*              X'C0' - UNCONDITIONAL VARIABLE REQUEST                 * 17650021
*              X'E0' - CONDITIONAL   VARIABLE REQUEST                 * 17700021
*                                                                     * 17750021
*                                                                     * 17800021
*                                                                     * 17850021
*                 ..... LIST FORMATS .....                            * 17900021
*                                                                     * 17950021
*            SINGLE ELEMENT REQUEST                                   * 18000021
*                                                                     * 18050021
*              AREA LIST                                              * 18100021
*                   **********************************                * 18150021
*                   *    * ADDRESS OF AREA ALLOCATED *                * 18200021
*                   **********************************                * 18250021
*                                                                     * 18300021
*                                                                     * 18350021
*            VARIABLE REQUEST                                         * 18400021
*                                                                     * 18450021
*              LENGTH LIST                                            * 18500021
*                   **********************************                * 18550021
*                   * 0 * MINIMUM LENGTH REQUESTED   *                * 18600021
*                   **********************************                * 18650021
*                   * 0 * MAXIMUM LENGTH REQUESTED   *                * 18700021
*                   **********************************                * 18750021
*                                                                     * 18800021
*              AREA LIST                                              * 18850021
*                   **********************************                * 18900021
*                   *    * ADDRESS OF AREA ALLOCATED *                * 18950021
*                   **********************************                * 19000021
*                   *    * ACTUAL LENGTH ALLOCATED   *                * 19050021
*                   **********************************                * 19100021
*                                                                     * 19150021
*********************************************************************** 19200021
         EJECT                                                          19250021
** REGISTER EQUATES **                                                  19300021
         SPACE 2                                                        19350021
*REGS USED BY ALL ROUTINES *                                            19400021
REG0     EQU   0              PARM REG                                  19450021
REG1     EQU   1              PARM REG                                  19500021
REG3     EQU   3              CURRENTLY NOT BEING USED                  19550021
REG4     EQU   4              TCB REG                                   19600021
REG14    EQU   14             SVC TYPE 1 EXIT ADDR                      19650021
REG15    EQU   15                                                       19700021
RETREG   EQU   2              BRANCH AND LINK REG1                      19750021
RETREG2  EQU   5              BRANCH AND LINK REG2                      19800021
BASEREG  EQU   12             BASE REG                                  19850021
BBOXREG   EQU   6              ADDR JOBSTEP BBOX                        19900021
CURFQREG EQU   7 .             ADDR CURRENT FQE                         19950021
LSTFQREG EQU   9 .             ADDR LAST FQE                            20000021
LOWBBREG EQU   8 .             BBOX LOWEST ADDR                         20050021
NXTFQREG EQU   11 .            ADDR NEXT FQE                            20100021
WORKREGA EQU   10 .            WORKREG                                  20150021
*SPGET REGISTERS*                                                       20200021
SPLOW    EQU   7             BBOX LOWEST ADDR                           20250021
SPHI     EQU   8             BBOX HIGHEST ADDR                          20300021
SPWORK2  EQU   9             WORK REG                                   20350021
*GETCORE REGISTERS*                                                     20400021
GTWORK2  EQU   RETREG         WORK REG                                  20450021
GETADDR  EQU   13 .          ADDR ALLOCATED AREA                        20500021
*FREECORE REGISTERS*                                                    20550021
FRCURTCB EQU   7                    ADDR CURRENT TCB                    20600021
FRLSTCB EQU   9                                                         20650021
FREESIZE EQU   REG15          LENGTH OF AREA TO BE FREED                20700021
FREEADDR EQU   13                                                       20750021
*ABEND REGISTERS*                                                       20800021
ABWORK1  EQU   7 .           WORK REG                                   20850021
ABWORK2  EQU   9     WRK REG                                   @SA66514 20870021
ABPDBUF  EQU   8 .           ADDR IEAQMSGS ENTRY                        20900021
ABPDEND  EQU   9 .           ADDR END FO IEAQMSGS                       20950021
*SMF REGISTERS*                                                         21000021
SMJSTCB  EQU   11       .     JOB STEP TCB                          SMF 21050021
SMTCT    EQU   9        .     TCT REG                               SMF 21100021
SMFSZ       EQU   10 .         LARGEST FQE SIZE                     SMF 21150021
SMWORK1  EQU   8        .      WORK REG                             SMF 21200021
SMFQE    EQU   7         .     ADDR FQE                             SMF 21250021
*GQESRCH REGISTERS*                                                     21300021
GQCURTCB EQU   7        .    ADDR CURRENT TCB                       ATT 21350021
GQEREG EQU   11      .      ADDR GQE                                ATT 21400021
GQDUMBBX EQU   8        .     ADDR DUMMY BBOX                       ATT 21450021
GQWORK1  EQU   10      .     WORK REG                               ATT 21500021
GQWORK2  EQU   7             WORK REG                               ATT 21550021
GQWORK3  EQU   8              WORK REG                              ATT 21600021
         EJECT                                                          21650021
***  SUBPOOL IDS  ***                                                   21700021
SP128    EQU   128            VALID SUBPOOL ID                          21750021
SP240    EQU   240            VALID SUBPOOL ID                          21800021
SP243    EQU   243            VALID SUBPOOL ID                          21850021
SP244    EQU   244            VALID SUBPOOL ID                          21900021
SP245    EQU   245            VALID SUBPOOL ID                          21950021
SP249    EQU   249            VALID SUBPOOL ID                          22000021
SP255    EQU   255            VALID SUBPOOL ID                          22050021
         SPACE 2                                                        22100021
***  TCB DISPLACEMENTS  ***                                             22150021
TCBFTJST EQU   44             JOB STEP TCB DISPLACEMT                   22200021
TCBMSS   EQU   24             BBOX TCB DISPLACEMT                       22250021
TCBFLGS  EQU   29 .                TCBFLGS DISPLACEMT                   22300021
TCBNTC   EQU   128            SISTER TCB DISPLACEMT                     22350021
TCBLTC   EQU   136            DAUGHTER TCB DISPLACEMT                   22400021
TCBOTC   EQU   132            MOTHER TCB DISPLACEMT                     22450021
TCBTCT   EQU   164 .          DISPLACMT TIMING CONTROL TABLE IN TCB SMF 22500021
TCBTCTGF EQU   164 .          DISPLCMT OF SMF CALCULATION FLAG      SMF 22510021
SMFCALC EQU   X'80' .        IF BIT=1,GETMAIN CALCULATES SMF INFO   SMFX22520021
                             IF BIT=0 DON'T CALCULATE JOB SCHED CORESMF 22530021
         SPACE 2                                                        22550021
***  TCT DISPLACEMENTS  ***                                             22600021
TCTLWM   EQU   0 .            HIGH WATER MARK IN PROCESSOR STORAGE  SMF 22650021
TCTHWM   EQU   4 .            LOW  WATER MARK IN PROCESSOR STORAGE  SMF 22700021
TCTMINC  EQU   8 .            MINIMUM DIFF BETWEEN TCTLWM & TCTHWM  SMF 22750021
TCTCRTBL EQU   8 .            ADDR OF HOT STORAGE TABLE             SMF 22800021
         SPACE 2                                                        22850021
***  BOUNDARY BOX DISPLACEMENTS  ***                                    22900021
BBLCS    EQU   0                   LCS FLAG FOR 1ST BBOY                22950021
BBFQE    EQU   0                   ADDR FIRST FQE                       23000021
BBHI     EQU   8                   TOP STORAGE ADDRESS                  23050021
BBLOW    EQU   4                   BOTTOM STORAGE ADDRESS               23100021
LOWADDR0 EQU    4 .              LOWEST HIER=0 ADDR                     23150021
LOWADDR1 EQU    16 .               LOWEST HIER=0 ADDR                   23200021
HIADDR0  EQU   8             HIGHEST HIERARCHY=0 ADDR DISPLACEMT        23250021
HIADDR1  EQU   20            HIGHEST HIERARCHY=1 ADDR DISPLACEMT    LCS 23300021
         SPACE 2                                                        23350021
***  OTHER EQUATES  ***                                                 23400021
FQELNGTH EQU   4             FQE LENGTH DISPLACEMT                      23450021
FQEPTR   EQU   0             FQE POINTER DISPLACEMT                     23500021
GQESIZE  EQU   4             GQE LENGTH DISPLACEMT                  ATT 23550021
GQEPTR   EQU   0             GQE POINTER DISPLACEMT                 ATT 23600021
GQEBBOX  EQU   0             GQEPTR IN DUMMY BBOX DISPLACEMT        ATT 23650021
SVCOPSW  EQU   32  .         BEGIN OF SVC OPSW                          23700021
SVC10    EQU   X'0A' .        REGMAIN SVC                               23750021
SVC5     EQU   X'05' .        FREEMAIN SVC                              23800021
SVC4     EQU   X'04'          GETMAIN SVC                               23850021
BUFLNG   EQU   X'20'          LENGTH OF IEAQMSGS ENTRY           A49808 23900021
RBNAME   EQU   0 .                 RB PROGRAM NAME                      23950021
KEYF     EQU   X'F0'          ZERO PROTECT KEY MASK                     24000021
SUPVSTAT EQU   X'01'          SUPERVISOR MASK IN PSW+8                  24050021
MSBBOX   EQU   X'64' .      DISP OF SQA BBOX ADDR IN MS RESI AREA       24100021
STEALUSR EQU   X'1B0'  . DISPLCMT OF TCB IN STEAL CORE SVRB POOL        24150021
SVRB3    EQU   X'120' .  DISPLCMT 3RD SVRB IN SVRB POOL                 24200021
RBSIZE   EQU   9 .           RBSIZE DISPLACEMENT                        24250021
ZERO     EQU   0              DISPLACEMENT OR MASK                      24300021
ONE      EQU   1              ONE                                       24350021
TWO      EQU   2              DISPLACEMENT OR MASK                      24400021
THREE    EQU   3             DISPLACEMENT 3                             24450021
FOUR     EQU   4              DISPLACEMENT OR MASK                      24500021
SEVEN    EQU   7              DISPLACEMENT OR MASK                      24550021
EIGHT    EQU   8              DISPLACEMENT OR MASK                      24600021
ELEVEN   EQU   11 .          DISPLACEMENT OR MASK                       24650021
TWELVE   EQU   12             DISPLACEMENT OR MASK                      24700021
SIXTN    EQU   16      .      DISPLACEMENT OR MASK                      24750021
         TITLE 'IGC010 ENTRY ROUTINE'                                   24800021
         ENTRY IGC004,IGC005                                            24850021
         ENTRY GETCORE,SPGET,FQECHECK,FREECORE,PDBUFFER                 24900021
         AIF (NOT &ATT).NOGQEN                                          24950021
         ENTRY GQESRCH                                                  25000021
.NOGQEN  ANOP                                                           25050021
         AIF (NOT &SMF).NOSMFEN                                         25100021
         ENTRY SMFGET                                                   25150021
.NOSMFEN ANOP                                                           25200021
         AGO .AMS1                                                      25250021
*/*IGC010: CHART REGMAIN SVC10 */                                       25300021
*/*IGC010: E IGC010 */                                                  25350021
*/*    P  ZERO DATAWORK AREA */                                         25400021
*/*    D  (YES,RMGETM,NO,) GETMAIN REQUEST? */                          25450021
*/*    D  (YES,%RM1,NO,) IS ADDR OF AREA TO FREE ON DBL WORD BDY*/      25500021
*/*    P  PUT 90X-1 INFO IN BUFFER*/                                    25550021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           25600021
*/*%RM1:    S  SPGET:VALIDITY CK PARMS, GET BBOX */                     25650021
*/*    S  FREECORE:GO TO FREE CORE */                                   25700021
*/*    R  GO TO TYPE 1 EXIT */                                          25750021
*/*RMGETM:   D (YES,,NO,RMGOVAL) IS REQUEST HIER=1 */                   25800021
*/*    P  SET LCS SWITCH ON */                                          25850021
*/*RMGOVAL:  S  SPGET:VALIDITY CK PARMS, GET BBOX */                    25900021
*/*    S  GETCORE:GO GET CORE */                                        25950021
*/*    D  (YES,,NO,ABNOCORE)  WAS GETCORE SUCCESSFUL */                 26000021
*/*    P  RETURN CODE = 0*/                                             26050021
*/*    R  GO TO TYPE 1 SVC EXIT*/                                       26100021
*/*ABNOCORE:  D (YES,%ABSTL,NO,) IS REQUESTOR ABEND OR ABTERM*/         26150021
*/*    D  (YES,,NO,%ABTSTE) IS REQUESTOR SVC FLIH*/                     26200021
*/*%ABSTL:    P  RETURN CODE=4 */                                       26250021
*/*    R  GO TO TYPE 1 SVC EXIT*/                                       26300021
*/*%ABTSTE: D (YES,,NO,AB80X1) IS SUBPOOL = 245 OR 255*/                26350021
*/*    P  (,%RMEX)  PUT E04 INFO IN BUFFER*/                            26400021
*/*AB80X1: P  PUT 80X-1 INFO IN BUFFER*/                                26450021
*/*%RMEX:    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                     26500021
*/*IGC010:   END */                                                     26550021
.AMS1    ANOP                                                           26600021
*IGC010 ENTRY *                                                         26650021
RMBEGIN  BALR  BASEREG,0           GET                                  26700021
         USING *,BASEREG               ADDRESSABILITY                   26750021
         XC    DATAWORK(END-BEGIN),DATAWORK .ZERO WORKAREA              26800021
         ST    REG0,SAVELNGT .     SAVE LENGTH &SUBPOOL                 26850021
         MVC   SAVESPID(ONE),SAVELNGT .MOVE SUBPOOL ID                  26900021
         MVI   SAVELNGT,ZERO .     ZERO HI SUBPOOL BYTE                 26950021
         LTR   REG1,REG1 .         IS THIS GETMAIN FORM OF REGMAIN      27000021
         SPACE 1                                                        27050021
** FREEMAIN  FUNCTION  OF  REGMAIN  ***                                 27100021
         SPACE 1                                                        27150021
         BM    RMGETM .            YES                                  27200021
         ST    REG15,FRSAV15 .SAVE REG15 FOR FREEMAIN CALLER            27250021
         LA    FREEADDR,ZERO(REG1) .ZERO HIGH BYTE OF ADDR TO FREEM4916 27300021
         LA    WORKREGA,SEVEN .    GET DOUBLEWORD MASK                  27350021
         NR    WORKREGA,FREEADDR . IS ADDR AREA TO FREE ON DBLWORD BDY  27400021
         BNZ   AB90X1 .              NO,90X-1 ABEND                     27450021
         L     FREESIZE,SAVELNGT . SET UP REG FOR FREECORE              27500021
         BAL   RETREG2,SPGET .     GO VALIDITY CHECK, GET BBOX          27550021
         BAL   RETREG2,FREECORE .  GO FREE CORE                         27600021
         AIF   (NOT &LCS).RMEND                                         27650021
         BAL   RETREG,COMMLCS .GO RESTORE LCS FLAG                  LCS 27700021
.RMEND   ANOP                                                           27750021
         L     REG15,FRSAV15 .RESTORE REG15 FOR FREEMAIN CALLER         27800021
         BR    REG14 .             RETURN TO SVE TYPE 1 EXIT            27850021
         SPACE 1                                                        27900021
** GETMAIN FUNCTION OF  REGMAIN ***                                     27950021
         SPACE 1                                                        28000021
RMGETM   EQU   *                                                        28050021
         OI    SWITCHES,GETMAIN .SET GETMAIN REQUEST FLAG               28100021
         AIF   (NOT &LCS).RMGOVAL                                       28150021
         CL    REG1,LCSREGM .      IS REQUEST FOR HIER=1            LCS 28200021
         BNE   RMGOVAL .           NO, GO VALIDITY CHECK            LCS 28250021
         OI    SWITCHES,LCSW .     SET LCS SWITCH                   LCS 28300021
.RMGOVAL ANOP                                                           28350021
RMGOVAL  BAL   RETREG2,SPGET .     GO VALIDITY CK, GET BBOX             28400021
         BAL   RETREG2,GETCORE .   GO GET CORE                          28450021
         B     RMSUCCES .          SUCCESSFUL GETMAIN                   28500021
         BNO   ABTSTE04      CORE NOT AVAILABLE                @SA66514 28550021
RMSUCCES EQU   *                                                        28600021
         AIF   (NOT &LCS).RMEXIT                                        28650021
         BAL   RETREG,COMMLCS .GO RESTORE LCS FLAG                  LCS 28700021
.RMEXIT  ANOP                                                           28750021
         LR    REG1,GETADDR .      REG1=ADDR ALLOC AREA                 28800021
         SR    REG15,REG15 .      REG15=0 FOR SUCCESFUL REGMAIN         28850021
         BR    REG14 .             GO TO SVC TYPE 1 EXIT                28900021
         TITLE 'IGC004 ENTRY ROUTINE'                                   28950021
         AGO .AMS2                                                      29000021
*/*IGC004: CHART GETMAIN SVC4*/                                         29050021
*/*IGC004:    E  IGC004   */                                            29100021
*/*    P  ZERO DATAWORK AREA */                                         29150021
*/*    D  (YES,%GM1,NO,)  IS PARM PTR ON WORD BDY*/                     29200021
*/*    P   PUT 60X-1 INFO IN BUFFER*/                                   29250021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           29300021
*/*%GM1:    D  (YES,,NO,GMVALCK)  IS REQUEST HIER=1 */                  29350021
*/*    P  SET LCS SWITCH ON */                                          29400021
*/*GMVALCK:  S SPGET:VALIDITY CK PARMS, GET BBOX */                     29450021
*/*    D  (YES,,NO,GMGOGET) VARIABLE REQUEST? */                        29500021
*/*    P  GETMAIN LENGTH=MAXIMUM LENGTH */                              29550021
*/*GMGOGET: S GETCORE:GO GET CORE*/                                     29600021
*/*    D  (YES,GMSUCCES,NO,) WAS GETCORE SUCCESSFUL */                  29650021
*/*    D  (YES,GMCKMIN,NO,) VARIABLE REQUEST*/                          29700021
*/*GMCKCOND: D (YES,,NO,ABNOCORE)  CONDITIONAL  REQUEST? */             29750021
*/*    P  RETURN CODE=4 */                                              29800021
*/*    R  GO TO TYPE 1 SVC EXIT */                                      29850021
*/*GMSUCCES: P RETURN CODE=0 */                                         29900021
*/*    R  GO TO TYPE 1 EXIT */                                          29950021
*/*GMCKMIN:  D (YES,GMCKCOND,NO,) IS MINIMUM SIZE GT LARGEST FQE */     30000021
*/*    P  (,GMGOGET)  GETMAIN LENGTH= LARGEST FQE SIZE */               30050021
*/*ABNOCORE: D (YES,%ABSTL,NO,) IS REQUESTOR ABEND OR ABTERM*/          30100021
*/*        D (YES,,NO,%ABTSTE) IS REQUESTOR SVC FLIH*/                  30150021
*/*%ABSTL:        P RETURN CODE=4 */                                    30200021
*/*        R GO TO TYPE 1 SVC EXIT*/                                    30250021
*/*%ABTSTE: D (YES,,NO,AB80X1) IS SUBPOOL= 245 OR 255*/                 30300021
*/*    P  (,%GMEX) PUT E04 INFO IN BUFFER*/                             30350021
*/*AB80X1: P  PUT 80X-1 INFO IN BUFFER*/                                30400021
*/*%GMEX:    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                     30450021
*/*IGC004:   END  */                                                    30500021
.AMS2    ANOP                                                           30550021
         DS    0D                                                       30600021
IGC004   EQU   *                                                        30650021
GMBEGIN  BALR  BASEREG,0           SET UP ADDRESSABILITY                30700021
         LA    WORKREGA,GMBEGIN-RMBEGIN .AJUST                          30750021
         SLR   BASEREG,WORKREGA .             ADDRESSABILITY            30800021
         USING GETDSECT,REG1       SET UP PARMLIST DSECT                30850021
         XC    DATAWORK(END-BEGIN),DATAWORK .ZERO WORKAREA              30900021
         OI    SWITCHES,GETMAIN .SET GETMAIN REQUEST FLAG               30950021
         LA    WORKREGA,THREE .    GET WORD MASK                        31000021
         NR    WORKREGA,REG1 .      IS PARMLIST PTR ON WORD BDY         31050021
         BNZ   AB60X1            NO, 60X ABEND                          31100021
         MVC   SAVESPID(1),GETSPID .SAVE SUBPOOL                        31150021
         MVC   SAVELNGT(FOUR),GETLNGTH .SAVE LENGTH                     31200021
         AIF   (NOT &LCS).GMVALCK                                       31250021
         CLI   GETHID,HIERAR1      IS REQUEST HIER=1                LCS 31300021
         BNE   GMVALCK             NO                               LCS 31350021
         OI    SWITCHES,LCSW       YES, SET HIER=1 SWITCH           LCS 31400021
.GMVALCK ANOP                                                           31450021
GMVALCK  BAL   RETREG2,SPGET        GO VALIDITY CK SP , GET BBOX        31500021
         TM    GETYPE,UNCONDVA .   IS THIS A VARIABLE REQ               31550021
         BNO   GMGOGET .           NO                                   31600021
         TM    GETLNGTH+3,THREE .IS PTR TO DBLEWD LENGTH ON WORD BDY    31650021
         BNZ   AB60X1 .           NO,60X-1 ABEND                        31700021
         L     WORKREGA,GETLNGTH .  GET PTR TO DBLEWD LENGTH            31750021
         MVC   SAVELNGT(FOUR),FOUR(WORKREGA) .SAVE MAXIMUM REQ SIZE     31800021
GMGOGET  BAL   RETREG2,GETCORE .   GO GET CORE                          31850021
         B     GMSUCCES .          GETCORE SUCCESSFUL                   31900021
         SPACE 2                                                        31950021
****GETMAIN WAS UNSUCCESSFUL ****                                       32000021
         SPACE 1                                                        32050021
* GETCORE= RETURN+4 FOR CORE NOT FOUND ***                              32100021
         TM    GETYPE,UNCONDVA .   IS THIS VARIABLE REQ                 32150021
         BO    GMCKMIN .           YES                                  32200021
* REQUEST CAN NOT BE SATISFIED, CHECK FOR CONDITIONAL REQUEST           32250021
GMCKCOND TM    GETYPE,CONDSE .     IS THIS A CONDITIONAL REQ            32300021
         BNO   ABTSTE04      CORE NOT AVALABLE, UNCOND REQUEST @SA66514 32350021
         LA    REG15,FOUR .        SET RETURN CODE =4                   32400021
         AIF   (NOT &LCS).GMEXIT2                                       32450021
         BAL   RETREG,COMMLCS .GO RESTORE LCS FLAG                  LCS 32500021
.GMEXIT2 ANOP                                                           32550021
         BR    REG14 .             GO TO SVC TYPE 1 EXIT                32600021
         SPACE 2                                                        32650021
**** GETMAIN WAS SUCCESSFUL ****                                        32700021
GMSUCCES EQU   * .      ***GETMAIN WAS SUCCESSFUL ***                   32750021
         L     WORKREGA,GETADD .    GET USER'S PARM ADDR                32800021
         ST    GETADDR,ZERO(WORKREGA) .GIVE USER ALLOC AREA ADDR        32850021
         AIF   (NOT &LCS).GMEXIT                                        32900021
         BAL   RETREG,COMMLCS .GO RESTORE LCS FLAG                  LCS 32950021
.GMEXIT  ANOP                                                           33000021
         TM    GETYPE,UNCONDVA .   IS THIS A VARIABLE REQ               33050021
         BNO   GMEXIT              NO, GO EXIT                          33100021
         MVC   FOUR(FOUR,WORKREGA),ROUNDSIZ .2ND WORD=LNGTH ALLOC       33150021
GMEXIT   SR    REG15,REG15 .       RETURN CODE=0                        33200021
         BR    REG14 .             GO TO SVC TYPE 1 EXIT                33250021
         SPACE 2                                                        33300021
GMCKMIN  L     WORKREGA,GETLNGTH .  GET PTR TO DBLEWD LENGTH            33350021
         L     WORKREGA,ZERO(WORKREGA) .GET MINIMUM LENGTH              33400021
         CL    WORKREGA,LARFQSIZ .  IS MINIMUM GT LARGEST FQE           33450021
         BH    GMCKCOND .          YES, GETCORE UNSUCCESSFUL            33500021
         AIF   (NOT &ATT).GMVC                                          33502021
         TM    SWITCHES,GQESW .          IS THIS A GQE        AC A61243 33510021
         BZ    GMMVC .                   NO ,BYPASS SIZE ADJ  AC A61243 33520021
         L     WORKREGA,LARFQSIZ  .      YES,GET FQE SIZE     AC A61243 33530021
         SH    WORKREGA,EIGHTDC .        REDUCE SIZE BY 8     AC A61243 33540021
         ST    WORKREGA,LARFQSIZ .       SAVE NEW SIZE        AC A61243 33542021
.GMVC    ANOP                                                           33542421
GMMVC    EQU   * .                                            AC A61243 33544021
         MVC   SAVELNGT(FOUR),LARFQSIZ .GIVE USER LARGEST FQE           33550021
         B     GMGOGET .           GO GET CORE                          33600021
         TITLE                'IGC005 ENTRY ROUTINE'                    33650021
         AGO .AMS3                                                      33700021
*/*IGC005: CHART FREEMAIN SVC5*/                                        33750021
*/*IGC005:  E  IGC005*/                                                 33800021
*/*    P  ZERO DATAWORK AREA */                                         33850021
*/*    D  (YES,%FM1,NO,) IS PARM PTR ON WORD BOUNDARY */                33900021
*/*    P    PUT 60X-1 INFO IN BUFFER*/                                  33950021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           34000021
*/*%FM1:    D (YES,%FM2,NO,) IS ADDR OF AREA TO FREE ON DBL WORD BDY*/  34050021
*/*    P PUT 90X-1 INFO IN BUFFER*/                                     34100021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           34150021
*/*%FM2:     S  SPGET:GO VALIDITY CHECK PARMS, GET BBOX */              34200021
*/*    S  FREECORE:GO FREE CORE */                                      34250021
*/*    R  GO TO SVC TYPE 1 EXIT */                                      34300021
*/*IGC005: END*/                                                        34350021
.AMS3    ANOP                                                           34400021
         DS    0D                                                       34450021
IGC005   EQU   *                                                        34500021
FMBEGIN  BALR  BASEREG,0 .         SET UP ADDRESSABILITY                34550021
         LA    WORKREGA,FMBEGIN-RMBEGIN .ADJUST                         34600021
         SLR   BASEREG,WORKREGA .               ADDRESSABILITY          34650021
         USING GETDSECT,REG1 .     SET UP PARMLIST DSECT                34700021
         ST    REG15,FRSAV15 .SAVE REG15 FOR FREEMAIN CALLER            34750021
         XC    DATAWORK(END-BEGIN),DATAWORK .ZERO WORKAREA              34800021
         LA    WORKREGA,THREE .    GET WORD MASK                        34850021
         NR    WORKREGA,REG1 .      IS PARMLIST PTR ON WORD BDY         34900021
         BNZ   AB60X1            NO, 60X ABEND                          34950021
         MVC   SAVESPID(ONE),GETSPID .PUT SUBPOOL IN WORK AREA          35000021
         TM    GETADD+3,THREE .   IS PTR TO ADDR TO FREE ON WORD BDY    35050021
         BNZ   AB60X1 .           NO,60X-1 ABEND                        35100021
         L     WORKREGA,GETADD .   GET PTR TO ADDR OF AREA TO FREE      35150021
         TM    THREE(WORKREGA),SEVEN .IS ADDR AREA TO FREE DBLWORD BDY  35200021
         BNZ   AB90X1 .             NO,90X-1 ABEND                      35250021
         L     FREEADDR,ZERO(WORKREGA) .GET ADDR TO FREE                35300021
         LA    FREEADDR,ZERO(FREEADDR) .CLEAR HI BYTE                   35350021
         TM    GETYPE,UNCONDVA .  IS THIS A VARIABLE FREEMAIN           35400021
         BNO   FMSINELE .         NO SINGLE ELEMENT REQ                 35450021
         L     FREESIZE,FOUR(WORKREGA) .GET LENGTH TO FREE              35500021
         B     FMGOVAL .          GO VALIDITY CHECK                     35550021
FMSINELE L     FREESIZE,GETLNGTH . GET LENGTH TO FREE                   35600021
FMGOVAL  BAL   RETREG2,SPGET .     GO VALIDITY CHECK PARMS,GET BBOX     35650021
         BAL   RETREG2,FREECORE .  GO ADJUST FQE'S                      35700021
         AIF   (NOT &LCS).FMEND                                         35750021
         BAL   RETREG,COMMLCS .GO RESTORE LCS FLAG                  LCS 35800021
.FMEND  ANOP                                                            35850021
         L     REG15,FRSAV15 .RESTORE REG15 FOR FREEMAIN CALLER         35900021
         BR    REG14 .             RETURN TO SVC TYPE 1 EXIT            35950021
         SPACE 3                                                        36000021
         AIF   (NOT &LCS).COMZEND                                       36050021
*** THIS CODE RESTORES THE LCS FLAGS IN THE BOUNDARY BOX WHICH      LCS 36100021
*** SPGET ZEROED OUT FOR FQE PROCESSING.                            LCS 36150021
COMMLCS  EQU   *                                                    LCS 36200021
         TM    SWITCHES,SQSREQ .IS REQUEST FOR SUBPOOL 245,255    M4914 36250021
         BCR   ONE,RETREG .     YES,NO LCS FLAG, RETURN           M4914 36300021
         AIF   (NOT &ATT).COMNOAT                                       36450021
         L     BBOXREG,TCBFTJST(REG4) .GET JOBSTEP TCB              ATT 36500021
         L     BBOXREG,TCBMSS(BBOXREG) .GET JOBSTEP BBOX            ATT 36550021
         AGO   .COMLCS                                                  36600021
.COMNOAT ANOP                                                           36650021
         L     BBOXREG,TCBMSS(REG4) .GET BBOX                       LCS 36700021
.COMLCS  ANOP                                                           36750021
         MVC   BBLCS(ONE,BBOXREG),LCSFLGSV .RESTORE FLAG            LCS 36800021
         BR    RETREG .RETURN TO PROLOGUE                           LCS 36850021
.COMZEND ANOP                                                           36900021
         TITLE 'GETCORE SUBROUTINE'                                     36950021
        AGO .AMS4                                                       37000021
*/*GETCORE: CHART */                                                    37050021
*/*GETCORE: E  ENTRY */                                                 37100021
*/*    P  ROUND SIZE TO DOUBLEWORD */                                   37150021
*/*    D  (YES,%GT,NO,)  IS SIZE POSITIVE */                            37200021
*/*    P    PUT 80X-2 INFO IN BUFFER*/                                  37250021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           37300021
*/*%GT:    D  (YES,,NO,%GTINIT) IS GQE SWITCH ON */                     37350021
*/*    P  INCREMENT SIZE BY 8 FOR GQE */                                37400021
*/*%GTINIT:    P  GET ADDR 1ST FQE IN BBOX */                           37450021
*/*    P  GET TOP & BOTTOM OF PARTITION */                              37500021
*/*    D  (YES,,NO,GTCKFQE) IS 1ST FQE=0 */                             37550021
*/*    R  RETURN NOT FOUND */                                           37600021
*/*GTCKFQE: S  FQECHECK:GO VALIDITY CHECK FQE */                        37650021
*/*    D  (YES,,NO,GTCKSIZ) IS THIS THE LARGEST FQE */                  37700021
*/*    P  SAVE LARGEST FQE SIZE */                                      37750021
*/*GTCKSIZ: D  (YES,,NO,GTNEXTFQ) DOES FQE SATISY REQUEST? */           37800021
*/*    D  (YES,GTFNDFQE,NO,) IS THIS A HIGH CORE REQUEST? */            37850021
*/*    P  SAVE LAST,CURR FQE ADDRESSES */                               37900021
*/*GTNEXTFQ: P  GET NEXT FQE */                                         37950021
*/*    D  (YES,GTCKFQE,NO,) ANY MORE FQES? */                           38000021
*/*    D  (YES,,NO,%GT1) IS THIS HIGH CORE REQUEST */                   38050021
*/*    R  RETURN NOT FOUND  */                                          38100021
*/*%GT1: P  RESTORE CURRENT,LAST FQE ADDRESSES */                       38150021
*/*    D  (YES,GTFNDFQE,NO,) WAS FQE FOUND TO SATISFY REQ */            38200021
*/*    R  RETURN NOT FOUND */                                           38250021
*/*GTFNDFQE: P SUBTRACT ALLOCATED AREA FROM FQE SIZE */                 38300021
*/*    D  (YES,GTDROPFQ,NO,) IS NEW SIZE=0 */                           38350021
*/*    D  (YES,GTLOWREQ,NO,) LOW CORE REQUEST? */                       38400021
*/*    P  (,GTALLOC) STORE NEW SIZE IN FQE,ADD FQE SIZE TO ALLOC ADDR*/ 38450021
*/*GTLOWREQ: P ADD REQ SIZE TO ADDR OF FQE AND STORE IN PREV FQE ADDR*/ 38500021
*/*    P  (,GTALLOC) STORE NEW SIZE IN NEW FQE,                         38550021
*/*                  NEW FQE PTR=ADDR NEXT FQE */                       38600021
*/*GTDROPFQ: P MOVE OLD FQE PTR TO NEW FQE */                           38650021
*/*GTALLOC:  D (YES,,NO,GTSMFCK) IS GQE SWITCH ON */                    38700021
*/*    P  STORE GQE SIZE IN NEW GQE*/                                   38750021
*/*    P  GET ADDRESS OF DUMMY BBOX */                                  38800021
*/*    P  MOVE CURRENT GQEPTR IN DUMMY BBOX TO NEW GQE */               38850021
*/*    P  STORE NEM GQE PTR IN DUMMY BBOX*/                             38900021
*/*GTSMFCK:    D   (YES,GTSMRET,NO,)  IS REQUEST FOR SQS */             38950021
*/*    S  SMFGET: GO UPDATE SMF RECORDS*/                               38960021
*/*GTSMRET: R  RETURN CORE FOUND */                                     39000021
*/*GETCORE: END */                                                      39050021
.AMS4    ANOP                                                           39100021
*-----------------------------------------------------------------      39150021
* THE INPUT TO GETCORE IS THE BOUNDARY BOX ADDRESS IN REG 6.            39200021
* GETCORE SEARCHES DOWN THE FQE CHAIN, VALIDITY CHECKING ON ITS         39250021
* WAY, TO SATISFY THE GETMAIN REQUEST, UDATES THE FQE CHAIN, AND        39300021
         AIF  (NOT &ATT).NOGQESR                                        39350021
* BUILDS A GQE FOR A SUBTASK REQUEST,                                   39400021
.NOGQESR  ANOP                                                          39450021
          AIF  (NOT &SMF).NOSMCAL                                       39500021
* GOES TO SMF FOR UPDATING.                                             39550021
.NOSMCAL ANOP                                                           39600021
* THE OUTPUT IS THE ADDR OF THE ALLOCATED AREA  IN REG 13.              39650021
*-----------------------------------------------------------------      39700021
         SPACE 2                                                        39750021
         DS 0F                                                          39800021
GETCORE  EQU *                                                          39850021
         L     WORKREGA,SAVELNGT    GET SIZE                            39900021
         LA    GETADDR,SEVEN .  ROUND                            A57386 39950021
         AR    WORKREGA,GETADDR .     SIZE                       A57386 40000021
         OR    WORKREGA,GETADDR .          TO DBLEWORD           A57386 40050021
         XR    WORKREGA,GETADDR .                      BOUNDARY  A57386 40060021
         LTR   WORKREGA,WORKREGA     TEST SIZE                          40100021
         BNP   AB80X2 .           FOR ZERO OR NEGATIVE SIZE ABEND       40150021
         AIF   (NOT &ATT).GTSAVSZ                                       40200021
         TM    SWITCHES,GQESW      IS THIS A GQE REQUEST            ATT 40250021
         BZ    GTSAVSIZ            NO                               ATT 40300021
         LA    WORKREGA,EIGHT(WORKREGA) INCREASE SIZE 8 FOR GQE     ATT 40350021
.GTSAVSZ ANOP                                                           40400021
GTSAVSIZ EQU   *                                                        40450021
         ST    WORKREGA,ROUNDSIZ    SAVE ROUNDED SIZE                   40500021
         SPACE 2                                                        40550021
****  SEARCH FOR AN FQE TO SATISFY THE GETMAIN REQUEST ****             40600021
         SPACE 1                                                        40650021
* INITIALIZE REG7 WITH 1ST FQE ADDR, REG9 WITH TOP PARTITION            40700021
*            ADDRESS+1, AND REG 8 WITH BOTTOM PARTITION ADDR.           40750021
         LM    CURFQREG,LSTFQREG,BBLCS(BBOXREG)  INIT REGS FOR 1ST FQE X40800021
                                        TOP AND BOTTOM OF PARTITION     40850021
         LA    LSTFQREG,ONE(LSTFQREG)   TOP BOUNDARY=HI ADDR+1          40900021
         LTR   CURFQREG,CURFQREG        IS 1ST FQE=0                    40950021
         BZ    FOUR(RETREG2)            YES, RETURN NOT FOUND           41000021
GTCKFQE  BAL   RETREG,FQECHECK     GO VALIDITY CHECK 1ST FQE            41050021
*  WITH RETURN, THE FQE IS VALID                                        41100021
         CLC   LARFQSIZ(FOUR),FQELNGTH(CURFQREG) SAVE BIGGEST FQE       41150021
*  FOR A HIGH-CORE REQUEST, LARFQSIZ DOESNT TRULY REPRESENT THE  *      41200021
*  LARGEST FQE, BUT ONLY THE FIRST FQE FOUND TO SATISFY REQUEST. *      41250021
         BH    GTCKSIZ             NOT LARGER                           41300021
         MVC   LARFQSIZ(FOUR),FQELNGTH(CURFQREG) SET LARGER SIZ         41350021
GTCKSIZ  CLC   FQELNGTH(FOUR,CURFQREG),ROUNDSIZ DOES FQE SATISFY REQ    41400021
         BL    GTNEXTFQ            NO                                   41450021
         TM    SWITCHES,LOCORESW   IS THIS A LOWCORE REQ                41500021
         BZ    GTFNDFQE            NO, FQE IS FOUND FOR HICORE          41550021
         STM   CURFQREG,LSTFQREG,LOCORSAV  SAVE CUR,LAST FQES           41600021
GTNEXTFQ LR    LSTFQREG,CURFQREG   UPDATE LAST FQE                      41650021
         LR    CURFQREG,NXTFQREG   UPDATE CURRENT FQE                   41700021
         LTR   CURFQREG,CURFQREG   IS THIS END OF FQES                  41750021
         BNZ   GTCKFQE             NO                                   41800021
* END OF FQES HAS BEEN REACHED *                                        41850021
         TM    SWITCHES,LOCORESW   IS THIS LOCORE REQ                   41900021
         BZ    FOUR(RETREG2)       NO, RETURN NOT FOUND-HI REQ          41950021
         LM    CURFQREG,LSTFQREG,LOCORSAV RESTORE CUR,LAST FQES         42000021
         LTR   CURFQREG,CURFQREG . WAS FQE FOUND TO SATISFY REQ         42050021
         BZ    FOUR(RETREG2) .  NO,RETURN NOT FOUND                     42100021
         L     NXTFQREG,FQEPTR(CURFQREG) RESTORE NEXT FQE               42150021
         SPACE 2                                                        42200021
**** AN FQE HAS BEEN FOUND TO SATISFY THE GETMAIN REQUEST ****          42250021
         SPACE 1                                                        42300021
*  IN THE CASE OF EITHER AN EXACT FIT OR A LOW CORE REQUEST IN WHICH    42350021
*  THE 1ST FQE WILL BE ALTERED,THE PREVIOUS FQE PTR IS UPDATED TO       42400021
*  THE ADDR OF THE BOUNDARY BOX.                                        42450021
GTFNDFQE CL    CURFQREG,BBFQE(BBOXREG) . IS 1ST FQE BEING CHANGED       42500021
         BNE   GTNOT1ST .         NO                                    42550021
         LR    LSTFQREG,BBOXREG .  YES,LAST FQE PTR=ADDR BBOX           42600021
GTNOT1ST L     WORKREGA,FQELNGTH(CURFQREG) GET FQE SIZE                 42650021
         S     WORKREGA,ROUNDSIZ SUBTRACT ALLOCATED AREA FROM FQE       42700021
         LTR   WORKREGA,WORKREGA     IS RESULT=0                        42750021
         BZ    GTDROPFQ            YES                                  42800021
         TM    SWITCHES,LOCORESW   IS THIS LOWCORE REQ                  42850021
         BO    GTLOWREQ            YES                                  42900021
         SPACE 1                                                        42950021
* FOR A HIGH CORE REQUEST DECREMENT FQE SIZE                            43000021
         ST    WORKREGA,FQELNGTH(CURFQREG) UPDATE SIZE IN CUR FQE       43050021
         A     WORKREGA,FQEPTR(LSTFQREG) GET ADDR ALLOC AREA            43100021
         B     GTALLOC                                                  43150021
         SPACE 1                                                        43200021
* BUILD A NEW FQE FOR LOW CORE REQUEST.                                 43250021
GTLOWREQ L     GTWORK2,ROUNDSIZ     GET REQ SIZE                        43300021
         AR    GTWORK2,CURFQREG    ADD CURR FQE ADDR TO REQ SIZE        43350021
         ST    GTWORK2,FQEPTR(LSTFQREG) UPDATE PREVIOUS FQEPTR          43400021
         ST    NXTFQREG,FQEPTR(GTWORK2) BUILD 1ST WORD NEW FQE          43450021
         ST    WORKREGA,FQELNGTH(GTWORK2) BUILD 2ND WORD NEW FQE        43500021
         LR    WORKREGA,CURFQREG         GET ADDR ALLOC AREA            43550021
         B     GTALLOC                                                  43600021
         SPACE 1                                                        43650021
* FOR A PERFECT MATCH REMOVE CURRENT FQEFROM CHAIN *                    43700021
GTDROPFQ ST NXTFQREG,FQEPTR(LSTFQREG)  REMOVE CURRENT FQE               43750021
         LR    WORKREGA,CURFQREG  GET ADDR ALLOC AREA                   43800021
* WORKREGA NOW CONTAINS THE ADDRESS OF THE ALLOCATED CORE.              43850021
GTALLOC  LR    GETADDR,WORKREGA .  GET ADDR ALLOCATED AREA IN REG 13    43900021
         AIF   (NOT &ATT).GTSMFCK                                       43950021
         SPACE 2                                                        44000021
*FOR A GQE REQUEST BUILD A GQE AND CHAIN TO DUMMY BOUNDARY BOX.         44050021
         TM    SWITCHES,GQESW      IS SUBTASK REQUESTOR             ATT 44100021
         BZ    GTSMFCK             NO ,BYPASS GQE PROCESS           ATT 44150021
* WORKREGA CONTAINS THE ADDR OF THE ALLOCATED AREA.                 ATT 44200021
         L     GTWORK2,ROUNDSIZ     GET REQ SIZE                    ATT 44250021
         ST    GTWORK2,GQESIZE(WORKREGA) PUT SIZE IN GQE            ATT 44300021
         SH    GTWORK2,EIGHTDC .SUBTRACT 8 FOR BEGIN ALLOC AREA     ATT 44350021
         ST    GTWORK2,ROUNDSIZ .UPDATE ALLOC SIZE FOR VAR REQUEST  ATT 44400021
         L     GTWORK2,TCBMSS(REG4)  GET ADDR DUMMY BBOX            ATT 44450021
         MVC   GQEPTR(FOUR,WORKREGA),GQEBBOX(GTWORK2) MOVE CURRENT  ATT*44500021
                            GQE PTR IN DUMMY BBOX TO NEW GQE        ATT 44550021
         ST    WORKREGA,GQEBBOX(GTWORK2) STORE CUR GQE IN DUM BBOX  ATT 44600021
         LA    GETADDR,EIGHT(GETADDR) .ADD 8 TO ALLOC ADDR FOR GQE  ATT 44650021
.GTSMFCK ANOP                                                           44700021
GTSMFCK  EQU   *                                                        44750021
         AIF   (NOT &SMF).GTENDGT                                       44800021
         SPACE 2                                                        44850021
         TM   SWITCHES,SQSREQ  IS REQUEST FOR SUBPOOL 245,255     M4914 44860021
         BCR  ONE,RETREG2      YES, BYPASS SMF CALCULATIONS       M4914 44870021
* GO CALCULATE SMF INFORMATION                                      SMF 44900021
         BAL   RETREG,SMFGET       GO UPDATE SMF RECORDS            SMF 44950021
.GTENDGT ANOP                                                           45000021
         BR    RETREG2             RETURN TO CALLER,CORE FOUND          45050021
         TITLE 'SPGET SUBROUTINE'                                       45100021
         AGO .AMS5                                                      45150021
*/*SPGET: CHART */                                                      45200021
*/*SPGET: E ENTRY */                                                    45250021
*/*    D  (YES,SPCKSPVR,NO,) IS THIS SVC 10*/                           45300021
*/*SPCKLST:    D  (NO,SPCKSPVR,YES,) LIST REQUEST */                    45350021
*/*    P  (,ABTERM)  PUT 70X INFO IN BUFFER*/                           45400021
*/*SPCKSPVR: D (YES,SPSPVR,NO,) IS REQUESTOR KEY=0 OR SUPV STATE*/      45450021
*/*SPROBPGM:    D  (YES,%SP,NO,) SUBPOOL < 128 */                       45500021
*/*ABB0X:    P  (,ABTERM)  PUT B0X INFO IN BUFFER*/                     45550021
*/*%SP:    D  (YES,SPJSTCB,NO,) SVC 10 */                               45600021
*/*    D  (YES,,NO,AB60X1) 2ND WORD IN PARMLIST ON WORD BDY */          45650021
*/*    D  (YES,SPJSTCB,NO,AB60X1)                                       45700021
*/*            ARE PARMPTR & 2ND WORD IN HIER 0 OR 1 */                 45750021
*/*SPSPVR: D (YES,,NO,SPNOTSQA) IS REQUEST FOR SQS */                   45800021
*/*    P  GET ADDR SQS BBOX FROM MASTER SCHED DATA AREA */              45850021
*/*    R  RETURN */                                                     45900021
*/*SPNOTSQA: D  (YES,%SPGQ,NO,) IS THIS FREEMAIN*/                      45950021
*/*     D (YES,SPCKLOWR,NO,) IS REQ JOBSTEP */                          46000021
*/*SPTST240: D (YES,SPJSTCB,NO,) IS REQ FOR SUBPOOL 240*/               46050021
*/*%SPGQ:    P  SET GQE SWITCH ON */                                    46100021
*/*SPCKLOWR: D  (YES,,NO,SPGT127) IS SUBPOOL < 128 */                   46150021
*/*    D  (YES,,NO,SPSTEAL) IS REQUESTOR IN SUPV STATE*/                46200021
*/*    P  (,SPJSTCB) SET LOWCORE SWITCH */                              46250021
*/*SPGT127: D  (YES,SPJSTCB,NO,)  IS SUBPOOL = 249-254 */               46300021
*/*         D  (YES,SPJSTCB,NO,)  IS SUBPOOL = 243-244 */               46350021
*/*         D  (YES,SPJSTCB,NO,)  IS SUBPOOL = 240*/                    46400021
*/*         D  (YES,,NO,ABB0X)  IS SUBPOOL=128 */                       46450021
*/*SPJSTCB: P  GET JOBSTEP HIERARCHY=0 BBOX ADDR */                     46500021
*/*    D  (YES,SPFREEM,NO,) FREEMAIN */                                 46550021
*/*SPGETM:  D  (YES,SPTSTH1,NO,) IS LCS SWITCH ON */                    46600021
*/*    D  (YES,,NO,%SP1) ANY HIERARCHY=0 */                             46650021
*/*R  RETURN */                                                         46700021
*/*%SP1:     P  (,SPGETH1) SET DUMMY HIERARCHY SWITCH ON */             46750021
*/*SPTSTH1: D  (YES,SPGETH1,NO,)  ANY HIERARCHY=1  */                   46800021
*/*    P   SET DUMMY HIERARCHY SWITCH ON */                             46850021
*/*    R  RETURN */                                                     46900021
*/*SPGETH1:  P GET ADDR 2ND BBOX */                                     46950021
*/*    R  RETURN */                                                     47000021
*/*SPFREEM:  D (YES,,NO,SPSTEAL)                                        47050021
*/*            IS ADDR AREA TO FREE HIER=0 OR HIER=1*/                  47100021
*/*    R  RETURN */                                                     47150021
*/*SPSTEAL: D  (YES,,NO,AB90X2) IS REQ IN SUPV STATE, KEY=0*/           47200021
*/*         D (YES,,NO,AB90X2) IS REQ TCB = STEALCORE TCB*/             47250021
*/*         D  (YES,,NO,AB90X2) IS AREA TO FREE A SVRB IN SVRB POOL*/   47300021
*/*        P  FREE SVRB BY ZEROING SVRB SIZE BYTE*/                     47350021
*/*         R  GO TO SVC TYPE 1 EXIT*/                                  47400021
*/*AB90X2: P  (,ABTERM) PUT 90X-2 INFO IN BUFFER*/                      47450021
*/*AB60X1: P   PUT 60X-1 INFO IN BUFFER*/                               47500021
*/*ABTERM: R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                       47550021
*/*SPGET: END*/                                                         47600021
.AMS5    ANOP                                                           47650021
*--------------------------------------------------------------------   47700021
* SPGET IS A SUBROUTINE WHICH CHECKS THE SUBPOOL NUMBER AND GETS      * 47750021
*       THE ADDRESS OF THE BOUNDARY BOX. INPUT IS THE SUBPOOL AT      * 47800021
*       SAVESPID, AND TCB IN REG4, FOR FREEMAIN THE ADDR OF THE         47850021
*       AREA TO FREE IN REG 13,SIZE TO FREE IN REG15 .                  47900021
*       OUTPUT IS THE ADDR OF THE BOUNDARY BOX IN REG 6.                47950021
*--------------------------------------------------------------------   48000021
        SPACE 3                                                         48050021
        DS 0F                                                           48100021
SPGET    EQU *                                                          48150021
         CLI   SVCOPSW+3,SVC10 .IS THIS REGMAIN                         48200021
         BE    SPCKSPVR .         YES                                   48250021
SPCKLST  CLI   GETYPE,CONDLST .   IS THIS A LIST REQUEST                48300021
          BE   ABEND70X .         YES,GO ABEND                          48350021
         CLI   GETYPE,UNCONDLS .  IS THIS A LIST REQUEST                48400021
         BE    ABEND70X .         YES,GO ABEND                          48450021
SPCKSPVR TM    SVCOPSW+1,KEYF  .IS REQUESTOR KEY=0                      48500021
         BZ    SPSPVR  .           YES, GO CHECK SUPERVISOR REQ         48550021
         TM    SVCOPSW+1,SUPVSTAT .IS REQUESTOR IN SUPV STATE           48600021
         BZ    SPSPVR .      YES,GO CHECK SUPV REQ                      48650021
SPROBPGM CLI    SAVESPID,SP128 .    IS SUBPOOL VALID FOR P/P            48700021
         BNL   ABB0X .           NO, B0X ABEND                          48750021
         SPACE 3                                                        48800021
* VALIDITY CHECK PARMS FROM P/P SVC4,SVC5                               48850021
         CLI   SVCOPSW+3,SVC10 .   IS THIS REGMAIN                      48900021
         BE     SPJSTCB             YES,GO GET BBOX                     48950021
         TM    GETADD+3,THREE .    IS 2ND WORD PARMLIST ON WORD         49000021
         BNZ   AB60X1            NO                                     49050021
         L     WORKREGA,GETADD .    GET 2ND WORD IN PARMLIST            49100021
         LA    WORKREGA,ZERO(WORKREGA) .CLEAR HIGH BYTE FOR HIER        49150021
        AIF   (NOT &ATT).SPNOATT                                        49200021
         L     BBOXREG,TCBFTJST(REG4) .GET JOBSTEP TCB              ATT 49250021
         L      BBOXREG,TCBMSS(BBOXREG) .GET BBOX                   ATT 49300021
        AGO   .SPCONT                                                   49350021
.SPNOATT ANOP                                                           49400021
         L     BBOXREG,TCBMSS(REG4) .GET BBOX                           49450021
.SPCONT  ANOP                                                           49500021
         LA    SPWORK2,TWO .      INIT BCT COUNT LOOP                   49550021
* CHECK FIRST IF PARM PTR IN VALID BOUNDARIES AND THEN 2ND PARM WORD    49600021
SPBDYCK EQU   *                                                         49650021
         LM    SPLOW,SPHI,LOWADDR0(BBOXREG) .GET HIER=0 LOW AND HI      49700021
         BAL   RETREG,SPCKPARM .   GO CHECK HIER 0 PARMS                49750021
         AIF   (NOT &LCS).SPCKH0                                        49800021
         B     SPTSTNXT .         PARM FOUND                        LCS 49850021
         LM    SPLOW,SPHI,LOWADDR1(BBOXREG) .GET HIER=1 LOW AND HI  LCS 49900021
         BAL   RETREG,SPCKPARM .   GO CHECK HIER=1 PARMS            LCS 49950021
.SPCKH0  ANOP                                                           50000021
         B     SPTSTNXT .         PARM FOUND                            50050021
         B     AB60X1 .         PARM NOT FOUND                          50100021
SPTSTNXT LR    WORKREGA,REG1         . GET PTR TO PARM LIST             50150021
         LA    WORKREGA,ZERO(WORKREGA) .ZERO HIGH BYTE                  50200021
         BCT   SPWORK2,SPBDYCK .  GO CHECK NEXT PARM                    50250021
         LA    WORKREGA,TWELVE(WORKREGA) .GET END PARMLIST              50300021
         CLR   WORKREGA,SPHI .     IS END GT HIGHEST                    50350021
         BH    AB60X1 .         YES                                     50400021
         B     SPJSTCB .            GO CHECK IF FREE OR GET             50450021
* END OF PROBLEM PGM STATE SPECIAL VALIDITY CHECKING ***                50500021
         SPACE 2                                                        50550021
* THIS SUBROUTINE VALIDITY CHECKS TO INSURE THAT THE PARM PASSED        50600021
* IS WITHIN THE BOUNDARIES PASSED.BRANCH ON RETREG IF FOUND             50650021
* BRANCH ON RETREG+4 IF NOT FOUND.*                                     50700021
SPCKPARM LTR   SPHI,SPHI .         ANY HIER CORE                        50750021
         BZ     FOUR(RETREG) .    NO,RETURN NOT FOUND                   50800021
         CLR   WORKREGA,SPHI .     IS PARM LT HIGHEST                   50850021
         BNL   FOUR(RETREG) .     NO,RETURN NOT FOUND                   50900021
         CLR   WORKREGA,SPLOW .     IS   PARM GT LOWEST                 50950021
         BL    FOUR(RETREG) .     NO,RETURN NOT FOUND                   51000021
         BR    RETREG .                                                 51050021
         SPACE 2                                                        51100021
*  VALIDITY CHECKING FOR SUPERVISOR  STATE---CHECK SUBPOOL ID  *        51150021
SPSPVR   EQU   *                                                        51200021
         CLI   SAVESPID,SP255 .     IS REQUEST FOR SQA                  51250021
         BE    SPSQA               YES                                  51300021
         CLI   SAVESPID,SP245 .     IS REQUEST FOR SQA                  51350021
         BNE   SPNOTSQA .                                               51400021
SPSQA    L     BBOXREG,VCMSER                                           51450021
         LA    BBOXREG,MSBBOX(BBOXREG) .GET ADDR SQA BBOX               51500021
         OI   SWITCHES,SQSREQ  SET SWITCH FOR SQS REQUEST         M4914 51510021
         BR    RETREG2 .      RETURN TO PROLOGUE                        51550021
SPNOTSQA EQU   *                                                        51600021
         AIF   (NOT &ATT).SPCKLOW                                       51650021
         TM    SWITCHES,GETMAIN .IS THIS GETMAIN                    ATT 51700021
         BNO   SPGQSWON .  NO GO TO GQESEARCH FOR ALL FREEMAINS     ATT 51750021
         CL    REG4,TCBFTJST(REG4) .IS REQUESTOR JOBSTEP            ATT 51800021
         BE    SPCKLOWR .          YES                              ATT 51850021
SPTST240 CLI   SAVESPID,SP240 .     IS REQUESTOR SUBPOOL 240        ATT 51900021
         BE    SPJSTCB .          YES                               ATT 51950021
SPGQSWON OI    SWITCHES,GQESW .    SET GQE FLAG,REQ=SUPV SUBTASK    ATT 52000021
.SPCKLOW ANOP                                                           52050021
SPCKLOWR CLI   SAVESPID,SP128 .     IS SUBPOOL LT 128                   52100021
         BNL   SPGT127             NO, GO VALIDITY CHECK 128-254        52150021
         TM    SVCOPSW+1,SUPVSTAT .IS REQUESTOR IN SUPV STATE           52200021
         BNZ   SPJSTCB .NO,HIGH CORE REQUEST                            52250021
         OI    SWITCHES,LOCORESW . YES, LOW CORE REQUEST SW SET         52300021
         B     SPJSTCB             GO GET BBOX                          52350021
SPGT127  EQU   *    REMAINING VALID SUBPOOLS ARE 249-254,243-244,128    52400021
         CLI   SAVESPID,SP249 .     IS SUBPOOL 249-254                  52450021
         BNL   SPJSTCB .           YES                                  52500021
         CLI   SAVESPID,SP244 .     IS SUBPOOL= 244                     52550021
         BE    SPJSTCB .           YES                                  52600021
         CLI   SAVESPID,SP243 .     IS SUBPOOL= 243                     52650021
         BE    SPJSTCB .           YES                                  52700021
         CLI   SAVESPID,SP240 .   IS SUBPOOL=240                        52750021
         BE    SPJSTCB .          YES                                   52800021
         CLI   SAVESPID,SP128 .  IS SUBPOOL=128                         52850021
         BNE   ABB0X .         NO INVALID SUBPOOL                       52900021
* END OF SUPERVISOR STATE SPECIAL VALIDITY CHECKING **                  52950021
         SPACE 2                                                        53000021
SPJSTCB  EQU   *                                                        53050021
         AIF   (NOT &ATT).SPRQTCB                                       53100021
         L     BBOXREG,TCBFTJST(REG4) .  GET JOBSTEP TCB            ATT 53150021
         L     BBOXREG,TCBMSS(BBOXREG) .  GET JOBSTEP'S BBOX        ATT 53200021
         AGO   .SPCKLCS                                                 53250021
.SPRQTCB ANOP                                                           53300021
         L     BBOXREG,TCBMSS(REG4) .    GET TCB'S BBOX                 53350021
.SPCKLCS  ANOP                                                          53400021
         AIF   (NOT &LCS).SPCKFG                                        53450021
         MVC   LCSFLGSV(ONE),BBLCS(BBOXREG) .SAVE LCS FLAG          LCS 53500021
         MVI   BBLCS(BBOXREG),ZERO .ZERO LCS FLAG                   LCS 53550021
.SPCKFG  ANOP                                                           53600021
         TM   SWITCHES,GETMAIN . IS THIS GETMAIN                        53650021
         BNO   SPFREEM .      NO                                        53700021
         SPACE 3                                                        53750021
SPGETM   EQU   *  FOR GETMAIN REQUESTS GET ADDR OF BBOX IN BBOXREG-REG. 53800021
         AIF   (NOT &LCS).SPNOLCS                                       53850021
* WITH LCS, IF THE REQUESTED HIERARCHY DOESN'T EXIST, SET DUMHIER SWLCS 53900021
* AND GET OTHER HIER BBOX. OTHERWISE GET BBOX REQUESTED AND RETURN. LCS 53950021
         TM    SWITCHES,LCSW       REQUEST FOR HIER=1               LCS 54000021
         BO    SPTSTH1             YES                              LCS 54050021
         NC    HIADDR0(FOUR,BBOXREG),HIADDR0(BBOXREG) ANY HIER=0    LCS 54100021
         BCR   SEVEN,RETREG2       YES, RETURN, 1ST BBOX IN BBOXREG LCS 54150021
         OI    SWITCHES,DUMHIER    NO,SET DUMMY HIER SWITCH         LCS 54200021
         B     SPGETH1             GO GET 2ND BBOX                  LCS 54250021
SPTSTH1  NC    HIADDR1(FOUR,BBOXREG),HIADDR1(BBOXREG) ANY HIER=1    LCS 54300021
         BNZ   SPGETH1             YES                              LCS 54350021
         OI    SWITCHES,DUMHIER    NO, SET DUMMY HIER SWITCH        LCS 54400021
         BR    RETREG2             RETURN ADDR 1ST BBOX IN REGA     LCS 54450021
SPGETH1  LA    BBOXREG,TWELVE(BBOXREG) GET ADDR SECOND BBOX         LCS 54500021
.SPNOLCS   ANOP                                                         54550021
         BR    RETREG2             RETURN,   BBOX IN REGA               54600021
         SPACE 2                                                        54650021
SPFREEM  EQU   *   INSURE THAT THE AREA TO FREE BEGINS IN BBOX .        54700021
         LR    WORKREGA,FREEADDR . SET UP FOR SPCKPARM                  54750021
         LM    SPLOW,SPHI,LOWADDR0(BBOXREG) . GET HIER=0 LOW,HI         54800021
         BAL   RETREG,SPCKPARM .  GO CHECK IF FREEADDR IS IN HIER=0     54850021
         B     ZERO(RETREG2) .     YES,RETURN WITH HIER0BBOX            54900021
         AIF   (NOT &LCS).SPFRH0                                        54950021
*  FREEAREA NOT IN HIER=0,TRY HIER=1                                LCS 55000021
         LM    SPLOW,SPHI,LOWADDR1(BBOXREG) . GET HIER=1 LOW,HI     LCS 55050021
         BAL   RETREG,SPCKPARM .  GO CHECK IF FREEADDR IS IN HIER=1 LCS 55100021
         B     SPGETH1 .          YES,GO GET HIER=1BBOX             LCS 55150021
         MVC   BBLCS(ONE,BBOXREG),LCSFLGSV .RESTORE FLAG            LCS 55200021
.SPFRH0  ANOP                                                           55250021
         SPACE 5                                                        55300021
SPSTEAL  EQU *                                                          55350021
***  THE FOLLOWING CODE WILL COVER THE STEAL CORE CONDITION             55400021
***  IN WHICH EXIT WANTS TO FREE THE SVRB. THE SVRB IS FREED            55450021
***  BY ZEROING THE SVRBSIZE BYTE.                                      55500021
         TM    SVCOPSW+1,SUPVSTAT+KEYF .IS REQ KEY0 AND SUPV STATE      55550021
         BNZ   AB90X2 .           NO                                    55600021
         L     WORKREGA,VCSVRBS . GET ADDR STEAL CORE POOL              55650021
         CL    REG4,STEALUSR(WORKREGA) .IS REQUESTOR THE STEALOR        55700021
         BNE   AB90X2 .           NO                                    55750021
         CLR   FREEADDR,WORKREGA .IS AREA TO FREE LT 1ST SVRB           55800021
         BL    AB90X2 .           NO                                    55850021
         LA    WORKREGA,SVRB3(WORKREGA) .GET ADDR LAST SVRB             55900021
         CLR   FREEADDR,WORKREGA .IS AREA TO FREE GT 3RD SVRB           55910021
         BH    AB90X2 .                  NO                             55950021
         MVI   RBSIZE(FREEADDR),ZERO .FREE THE SVRB                     56000021
         L     REG15,FRSAV15 .     RESTORE USER'S REG 15                56100021
         BR    REG14 .            GO TO SVC TYPE 1 EXIT                 56150021
         TITLE 'FQECHECK SUBROUTINE'                                    56200021
         AGO .AMS6                                                      56250021
*/*FQECHECK: CHART  FQE VALIDITY CHECK ROUTINE */                       56300021
*/*FQECHECK: E ENTRY */                                                 56350021
*/*    D  (YES,,NO,FQEBAD) IS SIZE MULTIPLE OF 8 */                     56400021
*/*    D  (YES,,NO,FQEBAD) IS HIGH BYTE OF SIZE=0 */                    56450021
*/*    P  UPPER BOUND= SIZE OF FQE + ADDR FQE */                        56500021
*/*    D  (YES,FQEBAD,NO,) IS UPPER BOUND GT OR EQ LAST FQE */          56550021
*/*    D  (YES,,NO,FQEBAD) IS FQE PTR ON DOUBLE WORD*/                  56600021
*/*    D  (YES,,NO,FQEBAD) IS HIGH BYTE OF FQEPTR =0*/                  56650021
*/*    D  (YES,,NO,FQEBAD) IS FQEPTR LT ADDR FQE */                     56700021
*/*    D  (YES,,NO,%FQ1) IS FQEPTR LT BOTTOM OF BBOX*/                  56750021
*/*    D  (YES,,NO,FQEBAD) IS FQEPTR = 0 */                             56800021
*/*%FQ1: R  RETURN */                                                   56850021
*/*FQEBAD: P ZERO FQEPTR IN PREVIOUS FQE TO TERMINATE CHAIN*/           56900021
*/*        P  PUT 60X-2 INFO IN BUFFER*/                                56950021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           57000021
*/*FQECHECK: END*/                                                      57050021
.AMS6    ANOP                                                           57100021
*---------------------------------------------------------------------  57150021
* FQECHECK  IS A SUBROUTINE WHICH VALIDITY CHECKS THE FQES. THE  *      57200021
*           INPUT IS: FQE TO CHECK IN REG7,THE PREVIOUS FQE    *        57250021
*           IN REG9 AND THE LOWEST VALID ADDR IN REG8.      *           57300021
*           OUTPUT IS: ADDR OF NEXT FQE IN CHAIN IN REG 11.             57350021
*---------------------------------------------------------------------  57400021
         SPACE 3                                                        57450021
         DS 0F                                                          57500021
FQECHECK EQU   *                                                        57550021
         CLI   FQELNGTH(CURFQREG),ZERO IS HIGH BYTE OF SIZE=0           57600021
         BNE   FQEBAD              NO, ERROR                            57650021
         TM    FQELNGTH+3(CURFQREG),SEVEN .IS SIZE MULT OF 8            57700021
         BNZ   FQEBAD .           NO, BAD FQE                           57750021
*    CHECK  IF SIZE  IS =0                                              57800021
         NC    FQELNGTH+1(THREE,CURFQREG),FQELNGTH+1(CURFQREG)          57850021
         BZ    FQEBAD .           NO SIZE=0                             57900021
         LR    WORKREGA,CURFQREG       SAVE FQE ADDR                    57950021
         A     WORKREGA,FQELNGTH(WORKREGA) GET UPPER BOUND              58000021
         CR    WORKREGA,LSTFQREG       IS UPPERBND GT OR EQ LASTFQE     58050021
         BNL   FQEBAD              YES, ERROR                           58100021
         TM    FQEPTR+3(CURFQREG),SEVEN IS FQE ON DOUBLEWORD            58150021
         BNZ   FQEBAD              NO, ERROR                            58200021
         CLI   FQEPTR(CURFQREG),ZERO IS HI BYTE OF FQEPTR=0             58250021
         BNE   FQEBAD              NO                                   58300021
         L     NXTFQREG,FQEPTR(CURFQREG)  GET NEXT FQE                  58350021
         CR    NXTFQREG,CURFQREG   IS NEXT FQE LESS THAN CURRENT        58400021
         BNL   FQEBAD              NO, ERROR                            58450021
         CR    NXTFQREG,LOWBBREG    IS NEXT FQE LESS OR EQ TO LOW BBOX  58500021
         BCR   10,RETREG          NO, RETURN                            58550021
         LTR   NXTFQREG,NXTFQREG   IS NEXT FQE=0                        58600021
         BCR   EIGHT,RETREG        YES, RETURN                          58650021
         SPACE 3                                                        58700021
FQEBAD   EQU   *                                                        58750021
         CL    CURFQREG,BBFQE(BBOXREG) .IS 1ST FQE BAD                  58800021
         BNE   FQZERPTR .        NO                                     58850021
         LR    LSTFQREG,BBOXREG .  SET LAST TO BBOX                     58900021
FQZERPTR XC    FQEPTR(FOUR,LSTFQREG),FQEPTR(LSTFQREG)  ZERO FORWARD    *58950021
                                   PTR IN LAST RQE TO END BAD CHAIN     59000021
         B     AB60X2                                                   59050021
         TITLE 'FREECORE SUBROUTINE'                                    59100021
         AGO .AMS7                                                      59150021
*/*FREECORE: CHART */                                                   59200021
*/*FREECORE: E ENTRY */                                                 59250021
*/*    P  ROUND SIZE TO DOUBLEWORD*/                                    59300021
*/*    D  (YES,,NO,%FR1) IS SIZE TO FREE = 0 */                         59350021
*/*    R  RETURN */                                                     59400021
*/*%FR1: D   (YES,FRGQETST,NO,) IS GQE SWITCH ON */                     59450021
*/*FRCKSIZ:    D  (YES,,NO,%FR2) IS SIZE=0 AFTER GQESEARCH*/            59500021
*/*    R  RETURN */                                                     59550021
*/*%FR2: P GET TOP OF PARTITION & ADDR 1ST FQE */                       59600021
*/*    D  (YES,FR1STNEW,NO,)  IS ALL CORE ALLOC (1ST FQE=0)*/           59650021
*/*    S  FQECHECK:VALIDITY CHECK 1ST FQE */                            59700021
*/*    D  (YES,,NO,FRNEXTFQ) IS ADDR OF AREA TO FREE GT 1ST FQE */      59750021
*/*    D  (>,ABA0X,=,FRUP1SIZ,<,)                                       59800021
*/*            COMPARE END OF FQE WITH ADDR TO FREE */                  59850021
*/*FR1STNEW: P NEW FQEPTR= ADDR CURRENT FQE, NEW FQESIZE= SIZE OF REQ*/ 59900021
*/*          P BBOX FQE = ADDR OF AREA TO FREE */                       59950021
*/*    R  RETURN */                                                     60000021
*/*ABA0X: P  PUT A0X INFO IN BUFFER*/                                   60050021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           60100021
*/*FRUP1SIZ: P ADD REQUEST SIZE TO SIZE OF 1ST FQE */                   60150021
*/*    R  RETURN */                                                     60200021
*/*FRNEXTFQ: D (YES,FRNEWLOW,NO,) IS NEXT FQE  ADDR=0*/                 60250021
*/*    S  FQECHECK:VALIDITY CK NEXT FQE */                              60300021
*/*    D  (YES,,NO,FRNEXTFQ) IS ADDR OF AREA TO FREE GT CURRENT FQE*/   60350021
*/*    D  (>,ABA0X,=,FRADDSIZ,<,)                                       60400021
*/*            COMPARE END OF FQE WITH ADDR AREA TO FREE*/              60450021
*/*    P  NEW FQESIZE= SIZE OF REQUEST */                               60500021
*/*    P  NEW FQEPTR= ADDR CURRENT FQE*/                                60550021
*/*   P  (,FRBACKPT)    NEW FQE = CURRENT FQE */                        60600021
*/*FRADDSIZ: P  ADD SIZE OF REQUEST TO SIZE OF CURRENT FQE */           60650021
*/*FRBACKPT: P (>,ABA0X,=,FRBIGFQE,<,)                                  60700021
*/*            COMPARE END OF NEW FQE WITH ADDR PREVIOUS FQE */         60750021
*/*    P  PREVIOUS FQE PTR= NEW FQE */                                  60800021
*/*    R  RETURN */                                                     60850021
*/*FRBIGFQE: P ADD SIZE OF PREVIOUS FQE TO NEW FQE */                   60900021
*/*    P  DROP PREVIOUS FQE FROM CHAIN */                               60950021
*/*    R  RETURN */                                                     61000021
*/*FRNEWLOW: P (>,ABA0X,<,FRBLDLOW,=,)                                  61050021
*/*            COMPARE END OF AREA TO FREE WITH CURRENT FQE*/           61100021
*/*    P LAST FQEPTR= ADDR AREA TO FREE */                              61150021
*/*    P NEW FQEPTR=0 ,NEW FQESIZE= REQUEST SIZE+ CURRENT FQESIZE*/     61200021
*/*    R  RETURN */                                                     61250021
*/*FRBLDLOW: P  NEW FQEPTR= 0, CURRENT FQEPTR= ADDR AREA TO FREE*/      61300021
*/*    P  NEW FQESIZE = REQUESTED SIZE */                               61350021
*/*    R  RETURN */                                                     61400021
*/*FRGQETST: D  (YES,%FRDAU,NO,) IS REQUESTOR = JOBSTEP*/               61450021
*/* S GQESRCH:SEARCH FOR GQE ON REQUESTOR'S TCB BBOX */                 61500021
*/*    D  (YES,FRCKSIZ,NO,) WAS GQE FOUND */                            61550021
*/*%FRDAU:    S  (,FRCKSIZ) GQESRCH:                                    61600021
*/*      SEARCH DOWN  TCBS IN TCB TREE FOR GQE */                       61650021
*/*FREECORE: END*/                                                      61700021
.AMS7    ANOP                                                           61750021
*---------------------------------------------------------------------  61800021
* INPUT TO FREECORE IS: THE ADDR OF AREA TO BE FREED IN REG 13          61850021
*                     : THE SIZE TO FREE IN REG 15                      61900021
*---------------------------------------------------------------------  61950021
         SPACE 3                                                        62000021
         DS 0F                                                          62050021
FREECORE EQU *                                                          62100021
         LA    FREESIZE,SEVEN(FREESIZE) .    ROUND UP BY 7              62150021
         SRL   FREESIZE,THREE CLEAR THE ROUND                           62200021
         SLL   FREESIZE,THREE .    UP BITS                              62250021
          LTR    FREESIZE,FREESIZE . IS LENGTH TO BE FREED=0            62300021
          BCR    EIGHT,RETREG2 .   YES, RETURN                          62350021
         AIF   (NOT &ATT).FREECO1                                       62400021
         SPACE 2                                                        62450021
*** A DESIGN CHANGE WAS  MADE(APAR 56028) TO ALLOW PROBLEM PGM   A56028 62500021
*** AS WELL AS SUPERVISOR TO FREE GQES.....THUS  AVOIDING THE    A56028 62510021
*** 90A'S AND A0A'S.                                             A56028 62520021
         TM    SWITCHES,SQSREQ .    IS REQUEST FOR SQS           A56028 62550021
         BZ    FRGQETST .          NO                            A56028 62600021
FRCKSIZ  LTR   FREESIZE,FREESIZE . IS SIZE=0 AFTER GQESEARCH        ATT 62650021
         BCR   EIGHT,RETREG2 .    YES,RETURN                        ATT 62700021
.FREECO1 ANOP                                                           62750021
         SPACE 3                                                        62800021
**** SEARCH FOR FQES ABOVE AND BELOW ADDRESS OF AREA TO FREE            62850021
         SPACE 1                                                        62900021
* INITIALIZE CURFQREG WITH 1ST FQE ADDR, LSTFQREG WITH TOP PARTITION    62950021
*            ADDRESS+1, AND LOWBBREG WITH BOTTOM PARTITION ADDR.        63000021
         LM    CURFQREG,LSTFQREG,BBLCS(BBOXREG) .INIT REGS FROM BBOX    63050021
         LA    LSTFQREG,ONE(LSTFQREG) .TOP BOUNDS=HIGH ADDR+1           63100021
         LA    WORKREGA,ZERO(FREESIZE,FREEADDR) . END OF FREE   SA75913 63110029
         CLR   WORKREGA,LSTFQREG  .  IS END IN FREE CORE        SA75913 63120029
         BNL   AB60X1             .  IF YES GO TO ERROR         SA75913 63130029
         LTR   CURFQREG,CURFQREG . IS ALL CORE ALLOCATED                63150021
         BZ    FR1STNEW .          YES, GO BUILD IST FQE                63200021
         BAL   RETREG,FQECHECK .   GO VALIDITY CHECK 1ST FQE            63250021
        LR    LSTFQREG,BBOXREG .  INIT LST IN CASE OF 1ST FQE CHANGED   63300021
         CLR   FREEADDR,CURFQREG . IS ADDR TO FREE GT 1ST FQE           63350021
         BL    FRNEXTFQ .          NO, GO GET NEXT FQE                  63400021
         SPACE 3                                                        63450021
***THE FQES HAVE BEEN FOUND WHICH SURROUND AREA TO FREE                 63500021
         SPACE 1                                                        63550021
* THE AREA TO BE FREE LIES BETWEEN BBOX AND 1ST FQE *                   63600021
         LR    WORKREGA,CURFQREG .  GET CURRENT FQE ADDR                63650021
         A     WORKREGA,FQELNGTH(CURFQREG) .GET BEGIN ALLOC AREA        63700021
         CLR   WORKREGA,FREEADDR .  IS AREA TO FREE IN ALLOC AREA       63750021
         BH    ABA0X .            NO, AREA TO FREE IN FQE -A0A          63800021
         BE    FRUP1SIZ .          YES, FROM BEGIN OF ALLOC AREA *      63850021
* BUILD NEW FQE PTR AND CHAIN FROM BBOX *                               63900021
FR1STNEW ST    CURFQREG,FQEPTR(FREEADDR) .BUILD 1ST WORD FQE            63950021
         ST    FREESIZE,FQELNGTH(FREEADDR) .     BUILD 2ND WORD         64000021
         ST    FREEADDR,BBLCS(BBOXREG) .UPDATE BBOX FQE                 64050021
.FRRTN   ANOP                                                           64100021
         BR    RETREG2 .           RETURN TO PROLOGUE                   64150021
FRUP1SIZ A     FREESIZE,FQELNGTH(CURFQREG) . INCREASE 1ST FQE SIZE      64200021
         ST    FREESIZE,FQELNGTH(CURFQREG) . STORE INCREASED SIZE       64250021
         BR    RETREG2 .           RETURN TO PROLOGUE                   64300021
         SPACE 1                                                        64350021
FRNEXTFQ LTR   NXTFQREG,NXTFQREG . IS NEXT FQE ADDR=0                   64400021
         BZ    FRNEWLOW .          YES                                  64450021
         LR    LSTFQREG,CURFQREG . UPDATE LAST FQE                      64500021
         LR    CURFQREG,NXTFQREG . UPDATE CURRENT FQE                   64550021
         BAL   RETREG,FQECHECK .   GO VALIDITY CHECK NEXT FQE           64600021
         CLR   FREEADDR,CURFQREG . IS ADDR TO FREE GT CURRENT FQE       64650021
         BL    FRNEXTFQ .     NO, CONTINUE FQE SCAN                     64700021
         SPACE 1                                                        64750021
* AREA TO FREE IS BETWEEN CURRENT AND PREVIOUS FQE *                    64800021
         LR    WORKREGA,CURFQREG . GET CURRENT FQE                      64850021
         A     WORKREGA,FQELNGTH(CURFQREG) . GET BEGIN ALLOC AREA       64900021
         CLR   WORKREGA,FREEADDR . IS AREA TO FREE IN ALLOC AREA        64950021
         BH    ABA0X .            NO, AREA TO FREE IN FREE AREA         65000021
         BE    FRADDSIZ .          YES, AREA BEGINS AFTER FQE           65050021
* BUILD NEW FQE BETWEEN CURRENT AND LAST FQES *                         65100021
         ST    FREESIZE,FQELNGTH(FREEADDR) . BUILD 2ND WORD OF FQE      65150021
         ST    CURFQREG,FQEPTR(FREEADDR) . BUILD 1ST WORD OF FQE        65200021
         LR    CURFQREG,FREEADDR .                                      65250021
         B     FRBACKPT .                                               65300021
* ADD AREA TO FREE TO THE CURRENT FQE *                                 65350021
FRADDSIZ AR    WORKREGA,FREESIZE  .  ADD NEW FREE SPACE         SA75913 65360029
         CLR   WORKREGA,LSTFQREG  .  OVERLAP WITH PREVIOUS FQE  SA75913 65370029
         BH    ABA0X              .  IF YES, GO TO ERROR        SA75913 65380029
         A     FREESIZE,FQELNGTH(,CURFQREG) . AD INCR TO CURFQE SA75913 65400029
         ST    FREESIZE,FQELNGTH(CURFQREG) . SAVE FQE INCR SIZE         65450021
* CHECK TO SEE IF AREA TO FREE JOINS PREVIOUS FQE *                     65500021
FRBACKPT LR    WORKREGA,CURFQREG .  GET CURRENT FQE FOR ADD             65550021
         A     WORKREGA,FQELNGTH(CURFQREG) .GET END OF FREED AREA       65600021
         CLR   WORKREGA,LSTFQREG .  DOES AREA TO FREE JOIN PREV FQE     65650021
         BH    ABA0X .            NO, OVERLAPS INTO PREV FQE            65700021
         BE    FRBIGFQE .          YES, MEETS EXACTLY                   65750021
* AREA TO FREE DOESN'T MEET PREVIOUS FQE                                65800021
         ST    CURFQREG,FQEPTR(LSTFQREG) .PREV FQEPTR= AREA FREED       65850021
         BR    RETREG2 .           RETURN TO PROLOGUE                   65900021
         SPACE 1                                                        65950021
* AREA TO FREE JOINS PREV FQE. ADD JOINED SIZE TO AREA TO BE FREED, *   66000021
* DROP PREV FQE FROM CHAIN, AND ADJUST FQEPTR IN FQE BEFORE PREVFQE *   66050021
FRBIGFQE L     WORKREGA,FQELNGTH(CURFQREG) .GET SIZE CURRENT FQE        66100021
         A     WORKREGA,FQELNGTH(LSTFQREG) .ADD SIZE PREV FQE JOIN      66150021
         ST    WORKREGA,FQELNGTH(CURFQREG) .STORE JOINED SIZE           66200021
        LR     WORKREGA,BBOXREG .   GET ADDR BBOX                       66250021
FRGETNXT CL    LSTFQREG,FQEPTR(WORKREGA) . IS FORWARD PTR=DROP FQE      66300021
         BE    FRDROPFQ .          YES                                  66350021
         L     WORKREGA,FQEPTR(WORKREGA) .GET NEXT FQE                  66400021
         B     FRGETNXT .               KEEP LOOKING FOR FQE            66450021
FRDROPFQ ST    CURFQREG,FQEPTR(WORKREGA) .DROP PREV FQE FROM CHAIN      66500021
         BR    RETREG2 .           RETURN TO PROLOGUE                   66550021
         SPACE 1                                                        66600021
FRNEWLOW EQU   *                                                        66650021
* BUILD OR JOIN NEW FQE BELOW LAST FQE ON CHAIN ***                     66700021
         LR    WORKREGA,FREESIZE . GET SIZE                             66750021
        AR     WORKREGA,FREEADDR . GET END OF AREA TO FREE              66800021
         CR    WORKREGA,CURFQREG . DOES AREA TO FREE MEET CURFQE        66850021
         BL    FRBLDLOW .         NO BUILD NEW LAST FQE ON CHAIN        66900021
        BH    ABA0X .         GT, OVERLAPS INTO CUR FQE                 66950021
* COMBINE NEW FQE WITH LAST FQE ON CHAIN,DROP LAST FROM CHAIN **        67000021
         ST    FREEADDR,FQEPTR(LSTFQREG) .DROP LAST FROM CHAIN          67050021
         MVC   FQEPTR(FOUR,FREEADDR),FQEPTR(CURFQREG) .1ST NEW WORD     67100021
         A     FREESIZE,FQELNGTH(CURFQREG) .NEW SIZE=CUR+NEW SIZE       67150021
         ST    FREESIZE,FQELNGTH(FREEADDR) .2ND WORD NEW FQE            67200021
        BR     RETREG2 .          RETURN TO PROLOUGE                    67250021
         SPACE 1                                                        67300021
* BUILD NEW FQE BELOW LAST FQE ON CHAIN ***                             67350021
FRBLDLOW MVC   FQEPTR(FOUR,FREEADDR),FQEPTR(CURFQREG) .1ST WORD NEW     67400021
         ST    FREEADDR,FQEPTR(CURFQREG) .CHAIN CUR TO NEW              67450021
         ST    FREESIZE,FQELNGTH(FREEADDR) .2ND WORD NEW FQE            67500021
         BR    RETREG2 .          RETURN TO PROLOGUE                    67550021
         AIF   (NOT &ATT).FRCOEND                                       67600021
         SPACE 3                                                        67650021
**** THIS CODE LOADS REG 7 WITH THE TCB ADDR FOR GQESRCH TO USE         67700021
****IN SEARCHING DOWN THE GQE CHAIN  FOR THE GQE DESCRIBING THE         67750021
****AREA BEING FREED.                                                   67800021
         SPACE 1                                                        67850021
FRGQETST EQU   *                                                    ATT 67900021
         LR    FRCURTCB,REG4 .     GET REQUESTING SUBTASK           ATT 67950021
         CL    REG4,TCBFTJST(REG4) . IS REQUESTOR JOBSTEP           ATT 68000021
         BE    FRGSVCUR .        YES, SKIP CURRENT TCB SEARCH       ATT 68050021
         BAL   RETREG,GQESRCH .    GO SEE IF GQE IS FOR REQ SUBTASK ATT 68100021
         B     FRCKSIZ .          YES, GQES ADJUSTED, GO CK FQES    ATT 68150021
         L     FRCURTCB,TCBFTJST(FRCURTCB) .CURR TCB= JOBSTEP       ATT 68200021
*  BEGINNING WITH JOBSTEP'S 1ST DAUGHTER, SEARCH DOWN COMPLETE      ATT 68250021
*  FAMILY TCB TREE FOR EACH OF JOBSTEP'S DAUGHTERS FOR THE GQE      ATT 68300021
*  DESCRIBING THE AREA TO BE FREED.                                 ATT 68350021
FRGSVCUR LR    FRLSTCB,FRCURTCB .  SAVE CURRENT TCB IN LAST TCB     ATT 68400021
         L     FRCURTCB,TCBLTC(FRLSTCB) .GET DAUGHTER IN CUR TCB    ATT 68450021
FRGETDAU LTR   FRCURTCB,FRCURTCB . ANY DAUGHTERS ?                  ATT 68500021
         BNZ   FRGCKDAU .          YES. GO SEARCH DAUGHTER GQES     ATT 68550021
         L     FRCURTCB,TCBNTC(FRLSTCB) .CURR TCB=SISTER            ATT 68600021
         C     FRLSTCB,TCBFTJST(FRLSTCB) .IS THIS LAST TCB          ATT 68650021
         BE    FRCKSIZ .          YES,END TCB SEARCH                ATT 68700021
         L     FRLSTCB,TCBOTC(FRLSTCB) .LOAD MOTHER OF LAST TCB     ATT 68750021
         B     FRGETDAU .          GO GET DAUGHTER                  ATT 68800021
FRGCKDAU BAL   RETREG,GQESRCH .                                     ATT 68850021
         B     FRCKSIZ .          GQE FOUND, GO CHECK FQES          ATT 68900021
         B     FRGSVCUR .          GQE NOT FOUND, TRY AGAIN         ATT 68950021
         TITLE 'GQESRCH SUBROUTINE'                                     69000021
         AGO   .AMS8                                                    69050021
*/*GQESRCH: CHART */                                                    69100021
*/*GQESRCH: E ENTRY */                                                  69150021
*/*    P  GET ADDR DUMMY BBOX AND ADDR 1ST FQE */                       69200021
*/*%GQ:  D  (YES,%GQ1,NO,) IS HIGH BYTE GQEPTR=0*/                      69250021
*/*AB60X3: P  ZERO GQE PTR IN PREVIOUS GQE TO CLEAN UP CHAIN*/          69300021
*/*     P  PUT 60X-3 INFO IN BUFFER */                                  69350021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           69400021
*/*%GQ1:  D  (YES,,NO,AB60X3) IS GQEPTR ON DOUBLE WORD BDY*/            69450021
*/*    D  (YES,,NO,AB60X3) IS HIGH BYTE OF GQESIZE=0*/                  69500021
*/*    D  (YES,,NO,AB60X3) IS GQESIZE A MULTIPLE OF 8 */                69550021
*/*    D  (YES,,NO,AB60X3) IS GQE IN BOUNDS OF JOBSTEP BBOX*/           69600021
*/*    D  (YES,GQCKUPBD,NO,) IS ADDR AREA TO FREE GT GQE ADDR*/         69650021
*/*GQNXTGQE: P (,GQCKLAST) GET NEXT GQE */                              69700021
*/*GQCKUPBD:   D  (YES,,NO,GQNXTGQE) IS ADDR AREA TO FREE LT GQE END*/  69750021
*/*    D  (YES,AB90X3,NO,) IS ADDR TO FREE IN GQE BLOCK*/               69800021
*/*    D  (YES,AB90X3,NO,) IS END OF AREA TO FREE GT END OF GQE*/       69850021
*/*    D  (YES,,NO,GQCKPART) IS ENTIRE GQE BEING FREED*/                69900021
*/*    P  DROP GQE FROM CHAIN*/                                         69950021
*/*    P  ADDR AREA TO FREE=BEGIN GQE, SIZE TO FREE= SIZE+8*/           70000021
*/*    R  RETURN FOUND */                                               70050021
*/*GQCKPART: D (YES,,NO,GQMID) IS ADDR AREA TO FREE AT BEGIN OF GQE*/   70100021
*/*    P  ADDR AREA TO FREE= BEGIN OF GQE*/                             70150021
*/*    P  BUILD NEW GQE AT END OF AREA TO FREE */                       70200021
*/*    R  RETURN FOUND */                                               70250021
*/*GQCKLAST: D (YES,,NO,%GQ) IS THIS END OF GQES*/                      70300021
*/*    R  RETURN NOT FOUND */                                           70350021
*/*GQMID: D  (YES,,NO,GQNEWGQ) IS END OF AREA TO FREE = END OF GQE*/    70400021
*/*    P  GQESIZE = GQESIZE - LENGTH OF AREA TO FREE */                 70450021
*/*    R  RETURN FOUND*/                                                70500021
*/*GQNEWGQ: P   SIZE TO FREE= SIZE TO FREE-8 */                         70550021
*/*    P  BUILD NEW GQE AT ADDR AREA TO FREE+ SIZE */                   70600021
*/*    P  ADJUST CURRENT GQE*/                                          70650021
*/*    R  RETURN FOUND*/                                                70700021
*/*AB90X3:  P  PUT 90X-3 INFO IN BUFFER*/                               70750021
*/*    R  ERROR EXIT TO ABTSETUP SUBROUTINE*/                           70800021
*/*GQESRCH: END*/                                                       70850021
.AMS8    ANOP                                                           70900021
*---------------------------------------------------------------------  70950021
*        GQESRCH SEARCHES DOWN THE GQE CHAIN OF THE TCB PASSED IN  ATT  71000021
*        REG7.  REG 11 IS USED AS THE GQE ADDR.  IF THE GQE IS     ATT  71050021
*        FOUND,ADJUST THE GQES TO ACCOUNT FOR THE AREA FREED       ATT  71100021
*        AND RETURN+0 TO FREECORE.  IF NOT FOUND, RETURN+4.        ATT  71150021
*---------------------------------------------------------------------  71200021
         SPACE 2                                                        71250021
         DS  0F                                                         71300021
GQESRCH  EQU   *                                                    ATT 71350021
         L     GQDUMBBX,TCBMSS(GQCURTCB) .GET ADDR DUMMY BBOX       ATT 71400021
         L     GQEREG,GQEPTR(GQDUMBBX) .GET ADDR 1ST GQE            ATT 71450021
         LTR   GQEREG,GQEREG .IS GQE CHAIN EMPTY                    ATT 71500021
         BZ    FOUR(RETREG) .YES,RETURN NOT FOUND                   ATT 71550021
         C     GQEREG,GQEPTR(GQEREG) . GQE CHAINED TO ITSELF   @SA71329 71560021
         BE    GQEBAD .            YES                         @SA71329 71570021
         ST    GQDUMBBX,SAVEGQE .  INIT ADDR LAST GQE               ATT 71600021
         CLI   GQEPTR(GQDUMBBX),ZERO .  IS HI BYTE ADDR=0           ATT 71650021
         BNZ   GQEBAD .         NO,ERROR                            ATT 71700021
         TM    GQEPTR+3(GQDUMBBX),SEVEN . IS 1ST GQE ON DBLEWD      ATT 71750021
         BNZ   GQEBAD .        NO,ERR                               ATT 71800021
GQCKLAST LTR   GQEREG,GQEREG .     IS THIS LAST GQE                 ATT 71850021
         BZ    FOUR(RETREG) .      YES, RETURN NOT FOUND            ATT 71900021
         SPACE 2                                                        71950021
* VALIDITY CHECK THE GQE *                                          ATT 72000021
         CLI   GQEPTR(GQEREG),ZERO . IS HI BYTE PTR=0               ATT 72050021
         BNZ   GQEBAD .         NO,ERR                              ATT 72100021
         TM    GQEPTR+3(GQEREG),SEVEN .IS GQE PTR ON DBLEWD         ATT 72150021
         BNZ   GQEBAD .         NO,ERR                              ATT 72200021
         L     GQWORK1,GQESIZE(GQEREG) .GET GQE LENGTH              ATT 72250021
         LTR   GQWORK1,GQWORK1 .   IS LENGTH ZERO              @SA71329 72260021
         BZ    GQEBAD .            YES                         @SA71329 72270021
         CLI   GQESIZE(GQEREG),ZERO . IS HI BYTE OF SIZE=0          ATT 72300021
         BNZ   GQEBAD .         NO,ERR                              ATT 72350021
         TM    GQESIZE+3(GQEREG),SEVEN . IS SIZE A MULTIPLE OF 8    ATT 72400021
         BNZ   GQEBAD .         NO,ERR                              ATT 72450021
         AR    GQWORK1,GQEREG .    GET GQE UPPER BOUNDS             ATT 72500021
         AIF   (&LCS).GQCKBTH                                           72510021
         CL    GQWORK1,BBHI(BBOXREG) .GQE GT HIGHEST ADDR PARTIT?   ATT 72550021
         BH    GQEBAD .          YES                                ATT 72600021
         CL    GQEREG,BBLOW(BBOXREG) .GQE LT LOWEST ADDR IN PARTIT? ATT 72650021
         BNL    GQEGOOD .          YES                              ATT 72700021
         AGO   .GQEBAD                                                  72710021
.GQCKBTH ANOP                                                           72720021
         L     GQWORK3,TCBFTJST(REG4) .GET  JOBSTEP TCB           M4913 72730021
         L     GQWORK3,TCBMSS(GQWORK3) .GET ADDR  BBOX            M4913 72740021
         CL    GQWORK1,HIADDR0(GQWORK3) .GQE GT HIGH ADDR HIER0?  M4913 72742021
         BH    GQCKBB2 .  YES,GO CK 2ND BBOX                      LCATT 72744021
         CL    GQEREG,LOWADDR0(GQWORK3) .GQE LT LOW ADDR HIER0?   M4913 72746021
         BNL   GQEGOOD .GQE IS HIER0 BOUNDS                       LCATT 72748021
GQCKBB2  CL    GQWORK1,HIADDR1(GQWORK3) .GQE GT HIGH ADDR HIER1?  M4913 72748421
         BH    GQEBAD .GQE IS INVALID                             LCATT 72748821
         CL    GQEREG,LOWADDR1(GQWORK3) .GQE LT LOW ADDR HIER1?   M4913 72749221
         BNL   GQEGOOD .GQE IS IN HIER1 BOUNDS                    LCATT 72749621
.GQEBAD  ANOP                                                           72749721
* THE GQE IS INVALID.  ZERO THE GQE PTR IN THE PREVIOUS GQE TO      ATT 72750021
* END THE CHAIN AT THE LAST VALID GQE.                              ATT 72800021
GQEBAD   L     GQWORK1,SAVEGQE .GET ADDR OF PREVIOUS GQE            ATT 72850021
         XC    GQEPTR(FOUR,GQWORK1),GQEPTR(GQWORK1) .ZERO GQE PTR   ATT 72900021
         B     AB60X3 .           GO SET UP 60X3 INFO               ATT 72950021
         SPACE 2                                                        73000021
* THE GQE HAS BEEN SUCESSFULLY VALIDITY CKECKED. *                  ATT 73050021
GQEGOOD  CLR   FREEADDR,GQEREG .  IS ADDR TO BE FREED GT GQE        ATT 73100021
         BE    GQEBAD .NO, ADDR TO FREE IS GQE BLOCK                ATT 73150021
         BH    GQCKUPBD .                                           ATT 73200021
GQNXTGQE EQU   *                                               @SA71329 73250021
         C     GQEREG,GQEPTR(GQEREG) . GQE CHAINED TO ITSELF   @SA71329 73260021
         BE    GQEBAD                                          @SA71329 73270021
         ST    GQEREG,SAVEGQE .    SAVE PREVIOUS GQE PTR       @SA71329 73280021
         L     GQEREG,GQEPTR(GQEREG) .  GET PTR TO NEXY GQE         ATT 73300021
         B     GQCKLAST .          GO CK FOR LAST GQE               ATT 73350021
* REG GQWORK1 CONTAINS GQE UPPER BOUND FROM GQE VALIDITY CHECK.     ATT 73400021
GQCKUPBD CLR   FREEADDR,GQWORK1 .  IS ADDR TO FREE LT END OF GQE    ATT 73450021
         BNL    GQNXTGQE .          NO, GO GET NEXT GQE             ATT 73500021
         LA     GQWORK2,EIGHT(GQEREG) .GET ADDR ALLOC AREA          ATT 73550021
         CLR    FREEADDR,GQWORK2 .IS ADDR TO FREE IN ALLOC AREA     ATT 73600021
         BL     AB90X3 .         NO,ADDR TO FREE IN GQE BLOCK       ATT 73650021
         LR     GQWORK2,FREEADDR .GET ADDR OF AREA TO FREE          ATT 73700021
         AR     GQWORK2,FREESIZE .GET END ADDR OF AREA TO FREE      ATT 73750021
         CLR    GQWORK2,GQWORK1 .IS END OF AREA TO FREE GT GQE END  ATT 73800021
         BH     AB90X3 .         YES TRYING TO FREE TOO MUCH        ATT 73850021
         SPACE 3                                                        73900021
* THE GQE HAS BEEN FOUND *                                          ATT 73950021
         LA    GQWORK1,EIGHT(FREESIZE) .GET AREA TO FREE+8          ATT 74000021
         CL    GQWORK1,GQESIZE(GQEREG) .IS ENTIRE GQE FREED         ATT 74050021
         BNE   GQCKPART .          NO                               ATT 74100021
         SPACE 2                                                        74150021
* ENTIRE GQE IS BEING FREED . DROP GQE FROM CHAIN AND ADJUST        ATT 74200021
*        FREEADDR AND FREESIZE BY 8. *                              ATT 74250021
         L     GQWORK1,SAVEGQE                                      ATT 74300021
         MVC   GQEPTR(FOUR,GQWORK1),GQEPTR(GQEREG) .                ATT 74350021
         LA    FREESIZE,EIGHT(FREESIZE) .UPDATE SIZE FOR GQE        ATT 74400021
         SH    FREEADDR,EIGHTDC .  UPDATE AREA TO FREE FOR GQE      ATT 74450021
         BR    RETREG .            RETURN TO FREECORE               ATT 74500021
         SPACE 2                                                        74550021
* PARTIAL GQE IS BEING FREED *                                      ATT 74600021
GQCKPART LR    GQWORK1,FREEADDR .  GET ADDR TO FREE                 ATT 74650021
         SR    GQWORK1,GQEREG .    GET LNGTH BEGIN GQE TO FREEADDR  ATT 74700021
         CH    GQWORK1,EIGHTDC .   IS SIZE=8                        ATT 74750021
         BNE   GQMID               NO, SIZE TO FREE IN MIDDLE       ATT 74800021
* THE GQE IS BEING FREED FROM THE BEGINNING. FREE GQE AT BEGINNING  ATT 74850021
* AND MOVE IT TO LAST 8 BYTES OF FREED AREA.                        ATT 74900021
         LR    FREEADDR,GQEREG .   NEW ADDR TO FREE=BEGIN GQE       ATT 74950021
         LR    GQWORK1,GQEREG .    GET GQE ADDR                     ATT 75000021
         AR    GQWORK1,FREESIZE .  GET ADDR NEW GQE                 ATT 75050021
         MVC   GQEPTR(FOUR,GQWORK1),GQEPTR(GQEREG) . INIT 1ST WORD  ATT 75100021
         L     GQWORK2,GQESIZE(GQEREG) .GET OLD GQE SIZE            ATT 75150021
         SR    GQWORK2,FREESIZE .  GET LENGTH NEW GQE               ATT 75200021
         ST    GQWORK2,GQESIZE(GQWORK1) .INIT 2ND WORD NEW GQE      ATT 75250021
         L     GQWORK2,SAVEGQE . GET ADDR PREVIOUS GQE              ATT 75300021
         ST    GQWORK1,GQEPTR(GQWORK2) .UPDATE PREV PTR             ATT 75350021
         BR    RETREG .            RETURN TO FREECORE               ATT 75400021
         SPACE 2                                                        75450021
* THE PARTIAL GQE TO FREE BEGINS IN THE MIDDLE OF THE GQE           ATT 75500021
GQMID    LR    GQWORK2,FREEADDR .  GET ADDR OF                      ATT 75550021
         AR    GQWORK2,FREESIZE .              END AREA TO FREE     ATT 75600021
         LR    GQWORK3,GQEREG .    GET ADDR OF                      ATT 75650021
         A     GQWORK3,GQESIZE(GQEREG) .       END OF GQE           ATT 75700021
         CLR   GQWORK2,GQWORK3 .   IS END AREA TO FREE=END GQE      ATT 75750021
         BNE   GQNEWGQ                                              ATT 75800021
* PARTIAL GQE ENDS AT GQE END. DECREMENT SIZE OF GQE.               ATT 75850021
         ST    GQWORK1,GQESIZE(GQEREG) .                            ATT 75900021
         BR    RETREG .            RETURN TO FREECORE               ATT 75950021
         SPACE 2                                                        76000021
GQNEWGQ  EQU   *              AREA TO FREE IS IN MIDDLE OF GQE      ATT 76050021
         SH    FREESIZE,EIGHTDC .  DECREMT SIZE FOR NEW GQE         ATT 76100021
         LR    GQWORK2,FREEADDR .  GET ADDR                         ATT 76150021
         AR    GQWORK2,FREESIZE .           OF NEW GQE              ATT 76200021
         MVC   GQEPTR(FOUR,GQWORK2),GQEPTR(GQEREG) .FORWARD CHAIN   ATT 76250021
         L     GQWORK3,GQESIZE(GQEREG) .                            ATT 76300021
         SR    GQWORK3,FREESIZE .  GET SIZE OF                      ATT 76350021
         SR    GQWORK3,GQWORK1 .               NEW GQE              ATT 76400021
         ST    GQWORK3,GQESIZE(GQWORK2) . INIT SIZE OF NEW GQE      ATT 76450021
         ST    GQWORK1,GQESIZE(GQEREG) .ADJUST CURR GQE SIZE        ATT 76500021
         ST    GQWORK2,GQEPTR(GQEREG) .ADJUST CURR GQE PTR          ATT 76550021
         BR    RETREG .            RETURN TO FREECORE               ATT 76600021
.FRCOEND ANOP                                                           76650021
         TITLE 'ABTSETUP SUBROUTINE'                                    76700021
         AGO .AMS9                                                      76750021
*/*ABTSETUP: CHART */                                                   76800021
*/*ABTSETUP: E ENTRY */                                                 76850021
*/*    P  FILL WORK BUFFER WITH PROBLEM DETERMINATION INFO*/            76900021
*/*    D  (YES,,NO,ABGETCC) ENTRY AVAILABLE IN IEAQMSG BUFFER*/         76950021
*/*    P  COPY WORK BUFFER TO IEAQMSG ENTRY */                          77000021
*/*ABGETCC:  P SET UP COMPLETION CODE IN REG1, TCB IN REG 0 */          77050021
*/*    R   GO TO ABTERM */                                              77100021
*/*ABTSETUP: END */                                                     77150021
.AMS9    ANOP                                                           77200021
****ABTERM INTERFACE AREA****                                           77250021
*---------------------------------------------------------------------  77300021
         SPACE 2                                                        77350021
ABNOCORE EQU   *                                                        77400021
* CHECK  IF REQUESTOR IS ABEND/ABTERM OR SVC FLIH                       77450021
         TM    TCBFLGS(REG4),X'A0' . HAS ABTERM BEEN ENTERED            77500021
         BCR   EIGHT,RETREG2   NO, NOT RECURSIVE ABEND         @SA66514 77550021
         L     ABWORK2,ZERO(REG4)   GET TOP RB                 @SA66514 77600021
         CLC   RBNAME+6(TWO,ABWORK2),SVC13ID IS ABEND REQUEST? @SA72568 77650029
         BE    ABRECUR .                                                77700021
         CLC   SVCOPSW+5(3),IEAATADD+1 .IS SVC FLIH GETTING ABEND SVRB  77750021
         BCR   SEVEN,RETREG2   NO, DON'T WANT STEAL CORE       @SA66514 77800021
ABRECUR   EQU   *                                                       77850021
         LA    REG15,FOUR .        SET RETURN CODE=4                    77900021
         AIF   (NOT &LCS).ABEXIT                                        77950021
         BAL   RETREG,COMMLCS .GO RESTORE LCS FLAG                  LCS 78000021
.ABEXIT  ANOP                                                           78050021
         BR    REG14 .             GO TO SVC TYPE 1 EXIT                78100021
         SPACE 4                                                        78150021
AB60X1 EQU   *  **PARM IS OUTSIDE USER'S CORE 60X-1ABEND                78200021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 78220021
         MVI   PDCOMPCD,X'06' .   SET 1ST BYTE COMP CODE                78250021
         MVI   PDRCNUM,X'24' .    REASONCODE=1,LENGTH=4                 78300021
         ST    REG1,PDVAR1 .      PUT ADDR PARMLIST IN VAR DATA 1       78350021
         B     ABFINISH .         GO FINISH                             78400021
         SPACE 3                                                        78450021
AB60X2 EQU   *         **** FQE INVALID- 60X-2 ABEND ***                78500021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 78520021
         MVI   PDRCNUM,X'50' .     REASON CODE=2,LNGTH=16               78550021
         CLI   SVCOPSW+3,SVC5 .   IS THIS SVC 5                         78600021
         BE   ABCKSP .           YES                                    78650021
         MVI   PDRCNUM,X'4C' .    REASON CODE=2,LNGTH=12                78700021
ABCKSP   MVI   PDCOMPCD,X'06' .    SET 1ST BYTE COMP CODE               78750021
         ST    CURFQREG,CLOBBERD . SAVE ADDR BAD FQE OR GQE             78800021
         CLI   SVCOPSW+3,SVC5 .    IS THIS SVC 5                        78850021
         BE    ABFQ5 .             YES                                  78900021
         MVC   PDVAR2(EIGHT),FQEPTR(CURFQREG) .PUT FQE IN VAR DATA2,3   78950021
         B     ABCKLCS .          GO FINISH BUFFER                      79000021
ABFQ5    ST    FREEADDR,PDVAR2 .  PUT ADDR TO FREE IN VAR DATA2         79050021
         MVC   PDVAR3(EIGHT),FQEPTR(CURFQREG) .PUT FQE IN VAR DATA3,4   79100021
         B     ABCKLCS .                                                79150021
         SPACE 3                                                        79200021
         AIF   (NOT &ATT).ABNOATT                                       79250021
AB60X3 EQU   *   ***GQE INVALID-60X-3 ABEND***                      ATT 79300021
         LR    CURFQREG,GQEREG . FQEREG=GQEREG FOR 604-2 CODE       ATT 79350021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 79370021
         MVI   PDRCNUM,X'70' .    FOR SVC5,REASONCODE=3,LNGTH=16    ATT 79400021
         CLI   SVCOPSW+3,SVC5 .   IS THIS SVC5                      ATT 79450021
         BE    ABCKSP .           YES                               ATT 79500021
         MVI   PDRCNUM,X'6C' .    REASON CODE=3,LNGTH=12            ATT 79550021
         B     ABCKSP .           GO USE 60X-2                      ATT 79600021
.ABNOATT ANOP                                                           79650021
         SPACE 3                                                        79700021
ABEND70X  EQU  *   ***LIST TYPE REQUEST  70X COMP CODE                  79750021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 79770021
         MVI   PDCOMPCD,X'07' .SET 1ST BYTE COMP CODE                   79800021
         MVI   PDRCNUM,X'04' .REASON CODE=0,LNGTH=4                     79850021
         ST    REG1,PDVAR1 .       1ST VARDATA=PARMLIST                 79900021
         B     ABFINISH .         GO FINISH BUFFER                      79950021
         SPACE 3                                                        80000021
AB80X1   EQU   *    ***  MAIN STORAGE NOT AVAILABLE  80X-1 ***          80050021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 80070021
         MVI   PDRCNUM,X'28' .     REASON CODE=1,LNGTH=8                80100021
AB80XX   MVI   PDCOMPCD,X'08' .    SET 1ST BYTE COMP CODE               80150021
         MVC   PDVAR2(FOUR),LARFQSIZ .VAR DATA2=LARGEST FQE             80200021
         B     ABCKLCS .          GO GET SUBPOOL                        80250021
         SPACE 3                                                        80300021
AB80X2   EQU   *   ***ZERO OR NEGATIVE SIZE SPECIFIED  80X-2 ABEND      80350021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 80370021
         MVI   PDCOMPCD,X'08' .   GET 1ST BYTE COMP CODE                80400021
         MVI   PDRCNUM,X'44' .    REASON CODE=2,LENGTH=4                80450021
         B     ABCKLCS .         GO FINISH BUFFER                       80500021
         SPACE 3                                                        80550021
AB90X1    EQU   *    ***AREA TO FREE NOT ON DBLEWORD BDY ***            80600021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 80620021
          MVI   PDRCNUM,X'28' . REASON CODE=1,LNGTH=8                   80650021
AB90XXX  MVI   PDCOMPCD,X'09' .   SET 1ST BYTE COMPLETION CODE          80700021
         ST    FREEADDR,PDVAR2 .PUT ADDR TO FREE IN DATA 2              80750021
         B     ABSPIDCK .     GO FINISH BUFFER                          80800021
         SPACE 3                                                        80850021
AB90X2   EQU    *    ***AREA TO FREE NOT IN USERS BBOX ***              80900021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 80920021
         MVI   PDRCNUM,X'48' .REASON CODE=2,LNGTH=8                     80950021
         B     AB90XXX .   GO USE 90X-1 CODE                            81000021
         SPACE 3                                                        81050021
         AIF (NOT &ATT).NO90X3                                          81100021
AB90X3   EQU *  ****AREA TO FREE GOES BEYOND GQE ****               ATT 81150021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 81170021
         MVI   PDRCNUM,X'6C'  REASON CODE=6,LNGTH=12              M5279 81200021
         MVI   PDCOMPCD,X'09' .SET 1ST BYTE COMP CODE               ATT 81250021
         ST    FREEADDR,PDVAR2 . VAR DATA 2 = ADDR AREA TO FREE     ATT 81300021
         ST    GQEREG,PDVAR3 .VAR DATA 3= GQE ADDR                M5279 81310021
         B     ABCKLCS          GO FINISH BUFFER                    ATT 81350021
.NO90X3  ANOP                                                           81400021
         SPACE 3                                                        81450021
ABA0X  EQU   *         **** AREA TO FREE RUNS INTO FQE -AOX ****        81500021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 81520021
         MVI   PDCOMPCD,X'0A' .    SET 10T BYTE COMP CODE               81550021
ABRC8    MVI   PDRCNUM,X'08' .     REASON CODE=0,LNGTH=8                81600021
         ST    FREEADDR,PDVAR2 .   PUT ADDR TO FREE IN VAR DATA2        81650021
         B     ABCKLCS .          GO FINISH BUFFER                      81700021
         SPACE 3                                                        81750021
ABB0X  EQU   * .      ****  SUBPOOL ID IS INVALID- BOX ABEND ****       81800021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 81820021
         MVI   PDCOMPCD,X'0B' .    SET 1ST BYTE COMPLET CODE            81850021
         CLI   SVCOPSW+3,SVC5 .    IS THIS SVC 5                        81900021
         BE    ABB0XFR .             YES                                81950021
         MVI   PDRCNUM,FOUR .      REASON CODE=0, LNGTH=4               82000021
         B     ABSPIDCK                                                 82050021
ABB0XFR  MVI   PDRCNUM,X'08' .REASON CODE=0,LNGTH=8                     82100021
         ST    FREEADDR,PDVAR2 . PUT ADDR TO FREE IN VAR DATA2          82150021
         B     ABSPIDCK .     GO FINISH BUFFER                          82200021
          SPACE 3                                                       82250021
ABTSTE04 EQU *    ***SQA STORAGE NOT AVAILABLE***                       82300021
         TM    SWITCHES,SQSREQ .IS REQUEST FOR SQS                M4914 82350021
         BZ    AB80X1 .          NO, NOT SQS E04                  M4914 82400021
         BAL   RETREG2,ABNOCORE CHECK FOR RECURSIVE ABEND 1ST  @SA66514 82470021
ABE04    MVC   PDCOMPCD(TWO),CCE04 .COMP CODE= E04                      82550021
         MVI   PDRCNUM,X'08' .REASON CODE=0 LENGTH=8                    82600021
         MVC   PDVAR2(FOUR),LARFQSIZ  . VAR DATA2= LARGEST FQE          82650021
         SPACE 5                                                        82700021
ABCKLCS EQU   *                                                         82750021
         AIF   (NOT &LCS).ABSPID                                        82800021
*** ERROR CODE 60X-1,60X-2,70X,90X-1,90X-2,B0X HAVE NOT ZEROED      LCS 82850021
*** THE LCS BOUNDARY BOX FLAG,SO DON'T BALR TO COMMLCS.             LCS 82900021
         BAL   RETREG,COMMLCS .GO RESTORE LCS FLAG                  LCS 82950021
.ABSPID  ANOP                                                           83000021
*  THE FOLLOWING CODE PUTS THE SUBPOOL ID AND LENGTH IS VAR DATA 1      83050021
ABSPIDCK CLI   SVCOPSW+3,SVC10 .  IS THIS REGMAIN                       83100021
         BNE   ABSVC45 .           NO                                   83150021
         ST    REG0,PDVAR1 .       GET SUBPOOL ID, LENGTH               83200021
         B     ABFINISH .         GO CONTINUE BUFFER FILL               83250021
ABSVC45  MVC   PDVAR1(1),SAVESPID . GET SUBPOOL ID                      83300021
         MVC   PDVAR1+1(3),GETLNGTH+1 .GET SUBPOOL LENGTH               83350021
ABFINISH EQU   *                                                        83400021
         CLI   PDCOMPCD,X'0E' .  IS THIS E04                            83450021
         BE    ABSTCB .          YES, COMP CODE DONE                    83500021
         MVC   PDCOMPCD+1(1),SVCOPSW+3 .GET SVC ID                      83550021
ABSTCB   ST    REG4,PDTCB .       PUT TCB IN BUFFER                     83600021
**  PROBLEM DETERMINATION CODE FOLLOWS IN WHICH IEAQMSG BUFFER IS       83650021
** FILLED IF A BUFFER IS AVAILABLE.                                     83700021
         L     ABPDBUF,VCQMSG .GET ADDR IEAQMSGS INFOLIST               83750021
         L     ABPDEND,ZERO(ABPDBUF) .GET ADDR END OF LIST              83800021
         LA    ABPDBUF,FOUR(ABPDBUF) .GET ADDR OF 1ST ENTRY             83850021
         SR    ABWORK1,ABWORK1 .ZERO WORK REG                           83900021
ABTSTEND CR    ABPDBUF,ABPDEND .MORE ENTRIES?                           83950021
         BE    ABGETCC .          NO, GO SET UP FOR ABTERM              84000021
         C     ABWORK1,ZERO(ABPDBUF) .ENTRY AVAILABLE?                  84050021
         BE    ABFILBUF .       YES, GO FILL ENTRY                      84100021
         LA    ABPDBUF,BUFLNG(ABPDBUF) .GET NEXT ENTRY                  84150021
         B     ABTSTEND .           GO CHECK NEXT ENTRY                 84200021
ABFILBUF MVC   ZERO(BUFLNG,ABPDBUF),PDBUFFER .COPY TO ENTRY     A49808  84250021
ABGETCC  LH    REG1,PDCOMPCD .    GET COMPLETION CODE                   84300021
         SLL   REG1,TWELVE .      SET UP REG1 FOR ABEND                 84350021
         O     REG1,DUMPMASK .    SET HIGH BIT ON FOR DUMP              84400021
         LR    REG0,REG4 .        SET UP TCB IN REG0 FOR ABTERM         84450021
         L     REG15,VCABTERM .   GET ADDR ABTERM                       84500021
         L     BASEREG,VCCVT .    GET CVT ADDR FOR ABTERM               84550021
         BR    REG15 .            GO TO ABTERM                          84600021
         TITLE 'SMFGET SUBROUTINE'                                      84650021
         AGO   .AMS10                                                   84700021
*/*SMFGET: CHART */                                                     84750021
*/*SMFGET: E ENTRY */                                                   84800021
*/*    P  GET JOBSTEP TCB AND TCT */                                    84850021
*/*    D  (YES,SMTSTH1,NO,) IS REQUEST FOR HIER=1 */                    84900021
*/*    D  (YES,SMGETH1,NO,) IS DUMMY HIERARCHY SWITCH ON*/              84950021
*/*SMGETH0:  P (,SMTSTHWM) GET ADDR HIER=0 STORAGE TABLE*/              85000021
*/*SMTSTH1:  D (YES,SMGETH0,NO,) IS DUMMY HIERARCHY SWITCH ON*/         85050021
*/*SMGETH1:  P GET ADDR HIER=1 STORAGE TABLE */                         85100021
*/*SMTSTHWM: D (YES,%SM1,NO,) IS SMF RECORDING (HWM NOT =0)*/           85150021
*/*    R  RETURN */                                                     85200021
*/*%SM1: D  (YES,,NO,SMTSTLWM) DOES END OF ALLOC AREA JOIN HWM*/        85250021
*/*    P  (,SMLARGFQ) NEW HWM= ADDR ALLOCATED ARGA*/                    85300021
*/*SMTSTLWM: D (YES,,NO,SMLARGFQ) DOES BEGIN OF ALLOC AREA JOIN LWM*/   85350021
*/*    P  NEW LWM= ADDR OF END OF ALLOCATED AREA */                     85400021
*/*SMLARGFQ: P POSSIBLE DELTA=(LARGEST FQE-ALLOC SIZE)/2K */            85450021
*/*    D   (YES,%SM2,NO,) IS POSSIBLE DELTA < TCTMINC*/                 85500021
*/*    R  RETURN */                                                     85550021
*/*%SM2:  P  ZERO SMFSZ AND GET 1ST FQE */                              85600021
*/*SMTSTEND:    D  (YES,SMFQEND,NO,) IS THIS LAST FQE*/                 85650021
*/*    D  (YES,,NO,SMNXTFQE) IS FQE GT SMFSZ*/                          85700021
*/*    P     SMFSZ= FQE SIZE */                                         85750021
*/*SMNXTFQE: P  (,SMTSTEND)  GET NEXT FQE*/                             85800021
*/*SMFQEND:  D (YES,,NO,%SM3) IS SMFSZ/2K < TCTMINC*/                   85850021
*/*    P  TCTMINC = SMFSZ/2K */                                         85900021
*/*%SM3: R RETURN */                                                    85950021
*/*SMFGET: END */                                                       86000021
.AMS10   ANOP                                                           86050021
         AIF   (NOT &SMF).SMFEND                                    SMF 86100021
*---------------------------------------------------------------------  86150021
*    SMFGET UPDATES THE LOW WATER  AND HIGH WATER MARKS AND THE     SMF 86200021
*    MINIMUM DIFFERENCE BETWEEN THE WATER MARKS.                    SMF 86250021
*    HWM = LOWEST ADDR ALLOCATED FROM HIGH END OF PARTITION         SMF 86260021
*    LWM = HIGHEST ADDR ALLOCATED FROM LOW END OF PARTITION         SMF 86270021
*    HWM AND LWM MAY OVERLAP                                        SMF 86272021
*    TCTMINC = LARGEST FQE (IN 2K BLOCKS) NOT USED BY JOB           SMF 86280021
*    INPUT IS THE ADDR OF THE ALLOCATED AREA  IN REG 13 AND THE     SMF 86300021
*    THE SIZE ALLOCATED AT ROUNDSIZ.                                SMF 86350021
*---------------------------------------------------------------------  86400021
          SPACE 2                                                       86450021
          DS 0F                                                         86500021
SMFGET   EQU   *                                                    SMF 86550021
         L     SMJSTCB,TCBFTJST(REG4) .GET JOBSTEP TCB              SMF 86600021
         TM    TCBTCTGF(SMJSTCB),SMFCALC .JOB SCHEDULER IN TERMINAT?SMF 86610021
         BCR   EIGHT,RETREG .YES DON'T CALCULATE SMF INFO           SMF 86620021
         L     SMTCT,TCBTCT(SMJSTCB) .GET TIMING CNTRL TABLE        SMF 86650021
         LA    SMTCT,ZERO(SMTCT) . ZERO HIGH BYTE                   SMF 86660021
         LTR   SMTCT,SMTCT .IS THER A TCT TABLE                     SMF 86700021
         BCR   EIGHT,RETREG .NO,MUST BE SYSTEM TASK                 SMF 86750021
         L     SMTCT,TCTCRTBL(SMTCT) . GET ADDR HOT STORAGE TABLE   SMF 86800021
         AIF   (NOT &LCS).SMNOLCS                                   SMF 86850021
         TM    SWITCHES,LCSW .     IS REQUEST FOR HER=1           LCSMF 86900021
         BO    SMTSTH1 .           YES                            LCSMF 86950021
         TM    SWITCHES,DUMHIER .  IS HIER=0 REQ BUT HIER=1 USED  LCSMF 87000021
         BO    SMGETH1 .           YES                            LCSMF 87050021
         B     SMTSTHWM .    USE HOT STOR TABLE                   LCSMF 87100021
SMTSTH1  TM    SWITCHES,DUMHIER .  IS HIER=1 REQ BUT HIER=0 USED  LCSMF 87150021
         BO    SMTSTHWM .          YES, USE HOT STOR TABLE        LCSMF 87200021
SMGETH1  LA    SMTCT,SIXTN(SMTCT) .GET ADDR LCS STOR TABLE        LCSMF 87250021
.SMNOLCS ANOP                                                       SMF 87300021
* THE ADDR OF THE PROCESSOR STORAGE TABLE(HOT STORAGE) OR THE       SMF 87350021
* HIERARCHY SUPPORT TABLE(LCS STORAGE) IS NOW IN REG SMTCT.         SMF 87400021
SMTSTHWM EQU   *                                                    SMF 87450021
         NC    TCTHWM(FOUR,SMTCT),TCTHWM(SMTCT) .IS SMF RECORDING   SMF 87500021
         BCR   EIGHT,RETREG .      NO, RETURN TO GETCORE            SMF 87550021
         SPACE 2                                                        87600021
*** CHECK FOR UPDATES TO HWM AND LWM***                             SMF 87650021
         LR    SMWORK1,GETADDR .   GET ADDR AREA ALLOCATED          SMF 87700021
         A     SMWORK1,ROUNDSIZ .  GET   END OF AREA ALLOCATED      SMF 87750021
         CL    SMWORK1,TCTHWM(SMTCT) .DOES ALLOC AREA JOIN HWM      SMF 87800021
         BL    SMTSTLWM .          NO, TRY LWM                   A56743 87850021
         CL    GETADDR,TCTHWM(SMTCT) IS BEGIN ALLOC AREA LT HWM  A56743 87860021
         BNL   SMTSTLWM  NO CK LWM IN CASE OF OVERLAP            A56743 87870021
         ST    GETADDR,TCTHWM(SMTCT) .UPDATE HWM                    SMF 87900021
         B     SMLARGFQ .          GO CHECK DELTA                   SMF 87950021
SMTSTLWM CL    GETADDR,TCTLWM(SMTCT) .DOES ALLOC AREA JOIN LWM      SMF 88000021
         BH    SMLARGFQ .NO, GO CK DELTA                         A56743 88050021
         CL    SMWORK1,TCTLWM(SMTCT) IS END ALLOC AREA GT LWM    A56743 88060021
         BNH   SMLARGFQ NO GO CK DELTA                           A56743 88070021
         ST    SMWORK1,TCTLWM(SMTCT) .UPDATE LWM                    SMF 88100021
         SPACE 2                                                        88150021
****CHECK IF THE LARGEST FQE IN SCAN IS LESS THAN PREVIOUS LARGEST  SMF 88200021
SMLARGFQ L     SMFSZ+1,LARFQSIZ .  GET LARGEST FQE FOUND IN GETCORE SMF 88250021
* LARFQSIZ CONTAINS THE LARGEST FQE ONLY FOR LOW-CORE REQUEST.      SMF 88300021
         S     SMFSZ+1,ROUNDSIZ .GET POSSIBLE NEW DELTA =PD         SMF 88350021
         SR    SMFSZ,SMFSZ .ZERO EVEN REG FOR DIVIDE                SMF 88400021
         D     SMFSZ,TWOKDC .     DIVIDE BY 2K FOR DELTA COMPARE    SMF 88450021
         CH    SMFSZ+1,TCTMINC(SMTCT) .QUOTIENT LT CURRENT DELTA?   SMF 88500021
         BCR   ELEVEN,RETREG .     NO,EXISTING DELTA OKAY,RETURN    SMF 88550021
         SR    SMFSZ,SMFSZ .       ZERO EVEN REG FOR DIVIDE         SMF 88600021
         SR    SMFSZ+1,SMFSZ+1 .  ZERO LARGEST FQE HOLDER           SMF 88650021
* SCAN DOWN ALL FQES LOOKING FOR LARGEST .                          SMF 88700021
         L     SMFQE,BBFQE(BBOXREG) .GET 1ST FQE ADDR               SMF 88750021
SMTSTEND LTR   SMFQE,SMFQE .       IS THIS LAST FQE                 SMF 88800021
         BZ    SMFQEND .           YES                              SMF 88850021
         CL    SMFSZ+1,FQELNGTH(SMFQE) .IS FQE GT SMFZE             SMF 88900021
         BH    SMNXTFQE .          NO,GET NEXT FQE                  SMF 88950021
         L     SMFSZ+1,FQELNGTH(SMFQE) .UPDATE SMFZE                SMF 89000021
SMNXTFQE L     SMFQE,FQEPTR(SMFQE) .GET NEXT FQE                    SMF 89050021
         B     SMTSTEND .          GO CHECK IF END OF FQES          SMF 89100021
SMFQEND  D     SMFSZ,TWOKDC .     ROUND CORE TO 2K                  SMF 89150021
         CH   SMFSZ+1,TCTMINC(SMTCT) .IS LARGEST FQE LT DELTA       SMF 89200021
         BCR   TWO,RETREG .        NO                               SMF 89250021
         STH   SMFSZ+1,TCTMINC(SMTCT) .UPDATE DELTA                 SMF 89300021
         BR    RETREG .            RETURN TO GETCORE                SMF 89350021
         TITLE 'IEAAMS CONSTANTS'                                       89400021
.SMFEND  ANOP                                                       SMF 89450021
***  CONSTANTS   ***                                                    89500021
         SPACE 5                                                        89550021
DATAWORK EQU   *     DATA AREA WHICH IS CLEARED IN PROLOGUES            89600021
         SPACE 2                                                        89650021
BEGIN    EQU   *              BEGIN OF AREA TO CLEAR                    89700021
SWITCHES DC    1X'00'         SWITCH FLAGS                              89750021
LOCORESW EQU   X'80'          GET CORE FROM BOTTOM OF PARTITION         89800021
GQESW    EQU   X'40'          REQUESTOR=SUBTASK                     ATT 89850021
LCSW     EQU   X'20'          HIERARCHY=1 REQUEST                   LCS 89900021
DUMHIER  EQU   X'10'              PARTITION DOESNT HAVE HIER REQUESTED  89950021
GETMAIN  EQU   X'08' .            GETMAIN REQUEST                       90000021
SQSREQ   EQU   X'04' .   SUBPOOL 245, 255 REQUEST                 M4914 90010021
LARFQSIZ DS    1F                  SAVE AREA FOR LARGEST FQE SIZE       90050021
LOCORSAV DS    3F . SAVEAREA FOR LOW CORE HUNT OF FQES-CUR,PREV,LAST    90100021
ROUNDSIZ DS    1F                  REQUESTOR'S SIZE ROUNDED TO DOUBLEW  90150021
         AIF   (NOT &ATT).NOSVGQE                                       90200021
SAVEGQE  DS    1F .          SAVE AREA FOR LAST GQE                 ATT 90250021
.NOSVGQE ANOP                                                           90300021
SAVELNGT DS    1F                                                       90350021
FRSAV15  DS    1F .REG15 SAVE AREA FOR FREEMAIN                         90400021
         AIF   (NOT &LCS).NOLCSAV                                       90450021
LCSFLGSV DS    1X                   SAVE AREA FOR BBOX LCS FLAG     LCS 90500021
.NOLCSAV ANOP                                                           90550021
SAVESPID DS    1X                                                       90600021
END      EQU   *              END OF AREA TO CLEAR                      90650021
         SPACE 2                                                        90700021
* PROBLEM DETERMINATION AREA                                            90750021
          DS 0F                                                         90800021
PDBUFFER EQU   *                                                        90850021
PDTJID   DS    1F .           NOT USED- FOR MVT-TSO              A49808 90860021
PDTCB    DS    1F .           REQUESTING TCB                            90900021
         DS    1F .           NOT USED- FOR BRANCH ENTRIES              90950021
PDRCNUM  DS    1X .           BITS 0-2=REASON CODE                     X91000021
                              BITS 3-7=NUMBER BYTES VARIABLE DATA       91050021
         DS    1X .           NOT USED- BRANCH ENTRY FLAG               91100021
PDCOMPCD DS    2X .           SYSTEM COMPLETION CODE                    91150021
PDVAR1   DS    1F .           VARIABLE INFO ACCORDING TO COMP CODE      91200021
PDVAR2   DS    1F .           VARIABLE INFO ACCORDING TO COMP CODE      91250021
PDVAR3   DS    1F .           VARIABLE INFO ACCORDING TO COMP CODE      91300021
PDVAR4   DS    1F .           VARIABLE INFO ACCORDING TO COMP CODE      91350021
         SPACE 2                                                        91400021
CLOBBERD DC    F'0' .  SAVE AREA FOR ADDR OF BAD FQE OR GQE             91450021
         AIF   (NOT &ATT).NOATTDC                                       91500021
EIGHTDC  DC  H'8'                SUBTRACT FACTOR FOR GQE            ATT 91550021
SIXTNDC  DC     H'16' .           GQE MINIMUM SIZE                  ATT 91600021
.NOATTDC ANOP                                                           91650021
SVC13ID  DC   X'F1C3' .          SVRB ABEND ID                          91700021
CCE04    DC   X'0E04' .          COMPETION CODE E04                     91710021
         DS    0F                                                       91750021
DUMPMASK DC    X'80000000' .      HIGH BIT MASK FOR ABTERM TO DUMP      91800021
         AIF   (NOT &LCS).NOLCT                                         91850021
LCSREGM  DC     X'80D3C3E3' .     REG1 VALUE FOR LCS GETMAIN-REGMAINLCS 91900021
.NOLCT   ANOP                                                           91950021
         AIF   (NOT &SMF).NO2KSMF                                       92000021
TWOKDC   DC    F'2048' .         2K DIVIDER FOR DELTA COMPARE       SMF 92050021
.NO2KSMF ANOP                                                           92100021
IEAATADD DC    V(ABENDSUC) .                                            92150021
VCABTERM DC    V(IEA0AB00) .  ENTRY POINT ABTERM                        92200021
VCMSER   DC    V(IEEMSER) .  ADDR MASTER SCHE RESIDENT DATA AREA        92250021
VCQMSG   DC    V(IEAQMSGS) .ADDR IEAQMSGS  ENTRIES                      92300021
VCCVT    DC    V(IEACVT)  .ADDR CVT                                     92350021
VCSVRBS  DC    V(SVRBPOOL) .ADDR STEAL CORE SVRB POOL IN IEAATA         92400021
SAVEWORK DC    10F'0' .       HELP AREA                                 92450021
         SPACE 2                                                        92500021
**** PARAMETER LIST DESECT ****                                         92550021
GETDSECT DSECT                                                          92600021
GETLNGTH DS    1F             LENGTH OR ADDR LENGTH PARM LIST           92650021
GETHID   DS    1C             HIERARCHY ID                              92700021
HIERAR1  EQU   X'01'          HIERARCHY=1 REQUEST                       92750021
         ORG   *-1                                                      92800021
GETADD   DS    4C             ADDR OF AREA GETMAIN FILLS WITH RESULT    92850021
GETYPE   DS    1C             FLAGS                                     92900021
CONDSE   EQU   X'20'          CONDITIONAL SINGLE REQUEST                92950021
UNCONDSE EQU   X'00'          UNCONDITIONAL SINGLE REQUEST              93000021
CONDLST  EQU   X'A0'          CONDITIONAL LIST REQUEST                  93050021
UNCONDLS EQU   X'80'          UNCONDITIONAL LIST REQUEST                93100021
CONDVAR  EQU   X'E0'          CONDITIONAL VARIABLE REQUEST              93150021
UNCONDVA EQU   X'C0'          UNCONDITIONAL VARIABLE REQUEST            93200021
GETSPID  DS    1C             SUBPOOL NUMBER                            93250021
         DS    2C             RESERVED                                  93300021
         MEND                                                           93350021
