         MACRO                                                          00700014
   IECICS  &CHAN,&DATOT,&M65MP,&SLCHS,&ALTSW,&ALTSWA,&PRI,&RESREL,     *01100021
               &TBASE,&SSDA,&MLCHPRI                             A36305 01600020
         GBLA  &SSCCW(16),&CCW(16)                                      01650021
         LCLA  &COUNT,&LCHNS(60),&LCOUNT,&COUNT2                        02200021
         LCLA  &NUM,&NUM2                                               02800021
         LCLC  &LABEL,&LCHADR(30)                                       03500021
         AIF   (&DATOT EQ 0).LCH11                                      04100017
&NUM     SETA  1                                                        04150021
         AIF   (&SSDA(&NUM) EQ 0).NOTC                                  04200021
&SSCCW(&CHAN+1)  SETA  1                                                04250021
.NOTC    ANOP                                                           04300021
&NUM     SETA  &NUM+1                                                   04350021
         AIF   (&SSDA(&NUM) EQ 0).NOTD                                  04400021
&SSCCW(&CHAN+1)  SETA  &SSCCW(&CHAN+1)+2                                04450021
.NOTD    ANOP                                                           04500021
&NUM     SETA  &NUM+1                                                   04550021
         AIF   (&SSDA(&NUM) EQ 0).NOTE                                  04600021
&SSCCW(&CHAN+1)  SETA  &SSCCW(&CHAN+1)+4                                04650021
.NOTE    ANOP                                                           04700021
&NUM     SETA  &NUM+1                                                   04750021
         AIF   (&SSDA(&NUM) EQ 0).NOTF                                  04800021
&SSCCW(&CHAN+1)  SETA  &SSCCW(&CHAN+1)+8                                04850021
.NOTF    AIF   (&SSCCW(&CHAN+1) EQ 0).NORES                             04900021
         AIF   (&RESREL EQ 0).NORES                                     04950021
&SSCCW(&CHAN+1)  SETA  &SSCCW(&CHAN+1)+16                               05000021
.NORES   AIF   (&SSCCW(&CHAN+1) NE 0).LCH11                             05050021
&CCW(&CHAN+1) SETA  1                                                   05100021
         AIF   (&RESREL EQ 0).LCH11                                     05150021
&CCW(&CHAN+1)  SETA  &CCW(&CHAN+1)+16                                   05200021
.LCH11   ANOP                                                      RRSS 08400021
&NUM     SETA  0                                                        08500017
&NUM2    SETA  0                                                        08600017
&COUNT   SETA  0                                                        08700017
&COUNT2  SETA  0                                                        08800017
         SPACE 1                                                        09100014
INTCS&CHAN    DS    0C                                                  09800014
.*      THIS LOOP DETERMINES THE LCHS -HOW MANY AND WHAT NUMBERS        10500014
         AIF   (T'&SLCHS EQ 'O').MPXSRH  TEST FOR MPX CHAN              11200021
&COUNT2  SETA  1                        INITIALIZE COUNTER              11900014
         AGO   .LCHFND2                 SKIP FIRST UPDATE               12600014
.LCHFND  ANOP                                                           13300014
&COUNT2  SETA  &COUNT2+2                UPDATE THRU SLCH LIST           14000014
.LCHFND2 ANOP                                                           14700014
&COUNT   SETA  &COUNT+1                UPDATE COUNTER                   15400014
         AIF   (&COUNT2+1  EQ  N'&SLCHS).MVCCODE  TEST END OF LIST      16100014
         AIF   (&SLCHS(&COUNT2+1)  EQ  0).LCH3   CHECK IF LCH ASSIGNED  16800014
&LCOUNT  SETA  &LCOUNT+1               UPDATE NUM OF LCHS THIS CHAN     17500014
&LCHNS(&LCOUNT) SETA &COUNT+&SLCHS(1)  SET PROPER LCH NUMBER            18200014
.LCH3   AIF   (&SLCHS(&COUNT2+2)  EQ  0).LCHFND   CHECK FO R DA SK DEV  18900014
         LA    LCHREG,LCH&LCHNS(&LCOUNT)   SET LCH FOR SEEK DEV         19600014
         BAL   LNKRG2,INT036C           TO START AT TOP OF QUEUE        20300014
*    VECTOR ENTRY FOR NEXT IN QUEUE                                     21000014
         BC    15,INTCIC                TO PICK UP NEXT RQE             21700014
*    VECTOR ENTRY FOR NEXT LCH                                          22400014
         AGO   .LCHFND                 RETURN TO FIND LOOP              23100014
.MVCCODE ANOP       THIS IS THE INITIALIZATION CODE FOR SEARCH          23800014
&COUNT   SETA  0                       RESET COUNTER                    24500014
**       THIS CODE SETS THE SEARCH LOGIC FOR ALL I/O DATA TRANSFER      25900014
         AIF   (&LCOUNT LT 2).LCH4                                      26600014
         LH    WKREG1,INTCS&CHAN.A      SAVE FIRST ENTRY                27300014
&NUM     SETA  &LCOUNT*2-2                                              28000014
         MVC   INTCS&CHAN.A(&NUM),INTCS&CHAN.A+2  MOVE UP LIST          28700014
         STH   WKREG1,INTCS&CHAN.A+&NUM MAKE FIRST LAST                 29400014
&NUM     SETA  0                                                        30100014
.LCH4    ANOP                                                           30800014
&COUNT   SETA  &COUNT+1                                                 31500014
         AIF   (&PRI EQ 1 AND &LCOUNT GT 1).MVCLOOP               PRQ1  31800016
         AIF   (&COUNT GT &LCOUNT).LCH5  ALL DONE                       32200014
         AIF   (&LCOUNT LT 2).LCH9                                      32900014
         LH    LCHREG,INTCS&CHAN.A+&NUM GET LCH ADDR.                   33600014
         AIF   (&TBASE EQ 0).TBS010                                IMP3 33700017
         AR    LCHREG,BASREG            ADJUST ADDRESS           BBBBBB 33800019
.TBS010  ANOP                                                      IMP3 33900017
&NUM     SETA  &NUM+2                   INCR. LCH POINTER               34300014
&NUM2    SETA  &NUM2+1                  INCR LIST ID                    35000014
&LCHADR(&NUM2)  SETC   'LCH'.'&LCHNS(&COUNT)'  SET ENTRY FOR DC LIST    35700014
         AGO   .LCH10                                                   36400014
.LCH9    LA    LCHREG,LCH&LCHNS(&COUNT)  SET PROPER LCH ADDR            37100014
.LCH10   BAL   LNKRG2,INT034C           TEST FOR STARTABLE DEVICE       37800014
*    VECTOR ENTRY FOR NEXT IN QUEUE                                     38500014
         BC    15,INT034D               TO PICK-UP NEXT RQE             39200014
*    VECTOR ENTRY FOR NEXT LCH                                          39900014
         AGO   .LCH4                    CONTINUE WITH LCHS              40600014
.LCH5    ANOP                           LAST ENTRY IN SEARCH            41300014
         BC    15,INT033                EXIT FROM CHANNEL SEARCH        42000014
         SPACE 2                                                  PRQ1  42700016
         AIF   (&LCOUNT LT 2).LCHEND    NEED LIST?                      43400014
&LABEL   SETC  'INTCS&CHAN.A'                                           44100014
&LABEL   DS    0C                                                       44800014
&NUM     SETA  1                                                        45500014
.LCHCON  DC    AL2(&LCHADR(&NUM)-IOSBASE)    LCH ADDRESS         BBBBBB 46200019
&NUM     SETA  &NUM+1                                                   46900014
         AIF   (&NUM-1 NE &LCOUNT).LCHCON                               47600014
         SPACE 2                                                  PRQ1  47800016
.LCHEND  AIF   (&MLCHPRI EQ 1).LASTCHK  IF PRIORITY QUEUING AND  A36305 48100020
.*   MULTIPLE LCHS WITH PRIORITY, GO GENERATE PRIORITY COMPARE.  A36305 48400020
         MEXIT                                                     PRQ1 48800016
.*   CODE FOR PRIORITY LCHS                                       PRQ1  49300016
.MVCLOOP ANOP                                                           50400014
&COUNT   SETA  &COUNT+1                UPDATE COUNTER                   51100014
         AIF   (&COUNT GT &LCOUNT).SRCODE  END OF LIST CHECK            51800014
         MVC   LCH&LCHNS(&COUNT)+LCHSRH(2),LCH&LCHNS(&COUNT)       PRQ1 52200016
&LCHADR(&COUNT) SETC   'LCH'.'&LCHNS(&COUNT)'                      PRQ1 52600016
         AGO   .MVCLOOP                                                 53200014
.SRCODE  ANOP       THIS IS SEARCH CODE -PER CHANNEL                    53900014
&COUNT   SETA  1                       RESET COUNTER                    54600014
&LCHADR(&COUNT) SETC   'LCH'.'&LCHNS(&COUNT)'                     PRQ1  54900016
         LA    LCHREG,LCH&LCHNS(&COUNT)                           PRQ1  55200016
         LR    TSTREG,LCHREG                                      PRQ1  55500016
INTCS&CHAN.B  MVC   LCHSRH(2,LCHREG),TSTLNK(TSTREG)               PRQ1  55800016
         LH    LCHREG,INTCS&CHAN.A                                PRQ1  56100016
         AIF   (&TBASE EQ 0).TBS020                                IMP3 56170017
         AR    LCHREG,BASREG            ADJUST ADDRESS           BBBBBB 56240019
.TBS020  ANOP                                                      IMP3 56310017
         LH    TSTREG,LCHSRH(LCHREG)                              PRQ1  56400016
.SRCLOOP ANOP            COMPARE LOOP FOR MORE THAN ONE LCH             56700014
         AIF   (&COUNT EQ &LCOUNT).SRCOMN      TO COMMON CODE/PER CHAN  57400014
&COUNT   SETA  &COUNT+1                UPDATE COUNTER                   58100014
&NUM     SETA &NUM+2                                              PRQ1  58600016
         LH    WKREG1,INTCS&CHAN.A+&NUM                           PRQ1  59100016
         AIF   (&TBASE EQ 0).TBS030                                     59200017
         AR    WKREG1,BASREG            ADJUST ADDRESS           BBBBBB 59300019
.TBS030  ANOP                                                      IMP3 59400017
         LH    WKREG2,LCHSRH(WKREG1)                              PRQ1  59600016
         AIF   (&ALTSW NE 1).SRCOMN    CHECK FOR ANY ALTERNATES         60200014
         BAL   LNKRG2,CSCHCMP          TO COMMON COMPARE ROUTINE        60900014
         AGO   .SRCLOOP                RETURN TO COMPARE FOR LAST       61600014
.SRCOMN  ANOP            THIS IS COMMON CODE FOR EACH SEARCH MODULE     62300014
         BAL   LNKRG2,INT034                                      PRQ1  62700016
         BC    15,INTCS&CHAN.B                                    PRQ1  63100016
         AGO   .LCH5                                              PRQ1  63500016
.LASTCHK ANOP                                                     PRQ1  63900016
&COUNT   SETA  N'&SLCHS                SET UP FOR COMPARE RTN TEST      64400014
         AIF   (&SLCHS(&COUNT) EQ 1).COCOMP  ALT PATH SWITCH ON         65100014
         MEXIT                         NO-EXIT FROM MACRO               65800014
.COCOMP  ANOP                   COMMON COMPARE CODE AND RQE UPDAAE      66500014
CSCHCMP  LTR   WKREG2,WKREG2           IS TEST REQUEST DUMMY            67900014
         BCR   4,LNKRG2                YES,RETURN                       68600014
         LTR   TSTREG,TSTREG           IS FIRST REQUEST DUMMY           69300014
         BC    4,CSCHCMPA              YES, SWITCH RQE'S                70000014
         CLC   TSTPR(1,TSTREG),TSTPR(WKREG2)     TEST FOR HIGH          70700014
         BCR   10,LNKRG2               FIRST IS HIGH-RETURN             71400014
CSCHCMPA LR    TSTREG,WKREG2           SWITCH-TEST IS HIGHER            72100014
         LR    LCHREG,WKREG1           SWITCH CURRENT LCH WITH NEW      72800014
         BCR   15,LNKRG2               RETURN                           73500014
         SPACE 2                                                        74200014
         MEXIT                                                    PRQ1  74900021
.MPXSRH  ANOP           THIS IS MULTIPLEXOR SEARCH CODE                 83300014
         AIF   (&DATOT EQ 0).LCH7       ANY DA ON MPLX                  84000014
         LA    LCHREG,LCHTAB            MPLX LCH                        84700014
         BAL   LNKRG2,INT036C           TO START AT TOP OF QUEUE        85400014
*    VECTOR ENTRY FOR NEXT IN QUEUE                                     86100014
         BC    15,INTCIC                TO PICK UP NEXT IN QUEUE        86800014
*    VECTOR ENTRY FOR NEXT LCH                                          87500014
.LCH7    ANOP                                                           88200014
         LA    LCHREG,LCHTAB            INITILIZE TO 1ST LCHWORD        88900014
         BAL   LNKRG2,INT034C           TO START AT TOP OF QUEUE        89600014
*    VECTOR ENTRY FOR NEXT IN QUEUE                                     90300014
         BC    15,INT034D               TO PICK-UP NEXT DTR IN QUEUE    91000014
*    VECTOR ENTRY FOR NEXT LCH                                          91700014
         BC    15,INT033               RETURN WHEN RQE IS DUMMY         92400014
         EJECT                                                          93100014
         MEND                                                           93800014
