        MACRO                                                           00030020
         IEAQGM &RORI,&LCS,&MPS,&SMF,&TSO                         20021 00036020
.*316200                                                       @AS75933 00042000
.* A     339100-339200,322500-322590,328300                    @SA77169 00045000
.* A     547240-547440                                         @SA77070 00048000
.*316500-316740                                                @AS75933 00052000
.* C     794500                                                @SA78255 00057000
.* A 712510-712680                                             @SA78437 00058000
         TITLE ' MVT GETMAIN / FREEMAIN SERVICE ROUTINE '               00062720
.*                                                                      00063016
.* THE FOLLOWING TABLE IDENTIFIES THE FLAG FIELDS (COL. 68 - 71)        00066016
.* OF RECORDS SUBMITTED AS DEVELOPMENT CHANGES TO INTEGRATION TO        00069016
.* SUPPORT THE INDICATED OS/360 COMPONENT FOR THE SPECIFIED RELEASE.    00072016
.*                                                                      00075016
.* FLAG             OS/360 COMPONENT        REL. NO.       INTEG. START 00078016
.*                                                             DATE     00081016
.* TS0A    TIME SLICING                        16             2-26-68   00084016
.* LC0A    LARGE CAPACITY STORAGE (LCS)        17             5-27-68   00086017
.* MP65    M65 MULTIPROCESSING                 17             5-27-68   00087017
.* 20021   TIME SHARING OPTION(TSO)            20             8-07-70   00087120
.*                                                                      00088017
.* REL.  APARS FIXED                                                    00088620
.* 20    26046, 29420, 30185, 32583, 33335                              00089220
IEAQGM00 START 0                                                        00090015
         ENTRY IGC004                                                   00120015
         ENTRY IGC005                                                   00150015
         ENTRY IGC010                                                   00180015
         ENTRY RMBRANCH                                                 00210015
         ENTRY GMBRANCH                                                 00240015
         ENTRY FMBRANCH                                                 00270015
         ENTRY GOVRFLB                                                  00300015
         ENTRY CDPURGE                                                  00330015
         ENTRY MRELEASE                                                 00360015
         ENTRY GETMAINB                                                 00390015
         ENTRY FBQSRCH                                                  00420015
         ENTRY MSSBASE                                                  00450015
         EXTRN IEATCBP                                                  00480015
         EXTRN IEA0AB01                                                 00510015
         EXTRN CDHKEEP                                                  00540015
         EXTRN CDDESTRY                                                 00570015
         EXTRN IEAMSTCB                                                 00600015
         EXTRN IEA0XE00                                                 00630015
         EXTRN DISPINIT                                            SWS  00650018
         EXTRN IEAQPRT0                                            SWS  00670018
         ENTRY SVCBYTE                                                  00690015
         ENTRY SPIDSAV .                                         A32912 00691020
         ENTRY IEA10FS                                            M3806 00691420
         AIF   ('&MPS' NE 'Y').MP01                                MP65 00692017
         ENTRY VQEPTR                                              MP65 00694017
.MP01    ANOP                                                      MP65 00696017
         AIF   ('&RORI' NE 'Y').GOG1                               LC0A 00700017
         ENTRY IEAROSW                                                  00720015
.GOG1    ANOP                                                           00750015
         EJECT                                                          00780015
*ROUTINE NAME-           IEAQGM00-MAIN STORAGE SUPERVISOR               00810015
*                                                                       00840015
*FUNCTION-               THE BASIC FUNCTION OF THE MAIN STORAGE         00870015
*                        SUPERVISOR IS TO ASSIGN STORAGE BLOCKS FOR THE 00900015
*                        USE OF VARIOUS TASKS IN THE MULTIPROGRAMMING   00930015
*                        ENVIRONMENT ACCORDING TO THEIR NEEDS AND IN    00960015
*                        ORDER OF THEIR PRIORITY WITHIN THE SYSTEM.     00990015
*                        THIS INVOLVES                                  01020015
*                          1) ALLOCATION OF STORAGE BLOCKS ON REQUEST.  01050015
*                          2) RELEASE OF STORAGE BLOCKS ON REQUEST.     01080015
*                          3) MAINTAINING OWNERSHIP OF ALL 2K BLOCKS.   01110015
*                              A) MAINTAINING A RECORD OF ALL 2K BLOCKS 01140015
*                                 ASSIGNED TO EACH TASK AND TO EACH     01170015
*                                 SUB-POOL BELONGING TO THAT TASK.      01200015
*                              B) MAINTAINING A QUEUE OF FREE AREAS     01230015
*                                 WITHIN THE MAIN STORAGE ASSIGNED TO   01260015
*                                 EACH TASK SUB-POOL.                   01290015
*                              C) MAINTAINING A RECORD OF ASSOCIATION   01320015
*                                 OF STORAGE ALLOCATED FROM SUPERVISOR  01350015
*                                 OWNED STORAGE WHEN REQUESTED TO DO SO 01380015
         AIF   (&SMF EQ 0).MSSMFA                                   SMF 01381018
*                                                                   SMF 01382018
*                        A SECONDARY FUNCTION IN SUPPORT OF SYSTEMS SMF 01383018
*                        MANAGEMENT FACILITIES IS TO PRODUCE        SMF 01384018
*                        ACTUAL CORE USED VALUES.                   SMF 01385018
*                        THIS INVOLVES                              SMF 01386018
*                          1) MONITORING REQUESTS FOR NON ZERO      SMF 01387018
*                             PROTECT KEY AND SUB POOL 252, AND     SMF 01388018
*                             MAINTAINING CORE USED FIELDS          SMF 01389018
*                             ASSOCIATED WITH EACH PP TCB.          SMF 01390018
*                          2) THE FIELDS MAINTAINED ARE             SMF 01391018
*                              A) LOW WATER MARK.                   SMF 01392018
*                              B) HIGH WATER MARK.                  SMF 01393018
*                              C) MINIMUM DIFFERENCE BETWEEN MARKS. SMF 01394018
*                          3) EACH TYPE OF CORE AVAILABLE HAS A SET SMF 01395018
*                             OF RELATED FIELDS.                    SMF 01396018
         AIF   ('&RORI' NE 'Y').MSSMFA                              SMF 01397018
*                                                                   SMF 01398018
*                        IN ADDITION BORROWED CORE FIELDS ARE       SMF 01399018
*                        MAINTAINED IN THE TCT FOR EACH PP TCB.     SMF 01400018
*                        THIS INVOLVES                              SMF 01401018
*                          1) KEEPING A CURRENT VALUE OF BORROWED   SMF 01402018
*                             CORE IN 2K BLOCKS.                    SMF 01403018
*                          2) UPDATEING A MAXIMUM VALUE OF BORROWED SMF 01404018
*                             CORE IN 2K BLOCKS.                    SMF 01405018
.MSSMFA  ANOP                                                       SMF 01406018
         AIF   (&TSO NE 1).TSOP000                                20021 01407020
*                                                                 20021 01407120
*                        FOR THE TIME SHARING OPTION(TSO)         20021 01408020
*                        PROVIDE THE CAPIBILITY TO:               20021 01409020
*                        1) MAP SUBPOOLS 253, 254, AND 255 INTO   20021 01409120
*                        LOCAL SQS(LSQS) FOR TIME SHARING TASKS.  20021 01409220
*                        2) TO ABTERM A TIME SHARING TASK THAT    20021 01409320
*                        EXHAUSTS ITS LSQS.  TO PREVENT AN ABTERM 20021 01409420
*                        RECURSION AND ALLOW THE ABTERMING TASK   20021 01409520
*                        TO COMPLETE, MAIN STORAGE(253, 254 ,255) 20021 01409620
*                        REQUESTS DURING ABTERM WILL BE HONORED   20021 01410020
*                        FROM SQS.                                20021 01410120
*                                                                       01410420
.TSOP000 ANOP                                                     20021 01410720
*                        REQUEST FOR SUBPOOLS 243, 244, 245 WILL  20021 01410820
*                        BE HONORED UNCONDITIONALLY FROM SQS FOR  20021 01410920
*                        BOTH TIME SHARING AND NON-TIME SHARING   20021 01411020
*                        TASKS.                                   20021 01411120
*                                                                       01411220
*ENTRY POINT NAMES-      IGC004-SVC 4 - S-TYPE GETMAIN ENTRY POINT.     01440015
*                        IGC005-SVC 5 - S-TYPE FREEMAIN ENTRY POINT.    01470015
*                        IGC010-SVC 10- R-TYPE GETMAIN AND FREEMAIN     01500015
*                                       ENTRY POINT.                    01530015
*                        GMBRANCH-BRANCH ENTRY - S-TYPE GETMAIN.        01560015
*                        FMBRANCH-BRANCH ENTRY - S-TYPE FREEMAIN.       01590015
*                        RMBRANCH-BRANCH ENTRY - R-TYPE GETMAIN AND     01620015
*                                                FREEMAIN.              01650015
*                                                                       01680015
*CONTAINED IN MODULE-    IEAQGM - MAIN STORAGE SUPERVISOR.              01710015
*                                                                       01740015
*ATTRIBUTES-             NON-REENTRANT, OPERATES IN SUPERVISOR STATE,   01770015
*                        RESIDENT, DISABLED FOR ALL MASKABLE INTERRUPTS 01800015
*                        EXCEPT MACHINE CHECK, TYPE 1 SVC ROUTINE.      01830015
*                                                                       01860015
*APPLICABILITY-          OPTION 4 ONLY.                                 01890015
*                                                                       01920015
*EXTERNAL REFERENCES-    IEA0AB01 - ABTERM                              01950015
*                        CDHKEEP  - CDDESTRY BASE ADDRESS               01980015
*                        CDDESTRY - CDDESTRY ROUTINE                    02010015
*                        IEAQPRT0 - GET-FREE PARTITION                  02040015
*                        IEATCBP  - LOCATION 'NEW' AND 'OLD'            02070015
*                                                                       02100015
*SVCS USED-              NONE                                           02130015
*                                                                       02160015
*ENTRY POINTS-         1.IGC004 - S-TYPE GETMAIN ENTRY POINT.  GIVEN    02190015
*                        CONTROL BY SVC FIRST LEVEL INTERRUPT HANDLER   02220015
*                        (FLIH) VIA LPSW IN ORDER TO PERFORM THE        02250015
*                        GETMAIN FUNCTION REQUESTED BY THE CALLER.  AN  02280015
*                        SVC 4 IS ISSUED BY THE CALLER.                 02310015
*                                                                       02340015
*                      2.THE PSW MUST BE DISABLED FOR ALL MASKABLE      02370015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 02400015
*                        MODE, AND HAVE SUPERVISOR PROTECT KEY.         02430015
*                                                                       02460015
*                      3.THE REGISTERS CONTAIN                          02490015
*                          REGISTER 1 CONTAINS THE ADDRESS OF THE       02520015
*                          PARAMETER LIST.                              02550015
*                          REGISTER 3 CONTAINS THE ADDRESS OF THE CVT   02580015
*                          TABLE.                                       02610015
*                          REGISTER 4 CONTAINS THE ADDRESS OF THE       02640015
*                          CURRENT TCB.                                 02670015
*                          REGISTER 5 CONTAINS THE ADDRESS OF THE RB AT 02700015
*                          THE TOP OF THE RB QUEUE.                     02730015
*                          REGISTER 13 CONTAINS THE ADDRESS OF THE      02760015
*                          ABTERM ROUTINE.                              02790015
*                          REGISTER 14 CONTAINS THE ADDRESS OF THE TYPE 02820015
*                          1 SVC EXIT HANDLER.                          02850015
*                          REGISTERS 0,2,6-12, AND 15 CONTAIN THE       02880015
*                          CONTENTS AT THE TIME THE SVC 4 WAS GIVEN.    02910015
*                                                                       02940015
*                      1.IGC005 - S-TYPE FREEMAIN ENTRY POINT.  GIVEN   02970015
*                        CONTROL BY SVC FIRST LEVEL INTERRUPT HANDLER   03000015
*                        (FLIH) VIA LPSW IN ORDER TO PERFORM THE        03030015
*                        FREEMAIN FUNCTION REQUESTED BY THE CALLER.  AN 03060015
*                        SVC 5 IS ISSUED BY THE CALLER.                 03090015
*                                                                       03120015
*                      2.THE PSW MUST BE DISABLED FOR ALL MASKABLE      03150015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 03180015
*                        MODE, AND HAVE SUPERVISOR PROTECT KEY.         03210015
*                                                                       03240015
*                      3.THE REGISTERS CONTAIN                          03270015
*                          REGISTER 1 CONTAINS THE ADDRESS OF THE       03300015
*                          PARAMETER LIST.                              03330015
*                          REGISTER 3 CONTAINS THE ADDRESS OF THE CVT   03360015
*                          TABLE.                                       03390015
*                          REGISTER 4 CONTAINS THE ADDRESS OF THE       03420015
*                          CURRENT TCB.                                 03450015
*                          REGISTER 5 CONTAINS THE ADDRESS OF THE RB AT 03480015
*                          THE TOP OF THE RB QUEUE.                     03510015
*                          REGISTER 13 CONTAINS THE ADDRESS OF THE      03540015
*                          ABTERM ROUTINE.                              03570015
*                          REGISTER 14 CONTAINS THE ADDRESS OF THE TYPE 03600015
*                          1 SVC EXIT HANDLER.                          03630015
*                          REGISTERS 0,2,6-12, AND 15 CONTAIN THE       03660015
*                          CONTENTS AT THE TIME THE SVC 5 WAS GIVEN.    03690015
*                                                                       03720015
*                      1.IGC010 - R-TYPE GETMAIN AND FREEMAIN ENTRY     03750015
*                        POINT.  GIVEN CONTROL BY SVC FIRST LEVEL       03780015
*                        INTERRUPT HANDLER (FLIH) VIA LPSW IN ORDER TO  03810015
*                        PERFORM THE GETMAIN OR FREEMAIN FUNCTION       03840015
*                        REQUESTED BY THE CALLER.  AN SVC 10 IS ISSUED  03870015
*                        BY THE CALLER.                                 03900015
*                                                                       03930015
*                      2.THE PSW MUST BE DISABLED FOR ALL MASKABLE      03960015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 03990015
*                        MODE, AND HAVE SUPERVISOR PROTECT KEY.         04020015
*                                                                       04050015
*                      3.THE REGISTERS CONTAIN                          04080015
*                          REGISTER 0 CONTAINS THE NUMBER OF THE        04110015
*                          SUBPOOL REQUESTED IN THE HIGH ORDER BYTE AND 04140015
*                          THE NUMBER OF BYTES REQUESTED IN THE LOW     04170015
*                          ORDER THREE BYTES.  IF THE REQUEST IS FOR A  04200015
*                          FREEMAIN FOR AN ENTIRE SUBPOOL, THE LOW      04230015
*                          ORDER THREE BYTES MUST BE ZERO.              04260015
*                          REGISTER 1 CONTAINS ANY NEGATIVE VALUE IF    04290015
*                          THE REQUEST IS FOR A GETMAIN, OR THE ADDRESS 04320015
*                          OF THE STORAGE TO BE FREED IF THE REQUEST IS 04350015
*                          FOR A FREEMAIN.  IF THE REQUEST IS FOR A     04380015
*                          FREEMAIN FOR AN ENTIRE SUBPOOL, THE ENTIRE   04410015
*                          REGISTER MUST BE ZERO.                       04440015
*                          REGISTER 3 CONTAINS THE ADDRESS OF THE CVT   04470015
*                          TABLE.                                       04500015
*                          REGISTER 4 CONTAINS THE ADDRESS OF THE       04530015
*                          CURRENT TCB.                                 04560015
*                          REGISTER 5 CONTAINS THE ADDRESS OF THE RB AT 04590015
*                          THE TOP OF THE RB QUEUE.                     04620015
*                          REGISTER 13 CONTAINS THE ADDRESS OF THE      04650015
*                          ABTERM ROUTINE.                              04680015
*                          REGISTER 14 CONTAINS THE ADDRESS OF THE TYPE 04710015
*                          1 SVC EXIT HANDLER.                          04740015
*                          REGISTERS 2,6-12, AND 15 CONTAIN THE         04770015
*                          CONTENTS AT THE TIME THE SVC 10 WAS GIVEN.   04800015
*                                                                       04830015
*                      1.GMBRANCH - S-TYPE GETMAIN BRANCH ENTRY POINT.  04860015
*                        GIVEN CONTROL BY THE CALLING SUPERVISOR        04890015
*                        ROUTINE VIA A BRANCH IN ORDER TO PERFORM THE   04920015
*                        GETMAIN FUNCTION REQUESTED BY THE CALLER.      04950015
*                                                                       04980015
*                      2.THE PSW MUST BE DISABLED FOR ALL MASKABLE      05010015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 05040015
*                        MODE, AND HAVE SUPERVISOR PROTECT KEY.         05070015
*                                                                       05100015
*                      3.THE REGISTERS CONTAIN                          05130015
*                          REGISTER 1 CONTAINS THE ADDRESS OF THE       05160015
*                          PARAMETER LIST.                              05190015
*                          REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.  05220015
*                          REGISTER 4 CONTAINS THE ADDRESS OF THE TCB   05250015
*                          UNDER WHICH STORAGE IS TO BE ALLOCATED.      05280015
*                          REGISTER 14 CONTAINS THE ADDRESS OF THE      05310015
*                          LOCATION TO WHICH CONTROL IS TO BE RETURNED. 05340015
*                          REGISTERS 0,2,5-13 AND 15 CONTAIN            05370015
*                          INFORMATION FROM THE CALLER WHICH IS NOT     05400015
*                          USEFUL TO THE MAIN STORAGE SUPERVISOR        05430015
*                          ROUTINES.                                    05460015
*                                                                       05490015
*                      1.FMBRANCH - S-TYPE FREEMAIN BRANCH ENTRY POINT. 05520015
*                        GIVEN CONTROL BY THE CALLING SUPERVISOR        05550015
*                        ROUTINE VIA A BRANCH IN ORDER TO PERFORM THE   05580015
*                        FREEMAIN FUNCTION REQUESTED BY THE CALLER.     05610015
*                                                                       05640015
*                      2.THE PSW MUST BE DISABLED FOR ALL MASKABLE      05670015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 05700015
*                        MODE, AND HAVE SUPERVISOR PROTECT KEY.         05730015
*                                                                       05760015
*                      3.THE REGISTERS CONTAIN                          05790015
*                          REGISTER 1 CONTAINS THE ADDRESS OF THE       05820015
*                          PARAMETER LIST.                              05850015
*                          REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.  05880015
*                          REGISTER 4 CONTAINS THE ADDRESS OF THE TCB   05910015
*                          UNDER WHICH STORAGE IS TO BE RELEASED.       05940015
*                          REGISTER 14 CONTAINS THE ADDRESS OF THE      05970015
*                          LOCATION TO WHICH CONTROL IS TO BE RETURNED. 06000015
*                          REGISTERS 0,2,5-13 AND 15 CONTAIN            06030015
*                          INFORMATION FROM THE CALLER WHICH IS NOT     06060015
*                          USEFUL TO THE MAIN STORAGE SUPERVISOR        06090015
*                          ROUTINES.                                    06120015
*                                                                       06150015
*                      1.RMBRANCH - R-TYPE GETMAIN AND FREEMAIN ENTRY   06180015
*                        POINT.  GIVEN CONTROL BY THE CALLING           06210015
*                        SUPERVISOR ROUTINE VIA A BRANCH IN ORDER TO    06240015
*                        PERFORM THE GETMAIN OR FREEMAIN FUNCTION       06270015
*                        REQUESTED BY THE CALLER.                       06300015
*                                                                       06330015
*                      2.THE PSW MUST BE DISABLED FOR ALL MASKABLE      06360015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 06390015
*                        MODE, AND HAVE SUPERVISOR PROTECT KEY.         06420015
*                                                                       06450015
*                      3.THE REGISTERS CONTAIN                          06480015
*                                                                       06510015
*                          REGISTER 0 CONTAINS THE NUMBER OF THE        06540015
*                          SUBPOOL REQUESTED IN THE HIGH ORDER BYTE AND 06570015
*                          THE NUMBER OF BYTES REQUESTED IN THE LOW     06600015
*                          ORDER THREE BYTES.  IF THE REQUEST IS FOR A  06630015
*                          FREEMAIN FOR AN ENTIRE SUBPOOL, THE LOW      06660015
*                          ORDER THREE BYTES MUST BE ZERO.              06690015
*                          REGISTER 1 CONTAINS ANY NEGATIVE VALUE IF    06720015
*                          THE REQUEST IS FOR A GETMAIN, OR THE ADDRESS 06750015
*                          OF THE STORAGE TO BE FREED IF THE REQUEST IS 06780015
*                          FOR A FREEMAIN.  IF THE REQUEST IS FOR A     06810015
*                          FREEMAIN FOR AN ENTIRE SUBPOOL, THE ENTIRE   06840015
*                          REGISTER MUST BE ZERO.                       06870015
*                          REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.  06900015
*                          REGISTER 4 CONTAINS THE ADDRESS OF THE TCB   06930015
*                          UNDER WHICH THE STORAGE IS TO BE ALLOCATED   06960015
*                          OR RELEASED.                                 06990015
*                          REGISTER 14 CONTAINS THE ADDRESS OF THE      07020015
*                          LOCATION TO WHICH CONTROL IS TO BE RETURNED. 07050015
*                          REGISTERS 2,5-13, AND 15 CONTAIN INFORMATION 07080015
*                          FROM THE CALLER WHICH IS NOT USEFUL TO THE   07110015
*                          MAIN STORAGE SUPERVISOR ROUTINES.            07140015
*                                                                       07170015
*EXIT POINTS-          1.TO THE TYPE 1 SVC EXIT ROUTINE VIA A BRANCH ON 07200015
*                        REGISTER 14 IF ENTRY WAS BY AN SVC OR TO A     07230015
*                        LOCATION SPECIFIED BY THE CALLER IF ENTRY WAS  07260015
*                        BY A BRANCH.                                   07290015
*                                                                       07320015
*                      2.THE PSW IS DISABLED FOR ALL MASKABLE           07350015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 07380015
*                        MODE, AND HAS SUPERVISOR PROTECT KEY.          07410015
*                                                                       07440015
*                      3.THE REGISTERS CONTAIN                          07470015
*                          REGISTERS 0-15 CONTAIN MEANINGLESS INFORM-   07500015
*                          ATION UPON EXIT IF ENTRY WAS BY AN SVC       07530015
*                          EXCEPT FOR A GETMAIN REQUEST UNDER SVC 10,   07560015
*                          IN WHICH CASE REGISTER 1 CONTAINS THE        07590015
*                          ADDRESS OF THE STORAGE ALLOCATED.            07620015
*                          REGISTERS 2-7 AND 9-14 ARE UNALTERED AND     07650015
*                          REGISTERS 0,1,8, AND 15 CONTAIN MEANINGLESS  07680015
*                          INFORMATION IF ENTRY WAS BY A BRANCH EXCEPT  07710015
*                          FOR A GETMAIN REQUEST UNDER AN ENTRY TO      07740015
*                          RMBRANCH, IN WHICH CASE REGISTER 1 CONTAINS  07770015
*                          THE ADDRESS OF THE STORAGE ALLOCATED.        07800015
*                                                                       07830015
*ERROR EXIT POINTS-    1.TO ABTERM IN ORDER TO CAUSE THE ISSUING TASK   07860015
*                        TO BE TERMINATED.                              07890015
*                                                                       07920015
*                      2.THE PSW IS DISABLED FOR ALL MASKABLE           07950015
*                        INTERRUPTS EXCEPT MACHINE CHECK, IN SUPERVISOR 07980015
*                        MODE, AND HAS SUPERVISOR PROTECT KEY.          08010015
*                                                                       08040015
*                      3.REGISTER 1 CONTAINS THE ERROR CODE.            08070015
*                        THE REMAINING REGISTERS CONTAIN MEANINGLESS    08100015
*                        INFORMATION.                                   08130015
*                                                                       08160015
*                      4.THE ERROR CODES ARE                            08190015
         AIF   (&TSO NE 1).TSOP100                                20021 08191020
*                          X'0104' ERROR CODE #1 - OUT OF LOCAL   20021 08200020
*                          X'010A'                 SQS            20021 08210020
*                                  ERROR CODE #2 - NOT USED       20021 08211020
.TSOP100 ANOP                                                     20021 08213020
*                          X'0305' ERROR CODE #3 - STORAGE NOT IN       08220015
*                          X'030A'                 SPECIFIED SUBPOOL.   08250015
*                          X'040A' ERROR CODE  4 - PROBLEM PROGRAM      08280015
*                                                  ATTEMPTING TO FREE   08310015
*                                                  ALL OF SUBPOOL 0.    08340015
*                          X'0504' ERROR CODE  5 - LENGTH LIST AND      08370015
*                          X'0505'                 ADDRESS LIST HAVE    08400015
*                                                  COMMON LOCATIONS     08430015
*                          X'0604' ERROR CODE  6 - PARAMETER LIST NOT   08460015
*                                                  IN PROBLEM PROGRAM   08490015
*                                                  AREA, INPUT LIST     08520015
*                                                  ADDRESS NOT ON WORD  08550015
*                                                  BOUNDARY, OR FQE     08580015
*                                                  QUEUE DESTROYED.     08610015
*                          X'0804' ERROR CODE #8 - REQUEST FOR MORE     08640015
*                          X'080A'                 STORAGE THAN IS      08670015
*                                                  AVAILABLE - UNCONDI- 08700015
*                                                  TIONAL REQUEST.      08730015
*                          X'0905' ERROR CODE  9 - ADDRESS OF AREA TO   08760015
*                                                  BE FREED NOT A       08790015
*                                                  MULTIPLE OF 8.       08820015
*                          X'0A05' ERROR CODE #10- AREA BEING FREED     08850015
*                          X'0A0A'                 OVERLAPS A FREE AREA 08880015
*                          X'0B04' ERROR CODE #11- PROBLEM PROGRAM      08910015
*                          X'0B05'                 REQUESTS SUBPOOLS    08940015
*                          X'0B0A'                 128-255.             08970015
*                          X'0C04' ERROR CODE =12- GENERAL LCS     LC0A 08975017
*                                                  ERROR - RELATINGLC0A 08980017
*                                                  TO INVALID      LC0A 08985017
*                                                  HIERARCHY       LC0A 08990017
*                                                  REQUESTS.       LC0A 08995017
*                          X'0D05' ERROR CODE =13- REQUEST TO FREE 8098 08996017
*                          X'0D0A'                 CORE FROM SQS - 8098 08997017
*                                                  NOT OWNED BY    8098 08998017
*                                                  REQUESTING TASK.8098 08999017
*                                                                       09000015
*TABLES AND CONTROL                                                     09030015
*BLOCKS REFERENCED-    1.TCB - TASK CONTROL BLOCK                       09060015
*                        THE CONTROL BLOCK UNDER WHICH THE TASK IS      09090015
*                        OPERATING.                                     09120015
*                                                                       09150015
*                        FIELDS USED BY MAIN STORAGE SUPERVISOR         09180015
*                                                                       09210015
*                          TCBMSS - POINTER TO THE QUEUE OF SPQES       09240015
*                                   (SUBPOOL QUEUE ELEMENTS).           09270015
*                                                                       09300015
*                          TCBJSTCB - JOB STEP TCB POINTER.             09330015
*                                                                       09360015
*                          TCBPKF - PROTECT KEY.                        09390015
*                                                                       09420015
*                          TCBJPQ - JOB PACK QUEUE POINTER.             09450015
*                                                                       09480015
*                          TCBPQE - PARTITION QUEUE ELEMENT POINTER OR, 09510015
*                                   IF ROLLOUT/ROLLIN, A POINTER TO THE 09540015
*                                   DUMMY PQE.                          09570015
*                                                                       09600015
*                          TCBAQE - POINTER TO QUEUE OF SUPERVISOR      09630015
*                                   QUEUE SPACE ALLOCATED TO THIS TASK. 09660015
         AIF   (&SMF EQ 0).MSSMFB                                   SMF 09666018
*                                                                   SMF 09672018
*                          TCBTCT - POINTER TO TIMING CONTROL TABLE.SMF 09678018
.MSSMFB  ANOP                                                       SMF 09684018
         AIF   (&TSO NE 1).TSOP200                                20021 09685020
*                                                                 20021 09685120
*                          TCBRBP - ADDR. OF FIRST RB             20021 09686020
*                                                                 20021 09687020
*                          TCBFLGS - TCB FLAGS                    20021 09688020
*                                                                 20021 09689020
*                          TCBTSLFG - TCB TSO FLAGS               20021 09689120
.TSOP200 ANOP                                                     20021 09689220
*                                                                       09690015
*                      2.PQE - PARTITION QUEUE ELEMENT                  09720015
*                        A QUEUE ELEMENT IDENTIFYING THE FIRST AND LAST 09750015
*                        FBQES IN AN FBQE QUEUE, THE NEXT AND PREVIOUS  09780015
*                        PQES IN A ROLLOUT/ROLLIN ENVIRONMENT, THE SIZE 09810015
*                        OF THE REGION BEING DESCRIBED AND ITS STARTING 09840015
*                        ADDRESS.                                       09870015
*                                                                       09900015
*                        THESE FIELDS ARE REFERENCED                    09930015
*                                                                       09960015
*                          FWDPTR - A FOUR BYTE FIELD IN WHICH THE      09990015
*                                   FIRST BYTE IS ZERO AND IN WHICH THE 10020015
*                                   LAST THREE BYTES CONTAIN A POINTER  10050015
*                                   TO THE LOWEST ADDRESS FBQE IN THE   10080015
*                                   REGION OR THE ADDRESS OF THE PQE.   10110015
*                                                                       10140015
*                          BCKPTR - A FOUR BYTE FIELD IN WHICH THE      10170015
*                                   FIRST BYTE IS ZERO AND IN WHICH THE 10200015
*                                   LAST THREE BYTES CONTAIN A POINTER  10230015
*                                   TO THE HIGHEST ADDRESS FBQE IN THE  10260015
*                                   REGION OR THE ADDRESS OF THE PQE.   10290015
*                                                                       10320015
*                          PQENXT - A FOUR BYTE FIELD IN WHICH THE      10350015
*                                   FIRST BYTE IS ZERO AND IN WHICH THE 10380015
*                                   LAST THREE BYTES CONTAIN A POINTER  10410015
*                                   TO THE PQE OF THE NEXT HIGHEST      10440015
*                                   ADDRESSED PARTITION.                10470015
*                                                                       10500015
*                          PQEPREV - A FOUR BYTE FIELD IN WHICH THE     10530015
*                                    FIRST BYTE IS ZERO AND IN WHICH    10560015
*                                    THE LAST THREE BYTES CONTAIN A     10590015
*                                    POINTER TO THE PQE OF THE NEXT     10620015
*                                    LOWEST ADDRESSED PARTITION.        10650015
*                                                                       10680015
*                          PQETCB - A FOUR BYTE FIELD IN WHICH THE      10710015
*                                   FIRST BYTE IS ZERO AND IN WHICH THE 10740015
*                                   LAST THREE BYTES CONTAIN A POINTER  10770015
*                                   TO THE OWNING TCB.                  10800015
*                                                                       10830015
*                          PQERGSZ - A FOUR BYTE FIELD IN WHICH THE     10860015
*                                    FIRST BYTE IS ZERO AND IN WHICH    10890015
*                                    THE LAST THREE BYTES CONTAIN THE   10920015
*                                    SIZE OF THE REGION.                10950015
*                                                                       10980015
*                          PQESTADD - A FOUR BYTE FIELD IN WHICH THE    11010015
*                                     FIRST BYTE IS ZERO AND IN WHICH   11040015
*                                     THE LAST THREE BYTES CONTAIN A    11070015
*                                     POINTER TO THE STARTING ADDRESS   11100015
*                                     OF THE REGION.                    11130015
*                                                                       11160015
*                          BORROWED PARTITION BIT - BIT INDICATOR WHICH 11190015
*                                                   INDICATES THAT THIS 11220015
*                                                   PARTITION IS OWNED  11250015
*                                                   BY ANOTHER TASK.    11280015
*                                                                       11310015
         AIF   ('&LCS' NE 'Y').LC16                                LC0A 11315017
*                          PQEHIID - A ONE BYTE FIELD CONTAINING   LC0A 11320017
*                                    THE HIERARCHY IDENTIFICATION  LC0A 11325017
.LC16    ANOP                                                      LC0A 11330017
*                                                                  LC0A 11335017
*                      3.FBQE - FREE BLOCK QUEUE ELEMENT                11340015
*                        A QUEUE ELEMENT WHICH IDENTIFIES AND DESCRIBES 11370015
*                        ONE OR MORE CONTIQUOUS FREE 2K BLOCKS.         11400015
*                                                                       11430015
*                        THESE FIELDS ARE REFERENCED                    11460015
*                                                                       11490015
*                          FWDPTR - A FOUR BYTE FIELD IN WHICH THE      11520015
*                                   FIRST BYTE IS ZERO AND IN WHICH THE 11550015
*                                   LAST THREE BYTES CONTAIN A POINTER  11580015
*                                   TO THE LOWEST ADDRESS FBQE IN THE   11610015
*                                   REGION.                             11640015
*                                                                       11670015
*                          BCKPTR - A FOUR BYTE FIELD IN WHICH THE      11700015
*                                   FIRST BYTE IS ZERO AND IN WHICH THE 11730015
*                                   LAST THREE BYTES CONTAIN A POINTER  11760015
*                                   TO THE HIGHEST ADDRESS FBQE IN THE  11790015
*                                   REGION.                             11820015
*                                                                       11850015
*                          SIZE - A FOUR BYTE FIELD IN WHICH THE FIRST  11880015
*                                 BYTE IS ZERO AND IN WHICH THE LAST    11910015
*                                 THREE BYTES CONTAIN THE SIZE OF THE   11940015
*                                 FREE AREA.  THIS IS ALWAYS A MULTIPLE 11970015
*                                 OF 2K.                                12000015
*                                                                       12030015
*                      4.SPQE - SUBPOOL QUEUE ELEMENT                   12060015
*                        THE QUEUE ELEMENT ESTABLISHED TO IDENTIFY A    12090015
*                        SUBPOOL.                                       12120015
*                                                                       12150015
*                        THESE FIELDS ARE REFERENCED                    12180015
*                                                                       12210015
*                          SHARED SUBPOOL BIT - BIT INDICATOR WHICH     12240015
*                                               INDICATES THAT THIS     12270015
*                                               SUBPOOL IS OWNED BY     12300015
*                                               ANOTHER TASK.           12330015
*                                                                       12360015
*                          LAST SPQE BIT - BIT INDICATOR WHICH          12390015
*                                          INDICATES THAT THIS IS THE   12420015
*                                          LAST SPQE IN THE QUEUE.      12450015
*                                                                       12480015
*                          NEXT SPQE FIELD - A THREE BYTE FIELD WHICH   12510015
*                                            CONTAINS THE ADDRESS OF    12540015
*                                            THE NEXT SPQE IN THE QUEUE 12570015
*                                            EXCEPT IN THE LAST SPQE IN 12600015
*                                            THE QUEUE IN WHICH CASE IT 12630015
*                                            CONTAINS ZERO.             12660015
*                                                                       12690015
*                          SPQEID FIELD - A ONE BYTE FIELD CONTAINING   12720015
*                                         THE SUBPOOL ID NUMBER.        12750015
*                                                                       12780015
*                          SPQEDQE FIELD - A THREE BYTE FIELD           12810015
*                                          CONTAINING THE POINTER TO    12840015
*                                          THE FIRST DQE (DESCRIPTOR    12870015
*                                          QUEUE ELEMENT) BELONGING TO  12900015
*                                          THIS SUBPOOL EXCEPT IN A     12930015
*                                          SHARED SUBPOOL IN WHICH CASE 12960015
*                                          THIS FIELD POINTS TO THE     12990015
*                                          OWNING SPQE.                 13020015
*                                                                       13050015
*                      5.DQE - DESCRIPTOR QUEUE ELEMENT                 13080015
*                        A QUEUE ELEMENT WHICH IDENTIFIES A SET OF      13110015
*                        CONTIGUOUS 2048 BYTE BLOCKS BELONGING TO A     13140015
*                        SUBPOOL.                                       13170015
*                                                                       13200015
*                        THESE FIELDS ARE REFERENCED                    13230015
*                                                                       13260015
*                          DQEFQE FIELD - THIS IS A THREE BYTE FIELD    13290015
*                                         WHICH POINTS TO THE FIRST FQE 13320015
*                                         IN THE SET OF 2048 BYTE       13350015
*                                         BLOCKS EXCEPT WHEN THERE ARE  13380015
*                                         NO FREE AREAS.  IT IS THEN    13410015
*                                         ZERO.                         13440015
*                                                                       13470015
*                          NEXT DQE POINTER FIELD - THIS IS A THREE     13500015
*                                                   BYTE FIELD WHICH    13530015
*                                                   POINTS TO THE NEXT  13560015
*                                                   DQE IN THE QUEUE    13590015
*                                                   EXCEPT IN THE LAST  13620015
*                                                   DQE IN THE QUEUE IN 13650015
*                                                   WHICH IT IS ZERO.   13680015
         AIF   ('&LCS' NE 'Y').LC17                                LC0A 13685017
*                                                                  LC0A 13690017
*                          DQEHIID - A ONE BYTE FIELD CONTAINING   LC0A 13695017
*                                    THE HIERARCHY IDENTIFICATION  LC0A 13700017
.LC17    ANOP                                                      LC0A 13705017
*                                                                       13710015
*                          DQE ADDRESS FIELD - THIS IS A FOUR BYTE      13740015
*                                              FIELD IN WHICH THE FIRST 13770015
*                                              BYTE IS ZERO AND THE     13800015
*                                              LAST THREE BYTES CONTAIN 13830015
*                                              THE ADDRESS OF THE FIRST 13860015
*                                              2048 BYTE BLOCK          13890015
*                                              DESCRIBED BY THIS DQE.   13920015
*                                                                       13950015
*                          DQE LENGTH FIELD - THIS IS A FOUR BYTE FIELD 13980015
*                                             IN WHICH THE FIRST BYTE   14010015
*                                             IS ZERO AND THE LAST      14040015
*                                             THREE BYTES CONTAIN THE   14070015
*                                             NUMBER OF BYTES IN THE    14100015
*                                             SET OF CONTIGUOUS 2048    14130015
*                                             BYTE BLOCKS DESCRIBED BY  14160015
*                                             THIS DQE.                 14190015
*                                                                       14220015
*                      6.FQE - FREE AREA QUEUE ELEMENT                  14250015
*                        A QUEUE ELEMENT WHICH IDENTIFIES AND DESCRIBES 14280015
*                        A FREE AREA WITHIN THE SET OF 2048 BYTE BLOCKS 14310015
*                        DESCRIBED BY A DQE.                            14340015
*                                                                       14370015
*                        THESE FIELDS ARE REFERENCED                    14400015
*                                                                       14430015
*                          NEXT FQE FIELD - A FOUR BYTE FIELD IN WHICH  14460015
*                                           THE FIRST BYTE IS ZERO AND  14490015
*                                           IN WHICH THE LAST THREE     14520015
*                                           BYTES CONTAIN A POINTER TO  14550015
*                                           THE NEXT FREE AREA EXCEPT   14580015
*                                           IN THE LAST FREE AREA IN    14610015
*                                           THE QUEUE IN WHICH THIS     14640015
*                                           FIELD IS ZERO.              14670015
*                                                                       14700015
*                          FQE LENGTH FIELD - A FOUR BYTE FIELD IN      14730015
*                                             WHICH THE FIRST BYTE IS   14760015
*                                             ZERO AND IN WHICH THE     14790015
*                                             LAST THREE BYTES CONTAIN  14820015
*                                             THE NUMBER OF BYTES IN    14850015
*                                             THIS FREE AREA (THIS      14880015
*                                             INCLUDES THE QUEUE        14910015
*                                             ELEMENT).                 14940015
*                                                                       14970015
*                      7.AQE - QUEUE ELEMENT FOR STORAGE ALLOCATED TO   15000015
*                        SUBPOOL 253 OR 254.                            15030015
*                                                                       15060015
*                        THESE FIELDS ARE REFERENCED                    15090015
*                                                                       15120015
*                          NEXT AQE FIELD - A FOUR BYTE FIELD IN WHICH  15150015
*                                           THE FIRST BYTE IS ZERO AND  15180015
*                                           IN WHICH THE LAST THREE     15210015
*                                           BYTES CONTAIN A POINTER TO  15240015
*                                           THE NEXT AQE FOR THIS TASK  15270015
*                                           EXCEPT IN THE LAST AQE IN   15300015
*                                           THE QUEUE FOR THIS TASK IN  15330015
*                                           WHICH THIS FIELD IS ZERO.   15360015
*                                                                       15390015
*                          AQE LENGTH FIELD - A FOUR BYTE FIELD IN      15420015
*                                             WHICH THE FIRST BYTE IS   15450015
*                                             ZERO AND IN WHICH THE     15480015
*                                             LAST THREE BYTES CONTAIN  15510015
*                                             THE NUMBER OF BYTES IN    15540015
*                                             THIS ALLOCATED AREA (THIS 15570015
*                                             INCLUDES THE QUEUE        15600015
*                                             ELEMENT).                 15630015
*                                                                       15660015
*                      8.CDE - CONTENTS DIRECTORY ENTRY                 15690015
*                                                                       15720015
*                        THESE FIELDS ARE REFERENCED                    15750015
*                                                                       15780015
*                          CDATTR2 - A ONE BYTE FIELD CONTAINING        15810015
*                                    ATTRIBUTE FLAGS.                   15840015
*                                                                       15870015
*                          REL - AN ATTRIBUTE FLAG IN CDATTR2           15900015
*                                INDICATING THAT THE LOAD MODULE IS     15930015
*                                INACTIVE AND MAY BE RELEASED.          15960015
*                                                                       15990015
*                      9.DUMMY PQE                                      16020015
*                        A QUEUE ELEMENT INDENTIFYING THE FIRST AND     16050015
*                        LAST PQES ON THE PQE CHAIN                     16080015
         AIF   (&SMF EQ 0).MSSMFC                                   SMF 16081018
*                                                                   SMF 16082018
*                     10.TCT - TIMING CONTROL TABLE.                SMF 16083018
*                                                                   SMF 16084018
*                        THESE FIELDS ARE REFERENCED.               SMF 16085018
*                                                                   SMF 16086018
*                          TCTLWM - HIGHEST ADDRESS ALLOCATED FROM  SMF 16087018
*                                   LOW END OF REGION.              SMF 16088018
*                                                                   SMF 16089018
*                          TCTHWM - LOWEST ADDRESS ALLOCATED FROM   SMF 16090018
*                                   HIGH END OF REGION.             SMF 16091018
*                                                                   SMF 16092018
*                          TCTMINC - MINIMUM DIFFERENCE BETWEEN LWM SMF 16093018
*                                    AND HWM IN 2K VALUE.           SMF 16094018
         AIF   ('&RORI' NE 'Y').MSSMFC                              SMF 16095018
*                                                                   SMF 16096018
*                          TCTRBC - CURRENT BORROWED CORE IN 2K BLKSSMF 16097018
*                                                                   SMF 16098018
*                          TCTMBC - MAXIMUM BORROWED CORE IN 2K BLKSSMF 16099018
.MSSMFC  ANOP                                                       SMF 16100018
*                                                                       16110015
*LIST ORIGINS, TABLES                                                   16140015
*AND CONTROL BLOCKS                                                     16170015
*INCLUDED-               NONE                                           16200015
*                                                                       16230015
*RESTRICTIONS ON                                                        16260015
*USE OF ROUTINE-       1.PROBLEM PROGRAMS MAY ONLY USE SUBPOOLS 0-127.  16290015
*                                                                       16320015
*                      2.PROGRAMS IN SUPERVISOR MODE MAY ALSO USE       16350015
*                        SUBPOOLS 128-255, BUT ONLY AS  DEFINED BY THE  16380015
*                        SUPERVISOR.                                    16410015
*                                                                       16440015
*                      3.DISABLED ROUTINES MAY NOT USE THE              16470015
*                        UNCONDITIONAL FORM OF SVC 4 OR THE GETMAIN     16500015
*                        FORM OF SVC 10.                                16530015
*                                                                       16560015
*NOTES-                  NONE                                           16590015
         EJECT                                                          16620015
*        INPUT PARAMETERS                                               16650015
*                                                                       16680015
*    TO REGMAIN (SVC 10)                                                16710015
*                                                                       16740015
*        REGISTER 0 = SUBPOOL ID IN THE HIGH ORDER BYTE                 16770015
*                   = LENGTH IN THE LOW ORDER THREE BYTES               16800015
*                                                                       16830015
*        REGISTER 1 = ANY NEGATIVE VALUE IF REQUEST IS TO GETMAIN       16860015
*                   = THE POSITIVE ADDRESS OF THE AREA TO BE FREED IF   16890015
*                          THE REQUEST IS TO FREEMAIN                   16920015
*                                                                       16950015
*                                                                       16980015
*    TO GETMAIN (SVC 4)                                                 17010015
*                                                                       17040015
*        REGISTER 1 = ADDRESS OF A PRAMETER LIST                        17070015
*                                                                       17100015
*                                                                       17130015
*    TO FREEMAIN (SVC 5)                                                17160015
*                                                                       17190015
*        REGISTER 1 = ADDRESS OF A PARAMETER LIST                       17220015
*                                                                       17250015
*    TO BRANCH ENTRY POINTS                                             17280015
*                                                                       17310015
*        SAME INPUT AS FOR CORRESPONDING SVC ENTRY EXCEPT THAT IN       17340015
*        ADDITION THE ENVIRONMENTAL REGISTERS AND THE RETURN REGISTER   17370015
*        MUST BE SET UP BY THE CALLER SINCE THE INTERRUPT HANDLER IS    17400015
*        BYPASSED.                                                      17430015
*                                                                       17460015
*                                                                       17490015
*    PARAMETER LIST FORMAT                                              17520015
*                                                                       17550015
*              ********************************************             17580015
*              * LENGTH REQUESTED IF SINGLE AREA REQUEST  *             17610015
*              *  OR ADDRESS OF A LIST OF LENGTHS         *             17640015
*              ********************************************             17670015
         AIF   ('&LCS' NE 'Y').LC18                                LC0A 17675017
*              * HIERARCHY*     ADDRESS OF AREA LIST      *        LC0A 17680017
*              *   IDENT  *                               *        LC0A 17685017
         AGO   .LC19                                               LC0A 17690017
.LC18    ANOP                                                      LC0A 17695017
*              * ADDRESS OF A LIST IN WHICH THE ADDRESSES *             17700015
*              *  OF ALLOCATED AREAS IS TO BE RETURNED    *             17730015
.LC19    ANOP                                                      LC0A 17740017
*              ********************************************             17760015
*              * CODE     * SUBPOOL  *                                  17790015
*              *          *   ID     *                                  17820015
*              ***********************                                  17850015
*                                                                       17880015
*          CODE VALUES                                                  17910015
*              X'00' - UNCONDITIONAL SINGLE ELEMENT REQUEST             17940015
*              X'20' - CONDITIONAL     ''     ''      ''                17970015
*              X'C0' - UNCONDITIONAL VARIABLE REQUEST                   18000015
*              X'E0' - CONDITIONAL      ''      ''                      18030015
*              X'80' - UNCONDITIONAL LIST REQUEST                       18060015
*              X'A0' - CONDITIONAL    ''    ''                          18090015
         EJECT                                                          18120015
*    LIST FORMATS                                                       18150015
*                                                                       18180015
*        SINGLE ELEMENT REQUEST                                         18210015
*                                                                       18240015
*           AREA LIST                                                   18270015
*              ********************************************             18300015
*              *          * ADDRESS OF AREA ALLOCATED     *             18330015
*              ********************************************             18360015
*                                                                       18390015
*        VARIABLE REQUEST                                               18420015
*                                                                       18450015
*           LENGTH LIST                                                 18480015
*              ********************************************             18510015
*              *    0     * MINIMUM LENGTH REQUESTED      *             18540015
*              ********************************************             18570015
*              *    0     * MAXIMUM LENGTH REQUESTED      *             18600015
*              ********************************************             18630015
*                                                                       18660015
*           AREA LIST                                                   18690015
*              ********************************************             18720015
*              *          * ADDRESS OF AREA ALLOCATED     *             18750015
*              ********************************************             18780015
*              *          * ACTUAL LENGTH ALLOCATED       *             18810015
*              ********************************************             18840015
*                                                                       18870015
*        LIST REQUEST                                                   18900015
*                                                                       18930015
*           LENGTH LIST                                                 18960015
*              ********************************************             18990015
*              * SIGN = 0 * FIRST LENGTH REQUESTED        *             19020015
*              ********************************************             19050015
*              * SIGN = 0 * SECOND LENGTH REQUESTED       *             19080015
*              ********************************************             19110015
*              /                                          /             19140015
*              ********************************************             19170015
*              * SIGN = 1 * LAST LENGTH REQUESTED         *             19200015
*              ********************************************             19230015
*                                                                       19260015
*           AREA LIST                                                   19290015
*              ********************************************             19320015
*              *          * ADDR OF AREA FOR FIRST LENGTH *             19350015
*              ********************************************             19380015
*              *          * ADDR OF AREA FOR SECOND LENGTH*             19410015
*              ********************************************             19440015
*              /                                          /             19470015
*              ********************************************             19500015
*              *          * ADDR OF AREA FOR LAST LENGTH  *             19530015
*              ********************************************             19560015
         EJECT                                                          19590015
         SPACE                                                          19620015
         SPACE 2                                                        19650015
*    PQE - PARTITION QUEUE ELEMENT                                      19680015
         SPACE                                                          19710015
*********************************************************************   19740015
*        *  FORWARD FBQE POINTER  *        * BACKWARD FBQE POINTER  *   19770015
*   0    *  OR PQE ADDRESS        *   0    * OR PQE ADDRESS         *   19800015
*        *         (FWDPTR)       *        *        (BCKPTR)        *   19830015
*********************************************************************   19860015
*        *                        *        *                        *   19890015
*   0    *   FORWARD PQE POINTER  *   0    *  BACKWARD PQE POINTER  *   19920015
*        *        (PQENXT)        *        *       (PQEPREV)        *   19950015
*********************************************************************   19980015
*        *                        *        *                        *   20010015
*   0    *      TCB POINTER       *    0   *    SIZE OF REGION      *   20040015
*        *        (PQETCB)        *        *      (PQERGSZ)         *   20070015
*********************************************************************   20100015
*        *   ADDRESS OF FIRST     *        *        *               *   20130015
*   0    *    BYTE IN REGION      * FLAGS  * HI ID  *        0      *   20160015
*        *      (PQESTADD)        *        *        *               *   20190015
*********************************************************************   20220015
         SPACE                                                          20250015
*        FLAGS- X'80' - PQE REGION IS BORROWED BY ROLLOUT               20280015
         SPACE 3                                                        20310015
*    FBQE - FREE BLOCK QUEUE ELEMENT                                    20340015
         SPACE                                                          20370015
*********************************************************************   20400015
*        *                        *        *                        *   20430015
*   0    *     FORWARD POINTER    *    0   *    BACKWARD POINTER    *   20460015
*        *         (FWDPTR)       *        *        (BCKPTR)        *   20490015
*********************************************************************   20520015
*        *                        *                                     20550015
*   0    *          SIZE          *                                     20580015
*        *                        *                                     20610015
***********************************                                     20640015
         SPACE 3                                                        20670015
*    SPQE - SUBPOOL QUEUE ELEMENT                                       20700015
         SPACE                                                          20730015
*********************************************************************   20760015
*        *  SPQE POINTER OR       * SUBPOOL*  DQE ADDRESS OR        *   20790015
* FLAGS  *    ZERO (IF LAST SPQE) *   ID   *   SPQE OF HIGHER LEVEL *   20820015
*        *                        *        *   TASK SHARING SUBPOOL *   20850015
*********************************************************************   20880015
         SPACE                                                          20910015
*        FLAGS- X'80' - SUBPOOL IS SHARED                               20940015
*             - X'40' - LAST SPQE ON CHAIN                              20970015
         SPACE 3                                                        21000015
*    DQE - DESCRIPTOR QUEUE ELEMENT                                     21030015
         SPACE                                                          21060015
*********************************************************************   21090015
*        *                        *        *                        *   21120015
*   0    *    FQE POINTER         *    0   *      DQE POINTER       *   21150015
*        *   (0 = NO FQES)        *        * (0 = LAST DQE ON CHAIN)*   21180015
*********************************************************************   21210015
*        *                        *        *    NUMBER OF BYTES     *   21240015
         AIF   ('&LCS' NE 'Y').LC20                                LC0A 21246017
* HI ID  *  FIRST BLOCK ADDRESS   *    0   *       IN BLOCKS        *   21252017
         AGO   .LC21                                               LC0A 21258017
.LC20    ANOP                                                      LC0A 21264017
*   0    *  FIRST BLOCK ADDRESS   *    0   *       IN BLOCKS        *   21270015
.LC21    ANOP                                                      LC0A 21280017
*        *                        *        *                        *   21300015
*********************************************************************   21330015
         SPACE 3                                                        21360015
*    FQE - FREE QUEUE ELEMENT                                           21390015
         SPACE                                                          21420015
*********************************************************************   21450015
*        *                        *        *                        *   21480015
*   0    *    FQE POINTER         *    0   * LENGTH OF FREE AREA    *   21510015
*        *                        *        *                        *   21540015
*********************************************************************   21570015
         SPACE 4                                                        21600015
*    AQE - ALLOCATED SUPERVISOR QUEUE SPACE QUEUE ELEMENT (FOR SUBPOOLS 21630015
*          253-254)                                                     21660015
         SPACE                                                          21690015
*********************************************************************   21720015
*        *                        *        *                        *   21750015
*   0    *    AQE POINTER         *    0   *       LENGTH OF        *   21780015
*        *                        *        *     ALLOCATED AREA     *   21810015
*********************************************************************   21840015
         AIF   (&SMF EQ 0).MSSMFD                                   SMF 21841018
         SPACE 4                                                    SMF 21842018
*    TCT - TIMING CONTROL TABLE CORE USED AREA.                     SMF 21843018
         SPACE 1                                                    SMF 21844018
********************************************************************SMF 21845018
*        *                        *        *                        SMF 21846018
*   0    *    LOW WATER MARK      *   0    *     HIGH WATER MARK    SMF 21847018
*        *                        *        *                        SMF 21848018
********************************************************************SMF 21849018
*                *                *                                 SMF 21850018
* MINIMUM DIFF.  *  REGION SIZE   *                                 SMF 21851018
* (2K BLOCKS)    *  (2K BLOCKS)   *                                 SMF 21852018
********************************************************************SMF 21853018
         AIF   ('&RORI' NE 'Y').MSSMFD                              SMF 21854018
         SPACE 1                                                    SMF 21855018
********************************************************************SMF 21856018
*                                 *                *                SMF 21857018
*                                 * CUR BORWD CORE * MAX BORWD CORE SMF 21858018
*                                 *  (2K BLOCKS)   *  (2K BLOCKS)   SMF 21859018
********************************************************************SMF 21860018
.MSSMFD  ANOP                                                       SMF 21861018
         EJECT                                                          21870015
*        GETMAIN ENTRY POINT                                            21900015
*                                                                       21930015
         DS    0D                                                       21960015
IGC004   BALR  RBASE,0                                                  21990015
         USING MSSBASE,RBASE,FREBAS   ESTABLISH DOUBLE BASE       20021 22020020
*                                                                       22050015
MSSBASE  L     FREBAS,DBASADR      ESTABLISH DOUBLE BASE          20021 22060020
         MVC   MODEBYTE(1),33(0)   MOVE INTO MODE BYTE            20021 22080020
         AIF   ('&RORI' NE 'Y').GO60                               LC0A 22110017
         MVI   ENTRANT,X'F4'  SET ENTRY SWITCH TO NON-BRANCH CODE       22140015
.GO60    ANOP                                                           22170015
GMBASE   MVI   SVCBYTE,4                                                22200015
         AIF   ('&LCS' NE 'Y').LC01                                LC0A 22207017
         MVC   HIBYTE(1),4(RIN1)   ISOLATE HIERARCHY IDENT         LC0A 22214017
.LC01    ANOP                                                      LC0A 22221017
         L     IPVLBASE,IPVAL                                           22230020
         BALR  RCOMRET1,IPVLBASE   VALIDITY CHECK INPUT PARAMETERS      22260015
*                  RETURN WITH - RLENGTH = LENGTH/ADDR OF LENGTH LIST   22290015
*                                 RADDR   = ADDR OF AREA LIST           22320015
*                                 RSPID   = SUBPOOL ID                  22350015
         SPACE                                                          22380015
         TM    8(RIN1),X'C0'       CHECK TYPE OF REQUEST                22410015
         BC    4,GLIST             LIST                                 22440015
         BC    1,GVAR              VARIABLE                             22470015
*                                                                       22500015
         BAL   RGMRET,GMCOMMON     ELEMENT - BRANCH TO GET STORAGE      22530015
         B     GMSEXIT              BRANCH TO S-TYPE REQUEST EXIT       22560015
         B     GNOTSAT             EXIT-REQUEST NOT SATISFIED           22590015
         SPACE                                                          22620015
*        LIST REQUEST PROCESSING                                        22650015
*                                                                       22680015
GLIST    LR    RLST,RLENGTH        SAVE LENTH LIST ADDR                 22710015
         LA    RGMRET,GMCOMMON     ADDR OF COMMON ROUTINE               22740015
GLIST1   L     RLENGTH,0(RLST)     LOAD REQUESTED LENGTH                22770015
         AIF   ('&LCS' NE 'Y').LC02                                LC0A 22778017
         CLI   4(RIN1),X'80'       Q. CTL PGM MIXED HIERARCHY REQ. LC0A 22786017
         BNE   GLIST1A             NO                              LC0A 22794017
         MVC   HIBYTE(1),0(RADDR)  INSERT HIERARCHY IDENT FROM LISTLC0A 22802017
.LC02    ANOP                                                      LC0A 22810017
GLIST1A  LA    RLENGTH,0(RLENGTH)  CLEAR LAST ENTRY INDICATOR      LC0A 22818017
         BALR  RGMRET,RGMRET       BRANCH TO COMMON ROUTINE             22830015
         B     GLEFND              ENTRY FOUND                          22860015
*                                                                       22890015
*        LIST REQUEST NOT SATISFIED-RELEASE CORE ALREADY ALLOCATED      22920015
*                                                                       22950015
         B     GNOTSAT                                                  22980015
GLIST2   C     RLST,0(RIN1)        IF FIRST LIST ENTRY FAILED           23010015
         AIF   ('&RORI' NE 'Y').GOR5                               LC0A 23040017
         BCR   8,RORIREG  BYPASS FREEING ENTRIES                        23070015
         AGO   .GOR6                                                    23100015
.GOR5    ANOP                                                           23130015
         BE    GNOTSAT4  BYPASS FREEING ENTRIES                         23160015
.GOR6    ANOP                                                           23190015
         LA    RWORK2,4            DECREMENT LIST ADDRESS TO LAST       23220015
         SR    RLST,RWORK2           ENTRY ALLOCATED                    23250015
         OI    0(RLST),X'80'     SET TEMPORARY END OF LIST FOR FREEMAIN 23280015
         ST    RLST,SAVEREGS+LSTREG     SAVE CURRENT LIST ADDR    ****  23310015
         L     RLST,0(RIN1)        LOAD STARTING LIST ADDRESSES         23340015
         L     RADDR,4(RIN1)                                            23370015
         LA    RFMRET,FCOMMON1                                          23400015
         BAL   RRETURN,FLISTADV    FREE LIST ENTRIES ALREADY ALLOCATED  23430015
         NI    FREESW,255-X'08'                                   21016 23440021
         LM    RADDR,FREBAS,SAVEREGS  RESTORE REGS (11-3)         20021 23460020
         XI    0(RLST),X'80'       TURN OFF TEMPORARY END OF LIST BIT   23490015
         AIF   ('&RORI' NE 'Y').GOR7                               LC0A 23520017
         BCR   15,RORIREG  EXIT-REQUEST NOT SATISFIED                   23550015
         AGO   .GOR8                                                    23580015
.GOR7    ANOP                                                           23610015
         B     GNOTSAT4  EXIT-REQUEST NOT SATISFIED                     23640015
.GOR8    ANOP                                                           23670015
*                                                                       23700015
*        CHECK FOR MORE LIST ENTRIES                                    23730015
*                                                                       23760015
GLEFND   TM    0(RLST),X'80'       IS THIS LAST ENTRY IN LIST           23790015
         AIF   ('&RORI' NE 'Y').GO101                              LC0A 23820017
         MVI   PQESTAT,X'00'       RESET SEARCH TO OWNED CORE           23850015
.GO101   ANOP                                                           23880015
         BO    GMSEXIT               YES - EXIT                         23910015
*                                                                       23940015
         LA    RLST,4(RLST)          NO  - CHECK NEXT ENTRY             23970015
         AIF   ('&RORI' NE 'Y').GO102                              LC0A 24000017
         L     RADDR,SAVEREGS                                           24030015
.GO102   ANOP                                                           24060015
         LA    RADDR,4(RADDR)                                           24090015
         LA    RGMRET,GCOMMON1     ADDR OF COMMON ROUTINE BYPASSING     24120015
*                                     SPQE SEARCH                       24150015
         B     GLIST1                                                   24180015
*                                                                       24210015
*                                                                       24240015
*        VARIABLE REQUEST PROCESSING                                    24270015
*                                                                       24300015
GVAR     LR    RLST,RLENGTH                                             24330015
         L     RLENGTH,4(RLST)     LOAD MAXIMUM REQUESTED               24360015
         BAL   RGMRET,GMCOMMON     GET STORAGE                          24390015
         B     GVARFND             CORE FOUND                           24420015
*                                  CORE NOT FOUND                       24450015
         BAL   RRET,CDPURGE        PURGE JPA AND LPA                    24480015
         AIF   ('&RORI' NE 'Y').GO70                               LC0A 24510017
         B     PURGSW             IF STORAGE FREED                      24540015
         AGO   .GO71                                                    24570015
.GO70    ANOP                                                           24600015
         B     GMREPEAT            IF STORAGE FREED                     24630015
.GO71    ANOP                                                           24660015
         AIF   ('&RORI' NE 'Y').GO72                               LC0A 24690017
         TM    IEAROSW,X'FF'  IS ROLLOUT DATA SET OPEN.                 24720015
         BO    GVFNDR  NO. TRY TO SATISFY MINIMUM.                      24750015
         TM    8(RIN1),X'E0'    IS THIS A VAR COND REQ?         SA63045 24752021
         BC    1,GVFNDR .                YES, BR TO SAT MIN NOT  A26046 24754020
*                                            CAUSING A ROLLOUT   A26046 24756020
         ST    RADDR,SAVEREGS      SAVE ADDR. OF AREA ALLOCATED         24760017
         L     FPQEBASE,FRBASEAD                                        24770017
         L     RORIREG,VARUNCAD                                         24780017
         BR    RORIREG                                                  24790017
.GO72    ANOP                                                           24810015
GVFNDR   EQU   * .                                               A31213 24840020
         LTR   RSPID,RSPID         REQUEST FOR SUBPOOL 253 OR 254       24870015
         BC    11,GMINCK             NO-CHECK MINIMUM LENGTH            24900015
         LA    RGMRET,8            DECREMENT MAXIMUM AVAILABLE TO ALLOW 24930015
         SR    RLRGSIZ,RGMRET       FOR QEC                             24960015
*                                                                       24990015
GMINCK   EQU   * .                                               A31213 24992020
         LR    RGMRET,RLENGTH .          SAVE MAX LENGTH         A31213 24994020
         L     RLENGTH,0(RLST) .         LOAD MIN LENGTH         A31213 24996020
         C     RLENGTH,FBQESIZ .         IS LENGHT > THAN FBQE?  A31213 24998020
         BH    CKMAX .                   YES, BRANCH             A31213 25000020
         L     RLENGTH,FBQESIZ .         LOAD SIZE FOR ALLOC     A31213 25002020
         B     GETMIN .                                          A31213 25004020
GNTST4   EQU   * .                                               A31213 25006020
         AIF   ('&RORI' EQ 'Y').RO0                              A31213 25008020
         B     GNOTSAT4 .              PROCESS CONDITIONAL REQ   A31213 25010020
         AGO   .RO1                                              A31213 25012020
.RO0     ANOP                                                    A31213 25014020
         SR    RLENGTH,RGMRET .    RESTORE MAX SIZ FOR RORI      A31213 25016020
         L     FPQEBASE,FRBASEAD .      LOAD BASE FOR BRANCH     A31213 25018020
         L     RORIREG,GNSAT4AD .       LOAD ADDR OF GNOTSAT4    A31213 25020020
         BR    RORIREG .                BRANCH TO GNOTSAT4       A31213 25022020
.RO1     ANOP                                                    A31213 25024020
CKMAX    EQU   * .                                               A31213 25026020
         C     RLENGTH,K4080 .      CAN REQUEST BE SAT BY FQE    A31213 25028020
         BH    GNTST4 .             NO, PROCESS CONDITIONAL REQ  A31213 25030020
         L     RLENGTH,K4080 .         LARGEST FQE CAN ALLOC  BC A49843 25030421
         L     RADDR,SAVEREGS .                               BC A49843 25030821
         BAL   RGMRET,GCOMMON1 .      INIT FQESIZE FIELD      BC A49843 25031221
         B     GVARFND .              CORE FOUND              BC A49843 25031621
         L     RLENGTH,0(RLST) .     RELOAD MIN LENGTH        BC A49843 25031721
         C     RLENGTH,FQESIZ .     IS FREE CORE AVAIL IN FQE    A31213 25032020
         BH    GNTST4 .             NO, PROCESS CONDITIONAL REQ  A31213 25034020
         L     RLENGTH,FQESIZ .     LOAD SIZE OF LARGEST FQE     A31213 25036020
GETMIN   EQU   * .                                               A31213 25038020
         L     RADDR,SAVEREGS .                                  A31213 25040020
*                                                                       25080015
         BAL   RGMRET,GCOMMON1       -BYPASS SPID CHECK                 25140015
         B     GVARFND             CORE FOUND                           25170015
         AIF   ('&RORI' NE 'Y').GO77                               LC0A 25200017
         L     FPQEBASE,FRBASEAD                                        25210017
         L     RORIREG,ROTST5AD                                         25220017
         BR    RORIREG                                                  25230017
         AGO   .GO78                                                    25260015
.GO77    ANOP                                                           25290015
         B     GNTST4   NO CORE AVAILABLE, PROCESS COND. REQ    SA66067 25320021
.GO78    ANOP                                                           25350015
*                                                                       25380015
         AIF   ('&RORI' NE 'Y').GO103                              LC0A 25410017
GVARFND  L     RADDR,SAVEREGS      LOAD ADDRESS OF AREA LIST IN REG. A  25440015
         ST    RLENGTH,4(RADDR)    STORE ALLOCATED LENGTH IN LIST       25470015
         AGO   .GO104                                                   25500015
.GO103   ANOP                                                           25530015
GVARFND  ST    RLENGTH,4(RADDR)    STORE ALLOCATED LENGTH IN LIST       25560015
.GO104   ANOP                                                           25590015
         B     GMSEXIT                                                  25620015
*                                                                       25650015
         SPACE 2                                                        25680015
*        BRANCH ENTRY PROCESSING                                        25710015
         SPACE                                                          25740015
         DROP  FREBAS .            DROP BASE FOR ADDRESSABILITY   M0105 25750020
GMBRANCH LR    RIN15,RBASE         SAVE REGISTER 8                      25770015
         BALR  RBASE,0                                                  25800015
         USING *,RBASE                                                  25830015
         L     RBASE,MSSADR                                             25860015
         USING MSSBASE,RBASE,FREBAS                               20021 25890020
         SSM   CLHIBYTE .           DISABLE                       M3872 25900020
         ST    RIN15,BRANCHSV+24   RIN15 = ENTRY CONTENTS OF REG8       25920015
         LA    RIN15,GMBASE        SET UP BRANCH TO GETMAIN             25950015
GMBRNCOM STM   RLST,RCOMRET3,BRANCHSV SAVE REGISTERS FOR CALLER   M3872 26010020
         STM   RCOMRET1,RRETURN,BRANCHSV+28                             26040015
         L     FREBAS,DBASADR      INITIALIZE SECOND BASE         20021 26050020
         ST    RRETURN,BRNREG   SAVE RETURN REG FOR ABEND INFO    21016 26060021
         MVI   MODEBYTE,0          SET MODE AS SUPERVISOR               26070015
         MVI   BESW,X'FF'              SET BRANCH ENTRY SWITCH          26090015
.A       BALR  RRETURN,RIN15            BRANCH TO GETMAIN OR FREEMAIN   26100015
         MVI   BESW,X'00'               RESET BRANCH ENTRY SWITCH       26120015
.B       LM    RLST,RRETURN,BRANCHSV    RESTORE REGISTERS FOR CALLER    26130015
         BR    RRETURN             RETURN TO CALLER                     26160015
         AIF   ('&RORI' NE 'Y').GO13                               LC0A 26190017
         SPACE 2                                                        26220015
IEAFRPQE CSECT                                                          26250015
         ENTRY FRBRBASE                                                 26280015
         ENTRY FREBRF                                                   26310015
         ENTRY GETIQE                                                   26340015
         ENTRY GNOTSAT4                                                 26350017
         ENTRY ROTEST5                                                  26360017
         ENTRY TESTRO                                                   26370017
         ENTRY VARUNCD                                                  26380017
FREBRPQE BALR FPQEBASE,0                                                26400015
         USING *,FPQEBASE                                               26430015
FRBRBASE CLI   CDPRGSW,X'FF'       WAS THERE A SUCCESSFUL PURGE         26460015
         BNE   RESTORE             NO, BYPASS PQE TEST                  26490015
FREBRF   EQU   * .                                               A30185 26500020
         L     RTCB,TCBJSTCB(RTCB) .    GET JOBSTP TCB ADDR      A30185 26510020
         L     RWORK1,TCBPQE(RTCB) .    PICK UP DUMMY PQE        A30185 26520020
         NI    31(RTCB),X'BF'           TURN OFF TCBFRI FLAG            26530017
         LTR   RWORK1,RWORK1                                            26550015
         BZ    RESTORE                                                  26580015
         L     RWORK1,DUMFWD(RWORK1) PICK UP REAL PQE                   26610015
MOREPQE  TM    RORIFLG(RWORK1),RGNSHRD IS THE REGION BORROWED           26640015
         BO    TSTFBQE            YES, DETERMINE IF IT IS FREE          26670015
NXTPQE   L     RWORK1,PQENXT(RWORK1)                                    26700015
         LTR   RWORK1,RWORK1      IS THIS THE END OF THE CHAIN          26730015
         BZ    RESTORE            GO TO RESTORE AND RETURN              26760015
         B     MOREPQE                                                  26790015
TSTFBQE  L     RWORK2,FWDPTR(RWORK1) PICK UP FIRST FBQE                 26820015
         CR    RWORK2,RWORK1      IS FBQE PTR EQUAL TO PQE PTR          26850015
         BE    SETRIFLG .            YES,SET RORI FLAG           A32583 26880020
         CLC   FBQESIZE(4,RWORK2),PQERGSZ(RWORK1) IS THE AREA FREE      26910015
         BE    SCHEDRRI                                                 26940015
SETRIFLG EQU   *                                                SA63886 26950021
*****    THE NEXT STATEMENTS DETERMINE IF WE'RE RUNNING ******  SA63886 26950221
*****    UNDER AN INITIATOR FOR A JSTCB, IF SO DON'T TURN ON *  SA63886 26950421
*****    TCBFRI FLAG IN THE TCB                        *******  SA63886 26950621
         L     RWORK2,132(RTCB)   PICK UP MOTHER TCB            SA63886 26950821
         L     RWORK2,132(RWORK2) PICK UP MOTHER'S MOTHER       SA63886 26951021
         L     RWORK3,MSCEDADD     PICK UP M/S TCB              SA63886 26951221
         CR    RWORK2,RWORK3   IS GRANDMOTHER TCB THE M/S?      SA63886 26951421
         BE    RESTORE         YES, DON'T TURN ON TCBFRI        SA63886 26951621
         OI    31(RTCB),X'40'  TURN ON TCBFRI FLAG              SA63886 26951821
         B     NXTPQE                                                   26970015
SCHROUT  LCR   RWORK4,RWORK4            COMPLEMENT IQE ADDRESS          27030015
         ST    RRETURN,BASEHOLD                                         27060015
         L     RRETURN,16(0)                                            27090015
         L     RRETURN,CVT0EF00(RRETURN)                                27120015
         BALR  RRETURN,RRETURN          SCHEDULE IRB                    27150015
         L     RRETURN,BASEHOLD         RESTORE AND RETURN              27180015
         BR    RORIREG                                                  27210015
SCHEDRRI L     RORIREG,PQETCB(RWORK1)     IS THIS THE SYSTEM QUEUE      27240015
         LTR   RORIREG,RORIREG                                          27270015
         BZ    DEQUESYS                 YES                             27300015
UPD3     L     RORIREG,PQEPREV(RWORK1)    IS THIS THE FIRST PQE         27330015
         LTR   RORIREG,RORIREG                                          27360015
         BZ    DUMFIR                                                   27390015
         L     RORIREG,PQEPREV(RWORK1)    UPDATE PQE POINTER            27420015
         MVC   PQENXT(4,RORIREG),PQENXT(RWORK1)                         27450015
UPD1     L     RORIREG,PQENXT(RWORK1)                                   27480015
         LTR   RORIREG,RORIREG              IS THIS THE LAST PQE        27510015
         BZ    DUMLST                                                   27540015
         MVC   PQEPREV(4,RORIREG),PQEPREV(RWORK1)                       27570015
UPD2     MVC   IQESAVE(4),PQERET       SAVE PQERET OVER GET IQE         27580015
         BAL   RORIREG,GETIQE          GET IQE                          27590015
         MVC   PQERET(4),IQESAVE       RESTORE PQERET                   27600015
         LA    RORIREG,16(RWORK4)  ADDRESS OF PARAMETER LIST            27630015
         ST    RWORK1,4(RORIREG)     ADDRESS OF PQE                     27660015
         ST    RTCB,0(RORIREG)       ADDRESS OF TCB                     27690015
         MVI   4(RORIREG),0          INITIALIZE REMAINDER OF LIST       27720015
         LCR   RORIREG,RORIREG                                          27750015
         ST    RORIREG,4(RWORK4)     ADDRESS OF LIST IN COMPLEMENT FORM 27780015
         BAL   RORIREG,SCHROUT       SCHEDULE IRB                       27810015
         B     NXTPQE                                                   27840015
DUMFIR   L     RORIREG,TCBPQE(RTCB)       DUMMY                         27870015
         MVC   DUMFWD(4,RORIREG),PQENXT(RWORK1)                         27900015
         B     UPD1                                                     27930015
DUMLST   L     RORIREG,TCBPQE(RTCB)       DUMMY                         27960015
         MVC   DUMBWD(4,RORIREG),PQEPREV(RWORK1)                        27990015
         L     RORIREG,PQEPREV(RWORK1)                                  28020015
         MVC   PQENXT(4,RORIREG),PQENXT(RWORK1)                         28050015
         B     UPD2                                                     28080015
DEQUESYS L     RPQE,GOVRFLB+8           ADDRESS OF PQE                  28110015
         L     RPQE,DUMFWD(RPQE)   PICK UP ADDRS OF REAL PQE            28140015
         AIF   ('&LCS' NE 'Y').LCR1                                LC0A 28145017
COMPARE  CLC   29(1,RPQE),29(RWORK1) FREE AREA IN THIS HIERARCHY   LC0A 28150017
         BE    STORE                    YES, BRANCH                LC0A 28160017
         L     RPQE,8(RPQE)             GET NEXT SYSTEM PQE        LC0A 28170017
         B     COMPARE                  TEST THIS ONE              LC0A 28180017
STORE    ST    RRETURN,BASEHOLD         SAVE REGISTER E            LC0A 28190017
         AGO   .LCR2                                               LC0A 28192017
.LCR1    ANOP                                                      LC0A 28194017
         ST    RRETURN,BASEHOLD                                    LC0A 28196017
.LCR2    ANOP                                                      LC0A 28198017
         ST    RWORK1,BASEHOLD+4     SAVE PQE ADDRESS             20021 28199020
         L     RBLOCK,FWDPTR(RWORK1)    ADDRESS OF PARTITION            28200015
         L     RSIZE,FBQESIZE(RBLOCK)   PARTITION SIZE                  28230015
         BAL   RCOMRET1,MRELEASE        RELEASE TO SYSTEM PQE           28260015
         L     RWORK1,BASEHOLD+4  RESTORE PQE ADDRESS             20021 28261020
         AIF   ('&MPS' NE 'Y').MP02                                MP65 28263017
         STM   RIN0,RIN15,VQERISAV SAVE REGS WHILE TEST VQES       MP65 28266017
         LR    RWORK5,RWORK1       PICK PQE FOR RETD STORAGE       MP65 28269017
         L     RIN1,VQBASE         ADDR OF DEFERRED VARY RTN       MP65 28272017
         BALR  RIN1,RIN1           LINK TO PROCESS VQES            MP65 28275017
         USING *,RIN1                                              MP65 28278017
         LM    RIN0,RIN15,VQERISAV RESTORE REGISTERS               MP65 28281017
         DROP  RIN1                                                MP65 28284017
.MP02    ANOP                                                      MP65 28287017
         L     RRETURN,BASEHOLD                                         28290015
         B     UPD3                                                     28320015
ROTEST5  TM    IEAROSW,X'FF'     IS ROLLOUT IN THE SYSTERM         MO18 28322018
         BO    GNOTSAT6          NO  - CANNOT ATTEMPT ROLLOUT      MO18 28324018
         CL    RSPID,C252        IS REQUEST FOR SQS                MO18 28326018
         BH    GNOTSAT6          YES - CANNOT ATTEMPT ROLLOUT      MO18 28328018
TESTRO   TM    IEAROSW,X'FF'       IS ROLLOUT DATA SET OPEN             28330017
         BO GNOTSAT8  NO.  CAN OT SATISFY REQUEST                       28332017
         CLI   PQESTAT,X'FF'      HAS REQUEST SEARCHED BORROWED         28334017
         BE    ROTEST             YES, TEST FOR ROLLOUT ELIGIBILITY     28336017
         MVI   PQESTAT,X'FF'      SET BORROWED SWITCH                   28338017
         B     GMREPEAT                                                 28340017
ROTEST   TM    ENTRANT,X'F0'  WAS THIS A BRANCH ENTRY                   28342017
         BZ    ROTEST1  YES, ROLLOUT CANNOT BE INVOKED                  28344017
         CLI   ENTRANT,X'FA'  WAS THIS A SVC 10                         28346017
         BE    SETRTRN                                                  28348017
         TM    8(RIN1),X'C0'  IS THIS A LIST REQUEST                    28350017
         BC    9,ROCONTST  NO, TEST FOR CONDITIONAL                     28352017
         BAL   RORIREG,GLIST2  YES. FREE UP CORE ALREADY GOTTEN.        28354017
         BALR  FPQEBASE,0                                               28356017
         USING *,FPQEBASE                                               28358017
         L     FPQEBASE,FRBASE                                          28360017
         USING FRBRBASE,FPQEBASE                                        28362017
ROCONTST TM    8(RIN1),32  CONDITIONAL                                  28364017
         BC    1,GNOTST1  YES. CANNOT ROLLOUT.                          28366017
SETRTRN  LA    RGMRET,GRETURN1                                          28368017
         ST    RGMRET,PQERET                                            28370017
         B     ROTEST2                                                  28372017
ROTEST1  LA    RGMRET,GNOTSAT6  SET UP RETURN POINT                     28374017
         B     PQESETP                                                  28376017
ROTEST2  L     RCVT,16(0)  PICK UP CVT                                  28378017
         L     RTCB,CVTTCB(RCVT)  PICK UP 'NEW'                         28380017
         L     RTCB,4(RTCB)  PICK UP 'OLD'                              28382017
         TM    TCBABND(RTCB),X'C0'  IS ABEND IN PROGRESS FOR STEP       28384017
         BC    5,GNOTSAT8  YES.  DON'T SCHEDULE ROLLOUT                 28386017
         L     RORIREG,TCBJSTCB(RTCB)  PICK UP JOBSTEP TCB              28388017
         TM    TCBFMC(RORIREG),X'20'  CAN THIS TASK CAUSE ROLLOUT.      28390017
         BZ    GNOTSAT8            NO                                   28392017
         AIF   ('&LCS' NE 'Y').LC51                                LC0A 28394017
         CLI   HIBYTE,X'01'        Q. IS REQUEST FOR HIERARCHY 1   LC0A 28396017
         BNE   TSTH0MAX            NO - CHECK H0 MAX. AVAIL. CORE  LC0A 28398017
         C     RLENGTH,GOVRFLB+16  Q. IS REQUEST GT AVAIL. H1 CORE LC0A 28400017
         BH    GNOTSAT8            YES - ERROR                     LC0A 28402017
         B     SHEDRO             NO - SCHEDULE ROLLOUT            MO18 28404018
TSTH0MAX C     RLENGTH,GOVRFLB+12  Q. IS REQUEST GT AVAIL. H0 CORE LC0A 28406017
         AGO   .LC52                                               LC0A 28409017
.LC51    ANOP                                                      LC0A 28412017
         C     RLENGTH,GOVRFLB+12  DOES REQUEST EXCEED AVAIL CORE SIZE  28415017
.LC52    ANOP                                                      LC0A 28418017
         BH    GNOTSAT8            YES. ZONK IDIOT TASK                 28421017
SHEDRO   MVC   IQESAVE(8),SAVEREGS+20  SAVE REGS ACROSS GETIQE     MO18 28424018
         MVC   IQESAVE+8(4),PQERET                                      28427017
         BAL   RORIREG,GETIQE      GET AN IQE                           28430017
         MVC   SAVEREGS+20(8),IQESAVE                                   28440015
         MVC   PQERET(4),IQESAVE+8                                      28470015
         LA    RORIREG,16(RWORK4)  ADDRESS OF ROLLOUT PARAMETER LIST    28500015
         ST    RTCB,0(RORIREG)           ADDRESS OF TCB                 28530015
         TM    8(RIN1),X'C0' .    IS IT A LIST REQUEST       BC  A37143 28562021
         BC    9,SHEDONE .        NO, USE ONE LENGTH         BC  A37143 28564021
         LR    RLST,RIN1 .        YES, SAVE LIST ADDR        BC  A37143 28566021
SHEDLST  L     RWORK1,0(RLST) .   ADD LENGTHS                BC  A37143 28566421
         LA    RLENGTH,RWORK1 .   CLEAR BYTE AND ADD         BC  A37143 28566821
         TM    0(RLST),X'80' .    IS TI LAST ENTRY           BC  A37143 28566921
         BO    SHEDONE .          YES, USE TOTAL             BC  A37143 28575721
         LA    RLST,4(RLST) .     NO, REPEAT                 BC  A37143 28577721
         B     SHEDLST .          ADD NEXT ELEMENT           BC  A37143 28579721
SHEDONE  ST    RLENGTH,4(RORIREG) .     SIZE OF STORAGE      BC  A37143 28581721
         AIF   ('&LCS' NE 'Y').LCR0                                LC0A 28584821
         MVC   4(1,RORIREG),HIBYTE      INSERT HIERARCHY IDENT     LC0A 28593621
.LCR0    ANOP                                                      LC0A 28602421
         ST    RORIREG,4(RWORK4)         ADDRESS OF LIST IN TRUE FORM   28611221
         BAL   RORIREG,SCHROUT           SCHEDULE IRB                   28620015
         OI   TCBFCD1(RTCB),X'20' .    INDICATE TASK WAITING     A33335 28640020
*                                   FOR CORE                     A33335 28660020
         L     RWORK1,36        LOAD RIGHT HALF OF PSW                  28680015
         LA    RWORK2,2                                                 28710015
         SR    RWORK1,RWORK2    BACK UP PSW                             28740015
         ST    RWORK1,36        STORE PSW                               28770015
         L     RWK3CVT,16(0)          RELOAD CVT ADDR             20021 28800020
         L     RWORK3,0(RWK3CVT)      LOAD ADDRESS OF NEW         20021 28830020
         CLC   0(4,RWORK3),4(RWORK3)  TASK SWITCH ALREADY INDICATED     28860015
         BNE   NOSWITCH                                                 28890015
         SR    RWORK1,RWORK1                                            28920015
         ST    RWORK1,0(RWORK3) SET 'NEW' TO 0, CAUSE A TASK SWITCH     28950015
NOSWITCH LM    RIN0,RIN1,SAVEREGS+20  RESTORE REGISTERS                 28980015
         L     14,SVCXT .          GET ADDR OF SPECIAL EXIT             28985021
         XC    PQESTAT(3),PQESTAT . TURN OFF SW FOR EXIT                28990021
         BR    14 .                GO TO SPECIAL EXIT IN QNU BL         28995021
GNOTSAT8 XC    PQESTAT(3),PQESTAT .   TURN OFF SW FOR EXIT        M3872 29000020
         B     SETERR8                                                  29010017
VARUNCD  CLI   PQESTAT,X'FF'      HAS REQUEST BEEN REISSUED             29014017
         BE    VARSRCH            YES, TEST TO ALLOCATE OR ROLLOUT      29018017
         MVI   PQESTAT,X'FF'      SEARCH BORROWED PQE                   29022017
         ST    RLRGSIZ,ORGLRG     KEEP LARGEST SIZE                     29026017
         B     GMREPEAT           REISSUE REQUEST                       29030017
VARSRCH  C     RLRGSIZ,ORGLRG     IS BORROWED LARGER THEN ORIGINAL      29034017
         BNH   FURCOM             NO, ORIGINAL WILL BE ASSIGNED         29038017
VARORG   C     RLRGSIZ,0(RLST)    IS BORROWED GREAT OR EQ TO MINIMUM    29042017
         BNL   GVFNDR             YES, ASSIGN THE CORE                  29046017
         LTR   RSPID,RSPID        REQUEST FOR SUBPOOL 253 OR 254        29050017
         BC    11,ROTEST          NO, SCHEDULE ROLLIN/ROLLOUT           29054017
         LA    RGMRET,8           DECREMENT TO ALLOW FOR QEC            29058017
         SR    RLRGSIZ,RGMRET                                           29062017
         C     RLRGSIZ,0(RLST)                                          29066017
         BNH   GNOTSAT4  CORE CANNOT BE ALLOCATED                       29070017
         B     ROTEST             TEST FOR ROLLOUT ELIGIBILITY          29074017
FURCOM   L     RLRGSIZ,ORGLRG     GET OWNED LARGEST CORE                29078017
         B     VARORG             ALLOCATE OR ROLLOUT                   29082017
GNOTSAT6 TM    ENTRANT,X'F0'  WAS THIS A BR ENTRY             A36468    29091000
         BZ    GNOTSAT4 .                                        A57079 29093021
         CLI   ENTRANT,X'FA' .         WAS IT SVC 10          BC A36468 29093521
         BE    COND2                                                    29094017
         TM    8(RIN1),X'C0'  IS THIS A LIST REQUEST                    29097017
         BC    9,GNOTSAT4  NO, TEST FOR CONDITIONAL                     29100017
         BAL   RORIREG,GLIST2  YES. FREE UP CORE ALREADY GOTTEN.        29103017
         BALR  FPQEBASE,0                                               29106017
         USING *,FPQEBASE                                               29109017
         L     FPQEBASE,FRBASE                                          29112017
         USING FRBRBASE,FPQEBASE                                        29115017
GNOTSAT4 TM    8(RIN1),32          IS THIS CONDITIONAL                  29118017
         BC    14,COND2            NO                                   29121017
GNOTST1  LA    RIN15,4             SET RETURN CODE OF 4                 29124017
         B     GRETURN             RETURN                               29127017
COND2    CL    RSPID,C252          IS REQUEST FOR SQ SPACE              29130017
         BH    GNOTSAT5            YES                                  29133017
         B     GNOTSAT8                                                 29136017
RESTORE  L     RGMRET,PQERET                                            29139017
         BR    RGMRET                                                   29142017
*                                                                       29145017
* GETIQE SUBROUTINE                                                     29148017
*                                                                       29160015
* THE FOLLOWING INSTRUCTIONS ESTABLISH PROPER ADDRESSABILITY FOR        29190015
* ROUTINES WHICH ACCESS GETIQE FROM EXTERNAL REFERENCES.                29220015
*                                                                       29250015
GETIQE   BALR  FPQEBASE,0                                               29280015
         USING *,FPQEBASE                                               29310015
         STM   RIN1,RIN0,RIVSAVE                                        29340015
         L     FPQEBASE,FRBASE                                          29370015
         USING FRBRBASE,FPQEBASE                                        29400015
*                                                                       29430015
         L     RCVT,16(0)               GET ADDRESS OF CVT              29460015
         L     RTCB,CVTTCB(RCVT)        GET ADDRESS OF 'NEW'            29490015
         L     RTCB,4(RTCB)             GET ADDRESS OF 'OLD'            29520015
         L     RPQE,AROIRB                                              29550015
         L     RIN1,RBNEXAVL(RPQE)      GET NEXT AVAILABLE IQE ADDRESS  29580015
         LTR   RIN1,RIN1                IS THERE AN AVAILABLE IQE       29610015
         BC    7,DEQIQE                 DEQUEUE IQE FROM AVAILABLE Q    29640015
         LM    RIN0,RIN1,RMBRCONS       LOAD SP, SIZE AND GETM FLAG     29670015
         L     RRETURN,REGMAIN         GET STORAGE FOR AN IQE.          29700015
         BALR  RRETURN,RRETURN                                          29730015
         MVI   0(RIN1),X'00'           CLEAR THE IQE.                   29760015
         MVC   1(23,RIN1),0(RIN1)                                       29790015
         MVC   IQEIRB(8,RIN1),AROIRB    INITIALIZE IRB ADDRESS IN IQE   29820015
*                                       AND TCB ADDRESS                 29850015
         B     RETIQE                                                   29880015
DEQIQE   L     RWORK1,0(RIN1)           GET NEXT IQE                    29910015
         ST    RWORK1,RBNEXAVL(RPQE)    UPDATE AVAILABLE IQE POINTER    29940015
RETIQE   LM    RDQE,RLENGTH,RIVSAVE+4   RESTORE                         29970015
         LM    RSPQE,RIN0,RIVSAVE+44    AND RETURN WITH IQE ADDRESS     30000015
         BR    RORIREG                                                  30030015
RIVSAVE  DS    16F                                                      30060015
IQESAVE  DS    3F                                                       30090015
RMBRCONS DC    X'FF00001880000000'                                      30120015
REGMAIN  DC    V(RMBRANCH)                                              30150015
FRBASE   DC    V(FRBRBASE)                                              30180015
         AIF   ('&MPS' NE 'Y').MP03                                MP65 30186017
VQBASE   DC    V(IFSVRYOF)                                         MP65 30192017
VQERISAV DS    16F                                                 MP65 30198017
.MP03    ANOP                                                      MP65 30204017
*                                                                       30210015
** THE FOLLOWING PAIR OF VCONS ARE POSITIONALLY DEPENDENT FOR GETIQE ** 30240015
AROIRB   DC    V(IEAROIRB)                                              30270015
ADROTCB  DC    V(IEAROTCB)                                              30300015
*                                                                       30330015
RBNEXAVL EQU   96                                                       30360015
IQEIRB   EQU   8                                                        30390015
         DROP  FPQEBASE                                                 30420015
         AIF   ('&MPS' NE 'Y').MP0118                              MP2K 30420318
.GO13    ANOP                                                           30420418
         AIF   ('&MPS' NE 'Y').GO13Z18                                  30420518
         EJECT                                                          30420618
IEAMP2K  CSECT                                                     MP2K 30420918
*                                                                       30421218
* THIS CSECTS PRIMARY FUNCTION IS TO FREE ALL SPQES, DQES AND ZERO THE  30421518
* TCBMSS FIELD WHEN THE USER COMPLETION CODE X'0F4' IS FOUND IN THE     30421818
* MAIN LINE PROGRAM. THIS SPECIAL SUBROUTINE NEGATES THE FREEING OF     30422118
* SUBPOOL ZERO AS THIS IS NO LONGER POSSIBLE BECAUSE OF STORAGE         30422418
* RECONFIGURATION. ENTRY IS VIA A BRANCH AND RETURN IS TO THE CALLER    30422718
* OF FREEMAIN ACCORDING TO CONVENTION.                                  30423018
*                                                                       30423318
         BALR  MP65BASE,RIN0           ESTABLISH ADDRESSIBILITY    MP2K 30423618
         USING *,MP65BASE                                          MP2K 30423918
         XC    TCBCMCDE(1,RTCB),TCBCMCDE(RTCB) TURN OFF COMP CODE  MP2K 30424218
         ST    RRETURN,MP2KRTUN   SAVE MP2K EXIT ADDRESS           MP2K 30424518
         L     RWORK2,TCBMSS(RTCB) GET ADDR OF SPQE IN REG 7       MP2K 30424818
         LA    RWORK2,0(RWORK2)    ZERO HIGH ORDER BYTE            MP2K 30425118
         LTR   RWORK2,RWORK2       IS TCBMSS FIELD ZERO            MP2K 30425418
         BZ    MPEXIT  BRANCH ON NO SPQES AT ALL                   MP2K 30425718
NXTSPQE1 L     RWORK5,0(RWORK2)         GET 1ST WD OF SPQE (REG2)  MP2K 30426018
         L     RWORK3,SPQEDQE(RWORK2)   GET 2ND WD OF SPQE (REG9)  MP2K 30426318
         TM    0(RWORK2),SPQESHRD  IS THIS SPQE SHARED             MP2K 30426618
         BNZ   SHSPQE                   SPQE IS SHARED - BRANCH    MP2K 30426918
         ST    RWORK5,SPQESAVE          SAVE POINTER TO NEXT SPQE  MP2K 30427218
NXTDQE1  LA    RWORK3,0(RWORK3)  0 HIGH ORDER BYTE OF DQE POINTER  MP2K 30427518
         LTR   RWORK3,RWORK3            IS THE DQE FIELD ZERO      MP2K 30427818
         BZ    NXTSPQE                  BRANCH TO GET NEXT SPQE    MP2K 30428118
         LR    RIN1,RWORK3      PUT ADDR OF DQE IN REG1            MP2K 30428418
         L     RIN0,MP2KFDQE    PUT LENGTH, SUBPOOL IN REG0        MP2K 30428718
         MVC   DQESAVE(4),DQENXT(RWORK3)  POINTER TO THE NEXT PQE  MP2K 30429018
         BAL   RRETURN,RMBRANCH    FREE DQE CORE                   MP2K 30429318
         L     RWORK3,DQESAVE   REFRESH DQE POINTER                MP2K 30429618
         B     NXTDQE1          PROCESS DQE NEXT                   MP2K 30429918
NXTSPQE  L     RWORK5,SPQESAVE  REFRESH SPQE NEXT POINTER          MP2K 30430218
         XC    K5(LEN3,RWORK2),K5(RWORK2) MAKE DQE PTR ZERO     MP2K    30430318
         LA    RWORK2,0(RWORK5) ZERO HIGH ORDER BYTE SPQE POINTER  MP2K 30430518
         LTR   RWORK2,RWORK2  IS THE SPQE POINTER NEXT ZERO        MP2K 30430818
         BZ    FMBRSPQE  BRANCH ZERO FOR ALL DQES FREED ON CHAIN   MP2K 30431118
         B     NXTSPQE1  GET NEXT SPQE                             MP2K 30431418
SHSPQE   LR    RWORK2,RWORK3  TREAT A BORROWING SPQE AS ANY SPQE   MP2K 30431718
         ST    RWORK5,SHSPQESV  SAVE CHAIN SPQE POINTERS           MP2K 30432018
         OI    TCBCMCDE(RTCB),X'B4'   SET SWITCH FOR BORROWED SPQE MP2K 30432318
         B     NXTSPQE1   GET NEXT SPQE                            MP2K 30432618
FMBRSPQE CLI   TCBCMCDE(RTCB),X'B4'  WAS THERE A BORROWED SPQE     MP2K 30432918
         BNE   FMSPQES                                             MP2K 30433218
         L     RWORK2,SHSPQESV  REFRESH THE SPQE POINTER           MP2K 30433518
         XC    TCBCMCDE(1,RTCB),TCBCMCDE(RTCB) TURN OFF BROWED COCEMP2K 30433818
         LA    RWORK2,0(RWORK2)         CLEAR OUT HIGH ORDER BYTE  MP2K 30433918
         LTR   RWORK2,RWORK2            IS A SPQE PRESENT          MP2K 30434018
         BNZ   NXTSPQE1                 YES, GET NEXT SPQE         MP2K 30434118
FMSPQES  L     RWORK2,TCBMSS(RTCB) GET ADDR OF 1ST SPQE            MP2K 30434418
         LA    RWORK2,0(RWORK2)    ZERO HIGH ORDER BYTE            MP2K 30434718
FMNXTSPQ L     RWORK5,0(RWORK2)    GET ADDR OF NEXT SPQE           MP2K 30435018
         ST    RWORK5,SPQESAVE     SAVE ADDR OF NEXT SPQE          MP2K 30435318
FREESPQE LR    RIN1,RWORK2         PUT ADDR OF SPQE IN REG1        MP2K 30436218
         L     RIN0,MP2KFSPQ       PUT LENGTH, SUBPOOL IN REG0     MP2K 30436518
         BAL   RRETURN,RMBRANCH    FREE SPQE                       MP2K 30436818
         L     RWORK5,SPQESAVE     REFRESH SPQE NEXT POINTER       MP2K 30437418
         LA    RWORK5,0(RWORK5)  0 HIGH ORDER BYTE                 MP2K 30438018
         LTR   RWORK5,RWORK5  IS POINTER TO NEXT SPQE ZERO         MP2K 30438318
         BZ    NOSPQES        BRANCH NO MORE SPQES                 MP2K 30438618
         LR    RWORK2,RWORK5    GET NEXT SPQE POINTER              MP2K 30438918
         B     FMNXTSPQ         FREEMAIN NEXT SPQE                 MP2K 30439218
LEN3     EQU   3                                                MP2K    30439918
K5       EQU   5                                                MP2K    30440618
NOSPQES  XC    TCBMSS+1(3,RTCB),TCBMSS+1(RTCB)  ZERO TCBMSS FIELD  MP2K 30441318
         L     RRETURN,MP2KRTUN   REFRESH MP2K RETURN ADDRESS      MPIK 30441618
MPEXIT   BR    RRETURN                                             MP2K 30441918
*                                                                  MP2K 30442218
*       FREEMAIN CONSTANTS FOR 2K STORAGE RECONFIGURATION          MP2K 30442518
*                                                                  MP2K 30442818
         DS    0F                                                  MP2K 30443118
MP2KFDQE DC    X'FF000010' MASK FOR FREEING DQE                    MP2K 30443418
MP2KFSPQ DC    X'FF000008' MASK FOR FREEING SPQE                   MP2K 30443718
SPQESAVE DS    F                                                   MP2K 30444018
SHSPQESV DS    F                                                   MP2K 30444318
MP2KRTUN DS    F                                                   MP2K 30444618
TCBCMCDE EQU   19                                                  MP2K 30444918
         DROP  MP65BASE                                            MP2K 30445218
         EJECT                                                          30445518
.MP0118  ANOP                                                      MP2K 30445818
IEAQGM00 CSECT                                                          30450015
.GO13Z18 ANOP                                                      MO18 30480018
         EJECT                                                          30510015
*        REGMAIN ENTRY POINT                                            30540015
*                                                                       30570015
         DS    0D                                                       30600015
         DROP  FREBAS .    DROP SECOND BASE                       M0105 30610020
IGC010   BALR  RBASE,0                                                  30630015
         USING *,RBASE                                                  30660015
         L     RBASE,MSSADR                                             30690015
         USING MSSBASE,RBASE,FREBAS                               20021 30700020
         L     FREBAS,DBASADR      INITIALIZE SECOND BASE         20021 30720020
         MVC   MODEBYTE(1),33(0)   MODE INTO MODE BYTE                  30750015
         AIF   ('&RORI' NE 'Y').GOB1                               LC0A 30780017
         LTR   RIN1,RIN1    IIS THIS A FREEMAIN REQUEST                 30810015
         BC    10,RMBASE    YES. DO NOT SET GETMAIN NON-BRANCH SWTCH    30840015
         MVI   ENTRANT,X'FA'  SET ENTRY SWITCH                          30870015
.GOB1    ANOP                                                           30900015
RMBASE   LA    RERROR,GERRCODE     SET UP ERROR CODE REGISTER      LC0A 30930017
         MVI   SVCBYTE,10                                               30960015
         LR    RLENGTH,RIN0        LOAD REQUEST LENGTH                  30990015
         LA    RLENGTH,0(RLENGTH)  CLEAR SPID FROM HIGH ORDER BYTE      31020015
         LR    RSPID,RIN0          LOAD INPUT SUBPOOL ID                31050015
         SRL   RSPID,24            SHIFT TO LOW ORDER BYTE              31080015
         STC   RSPID,SPIDSAV .           SAVE SPID               A32912 31090020
         STH   RSPID,@SPSAVE       SAVE SUBPOOL ID             @AS76397 31100000
         LA    RADDR,RECURSE       LOAD ADDRESS OF ACSAVE AREA TO       31110015
*                                   MAKE REQUEST LOOK LIKE S-TYPE REQ   31140015
         ST    RIN1,0(RADDR)       SAVE INPUT ADDR FOR FREEMAIN         31170015
         NI    0(RADDR),0          CLEAR HIGH ORDER BYTE                31200015
*                                                                       31230015
*                                                                       31260015
*        DETERMINE TYPE OF REQUEST                                      31290015
*                                                                       31320015
         LTR   RIN1,RIN1                                                31350015
         BZ    SPFRMAIN            SUBPOOL FREEMAIN                     31380015
         BP    FELEMENT            BRANCH TO FREE MAIN                  31410015
*                                                                       31440015
*        INTERFACE TO S-TYPE GETMAIN                                    31470015
*                                                                       31500015
         AIF   ('&LCS' NE 'Y').LC03                                LC0A 31507017
         MVI   HIBYTE,0            INITIALIZE HIERARCHY IDENT      LC0A 31514017
         CL    RIN1,HIMASK         Q. IS REQUEST FOR HIERARCHY 1   LC0A 31521017
         BNE   RMGM                NO                              LC0A 31528017
         MVI   HIBYTE,1            INSERT HIERARCHY IDENT OF 1     LC0A 31535017
.LC03    ANOP                                                      LC0A 31542017
RMGM     BAL   RGMRET,GMCOMMON                                     LC0A 31549017
         B     RMEXIT              CORE FOUND                           31560015
         BAL   RRET,CDPURGE        PURGE JPA AND LPA                    31590015
         B     FREEA                                           @AS76858 31620000
         B     GNOTSAT1                                        @AS76858 31650000
FREEA    STC   RSPID,SPIDSAV                                   @AS76858 31657000
         MVI   SVCBYTE,10                                      @AS76858 31664000
         B     GMREPEAT                                        @AS76858 31671000
*                                                                       31680015
RMEXIT   LR    RIN1,RFQE           LOAD ADDR OF ASSIGNED CORE           31710015
         B     GRETURN                                                  31740015
         SPACE 2                                                        31770015
*        BRANCH ENTRY PROCESSING                                        31800015
         SPACE                                                          31830015
         DROP  FREBAS .    DROP SECOND BASE                       M0105 31840020
RMBRANCH LR    RIN15,RBASE         SAVE REGISTER 8                      31860015
         BALR  RBASE,0                                                  31890015
         USING *,RBASE                                                  31920015
         L     RBASE,MSSADR                                             31950015
         USING MSSBASE,RBASE,FREBAS                               20021 31970020
         SSM   CLHIBYTE .          DISABLE                        M3872 31980020
         LTR   RIN1,RIN1           IS IT A FREEMAIN              A28819 31990019
         BC    10,FMBREN           IF POSITIVE, FREEMAIN        A28819  32000019
         ST    RIN15,BRANCHSV+24   RIN15 = ENTRY CONTENTS OF REG8       32010015
         LA    RIN15,RMBASE        SET UP BRANCH TO REGMAIN             32040015
         B     GMBRNCOM            TO BRANCH ENTRY COMMON ROUTINE       32070015
FMBREN   ST    RIN15,FMBRSAV+24                                  A28819 32077019
         LA    RIN15,RMBASE                                      A28819 32084019
         B     FMBRNCOM                                          A28819 32091019
         EJECT                                                          32100015
*        REQUEST NOT SATISFIED - PUT TASK IN WAIT STATE                 32130015
*                                                                       32160015
*                                                                       32190015
*                                                                       32220015
GNOTSAT  BAL   RRET,CDPURGE        PURGE JPA AND LPA                    32250015
         AIF   ('&RORI' NE 'N').GO63A                          @SA77169 32254000
         B     XRETRY                                          @SA77169 32258000
         B     NORETRY                                         @SA77169 32262000
XRETRY   STC   RSPID,SPIDSAV                                   @SA77169 32266000
         MVI   SVCBYTE,X'04'                                   @SA77169 32270000
.GO63A   ANOP                                                  @SA77169 32274000
         AIF   ('&RORI' NE 'Y').GO63                               LC0A 32280017
         B     PURGSW             IF STORAGE FREED, SET PURGE SWITCH    32310015
         L     FPQEBASE,FRBASEAD                                        32317017
         L     RORIREG,ROTST5AD                                         32324017
         BR    RORIREG                                                  32331017
         AGO   .GO64                                                    32760015
.GO63    ANOP                                                           32790015
         B     GMREPEAT            IF STORAGE FREED                     32820015
NORETRY  EQU   *                                               @SA77169 32830000
         TM    8(RIN1),X'C0'       IS IT LIST REQUEST                   32850015
         BM    GLIST2              YES                                  32880015
GNOTSAT4 TM    8(RIN1),32          IS REQUEST CONDITIONAL               32910015
         BC    14,GNOTSAT1         NO                                   32940015
         LA    RIN15,4    SET RETURN CODE OF 4                          32970015
         AIF   ('&RORI' NE 'Y').GO92                               LC0A 33000017
.GO64    ANOP                                                           33030015
PQESETP  ST    RGMRET,PQERET                                            33060015
         L     FPQEBASE,FREPQEAD                                        33090015
         BR    FPQEBASE            FREE UP PQE'S                        33120015
         AGO   .GOPRG                                                   33690015
.GO92    ANOP                                                           33720015
         B     GRETURN             RETURN                               33750015
.GOPRG   ANOP                                                           33780015
         SPACE                                                          33810015
         AIF   ('&RORI' NE 'Y').GO62                               LC0A 33840017
         SPACE                                                          33870015
PURGSW   MVI   CDPRGSW,X'FF'      SET SWITCH TO INDICATE SUCCESSFUL     33900015
         STC   RSPID,SPIDSAV                                   @SA77169 33910000
         MVI   SVCBYTE,X'04'                                   @SA77169 33920000
*                                 PURGE                                 33930015
         B     GMREPEAT           REISSUE INITIAL REQUEST               33960015
.GO62    ANOP                                                           33990015
         SPACE 2                                                        34020015
*        ROUTINE FOR HANDLING REQUEST-NOT-SATISFIED CONDITION           34050015
*        DETERMINE WHETHER TO ABEND OR PLACE SYSTEM IN WAIT             34080015
         SPACE                                                          34110015
GNOTSAT1 CL    RSPID,C252          IS REQUEST FOR SQ SPACE              34140015
         BH    GNOTSAT5            YES                                  34170015
         AIF   ('&RORI' NE 'Y').GO90                               LC0A 34200017
         L     FPQEBASE,FRBASEAD   NO - ESTABLISH ADDRESSABILITY        34207017
         L     RORIREG,TESTROAD    SET UP ENTRY                         34214017
         BR    RORIREG             TEST FOR ROLLOUT                     34221017
.GO90    ANOP                                                           35250015
SETERR8  LA    RERROR,GERRCODE     SET UP ERROR CODE REGISTER      LC0A 35280017
         MVC   ABNDATA(4),ORGLRG   SAVE LARGEST SIZE              21016 35287021
         L     RADDR,ABNDATA                                      21016 35294021
         MVI   MSGLEN,X'28'        SET REASON CODE AND LENGTH     21016 35301021
         B     GERROR8                                                  35310015
*THIS ROUTINE IS ENTERED WHEN A REQUEST FOR SUPERVISOR QUEUE SPACE SWS  35330018
*CANNOT BE SATISFIED.                                              SWS  35350018
*IN AN ATTEMPT TO AVOUD A WAIT STATE, THIS ROUTINE WILL EXAMINE THESWS  35370018
*SIZE OF THE REQUEST.  IF THE SIZE OF THE REQUEST IS LARGER THAN   SWS  35390018
*144 BYTES,THE REQUESTOR WILL BE ABTERMED WITH A E04 COMPLETION    SWS  35410018
*CODE                                                              SWS  35430018
*IF THE SIZE OF THE REQUEST IS EQUAL TO OR LESS THAN 144 BYTES, A  SWS  35450018
*DISABLED WAIT STATE PSW WILL BE LOADED.                           SWS  35470018
*                                                                  SWS  35490018
GNOTSAT2 DS    0H                                                  SWS  35510018
         LA    RWORK1,144         SET UP XR FOR COMPARE            SWS  35530018
         C     RWORK1,REQSIZE     ABTERM REQUESTOR IF SIZE         SWS  35550018
         BL    TERM               IS LARGER THAN 144               SWS  35570018
         L     RIN1,WAIT+4        PICK UP ABEND CODE               SWS  35572019
         SLL   RIN1,12       SET UP COMPLETION CODE                SWS  35574019
         ST    RIN1,16(RTCB)     STORE CODE IN TCB                 SWS  35576019
         L     RIN15,CVTPTR        LOCATE CVT                     21014 35576421
         L     RIN15,CVTPURG(RIN15)   LOCATE SUBSYSTEM PURGE ROUT 21014 35576821
         LR    RIN1,RTCB           MOVE TCB ADDR TO REG 1         21014 35577221
         BALR  RRETURN,RIN15       GO TO SUBSYSTEM PURGE          21014 35577621
         OI    16(RTCB),X'80'    SET FLAG BIT                      SWS  35578019
         OI    33(RTCB),X'01'     SET NON-DISPATCHABILITY BIT      SWS  35580019
         OI    173(RTCB),X'40'     INDICATE OUT OF STORAGE         SWS  35582019
         LPSW  WAIT               PLACE MACHINE IN WAIT STATE      SWS  35590018
TERM     L     RIN1,WAIT+4        PICK UP ABEND CODE               SWS  35610018
         B     ERRF11                                              SWS  35630018
*                                                                       35700015
GNOTSAT5 EQU   *                                                  20021 35705020
         AIF   (&TSO NE 1).TSO1000                                20021 35710020
         TM    LSQSSW,LSQSMSK      IS REQUEST FOR LSQS?           20021 35715020
         BNZ   GNOLSQS            YES-BRANCH TO LSQS PROCSSNG     20021 35720020
.TSO1000 ANOP                                                     20021 35725020
         BAL   RCOMRET1,GNOTSAT3   ATTEMPT TO GET MORE SQS SPACE  20021 35735020
GMREPEAT LM    RADDR,FREBAS,SAVEREGS  RESTORE REGS (11-3) RETRY   20021 35755020
         B     GCOMMON2            TO REPEAT REQUEST                    35790015
         EJECT                                                          35820020
         AIF   (&TSO NE 1).TSO1100                                20021 35821020
*                                                                 20021 35822020
*        THIS ROUTINE HANDLES AN OUT OF LSQS CONDITION.  IF THE   20021 35823020
*        CALLING TASK IS NOT ABENDING, IT IS ABENDED. IF THE      20021 35824020
*        TASK IS ABENDING, THE REQUEST IS RETRIED FROM SQS.       20021 35825020
*        SUBPOOL 254, RTCB=JOBSTEP TCB AND A DAUGHTER MAY BE      20021 35825420
*        ABENDING.  ALSO, CHECK CURRENT TCB                       20021 35825820
GNOLSQS  SR    RERROR,RERROR -     SET FIRST TCB                  20021 35826720
GNOLSQS1 TM    TCBFLG1(RTCB),TCBFA IS CALLING TASK ABENDING       20021 35827020
         BNZ   GETSQS -            YES-ALLOCATE FROM SQS          20021 35828020
         TM    TCBFLG3(RTCB),TCBABTRM IS CALLING TASK ABTERMING   20021 35829020
         BNZ   GETSQS -             YES-ALLOCATE FROM SQS         20021 35830020
         TM    TCBFLG2(RTCB),TCBMC -TASK MUST COMPLETE            20021 35831020
         BNZ   GETSQS -             YES-ALLOCATE FROM SQS         20021 35832020
         TM    TCBSTAE(RTCB),TCBSTABE IS CALLING TASK STAE EXIT   20021 35833020
         BNZ   GETSQS -             YES-ALLOCATE FROM SQS         20021 35834020
         L     RIN1,TCBRBP(RTCB) -  GET CURR RB ADDRSS            20021 35834420
         TM    RBSTAB(RIN1),X'C0' - IS IT AN SVRB?                20021 35834820
         BNO   GNOLSQS2 -          NO, CHECK FOR 254              M3872 35834920
         CLC   RBEXSAVE+DISP(L5,RIN1),ABENDMSK .  ABEND SVRB ?   M3872  35835320
         BE    GETSQS -            YES-USE SQS                    20021 35836020
GNOLSQS2 LTR   RERROR,RERROR -     CHECKING SECOND TCB            20021 35837020
         BNZ   OUTLSQS -           TWO TCBS AND YOUR OUT          20021 35837620
         LCR   RWORK2,RSPID -      COMPLEMENT SUBPOOL NUMBER      20021 35838220
         CL    RWORK2,C254 -       SUBPOOL 254                    20021 35838820
         BNE   OUTLSQS -           NO, TERMINATE TASK             20021 35839420
         LR    RERROR,RTCB -       SAVE THE JOBSTEP TCB           20021 35839820
         L     RTCB,16(0) -        GET CURRENT TCB ADDR.          20021 35840220
         L     RTCB,0(RTCB) -      *                              20021 35840620
         L     RTCB,4(RTCB) -      *                              20021 35841020
         B     GNOLSQS1 -          CHECK CURRENT TCB              20021 35841520
OUTLSQS  LA    RERROR,GERRCODE -   TASK OUT OF LSQS-TERMINATE     20021 35842120
         B     GERROR1 -           CALLING TASK (LOADS RTCB)      20021 35842520
GETSQS   MVI   LSQSSW,LSQSOFF -    CLEAR LSQS SWITCH              20021 35842920
         LTR   RERROR,RERROR -     SECOND TCB                     20021 35843320
         BZ    GETSQS1 -           NO                             20021 35844020
         LR    RTCB,RERROR -       YES, RE LOAD TCB ADDR.         20021 35844720
GETSQS1  LA    RSPQE,SQESPQE -     ADDR. OF SQS SPQE              20021 35845420
         ST    RSPQE,SAVEREGS+4 -  STORE IN RETRY REGS(REG 12)    20021 35846120
         LM    RADDR,FREBAS,SAVEREGS RESTORE REGS(11-3) RETRY     20021 35846820
         B     GCOMMON2 -          RETRY REQUEST                  20021 35847520
         EJECT                                                    20021 35847920
.TSO1100 ANOP                                                     20021 35848020
*        THIS ROUTINE ATTEMPTS TO MAKE STORAGE AVAILABLE FOR SUPERVISOR 35850015
*        QUEUE SPACE BY PURGING THE JPA AND THE LPA.  IF THIS IS NOT    35880015
*        SUCCESSFUL IN MAKING ENOUGH STORAGE AVAILABLE, THIS ROUTINE    35910015
*        WILL EXTEND THE SUPERVISOR QUEUE SPACE BY ONE 2K BLOCK AT A    35940015
*        TIME IF THE NEXT ADJACENT 2K BLOCK IS AVAILABLE.  IF THIS      35970015
*        ROUTINE IS UNSUCCESSFUL IN MAKING SUFFICIENT SUPERVISOR        36000015
*        STORAGE AVAILABLE TO SATISFY THE REQUEST, IT WILL ENTER A      36030015
*        MACHINE WAIT STATE.                                            36060015
*           INPUT - RCOMRET1 - RETURN ADDRESS                           36090015
*           OUTPUT - NONE                                               36120015
*           REGISTERS USED - RCOMRET1,RRET,RWORK1,RDISP,RCOMRET3,       36150015
*                           RBLOCK,RDQE,RFQE,RQESIZ,RSIZE,RWORK4,       36180015
*                           RWORK5                                      36210015
         SPACE                                                          36240015
GNOTSAT3 LR    RWORK1,RTCB         SAVE TCB ADDRESS                     36270015
         LA    RWORK4,2            INITIALIZE CORE FREED INDICATOR      36300015
         LA    RRET,NEXTTCB        SET UP RETURN FROM CDPURGE           36330015
         L     RTCB,MSCEDADD       PICK UP MASTER SCHEDULER TCB ADDRESS 36360015
         B     TSTPRG              TO CHECK FOR PURGE OF M.S. JPQ       36390015
NEXTTCB  L     RTCB,TCBTCB(RTCB)   PICK UP NEXT TCB ON TCB QUEUE        36420015
         LTR   RTCB,RTCB           IS THIS END OF QUEUE                 36450015
         BZ    RSTRTCB             YES                                  36480015
TSTPRG   TM    TCBJPQ(RTCB),X'80'  IS PURGE FLAG IN TCB SET             36510015
         BZ    NEXTTCB             NO - GET NEXT TCB                    36540015
         AIF   (&TSO NE 1).TSO1200                                20021 36542020
*                                                                 20021 36544020
* DON'T PURGE JPAQ FOR A TIME-SHARING TASK. PURGE WOULD ONLY      20021 36546020
* MAKE LSQS AVAILABLE NOT SQS. PURGE COULD RESULT IN AN ABEND     20021 36548020
* BECAUSE FREEMAIN FOR A TIME-SHARING TASK WILL GET THE TCB       20021 36550020
* ADDRESS FROM 'OLD' WHICH IS NOT THE TCB BEING PURGED.           20021 36552020
         SPACE 1                                                  20021 36554020
         TM    TCBTSFLG(RTCB),TCBTSTSK  IS THIS A TIME-SHARING    20021 36556020
*                                       TASK?                     20021 36558020
         BO    NEXTTCB             YES. GET NEXT TCB.             20021 36560020
.TSO1200 ANOP                                                     20021 36562020
         AIF   ('&RORI' NE 'Y').GOJB1                              LC0A 36570017
         TM    TCBFCD1(RTCB),X'10'  HAS TASK BEEN ROLLED OUT            36600015
         BO    NEXTTCB  YES.  GET NEXT TCB.                             36630015
.GOJB1   ANOP                                                           36660015
         LA    RWORK4,0            SET INDICATOR FOR STORAGE FREED      36690015
         B     CDPURGE             PURGE JOB PACK QUEUE                 36720015
RSTRTCB  LR    RTCB,RWORK1         RESTORE TCB ADDRESS                  36750015
         B     RETN(RWORK4)                                             36780015
RETN     BR    RCOMRET1            IF CORE FREED AS RESULT OF PURGES    36810015
         L     RBLOCK,GOVRFLB+8    GET PTR TO FREE AREA PQE    @SA70721 36814029
         L     RBLOCK,PQENXT(RBLOCK)    GET ONLY OR H0 PQE     @SA70721 36818029
         L     RWORK1,GOVRFLB      FIRST BYTE BEYOND SQA       @SA70721 36822029
         LA    RWORK1,0(RWORK1)    CLEAR POSSIBLE FLAG         @SA70721 36826029
         C     RWORK1,0(RBLOCK)    CONTIGUOUS EXPNSN POSBLE?   @SA70721 36830029
         BNE   GNOTSAT2            NO                          @SA70721 36834029
         LA    RWORK1,2048         SIZE OF A 2K BLOCK                   36840015
         SR    RDISP,RDISP         SET DISPLACEMENT FOR FBQE POINTER    36870015
         LR    RSIZE,RDISP         INITIALIZE REGISTER                  36900015
         BAL   RCOMRET3,FREEPTR    GET A 2K BLOCK                       36930015
         B     CONTIGCH            2K BLOCK FOUND                       36960015
         B     GNOTSAT2            NO UNASSIGNED STORAGE                36990015
CONTIGCH EQU   *                                                 A29420 36992020
         TM    GOVRFLB,X'80' .           IS SQS TRIGGER SET      A29420 36994020
         BC    14,CONTIGCK .             NO, BRANCHTO EXPND SQS  A29420 36996020
         LR    RDQE,RCOMRET1 .           SAVE REGISTER           A29420 36998020
         LR    RFQE,RADDR .              SAVE REGISTER           A29420 37000020
         L     RADDR,ADPART .            LOAD BASE FOR GET/FRE - A29420 37002020
*                                            PART                A29420 37004020
         L     RCOMRET1,ADDISP .         LOAD ADDRESS FOR BALR   A29420 37006020
         BALR  RCOMRET1,RCOMRET1 .       GO TO GET/FREEPART IN   A29420 37008020
*                                            IEAQPR              A29420 37010020
         LR    RCOMRET1,RDQE .           RESTORE REG             A29420 37012020
         LR    RADDR,RFQE .              RESTORE REG             A29420 37014020
CONTIGCK EQU   *                                                        37016020
         NI    GOVRFLB,X'00' .           CLEAR HIGH ORDER BYTE   A29420 37018020
*                                         FOR COMPARE            A29420 37020020
         L     RDQE,GOVRFLB+4      PICK UP PTR TO SUPERVISOR DQE        37080015
         L     RFQE,DQEFQE(RDQE)   PICK UP FIRST FQE                    37110015
         LA    RFQE,0(RFQE)                                             37140015
         L     RQESIZ,DQELNTH(RDQE) PICK UP SIZE FROM DQE               37170015
         LTR   RFQE,RFQE               IS THERE AN FQE FOR SQS @JK70115 37180021
         BZ    NEWSQFQE                NO CREATE NEW FQE       @JK70115 37190021
         L     RFQEUB,FQELNTH(RFQE) PICK UP SIZE OF FREE AREA           37200015
         AR    RFQEUB,RFQE         COMPUTE UPPER BOUND OF FREE AREA     37230015
         CR    RFQEUB,RBLOCK       IS IT CONTIGUOUS TO NEW BLOCK        37260015
         BNE   NEWSQFQE            NO - CREATE NEW FQE                  37290015
         A     RSIZE,FQELNTH(RFQE) COMBINE SIZES                        37320015
         ST    RSIZE,FQELNTH(RFQE) PUT NEW SIZE IN FQE                  37350015
NEWSQSIZ LA    RQESIZ,2048(RQESIZ) INCREMENT DQE SIZE                   37380015
         ST    RQESIZ,DQELNTH(RDQE) PUT NEW SIZE IN DQE                 37410015
         L     RBLOCK,GOVRFLB+8        PICK UP PTR TO PQE               37440015
         L     RBLOCK,DUMFWD(RBLOCK)   PICK UP ADDRS OF REAL PQE        37470015
         L     RWORK5,PQERGSZ(RBLOCK)  PICK UP REGION SIZE              37500015
         SH    RWORK5,KTWO             DECREMENT SIZE BY ONE BLOCK      37530015
         ST    RWORK5,PQERGSZ(RBLOCK)  UPDATE RGN SIZE IN PQE           37560015
         L     RWORK5,GOVRFLB      PICK UP SQ SPACE UPPER BOUND         37590015
         LA    RWORK5,2048(RWORK5) UPDATE SQ SPACE UPPER BOUND          37620015
         ST    RWORK5,GOVRFLB                                           37650015
         ST    RWORK5,PQESTADD(RBLOCK) UPDATE START ADD IN PQE          37680015
         L     RWORK5,16               LOAD ADDR OF CVT            0697 37710015
         MVC   CVTNUCB(4,RWORK5),GOVRFLB    UPDATE CVT             0697 37740015
         BR    RCOMRET1            RETURN                               37770015
NEWSQFQE ST    RSIZE,FQELNTH(RBLOCK) STORE SIZE IN NEW FQE              37800015
         ST    RFQE,FQENXT(RBLOCK) PUT POINTER TO NEXT FQE IN NEW FQE   37830015
         ST    RBLOCK,DQEFQE(RDQE) PUT ADDRESS OF NEW FQE IN DQE        37860015
         B     NEWSQSIZ            ADJUST DQE                           37890015
         EJECT                                                          37920015
*        TERMINATION PROCEDURES - CORE ALLOCATED                        37950015
         SPACE                                                          37980015
GMSEXIT  TM    8(RIN1),32          WAS REQUEST CONDITIONAL              38010015
         BC    14,GRETURN                                               38040015
GRETURN1 SR    RIN15,RIN15         YES-SET ERROR CODE TO ZERO.          38070015
*                                                                       38100015
         AIF   ('&RORI' NE 'Y').GOG2                               LC0A 38130017
GRETURN  XC    PQESTAT(3),PQESTAT . TURN OFF SW FOR EXIT          M3872 38160020
         BR    RRETURN             RETURN TO CALLER                     38190015
         AGO   .GOG3                                                    38220015
.GOG2    ANOP                                                           38250015
GRETURN  BR    RRETURN             RETURN TO CALLER                     38280015
.GOG3    ANOP                                                           38310015
         EJECT                                                          38340015
*        MAINLINE CONTROL ROUTINE FOR GETMAIN                           38370015
*           INPUT - RLENGTH - REQUESTED LENGTH                          38400015
*                   RSPID   - REQUESTED SUBPOOL ID                      38430015
*                   RADDR   - ADDR OF LIST ENTRY TO STORE AREA ADDR     38460015
*                   RTCB    * ADDR OF TCB FOR REQUESTING TASK           38490015
*                   RGMRET  * RETURN REG                                38520015
*           OUTPUT -                                                    38550015
*              IF REQUEST IS SATISFIED (RETURN TO  RGMRET')             38580015
*                   ADDRESS OF ALLOCATED AREA IS IN LIST ENTRY          38610015
*              IF REQUEST IS NOT SATISFIED (RETURN TO 'RGMRET + 4')     38640015
*                   RLRGSIZ - SIZE OF LARGEST AVAILABLE FREE AREA       38670015
*           REGISTERS USED - EXCLUDING THOSE USED BY SUBROUTINES        38700015
*                   RCOMRET1,RMASK,RWORK1,RLENGTH,RSPID,RFQE,RADDR,     38730015
*                   RGMRET                                              38760015
*                                                                       38790015
GMCOMMON ST    RLENGTH,REQSIZE  SAVE SIZE OF REQUEST FOR LATER USE SWS  38800018
         BAL   RCOMRET1,CSPCHK    GET SPQE FOR REQUESTED SUBPOOL   SWS  38820018
         B     GSPQESPC            NOT FOUND-CREATE SPQE                38850015
         SPACE 2                                                        38880015
*        ALTERNATE ENTRY POINT USED FOR LIST AND VARIABLE REQUESTS-     38910015
*          AFTER THE FIRST ENTRY IN THE LIST WAS SATISFIED FOR LIST     38940015
*          REQUESTS OR TO GET THE MAXIMUM AVAILABLE CORE FOR VARIABLE   38970015
*          REQUESTS.     (RSPQE MUST POINT TO THE SPQE FOR THE REQ SP)  39000015
         SPACE                                                          39030015
GCOMMON1 LTR   RLENGTH,RLENGTH     Q. IS NEGATIVE LENGTH SPECIFIED 5020 39036016
         BC    10,RNDLNGTH            NO - PROCESS NORMALLY        5020 39042016
         TM    8(RIN1),32          Q. IS REQUEST CONDITIONAL       5020 39048016
         BC    1,SETRET4              YES - SET RETURN CODE 4      5020 39054016
         LA    RERROR,GERRCODE     SET UP ERROR CODE REGISTER      5020 39060017
         MVI   MSGLEN,X'44'        LENGTH AND REASON CODE         21016 39062021
         B     GERROR8                                             5020 39066016
SETRET4  LA    RIN15,4             SET RETURN CODE TO 4            5020 39072016
         B     GRETURN                                             5020 39078016
RNDLNGTH BAL   RCOMRET1,CRNDLNTH   ROUND UP LENGTH TO DOUBLE WORD  5020 39084016
         STM   RADDR,FREBAS,SAVEREGS  SAVE REGSTRS (11-3)         20021 39094020
GCOMMON2 L     RMASK,CLHIBYTE      LOAD MASK TO CLEAR HIGH ORDER BYTE   39120015
         CL    RSPID,C252          IS REQUEST FOR SQ SPACE              39150015
         BNH   GCOMPSP             NO                                   39180015
         BAL   RCOMRET1,GFRECORE   SEARCH SQ AREA FOR FREE AREA         39210015
         B     GNOTFND             SQ SPACE NOT FOUND                   39240015
         LTR   RSPID,RSPID         IF REQUEST IS FOR SUBPOOL 253-254    39270015
         BM    GAQE                 BUILD AN AQE FOR ASSIGNED AREA      39300015
         B     GFQEADJ                                                  39330015
GCOMPSP  DS    0H                                                  I283 39332019
        AIF ('&LCS' EQ 'N').LCS01                                  I283 39334019
         SPACE                                                          39336019
* IF REGION CONSISTS ONLY OF ONE SEGMENT, THIS SECTION OF CODE     I283 39338019
*   FUNNELS ALL REQUESTS TO THAT SEGMENT; OTHERWISE THE            I283 39340019
*   SPECIFIED HIERARCH IS USED.                                    I283 39342019
         SPACE                                                          39344019
         LA    WORK15,2            SET UP TO TEST FOR 2 SEGMENTS   I283 39346019
         L     PQE6,TCBPQE(RTCB)   @ DUMMY                         I283 39348019
OWNPQE   LR    PQE9,PQE6           SAVE @ LAST PQE IF NECESSARY    I283 39350019
GETPQE   L     PQE6,PQENXT(PQE6)   @ NEXT PQE ON CHAIN             I283 39352019
         LTR   PQE6,PQE6           IS THERE ANOTHER PQE ?          I283 39354019
         BE    ONESEG              NO - MUST ONLY BE ONE SEGMENT   I283 39356019
         TM    RORIFLG(PQE6),RGNSHRD  PQE OWNED BY THIS TCB ?      I283 39358019
         BO    GETPQE              NO - TEST NEXT PQE              I283 39360019
         BCT   WORK15,OWNPQE       DECREMENT SEGMENT CTR,CK NXT    I283 39362019
         B     FINHIER             IF 0, REGION HAS 2 SEGMENTS     I283 39364019
ONESEG   MVI   HIBYTE,1            SET UP TO ISOLATE HIER          I283 39366019
         NC    HIBYTE(1),PQEHIID(PQE9) ISOLATE SEGMENT HIER ID     I283 39368019
FINHIER  DS    0H                                                  I283 39370019
.LCS01   ANOP                                                      I283 39372019
         LA    RWORK1,4080         IS REQ. LENGTH GREATER THAN     I283 39374019
         CR    RWORK1,RLENGTH       MAXIMUM AVAILABLE IN AN FQE         39390015
         BL    GM2KPREF           YES - GET FREE 2K BLOCKS              39420015
*                                                                       39450015
         BAL   RCOMRET1,GFRECORE  SEARCH SUBPOOL FOR FREE AREA          39480015
         B     GM2KT               AREA NOT FOUND-GET FREE 2K BLOCKS    39510015
*                                                                       39540015
GFQEADJ  BAL   RCOMRET1,GFQEUPDT   REMOVE ASSIGNED AREA FROM FQE        39570015
         SPACE                                                          39600015
*        RETURN - REQUEST SATISFIED                                     39630015
*             (RFQE = ADDR OF ASSIGNED AREA)                            39660015
GFNDRET  LM    RADDR,FREBAS,SAVEREGS  RESTORE REGS (11-3)         20021 39690020
         ST    RFQE,0(RADDR)       STORE AREA'S ADDR IN CALLER'S LIST   39720015
         AIF   ('&RORI' NE 'Y').GO94                               LC0A 39750017
         ST    RGMRET,PQERET                                            39780015
         L     FPQEBASE,FREPQEAD                                        39810015
         BR    FPQEBASE                                                 39840015
         AGO   .GO95                                                    39870015
.GO94    ANOP                                                           39900015
         BR    RGMRET              RETURN                               39930015
.GO95    ANOP                                                           39960015
         SPACE 2                                                        39990015
*                                                                       40020015
GAQE     BAL   RCOMRET1,GBLDAQE    BUILD AQE FOR ASSIGNED 253/254 CORE  40050015
         B     GFNDRET             RETURN - STORAGE IS ALLOCATED        40080015
         EJECT                                                          40110015
*        GET STORAGE FROM UNASSIGNED 2K BLOCKS                          40140015
*                                                                       40170015
GM2KPREF SR    RLRGBLK,RLRGBLK     INITIALIZE ADDR OF LARGEST BLOCK     40200015
GM2KPRF1 L     RDQE,DQENXT(RSPQE)  GET ADDRESS OF DQE              LC0A 40230017
         NR    RDQE,RMASK               FOR SUBPOOL REQUESTED           40260015
         BZ    GM2K                                                     40290015
         LR    RPREDQE,RDQE                                             40320015
         B     GM2KPRF1                                                 40350015
*                                                                       40380015
GM2KT    LTR   RLENGTH,RLENGTH     IS REQUEST FOR ZERO BYTES            40410015
         BZ    GFNDRET             YES - RETURN                         40440015
GM2K     LA    RWORK1,2047         DETERMINE NUMBER OF 2K BLOCKS NEEDED 40470015
         LR    RWORK4,RWORK1                                            40500015
         AR    RWORK1,RLENGTH        TO SATISFY REQUEST                 40530015
         OR    RWORK1,RWORK4                                            40560015
         XR    RWORK1,RWORK4                                            40590015
*                                                                       40620015
         BAL   RCOMRET2,G2KSRCH    SEARCH FOR FREE 2K BLOCKS            40650015
         B     GFNDRET             CORE FOUND-RETURN                    40680015
GSIZCK   LR    RLRGSIZ,RSIZE       SAVE SIZE OF LARGEST SET OF FREE BLK 40860015
GNOTFND  LM    RADDR,FREBAS,SAVEREGS  RESTORE REGS (11-3)         20021 40890020
         B     4(RGMRET)           RETURN - CORE NOT FOUND              40920015
         EJECT                                                          40950015
*        SEARCH FREE AREAS OF SUBPOOL FOR AN AREA LARGE ENOUGH TO       40980015
*           SATISFY THE REQUEST                                         41010015
*           INPUT - RLENGTH - REQUESTED LENGTH                          41040015
*                   RSPQE - ADDRESS OF SUBPOOL QUEUE ELEMENT            41070015
*           OUTPUT -                                                    41100015
*              IF RETURN IS TO  RCOMRET1' (NOT FOUND)                   41130015
*                RPREDQE = ADDRESS OF LAST DQE FOR SUBPOOL(OR OF SPQE)  41160015
*                RLRGSIZ = SIZE OF LARGEST FREE AREA - REQUESTED LENGTH 41190015
*                RLRGBLK = ADDR OF FQE FOR LARGEST FREE AREA            41220015
*              IF RETURN IS TO 'RCOMRET1 + 4' (FOUND)                   41250015
*                RFRELNTH- SIZE REMAINING IN FQE                        41280015
*                RFQE    = ADDR OF FQE SATISFYING REQUEST               41310015
*                RPREFQE = ADDR OF PREVIOUS FQE (OR OF DQE)             41340015
*           REGISTERS USED - RMASK,RDQE,RPREDQE(=RSPQE),RFQE,RPREFQE,   41370015
*                      RLRGBLK,RFRELNTH,RLENGTH,RCOMRET1,RLRGSIZ        41400015
*                                                                       41430015
*                                                                       41460015
GFRECORE SR    RLRGSIZ,RLRGSIZ     LOAD REGISTERS TO SAVE LENGTH AND    41490015
         LR    RLRGBLK,RLRGSIZ     ADDR OF LARGEST AVAILABLE FREE AREA  41520015
GDQESRCH L     RDQE,DQENXT(RPREDQE)  LOAD ADDRESS OF NEXT DQE           41550015
         NR    RDQE,RMASK            IS THERE A DQE                     41580015
         ST    RLRGSIZ,FQESIZ .     STORE SIZE OF LARGEST FQE    A31213 41590020
         BCR   8,RCOMRET1             NO-RETURN-FREE AREA NOT FOUND     41610015
         AIF   ('&RORI' NE 'Y').GO204                              LC0A 41640017
         CL    RSPID,C252          IF REQUEST IS FOR SQS BYPASS CHECK   41670015
         BH    FQESRCH             FOR OWNED AND BORROWED CORE          41700015
         L     RIN1,TCBPQE(RTCB)                 GET PQE AND TEST       41730015
PQE1     L     RIN1,DUMBWD(RIN1)                 DQE STARTING ADDR TO   41760015
         CLC   DQEADDR+1(3,RDQE),PQESTADD+1(RIN1) REGION IN PQE         41790015
         BL    PQE1                                                     41820015
         CLI   PQESTAT,X'FF'                     IF SEARCH IS FOR       41850015
         BE    PQE2                              BORROWED CORE BRANCH   41880015
         TM    RORIFLG(RIN1),RGNSHRD             IF PQE OWNED CONTINUE  41910015
         BC    1,GDQEADV                         OTHERWISE BRANCH       41940015
         B     FQESRCH                           IF PQE OWNED BRANCH    41970015
PQE2     TM    RORIFLG(RIN1),RGNSHRD             OTHERWISE CONTINUE TO  42000015
         BC    8,GDQEADV                         FQESRCH                42030015
.GO204   ANOP                                                           42060015
*                                                                       42090015
*        SEARCH FQE CHAIN OF DQE FOR FREE AREA                          42120015
*                                                                       42150015
FQESRCH  LR    RPREFQE,RDQE                                             42180015
         AIF   ('&LCS' NE 'Y').LC05                                LC0A 42185017
         CLC   DQEHIID(1,RPREFQE),HIBYTE  Q. IS THIS DQE FOR THE   LC0A 42190017
*                                         REQUESTED HIERARCHY      LC0A 42195017
         BNE   GDQEADV                                             LC0A 42200017
.LC05    ANOP                                                      LC0A 42205017
         L     RFQE,FQENXT(RPREFQE) LOAD ADDRESS OF FIRST FQE           42210015
         NR    RFQE,RMASK            IS THERE AN FQE                    42240015
         BZ    GDQEADV                NO - CHECK NEXT DQE               42270015
GFQESRCH TM    FQENXT+3(RPREFQE),7 .    CHK FQE ADD FOR VALIDITY A39433 42300000
         BC    7,BADFQE                                           21016 42305021
         TM    FQENXT(RPREFQE),X'FF'   CHK FOR NON-ZERO HIBYTE @SA68309 42306021
         BC    7,BADFQE                NOT ZERO BRANCH         @SA68309 42307021
         L     RFRELNTH,FQELNTH(RFQE) .  IS FREE AREA SUFFICIENT A39433 42310400
         SR    RFRELNTH,RLENGTH           FILL REQUEST                  42330015
         BC    11,4(RCOMRET1)        YES -RETURN-FREE AREA FOUND        42360015
*                                                                       42390015
         AR    RFRELNTH,RLENGTH                                         42420015
         CR    RFRELNTH,RLRGSIZ         IS FREE AREA LARGEST SO FAR     42450015
         BNH   GFQEADV               NO-CHECK NEXT FQE                  42480015
         LR    RLRGSIZ,RFRELNTH    SAVE SIZE OF FREE AREA               42510015
         ST    RLRGSIZ,ORGLRG .    LRGEST BLK OF CORE AVAIL       21016 42520021
         LR    RLRGBLK,RFQE        SAVE ADDR OF FQE (FOR VARIABLE)      42540015
*                                                                       42570015
GFQEADV  LR    RPREFQE,RFQE        CHECK NEXT FQE                       42600015
         TM    FQENXT+3(RPREFQE),7 DOES NEXT FQE SPECIFY DOUBLE WORD    42630015
         BC    7,BADFQE                NO BRANCH OUT           @SA68309 42640021
         TM    FQENXT(RPREFQE),X'FF'   CHK FOR NON-ZERO HIBYTE @SA68309 42650021
         BC    7,BADFQE                NOT ZERO BRANCH OUT     @SA68309 42660021
FQEOK    L     RFQE,FQENXT(RPREFQE) LOAD ADDRESS OF NEXT FQE      21016 42680021
         NR    RFQE,RMASK          IS THERE AN FQE                      42720015
         BZ    GDQEADV             NO - CHECK NEXT DQE                  42750015
         CR    RFQE,RPREFQE        IS FQE LESS THAN PREVIOUS FQE        42780015
         BL    GFQESRCH            YES                                  42810015
SPECERR  LA    RERROR,GERRCODE     NO - ERROR - FQE QUEUE DESTROYEDLC0A 42840017
         B     GERROR6                                                  42870015
*                                                                       42900015
GDQEADV  LR    RPREDQE,RDQE        CHECK NEXT DQE                       42930015
         B     GDQESRCH                                                 42960015
         EJECT                                                          42990015
*        SEARCH FOR FREE 2K BLOCKS                                      43020015
*           INPUT - RWORK1 = NUMBER OF 2K BLOCKS NEEDED                 43050015
*                   RPREDQE= ADDRESS OF LAST DQE FOR SPQE               43080015
*                                                                       43110015
*           OUTPUT -                                                    43140015
*              IF CORE IS FOUND (RETURN TO 'RCOMRET2')                  43170015
*                RFQE - ADDRESS OF ALLOCATED STORAGE                    43200015
*              IF CORE IS NOT FOUND (RETURN TO 'RCOMRET2 + 4')          43230015
*                RSIZE  = NUMBER OF BLOCKS IN SET OF FREE BLOCKS        43260015
*                                                                       43290015
*        REGISTERS USED - RCDPRGIN,RCOMRET1,RCOMRET2,RCOMRET3,RBLOCK    43320015
*                                                                       43350015
G2KSRCH  BAL   RCOMRET3,FBQSRCH    SEARCH FOR FREE BLOCKS               43380015
         B     GDQEBLD             BLOCKS FOUND - CREATE DQE            43410015
         B     4(RCOMRET2)         RETURN - BLOCKS NOT AVAILABLE        43440015
         SPACE                                                          43470015
*        CREATE DQE                                                     43500015
         SPACE                                                          43530015
GDQEBLD  LR    RBLOCK1,RBLOCK      SAVE BLOCK NUMBER AND SIZE           43560015
         LR    RSIZE1,RSIZE                                             43590015
         SRL   RSIZE1,DIV2048      GET NUMBER OF BLOCKS                 43620015
         LA    RIN1,16             LOAD DQE SIZE                        43650015
*                                                                       43680015
         BAL   RCOMRET1,GETMAINB   GET 16 BYTES FOR DQE                 43710015
         ST    RBLOCK1,DQEADDR(RIN1) STORE BLOCK ADDRESS IN DQE         43740015
         ST    RSIZE,DQELNTH(RIN1) STORE SIZE IN DQE                    43770015
         AIF   ('&LCS' NE 'Y').LC06                                LC0A 43777017
         MVC   DQEHIID(1,RIN1),HIBYTE   INSERT HIERARCHY IDENT     LC0A 43784017
.LC06    ANOP                                                      LC0A 43791017
*                                                                       43800015
*        SET STORAGE KEYS IN 2K BLOCKS ASSIGNED                         43830015
         LR    RBLOCK1,RBLOCK                                           43860015
         LA    RBLOCK1,0(RBLOCK1)  CLEAR HI BYTE                SA66792 43865021
         SR    RWORK2,RWORK2                                            43890015
         CL    RSPID,C252          IF REQUEST IS FOR SP 252-255         43920015
         AIF   (&SMF EQ 0).GMCOMM                                   SMF 43925018
         BE    GOCORE                  BRANCH IF 252-NOT SET KEY    SMF 43930018
         BH    GFQEBLD                 DO NOT SET STORAGE KEY       SMF 43935018
         AGO   .GMCOMN                                              SMF 43940018
.GMCOMM  ANOP                                                       SMF 43945018
         BNL   GFQEBLD              DO NOT SET STORAGE KEY              43950015
.GMCOMN  ANOP                                                       SMF 43960018
         IC    RWORK2,TCBPKF(RTCB) LOAD TASKS PROTECT KEY               43980015
*                                                                       44010015
GSBSK    SSK   RWORK2,RBLOCK1      SET STORAGE KEY TO TASK'S PROTECT    44040015
         LA    RBLOCK1,2048(RBLOCK1)  KEY IN ALL ALLOCATED 2K BLOCKS    44070015
         BCT   RSIZE1,GSBSK                                             44100015
*                                                                       44130015
         AIF   (&SMF EQ 0).GMCOMA                                   SMF 44132018
         SPACE 2                                                    SMF 44134018
*                                                                   SMF 44136018
*        GO TO SMF CORE ROUTINE FOR GETMAIN                         SMF 44138018
*                                                                   SMF 44140018
GOCORE   L     GMSMFB,GMSMFAD          LOAD GETMAIN SMF CORE BASE   SMF 44142018
         L     RWORK1,SMFPQESV         LOAD ALLOCATION PQE POINTER  SMF 44146018
         BALR  GMSMFRT,GMSMFB          GO TO PROCESS CORE           SMF 44150018
         SPACE 2                                                    SMF 44152018
.GMCOMA  ANOP                                                       SMF 44154018
*        BUILD FQE FOR ANY REMAINING CORE                               44160015
*                                                                       44190015
GFQEBLD  O     RIN1,DQENXT(RPREDQE)     STORE DQE ADDRESS IN PREV DQE   44220015
         ST    RIN1,DQENXT(RPREDQE)                                     44250015
         SR    RSIZE,RLENGTH            GET EXCESS LENGTH IN 2K BLOCKS  44280015
         LA    RFQE,0(RSIZE,RBLOCK)  LOAD ADDR OF ASSIGNED CORE         44310015
         BZ    GAQETST             IF LENGTH IS ZERO-CHECK AQE NEEDED   44340015
*                                                                       44370015
         ST    RBLOCK,DQEFQE(RIN1) STORE FQE ADDRESS IN DQE             44400015
         ST    RSIZE,FQELNTH(RBLOCK)    STORE REMAINING LENGTH IN FQE   44430015
GAQETST  SR    RWORK3,RWORK3       CLEAR POINTER                        44460015
         ST    RWORK3,FQENXT(RBLOCK)       TO NEXT FQE                  44490015
*                                                                       44520015
         LA    RIN1,0(RIN1)        CLEAR HIGH ORDER BYTE                44550015
         BR    RCOMRET2            RETURN-CORE ALLOCATED                44580015
         EJECT                                                          44610015
*        SEARCH FREE BLOCK QUEUE FOR AVAILABLE BLOCKS                   44640015
*           INPUT - RWORK1 - NUMBER OF BYTES NEEDED                     44670015
*           OUTPUT - RBLOCK - ADDRESS OF FIRST AVAILABLE BLOCK          44700015
*                    RSIZE  - NUMBER OF BYTES AVAILABLE                 44730015
*           REGISTERS USED - RWORK1,RBLOCK,RSIZE,RDISP,RSPID,RTCB,      44760015
*                            RCOMRET3,RWORK4,RWORK5                     44790015
         SPACE                                                          44820015
FBQSRCH  ST    RCOMRET3,RREGSAVE      SAVE BAL LINK REG FOR EXIT  20021 44830020
         SR    RSIZE,RSIZE            INITIALIZE SIZE REGISTER    20021 44850020
         ST    RSIZE,FBQESIZ .      STORE SIZE OF LARGEST FBQE   A31213 44860020
         LA    RDISP,BCKPTR        INITIALIZE FBQE PTR DISPLACEMENT     44880015
         CH    RSPID,C246          IS IT PP SUBPOOL                     44910015
         BL    TCBPART             YES - PICK UP TCBPQE                 44940015
         C     RSPID,C252          IS IT REQUEST FOR SP 252             44970015
         BE    TCBPART             YES - PICK UP TCBPQE                 45000015
         CH    RSPID,C248          IS IT REQUEST FOR PARTITION          45030015
         BNH   FREEPTR             YES - PICK UP PTR FROM GOVRFLB+8     45060015
         SR    RDISP,RDISP         NO - SET DISPLACEMENT FOR FWD PTR    45090015
TCBPART  L     RBLOCK,TCBPQE(RTCB) PICK UP TCBPQE                       45120015
         LTR   RBLOCK,RBLOCK     IS THERE A REGION              SA64994 45121021
         L     RCOMRET3,RREGSAVE LOAD UP RETURN REG             SA64994 45122021
         BZ    4(RCOMRET3)       NO, DON'T GO ANY FURTHER       SA64994 45123021
NEXTPQE  L     RBLOCK,PQEPREV(RBLOCK)   PICK UP NEXT PQE.               45150015
         LTR   RBLOCK,RBLOCK       IS THIS THE END OF PQE CHAIN    LC0A 45151017
         L     RCOMRET3,RREGSAVE      RESTORE RETURN REGISTER     20021 45151520
         BZ    4(RCOMRET3)         EXIT - CORE NOT IN OWNED PQE    LC0A 45152017
         AIF   ('&LCS' NE 'Y').LC07                                LC0A 45155017
         CLC   PQEHIID(1,RBLOCK),HIBYTE Q. IS THIS PQE FOR THE     LC0A 45160017
*                                       REQUESTED HIERARCHY        LC0A 45165017
         BNE   NEXTPQE                  NO - GET NEXT PQE          LC0A 45170017
.LC07    ANOP                                                      LC0A 45175017
         AIF   ('&RORI' NE 'Y').GO30                               LC0A 45240017
TESTPQE  CLI   PQESTAT,X'FF'       SEARCH BORROWED.                     45270015
         BE    TCBPART1            YES. SEARCH BORROWED CORE.           45300015
         TM    RORIFLG(RBLOCK),RGNSHRD  IS THE REGION OWNED             45330015
         BO    NEXTPQE            NO - PICK UP NEXT PQE                 45360015
.GO30    ANOP                                                           45390015
TCBPART1 LR    RWORK2,RBLOCK          SAVE PQE ADDRESS            20021 45420020
FBQLOOP  L     RBLOCK,0(RBLOCK,RDISP) PICK UP ADDRESS OF FBQE           45450015
         CR    RBLOCK,RWORK2          IS THIS THE OWNING PQE      20021 45530020
         BE    NEXTPQE            SEARCH FOR OWNED PQE                  45610017
         C     RSIZE,FBQESIZE(RBLOCK) IS BLOCK LARGEST THUS FAR         45690015
         BNL   CKLSTBLK            NO - CHECK IF LAST FBQE         LC0A 45720017
         L     RSIZE,FBQESIZE(RBLOCK) PICK UP SIZE OF BLOCK             45750015
         ST    RSIZE,FBQESIZ .      STORE SIZE OF LARGEST FBQE   A31213 45760020
         ST    RSIZE,ORGLRG .      LARGEST BLOCK AVAILABLE        21016 45770021
         CR    RSIZE,RWORK1        IS BLOCK LARGE ENOUGH                45780015
         BL    CKLSTBLK            NO - CHECK IF LAST FBQE         LC0A 45810017
         AIF   (&SMF EQ 0).GMCOMZ                                   SMF 45816018
         ST    RWORK2,SMFPQESV  SAVE ALLOCATION PQE FOR SMF       20021 45828020
.GMCOMZ  ANOP                                                       SMF 45834018
         BH    FBQREPR(RDISP)      TOO LARGE                            45840015
         L     RWORK4,FWDPTR(RBLOCK) BLOCK IS EXACT SIZE NEEDED         45870015
         L     RWORK5,BCKPTR(RBLOCK)                                    45900015
         ST    RWORK4,FWDPTR(RWORK5) ELIMINATE BLOCK FROM QUEUE         45930015
         ST    RWORK5,BCKPTR(RWORK4)                                    45960015
         B     FBBEGOUT            RETURNING                      20021 45970020
CKLSTBLK C     RWORK2,0(RBLOCK,RDISP)   Q. LAST FBQE              20021 45980020
         BNE   FBQLOOP             NO - CHECK NEXT FBQE            LC0A 46002017
         LR    RBLOCK,RWORK2 YES - RESTORE PQE ADDRESS AND        20021 46007020
         B     NEXTPQE                   CONTINUE THE SEARCH       LC0A 46012017
FREEPTR  L     RBLOCK,GOVRFLB+8    PICK UP PTR TO FREE AREA PQE         46020015
         ST    RCOMRET3,RREGSAVE  SAVE RETURN ADDRESS             20021 46030020
         B     NEXTPQE                                                  46050015
FBQREPR  B     FBBEG               SUBPOOLS 0-127                       46080015
         SR    RSIZE,RWORK1        FIND NUMBER OF SURPLUS BYTES         46110015
         ST    RSIZE,FBQESIZE(RBLOCK) ADJUST FBQE FOR ALLOCATED BLOCKS  46140015
         AR    RBLOCK,RSIZE        COMPUTE ADDRESS OF ALLOCATED BLOCK   46170015
         LR    RSIZE,RWORK1        RETURN SIZE OF ALLOCATED BLOCK       46200015
         B     FBBEGOUT            RETURNING                      20021 46230020
FBBEG    SR    RSIZE,RWORK1        FIND NUMBER OF SURPLUS BYTES         46260015
         ST    RSIZE,FBQESIZE(RBLOCK) PUT CORRECTED SIZE IN OLD FBQE    46290015
         LR    RSIZE,RWORK1        RETURN SIZE OF ALLOCATED BLOCK       46320015
         AR    RWORK1,RBLOCK       COMPUTE ADDRESS OF NEW FBQE          46350015
         L     RWORK4,FWDPTR(RBLOCK) PICK UP FWD PTR FROM OLD FBQE      46380015
         L     RWORK5,BCKPTR(RBLOCK) PICK UP BACK PTR FROM OLD FBQE     46410015
         MVC   0(FBQELNTH,RWORK1),0(RBLOCK) MOVE FBQE TO NEW LOCATION   46440015
         ST    RWORK1,FWDPTR(RWORK5) PUT NEW FBQE ADDRESS IN PREVIOUS   46470015
*                                     BLOCK FWD PTR                     46500015
         ST    RWORK1,BCKPTR(RWORK4) PUT NEW FBQE ADDRESS IN FOLLOWING  46530015
*                                     BLOCK BACK POINTER                46560015
FBBEGOUT L     RCOMRET3,RREGSAVE   RESTORE RETURN REGISTER        20021 46570020
         BR    RCOMRET3            RETURN                               46590015
         EJECT                                                          46620015
*        UPDATE FQE TO REMOVE ASSIGNED AREA                             46650015
*           INPUT - RFRELNTH - LENGTH OF REMAINING FREE AREA            46680015
*                   RFQE   - FQE TO BE UPDATED                          46710015
*                   RPREFQE- PREVIOUS FQE ON QUEUE                      46740015
*           OUTPUT- RFQE   - ADDR OF ASSIGNED AREA                      46770015
*           REGISTERS USED - RFRELNTH,RFQE,RPREFQE,RCOMRET1,RCOMRET2,   46800015
*                            RVALCKIN                                   46830015
*                                                                       46860015
GFQEUPDT CL    RSPID,C252          IS REQUEST FOR SP 252-255            46890015
         BC    11,GFQEUP1          YES - BYPASS VALIDITY CHECK          46920015
         MVI   MSGLEN,X'0C'   SET TEMP MSG LEN IN CASE OF ABEND   21016 46930021
         BAL   RCOMRET2,CFQECHK    CHK THAT FQE & PREV FQE IN USER CORE 46950015
         MVI   MSGLEN,X'00'        TURN OFF MSG LEN               21016 46960021
GFQEUP1  LTR   RFRELNTH,RFRELNTH   IF LENGTH REMAINING IN FQE IS ZERO   46980015
         BZ    GFQEOUT             REMOVE FQE FROM QUEUE                47010015
         ST    RFRELNTH,FQELNTH(RFQE) STORE REMAINING LNTH IN FQE       47040015
         AR    RFQE,RFRELNTH       GET ADDRESS OF ASSIGNED AREA         47070015
GFQEUP2  CL    RSPID,C252          IS REQUEST FOR SP 252-255            47100015
         BCR   11,RCOMRET1         YES - RETURN                         47130015
         LA    RWORK4,0(RFQE,RLENGTH) COMPUTE UPPER BOUND OF FQE        47160015
         CR    RPREFQE,RDQE        IS PREVIOUS QE A DQE                 47190015
         BE    GFQEUP3             YES                                  47220015
         CR    RWORK4,RPREFQE      IS UPPER BOUND OF FQE AREA LESS      47250015
*                                   THAN PREVIOUS FQE                   47280015
         BCR   4,RCOMRET1          YES - RETURN                         47310015
         B     BADFQE              NO - ERROR                     21016 47340021
GFQEUP3  CR    RWORK4,RWORK6       IS UPPER BOUND OF FQE AREA GREATER   47370015
*                                   THAN DQE UPPER BOUND                47400015
         BCR   13,RCOMRET1         NO - RETURN                          47430015
         B     BADFQE              YES - ERROR                    21016 47460021
GFQEOUT  MVC   FQENXT+1(3,RPREFQE),FQENXT+1(RFQE) DEQUEUE 0 LENGTH FQE  47490015
         B     GFQEUP2             CHECK FOR DESTROYED FQE              47520015
         EJECT                                                          47550015
*        BUILD QUEUE ELEMENT (AQE) FOR SUBPOOL 253 OR 254 CORE          47580015
*           INPUT - RFRELNTH - LENGTH OF REMAINING FREE AREA            47610015
*                   RFQE   - ADDRESS OF FQE                             47640015
*                   RPREFQE - ADDRESS OF PREVIOUS FQE                   47670015
*                                                                       47700015
*           OUTPUT- RFQE   - ADDRESS OF ASSIGNED CORE                   47730015
*           REGISTERS USED - RFRELNTH,RFQE,RLENGTH,RAQE,RTCB            47760015
*                            RCOMRET1                                   47790015
*                                                                       47820015
GBLDAQE  ST    RFRELNTH,FQELNTH(RFQE)   STORE REMAINING LENGTH IN FQE   47850015
         LA    RAQE,0(RFRELNTH,RFQE)    GET ADDRESS OF AQE              47880015
         LTR   RFRELNTH,RFRELNTH        IF FQE LENGTH IS ZERO           47910015
         BC    7,GBLDAQE2                                               47940015
         MVC   FQENXT+1(3,RPREFQE),FQENXT+1(RFQE) IF FQE LNTH IS 0,     47970015
*                                              REMOVE FROM QUEUE        48000015
GBLDAQE2 MVC   AQENXT(4,RAQE),TCBAQE(RTCB) PUT POINTER IN NEW AQE       48030015
         ST    RAQE,TCBAQE(RTCB)   PUT AQE IN QUEUE                     48060015
         ST    RLENGTH,AQELNTH(RAQE) PUT LENGTH IN AQE                  48090015
          LA    RFQE,8                                                  48120015
          SR    RLENGTH,RFQE                                            48150015
         LA    RFQE,8(RAQE)        GET ADDR OF ASSIGNED CORE            48180015
         BR    RCOMRET1                 RETURN                          48210015
*                                                                       48240015
*                                                                       48270015
*                                                                       48300015
*        CREATE AN SPQE FOR A NEW SUBPOOL                               48330015
*           INPUT - RTCB - ADDRESS OF TCB                               48360015
*                                                                       48390015
*                                                                       48420015
*                                                                       48450015
*                                                                       48480015
GSPQESPC LR    RWORK1,RIN1         SAVE INPUT REG                       48510015
         LA    RIN1,8                                                   48540015
         BAL   RCOMRET1,GETMAINB   GET 8 BYTES FOR AN SPQE              48570015
         LR    RSPQE,RIN1                                               48600015
         MVC   SPQENXT+1(3,RSPQE),TCBMSS+1(RTCB) NXT SPQE PTR TO SPQE   48630015
         IC    RWORK4,TCBMSS(RTCB)                                      48660015
         ST    RSPQE,TCBMSS(RTCB)       NEW SPQE ADDR TO TCB            48690015
         STC   RWORK4,TCBMSS(RTCB)                                      48720015
         STC   RSPID,SPQEID(RSPQE)      STORE SUBPOOL ID IN SPQE        48750015
***************  CREATE INITIAL SPQE FOR TASK  ***************          48780015
         OC    SPQENXT+1(3,RSPQE),SPQENXT+1(RSPQE) FIRST SPQE IF PTR=0  48810015
         BNE   GSPQESP1                 BRANCH IF NOT FIRST SPQE        48840015
         MVI   SPQEFLGS(RSPQE),SPQELAST SET FLAG-SPQE IS LAST ON CHAIN  48870015
*************************************************************           48900015
GSPQESP1 LR    RIN1,RWORK1                                              48930015
         B     GCOMMON1                                                 48960015
         EJECT                                                          48990015
*        ENTRY POINT TO FREEMAIN                                        49020015
         SPACE                                                          49050015
         DS    0D                                                       49080015
         DROP  FREBAS .          DROP SECOND BASE                 M0105 49090020
IGC005   BALR  RBASE,0                                                  49110015
         USING *,RBASE                                                  49140015
         L     RBASE,MSSADR                                             49170015
         USING MSSBASE,RBASE,FREBAS                               20021 49180020
         SPACE 2                                                        49230015
*        ROUTINE TO PICK UP SUBPOOL ID, BRANCH TO VALIDITY CHECK        49260015
*           ROUTINE TO CHECK LISTS, AND TO CHECK FOR LIST REQUEST       49290015
*           INPUT REGISTER                                              49320015
*              RIN1 - ADDRESS OF PARAMETER LIST                         49350015
*           OUTPUT REGISTERS                                            49380015
*              RSPID   - SUBPOOL ID                                     49410015
*              RLENGTH - LENGTH OR ADDRESS OF LENGTH LIST               49440015
*              RADDR   - ADDRESS OF AREA LIST OR ADDRESS OF LENGTH-AREA 49470015
*                          LIST                                         49500015
         SPACE                                                          49530015
         L     FREBAS,DBASADR .    ESTABLISH SECOND BASE          20021 49540020
         MVC   MODEBYTE(1),33(0)   MODE INTO MODE BYTE                  49560015
FMBASE   MVI   SVCBYTE,5 .           SAVE THE SVC NUMBER                49590020
         L     IPVLBASE,IPVAL .    LOAD ADD OF VALIDY CK RTN      M2198 49630020
         BALR  RCOMRET1,IPVLBASE   VALIDITY CHECK INPUT PARAMETERS      49650015
         TM    TYPE(RIN1),CODE                                          49680015
         BC    NOTLIST,FVARCHK     IF NOT A LIST REQUEST                49710015
         SPACE 2                                                        49740015
*        ROUTINE TO HANDLE FREEING OF LIST REQUESTS                     49770015
*           INPUT REGISTERS                                             49800015
*              RLENGTH - ADDRESS OF LENGTH LIST                         49830015
*              RADDR   - ADDRESS OF AREA LIST                           49860015
*           OUTPUT REGISTERS                                            49890015
*              RLST    - ADDRESS OF CURRENT LENGTH IN LENGTH LIST       49920015
*              RADDR1  - ADDRESS OF CURRENT AREA IN AREA LIST           49950015
*              RLENGTH - CURRENT LENGTH                                 49980015
*              RADDR   - CURRENT AREA ADDRESS                           50010015
         SPACE                                                          50040015
         LR    RLST,RLENGTH        SAVE LENGTH LIST ADDRESS             50070015
         LA    RFMRET,FMCOMMON                                          50100015
FLISTADV L     RLENGTH,0(RLST)     PICK UP LENGTH FROM LIST             50130015
         LA    RLENGTH,0(RLENGTH)  CLEAR LAST ENTRY INDICATOR           50160015
         TM    0(RLST),X'80'       IS THIS LAST ENTRY IN LIST           50190015
         BC    1,FLAST                                                  50220015
         BALR  RFMRET,RFMRET       BRANCH TO FREEMAIN COMMON ROUTINE    50250015
         LA    RLST,4(RLST)        PICK UP NEXT ENTRY                   50280015
         LA    RADDR,4(RADDR)                                           50310015
         LA    RFMRET,FCOMMON1     BYPASS SPQE SEARCH                   50340015
         B     FLISTADV                                                 50370015
FLAST    BALR  RFMRET,RFMRET       TO FREE LAST ELEMENT IN LIST         50400015
         BR    RRETURN                                                  50430015
         SPACE 2                                                        50460015
*        ROUTINE TO HANDLE FREEING OF VARIABLE REQUESTS                 50490015
*           INPUT REGISTER                                              50520015
*              RADDR   - ADDRESS OF LENGTH-ADDRESS LIST                 50550015
*           OUTPUT REGISTERS                                            50580015
*              RLENGTH - LENGTH OF AREA TO BE FREED                     50610015
*              RADDR   - ADDRESS OF AREA TO BE FREED                    50640015
         SPACE                                                          50670015
FVARCHK  BC    ELEMENT,FELEMENT    IF ELEMENT REQUEST                   50700015
         L     RLENGTH,VLNTH(RADDR)                                     50730015
         SPACE 2                                                        50760015
*        ROUTINE TO HANDLE FREEING OF ELEMENT REQUESTS                  50790015
*           INPUT REGISTERS                                             50820015
*              RLENGTH - LENGTH                                         50850015
*              RADDR   - ADDRESS OF LOCATION CONTAINING AREA ADDRESS    50880015
*           OUTPUT REGISTERS                                            50910015
*              RLENGTH - LENGTH OF AREA TO BE FREED                     50940015
*              RADDR   - ADDRESS OF AREA TO BE FREED                    50970015
         SPACE                                                          51000015
FELEMENT OI    FREESW,X'08'                                       21016 51020021
         BAL   RFMRET,FMCOMMON     ELEMENT - BR TO FREE STORAGE   21016 51040021
         BR    RRETURN                                                  51060015
         SPACE 2                                                        51090015
*        BRANCH ENTRY PROCESSING                                        51120015
         SPACE                                                          51150015
         DROP  FREBAS .          DROP SECOND BASE                 M0105 51160020
FMBRANCH LR    RIN15,RBASE         SAVE REGISTER 8                      51180015
         BALR  RBASE,0                                                  51210015
         USING *,RBASE                                                  51240015
         L     RBASE,MSSADR                                             51270015
         USING MSSBASE,RBASE,FREBAS                               20021 51300020
         SSM   CLHIBYTE .          DISABLE                        M3872 51310020
         ST    RIN15,FMBRSAV+24    RIN15=ENTRY CONTENTS OF REG8  A28819 51330019
         LA    RIN15,FMBASE        SET UP BRANCH TO FREEMAIN      M3872 51360020
FMBRNCOM EQU   *                                                  M3872 51362020
         STM   RLST,RCOMRET3,FMBRSAV                             A28819 51370019
         STM   RCOMRET1,RRETURN,FMBRSAV+28                       A28819 51375019
         L     FREBAS,DBASADR .     ESTABLISH SECOND BASE         M0105 51376020
         ST    RRETURN,BRNREG    SAVE RETURN REG                  21016 51378021
         MVI   MODEBYTE,0 .        SET SUPERVISOR MODE           PIT032 51380021
         MVI   BESW,X'FF'          SET BRANCH ENTRY SWITCH        21016 51388021
         BALR   RRETURN,RIN15                                           51396021
         MVI   BESW,X'00'          RESET BRANCH ENTRY SWITCH     A28819 51405019
.D       LM    RLST,RRETURN,FMBRSAV RESTORE CALLERS REGS         A28819 51410019
         BR    RRETURN                                           A28819 51412020
*               SAVE AREAS                                              51417020
BRANCHSV DS    13F .                                              M2279 51419020
IEA10FS  EQU   *                           REF USED BY ABEND      M3806 51419120
FMBRSAV  DS    16F .     SAVE AREA FOR FM BRANCH ENTRY            M2279 51419420
FMSAVE   DS    16F .                                              M2279 51419820
SAVREG2  DS    16F .                                              M2279 51427320
SAVEAREA DS    16F .                                              M2279 51429320
SAVEREGS DS    12F .                                              M2279 51435020
DBASADR  DC    A(MSSBASE+4096) .                                  M2279 51437020
CLHIBYTE DC    X'00FFFFFF' .                                      M2279 51439020
MSSADR   DC    A(MSSBASE)                                         21016 51440021
         EJECT                                                          51442520
*        SPECIAL SUBPOOL FREEMAIN TO HANDLE FREEING OF A COMPLETE       51450015
*        SUBPOOL                                                        51480015
         SPACE                                                          51510015
SPFRMAIN OI    FREESW,X'08'        SET FREEMAIN SWITCH            21016 51520021
         LTR   RLENGTH,RLENGTH     IS LENGTH ZERO                 21016 51530021
         BZ    LENOK                                              21016 51540021
         MVI   MSGLEN,X'8C'       REASON CODE(4) AND LENGTH(12)   21016 51550021
         ST    RTCB,ABNDATA       STORE TCB SEARCHED              21016 51560021
         SR    RADDR,RADDR        SET ZERO FOR SUBPOOL FREEMAIN   21016 51570021
         B     GERROR3                                            21016 51580021
LENOK    LA    RWORK3,254                 (21016) ***** TEMPORARY ****  51590021
         CR    RSPID,RWORK3                       ***** TEMPORARY ***** 51630015
         BNL   GERR4   **TEMP** 254-255 SUBPOOL FREEMAIN ILLEGAL  21016 51640021
.*       AIF   (&TSO NE 1).TSO1300        *516620*             @AS76386 51662000
         LA    RWORK3,243         FREEMAIN OF SUBPOOLS            20021 51664020
         CR    RSPID,RWORK3       243,244,245 IS ILLEGAL          20021 51666020
         BL    SPOK                                               20021 51668020
         LA    RWORK3,245                                         20021 51670020
         CR    RSPID,RWORK3                                       20021 51672020
         BNH   GERR4                                              21016 51674021
SPOK     EQU   *                                                  20021 51676020
         SPACE                                                    20021 51678020
.TSO1300 ANOP                                                     20021 51680020
         OI    MODEBYTE,2          INDICATE SUBPOOL FREEMAIN            51690015
         BAL   RCOMRET1,CSPCHK     TO LOCATE SPQE                       51720015
         BR    RRETURN             SPQE NOT FOUND                       51750015
         BCR   0,RRET              NOP                                  51760015
         TM    MODEBYTE,X'F0'      SUPERVISOR KEY                       51780015
         BZ    SPFRMNSV            YES                                  51810015
         LTR   RSPID,RSPID         SUBPOOL ZERO?                        51840015
         BNZ   SPFRMNSV                                           21016 51850021
GERR4    SR    RADDR,RADDR                                        21016 51860021
         MVI   MSGLEN,X'08'                                       21016 51870021
         B     GERROR4             PROBLEM PGM ATTEMPTING TO FREE 21016 51880021
*                                   ALL OF SUBPOOL ZERO                 51900015
SPFRMNSV LTR   RSPID,RSPID         IS IT SUBPOOL 253                    51930015
         BM    SP253FRE            YES, SP253 OR SP254             MP2K 51936018
         AIF   ('&MPS' NE 'Y').MP0218                              MP2K 51942018
         BP    NOTRMS  NOT NEGATIVE OR SUBPOOL 0                   MP2K 51948018
         CLI   TCBCMCDE(RTCB),X'F4'                                MP2K 51954018
         BNE   NOTRMS                                              MP2K 51960018
         L     RWORK2,ENPTMP2K  GET ENTRY POINT TO MP SUBROUTINE   MP2K 51966018
         BR    RWORK2           BRANCH TO MP SUBROUTINE            MP2K 51972018
.MP0218  ANOP                                                      MP2K 51978018
NOTRMS   LA    RFMRET,SPFRMRET          SET UP RETURN              MP2K 51998018
         STM   RRETURN,RFMRET,FMSAVE SAVE REGISTERS                     52020015
SPFRMRET L     RDQE,SPQEDQE(RSPQE)      PICK UP DQE                     52050015
         LA    RDQE,0(RDQE)        CLEAR OUT SPID                       52080015
         LTR   RDQE,RDQE           END OF QUEUE IF ZERO                 52110015
         BCR   8,RRETURN           END OF QUEUE - EXIT                  52140015
         SR    RSIZE,RSIZE                                              52170015
         LR    RBLOCK,RSIZE                                             52200015
         L     RSIZE,DQELNTH(RDQE) PICK UP NUMBER OF BYTES              52230015
         L     RBLOCK,DQEADDR(RDQE) ADDRESS OF FIRST 2K BLOCK           52260015
         AIF   ('&LCS' NE 'Y').LC50                                LC0A 52267017
         LA    RBLOCK,0(RBLOCK)    CLEAR HIERARCHY IDENT           LC0A 52274017
.LC50    ANOP                                                      LC0A 52281017
         LR    RWORK4,RSIZE                                             52290015
SPFSTDQE ST    RSPQE,PREVDQSV      SPQE IS ALWAYS PREVIOUS DQE          52320015
         L     RPQE,TCBPQE(RTCB)        PICK UP ADDR OF PQE             52350015
         AIF   (&SMF NE 1).NOSMFSV                                      52352018
         ST    RTCB,SMFTCBSV            SAVE TCB POINTER            SMF 52354018
.NOSMFSV ANOP                                                           52356018
         L     RPQE,DUMBWD(RPQE)        PICK UP PTR TO PQE         MP2K 52360018
LOOP1    C     RBLOCK,PQESTADD(RPQE)   9IS CORE IN THIS REGION     MP2K 52370018
         BNL   FCOMMON3                 YES                        MP2K 52380018
         L     RPQE,DUMBWD(RPQE)        PICK UP END OF PQE CHAIN   MP2K 52390018
         LTR   RPQE,RPQE               IS THIS END OF CHAIN?  SC A63059 52395021
         BNZ   LOOP1                                              21016 52400021
         MVI   MSGLEN,X'6C'         REASON CODE(3) AND LENGTH(12) 21016 52410021
         ST    RTCB,ABNDATA     STORE TCB SEARCHED                21016 52420021
         SR    RADDR,RADDR      SET 0 INPUT TO SUBPOOL FREEMAIN   21016 52430021
         B     GERROR3                                            21016 52440021
         SPACE                                                          52500015
*        ROUTINE TO FREE SUBPOOL FOR SUBPOOL 253                        52530015
         SPACE                                                          52560015
SP253FRE LA    RFMRET,SP253RET                                          52590015
         AIF   (&TSO NE 1).TSO1400                                20021 52593020
         L     RWORK2,TCBPQE(RTCB)                                20021 52596020
         LTR   RWORK2,RWORK2           BRANCH IF NO               20021 52599020
         BZ    SP253RET        PQE                                20021 52602020
         L     RWORK2,PQENXT(RWORK2)                              20021 52605020
         L     RWORK2,PQESTADD(RWORK2)  GET LSQS SPQE ADDRESS     20021 52608020
         AGO   .TSO1500                                           20021 52611020
.TSO1400 ANOP                                                     20021 52614020
         L     RDQE,SPQEDQE(RSPQE) PICK UP DQE                          52620015
         LA    RDQE,0(RDQE)        CLEAR HIGH ORDER BYTE                52650015
.TSO1500 ANOP                                                     20021 52660020
SP253RET L     RADDR,TCBAQE(RTCB)  PICK UP ADDRESS OF FIRST AREA        52680015
         LTR   RADDR,RADDR         IS IT ZERO                           52710015
         BCR   8,RRETURN           YES - END OF QUEUE             20021 52716020
         AIF   (&TSO NE 1).TSO1600                                20021 52722020
         L     RSPQE,SQSBOUND .    LOAD SQS + 1 ADDRESS           M1389 52724020
         LA    RSPQE,0(RSPQE) .    ZERO HIGH ORDER BYTE           M1389 52726020
         CR    RADDR,RSPQE .       IS AQE IN SQS                  M1389 52734020
         LA    RSPQE,SQESPQE .     LOAD SQS SPQE                  M1389 52736020
         BL    *+6                   YES-BRANCH                   20021 52740020
         LR    RSPQE,RWORK2       NO-LOAD LSQS SPQE               20021 52746020
         L     RDQE,SPQEDQE(RSPQE) LOAD DQE                       20021 52752020
         LA    RDQE,0(RDQE)                                       20021 52758020
.TSO1600 ANOP                                                     20021 52764020
         L     RLENGTH,AQELNTH(RADDR) PICK UP LENGTH OF AREA            52770015
         LA    RAREAUB,0(RADDR,RLENGTH) FIND UPPER BOUND OF AQE AREA    52800015
         STM   RRETURN,RFMRET,FMSAVE SAVE REGISTERS                     52830015
         B     FCOMMON4                                                 52860015
         EJECT                                                          52890015
*        ************************************************************** 52920015
*                           FREEMAIN COMMON ROUTINES                    52950015
*        ************************************************************** 52980015
         SPACE 2                                                        53010015
*        THE FREEMAIN COMMON ROUTINES CONSIST OF THE CODE WHICH IS      53040015
*        COMMON TO ALL FORMS OF FREEMAIN EXCEPT THE SPECIAL R-FORM      53070015
*        FREEING A COMPLETE SUBPOOL.  THIS CODE MAKES USE OF OTHER      53100015
*        SUBROUTINES WHICH ARE COMMON TO GETMAIN AND FREEMAIN AND       53130015
*        WHICH ARE LOCATED ELSEWHERE IN THIS MODULE.                    53160015
*           INPUT REGISTERS                                             53190015
*              RSPID   - SUBPOOL ID                                     53220015
*              RLENGTH - LENGTH OF AREA TO BE FREED (IN BYTES)          53250015
*              RADDR   - BEGINNING ADDRESS OF AREA TO BE FREED          53280015
*              RTCB    - TCB OF REQUESTING TASK                         53310015
         SPACE                                                          53340015
FMCOMMON BAL   RCOMRET1,CSPCHK     TO LOCATE SPQE                       53370015
         B     SUBPERR             ERROR - NOT IN SUBPOOL NAMED   21016 53400021
         SPACE 2                                                        53430015
         AIF   (&TSO NE 1).TSO1700                                20021 53432020
*        IF REQUEST IS FOR LSQS SUBPOOL- CHECK IF AREA WAS        20021 53434020
*        OBTAINED FROM LSQS OR SQS. SQS IS ALLOCATED WHEN         20021 53436020
*        LSQS IS FULL.                                            20021 53438020
         TM    LSQSSW,LSQSMSK      IS REQUEST FOR LSQS?           20021 53440020
         BZ    FCOMMON1          NO- CONTINUE.                    20021 53442020
         LA    RSPQE,0(RSPQE)     CLEAR HI-BYTE OF SPQE           20021 53444020
         C     RSPQE,0(RADDR)      STORAGE IN SQS?                20021 53446020
         BL    FCOMMON1            NO- CONTINUE                   20021 53448020
         LA    RSPQE,SQESPQE       LOAD SQS SPQE                  20021 53450020
         MVI   LSQSSW,LSQSOFF      CLEAR LSQS SWITCH.             20021 53452020
         SPACE 2                                                  20021 53454020
.TSO1700 ANOP                                                     20021 53456020
*        ROUTINE TO LOCATE THE DQE CONTAINING THE STORAGE TO BE FREED   53460015
*           A SUCCESSFUL RETURN FROM GSPCHK RETURNS TO THIS POINT       53490015
*           INPUT REGISTERS                                             53520015
*              RSPQE   - SPQE ADDRESS                                   53550015
*              RADDR   - ADDRESS OF STORAGE TO BE FREED                 53580015
*              RLENGTH - LENGTH OF STORAGE TO BE FREED                  53610015
*           OUTPUT REGISTERS                                            53640015
*              RDQE    - ADDRESS OF DQE CONTAINING STORAGE TO BE FREED  53670015
*              RDQELB  - LOWER BOUND OF AREA DESCRIBED BY DQE           53700015
*              RDQEUB  - UPPER BOUND OF AREA DESCRIBED BY DQE           53730015
*              RAREAUB - UPPER BOUND OF AREA TO BE FREED                53760015
*              RPREVDQ - ADDRESS OF PREVIOUS DQE                        53790015
         SPACE                                                          53820015
FCOMMON1 STM   RRETURN,RFMRET,FMSAVE SAVE REGISTERS                     53850015
         L     RADDR,0(RADDR)      PICK UP ADDRESS                      53880015
         LA    RADDR,0(RADDR)  CLEAR HI-ORDER BYTE.                     53910015
FCOMMON2 BAL   RCOMRET1,CRNDLNTH   TO ROUND UP LENGTH                   53940015
         LTR   RLENGTH,RLENGTH                                          53970015
         BZ    FCOMRET             RETURN IF LENGTH=0 FOR SUBPOOL       54000015
*                                   OTHER THAN 253 OR 254               54030015
         NR    RWORK2,RADDR        RWORK2 CONTAINS 7 FROM CRNDLNTH      54060015
         BE    ADROK               ERR - ADDR NOT MULTIPLE OF 8   21016 54069021
         MVI   MSGLEN,X'0C'        SET LENGTH EQUAL 12            21016 54078021
         ST    RTCB,ABNDATA        SAVE TCB ADDR                  21016 54087021
         CLI   SVCBYTE,X'05'       SVC 5?                         21016 54096021
         BE    GERROR9             YES. TEMP DATA CORRECT         21016 54105021
         MVI   MSGLEN,X'08'        NO. CHANGE LENGTH TO 8         21016 54114021
         ST    RADDR,ABNDATA       SAVE ALTERNATE DATA            21016 54123021
         B     GERROR9             GO TO ABEND                    21016 54132021
ADROK    LTR   RSPID,RSPID         IS THIS SUBPOOL 253 OR 254     21016 54141021
         BC    NN,STRTSRCH         NO                                   54150015
         LA    RWORK3,QESIZE       YES                                  54180015
         SR    RADDR,RWORK3        BACK UP ADDRESS TO BEGINNING OF QE   54210015
STRTSRCH LR    RDQE,RSPQE                                               54240015
FADVDQE  LR    RPREVDQ,RDQE        SAVE ADDRESS OF PREVIOUS DQE         54270015
         L     RDQE,DQENXT(RDQE)   PICK UP ADDRESS OF DQE               54300015
         N     RDQE,CLHIBYTE       CLEAR HIGH ORDER BYTE                54330015
         BNZ   ADRDQE                                             21016 54340021
         MVI   MSGLEN,X'2C'         REASON CODE(1) AND LENGTH(12) 21016 54350021
         ST    RTCB,ABNDATA         STORE TCB SEARCHED            21016 54360021
         B     GERROR3                                            21016 54370021
ADRDQE   L     RDQELB,DQEADDR(RDQE) PICK UP ADDR OF FIRST BLOCK   21016 54380021
         AIF   ('&LCS' NE 'Y').LC23                                LC0A 54397017
         LA    RDQELB,0(RDQELB)    CLEAR HIERARCHY IDENT           LC0A 54404017
.LC23    ANOP                                                      LC0A 54411017
         L     RDQEUB,DQELNTH(RDQE) PICK UP NUMBER OF BYTES             54420015
FCUPRBND AR    RDQEUB,RDQELB       COMPUTE UPPER BOUND OF DQE AREA      54450015
*                                  COMPUTE UPPER BOUND OF AREA TO BE    54480015
*                                   FREED                               54510015
         LR    RAREAUB,RADDR                                   @JK69892 54520021
         AR    RAREAUB,RLENGTH                                 @JK69892 54530021
*                                  IS AREA TO BE FREED WITHIN DQE       54570015
*                                   BOUNDS - IF NOT, PICK UP NEXT DQE   54600015
         CR    RADDR,RDQELB                                             54630015
         BL    FADVDQE                                                  54660015
         CR    RAREAUB,RDQEUB                                           54690015
         BH    FADVDQE                                                  54720015
         CR    RADDR,RDQEUB        IS START GREATER DQE END    @SA77070 54724000
         BH    FADVDQE                                         @SA77070 54728000
         CR    RAREAUB,RDQELB      IS END LESS THAN DQE START  @SA77070 54732000
         BL    FADVDQE                                         @SA77070 54736000
         CR    RADDR,RAREAUB       IS START GREATER THAN END   @SA77070 54740000
         BH    FADVDQE             *                           @SA77070 54744000
         ST    RPREVDQ,PREVDQSV    SAVE ADDRESS OF PREVIOUS DQE         54750015
         SPACE                                                          54780015
         LTR   RSPID,RSPID         IS THIS SUBPOOL 253 OR 254           54810015
         BC    NN,FRECOMBN         NO                                   54840015
         SPACE 2                                                        54870015
*        ROUTINE TO REMOVE FREE SUBPOOL 253 OR 254 STORAGE FROM QUEUE   54900015
*           INPUT REGISTERS                                             54930015
*              RADDR   - ADDRESS OF STORAGE TO BE FREED                 54960015
*              RLENGTH - LENGTH OF STORAGE TO BE FREED                  54990015
*              RAREAUB - UPPER BOUND OF AREA TO BE FREED                55020015
*              RDQE    - ADDRESS OF DQE CONTAINING STORAGE TO BE FREED  55050015
         SPACE                                                          55080015
*        LOCATE QE LESS THAN OR EQUAL TO RADDR.  SAVE PREVIOUS QE ADDR  55110015
         SPACE                                                          55140015
FCOMMON4 LA    RQE,TCBAQE(RTCB)                                         55170015
         L     RWORK1,0(0,RQE)     GET AQE ADDRESS                 8098 55175017
         LTR   RWORK1,RWORK1       Q. IS AQE ADDRESS ZERO          8098 55180017
         BNZ   FC4LOOP             NO - PROCESS NORMALLY           8098 55185017
         LA    RERROR,GERRCODE     YES- SET UP ERROR CODE REGISTER 8098 55190017
FCOMMN4B MVI   MSGLEN,X'08'                                       21016 55191021
         ST    RADDR,ABNDATA                                      21016 55192021
         B     GERROR13                                            8098 55195017
FC4LOOP  LR    RPREVQE,RQE         SAVE PREVIOUS AQE ADDRESS            55200015
         L     RQE,0(0,RQE)        PICK UP AQE ADDRESS                  55230015
         CR    RADDR,RQE           IS THIS AQE WANTED                   55260015
         BL    FC4LOOP             NO - CHECK NEXT AQE                  55290015
         LA    RERROR,GERRCODE  SET UP ERROR CODE IN REGISTER SIX  9774 55295017
         LTR   RQE,RQE  Q. THIS THE END OF THE AQE CHAIN           9774 55300017
         BC    8,FCOMMN4B     THIS CORE ALREADY FREED             21016 55310021
         SPACE                                                          55320015
*        COMPUTE UPPER BOUND OF AQE AREA                                55350015
         SPACE                                                          55380015
         L     RQESIZ,AQELNTH(RQE) PICK UP SIZE                         55410015
         LA    RAQEUB,0(RQE,RQESIZ) COMPUTE UPPER BOUND                 55440015
         CR    RAREAUB,RAQEUB      IS AREA WITHIN AQE AREA              55470015
         BH    FC4LOOP             NO - PICK UP NEXT AQE                55500015
         BL    FAQELOWR            NOT FREEING UPPER PART OF AQE AREA   55530015
         CR    RADDR,RQE                                                55560015
         BNE   FAQEUPPR            NOT FREEING LOWER PART OF AQE AREA   55590015
*                                  THE FOLLOWING INSTRUCTION REMOVES    55620015
*                                   THE FREE AREA FROM THE QUEUE        55650015
         MVC   AQENXT+PTROFST(ADRLNTH,RPREVQE),AQENXT+PTROFST(RQE)      55680015
         B     FRECOMBN                                                 55710015
         SPACE                                                          55740015
*        FREEING UPPER PART OF STORAGE DESCRIBED BY AQE                 55770015
         SPACE                                                          55800015
FAQEUPPR LA    RWORK3,QESIZE                                            55830015
         AR    RADDR,RWORK3        ADJUST ADDRESS AND SIZE FOR PORTION  55860015
         SR    RLENGTH,RWORK3       ACTUALLY BEING FREED                55890015
         BZ    FCOMRET             RETURN IF LENGTH=0                   55920015
         SR    RQESIZ,RLENGTH      COMPUTE NEW SIZE FOR AQE (BYTES)     55950015
         B     FAQEUPR1                                                 55980015
         SPACE                                                          56010015
*        FREEING LOWER PART OF STORAGE DESCRIBED BY AQE                 56040015
         SPACE                                                          56070015
FAQELOWR LA    RWORK1,QESIZE       REMOVE 8 BYTES FROM FREE AREA FOR    56100015
         SR    RAREAUB,RWORK1       NEW AQE                             56130015
         SR    RLENGTH,RWORK1                                           56160015
         ST    RAREAUB,AQENXT(RPREVQE) PUT NEW AQE IN QUEUE             56190015
         SR    RAQEUB,RAREAUB      NUMBER OF BYTES FOR NEW AQE          56220015
         LR    RWORK3,RAREAUB      RAREAUB IS REG 0 AND CANNOT BE USED  56250015
*                                   AS INDEX                            56280015
         ST    RAQEUB,AQELNTH(RWORK3)                                   56310015
         CR    RQE,RADDR                                                56340015
         BNE   FAQEMID             FREEING MIDDLE OF AQE AREA           56370015
         MVC   AQENXT(4,RWORK3),AQENXT(RQE) PTR INTO NEW AQE            56400015
         B     FRECOMBN                                                 56430015
         SPACE                                                          56460015
*        FREEING MIDDLE PART OF STORAGE DESCRIBED BY AQE                56490015
         SPACE                                                          56520015
FAQEMID  ST    RQE,0(RWORK3) POINT NEW AQE TO NEXT QE                   56550015
         AR    RADDR,RWORK1        ADJUST ADDRESS AND SIZE FOR PORTION  56580015
         SR    RLENGTH,RWORK1       ACTUALLY BEING FREED                56610015
         LR    RWORK1,RADDR                                             56640015
         SR    RWORK1,RQE          SIZE OF REMAINING LOWER PART (BYTES) 56670015
FAQEUPR1 ST    RWORK1,AQELNTH(RQE)                                      56700015
         SPACE 2                                                        56730015
*        ROUTINE TO PUT FREE STORAGE INTO THE QUEUE AND TO COMBINE      56760015
*         ADJOINING FREE AREAS                                          56790015
*           INPUT REGISTERS                                             56820015
*              RADDR   - ADDRESS OF STORAGE TO BE FREED                 56850015
*              RLENGTH - LENGTH OF STORAGE TO BE FREED                  56880015
*              RAREAUB - UPPER BOUND OF AREA TO BE FREED                56910015
*              RDQE    - ADDRESS OF DQE CONTAINING STORAGE TO BE FREED  56940015
*              RSPID   - SUBPOOL ID OF STORAGE TO BE FREED              56970015
*           OUTPUT REGISTERS                                            57000015
*              RFQE    - ADDRESS OF FQE CONTAINING STORAGE FREED        57030015
*              RPREVQE - ADDRESS OF QUEUE ELEMENT PREVIOUS IN QUEUE TO  57060015
*                         FQE CONTAINING STORAGE FREED                  57090015
*              RLENGTH - LENGTH OF STORAGE DESCRIBED BY FQE             57120015
         SPACE                                                          57150015
*        LOCATE QE LESS THAN OR EQUAL TO RAREAUB. SAVE PREVIOUS QE ADDR 57180015
         SPACE                                                          57210015
FRECOMBN EQU   *                                                  20021 57240020
         BAL   RCOMRET1,QELOCATE                                        57270015
         CL    RSPID,C252          IS REQUEST FOR SP 252-255            57300015
         BC    11,FRECMBN1         YES - BYPASS VALIDITY CHECK          57330015
         LR    RWORK3,RDQELB       SAVE DQE LOWER BOUND ACROSS CFQECHK  57360015
         MVI   MSGLEN,X'10'    SET TEMP MSG LEN IN CASE OF ABEND  21016 57370021
         BAL   RCOMRET2,CFQECHK                                         57390015
         MVI   MSGLEN,X'00'        TURN OFF MSG LENGTH            21016 57400021
         LR    RDQELB,RWORK3       RESTORE DQE LOWER BOUND              57420015
         SPACE                                                          57450015
*        THE 'STRAIGHT THROUGH' PATH IN THIS ROUTINE COMBINES A FREE    57480015
*         AREA WITH AN ADJACENT UPPER FREE AREA AND AN ADJACENT LOWER   57510015
*         FREE AREA                                                     57540015
         SPACE                                                          57570015
FRECMBN1 CR    RQE,RAREAUB                                              57600015
         BNE   FQENDTST            UPPER AREA NOT ADJACENT              57630015
         A     RLENGTH,FQELNTH(RQE) COMBINE LENGTH OF FREE AREA AND     57660015
*                                    ADJACENT UPPER FREE AREA           57690015
FQEADV   L     RQE,FQENXT(RQE)     PICK UP NEXT QE ADDRESS              57720015
         LTR   RQE,RQE             IS IT END OF QUEUE                   57750015
         BZ    FQREPAIR            YES - TIE ONTO END OF QUEUE          57780015
*                                   255                                 57810015
* THE HIGH ORDER BYTE OF AN FQE IS ALWAYS ZERO WHEN CORRECT        MP2K 57830018
FCHOVRLP TM    FQENXT(RQE),X'FF'   CHECK IT                        MP2K 57850018
         BNE   BADFQE                                             21016 57870021
         LR    RQEUB,RQE                                                57900015
         A     RQEUB,FQELNTH(RQE)  COMPUTE UPPER BOUND OF FQE AREA      57930015
         CL    RSPID,C252          IS REQUEST FOR SP 252-255            57960015
         BC    11,FQECH2           YES - BYPASS VALIDITY CHECK          57990015
         CR    RPREVQE,RDQE        IS PREVIOUS QE A DQE                 58020015
         BNE   FQECH1              NO                                   58050015
         CR    RQEUB,RWORK6        IS UPPER BOUND OF FQE AREA GREATER   58080015
*                                   THAN DQE UPPER BOUND                58110015
         BC    13,FQECH2           NO                                   58140015
BADFQE   MVI   MSGLEN,X'4C'        SET REASON CODE(2) AND LEN(12) 21016 58143021
         LM    13,14,FQENXT(RQE)                                        58146021
         STM   13,14,ABNDATA                                            58148021
         CLI   SVCBYTE,X'05'       SVC 4, 5, OR A?                21016 58149021
         BL    SPECERR             PROB DETERM DATA OK FOR SVC 04 21016 58152021
         BE    BADFQEX             SVC 5                          21016 58155021
         NI    FREESW,X'FF'-X'08'  SVC A , DUMMY FREESW           21016 58158021
         B     SPECERR                                            21016 58161021
BADFQEX  MVI   MSGLEN,X'50'        SET REASON CODE(2) AND LEN(16) 21016 58164021
         B     SPECERR                                            21016 58175021
OVRLAP   SR    RQEUB,RADDR                                        21016 58180021
         ST    RQEUB,ABNDATA                                      21016 58185021
         MVI   MSGLEN,X'0C'        LENGTH OF VARIABLE DATA        21016 58190021
         B     GERROR10                                           21016 58195021
FQECH1   CR    RQEUB,RPREVQE       IS UPPER BOUND OF FQE AREA LESS      58200015
*                                   THAN ADDRESS OF PREVIOUS FQE        58230015
         BNL   BADFQE              NO - ERROR                     21016 58260021
FQECH2   CR    RQEUB,RADDR                                              58290015
         LA    RERROR,GERRCODE     SET UP ERROR CODE REGISTER      LC0A 58320017
         BH    OVRLAP              ERROR - OVERLAP                21016 58350021
         BL    FQREPAIR            LOWER AREA IS NOT ADJACENT           58380015
         A     RLENGTH,FQELNTH(RQE) COMBINE LENGTH OF ADJACENT FREE     58410015
*                                   AREAS                               58440015
FCOMPRPR ST    RLENGTH,FQELNTH(RQE) COMBINED SIZE IN FQE                58470015
         ST    RQE,FQENXT(RPREVQE) REPAIR QUEUE                         58500015
         SPACE 2                                                        58530015
*        ROUTINE TO DETERMINE WHETHER 2K BLOCKS CAN BE RELEASED         58560015
*        IF 2K BLOCKS CAN BE RELEASED, THIS ROUTINE WILL RESTRUCTURE    58590015
*         THE QUEUES AS NECESSARY AND RELEASE THE BLOCKS TO FBMAP       58620015
*           INPUT REGISTERS                                             58650015
*              RFQE    - ADDRESS OF FQE CONTAINING STORAGE FREED        58680015
*              RLENGTH - LENGTH OF STORAGE DESCRIBED BY FQE             58710015
*              RPREVQE - ADDRESS OF QUEUE ELEMENT PREVIOUS IN QUEUE TO  58740015
*                         FQE CONTAINING STORAGE FREED                  58770015
*              RDQE    - ADDRESS OF DQE CONTAINING STORAGE FREED        58800015
*              RDQEUB  - UPPER BOUND OF STORAGE DESCRIBED BY DQE        58830015
*                         CONTAINING STORAGE FREED                      58860015
*              RPREVDQ - ADDRESS OF DQE PREVIOUS IN QUEUE TO DQE        58890015
*                         CONTAINING STORAGE FREED                      58920015
         SPACE                                                          58950015
*        DETERMINE WHETHER THERE ARE 2K BLOCKS TO BE RELEASED           58980015
         SPACE                                                          59010015
         CL    RSPID,C252          IS IT SQ AREA                        59040015
         BH    FCOMRET             YES - DO NOT RELEASE BLOCK           59070015
         LA    RAREAUB,0(RFQE,RLENGTH) DETERMINE UPPER BOUND OF AREA    59100015
         LA    RWORK1,2047                                              59130015
         LR    RFQRND,RFQE                                              59160015
         LR    RUBRND,RAREAUB                                           59190015
         AR    RFQRND,RWORK1                                            59220015
         OR    RFQRND,RWORK1                                            59250015
         XR    RFQRND,RWORK1       RFQRND CONTAINS FQE ADDR. ROUNDED UP 59280015
*                                   TO NEXT 2K BOUNDARY                 59310015
         OR    RUBRND,RWORK1                                            59340015
         XR    RUBRND,RWORK1       RUBRND CONTAINS UPPER BOUND OF FQE   59370015
*                                   ROUNDED DOWN TO PREVIOUS 2K BOUND.  59400015
         LR    RSIZE,RUBRND                                             59430015
         SR    RSIZE,RFQRND                                             59460015
         BC    NP,FCOMRET          NO 2K BLOCKS TO BE RELEASED          59490015
         SPACE                                                          59520015
*        DETERMINE NUMBER OF 2K BLOCKS TO BE RELEASED, BLOCK NUMBER OF  59550015
*         FIRST BLOCK TO BE RELEASED, THEN TO RELEASE THE BLOCKS TO     59580015
*         THE FBQE QUEUE AND SET THE STORAGE KEYS TO ZERO               59610015
         SPACE                                                          59640015
         ST    RPREVQE,PREVQESV                                         59670015
         LR    RBLOCK,RFQRND                                            59700015
         L     RPQE,TCBPQE(RTCB)   PICK UP ADDRESS OF PQE               59730015
LOOP2    L     RPQE,DUMBWD(RPQE)   PICK UP END OF PQE CHAIN.            59760015
         C     RADDR,PQESTADD(RPQE)  IS CORE IN THIS REGION.            59790015
         BL    LOOP2                 NO. CHECK NEXT PQE.                59820015
         AIF   (&SMF EQ 0).NOTSTCB                                  SMF 59827018
         ST    RTCB,SMFTCBSV           SAVE TCB POINTER             SMF 59834018
.NOTSTCB ANOP                                                       SMF 59841018
         LR    RFQE1,RFQE          SAVE FQE ADDRESS                     59850015
         ST    RAREAUB,AREAUBSV    SAVE AREA UPPER BOUND                59880015
         MVC   FQESAVE(FQNXTFLD),FQEOFSET(RFQE1) SAVE FQE PTR           59910015
FCOMMON3 BAL   RCOMRET1,MRELEASE   RELEASE 2K BLOCKS                    59940015
         SR    RWORK1,RWORK1                                            60000015
         LR    RIN0,RSIZE                                               60030015
         LR    RIN1,RBLOCK                                              60060015
         SRL   RIN0,11             NUMBER OF 2K BLOCKS                  60090015
         BAL   RCOMRET1,MSETKEYS   SET KEYS OF RELEASED BLOCKS TO ZERO  60120015
         L     RAREAUB,AREAUBSV                                         60150015
         SPACE                                                          60180015
*        DETERMINE WHETHER ALL OF SPACE DESCRIBED BY DQE IS FREE AND,   60210015
*         IF SO, TO FREE THE SPACE USED BY THE DQE AND REMOVE THE DQE   60240015
*         FROM THE QUEUE                                                60270015
         SPACE                                                          60300015
         L     RPREVDQ,PREVDQSV    PICK UP ADDRESS OF PREVIOUS DQE      60330015
         L     RDQE,DQENXT(RPREVDQ) PICK UP ADDRESS OF DQE              60360015
         N     RDQE,CLHIBYTE   CLEAR OUT HI ORDER BYTE          SA66492 60365021
         L     RDQESIZ,DQELNTH(RDQE) PICK UP SIZE                       60390015
FDQECMPR CR    RDQESIZ,RSIZE IS STORAGE DESCRIBED BY DQE ALL FREE 20021 60420020
         BNE   DQENDFCH            NO IF TAKEN                          60450015
         MVC   DQENXT+PTROFST(ADRLNTH,RPREVDQ),DQENXT+PTROFST(RDQE)     60480015
*                                  THE ABOVE INSTRUCTION REMOVES THE    60510015
*                                   DQE FROM THE QUEUE                  60540015
         LA    RADDR,0(RDQE)                                            60570015
         LA    RLENGTH,16                                               60600015
         SPACE                                                          60630015
*        FREE SPACE USED FOR DQE                                        60660015
         SPACE                                                          60690015
         AIF   (&TSO NE 1).M138900                                M1389 60700020
FREEDQE  L     RSPQE,SQSBOUND .     LOAD SQS+1 ADDRESS            M1389 60720020
         LA    RSPQE,0(RSPQE) .     ZERO HIGH ORDER BYTE          M1389 60722020
         CR    RADDR,RSPQE .        IS AQE IN SQS                 M1389 60724020
.M138900 ANOP                                                     M1389 60724420
         LA    RSPQE,SQESPQE .      LOAD SQS SPQE                 M1389 60724820
         AIF   (&TSO NE 1).TSO1800                                20021 60726020
         BL    FREEDQE1            YES, USE SQS SPQE              20021 60731020
         BAL   RCOMRET1,GETLSQS    GET LSQS SPQE IF TIME-SHRNG    20021 60732020
FREEDQE1 EQU   *                                                  20021 60733020
.TSO1800 ANOP                                                     20021 60744020
         LA    RSPID,255           INDICATE SUPERVISOR SUBPOOL          60750015
         LA    RERROR,GERRCODE     SET UP ERROR CODE REGISTER      LC0A 60780017
         B     FCOMMON2            FREE SPACE USED FOR DQE              60810015
         SPACE                                                          60840015
*        DETERMINE WHETHER SPACE AT UPPER END OF AREA DESCRIBED BY DQE  60870015
*         IS FREE AND, IF SO, TO CHANGE THE NUMBER OF BLOCKS IN THE DQE 60900015
*         AND TO CHANGE THE LENGTH IN THE FQE                           60930015
         SPACE                                                          60960015
DQENDFCH LR    RSIZE2,RSIZE        SAVE NUMBER OF BLOCKS                60990015
         L     RDQEUB,DQEADDR(RDQE) PICK UP BLOCK ADDRESS               61020015
         AIF   ('&LCS' NE 'Y').LC25                                LC0A 61027017
         LA    RDQEUB,0(RDQEUB)    CLEAR HIERARCHY IDENT           LC0A 61034017
.LC25    ANOP                                                      LC0A 61041017
         AR    RDQEUB,RDQESIZ      UPPER BOUND OF DQE                   61050015
         CR    RDQEUB,RUBRND       IS UPPER END OF AREA DESCRIBED BY    61080015
*                                   DQE FREE                            61110015
         BNE   DQBEGFCH            NO IF TAKEN                          61140015
         L     RDQESIZ,DQELNTH(RDQE) PICK UP NUMBER OF BYTES            61170015
         SR    RDQESIZ,RSIZE2      COMPUTE NUMBER OF BYTES FOR DQE      61200015
         ST    RDQESIZ,DQELNTH(RDQE) CHANGE NUMBER OF BYTES IN DQE      61230015
         SR    RFQRND,RFQE1        DOES PART OF FQE REMAIN              61260015
         BC    NZ,CHNGFQE          YES IF TAKEN                         61290015
         MVC   DQEFQE+PTROFST(ADRLNTH,RDQE),FQESAVE+1                   61320015
*                                  THE ABOVE INSTRUCTION PUTS THE       61350015
*                                   POINTER TO THE NEXT FQE IN THE DQE  61380015
         B     FCOMRET             RETURN - 2K BLOCKS RELEASED          61410015
CHNGFQE  ST    RFQRND,FQELNTH(RFQE1) STORE NEW LENGTH IN FQE            61440015
         B     FCOMRET             RETURN - 2K BLOCKS RELEASED          61470015
         SPACE                                                          61500015
*        DETERMINE WHETHER SPACE AT BEGINNING OF AREA DESCRIBED BY DQE  61530015
*         IS FREE AND, IF SO, TO CHANGE THE NUMBER OF BLOCKS IN THE     61560015
*         DQE, THE BLOCK NUMBER IN THE DQE, AND TO ADJUST THE FQE QUEUE 61590015
         SPACE                                                          61620015
DQBEGFCH L     RPREVQE,PREVQESV                                         61650015
         CR    RDQELB,RFQE1        IS BEGINNING OF AREA DESCRIBED BY    61680015
*                                   DQE FREE                            61710015
         BNE   DQMIDFRE            NO IF TAKEN                          61740015
         L     RDQEBLK,DQEADDR(RDQE) PICK UP BLOCK ADDRESS              61770015
         AR    RDQEBLK,RSIZE2      COMPUTE NEW BLOCK ADDRESS            61800015
         ST    RDQEBLK,DQEADDR(RDQE) CHANGE BLOCK ADDRESS IN DQE        61830015
         L     RDQESIZ,DQELNTH(RDQE) PICK UP NUMBER OF BYTES            61860015
         SR    RDQESIZ,RSIZE2      COMPUTE NUMBER OF BYTES FOR DQE      61890015
         ST    RDQESIZ,DQELNTH(RDQE) CHANGE NUMBER OF BYTES IN DQE      61920015
         SR    RAREAUB,RUBRND      DOES PART OF FQE REMAIN              61950015
         BC    NZ,MOVEFQE          YES IF TAKEN                         61980015
         ST    RAREAUB,FQENXT(RPREVQE) ZERO POINTER IN PREVIOUS FQE.    62010015
*                                       IT IS NOW LAST IN QUEUE         62040015
         B     FCOMRET             RETURN - 2K BLOCKS RELEASED          62070015
MOVEFQE  ST    RUBRND,FQENXT(RPREVQE) CHANGE POINTER IN PREVIOUS FQE TO 62100015
         MVC   FQEOFSET(FQNXTFLD,RUBRND),FQESAVE                        62130015
*                                  THE ABOVE INSTRUCTION MOVES THE FQE  62160015
*                                   TO THE BEGINNING OF THE NEW FREE    62190015
*                                   AREA                                62220015
         ST    RAREAUB,FQELNTH(RUBRND) STORE SIZE IN NEW FQE            62250015
         B     FCOMRET             RETURN - 2K BLOCKS RELEASED          62280015
         SPACE                                                          62310015
*        FREE SPACE IS IN MIDDLE OF AREA DESCRIBED BY DQE.              62340015
         SPACE                                                          62370015
*        THIS SECTION OF CODE GETS STORAGE FOR THE ADDITIONAL DQE       62400015
*         NEEDED, PUTS IT INTO THE DQE QUEUE, PUTS THE NEW NUMBER OF    62430015
*         BLOCKS INTO EACH DQE, AND PUTS THE BLOCK NUMBER INTO THE NEW  62460015
*         DQE                                                           62490015
DQMIDFRE LA    RIN1,16             SIZE FOR DQE                         62520015
         BAL   RCOMRET1,GETMAINB   GET STORAGE FOR NEW DQE              62550015
         MVC   DQENXT+PTROFST(ADRLNTH,RNEWDQE),DQENXT+PTROFST(RDQE)     62580015
*                                  THE ABOVE INSTRUCTION MOVES THE DQE  62610015
*                                   POINTER FROM THE OLD DQE TO THE NEW 62640015
*                                   DQE                                 62670015
         ST    RNEWDQE,DQENXT(RDQE) POINT OLD DQE TO NEW DQE            62700015
         LR    RWORK1,RDQEUB                                            62730015
         SR    RWORK1,RUBRND       COMPUTE SIZE OF AREA DESCRIBED BY    62760015
*                                   NEW DQE                             62790015
         LA    RWORK1,0(RWORK1) .                                A39883 62800020
         ST    RWORK1,DQELNTH(RNEWDQE) PUT SIZE IN DQE                  62820020
         ST    RUBRND,DQEADDR(RNEWDQE) PUT ADDRESS IN DQE               62850015
         AIF   ('&LCS' NE 'Y').LC22                                LC0A 62856017
         MVC   DQEHIID(1,RNEWDQE),DQEHIID(RDQE) INSERT HI ID  BC A50611 62866021
.LC22    ANOP                                                      LC0A 62871017
         LR    RWORK1,RFQRND                                            62880015
         L     RWORK3,DQEADDR(RDQE)                                     62910015
         SR    RWORK1,RWORK3       COMPUTE ADDRESS FOR OLD DQE          62940015
         LA    RWORK1,0(RWORK1) .   CLEAR HI ORDER BYTE          A34874 62950020
         ST    RWORK1,DQELNTH(RDQE) PUT FIRST BYTE ADDRESS IN OLD DQE   62970015
         SPACE                                                          63000015
*        THIS SECTION OF CODE ADJUSTS THE FQE QUEUE FOR THE NEW DQE AND 63030015
*         PUTS THE POINTER TO THE QUEUE INTO THE DQE                    63060015
STNEWFQE L     RWORK1,DQEFQE(RDQE) PICK UP FQE POINTER FROM OLD DQE     63090015
         LA    RWORK1,0(RWORK1)    CLEAR HIGH ORDER BYTE                63120015
         CR    RWORK1,RFQE1                                             63150015
         BH    MVFQEPTR            THE BRANCH WILL BE TAKEN IF A PART   63180015
*                                   OF THE OLD FQE QUEUE LIES WITHIN    63210015
*                                   THE AREA DESCRIBED BY THE NEW DQE.  63240015
*                                   OTHERWISE THE FOLLOWING INSTRUCTION 63270015
*                                   WILL CLEAR THE FQE POINTER FIELD    63300015
*                                   FROM THE NEW DQE                    63330015
         XC    DQEFQE+PTROFST(ADRLNTH,RNEWDQE),DQEFQE+PTROFST(RNEWDQE)  63360015
         B     UPRREMCH                                                 63390015
*                                  IF PART OF THE OLD FQE LIES WITHIN   63420015
*                                   THE AREA DESCRIBED BY THE NEW DQE,  63450015
*                                   IT IS THE BEGINNING OF THE OLD FQE  63480015
*                                   QUEUE AND THE FQE POINTER FROM THE  63510015
*                                   OLD DQE BECOMES THE FQE POINTER FOR 63540015
*                                   THE NEW DQE. THE NEXT INSTRUCTION   63570015
*                                   PUTS THE OLD FQE POINTER INTO THE   63600015
*                                   NEW DQE                             63630015
MVFQEPTR MVC   DQEFQE+PTROFST(ADRLNTH,RNEWDQE),DQEFQE+PTROFST(RDQE)     63660015
*                                  THE NEXT FEW INSTRUCTIONS DETERMINE  63690015
*                                   THE END OF THE FQE QUEUE FOR THE    63720015
*                                   NEW DQE AND COMPLETE THIS QUEUE     63750015
UPRREMCH SR    RAREAUB,RUBRND      IS THERE A REMAINDER OF FREE AREA    63780015
*                                   ABOVE THE 2K BLOCKS BEING FREED     63810015
         BZ    STPREVFQ            NO IF BRANCH TAKEN                   63840015
         XC    FQENXT(FQNXTFLD,RUBRND),FQENXT(RUBRND)            A36201 63900000
*                                      CLEAR NEW FQE PTR        A36201  63930000
         ST    RAREAUB,FQELNTH(RUBRND) .PUT LENGTH IN NEW FQE    A36201 63940000
         CR    RPREVQE,RDQE .           WAS PREV FQE A DQE      A36201  63960000
         BE    FQENEWS .                YES NEW FQE IS FIRST     A36201 63962000
         ST    RUBRND,FQENXT(RPREVQE) . PT PREV FQE TO NEW FQE   A36201 63972000
         B     STOLDFQE .                                        A36201 63980000
FQENEWS  ST    RUBRND,FQENXT(RNEWDQE) . THIS IS FIRST FQE        A36201 63982000
         B     STOLDFQE                                                 63990015
STPREVFQ ST    RAREAUB,FQENXT(RPREVQE) CLEAR POINTER IN PREVIOUS FQE    64020015
*                                       IT IS LAST ONE IN THIS QUEUE    64050015
         SPACE                                                          64080015
*        THIS SECTION OF CODE ADJUSTS THE FQE QUEUE FOR THE OLD DQE AND 64110015
*         PUTS THE POINTER TO THE QUEUE INTO THE DQE                    64140015
STOLDFQE SR    RFQRND,RFQE1        IS THERE A REMAINDER OF FREE AREA    64170015
*                                   BELOW THE 2K BLOCKS BEING FREED     64200015
         BZ    NOLWRREM            NO IF BRANCH TAKEN                   64230015
         ST    RFQRND,FQELNTH(RFQE1) YES - CHANGE LENGTH IN FQE FOR     64260015
*                                    AREA TO SIZE OF THIS REMAINDER     64290015
         ST    RFQE1,DQEFQE(RDQE)  PUT POINTER TO FQE QUEUE IN OLD DQE  64320015
         B     FCOMRET             RETURN - 2K BLOCKS RELEASED          64350015
*                                  IF THERE IS NO LOWER REMAINDER OF    64380015
*                                   FREE AREA, THE NEXT INSTRUCTION     64410015
*                                   WILL PLACE THE POINTER TO THE LOWER 64440015
*                                   PART OF THE OLD FQE QUEUE INTO THE  64470015
*                                   OLD DQE AS THE FQE QUEUE POINTER    64500015
NOLWRREM MVC   DQEFQE+PTROFST(ADRLNTH,RDQE),FQESAVE+PTROFST             64530015
         B     FCOMRET             RETURN - 2K BLOCKS RELEASED          64560015
         SPACE                                                          64590015
*        COMMON RETURN TO MAINLINE                                      64620015
         SPACE                                                          64650015
         AIF   ('&RORI' NE 'Y').GO202                              LC0A 64680017
FCOMRET  LM    RRETURN,RFMRET,FMSAVE  RESTORE REGISTERS                 64710015
         LA    RFMRET,FMRET                                             64740015
         TM    BESW,X'FF'               WAS THIS A BRANCH ENTRY         64770015
         BCR   1,RFMRET   YES, BYPASS ROLLIN                            64800015
         TM    IEAROSW,X'FF'       IS ROLLOUT DATA SET OPEN.            64830015
         BCR   1,RFMRET            NO. BYPASS ROLLIN.                   64860015
         ST    RFMRET,PQERET                                            64890015
         L     FPQEBASE,FRBASEAD   ESTABLISH ADDRESSABILITY -           64920015
         L     RWORK1,FREBRFAD     SET UP ENTRY -                       64950015
         BR    RWORK1              AND TEST FOR ROLLIN CONDITIONS       64980015
FMRET    LM    RRETURN,RFMRET,FMSAVE   RESTORE REGISTERS.               65010015
         XC    ABNDATA(ABNDATAL),ABNDATA CLEAR MSG SWITCHES       21016 65020021
         BR    RFMRET                  RETURN TO CALLER                 65040015
         AGO   .GO203                                                   65070015
.GO202   ANOP                                                           65100015
FCOMRET  LM    RRETURN,RFMRET,FMSAVE  RESTORE REGISTERS                 65130015
         BR    RFMRET              RETURN                               65160015
.GO203   ANOP                                                           65190015
SUBPERR  L     RADDR,0(RADDR)  FREEMAIN ADDRESS                   21016 65196021
         MVI   MSGLEN,X'4C'        REASON CODE(2) AND LENGTH(12)  21016 65202021
         ST    RTCB,ABNDATA         STORE TCB SEARCHED            21016 65208021
         B     GERROR3                                            21016 65214021
         EJECT                                                          65220015
*        ROUTINE TO LOCATE AN FQE EQUAL TO OR LESS THAN A GIVEN ADDRESS 65250015
*           INPUT REGISTERS                                             65280015
*              RDQE   - DQE ADDRESS                                     65310015
*              RWORK1 - GIVEN ADDRESS                                   65340015
*           OUTPUT REGISTERS                                            65370015
*              RQE     - REQUESTED QUEUE ELEMENT ADDRESS                65400015
*              RPREVQE - ADDRESS OF QUEUE ELEMENT PREVIOUS TO REQUESTED 65430015
*                         QUEUE ELEMENT                                 65460015
         SPACE                                                          65490015
QELOCATE LR    RPREVQE,RDQE        SAVE ADDRESS OF PREVIOUS QE          65520015
         L     RQE,FQENXT(RPREVQE) PICK UP QE PTR                       65550015
         LA    RQE,0(RQE)          CLEAR OUT BLOCK NUMBER               65580015
FADVQE   CR    RQE,RAREAUB         IS IT REQUESTED QUEUE ELEMENT  20021 65610020
         BCR   13,RCOMRET1         YES - RETURN                         65640015
         LR    RPREVQE,RQE         SAVE ADDRESS OF PREVIOUS QE          65670015
         TM    FQENXT+3(RPREFQE),7 DOES NEXT FQE SPECIFY DOUBLE WORD    65700015
         BC    7,BADFQE            NO - FQE DESTROYED             21016 65730021
         L     RQE,FQENXT(RPREVQE) PICK UP QE PTR                       65760015
         LA    RQE,0(RQE)          CLEAR HIGH ORDER BYTE (IF DESTROYED  65790015
*                                   BY PROBLEM PROGRAM)                 65820015
         CR    RQE,RPREFQE         IS FQE LESS THAN PREVIOUS FQE        65850015
         BL    FADVQE              YES                                  65880015
         B     BADFQE                                             21016 65910021
         SPACE 2                                                        65940015
*        PART OF ROUTINE TO PUT FREE STORAGE INTO THE QUEUE AND TO      65970015
*         COMBINE ADJOINING FREE AREAS                                  66000015
         SPACE                                                          66030015
*        UPPER AREA NOT ADJACENT                                        66060015
         SPACE                                                          66090015
FQENDTST LTR   RQE,RQE             IS IT END OF QUEUE                   66120015
         BC    7,FCHOVRLP          NO - CHECK FOR OVERLAP               66150015
         SPACE                                                          66180015
*        LOWER AREA NOT ADJACENT                                        66210015
         SPACE                                                          66240015
FQREPAIR ST    RQE,FQENXT(RADDR)   POINTER TO NEXT QE IN NEW FQE        66270015
         LR    RQE,RADDR           QE POINTER TO NEW QE                 66300015
         B     FCOMPRPR            TO COMPLETE REPAIR OF QUEUE          66330015
         SPACE 2                                                        66360015
*        THIS ROUTINE SETS THE STORAGE KEYS OF A NUMBER OF CONSECUTIVE  66390015
*         BLOCKS                                                        66420015
*           INPUT REGISTERS                                             66450015
*              RWORK1 - KEY IN BITS 24 - 27                             66480015
*              RIN0   - NUMBER OF 2K BLOCKS                             66510015
*              RIN1   - ADDRESS OF FIRST 2K BLOCK                       66540015
         SPACE                                                          66570015
MSETKEYS SSK   RWORK1,RIN1         SET STORAGE KEY                      66600015
         LA    RIN1,TWOK(RIN1)     INCREMENT TO NEXT BLOCK              66630015
         BCT   RIN0,MSETKEYS       COUNT DOWN NUMBER OF BLOCKS          66660015
* FREEMAIN NO LONGER DOES SMF PROCESSING DUE TO PTF 00110               66663021
         BR    RCOMRET1            RETURN                               66690015
         SPACE 2                                                        66720015
         EJECT                                                          66750015
*********************************************************************** 66780015
*        SUBROUTINES COMMON TO GETMAIN AND FREEMAIN                     66810015
*********************************************************************** 66840015
         SPACE 2                                                        66870015
*                                                                       66900015
*        SUBROUTINE TO DETERMINE SUBPOOL REQUEST AND TO GET SPQE FOR    66930015
*              REQUESTED SUBPOOL                                        66960015
*           INPUT                                                       66990015
*              RTCB  - TCB OF REQUESTING TASK                           67020015
*              RSPID - SUBPOOL ID REQUESTED                             67050015
*           OUTPUT                                                      67080015
*              RSPQE - SPQE ADDRESS                                     67110015
*              RSPID - IS COMPLEMENTED IF REQUEST IS FOR SP253 OR 254   67140015
*              RLENGTH- IS INCREMENTED BY 8 IF SPID IS 253 OR 254       67170015
CSPCHK   LA    RWORK2,128                                               67200015
         AIF   (&TSO NE 1).TSO2000                                20021 67207020
         MVI   LSQSSW,LSQSOFF          CLEAR LSQS SWITCH          20021 67214020
.TSO2000 ANOP                                                     20021 67221020
         SR    RWORK2,RSPID                                             67230015
         BP    PGETSPQE            PROBLEM PROGRAM SUBPOOL REQUESTED    67260015
*        DETERMINE WHICH SUPERVISOR SUBPOOL IS REQUESTED                67290015
         AIF   (&TSO NE 1).TSO2100                                20021 67295020
         TM    TCBTSFLG(RTCB),TCBTSTSK TIME-SHARING TASK?         20021 67300020
         BZ    *+8                                                20021 67305020
         MVI   LSQSSW,LSQSMSK          YES-SET LSQS SWITCH        20021 67310020
.TSO2100 ANOP                                                     20021 67315020
         LA    RWORK2,243                                         20021 67325020
         SR    RWORK2,RSPID        IS REQUEST FOR A SUPERVISOR          67350015
         LCR   RWORK2,RWORK2        SUBPOOL LESS THAN 243?        20021 67380020
         BM    GERRB               YES - INVALID SUBPOOL          21016 67410021
         SLL   RWORK2,2                                                 67440015
         TM    MODEBYTE,X'F0'      IS REQUESTOR IN KEY OF ZERO          67470015
         BZ    TABLE(RWORK2)       DETERMINE REQUESTED SUBPOOL          67500015
         TM    MODEBYTE,1              IS REQUESTOR IN SUPVR MODE  699  67530015
         BZ    TABLE(RWORK2)           DETERMINE REQUESTED SUBPOOL 699  67560015
GERRB    L     RADDR,0(RADDR)                                     21016 67565021
         MVI   MSGLEN,X'04'       SET REASON CODE(0) AND LENGTH(4)21016 67570021
         CLI   SVCBYTE,X'05'      IS IT SVC 5 ?                   21016 67575021
         BNE   GERROR11           IF NOT SVC 5 MSGLEN = X'04'     21016 67580021
         MVI   MSGLEN,X'08'       FOR SVC 5, MSGLEN = 8           21016 67585021
         B     GERROR11            NOT KEY OF ZERO - ERROR              67590015
         SPACE                                                          67620015
TABLE    B     SP243                                              20021 67630020
         B     SP244                                              20021 67640020
         B     SP245                                              20021 67650020
         B     PART                                               20021 67660020
         B     PART                                                     67680015
         AIF   ('&RORI' NE 'Y').LC13                               LC0A 67688017
         B     PART                                                LC0A 67696017
         AGO   .LC14                                               LC0A 67704017
.LC13    ANOP                                                      LC0A 67712017
         B     GERRB .            INVALID SUBPOOL            BL   M1536 67720021
.LC14    ANOP                                                      LC0A 67728017
         B     GERRB .            INVALID SUBPOOL            BL   M1536 67738021
         B     SP250                                                    67770015
         B     SP251                                                    67800015
         B     SP251                                                    67830015
         B     SP253                                                    67860015
         B     SP254                                                    67890015
         B     SP255                                                    67920015
*                                                                       67922020
SP245    LA    RSPID,10(RSPID)          CHANGE SP NUMBER TO SQS   20021 67924020
SP243    EQU   SP245                                              20021 67926020
SP244    EQU   SP245                                              20021 67928020
         AIF   (&TSO NE 1).TSO2200                                20021 67930020
         MVI   LSQSSW,LSQSOFF          FORCE ALLOCATION FROM SQS  20021 67932020
.TSO2200 ANOP                                                     20021 67934020
         LA    RWORK2,40(RWORK2)       CHANGE BRANCH TABLE DIS-   20021 67936020
*                                      PLACEMENT TO SUBPOOL 253,  20021 67938020
*                                      254, OR 255.               20021 67940020
         B     TABLE(RWORK2)           BRANCH TO PROCESS REQUEST  20021 67942020
*                                                                 20021 67944020
*                                                                       67950015
*        SUBPOOL 250 - SYNONYM FOR SUBPOOL ZERO                         67980015
*                                                                       68010015
SP250    SR    RSPID,RSPID                                              68040015
         B     GETSPQE                                                  68070015
*                                                                       68100015
*        SUPERVISOR REQUEST FOR PP STORAGE - CONVERT TO SP 252          68130015
*                                                                       68160015
SUPVPPSP TM    MODEBYTE,2                                               68190015
         BC    1,GETSPQE                                                68220015
         LA    RSPID,252                                                68250015
*                                                                       68280015
*        SUBPOOL 251 - GET JOB STEP TCB ADDRESS (JOB PACK AREA SUBPOOL) 68310015
*        ALSO SUBPOOL 252 (LINK PACK AREA WITHIN PARTITION)             68340015
*                                                                       68370015
SP251    L     RTCB,TCBJSTCB(RTCB) PICK UP ADDRESS OF JOB STEP TCB      68400015
         B     GETSPQE                                                  68430015
*                                                                       68460015
*        SUBPOOL 254 - GET JOB STEP TCB ADDRESS                         68490015
*                                                                       68520015
SP254    L     RTCB,TCBJSTCB(RTCB) PICK UP ADDRESS OF JOB STEP TCB      68550015
*                                                                       68580015
*        SUBPOOL 253 - COMPLEMENT SPID TO INDICATE AQE NEEDED           68610015
*                                                                       68640015
SP253    LCR   RSPID,RSPID                                              68670015
*                                                                       68700015
*        SUBPOOL 255 - LOAD ADDRESS OF SPQE FOR SUPERVISOR CORE         68730015
*                         (ALSO FOR SP253 AND SP254)                    68760015
SP255    LA    RSPQE,SQESPQE                                            68790015
*                                                                       68790818
*BEFORE RETURNING TO MAINLINE, THIS ROUTINE WILL DETERMINE WHETHER SWS  68791618
*THE TCB READY QUEUE SHOULD BE SCANNED FOR ANY TASKS WHICH ARE     SWS  68792418
*NON-DISPATCHABLE BECAUSE THE 2K LIMIT ON QUEUE SPACE HAD BEEN     SWS  68793218
*REACHED.  IT WILL PROCEED AS FOLLOWS                              SWS  68794018
*DETERMINE IF THE REQUEST IS A FREEMAIN.  AT THIS POINT WE         SWS  68794818
*ALREADY KNOW THAT THE REQUEST PERTAINS TO QUEUE SPACE.            SWS  68795618
*IF THIS IS A REQUEST TO FREE QUEUE SPACE, THE HIGH ORDER BYTE     SWS  68796418
*OF GOB GOVRFLB WILL BE EXAMINED                                   SWS  68797218
*IF THE FLAG IS ZERO, THIS ROUTINE WILL RETURN TO MAINLINE         SWS  68798018
*IF IT IS NON-ZERO, IT MEANS ONE OR MORE TASKS ARE NON-DISPATCHABLESWS  68798818
*BECAUSE OF THE 2K LIMIT ON QUEUE SPACE.  THEREFORE, THIS ROUTINE WILL  68799618
*BALR TO A SUBROUTINE WITHIN GETPART/FREEPART CALLED  DISPINIT     SWS  68800418
*TO MAKE THESE TASKS DISPATCHABLE AND RESET THE FLAG IN GOVRFLB    SWS  68801218
*TO ZERO.                                                          SWS  68802018
*THE  DISPINIT  SUBROUTINE WILL SAVE ALL THE XRS ON ENTRY.         SWS  68802818
         TM    GOVRFLB,X'80'      IS THE TRIGGER SET               SWS  68803618
         BZ    OK                 NO                               SWS  68804418
*        FALL THRU HERE MEANS 2K LIMIT IS IN EFFECT AND ONE OR     SWS  68805218
*        QUEUE SPACE (SVC 10,SVC 5, OR BRANCH ENTRY )              SWS  68806018
*        MORE TASKS ARE NON-DISPATCHABLE.                          SWS  68806818
         CLI   SVCBYTE,4          IS THIS A GETMAIN REQUEST - SVC 4SWS  68807618
         BE    OK                 YES                              SWS  68808418
         LTR   RIN1,RIN1          IS THIS A GETMAIN REQUEST - SVC 1SWS  68809218
         BM    OK                 YES                              SWS  68810018
         AIF   (&TSO NE 1).TSO2250                                20021 68810120
*        FREEMAIN REQUESTS FOR LSQS HAVE NO EFFECT ON SQS.        20021 68810220
         TM    LSQSSW,LSQSMSK                                     20021 68810320
         BO    OK                                                 20021 68810420
.TSO2250 ANOP                                                     20021 68810520
*        FALL THRU HERE MEANS REQUEST IS A FREEMAIN FOR            SWS  68810818
*        AND THE 2K LIMIT IS IN EFFECT.                            SWS  68811618
         LR    RIN15,RCOMRET1     SAVE VOLATILE XRS                SWS  68812418
         LR    RWORK2,RADDR                                        SWS  68813218
         L     RADDR,ADPART       LOAD BASE XR FOR GETPART         SWS  68814018
         L     RCOMRET1,ADDISP    LOAD ADDR FOR BALR               SWS  68814818
         BALR  RCOMRET1,RCOMRET1  LINK TO SUBROUTINE WITHIN GETPARTSWS  68815618
         LR    RADDR,RWORK2       RESTORE VOLATILE XRS             SWS  68816418
         LR    RCOMRET1,RIN15                                      SWS  68817218
OK       DS    0H                                                  SWS  68818018
         AIF   (&TSO NE 1).TSO2300                                20021 68818220
         TM    LSQSSW,LSQSMSK          LSQS REQUESTED?            20021 68818420
         BZ    4(RCOMRET1)             NO-RETURN                  20021 68818620
         L     RSPQE,TCBPQE(RTCB)      YES-LOAD LSQS SPQE         20021 68818820
         L     RSPQE,PQENXT(RSPQE)                                20021 68819020
         L     RSPQE,PQESTADD(RSPQE)                              20021 68819220
.TSO2300 ANOP                                                     20021 68819420
         BC    15,4(RCOMRET1)      RETURN-SPQE FOUND                    68820015
*                                                                       68850015
*        FIND SUBPOOL QUEUE ELEMENT FOR PROBLEM PROGRAM SUBPOOLS        68880015
*              AND FOR SUBPOOL 250 AND 251                              68910015
*              TEMPORARILY FOR SP128 ALSO                         ***** 68940015
*                                                                       68970015
PGETSPQE TM    MODEBYTE,1              IS REQUESTOR IN SUPVR MODE  699  69000015
         BO    GETSPQE                 NO                          699  69030015
         TM    MODEBYTE,X'F0'          IS REQUESTOR IN KEY OF ZERO 699  69060015
         BZ    SUPVPPSP                YES, DETERMINE SUBPOOL      699  69090015
GETSPQE  L     RSPQE,TCBMSS(RTCB)  LOAD FIRST SPQE FOR TASK             69120015
         LA    RSPQE,0(RSPQE)                                           69150015
         AIF   (&TSO NE 1).TSO2350                                20021 69157020
         MVI   LSQSSW,LSQSOFF      NOT LSQS REQUEST. RESET SWTCH  20021 69164020
.TSO2350 ANOP                                                     20021 69171020
         LTR   RSPQE,RSPQE         RETURN NOT FOUND IF           ****** 69180015
         BCR   8,RCOMRET1             SPQE PTR IS ZERO           ****** 69210015
         SR    RWORK2,RWORK2                                            69240015
GETSPQE1 IC    RWORK2,SPQEID(RSPQE)     CHECK IF ID OF SPQE             69270015
         CR    RWORK2,RSPID           IS REQUESTED SPID                 69300015
         BE    GETSPQE2                 YES-BRANCH-CHECK IF SP SHARED   69330015
         TM    SPQEFLGS(RSPQE),SPQELAST IS THIS LAST SPQE               69360015
         BCR   1,RCOMRET1               YES-RETURN-SPQE NOT FOUND       69390015
         L     RSPQE,SPQENXT(RSPQE)     LOAD NEXT SPQE                  69420015
         B     GETSPQE1                                                 69450015
*                                                                       69480015
GETSPQE2 TM    SPQEFLGS(RSPQE),SPQESHRD  IS SUBPOOL SHARED              69510015
         BC    8,4(RCOMRET1)       NO-RETURN-OWNING SPQE FOUND          69540015
         L     RSPQE,SPQEDQE(RSPQE)  LOAD OWNING  SPQE                  69570015
         BC    15,4(RCOMRET1)      RETURN-SPQE FOUND                    69600015
         EJECT                                                          69630015
*        GETMAIN FOR AN MSS QUEUE ELEMENT                               69660015
*           INPUT - RIN1- LENGTH OF REQUEST                             69690015
*           OUTPUT-RIN1- ADDRESS OF ASSIGNED CORE                       69720015
*           REGISTERS USED - RIN1,RIN0,RLENGTH,RSPQE,RCOMRET1,RCOMRET2  69750015
*                                                                       69780015
*                                                                       69810015
GETMAINB STM   RLST,RIN1,SAVREG2                                        69840015
         LR    RLENGTH,RIN1                                             69870015
         L     RMASK,CLHIBYTE                                           69900015
GMBREPET LA    RSPQE,SQESPQE       LOAD SPQE FOR SUPERVISOR             69930015
         AIF   (&TSO NE 1).TSO2400                                20021 69936020
         BAL   RCOMRET1,GETLSQS -  GET LSQS SPQE IF TIME-SHRNG    20021 69942020
NOSQSPC1 LA    RSPID,255 -         SUBPOOL ID FOR MSS QUEUE ELE   20021 69943020
         AGO   .TSO2405                                           20021 69948020
.TSO2400 ANOP                                                     20021 69954020
         LA    RSPID,255 -         SUBPOOL ID FOR MSS QUEUE ELE   20021 69960020
.TSO2405 ANOP                                                     20021 69963020
         AIF   ('&LCS' NE 'Y').LC26                                LC0A 69966017
         MVC   HISAVE(1),HIBYTE    SAVE HIBYTE OVER GETMAINB RTN.  LC0A 69972017
         MVI   HIBYTE,0            RESET HIERARCHY IDENT           LC0A 69978017
.LC26    ANOP                                                      LC0A 69984017
         BAL   RCOMRET1,GFRECORE   SEARCH FOR FREE AREA                 69990015
         B     NOSQSPC2            NOT FOUND                            70020015
         BAL   RCOMRET1,GFQEUPDT   FOUND-REMOVE ASSIGNED CORE FROM FQE  70050015
         LR    RIN1,RFQE           LOAD ADDR OF ASSIGNED AREA           70080015
         BCTR  RLENGTH,0           DECREMENT LENGTH TO CLEAR CORE       70110015
         EX    RLENGTH,CLRCORE     CLEAR QUEUE ELEMENT SPACE            70140015
         LM    RLST,RIN0,SAVREG2                                        70170015
         AIF   ('&LCS' NE 'Y').LC27                                LC0A 70177017
         MVC   HIBYTE(1),HISAVE    RESTORE HIERARCHY IDENT         LC0A 70184017
.LC27    ANOP                                                      LC0A 70191017
         BR    RCOMRET1            RETURN                               70200015
         AIF   (&TSO NE 1).TSO2410                                20021 70210020
NOSQSPC2 TM    LSQSSW,LSQSMSK -    LSQS FAIL                      20021 70221020
         BO    NOSQSPC3 -          YES, CANNOT GET MORE LSQS      20021 70222020
         BAL   RCOMRET1,GNOTSAT3 - ATTEMPT TO GET MORE SQ SPACE   20021 70223020
NOSQSPC3 MVI   LSQSSW,LSQSOFF -    RE SET LSQS SWITCH             20021 70224020
         LA    RSPQE,SQESPQE -     LOAD SPQE FOR SUPERVISOR       20021 70225020
         B     NOSQSPC1 -          REPEAT REQUEST                 20021 70226020
         AGO   .TSO2415                                           20021 70227020
.TSO2410 ANOP                                                     20021 70228020
NOSQSPC2 BAL   RCOMRET1,GNOTSAT3   ATTEMPT TO GET MORE SQ SPACE         70230015
         B     GMBREPET            REPEAT REQUEST                       70260015
.TSO2415 ANOP                                                     20021 70270020
*                                                                       70290015
*                                                                       70320015
CLRCORE  XC    0(0,RIN1),0(RIN1)                                        70350015
         EJECT                                                          70380015
*        ROUND UP REQUESTED LENGTH TO DOUBLE WORD BOUNDRY               70410015
*           INPUT - RLENGTH - REQUESTED LENGTH                          70440015
*           OUTPUT- RLENGTH - ROUNDED LENGTH                            70470015
*           REGISTERS USED - RLENGTH,RWORK2,RCOMRET1                    70500015
*                                                                       70530015
CRNDLNTH LA    RWORK2,7                                                 70560015
         AR    RLENGTH,RWORK2                                           70590015
         OR    RLENGTH,RWORK2                                           70620015
         XR    RLENGTH,RWORK2                                           70650015
         LTR   RSPID,RSPID         IF SUBPOOL 253 IS REQUESTED          70680015
         BCR   11,RCOMRET1                                              70710015
         LA    RLENGTH,8(RLENGTH)  ADD 8 BYTES TO LENGTH FOR AQE        70740015
         BR    RCOMRET1                                                 70770015
         AIF   (&TSO NE 1).TSO2500                                20021 70771020
*                                                                 20021 70772020
*        GET LSQS SPQE IF THE CALLING TASK IS A TIME-SHARING      20021 70773020
*        TASK.                                                    20021 70774020
GETLSQS  L     RSPID,16(0) -       GET TCB ADDRESS                20021 70775020
         L     RSPID,0(RSPID) -    *                              20021 70776020
         L     RSPID,4(RSPID) -    *                              20021 70777020
         TM    TCBTSFLG(RSPID),TCBTSTSK - TIME SHARING TASK       20021 70778020
         BCR   8,RCOMRET1 - (BZ)   NO, RETURN                     20021 70779020
         L     RSPID,TCBPQE(RSPID) GET PQE ADDRESS                20021 70781020
         L     RSPID,PQENXT(RSPID) *                              20021 70782020
         L     RSPQE,PQESTADD(RSPID) GET LSQS SPQE ADDRESS        20021 70783020
         MVI   LSQSSW,LSQSMSK -    SET LSQS SWITCH                20021 70784020
         BR    RCOMRET1 -          RETURN                         20021 70787020
         EJECT                                                    20021 70788020
.TSO2500 ANOP                                                     20021 70789020
*                                                                       70800015
*                                                                       70830015
*                                                                       70860015
*                                                                       70890015
*        INPUT PARAMETERS VALIDITY CHECK ROUTINE                        70920015
*           INPUT - RIN1 -ADDR OF PARAMETER LIST                        70950015
*           OUTPUT- RLENGTH - LENGTH/ADDR OF LENGTH LIST                70980015
*                 - RADDR   - ADDR OF AREA LIST                         71010015
*                                                                       71040015
*                                                                       71070015
IEAQVLCH CSECT                                                          71100015
IPVALCHK BALR  IPVLBASE,0          SET UP BASE REGISTER                 71130015
         USING *,IPVLBASE                                               71160015
         TM    MODEBYTE,X'F0'     IS CALLER IN KEY ZERO                 71190015
         LA    RERROR,GERRCODE     SET UP ERROR CODE REGISTER      LC0A 71220017
         ST   FREBAS,SAVE3BAS .    SAVE ALTERNATE BASE REG        M0550 71240020
         BZ    IPVLRET1                 RETURN                          71250015
         SR    RSPID,RSPID         . CLEAR REG                 @SA78437 71251000
         L     RWORK2,4(RIN1)      . GET ADDRS OF AREA LIST    @SA78437 71252000
         LA    RLENGTH,X'10'       . PUT X'FFFFFFF0' IN        @SA78437 71253000
         LCR   RLENGTH,RLENGTH     . RLENGTH FOR AND OF RWORK2 @SA78437 71254000
         NR    RWORK2,RLENGTH      . ZERO BITS 28-31           @SA78437 71255000
         ISK   RSPID,RWORK2        . GET PROTECT KEY OF PARMADR@SA78437 71256000
         SR    RWORK2,RWORK2       .                           @SA78437 71257000
         IC    RWORK2,MODEBYTE     . GET PROTECT KEY OF TASK   @SA78437 71258000
         NR    RWORK2,RLENGTH      .                           @SA78437 71259000
         CR    RSPID,RWORK2        . PROTECT KEYS MUST MATCH   @SA78437 71260000
         BNE   BADPARM             .                           @SA78437 71261000
         TM    7(RIN1),X'03'       . WORD BOUNDARY CHECK       @SA78437 71262000
         BNZ   BADPARM             .                           @SA78437 71263000
         B     PARMSOK             .                           @SA78437 71264000
BADPARM  EQU   *                                               @SA78437 71265000
         LR    RSPID,RIN1          . GET BAD PARM ADDRESS      @SA78437 71266000
         B     PARMERR             . ERROR GET OUT             @SA78437 71267000
PARMSOK  EQU   *                                               @SA78437 71268000
         LA   RGMRET,PARMERR                                      21016 71280021
         LR    RSPID,RIN1          SAVE INPUT REG                       71310015
         L     RVALBAS,VALIDCHK    ADDRESS OF VALIDITY CHECK RTN.  TS0A 71340016
         L     FREBAS,16(,0) .     PICK UP CVT ADDR               M0550 71350020
         BAL   RVALRET,4(RVALBAS)  CHECK PARAMETER LIST ADDR            71370015
         L     FREBAS,SAVE3BAS .       RESTORE SEC BASE           M2752 71380020
         BCR   7,RGMRET .              RETURN                     M2752 71400020
*                                                                       71430015
         L     RIN1,4(RSPID)       CHECK AREA LIST STARTING ADDRESS     71460015
         AIF   ('&LCS' NE 'Y').LC08                                LC0A 71467017
         LA    RIN1,0(RIN1)        CLEAR HIERARCHY IDENT           LC0A 71474017
.LC08    ANOP                                                      LC0A 71481017
         BAL   RVALRET,TSTALIN    ALIGNMENT & IN MACHINE       @JK69031 71490021
         AIF   ('&LCS' NE 'Y').LC09                                LC0A 71525017
*                                                                  LC0A 71530017
         CLI   HIBYTE,X'01'        Q. IS REQUEST FOR A HIERARCHY   LC0A 71535017
         BH    GERROR12               GREATER THAN 1 - YES - ERROR LC0A 71540017
.LC09    ANOP                                                      LC0A 71545017
*                                                                       71550015
         TM    8(RSPID),X'C0'      IF REQUEST IS FOR A SINGLE AREA      71580015
         BZ    IPVALRET              RETURN                             71610015
         BO    FREEVAR             VARIABLE REQUEST                     71640015
*                                                                       71670015
LENCHK   L     RIN1,0(RSPID)       CHECK LENGTH LIST STARTING ADDRESS   71700015
         BAL   RVALRET,TSTALIN    ALIGNMENT & IN MACHINE       @JK69031 71730021
*                                                                       71790015
         LM    RLENGTH,RADDR,0(RSPID)                                   71820015
         TM    8(RSPID),X'C0'      IF REQUEST IS VARIABLE,              71850015
         BO    IPV1                 CONTINUE                            71880015
         TM    0(RLENGTH),X'80'    IF ENTRY IS NOT LAST ON LIST         71910015
         BZ    IPV1                 CONTINUE                            71940015
         LA    RWORK2,4            LENGTH OF LIST                       71970015
         B     IPVLOVLP            SINGLE ENTRY IN LIST REQUEST         72000015
IPV1     SR    RWORK2,RWORK2                                            72030015
         SPACE                                                          72060015
IPV2     LA    RWORK2,4(RWORK2)    INCREMENT COUNT OF ENTRIES           72090015
*                                                                       72120015
         LA    RIN1,0(RWORK2,RLENGTH)   CHECK LENGTH LIST ENTRY         72150015
         BAL   RVALRET,INMACH      ADDR IN MACHINE             @JK69031 72180021
*                                                                       72240015
         LA    RIN1,0(RWORK2,RADDR)     CHECK AREA LIST ENTRY           72270015
FREEVAR1 EQU   *                                                  M2752 72280020
         L     FREBAS,16(0)  PICK UP THE CVT ADDRESS              20021 72290020
         BALR  RVALRET,RVALBAS                                    20021 72300020
         L     FREBAS,SAVE3BAS .       RESTORE SEC BASE           M2752 72310020
         BCR   7,RGMRET .              RETURN                     M2752 72330020
*                                                                       72360015
         TM    8(RSPID),X'C0'      IF REQUEST IS VARIABLE, ALL ENTRIES  72390015
         BO    IPVALRET            OMIT CHECK FOR OVERLAP FOR VARIABLE  72420015
*                                                                       72450015
         LA    RIN1,0(RWORK2,RLENGTH)                                   72480015
         TM    0(RIN1),X'80'       IF ENTRY IS NOT LAST ON LIST         72510015
         BZ    IPV2                  CHECK NEXT ENTRY                   72540015
         SPACE                                                          72570015
IPVLOVLP SR    RLENGTH,RADDR       GET NUMBER OF BYTES BETWEEN          72600015
         BC    11,IPVL3             STARTING ADDRESSES OF LISTS         72630015
         LCR   RLENGTH,RLENGTH                                          72660015
IPVL3    SR    RLENGTH,RWORK2      GREATER THAN LENGTH OF LIST          72690015
         BNM   IPVALRET                                           21016 72700021
         LR    RLENGTH,RSPID       SET BAD PARM ADDR AS INPUT REG 21016 72710021
         SR    RSPID,RSPID                                        21016 72720021
         MVI   MSGLEN,X'04'        LENGTH OF VARIABLE DATA        21016 72730021
         B     GERROR5             NO - ERROR LISTS OVERLAP       21016 72740021
IPVALRET LR    RIN1,RSPID          RESTORE PARAMETER REG                72750015
IPVLRET1 LM    RLENGTH,RADDR,0(RIN1)    LOAD ADDRS OF LENGTH & AREA LST 72780015
         SR    RSPID,RSPID                                              72810015
         IC    RSPID,SPID(RIN1)    LOAD SUBPOOL ID                      72840015
         STC   RSPID,SPIDSAV .      SAVE SPID                    A32912 72841020
         BR    RCOMRET1            RETURN                               72870015
FREEVAR  LA    RCOMRET1,0(RCOMRET1) CLEAR HIGH ORDER BYTE               72900015
         CLI   SVCBYTE,5           IS IT VARIABLE FREEMAIN              72930015
         BNE   LENCHK              NO - CONTINUE                        72960015
         L     RADDR,4(RSPID)      YES                                  72990015
         LA    RIN1,4(RADDR)       VALIDITY CHECK SECOND ENTRY IN LIST  73020015
         B     FREEVAR1             AND RETURN                          73050015
PARMERR  LR    RLENGTH,RSPID      SET BAD PARM ADDR AS INPUT REG  21016 73054021
         SR    RSPID,RSPID                                        21016 73058021
         MVI   MSGLEN,X'24'     LENGTH AND REASON CODE            21016 73062021
         B     GERROR6                                            21016 73066021
TSTALIN  EX    RIN1,WDTEST         ON FULL WORD BOUNDARY       @JK69031 73070021
         BCR   5,RGMRET            NO                          @JK69031 73073021
INMACH   L     FREBAS,16           GET CVT     M2752           @JK69031 73076021
         LA    RIN1,0(RIN1)                                    @JK69031 73079021
         CL    RIN1,164(FREBAS)    ADDR WITHIN MACHINE         @JK69031 73082021
         L     FREBAS,SAVE3BAS     RESTORE 2ND BASE  M2752     @JK69031 73085021
         BCR   2,RGMRET            NO                          @JK69031 73088021
         BR    RVALRET                                         @JK69031 73091021
SAVE3BAS DC    1F'0'                                              20021 73094021
WDTEST   TM    WORD,X'00'          BOUNDARY ALIGNMENT          @JK69031 73097021
WORD     DC    X'03'                                           @JK69031 73100021
         DROP  IPVLBASE                                                 73103021
IEAQGM00 CSECT                                                          73110015
         SPACE 5                                                        73140015
*        VALIDITY CHECK FQE AND PREVIOUS FQE ADDRESSES                  73170015
*        INPUT - RFQE - ADDRESS OF FQE                                  73200015
*                RPREFQE - ADDRESS OF PREVIOUS FQE                      73230015
*        OUTPUT- NONE                                                   73260015
*        REGISTERS USED -RERROR,RCOMRET2,RVALBAS,RVALRET,RIN1,RFQE,     73290015
*                        RPREFQE,RCVT,RTCB,                             73320015
*                                                                       73350015
*                                                                       73380015
CFQECHK  ST    RDQE,DQESAVE        SAVE DQE ADDRESS ACROSS CFQECHK      73410015
         L     RWORK4,DQEADDR(RDQE) PICK UP BLOCK ADDRESS               73500015
         AIF   ('&LCS' NE 'Y').LC28                                LC0A 73507017
         LA    RWORK4,0(RWORK4)    CLEAR HIERARCHY IDENT           LC0A 73514017
.LC28    ANOP                                                      LC0A 73521017
         L     RWORK6,DQELNTH(RDQE) PICK UP BLOCK SIZE                  73530015
         AR    RWORK6,RWORK4       COMPUTE UPPER BOUND OF DQE AREA      73560015
         LTR   RFQE,RFQE           IS Q ELEMENT ZERO                    73590015
         BZ    FQEZERO             YES - BYPASS FQETEST                 73620015
         CR    RFQE,RWORK4         IS FQE WITHIN DQE BOUNDS             73650015
         BL    BADFQE              NO - FQE QUEUE DESTROYED       21016 73680021
         CR    RFQE,RWORK6                                              73710015
         BNL   BADFQE              NO - FQE QUEUE DESTROYED       21016 73740021
         CLI   4(RFQE),X'00' .          HI-ORDER BYTE VALID   BC A45998 73743021
         BNE   BADFQE .            NO- INVALID FQE (60A)      BL  M1723 73746021
         TM    7(RFQE),X'07' .     BOUNDARY ALIGNMENT OK      BC A45998 73749021
         BC    7,BADFQE .           NO- INVALID FQE (60A)     BL  M1723 73752021
         CLI   0(RFQE),X'00' .     HI ORDER BYTE VALID FOR NEXT         73752621
         BNE   BADFQE .            NO- INVALID FQE                      73753221
         TM    3(RFQE),X'07' .     DOUBLEWORD ALIGNMENT FOR NEXT        73753821
         BC    7,BADFQE .          NO- INVALID FQE                      73754421
         ST    RFQE,RFQESAVE .                                BC A45998 73755021
         A     RFQE,4(RFQE) .      IS FQE LENGTH              BC A45998 73758021
         CR    RFQE,RWORK6 .       WITHIN DQE BOUNDS          BC A45998 73759021
         BH    FQEBAD .            NO LENGTH IS BAD                     73760021
         L     RFQE,RFQESAVE .     RESTORE FQE ADDRESS          SA57395 73761021
         L     RFQE,0(RFQE) .      GET NEXT FQE                         73762021
         LTR   RFQE,RFQE .         IS NEXT ZERO                         73763021
         BZ    NFTHRCHK .          YES                                  73764021
         CR    RFQE,RWORK4 .       IS FQE WITHIN DQE BOUNDS             73765021
         BL    FQEBAD .            NO- INVALID FQE                      73766021
         CR    RFQE,RWORK6                                              73767021
         BNL   FQEBAD .            NO- INVALID FQE                      73768021
NFTHRCHK L     RFQE,RFQESAVE .     RESTORE PREVIOUS POINTER             73769021
*                                                                       73770015
FQEZERO  C     RPREFQE,DQESAVE     IS PREVIOUS QE A DQE                 73800015
         BE    CFQERETN            YES, DO NOT CHECK PREVIOUS QE        73830015
         CR    RPREFQE,RWORK4      IS PREVIOUS FQE WITHIN DQE BOUNDS    73860015
         BL    BADFQE              NO - FQE QUEUE DESTROYED       21016 73890021
         CR    RFQE,RWORK6                                              73920015
         BNL   BADFQE              NO - FQE QUEUE DESTROYED       21016 73950021
CFQERETN L     RDQE,DQESAVE        RESTORE DQE ADDRESS                  73980015
         BR    RCOMRET2            NO ERROR-RETURN                      74010015
FQEBAD   L     RFQE,RFQESAVE .     RESTORE REAL FQE FOR                 74020021
         B     BADFQE .            ABEND                                74030021
         EJECT                                                          74040015
*        RETURN FREE BLOCKS TO QUEUE OF FREE STORAGE FOR PARTITION      74070015
*        RETURN FREE PARTITIONS TO QUEUE OF UNASSIGNED STORAGE          74100015
         SPACE                                                          74130015
*           INPUT - RBLOCK - BLOCK NUMBER OF FIRST BLOCK                74160015
*                   RSIZE  - NUMBER OF BLOCKS                           74190015
*                   RPQE - ADDRESS OF PQE                               74220015
*                   RCOMRET1 - RETURN REG                               74250015
*           REGISTERS USED - RBLOCK,RSIZE,RCOMRET1,RCOMRET3,RFBQE,RPQE, 74280015
*                            RFBQEUB,RDISP1,RPRQE,RMASK1                74310015
         SPACE                                                          74340015
MRELEASE ST    RSIZE,FBQESIZE(RBLOCK) PUT SIZE IN NEW FBQE              74370015
         LA    RDISP1,BCKPTR       SET UP DISPLACEMENT FOR BACK QUEUE   74400015
         LA    RMASK1,X'20'        SET MASK FOR BH                      74430015
         LR    RPRQE,RPQE          INITIALIZE RPRQE                     74460015
         BAL   RCOMRET3,MRELEAS1   TO ADJUST BACK POINTERS              74490015
         SR    RDISP1,RDISP1       SET UP DISPLACEMENT FOR FORWARD Q    74520015
         LA    RMASK1,X'40'        SET MASK FOR BL                      74550015
         LR    RPRQE,RPQE          INITIALIZE RPRQE                     74580015
         BAL   RCOMRET3,MRELEAS1   TO ADJUST FORWARD POINTERS           74610015
         LR    RBLOCK2,RBLOCK                                           74640015
         CR    RPQE,RPRQE          IS PREVIOUS PTR POINTING TO PQE      74670015
         BE    MRELADV             YES - NEW BLOCK IS FIRST IN QUEUE    74700015
         BAL   RCOMRET3,MRELCOMB   TO COMBINE NEW BLOCK AND PREVIOUS    74730015
*                                   BLOCK IF POSSIBLE                   74760015
MRELADV  LR    RPRQE,RBLOCK        ADVANCE ALL BLOCK POINTERS           74790015
         LR    RBLOCK2,RFBQE                                            74820015
         L     RFBQE,FWDPTR(RFBQE)                                      74850015
         BAL   RCOMRET3,MRELCOMB   TO COMBINE NEW BLOCK AND NEXT BLOCK  74880015
*                                   IF POSSIBLE                         74910015
         BR    RCOMRET1                 RETURN                          74940015
         BR    RCOMRET1                 RETURN                          74950015
         SPACE                                                          74970015
*        THIS CODE ELIMINATES FORWARD OR BACK POINTER FROM QUEUE        75000015
*        ACCORDING TO SETTING OF RDISP1 AND RMASK                       75030015
         SPACE                                                          75060015
MRELEAS2 LR    RPRQE,RFBQE         ADVANCE PTR TO PREVIOUS BLOCK        75090015
MRELEAS1 L     RFBQE,0(RPRQE,RDISP1) ADVANCE PTR TO FOLLOWING BLOCK     75120015
         CR    RFBQE,RPQE          DOES NEW BLOCK BELONG ON END OF Q    75150015
         BE    MRELENDQ            YES                                  75180015
         CR    RFBQE,RBLOCK        IS THIS BLOCK WHICH FOLLOWS NEW BLK  75210015
         EX    RMASK1,MRELBR       NO - ADVANCE PTRS                    75240015
MRELBR   BC    0,MRELEAS2          NO - ADVANCE PTRS                    75270015
MRELENDQ ST    RFBQE,0(RBLOCK,RDISP1) POINT NEW BLOCK TO FOLLOWING BLK  75300015
         ST    RBLOCK,0(RPRQE,RDISP1) POINT PREVIOUS BLOCK TO NEW BLOCK 75330015
         BR    RCOMRET3            RETURN TO MRELEASE MAINLINE          75360015
         SPACE                                                          75390015
*        THIS CODE CHECKS WHETHER TWO ADJACENT FREE AREAS ARE           75420015
*        CONTIGUOUS AND IF SO, COMBINES THEM AND ELIMINATES THE SECOND  75450015
*        FBQE FROM THE QUEUE                                            75480015
         SPACE                                                          75510015
MRELCOMB L     RSIZE3,FBQESIZE(RPRQE) COMPUTE UPPER BOUND OF PREVIOUS   75540015
         LR    RFBQEUB,RPRQE           BLOCK                            75570015
         AR    RFBQEUB,RSIZE3                                           75600015
         CR    RFBQEUB,RBLOCK2     ARE BLOCKS ADJACENT                  75630015
         BCR   7,RCOMRET3          NO - RETURN TO MRELEASE MAINLINE     75660015
         A     RSIZE3,FBQESIZE(RBLOCK2) COMPUTE COMBINED SIZE OF BLOCKS 75690015
         ST    RSIZE3,FBQESIZE(RPRQE) PUT SIZE IN COMBINED FBQE         75720015
         ST    RFBQE,FWDPTR(RPRQE) PUT PTR TO NEXT FBQE IN COMBINED QE  75750015
         ST    RPRQE,BCKPTR(RFBQE) PUT BACK PTR TO NEW BLK IN NEXT BLK  75780015
         B     2(RCOMRET3)              RETURN TO MRELEASE MAINLINE     75810015
         EJECT                                                          75840015
PART     EQU   *                                                  20021 75842020
         AIF   (&TSO NE 1).TSO2510                                20021 75844020
*        A GETPART OR FREEPART FOR A TIME-SHARING TASK IS         20021 75846020
*        INVALID.                                                 20021 75848020
         TM    TCBTSFLG(RTCB),TCBTSTSK  TIME-SHARING TASK?        20021 75850020
         BZ    NOTSPART           NO. CONTINUE                    20021 75852020
         SR    RIN15,RIN15        CLEAR RETURN REGISTER.          20021 75854020
         BR    RRETURN            RETURN TO CALLER.               20021 75856020
NOTSPART EQU   *                                                  20021 75858020
.TSO2510 ANOP                                                     20021 75860020
         L     RBASE1,PARTADDR                                          75880020
         BR    RBASE1              BRANCH TO GET-FREE PARTITION MODULE  75900015
*********************************************************************** 75930015
*                        JOB PACK PURGE ROUTINE                       * 75960015
*********************************************************************** 75990015
         SPACE                                                          76020015
*           INPUT - NONE                                                76050015
*           OUTPUT - NONE                                               76080015
         SPACE 2                                                        76110015
CDPURGE  STM   0,15,SAVEAREA       SAVE REGISTERS                       76140015
         SR    RSWITCH,RSWITCH     INITIALIZE SWITCH                    76170015
         L     RTCB,TCBJSTCB(RTCB) PICK UP ADDRESS OF JOB STEP TCB      76200015
         TM    TCBJPQ(RTCB),X'80'  IS PURGE FLAG IN TCB SET             76230015
         BC    8,CDRETURN          NO - RETURN                          76260015
         MVI   TCBJPQ(RTCB),X'00'  CLEAR PURGE FLAG                     76290015
         L     RCDE,TCBJPQ(RTCB)   GET ADDRESS OF CDE PTR               76320015
CDNEXT   LA    RCDE,0(RCDE)        CLEAR HIGH ORDER BYTE                76350015
         LTR   RCDEIN,RCDE         ANY MORE ENTRIES                     76380015
         BC    8,CDRETURN          NO - RETURN - PURGE COMPLETE         76410015
CDNEXT1  L     RCDE,0(RCDE)        LOAD ADDR OF CD ENTRY                76440015
         LA    RCDE,0(RCDE)                                             76470015
         LTR   RCDE,RCDE           ANY MORE ENTRIES                     76500015
         BZ    CDREL               NO                                   76530015
         TM    CDATTR(RCDE),MIN    IS IT MINOR                          76560015
         BO    CDNEXT1             YES                                  76590015
CDREL    TM    CDATTR2(RCDEIN),REL CAN LOAD MODULE BE RELEASED          76620015
         BZ    CDNEXT              NO - CHECK NEXT ENTRY                76650015
         L     REXBAS,XCDEXBAS     SET UP BASE ADDRESS FOR CDDESTRY     76680015
         L     RRET1,XCDDSTRY      SET UP ENTRY POINT TO CDDESTRY       76710015
         LA    RSWITCH,4           INDICATE STORAGE FREED               76740015
         BALR  RRET1,RRET1         TO CDDESTRY                          76770015
         BALR  RBASE,0                                                  76800015
         USING *,RBASE                                                  76830015
         L     RBASE,MSSADR2                                      21016 76860021
         USING MSSBASE,RBASE                                            76890015
         B     CDNEXT              CHECK NEXT ENTRY                     76920015
CDRETURN LTR   RSWITCH,RSWITCH                                          76950015
         LM    0,15,SAVEAREA                                            76980015
         BZ    4(RRET)             IF NO STORAGE HAS BEEN FREED         77010015
         BR    RRET                IF STORAGE HAS BEEN FREED            77040015
RFQESAVE DC    F'0' .                                         BC A45998 77045021
MSSADR2  DC    A(MSSBASE)                                         21016 77050021
         EJECT                                                          77070015
*        ERROR EXITS - TERMINATE REQUESTING TASK                        77100015
*                                                                       77130015
         AIF   (&TSO NE 1).TSO2600                                20021 77136020
GERROR1  BCTR  RERROR,0 -          TASK OUT OF LSQS               20021 77142020
NOTUSED  BCTR  RERROR,0 -                                         20021 77148020
.TSO2600 ANOP                                                     20021 77154020
GERROR3  BCTR  RERROR,0            STORAGE NOT IN SPECIFIED SUBPOOL     77160015
GERROR4  BCTR  RERROR,0            PP ATTEMPTING TO FREE ALL OF SP 0    77190015
GERROR5  BCTR  RERROR,0            LENGTH LIST AND ADDRESS LIST HAVE    77220015
*                                   COMMON LOCATIONS                    77250015
GERROR6  BCTR  RERROR,0            PARAMETER LIST OR FQE NOT IN PP AREA 77280015
*                                 OR INPUT LIST ADDRS NOT ON WORD BNDRY 77310015
         BCTR  RERROR,0                                                 77340015
GERROR8  BCTR  RERROR,0            CORE UNAVAILABLE - UNCONDITIONAL     77370015
*                                   REQUEST                             77400015
GERROR9  BCTR  RERROR,0            ADDR TO FREE NOT A MULTIPLE OF 8     77430015
GERROR10 BCTR  RERROR,0            AREA BEING FREED OVERLAPS A FREEAREA 77460015
GERROR11 BCTR  RERROR,0            PROB. PROG. REQUESTS SP 128-255 LC0A 77480017
GERROR12 BCTR  RERROR,0            GENERAL LCS GM ERROR CODE       LC0A 77488017
GERROR13 LR    RIN1,RERROR         TCBAQE FIELD IS ZERO            8098 77496017
*                                  INDICATES A REQUEST TO FREE SQS 8098 77504017
*                                  NOT OWNED BY REQUESTING TASK    8098 77512017
H8       EQU   *+2                                                      77516021
         SLL   RIN1,8                                                   77520015
         IC    RIN1,SVCBYTE                                             77550015
ERRF11   DS    0H                                                 21016 77550521
         L     RRETURN,SVCXT .    SET UP RETURN TO SVCXT          21016 77551021
         L     RABTERM,ABTERM                                     21016 77551521
         L     RWORK3,16(0)             GET CVT ADDR              21016 77552021
         L     RTCB,0(RWORK3)           GET OLD NEW               21016 77552521
         L     RTCB,4(RTCB)        ABTERM CURRENT TASK            21016 77553021
*                                                                       77553521
         C     RIN1,WAIT+4             E04 ABEND                  21016 77554021
         BE    ERRMSGX     YES, DO NOT BUILD INFO LIST            21016 77554521
         L     RIN15,CVTABEND(RWORK3) ADDR OF SECONDARY CVT(SCVT) 21016 77557621
         TM    SCVTFMSA(RIN15),SCVTSW1  CONDITIONAL FREEMAIN ?    21016 77557921
         BO    ERRMSGX             YES. BYPASS.                   21016 77558221
         L     RIN15,CVTQMSG(RWORK3) ADDR OF INFOLIST             21016 77558521
         L     RWORK3,0(RIN15)       ADDR END OF LIST             21016 77559021
         LA    RIN15,4(RIN15)        ADDR OF 1ST ENTRY            21016 77559521
         SR    RWORK2,RWORK2         ZERO REG FOR COMPARE         21016 77560021
         AIF   ('&RORI' NE 'Y').GOR21K                            M3872 77562020
         XC    PQESTAT(6),PQESTAT .  TURN OFF SW FOR EXIT       A36468  77564000
.GOR21K  ANOP                                                     M3872 77566020
         USING INFOLIST,RIN15                                     21016 77574021
ERRMSG1  CR    RIN15,RWORK3       ANY MORE ENTRIES TO SEARCH?     21016 77582021
         BE    ERRMSGX            NO. BYPASS SETTING INFO         21016 77590021
         C     RWORK2,INFTCB      THIS ENTRY AVAILABLE?           21016 77598021
         BE    ERRMSG2            YES. SET UP ENTRIES.            21016 77606021
         LA    RIN15,INFLEN(RIN15) NEXT ENTRY.                    21016 77614021
         B     ERRMSG1            CHECK NEXT.                     21016 77622021
*                                                                 21016 77630021
ERRMSG2  ST    RTCB,INFTCB        STORE TCB ADDRRESS              21016 77638021
         AIF   (&TSO NE 1).TSONOID                               A49808 77640021
         TM    TCBTSFLG(RTCB),TCBTSTSK  IS THIS TSO TASK?        A49808 77642021
         BZ    ERRM2              NO,BYPASS USER ID              A49808 77644021
         L     RWORK3,TCBJSCB(RTCB) GET ADDR JSCB                A49808 77644421
         LA    RWORK3,0(RWORK3) CLEAR HIGH BYTE                  A49808 77644821
         MVC   INFTJID(2),JSCBTJID(RWORK3) PUT USERID IN INFOLISTA49808 77645221
.TSONOID ANOP                                                    A49808 77645621
ERRM2    TM    BESW,X'FF'    IS THIS BRANCH ENTRY ?              A49808 77646021
         BZ    SVCENTR       MOVE VARIABLE DATA SWITCH            21016 77654021
         OI    INFFLG,INFFLG0        SET BRANCH ENTRY SW          21016 77662021
         MVC   INFBADDR(4),BRNREG       STORE RETURN ADDRESS      21016 77670021
SVCENTR  STH   RIN1,INFCC         STORE ABEND CODE                21016 77678021
         LTR   RSPID,RSPID        IS THIS SUBPOOL 253 OR 254 ?    21016 77678521
         BC    NN,ERRMSG2A        NO. CONTINUE                    21016 77679021
         LCR   RSPID,RSPID        YES. SUBPOOL WAS COMPLIMENTED.  21016 77679521
         SH    RLENGTH,H8         - LENGTH INCLUDES 8 BYTE AQE    21016 77680021
         AH    RADDR,H8           - RADDR WAS ADDR OF AQE.        21016 77680521
         CH    RIN1,H60A          CC '60A' OR '80A'?              21016 77681021
         BL    ERRMSG2A           NO.                             21016 77681521
         CH    RIN1,H80A          CC '60A' OR '80A'?              21016 77682021
         BH    ERRMSG2A           NO.                             21016 77682521
         L     RWORK3,ABNDATA     YES.                            21016 77683021
         AH    RWORK3,H8          ADDR OF AREA MUST BE INCRE-     21016 77683521
         ST    RWORK3,ABNDATA       MENTED BY LENGTH OF AQE.      21016 77684021
ERRMSG2A EQU   *                                                  21016 77684521
         ST    RLENGTH,INFVAR1    ROUNDED LENGTH                  21016 77686021
         STC   RSPID,INFVAR1      STORE SUBPOOL                   21016 77694021
         TM    FREESW,X'08'           IS THIS A FREEMAIN          21016 77702021
         BO    FREE                                               21016 77710021
         MVC   INFVAR2(8),ABNDATA       VARIABLE DATA             21016 77718021
         B     ERRMSG3                                            21016 77726021
FREE     MVC   INFVAR3(8),ABNDATA                                 21016 77734021
         ST    RADDR,INFVAR2                                      21016 77742021
ERRMSG3  MVC   INFRCL(1),MSGLEN   SET REASON CODE AND LENGTH      21016 77750021
ERRMSGX  XC    ABNDATA(ABNDATAL),ABNDATA   CLEAR LIST AND SW      21016 77758021
         L     CVTREG,16(0)                                       21016 77766021
         BR    RABTERM                                            21016 77774021
         EJECT                                                    21016 77782021
BESW     DC    X'00'                                              21016 77790021
ORGLRG   DC    F'0'               LARGEST FREECORE IN OWNED REGION21016 77798021
         AIF   ('&RORI' NE 'Y').GO40                               LC0A 77820017
IEAROSW  DC    X'00'               RO/RI DATA SET SWITCH                77850015
PQESTAT  DC    X'00'              PQE INTERROGATION SWITCH              77880015
ENTRANT  DC    X'00'              ENTRY TYPE SWITCH                     77910015
CDPRGSW  DC    X'00'              AREA HAS BEEN PURGED SUCCESSFULLY SW  77940015
PQERET   DC    F'0'                                                     78000015
.GO40    ANOP                                                           78030015
         AIF   (&TSO NE 1).TSO2700                                20021 78031020
**************TS DATA**********                                   20021 78032020
TCBRBP   EQU   0 -                 RB ADDRS IN TCB                20021 78033020
TCBFLG1  EQU   29 -                TCB FLAGS BYTE 1               20021 78034020
TCBFLG2  EQU   30 -                STATUS FLAGS IN TCB            20021 78035020
TCBFLG3  EQU   31 -                TCB FLAGS BYTE 3               20021 78036020
TCBTSFLG EQU   148 -               TCB TIME-SHARING FLAGS         20021 78036120
TCBSTAE  EQU   160 -               TCB STAE FLAGS                 20021 78036220
TCBFA    EQU   X'80' -             ABEND IN PROGRESS BIT          20021 78037020
TCBMC    EQU   X'18' -             SET COMPLETE BITS              20021 78038020
TCBABTRM EQU   X'20' -             TASK ABTERM BIT                20021 78039020
TCBTSTSK EQU   X'80' -             TIME SHARING TASK BIT          20021 78042020
TCBSTABE EQU   X'80' -             STAE EXIT BIT                  20021 78043120
LSQSMSK  EQU   X'FF' -             MASK FOR TESTING LSQS SWITCH   20021 78044020
LSQSOFF  EQU   X'00' -             MASK FOR RESETTING LSQS SWTCH  20021 78045020
LSQSSW   DC    X'00' -             LSQS SWITCH                    20021 78046020
ABENDMSK DC    C'ABEND' .           MASK TO TEST FOR ABEND SVRB   M3872 78047020
RBEXSAVE EQU   X'60'  .            BEGIN OF EXSAVE AREA           M3872 78047420
DISP     EQU   X'28' .             DISP INTO EXT SAVE -ABEND SVRB-M3872 78047820
L5       EQU   5 .                 LENGTH OF FIVE                 M3872 78047920
RBABOPSW EQU   4 -                 NAME FIELD IN SVRB             20021 78048020
RBSTAB   EQU   10 -                STATUS FLAGS IN RB             20021 78049020
TCBJSCB  EQU   X'B4'   DISPLACEMT OF JSCB IN TCB                 A49808 78049421
JSCBTJID EQU   X'10C'  DISPLACEMT OF USERID IN JSCB              A49808 78049821
*******************************                                   20021 78050020
.TSO2700 ANOP                                                     20021 78051020
MODEBYTE DC    X'00'               KEY INDICATION                       78060015
SVCBYTE  DC    X'00'               SVC INDICATION                       78090015
         AIF   ('&LCS' NE 'Y').LC10                                LC0A 78094017
HIBYTE   DC    X'00'               HIERARCHY IDENT SAVE AREA       LC0A 78098017
HISAVE   DC    X'00'               HIERARCHY SAVE AREA             LC0A 78102017
         DS    0F                                                  LC0A 78106017
HIMASK   DC    X'80D3C3E3'         HIERARCHY 1 IDENT - R-FORM      LC0A 78110017
.LC10    ANOP                                                      LC0A 78114017
*******************************************************************LC0A 78125017
*                                 GOVRFLB                         *LC0A 78130017
*******************************************************************LC0A 78135017
         DS    0D                                                 M2279 78137020
GOVRFLB  DS    0CL28                                             A36186 78140020
SQSBOUND DC    F'0'                UPPER BOUND OF SQS              LC0A 78145017
DQESQES  DC    F'0'                ADDR. OF DQE DESCRIBING SQS     LC0A 78150017
PQEPTR   DC    F'0'                PQE ADDR. DESCRIBING DYN. CORE  LC0A 78155017
SZDPRS   DC    F'0'                SIZE OF DYNAMIC PROC. STORAGE   LC0A 78160017
SZDLCS   DC    F'0'                SIZE OF DYNAMIC LCS STORAGE     LC0A 78165017
VQEPTR   DC    F'0'                VARY QUEUE ELEM. LIST ORIG. PTR MP65 78170017
NIPSQSBD DC    F'0'                SQS BOUNDARY FOR NIP & RORI   A36186 78172020
*******************************************************************LC0A 78175017
RECURSE  DC    F'0'                                                     78180015
SVCXT    DC    A(IEA0XE00)                                              78210015
MSCEDADD DC    A(IEAMSTCB)                                              78240015
ABTERM   DC    A(IEA0AB01)                                              78270015
VALIDCHK DC    V(IEA0VL01)                                         TS0A 78280016
C246     DC    H'246'                                                   78330015
C248     DC    H'248'                                                   78360015
C252     DC    A(252)                                                   78390015
         AIF   (&TSO NE 1).TSO2750                                20021 78397020
C254     DC    A(254)                                             20021 78404020
.TSO2750 ANOP                                                     20021 78411020
C255     DC    A(255)                                                   78420015
SPIDSAV  DC    X'00' .             SAVE AREA FOR SUBPOLL ID      A32912 78425020
@SPSAVE  DC    H'0'                SUBPOOL ID SAVE AREA        @AS76397 78427000
KTWO     DC    H'2048' .                                         A31213 78430020
K4080    DC    F'4080' .                                         A31213 78435020
FBQESIZ  DC    F'0' .              SAVE AREA FOR LARGEST FBQE    A31213 78440020
FQESIZ   DC    F'0' .              SAVE AREA FOR LARGEST FQE     A31213 78445020
         AIF   ('&RORI' NE 'Y').GOR3                               LC0A 78450017
FRBASEAD DC    V(FRBRBASE)                                              78480015
FREPQEAD DC    V(IEAFRPQE)                                              78510015
GNSAT4AD DC    V(GNOTSAT4)                                              78520017
ROTST5AD DC    V(ROTEST5)                                               78530017
TESTROAD DC    V(TESTRO)                                                78540017
VARUNCAD DC    V(VARUNCD)                                               78550017
FREBRFAD DC    V(FREBRF)                                                78570015
BASEHOLD DS    2F                                                       78600015
.GOR3    ANOP                                                           78630015
XCDEXBAS DC    A(CDHKEEP+2)                                             78660015
XCDDSTRY DC    A(CDDESTRY)                                              78690015
PARTADDR DC    V(IEAQPRT0)                                              78720015
IPVAL    DC    A(IEAQVLCH)                                              78750015
         AIF   ('&MPS' NE 'Y').MP0318                              MP2K 78752018
ENPTMP2K DC    A(IEAMP2K)       ENTRY POINT TO THE MP CSECT        MP2K 78754018
.MP0318  ANOP                                                      SMF  78756018
         AIF   (&SMF EQ 0).FMCOMG                                   SMF 78758018
GMSMFAD  DC    A(GMSMFCRE)             ADDRESS OF GM CORE PROCESSOR SMF 78760018
         ENTRY SMFTCBSV                                             SMF 78764018
SMFTCBSV DC    F'0'                    TCB POINTER SAVE AREA        SMF 78766018
SMFPQESV DC    F'0'                    PQE POINTER SAVE AREA        SMF 78770018
.FMCOMG  ANOP                                                       SMF 78772018
ABNDATA  DC    2F'0'                                              21016 78802021
BRNREG   DC     F'0'                                              21016 78832021
MSGLEN   DC    X'00'                                              21016 78862021
FREESW   DC    X'00'                                              21016 78892021
ABNDATAL EQU   (*-ABNDATA)                                        21016 78922021
H60A     DC    X'060A'                                            21016 78932021
H80A     DC    X'080A'                                            21016 78942021
         SPACE                                                    21016 78952021
PREVDQSV DS    F                                                        79020015
AREAUBSV DS    F                                                        79050015
PREVQESV DS    F                                                        79080015
DQESAVE  DS    F                                                        79110015
FQESAVE  DS    F                                                        79140015
RREGSAVE DS    F                                                  20021 79150020
         SPACE 2                                                        79170015
TCBFRA   EQU   29                  DISPATCHABILITY BIT                  79200015
CVTPTR   EQU   16                                                 21014 79210021
CVTTCB   EQU   0                                                        79230015
LSTREG   EQU   28                                                ****** 79290015
CVTPURG  EQU   260      CVT PTR TO SUBSYSTEM PURGE ROUTINE        21014 79350021
SQESPQE  EQU   GOVRFLB                                                  79410015
GERRCODE EQU   X'0D'               BASIC ERROR CODE                8098 79420017
         SPACE 2                                                  20021 79426020
*        WAIT STATE PSW - DIASTER CONDITION                       20021 79432020
         SPACE                                                    20021 79438020
         DS    0D                                                 20021 79444020
WAIT     DC    X'00020000'         WAIT STATE PSW              @SA78255 79450000
         DC    X'00000E04'                                        20021 79456020
REQSIZE  DS    1F                  SAVE AREA FOR SIZE OF SQS      20021 79462020
*                                  REQUEST                        20021 79469020
ADPART   DC    A(IEAQPRT0+2)       BASE ADDRESS OD GETPART        20021 79476020
ADDISP   DC    A(DISPINIT)         ARRR OF RTN WITHIN GETPART     20021 79483020
       EJECT                                                      20021 79490020
         DS    0F                                                 20021 79500020
SAVSIX1  DC    1F'0'                                              20021 79510020
SAVSIX2  DC    1F'0'                                              20021 79520020
         AIF   (&SMF EQ 0).EQCOMA                                   SMF 79533618
         EJECT                                                      SMF 79534218
********************************************************************SMF 79534818
*                                                                   SMF 79535418
**************  SMF GETMAIN ROUTINE                           CH A45474 79536021
*                                                                   SMF 79536618
********************************************************************SMF 79537218
         SPACE 2                                                    SMF 79537818
*          INPUT - INITIALIZED CORE USED FIELDS IN TCT.             SMF 79538418
*                  FIELDS ARE INITIALIZED BY SCHEDULAR.             SMF 79539018
*                  REGS:RWPQE=PQE ADDR,RBLOCK=ADDR ALLOC CORE,CH A45474 79539221
*                  RSIZE=NUMBER BYTES ALLOCATED.              CH A45474 79539421
*                                                                   SMF 79539618
*          OUTPUT - MODIFIED CORE USED FIELDS IN TCT.               SMF 79540218
*                                                             CH A45474 79540821
*        FUNCTION-                                            CH A45474 79541821
*                                                             CH A45474 79542821
*        DETERMINE IF THERE IS A TCT ASSOCIATED WITH THIS REQUEST.  SMF 79543818
*        DETERMINE IF MAIN OR LCS CORE.                             SMF 79544418
*        DETERMINE WHEATHER REGION CORE OR BORROWED CORE.           SMF 79545018
*              UPDATE WATER MARKS IF NECESSARY.               CH A45474 79545621
*              HWM=LOWEST ADDR FROM HIGH END OF REGION.       CH A45474 79546321
*              LWM=HIGHEST ADDR FROM LOW END OF REGION.       CH A45474 79547021
*              HWM AND LWM MAY OVERLAP                        CH A45474 79547721
*              TCTMINC= LARGEST FBQE (IN 2K BLOCKS)NOT USED   CH A45474 79548421
*              BY JOB.                                        CH A45474 79549121
         SPACE 1                                                    SMF 79549818
IEASMFGF CSECT                                                      SMF 79550418
         ENTRY GMSMFCRE                                             SMF 79551018
GMSMFCRE BALR  GMSMFB,0                                             SMF 79552218
         USING *,GMSMFB                                             SMF 79552818
         STM   10,12,GFSMFSVE          SAVE WORK REGISTERS          SMF 79553418
         TM    TCBTCT(RTCB),TCBTCTGF . SHOULD TCT BE UPDATED  BC A32900 79553800
         BZ    RCEXIT .            BRANCH IF NO               BC A32900 79553921
         L     RTCT,TCBTCT(RTCB)       GET TCT POINTER              SMF 79554018
         LA    RTCT,0(RTCT)                                         SMF 79554618
         LTR   RTCT,RTCT               IS THERE A TCT               SMF 79555218
         BZ    RCEXIT                  BRANCH IF NO                 SMF 79555818
         L     RCORE,TCTCRTBL(RTCT)   INITIALIZE TCT CORE AREA PTR  SMF 79556418
         AIF   ('&LCS' NE 'Y').GMCOMB                               SMF 79557018
         CLI   PQEHIID(RWPQE),X'01'    TEST FOR LCS                 SMF 79557618
         BNE   NOLCS                   BRANCH IF NOT LCS            SMF 79558218
         LA    RCORE,TCTCSZE(RCORE)    STEP POINTER TO LCS AREA     SMF 79558818
NOLCS    NOP   *                                                   SSMF 79558918
.GMCOMB  ANOP                                                       SMF 79559418
         AIF   ('&RORI' NE 'Y').GMCOMC                              SMF 79560018
         TM    RORIFLG(RWPQE),RGNSHRD  IS IT SHARED CORE           SSMF 79560618
         BZ    NOSHRE                  BRANCH IF NOT SHARED         SMF 79561218
         LR    RCWRK,RSIZE             GET CURRENT BORROWED CORE    SMF 79561818
         SRL   RCWRK,DIV2048           DEVELOP NUMBER OF 2K BLOCKS  SMF 79562418
         AH    RCWRK,TCTRBC(RCORE)     ADD CURRENT 2K BLOCKS        SMF 79563018
         STH   RCWRK,TCTRBC(RCORE)     UPDATE CURRENT BORROWED CORE SMF 79563618
         CH    RCWRK,TCTMBC(RCORE)     IS NEW CURRENT MORE THAN MAX SMF 79564218
         BNH   NOTHI                   BRANCH IF NO                 SMF 79564818
         STH   RCWRK,TCTMBC(RCORE)     STORE NEW MAXIMUM            SMF 79565418
NOTHI    B     RCEXIT                                               SMF 79566018
.GMCOMC  ANOP                                                       SMF 79566618
NOSHRE   LA    RCWRK,0(RSIZE,RBLOCK) .  GET END OF ALLOC AREA CH A45474 79567221
         C     RBLOCK,TCTLWM(RCORE)  .  IS BEGIN GT LWM       BC A45474 79568221
         BH    GMTSTHWM .               YES , TRY HWM UPDATE  BC A47474 79569221
         C     RCWRK,TCTLWM(RCORE) .    IS END GT LWM         BC A45474 79570221
         BNH   GMTSTHWM .               NO , TRY HWM          BC A45474 79571221
         ST    RCWRK,TCTLWM(RCORE)   .  STORE NEW LWM         CH A45474 79572221
         B     GMCKFBQ                  GO CK MIN DIFF        CH A45474 79573221
GMTSTHWM C     RCWRK,TCTHWM(RCORE)      IS END LT HWM         BC A45474 79574221
         BL    GMCKFBQ .                YES , NO HWM CHANGE   BC A45474 79575221
         C     RBLOCK,TCTHWM(RCORE) .   IS BEGIN LT HWM       BC A45474 79576221
         BNL   GMCKFBQ .                NO , GO CK MIN DIFF   BC A45474 79577221
         ST    RBLOCK,TCTHWM(RCORE)  .  STORE NEW HWM         CH A45474 79578221
* SEARCH FOR LARGEST FBQE .IF LARGEST FBQE IS GRTR THAN THE   CH A45474 79579221
* MINIMUM DIFFERENCE, MAKE IT NEW TCTMINC.                    CH A45474 79580221
GMCKFBQ  SR    RCWRK,RCWRK           .  INIT LARGEST SIZE=0   CH A45474 79581221
         CH    RCWRK,TCTMINC(RCORE)  .  IS TCTMINC=0          CH A45474 79582221
         BE    RCEXIT                   YES, BYPASS FBQE SRCH CH A45474 79583221
         L     RCFBQREG,FWDPTR(RWPQE) . GET LOWEST FBQE       CH A45474 79584221
GMLSTFBQ CLR   RCFBQREG,RWPQE           IS THIS END OF CHAIN  CH A45474 79585221
         BE    GMCKMIN                  YES, GO CK IF NEW MIN CH A45474 79586221
         C     RCWRK,FBQESIZE(RCFBQREG) IS THIS LARGEST FBQE  CH A45474 79587221
         BNL   GMNXTFBQ                 NO                    CH A45474 79588221
         L     RCWRK,FBQESIZE(RCFBQREG) SAVE LARGEST FBQE     CH A45474 79589221
GMNXTFBQ L     RCFBQREG,FWDPTR(RCFBQREG) GET NEXT HIGHER FBQE CH A45474 79590221
         B     GMLSTFBQ                 GO CHECK FOR END CHAINCH A45474 79591221
GMCKMIN  SRL   RCWRK,DIV2048            CONVERT TO 2K BLOCKS  CH A45474 79592221
         CH    RCWRK,TCTMINC(RCORE)     IS THIS A NEW MIN DIFFCH A45474 79593221
         BNL   RCEXIT                   NO                    CH A45474 79594221
         STH   RCWRK,TCTMINC(RCORE)     STORE NEW TCTMINC     CH A45474 79595221
RCEXIT   LM    10,12,GFSMFSVE           RESTORE WORK REGS     CH A45474 79596221
         BR    GMSMFRT                  RETURN                CH A45474 79597221
         DROP  GMSMFB                                         CH A45474 79598221
         SPACE 2                                              BC A45474 79600021
         LR    RCWRK1,RSIZE .                                    A57388 79600421
         SLR   RCWRK1,DIV2048 .                                  A57388 79600521
RCFBQREG EQU   12                      ADDR FBQE              BC A45474 79608221
         SPACE 1                                                    SMF 79625221
SMF252   DC    X'FC' .                                           A32912 79626021
GFSMFSVE DC    3F'0'                   SMF CORE ROUTINES SAVE AREA  SMF 79626821
SMFFQESV DC    F'0'                    FQE POINTER SAVE AREA        SMF 79627621
ASMFTCB  DC    A(SMFTCBSV)             ADDRESS OF TCB PTR SAVE      SMF 79628421
ADSPSAV  DC     V(SPIDSAV) .        ADDR OF SPIDSAV IN QGM       A32912 79629221
         SPACE 1                                                    SMF 79630021
         SPACE 2                                                    SMF 79630821
FMSMFRT  EQU   1                       RETURN REGISTER              SMF 79631621
TCBTCTGF EQU   X'80' .                                        BC A32900 79632100
GMSMFB   EQU   2                       BASE REGISTER                SMF 79632421
RWPQE1   EQU   2                       DEALLOCATION PQE POINTER     SMF 79633221
RCWRK2   EQU   4 .                                            BC A32900 79633921
FMSMFB   EQU   6                       BASE REGISTER                SMF 79634021
RWPQE    EQU   6                       ALLOCATION PQE POINTER       SMF 79634821
GMSMFRT  EQU   7 RETURN REGISTER TO GETMAIN                       20021 79635621
RTCT     EQU   10                      TCT POINTER                  SMF 79636421
RTCT1    EQU   10                      TCT POINTER                  SMF 79637221
RCORE    EQU   10                      CORE AREA POINTER            SMF 79638021
RCORE1   EQU   10                      CORE AREA POINTER            SMF 79638821
RCWRK    EQU   11                      WORK REGISTER                SMF 79639621
RCWRK1   EQU   11                      WORK REGISTER                SMF 79640421
RCWRKA   EQU   12                      WORK REGISTER                SMF 79641221
         SPACE 1                                                    SMF 79642021
TCBTCT   EQU   164                       TCT POINTER                SMF 79642821
TCTCSZE  EQU   16                      SIZE OF CORE AREA OF TCT     SMF 79643621
TCTCRTBL EQU   8                      ADDR OF TCT CORE TABLE        SMF 79644421
TCTLWM   EQU   0                       LOW WATER MARK OF CORE USED  SMF 79645221
TCTHWM   EQU   4                       HI WATER MARK OF USED CORE   SMF 79646021
TCTMINC  EQU   8                       MINIMUM DIFF BETWEEN LWM/HWM SMF 79646821
TCTRBC   EQU   12                      CURRENT BORROWED CORE        SMF 79647621
TCTMBC   EQU   14                      MAXIMUM BORROWED CORE        SMF 79648421
.EQCOMA  ANOP                                                       SMF 79649221
         SPACE                                                          79650015
TWOK     EQU   2048                                                     79680015
MULT8    EQU   3                                                        79710015
MULT2048 EQU   11                  SHIFT TO MULTIPLY BY 2048            79740015
DIV2048  EQU   11                  SHIFT TO DIVIDE BY 2048              79770015
         SPACE                                                          79800015
*        CONDITION CODES                                                79830015
         SPACE                                                          79860015
NZ       EQU   7                   NOT ZERO                             79890015
NN       EQU   10                  NOT NEGATIVE                         79920015
NOTLIST  EQU   11                  NOT LIST REQUEST                     79950015
ELEMENT  EQU   8                   ELEMENT REQUEST                      79980015
NP       EQU   12                  NOT POSITIVE                         80010015
         SPACE                                                          80040015
*        PARAMETER LIST OFFSETS                                         80070015
         SPACE                                                          80100015
SPID     EQU   9                   OFFSET OF SUBPOOL ID IN PARAMETER    80130015
*                                   LIST                                80160015
TYPE     EQU   8                   OFFSET OF TYPE CODE IN PARAMETER     80190015
*                                   LIST                                80220015
VLNTH    EQU   4                   OFFSET OF LENGTH IN VARIABLE         80250015
*                                   LENGTH-ADDRESS LIST                 80280015
         SPACE                                                          80310015
PTROFST  EQU   1                   OFFSET OF POINTER IN AQE, FQE, DQE   80340015
FQEOFSET EQU   0                   OFFSET OF BEGINNING OF FQE           80370015
         SPACE                                                          80400015
QESIZE   EQU   8                   SIZE OF QUEUE ELEMENT                80430015
FBQELNTH EQU   12                  SIZE OF FBQE                         80460015
FQNXTFLD EQU   4                   LENGTH OF POINTER IN FQE             80490015
ADRLNTH  EQU   3                   NUMBER OF BYTES OCCUPIED BY ADDRESS  80520015
         SPACE                                                          80550015
DQETEST  EQU   0                   MASK TO TEST FOR LARGE DQE           80580015
CODE     EQU   X'C0'               MASK FOR CHECKING TYPE CODE IN       80610015
*                                   PARAMETER LIST                      80640015
         SPACE 2                                                        80670015
*                                                                       80700015
*        SPQE FIELDS                                                    80730015
*                                                                       80760015
SPQEFLGS EQU   0         FLAG BYTE                                      80790015
SPQENXT  EQU   0         NEXT SPQE POINTER -1                           80820015
SPQEID   EQU   4         SUBPOOL ID                                     80850015
SPQEDQE  EQU   4         FIRST DQE POINTER -1                           80880015
SPQESHRD EQU   X'80'     MASK FOR FLAG BIT INDICATING SPQE IS SHARED    80910015
SPQELAST EQU   X'40'     MASK FOR FLAG BIT INDICATING LAST SPQE FOR TCB 80940015
*                                                                       80970015
*        DQE FIELDS '                                                   81000015
*                                                                       81030015
DQEFQE   EQU   0         FIRST FQE POINTER -1                           81060015
DQENXT   EQU   4         NEXT DQE POINTER -1                            81090015
         AIF   ('&LCS' NE 'Y').LC11                                LC0A 81097017
DQEHIID  EQU   8                   HIERARCHY IDENT                 LC0A 81104017
.LC11    ANOP                                                      LC0A 81111017
DQEADDR  EQU   8                   ADDRESS OF AREA DEFINED BY DQE       81120015
DQELNTH  EQU   12                  LENGTH OF AREA DEFINED BY DQE        81150015
*                                                                       81180015
*        FQE FIELDS                                                     81210015
*                                                                       81240015
FQENXT   EQU   0         NEXT FQE POINTER                               81270015
FQELNTH  EQU   4         LENGTH OF FREE AREA                            81300015
*                                                                       81330015
*        AQE FIELDS                                                     81360015
*                                                                       81390015
AQENXT   EQU   0                   POINTER TO NEXT AQE                  81420015
AQELNTH  EQU   4                   LENGTH OF ASSIGNED AREA              81450015
*                                                                       81480015
*        PQE FIELDS                                                     81510015
PQENXT   EQU   8                  OFFSET OF NEXT PQE PTR IN PQE         81540015
PQEPREV  EQU   12                 OFFSET OF PREVIOUS PQE PTR IN PQE     81570015
*                                                                       81600015
*        FBQE FIELDS                                                    81630015
*                                                                       81660015
*                                                                       81690015
*        DUMMY PQE FIELDS                                               81720015
*                                                                       81750015
DUMFWD   EQU   PQENXT             OFFSET OF FORWARD PQE PTR IN DUMMY    81780015
DUMBWD   EQU   PQEPREV            OFFSET OF BACKWARD PQE PTR IN DUMMY   81810015
PQETCB   EQU   16                  OFFSET OF TCB POINTER IN PQE         81840015
PQERGSZ  EQU   20                      OFFSET OF REGION SIZE IN PQE     81870015
PQESTADD EQU   24                      OFFSET OF RGN STRT ADD IN PQE    81900015
RORIFLG  EQU   28                 ROLLOUT FLAG IN PQE                   81930015
         AIF   ('&LCS' NE 'Y').LC12                                LC0A 81937017
PQEHIID  EQU   29                  HIERARCHY IDENT                 LC0A 81944017
.LC12    ANOP                                                      LC0A 81951017
RGNSHRD  EQU   X'80'              MASK FOR FLAG BIT INDICATING REGION   81960015
*                                 IS BORROWED                           81990015
*                        PQES ON THE PQE QUEUE.                         82020015
*                                                                       82050015
*                        THESE FIELDS ARE REFERENCED                    82080015
*                                                                       82110015
*                          DUMFWD - A FOUR BYTE FIELD IN WHICH THE      82140015
*                                   FIRST BYTE IS ZERO AND IN WHCIH THE 82170015
*                                   LAST THREE BYTES CONTAIN A POINTER  82200015
*                                   TO THE FIRST PQE ON THE CHAIN       82230015
*                                                                       82260015
*                          DUMBWD - A FOUR BYTE FIELD IN WHICH THE      82290015
*                                   FIRST BYTE IS ZERO AND IN WHICH THE 82320015
*                                   LAST THREE BYTES CONTAIN A POINTER  82350015
*                                   TO THE LAST PQE ON THE CHAIN.       82380015
FWDPTR   EQU   0                   OFFSET OF FORWARD POINTER IN PQE     82410015
BCKPTR   EQU   4                   OFFSET OF BACKWARD POINTER IN PQE    82440015
FBQESIZE EQU   8                   OFFSET OF SIZE FIELD IN PQE          82470015
*                                                                       82500015
*        TCB FIELDS REFERENCED                                          82530015
*                                                                       82560015
TCBABND  EQU   29                                                       82590015
TCBFMC   EQU   30                                                       82620015
TCBTCB   EQU   116                                                      82650015
TCBJSTCB EQU   124                 JOB STEP TCB POINTER                 82680015
TCBMSS   EQU   24        SPQE POINTER -1                                82710015
TCBFCD1  EQU   33               FIFTH FLAG BYTE IN TCB                  82740015
TCBPKF   EQU   28        PROTECT KEY                                    82770015
TCBJPQ   EQU   44                  OFFSET FOR TCBJPQ FIELD IN TCB       82800015
TCBPQE   EQU   152                 OFFSET OF TCBPQE IN TCB              82830015
TCBAQE   EQU   156                 OFFSET OF TCBAQE IN TCB              82860015
*                                                                       82890015
*        REFERENCES TO CDE                                              82920015
*                                                                       82950015
CDATTR   EQU   0                   OFFSET FOR ATTRIBUTE FIELD IN CDE    82980015
CDATTR2  EQU   20                  OFFSET FOR ATTRIBUTE FIELD IN CDE    83010015
REL      EQU   X'40'               MASK FOR INACTIVE FLAG IN CDE ATTR.  83040015
MIN      EQU   X'04'               MASK FOR MINOR FLAG IN CDE ATTR.     83070015
*        SYMBOLIC REGISTER ASSIGNMENTS                                  83100015
*                                                                       83130015
RIN0     EQU   0                                                        83160015
RMASK    EQU   0                                                        83190015
RFBQEUB  EQU   0                                                        83220015
RAREAUB  EQU   0                                                        83250015
RIN1     EQU   1                                                        83280015
RPRQE    EQU   1                                                        83310015
RDISP    EQU   1                                                        83340015
RAQEUB   EQU   1                                                        83370015
RQEUB    EQU   1                                                        83400015
RDQEBLK  EQU   1                                                        83430015
RWORK4   EQU   1                                                        83460015
RNEWDQE  EQU   1                                                        83490015
RVALBAS  EQU   2                                                        83520015
RLST     EQU   2                                                        83550015
RDQE     EQU   2                                                        83580015
RWORK5   EQU   2                                                        83610015
RPQE     EQU   2                                                        83640015
RBLOCK1  EQU   2                                                        83670015
REXBAS   EQU   2                                                        83700015
FREBAS   EQU   3 BASE REGISTER FOR FREEMAIN                       20021 83720020
CVTREG   EQU   3                        CVT REGISTER                    83740020
RCVT     EQU   4                                                  20021 83780020
RTCB     EQU   4                                                        83850015
RFQE1    EQU   4                                                        83880015
RSPID    EQU   5                                                        83910015
RUBRND   EQU   5                                                        83940015
RCDE     EQU   5                                                        83970015
        AIF ('&LCS' EQ 'N').LCSEQ01                                I283 83975019
PQE6     EQU   6                   REGISTER 6 - @ PQE              I283 83980019
PQE9     EQU   9                                                   I283 83985019
WORK15   EQU   15                                                  I283 83990019
.LCSEQ01 ANOP                                                      I283 83995019
RWORK1   EQU   6                                                        84000015
RERROR   EQU   6                                                        84030015
RLRGSIZ  EQU   6                                                        84060015
RQESIZ   EQU   6                                                        84090015
RDQESIZ  EQU   6                                                        84120015
RSWITCH  EQU   6                                                        84150015
RFBQE    EQU   6                                                  20021 84157020
RSIZE1   EQU   6                                                  20021 84164020
RWORK6   EQU   6                                                  20021 84171020
RWORK2   EQU   7                                                        84180015
RFQE     EQU   7                                                        84210015
RCOMRET3 EQU   7                                                        84240015
RQE      EQU   7                                                        84270015
RBASE    EQU   8                                                        84300015
RCOMRET1 EQU   9                                                        84330015
RORIREG  EQU   9                                                        84360015
RWK3CVT  EQU   9                                                  20021 84367020
RWORK3   EQU   9                                                        84390015
RLENGTH  EQU   10                                                       84420015
RSIZE2   EQU   10                                                       84450015
RSIZE3   EQU   10                                                       84480015
RMASK1   EQU   10                                                       84510015
RADDR    EQU   11                                                       84540015
RFQRND   EQU   11                                                       84570015
RLRGBLK  EQU   11                                                       84600015
RCDEIN   EQU   11                                                       84630015
RBASE1   EQU   11                                                       84660015
FPQEBASE EQU   11                                                       84690015
RVALRET  EQU   12                                                       84720015
RSPQE    EQU   12                                                       84750015
RPREDQE  EQU   12                                                       84780015
RAQE     EQU   12                                                       84810015
RPREVDQ  EQU   12                                                       84840015
RDISP1   EQU   12                                                       84870015
RRET1    EQU   12                                                       84900015
RBLOCK2  EQU   12                                                       84930015
RFQEUB   EQU   12                                                       84960015
RABTERM  EQU   13                                                       84990015
RGMRET   EQU   13                                                       85020015
RFMRET   EQU   13                                                       85050015
RCOMRET2 EQU   13                                                       85080015
RDQELB   EQU   13                                                       85110015
RRET     EQU   13                                                       85140015
MP65BASE EQU   13                                                  MP2K 85150018
RRETURN  EQU   14                                                       85170015
RPREFQE  EQU   14                                                       85200015
RBLOCK   EQU   14                                                       85230015
RPREVQE  EQU   14                                                       85260015
RIN15    EQU   15                                                       85290015
RFRELNTH EQU   15                                                       85320015
RSIZE    EQU   15                                                       85350015
RDQEUB   EQU   15                                                       85380015
IPVLBASE EQU   15                                                       85410015
         SPACE                                                          85440015
***************************************************************   21016 85840021
*        DSECT TO COVER INFORMATION LIST ENTRY                    21016 86240021
***************************************************************   21016 86640021
         SPACE 1                                                  21016 87040021
INFOLIST DSECT                                                    21016 87440021
INFENTRY DS    H      NOT USED                                   A49808 87490021
INFTJID  DS    H      USER TSO ID FIELD                          A49808 87540021
INFTCB   DS    F                                                  21016 87840021
INFBADDR DS    F                                                  21016 88240021
INFRCL   DS    X     BITS 0-2 USED FOR REASON CODE(0=>NO RC)      21016 88640021
*                    BITS 3-7 USED FOR COUNT OF VARIABLE DATA BYTE21016 89040021
INFFLG   DS    X     FLAG BYTE                                    21016 89440021
INFFLG0  EQU   X'80' BIT 0 ON => BRANCH ENTRY                     21016 89840021
INFCC    DS    H     COMPLETION CODE                              21016 90240021
INFVAR   DS    4F    VARIABLE INFORMATION                         21016 90640021
         ORG   INFVAR                                             21016 91040021
INFVAR1  DS    F                                                  21016 91440021
INFVAR2  DS    F                                                  21016 91840021
INFVAR3  DS    F                                                  21016 92240021
INFVAR4  DS    F                                                  21016 92640021
INFEND   EQU   *                                                  21016 93040021
INFLEN   EQU   (INFEND-INFENTRY)  LENGTH OF ENTRY                A49808 93440021
         EJECT                                                    21016 93840021
SCVTMSGS EQU   X'94'                                              21016 94240021
SCVTFMSA EQU   X'98'           ADDR OF CONDITIONAL FREEMAIN BITS  21016 94340021
SCVTSW1  EQU   X'80'           CONDITIONAL FREEMAIN BITS.         21016 94440021
         SPACE 2                                                  21016 94640021
CVT0EF00 EQU   4                                                  21016 95040021
CVTNUCB  EQU   128                                                21016 95440021
CVTCRTTR EQU   X'B8'                                              21016 95840021
CVTABEND EQU   X'C8'                                              21016 96240021
CVTQMSG  EQU   X'10C'                                             21016 96440021
         SPACE 2                                                  21016 96640021
         MEND                                                           97040021
          IEAQGM Y,Y,Y,1,1                                              99540021
          END                                                           99740021
