          MACRO                                                         00070021
         IECINT &TAPE,&SMF,&P3211,&TP,&APR,&VP,&SKORD,&RFIFO,&RPR,     *00140021
               &TWOSW,&VS,&PROTECT,&TRACE,&SSDA,&TCBTYP,&SSTA,&GR,     *00210021
               &NOP1,&RWTAU,&RESJQ,&NOP2,&ASR,&M65MP,&TBASE,&ANR,      X00230021
               &DAVV,&DDR,&M7CH,&ASPN,&NOP4,&OLTEP,&TSO,&CEXT,&RMS,    X00250020
               &TCAM,&MFTATT,&NOP3,&ALTSHR                              00270021
         GBLB  &D2311,&D2321,&D2301,&D2303,&D2305,&DML            20201 00290020
         GBLB  &R2311,&R2321,&R2301,&R2303,&R2305,&RML            20201 00310020
         GBLB  &IECITB                                            20201 00330021
         LCLB  &RESREL,&RPS,&TBYT                                 20201 00350021
         LCLC  &LABEL                                             20201 00370020
&RESREL  SETB  (&R2321 OR &R2311)                                 20201 00390020
&RPS     SETB  (&D2305 OR &DML)                                   20201 00410020
&TBYT    SETB  (&IECITB)        SET IF 2 BYTE CU LOOKUP TABLE     20201 00450020
         SPACE 2                                                   RL19 00560019
*        THE INPUT OUTPUT INTERRUPT SUPERVISOR                        * 00630019
         SPACE 2                                                        00700019
*              THE IOS INTERRUPT SUPERVISOR IS THAT PART OF THE         00770019
*              INPUT OUTPUT SUPERVISOR WHICH HANDLES THE INPUT OUTPUT   00840019
*              INTERRUPTS.                                              00910019
*              THE FOLLOWING IS A GENERAL OUTLINE OF THE OPERATION      00980019
*              OF THIS PROGRAM.                                         01050019
         SPACE 1                                                        01120019
*                   1. CHECKS FOR CATASTROPHIC ERROR.MAKES INSPECTION   01190019
*                      OF STATUS AND SENSE CONDITIONS.                  01260019
*                   2. LINKS TO ABNORMAL END, CHANNEL END, AND PROGRAM  01330019
*                      CONTROLLED INTERRUPT APPENDAGES.                 01400019
*                   3. INVESTIGATES NON-CHANNEL END CONDITIONS.         01470019
*                   4. TESTS FOR ABEOT CONDITIONS                       01540019
*                   5. ATTEMPTS TO RESTART THE CHANNEL WITH A REQUEST   01610019
*                      FROM THE LOGICAL CHANNEL QUEUES.  RETURNS TO     01680019
*                      SUPERVISOR.                                      01750019
*                   6. LINKS TO ATTENTION ROUTINE.                      01820019
*                   7. DETERMINES ERRORS AND BRANCHES OR LINKS TO       01890019
*                      PROPER HANDLING ROUTINE.                         01960019
         SPACE 3                                                        02030019
IECINT   DS    0H                                                  TBSE 02100019
         AIF   (&TBASE EQ 0).TBS187                                TBSE 02170019
         BALR  BASREG,0                                            TBSE 02240019
IECINTA  LA    BASREG2,IECINTA-IOSBAS                              TBSE 02310019
         SR    BASREG,BASREG2      SET LOW BASE REGISTER           TBSE 02380019
         LA    BASREG2,4094(BASREG)     SET UP HIGH BASE REG       RL19 02450019
         LA    WKREG1,INT027            SET MAIN RETURN REG        IMP4 02520019
         ST    WKREG1,LNKRG1S      SET MAIN RETURN REGISTER        TBSE 02590019
         AGO   .TBS190                                                  02660019
.TBS187  LA    LNKRG1,INT027            SET MAIN RETURN REG        IMP4 02730019
.TBS190  NI    XCPBTE,FF-XCPCNT-XCPERR-XCPST-XCPRECUR-XCPVALID   A24739 02750019
*                                       RESET ALL NON-RMS FLAGS  A24739 02770019
         L     APBSRG,IECPL2            GET TEMP BASE REG      @SA77644 02820018
         SR    ICREG,ICREG              CLEAR INSERT CHARACTER REG      02870021
         STH   ICREG,LTSVALSV           NO VALID RQE             A24739 02910019
         LH    UAREG,IOPSWO+2           PICK UP UNIT ADDRESS     A24739 02930021
         LM    WKREG1,WKREG2,CSWLOC     GET CURRENT CSW           19022 03490021
         N     WKREG2,CUBMSK            REMOVE CUB BITS           19022 03780019
         ALR   WKREG1,WKREG2            ALL OTHER STATUS = ZERO   19022 03850019
         BC    8,GTF01                  ZERO STATUS, TRACE IT     21014 03970021
         SPACE 1                                                  21014 03990021
*   THE NEXT PROCEDURE ATTEMPTS TO ELIMINATE THE UCB LOOK-UP PROCEDURE  04060019
*   IF THE CORRECT UCB ADDRESS HAS BEEN SAVED IN THE CHANNEL SAVE       04130019
*   AREA, NO LOOK UP IS NECESSARY.                                      04200019
         SPACE 1                                                        04270019
         IC    ICREG,IOPSWO+2           PICK UP CHANNEL ADDRESS         04300020
         AR    ICREG,ICREG              DOUBLE CHAN ADDR TO GET INDEX   04340019
         LH    UCBREG,UCBSAVE(ICREG)    PICK UP LAST ACTIVE UCB ADDR    04410019
         CH    UAREG,UCBCHA(0,UCBREG)   IS THIS THE LAST UCB STARTED    04480019
         BC    8,INT01A                YES- GO LOAD REGS           IMP2 04550019
         SPACE 1                                                   IMP2 04620019
*   GET UCB ADDRESS VIA LOOK-UP METHOD                                  04690019
         LR    WKREG1,UAREG        COPY UNIT ADDRESS               IMP2 04760019
         SRDL  UAREG,8                  ISOLATE CHAN ADDR IN UAREG      04830019
         SRL   UCBREG,28                ISOLATE CONTROL UNIT ADDR       04900019
         IC    UAREG,UCBTAB(UAREG)      FIND CHANNEL CONSTANT           04970019
         AIF   (&M7CH EQ 0).M7CH01                                 I267 05040019
         AR    UAREG,UAREG              DOUBLE CHAN CONS TO INDEX  I267 05110019
.M7CH01  AR    UAREG,UCBREG             CHAN INDEX + CU ADDRESS    I267 05180019
         AIF   (&TBYT EQ 0).TBYT01                                 IMP4 05250019
         AR    UAREG,UCBREG             CHAN INDX + 2 X CU ADR     IMP4 05320019
         LH    UAREG,UCBTAB(UAREG)      GET CU INDEX               IMP4 05390019
         AGO .TBYT03                                               IMP4 05460019
.TBYT01  IC    UAREG,UCBTAB(UAREG)      GET CU INDEX               IMP4 05530019
.TBYT03  N     WKREG1,DEVMSK            ISOLATE DEVICE             IMP4 05600019
         AR    UAREG,UAREG              DOUBLE C U CONSTANT             05670019
         AR    WKREG1,WKREG1            DOUBLE DEVICE ADDRESS           05740019
         AR    WKREG1,UAREG             CU CONST + 2X DEV ADDR          05810019
         CH    WKREG1,MAXUCBO           COMPARE WITH HIGHEST OFFSET     05880019
         LH    UAREG,IOPSWO+2           RE-INITIALIZE INT. ADD.   M0154 05910020
         BC    8+2,SERR-IECCPL02(APBSRG) CHECK FOR CHAN ERRORS @SA77644 05950018
         L     UCBREG,LISTA             FIND UCB LIST           SA71362 06020018
         LH    UCBREG,0(WKREG1,UCBREG)  FIND UCB POINTER        SA71362 06090018
         LTR   UCBREG,UCBREG            CHECK FOR PAD ENTRY             06160018
         BC    8,SERR-IECCPL02(APBSRG)  CHECK FOR CHAN ERRORS  @SA77644 06230018
          SPACE 1                                                  CCHB 06300019
*    INTERFACE TO SERR OR CCH IF CHANNEL ERROR                     CCHB 06370019
INT01A   TM    CSWLOC+5,CSWPCI          TEST FOR PCI INTERRUPT    21014 06490021
         BC    8,INT01B                 NO, TRACE THE INTERRUPT   21014 06500021
         TM    CSWLOC+5,CSWCTK+CSWICK+CATCCH CAT.ERRORS           21014 06510021
         BC    8,INTCCH                 PCI WITHOUT CAT. ERROR    21014 06560021
INT01B   HOOK  EID=IHLMIO2              TRACE ALL EXCEPT PCI      21014 06570021
         TM    CSWLOC+5,CSWCTK+CSWICK+CATCCH CAT.ERRORS           21014 06572021
         BC    7,SERR02-IECCPL02(APBSRG) YES, GO HANDLE THEM   @SA77644 06574018
INTCCH   DS    0H                                                  CCHB 06580019
         CLC   UCBTYP+2(2,UCBREG),IT7330 * IS DEVICE 7330?        ITH01 06580521
         BNE   ITIOSINT *               NO, SKIP CMD RTRY ROUTINE ITH01 06581021
         L     APBSRG,ITBLKMPX *        GET ADDR OF CMD RTRY MOD  ITH01 06582021
         BAL   LNKRG2,4(,APBSRG) *      CALL INTERRUPT ROUTINE    ITH01 06583021
ITIOSINT DS    0H *                     CONNECT                   ITH01 06589021
*   GET USER'S CONTROL BLOCKS IF RQE IS VALID.                          06650019
         TM    UCBFL1(UCBREG),UCBPST    IS THERE AN RQE            CCHB 06720021
         BC    8,INT009            NO-BY PASS SET-UP               IMP1 06790019
         AIF   (&TWOSW EQ 0).SXIOSF                             SA52441 06840021
*   FLUSH INTERRUPTS COMING FROM OTHER THAN LAST                SA52441 06850021
*   PATH STARTED WHILE DEVICE IS BUSY (UCBPST ON).              SA52441 06852021
         LH    WKREG1,UCBCHA(UCBREG)    GET DEVICE ADDRESS      SA52441 06854021
         N     WKREG1,CHCUMASK          LAST STARTED CH/CU ADDR SA52441 06856021
         XR    WKREG1,UAREG             ZERO CH/CU ADDR IF EQUALSA52441 06858021
         N     WKREG1,CHCUMASK          INT. PATH EQUAL LAST PATSA52441 06858421
         BC    7,INT027                 NO-TRY TO RESTART CHANNESA52441 06858821
.SXIOSF  AIF   (&M65MP EQ 0).MPB060                             SA52441 06859221
         LR    WKREG1,UCBREG            TRANSFER UCB POINTER    SA52441 06859621
         S     WKREG1,NEGDISP    GET NEGATIVE DISPLACEMENT IN UCSA52441 06859721
         IC    ICREG,UCBFL3(WKREG1) GET ID OF CPU THAT STARTED   SM5272 06862221
         N     ICREG,CPUIDMSK    MASK OUT ALL BITS EXCEPT IOCPUISA52441 06864921
         C     ICREG,IOCPUID           THIS CPU LAST STARTED    SA52441 06867421
         BC    7,INT027                 NO-TRY TO RESTART CHANNESA52441 06869921
.MPB060  LH    TSTREG,UCBLTS(UCBREG)    GET RQE POINTER FROM UCBSA52441 06880021
         STH   TSTREG,LTSVALSV          VALID RQE                A24739 06920019
         LM    IOBREG,DEBREG,TSTIOB-1(TSTREG) GET IOB + DEB ADDR A24739 06950021
         L     DCBREG,DEBDCB-1(DEBREG)    LOAD DCB ADDRESS              07000019
         AIF   (&PROTECT EQ 0).NVALCHK                          SA68418 07050021
         SPACE 1                                                        07052021
*    VALIDITY CHECK USER'S CONTROL BLOCKS IF NON SUPERVISOR             07060021
         SPACE 1                                                        07062021
         AIF   (&TCBTYP LT 2).PCP010    NOT MVT, SKIP            A24739 07070019
         TM    TSTKEY(TSTREG),X'F0'     CHECK FOR REQUESTOR KEY OF 0    07280019
         AGO   .PCP020                                          SA68418 07330021
.PCP010  ANOP                                                   SA68418 07340021
         TM    DEBPRT(DEBREG),PPKEY     CHECK FOR KEY 0 REQUEST SA68418 07342021
.PCP020  ANOP                                                   SA68418 07344021
         BC    8,INT002A                YES-SKIP VALCK                  07350019
         OI    XCPBTE,XCPVALID          SET VDTY CHK FLAG        A24739 07380019
         BAL   LNKRG2,VALCHK            NO-GO DO VALIDITY CHECK    VDTY 07420019
         NI    XCPBTE,FF-XCPVALID       RESET VDTY CHK FLAG      A24739 07450019
.NVALCHK ANOP                                                   SA68418 07490021
INT002A  TM    UCBCHA(UCBREG),UCBSMD   WAITING FOR SENSE OPERAT    IMP2 07560019
         BC    1,INT006                YES- RE-ENTER SENSE ROUTN   IMP2 07630019
         SPACE 1                                                        07700019
*   PREPARE LINKAGE TO PCI APPENDAGE IF REQUESTED BY USER.              07770019
INT003   TM    CSWLOC+5,CSWPCI         TEST FOR PCI INTERRUPT      IMP2 07840019
         BC    8,INT008                 NO-BYPASS PCI APPENDAGE SA52441 07890021
         L     APBSRG,DEBAPG-1(DEBREG)  GET APPD TABLE ADDR.            07940021
         L     APBSRG,APGPCI(APBSRG)    GET PCI APG ADDR.               08050019
         BALR  LNKRG2,APBSRG            TO APPENDATS                    08120019
         SPACE 1                                                        08190019
*    DEFINITION OF PCI APPENDAGE - IOS INTERFACE                 BBBBBB 08260019
*    INPUT     TSTREG,IOBREG,DEBREG,DCBREG,UCBREG,               BBBBBB 08330019
*              LNKRG2(RET ADDR),APBSRG(BASE ADDR)                BBBBBB 08400019
*    REGS CHANGED  WKREG1,WKREG2,WKREG3,LCHREG                   BBBBBB 08470019
         SPACE 1                                                        08540019
*   RETURN FROM PCI APPENDAGE.                                          08610019
         HOOK  EID=IHLMPCI              TRACE FOR PCI INTERRUPTS  21014 08640021
         AIF   (&SMF EQ 0).SMF110                                 TEST2 08710021
         AIF   (NOT &D2305).ZU020                                       08720020
         SPACE 1                                                        08730020
*              GO GET ADDR OF BASE EXPOSURE UCB IN CASE 2305      20201 08740020
         L     WKREG2,AZUSRTN           GET SUBRTN ADDR           20201 08750020
         BALR  LNKRG3,WKREG2            GO GET BASE ADDR IF 2305  20201 08760020
.ZU020   AIF   (&TCBTYP GT 1).SMF090                              20201 08770020
         BAL   LNKRG2,SMF010           GO SET UP TCB ADR           SMF2 08820019
         AGO   .SMF095                                             SMF2 08890019
.SMF090  L     REG0,TSTTCB(0,TSTREG)    SET UP TCB ADDRESS         SMF2 08960019
.SMF095  L     APBSRG,SMFRTN            GET ADDRESS OF SMF RTN     SMF2 09030019
         BALR  LNKRG2,APBSRG .          REPORT PCI TO SMF        A31489 09070020
         AIF   (NOT &D2305).SMF110                                20201 09120020
         LH    UCBREG,TSTUCB(0,TSTREG)  RE-INIT UCB POINTER       20201 09140020
.SMF110  LH    WKREG1,CSWLOC+4         GET STATUS                  SMF2 09170019
         N     WKREG1,PCIMSK           ANY STATUS EXCEPT PCI       IMP2 09240019
         BC    7,INT008                YES, CONTINUE                    09340018
         SR    TSTREG,TSTREG            CLEAR RQE ADDR REG      SA71481 09350018
         STH   TSTREG,LTSVALSV          NO VALID RQE            SA71481 09360018
         B     INT027                  GO TO CHANNEL RESTART  M2563     09390018
         SPACE 1                                                        09440020
*   ENTRY POINT FOR SIO POST INSPECTION                                 09660019
INT008   NI    UCBFL5(UCBREG),FF-UCBTICBT SHOW INTER. RECEIVED   A42261 09840021
         MVC   IOBCSW+1(7,IOBREG),CSWLOC+1 MOVE CSW TO IOB              09880021
         TM    CSWLOC+4,CSWCHE          TEST FOR CHANNEL END    SA52441 09930021
         BC    8,INT010                 NO, FREE UCB            SA52441 09932021
         TM    CSWLOC+4,CSWDVE          TEST FOR DEVICE END     SA60254 09940021
         BC    8,INT010A                NO, DON'T FREE UCB      SA60254 10010021
INT010   NI    UCBFL1(UCBREG),FF-UCBBSY YES-MAKE IT AVAILABLE    BBBBBB 10080019
INT010A  LH    WKREG1,CSWLOC+4          CHECK FOR ABNORMAL STATUS       10150019
         N     WKREG1,CHEDVE            TEST FOR OTHER BITS ON          10220019
         BC    7,INT011B           YES-GO TO STATUS INSPECTION     IMP2 10290019
         SPACE 1                                                   IMP2 10360019
*********************************************************************** 10430019
*                                                                     * 10500019
*                      TRAP ROUTINE EXIT                              * 10570019
*                                                                     * 10640019
*              THE FOLLOWING CODING SETS UP THE EXIT                  * 10710019
*              ADDRESS TO THE CORRECT TRAP ROUTINE                    * 10780019
*                                                                     * 10850019
INTTRAP  IC    ICREG,UCBDTI(UCBREG)     GET DEVICE TABLE INDEX          10920019
         LH    WKREG1,DEVTAB+DVTTRP(ICREG)   GET TRAP RTN INDEX         10990019
         AIF   (&TBASE EQ 0).TBS215                                IMP3 11060019
         AR    WKREG1,BASREG            ADJUST ADDRESS             RL19 11130019
.TBS215  BALR  LNKRG2,WKREG1           GO TO TRAP ROUTINE          IMP3 11200019
INTNOT   DS    0H *                     RETURN FOR NO TRAP DEVICESITH01 11201021
         CLC   UCBTYP+2(2,UCBREG),IT7330 * IS IT 7330?            ITH01 11202021
         BNE   ITINTNOT *               NO, SKIP IMMED RESTART    ITH01 11203021
         TM    UCBFL1(UCBREG),UCBASK+UCBDTR * SEEKEND?            ITH01 11204021
         BC    8+1,ITINTNOT *           NO, SKIP IMMED RESTART    ITH01 11205021
         NI    UCBFL1(UCBREG),FF-UCBPST * RESET POST FLAG         ITH01 11206021
         AIF   (&RMS EQ 0).IRMS03                                 ITH01 11209421
         L     WKREG1,RMSFLAD *         ADDR OF RMS FLAG          ITH01 11209621
         TM    0(WKREG1),RMSACTV *      TEST IF RMS REQUEST       ITH01 11209821
         BO    INT026 *                 YES, RETURN TO CH SEARCH  ITH01 11209921
.IRMS03  ANOP                                                     ITH01 11210021
         IECLNK1 ,LA,LNKRG1,IINT037,,,,&TBASE SET RET FOR PSIO    ITH01 11211021
         BAL   LNKRG3,XCP064 *          GO LOAD LCHREG            ITH01 11212021
         LH    UAREG,IOPSWO+2 *         GET UNIT ADDRESS          ITH01 11213021
         NI    UCBFL1(UCBREG),X'FF'-UCBCUB * CLEAR C.U.BSY        ITH01 11214021
         LA    REG0,IINT037 *           LOAD RET AND IND RESTART  ITH01 11215021
         B     RPSSIO *                 GO TO SIO ROUTINE         ITH01 11217021
IINT037  B     IINT026 *                BUSY OR SIO SUCCESSFUL    ITH01 11218021
         B     IINT026 *                CU BUSY OR CU END         ITH01 11219021
         B     IINT026 *                DEVICE BUSY               ITH01 11219221
         IECLNK1 IINT026,LA,LNKRG1,INT027,,,,&TBASE SET FOR CH SR ITH01 11219421
         B     INT026 *                 GO TO CH SEARCH           ITH01 11220021
ITINTNOT DS    0H *                     CONNECT                   ITH01 11230020
* IF A MACHINE MALFUNCTION OCCURS CAUSING PREMATURE TERMINATION SA69782 11232021
* WITH INVALID STATUS, PREVENT NORMAL POSTING; POST IN ERROR    SA69782 11234021
         TM    CSWLOC+4,CSWCHE+CSWDVE+CSWUEX  VALID TERM STATUS SA69782 11240021
         BC    4+1,INT019C              YES, CONTINUE           SA69782 11250021
         SR    ICREG,ICREG              CLEAR REG               SA69782 11250418
         CH    ICREG,CSWLOC+4           ZERO STATUS             SA69782 11250818
         BC    8,INT019K                YES, FORCE ERROR        SA69782 11251218
         TM    CSWLOC+4,CSWBSY+CSWSMD+CSWCUE  INVALID TERM STAT SA69782 11252021
         BC    8,INT019C                NO, CONTINUE            SA69782 11254021
         AIF   (&DAVV EQ 0).DAVV04                              SA74387 11256018
         TM    UCBTYP+2(UCBREG),DSKTYP  TEST FOR DIRECT ACCESS  SA74387 11258018
         BZ    INT019K                  NO, SKIP                SA74387 11258418
         TM    UCBFL4(UCBREG),UCBVVR    DAVV IN CONTROL         SA74387 11258818
         BO    INTERR4A                 YES, RESCHEDULE DAVV    SA74387 11259218
.DAVV04  ANOP                                                   SA74387 11259618
INT019K  MVI   UCBFL1(UCBREG),ZERO      CLEAR UCB FLAGS         SA69782 11260018
         MVI   IOBCOD(IOBREG),PERMER    SET PERM ERROR CODE     SA69782 11262021
         L     WKREG1,IOBFL1(IOBREG)    CLEAR SENSE             SA74387 11262418
         N     WKREG1,CLEARM                AND IOB FLAGS       SA74387 11262818
         ST    WKREG1,IOBFL1(IOBREG)            ONE AND TWO     SA74387 11263218
         OI    IOBFL1(IOBREG),IOBEX     SET IOB EXCEPTION FLAG  SA74387 11263618
         LA    APBSRG,APGABE            GET ABN END APG INCR    SA74387 11263718
         BC    15,INT12C                ENTER APG AS PERM ERROR SA74387 11263818
         SPACE 2                                                        11270019
*********************************************************************** 11340019
*                                                                     * 11410019
*           CHANNEL END AND ABNORMAL END APPENDAGE EXIT AND             11480019
*              CHANNEL END APPENDAGE BASE INCREMENT SETUP               11550019
*                                                                     * 11620019
*              THE FOLLOWING CODING IS THE EXIT TO THE                * 11690019
*              PROPER APPENDAGE (CHANNEL END OR ABNORMAL END).          11760019
*                                                                     * 11830019
INT019C  NI    UCBFL1(UCBREG),UCBBSY    RESET ALL EXECPT BUSY    BBBBBB 11900021
         TM    18(UCBREG),X'20'         DIRECT ACCESS DEVICE?  @SA76637 11910018
         BZ    INT019B                  NO,CONTINUE            @SA76637 11920018
         TM    CSWLOC+4,X'08'           CHANNEL END IN CSW?    @SA76637 11930018
         BO    INT019B                  YES,CONTINUE           @SA76637 11940018
         OI    6(UCBREG),X'08'          SET UCB CONT UNIT BUSY @SA76637 11950018
         B     INT17C                   AND RE-EXCP.           @SA76637 11960018
*   INCREMENT TO CHANNEL END APPENDAGE.                                 11970019
INT019B  LA    APBSRG,APGCHE            NORMAL END APD. INCR.           12040019
INT019   TM    IOBFL1(IOBREG),IOBERR    IS ERROR ROUTINE IN CONTROL     12110019
         BC    1,INTERR                 YES-BYPASS APPENDAGE     BBBBBB 12180019
         SPACE 1                                                        12250019
INT12C   L     WKREG1,DEBAPG-1(DEBREG)  GET APPENDAGE TABLE ADDRESS     12320019
         L     APBSRG,0(APBSRG,WKREG1)  FORM APPROPRATE APP. ADDR       12390019
*   SET CONDITION AND IOB EXCEPTION CODE BEFORE ENTERING APPENDAGE      12460019
         TM    IOBCSW+4(IOBREG),CSWUEX+CSWUCK+CSWBSY TEST FOR UNIT ERR  12530018
         BC    7,INT012                 TO APPENDAGE                    12600019
         TM    IOBCSW+5(IOBREG),CSWIL+CSWPC+CSWPCK+CSWCCK+CATBIT   CCHA 12670019
*                                       TEST OTHER CONDITIONS           12740019
         BC    8,INT12B                 SKIP SETTING OF FLAG            12810019
INT012   OI    IOBFL1(IOBREG),IOBEX     SET IOB EXCEPTION FLAG          12880019
INT12B   BALR  LNKRG2,APBSRG            TO PROPER APPENDAGE             12950019
         SPACE 1                                                        13020019
*    DEFINITION OF CHAN AND ABN END APPENDAGE - IOS INTERFACE    BBBBBB 13090019
*    INPUT     TSTREG,IOBREG,DEBREG,DCBREG,UCBREG,               BBBBBB 13160019
*              LNKRG2(RET ADDR),APBSRG(BASE ADDR)                BBBBBB 13230019
*    REGS CHANGED  WKREG1,WKREG2,WKREG3,LCHREG                   BBBBBB 13300019
         SPACE 1                                                        13370019
*********************************************************************** 13440019
*                                                                     * 13510019
*              CHANNEL END AND ABNORMAL END VECTOR TABLE              * 13580019
*                                                                     * 13650019
         BC    15,INT023                NORMAL                          13720019
         BC    15,INT024B          SKIP POST                       TBSE 13790019
         BC    15,INT17A                EXCP                            13860019
         BC    15,PRGCOMA               SKIP POST, DON'T RETURN RQE     13930019
         AIF   (&CEXT EQ 0).SPEXT1                                BBBBB 14000019
         BC    15,INT17                 SWITCH EXTENT RETURN      BBBBB 14070019
.SPEXT1  ANOP                                                     BBBBB 14140019
*                                                                     * 14210019
*********************************************************************** 14280019
*   THE NORMAL RETURN BRANCHES HERE                                     14350019
INT023   TM    IOBFL1(IOBREG),IOBEX     TEST FOR EXCEPTION              14420019
         BC    1,INTERR                 YES TO ERROR INTERFACE          14490019
INT024   BAL   LNKRG2,XCPPST            BRANCH TO POST ROUTINE          14560019
*   SKIP POST RETURN POINT                                              14630019
         AIF   (&TBASE EQ 1).TBS220                                     14700019
*   INT025 (EXTERNED) IS USED BY THE SUPERVISOR EXIT ROUTINE TO         14770019
*   RETURN AN RQE AND CHECK FOR PURGE COMPLETE AFTER DEQUEUING THE RQE  14840019
*   FROM AN IRB.                                                        14910019
*   RETURN IS BACK TO THE SUPERVISOR EXIT ROUTINE.                      14980019
INT025   DS    0H                                                       15050019
.TBS220  ANOP                                                      TBSE 15120019
INT024B  BAL   LNKRG2,PRGCOMB          GO CHECK FOR PURGE          IMP4 15190019
         SPACE 1                                                        15260019
         AIF   (&TCBTYP EQ 1).RQEMFT                                    15310021
INT025A  TM    TSTASSN(TSTREG),FF       IS RQE ALREADY FREE             15320021
         AGO   .RETNRQE                                                 15322021
.RQEMFT  ANOP                                                           15324021
INT025A  TM    TSTTCB(TSTREG),FF        IS RQE ALREADY FREE             15326021
.RETNRQE BC    1,INT026                 DON'T FREE IT AGAIN DUMMY       15328021
         MVC   TSTLNK(2,TSTREG),NEXAVL  RETURN RQE                      15330021
         STH   TSTREG,NEXAVL            TO NEXT AVAILABLE               15400019
         AIF   (&TCBTYP LT 2).INTPSD    NOT MVT, SKIP            A24739 15470019
         MVI   TSTASSN(TSTREG),FF       MARK AS AVAILABLE        BBBBBB 15540019
INT025B  BC    0,INTVMSA                TO TASK SW IF LAST RQE SW SET   15610019
         AGO   .INTVMSA                                                 15680019
.INTPSD  MVI   TSTTCB(TSTREG),FF        PUT FF IN TCBID FIELD    BBBBBB 15750019
.INTVMSA ANOP             MS/1 TASK SWITCH ROUTINE                      15820019
*   POST AND RQE RETURN SKIP                                            15890019
INT026   DS    0H                       GENERAL RETURN POINT     BBBBBB 15960019
         XC    LTSVALSV(2),LTSVALSV     NO VALID RQE             A24739 16020019
         IECLNK1 ,BCR,15,LNKRG1,,,,&TBASE                        A24739 16050021
         SPACE 1                                                        16100019
         AIF   (&TBASE EQ 0).TBS245                                TBSE 16170019
INT025   DS    0H                                                  TBSE 16240019
*   INT025 (EXTERNED) IS USED BY THE SUPERVISOR EXIT ROUTINE TO         16310019
*   RETURN AN RQE AND CHECK FOR PURGE COMPLETE AFTER DEQUEUING THE RQE  16380019
*   FROM AN IRB.                                                        16450019
*   RETURN IS BACK TO THE SUPERVISOR EXIT ROUTINE.                      16520019
         LR    WKREG1,BASREG2      SAVE REG CONTENTS FOR RETURN    TBSE 16590019
         BALR  BASREG,0                                            TBSE 16660019
INT0025  LA    BASREG2,INT0025-IOSBAS                              TBSE 16730019
         SR    BASREG,BASREG2      SET LOW BASE REGISTER           TBSE 16800019
         LA    BASREG2,4094(BASREG)     SET UP HIGH BASE REG       RL19 16870019
         ST    WKREG1,BUSYSV           SAVE RETURN TO EXIT         TBSE 16940019
         LA    WKREG1,INT0025A         RETURN FROM SELECTV         TBSE 17010019
         ST    WKREG1,LNKRG1S                                      TBSE 17080019
         BC    15,INT024B                                          TBSE 17150019
         SPACE 1                                                        17220019
INT0025A L     BASREG2,BUSYSV          RESTORE SUPVSR BASE         TBSE 17290019
         BCR   15,BASREG2              RETURN TO SUPRVSR EXIT      TBSE 17360019
.TBS245  SPACE 1                                                   TBSE 17430019
         AIF   (&CEXT EQ 0).SPEXT2                                BBBBB 17500019
*   SPECIAL CH. END APPENDAGE ENTRY FOR EXTENT SWITCHING.         BBBBB 17570019
*   THE NEW EXTENT IS INDICATED BY THE IOB MODIFIER BYTE SETTING. BBBBB 17640019
*   INITIALIZE REG0 FOR ABTERM IN CASE OF ILLEGAL UCB ADDRESS.    BBBBB 17710019
         SPACE 1                                                  BBBBB 17780019
INT17    DS    0H                                                 BBBBB 17850019
         AIF   (&TCBTYP LT 2).TCB050    NOT MVT, SKIP            A24739 17920019
         L     WKREG3,TSTTCB(TSTREG)    GET TCB ADDRESS           BBBBB 17990019
         AGO   .TCB051                                            BBBBB 18060019
.TCB050  IC    ICREG,TSTTCB(TSTREG)     GET TCB ID                BBBBB 18130019
         SLL   ICREG,2                                                  18160019
         L     WKREG3,TCBTBL            GET TCB TABLE ADDRESS     BBBBB 18200019
         L     WKREG3,0(ICREG,WKREG3)   GET PROPER TCB ADDRESS    BBBBB 18270019
.TCB051  LA    REG0,0(WKREG3)           INIT ABERM INTERFACE REG  BBBBB 18340019
*   DETERMINE VALIDITY OF NEW EXTENT                              BBBBB 18410019
         BAL   LNKRG3,XCP061            USE COMMON RTN TO VAL CHK BBBBB 18480019
         SPACE 1                                                  BBBBB 18550019
*   NEW EXTENT WAS GOOD - SET UP RQE                              BBBBB 18620019
         STH   UCBREG,TSTUCB(TSTREG)    CHANGE UCB PTR IN RQE     BBBBB 18690019
.SPEXT2  SPACE 1                                                  BBBBB 18760019
*   EXCP EXIT FROM APPENDAGE VECTOR TABLE                               18830019
INT17A   DS    0H                                                 19022 18900019
         AIF   (NOT &D2305).ZUS040                                20201 18900520
         SPACE 1                                                        18901020
*              GO GET ADDR OF BASE EXPOSURE UCB IN CASE 2305      20201 18901520
         L     WKREG2,AZUSRTN           GET SUBRTN ADDR           20201 18902020
         BALR  LNKRG3,WKREG2            GO GET BASE ADDR IF 2305  20201 18902520
         STH   UCBREG,TSTUCB(0,TSTREG)  RESET IN CASE BASE FOUND  2020  18903020
.ZUS040  AIF   (&TSO EQ 0).INTS3        TEST FOR TSO              20001 18903520
         NC    DEBEPG(3,DEBREG),DEBEPG(DEBREG)    TEST FOR ADDR   20001 18904020
         BC    8,INT17A1                NO-BRANCH AROUND          20001 18906020
         L     WKREG2,DEBEPG-1(DEBREG)  GET LIST ADDR FOR TSO PRG 20001 18908020
         TM    ZERO(WKREG2),LSTOPT      TEST FOR LIST OPTION      20001 18910020
         BC    8,INT17A1                NO-BRANCH AROUND          20001 18912020
         L     WKREG1,QPLPTR(WKREG2)    GET LIST POINTER          20001 18914020
         LA    WKREG1,FOUR(WKREG1)      UPDATE TO FIRST ENTRY     20001 18916020
         AIF   (&TCBTYP EQ 2).INTS1     TEST FOR MVT              20001 18918020
INTSLP   L     WKREG2,FOUR(WKREG1)      GET TCB ADDRESS           20001 18920020
         CLC   TCBID(1,WKREG2),TSTASSN(TSTREG)    TCB ID COMPARE  20001 18922020
         AGO   .INTS2                                             20001 18924020
.INTS1   ANOP                                                     20001 18926020
INTSLP   CLC   TSTTCB+1(3,TSTREG),FIVE(WKREG1) TEST FOR TCB COMP  20001 18928020
.INTS2   BC    7,INTSLP1                NO-TEST FOR LAST          20001 18930020
         MVC   IOBRST(3,IOBREG),ONE(WKREG1)  IOB TO TOP OF CHAIN  20001 18932020
         ST    IOBREG,ZERO(WKREG1)      IOB ADDR TO CHAIN FLD     20001 18934020
         MVI   IOBCC(IOBREG),X'FF'      SET PTK SAVED INDICATOR@SA78151 18934618
         MVZ   IOBCC(1,IOBREG),TSTKEY(TSTREG) SAVE PTK IN IOB  @SA78151 18935318
         B     INT024B                  GO TO PURGE COMP RTN      20001 18936020
INTSLP1  TM    FOUR(WKREG1),QPLFLST     TEST FOR LAST ENTRY       20001 18938020
         BC    1,INT17A1                YES-CONTINUE NORMAL       20001 18940020
         AH    WKREG1,EIGHT             BUMP TO NEXT ENTRY        20001 18942020
         B     INTSLP                   GO TEST NEXT              20001 18944020
INT17A1  DS    0H                                                 20001 18946020
.INTS3   ANOP                                                     20001 18948020
         AIF   (&SMF EQ 0).SMF150                                  SMF2 18970019
         AIF   (&TCBTYP GT 1).SMF130    IF MVT, SKIP             A24739 19040019
         BAL   LNKRG2,SMF010           GO SET UP TCB ADR           SMF2 19110019
         AGO   .SMF135                                             SMF2 19180019
.SMF130  L     REG0,TSTTCB(0,TSTREG)   SET UP TCB ADDRESS          SMF2 19250019
.SMF135  L     APBSRG,SMFRTN            GET ADDRESS OF SMF RTN     SMF2 19320019
         BALR  LNKRG2,APBSRG .          REPORT EXCP RETRY TO SMF A31489 19390020
.SMF150  ANOP                                                     19022 19460019
INT17B   MVI   IOBCOD(IOBREG),NORMC     SET NORMAL COMPLETION     19022 19530019
         XC    IOBFL3(9,IOBREG),IOBFL3(IOBREG) CLEAR FLGS,SENSE   19022 19600019
         XC    IOBECT(2,IOBREG),IOBECT(IOBREG)  ZERO ERROR COUNT A43797 19630021
         NC    IOBFL1(4,IOBREG),CLEARM  CLEAR FLAGS AND SENSE      IMP5 19670019
INT17C   BC    15,INTER7A               PICK UP ENQUEUE            PRER 19740019
         EJECT                                                          19810019
*  THIS SECTION INVESTIGATES NON-CHANNEL END CONDITIONS                 19880019
INT009   NI    UCBFL5(UCBREG),FF-UCBTICBT SHOW INTER. RECEIVED   A42261 19940021
         TM    UCBCHA(UCBREG),UCBSMD    WAITING FOR SENSE OPER. US05348 19990018
         BO    INT011                   YES, CHECK ATTENTION    US05348 19992018
         TM    UCBFL1(UCBREG),UCBBSY+UCBASK+UCBCUB INT. EXPECTED A27707 20000021
         BC    7,IINT009J *             YES, BRANCH AROUND        ITH01 20080020
         CLC   UCBTYP+2(2,UCBREG),IT7330 * IS IT 7330             ITH01 20091021
         BNE   INTATT *                 NO, HANDLE LIKE ATTENTION ITH01 20092021
         TM    CSWLOC+4,CSWRETRY *      RETRY STATUS FROM HIO     ITH01 20093021
         BO    INTSEN3A *               YES, GO ISSUE SENSE       ITH01 20094021
         L     WKREG1,UCBWKADB(0,UCBREG) * GET PTR TO EXTENSION   ITH01 20095021
         TM    RSBFLG1(WKREG1),RTRYSSS * PURGED RETRY ON SK&SS    ITH01 20095221
         BNO   INTATT *                 NO, HANDLE LIKE ATTENTION ITH01 20095421
         NI    RSBFLG1(WKREG1),X'FF'-RTRYSSS * CLEAR RETRY SK&SS  ITH01 20095621
         B     INTSEN3A *               GO ISSUE SENSE            ITH01 20095821
IINT009J DS    0H *                     CONNECT                   ITH01 20096021
         TM    CSWLOC+4,CSWUCK+CSWUEX   INTERCEPT COND AT D.E.   BBBBBB 20190019
         BC    8,INT011                 NO-GO FREE UCB                  20370018
*  IF ERP IS ALREADY IN CONTROL (RQE ON QUEUE FOR RESTART) DO    A32507 20390020
*   NOT TREAT AS INTERCEPT, BUT GO TO CHANNEL RESTART.           A32507 20400020
         TM    UCBFL1(UCBREG),UCBASK+UCBERR+UCBCUB UCBLTS GOOD   A36514 20410021
         BC    4+1,INT011 .             YES, DO NOT INTERCEPT    A32507 20420020
         SPACE 1                                                        20430020
*   NEXT TIME WILL INTERCEPT IOB                                        20440019
         MVC   UCBLTS(2,UCBREG),CSWLOC+4     MOVE STATUS TO UCB         20510019
         OI    UCBFL1(UCBREG),UCBITF    SET INTERCEPT FLAG              20580019
INT011   NI    UCBFL1(UCBREG),FF-UCBBSY . MARK FREE             US05348 20650018
         CLC   UCBTYP+2(2,UCBREG),IT7330 * IS IT 7330?            ITH01 20651021
         BNE   IINT011J *               NO, BRANCH AROUND         ITH01 20652021
         TM    UCBCHA(UCBREG),UCBSMD *  SENSE WAITING?            ITH01 20653021
         BNO   IINT011J *               NO, BRANCH AROUND         ITH01 20654021
         NI    UCBCHA(UCBREG),X'FF'-UCBSMD * RESET SENSE FLAG     ITH01 20655021
         B     INTSEN3A *               GO DO SENSE               ITH01 20657021
IINT011J DS    0H *                     CONNECT                   ITH01 20658021
INT011B  EQU   *                                                SA74193 20660018
         AIF   (NOT &D2305).ZU000       TEST FOR ZEUS IN SYS    SA74193 20700018
         LR    WKREG1,UCBREG            SAVE UCB ADDR           SA74193 20702018
         L     WKREG2,AZUSRTN           GO CHECK IF DEVICE IS   SA74193 20710018
         BALR  LNKRG3,WKREG2            A 2305 AND GET BASE AD  SA74193 20712018
         BC    7,INT011C                NO, CONTINUE            SA74193 20714018
         NI    UCBFL1(UCBREG),FF-UCBBSY FREE THE BASE           SA74193 20716018
         LR    UCBREG,WKREG1            RESTORE EXPOSURE UCB AD SA74193 20718018
.ZU000   SPACE 1                                                SA74193 20720018
*    ENTERED FROM MAINLINE ON ANY INTERRUPT WITH ABNORMAL STATUS.       20790019
INT011C  TM    CSWLOC+4,CSWATN     CSW CONTAIN ATTENTION           IMP2 20840018
         BC    1,INTATT2           YES-GO TO ATTENTION RTN.        IMP2 20930019
INT013   TM    UCBCHA(UCBREG),UCBSMD    WAITING FOR SENSE OPER. US05348 20980018
         AIF   (&TP EQ 0 AND &RESREL EQ 0).RR020                SA75351 20992418
         BO    INTSEN4                  YES, RETURN TO SENSE RT SA75351 20992818
         AGO   .RR022                                           SA75351 20993218
.RR020   BO    INTSEN6                  YES, RETURN TO SENSE RT SA75351 20993618
.RR022   ANOP                                                   SA75351 20993718
INT013B  TM    CSWLOC+4,CSWUCK     CSW=UNIT FAILURE                IMP2 21000018
         BC    1,INTSEN            YES-GO TO SENSE RTN.            IMP2 21070019
         TM    UCBFL1(UCBREG),UCBPST  OPERATION COMPLETE INTERRUPT IMP2 21140019
         IECLNK1 ,BCR,8,LNKRG1,,,,&TBASE                           TBSE 21210019
*        TEST FOR CATASTROPHIC ERRORS                             19062 21280019
         TM    CSWLOC+5,CSWPC+CSWPCK+CSWCDK+CSWCTK+CSWICK+CSWCCK  19062 21420019
         BC    8,INTTRAP                NO, RETURN TO NORMAL FLOW 19062 21620021
         BC    15,INT031                GO TO ABN APPENDAGE       19062 21840019
         SPACE 1                                                 BBBBBB 21910019
INT006   DS    0H                                                BBBBBB 21980019
         AIF   (&TP EQ 1 OR &RESREL EQ 1).ASR2                    21111 22010021
         AIF   (&ASR EQ 0 OR &M65MP EQ 1).RR025                   21111 22040021
.ASR2    TM    IOBFL2(IOBREG),IOBSNB    WAITING FOR DEVICE        BBBBB 22070021
         AIF   (&TP EQ 0 AND &RESREL EQ 0).ASR2A                  21111 22100021
         BC    8,INTSEN4                NO MUST BE END OF SENSE   BBBBB 22130021
         AGO   .RR025                                                   22160021
.ASR2A   BC    8,INTSEN6                NO MUST BE LOG PEND COND  21111 22190021
.RR025   OC    CSWLOC+1(7),IOBCSW+1(IOBREG) OR IN PREVIOUS COND. BBBBBB 22260019
         NI    IOBFL2(IOBREG),FF-IOBSNB RESET SENSE FLAG         BBBBBB 22330019
         NI    UCBCHA(UCBREG),FF-UCBSMD RESET SENSE FLAG         BBBBBB 22400019
         BC    15,INT008                                                23100019
      TITLE 'CHANNEL RESTART INITIALIZATION - INPUT/OUTPUT SUPERVISOR'  23400021
*              RETURN TO I/O FLIH SUBROUTINE                            23870019
*                                                                       23940019
*                                  AND                                  24010019
*                                                                       24080019
*              CHANNEL RESTART INITIALIZATION SUBROUTINE                24150019
         SPACE 3                                                        24220019
* CHECK IF OTHER CHANNELS NEED PROCESSING BEFORE RETURNING         IMP3 24710019
INT033   L     WKREG2,CHMSK             GET MASK BYTE             19021 24780019
         SR    WKREG3,WKREG3           CLEAR COUNTER               IMP3 24850019
INT030A  ALR   WKREG2,WKREG2           DOUBLE THE MASK BYTE        IMP3 24920019
         BC    8,INT033C                IF BYTE=0, GO TO TEST EXIT19021 24990019
         LA    WKREG3,1(WKREG3)        IF OVERFLOW OR BYTE NOT 0   IMP3 25060021
         BC    4,INT030A               CONT. TILL CORRECT CHAN FOUNDMP3 25130019
         BCTR  WKREG3,0                ON OVERFLOW, BACK UP CHANADRIMP3 25200019
         STC   WKREG3,IOPSWO+2         SET UP CHAN FOR RESTART          25270019
* THIS IS A GENERAL RETURN FROM AN I/O INTERRUPT (IECINT) ENTRY,   IMP3 25340019
* FOR THE PURPOSE OF RESTARTING THE CHANNEL THAT CAUSED THE        IMP3 25410019
* INTERRUPT.  ERREXCP, THE SELECT ROUTINE TRY-AGAIN VECTOR, AND    IMP3 25480019
* DISK ERP'S REQUIRING FUTHER I/O ALSO BRANCH HERE.                IMP3 25550019
         SPACE 1                                                   IMP5 25620019
INT027   DS    0H                                                       25670021
         AIF   (&M7CH EQ 0).RST027                                      25680021
         CLI   CHMSK,RSTMSK             RESTART ALL CHANNELS            25682021
         BC    7,INTM7CH                NO, CHMSK OK                    25684021
         MVC   CHMSK(2),RST7MSK         RESTART ALL CHANNELS            25684421
.RST027  ANOP                                                           25686021
INTM7CH  IC    ICREG,IOPSWO+2           GET CH ADR FOR RESTART   BBBBBB 25690021
         AIF   (&M65MP EQ 0).MPB039                                MP1A 25710020
         LR    WKREG1,ICREG     TRANSFER CHAN ADDR                 MP1A 25730020
         AR    WKREG1,WKREG1     DOUBLE ADDR TO GET INDEX          MP1A 25750020
         NI    CHAN0-IEAQFX00(WKREG1),X'FF'-CHBSY   FREE CHANNEL   MP1A 25770020
.MPB039  AIF   (&M7CH EQ 1).M7CH002                                     25790020
         SLL   ICREG,2                  CH ADR * 4 TO SPAN TAB ENT BBBB 25830019
         LA    WKREG1,IECCST(ICREG)     POINT AT CHAN TAB ENTRY  BBBBBB 25900019
         OC    CHMSK(1),LCTMSK(WKREG1) SET ON IN CASE OF INTERRUPT IMP3 25970019
         AGO   .M7CH003                                            MSVN 26040019
.M7CH002 L     WKREG1,CHANBIT           GET CHANNEL BIT            I267 26110019
         SRL   WKREG1,ZERO(ICREG)       DERIVE PSW EQUIVALENT      MSVN 26180019
         LR    WKREG2,WKREG1            SAVE IT FOR LATER          MSVN 26250019
         O     WKREG1,CHMSK             PICK UP ANY CHANS TO RSTRT MSVN 26320019
         ST    WKREG1,CHMSK             SET THIS CHAN IN CASE OF INTSVN 26390019
         SLL   ICREG,2                  ICREG = ICREG * 4          IMP3 26460019
.M7CH003 ANOP                                                      MSVN 26530019
         LH    LNKRG2,IECCST(ICREG)    GET CHANNEL SEARCH CODE ADR IMP3 26600019
         AIF   (&TBASE EQ 0).TBS249                                IMP3 26670019
         AR    LNKRG2,BASREG            ADJUST ADDRESS             RL19 26740019
.TBS249  TM    XCPBTE,XCPCNT+XCPST+XCPRMS EXCP OR MCH ENTRY       19021 26810019
         BC    4+1,INT027A              YES, NO ENABLE            19021 26880019
* PROCESS ANY STACKED INTERRUPTS BEFORE CHANNEL SEARCH             IMP3 26950019
         AIF   (&M65MP EQ 0).MPB053A                               MP1A 27020019
INT030B  LPSW  MPENBA                  ENABLE FOR INTERRUPTS       MP1A 27090019
         AGO   .MPB053B                                            MP1A 27160019
.MPB053A SSM   XCPENB                  ENABLE FOR INTERRUPTS       MP1A 27230019
.MPB053B ANOP                                                      MP1A 27300019
* IF AN INTERRUPT IS PENDING, THE FLIH WILL RE-ENTER IOS AT IECINT.     27370019
* IF NO INTERRUPT IS PENDING, THE NEXT INSTRUCTION IS EXECUTED.    IMP3 27440019
         AIF   (&M65MP EQ 0).MPB053C                               MP1A 27510019
INT030C  LPSW  MPDSBA                                              MP1A 27580019
         AGO   .MPB053D                                            MP1A 27650019
.MPB053C SSM   IONPSW                  DISABLE BEFORE CH.SRCH.     MP1A 27720019
.MPB053D CLI   CLPCNT,ZERO              CH LOGOUT COUNT ZERO    SA71482 27770018
         BE    INT027A                  YES, CONTINUE           SA71482 27780018
         L     APBSRG,ACLPRTN           GET ADDR OF CH LOGOUT RTSA71482 27782018
         BR    APBSRG                   GO TO CHAN LOG PEND RTN SA71482 27784018
         AIF   (&M7CH EQ 1).M7CH004                             SA71482 27790018
INT027A  XC    CHMSK(1),LCTMSK(WKREG1)  RESET THIS CHANNEL        19021 27860019
         AGO   .M7CH005                                            MSVN 27930019
.M7CH004 ANOP                                                      MSVN 28000019
INT027A  X     WKREG2,CHMSK             RESET THIS CHANNEL         MSVN 28070019
         ST    WKREG2,CHMSK             STORE ALL OTHERS BACK      MSVN 28140019
.M7CH005 BR    LNKRG2                   GO TO CHANNEL SEARCH    SA71482 28280018
*    SEND EXCP, RMS, AND SHOULDER TAP ENTRIES TO EXIT ROUTINE     19021 28350019
INT033C  TM    XCPBTE,XCPCNT+XCPST+XCPRMS TEST NON-INTRPT ENTRY   19021 28420019
&LABEL   SETC  'XCP021'                                           19021 28490019
         AIF   (&RMS EQ 0 AND &M65MP EQ 0).RMS30                  19021 28560019
&LABEL   SETC  'IECEXIT'                                          19021 28630019
.RMS30   BC    4+1,&LABEL               YES-GO TO EXIT PROC       19021 28700019
*    ENABLE TO ACCEPT ANY PENDING I/O INTERRUPTS                  19021 28770019
         AIF   (&M65MP EQ 0).MPB052A                               MP1A 28840019
INT033A  LPSW  MPENB                   ENABLE FOR INTERRUPTS       MP1A 28910019
         AGO   .MPB052B                                            MP1A 28980019
.MPB052A SSM   XCPENB                  ENABLE FOR INTERRUPTS       MP1A 29050019
.MPB052B L     WKREG1,DISMIS            GET RETURN ADDRESS              29120019
         SPACE 1                                                        29190019
*    DISABLE AND RETURN TO I/O FLIH IF NO CHAN NEEDS TO BE RESTARTED    29260019
         AIF   (&M65MP EQ 0).MPB052C                               MP1A 29330019
INT033B  LPSW  MPDSB                   DISABLE AND TEST FOR EXIT   MP1A 29400019
         AGO   .MPB052D                                                 29470019
.MPB052C SSM   IONPSW                  DISABLE AND TEST FOR EXIT   MP1A 29540019
.MPB052D BCR   15,WKREG1                RETURN TO I/O FLIH        19021 29610019
         AIF   (&RMS EQ 0 AND &M65MP EQ 0).RMS31                  19021 29680019
         SPACE 1                                                  19021 29750019
*    EXIT PROCEDURE FOR NON-INTERRUPT ENTRIES                     19021 29820019
IECEXIT  DS    0H                                                 19021 29890019
         AIF   (&RMS EQ 0).RMS32                                  19021 29960019
         TM    XCPBTE,XCPRMS            TEST FOR RMS IN CTL       19021 30030019
         L     APBSRG,RMSEXAD           ADDR OF IECRMS           BBBBBB 30070020
         BC    1,INTRMSEX-IECRMS(APBSRG)  YES-GO TO RMS EXIT            30120020
.RMS32   AIF   (&M65MP EQ 0).RMS33                                19021 30170019
         TM    XCPBTE,XCPST             TEST FOR SHOULDER TAP ENT 19021 30240019
         BC    1,IECIOSTV                                               30310020
.RMS33   BC    15,XCP021                GO TO SVC EXIT            19021 30380019
.RMS31 TITLE 'COMMON CHANNEL SEARCH ROUTINE - INPUT/OUTPUT SUPERVISOR'  30450021
*********************************************************************** 30457020
*                                                                     * 30464020
*                                                                     * 30471020
*                  COMMON CHANNEL SEARCH ROUTINE OF IOS               * 30478020
*                                                                     * 30485020
*    THE FOLLOWING CODE, IN COMBINATION WITH THE CHANNEL-DEPENDENT    * 30492020
*    CHANNEL SEARCH MODULES, CONSTITUTES THE CHANNEL SEARCH ROUTINE OF* 30499020
*    IOS. EACH CHANNEL SEARCH MODULE INITIALIZES LCHREG WITH THE      * 30506020
*    APPROPRIATE LOGICAL CHANNEL WORD ADDRESS, AND ROUTES CONTROL TO  * 30513020
*    VARIOUS ENTRY POINTS WITHIN THE COMMON ROUTINE, SO THAT THE      * 30520020
*    COMMON ROUTINE MAY DETERMINE THE STARTABILITY OF EACH REQUEST    * 30527020
*    ON THE QUEUE IN TURN.                                            * 30534020
*                                                                     * 30541020
*                                                                     * 30548020
*********************************************************************** 30555020
         SPACE 2                                                        30562020
*    THIS PORTION GETS CONTROL IF THE CHANNEL HAS SEEKABLE DEVICES.     30569020
INT036C  LR    TSTREG,LCHREG            INITIALIZE PTR TO TOP           30590019
INTCIC   LH    TSTREG,TSTLNK(TSTREG)    GET NEXT RQE                    30660019
         SPACE 1                                                        30670021
*  RETURN FROM SEARCH CODE- ONLY FOR OVERLAP SEEKS                      30730019
INT036   LTR   TSTREG,TSTREG            IS THIS THE LAST RQE            30800019
         BC    4,CHSNXT(LNKRG2)         YES-SKIP TO NEXT LCH            30870019
         LH    UCBREG,TSTUCB(TSTREG)    ADDR. OF DEVICE                 30940019
         TM    UCBFL1(UCBREG),UCBASK+UCBDTR+UCBBSY+UCBNRY+UCBPST A24150 31010019
         BCR   7,LNKRG2                 NO-SKIP IT                      31150019
         TM    UCBTYP+2(UCBREG),DSKTYP  DIRECT ACCESS TYPE              31220019
         BCR   8,LNKRG2                 NO-SKIP THIS ONE                31290019
         AIF   (&RPS EQ 0).RPS06                                  19025 31360019
         TM    UCBTYP+1(UCBREG),UCBRPS  TEST FOR RPS              19025 31430019
         BCR   1,LNKRG2                 YES, SKIP UNTIL DATA XFER 19025 31500019
.RPS06   AIF   (NOT &D2301 AND NOT &D2303 AND NOT &D2305).SXIOSS4 20201 31570020
         TM    UCBTYP+3(UCBREG),DRUM    IFDRUM NO SEEK                  31640019
         BCR   1,LNKRG2                 SO SKIP THIS REQUEST            31710019
.SXIOSS4 BC    15,INT034B               TO START UP DEVICE              31780019
         SPACE 3                                                  20201 31850020
*    THIS PORTION GETS CONTROL FOR ALL DATA TRANSFER OPERATIONS.  20201 31920020
INT034C  LR    TSTREG,LCHREG            INITIALIZE POINTER TO TOP       31990019
INT034D  LH    TSTREG,TSTLNK(0,TSTREG)  PICK NEXT IN QUEUE              32060019
INT034   LTR   TSTREG,TSTREG            TEST FOR DUMMY RQE              32130019
         BC    4,CHSNXT(LNKRG2)         CONTINUE WITH NEXT DISK OR UNIT 32200019
*              THIS WAS A VALID QUEUED REQUEST                          32270019
         SPACE 1                                                        32340019
         LH    UCBREG,TSTUCB(TSTREG)    SELECT                          32410019
INT034A  TM    UCBFL1(UCBREG),UCBDTR+UCBBSY+UCBNRY+UCBPST          TPF1 32480019
*                                       TEST ALL NOT AVAILABLE FLAGS    32550019
         BCR   7,LNKRG2                 BRANCH NOT AVAIL  TRY NEXT      32620019
         TM    UCBTYP+2(UCBREG),DSKTYP    DIRECT ACCESS                 32690019
         BC    8,INT034B                NO, BRANCH AROUND         20201 32696020
         AIF   (NOT &D2301 AND NOT &D2303 AND NOT &D2305).IODRM10 20201 32702020
         TM    UCBTYP+3(UCBREG),DRUM    IS IT A DRUM              20201 32708020
         BC    1,INT034B                YES, GO START IT          20201 32714020
.IODRM10 AIF   (&RPS EQ 0).RPS07                                  20201 32720020
         CLC   UCBTYP+2(2,UCBREG),IT7330 * IS IT 7330             ITH01 32721021
         BE    IINT034J *               YES, DONT CHK RPS         ITH01 32722021
         TM    UCBTYP+1(UCBREG),UCBRPS  IS IT AN RPS DEVICE       20201 32726020
         BC    1,INT034B                YES, GO START IT          20201 32732020
.RPS07   SPACE 1                                                  20201 32738020
*    SCREEN OUT A REQUEST FOR WHICH THE STAND-ALONE SEEK IS COMPLETE,   32744020
*    AND WHICH IS THEREFORE READY TO BEGIN THE DATA TRANSFER OPERATION. 32750020
         TM    UCBFL1(UCBREG),UCBASK    IS SEEK COMPLETE          20201 32756020
         BCR   8,LNKRG2                 NO, GET NEXT REQUEST      20201 32762020
IINT034K DS    0H *                     TEST IF SAME RQE          ITH01 32765021
         CH    TSTREG,UCBLTS(0,UCBREG)  YES, IS THIS THE SAME RQE 20201 32768020
         BCR   7,LNKRG2                 NO, GET NEXT REQUEST      20201 32774020
         AIF   (&RESREL EQ 0 AND &RML EQ 0).RR040                 ITH01 32780020
         TM    UCBCHA(UCBREG),UCBHLT    DOES DEVICE REQUIRE RELEAS20201 32786020
         BC    1,INTRREL                YES, GO EXECUTE RELEASE   20201 32792020
         CLC   RRDCBDEB+1(3),TSTDEB(TSTREG) HAS SIO BEEN TRIED    M3422 32798020
         BC    8,INTRREL1               YES, GO RE-INIT. UCB ADR  20201 32804020
.RR040   ANOP                                                     20201 32810020
INT034B  DS    0H                                                 19021 32830019
         AIF   (&RMS EQ 0).RMS03                                  19021 32900019
         L     WKREG1,RMSFLAD           ADDR OF RMS FLAG         BBBBBB 32940020
         TM    0(WKREG1),RMSACTV        TEST IF RMS REQUEST      BBBBBB 32980020
         L     APBSRG,RMSAD             ADDR OF INTRMS           BBBBBB 33020020
         BCR   1,APBSRG                 YES-GO TO CHECK RQE      BBBBBB 33060020
INTRMS1  DS    0H                                                 19021 33110019
.RMS03   ANOP                                                           33120021
         STH   TSTREG,LTSVALSV          VALID RQE                A24739 33130019
         STM   LCHREG,LNKRG2,BUSYSV     SAVE REGS FOR POSS RETURNA24739 33140021
         LM    IOBREG,DEBREG,TSTIOB-1(TSTREG)  FOR RESTART         IMP3 33250019
         L     DCBREG,DEBDCB-1(DEBREG)    SET UP REGISTERS         IMP3 33320021
         IECLNK1 ,LA,LNKRG1,INT037,,,,&TBASE                       TBSE 33390019
         LA    LNKRG2,XCP011            SET UP TO GO TO TEST CHAN  IMP4 33460019
         TM    UCBFL1(UCBREG),UCBCUB+UCBERR IS LAST RQE IMPORTANT  IMP4 33530019
         BC    7,INT034H                YES - CHECK FURTHER             33600019
INT034G  TM    IOBFL1(IOBREG),IOBURL    IS IOB UNRELATED                33670019
         BCR   1,LNKRG2                YES, GO TO TEST CHAN OR XCP IMP3 33740019
         TM    DCBFL(DCBREG),DCBPER    PERM ERR IN PREVIOUS REQ    IMP3 33810021
         BCR   8,LNKRG2                NO, TO TEST CHAN OR XCP     IMP3 33880019
         BC    1,INT038B                YES, PURGE REQUEST         IMP3 33950019
* THIS DCB IS FLAGGED - ERP IN CONTROL - FIND IOB ERP IS PROCESSING     34020019
         TM    IOBFL1(IOBREG),IOBERR   IS ERP IN CONTROL           IMP3 34090019
         BCR   7,LNKRG2                YES, TRY TO START THIS REQ  IMP3 34160019
         IECLNK1 ,BC,15,SELBSY,0,LNKRG1,,&TBASE                    TBSE 34230019
         SPACE 1                                                        34300019
INT034H  CH    TSTREG,UCBLTS(0,UCBREG)  WAS IT LAST REQUEST STARTED     34370019
         BC    7,INT037+SELBSY          NO - CONTINUE WITH RESTART      34440019
         BCR   15,LNKRG2                YES - START IT UP               34510019
IINT034J TM    UCBFL1(UCBREG),UCBASK *  IS SEEK COMPLETE?         ITH01 34551021
         BO    IINT034K *               YES, GO TEST IF SAME RQE  ITH01 34552021
         B     INT034B *                GO START IT               ITH01 34553021
         SPACE 1                                                   IMP4 34580019
*********************************************************************** 34650019
*                                                                     * 34720019
*                  SELECT ROUTINE RETURN VECTOR TABLE                 * 34790019
*                       FOR CHANNEL RESTART                           * 34860019
INT037   BC    15,INT035A               ACCEPT VECTOR CONT. WITH SEARCH 34930019
         BC    15,INT027                TRY FROM THE TOP AGAIN     IMP5 35000019
         BC    15,INT035                BUSY VECTOR-GET NEXT RQE.       35070019
*****    BC    15,INT037B               CHANGE LCH VECTOR          IMP5 35140019
*                                                                     * 35210019
*********************************************************************** 35280019
INT037B  TM    IOBCC(IOBREG),IOBCC3     WAS REQ REJECTED DUE TO    P340 35350019
*                             CONTROL UNIT BUSY OR CC1,2, OR 3     P340 35420019
         BC    7,INT035                 YES DO NOT SWITCH LCH WORD P340 35490019
         AIF   (&APR EQ 0).APR00C                                       35560019
         AIF   (NOT &D2305).NOZUS                               SA68549 35610021
         L     WKREG2,AZUSRTN           GET ZEUS SUBRTN ADDR    SA68549 35620021
         BALR  LNKRG3,WKREG2            GO GET BASE ADR IF 2305 SA68549 35622021
.NOZUS   ANOP                                                   SA68549 35624021
         TM    UCBCHM(UCBREG),OF        IS A PATH OFFLINE               35630019
         BC    4+1,INT035               YES, DON'T SWITCH LCH WORDS     35700019
.APR00C  LM    LCHREG,LNKRG2,BUSYSV     RECOVER LAST LCH VECTOR  BBBBBB 35780021
         XC    LTSVALSV(2),LTSVALSV     NO VALID RQE             A24739 35820019
         AIF   (&RPR EQ 1).SXIOSS5                               A24739 35840021
         BC    15,CHSNXT(0,LNKRG2)      CONTINUE SEARCH WITH NEXT LCH   35910019
         SPACE 1                                                        35980019
         AGO   .SXIOSS6                                                 36050019
.SXIOSS5 LA    TSTREG,DUMMY             SET LCH TO END OF QUEUE    PRQ1 36120019
         BCR   15,LNKRG2                TO CONTINUE SEARCH              36190019
.SXIOSS6 SPACE 1                                                        36260019
INT035A  DS    0H                                                  SMF1 36330019
         L     TSTREG,BLNKPTR          INIT RQE TO BACK LINK PTR   SMF1 36400019
INT035   LM    LCHREG,LNKRG2,BUSYSV     RE-INITIALIZE FOR CH. SEARCH    36470019
         XC    LTSVALSV(2),LTSVALSV     NO VALID RQE             A24739 36530019
         BCR   15,LNKRG2                CONTINUE CHN SRCH        A24739 36560021
         SPACE 2                                                  20201 37310020
*   THE DCB FOR THIS REQUEST INDICATES A PERMANENT ERROR ON A      IMP4 38150019
*   PREVIOUS REQUEST.  THIS REQUEST MUST THEREFORE BE DEQUEUED     IMP4 38220019
*   AND THE ABNORMAL END APPENDAGE MUST BE ENTERED.                IMP4 38290019
INT038B  DS    0H                                                  IMP4 38360019
         BAL   LNKRG2,XCPPDQ            GO DEQUEUE REQUEST      SA66299 38430021
         MVI   IOBCOD(IOBREG),PRGCOD    MARK IOB PURGED            IMP4 38500021
         CH    TSTREG,UCBLTS(UCBREG)    IS RQE ON UCB?          SA66299 38570021
         BC    8,INT031                 YES, CLEAR FLAGS, AB AP SA66299 38620021
         BC    15,INT031B               TO ABNORM END APPENDAGE SA66299 38630021
         AIF   (&RESREL EQ 0 AND &RML EQ 0).RMS08                 ITH01 38640019
         SPACE 1                                                   IMP5 38710019
*    THE FOLLOWING ROUTINE INITIALIZES CONTROL BLOCKS FOR          IMP5 38780019
*    EXECUTING A RELEASE TO A DEVICE ASSOCIATED WITH A PURGED    BBBBBB 38850019
*    REQUEST.  RETURN IS TO INT034B.                             BBBBBB 38920019
         SPACE 1                                                   IMP5 38990019
INTRREL  DS    0H                       RELEASE ROUTINE            IMP5 39060019
         MVI   UCBSKA(UCBREG),ZERO      INSURE M IS 0 IN THE UCB   IMP5 39130019
*    NOW INITIALIZE THE RQE.                                       IMP5 39200019
         LA    IOBREG,RRIOB             GET IOB ADDRESS            IMP5 39270019
         ST    IOBREG,TSTIOB-1(0,TSTREG) STORE IT IN THE RQE       IMP5 39340019
         MVC   TSTDEB(3,TSTREG),RRDCBDEB+1 PUT DEB PTR IN RQE     M3422 39410019
         AIF   (&TCBTYP EQ 2).MVTRREL   MVT SYSTEM              SA55452 39460021
         MVI   TSTTCB(TSTREG),ZERO      SKIP VALIDITY CHECK        IMP5 39480019
         AGO   .ENDRREL                                         SA55452 39530021
.MVTRREL MVC   TSTTCB(4,TSTREG),ERRTCB  PUT SYS ERR TCB IN RQE  SA55452 39540021
.ENDRREL ANOP                                                   SA55452 39542021
INTRREL1 STH   UCBREG,RRDEBUCB+2       PUT UCB PTR. INTO DEB       IMP5 39550019
         BC    15,INT034B               GO BACK TO MAINLINE IOS    IMP5 39620019
.RMS08   TITLE 'QUIESCE COMPLETE ROUTINE - INPUT/OUTPUT SUPERVISOR'     40620021
*                     QUIESCE COMPLETE SUBROUTINE                       42560021
         SPACE 2                                                        42630019
*   THIS ROUTINE POSTS THE PURGE ECB WHEN QUIESCE COMPLETE              42700019
         SPACE 3                                                        42770019
PRGCOMA  LA    LNKRG2,INT026            RETURN ADDR IF BYPASS      TSOS 42840019
PRGCOMB  NC    DEBEPG(3,DEBREG),DEBEPG(DEBREG)    TEST FOR ADDR   20001 42940020
         BCR   8,LNKRG2                 NO-RETURN                  TSOS 43050019
         L     WKREG2,DEBEPG-1(DEBREG)  GET LIST ADDR FOR TSO PRG 20001 43080020
         TM    ZERO(WKREG2),TWO         PURGE BY TCB OR DEB      BBBBBB 43120019
         BC    8,PRGCOMA1               BRANCH IF BY DEB           TSOS 43190019
         AIF   (&TSO EQ 0).PRGNTS       TEST FOR TSO              20001 43210020
         TM    ZERO(WKREG2),LSTOPT      TEST FOR LIST OPTION      20001 43230020
         BC    8,PRGTCBCM               NO, GO DO TCB ADDR COMP  M5401  43234020
         L     WKREG1,QPLPTR(WKREG2)    GET TCB LIST POINTER     M5401  43238020
PRGTCBLP CLC   TCBADR+1(3,WKREG1),TSTTCB+1(TSTREG) TCB ADDR COMP M5401  43242020
         BE    PRGCOMA1                 YES, CONTINUE WITH COUNT M5401  43246020
         TM    TCBADR(WKREG1),QPLFLST   END OF TCB LIST          M5401  43250020
         BCR   1,LNKRG2                 YES, RETURN              M5401  43254020
         LA    WKREG1,TCBADR(WKREG1)    NO, GET NEXT TCB         M5401  43258020
         BC    15,PRGTCBLP                                       M5401  43262020
.PRGNTS  AIF   (&TCBTYP LT 2).PRGID     TEST FOR OPTION 4         20001 43270020
PRGTCBCM CLC   TCBADR+1(3,WKREG2),TSTTCB+1(TSTREG) TCB ADDR COMP M5401  43330020
         AGO   .PRGTCB                                             TSOS 43400019
.PRGID   L     WKREG1,TCBADR(WKREG2)    GET TCB ADDRESS          BBBBBB 43470019
PRGTCBCM CLC   TCBID(1,WKREG1),TSTASSN(TSTREG) TCB ID COMPARE    M5401  43540020
.PRGTCB  BCR   7,LNKRG2                 NO - RETURN                TSOS 43610019
PRGCOMA1 IC    ICREG,DEBQUS(DEBREG)     GET COUNT FROM DEB       BBBBBB 43680019
         LTR   ICREG,ICREG              TEST FOR ANY COUNT         TSOS 43750019
         BCR   12,LNKRG2                NO - RETURN                TSOS 43820019
         BCT   ICREG,PRGDEC1            DECREMENT DEB COUNT        TSOS 43890019
         XC    DEBEPG(3,DEBREG),DEBEPG(DEBREG) CLR PARM. LIST ADDR TSOS 43960019
PRGDEC1  STC   ICREG,DEBQUS(DEBREG)     UPDATE DEB COUNT           TSOS 44030019
         IC    ICREG,QCNT(WKREG2)       GET TOTAL CNT FROM LIST  BBBBBB 44100019
         LTR   ICREG,ICREG              TEST FOR ANY COUNT      SA61289 44150021
         BCR   12,LNKRG2                NO - RETURN             SA61289 44160021
         BCT   ICREG,PRGDEC2            DECREMENT COUNT            ABCD 44200019
         STC   ICREG,QCNT(WKREG2)       ZERO MAIN COUNTER         20001 44290020
PRGPST1  L     WKREG3,ZERO(0,WKREG2)    GET TCB ADDRESS            TSOS 44380021
         LA    WKREG2,FOUR(0,WKREG2)    GET ECB ADDRESS          BBBBBB 44450019
         LA    WKREG1,NORMC             GET NORMAL COMP CODE     BBBBBB 44520019
         SLL   WKREG1,24                SHIFT CODE                 TSOS 44590019
         L     APBSRG,POSTADR           GET ADDR. TO POST          TSOS 44660019
         BCR   15,APBSRG                GO TO POST                 TSOS 44730019
         SPACE 2                                                   TSOS 44800021
PRGDEC2  STC   ICREG,QCNT(0,WKREG2)     STORE UPDATED COUNT        ABCD 44820019
         BCR   15,LNKRG2                RETURN                          44830019
         AIF   (&SMF EQ 0 OR &TCBTYP GT 1).SMF070                A24739 44880019
         SPACE 2                                                   SMF2 44940019
*    THE FOLLOWING ROUTINE PUTS THE ADDRESS OF THE TCB IN REG 0.   SMF2 45010019
SMF010   IC    ICREG,TSTTCB(TSTREG)    GET TCB ID                  SMF2 45080019
         SLL   ICREG,2                  MULTIPLY BY 4             M4778 45110019
         L     WKREG1,TCBTBL           GET TCB TABLE ADDRESS       SMF2 45150019
         L     REG0,0(ICREG,WKREG1)     GET TCB ADDRESS            SMF2 45220019
         SR    ICREG,ICREG              CLEAR PRIOR TO RETURN     M1542 45250020
         BCR   15,LNKRG2                RETURN TO CALLER           SMF2 45290019
.SMF070  SPACE 1                                                   RL19 45360019
         AIF   (&TCBTYP LT 2).INTATN    NOT MVT, SKIP            A24739 45430019
    TITLE 'TASK SWITCH ON LAST RQE RETURN - INPUT/OUTPUT SUPERVISOR'    45500021
*         THIS ROUTINE IS ENTERED ONLY IF THE LAST RQE WAS USED AND     45570019
*         A EXCP ISSUED CAUSING IOS TO SET THE NON DISPATCHABILITY BIT  45640019
*         IN THE TCB OF THE ISSUING  TASK.                              45710019
*                   1. RESET ALL RQE NON DISP. BITS IN TCBS ON RDY Q    45780019
*                   2. INDICATE TASK SWITCH TO IEAHEAD                  45850019
*                   3. RESET THE NO-OP BRANCH SWITCH FOR LAST RQE       45920019
INTVMSA  MVI   INT025B+1,ZERO           RESET LAST RQE SWITCH    BBBBBB 45990019
         L     WKREG1,AIEAHEAD          GET ADDRESS OF HEAD TCB         46060019
INTSDISP L     WKREG2,AIEADS02          GET ADD. OF TASK SW.            46130019
         NI    TCBFLGS(WKREG1),FF-TCBRQENA RESET NON-DISP. BIT   BBBBBB 46200019
         BALR  LNKRG2,WKREG2            INVOKE TASK SWITCH              46270019
***  RETURN FROM TASK SWITCH ROUTINE                                    46340019
         L     WKREG1,TCBTCB(0,WKREG1)  GET NEXT TCB ON READY Q         46410019
         LTR   WKREG1,WKREG1            ARE WE FINISHED                 46480019
         BC    7,INTSDISP               NO, PROCESS NEXT                46550019
         BC    15,INT026                YES, RETURN TO MAINLINE         46620019
.INTATN  ANOP                                                           46670021
  TITLE 'ATTENTION INTERFACE AND TRAP CODE - INPUT/OUTPUT SUPERVISOR'   46690021
*        IOS INTERRUPT SUPERVISOR ATTENTION ROUTINE INTERFACE           46760019
         SPACE 2                                                        46830019
*      FUNCTION:    TO LINK TO ATTENTION ROUTINE                        46900019
*         ENTRY:    MAIN LINE OF EXCP AND MAIN LINE OF IOS INTERRUPT    46970019
*                   SUPERVISOR                                          47040019
*          EXIT:    ATTENTION ROUTINE                                   47110019
         SPACE 3                                                        47180019
INTATT   TM    CSWLOC+4,CSWCHE+CSWDVE                              IMP2 47250019
         BC    8+1,INT011B             LET ONLY D.E.'S THROUGH     IMP2 47320019
INTATT2  IC    ICREG,UCBATI(UCBREG)    GET INCREMENT TO ATN RTN    IMP2 47390021
         L     APBSRG,ATNTAB(ICREG)     GET ADDRESS OF ATN RTN          47460019
         L     WKREG1,XITFTR            SET EXIT EFFECTOR ADDR. FOR RTN 47530019
         BALR  LNKRG2,APBSRG            BRANCH TO ATTENTION ROUTINE     47600019
INTATT3  NI    UCBFL1(UCBREG),FF-UCBNRY-UCBITF-UCBBSY           US05348 47670018
         LH    TSTREG,UCBLTS(UCBREG)    GET RQE ADDRESS AGAIN-USED IN   47740019
*                                       ATTENTINON ROUTINE              47810019
         TM    UCBFL1(UCBREG),UCBPST+UCBDTR+UCBASK+UCBERR+UCBCUB US5348 47880018
         BC    7,INT013                YES- RETURN TO MAIN LINE    TPF1 47950019
         MVI   UCBLTS(UCBREG),ZERO      INDICATE DVE TO ERR RTN  BBBBBB 48020019
         BC    15,INT013                BACK TO MAIN LINE FLOW          48090019
         SPACE 3                                                   DAVV 48160019
         AIF   (&DAVV EQ 0).DAVV06                                 DAVV 48230019
*    DUMMY APPENDAGE FOR USERS WHO DO NOT REQUIRE APPENDAGES.      DAVV 48300019
         SPACE 1                                                   DAVV 48370019
SYSRTN   BCR   15,LNKRG2                RETURN ON REGISTER 14      DAVV 48440019
         SPACE 3                                                   DAVV 48510019
*    ATTENTION ROUTINE FOR DEVICES WHICH DO NOT REQUIRE ATTENTION  DAVV 48580019
*    ROUTINES.  THIS ROUTINE INITIATES THE SCHEDULING OF THE XSNT  DAVV 48650019
*    VOLUME VERIFICATION ROUTINE FOR 2311 AND 2314 UNSOLICITED     DAVV 48720019
*    DEVICE END INTERRUPTS.                                        DAVV 48790019
         SPACE 1                                                   DAVV 48860019
INTATN   TM    UCBTYP+2(UCBREG),DSKTYP  TEST FOR DIRECT ACCESS     DAVV 48930019
         BCR   8,LNKRG2                 NO, RETURN                 DAVV 49000019
         NI    UCBFL4(UCBREG),FF-UCBDAVV ZERO DAVV FLAGS        SA57136 49030021
         TM    SRTESTAT(UCBREG),SYSCON  SYSRES DEVICE              DAVV 49070019
         BCR   1,LNKRG2                 YES, RETURN                DAVV 49140019
         TM    UCBTYP+3(UCBREG),DRUM    TEST FOR DRUM            A30638 49160019
         BCR   1,LNKRG2                 YES, RETURN              A30638 49180019
         AIF   (NOT &D2321).DCEL005                               20201 49380020
         CLI   UCBTYP+3(UCBREG),UCB2321 TEST FOR 2321            BBBBBB 49770019
         BC    8,INTATN2                YES-NO TEST FOR VOL SER  BBBBBB 49840019
.DCEL005 CLI   UCBVOL1(UCBREG),ZERO     TEST IF VOL SER IN UCB   BBBBBB 49910019
         BCR   8,LNKRG2                 NO, RETURN                 DAVV 49980019
INTATN2  OI    UCBFL4(UCBREG),UCBVVR    SET DAVV RTN TO GET CTL  BBBBBB 50050019
         MVI   UCBRQESV(UCBREG),ZERO    INIT FIELD FOR DAVV RTN    DAVV 50120019
         BCR   15,LNKRG2                RETURN                     DAVV 50190019
         AGO   .DAVV07                                             DAVV 50260019
.DAVV06  ANOP                                                      DAVV 50330019
*    THIS IS THE DUMMY APPENDAGE AND ATTENTION ROUTINE WHICH IS    DAVV 50400019
*    REFERRED TO BY USERS WHO DO NOT REQUIRE APPENDAGES, AND BY    DAVV 50470019
*    DEVICES WHICH DO NOT REQUIRE ATTENTION ROUTINES.              DAVV 50540019
         SPACE 1                                                   DAVV 50610019
INTATN   DS    0H                                                  DAVV 50680019
SYSRTN   BCR   15,LNKRG2                RETURN ON REGISTER 14      DAVV 50750019
.DAVV07  EJECT                                                     DAVV 50820019
*              UNIT RECORD TRAP CODE MODULE                             50890019
         SPACE 2                                                        50960019
INTURT   DS    0C                                                       51030019
         TM    UCBFL1(UCBREG),UCBBSY    RESTART POSSIBLE         BBBBBB 51100019
         BCR   8,LNKRG2                 YES-CONTINUE                    51170019
* SELECTOR SUB CHANNELS HAVE 0C0 ADDRESSES- MULTIPLEXOR SHARED SUBCH.   51240019
*  HAVE 080 ADDRESSES. THE NEXT CODE TRIES TO CIRCUMVENT CH. RESTART    51310019
*   ON DEVICES WHICH ARE CONNECTED TO THE MULTIPLEXOR AND PRESENTS      51380019
*   CHE/DVE SEPERATELY.                                                 51450019
         LR    WKREG1,UAREG             GET DEVICE ADDR          A47317 51500021
         SRL   WKREG1,8                 SEPARATE OFF CHAN ADDR   A47317 51550021
         SLL   WKREG1,2                 MULTIPLY CHAN BY 4       A47317 51600021
         LA    WKREG1,IECCST(WKREG1)    GET CHAN TBL ENTRY       A47317 51650021
         TM    LCTFLS(WKREG1),LCTSLBX   TEST FOR SEL OR BLK MPX  A47317 51652021
         BCR   1,LNKRG2                 YES, GO RESTART CHANNEL  A47317 51654021
         CLI   UCBUA(UCBREG),SHRDMPX    TEST FOR SHARED          A47317 51656021
         BCR   8+2,LNKRG2               YES, GO RESTART CHANNEL SA73324 51658018
         SPACE 1                                                        51660019
*   BECAUSE OF CASCADING INTERRUPTS FROM THE MULTIPLEXOR CHANNEL AT     51730019
*   INT027, DO NOT CIRCUMVENT CHANNEL RESTART IF IMMEDIATE              51800019
*   OPERATION WAS PERFORMED AND TRAP CODE ENTERED AFTER SIO.            51870019
         SPACE 1                                                        51940019
         TM    IOBCC(IOBREG),IOBCC3 ENTERED FRM IMMEDIATE OPERATION0588 52010019
         BCR   7,LNKRG2                 YES-TRY TO RESTART CHANNEL 0588 52080019
         IECLNK1 ,BALR,LNKRG1,LNKRG2,,,INT033D,&TBASE              TBSE 52150019
         SPACE 1                                                        52220019
INT033D  BC    15,INT033                TO EXIT                         52290019
         SPACE 2                                                        52360019
         AIF   (&TAPE EQ 0).STIOS22                                     52430019
*              TAPE TRAPCODE MODULE                                     52500019
         SPACE 1                                                        52570019
         AIF   (&VS EQ 0 AND &ASPN EQ 0).NOVSTAT                  21048 52640021
         AIF   (&ASPN EQ 0).NOASP                                 21048 52690021
INTASP   DS    0C                       ENTRY POINT FOR 3420      21048 52700021
.NOASP   ANOP                                                     21048 52710021
         AIF   (&VS EQ 0).NOVES                                   21048 52760021
INTTAT   DS    0C                  INTRY POINT FOR 2400 WITH VES  21048 52770021
         AIF   (&RWTAU EQ 0).NOVES     READ WRITE TAU?            21048 52780021
         TM    CSWLOC+4,CSWSMD+CSWBSY  IS CONTROL UNIT BUSY       21048 52830021
         BC    1,INTERR3A              YES-GO TEST FOR ERROR      21048 52840021
.NOVES   ANOP                                                     21048 52850021
*********************************************************************** 52900021
*                                                                       52910021
*         STATISTICS UPDATE ROUTINE                               21048 52920021
*                                                                       52970021
*         USED FOR BOTH VES AND 3420                              21048 52980021
*                                                                       52990021
         TM    IOBFL1(IOBREG),IOBERR   IS ERR RTN IN CONTROL      21048 53040021
         BC    1,COMCOD                YES-DO NOT UPDATE CTR      21048 53050021
         L     WKREG1,UCBROR(0,UCBREG)  GET POINTER TO WRK AREA   21048 53060021
         LH    WKREG2,SIOCNT(0,WKREG1)  GET SIO COUNT             21048 53110021
         LA    WKREG2,ONE(0,WKREG2)     UPDATE COUNTER            21048 53120021
         STH   WKREG2,SIOCNT(0,WKREG1)   STORE COUNT              21048 53130021
*********************************************************************** 53180021
         AIF   (&VS EQ 1).VES                                     21048 53190021
.NOVSTAT ANOP                                                     21048 53200021
INTTAT   DS    0C              INTRY POINT FOR 2400 W/O VES       21048 53250021
         AIF   (&RWTAU EQ 0).VES                                  21048 53260021
         TM    CSWLOC+4,CSWSMD+CSWBSY  IS CONTROL UNIT BUSY       21048 53270021
         BC    1,INTERR3A              YES-GO TEST FOR ERROR      21048 53320021
.VES     ANOP                                                     21048 53330021
COMCOD   L     WKREG1,DCBBLK(0,DCBREG)  GET BLOCK COUNT           21048 53340021
         AH    WKREG1,IOBBCI(IOBREG)     INC BLOCK COUNT          21048 53390021
         ST    WKREG1,DCBBLK(DCBREG)     STORE UPDATED BLOCK COUNT21048 53400021
         BCR   15,LNKRG2                                          21048 53410021
         SPACE 2                                                        54390019
.STIOS22 ANOP                                                           54460019
*              DISK TRAPCODE MODULE                                     54530019
         SPACE 1                                                        54600019
INTDAT   TM    UCBFL1(UCBREG),UCBASK+UCBDTR SEEK END                    54670019
         BCR   8+1,LNKRG2               NO-EXIT                         54740019
         NI    UCBFL1(UCBREG),FF-UCBPST RESET POST FLAG          BBBBBB 54810019
         BC    15,INT026           TO RETURN FOR CH. S.            IMP1 54880019
         SPACE 2                                                        54950019
         AIF   (NOT &D2305).ZU010                                 20201 54957020
*    TRAP CODE FOR 2305 DRUM                                      20201 54964020
         SPACE 1                                                  20201 54971020
INTZUT   L     WKREG1,UCBWKADB(UCBREG)  GET PTR TO UCB EXTENSION  20201 54978020
         L     WKREG1,EXPCHN+BASADR(WKREG1)  GET BASE             20201 54985020
         NI    UCBFL1(WKREG1),FF-UCBBSY MAKE IT AVAILABLE         20201 54992020
         BCR   15,LNKRG2                                          20201 54999020
.ZU010   SPACE 2                                                  20201 55006020
         AIF   (&TP EQ 0).STIOS24                                       55020019
*   THIS IS THE TELECOMMUNICATIONS TRAP MODULE                          55090019
         SPACE 1                                                        55160019
XCPTPT   BCR   15,LNKRG2                TO APPENDAGE INSPECTION         55230019
.STIOS24 AIF   (&GR EQ 0).GRH                                           55300019
         SPACE 3                                                        55370019
*  GRAPHIC UNITS TRAP CODE                                              55440019
         SPACE 1                                                        55510019
INTDNP   TM    UCBFL1(UCBREG),UCBBSY    UCBBSY DE/CE OR DE ALONE        55580019
         BCR   8,LNKRG2                 YES SKIP                        55650019
         TM    UCBFL5(UCBREG),UCBNALOC  DOES OLTEP OWN DEVICE           55710000
         BCR   1,LNKRG2                                                 55712000
         OI    IOBFL2(IOBREG),IOBSNB+IOBGRF SET CH. END ALONE           55720021
         BC    15,INT026           RETURN                          IMP2 55790019
.GRH     TITLE 'SENSE ROUTINE - INPUT/OUTPUT SUPERVISOR'                55850021
*********************************************************************** 55910020
*                                                                     * 55970020
*                                                                     * 56030020
*                           SENSE SUBROUTINE                            56090020
*                                                                     * 56150020
*    FUNCTION  SELECT PROPER DEVICE-DEPENDENT SENSE ENTRY POINT,      * 56210020
*              USING THE DEVICE TABLE INDEX IN THE UCB, CONSTRUCT THE * 56270020
*              APPROPRIATE CCW'S FOR EXECUTING THE SENSE OPERATION,   * 56330020
*              ISSUE THE SIO COMMAND, AND HANDLE THE RESULTING        * 56390020
*              CONDITIONS.                                            * 56450020
*                                                                     * 56510020
*    ENTRY PT  INTSEN, FROM THE INTERRUPT HANDLER AFTER UNIT CHECK    * 56570020
*              OR CHANNEL ERRORS.                                     * 56630020
*                                                                     * 56690020
*    EXITS     TO ABNORMAL END APPENDAGE IF NORMAL REQUEST            * 56750020
*              TO INT026, IF DEVICE IS BUSY, TP, OR SHARED FILE       * 56810020
*              TO INTERR, IF ERP IS IN CONTROL                        * 56870020
*              TO CCH IF CHANNEL ERRORS                               * 56930020
*                                                                     * 56990020
*    OPERATION CONSTRUCT THE DEVICE-DEPENDENT CHANNEL PROGRAM AND GO  * 57050020
*              TO THE COMMON CODE TO ISSUE SIO, AND IF NOT TP OR      * 57110020
*              RHA/R0, TIO.  HANDLE THE RESULTS AS FOLLOWS-           * 57170020
*                                                                     * 57230020
*        CSW STORED - C.C.=1 - EXAMINE STATUS                         * 57290020
*           CHANNEL ERRORS - GO TO SERR04                             * 57350020
         AIF   (&ASR EQ 0 OR &M65MP EQ 1).ASRCL05                 21111 57360021
*           CHANNEL LOGOUT PENDING CONDITION - SET DELAYED SENSE BIT  * 57370021
*                                              IN UCB-INCREMENT COUNT * 57380021
*                                              AND EXIT VIA LNKRG1    * 57390021
.ASRCL05 ANOP                                                     21111 57400021
*           UNIT CHECK - SET EQUIPMENT CHECK INDICATION IN FIRST      * 57410020
*                        TWO SENSE BYTES - X'10FE' - AND GO TO INTS09 * 57470021
*           ALL REMAINING STATUS - COPY FIRST TWO SENSE BYTES INTO    * 57530020
*           THE IOB, DEQUEUE THE RQE, AND ENTER THE ABNORMAL END      * 57590020
*           APPENDAGE. IF THE ERP IS IN CONTROL, HOWEVER, ENTER THE   * 57650020
*           ERP INTERFACE AT INTERR.                                  * 57710020
*                                                                     * 57770020
*           IF NO RQE WAS AVAILABLE, RETURN VIA LNKRG1                * 57830020
*                                                                     * 57890020
*        BUSY - C.C.=2                                                * 57950020
*              RE-ISSUE THE COMMAND                                   * 58010020
*                                                                     * 58070020
*        NON-OPERATIONAL - C.C.=3, OR C.C=0 AFTER TIO                 * 58130020
*              SET EQUIPMENT CHECK INDICATION, GO TO INTS09           * 58190020
*                                                                     * 58250020
*                                                                     * 58310020
*********************************************************************** 58370020
         SPACE 3                                                  20201 58430020
INTSEN   TM    UCBFL1(UCBREG),UCBBSY    IS UCB BUSY               20201 58490020
         BC    8,INTSEN3A               NO, CONTINUE WITH SENSE SA59828 58550021
         SPACE 1                                                  20201 58610020
*   SET FLAGS TO CAUSE RETURN TO SENSE ON DEVICE END              20201 58670020
         OI    IOBFL2(IOBREG),IOBSNB    SET SENSE FLAG IN IOB     20201 58730020
INTSEN2  OI    UCBCHA(UCBREG),UCBSMD   SET RETURN TO SENSE FLAG    IMP5 58790020
         SRL   UAREG,8                  ISOLATE CHANNEL ADDRESS SA59828 58840021
         AR    UAREG,UAREG              DOUBLE CHANNEL ADDR     SA59828 58842021
         STH   UCBREG,UCBSAVE(UAREG)    SET UP FOR FAST LOOKUP  SA59828 58844021
         BAL   WKREG1,IINTSENJ *        GO TEST IF CMD RETRY      ITH01 58845021
         B     IINTSEN2 *               NO, CONTINUE PROCESSING   ITH01 58845221
         L     WKREG1,UCBWKADB(0,UCBREG) * GET PTR TO EXTENSION   ITH01 58845421
         TM    RSBFLG1(WKREG1),RTRYSSS * IS RETRY CMD SK&SS       ITH01 58845621
         IECLNK1 ,BC,1,SELBSY,0,LNKRG1,,&TBASE * YES, BUSY EXIT   ITH01 58845821
IINTSEN2 DS    0H *                     CONNECT                   ITH01 58845921
         TM    UCBFL1(UCBREG),UCBPST    IS THERE AN RQE         US05348 58846018
         BO    INT026                   YES, EXIT, WAIT FOR INT US05348 58848018
         OI    UCBFL1(UCBREG),UCBBSY    IND INT EXPECTED        US05348 58848818
         BC    15,INT026                EXIT, WAIT FOR INTERRUPTSA59828 58850021
         SPACE 1                                                  20201 58910020
INTSEN3A DS    0H                                               SA61121 58960021
         AIF   (&ASR EQ 0).ASR6         CCH IN SYSTEM           SA61121 58962021
         SPACE 1                                                SA61121 58964021
*   INITIALIZE A COUNTER TO ALLOW THREE RETRIES OF THE SENSE    SA61121 58966021
*   OPERATION WHEN CHANNEL ERRORS OCCUR.                        SA61121 58968021
         LA    REG0,3                   INIT 3 INTO REG 0       SA61121 58968421
.ASR6    ANOP                                                   SA61121 58968821
         MVI   SNSCNT,ZERO              CLEAR RETRY COUNT       SA61121 58969221
INTSEN3  IC    ICREG,UCBDTI(UCBREG)     GET INDEX TO DEVICE TABLE 20201 58970021
         LH    LNKRG2,DEVTAB+DVTSEN(ICREG) GET PTR TO SENSE RTN   20201 59030021
         AIF   (&TBASE EQ 0).TBS233                               20201 59090020
         AR    LNKRG2,BASREG            ADJUST ADDRESS            20201 59150020
.TBS233  BCR   15,LNKRG2                GO TO SENSE ROUTINE       20201 59210020
         AIF   (&TP EQ 0).TP050                                   20201 59270020
         SPACE 3                                                  20201 59330020
*   SENSE ENTRY FOR TELEPROCESSING DEVICES                        20201 59390020
TPSEN    LA    LNKRG3,INTSEN2           SET RETURN ADDRESS A51138 20201 59450021
         BC    15,INTS00                JOIN COMMON CODE          20201 59510020
.TP050   SPACE 3                                                  20201 59570020
*    SENSE ENTRY FOR ALL NEW DEVICES                              20201 59630020
EXPSEN   BAL   WKREG1,IINTSENJ *        GO TEST IF CMD RETRY      ITH01 59681021
         B     IEXPSEN *                NO, GO SETUP FOR SENSE    ITH01 59682021
         L     WKREG1,UCBWKADB(0,UCBREG) * GET PTR TO EXTENSION   ITH01 59684021
         LA    WKREG2,UCBWKDCC(0,WKREG1) * POINT TO BLKMPX CP     ITH01 59684221
         L     WKREG2,SEEK2(0,WKREG2) * GET SEEK ARG ADDRESS      ITH01 59684421
         MVC   SSS1ARG(6),0(WKREG2) *   SETUP SEEK ADDRESS        ITH01 59684621
         MVC   SSS1ARG+6(1),RSBSECTR(WKREG1) SETUP SECTOR VALUE   ITH01 59684821
         L     WKREG1,RSBCAW(WKREG1) *  GET CAW FOR RETRY SIO     ITH01 59685021
         B     INTS03P *                GO DO RETRY SIO           ITH01 59686021
IEXPSEN  MVC   SYSSENSE+7(1),UCBSNS+2(UCBREG) * INIT BYTE COUNT   ITH01 59690020
         L     WKREG2,UCBSNS+2(UCBREG)  GET POINTER TO SENSE AREA 20201 59750020
         AIF   (&RESREL EQ 0 AND &TP EQ 0).TP090                  20201 59800021
         LA    LNKRG3,INTS05A           SETUP RETURN REG         A51138 59810021
.TP090   BC    15,INTS01                GO TO COMMON SENSE SUBROU 20201 59870021
         SPACE 3                                                  20201 59930020
*   ENTRY FOR MOST OTHER DEVICES, AND COMMON CODE                 20201 59990020
NORMSEN  DS    0H                       COMMON CODE               20201 60050020
         AIF   (&RESREL EQ 0 AND &TP EQ 0).TP060                  20201 60110020
         LA    LNKRG3,INTS05A           SETUP RETURN REG         A51138 60170021
.TP060   ANOP                                                     20201 60230020
INTS00   LA    WKREG2,UCBSNS(UCBREG)    PT AT UCB SENSE AREA      20201 60290020
         MVI   SYSSENSE+7,X'06'         SET BYTE COUNT IN CCW     20201 60350020
         TM    UCBTYP+2(UCBREG),DSKTYP+TAPE   TAPE OR DA DEVICE SA70856 60400018
         BC    5,INTS01                 YES, COUNT OK           SA70856 60402018
         TM    UCBTYP+2(UCBREG),GRTYPE  GRAPHICS               @SA76027 60402418
         BZ    INTSUR                   NO, INIT 2 BYTE SNS    @SA76027 60402618
         CLI   UCBTYP+3(UCBREG),X'02'   2250                   @SA76027 60402818
         BE    INTSGR                   YES, INIT 4 BYTE SNS   @SA76027 60403018
         CLI   UCBTYP+3(UCBREG),X'03'   2260                   @SA76027 60403218
         BNE   INTSUR                   NO, INIT 2 BYTE SNS    @SA76027 60403418
INTSGR   MVI   SYSSENSE+7,X'04'         SET BYTE COUNT IN CCW   SA70856 60403918
         B     INTS01                   CONTINUE                SA70856 60415418
INTSUR   MVI   SYSSENSE+7,X'02'         SET BYTE COUNT IN CCW   SA70856 60427018
INTS01   LA    WKREG1,SYSSENSE          FORM COMD ADDR FOR SIO    20201 60438518
INTS02   ST    WKREG2,0(WKREG1)         SET SENSE DATA ADDR IN CCW20201 60450020
         MVI   0(WKREG1),SENSOP         RESTORE CCW OP CODE       20201 60490020
INTS03   MVI   1(WKREG2),ZERO           CLEAR SECOND SENSE BYTE   20201 60530020
INTS03P  DS    0H                                                       60560021
         ST    WKREG1,CAWLOC      STORE AND ZERO PROTECTION KEY   20201 60590020
         MVI   CATAPP,CATSNS .          SET CCH CODE FOR SIO SENSE  CCH 60950020
         LA    LNKRG2,INTS04            SET RETURN REGISTER     SA68848 61000021
         L     WKREG1,LPCNT             GET CHAN BUSY LIMIT     SA68848 61050018
         LR    LCHREG,WKREG1            GET DEV/CU BUSY LIMIT           61060018
         TM    UCBTYP+2(UCBREG),DSKTYP+TAPE   TAPE OR DA DEVICE         61062021
         BCR   5,LNKRG2                 YES, LEAVE HIGH LIMIT           61064021
         SRL   LCHREG,6                 LOWER LIMIT                     61066021
INTS04   DS    0H                                                 20201 61070020
         SIO   0(UAREG)                 START SENSE OPERATION      TEST 61250021
         BC    4,INTS07C                CSW STORED-GO INSPECT   SA57297 61310021
         BC    2,INTS20                 DECREMENT LOOP COUNT    SA68848 61370021
         BC    1,INTS10                 EQP. MALFUNCTION          20201 61430020
         BAL   WKREG1,IINTSENJ *        GO TEST IF CMD RETRY      ITH01 61431021
         B     IINTS04 *                NO, PROCEED WITH SENSE OP ITH01 61432021
         L     WKREG1,UCBWKADB(0,UCBREG) * GET PTR TO EXTENSION   ITH01 61435021
         MVC   IOBCSW+1(7,IOBREG),RSBCSW+1(WKREG1) RESTORE IOBCSW ITH01 61436021
         TM    RSBFLG1(WKREG1),RTRYSSS * IS RETRY CMD SK&SS       ITH01 61437021
         BZ    IINTS04J *               NO, GO RESET BUSY         ITH01 61438021
         IECLNK1 ,LA,LNKRG1,IINT037,,,,&TBASE * SETUP RETURN      ITH01 61439021
         BAL   LNKRG3,XCP064 *          GO LOAD LCHREG            ITH01 61440021
         LA    REG0,IINT037 *           SETUP RETURN FOR PSIO     ITH01 61441021
         B     XCP162 *                 GO TO SK&SS TIO           ITH01 61442021
IINTS04J OI    UCBFL1(UCBREG),UCBBSY *  RESET BUSY                ITH01 61442221
         B     INT026 *                 GO TO CHANNEL SEARCH      ITH01 61442421
IINTS04  DS    0H *                     CONNECT                   ITH01 61443021
         AIF   (&RESREL EQ 0 AND &TP EQ 0).TP070                  20201 61490020
         BCR   15,LNKRG3                RETURN OR CONTINUE       A51138 61550021
.TP070   SPACE 1                                                  20201 61610020
INTS05A  LA    LNKRG2,INTS05            SET RETURN REGISTER     SA57297 61660021
         MVI   CATAPP,CATTIOSN .        SET CCH CODE FOR TIO SENSE  CCH 61660421
         L     WKREG1,LPCNT             GET CHAN BUSY LIMIT     SA68848 61662018
         LR    LCHREG,WKREG1            GET DEV/CU BUSY LIMIT           61664018
         TM    UCBTYP+2(UCBREG),DSKTYP+TAPE   TAPE OR DA DEVICE         61666021
         BCR   5,LNKRG2                 YES, LEAVE HIGH LIMIT           61668021
         SRL   LCHREG,6                 LOWER LIMIT                     61668421
INTS05   DS    0H                                                 20201 61670020
         TIO   0(UAREG)                                            TEST 61850021
         BC    2,INTS20                 DECREMENT LOOP COUNT            61910021
         BC    8+1,INTS10               EQP. MALFUNCTION          20201 61970020
         BC    15,INTS07C               GO CHECK STATUS         SA57297 62140021
         SPACE 1                                                        62150020
INTS07   LA    LNKRG2,INTSEN3           SET RETURN REGISTER     SA61121 62200021
         MVI   SNSCNT,ZERO              CLEAR RETRY COUNT       SA61121 62202021
         L     WKREG1,LPCNT             GET CHAN BUSY LIMIT     US05348 62202418
         LR    LCHREG,WKREG1            GET DEV/CU BUSY LIMIT   US05348 62202818
         AIF   (&ASR EQ 0).ASR47                                SA61121 62204021
         LA    REG0,3                   INIT 3 INTO REG 0       SA57297 62206021
         SPACE 1                                                SA57297 62208021
*    TEST CSW STATUS AND GO TO CCH IF CHANNEL OR INTERFACE CNTRL CHECK. 62210020
INTS07C  DS    0H .                                             SA57297 62220021
         AIF   (&M65MP EQ 1).ASRCL06    CHANNEL LOGOUT PENDING    21111 62230021
         TM    CSWLOC,CSWCLP            CHANNEL LOGOUT PENDING    21111 62240021
         BC    7,INTSLOG                YES-GO HANDLE LOGOUT PEND 21111 62250021
.ASRCL06 ANOP                                                     21111 62260021
         TM    CSWLOC+5,CSWCTK+CSWICK+CATCCH . CAT. ERRORS        20201 62270021
         L     APBSRG,IECPL2            GET TEMP BASE REG      @SA77644 62330018
         BC    7,SERR04-IECCPL02(APBSRG) GO TO CCH             @SA77644 62360018
         TM    CSWLOC+5,CSWCDK+CSWCCK   CHAN DATA & CHAN CHG CHK  19062 62390020
         BC    7,INTSEN3                YES, RE-TRY SENSE       SA61121 62450021
         AGO   .ASR83                                            20201  62510020
.ASR47   SPACE 1                                                  20201 62570021
*    CSW STORED TEST STATUS - TIO & SIO COMMON ROUTINES.          20201 62630020
INTS07C  TM    CSWLOC+5,CSWCDK+CSWCTK+CSWICK+CSWCCK CAT. ERRORS SA57297 62690021
         L     APBSRG,IECPL2            GET TEMP BASE REG      @SA77644 62750018
         BC    7,SERR04-IECCPL02(APBSRG) YES, GO TO SERR       @SA77644 62780018
.ASR83   ST    WKREG1,ITSAVWK1 *        SAVE WKREG1               ITH01 62791021
         BAL   WKREG1,IINTSENJ *        GO TEST IF CMD RETRY      ITH01 62792021
         B     IINTS07C *               NO, PROCEED WITH SENSE OP ITH01 62793021
         L     WKREG1,ITSAVWK1 *        RESTORE WKREG1            ITH01 62793521
         TM    CSWLOC+4,CSWUCK+CSWCHE * IS IT CHE OR UNIT CHK?    ITH01 62794021
         BZ    INTS15 *                 NO, RETRY THE SIO         ITH01 62795021
         L     WKREG1,UCBWKADB(0,UCBREG) * GET PTR TO EXTENSION   ITH01 62796021
         TM    RSBFLG1(WKREG1),RTRYFE * WAS RETRY CMD NOT FOUND?  ITH01 62797021
         BO    IINTS07J *               YES, GO SIMULATE ADDR     ITH01 62798021
         L     LNKRG2,CAWLOC *          GET CAW                   ITH01 62799021
         MVC   CSWLOC+6(2),6(LNKRG2) *  SIMULATE RESIDUAL COUNT   ITH01 62800021
         AL    LNKRG2,EIGHTF *          SIMULATE CSW ADDRESS      ITH01 62801021
         ST    LNKRG2,CSWLOC *          STORE                     ITH01 62802021
IINTS07K MVC   IOBCSW+1(7,IOBREG),RSBCSW+1(WKREG1) RESTORE IOBCSW ITH01 62803021
         TM    RSBFLG1(WKREG1),RTRYSSS * IS RETRY CMD SK&SS       ITH01 62804021
         BZ    INT008 *                 NO, GO EXAMINE STATUS     ITH01 62805021
         IECLNK1 ,LA,LNKRG1,IINT037,,,,&TBASE * SETUP RETURN      ITH01 62806021
         BAL   LNKRG3,XCP064 *          GO LOAD LCHREG            ITH01 62807021
         LA    REG0,IINT037 *           SETUP RETURN FROM PSIO    ITH01 62808021
         B     IXCP162A *               GO TO POST TIO INSPECTION ITH01 62809021
IINTS07J MVC   CSWLOC+1(3),IOBCSW+1(IOBREG) * SIMULATE CSW ADDR   ITH01 62810021
         B     IINTS07K *               GO CLEANUP AND EXIT       ITH01 62811021
IINTS07C L     WKREG1,ITSAVWK1 *        RESTORE WKREG1            ITH01 62819021
         TM    CSWLOC+4,CSWUCK *        UNIT CHECK ON SENSE       ITH01 62820021
         BC    1,INTS10                 YES, SET UP SENSE ERROR  A53284 62830021
INTS08   TM    CSWLOC+4,CSWBSY          BUSY STATUS              A53284 62860021
         BC    1,INTS15                 YES, RETRY THE SIO/TIO  SA57297 62910021
         NI    UCBFL5(UCBREG),FF-UCBUEX CLEAR UNIT EXEC STATUS   S22024 62960021
         TM    CSWLOC+4,CSWUEX          TEST FOR UNIT EXCEPTION  S22024 63010021
         BC    8,INTS09                 NO, DO NOT SET UEX FLAG  S22024 63060021
         OI    UCBFL5(UCBREG),UCBUEX    INDICATE UEX ON SENSE    S22024 63110021
INTS09   TM    UCBFL1(UCBREG),UCBPST    DE WITHOUT CE             20201 63290020
         IECLNK1 ,BCR,8,LNKRG1,,,,&TBASE                                63350020
INTS02H  MVC   IOBSNS(2,IOBREG),ZERO(WKREG2) SAVE SENSE DATA      20201 63410020
         SPACE 1                                                  20201 63470020
*  ON UNIT CHECK ON DE FROM A STANDALONE SEEK THE RQE MUST BE DEQ.      63530020
*   BEFORE IT IS SENT TO THE ERP.                                       63590020
INTS02G  BAL   LNKRG2,XCPPDQ           GO DEQUEUE REQUEST          IMP3 63650020
INT031   NI    UCBFL1(UCBREG),UCBBSY    RESET ALL FLAGS BUT BUSY  20201 63710020
INT031B  LA    APBSRG,APGABE            ABNORMAL END APD. INCR.   20201 63770020
         BC    15,INT019                GO TO APPENDAGE INTERFACE 20201 63830020
         SPACE 3                                                  20201 63890020
*    RETRY FAILING SENSE TEN TIMES                               A53284 63940021
INTS10   IC    ICREG,SNSCNT             LOAD UC COUNTER          A53284 63942021
         LA    ICREG,1(ICREG)           INCREMENT COUNT          A53284 63944021
         STC   ICREG,SNSCNT             STORE UC COUNTER         A53284 63946021
         CLI   SNSCNT,TEN               TEST FOR TEN RETRIES     A53284 63948021
         BC    13,INTSEN3               NO, GO TRY AGAIN        SA61121 63948421
*    ON EQUIPMENT CHECK, SET FIRST TWO SENSE BYTES TO X'10FE'    A53284 63950021
INTS10A  MVI   ZERO(WKREG2),X'10'       YES-SET EQUIPMENT CHECK  A53284 64010021
         MVI   1(WKREG2),X'FE'          SET IND IN SECOND BYTE   A53284 64070021
INTS10B  LTR   TSTREG,TSTREG            DO WE HAVE AN RQE        A53284 64120021
         IECLNK1  ,BCR,8,LNKRG1,,,,&TBASE                        A53284 64130021
         CH    TSTREG,LTSVALSV          IS THE RQE VALID         A53284 64130421
         IECLNK1  ,BCR,7,LNKRG1,,,,&TBASE                        A53284 64130821
         STH   TSTREG,UCBLTS(UCBREG)    RESTORE RQE ADDRESS     SA60254 64130921
         MVI   CHMSK,RSTMSK             RESTART ALL CHANNELS    SA60254 64131021
         IECLNK1  ,LA,LNKRG1,INT027,,,,&TBASE                   SA60254 64131121
         BC    15,INTS09                GO POST REQUEST IN ERR  SA71481 64131218
         SPACE 1                                                        64133221
*    THE FOLLOWING ROUTINE IS AN ATTEMPT TO KEEP THE SYSTEM             64133621
*    UP IF A DEVICE RESPONDS WITH UNIT CHECK AND THEN DEVICE            64133721
*    OR CONTROL UNIT BUSY WHEN PERFORMING A SENSE OPERATION.            64133821
*    THE SENSE WILL BE DUMMIED AS '10FC' (SIMILAR TO '10FE'             64133921
*    WHEN A UNIT CHECK IS RECEIVED PERFORMING A SENSE                   64135021
*    OPERATION.)                                                        64137021
         SPACE 1                                                        64137421
INTS15   BCTR  LCHREG,LNKRG2            RE-SIO/TIO TIL CNT LIMIT        64137821
         TM    UCBTYP+2(UCBREG),DSKTYP+TAPE   TAPE OR DA                64137921
         BC    4,INTSLOG                AVOID CONTINGENT CONNEC         64138021
         MVI   ZERO(WKREG2),X'10'       DEV HUNG IN BUSY LOOP           64138221
         MVI   1(WKREG2),X'FC'          SET IND IN SENSE BYTES          64138621
         BC    15,INTS10B               HANDLE BSY LIKE UNIT CHK        64138721
         SPACE 1                                                        64139021
*    THE FOLLOWING ROUTINE, UTILIZING THE LOGOUT PENDING ROUTINE,       64139421
*    LIMITS THE CHANNEL BUSY LOOP OF THE SENSE SUBROUTINE.  WHEN        64139521
*    THE LIMIT IS REACHED, THE CHANNEL LOGOUT PENDING ROUTINE IS        64139621
*    ENTERED.  THE CLP ROUTINE ALLOWS THE SYSTEM TO ENABLE, AFTER       64139721
*    WHICH THE SIO/TIO MAY BE RESUMED.  ALLOWING THE SYSTEM TO  SA68848 64139821
*    ENABLE MAY ALLOW THE SENSE OPERATION TO TERMINATE.         SA68848 64140221
         SPACE 1                                                        64141121
INTS20   BCTR  WKREG1,LNKRG2            REISSUE SIO/TIO TIL CNT SA68848 64141321
         CLI   CATAPP,CATTIOSN          TIO IN PROC             SA71483 64141418
         BE    INTSEN2                  YES, CLEAR STAT VIA INT SA71483 64141518
*        B     INTSLOG                  ENABLE CPU BEFORE CONT  SA68848 64141721
         SPACE 2                                                  21111 64141821
*   ON CHANNEL LOGOUT PENDING CONDITION MARK UCB FOR DELAYED SENSE      64142021
*   INCREMENT DELAYED SENSE COUNT-IF EXCP ENTRANCE SET CHMSK TO FORCE   64142221
*   FRONT END ENTRANCE TO IOS TO GO TO CHANNEL RESTART WHERE IOS WILL   64142421
*   EVENTUALLY ENABLE ALLOWING CHANNEL TO LOGOUT.               SA62867 64143221
*   IF LOG PENDING STATUS WAS PRESENTED ON THE SIO FOR SENSE,   SA62867 64144321
*   SET BOTH DELAYED SENSE AND DELAYED HIO FLAGS TO INDICATE    SA62867 64145421
*   THE SENSE MAY BE RETRIED.                                   SA62867 64146521
         SPACE 1                                                SA62867 64147621
INTSLOG  DS    0H .                                               21111 64148721
         AIF   (NOT &D2305).ASRCL09                             SA62867 64149818
         LR    WKREG1,UCBREG .          SAVE UCBREG             SA62867 64150921
         L     WKREG2,AZUSRTN .         GET ADDR OF 2305 RTN    SA62867 64152021
         BALR  LNKRG3,WKREG2 .          GO GET BASE IF 2305     SA62867 64153121
         BC    7,INTSLG1 .              NOT 2305, CONTINUE      SA62867 64154221
         LR    WKREG2,UAREG .           COPY UAREG              SA62867 64155321
         N     WKREG2,ZEXPMSK .         CLEAR ALL BUT EXP BITS  SA62867 64156421
         SLL   WKREG2,6 .               GET OFFSET TO 2305 EXP  SA62867 64157521
         LA    UCBREG,0(WKREG2,UCBREG) .GET EXPOSURE UCB        SA62867 64158621
         CR    UCBREG,WKREG1 .          SAME UCB NOW            SA62867 64159721
         BC    8,INTSLG1 .              YEP, CONTINUE           SA62867 64160821
         STH   UCBREG,TSTUCB(TSTREG) .  SETUP RQE IN UCB        SA62867 64161921
         MVC   UCBFL1(1,UCBREG),UCBFL1(WKREG1) .MOVE UCBFL1     SA62867 64163021
         MVI   UCBFL1(WKREG1),ZERO .    CLEAR BASE UCBFL1       SA62867 64164121
.ASRCL09 ANOP                                                   SA62867 64165218
INTSLG1  OI    UCBCHA(UCBREG),UCBDSNS+UCBSMD WAIT FOR DELAY SENSE 21111 64166321
         CLI   CATAPP,CATSNS .          WAS LOG PENDING ON SIO  SA62867 64167421
         BC    7,INTSLG3 .              NO, DON'T INDICATE SIO  SA62867 64168521
         OI    UCBCHA(UCBREG),UCBDHIO . SIO MAY BE RETRIED      SA62867 64169621
INTSLG3  IC    ICREG,CLPCNT .           LOAD DELAY EVENT CNTR   SA62867 64170721
         LA    ICREG,ONE(ICREG) .       INCREMENT BY ONE          21111 64171821
         STC   ICREG,CLPCNT .           STORE COUNTER             21111 64172921
         TM    XCPBTE,XCPCNT+XCPERR .   EXCP ENTRANCE           SA62867 64174021
         IECLNK1 ,BCR,8+1,LNKRG1,,,,&TBASE                      SA62867 64176421
         MVI   CHMSK,RSTMSK .           SET FOR DISABLE EXCP USER 21111 64178021
         IECLNK1 ,BCR,15,LNKRG1,,,,&TBASE                       SA62867 64180021
         AIF   (&RESREL EQ 0).RR015                               20201 65030021
  TITLE 'SHARED FILE SUPPORT FOR SENSE - INPUT/OUTPUT SUPERVISOR'       65090021
*                  SHARED FILE SUPPORT FOR SENSE                  20201 65210020
*                                                                 20201 65270020
*    A RHA/RR0 CHANNEL PROGRAM IS CHAINED TO THE SENSE CHANNEL    20201 65330020
*    PROGRAM SO THAT THE HA AND R0 ARE AVAILABLE TO THE ERP       20201 65390020
*    DURING ERROR RECOVERY. FURTHERMORE, IF THE RESERVE COUNTER   20201 65450020
*    IS ZERO, THE SENSE COMMAND IS CHANGED TO A RELEASE, SO THAT  20201 65510020
*    THE DEVICE IS AVAILABLE TO THE OTHER CPU DURING THIS CPU'S   20201 65570020
*    ERROR RECOVERY PROCESS. THIS SUPPORT IS USED ONLY FOR        20201 65630021
*    2311S, 2314S AND 2321S (STAND SEEK DEVICES).                       65680021
         SPACE 2                                                  20201 65690020
SDASEN   TM    UCBTYP+1(UCBREG),UCBRR   RES/REL CAPABILITY        20201 65750020
         BC    8,NORMSEN                NO, GO PREPARE FOR SENSE  20201 65810020
         TM    UCBFL1(UCBREG),UCBPST    IS THERE AN RQE TO USE    20201 65870020
         BC    8,NORMSEN                NO-BYPASS RHA/RR0         20201 65930020
         L     APBSRG,CCWRTNAD          GET CCW RTN ADDR                65980021
         BALR  WKREG1,APBSRG            GO GET CCW ADDR                 66030021
         AIF   (&SSDA EQ 0 AND &SSTA EQ 0).MPX025                       66080021
         BC    0,0                      NOP FILLER                      66130021
.MPX025  ANOP                                                           66180021
*    INITIALIZE SENSE/RELEASE, RHA AND RR0 CHANNEL PROGRAM              67010020
INTRR04  LR    WKREG1,WKREG3           PREPARE FOR CAW STORE       SDA1 67070021
         MVC   0(16,WKREG1),RRSNCCW     MOVE SKELETON TO CH AREA  20201 67182021
         SH    WKREG1,EIGHT            BACK UP TO SENSE           20201 67190020
INTRR005 MVI   CCWFLG(WKREG1),CCWCC+CCWSLI     SET  CCW FLAGS     20201 67490020
         AIF   (NOT &D2321).DCEL003                               20201 67550020
         L     WKREG2,UCBWKADA(0,UCBREG) GET PTR TO 2321 WORK AREA20201 67610020
         CLI   UCBTYP+3(UCBREG),UCB2321                            SDA1 67670020
         BC    8,INTRR01               DEVICE IS 2321              SDA1 67730020
.DCEL003 L     WKREG2,UCBWKADB(0,UCBREG) GET PTR TO ERP WKAREA    20201 67790020
INTRR01  LA    WKREG2,UCBRR0A(0,WKREG2) GET READ R0 OFFSET        20201 67850020
         ST    WKREG2,RR0ADR(WKREG1)   SET RR0 ADDRESS           A53742 67910021
         MVI   RR0ADR(WKREG1),RR0OP    SET UP READ R0 OP CODE    A53742 67960021
         LA    WKREG2,UCBRHA(WKREG2)   INCRE TO RHA AREA          20201 67970020
         ST    WKREG2,RHADR(WKREG1)    SET RHA ADR               A53742 68030021
         MVI   RHADR(WKREG1),HAOP       SET UP READ HA OP CODE   A53742 68080021
         MVC   1(4,WKREG2),UCBSKA+3(UCBREG) GET CCHH FOR ERROR    20201 68090020
         LA    WKREG2,UCBSNS(UCBREG)    GET ADDRESS OF UCB SENSE  20201 68150020
         MVI   7(WKREG1),X'06'          SET COUNT                 20201 68210020
         STH   WKREG2,2(WKREG1)         SET SENSE AREA ADDR IN CCWM5738 68250020
         MVI   0(WKREG1),SENSOP         SET CCW OP CODE TO SENSE A49373 68270021
         CLI   UCBRRCNT(UCBREG),ZERO    IS COUNTER ZERO          A49373 68280021
         BC    7,INTRR02                NO, DO NOT RELEASE       A49373 68282021
         MVI   0(WKREG1),RELEASE        CHANGE SENSE TO RELEASE  A49373 68284021
INTRR02  BAL   LNKRG3,INTS03            GO DO SENSE OPERATION    A51138 68290021
         BC    15,INTSEN2               GO TO WAIT FOR INTERRUPT  20201 68330020
.RR015   SPACE 3                                                  20201 68390020
         AIF   (&TP EQ 0 AND &RESREL EQ 0).RR010                  20201 68450020
         SPACE 4                                                  20201 68510020
*   STATUS MODIFIER ENTRANCE                                      20201 68570020
INTSEN4  LA    WKREG2,UCBSNS(UCBREG)    SETUP SENSE DATA PTR      20201 68630020
         TM    UCBFL5(UCBREG),UCBEXTSN  EXP SENSE DEVICE ?     @SA77172 68670018
         BZ    INTSEN4B                 NO, USE NORMAL SENSE   @SA77172 68675018
         L     WKREG2,UCBNBRSN(UCBREG)  GET PTR TO EXT. SENSE  @SA77172 68680018
INTSEN4B TM    UCBCHA(UCBREG),UCBDSNS . WAITING FOR DLY SENSE  @SA77172 68685018
         BO    INTSEN6 .                YES SETUP FOR STATUS CHECK21111 68690021
         AIF   (&TWOSW EQ 0).TW31300                             A31305 68692018
         LH    WKREG1,UCBCHA(UCBREG)    GET DEVICE ADDRESS       A31305 68694018
         N     WKREG1,ADDRMSK           CLEAR FLAGS              A31305 68696018
         CR    WKREG1,UAREG             EQUAL TO PATH STARTED    A31305 68698018
         BC    7,INT027                 NO, TRY TO RESTART CHANNEL31305 68698418
.TW31300 ANOP                                                    A31305 68698818
         NI    UCBCHA(UCBREG),FF-UCBSMD RESET PENDING SENSE     US05348 68700018
         AIF   (&ASR EQ 0).ASR85                                  SDA1  68710021
         MVI   CATAPP,CATREC          INDICATE SECOND ENTRY TO CCH IMP2 68750020
.ASR85   AIF   (&RESREL EQ 0).RR031                                SDA1 68810020
         TM    UCBTYP+2(UCBREG),DSKTYP  IS IT A DA DEVICE       SA71483 68870018
         BC    8,INTS07                 NO, GO INSPECT STATUS   SA71483 68930018
         TM    UCBTYP+1(UCBREG),UCBRR   IS IT A SHARED DEVICE   SA71483 68980018
         BC    8,INTS07                 NO, GO INSPECT STATUS   SA71483 69030018
         TM    UCBTYP+2(UCBREG),UCBRPS  IS IT AN RPS DEVICE     SA71483 69080018
         BC    1,INTS07                 YES, GO INSPECT STATUS  SA71483 69130018
         TM    CSWLOC+5,CSWCDK+CSWCTK+CSWICK+CSWCCK CAT. ERRORS SA56509 69404021
         BC    7,INTS07                 YES, GO SEE WHICH ERROR   20201 69410020
         TM    CSWLOC+4,CSWUCK          TEST FOR UNIT CHECK       20201 69470020
         BC    1,INTSEN4A .             YES, CHECK COMMAND       A36733 69500020
         MVC   UCBDVRES(1,UCBREG),UCBRRCNT(UCBREG) . IND DEV RES A36733 69530020
         B     INTS07 .                 NO UCK, CHECK OTHER STATUS05348 69560018
*    TEST IF UCK ON SENSE OR R-HA OR R-R0 COMMANDS.               20201 69590020
INTSEN4A L     APBSRG,CCWRTNAD          GET CCW RTN ADDR                69640021
         BALR  WKREG1,APBSRG            GO GET CCW ADDR                 69642021
         AIF   (&SSDA EQ 0 AND &SSTA EQ 0).MPX025A                      69644021
         BC    0,0                      NOP FILLER                      69646021
.MPX025A ANOP                                                           69648021
         L     WKREG1,CSWLOC            GET ADDR. OF CCW          20201 69710020
         LA    WKREG1,0(WKREG1)         GET ADDR. ONLY            20201 69770020
         SR    WKREG1,WKREG3            UNIT CHECK ON SENSE       20201 69830021
         LA    WKREG2,UCBSNS(UCBREG)    GET ADDR OF UCB SENSE     M5030 69860020
         BC    8,INTS10A                YES, HANDLE NORMAL      US05348 69890018
*    WHEN UCK ON HA OR R0, TEST IF THE SENSE IS TRACK COND. CHECK 20201 69950020
*    IF YES, SIMULATE THIS COND. WITH A D/C FOR POSSIBLE RECOVERY.20201 70010020
         TM    UCBSNS(UCBREG),X'02'     TRACK CONDITION CHECK     20201 70130020
         BC    8,INTSEN5                NO-AROUND                 20201 70190020
         OI    UCBSNS(UCBREG),X'08'     YES SET D/C               20201 70250020
INTSEN5  LA    WKREG1,RRSENSE2          ADDR. OF SENSE CCW        20201 70310020
         LA    LNKRG3,INTSEN2           SET FOR RETURN           A51138 70350021
         B     INTS03P                  GO SENSE                        70390021
         AGO   .RR010                                             20201 70430020
.RR031   BC    15,INTS07                GO INSPECT STATUS         20201 70490020
.RR010   ANOP                                                   SA68848 70499021
         SPACE 2                                                        70517021
*   ROUTINE HANDLES INTERRUPTS THAT ARE REALLY ENDING STATUS OF   21111 70526021
*   SENSE OPERATIONS BUT CAME AS INTERRUPT DUE TO LOG PENDING COND21111 70535021
INTSEN6  NI    UCBCHA(UCBREG),FF-UCBDSNS-UCBSMD PEND/DELAY SNS OFF21111 70535421
         TM    UCBCHA(UCBREG),UCBDHIO . WAS LOG PENDING ON SIO  SA62867 70537021
         BC    8,INTSENLT .             NO, GO HANDLE FOR TIO   SA62867 70539021
         NI    UCBCHA(UCBREG),FF-UCBDHIO .RESET SIO SWITCH      SA62867 70541021
         BC    15,INTSEN3A .            GO RETRY SENSE SIO      SA62867 70543021
INTSENLT LA    LNKRG2,INTS10A .         RETURN ADDR IF CHAN ERR SA62867 70554021
         TM    CSWLOC+5,CSWCTK+CSWICK+CATCCH .GONE TO CCH YET   SA62867 70564021
         BC    7,INTSEN6B .             YES, DON'T RESET RETURN SA62867 70574021
INTSEN6A LA    LNKRG2,INTS07 .          SET NORMAL RETURN       SA62867 70574121
INTSEN6B LA    WKREG2,UCBSNS(UCBREG) .  NORMAL SENSE POINTER      M0192 70575021
         TM    UCBFL5(UCBREG),UCBEXTSN .EXPANDED SENSE DEVICE     21111 70580021
         BCR   8,LNKRG2 .               INSPECT STATUS          SA62867 70589021
         L     WKREG2,UCBNBRSN(UCBREG) .GET PTR TO EXPAND SENSE   21111 70598021
         BCR   15,LNKRG2 .              INSPECT STATUS          SA62867 70607021
IINTSENJ CLC   UCBTYP+2(2,UCBREG),IT7330 * IS IT 7330?            ITH01 70610021
         BCR   7,WKREG1 *               NO, SENSE RETURN          ITH01 70610221
         TM    UCBFL1(UCBREG),UCBPST *  IS THERE AN RQE?          ITH01 70610421
         BCR   14,WKREG1 *              NO, SENSE RETURN          ITH01 70610621
         TM    IOBCSW+4(IOBREG),CSWRETRY * IS IT CMD RETRY STATUS?ITH01 70610821
         BCR   14,WKREG1 *              NO, SENSE RETURN          ITH01 70611021
         B     4(WKREG1) *              COMMAND RETRY RETURN      ITH01 70611221
         TITLE 'ERROR INTERFACES - INPUT/OUTPUT SUPERVISOR'             73850021
*        IOS INTERRUPT SUPERVISOR ERROR INTERFACE                       73920019
         SPACE 2                                                        73990019
*   FUNCTION   TO SCRUTINIZE ERRORS AND SCHEDULE PROPER               * 74060019
*              HANDLING ROUTINE                                       * 74130019
*   ENTRY      MAIN LINE OF IOS, 2311(DISK) RESIDENT ERROR ROUTINE    * 74200019
*   EXT REF    XTFKTR, ER2311                                         * 74270019
*   EXITS      IOS MAIN LINE, IOS EXCP, 2311 RESIDENT ERP             * 74340019
*                                                                       74410019
*   OPERATION       1. RETURN TO POST ROUTINE ON PERMANENT ERROR.       74480019
*                   2. CHECK IF IOS OR USER ERROR ROUTINES ARE USED     74550019
*                      (ALL OR SOME) - USER 'ALL' AND 'SOME', RETURN    74620019
*                      VIA EXIT EFFECTOR.                               74690019
*                   3. CHECK MASK IF 'SOME' ERRORS CHECKED.             74760019
*                   4. ON 'ALL' ERRORS (IOS) - GO TO 2311 ERROR         74830019
*                      ROUTINE FOR DIRECT ACCESS - PASS RQE TO EXIT     74900019
*                      EFFECTOR FOR ALL OTHERS.                         74970019
*                   5. IF 'NO' ERRORS CHECKED (IOS AND USER) - GO TO    75040019
*                      ABEOT IF PGM OR PROT CHECK.                      75110019
*                   6. PURGE IF RELATED REQ HAS A PERMANENT ERROR.      75180019
         SPACE 2                                                        75250019
         AIF   (&RWTAU EQ 0).RW150                                      75320019
INTERR3A NI    UCBFL1(UCBREG),FF-UCBPST ERP TO RESTART CCW       BBBBBB 75390019
.RW150   ANOP                                                    BBBBBB 75460019
INTERR   TM    IOBCOD(IOBREG),NOTPMF    PERMANENT ERROR                 75530019
         BC    8,INT024                 YES - TO POST                   75600019
INTERR3  NI    DCBFL(DCBREG),FF-DCBPER  RESET ERROR FLAG         BBBBBB 75670019
INT050   DS    0H                                                  DAVV 75740019
         AIF   (&DAVV EQ 0).DAVV08                                 DAVV 75810019
         TM    UCBTYP+2(UCBREG),DSKTYP  TEST FOR DIRECT ACCESS     DAVV 75880019
         BC    8,INT050A                NO, SKIP                   DAVV 75950019
         TM    UCBFL4(UCBREG),UCBVVR    TEST IF VOL VER RTN IN CTL DAVV 76020019
         AIF   (&DDR NE 0).DDR01                                SA68176 76030021
         BC    1,INTERR4A          YES, GO SCHEDULE RTN            DAVV 76040021
         AGO   .DAVV08                                          SA68176 76050021
.DDR01   ANOP                                                   SA68176 76060021
         BC    8,INT050A                NO, SKIP                SA68176 76070021
         C     TSTREG,ADDRRQE           IS THIS THE DDR RQE?    SA68176 76080021
         BC    7,INTERR4A               NO, GO TO SCHEDULE RTN  SA68176 76090021
.DAVV08  ANOP                                                      DAVV 76160019
INT050A  TM    DCBFL(DCBREG),DCBIEK     TEST FOR IOS ERROR KEY     DAVV 76230019
         BC    8,INT022                 USE IOS ERPS FOR ERRORS  BBBBBB 76300019
         AIF   (&TWOSW EQ 0).TWS160                              BBBBBB 76370019
         TM    IOBCC(IOBREG),IOBCC3     TEST IF CC=3 ON SIO      BBBBBB 76440019
         BC    1,INTERR4D               TO SCHEDULE PURGE        BBBBBB 76510019
.TWS160  ANOP                                                    BBBBBB 76580019
INT057   TM    IOBCOD(IOBREG),NOTPMF    PERMANENT ERROR          BBBBBB 76650019
         BC    8,INT058                 YES - BRANCH                    76720019
         CLI   IOBCOD(IOBREG),IOBINT    INTERCEPTED IOB                 76790019
         MVI   IOBCOD(IOBREG),INTCOD    PUT IN INTERCEPT CODE           76860019
         BC    8,INT058                 YES, LEAVE INTERCEPT CODE       76930019
         MVI   IOBCOD(IOBREG),PERMER   SET PERM ERROR CODE         IMP2 77000019
INT058   TM    IOBFL1(IOBREG),IOBURL    IS THE REQUEST UNRELATED        77070019
         BC    1,INT031B                YES, GO TO ABN APN       BBBBBB 77140019
         TM    DCBFL(DCBREG),DCBPER    PERM ERR SET BY PREV REQ    TPF1 77210019
         BC    1,INT031B                YES, GO TO ABN APN       BBBBBB 77280019
         NI    DCBFL(DCBREG),FF-DCBPER  RESET ERROR FLAG         BBBBBB 77350019
INTERR4D OI    DCBFL(DCBREG),DCBEX      SET DCB EXCEPTION FLAG   BBBBBB 77420019
         SPACE 1                                                   IMP3 77490019
*   FORCE EXIT EFFECTOR TO USE UCB ID BYTE TO SCHEDULE IGE0025E.   IMP3 77560019
         SPACE 1                                                   IMP3 77630019
INTERR4  LR    WKREG1,UCBREG            GET UCB ADDRESS            DAVV 77700019
         SH    WKREG1,SIX              POINT TO UCB ID BYTE        IMP3 77770019
         STH   WKREG1,TSTUCB(0,TSTREG)      IN THE RQE             IMP3 77840019
*  HANG RQE ON ERROR LCH. FOR TRANSIENT ERP AND WTO FUNCTION            77910019
INT059   DS    0H                                                 19021 77980019
         AIF   (&RMS EQ 0).RMS06                                  19021 78050019
         L     WKREG1,RMSFLAD           ADDR OF RMS FLAG         BBBBBB 78090020
         CH    TSTREG,TWO(WKREG1)       TEST IF RMS ERROR        BBBBBB 78130020
         BC    8,INT057                 YES, GO TO SET PERM ERR   19021 78190019
.RMS06   L     WKREG1,XITFTR            EXIT EFFECTOR EXTERN      19021 78260019
         OI    TSTUCB+1(TSTREG),ONE     INDICATE SIRB REQUEST    BBBBBB 78330019
         AIF   (&DDR EQ 0).DDRAEQ7                              SA58100 78380021
         C     TSTREG,ADDRRQE           IS THIS THE DDR RQE     SA58100 78390021
         BC    7,INT059T                NO, DONT SET UCBERR     SA58100 78392021
         OI    UCBFL1(UCBREG),UCBERR    TIE UCB TO DDR RQE      SA58100 78394021
         STH   TSTREG,UCBLTS(UCBREG)    TIE DDR RQE TO UCB      SA63107 78394421
.DDRAEQ7 ANOP                                                   SA58100 78396021
INT059T  LA    LNKRG2,INT026            SET RETURN ADDR         SA58100 78400021
         BCR   15,WKREG1                TO ENQ. ON ERROR LCH            78470019
         SPACE 1                                                        78540019
*    DEFINITION OF EXIT EFFECTOR - IOS INTERFACE                 BBBBBB 78610019
*    INPUT     TSTREG,WKREG1(BASE ADDR),LNKRG2(RET-INT026)       BBBBBB 78680019
*    REGS CHANGED  NONE                                          BBBBBB 78750019
         SPACE 1                                                 BBBBBB 78820019
         AIF   (&DAVV EQ 0).DAVV09                                 DAVV 78890019
         SPACE 1                                                   DAVV 78960019
INTERR4B MVI   UCBRQESV(UCBREG),ZERO    RQE PURGED-RE-INIT FIELD   DAVV 79030019
INTERR4A BAL   LNKRG2,XCPPDQ            GO TO DEQUEUE RQE          DAVV 79100019
         STH   TSTREG,UCBLTS(0,UCBREG)  INIT UCBLTS FIELD          DAVV 79170019
         OI    UCBFL1(UCBREG),UCBERR    RESERVE UCB FOR THIS RQE   DAVV 79240019
         BC    15,INTERR4               GO TO SCHEDULE RTN         DAVV 79310019
.DAVV09  SPACE 1                                                   DAVV 79380019
INTERR5  MVC   IOBCSW+4(2,IOBREG),UCBLTS(UCBREG) COPY CSW STATUS   IMP5 79450019
         STH   TSTREG,UCBLTS(UCBREG)    RESTORE RQE TO UCB         IMP5 79520019
         MVI   IOBCOD(IOBREG),IOBINT    SET INTERCEPT              IMP5 79590019
         LA    WKREG2,UCBSNS(UCBREG)    INITIALIZE FOR SENSE MOVE 20201 79600020
         TM    UCBFL5(UCBREG),UCBEXTSN  THIS UCB HAVE PTR TO SENSE20201 79610020
         BC    8,INTS02H                NO, GO SAVE SENSE INFO    20201 79620020
         L     WKREG2,UCBSNADR-1(UCBREG) GET PTR TO SENSE AREA    20201 79630020
         BC    15,INTS02H               DEQUE RQST, SEND TO ERP    IMP5 79660019
         SPACE 1                                                        79730019
*   SEND REQUEST TO IOS ERROR ROUTINE                                   79800019
INT022   TM    IOBFL1(IOBREG),IOBURL   IS REQUEST UNRELATED             79870019
         BC    1,INT055                YES- DO NOT SET FLAG             79940019
         OI    DCBFL(DCBREG),DCBEX     SET ERR ROUT IN CONTROL          80010019
INT055   TM    UCBTYP+2(UCBREG),DSKTYP  TEST FOR DIRECT ACCESS     TRCE 80570019
         BC    8,INT059                 NO-SKIP                    TRCE 80640021
         L     APBSRG,T311ERT           GET DISK ERROR ROUTINE ADDRESS  80710019
         BALR  LNKRG2,APBSRG            TO 2311 ERROR RTN               80780019
         SPACE 1                                                        80850019
*    DEFINITION OF RESIDENT 2311 ERP - IOS INTERFACE             BBBBBB 80920019
*    INPUT     LNKRG2(RET ADDR),APBSRG(BASE ADDR)                BBBBBB 80990019
*    REGS CHANGED  NONE                                          BBBBBB 81060019
         SPACE 1                                                        81130019
*********************************************************************** 81200019
*                                                                     * 81270019
*                  2311 ERROR ROUTINE VECTOR TABLE                    * 81340019
*                                                                     * 81410019
         BC    15,INTER7                TO EXCP INSPECT                 81480019
         BC    15,INTER8                CORRECTION PERM ERROR           81550018
         BC    15,INTER10               HANG REQUEST ON ERRLCH   A43707 81620021
         AIF   (&DDR EQ 0).DDR13                                  19022 81690019
         BC    15,INTER7                TO READ HA-R0             19022 81760019
**       BC    15,INTERDDR              TIE RQE TO UCB + HANG RQE 19022 81830019
*                                       ON THE ERR LCH FOR DDR    19022 81900019
*                                       OR PERM ERR FOR SYSRES DDR19022 81970019
         AGO   .DDR14                                             19022 82040019
.DDR13   ANOP                                                     19022 82110019
**       BC    15,INTER7                TO READ HA-R/                   82180019
.DDR14   ANOP                                                     19022 82250019
*                                                                     * 82320019
*********************************************************************** 82390019
         AIF   (&DDR EQ 0).DDR15                                  19022 82460019
*    SET UCBERR TO TIE UP UCB FOR DDR                             19022 82530019
INTERDDR OI    UCBFL1(UCBREG),UCBERR    TIE UCB TO THIS RQE       19022 82600019
         TM    SRTESTAT(UCBREG),SYSCON  TEST FOR SYSRES DEVICE    19022 82670019
         BC    1,INTER8                 YES, POST PERM ERR              82740018
         L     WKREG1,TOADDR            ADDR OF DDRSRTO          BBBBBB 82810020
         CH    UCBREG,0(WKREG1)         IS THIS DDR 'TO' DEVICE  BBBBBB 82880020
         BC    7,INT059                 NO, GO TO HANG ON ERRLCH  19022 82950019
         MVI   UCBFL1(UCBREG),ZERO      LET SYSRES DDR THRU       19022 83020019
         BC    15,INT059                HANG RQE ON ERR LCH       19022 83090019
         SPACE 1                                                  19022 83160019
.DDR15   ANOP                                                     19022 83230019
*   EXCP RETURN FROM DISK RESIDENT ERROR RTN.                           83300019
INTER7   OI    UCBFL1(UCBREG),UCBERR    TIE-UP UCB FOR THIS REQUEST     83370019
INTER7A  TM    XCPBTE,XCPCNT+XCPERR     TEST FOR EXCP ENTRANCE          83440019
         BC    8+1,INTER7B              NO, BRANCH AROUND               83510019
INTER7D  OI    XCPBTE,XCPERR            YES - MAKE LOOK LIKE SVC 15     83580019
         MVN   IOPSWO+2(1),UCBCHA(UCBREG)                               83650019
INTER7B  BAL   LNKRG3,XCP064            INITIALIZE LCH                  83720019
INTER7C  DS 0H                                                          83790019
         AIF   (&APR EQ 0).APR200                                       83860019
         L     APBSRG,ADEACT            ADDR OF APR RTN          BBBBBB 83880020
         LA    LNKRG2,INTER7E           RETURN ADDR              BBBBBB 83900020
         BC    15,INTAPR01-INTDEACT(APBSRG) TO TEST FOR APR      BBBBBB 83920020
.APR200  ANOP                                                    BBBBBB 83940020
INTER7E  L     APBSRG,ENQAD             ADDR OF XCPPNQ RTN       BBBBBB 83960020
         LA    LNKRG2,INTER7F           SET RETURN ADDR          BBBBBB 83980020
         BC    15,XCPPNQB-XCPPNQ(APBSRG)   TO ENQUEUE RQE        BBBBBB 84000020
INTER7F  XC    LTSVALSV(2),LTSVALSV     ZERO RQE SAVE AREA       BBBBBB 84040020
         AGO   .PGMCK19                                          BBBBBB 84050020
INTER7F  DS    0H                                                BBBBBB 84070020
.PGMCK19 BC    15,INT027                GO TO CHAN RESTART       BBBBBB 84080020
INTER8   TM    IOBFL1(IOBREG),IOBEX    IS IOBEX=1               US06042 84082018
         BO    INT057                                           US06042 84084018
         NI    DCBFL(DCBREG),FF-DCBPER  RESET ERR RTN IN CONTROLUS06042 84086018
         B     INT019B                  TO CHAN END APPENDAGE   US06042 84088018
INTER10  TM    SRTESTAT(UCBREG),SYSCON  SYSTEM RESIDENCE VOLUME  A43707 84090021
         BC    1,INT059                 YES,DO NOT PROTECT STAT  A43707 84100021
         OI    UCBFL1(UCBREG),UCBERR    TIE DEVICE TO THIS RQE   A43707 84110021
         BC    15,INT059                HANG REQUEST ON ERRLCH   A43707 84120021
         AIF   (&M65MP EQ 0).MPB028                                RL19 89040021
         TITLE 'SHOULDER TAP INTERFACE - INPUT/OUTPUT SUPERVISOR'       89110021
*****************************************************************  MP1A 89180019
*                                                                  MP1A 89250019
*              IOS SHOULDER TAP INTERFACE (RECEIVING CPU)          MP1A 89320019
*                                                                  MP1A 89390019
*FUNCTION                                                          MP1A 89460019
*   TO DETERMINE WHICH CHANNEL SHOULD BE RESTARTED IN ORDER TO     MP1A 89530019
*   SERVICE THE I/O REQUEST WHICH WAS ENQUEUED BY THE OTHER CPU.   MP1A 89600019
*                                                                  MP1A 89670019
*ENTRY POINT                                                       MP1A 89740019
*        IECISHTP                                                  MP1A 89810019
*   FROM THE EXTERNAL FIRST LEVEL INTERRUPT HANDLER WHEN IT        MP1A 89880019
*   DETERMINES THAT AN I/O SHOULDER TAP WAS RECEIVED.              MP1A 89950019
*                                                                  MP1A 90020019
*INPUT                                                             MP1A 90090019
*   THE SHOULDER TAP MASK (STMASK), WITH BIT SETTING TO INDICATE   MP1A 90160019
*   WHICH CHANNEL IS TO BE RESTARTED.                              MP1A 90230019
*                                                                  MP1A 90300019
*OUTPUT                                                            MP1A 90370019
*   THE CHANNEL ADDRESS IN THE I/O OLD PSW FOR CHANNEL RESTART.    MP1A 90440019
*                                                                  MP1A 90510019
*EXITS                                                             MP1A 90580019
*        INT027 - CHANNEL RESTART - WHEN A CHANNEL IS FOUND        MP1A 90650019
*   TO BE RESTARTED.                                               MP1A 90720019
*                                                                  MP1A 90790019
*        IEAQEXIO - EXTERNAL FLIH - WHEN A REQUEST IS FOUND FOR    MP1A 90860019
*   AN INVALID CHANNEL, AND WHEN ALL CHANNELS HAVE BEEN PROCESSED. MP1A 90930019
*                                                                  MP1A 91000019
*****************************************************************  MP1A 91070019
IECISHTP BALR  BASREG,0            ENTRY POINT FROM EXTERNAL FLIH  MP1A 91140019
         USING *,BASREG                                          BBBBBB 91210019
         DROP  BASREG2                  DON'T USE REG 5 HERE    SA58049 91260021
IECISTP1 S     BASREG,IECISTAD          ESTABLISH                       91280020
         USING IOSBAS,BASREG            ADDRESSABILITY           BBBBBB 91350019
         USING IOSBAS+4094,BASREG2                              SA58049 91400021
         LA    BASREG2,4094(BASREG)     SET HIGH BASE REGISTER  SA58049 91490021
         MVI   XCPBTE,XCPST             SET ENTRANCE FLAGS      SA58049 91560021
         L     APBSRG,PREFIX2           GET OTHER PSA POINTER           91660020
         MVI   STMASK+3-IPLPSW(APBSRG),ZERO  CLR SHLDR TAP IND.         91760020
         SR    ICREG,ICREG              SET UP FOR CHAN RESTART  M0147  91780020
         LA    WKREG1,STCHMSKB          GET CPU B'S CHAN. MASK   A42119 91790021
         CLI   CPUID-IEAQFX00,CPUA      IS THIS CPU A            A42119 91800021
         BC    8,IECISTP2               YES, GO AHEAD            A42119 91810021
         LA    WKREG1,STCHMSKA          NO, GET A'S CHAN. MASK   A42119 91820021
IECISTP2 OC    CHMSK(1),ZERO(WKREG1)    SET UP CHAN. FOR RESTART A42119 91830021
         ST    ICREG,ZERO(WKREG1)       RESET CHANNEL INDICATOR  A42119 91840021
         BC    15,INT033                GO ATTEMPT CHANNEL RESTART      91860020
         SPACE 1                                                        91960020
IECIOSTV L     LNKRG2,IECIOSTR     GO BACK TO EX-FLIH              MP1A 92190019
         BCR   15,LNKRG2                                           MP1A 92260019
         SPACE 1                                                        92330019
IECISTAD DC    A(IECISTP1-IOSBAS)       ADDRESSING CONSTANT      BBBBBB 92960019
         SPACE 1                                                 BBBBBB 93030019
*****************************************************************  MP1A 93100019
.MPB028  EJECT                                                     RL19 93170019
         MEND                                                           93240019
