         MACRO                                                          00090017
         IEAQPR     &RORI,&LCS,&MPS                                     00180017
         LCLB  &MP                                                 MP1A 00270017
.*0467002000-902000                                                MO17 00300017
.*3612                                                             MP2K 00306018
.*3612,147600,354600,684000-684900                                 3645 00312018
.*3612,149400,450900,477000,481500                                 SWS  00318018
.*3612,587740-588420,599400,665100                                 MP2A 00324018
         TITLE ' MVT GETPART / FREEPART ROUTINE '                       00330017
.*0467                                                             8499 00340017
*2970,140400-140800,145100-145500,477480,547200                   9400  00350019
&MP  SETB ('&MPS' EQ '1' OR '&MPS' EQ 'M65MP' OR '&MPS' EQ 'Y')    MP1A 00360017
IEAQPRT0 CSECT                                                          00450017
         ENTRY DISPINIT                                            SWS  00460018
         AIF   (NOT &MP).MP01PTM                                   MP1A 00470017
         ENTRY IEAMPSTR                                            MP1A 00490017
.MP01PTM ANOP                                                      MP1A 00510017
         EXTRN IEAMSTCB                                                 00540017
         EXTRN GOVRFLB                                                  00630017
         SPACE 10                                                       00720017
         EJECT                                                          00810017
*********************************************************************** 00900017
*********************************************************************** 00990017
*    THE GETPART/FREEPART FUNCTION IS AN EXTENSION OF  GETMAIN        * 01080017
*  (IEAQGM)    IT IS ENTERED VIA A BRANCH FROM GETMAIN WHEN SUBPOOL   * 01170017
*     246-247-OR-248 HAS BEEN SPECIFIED. THE GETPART MACRO CAN BE     * 01260017
*  ASSEMBLED WITH ANY OR ALL OF THREE OPTIONS -- '&LCS' INDICATING    * 01350017
*  LCS SUPPORT, '&RORI' FOR SUPPORT OF ROLLOUT/ROLLIN, AND '&MPS'     * 01440017
*  FOR MULTIPROCESSING SUPPORT.                                       * 01530017
*                                                                    *  01620017
*  ENTRIES TO GETPART INDICATE THE FOLLOWING                         *  01710017
*                                                                    *  01800017
*  SUBPOOL 247 - R-FORM  VIA SVC 10                                  *  01890017
*                                                                    *  01980017
*              R1 MINUS - GET PARTITION                              *  02070017
*                                                                    *  02160017
*              R1 PLUS OF ZERO - FREE PARTITION                      *  02250017
*                                                                    *  02340017
*              LIST FORM - VIA SVC 4                                 *  02430017
*                                                                    *  02520017
*              R1 - ZERO - GET PARTITION                             *  02610017
*                                                                    *  02700017
*              R1 - NON-ZERO - GET PARTITION AT THE ADDRESS          *  02790017
*            SPECIFIED IN R1                                         *  02880017
*                                                                    *  02970017
* SUBPOOL 246   R-FORM   VIA SVC  10                                 *  03060017
*                                                                    *  03150017
*              FREE THE PRESENT PARTITION AND THEN GET ANOTHER       *  03240017
*            OF THE SPECIFIED LENGTH                                 *  03330017
*                                                                    *  03420017
*              LIST FORM   VIA SVC 4                                 *  03510017
*                                                                    *  03600017
*              R1 - ZERO  SAME AS R-FORM                             *  03690017
*                                                                    *  03780017
*              R1 - NON-ZERO FREE PRESENT PARTITION AND OBTAIN NEW   *  03870017
*            PARTITION AT ADDRESS SPECIFIED IN R1                    *  03960017
*                                                                    *  04050017
*  SUBPOOL 248  INDICATES REQUEST FROM ROLLOUT/ROLLIN                *  04140017
*                                                                    *  04230017
*  NOTE- THE LENGTHS OF REQUESTS ARE OBTAINED THE SAME AS IN GETMAIN *  04320017
*                                                                    *  04410017
*                                                                    *  04500017
*  RETURNS FROM GETPART                                              *  04590017
*                                                                    *  04680017
*            RETURN= '00'  SUCCESSFUL IN OBTAINING PARTITION         *  04770017
*                                                                    *  04860017
*            RETURN = '04'  REQUEST CANNOT BE SATISFIED              *  04950017
*         EC OR LC  ONLY                                             *  05040017
*                                                                    *  05130017
*            RETURN = '08' THE REQUEST IS NOT VALID - REQUEST IS TOO *  05220017
*         LARGE OR FOR AN INVALID ADDRESS                            *  05310017
*                                                                    *  05400017
*            IF THE REQUEST IS UNCONDITIONAL AND CANNOT BE SATISFIED *  05490017
*         BUT IS VALID THE REQUESTING TCB IS PLACED IN A WAIT FOR    *  05580017
*         CORE                                                        * 05670017
*                                                                    *  05760017
*                                                                    *  05850017
*            IF A REQUEST IS MADE FOR A SPECIFIC ADDRESS AND CANNOT   * 05940017
*                                                                    *  06030017
*         NOW BE SATISFIED ALL FOLLOWING REQUESTS FOR CORE WILL      *  06120017
*         NOT BE HONORED UNTIL THE ACTUAL ADDRESS REQUEST            *  06210017
*         IS SATISFIED                                               *  06300017
*                                                                    *  06390017
*                                                                    *  06480017
*                                                                    *  06570017
*********************************************************************** 06660017
*********************************************************************** 06750017
*                                                                       06840017
*                                                                       06930017
         SPACE 2                                                        07020017
         DS  0D                                                         07110017
         BALR  RBASE,0                                                  07200017
         USING PART,RBASE                                               07290017
PART     STM   RRETURN,RIN1,RINSAVE  SAVE INPUT REGISTERS               07380017
         MVC   SWITCHES(3),ZEROES                                       07470017
         LA    RWORK2,247                                               07560017
         CR    RSPID,RWORK2   IS THIS A FREE-GET REQUEST                07650017
         BL    FREXCHNG       YES- SUBPOOL 246 SPECIFIED                07740017
         AIF   ('&RORI' NE 'Y').GO01                                    07830017
         BH    RORI           SUBPOOL 248 REQUEST FROM FOLLOUT/ROLLIN   07920017
.GO01    ANOP                                                           08010017
CKSVCBYT L     RWORK1,ADSVCB    ADDRESS OF SVC BYTE                     08100017
         CLI   0(RWORK1),4    IS THIS AN SVC 4                          08190017
         BE    SVC4       YES                                           08280017
         LTR   RIN1,RIN1      IS REQUEST FREEPART                       08370017
         BC    10,FREEPART   YES                                        08460017
         B     REGREQ     HAS TO BE REGISTER REQUEST FOR GETPART        08550017
SVC4     OI    SWITCHES,X'01'        INDICATE REQUEST VIA SVC 4         08640017
         CLI   WAITSW,X'FF'  IS WAIT SW ON                              08730017
         BE    CKTCB                                                    08820017
TCBOK    TM    8(RIN1),X'DF'  TEST FOR ELEMENT REQUEST                  08910017
         BZ    ELEREQ                                                   09000017
         SPACE 2                                                        09090017
*****                                                              **** 09180017
*                                                                     * 09270017
*                      THIS CODE OBTAINS THE  DESIRED PARTITION(S)    * 09360017
*                                                                     * 09450017
*****                                                              **** 09540017
         SPACE 2                                                        09630017
GPART    LR    RWORK1,RIN1                                              09720017
         AIF   ('&LCS' EQ 'Y').GO03                                     09810017
         LA    RWORK3,0       CLEAR TOTAL LENGTH REG                    09900017
.GO03    ANOP                                                           09990017
         L     RWORK1,0(RWORK1)    PICK UP POINTER TO LENGTH LIST       10080017
         L     RADDR,4(RIN1)     PICK UP ADDRESS POINTER                10170017
         AIF   ('&LCS' EQ 'N').GO39                                     10260017
LISTGP   ST    RWORK1,WORK1SV                                           10350017
         ST    RADDR,ADDRSV                                             10440017
.GO39    ANOP                                                           10530017
         L     RADDR,0(RADDR)    PICK UP ADDRESS ENTRY                  10620017
NLCSGP   L     RWORK2,0(RWORK1)  PICK UP LENGTH                         10710017
***      THIS SECTION OF CODE DETERMINES THE NUMBER OF 2K    BL A59054  10760021
*        BLOCKS NEEDED FOR A PARTITION AND GETS THEM         BL A59054  10770021
         LA    RWORK2,0(RWORK2) .       CLEAR HI BYTE        AC  M5282  10772021
         LA    RSIZE,2047 .                                  AC  M5282  10780021
         LR    RIN0,RSIZE .                                  AC  M5282  10790021
         AR    RSIZE,RWORK2 .  RWORK2 CONTAINS THE LENGTH    AC  M5282  10792021
         OR    RSIZE,RIN0 .                                  AC  M5282  10794021
         XR    RSIZE,RIN0 .                                  AC  M5282  10796021
         LR    RWORK2,RSIZE .                                AC  M5282  10798021
         AIF   ('&LCS' EQ 'N').GO10                                     10800017
         ST    RADDR,HSAVE       SAVE HIARCHY INDICATION                10890017
         CLI   HSAVE,X'01'       HAS H1 BEEN SPECIFIED                  10980017
         BNE   NOTH1DUM          NO SKIP PQE CHECK                      11070017
         L     RWORK4,OVRFLB     GOVERFLB                               11160017
         L     RWORK4,8(RWORK4)  ADDRESS OF DUMMY PQE - 8               11250017
         L     RWORK4,PQEPREV(RWORK4)   ADDRESS OF REAL PQE             11340017
         OC    PQEPREV(4,RWORK4),PQEPREV(RWORK4)  IS THER A SECOND PQE  11430017
         BC    7,NOTH1DUM     YES                                       11520017
         OI    SWITCHES,X'10' INDICATE H1 REQUEST -H1 NOT ON SYSTEM     11610017
         MVI   HSAVE,X'00'    INDICATE H0 REQUEST                       11700017
NOTH1DUM DS    0H                                                       11790017
.GO10    ANOP                                                           11880017
         CLI   0(RWORK1),X'80'   IS THIS THE END OF THE LIST            11970017
         BNE   NOSET                                                    12060017
         OI    SWITCHES,X'04'    SET END OF LIST SWITCH                 12150017
         AIF   ('&LCS' EQ 'Y').GO16                                     12240017
         LA    RADDR,0(RADDR) .         INSURE REQUEST IS FOR H0  M6377 12290000
         LTR   RADDR,RADDR  CHECK FOR A SPECIFIC REQUEST                12330017
         BNZ   GETSPEC                                                  12420017
         B     ENDLST            END OF LIST PROCESSING                 12510017
         AIF   ('&LCS' EQ 'N').GO06                                     12600017
.GO16    ANOP                                                           12690017
NOSET    LA    RADDR,0(RADDR)    CLEAR HIARCHY INDICATION               12780017
         LTR   RADDR,RADDR       CHECK FOR A SPECIFIC ADDRESS REQUEST   12870017
         AGO   .GO07                                                    12960017
.GO06    ANOP                                                           13050017
NOSET    LTR   RADDR,RADDR       CHECK FOR A SPECIFIC ADDRESS           13140017
.GO07    ANOP                                                           13230017
         BNZ   GETSPEC                                                  13320017
         AIF   ('&LCS' EQ 'Y').GO18                                     13410017
NOTH1    AR    RWORK3,RWORK2  COMBINE LENGTH                            13500017
         LA    RWORK1,4(RWORK1)  PICK UP PTR TO NEXT LENGTH             13590017
         B     NLCSGP                                                   13680017
ENDLST   AR    RWORK2,RWORK3  COMBINE FINAL ENTRY                       13770017
.GO18    ANOP                                                           13860017
****   CHECK FOR SUFFICIENT SPACE IN SQS                                13950017
*A REQUEST FOR A PARTITION WILL NOT BE SATISFIED UNLESS THERE IS   SWS  13951018
*AT LEAST 2K OF QUEUE SPACE AVAILABLE.  THE 2K LIMIT WILL BE       SWS  13952018
*COMPUTED BY SCANNING THE FREE QUEUE ELEMENTS. THE PURPOSE OF           13953021
*THRESHOLD ON QUEUE SPACE IS TO PREVENT THE INITIATION OF NEW WORK SWS  13955018
*WHENEVER AVAILABLE QUEUE SPACE FALLS BELOW THE PEAK QUEUE SPACE   SWS  13956018
*REQUIREMENTS OF THE AVERAGE JOB.  THE REASON FORCOMPUTING THE 2K FROM  13957018
*ONLY THOSE BLOCKS WHICH ARE EQUAL TO OR LARGER THAN 144 BYTES IS  SWS  13958018
*TO MINIMIZE THE POSSIBILITY OF A E04 WAIT STATE BY INCREASING          13959021
*THE AVERAGE SIZE OF THE FREE BLOCKS CLOSER TO THE AVERAGE SIZE    SWS  13960018
*REQUEST GENERETED BY THE INITIATION OF NEW WORK.                  SWS  13961018
*                                                                       13962018
*        FORMAT OF GOVRFLB                                         SWS  13963018
*                                                                       13964018
*        ****************************************                       13965018
*        *                                       *                      13966018
*        * FLAG    *  UPPER BOUND OF             *                 SWS  13967018
*  +0    *  BYTE   *                             *                 SWS  13968018
*        *         *           S. Q. S.          *                 SWS  13969018
*        *         *                             *                      13970018
*        *****************************************                      13971018
*        *                                       *                      13972018
*        *  ADDRESS  OF  D.Q.E.                  *                 SWS  13973018
*  +4    *                                       *                      13974018
*        *   FOR S. Q. S.                        *                 SWS  13975018
*        *                                       *                      13976018
*        *****************************************                      13977018
*        *                                       *                      13978018
*        *  ADDRESS OF  PQE                      *                 SWS  13979018
*  +8    *                                       *                      13980018
*        * FOR AVAILABLE MAIN STORAGE            *                 SWS  13981018
*        *                                       *                      13982018
*        *****************************************                      13983018
*        *                                       *                      13984018
*        *         AVAILABLE                     *                 SWS  13985018
*  +12   *                                       *                 SWS  13986018
*        *      CORE STORAGE SIZE IN H0          *                 SWS  13987018
*        *                                       *                      13988018
*        *****************************************                      13989018
*        *                                       *                      13990018
*        *  CORE STORAGE AVAILABLE IN H1         *                 SWS  13991018
*   +16  *                                       *                 SWS  13992018
*        *****************************************                      13993018
*        *                                       *                      13994018
*        *  ORIGIN OF THE VQE QUEUE FOR MP65     *                 SWS  13995018
*  +20   *                                       *                 SWS  13996018
*        *****************************************                      13997018
*        *                                       *                      13997420
*        * NIPSQSBD SQS BOUNDRY FOR NIP & RORI   *                      13997720
*  +24   *                                       *                      13997820
*        *****************************************                      13997920
*                                                                       13998018
*                                                                       13999018
*  FLAG BYTE AT OFFSET 0                                           SWS  14000018
*                                                                       14001018
*                                                                       14002018
*  SET TO X'80' WHEN A TASK IA MADE NON-DISPATCHABLE BECAUSE       SWS  14003018
* INSUFFICIENT QUEUE SPACE WAS AVAILABLE TO START NEW WORK.        SWS  14004018
*  THIS FLAG BYTE WILL BE RESET TO ZERO WHENEVER EITHER A FREEPART SWS  14005018
*IS ISSUED OR WHENEVER QUEUE SPACE IS FREED.                       SWS  14006018
         SPACE 4                                                        14007018
NOSET1   TM    SWITCHES,X'80'      IS THIS AN EXCHANGE REQUEST   A29400 14037019
         BO    COMP2KB             YES, BYPASS CHECK ON SQS      A29400 14067019
         AIF   ('&LCS' EQ 'N').GOAA                            @SA70977 14073029
         TM    SWITCHES,X'20'      CHECK ONE DONE SW           @SA70977 14079029
         BO    COMP2KB             YES-BYPASS 2ND SQA CHK      @SA70977 14085029
.GOAA    ANOP                                                  @SA70977 14091029
         SR    RADDR,RADDR                                       A29400 14097019
         L     RWORK3,OVRFLB      GOVRFLB                               14130017
         L     RWORK3,4(RWORK3)   PTR TO SQS AREA                       14220017
         L     RWORK3,FQENXT(RWORK3) .  PTR TO FIRST FQE         A40395 14310021
         LTR   RWORK3,RWORK3          END OF QUEUE                      14400017
         BZ    NOSQS          YES-NO SQS AVAILABLE             @JK69023 14490021
CKLOOP   A     RADDR,FQELNTH(RWORK3)  INCR COUNT OF FREE SQS     A40395 14580021
CKTTL    C     RADDR,SQSMIN   IS THERE SUFFICIENT SYS QUE SPACE TO 3645 14760018
*                             INITIATE A JOB STEP                       14850017
         BC    10,COMP2KB         YES, 2K OR MORE IS AVAILABLE.  GO     14870018
*                                 TO PROCESS GETPART REQUEST       SWS  14890018
         L     RWORK3,FQENXT(RWORK3) .    PTR TO NEXT FQE        A40395 14900021
         LTR   RWORK3,RWORK3 .            END OF QUEUE           A40395 14900121
         BNE   CKLOOP .                 NO                       A40395 14900221
NOSQS    L     RWORK3,OVRFLB NO-2K OF SQS IS NOT           SWS @JK69023 14925021
         OI    0(RWORK3),X'80'     AVAILABLE.                      SWS  14930018
         B     INITWAIT           SET FLAG IN GOVRFLB AND MAKE TASKSWS  14950018
*                                 NON-DISPATCHABLE                 SWS  14970018
COMP2KB  DS    0H                                                  SWS  14990018
*****  THIS CODE DETERMINES IF THE REQUEST IS VALID                     15030017
         L     RWORK3,OVRFLB          GOVRFLB                           15120017
         L     RWORK3,8(RWORK3)       DUMMY PQE - 8                     15210017
         L     RWORK3,PQEPREV(RWORK3)   LAST OR ONLY PQE                15300017
         AIF   ('&LCS' EQ 'N').GO20                                     15390017
         CLI   HSAVE,X'01'       WAS H1 SPECIFIED                       15480017
         BNE   CKNOTH1           NO                                     15570017
         CLI   PQEHID(RWORK3),X'01'   IS THIS H1 PQE                    15660017
         BE    CKPQEFND                                                 15750017
         OC    PQEPREV(4,RWORK3),PQEPREV(RWORK3) 2361 ONLINE ?     I283 15760019
         BNZ   CKOTHPQE            YES  GET OTHER PQE              I283 15770019
         MVI   HSAVE,X'00'         INDICATE CORE FROM HIAR ZERO    I283 15780019
         OI    SWITCHES,X'10'      H1 REEQUEST & 2361 OFFLINE      I283 15790019
         B     CKPQEFND            PROCESS AS H0 REQUEST         I283   15800019
CKOTHPQE L     RWORK3,PQEPREV(RWORK3) HAS TO BE OTHER PQE               15840017
         B     CKPQEFND                                                 15930017
CKNOTH1  CLI   PQEHID(RWORK3),X'00'   IS THIS H0 PQE                    16020017
         BE    CKPQEFND               YES                               16110017
         B     CKOTHPQE               THE OTHER IS H1                   16200017
.GO20    ANOP                                                           16290017
CKPQEFND L     RWORK3,PQERGSZ(RWORK3) SIZE OF CORE DESCRIBED BY PQE     16380017
         LA    RWORK2,0(RWORK2)    CLEAR HI ORDER BYTE                  16470017
         CR    RWORK2,RWORK3  IS REQUEST FOR MORE THAN IS               16560017
         AIF   ('&LCS' EQ 'N').GO71                                     16650017
         BH    RETURN08  AVAILABLE - BRANCH IF YES                      16740017
         AGO   .GO68                                                    16830017
.GO71    ANOP                                                           16920017
         BH    RTN08                  AVAILABLE - BRANCH IF YES         17010017
.GO68    ANOP                                                           17100017
*        THIS SECTION OF CODE DETERMINES THE NUMBER OF 2K BLOCKS        17150021
*        NEEDED FOR A PARTITION AND GETS THEM                           17200021
         LA    RWORK1,2047                                              17300021
         LR    RWORK3,RWORK1                                            17350021
         AR    RWORK1,RWORK2          RWORK2 CONTAINS THE LENGTH        17450021
         OR    RWORK1,RWORK3                                            17500021
         XR    RWORK1,RWORK3                                            17550021
         AIF   ('&LCS' EQ 'N').GO21                                     17820017
         L     RWORK3,ADSVCB  ADDRESS OF SVC BYTE - SVC BYTE + 1 IS     17910017
         MVC   1(1,RWORK3),HSAVE      HIARCHY BYTE IN GETMAIN           18000017
.GO21    ANOP                                                           18090017
         L     RCOMRET1,FBSRCH                                          18180017
         BALR  RCOMRET1,RCOMRET1                                        18270017
** OUTPUT OF FBQSRCH  RBLOCK = ADDRESS OF FIRST AVAILABLE BLOCK (14)    18360017
****                  RSIZE  = NUMBER OF BYTES (15)                     18450017
COREOK   B     CKONEDN        CORE HAS BEEN OBTAINED                    18540017
SRTN04   DS    0H             FROM SPECIFIC REQUEST WHEN UNSATISFIED    18630017
         AIF   ('&LCS' EQ 'N' AND '&RORI' EQ 'N').GO22                  18720017
         TM    SWITCHES,X'20' CORE NOT GOTTEN - CHECK ONE DONE SW       18810017
         BZ    RTN04                                                    18900017
         AIF   ('&RORI' EQ 'N').GO23                                    18990017
         TM    SWITCHES,X'40' CHECK FOR RO/RI REQUEST                   19080017
         BO    RTN04          YES-RO/RI DON'T FREE ANY CORE             19170017
.GO23    ANOP                                                           19260017
         OI    SWITCHES+1,X'02'    INDICATE  UNSATISFIED REQUEST        19350017
         B     FREEPART                                                 19440017
         AGO   .GO24                                                    19530017
.GO22    ANOP                                                           19620017
         B     RTN04                                                    19710017
.GO24    ANOP                                                           19800017
CKONEDN  DS    0H                                                       19890017
         L     QGM2BS,DBASADR .            LOAD QGM'S 2ND BAS     M2883 19930020
         A     QGM2BS,CON1K .      ADD 1 K DISP FOR 2ND BAS       M2883 19950020
         TM    SWITCHES,X'80'      IS THIS AN EXCHANGE REQUEST          19980017
         BO    PQENH1A        DO NOT OBTAIN CORE FOR PQE'S              20070017
         AIF   ('&LCS' EQ 'N' AND '&RORI' EQ 'N').GO26                  20160017
         TM    SWITCHES,X'20'      CHECK ONE DONE SW                    20250017
         BO    NODUMMY             YES-DUMMY EXISTS                     20340017
.GO26    ANOP                                                           20430017
         LA    RIN1,DUMPQESZ       LENGTH NEED FOR PQE                  20520017
         L     RCOMRET,PQEMAIN                                          20610017
         BALR  RCOMRET,RCOMRET     GETMAIN FOR DUMMY                    20700017
         SH    RIN1,DUMQELTH+2     TCB POINTS TO DUMMY - 8              20790017
         ST    RIN1,TCBPQE(RTCB)   INITIALIZE TCBPQE TO POINT TO DUMMY  20880017
NODUMMY  LA    RIN1,PQESIZE                                             20970017
         L     RCOMRET,PQEMAIN                                          21060017
         BALR  RCOMRET,RCOMRET     GETMAIN FOR PQE                      21150017
         AIF   ('&RORI' EQ 'N').GO28                                    21240017
         ST    RIN1,PQESAVE        SAVE PTR TO GIVE BACK FOR RORI       21330017
.GO28    ANOP                                                           21420017
         AIF   ('&LCS' EQ 'N').GO34                                     21510017
         TM    SWITCHES,X'10' CHECK H1 SW - H1 REQUEST BUT NO H1 ON SYS 21600017
         BZ    PQEH1OK                                                  21690017
         MVI   PQEHID(RIN1),X'01'   INDICATE H1 IN PQE                  21780017
         B     PQENH1                                                   21870017
PQEH1OK  MVC   PQEHID(1,RIN1),HSAVE  PLACE ACTUAL HIARCHY ID IN PQE     21960017
.GO34    ANOP                                                           22050017
PQENH1   ST    RIN1,FWDPTR(RBLOCK)     INITIALIZE FBQE BACKWARD POINTER 22140017
         ST    RIN1,BCKPTR(RBLOCK)     INITIALIZE FBQE BACKWRD POINTER  22230017
         ST    RSIZE,FBQESIZE(RBLOCK)  PUT SIZE IN FBQE                 22320017
         ST    RBLOCK,PQESTADD(RIN1)   INITIALIZE REGION START ADDR     22410017
         ST    RSIZE,PQERGSZ(RIN1)     INITIALIZE REGION SIZE           22500017
         ST    RBLOCK,FWDPTR(RIN1)     INITIALIZE PQE FORWARD POINTER   22590017
         ST    RBLOCK,BCKPTR(RIN1)     INITIALIZE PQE BACKWARD POINTER  22680017
         TM    SWITCHES,X'80'      CHECK FOR EXCHANGE REQUEST           22770017
         BO    CKENDLST       SKIP PQE POINTER INITIALIZATION           22860017
         ST    RTCB,PQETCB(RIN1)       INITIALIZE  PQE TCB POINTER      22950017
         L     RWORK1,TCBPQE(RTCB)     PICK UP DUMMY                    23040017
         AIF   ('&LCS' EQ 'N' AND '&RORI' EQ 'N').GO31                  23130017
         AIF   ('&RORI' EQ 'N').GO96                                    23220017
         TM    SWITCHES,X'60' CHECK RO/RI AND ONE DONE SWITCH           23310017
         BO    RTN00       RO/RI REQUEST - DON'T QUEUE PQE'S            23400017
         AIF   ('&LCS' EQ 'N').GO31                                     23490017
         BM    PQEQUE    ONE DONE SWITCH ON ALONE                       23580017
         AGO   .GO97                                                    23670017
.GO96    ANOP                                                           23760017
         TM    SWITCHES,X'20'          CHECK ONE DONE SW                23850017
         BNZ   PQEQUE                                                   23940017
.GO97    ANOP                                                           24030017
         ST    RIN1,PQENXT(RWORK1)     SET UP DUMMY TO POINT TO PQE     24120017
         ST    RIN1,PQEPREV(RWORK1)                                     24210017
         B     CKENDLST                                                 24300017
PQEQUE   L     RWORK1,PQEPREV(RWORK1)  PICK UP HIGH ADDR PQE            24390017
         LTR   RWORK1,RWORK1   WAS PREVIOUS PQE LAST                    24480017
         BZ    INSRTFST        YES INSERT NEW PQE AS FIRST              24570017
         CLC   PQESTADD+1(3,RIN1),PQESTADD+1(RWORK1) IS NEW REG ADDR    24660017
         BL    PQEQUE         LOWER THAN PREVIOUS PQE IF NOT FALL THRU  24750017
         CLC   PQENXT+1(3,RIN1),PQENXT+1(RWORK1)  CHECK PQENXT = 0      24840017
         BE    INSRTLST     YES INSERT NEW PQE LAST                     24930017
INSRTBTW MVC   PQENXT+1(3,RIN1),PQENXT+1(RWORK1) NEW PQENXT EQU OLD     25020017
         ST    RWORK1,PQEPREV(RIN1)  OLD NOW PREV TO NEW                25110017
         ST    RIN1,PQENXT(RWORK1)   NEW NOW NEXT TO OLD                25200017
         L     RWORK1,PQENXT(RIN1)   NEW PQE'S NEXT                     25290017
         ST    RIN1,PQEPREV(RWORK1)  OLD PREVIOUS NOW POINTS TO NEW     25380017
         B     CKENDLST                                                 25470017
INSRTFST L     RWORK1,TCBPQE(RTCB)  DUMMY - QUEUE FIRST PQE             25560017
         L     RSIZE,PQENXT(RWORK1)   OLD NEXT                          25650017
         ST    RIN1,PQENXT(RWORK1)    NEW NOW NEXT OFF DUMMY            25740017
         ST    RIN1,PQEPREV(RSIZE)    OLD PREVIOUS NOW NEW PQE          25830017
         ST    RSIZE,PQENXT(RIN1)     OLD NOW NEXT FOR NEW              25920017
         B     CKENDLST                                                 26010017
INSRTLST ST    RWORK1,PQEPREV(RIN1)   OLD NEW PREVIOUS TO NEW           26100017
         ST    RIN1,PQENXT(RWORK1)    NEW NOW NEXT FOR OLD              26190017
         L     RWORK1,TCBPQE(RTCB)    DUMMY                             26280017
         ST    RIN1,PQEPREV(RWORK1)   DUMMY LAST NOW POINTS TO NEW      26370017
         B     CKENDLST                                                 26460017
         AGO   .GO35                                                    26550017
.GO31    ST    RIN1,PQENXT(RWORK1)    SET UP DUMMY TO POINT TO PQE      26640017
         ST    RIN1,PQEPREV(RWORK1)                                     26730017
.GO35    ANOP                                                           26820017
CKENDLST DS    0H                                                       26910017
         AIF   ('&LCS' EQ 'N' AND '&RORI' EQ 'N').GO35A                 27000017
         TM    SWITCHES,X'20'         CHECK ONE DONE SW                 27090017
         BO    LISTENCK               YES SPACE ALREADY OBTAINED IN 252 27180017
.GO35A   ANOP                                                           27270017
         TM    SWITCHES,X'08'      WAS REQUEST ACTUAL                   27360017
         BO    LISTENCK            YES DON'T GET CORE IN SUBPOOL 252    27450017
GET252   L     RIN0,RESERVE   SET UP TO GET 8 BYTES FROM SP 252         27540017
         LCR   RIN1,RIN1      TO RESERVE 2K BLOCK                       27630017
         L     RBLOCK,REGMAIN                                           27720017
         BALR  RBLOCK,RBLOCK                                            27810017
LISTENCK DS    0H                                                       27900017
         AIF   ('&LCS' EQ 'N').GO38                                     27990017
         TM    SWITCHES,X'84' END OF LIST OR FREE EXCHANGE REQUEST      28080017
         BC    7,COMRTN0   YES                                          28170017
         OI    SWITCHES,X'20'      SET ONEDONE SW                       28260017
         L     RWORK1,WORK1SV         PICK UP POINTER TO                28350017
         L     RADDR,ADDRSV              NEXT LENGTH ENTRY              28440017
         LA    RWORK1,4(RWORK1)       PICK UP POINTER TO                28530017
         LA    RADDR,4(RADDR)            NEXT ADDRESS ENTRY             28620017
         B     LISTGP                                                   28710017
         AGO   .GO40                                                    28800017
.GO38    ANOP                                                           28890017
         B     COMRTN0                                                  28980017
.GO40    ANOP                                                           29070017
REGREQ   LR    RWORK2,RLENGTH LENGTH OF REGION REQUEST AND SPID         29160017
         AIF   ('&LCS' EQ 'N').GO95                                     29250017
         L     RWORK3,ADSVCB ADDRESS SVCBYTE + 1 IS ADDRESS OF     I283 29310019
         MVC   HSAVE(1),1(RWORK3)  HIARCHY BYTE IN GETMAIN         I283 29370019
.GO95    ANOP                                                           29430017
         B     SETLSTED                                                 29520017
ELEREQ   L     RWORK2,0(RIN1) LENGTH OF REGION REQUEST                  29610017
         AIF   ('&RORI' EQ 'N').GO45                                    29700017
         TM    SWITCHES,X'40'   IS REQUEST FROM RORI                    29790017
         BZ    NOTELROR                                                 29880017
         OI    SWITCHES,X'20'      SET ONE DONE SWITCH                  29970017
NOTELROR DS    0H                                                       30060017
.GO45    ANOP                                                           30150017
         AIF   ('&LCS' EQ 'N').GO43                                     30240017
         MVC   HSAVE(4),4(RIN1)    SAVE HIARCHY INDICATION              30330017
.GO43    ANOP                                                           30420017
SETLSTED DS    0H                                                       30510017
         AIF   ('&LCS' EQ 'N').GO44                                     30600017
         OI    SWITCHES,X'04'     SET END OF LIST INDICATION            30690017
.GO44    ANOP                                                           30780017
         B     NOSET1                                                   30870017
FREXCHNG OI    SWITCHES,X'80'     INDICATE REQUEST IS EXCHANGE          30960017
         L     RWORK1,ADSVCB       ADDRESS OF SVC BYTE                  31050017
         CLI   0(RWORK1),4          IS THIS AN SVC 4                    31140017
         BNE   FREEPART                                                 31230017
         OI    SWITCHES,X'01'  INDICATE SVC 4                           31320017
FREEPART L     RRET,PURGE                                               31410017
         BALR  RRET,RRET          BRANCH TO COPURGE                     31500017
         NOP   *+4                                                      31590017
         AIF   (NOT &MP).MP02PTM                                   MP1A 31610017
FREEMPST DS    0H                                                       31630017
.MP02PTM ANOP                                                      MP1A 31650017
         AIF   ('&RORI' EQ 'N').GO86                                    31680017
          L     RWORK2,RORIQUE PICK UP ADDRS OF QUEUED ROLLOUT REQUESTS 31770017
          L     RWORK2,0(RWORK2)                                        31860017
          LTR  RWORK2,RWORK2 ARE ANY REQUESTS OUTSTANDING               31950017
         BZ    SETINIT  NO CONTINUE                                     32040017
         LR    RWORK1,RBASE SAVE BASE REGISTER OF GETPART               32130017
         L     RBASE,GETIQE GET ADDRESS OF GETIQE SUBROUTINE            32220017
         BALR  RCOMRET,RBASE  GET AN IQE                                32310017
         LR    RBASE,RWORK1  RESTORE BASE                               32400017
         SR    RWORK1,RWORK1                                            32490017
         L     RWORK2,ADDRSNEW PICK UP ADDRESS OF 'NEW'                 32580017
         ST    RWORK1,0(RWORK2) ZERO OUT NEW TO CAUSE TASK SWITCH       32670017
         ST    RWORK1,4(RIQE) ZERO LINK FIELD OF IQE FOR DEQUEUE        32760017
         LCR   RIQE,RIQE  COMPLEMENT IQE ADDRESS                        32850017
         L     RRETURN,16(0) PICK UP CVT                                32940017
         L     RRETURN,CVT0EF00(RRETURN)                                33030017
         BALR  RRETURN,RRETURN  SCHEDULE IRB FOR ROLLOUT                33120017
SETINIT  DS    0H                                                       33210017
.GO86    ANOP                                                           33300017
         CLI   WAITSW,X'FF'    WAIT SWITCH ON                           33390017
         BE    WAITOFF                                                  33480017
         AIF   ('&LCS' EQ 'N').GO86A                             A32425 33482020
         TM    SWITCHES+1,X'02' .    WAS REQ SATISFIED           A32425 33490020
         BO    SUBPOLCK .            NO, RELE SPQE FROM SQA      A32425 33500020
.GO86A   ANOP                                                    A32425 33550020
         BAL   RCOMRET,DISPINIT                                         33570017
         SPACE 1                                                        33660017
*                                                                       33750017
*        THIS ROUTINE RELEASES THE EIGHT BYTES IN SUBPOOL 252 USED TO   33840017
*        RESERVE A 2K BLOCK                                             33930017
*                                                                       34020017
SUBPOLCK EQU   *                   ENTRY TO RELEASE STORAGE        MP1A 34040017
         AIF   (NOT &MP).MP06                                      MP1A 34060017
         TM    SWITCHES+1,X'40'   TEST FOR A MP BRANCH ENTRY       MP1A 34080017
         BO    RETURN  YES - BYPASS RELEASE STORAGE                MP1A 34100017
.MP06    ANOP                                                      MP1A 34120017
         L     RSPQE,TCBMSS(RTCB)  PICK UP ADDRESS OF FIRST SPQE   MP1A 34140017
         LA    RSPQE,0(RSPQE)     CLEAR HI ORDER BYTE                   34200017
         LTR   RSPQE,RSPQE         Q-TCBMSS ZERO                   MP2K 34230018
         BZ    RETURN              YES EXIT                        MP2K 34260018
         B     SPQE252B                                                 34290017
SPQE252  L     RSPQE,0(RSPQE)     PICK UP NEXT SPQE                     34380017
SPQE252B CLI   SPQID(RSPQE),252   IS IT SPQE FOR SUBPOOL 252            34470017
         BE    SPQE252A                                                 34560017
         TM    SPQEFLGS(RSPQE),SPQELAST                                 34650017
         BC    1,SPQECHK2         LAST SPQE                             34740017
         B     SPQE252            CHECK NEXT SPQE                       34830017
SPQE252A L     RDQE,SPQEDQE(RSPQE) PICK UP ADDRESS OF DQE               34920017
         LA    RDQE,0(RDQE)                                             35010017
         LTR   RDQE,RDQE          HAS SUBPOOL 252 BEEN FREED            35100017
         BZ    SPQECHK2           YES                                   35190017
         L     RFQE,DQEFQE(RDQE)  PICK UP ADDRESS OF FQE                35280017
         L     RIN1,FQELNTH(RFQE) PICK UP LENGTH FROM FQE               35370017
         C     RIN1,FQE252  IS 2K BLOCK FREE EXCEPT FOR 8 BYTES    3645 35460018
         BNE   GERROR2 ALL CORE NOT FREE   (GERROR2)                    35550017
         LA    RFQE,0(RFQE)        CLEAR HIGH ORDER BYTE                35640017
         AR    RIN1,RFQE  COMPUTE ADDRESS OF CORE TO BE FREED           35730017
         L     RIN0,RESERVE       SET UP REG 0 FOR REGMAIN              35820017
         L     RRETURN,REGMAIN    PICK UP ADDRESS OF REGMAIN            35910017
         BALR  RRETURN,RRETURN    FREE 8 BYTES USED TO RESERVE 2K BLCOK 36000017
         SPACE 1                                                        36090017
SPQECHK2 L     RSPQE,TCBMSS(RTCB) PICK UP SPQE POINTER                  36180017
         LA    RSPQE,0(RSPQE)     CLEAR HI ORDER BYTE                   36270017
         LTR   RSPQE,RSPQE         Q-TCBMSS ZERO                   MP2K 36300018
         BZ    RETURN              YES EXIT                        MP2K 36330018
SPQECHK  L     RDQE,SPQEDQE(RSPQE) PICK UP DQE POINTER FROM SPQE        36360017
         TM    SPQEFLGS(RSPQE),SPQESHRD  IS THIS A SHARED SUBPOOL       36450017
         BZ    NOSHARE1      NO NOT SHARED                              36540017
         L     RDQE,SPQEDQE(RDQE) PICK UP DQE POINTER FROM OWNER        36630017
NOSHARE1 LA    RDQE,0(RDQE) CLEAR HI ORDER BYTE                         36720017
         LTR   RDQE,RDQE          ANY STORAGE ASSIGNED TO SUBPOOL       36810017
         BC    7,GERROR2  ERROR                                         36900017
         TM    SPQEFLGS(RSPQE),SPQELAST    IS THIS LAST SPQE            36990017
         BO    FREEPQE            YES                                   37080017
         L     RSPQE,SPQENXT(RSPQE) NO- PICK UP POINTER TO NEXT SPQE    37170017
         B     SPQECHK             CHECK NEXT SUBPOOL                   37260017
FREEPQE  DS    0H                                                       37440017
         AIF   ('&LCS' EQ 'N').GO52                                     37530017
         TM    SWITCHES,X'80'      IS THIS AN EXCHANGE REQUEST          37620017
         BO    YESEXCH0       YES - JUST FREE THE REGION NOT THE PQE    37710017
         L     RIN1,TCBPQE(RTCB)                                        37750017
         LA    RIN1,0(RIN1)        CLEAR HI ORDER BYTE         @AS77039 37760000
         LTR   RIN1,RIN1           CHECK FOR ZERO              @AS77039 37770000
         BZ    RETURN              IF ZERO RETURN V1           @AS77039 37780000
         MVC   PQESAVE(4),PQEPREV(RIN1) SAVE ADDR OF LAST OR ONLY PQE   37800017
         L     RIN1,PQEPREV(RIN1)  LAST PQE                             37890017
FRNXTPQE L     RBLOCK,FWDPTR(RIN1) ADDRESS OF PARTITION                 37980017
         L     RSIZE,FBQESIZE(RBLOCK)   PICK UP PARTITION SIZE          38070017
         L     RPQE,OVRFLB                                              38160017
         L     RPQE,8(RPQE)   POINTER TO DUMMY                          38250017
         L     RPQE,PQENXT(RPQE)       &OINTER TO FIRST PQE             38340017
         CLI   PQEHID(RIN1),X'01'  WAS THIS PQE FOR H1                  38430017
         BNE   NOTPQEH1       NO                                        38520017
         OC    PQENXT(4,RPQE),PQENXT(RPQE) IS THERE AN H1 PQE OFF GOVFB 38610017
         BZ    NOTPQEH1       NO GIVE CORE BACK TO H0 PQE               38700017
         L     RPQE,PQENXT(RPQE)      H1 PQE                            38790017
NOTPQEH1 L     RCOMRET,RELEASE                                          38880017
         OC    PQEPREV(4,RIN1),PQEPREV(RIN1)  IS THIS THE LAST PQE      38970017
         BNZ   NLASTPQE    NO                                           39060017
         OI    SWITCHES+1,X'01'  INDICATE LAST PQE                      39150017
NLASTPQE BALR  RCOMRET,RCOMRET  GO TO MRELEASE TO FREE REGION           39240017
         L     RIN1,PQESAVE  PQE TO BE FREED                            39330017
         L     RWORK1,PQEPREV(RIN1)   ADDRESS OF NEXT PQE TO BE FREED   39420017
         L     OWNGTCB,PQETCB(RIN1) .   GET OWNING TCB       BL   M0459 39460021
         ST    RWORK1,PQESAVE                                           39510017
         L     RIN0,QELNTH    SET REG 0 FOR REGMAIN                     39600017
         L     RRETURN,REGMAIN                                          39690017
         BALR  RRETURN,RRETURN  FREE PQE                                39780017
         TM    SWITCHES+1,X'01'   WAS THIS LAST PQE                     39870017
         BO    ALLBUTDM                                                 39960017
         L     RIN1,PQESAVE     NEXT PQE TO BE FREED                    40050017
         B     FRNXTPQE                                                 40140017
         AGO   .GO54                                                    40230017
.GO52    ANOP                                                           40320017
         L     RIN1,TCBPQE(RTCB)  PICK UP ADDRESS OF DUMMY              40410017
         LA    RIN1,0(RIN1) . CLEAR HIGH ORDER BYTE            @JK69389 40430021
         LTR   RIN1,RIN1 .    IS  IT ZERO                      @JK69389 40450021
         BZ    RETURN .       YES                              @JK69389 40470021
         L     RIN1,DUMFWD(RIN1)  PICK UP PQE ADDRESS                   40500017
         ST    RIN1,PQESAVE   SAVE PQE ADDR FOR USE IN GETPART          40590017
         L     RBLOCK,FWDPTR(RIN1) ADDRESS OF PARTITION                 40680017
         L     RSIZE,FBQESIZE(RBLOCK)  PICK UP PARTITION SIZE           40770017
         L     RPQE,OVRFLB                                              40860017
         L     RPQE,8(RPQE)   ADDRESS OF SYSTEM DUMMY                   40950017
         L     RPQE,DUMBWD(RPQE)                                        41040017
         L     RCOMRET,RELEASE                                          41130017
         BALR  RCOMRET,RCOMRET            RELEASE PARTITION             41220017
         TM    SWITCHES,X'80' .         IS THIS AN EXCHANGE      A36202 41270021
         BO    YESEXCH1 .                   REQUEST              A36202 41280021
         AIF   (NOT &MP).MP01                                      MP1A 41310017
         STM   R0,R15,VQERSAV     SAVE REGS WHILE TEST FOR VQES    MP1A 41400017
         L     R2,TCBPQE(RTCB)    ADDR OF DUMMY PQE                MP1A 41490017
         L     R2,DUMFWD(R2)      ACTUAL PQE                       MP1A 41580017
         BAL   R1,IFSVRYOF        TEST IF VQE WAIT FOR PARTN STRG  MP1A 41670017
         USING *,R1               ADDRESSSIBILITY                  MP1A 41760017
         LM    R0,R15,VQERSAV     RESTORE REGS                     MP1A 41850017
         DROP  R1                                                  MP1A 41940017
.MP01    ANOP                                                           42030017
         L     RIN1,TCBPQE(RTCB)       ADDRESS OF DUMMY                 42300017
         L     RIN1,DUMFWD(RIN1)   ACTUAL PQE                           42390017
         L     OWNGTCB,PQETCB(RIN1) .   GET OWING TCB        BL   M0459 42430021
         L     RIN0,QELNTH SET REG 0 FOR REGMAIN                        42480017
         L     RRETURN,REGMAIN                                          42570017
         BALR  RRETURN,RRETURN     FREE REAL PQE                        42660017
.GO54    ANOP                                                           42750017
ALLBUTDM L RIN1,TCBPQE(RTCB)  POINTER TO DUMMY - 8                      42840017
         LA    RIN1,8(RIN1)       POINTER TO DUMMY                      42930017
         L     RIN0,DUMQELTH      SET REG 0 FOR REGMAIN FOR DUMMY       43020017
         L     RRETURN,REGMAIN                                          43110017
         XC    TCBPQE(4,OWNGTCB),TCBPQE(OWNGTCB) . 0 TCBPQE  BL   M0459 43150021
         XC    TCBPQE(4,RTCB),TCBPQE(RTCB) SET TCB POINTER TO ZERO      43200017
         BALR  RRETURN,RRETURN                                          43290017
         B     RTN00                                                    43380017
         AIF   ('&LCS' EQ 'N').GO55                                     43470017
YESEXCH0 L RIN1,TCBPQE(RTCB)   DUMMY                                    43560017
         L     RIN1,DUMFWD(RIN1)   FIRST PQE                            43650017
         CLI   PQEHID(RIN1),X'00'  IS THIS H0 PQE                       43740017
         BE    RIGHTPQE                                                 43830017
         OC    PQENXT(4,RIN1),PQENXT(RIN1) NO - IS THIS ONLY PQE ? I283 43860019
         BE    RIGHTPQE            YES - REPLACING H1 SEGMENT      I283 43890019
         L     RIN1,PQENXT(RIN1)   THIS MUST BE H0 PQE                  43920017
RIGHTPQE L     RBLOCK,FWDPTR(RIN1) ADDRESS OF PARTITION                 44010017
         L     RSIZE,PQERGSZ(RIN1)   ADDR OF REGION TO BE FREED         44100017
         ST    RIN1,PQESAVE   SAVE PQE ADDR FOR USE IN GETPART          44190017
         L     RPQE,OVRFLB                                              44280017
         L     RPQE,8(RPQE)       ADDRESS OF DUMMY                      44370017
         L     RPQE,PQENXT(RPQE)   ADDRESS OF H0 PQE                    44460017
         L     RWORK3,ADSVCB       ADDR TABLE IN GETMAIN WITH      I283 44468019
*                                   HIARCHY BYTE                   I283 44476019
         MVI   1(RWORK3),0         GETPART IS FOR H0 AT THIS PT.   I283 44484019
         CLC   PQEHID(1,RPQE),PQEHID(RIN1) REPLACING H1 SEGMENT ?  I283 44492019
         BE    SAMEID              NO - RETURN CORE TO H0 PQE      I283 44500019
         MVI   1(RWORK3),1           GETPART FOR H1                I283 44508019
         OC    PQENXT(4,RPQE),PQENXT(RPQE) IS 2361 ONLINE ?        I283 44516019
         BE    SAMEID              NO - RETURN CORE TO H0 PQE      I283 44524019
         L     RPQE,PQENXT(RPQE)   RETURN CORE TO H1 PQE           I283 44532019
SAMEID   DS    0H                                                  I283 44540019
         L     RCOMRET,RELEASE                                          44550017
         BALR  RCOMRET,RCOMRET     RELEASE PARTITION                    44640017
.GO55    ANOP                                                           44730017
YESEXCH1 LM    RRETURN,RIN1,RINSAVE                                     44820017
         TM    SWITCHES,X'01' IS REQUEST SVC 4                          44910017
         BO    GPART                                                    45000017
         LR    RLENGTH,RIN0                                        SWS  45060018
         LA    RLENGTH,0(RLENGTH)  CLEAR HIGH ORDER BYTE           I283 45120019
         B     REGREQ                                                   45180017
COMRTN0 DS     0H                                                       45270017
         AIF   ('&LCS' EQ 'N').GO57                                     45360017
         L     RWORK1,TCBPQE(RTCB)   POINTER TO DUMMY                   45450017
         L     RWORK1,PQENXT(RWORK1)    FIRST PQE                       45540017
         OC    PQENXT(4,RWORK1),PQENXT(RWORK1) ARE THERE 2 PQE'S        45630017
         BZ    NOCKNEED       NO                                        45720017
         L     RWORK2,PQENXT(RWORK1)                                    45810017
         CLC   PQESTADD(4,RWORK1),PQESTADD(RWORK2) ARE PQE'S IN         45900017
         BL    NOCKNEED    ASCENDING ORDER  -  YES                      45990017
         MVC   PQENXT(4,RWORK2),PQEPREV(RWORK2)   SWAP PQE'S            46080017
         MVC   PQEPREV(4,RWORK2),ZEROES                                 46170017
         MVC   PQEPREV(4,RWORK1),PQENXT(RWORK1)                         46260017
         MVC   PQENXT(4,RWORK1),ZEROES                                  46350017
         L     RWORK1,TCBPQE(RTCB)   NOW SWAP DUMMY                     46440017
         MVC   PQESAVE(4),PQENXT(RWORK1)                                46530017
         MVC   PQENXT(4,RWORK1),PQEPREV(RWORK1)                         46620017
         MVC   PQEPREV(4,RWORK1),PQESAVE                                46710017
NOCKNEED DS    0H                                                       46800017
.GO57    ANOP                                                           46890017
         TM    SWITCHES,X'C0'  IS THIS AN EXCHANGE OR RORI REQ. ?       46980017
         BNZ   RTN00               YES                                  47070017
         CLI   WAITSW,X'FF'        WAIT SW ON                           47160017
         BNE   RTN00         NO RETURN                                  47250017
         TM    SWITCHES,X'08'                  G/P SPEC REG       M3865 47300020
         BZ    RTN00                            NO RETURN         M3865 47310020
         BAL   RCOMRET,DISPINIT  SET INITIATORS WAITING FOR A REGION    47340017
***                          DISPATCHABLE                               47430017
         MVI   WAITSW,X'00'  TURN OFF WAIT SW                           47520017
         B     RTN00                                                    47610017
*                                                                       47616018
*                                                                       47622018
*  THIS ROUTINE IS ENTERED TO SCAN THE TCB READY QUEUE FOR TASKS   SWS  47628018
* WHICH ARE NON-DISPATCHABLE EITHER BECAUSE A GETPART COULD NOT BE SWS  47634018
* SATISFIED OR BECAUSE THE 2K THRESHOLD ON QUEUE SPACE HAD BEEN    SWS  47640018
* REACHED.                                                         SWS  47646018
*  IT IS ENTERED EITHER WHEN A FREEPART IS ISSUED OR A FREEMAIN FORSWS  47652018
* QUEUE SPACE.                                                     SWS  47658018
*  IT WILL RESET THE FLAG IN GOVRFLB IN ORDER TO PREVENT FREEMAIN  SWS  47664018
* FROM EXECUTING THIS ROUTINE WHEN IT IS NOT NECESSARY.            SWS  47670018
*  FREEMAIN E WILL EXECUTE THIS SUBROUTINE ONLY WHEN THE FLAG      SWS  47676018
* IS ON.                                                           SWS  47682018
         SPACE 4                                                        47688018
DISPINIT STM   RIN0,RSIZE,RIPSAVE  SAVE ALL XRS                    SWS  47708018
         L     RCVT,OVRFLB        GET ADDRESS OF GOVRFLB           SWS  47728018
         NI    0(RCVT),X'7F'       RESET GOVRFLB FLAG            A29400 47758019
         L     RCVT,16(0)               LOAD CVT POINTER                47790017
         L     TSWCH,CVTHEAD(RCVT) LOAD HIGHEST PRIORITY TCB IN SYSTEM  47880017
RIP1     LTR   TSWCH,TSWCH         ARE WE AT END OF READY QUEUE         47970017
         BC    7,RIP2              YES - RETURN                         48060017
         LM    RIN0,RSIZE,RIPSAVE  RESTORE XRS                     SWS  48150018
         BR    RCOMRET                                                  48240017
RIP2     TM    TCBFCD1(TSWCH),2    IS TCB IN WAIT FOR CORE              48330017
         BZ    RIP3                NO - GET NEXT TCB                    48420017
         AIF   ('&RORI' EQ 'N').GO88                                    48510017
         L     RWORK1,TCBPQE(TSWCH)                                     48600017
         LTR   RWORK1,RWORK1                                            48690017
         BNZ   RIP3                                                     48780017
.GO88    ANOP                                                           48870017
         NI    TCBFCD1(TSWCH),X'FD' TURN OFF WAIT BIT                   48960017
         LR    RSWCH,RBASE         SAVE BASE REGISTER OVER TSWITCH      49050017
         L     RBASE,TASKSWCH      GO TO TASK SWITCH ROUTINE            49140017
         BALR  RRETURN,RBASE                                            49230017
         LR    RBASE,RSWCH         RESTORE BASE REG                     49320017
RIP3     L     TSWCH,TCBTCB(TSWCH) NEXT TCB ON READY QUEUE              49410017
         B     RIP1                                                     49500017
RTN08    LA    RRETREG,8                                                49590017
         B     RETURN                                                   49680017
RTN04    LA    RRETREG,4                                                49770017
         TM    SWITCHES,X'08'  WAS REQUEST SPECIFIC                     49860017
         BZ    CKFORIWT                                                 49950017
         L     RWORK1,RINSAVE+12   R1 AT ENTRY                 @AS75900 49970000
         TM    8(RWORK1),X'20'     CONDITIONAL REQUEST         @AS75900 49990000
         BO    RETURN              YES,NO WAIT NEEDED          @AS75900 50010000
         MVI   WAITSW,X'FF'  TURN ON WAIT SW                            50040017
         ST    RTCB,TCBSAVE                                             50130017
CKFORIWT TM    SWITCHES,X'01' IS REQUEST SVC 4                          50220017
         BZ    INITWAIT            NO CAN'T BE A CONDITIONAL REQUEST    50310017
         L     RWORK1,RINSAVE+12   R1 WHEN ENTERED                      50400017
         TM    8(RWORK1),X'20'     WAS REQUEST CONDITIONAL              50490017
         BZ    INITWAIT       NO - NOT CONDITIONAL                      50580017
RETURN   L     RRETURN,RINSAVE                                          50670017
         LM    RIN0,RIN1,RINSAVE+8 RESTORE REGS                         50760017
         AIF   ('&RORI' EQ 'N').GO64                                    50850017
         TM    SWITCHES,X'40'  IS REQUEST FROM RO/RI                    50940017
         BZ    NORORI      NO                                           51030017
         LTR   RRETREG,RRETREG  HAS REQUEST BEEN SATISFIED              51120017
         BP    NORORI   NO                                              51210017
         L     RWORK1,4(RIN1)  POINTER TO PARM LIST ENTRY               51300017
         MVC   0(4,RWORK1),PQESAVE  PLACE ADDRESS OF PQE IN PARM LIST   51390017
.GO64    ANOP                                                           51480017
NORORI   BR    RRETURN  RETURN                                          51570017
INITWAIT OI    TCBFCD1(RTCB),2     INDICATE INITIATOR WAITING FOR       51660017
**                             PARTITION OR SQS SPACE                   51750017
         XC    TCBPQE(4,RTCB),TCBPQE(RTCB)                              51840017
         L     RWORK1,36       LOAD RIGHT HALF OF PSW                   51930017
         LA    RWORK2,2                                                 52020017
         LTR   RWORK1,RWORK1  TEST ILC                         @JK69024 52040021
         BNM   STUPRISS .     ILC FOR HALF WORD                @JK69024 52060021
         AR    RWORK2,RWORK2  ILC FOR FULL WORD                @JK69024 52080021
STUPRISS SR    RWORK1,RWORK2  ADDRESS FOR REISSUE              @JK69024 52110021
         ST    RWORK1,36       STORE PSW                                52200017
         L     RCVT,16(0)      RELOAD CVT ADDR                          52290017
         L     RWORK3,CVTTCB(RCVT)  LOAD ADDRESS OF NEW                 52380021
         CLC   0(4,RWORK3),4(RWORK3)                                    52470017
         BNE   RETURN .                                                 52520021
         SR    RWORK1,RWORK1                                            52650017
         ST    RWORK1,0(RWORK3)  SET NEW TO 0  CAUSE TASK SWITCH        52740017
         B     RETURN .                                                 52860021
RTN00    LA    RRETREG,0                                                52920017
         AIF   ('&LCS' EQ 'N').GO82                                     53010017
         TM    SWITCHES+1,X'06'  WAS THIS AN UNSATISFIED REQUEST        53100017
         BO    RTN08             YES - FROM RETURN08                    53190017
         BM    RTN04             YES - FROM FBQSRCH                     53280017
.GO82    ANOP                                                           53370017
         B     RETURN                                                   53460017
GERROR2  LA    RIN1,X'20A'  SUBTASKS EXIST FOR THE TASK REQUESTING GET, 53550017
***            FREE,OR REPLACE PARTITION                                53640017
         L     RRETURN,SVCXT      LOAD ADD OF SVC EXIT ROUTINE     8499 53650017
         L     RTCB,16(0)         GET THE CVT ADDRESS              8499 53660017
         L     RTCB,0(RTCB)       GET THE NEW/OLD DOUBLE WD (PSW)  8499 53670017
         L     RTCB,4(RTCB)       TCB OF CURRENT TASK TO ABTERM    8499 53680017
         TM    TCBTSTSK(RTCB),TSOTASK .IF TSO TASK, THEN          21016 53685021
         BO    GERROR2C .                DON'T MAKE ENTRY         21016 53690021
         L     RCVT,16(0) .            ADDR CVT                   21016 53695021
         L     RCVT,CVTQMSG(RCVT) .    ADDR INFOLIST              21016 53702021
         L     RABTERM,0(RCVT) .       END OF INFOLIST         AC 21016 53710021
         LA    RCVT,4(RCVT) .          FIRST ENTRY                21016 53715021
*                                                                 21016 53720021
         USING INFOLIST,RCVT .                                    21016 53725021
*                                                                 21016 53730021
GERROR2A CR    RCVT,RABTERM  .         NO ROOM FOR ENTRY          21016 53735021
         BNL   GERROR2C .               - THEN BYPASS          AC 21016 53740021
         CLC   ZEROES,INFTCB .         THIS ENTRY AVAILABLE?      21016 53745021
         BE    GERROR2B .              YES. GO SET UP INFO        21016 53750021
         LA    RCVT,INFLEN(RCVT) .     NO. CHECK IF MORE ENTRIES  21016 53755021
         B     GERROR2A .              SEARCH ALL ENTRIES.        21016 53760021
GERROR2B ST    RTCB,INFTCB .           SET UP TCB ADDRESS         21016 53765021
         TM    TCBTSTSK(RTCB),TSOTASK . IS THIS A TSO TASK    AC A49808 53767021
         BZ    ERRM2 .                 NO, BYPASS USERID      AC A49808 53769021
         L     Q13,TCBJSCB(RTCB) .     ADDR OF JSCB           AC A49808 53769821
         LA    Q13,0(Q13) .            CLEAR HI BYTE          AC A49808 53769921
         MVC   INFTJID(2),JSCBTJID(Q13) .USER ID IN INFO LIST AC A49808 53774221
ERRM2    EQU   * .                                            AC A49808 53778221
         STH   RIN1,INFCC .            SET COMPLETION CODE        21016 53779221
         ST    RTCB,INFVAR1 .          @TCB                       21016 53783521
         MVC   INFVAR2(1),4(RSPQE) .   SPID                       21016 53787821
         OI    INFRCL,X'05' .          LENGTH                     21016 53792121
         DROP    RCVT                                             21016 53796421
GERROR2C L     RABTERM,ABTERM .                                   21016 53800721
         L     RCVT,16(0) .        GET CVT ADDR FOR ABTERM   BL   M1531 53805021
         BR    RABTERM                                                  53820017
CKTCB    C     RTCB,TCBSAVE        IS THIS THE INITIATOR THAT IS        53910017
         BE    TCBOK           WAITING - TRY FOR REGION                 54000017
         B     INITWAIT                                                 54090017
WAITOFF  L     TSWCH,TCBSAVE    ADDR OF WAITING TCB                     54180017
         NI    TCBFCD1(TSWCH),X'FD'  TURN OFF WAIT BIT                  54270017
         LR    RSWCH,RBASE SAVE BASE REGISTER OVER TSWITCH              54360017
         L     RBASE,TASKSWCH YES- GO TO TASK SWITCH ROUTINE            54450017
         BALR  RRETURN,RBASE                                            54540017
         LR    RBASE,RSWCH  RESTORE BASE REGISTER                       54630017
         B     SUBPOLCK                                                 54810017
         AIF   ('&LCS' EQ 'N').GO69                                     54900017
RETURN08 OI    SWITCHES+1,X'06'  INDICATE UNSATISFIED REQUEST           54990017
         TM     SWITCHES,X'20'    CHECK ONE DONE SWITCH                 55080017
         BZ    RTN08                                                    55170017
         AIF    ('&RORI' EQ 'N').GO70                                   55260017
         TM    SWITCHES,X'40'    IS THIS A RORI REQUEST                 55350017
         BO    RTN04             DON'T FREE CORE                        55440017
.GO70    ANOP                                                           55530017
         B     FREEPART                                                 55620017
.GO69    ANOP                                                           55710017
         AIF   (NOT &MP).MP03PTM                                   MP1A 55717017
IEAMPSTR DS    0H                                                       55724017
         BALR  RBASE,RIN0    ESTABLISH ADDRESSIBILITY              MP1A 55731017
         USING MPBASPTM,RBASE                                      MP1A 55738017
MPBASPTM L     RBASE,PARTBASE  PICK UP BASE ADDRESS                MP1A 55745017
         USING PART,RBASE                                          MP1A 55752017
         STM   RRETURN,RIN1,RINSAVE     SAVE REGS                  MP1A 55759017
         MVC   SWITCHES(3),ZEROES  CLEAR SWITCHES                  MP1A 55766017
         OI    SWITCHES+1,X'40'   SET MP SW FOR BRANCH ENTRY       MP1A 55773017
         B     FREEMPST    SKIP SUBPOOL CHECKING                   MP1A 55780017
.MP03PTM ANOP                                                      MP1A 55787017
*********************************************************************** 55800017
*        THIS SECTION OF CODE OBTAINS CORE AT AN ACTUAL ADDRESS       * 55890017
*                                                                     * 55980017
*        OUTPUT =  RSISE= SIZE OF REGION OBTAINED IN BYTES            * 56070017
*                                                                     * 56160017
*                  RBLOCK=ADDRESS OF REGION OBTAINED                  * 56250017
*                                                                     * 56340017
*        RETURNS- COREOK = REGION OBTAINED                            * 56430017
*                                                                     * 56520017
*                SRTN04 = REGION CANNOT NOW BE OBTAINED               * 56610017
*                                                                     * 56700017
*                SRTN08 = INVALID REQUEST                             * 56790017
*                                                                     * 56880017
*********************************************************************** 56970017
GETSPEC  OI    SWITCHES,X'08'  INDICATE REQUEST SPECIFIC                57060017
         LA    RWORK2,0(RWORK2) CLEAR END OF LIST INDICATOR             57150017
         L     RWORK1,OVRFLB    GOVRFLB                                 57240017
         L     RWORK1,8(RWORK1)         POINTER TO DUMMY  -  8          57330017
         L     RWORK1,PQENXT(RWORK1)  POINTER TO FIRST OR ONLY PQE      57420017
RETRY    C     RADDR,PQESTADD(RWORK1) IS THIS A VALID REQUEST           57510017
         BL    SRTN08            INVALID REQUEST NOT WITHIN FREE CORE   57600017
         L     RWORK3,PQESTADD(RWORK1) BEGIN ADDRESS OF SYSTEM PQE      57690017
         A     RWORK3,PQERGSZ(RWORK1)   END ADDRESS +1 OF SYSTEM REGION 57780017
         CR    RADDR,RWORK3             IS REQUEST VALID FOR THIS PQE   57870017
         AIF   ('&LCS' EQ 'N').GO72                                     57960017
         BNL   TRYOTHR                                                  58050017
         AGO   .GO73                                                    58140017
.GO72    ANOP                                                           58230017
         BNL   SRTN08                                                   58320017
.GO73    ANOP                                                           58410017
         ST    RWORK2,WK2SV                                             58500017
         AR    RWORK2,RADDR       END ADDRESS + 1 OF REQUESTED REGION   58590017
         CR    RWORK2,RWORK3       IS THIS AN INVALID REQUEST           58680017
         BH    SRTN08                                                   58770017
         LR    RWORK6,RWORK1      PQE ADDRESS                           58860017
FBQELOOP L     RWORK6,FWDPTR(RWORK6)       PICK UP ADDRESS OF FBQE      58950017
         CR    RWORK1,RWORK6       END OF FBQE CHAIN                    59040017
         AIF   (&MP).MP06A                                         MP2A 59080018
         BE    SRTN04                                                   59130017
.MP06A   AIF   (NOT &MP).MP07                                      MP2A 59150018
         BE    CHKFSMAP            CHK FSSEMAP FOR OFFLINE         MP2A 59170018
.MP07    ANOP                                                      MP2A 59190018
         CR    RWORK6,RADDR        IS FBQE START GREATER THAN DESIRED   59220017
         AIF   (&MP).MP08                                          MP2A 59260018
         BH    SRTN04              YES REQUEST CANNOT BE SATISFIED      59310017
.MP08    AIF   (NOT &MP).MP09                                      MP2A 59330018
         BH    CHKFSMAP            CHK FSSEMAP FOR OFFLINE         MP2A 59350018
.MP09    ANOP                                                      MP2A 59370018
         L     RWORK4,FBQESIZE(RWORK6)                                  59400017
         AR    RWORK4,RWORK6  END ADDR + 1 OF SEGMENT DESCRIBED BY FBQE 59490017
         CR    RWORK4,RADDR        IS END ADDRESS GREATER THAN DESIRED  59580017
         BL    FBQELOOP                                                 59670017
         CR    RWORK2,RWORK4  IS END ADDR OF REQ GREATER THAN END ADDR  59760017
         AIF   (&MP).MP11                                          MP2A 59800018
         BH    SRTN04     OF FBQE - YES - CANNOT BE SATISFIED           59850017
         AIF   (NOT&MP).NMP                                        MP2A 59880018
.MP11    BH    CHKFSMAP            OF FBQE YES CANNOT BE SATISFIEDMP2A  59910018
.NMP     LR    RSIZE,RADDR                                         MP2A 59970018
         SR    RSIZE,RWORK6   DESIRED START MINUS FBQE START            60030017
         LTR   RSIZE,RSIZE    BOTH STARTS EQUAL                         60120017
         BZ    SET1                                                     60210017
         ST    RSIZE,FBQESIZE(RWORK6)                                   60300017
OTHREND  SR    RWORK4,RWORK2  END ADDR OF FBQE (-) END ADDR OF REQUEST  60390017
         LR    RBLOCK,RADDR                                             60480017
         L     RSIZE,WK2SV                                              60570017
         LTR   RWORK4,RWORK4  RESULT ZERO                               60660017
         BZ    CKSWX                                                    60750017
         TM    SWITCHES+1,X'20' IS NEW FBQE NEEDED                      60840017
         BO    USEOLD         NO                                        60930017
         ST    RWORK4,FBQESIZE(RWORK2)                                  61020017
         L     RADDR,FWDPTR(RWORK6)    OLD FBQE FWD PTR NOW NEW FWD     61110017
         ST    RADDR,FWDPTR(RWORK2)                                     61200017
         ST    RWORK2,BCKPTR(RADDR)    OLD BACK NOW POINTS TO NEW       61290017
         ST    RWORK6,BCKPTR(RWORK2)   OLD IS NOW PREVIOUS TO NEW       61380017
         ST    RWORK2,FWDPTR(RWORK6)    NEW FWD TO PREVIOUS OLD         61470017
         B     COREOK                                                   61560017
USEOLD   MVC   0(8,RWORK2),0(RWORK6) MOVE FWD/BCK PTRS TO NEW LOCATION  61650017
         ST    RWORK4,FBQESIZE(RWORK2) STORE NEW SIZE IN DISPLACED FBQE 61740017
         L     RWORK3,FWDPTR(RWORK2) STORE NEW ADDR IN BACK POINTER     61830017
         ST    RWORK2,BCKPTR(RWORK3)   OF THE FOLLOWING FBQE            61920017
         L     RWORK3,BCKPTR(RWORK2) STORE NEW ADDR IN FORWARD PTR      62010017
         ST    RWORK2,FWDPTR(RWORK3)   OF THE PREVIOUS FBQE             62100017
         B     COREOK                                                   62190017
CKSWX    TM    SWITCHES+1,X'20'  SHOULD FBQE BE ELIMINATED              62280017
         BZ    COREOK        NO                                         62370017
         L     RWORK4,BCKPTR(RWORK6)    PREVIOUS OF ONE TO ELIMINATE    62460017
         L     RADDR,FWDPTR(RWORK6)     NEXT OF ONE TO ELIMINATE        62550017
         ST    RADDR,FWDPTR(RWORK4)                                     62640017
         ST    RWORK4,BCKPTR(RADDR)                                     62730017
         B     COREOK                                                   62820017
SRTN08   DS    0H                                                       62910017
         AIF   ('&LCS' EQ 'N').GO76                                     63000017
         B     RETURN08                                                 63090017
         AGO   .GO80                                                    63180017
.GO76    ANOP                                                           63270017
         B     RTN08                                                    63360017
.GO80    ANOP                                                           63450017
         AIF   ('&LCS' EQ 'N').GO74                                     63540017
TRYOTHR  TM    SWITCHES+1,X'10'         SECOND PQE ALREADY TRIED        63630017
         BO    SRTN08                                                   63720017
         L     RWORK1,PQENXT(RWORK1)    OBTAIN NEXT PQE                 63810017
         OI    SWITCHES+1,X'10'        INDICATE NOW ON SECOND PQE       63900017
         B     RETRY                                                    63990017
.GO74    ANOP                                                           64080017
SET1     OI    SWITCHES+1,X'20' INDICATE REQUEST AND FBQE START EQUAL   64170017
         B     OTHREND                                                  64260017
         AIF   ('&RORI' EQ 'N').GO78                                    64350017
RORI     OI    SWITCHES,X'40'       INDICATE RORI REQUEST               64440017
         B     CKSVCBYT                                                 64530017
.GO78    ANOP                                                           64620017
PQENH1A  L     RIN1,PQESAVE                                             64710017
         B     PQENH1                                                   64800017
         AIF   (NOT &MP).MP05A                                     MP2A 64802018
         SPACE 2                                                        64804018
*        THIS RTN HAS BEEN ADDED FOR C/R IN AN MP SYSTEM.          MP2A 64806018
*        IT INTERCEPTS REQUESTS FOR A SPECIFIC REGION THAT         MP2A 64808018
*        CANNOT BE SATISFIED. IF ANY OF THE SPECIFIED 2K           MP2A 64810018
*        BLOCKS IS MARKED OFFLINE IN THE FSSEMAP, RETURN           MP2A 64812018
*        IS MADE TO CALLER VIA RTN08.   OTHERWISE IT               MP2A 64814018
*        REENTERS THE MAIN CODE AT SRTN04 AS BEFORE.               MP2A 64816018
         SPACE                                                          64818018
*        REGS 7-10,12,14-15 ARE DESTROYED BUT SHOULD NOT           MP2A 64820018
*        BE REQUIRED BY CODE EXECUTED AFTER CHKFSMAP               MP2A 64822018
         SPACE                                                          64824018
*        IT USES RTN IFSSEM00. REG SYMBOLS BEGINNING WITH          MP2A 64826018
*        X ARE DEFINED IN THAT RTN.                                MP2A 64828018
         SPACE 2                                                        64830018
CHKFSMAP DS    0H                                                  MP2A 64832018
         LR    XLIMT,RWORK2        SET UP PARM FOR IFSSEM00 END ADDMP2A 64834018
         LR    XADDR,RADDR         START ADDR                      MP2A 64836018
         L     XENT,IFSSEMAP       ENTRY PT                        MP2A 64838018
         LR    RWORK2,RBASE        SAVE BASE                       MP2A 64840018
         USING PART,RWORK2         TEMP BASE                       MP2A 64842018
         DROP  RBASE MP2A                                          MP2A 64844018
CHKLOOP  BALR  XRETN,XENT                                          MP2A 64846018
         B     NONEOFF             RET HERE IF LAST 2K BLK         MP2A 64848018
         EX    XMASK,TESTMAP       HERE IF NOT LAST TEST FOR       MP2A 64850018
*                                  OFFINE IN FSSEMAP               MP2A 64852018
*        NOTE ONLY RIGHTMOST OF 2 BITS TESTED BOTH BITS1=OFFLINE   MP2A 64854018
         BZ    CHKLOOP             IF NOT CHK NEXT BLK             MP2A 64856018
         LR    RBASE,RWORK2        OFFLINE RELOAD BASE             MP2A 64858018
         B     RTN08               RETURN WITH CODE 8              MP2A 64860018
NONEOFF  LR    RBASE,RWORK2        UNAVAILABILITY OF REG NOT DUE   MP2A 64862018
*                                  TO STORAGE OFFLINE IN MP        MP2A 64864018
         B     SRTN04              RESUME NORMAL PROCESSING        MP2A 64866018
TESTMAP  TM    0(XMAPA),0          XMAPA PTS TO BYTE IN FSSEMAP    MP2A 64868018
         DROP  RWORK2                                              MP2A 64870018
         USING PART,RBASE MP2A                                     MP2A 64872018
.MP05A   ANOP                                                      MP2A 64874018
ABTERM   DC    V(IEA0AB01)                                              64890017
SVCXT    DC    V(IEA0XE00)                                         8499 64920017
* END                                                                   64950017
CON1K    DC    A(4096) .               CONSTANT OF 1K             M2883 64960020
DBASADR  DC    V(MSSBASE) .             QGM'S BASE ADDRESS        M2883 64970020
PQEMAIN  DC    V(GETMAINB)                                              64980017
OVRFLB   DC    A(GOVRFLB)                                               65070017
TASKSWCH DC    V(IEA0DS02)                                              65160017
REGMAIN  DC    V(RMBRANCH)                                              65250017
PURGE    DC    V(CDPURGE)                                               65340017
RELEASE  DC    V(MRELEASE)                                              65430017
ADSVCB   DC    V(SVCBYTE)                                               65520017
FBSRCH   DC    V(FBQSRCH)                                               65610017
         AIF   ('&RORI' EQ 'N').GO87                                    65700017
MASTER   DC    V(IEAMSTCB)  ADDRESS OF MASTER SCHEDULER TCB             65790017
GETIQE   DC    V(GETIQE) ADDRESS OF GETIQE SUBROUTINE                   65880017
RORIQUE  DC    V(IEAROQUE) ADDRESS OF QUEUE OF ROLLOUT REQUESTS         65970017
ADDRSNEW DC    V(IEATCBP) ADDRESS OF H'NEW' AND 'OLD'                   66060017
.GO87    ANOP                                                           66150017
         AIF   (NOT &MP).MP02                                      MP1A 66240017
VQERSAV  DC    16F'0'              REG SAVE AREA WHILE PROCESS VQES     66330017
PARTBASE DC    A(PART)                                             MP1A 66370017
.MP02    ANOP                                                      MP1A 66420017
RIPSAVE  DS    16F                SAVE AREA                        MP2A 66510018
TCBSAVE  DC    F'0'                                                     66600017
RINSAVE  DS    4F                                                       66690017
WK2SV    DC    F'0'                                                     66780017
SWITCHES DC    F'0'                                                     66870017
* SWITCHES  BY BIT   BYTE 0                                             66960017
*              BIT  7 =  SVC 4 REQUEST       BIT 3 =H1 SWITCH           67050017
*              BIT  6 =  UNUSED              BIT 2 = ONE DONE SWITCH    67140017
*             BIT 6 =  RO/RI REQUEST       BIT 2 =  ONE DONE SWITCH     67180017
*              BIT  5 =  END OF LIST         BIT 1 = RORI REQUEST       67230017
*              BIT  4=   SPECIFIC REQUEST    BIT 0 = EXCHANGE REQUEST   67320017
* SWITCHES BY BIT BYTE 1                                                67330017
*             BIT 7 =  UNUSED              BIT 3 =  UNUSED              67340017
*             BIT 6 = MP SW FOR BRAN ENTY  BIT 2 =  UNUSED              67350017
*             BIT 6 =  MP SW FOR BRAN ENTY BIT 2 =  UNUSED              67360017
*             BIT 5 =  UNUSED              BIT 1 =  SATISFACTORY REQ    67370017
*             BIT 4 =  UNUSED              BIT 0 =  UNUSED              67380017
WAITSW   DC    X'00'                                                    67410017
         AIF   ('&LCS' EQ 'N').GODCS00                                  67500017
ADDRSV   DS    F                                                        67590017
WORK1SV  DS    F                                                        67680017
HSAVE    DC    F'0'                                                     67770017
.GODCS00    ANOP                                                        67860017
PQESAVE  DC    F'0'                                                     67950017
ZEROES   DC    F'0'                                                     68040017
DUMQELTH DC    X'FF000008'                                              68130017
QELNTH   DC    X'FF000020'  SUBPOOL NUMBER AND LENGTH FOR PQE           68220017
RESERVE  DC    X'FC000008'                                              68310017
FQE252   DC    F'2040'                                             3645 68400018
SQSMIN   DC    F'2048'                                             3645 68490018
*                                                                       68580017
*        PQE  FIELDS                                                    68670017
*                                                                       68760017
FWDPTR   EQU   0                                                        68850017
BCKPTR   EQU   4                                                        68940017
PQENXT   EQU   8                                                        69030017
PQEPREV  EQU   12                                                       69120017
PQETCB   EQU   16                                                       69210017
PQERGSZ  EQU   20                                                       69300017
PQESTADD EQU   24                                                       69390017
PQEHID   EQU   29                                                       69480017
PQESIZE  EQU   32                                                       69570017
FBQESIZE EQU   8                                                        69660017
         AIF   (NOT &MP).MP03                                      MP1A 69750017
*                                                                       69840017
*        VQE FIELDS                                                     69930017
*                                                                       70020017
VRYPTR   EQU   0                   POINTER TO NEXT VQE                  70110017
VRYBEG   EQU   4                   LOWER BOUND OF AREA TO BE VARIED     70200017
VRYLNG   EQU   8                   LENGTH OF AREA TO BE VARIED OFFLINE  70290017
VRYECB   EQU   12                  VARY TASK ECB, POST WHEN REMOV STORG 70380017
*                                                                       70470017
*        GOVRFLB FIELDS                                                 70560017
*                                                                       70650017
SQBOUND  EQU   0                   ADDR OF FIRST BYTE BEYOND SQS        70740017
DQESQS   EQU   4                   ADDR OF DQE DESCRIBING SQS           70830017
PQEPTR   EQU   8                   ADDR OF PQE FOR UNASSIGNED STORAGE   70920017
MSBOUND  EQU   12      ADDR OF 1ST BYTE BEYOND DYNAMIC FREE AREA   MP1A 71010017
SZDPRS   EQU   12                                                  MO17 71100017
SZDLCS   EQU   16                                                  MO17 71190017
VQEPTR   EQU   20                  POINTER TO FIRST VARY QUEUE ELEMENT  71280017
.MP03    ANOP                                                      MP1A 71370017
*                                                                       71375017
CVTQMSG  EQU   X'10C' .           ADDR OF INFO LIST               21016 71376021
TSOTASK  EQU   X'80' .            TIME SHARING TASK FLAG          21016 71378021
TCBTSTSK EQU   148 .              DISP TO TIME SHARING FLAGS      21016 71379021
TCBJSCB  EQU   X'B4'              DISP OF JSCB IN TCB         AC A49808 71379421
JSCBTJID EQU   X'10C'             DISP OF USERID IN JSCB      AC A49808 71379821
Q0       EQU   0                  NUMERIC 0                        MP1A 71380017
Q1       EQU   1                  NUMERIC 1                        MP1A 71385017
Q4       EQU   4                  NUMERIC 4                        MP1A 71390017
Q8       EQU   8                  NUMERIC 8                        MP1A 71395017
Q10      EQU   10                 NUMERIC 10                       MP1A 71400017
Q11      EQU   11                 NUMERIC 11                       MP1A 71405017
Q13      EQU   13                 NUMERIC 13                       MP1A 71410017
Q2048    EQU   2048               NUMERIC 2048                     MP1A 71415017
QX01     EQU   X'01'              HEX 01                           MP1A 71420017
*                                                                       71425017
OWNGTCB  EQU   9 .         REG TO GET OWNING TCB ADD OF PQE  BL   M0459 71427021
R0       EQU   0                  REGISTER 0                       MP1A 71430017
R1       EQU   1                  REGISTER 1                       MP1A 71435017
R2       EQU   2                  REGISTER 2                       MP1A 71440017
R15      EQU   15                 REGISTER 15                      MP1A 71445017
RIN0     EQU   0                                                        71460017
RIN1     EQU   1                                                        71550017
RIQE     EQU   1                                                        71640017
RADDR    EQU   2                                                        71730017
RDQE     EQU   2                                                        71820017
RPQE     EQU   2                                                        71910017
RWORK6   EQU   3                                                        72000017
QGM2BS   EQU   3 .                   QGM' 2DN BAS REG             M2883 72040020
RCVT     EQU   3                                                        72090017
RTCB     EQU   4                                                        72180017
RSPID    EQU   5                                                        72270017
RWORK1   EQU   6                                                        72360017
RCOMRET1 EQU   7                                                        72450017
RWORK2   EQU   7                                                        72540017
RFQE     EQU   7                                                        72630017
RWORK3   EQU   9                                                        72720017
RCOMRET  EQU   9                                                        72810017
RLENGTH  EQU   10                                                       72900017
RWORK4   EQU   10                                                       72990017
TSWCH    EQU   10                                                       73080017
RBASE    EQU   11                                                       73170017
RSWCH    EQU   12                                                       73260017
RSPQE    EQU   12                                                       73350017
RRET     EQU   13                                                       73440017
RABTERM  EQU   13                                                       73530017
RRETURN  EQU   14                                                       73620017
RBLOCK   EQU   14                                                       73710017
RRETREG  EQU   15                                                       73800017
RSIZE    EQU   15                                                       73890017
SPQEDQE  EQU   4                                                        73980017
SPQENXT  EQU   0     NEXT SPQE POINTER - 1                              74070017
SPQEFLGS EQU   0     FLAG BYTE                                          74160017
SPQID    EQU   4                                                        74250017
SPQELAST EQU   X'40' MASK FOR FLAG BIT INDICATING LAST SPQE FOR TCB     74340017
SPQESHRD EQU   X'80'        MASK INDICATING SUBPOOL IS SHARED           74430017
TCBMSS   EQU   24   SPQE POINTER -1                                     74520017
TCBFCD1  EQU   33    FIFTH FLAG BYTE - BIT 6 IS USED                    74610017
TCBTCB   EQU   116                                                      74700017
TCBOTC   EQU   132                                                      74790017
TCBPQE   EQU   152                                                      74880017
CVTTCB   EQU   0                                                        74970017
CVT0EF00 EQU   4                                                        75060017
CVTHEAD  EQU   160                                                      75150017
FQENXT   EQU   0                                                        75240017
FQELNTH  EQU   4                                                        75330017
DQEFQE   EQU   0                                                        75420017
DUMPQESZ EQU   8                                                        75510017
DUMFWD   EQU   8                                                        75600017
DUMBWD   EQU   12                                                       75690017
         AIF   (NOT &MP).MP04                                      MP1A 75780017
         TITLE 'V A R Y    S T O R A G E    O F F L I N E'              75870017
*           INPUT - XPQE - ADDR OF PQE FOR PARTITION BEING PROCESSED    75960017
*                   XITR - RETURN ADDRESS                               76050017
*           OUTPUT - FREE STORAGE FBQE CHAIN IS MODIFIED                76140017
*                  - FSSEMAP IS UPDATED TO INDICATE STORAGE REMOVED     76230017
*                  - POST 'VARY TASK' TO INDICAT STORAG WAS PUT OFFLINE 76320017
*           REGISTERS 3-15 ARE DESTROYED BY THE VARY OFFLINE ROUTINE.   76410017
*             THE USER IS RESPONSIBLE FOR SAVNG AND RESTORNG THESE REGS 76500017
         SPACE                                                          76590017
         ENTRY IFSVRYOF                                                 76680017
IFSVRYOF BALR  XBASE,R0           VARY STOARGE OFFLINE SUBR        MP1A 76770017
         USING IEAQFX00,R0        ADDRESSIBILITY                   MP1A 76860017
         USING IFSVRYBS,XBASE                                           76950017
IFSVRYBS DS    0H                  BASE ADDRESS                         77040017
*                                                                       77130017
*        WHEN STORAGE HAS BEEN RELEASED FROM A PARTITION, TEST IF THERE 77220017
*        ARE ANY OUTSTANDING VARY QUEUE ELEMENTS, REPRESENTING DEFERRED 77310017
*        VARY STORAGE OFFLINE REQUESTS, WHICH APPLY TO THE STORAGE AREA 77400017
*        DESCRIBED BY THE GIVEN PQE                                     77490017
*                                                                       77580017
         L     XGVR,GVRFLB         VQE LIST ORIGIN IS IN -GOVRFLB-      77670017
         LA    XVQE,VQEPTR(,XGVR)  INITIALIZE TO VQE LIST ORIGIN        77760017
VQELOOP  L     XVQE,VRYPTR(,XVQE)  STEP TO NEXT VQE                     77850017
         LA    XVQE,Q0(,XVQE)     ZERO HIGH ORDER BYTE             MP1A 77940017
         LTR   XVQE,XVQE           TEST IF HAVE VARY QUEUE ELEMENT      78030017
         BCR   Q8,XITR            ALL DONE, RETURN FROM SUBR       MP1A 78120017
         L     XBEG,PQESTADD(,XPQE)  GET PARTITION BEG ADDR             78210017
         L     XEND,PQERGSZ(,XPQE)  PICK PARTITION SIZE                 78300017
         AR    XEND,XBEG           GET PARTITION ENDING ADDRESS         78390017
         LM    XXBG,XXND,VRYBEG(XVQE) GET BEGIN ADDR OF VARY AREA       78480017
         AR    XXND,XXBG           GET ENDING ADDRESS OF VARY AREA      78570017
         BAL   XRET,IFSAPPLY       TEST IF VQE APPLIES TO PARTITION     78660017
         BNL   VQELOOP            NO - GO GET NEXT VQE             MP1A 78750017
         STM   XBEG,XEND,SAVBOUND  STORE LIMITS OF VARY AREA IN PARTITN 78840017
*                                                                       78930017
*        POST VARY TASK TO INDICATE THAT A PARTITION WITHIN THE RANGE   79020017
*        OF THE VQE HAS BEEN PROCESSED.  THE VARY TASK WILL EXAMINE     79110017
*        THE FSSEMAP STATUS BITS TO DETERMINE IF THE VQE HAS BEEN       79200017
*        COMPLETELY SATISFIED (THE ENTIRE -VARY- AREA RECONFIGURED OUT) 79290017
*                                                                       79380017
         LA    XECB,VRYECB(,XVQE)  ECB ON WHICH -VARY- WAITS IS IN VQE  79470017
         SR    XPST,XPST           INDICATE COMPLETION CODE OF ZERO     79560017
         L     XLNK,POSTADDR       ADDR OF BRANCH ENTRY POINT TO -POST- 79650017
         BALR  XRET,XLNK           POST VARY TASK - VQE WAS USED        79740017
*                                  POST RTN HAS REGS 0-9,14 TRANSPARENT 79830017
         USING *,XRET                                                   79920017
         L     XBASE,IFSSEVRY      REESTABLISH ADDRESSABILITY           80010017
         DROP  XRET                                                     80100017
*                                                                       80190017
*        STEP THROUGH THE FBQES ON THE MSS FREE STORAGE QUEUE, AND TEST 80280017
*        EACH FBQE TO SEE IF THE CURRENT VQE APPLIES TO IT              80370017
*                                                                       80460017
         L     XDMY,PQEPTR(,XGVR)  INITIALIZE TO FBQE LIST ORIG IN MSS  80550017
         L     XFBQ,DUMFWD(,XDMY)  PICK REAL PQE ADDR FROM DUMMY        80640017
FBQLOOP  L     XFBQ,FWDPTR(,XFBQ)  STEP TO NEXT FBQE                    80730017
         C     XFBQ,PQEPTR(,XDMY)  TEST IF FBQE QUEUE END (AT FREE PQE) 80820017
         BE    VQELOOP               YES - GO GET NEXT VQE              80910017
         LM    XBEG,XEND,SAVBOUND  SETUP LIMITS OF VARY STORAGE AREA    81000017
         LR    XXBG,XFBQ           GET FREE BLOCK AREA BEGIN ADDR       81090017
         LR    XXND,XFBQ                                                81180017
         A     XXND,FBQESIZE(,XFBQ) GET FREE BLOCK AREA END ADDRESS     81270017
         BAL   XRET,IFSAPPLY       TEST IF FBQE APPLIES TO VARY AREA    81360017
         BNL   FBQLOOP            NO - GO GET NEXT FBQE            MP1A 81450017
*                                                                       81540017
*        REMOVE STORAGE FROM AREA DESCRIBED BY FBQE                     81630017
*           IF REMOV LOWER PART - ALSO REMOVE ORIGINAL FBQE             81720017
*           IF REMOV UPPER PART - CHANGE ORIG FBQE SIZE TO SIZE LOWER   81810017
*           IF LEAVE UPPER PART - CREATE NEW FBQE IN REMAING UPPER PART 81900017
*           IF REMOV MIDDL PART - UPDAT SIZE LOWR FBQE, CREAT UPPR FBQE 81990017
*                                                                       82080017
         SR    XXBG,XBEG           DOES FBQE START BEFORE VARY AREA     82170017
         BNL   FBQE1DEL           NO - DELETE OLD FBQE             MP1A 82260017
         LCR   XXBG,XXBG             YES - GET SIZE BEFORE VARY AREA    82350017
         ST    XXBG,FBQESIZE(,XFBQ) STORE NEW SIZE IN OLD FBQE          82440017
         B     FBQE2BLD            GO TO TEST END OF VARY AREA          82530017
FBQE1DEL L     XFWD,FWDPTR(,XFBQ)                                       82620017
         L     XBCK,BCKPTR(,XFBQ)                                       82710017
         ST    XFWD,FWDPTR(,XBCK)  ELIMINATE FBQE FROM FWD,BCK QUEUES   82800017
         ST    XBCK,BCKPTR(,XFWD)                                       82890017
         LR    XFBQ,XBCK           PREV FBQE BECOMES CURRENT FBQE       82980017
FBQE2BLD SR    XXND,XEND           DOES VARY AREA END BEFORE FBQE AREA  83070017
         BNP   MAPUPDAT           NO, DO NOT BUILD NEW FBQE        MP1A 83160017
         L     XFWD,FWDPTR(,XFBQ)    YES - GET ADDR OF NEXT FBQE IN Q   83250017
         ST    XEND,FWDPTR(,XFBQ)  POINT PREV FBQE TO NEW BUILT FBQE    83340017
         ST    XFWD,FWDPTR(,XEND)                                       83430017
         ST    XFBQ,BCKPTR(,XEND)  INSERT (BUILD) NEW FBQE              83520017
         ST    XXND,FBQESIZE(,XEND)                                     83610017
         ST    XEND,BCKPTR(,XFWD)  POINT NEXT FBQE TO NEW BUILT FBQE    83700017
         LR    XFBQ,XEND           NEW BUILT FBQE BECOMES CURRENT FBQE  83790017
*                                                                       83880017
*        UPDATE -FSSEMAP- IN THE CPU FAIL-SOFT SAV AREA TO INDICAT THAT 83970017
*        THE STORAGE RANGE GIVEN BY -XBEG,XEND- HAS BEEN RECONFIGURED,  84060017
*        AND NO LONGER APPEARS ON ANY MAIN STORAGE SUPERVISOR QUEUES    84150017
*                                                                       84240017
MAPUPDAT L     XMAP,IFSSEMAP       BASE ADDR FOR SSEMAP INSPECT ROUTINE 84330017
         BALR  XRET,XMAP           SET MAP REGISTERS FOR ADDR IN -XBEG- 84420017
         B     MAPMOVE               EXIT WHEN STEPPD TO ADDR IN -XEND- 84510017
         LR    XWRK,XMSK           SAVE CONTENTS SO CAN INCREMENT MASK  84600017
         ALR   XMSK,XWRK           DOUBLE MASK TO SETON LEFT BIT OF TWO 84690017
         ALR   XMSK,XWRK           TRIPLE MASK TO SETON RGHT BIT OF TWO 84780017
         EX    XMSK,ORMAPA         MARK STORAGE -RECONFIGURED OUT- IN   84870017
         BR    XMAP                GO INSPECT NEXT 2K BLK STATUS IN MAP 84960017
*                                                                       85050017
*        UPDATE -FSSEMAP- IN THE OTHER CPU FAIL-SOFT SAVE AREA          85140017
*                                                                       85230017
MAPMOVE  TM    CPUSTAT,QX01       TEST IF PARTITIONED MODE         MP1A 85320017
         BO    FBQLOOP            YES, BYPASS UPDATE OTHER CPU MAP MP1A 85410017
         L     XWRK,PREFIX2        GET ADDR OF OTHER CPU PSA            85500017
         MVC   FSSEMAP-IEAQFX00(,XWRK),FSSEMAP    UPDATE OTHER CPU MAP  85590017
         B     FBQLOOP             GO TEST NEXT FBQE AGAINST VARY AREA  85680017
*                                                                       85770017
*        SUBROUTINE TO DETERMINE THE STORAGE COMMON TO TWO GIVEN AREAS, 85860017
*        BY SELECTING THE RIGHTMOST BEG ADDR AND THE LEFTMOST END ADDR, 85950017
*        AND THEN TEST THAT THE SELECTED BEG IS TO THE LEFT OF SEL END  86040017
*                                                                       86130017
IFSAPPLY CR    XBEG,XXBG           TEST IF ELEM CROSSES AREA LOW BOUND  86220017
         BNL   *+6                YES - USE AREA BOUND AS LOW      MP1A 86310017
         LR    XBEG,XXBG             NO - USE ELEMENT BOUNDARY AS LOW   86400017
         CR    XXND,XEND           TEST IF ELEM CROSSES AREA HIGH BOUND 86490017
         BNL   *+6                YES - USE AREA BOUND AS HIGH     MP1A 86580017
         LR    XEND,XXND             NO - USE ELEMENT BOUNDARY AS HIGH  86670017
         CR    XBEG,XEND           COND. CODE SHOWS IF HAVE AREA LEFT   86760017
         BR    XRET                RETURN TO MAINLINE OF -IFSVRYOF-     86850017
*                                                                       86940017
*        EXECUTED INSTRUCTIONS                                          87030017
*                                                                       87120017
ORMAPA   OI    Q0(XMPA),Q0        INSERT EX MASK BITS, CPU A MAP   MP1A 87210017
         DROP  R0                                                  MP1A 87300017
         DROP  XBASE                                                    87390017
*                                                                       87480017
*        CONSTANTS AND SAVE AREAS                                       87570017
*                                                                       87660017
GVRFLB   DC    A(GOVRFLB)          ADDR OF MSS LIST ORIGIN TABLE        87750017
IFSSEVRY DC    A(IFSVRYBS)         BASE ADDR FOR VARY STORAGE OFLIN RTN 87840017
POSTADDR DC    V(IEA0PT01)         ADDR OF BRANCH ENTRY POINT TO -POST- 87930017
IFSSEMAP DC    A(IFSSEM00)         ADDR OF FSSEMAP INSPECTION ROUTINE   88020017
SAVBOUND DC    2F'0'               SAVE AREA FOR VARY STORAGE LIMITS    88110017
*                                                                       88200017
*        REGISTER EQUATES                                               88290017
*                                                                       88380017
XITR     EQU   1         RETURN ADDRESS TO CALLING ROUTINE              88470017
XPQE     EQU   2         ADDR OF PQE TO GIVE SCOPE OF APPLICABLE STORAG 88560017
XVQE     EQU   3         ADDR OF VARY QUEUE ELEMENT BEING PROCESSED     88650017
XFBQ     EQU   4         ADDR OF CURRENT FBQE BEING INSPECTED           88740017
XGVR     EQU   5         POINTER TO MSS LIST ORIGIN TABLE -GOVRFLB-     88830017
XXBG     EQU   6         BEG ADDR OF AREA DESCRIBED BY CURR QUEUE ELEM  88920017
XXND     EQU   XXBG+1    END ADDR OF AREA DESCRIBED BY CURR QUEUE ELEM  89010017
XWRK     EQU   7         WORK REG USED TO SETON BOTH MAP BITS FOR 2K    89100017
XBEG     EQU   8         BEG ADDR OF AREA COMMON TO MULTIPLE QUEUE ELEM 89190017
XEND     EQU   XBEG+1    END ADDR OF AREA COMMON TO MULTIPLE QUEUE ELEM 89280017
XFWD     EQU   10        POINTER TO FBQE FOLLOWING CURR FBQE IN CHAIN   89370017
XMPA     EQU   10        POINTER TO PROPER BYTE WITHIN OWN CPU FSSEMAP  89460017
XPST     EQU   10        POST INPUT PARAMETER - COMPLETION CODE         89550017
XBCK     EQU   11        POINTER TO FBQE PRECEDING CURR FBQE IN CHAIN   89640017
XMSK     EQU   11        IFSSEM00 OUTPT - BIT CONFIG APPLIED TO FSSEMAP 89730017
XECB     EQU   11        POST INPUT PARAMETER - ECB ADDR                89820017
XMAP     EQU   12        LINK REGISTER USED TO BRANCH TO -IFSSEMAP- RTN 89910017
XDMY     EQU   13       ADDR OF REAL DYNAMIC FREE STORAGE PQE           90000017
XRET     EQU   14        RETURN REGISTER USED BY POST,MAP SUBROUTINES   90090017
XLNK     EQU   15        POST ENTRY POINT ADDRESS                       90180017
XBASE    EQU   15        BASE REGISTER FOR ADDRESSABILITY               90270017
         TITLE '-F S S E M A P-    S C A N    S U B R O U T I N E'      90360017
*           INPUT  -  8 - BEG ADDR OF STORAGE AREA FOR WHICH SCAN       90450017
*                     9 - END ADDR OF STORAGE AREA FOR WHICH SCAN       90540017
*                    12 - ADDR OF ENTRY POINT (BASE ADDRESS)            90630017
*                    14 - RETURN ADDRESS                                90720017
*           OUTPUT -  8 - ADDR OF NEXT 2K BLOCK OF STORAGE (PREV X8+2K) 90810017
*                    10 - ADDR OF MAP BYTE WITHIN OWN CPU -FSSEMAP-     90900017
*                    11 - MASKREG WITH '01' BITS POSITND FOR 2K IN BYTE 90990017
*                    12 - ADDR OF ENTRY PT TO SCAN MAP FOR NXT 2K BLOCK 91080017
*                                                                       91170017
*                                                                       91260017
*           REGISTERS 0-7,13-15 ARE NOT CHANGD DURING -IFSSEM00-.  REGS 91350017
*           8,10-12 WILL BE ALTERED.  THE USER OF -IFSSEM00- IS HIMSELF 91440017
*           RESPONSIBLE FOR SAVING AND RESTORING THE PROPER REGISTERS.  91530017
         SPACE                                                          91620017
         ENTRY IFSSEM00       FAIL-SOFT STORAGE ELEMENT MAP SCAN SUBRTN 91710017
IFSSEM00 DS    0H                  BRANCH ENTRY POINT                   91800017
         USING IFSSEM00,XENT       BASE REGISTER IS PRELOADED BY USER   91890017
         USING IEAQFX00,R0        ADDRESSIBILITY                   MP1A 91980017
*                                                                       92070017
         SRL   XLIMT,11            TRUNCATE END ADDR TO 2K BLOCK BOUND  92160017
         SLL   XLIMT,11            RESTORE END ADDR FOR COMPARISON      92250017
         BAL   XENT,IFSETEST       ESTABLISH ADDR FOR LOOP ENTRY POINT  92340017
         USING *,XENT                                                   92430017
*                                                                       92520017
*        SCAN LOOP.  DETERMINE MAP BYTE BY TRUNCATING THE GIVEN ADDR IN 92610017
*        -XADDR-.  POSITION A BIT MASK TO CORRESPOND TO THE PROPER TWO  92700017
*        BITS (DESCRIBING THE STATUS OF THE 2K BLOCK) WITHIN THE MAP    92790017
*        BYTE.  INCREMENT -XADDR- SO THAT WHEN THE LOOP IS AGAIN        92880017
*        ENTERED, THE NEXT 2K BLOCK STATUS WILL BE SCANNED.             92970017
*                                                                       93060017
         LA    XADDR,Q2048(,XADDR) INCR INPUT ADDR TO NEXT 2K BLK  MP1A 93150017
IFSETEST CR    XADDR,XLIMT         TEST IF HAVE EXCEEDED STORAGE AREA   93240017
         BCR   Q10,XRETN          YES - FINAL EXIT                 MP1A 93330017
         LM    XSHFT,XMASK,IFSEMCON PICK MASKS USED TO SELECT BITS      93420017
         NR    XSHFT,XADDR         PICK LOW 2 BITS OF 2K BLOCK ADDR     93510017
         SRL   XSHFT,10            GET DISPLACMT OF 2K FRM 16K BOUNDARY 93600017
         SRL   XMASK,0(XSHFT)      SHFT MASK FOR 2K POS WITHIN MAP BYTE 93690017
         LA    XBYTE,Q0(,XADDR)   CLEAR HIGH ORDER BITS OF ADDR    MP1A 93780017
         SRL   XBYTE,13            GET DISPLACMT OF MAP BYT FOR 16K BLK 93870017
         LA    XMAPA,FSSEMAP(XBYTE) GET ADDR OF MAP BYTE IN OWN IFSAREA 93960017
         B     Q4(,XRETN)         GO TO USERS PROCESS ROUTINE      MP1A 94050017
*                                                                       94140017
         DROP  XENT                                                     94230017
         DROP  R0                                                  MP1A 94320017
*                                                                       94410017
*        CONSTANTS AND SAVE AREAS                                       94500017
*                                                                       94590017
IFSEMCON DC    F'6144,64'     MASKS TO SEL SHFT AMT, TEST BIT 1 IN BYTE 94680017
*                                                                       94770017
*        REGISTER EQUATES                                               94860017
*                                                                       94950017
XADDR    EQU   8         ADDR OF 2K STRG BLOCK WHOSE MAP STATUS SOUGHT  95040017
XLIMT    EQU   9         ADDR OF 1ST BYTE BEYOND STRG AREA TO BE SCANND 95130017
XMAPA    EQU   10        POINTER TO PROPER BYTE WITHIN OWN CPU FSSEMAP  95220017
XBYTE    EQU   10        DISPLACEMENT OF BYTE FROM FSSEMAP BEGINNING    95310017
XSHFT    EQU   10        DISPLACEMENT OF PROPR 2 BITS WITHIN 8 BIT BYTE 95400017
XMASK    EQU   XSHFT+1   OUTPUT REG - '01' MASK POSITND OVR WANTED BITS 95490017
XENT     EQU   12        BASE REGISTER FOR ADDRESSABILITY               95580017
XRETN    EQU   14        RETURN ADDRESS TO CALLING ROUTINE              95670017
         TITLE '0 - 4K    S T O R A G E    M A P'                       95760017
         IEAQFX 65,MCH,1                                                95850017
.MP04    ANOP                                                      MP1A 95940017
         EJECT                                                          95946021
***************************************************************         95952021
*        DSECT TO COVER INFORMATION LIST ENTRY                          95958021
***************************************************************         95964021
         SPACE 1                                                        95970021
INFOLIST DSECT                                                          95976021
INFRESV  DS    H                        RESERVED              AC A49808 95978021
INFTJID  DS    H                                              AC A49808 95980021
INFTCB   DS    F                                                        95982021
INFBADDR DS    F                                                        95988021
INFRCL   DS    X     BITS 0-2 USED FOR REASON CODE(0=>NO RC)            95994021
*                    BITS 3-7 USED FOR COUNT OF VARIABLE DATA BYTES     96000021
INFFLG   DS    X     FLAG BYTE                                          96006021
INFFLG0  EQU   X'10' BIT 0 ON => BRANCH ENTRY                           96012021
INFCC    DS    H     COMPLETION CODE                                    96018021
INFVAR   DS    4F    VARIABLE INFORMATION                               96318021
         ORG   INFVAR                                                   96618021
INFVAR1  DS    F                                                        96918021
INFVAR2  DS    F                                                        97218021
INFVAR3  DS    F                                                        97518021
INFVAR4  DS    F                                                        97818021
INFEND   EQU   *                                                        98118021
INFLEN   EQU   (INFEND-INFRESV)  LENGTH OF ENTRY                        98418021
         MEND                                                           98718021
