         MACRO                                                          00600020
         IECTBL &CHANLST,&M65MP,&LCHTOT,&TYPE,&OLTEP                    01200021
         GBLB  &D2305                                           SA56509 01250021
         LCLA  &INSERT,&LSTINDX,&COUNT,&CHMSK                   SA56509 01800021
.*   &CHANLST  LIST OF CHANNELS                                         02400020
.*   &M65MP    M65MP SYSTEM INDICATOR                                   03000020
.*   &LCHTOT   TOTAL LCH'S IN SYSTEM                                    03600020
.*   &TYPE     SUBLIST OF DEVICE TYPES IN SYSTEM                        04200020
.*   &OLTEP    ON LINE DEVICE TEST SUPPORT INDICATOR                    04250021
*   DEVICE TABLE                                                        04800020
DEVTAB   DS    0F                                                       05400020
         AIF   (&OLTEP EQ 0).TSTLOOP                              21051 05450021
         AIF   (NOT &D2305).TSTLOOP                               21051 05500021
**  SPECIAL ENTRY FOR OLTEP SPECIFIC EXPOSURE REQUESTS            21051 05550021
         DC    AL2(0)                                             21051 05600021
         DC    AL2(ZEUSOLT-IOSBASE)     SPECIAL OLTEP SIO CODE    21051 05650021
         DC    AL2(0)                                             21051 05700021
         DC    AL2(0)                                             21051 05750021
.TSTLOOP AIF   (&COUNT EQ N'&TYPE).END  LAST TYPE OUT                   06000020
&COUNT   SETA  &COUNT+1                UPDATE COUNT OF TUPES            06600020
         AIF   ('&TYPE(&COUNT)' EQ '').TSTLOOP  TEST FOR BLANK TYPE     07200020
         AIF   ('&TYPE(&COUNT)'(1,1) EQ 'P').PRTYTST  TEST PRIOROTY Q   07800020
         AIF   ('&TYPE(&COUNT)'(1,1) EQ 'O').ORDDSK    TEST ORDERED Q   08400020
.*                 CHECK FOR FIFO ENQUE                                 09000020
    AIF   ('&TYPE(&COUNT)' EQ 'DA' OR '&TYPE(&COUNT)' EQ 'DS').DAWFIFO  09600020
         AIF   ('&TYPE(&COUNT)' EQ 'ML').DAWFIFO  TEST FOR MERLIN       10200020
         AIF   ('&TYPE(&COUNT)' EQ 'TA').TAWFIFO  TEST TA/FOFO          10800020
         AIF   ('&TYPE(&COUNT)' EQ 'TP').TPWFIFO  TEST TP/FIFO Q        11400020
         AIF   ('&TYPE(&COUNT)' EQ 'GR').GRWFIFO  TEST FOR GRAPHICS     12000020
    AIF   ('&TYPE(&COUNT)' EQ 'DR' OR '&TYPE(&COUNT)' EQ 'ZS').DRWFIFO  12600020
         AIF   ('&TYPE(&COUNT)' EQ 'AT').ASPFIFO ASPEN TYPE       21048 12650021
**  UNIT RECORD ENTRY WITH FIFO ENQUEING                                13200020
         DC    AL2(XCPENQ-IOSBASE)      FIFO QUEUE FOR UNIT RECORD RL19 13800020
.URSIO   AIF   ('&TYPE(&COUNT)' EQ 'WR' OR '&TYPE(&COUNT)' EQ 'PWR').WR*14000021
               SIO                      TEST FOR 3211 PRINTER    A44146 14200021
         DC    AL2(XIOUR-IOSBASE)       SIO CODE FOR UNIT RECORD        14400021
         AGO   .URTRAP                                                  14600021
.WRSIO   DC    AL2(XIOWR-IOSBASE)       SIO CODE FOR 3211        A44146 14800021
.URTRAP  DC    AL2(INTURT-IOSBASE)      TRAP CODE FOR UNIT RECORD       15000021
    AIF  ('&TYPE(&COUNT)' EQ 'WR' OR '&TYPE(&COUNT)' EQ 'PWR').EXPSN    15600020
    AIF  ('&TYPE(&COUNT)' EQ 'NR' OR '&TYPE(&COUNT)' EQ 'PNR').EXPSN    15650021
         DC    AL2(NORMSEN-IOSBASE)     SENSE ENTRY                     16200020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               16800020
.TAWFIFO ANOP                                                           17400020
**   TAPE ENTRY FOR FIFO QUEUEING                                       18000020
         DC    AL2(XCPENQ-IOSBASE)      FIFO QUEUE FOR TAPE        RL19 18600020
.TASIO   DC    AL2(XIOTPE-IOSBASE)      SIO FOR TAPE                    19200020
         DC    AL2(INTTAT-IOSBASE)      TRAP FOR TAPE              RL19 19800020
         DC    AL2(NORMSEN-IOSBASE)     SENSE ENTRY                     20400020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               21000020
.ASPFIFO ANOP                                                     21048 21050021
**   ASPEN ENTRY WITH FIFO QUEUING                                21048 21100021
         DC    AL2(XCPENQ-IOSBASE)      FIFO QUEUE FOR ASPEN      21048 21150021
.ASPSIO  DC    AL2(XIOTPEA-IOSBASE)     SIO FOR ASPEN             21048 21200021
         DC    AL2(INTASP-IOSBASE)      TRAP FOR ASPEN            21048 21250021
         DC    AL2(EXPSEN-IOSBASE)      SENSE FOR ASPEN           21048 21300021
         AGO   .TSTLOOP                 RTN TO TYPE TST LOOP      21048 21350021
.DAWFIFO ANOP                                                           21600020
**  DA OR ML ENTRY WITH FIFO QUEUEING                                   22200020
         DC    AL2(XCP100-IOSBASE)      FIFO QUEUEING FOR DA OR ML      22800020
         AIF   ('&TYPE(&COUNT)' EQ 'ML').DRPRIR   TEST FOR MERLIN       23400020
         DC    AL2(XIODSK-IOSBASE)      SIO FOR D.A.               RL19 24000020
         DC    AL2(INTDAT-IOSBASE)      TRAP FOR D.A.                   24600020
.SNS     AIF   ('&TYPE(&COUNT)' EQ 'OML').EXPSN   TEST FOR MERLIN       25200020
    AIF  ('&TYPE(&COUNT)' EQ 'PML' OR '&TYPE(&COUNT)' EQ 'PZS').EXPSN   25800020
    AIF  ('&TYPE(&COUNT)' EQ 'ML' OR '&TYPE(&COUNT)' EQ 'ZS').EXPSN     26400020
         AIF   ('&TYPE(&COUNT)' EQ 'DS').SHAR     TEST FOR SHARED       27000020
         DC    AL2(NORMSEN-IOSBASE)     SENSE ENTRY                     27600020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               28200020
.SHAR    DC    AL2(SDASEN-IOSBASE)      SHARED DA SENSE                 28800020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               29400020
.TPWFIFO ANOP                                                           30000020
**  TP SUPPORT ENTRY WITH FIFO QUEING                                   30600020
         DC    AL2(XCPENQ-IOSBASE)      FIFO QUEUEING FOR TP       RL19 31200020
         DC    AL2(XCP121-IOSBASE)      SIO FOR TP DEVICES         RL19 31800020
         DC    AL2(XCPTPT-IOSBASE)      TRAP FOR TP DEVICES        RL19 32400020
         DC    AL2(TPSEN-IOSBASE)       SENSE FOR TP                    33000020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               33600020
.DRWFIFO ANOP                                                           34200020
**  DR OR ZS SUPPORT ENTRY WITH FIFO QUEUEING                           34800020
         DC    AL2(XCP100-IOSBASE)      FIFO QUEUEING FOR DR            35400020
         AIF   ('&TYPE(&COUNT)' NE 'ZS').DRPRIR   TEST IF NOT ZEUS      36000020
.ZUS     DC    AL2(ZEUSIO-IOSBASE)      SIO CODE FOR ZEUS               36600020
         DC    AL2(INTZUT-IOSBASE)           ZEUS TRAP CODE             37200020
         AGO   .SNS                     GET SENSE POINTER               37800020
.DRPRIR  DC    AL2(RPSSIO-IOSBASE)      SIO CODE FOR RPS OR ML          38400020
         DC    AL2(INTNOT-IOSBASE)      NO TRAP CODE ENTRY              39000021
         AGO   .SNS                     GET SENSE POINTER               39600020
.GRWFIFO ANOP                                                           40200020
**  GRAPHICS SUPPORT ENTRY WITH FIFO QUEUING                            40800020
         DC    AL2(XCPENQ-IOSBASE)      FIFO QUEUING FOR GRAPHICS  RL19 41400020
         DC    AL2(XIOUR-IOSBASE)       SIO FOR GRPAHIC DEVICES    RL19 42000020
         DC    AL2(INTDNP-IOSBASE)      TRAP FOR GRAPHIC DEVICES   RL19 42600020
         DC    AL2(NORMSEN-IOSBASE)     SENSE ENTRY                     43200020
         AGO   .TSTLOOP            RETURN TO TYPE TST LOOP              43800020
.PRTYTST ANOP                                                           44400020
    AIF   ('&TYPE(&COUNT)' EQ 'PDA' OR '&TYPE(&COUNT)' EQ 'PDS').DAWPR  45000020
         AIF   ('&TYPE(&COUNT)' EQ 'PML').DAWPR   TEST FOR MERLIN       45600020
         AIF   ('&TYPE(&COUNT)' EQ 'PTA').TAPEWPR  TEST TAPE/PRI.Q      46200020
         AIF   ('&TYPE(&COUNT)' EQ 'PTP').TPWPR  TEST T/T / PRIORITY Q  46800020
         AIF   ('&TYPE(&COUNT)' EQ 'PGR').GRWPR  TEST GR PRIORITY QUE.  47400020
    AIF   ('&TYPE(&COUNT)' EQ 'PDR' OR '&TYPE(&COUNT)' EQ 'PZS').DRWPR  48000020
         AIF   ('&TYPE(&COUNT)' EQ 'PAT').ASPPRI                  21048 48050021
**  UNIT RECORD EQUIPMENT POINTS TO ENTRY ONE WITH PRIORITY             48600020
         DC    AL2(XCPPRQ-IOSBASE)      PRIORITY Q'ING FOR U.R.    RL19 49200020
         AGO   .URSIO                                                   49800020
.TAPEWPR ANOP                                                           50400020
**  TAPE ENTRY FOR PRIORITY QUEING                                      51000020
         DC    AL2(XCPPRQ-IOSBASE)      PRIORITY QUE FOR TAPE      RL19 51600020
         AGO   .TASIO                                                   52200020
.ASPPRI  ANOP                                                     21048 52250021
**   ASPEN ENTRY WITH PRIORITY QUEUING                            21048 52300021
         DC    AL2(XCPPRQ-IOSBASE)      PRIORITY QUEUE FOR ASPEN  21048 52350021
         AGO   .ASPSIO                                            21048 52400021
.DRWPR   ANOP                                                           52800020
**  DR OR ZS ENTRY WITH PRIORITY QUEUEING                               53400020
         AGO   .DRPRI                                                   54000020
.DAWPR   ANOP                                                           54600020
**  DA OR ML ENTRY WITH PRIORITY QUEUEING                               55200020
.DRPRI   DC    AL2(XCP100A-IOSBASE)     PRIORITY SEEK Q'NG FOR DA       55800020
         AIF   ('&TYPE(&COUNT)' EQ 'PZS').ZUS     TEST FOR ZEUS         56400020
    AIF  ('&TYPE(&COUNT)' EQ 'PDR' OR '&TYPE(&COUNT)' EQ 'PML').DRPRIR  57000020
         DC    AL2(XIODSK-IOSBASE)      SIO FOR DIRECT ACCESS      RL19 57600020
         DC    AL2(INTDAT-IOSBASE)      TRAP FOR DIRECT ACCESS     RL19 58200020
         AIF   ('&TYPE(&COUNT)' EQ 'PDS').SHAR    TEST FOR SHARED       58800020
         DC    AL2(NORMSEN-IOSBASE)     SENSE ENTRY                     59400020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               60000020
.TPWPR   ANOP                                                           60600020
**  TP SUPPORT ENTRY WITH PRIORITY QUEING                               61200020
         DC    AL2(XCPPRQ-IOSBASE)      PRIORITY QUE FOR TP        RL19 61800020
         DC    AL2(XCP121-IOSBASE)      SIO RTN FOR TP DEVICES     RL19 62400020
         DC    AL2(XCPTPT-IOSBASE)      TRAP FOR TP DEVICES        RL19 63000020
         DC    AL2(TPSEN-IOSBASE)       SENSE FOR TP                    63600020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               64200020
.GRWPR   ANOP                                                           64800020
**  GRAPHICS ENTRY WITH PRIORITY QUEUING                                65400020
         DC    AL2(XCPPRQ-IOSBASE)      PRIORITY QUEUING FOR GRAPH RL19 66000020
         DC    AL2(XIOUR-IOSBASE)       SIO FOR GRAPHICS           RL19 66600020
         DC    AL2(INTDNP-IOSBASE)      TRAP FOR GRAPHICS          RL19 67200020
         DC    AL2(NORMSEN-IOSBASE)     SENSE ENTRY                     67800020
         AGO   .TSTLOOP            RETURN TO TYPE TST LOOP              68400020
.ORDDSK  ANOP                                                      OSER 69000020
**   DA ENTRY WITH ORDERED SEEK QUEUEING                                69600020
         DC    AL2(XCPSEQ-IOSBASE)      ORDERED SEEK Q FOR DA      RL19 70200020
         AIF   ('&TYPE(&COUNT)' EQ 'OML').DRPRIR  TEST FOR MERLIN       70800020
         DC    AL2(XIODSK-IOSBASE)      SIO FOR DIRECT ACCESS      RL19 71400020
         DC    AL2(INTDAT-IOSBASE)      TRAP FOR DIRECT ACCESS     RL19 72000020
         AIF   ('&TYPE(&COUNT)' EQ 'ODS').SHAR    TEST FOR SHARED       72600020
         DC    AL2(NORMSEN-IOSBASE)     SENSE ENTRY                     73200020
         AGO   .TSTLOOP                 RETUN TO TEST LOOP              73800020
.EXPSN   DC    AL2(EXPSEN-IOSBASE)      EXPANDED SENSE ENTRY            74400020
         AGO   .TSTLOOP           RETURN TO TYPE TST LOOP               75000020
.END     ANOP                                                           75600020
**   CHANNEL TABLE                                                      76200020
IECCST   DS    0H                                                       76800020
.CONTIN  AIF  (&LSTINDX EQ N'&CHANLST).ENDA                             77400020
         AIF   (&CHMSK GT 1).CONTINA    TEST FOR INITIALIZATION         78000020
&CHMSK   SETA  256                      INITIALIZE MASK                 78600020
.CONTINA ANOP                                                           79200020
&CHMSK   SETA  &CHMSK/2                 SHIFT RIGHT 1                   79800020
&LSTINDX SETA  &LSTINDX+1               INCREMENT INDEX                 80400020
         AIF   (&CHANLST(&LSTINDX) EQ 0).OUT1     TEST FOR CHAN         81000020
&INSERT  SETA  &LSTINDX-1               SET CHAN CODE POINTER           81600020
         DC    AL2(INTCS&INSERT.-IOSBASE)    CHAN SEARCH CODE           82200020
         DC    AL1(&CHMSK)              MASK                            82800020
         DC    AL1(&CHANLST(&LSTINDX))  CHANNEL TYPE                    83400020
&INSERT  SETA  &LSTINDX                 GET HI-TOT FOR UCBSAVE          84000020
         AGO   .CONTIN                  CONTINUE                        84600020
.OUT1    DC    AL2(INT033-IOSBASE)                                      85200020
         DC    AL1(&CHMSK)              MASK                            85800020
         DC    X'00'                    FILLER                          86400020
         AGO   .CONTIN                  CONTINUE                        87000020
.ENDA    AIF   (N'&CHANLST LT 8).ENDB   MORE THAN 7 CHANNELS            87600021
&CHMSK   SETA  0                                                        87650021
&COUNT   SETA  65536                                                    87700021
&LSTINDX SETA  0                                                        87750021
.RSTLOOP AIF   (&LSTINDX EQ 16).RSTMSK                                  87800021
&LSTINDX SETA  &LSTINDX+1                                               87850021
&COUNT   SETA  &COUNT/2                                                 87900021
         AIF   (&CHANLST(&LSTINDX) EQ 0).RSTLOOP                        87950021
&CHMSK   SETA  &CHMSK+&COUNT                                            88000021
         AGO   .RSTLOOP                                                 88050021
.RSTMSK  ANOP                                                           88100021
*        RESTART MASK FOR GREATER THAN 7 CHANNELS                       88150021
RST7MSK  DC    AL2(&CHMSK)                                              88160021
.ENDB    AIF   (&M65MP EQ 1).NOSAVE     TEST FOR MP                     88170021
UCBSAVE  DS    0H                                                       88200020
         DC    &INSERT.Y(UCB1-IPLPSW)   INITIALIZE ADDRESS              88800021
.NOSAVE  ANOP                                                           89400020
*   LCH TABLE                                                           90000020
LCHTAB   DS    0H                                                       90600020
IECILCH  DS    0C                                                       91200020
&INSERT  SETA  1                        INITIALIZE NUMBER               91800020
.LCHST   AIF   (&INSERT GT &LCHTOT).LCHEND                              92400020
**             CHANNEL LCHWORD                                          93000020
LCH&INSERT DC X'FFFF',XL4'0',AL2(XCPCH&INSERT.-IPLPSW)   LCHWORD        93600020
&INSERT  SETA  &INSERT+1                UPDATE INDEX                    94200020
         AGO   .LCHST                                                   94800020
.LCHEND  ANOP                                                           95400021
         MEND                                                           96000020
