         MACRO                                                          00060019
         IECXCP &TAPE,&SMF,&P3211,&TP,&APR,&VP,&SKORD,&RFIFO,&RPR,     *00120021
               &TWOSW,&VS,&PROTECT,&TRACE,&SSDA,&TCBTYP,&SSTA,&GR,     *00180021
               &NOP1,&RWTAU,&RESJQ,&NOP2,&ASR,&M65MP,&TBASE,&ANR,      X00270021
               &DAVV,&DDR,&M7CH,&ASPN,&NOP4,&OLTEP,&TSO,&CEXT,&RMS,    X00360021
               &TCAM,&MFTATT,&NOP3,&ALTSHR                       A52475 00450021
         GBLB  &IECITB                                                  00540021
         GBLB  &D2311,&D2321,&D2301,&D2303,&D2305,&DML            20201 00560020
         GBLB  &R2311,&R2321,&R2301,&R2303,&R2305,&RML            20201 00580020
         LCLB  &RESREL,&RPS,&TBYT                                 20201 00610021
&RESREL  SETB  (&R2321 OR &R2311)                                 20201 00620020
&RPS     SETB  (&D2305 OR &DML)                                   20201 00630020
&TBYT    SETB  (&IECITB)                SET IF 2 BYTE CU LOOKUP TA20201 00650020
         TITLE 'EXTRNS AND ENTRYS - INPUT/OUTPUT SUPERVISOR'            00700021
         AIF   (&TCBTYP LT 2).MVT010                             A24739 00960019
         EXTRN  IEA0XE00,DISMISS                                        01020019
         AIF   (&M65MP EQ 1).MPB004                                     01080019
         EXTRN IEATCBP                                                  01140019
.MPB004  EXTRN IEA0DS02,IEAHEAD                                    MP1A 01200019
.MVT010  EXTRN IEA0PT01                POST ROUTINE ENTRY POINT    MP1A 01260019
         AIF   (&ASR EQ 0 OR &M65MP EQ 1 OR &TCBTYP EQ 1).NCLP01  M0192 01290021
         EXTRN IEA0IO02                 PSEUDO DISABLE SW IN FLIH 21111 01320021
.NCLP01  EXTRN ER2311                   2311 ERROR ROUTINE ENTRY POINT  01350021
         EXTRN IEEBA1         CONSOLE ATTENTION HANDLER                 01380019
         EXTRN IEFDPOST       SCHEDULE POST ROUTINE (ATTENTION)         01440019
         AIF   (&TCAM EQ 0).NTCAM       TEST FOR TCAM             20002 01470020
         EXTRN IEDQATTN                 TCAM ATTENTION HANDLER    20002 01500020
.NTCAM   AIF   (&DDR EQ 0).DDR21                                  20002 01530020
         EXTRN DDRIOB,DDRDEB,IGFRMTCB,IGF0IOB,IGF0DEB             19022 01560019
.DDR21   AIF   (&M65MP EQ 0).MPB008                               19022 01620019
         EXTRN SHOLDTAP                 SHOULDER TAP ENTRY POINT   MP1A 01680019
         ENTRY IECTCHMP       ENTRY FROM M65MP VARY COMMANDS       MP1A 01740019
         ENTRY IECTIOMP       ENTRY FROM M65MP VARY COMMANDS       MP1A 01800019
         ENTRY IECISHTP            S.T. INTERFACE, RECEIVING CPU   MP1A 01860019
.MPB008  ENTRY IGC000                   EXCP                            01920019
         AIF   (&TCBTYP EQ 0).PGMCK00                            A24739 01950019
         ENTRY IECCPL00       PROGRAM CHECK ROUTINE              A24739 01980019
.PGMCK00 ENTRY IECINT         I/O INTERRUPTION SUPERVISOR        A24739 02010019
         ENTRY IGC015         ERROR EXCP                                02040019
         ENTRY IECIHIO                 COMMON HIO ROUTINE          IMP2 02100019
         ENTRY IECIXAVL       POINTER TO NEXT AVAILABLE REQUEST ELEMENT 02160019
         ENTRY IECXAPG        APPENDAGE VECTOR TABLE                    02220019
         ENTRY IECILCH        LOGICAL CHANNEL WORD TABLE                02280019
         ENTRY IECILK1        UCB LOOKUP TABLE CH + CNTRL UNIT PORTION  02340019
         ENTRY IECILK2        UCB LOOKUP TABLE UCB ADDRESS PORTION      02400019
         ENTRY IECIOQET       REQUEST ELEMENT TABLE                     02460019
         ENTRY IECSTB         STATISTICS TABLE                          02520019
         ENTRY INT025         ENTRY TO PURGE COMPLETE AND RETURN        02580019
*                             RQE FOR THE SUPERVISOR                    02640019
         ENTRY XCP064         LOCATE LOGICAL CHANNEL WORD               02700019
         ENTRY IECDMS                   DIMISS ADDRESS-I/O INTR. RETURN 02760019
         ENTRY IECCST,IECITSAR                                     IMP4 02820019
         ENTRY IECRQE00                                         SA53191 02822021
         AIF   (&TSO EQ 0).TSO000       TEST FOR TIME SHARING     20001 02830020
         ENTRY IGC092                   TCB EXCP                  20001 02840020
.TSO000  ANOP                                                     20001 02850020
         ENTRY IECOLTVT,DEVTAB          OLTEP SUPPORT                   02880021
         AIF   (&RMS EQ 0).RMS10                                  19021 02940019
         ENTRY IECRMS                                             19021 03000019
.RMS10   AIF   (&DDR EQ 0).DDR20                                  19022 03060019
         ENTRY DDRRQE,DDRAPNVT,DDRSRTO  RQE, APN VT, SVAREA       19022 03090019
.DDR20   AIF   (&DDR LT 2).DDR22        NO SYSRES DDR, SKIP       19022 03120019
         ENTRY DDRRQESR                 RQE FOR SYSRES DDR        19022 03150019
.DDR22   TITLE 'EQUATES - INPUT/OUTPUT SUPERVISOR'                      03230021
*    REGISTER DEFINITIONS                                        BBBBBB 03240019
REG0     EQU   0                        TEMPORARY BAL REGISTER   BBBBBB 03300019
TCBRG0   EQU   0                        PARAMETER REGISTER        20001 03330020
TSTREG   EQU   1                        REQUEST ELEMENT ADDRESS         03360019
IOBREG   EQU   2                        IOB ADDRESS                     03420019
DEBREG   EQU   3                        DEB ADDRESS                     03480019
DCBREG   EQU   4                        DCB ADDRESS                     03540019
TCBREG   EQU   4                        TCB ENVIRONMENTAL REGISTER20001 03570020
BASREG   EQU   5                        BASE VALUE FOR IOS              03600019
UAREG    EQU   6                        UNIT ADDRESS                    03660019
UCBREG   EQU   7                        UCB ADDRESS                     03720019
BASREG2  EQU   8                        SECOND BASE REGISTER       TBSE 03780019
LNKRG1   EQU   8                        MAIN LINK REGISTER              03840019
ICREG    EQU   9                        INSERT CHARACTER REG            03900019
WKREG1   EQU   10                       MAIN WORKING REGISTER           03960019
WKREG2   EQU   11                       WORKING REGISTER                04020019
WKREG3   EQU   12                       SPARE WORK REGISTER             04140019
LNKRG3   EQU   WKREG3                   SPARE LINK REGISTER             04200019
LCHREG   EQU   13                       LOGICAL CHANNEL WORD            04260019
LNKRG2   EQU   14                       LINK REGISTER                   04320019
APBSRG   EQU   15                       APPENDAGE BASE REG              04380019
         EJECT                                                          04440019
*    IOB DEFINITION                                              BBBBBB 04500019
IOBFL1   EQU   0                        FLAGS 1                         04560019
IOBFL2   EQU   1                        FLAGS 2                         04620019
IOBSNS   EQU   2                        SENSE DATA                      04680019
IOBCOD   EQU   4                        ECB CODE                        04740019
IOBECB   EQU   5                        ECB POINTER                     04800019
IOBCSW   EQU   8                        CSW STORAGE                     04860019
IOBFL3   EQU   IOBCSW                   FLAGS 3 ARE IN FIRST BYTE       04920019
IOBCC    EQU   16                       CONDITION CODE                  04980019
IOBST    EQU   17                       START ADDRESS                   05040019
IOBWGT   EQU   20                       WEIGHT CODE                     05100019
IOBDCB   EQU   21                       DCB POINTER                     05160019
IOBMDB   EQU   24                       MODIFIER BYTE                   05220019
IOBRST   EQU   25                       RESTART POINTER                 05280019
IOBBCI   EQU   28                       BLOCK COUNT INCR.               05340019
IOBECT   EQU   30                       ERROR COUNTS                    05400019
IOBDAM   EQU   32                       DIRECT ACCESS EXTENT (M) BYTE   05460019
IOBCCR   EQU   35                       SEEK CYLINDER IN IOB            05520019
         SPACE 2                                                        05580019
*    THESE FLAGS ARE IN IOB FLAG 1                               BBBBBB 05640019
IOBCDS   EQU   X'C0'                    IOB CHANNEL DESP. FLAG          05700019
IOBERR   EQU   X'20'                    ERROR CORRECTION IND.           05760019
IOBMD1   EQU   X'10'                    MOD1 FLAG- POSITIONING          05820019
IOBMD2   EQU   X'08'                    MOD2 FLAG- TAPE(CRC CORRECTION) 05880019
IOBEX    EQU   X'04'                    EXCEPT FLAG                     05940019
IOBURL   EQU   X'02'                    UNRELATED OR NON-SEQUENT.       06000019
IOBSRS   EQU   X'01'                    START/RESTART FLAG              06060019
         SPACE 1                                                        06120019
*    THESE FLAGS ARE IN IOB FLAG 2                               BBBBBB 06180019
IOBHLT   EQU   X'80'                    HALT I/O ISSUED FLAG            06240019
IOBSNB   EQU   X'40'                    SENSE BIT                       06300019
IOBPRG   EQU   X'20'                    PURGE FLAG                      06360019
IOBHAR0  EQU   X'10'                    READ HA AND R0 FLAG             06420019
IOBNET   EQU   X'08'                    NO TEST FOR OUT OF EXT.  BBBBBB 06480019
IOBUEX   EQU   IOBNET                   WRT.ERR.ON UE FOR 2400 TAPE     06540019
IOBROR   EQU   X'04'                    RD OP RECOVERY IN PROC.  BBBBBB 06600019
IOBGRF   EQU   X'02'                    CE WITHOUT DE INDICAT. FOR GR.  06660019
IOBQSM   EQU   X'01'                    USED BY QSAM AND TP             06720019
         SPACE 1                                                        06780019
IOBCC1   EQU   X'10'                    CONDITION CODE OF SIO           06840019
IOBCC3   EQU   X'30'                    NOT OPERATIONAL C CODE          06900019
         SPACE 3                                                        06960019
*    ECB DEFINITION                                              BBBBBB 07020019
ECBFL    EQU   0                        FLAGS                           07080019
         SPACE 1                                                        07140019
*    THESE ARE COMPLETION CODE SETTINGS                          BBBBBB 07200019
NORMC    EQU   X'7F'                    NORMAL COMPLETE SETTING OF FLS  07260019
IOBINT   EQU   X'7E'                    IOB INTERCEPT CODE              07320019
PERMER   EQU   X'41'                    I-O PERM ERROR                  07380019
EXTERR   EQU   X'42'                    EXTENT PERM ERROR               07440019
INTCOD   EQU   X'44'                    INTERCEPT POST CODE             07500019
PRGCOD   EQU   X'48'                    PURGED REQUEST                  07560019
HAR0ER   EQU   X'4F'                    HOME ADDRESS AND R0 ERROR       07620019
         SPACE 3                                                        07680019
*    UCB DEFINITION                                              BBBBBB 07740019
UCBMPANX EQU   4                        NEG. DISP. FOR MP FLAGS3   MP1A 07800019
UCBFL3   EQU   0                        FLAG IN UCB ANNEX        BBBBBB 07860019
UCBALLC  EQU   1                        ALLOCATE MASK FOR UCB           07920019
UCBFL5   EQU   1                        EXTRA UCB FLAGS           20201 07950020
SRTESTAT EQU   3                        STATUS BYTE A                   07980019
UCBID    EQU   2                        UCB  I D                        08040019
UCBCHA   EQU   4                        CHANNEL ADDRESS                 08100019
UCBUA    EQU   5                        UNIT ADDRESS                    08160019
UCBFL1   EQU   6                        FLAGS 1                         08220019
UCBDTI   EQU   7                        DEVICE TABLE INDEX              08280019
UCBETI   EQU   8                        ERROR TABLE INDEX               08340019
UCBSTI   EQU   9                        STATISTICS TABLE INDEX          08400019
UCBLCI   EQU   10                       LOGICAL CHANNEL INDEX           08460019
UCBATI   EQU   11                       ATTENTION TABLE INDEX           08520019
UCBCHM   EQU   12                       CHANNEL MASK(BITS 4-7)          08580019
UCBNAM   EQU   13                       UNIT NAME - EBCDIC        19022 08640019
UCBTYP   EQU   16                       DEVICE TYPE CODE                08700019
UCBLTS   EQU   20                       LAST REQUEST ELEMENT ADDRESS    08760019
UCBSNS   EQU   22                       SENSE DATA                      08820019
UCBFL7   EQU   UCBSNS                   FLAGS 7 BYTE FOR DEVICES A44146 08826021
*                                       WITH EXPANDED SENSE      A44146 08832021
UCBNBRSN EQU   24                       COUNT OF DEVICE SENSE INFO20201 08840020
UCBSNADR EQU   25                       POINTER TO SENSE DATA AREA20201 08860020
UCBVOL1  EQU   28                       VOLUME SERIAL              DAVV 08880019
UCBRQESV EQU   42                       VOL VER RTN RQE SAVE AREA  DAVV 08940019
UCBFL4   EQU   44                       VOL VER RTN FLAGS          DAVV 09000019
UCBORCNT EQU   44                       ORD. SEEK QUEUE USER COUNT OSER 09060019
UCBORSV  EQU   45                       ORD. SEEK QUEUE LAST DEB   OSER 09120019
UCBSKA   EQU   48                       LAST SEEK ADDRESS               09180019
UCBROR   EQU   48                       RD OP RECOVERY WK AREA   BBBBBB 09240019
UCBVOPT  EQU   48                       TAPE VOLUME OPTIONS       21048 09290021
UCBCCR   EQU   51                       CYLINDER OF LAST OPERATION      09300019
DCELBBNR EQU   56                       FIRST SUB-UCB OF 2321     19022 09360019
UCBWKADB EQU   60                       PTR TO NON-2321 ERP WKAREA      09420019
UCBWKADA EQU   216                      PTR TO 2321 ERP WORK AREA  S248 09480019
UCBWKDCC EQU   80                       WK AREA DISPL TO DCC CP   19025 09540019
UCBRRCNT EQU   40                       ONE BYTE RES/REL COUNTER BBBBBB 09600019
UCBDVRES EQU   41                       DEVICE RESERVED INDICATOR  SDA1 09660019
RSVD     EQU   X'80'                    DEVICE RESERVED BIT     SA73317 09710018
PND      EQU   X'40'                    RESERVE/RELEASE PENDING SA73317 09712018
UCBRR0A  EQU   124                      INPUT AREA FOR READ R0     S248 09720019
UCBRHA   EQU   4                        OFSET FROM R-R0 TO R-HA         09780019
RHADR    EQU   8                        INCR. TO RHA ADDRESS     A49373 09840021
RR0ADR   EQU   16                       INCR. TO RR0 DATA ADDR   A49373 09900021
UCBRR    EQU   X'20'                    SHARED DEVICE OPTION IND.BBBBBB 09960019
UCBRPS   EQU   X'10'                    ROT. POS. SNS. OPT. FEAT  19025 10020019
UCBCHGS  EQU   X'40'                    VARY PENDING BIT        SA67706 10030021
UCBUNSOL EQU   X'01'                    UNSOLICITED INTERRUPT     21048 10070021
         SPACE 2                                                        10080019
*    FLAGS IN UCB CHANNEL FIELD                                         10140019
UCBHLT   EQU   X'80'                    HALT I/O FLAG FROM PURGE        10200019
UCBSMD   EQU   X'40'                    STATUS MODIFIER FLAG            10260019
UCBDSNS  EQU   X'20'                    DELAYED SENSE PENDING     21111 10280021
UCBDHIO  EQU   X'10'                    DELAYED HIO PENDING       21111 10300021
         SPACE 1                                                 BBBBBB 10320019
*    FLAGS 1 IN UCB                                              BBBBBB 10380019
UCBBSY   EQU   X'80'                    BUSY BIT                        10440019
UCBNRY   EQU   X'40'                    UCB NOT READY                   10500019
UCBPST   EQU   X'20'                    POST FLAG                       10560019
UCBITF   EQU   X'10'                    UCB INTERCEPT FLAG              10620019
UCBCUB   EQU   X'08'                    CONTROL UNIT BUSY FLAG          10680019
UCBDTR   EQU   X'04'                    DISK DATA TRANSFER              10740019
UCBASK   EQU   X'02'                    DISK ARM SEEKING                10800019
UCBERR   EQU   X'01'                    ERROR RTN IN CONTROL FLAG       10860019
UCBIDV   EQU   X'FF'                    ID BYTE OF UCB           BBBBBB 10920019
         SPACE 1                                                        10980019
*    FLAGS 5 IN UCB                                               20201 10990020
UCBUEX   EQU   X'80'                    UNIT EXEP ON SENSE       S22024 10992021
UCBTICBT EQU   X'20'                    CE OR DE INTER. OWED     A42261 11005021
UCBEXTSN EQU   X'08'                    SNESE DATA NOT IN UCB     20201 11007021
UCBNALOC EQU   X'04'                    OLTEP OWNS DEVICE       SA58683 11009021
         SPACE 1                                                        11010020
*    FLAGS 3 IN UCB FOR MULTIPROCESSING                          BBBBBB 11040019
UCBACU   EQU   X'80'                    ALT. C.U. ON THIS DEVICE  19022 11100019
UCBCPUA  EQU   X'08'                    WHICH CPU ISSUED LAST SIO 21063 11150021
         SPACE 1                                                  19022 11160019
*    FLAGS 4 IN UCB                                                     11220019
UCBDAV   EQU   X'F8'                    DAVV FLAG BYTE             DAVV 11280019
UCBDAVV  EQU   X'78'                    DAVV MNT MASK           SA57136 11330021
UCBVVR   EQU   X'40'                    VOL VER RTN IN CONTROL     DAVV 11340019
UCBVER   EQU   X'48'                    VOLUME VERIFIED FLAG       DAVV 11400019
         SPACE 1                                                        11460019
*    FLAGS 7 IN UCB                                                     11470021
STPPRNT  EQU   X'80'                    CANCEL KEY HIT ON 3211   A44146 11480021
         SPACE 1                                                        11490021
*    UCB DEVICE TYPE CODES                                              11520019
DRUM     EQU   X'02'                    DRUM                            11580019
UCB2321  EQU   X'05'                    DATA CELL                       11640019
ZEUSA    EQU   X'06'                                              20201 11650020
ZEUSC    EQU   X'07'                                              20201 11660020
MERLIN   EQU   X'09'                                              20201 11670020
GRTYPE   EQU   X'10'                    GRAPHICS                        11700019
DSKTYP   EQU   X'20'                    DISK                            11760019
TPTYPE   EQU   X'40'                    TELEPROCESSING                  11820019
TAPE     EQU   X'80'                    TAPE                            11880019
         SPACE 3                                                        11940019
*    DEB DEFINITION                                              BBBBBB 12000019
DEBTCB   EQU   1                        DEB POINTER TO TCB              12060019
DEBDEB   EQU   4                        ADDR OF NEXT DEB IN CHAINDEBVTY 12090019
DEBOPFL  EQU   8                        DATA SET STATUS FLAGS           12120019
DEBQUS   EQU   13                       DEB QUIESCE COUNT        BBBBBB 12180019
DEBENT   EQU   16                       NO. OF DEB EXTENTS              12240019
DEBUPG   EQU   17                       USER PURGE CHAIN                12300019
DEBPR    EQU   20                       PRIORITY                        12360019
DEBEPG   EQU   21                       PURGE ECB ADDR.                 12420019
DEBPRT   EQU   24                       PROTECTION TAG                  12480019
DEBID    EQU   24                       ID FOR PROTECTION               12540019
DEBDCB   EQU   25                       DCB LOC POINTER                 12600019
DEBEXT   EQU   28                       EXTENT SCALE                    12660019
DEBAPG   EQU   29                       APPD. TABLE BASE                12720019
DEBMDM   EQU   32                       MODIFIER MASK                   12780019
DEBUCB   EQU   33                       UCB POINTER                     12840019
DEBEXTNT EQU   36                       DEB EXTENT OFFSET               12940021
DEBIDV   EQU   X'0F'                    VALUE OF DEB ID                 13080019
DEBSCA   EQU   X'04'                    SPLIT CYLINDER ALLOCATION       13140019
         SPACE 2                                                        13200019
*    DEB EXTENT OFFSETS                                                 13210020
DEBBB    EQU   0                        BIN NUMBER                      13220021
DEBST    EQU   2                        EXTENT START ADDRESS            13230021
DEBEND   EQU   6                        EXTENT END ADDRESS              13240021
*    DEB APPENDAGE VECTOR TABLE OFFSETS                          BBBBBB 13260019
APGEOE   EQU   0                        END OF EXTENT VECTOR            13320019
APGSIO   EQU   4                        APPENDAGE SIO VECTOR            13380019
APGPCI   EQU   8                        APPENDAGE PCI VECTOR            13440019
APGCHE   EQU   12                       APPENDAGE CHANNEL END           13500019
APGABE   EQU   16                       APPENDAGE ABNORMAL END LOC      13560019
         SPACE 3                                                        13620019
*    DCB DEFINITION                                              BBBBBB 13680019
DCBBLK   EQU   12                       DCB FLOCK COUNT                 13740019
DCBFL    EQU   44                       FLAGS                           13800019
DCBDEB   EQU   45                       DEB POINTER                     13860019
DCBIEM   EQU   52                       IOS ERROR MASK                  13920019
DCBUEM   EQU   56                       USER ERROR MASK                 13980019
         SPACE 2                                                        14040019
*    DCB FLAGS                                                          14100019
DCBPER   EQU   X'C0'                    PERMANENT ERROR FLAGS           14160019
DCBEX    EQU   X'40'                    EXCEPTION CONDITION             14220019
DCBIEK   EQU   X'0C'                    IOS ERROR KEY                   14280019
DCBUEK   EQU   X'03'                    USER ERROR KEY                  14340019
         SPACE 3                                                        14400019
*    REQUEST ELEMENT DEFINITION                                  BBBBBB 14460019
TSTLNK   EQU   0                        FORWARD RQE LINK                14520019
TSTUCB   EQU   2                        UCB POINTER                     14580019
TSTASSN  EQU   4                        ASSIGN RQE BYTE                 14640019
         AIF   (&TCBTYP LT 2).STIOS33   NOT MVT, SKIP            A24739 14700019
TSTKEY   EQU   12                       REQUESTORS PROTECT KEY          14760019
TSTTCB   EQU   12                       TCB POINTER                     14820019
RQELN    EQU   16                       MVT RQE LENGTH                  14870021
         AGO   .STIOS34                                                 14880019
.STIOS33 ANOP                           SSS TCB/ID                      14940019
TSTTCB   EQU   4                        TCB ID BYTE                     15000019
RQELN    EQU   12                       MFT RQE LENGTH                  15050021
.STIOS34 ANOP                                                           15060019
TSTIOB   EQU   5                        IOB POINTER                     15120019
TSTPR    EQU   8                        PRIORITY OF ENTRY               15180019
TSTDEB   EQU   9                        DEB POINTER                     15240019
         SPACE 3                                                        15300019
*    LOGICAL CHANNEL DEFINITION                                  BBBBBB 15360019
LCHFTS   EQU   0                        FIRST RQE                       15420019
LCHLTS   EQU   2                        LAST RQE                        15480019
LCHENQ   EQU   4                        ENQUEUE CODE POINTER            15540019
LCHSRH   EQU   4                        SCRATCH AREA                    15600019
LCHTCH   EQU   6                        TEST CHANNEL CODE ADDRESS       15660019
LCHOUT   EQU   X'80'                                               PRER 15720019
         SPACE 3                                                        15780019
*    DEVICE TABLE DEFINITION                                     BBBBBB 15840019
DVTENQ   EQU   0                        ENQUEUE ADDRESS OFFSET          15900019
DVTSIO   EQU   2                        SIO ADDRESS OFFSET              15960019
DVTTRP   EQU   4                        TRAP ADDRESS OFFSET             16020019
DVTSEN   EQU   6                                                  20201 16050020
         SPACE 3                                                        16080019
*    LOGICAL CHANNEL TABLE                                       BBBBBB 16140019
LCTCSC   EQU   0                        LOGICAL CH. TBL SEARCH CODE     16200019
LCTMSK   EQU   2                        LOGICAL CH. TBL MSK             16260019
LCTFLS   EQU   3                        LOGICAL CHANNEL TBL FLAGS       16320019
LCTSLBX  EQU   X'03'                    SELECTOR OR BLK MPX MASK A47317 16370021
         SPACE 3                                                 BBBBBB 16380019
*    SYSTEM CHANNEL PROGRAM OFFSETS                              BBBBBB 16440019
SEEK2    EQU   0                        D/A DTR CCW                     16500019
SFMCCW   EQU   SEEK2+8                  SET FILE MASK CCW        BBBBBB 16560019
SMMSK2   EQU   SEEK2+13                 FILE MASK LOC. IN CCW           16620019
SKTIC    EQU   SEEK2+16                 TIC TO USERS PROGRAM            16680019
TAPEIO   EQU   8                        SET MODE OR TIE OPCODE  SA54451 16732021
CRCBTE   EQU   13                       CRC CORRECTION BYTE     SA54451 16734021
TAPETIC  EQU   16                       TIC TO USER             SA54451 16736021
         SPACE 2                                                 BBBBBB 16740019
*    CCW FLAG BITS                                               BBBBBB 16800019
CCWFLG   EQU   4                        CCW OFFSET TO FLAGS      BBBBBB 16860019
CCWCC    EQU   X'40'                    COMMAND CHAINING BIT     BBBBBB 16920019
CCWSLI   EQU   X'20'                    SUPPRESS LENGTH BIT      BBBBBB 16980019
CCWSD    EQU   X'10'                    SUPPRESS DATA TRANSFER   BBBBBB 17040019
CCWLN    EQU   8                        LENGTH OF CCW            A27691 17070019
         SPACE 1                                                        17100019
*    CCW COMMAND CODES                                                  17160019
RELEASE  EQU   X'94'                    2-CHANNEL SWITCH RELEASE   IMP5 17220019
RESERVE  EQU   X'B4'                    2-CHANNEL SWITCH RESERVE   IMP5 17280019
SENSOP   EQU   X'04'                    SENSE                      IMP5 17340019
RR0OP    EQU   X'16'                    READ R0                  A49373 17390021
SETFMSK  EQU   X'1F'                    SET FILE MASK              IMP5 17400019
HAOP     EQU   X'1A'                    READ HOME ADDRESS          IMP5 17460019
TICOP    EQU   X'08'                    TRANSFER IN CHANNEL        IMP5 17520019
TIEOP    EQU   X'1B'                    TRACK IN ERROR FOR TAPE    IMP5 17580019
NOOP     EQU   X'03'                    NO OPERATION               IMP5 17640019
         EJECT                                                          17700019
*    STATUS INDICATORS                                           BBBBBB 17760019
CSWATN   EQU   X'80'                    ATTENTION FLAG                  17820019
CSWSMD   EQU   X'40'                    STATUS MODIFIER                 17880019
CSWCUE   EQU   X'20'                    CONTROL UNIT END                17940019
CSWBSY   EQU   X'10'                    BUSY                            18000019
CSWCHE   EQU   X'08'                    CHANNEL END                     18060019
CSWDVE   EQU   X'04'                    DEVICE END                      18120019
CSWUCK   EQU   X'02'                    UNIT CHECK                      18180019
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  18240019
CSWPCI   EQU   X'80'                    PCI                             18300019
CSWIL    EQU   X'40'                    WRONG LENGTH IND.               18360019
CSWPC    EQU   X'20'                    PROGRAM CHECK                   18420019
CSWPCK   EQU   X'10'                    PROTECTION CHECK                18480019
CSWCDK   EQU   X'08'                    CHANNEL DATA CHECK              18540019
CSWCTK   EQU   X'04'                    CHANNEL CONTROL CHECK           18600019
CSWICK   EQU   X'02'                    INTERFACE CONTROL CHECK         18660019
CSWCCK   EQU   X'01'                    CHAINING CHECK                  18720019
CUBBIT   EQU   CSWSMD+CSWBSY            CONTROL UNIT BUSY        BBBBBB 18780019
CATBIT   EQU   CSWCDK+CSWCTK+CSWICK     CATASTROPHIC ERROR       BBBBBB 18840019
         AIF   (&ASR EQ 0).ASR00                                 BBBBBB 18850019
CATCCH   EQU   CSWCDK                   CHANNEL DATA CHECK       BBBBBB 18860019
CSWCLP   EQU   X'04'                    CHANNEL LOGOUT PENDING    21111 18863021
ERPWKA   EQU   104                      OFFSET TO ERP WORK AREA   21111 18866021
         AGO   .ASR01                                            BBBBBB 18870019
.ASR00   ANOP                                                    BBBBBB 18880019
CATCCH   EQU   0                        ZERO IF NO CCH IN SYSTEM BBBBBB 18890019
.ASR01   SPACE 3                                                 BBBBBB 18900019
*    CCH INDEX/FLAG DEFINITIONS                                  BBBBBB 18960019
CATSSK   EQU   0                        DIRECT ACCESS MODULE - SIO  CCH 19020019
CATTIOSK EQU   4                        DIRECT ACCESS MODULE - TIO  CCH 19080019
CATSNS   EQU   8 .                      SENSE SUBROUTINE ----- SIO  CCH 19140019
CATTIOSN EQU   12 .                     SENSE SUBROUTINE ----- TIO  CCH 19200019
CATSIO   EQU   16                       POST SIO MODULE -----SIO BBBBBB 19260019
CATINT   EQU   20                       IOS INTERRUPT SUP. ---INT.      19320019
CATHIO   EQU   24                       HIO SUBROUTINE -----HIO  BBBBBB 19380019
CATREC   EQU   28                       SENSE SUBROUTINE RETURN  BBBBBB 19440019
         SPACE 3                                                        19500019
*    CHANNEL ERROR BLOCK DEFINITION AND APR FLAGS                BBBBBB 19560019
CEBINA   EQU   0                        CEB INACTIVE FIELD        19022 19620019
CEBCHMSK EQU   1                        CEB CHAN MASK FIELD       19022 19680019
CEBRQE   EQU   2                        CEB RQE FIELD             19022 19740019
FREE     EQU   X'FE'                    INACTIVE CEB INDICATOR    19022 19800019
CEBNXT   EQU   4                        OFFSET TO NEXT CEB        19022 19860019
CEBACT   EQU   X'01'                    CEB ACT SW, AN ACTIVE CEB 19022 19920019
MULTPATH EQU   X'01'                    MULTIPLE PATH INDICATOR   19022 19980019
PTHIND   EQU   1                        PATH INDICATOR FIELD      19022 20040019
HEXF00   EQU   X'F00'                   CHANNEL MASK              19022 20100019
CUZER    EQU   X'0F'                    CONTRL UNIT ADDR MASK     19022 20160019
CUAZER   EQU   X'F0'                    CONT UNIT ADDR ZERO MSK   19022 20220019
CPUA     EQU   X'C1'                    CPUA INDICATOR            19022 20280019
CPUB     EQU   X'C2'                    CPUB INDICATOR          SA60510 20330021
TWOPATHS EQU   X'0A'                    PATH COMP MASK - 2 PATHS  19022 20340019
FOURPATH EQU   X'0F'                    PATH COMP MASK - 4 PATHS  19022 20400019
         SPACE 3                                                 BBBBBB 20460019
*    THESE ARE THE FLAGS SET IN XCPBTE                                  20520019
XCPCNT   EQU   X'80'                    XCP IN CONTROL FLAG             20580019
XCPERR   EQU   X'20'                    ERROR RTN ENTRANCE              20640019
XCPST    EQU   X'01'                    SHOULDER TAP ENTRANCE      MP1A 20700019
XCPRMS   EQU   X'10'                    RMS PROCESSING FLAG       19021 20760019
XCPRECUR EQU   X'08'                    PROGRAM CHECK RECURSING  A24739 20780019
XCPVALID EQU   X'02'                    VDTY CHK IN PROCESS      A24739 20800019
         SPACE 3                                                 BBBBBB 20820019
*    TCB FLAGS                                                          20880019
TCBPRT   EQU   28                       LOC IN TCB FOR USER PROTECT     20940019
TCBFLG   EQU   30                       TCB MUST COMPLETE FLAG BYTE     21000019
TCBPR    EQU   35                       TCB DISPATCH PRIORITY    BBBBBB 21060019
         AIF   (&TCBTYP LT 2).NOTMVT                             A24739 21120019
TCBFLGS  EQU   32                       TCB DISPATCHABILITY FLAGE       21180019
TCBTCB   EQU   116                      TCB READY Q LINK FIELD          21240019
.NOTMVT  ANOP                                                           21300019
TCBRQENA EQU   X'20'                    RQE NOT AVAL FLAG(TCB)          21360019
PPKEY    EQU   X'F0'                                                    21420019
         SPACE 3                                                 BBBBBB 21480019
*    RMS FLAGS                                                    19021 21540019
RMSACTV  EQU   X'80'                    RMS ACTIVE INDICATOR      19021 21600019
RMSRQEFL EQU   X'40'                    RMS RQE SAVE AREA IN USE  19021 21660019
         AIF   (&OLTEP EQ 0).OLT000                              BBBBBB 21710021
         SPACE 3                                                 BBBBBB 21720019
*    OPTION CODES FOR OLTEP                                       19026 21780019
OLTCHOPT EQU   X'80'                    OLTEP CHANNEL FUNCTION    19026 21840019
OLTDEPST EQU   X'40'                    OLTEP D.E. POSTING        19026 21900019
OLTATPST EQU   X'20'                    OLTEP ATTN POSTING        19026 21960019
OLTBYPFN EQU   X'10'                    BYPASS SK, SFM, TIC CHAIN 19026 22020019
OLTEXP   EQU   X'08'                    SPECIFIC 2305 EXPOSURE    21051 22070021
OLTSIO   EQU   X'02'                    2ND SIO FUNCTION          21051 22072021
         SPACE 2                                                        22080019
*    EXIT OFFSETS TO OLTEP ROUTINE                                19026 22140019
OLTHLT   EQU   8                        FROM HALT I/O ROUTINE     19026 22200019
OLTCHN   EQU   16                       FROM TEST CHANNEL         19026 22260019
OLTZEUS  EQU   20                       FROM 2305 SIO CODE        21051 22320021
.OLT000  SPACE 3                                                 BBBBBB 22370021
*    VECTOR TABLE OFFSETS                                        BBBBBB 22380019
SELTAG   EQU   4                        SELECT TRY AGAIN EXIT           22440019
SELBSY   EQU   8                        SELECT BUSY EXIT                22500019
SELNLCH  EQU   12                       SELECT NXT. LCH RETURN          22560019
         SPACE 3                                                 BBBBBB 22620019
*    PERMANENT STORAGE LOCATION ASSIGNMENTS                      BBBBBB 22980019
CVTADR   EQU   16                       LOCATION OF CVT ADDRESS  BBBBBB 23040019
SVOPSW   EQU   32                       SVC OLD PSW LOC.                23100019
PCKOPSW  EQU   40                       PGM CK OLD PSW                  23150021
IOPSWO   EQU   56                       I/O OLD PSW LOCATION            23160019
CSWLOC   EQU   64                       CSW LOCATION                    23220019
CAWLOC   EQU   72                       CAW LOCATION                    23280019
MCKPSW   EQU   112                      MACHINE CHECK PSW LOC    BBBBBB 23340019
         SPACE 3                                                        23390021
*        ABEND SAVE AREA EQUATES                                        23392021
ABID     EQU   0                    0   ABEND EBCDIC ID                 23394021
ABTCB    EQU   ABID+8               8   ABEND TCB                       23396021
ABCODE   EQU   ABTCB+4              C   ABEND CODE                      23398021
ABIOPSW  EQU   ABCODE+4            10   ABEND I/O OLD PSW               23398421
ABRQEAD  EQU   ABIOPSW+4           14   ABEND RQE ADDRESS               23398821
ABBTE    EQU   ABRQEAD             14   ABEND XCPBTE                    23399221
ABRQE    EQU   ABRQEAD+4           18   ABEND RQE CONTENTS              23399621
ABCSW    EQU   ABRQE+16            28   ABEND CURRENT CSW               23399721
ABPCOPSW EQU   ABCSW+8             30   ABEND PGM CHECK OLD PSW         23399821
ABSVOPSW EQU   ABPCOPSW+8          38   ABEND SVC OLD PSW               23399921
ABREGS   EQU   ABSVOPSW+8          40   ABEND PGM CK REGS               23419921
         AIF   (&TCBTYP GT 1).STMS1X1   IF MVT, SKIP             A24739 23440021
IONPSW   EQU   120                      IO NEW PSW DISAVLE MASK         23460019
.STMS1X1 SPACE 3                                                 BBBBBB 23520019
*    MISCELLANEOUS DEFINITIONS                                   BBBBBB 23580019
         AIF   (&TBASE EQ 1).TBS000                                RL19 23640019
IOSBASE  EQU   IPLPSW                                                   23700019
.TBS000  ANOP                                                      RL19 23760019
ZERO     EQU   0                        ZERO OFFSET                IMP5 23820019
CHPTH    EQU   0                        OFFSET IN MP CHAN AVAIL TBL     23880019
TSKSW    EQU   0                        TASK SWITCH                     23940019
BASADR   EQU   0                        OFFSET FOR BASE UCP PTR   20201 23970020
ONE      EQU   1                        USER COUNT INCREMENT       OSER 24000019
NXTCH    EQU   1                        INCREMENT CHAN ADDR             24060019
TWO      EQU   2                                                 BBBBBB 24120019
FOUR     EQU   4                                                 BBBBBB 24180019
OLDTCB   EQU   4                        OLD TCB ADDRESS                 24240019
CHSNXT   EQU   4                        INC. FOR NEXT CODING IN CH. SH. 24300019
NXTEXP   EQU   4                        OFFSET FOR EXPOSURE UCB CH20201 24310020
FIVE     EQU   5                        OFFSET TO TCB ADDR ENTRY  20001 24330020
TCBADR   EQU   8                        OFFSET IN PARM LIST      BBBBBB 24360019
QCNT     EQU   8                        QUIESCE COUNT OFFSET     BBBBBB 24420019
TEN      EQU   10                       SENSE RETRY COUNT        A50319 24470021
ADTCE    EQU   12                       ADDRESS TRACE ROUTINE      TRCE 24480019
QPLPTR   EQU   12                       LIST PTR IN PURGE PARM    20001 24510020
SIOCNT   EQU   14                       TAPE SIO COUNTER OFFSET  19023  24540019
SIRBRQE  EQU   26                       RQE OFFSET IN SIRB      SA53191 24590021
CVTABT   EQU   52                       OFFSET TO ABTERM ADDRESS BBBBBB 24600019
EXPCHN   EQU   92                       OFFSET FOR CONTROL UCB PTR20201 24630020
TCBID    EQU   112                      ID OFFSET IN THE TCB            24660019
CVTHEAD  EQU   160                      OFFSET TO HIGHEST TCB    A24739 24690019
UPBND    EQU   164                      UPPER BOUND OF CORE        TRCE 24720019
KYWD     EQU   252                      ADDRESS KEYWORD            TRCE 24780019
PLIST    EQU   264                      PARM LIST                  TRCE 24840019
ONLNPTH  EQU   X'80'                    PATH IS AVAILABLE       SA60510 24850021
SHRDMPX  EQU   X'80'                    LOW UNIT ON SHARED MPX   A47317 24890021
DUMADR   EQU   X'01'                    DUMMY ADDRESS                   24900019
SYSCON   EQU   X'02'                    SYSRES OR CONSOLE DEV           24960019
LSTOPT   EQU   X'08'                    LIST OPTION FOR PURGE     20001 24990020
BLKMPX   EQU   X'10'                    BLOCK MPX CHN INDICATOR   19025 25020019
NOTPMF   EQU   X'20'                    ALL CODES EXCEPT PERM ERROR     25080019
CHRCF    EQU   X'70'                    RECONFIGURED BITS               25140019
CHBSY    EQU   X'80'                    SELECTOR CHAN BUSY BIT          25200019
QPLFLST  EQU   X'80'                    LAST ENTRY INDICATOR      20001 25230020
PATHINOP EQU   X'0F'                    INOPERATIVE PATH MASK           25260019
OF       EQU   X'0F'                                                    25320019
EXTMSK   EQU   X'FE'                    EXTENT MASK                     25380019
RSTMSK   EQU   X'FE'                    CHANNEL MASK FOR RESTRT  A24739 25410019
FF       EQU   X'FF'                                                    25440019
         AIF   (&TSO EQ 0).TSO001                               SA71480 25490018
SVC92    EQU   X'5C'                    TSO TCB EXCP SVC CODE   SA71480 25492018
.TSO001  ANOP                                                   SA71480 25494018
MAXENQ   EQU   X'03'                    MAXIMUM USER COUNT         OSER 25500019
ORCNTR   EQU   X'07'                                               OSER 25560019
         IHLMHOOK                                                       25612021
INVECB   EQU   X'20'                    ABEND CODE FOR INVALID ECB21016 25616021
INVDEB   EQU   X'30'                    ABEND CODE FOR INVALID DEB21016 25618021
INVDCB   EQU   X'40'                    ABEND CODE FOR INVALID DCB21016 25618421
INVUCB   EQU   X'50'                    ABEND CODE FOR INVALID UCB21016 25618821
INVLCH   EQU   X'60'                    ABEND CODE FOR INVALID LCH      25619221
         TITLE 'MAJOR ROUTINE ENTRY POINTS - INPUT/OUTPUT SUPERVISOR'   25620021
*********************************************************************** 25680019
*                                                                     * 25740019
*             ENTRY LABELS TO MAJOR SUBROUTINES AND MODULES           * 25800019
*                                                                     * 25860019
*        TITLE                              LABEL          MACRO      * 25920019
         SPACE 1                                                        25980019
*        EXCP SUPERVISOR                    XEXCP          IECXCP     * 26040019
*        EXCP VALIDITY CHECK SUBROUTINE     XVCK01         IECXCP     * 26100019
*        GET REQUEST ELEMENT SUBROUTINE     XCPTST         IECXCP     * 26160019
*        TAPE SIO MODULE                    XIOTPE         IECXCP     * 26220019
*        DIRECT ACCESS SIO MODULE           XIODSK         IECXCP     * 26280019
*        UNIT RECORD AND TP SIO MODULE      XIOUR          IECXCP     * 26340019
*        SIO SUBROUTINE                     XCPSIO         IECXCP     * 26400019
*        POST SIO SUBROUTINE                XCPPIO         IECXCP     * 26460019
*        DEQUEUE MODULE                     XCPPDQ         IECXCP     * 26580019
*        I/O INTERRUPT SUPERVISOR           IECINT         IECINT     * 26760019
*        CHANNEL RESTART SUBROUTINE         INT033         IECINT     * 26820019
*        QUIESCE COMPLETE INTERFACE         PRGCOMA        IECINT     * 26880019
*        TASK SWITCH ON LAST RQE            INTVMSA        IECINT     * 26940019
*        ATTENTION ROUTINE INTERFACE        INTATT         IECINT     * 27000019
*        DAVV ATTENTION ROUTINE             INTATN         IECINT     * 27030020
*        UNIT RECORD TRAP MODULE            INTURT         IECINT     * 27060019
*        TAPE TRAP MODULE                   INTTAT         IECINT     * 27120019
*        DIRECT ACCESS TRAP MODULE          INTDAT         IECINT     * 27180019
*        TELEPROCESSING TRAP MODULE         XCPTPT         IECINT     * 27240019
*        SENSE SUBROUTINE                   INTSEN         IECINT     * 27300019
*        INTERRUPT ERROR INTERFACE          INTERR         IECINT     * 27420019
*        SHOULDER TAP INTERFACE             IECISHTP       IECINT     * 27480019
*        POST ROUTINE INTERFACE             XCPPST         IECIOS     * 27540019
*        VALIDITY CHECK SUBROUTINE          VALCHK         IECIOS     * 27600019
*        COMMON TEST CHANNEL MODULE         XCPTCH         IECXTCH    * 27630018
*        CHANNEL SEARCH - CONFIG DEP        INTCS-         IECICS     * 27720018
*        PROGRAM CHECK RECOVERY SUBROUTINE  IECCPL00       IECIOSB    * 27810018
*        ABTERM INTERFACE                   XERX04         IECIOSB    * 27900018
*        TSO TCB EXCP INTERFACE             IECXPT         IECIOSB    * 27990018
*        SERR INTERFACE                     SERR           IECIOSB    * 28080018
*        FIFO ENQUEUE MODULE                XCPENQ         IECIOSB    * 28201020
*        ORDERED SEEK ENQUEUE MODULE        XCPSEQ         IECIOSB    * 28202020
*        PRIORITY ENQUEUE MODULE            XCPPRQ         IECIOSB    * 28203020
*        RMS CHANNEL RESTART INTERFACE      INTRMS         IECIOSB    * 28204020
*        RMS MODULE LOADER INTERFACE        IECRMS         IECIOSB    * 28205020
*        DDR APPENDAGE SUPPORT INTERFACE    DDRAPNVT       IECIOSB    * 28206020
*        APR CEB DEACTIVATE SUBROUTINE      INTDEACT       IECIOSB    * 28210020
*        ALTERNATE PATH RETRY SUBROUTINE    INTAPR01       IECIOSB    * 28220020
*        COMMON HIO SUBROUTINE              IECIHIO        IECIOSB    * 28230020
*        M65MP VARY COMMAND INTERFACE       IECTIOMP       IECIOSB    * 28240020
*        EXCP ERROR INTERFACE               IECXCPER       IECIOSB    * 28250018
*                                                                     * 28260019
*********************************************************************** 28320019
         TITLE 'IOS PROBLEM DETERMINATION AREA LAYOUT'                  28370018
         AIF (&TCBTYP EQ 2).MVTPDA                                      28370418
*  TWO IOS PROBLEM DETERMINATION AREAS ARE PROVIDED IN IOS              28370818
*  AT LABELS ABSV1 AND ABSV2.  THESE ARE ROTATED AND USED               28371218
*  AS NEEDED.  THE PROBLEM DETERMINATION AREAS SAVE MUCH                28371618
*  INFORMATION IN A SYSABEND DUMP WHICH OTHERWISE MAY BE                28371718
*  IMPOSSIBLE TO OBTAIN.                                                28371818
         AGO   .PDA                                                     28371918
.MVTPDA  ANOP                                                           28372518
*  PROBLEM DETERMINATION AREAS ARE OBTAINED AS NEEDED FROM              28372618
*  SUBPOOL 253 IN SQS.  TO LOCATE THE AREA IN A SYSABEND DUMP,          28372718
*  LOCATE THE SQS POINTER AT TCB+X'9C'.  FOLLOW THE CHAIN TO            28372818
*  A BLOCK BEGINNING WITH THE CHARACTERS 'IOSABEND'.                    28373118
*  THE PROBLEM DETERMINATION AREA SAVES MUCH INFORMATION IN             28373518
*  A SYSABEND DUMP WHICH MAY OTHERWISE BE IMPOSSIBLE TO                 28373618
*  OBTAIN.                                                              28373718
.PDA     ANOP                                                           28373818
         SPACE 2                                                        28373918
************************************************                        28374018
*                                              *                        28374418
*        PROBLEM DETERMINATION AREA            *                US06042 28376018
*                                              *                        28378018
************************************************                        28378118
*00*     I  O  S  A  B  E  N  D                *                        28378218
************************************************                        28378418
*08*         TCB ADDRESS                       *                        28378818
************************************************                        28379218
*0C*       ABEND COMPLETION CODE               *                        28379618
************************************************                        28379818
*10*     FIRST HALF OF THE I/O OLD PSW         *                        28382018
************************************************                        28387918
*14*  XCPBTE  *          *   RQE ADDRESS       *                        28391918
************************************************                        28395918
*18*     RQE CONTENTS   (4 WORDS)              *                        28399918
************************************************                        28409918
*28*     CURRENT CSW    (2 WORDS)              *                        28419918
************************************************                        28426618
*30*    PGM CK OLD PSW  (2 WORDS)              *                        28428618
************************************************                        28430618
*38*     SVC OLD PSW    (2 WORDS)              *                        28431018
************************************************                        28433018
*40*     PGM CHECK REGS OR CURRENT REGS        *                        28476118
************************************************                        28476518
         SPACE 1                                                        28477418
*                         XCPBTE                                        28477518
* 00  INTERRUPT ENTRY TO IOS         * 02  VALIDITY CHECK IN PROC       28477618
* 80  EXCP ENTRY TO IOS              * 10  RMS IN CONTROL               28483218
* A0  ERROR EXCP ENTRY TO IOS        * 08  PGM CHECK IOS                28485218
         SPACE 1                                                        28487618
*                       ABEND CODES                                     28488018
* 200  INV ECB             * 0F1  PGM CHK IN INT HANDLER                28488518
* 300  INV DEB             * 0F2  PGM CHK IN IOS--SVC ENTRY             28488618
* 400  INV DCB             * 10F  INVALID RQE PASSED TO ERR EXCP        28488718
* 500  INV UCB             * F5C  INVALID USE OF SVC 92                 28502918
* 600  INV LCH                                                          28512918
         TITLE 'EXCP HANDLER - INTPUT/OUTPUT SUPERVISOR'                28517418
**********************************************************************  28531618
*                                                                    *  28545818
*                        EXCP SUPERVISOR                                28560019
         SPACE 2                                                        28620019
*              THE EXCP SUPERVISOR IS THAT PART OF THE INPUT OUTPUT     28680019
*              SUPERVISOR WHICH HANDLES THE EXCP MACRO INSTRUCTION.     28740019
*              THE FOLLOWING IS THE GENERAL FLOW THROUGH THIS ROUTINE.  28800019
         SPACE                                                          28860019
*                   1. THE ADDRESSES OF THE SYSTEM CONTROL BLOCKS FOR   28920019
*                      THIS REQUEST ARE DETERMINED.                     28980019
*                   2. THESE BLOCKS ARE CHECKED FOR VALIDITY. IF THEY   29040019
*                      ARE INVALID,THE TASK ISSUING THE I/O REQUEST     29100019
*                      IS ABNORMALLY TERMINATED.                        29160019
*                   3. A REQUEST ELEMENT IS OBTAINED AND THE ADDRESSES  29220019
*                      OF THE UCB, IOB AND DEB ARE PLACED INTO IT ALONG 29280019
*                      WITH TASK AND PRIORITY DATA.                     29340019
*                   4. A TEST IS MADE TO SEE IF THE DEVICE IS AVAILABLE 29400019
*                      IF NOT THE REQUEST IS ENQUEUED FOR FUTURE RE-    29460019
*                      START.                                           29520019
*                   5. A TEST IS MADE TO SEE IF THE CHANNEL IS AVAIL-   29580019
*                      ABLE. IF NOT, THE REQUEST IS ENQUEUED.           29640019
*                   6. THE APPROPRIATE SIO MODULE IS ENTERED AND DEVICE 29700019
*                      DEPENDANT SIO PROCEDURES ARE INITIATED.          29760019
*                   7. WHEN THE DEVICE IS STARTED, THE REQUEST ELEMENT  29820019
*                      IS HUNG ON THE UCB FOR THAT DEVICE.              29880019
*                   8. ANY ERROR CONDITIONS ASSOCIATED WITH THE SIO     29940019
*                      ARE ANALYZED AND APPROPRIATE ACTION TAKEN.       30000019
*                   9. RETURN IS MADE TO THE SUPERVISOR.                30060019
*                                                                    *  30120019
*********************************************************************** 30180019
        SPACE 2                                                         30240019
IGC000   DS    0D                       START ON DOUBLE WORD BOUNDRY    30300019
         AIF   (&TBASE EQ 0).TBS005                                TBSE 30360019
         USING IOSBAS,BASREG            SPECIFY                    RL19 30420019
         USING IOSBAS+4094,BASREG2      BASE REGISTERS             RL19 30480019
XEXCP    BALR  BASREG,0            SET LOW BASE REGISTER           TBSE 30540019
IOSBAS   LA    BASREG2,4094(BASREG)     SET HIGH BASE REG          RL19 30600019
IOSBASE  EQU   IOSBAS                   EQUATE FOR AL2'S           RL19 30660019
         AGO   .TBS006                                           BBBBBB 30720019
.TBS005  USING *,0,BASREG                                          TBSE 30780019
XEXCP    LA    BASREG,2048              INITIALIZE BASE REG             30840019
         AR    BASREG,BASREG            SET BASE EQUAL TO 4096          30900019
.TBS006  ST    TCBREG,CURRTCB           SAVE CURRENT TCB ADDR   SA53199 31010021
XBASE    LR    IOBREG,1                 TRANSFER FROM PASSING REGISTER  31020019
         TITLE 'EXCP VALIDITY CHECK - INTPUT/OUTPUT SUPERVISOR'         31080021
*********************************************************************** 31140019
*                                                                    *  31200019
*                        EXCP VALIDITY CHECK                            31260019
         SPACE 2                                                        31320019
*              THIS ROUTINE CHECKS THE VALIDITY OF THE VARIOUS CONTROL  31380019
*              BLOCKS USED BY THE I/O SUPERVISOR.  THESE BLOCKS ARE     31440019
*              THE IOB, DCB, DEB, AND UCB.  IMPROPER BOUNDRIES WILL   * 31500019
*              RESULT IN A PROGRAM CHECK IN IOS WHEN TRYING TO LOAD   * 31560019
*              REGISTERS.  THE BLOCK ID IS CHECKED ON THE DEB AND UCB * 31620019
*              THE BACKLINK FROM THE DEB TO THE DCB IS CHECKED. IF ANY  31680019
*              OF THESE CHECKS FAIL ABNORMAL TERMINATION PROCEDURES     31740019
*              ARE INITIATED.  THE REQUEST ELEMENT REGISTER IS ZEROED,  31800019
*              HOWEVER, IN CASE A PROGRAM CHECK WOULD OCCUR IN WHICH    31860019
*              CASE THE PC INTERRUPT HANDLER WILL CORRECTLY BE ABLE TO  31920019
*              ASSOCIATE THE INTERRUPT WITH THE PROPER TASK.            31980019
*                                                                    *  32040019
* ENTRY POINTS                                                        * 32100019
*              XVCK01   REGISTER INITIALIZATION FROM ERREXCP INTERFACE* 32160019
*                                                                     * 32220019
* EXITS                                                               * 32280019
*              XERX04  INVALID CONTROL BLOCK, EXIT TO ABTERM.         * 32340019
*                                                                     * 32400019
*********************************************************************** 32460019
        SPACE 2                                                         32520019
         MVI   XCPBTE,XCPCNT+XCPVALID   CLEAR FLAGS, SET EXCP    A24739 32580019
         LA    LNKRG3,XCP060            LOAD ADDR OF CTL BLK INITA51000 32700021
         SR    TSTREG,TSTREG            CLEAR FOR POSSIBLE PGM CHECK    32760021
         STH   TSTREG,LTSVALSV          NO VALID RQE YET         A24739 32820019
         SPACE 1                                                 A24739 32850021
**********************************************************************  32880019
*              ENTRANCE IS MADE HERE FROM THE ERREXCP ENTRANCE          32940019
*              SO THAT REGISTERS CAN BE SET UP.                         33000019
         SPACE 1                                                        33060019
*  THIS PICKS UP THE CURRENT TCB ADDR. IN CASE OF ABTERM. ON EXCP       33120019
         SPACE 1                                                        33180019
XVCK01   LR    REG0,4                  GET TCB ADDRESS             IMP4 33240019
         L     DCBREG,IOBDCB-1(IOBREG)  GET DCB POINTER                 33300019
         L     DEBREG,DCBDEB-1(DCBREG)  GET DEB POINTER                 33360019
         CLC   IOBDCB(3,IOBREG),DEBDCB(DEBREG) TEST FOR VALID DCB       33420019
         L     APBSRG,IECPL2            GET TEMP BASE REG      @SA77644 33450018
         BC    7,XERX02C-IECCPL02(APBSRG) ERROR,INVALID DCB    @SA77644 33510018
         TM    XCPBTE,XCPERR            ENTRY FROM SVC 15      @SA77622 33520018
         BC    8,XVCK02                 NO, NO RQE YET         @SA77622 33530018
         CLC   TSTDEB(3,TSTREG),DCBDEB(DCBREG) RQEDEB = DCBDEB @SA77622 33540018
         BC    7,XERX02C-IECCPL02(APBSRG) ERROR,INVALID DCB    @SA77622 33550018
XVCK02   EQU   *                                               @SA77622 33560018
         AIF   (&PROTECT EQ 0).NVALCK                            A24739 33570019
         TM    SVOPSW+1,PPKEY           IS PROTECT KEY ZERO             33600019
         BC    8,XCP061                 YES-BYPASS NEXT TEST            33660019
         AIF   (&TCBTYP EQ 2).SXIOS1A   MVT, SKIP                A24739 33760021
         MVZ   IDBYTE(1),DEBPRT(DEBREG) SEPARATE PROTECT KEY     BBBBBB 33780019
*    IF THIS IS NOT A SUPERVISOR REQUEST, INSURE THAT THE DEB      IMP5 33840019
*    PROTECTION KEY CORRESPONDS TO THE CURRENT TASK'S KEY.         IMP5 33900019
         LR    WKREG1,REG0             TRANSFER TCB ADDRESS        IMP4 33960019
         CLC   IDBYTE(1),TCBPRT(WKREG1) COMPARE WITH TAG IN TCB         34020019
         BC    7,XERX02D-IECCPL02(APBSRG) ERROR,INVALID DEB    @SA77644 34080018
.SXIOS1A ANOP                                                   SA68418 34140021
         BAL   LNKRG2,VALCHK            BRANCH TO VALIDITY CHECK A24739 34150019
.NVALCK  ANOP                                                      VDTY 34320019
XCP061   SR    ICREG,ICREG              CLEAR INSERT CHAR  REG.         34380019
         LR    WKREG1,ICREG             PREPARE SHIFT REG.              34440019
         TM    DEBENT(DEBREG),EXTMSK    TEST FOR ANY EXTENTS            34500019
         BC    7,XCP061B                YES-USE M GT 1 DIRECTLY         34560019
         LH    UCBREG,DEBUCB+1(DEBREG)  GET 1ST EXTENT                  34620019
         TM    UCBTYP+2(UCBREG),DSKTYP+TPTYPE+GRTYPE                    34680019
         BC    8,XCP061C                NO-DOESN'T HAVE AN M            34740019
XCP061B  IC    ICREG,DEBENT(DEBREG) .   GET NBR OF EXTENTS--DEB  A43938 34800021
         IC    WKREG1,IOBDAM(IOBREG)    GET EXTENT INDEX                34860019
         CR    WKREG1,ICREG .           IOB EXTENT TO USE + DEB  A43938 34870021
         BL    XCP061A .                DO NOT TEST FOR BAD M   SA61714 34880021
         LTR   WKREG1,WKREG1 .          IS DEB COUNT ZERO        SM5480 34882021
         L     APBSRG,IECPL2            GET TEMP BASE REG      @SA77644 34884018
         BC    7,XERX02D-IECCPL02(APBSRG) NO, INVALID DEB      @SA77644 34887018
XCP061A  IC    ICREG,DEBEXT(DEBREG) .   GET EXTENT SIZE          A43938 34890021
         SLL   WKREG1,0(ICREG)          MULTIPLY BY SIZE                34920019
         LH    UCBREG,DEBUCB+1(WKREG1,DEBREG)    GET UCB ADR       IMP2 34980019
XCP061C  DS    0C                                                       35040019
         TM    UCBID(UCBREG),UCBIDV     TEST UCB ID VALUE               35100019
         L     APBSRG,IECPL2            GET TEMP BASE REG      @SA77644 35160018
         BC    14,XERX02B-IECCPL02(APBSRG) ERROR,INVALID UCB   @SA77644 35560018
XCP061D  L     WKREG2,IOBECB-1(IOBREG) GET ECB POINTER             SMF2 36000019
         SPACE 1                                                  M4757 36060019
*********************************************************************** 36120019
*              NOW LOCATE THE LOGICAL CHANNEL WORD                      36180019
         SPACE                                                          36240019
XCP064   SR    WKREG1,WKREG1            PREPARE WORK REGISTER           36300019
         IC    WKREG1,UCBLCI(UCBREG)    GET LCH INDEX FROM UCB          36360019
         SLL   WKREG1,3                 MULTIPLY BY 8                   36420019
         LA    LCHREG,LCHTAB(WKREG1)    GET LCH ADDR. FROM IOS TABLE    36480019
         BCR   15,LNKRG3                BRANCH TO NEXT IN LINE OR EXIT  36540019
*********************************************************************** 36600019
         SPACE 1                                                        36660019
*              ZERO AND INITIALIZE CONTROL BLOCK AREAS                  36720019
XCP060   STH   TSTREG,IOBECT(IOBREG)    CLEAR ERROR COUNTER             36780019
        SPACE 1                                                         36840019
*   THE FOLLOWING IS AN INTIAL CLEAR OF IOB FLAGS AND CSW AREA          36900019
         XC    IOBFL3(9,IOBREG),IOBFL3(IOBREG)                          36960019
         NC    IOBFL1(4,IOBREG),CLEARM  CLEAR ALL FLAGS AND SENSE       37020019
        SPACE 1                                                         37080019
*   CLEAR IOB CODE BYTE AND SET COMPLETE FLAG FOR POST TRANSFER         37140019
         MVI   IOBCOD(IOBREG),NORMC     SET NORMAL COMPLETE FLAG        37200019
         ST    TSTREG,ECBFL(WKREG2)     RESET ECB FIELD                 37260019
         NI    XCPBTE,FF-XCPVALID       ALL BLOCKS ARE VALID      M4757 37320019
         IECLNK1 XCP020A,BAL,LNKRG1,XCPTST,,,XCP022,&TBASE         TBSE 39420019
**********************************************************************  39480019
*                                                                     * 39540019
*        EXCP SELECT ROUTINE RETURN VECTOR TABLE                        39600019
XCP022   BC    15,XCP021                ACCEPT VECTOR-EXIT              39660019
         BC    15,XCP030                TRY AGAIN VECTOR RE-INIT.       39720019
         BC    0,0                      BUSY VECTOR -ENQUE              39780019
*****    BC    15,XCP020                NEXT LCH VECTOR, ENQUE     IMP5 39840019
*                                                                     * 39900019
**********************************************************************  39960019
XCP020   L     APBSRG,ENQAD             ADDR OF XCPPNQ RTN       BBBBBB 40000020
         BALR  LNKRG2,APBSRG            TO ENQUEUE RQE           BBBBBB 40040020
*        PREPARE TO EXIT FROM EXCP PORTION OF IOS                       40080019
XCP021   LR    1,IOBREG            RESTORE IOB ADDRESS             IMP2 40140019
XCP021A  L     LNKRG2,SVCXAD            TYPE 1 EXIT ADDRESS             40200021
         BCR   15,LNKRG2                TO TYPE 1 EXIT                  40260019
         SPACE 1                                                        40320019
         IECLNK1 XCP030,LA,LNKRG1,XCP022,,,,&TBASE                      40380019
         BAL   LNKRG3,XCP064            GO SET UP LCHREG           IMP4 40440019
         BC    15,XCP011                GO TO TEST CHANNEL         IMP4 40500019
         TITLE 'GET REQUEST QUEUE ELEMENT - INPUT OUTPUT SUPERVISOR'    40560021
**********************************************************************  40620019
*                                                                    *  40680019
*                        GET REQUEST ELEMENT ROUTINE                    40740019
         SPACE 1                                                        40800019
*              THIS ROUTINE OBTAINS A REQUEST ELEMENT FROM A LIST OF    40860019
*              AVAILABLE ELEMENTS. IF NONE, IT ENTERS THE PSEUDO DIS-   40920019
*              ABLE FUNCTION AND "WAITS" FOR ONE. THE UCB, IOB AND      40980019
*              DEB ADDRESSES ARE PLACED IN THE RQE ALONG WITH THE    *  41040019
*              DISPATCHING PRIORITY AND THE TCB ID BYTE              *  41100019
*                                                                     * 41160019
* ENTRY POINTS                                                        * 41220019
*              XCPTST  NORMAL IN LINE ENTRY, FROM EXCP VALIDITY CHECK * 41280019
*                                                                     * 41340019
* EXITS                                                               * 41400019
*              XCP072  TO CHECK ID OF USER REQUESTING LAST RQE.       * 41460019
*                                                                     * 41520019
*                                                                    *  41580019
**********************************************************************  41640019
        SPACE 1                                                         41700019
XCPTST   DS    0H                                                       41760019
         AIF   (&APR EQ 0).APR030                                       41820019
         SPACE 1                                                        41880019
*    GO DEACTIVATE ANY INACTIVE CHANNEL ERROR BLOCKS IF THE ACTIVE      41940019
*    CEB SWITCH IS SET.                                                 42000019
         L     LNKRG3,CEBCTR            ADDR OF CEBTAB           BBBBBB 42030020
         L     APBSRG,ADEACT            ADDR OF APR DEACTIVATE RTN BBBB 42040020
         TM    0(LNKRG3),CEBACT         TEST FOR CEBACT SWITCH   BBBBBB 42060020
         BCR   7,APBSRG                 YES, GO DEACTIVATE       BBBBBB 42120020
XCPTST1  DS    0H                                                       42180019
.APR030  LH    TSTREG,NEXAVL            GET ADDR OF NEXT RQE            42240021
         LTR   TSTREG,TSTREG            TEST FOR DUMMY                  42300019
         BC    4,XCP070                 TO PSUEDO DISSABLE              42360019
         SPACE 1                                                        42370021
*        RESERVE THE LAST TWO RQES FOR SYSTEM TASK REQUESTS             42410021
         SPACE 1                                                        42412021
         TM    TSTLNK+1(TSTREG),DUMADR  TEST FOR LAST RQE               42420019
         BC    1,XCP072                 YES- CHECK USER                 42480019
         LH    WKREG1,TSTLNK(TSTREG)    GET NEXT RQE ADDR               42482021
         TM    TSTLNK+1(WKREG1),DUMADR  TEST FOR LAST RQE               42490021
         BC    1,XCP072                 YES- CHECK USER                 42500021
         SPACE 1                                                        42510021
XCPTST2  LR    WKREG1,REG0              GET TCB ADDR IN WORK REG A51000 42530021
         STH   UCBREG,TSTUCB(TSTREG)    STORE UCB ADDR. IN RQE   A51000 42540021
         STM   IOBREG,DEBREG,TSTIOB-1(TSTREG)  ST. IOB AND DEB ADDR.    42600019
*   THIS GETS AN ID FROM THE TCB REQUESTING IO ACTION                   42660019
         AIF   (&TCBTYP LT 2).TSTMFT    NOT MVT, SKIP            A51000 42720021
         ST    WKREG1,TSTTCB(TSTREG)    STORE TCB ADDR IN RQE    A51000 42780021
         MVI   TSTASSN(TSTREG),ZERO     MARK AS ASSIGNED         BBBBBB 42840019
*        STORE SVC OLD PSW PROTECT KEYIN RQE FOR VALIDITY CHECK AT INT  42900019
         AIF   (&TSO EQ 0).TSO002                               SA71480 42950018
         CLI   SVOPSW+3,SVC92           TSO TCB EXCP ENTRY     @SA76667 42952018
         BE    XCPTST2C                 YES, KEY OK ALREADY    @SA77080 42954018
.TSO002  MVZ   TSTKEY(1,TSTREG),SVOPSW+1 MOVE KEY OF REQUESTOR TO RQE   42960018
         AGO   .TSTMVT                                           A51000 43020021
.TSTMFT  MVC   TSTTCB(1,TSTREG),TCBID(WKREG1)  MOVE ID INTO RQE  A51000 43140021
.TSTMVT  ANOP                                                   SA71480 43190018
XCPTST2C MVC   NEXAVL(2),TSTLNK(TSTREG) UPDATE RQE LIST          A51000 43200018
         STH   TSTREG,LTSVALSV          NOW A VALID RQE          A24739 43260019
         AIF   (&RPR EQ 0).TSTRPR                                A51000 43290021
         MVC   TSTPR(1,TSTREG),TCBPR(WKREG1) SET TEMP. PRIORITY  A51000 43440021
.TSTRPR  AIF   (&SMF EQ 0).TSTSMF       IS SMF IN SYSTEM         A51000 43490021
         L     APBSRG,SMFRTN            GET ADDR OF SMF ROUTINE  A51000 43494021
         BALR  LNKRG2,APBSRG            REPORT EXCP TO SMF       A51000 43496021
         SPACE 1                                                 A51000 43498021
*    DEFINITION OF SMF - IOS INTERFACE                           A51000 43498421
*    INPUT   REG0(TCB ADDR),DCBREG,UCBREG,LNKRG2(RET ADDR),      A51000 43498821
*            APBSRG(BASE ADDR)                                   A51000 43499221
*    REGS CHANGED - WKREG1,WKREG2,WKREG3,LCHREG                  A51000 43499621
         SPACE 1                                                 A51000 43499721
         BAL   LNKRG3,XCP064            RESTORE LCHREG           A51000 43499821
.TSTSMF  BAL   LNKRG2,INT034G           INSPECT FURTHER          A51000 43500021
XCP010A  TM    UCBFL1(UCBREG),FF-UCBITF TEST ALL BUT INTERCEPT   BBBBBB 43560021
* THIS TESTS ALL THE OTHER FLAGS - UBCCUB, BSY, NRY, ASK, PST, ERR IMP3 43620019
         IECLNK1 ,BC,7,SELBSY,0,LNKRG1,,&TBASE                     TBSE 43680019
         AIF   (&M7CH EQ 0).M7CH000                                MSVN 43740019
         NC    CHMSK(2),CHMSK           PREVIOUS RSTRT INCOMPLETE  MSVN 43800019
         AGO   .M7CH001                                            MSVN 43860019
.M7CH000 TM    CHMSK,FF                 IS RESTART INCOMPLETE      RL19 43920019
.M7CH001 BC    4+1,INTER7D              YES, START FROM CH RESTRT  RL19 43980019
XCP011   TM    UCBFL1(UCBREG),UCBITF    PREV REQ HAVE INTCPT COND  P340 44040019
         BC    1,INTERR5                GO TO ERP INTERFACE        IMP5 44100019
         LH    WKREG1,LCHTCH(LCHREG)    GET TCH CODE ADDRESS       P340 44160019
         AIF   (&TBASE EQ 0).TBS045                                IMP3 44220019
         N     WKREG1,HWMSK             CLEAR PROPAGATED BITS    BBBBBB 44280019
.TBS045  BCR   15,WKREG1               GO TO TEST CHANNEL CODE     IMP3 44340019
         SPACE 1                                                        44400019
*              TEST CHANNEL CODE WILL LINK TO EITHER ENQUE OR SELECT RT 44460019
         SPACE 1                                                        44520019
*   CHECKS WHEN LAST RQE IS ABOUT TO BE GIVEN AWAY                      44580019
         AIF   (&TCBTYP EQ 2 OR &MFTATT EQ 1).CHKTCB             A48653 44630021
XCP072   CLC   IOBDCB(3,IOBREG),SVCDCB+1   CHECK FOR SVC LIB            44640019
         BC    8,XCPTST2                YES-LET THRU                    44700019
         AGO   .NOERR1                                           A48653 44750021
.CHKTCB  ANOP                                                    A48653 44752021
XCP072   CLC   CURRTCB+1(3),MASTCB+1    IS THIS A SYSTEM TASK   SA53199 44754021
         BC    4,XCPTST2                YES, GIVE AWAY LAST RQE  A48653 44756021
.NOERR1  ANOP                                                    A48653 44758021
*   SIMULATE PSUEDO DISABLE FUNCTION                                    44760019
XCP070   L     WKREG1,SVOPSW+4          PICK UP IC                      44820019
         IC    ICREG,SVOPSW+4           PICK UP ILC              A49380 44870021
         SRL   ICREG,6                  ISOLATE ILC              A49380 44920021
         SLL   ICREG,1                  MULTIPLY ILC BY 2        A49380 44930021
         SR    WKREG1,ICREG             GET PROPER RESUME ADDR   A49380 44932021
         ST    WKREG1,SVOPSW+4         STORE ADJUSTED                   44940019
         AIF   (&TCBTYP GT 1).MS1A      IF MVT, SKIP             A24739 45000019
         L     WKREG1,XCPSDA           GET SUPR ADDRESS                 45060019
         IC    ICREG,0(0,WKREG1)        OLD PSUEDO SWITCH               45120019
         MVI   0(WKREG1),X'F0'          SET FOR IOS RETURN              45180019
         SSM   XCPENB                   ENABLE                          45240019
         SSM   IONPSW                   DISABLE                         45300019
         STC   ICREG,0(0,WKREG1)        RESTORE OLD SWITCH              45360019
         BC    15,XCP021                TO TYPE 1 EXIT                  45420019
         AGO   .STMS1XA                                                 45480019
.MS1A    L     WKREG2,CURRTCB           TCB ADDRESS TO WKREG2   SA53199 45540021
         OI    TCBFLGS(WKREG2),TCBRQENA SET RQE NON DISPATCHABILITY BIT 45600019
         MVI   INT025B+1,X'F0'          SET RQE RERTRN SWITCH           45660019
         SR    ICREG,ICREG              CLEAR ICREG                     45720019
         AIF   (&M65MP EQ 1).MPB012                                MP1A 45780019
         L     WKREG1,AIEATCBP         PICK UP ADDRESS OF NEW           45840019
         AGO   .MPB013                                             MP1A 45900019
.MPB012  LA    WKREG1,IEATCBP          PICK UP TCB ADDRESS         MP1A 45960019
.MPB013  ST    ICREG,ZERO(0,WKREG1)     INDICATE TASK SWITCH            46020019
         AIF   (&M65MP EQ 0).MPB014                                MP1A 46080019
         L     WKREG2,PREFIX2            GET OTHER 4K ADDRESS      MP1A 46140019
         ST    ICREG,TSKSW(WKREG2,WKREG1) ADJUST OTHER CPU S NEW   MP1A 46200019
.MPB014  BC    15,XCP021                TO TYPE 1 EXIT                  46260019
.STMS1XA AIF   (&TAPE EQ 0).STIOS4      TEST FOR TAPE              RL19 46320019
         TITLE 'TAPE UNIT SIO ROUTINE - INPUT/OUTPUT SUPERVISOR'        46380021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46440019
*                                                                     * 46500019
*                      SIO MODULE FOR TAPE UNITS                      * 46560019
*                                                                     * 46620019
*  FUNCTION    SET UP THE TIC ADDRESS TO THE USER CCW CHAIN AND SET   * 46680019
*              MODE COMMAND FOR CRC RECOVERY BEFORE GOING TO THE SIO  * 46740019
*              SUBROUTINE                                             * 46800019
*                                                                     * 46860019
*     ENTRY    XIOTPE  FROM THE SELECT ROUTINE WHICH GETS THIS ADDRESS* 46920019
*                      FROM THE DEVICE TABLE FOR TAPE                 * 46980019
         AIF   (&ASPN EQ 0).ASPN1                                       47030021
*              XIOTPEA ENTRY POINT FOR 3400 TAPES                     * 47032021
*                      ADDRESS OF ENTRY POINT FROM DEVICE TABLE       * 47034021
.ASPN1   ANOP                                                           47036021
*                                                                     * 47040019
*     EXITS    XCP130  TO SIO SUBROUTINE FOR UNIT POSITIONING         * 47100019
*              XCPSIO  TO SIO SUBROUTINE                              * 47160019
*              XCP111B TO SIO SUBROUTINE FOR MODE SET-RETURN    SA54451 47220021
         AIF   (&ASPN EQ 0).ASPN2                                       47270021
*              INT022  TO IOS ERROR INTERFACE TO SCHEDULE ERP         * 47272021
.ASPN2   ANOP                                                           47274021
*                                                                     * 47280019
* OPERATION    CHECK IF UNIT POSITIONING IS NEEDED, IOB MODIFIER 1 FLAG 47340019
*              ON, YES EXIT TO XCP130 IN SIO SUBROUTINE               * 47400019
*              SET UP AND EXECUTE MODE SET.  BAD, GO TO POST.         * 47460019
*              NOP THE COMMAND AND MOVE THE IOB START ADDR. TO TIC CMD. 47520019
*              CHECK IF RESTART, YES REPLACE START ADDRESS IN TIC CMD * 47580019
*              WITH IOB RESTART ADDRESS                               * 47640019
*              CHECK FOR CRC CORRECTION, IOB MODIFIER 2 FLAG, YES       47700019
*              LOAD CRC CCW ADDRESS INTO WKREG1 AND MOVE UCB SENSE      47760019
*              BYTE 3 INTO THE CRC CCW.  IF NO CRC CORRECTION           47820019
*              LOAD ADDR OF TAPE INITIALZATION CCW INTO WKREG1 (NOP   * 47880019
*              OR CRC) AND BRANCH TO SIO SUBROUTINE                   * 47940019
*                                                                     * 48000019
         AIF   (&ASPN EQ 0).ASPN3                                       48050021
*              FOR 3400 TAPES - IF AN UNSOLICITED DEVICE END INTERRUPT* 48052021
*              IS RECEIVED AND THE USER IS USING IOS ERP'S, THE SIO   * 48054021
*              REQUEST WILL BE DEQUEUED AND THE ERP WILL BE SCHEDULED,* 48056021
*              OTHERWISE THE SIO WILL BE ISSUED.                      * 48058021
*                                                                     * 48058421
.ASPN3   ANOP                                                           48058821
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 48060019
         SPACE 4                                                        48120019
         AIF   (&ASPN EQ 0).ASPN4                                       48170021
XIOTPEA  TM    UCBVOPT(UCBREG),UCBUNSOL UNSOL INTER REC THIS DEV  21048 48172021
         BZ    XIOTPE                   NO GO DO SIO              21048 48174021
         TM    DCBFL(DCBREG),DCBIEK     CHECK FOR IOS ERP USED    21048 48176021
         BNZ   XIOTP00                  NO GO RESET UNSOL FLG     21048 48178021
         BAL   LNKRG2,XCPPDQ            GO DEQUEUE REQUEST        21048 48178421
         OI    IOBFL2(IOBREG),IOBHAR0   INDIC UNSOL DE FOR ERP    21048 48178821
         B     INT022                   GO SCHEDULE ERP           21048 48179221
XIOTP00  NI    UCBVOPT(UCBREG),FF-UCBUNSOL RESET UNSOL INT FLG    21048 48179621
         SPACE 2                                                        48179721
.ASPN4   ANOP                                                           48179821
XIOTPE   DS    0H                                               SA54451 48179921
         TM    IOBFL1(IOBREG),IOBMD1    UNIT POSITIONING NEEDED SA54451 48186521
         BC    8,XIOTP01                NO, GO BUILD CCWS       SA54451 48188521
         TM    IOBFL2(IOBREG),IOBROR    CHECK RD OP RECOVERY    SA54451 48190521
         BC    8,XCP130                 GO START IMMEDIATE CCW  SA54451 48192521
XIOTP01  L     APBSRG,CCWRTNAD          GET CCW ROUTINE ADDR            48193321
         BALR  WKREG1,APBSRG            GO GET CCW ADDR                 48243321
         AIF   (&SSDA EQ 0 AND &SSTA EQ 0).MPX060                       48293321
         BC    15,XIOREQUE              CCWS BUSY, REQUE RQE            48313321
         AGO   .MPX060                                                  48323321
.MPX060A LR    LNKRG2,REG0              SET RETURN FOR TCH              48333321
         BCR   15,LNKRG2                RETURN TO TCH                   48335321
.MPX060  AIF   (&RWTAU EQ 0).SXIO666    CHECK RWTAU             SA56509 48342021
         SPACE 1                                                SA54451 48352021
* READ-WRITE TAU SUPPORT SPLITS SET MODE COMMAND FROM CHANNEL PROG.     48360019
* ANY SYSTEM SPECIFING R/W TAU'S GET THIS SUPPORT FOR ALL TAPES.        48420019
         SPACE 1                                                SA54451 48420421
.SXIO666 ANOP                                                   SA54451 48422021
XIOTPE8  DS    0H                                               SA54451 48430021
         AIF   (&RWTAU EQ 0).SXIO6AA    CHECK RWTAU             SA54451 48440021
         ST    WKREG3,TAPECCW           SAVE CCW ADDRESS        SA54451 48470021
.SXIO6AA MVC   0(16,WKREG3),TAPESM      MOVE SKELETON CCWS      SA54451 48472021
         AIF   (&RWTAU EQ 0).SXIO6      CHECK RWTAU             SA54451 48522021
         MVC   0(1,WKREG3),DEBMDM(DEBREG)   SETMODE OP CODE     SA54451 48540021
         ST    WKREG3,CAWLOC            SET UP CAW FOR SIO      SA54451 48590021
         BAL   LNKRG3,XCP111B           EXECUTE MODE SET CMD    SA54451 48600021
         BCR   8+2+1,LNKRG3             TO PSIO IF NOT CSW STOREDA27691 48610019
         SPACE 1                                                 A27691 48620019
*    CC=1,CSW STORED, EXAMINE STATUS                             A27691 48630019
         LH    WKREG1,CSWLOC+4          TEST RETURN STATUS      SA54451 48660021
         N     WKREG1,CHEDVE            NORMAL STATUS                   48720019
         BC    7,XCP113                 CHECK ABNORMAL STATUS    A27691 48780019
.SXIO6   ANOP                                                   SA54451 48830021
         L     WKREG1,UCBROR(UCBREG)    GET PTR TO ROR CCW      SA54451 48840021
         TM    IOBFL2(IOBREG),IOBROR    IS RD OP RECOV IN PROCESS  ROR1 48900021
         BC    1,XCP131C                YES, BYPASS RESTART TEST   ROR1 48960021
         L     WKREG1,IOBST-1(IOBREG)   GOOD EXEC-CCW START ADDR        49020019
         TM    IOBFL1(IOBREG),IOBSRS    RESTART FROM ERROR RTN          49080019
         BC    8,XCP131C                NO-CHECK FOR CRC CORRECTION     49140019
         L     WKREG1,IOBRST-1(IOBREG)  YES- GET RESTART CCW            49200019
XCP131C  DS    0H                                               SA54451 49250021
         AIF   (&RWTAU EQ 0).SXIO6BB    CHECK RWTAU             SA54451 49252021
         TM    IOBFL1(IOBREG),IOBMD2    CRC CORRECTION NEEDED   SA54451 49252421
         BC    8,XCP131B                NO- SKIP                SA54451 49252821
         L     WKREG3,TAPECCW           GET CCW ADDRESS         SA54451 49254021
.SXIO6BB ST    WKREG1,TAPETIC(WKREG3)   SET UP TIC ADDRRESS     SA54451 49256021
         MVI   TAPETIC(WKREG3),TICOP    SET TIC COMMAND         SA54451 49258021
         AIF   (&RWTAU NE 0).SXIO6CC    CHECK RWTAU             SA54451 49258421
         LA    WKREG1,TAPEIO(WKREG3)    GET POSSIBLE SETMODE    SA54451 49258821
         TM    IOBFL1(IOBREG),IOBMD2    CRC CORRECTION NEEDED   SA54451 49260021
         BC    8,XCP133                 NO- SKIP                SA54451 49320021
.SXIO6CC LA    WKREG1,CRCBTE(WKREG3)    GET CRC BYTE ADDR       SA54451 49500021
         ST    WKREG1,TAPEIO(WKREG3)    SET ADDR IN CCW         SA54451 49550021
         MVI   TAPEIO(WKREG3),TIEOP     SET TIE OPCODE          SA54451 49550121
         AIF   (&RWTAU EQ 0).SXIO6DD    CHECK RWTAU             SA54451 49550421
         LA    WKREG1,TAPEIO(WKREG3)    GET START CCW ADDR      SA54451 49550821
         AGO   .SXIO6EE                                         SA54451 49552421
.SXIO6DD LR    WKREG1,WKREG3            GET START CCW ADDR      SA54451 49556021
.SXIO6EE AIF   (&ASPN EQ 0).TAP020B     CHECK EXTENDED SENSE    SA54451 49560021
         LA    WKREG2,UCBSNS(UCBREG)    SET PTR TO SENSE DATA     21048 49610021
         TM    UCBFL5(UCBREG),UCBEXTSN  THIS DEV USE EXPAND SENSE 21048 49612021
         BZ    XCP132B                  NO GET SENSE DATA FROM UCB21048 49614021
         L     WKREG2,UCBSNADR-1(UCBREG) GET PTR TO SENSE DATA    21048 49616021
XCP132B  MVC   CRCBTE(1,WKREG3),TWO(WKREG2) MOVE BYTE TO CCW    SA54451 49618021
         AGO   .TAP022B                                         SA54451 49618421
.TAP020B MVC   CRCBTE(1,WKREG3),UCBSNS+2(UCBREG) MOVE TO CCW    SA54451 49618821
.TAP022B AIF   (&RWTAU NE 0).TAP024B    CHECK RWTAU             SA54451 49619621
XCP133   MVC   0(1,WKREG1),DEBMDM(DEBREG)  GET MODE OPCODE      SA54451 49634721
         BC    15,XCPSIO                GO ISSUE SIO            SA54451 49644721
         AGO   .STIOS4                                          SA54451 49646721
.TAP024B ANOP                                                   SA54451 49649821
XCP131B  ST    WKREG1,CAWLOC            SET CCW ADDR                    49664921
         LA    LNKRG3,XCPPIO            SET RETURN REG           BBBBBB 49680019
         BC    15,XCP110                TO START UP UNIT                49740019
         SPACE 1                                                        49800019
.STIOS4  AIF   (NOT &D2305).SKPZU                                20201  50820021
  TITLE 'MULTIPLE-EXPOSURE UNIT SIO ROUTINE - INPUT/OUTPUT SUPERVISOR'  50822521
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50825021
*                                                                     * 50827521
*                   SIO MODULE FOR MULTIPLE-EXPOSURE UNITS            * 50830021
*                                                                     * 50832521
*    FUNCTION  FIND A FREE EXPOSURE TO WHICH THIS REQUEST MAY BE      * 50835021
*              ADDRESSED, CONSTRUCT THE APPROPRIATE SYSTEM CHANNEL    * 50837521
*              PROGRAM, AND INITIATE THE DATA TRANSFER OPERATION.     * 50840021
*                                                                     * 50842521
*    ENTRY     ZEUSIO  FROM THE TEST CHANNEL COMMON ROUTINE.  ITS     * 50845021
*    POINT     ADDRESS IS CONTAINED IN THE DEVICE-TABLE ENTRY FOR     * 50847521
*              THE MULTIPLE-EXPOSURE DEVICE.                          * 50850021
         AIF   (&OLTEP EQ 0).OLT010                                     50852521
*              FOR SPECIFIC EXPOSURE REQUESTS FROM OLTEP,ENTRY IS     * 50855021
*              TO ZEUSOLT VIA SPECIFIC EXPOSURE DEVTAB ENTRY.         * 50857521
.OLT010  ANOP                                                           50860021
*                                                                     * 50880021
*    EXITS     TO POST-SIO SOUTINE VIA LNKRG3                         * 50881521
*              TO TEST CHANNEL, TO THE ADDRESS IN REG0                * 50883021
*              TO ENQUEUE OR CHANNEL RESTART, VIA LNKRG1              * 50884521
*                                                                     * 50886021
*    SUBROUTINES   EXTTST FOR EXTENT CHECKING                         * 50887521
*       USED       CHPBLD FOR INITIALIZING SK/SFM/TIC CHAIN           * 50889021
*                  XCP111 FOR EXECUTING SIO                           * 50890521
*                                                                     * 50892021
*    NOTES     A MULTIPLE-EXPOSURE UNIT IS A DIRECT-ACCESS DEVICE,    * 50893521
*              CONNECTED TO A CHANNEL WITH THE BLOCK-MULTIPLEX        * 50895021
*              FEATURE, WHICH CAN BE ADDESSED THROUGH ANY ONE OF      * 50896521
*              EIGHT ADDRESSES. IT IS REPRESENTED BY 8 UCB'S - A BASE * 50898021
*              UCB AND 7 EXPOSURE UCB'S.  EXCP REQUESTS ARE ADDRESSED * 50899521
*              TO THE BASE UCB, BUT ARE SERVICED BY IOS ON ANY FREE   * 50901021
*              EXPOSURE.  IF AN ERROR OCCURS, ERROR RECOVERY IS       * 50902521
*              EXECUTED ON THE EXPOSURE WHERE THE ERROR WAS DETECTED. * 50904021
*              A SHARED-FILE DEVICE IS RESERVED USING THE BASE UCB,   * 50905521
*              BUT THE DATA TRANSFER REQUEST IS SERVICED ON ANY FREE  * 50907021
*              EXPOSURE.                                              * 50908521
*                                                                     * 50910021
*    OPERATION FOR A NORMAL REQUEST, THE EXPOSURE CHAIN IS SCANNED    * 50911521
*              UNTIL A FREE EXPOSURE IS FOUND. (AN EXPOSURE IS        * 50913021
*              DESIGNATED AS FREE IF THE UCBBSY AND UCBERR FLAGS      * 50914521
*              ARE BOTH OFF.) THE EXTENT SUBROUTINE, EXTTST, IS USED  * 50916021
*              TO INSURE THAT THE SEEK ADDRESS IS NOT OUT OF THE      * 50917521
*              EXTENTS SPECIFIED IN THE DEB.  THE CCW INITIALIZATION  * 50919021
*              SUBROUTINE (CHPBLD) IS ENTERED, AND XCP111 IS GIVEN    * 50920521
*              CONTROL TO INITIATE THE USER'S REQUEST.  IF THE        * 50922021
*              REQUEST WAS SUCCESSFULLY STARTED, THE RQE IS TIED TO   * 50923521
*              THE EXPOSURE UCB, AND CONTROL IS GIVEN TO THE POST-SIO * 50925021
*              ROUTINE.  IF THE SIO DID NOT RESULT IN A ZERO C.C.,    * 50926521
*              THE RQE IS TIED TO THE BASE UCB BEFORE GOING TO PSIO.  * 50928021
*                                                                     * 50929521
*              IF A FREE EXPOSURE IS NOT FOUND, THE REQUEST IS QUEUED * 50931021
*              (IF FROM EXCP), OR CHANNEL RESTART IS RESUMED          * 50932521
*              (IF FROM THE INTERRUPT HANDLER).                       * 50934021
*                                                                     * 50935521
*              IF THIS REQUEST IS RELATED, IT IS NOT INITIATED IF     * 50937021
*              ANOTHER RELATED REQUEST FOR THE SAME DEB IS PRESENTLY  * 50938521
*              BEING SERVICED.                                        * 50940021
*                                                                     * 50941521
         AIF   (NOT &R2305).COMZ1                                 M0418 50942521
*              IF THIS IS A SHARED-FILE DEVICE, THE SOFTWARE AND      * 50944521
*              ACTUAL RESERVE COUNTERS ARE COMPARED.  IF THEY ARE NOT * 50946021
*              EQUAL, AND ONE IS ZERO, A STAND-ALONE RESERVE OR       * 50947521
*              RELEASE COMMAND USING THE BASE UCB IS STARTED.  IF THE * 50949021
*              SIO WAS UNSUCCESSFUL, XCPPIO IS GIVEN CONTROL.         * 50950521
*              OTHERWISE, A TIO LOOP IS EXECUTED UNTIL THE CSW HAS    * 50952021
*              BEEN STORED. XCPPIO3 IS ENTERED IF ANY ABNORMAL        * 50953521
*              CONDITIONS ARE PRESENTED.  IF D/E IS OUTSTANDING,      * 50955021
*              RETURN IS ON LNKRG1+SELBSY.  OTHERWISE, THE USER'S     * 50956521
*              REQUEST IS PROCESSED IN THE USUAL MANNER.              * 50958021
.COMZ1   ANOP                                                    ZEUS01 50959521
*                                                                     * 50961021
*              IF THE ERP IS IN CONTROL, AND THE PATH ABOUT TO BE     * 50962521
*              ACCESSED IS DOWN, CONTROL IS RETURNED TO TEST CHANNEL. * 50964021
*              IF IT IS A REQUEST FOR STAND-ALONE I/O, THE REQUEST IS * 50965521
*              INITIATED.  IF IT IS A RESTART, THE EXTENT SUBROUTINE  * 50967021
*              IS ENTERED BEFORE FURTHER PROCESSING. OTHERWISE, THE   * 50968521
*              SEEK ADDRESS COPIED FROM THE IOB TO THE UCB BEFORE THE * 50970021
*              EXTENT SUBROUTINE IS ENTERED.                          * 50971521
*                                                                     * 50973021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50974521
         AIF   (&OLTEP EQ 0).OLT030                               21051 50976021
         SPACE 2                                                        50977521
*   ENTRY POINT FOR OLTEP SPECIFIC EXPOSURE REQUEST. THIS CODE    21051 50979021
*    BRANCHES TO IOS OWNED IECIOLTS FOR EXPOSURE SELECTION.       21051 50980521
*    RETURN + 4 MEANS TO QUEUE REQUEST. RTN + 0 MEANS START SIO   21051 50982021
         SPACE 1                                                        50983521
ZEUSOLT  TM    UCBFL1(UCBREG),UCBERR    IS ERP IN CONTROL         21051 50985021
         BO    ZU120                    YES, PREPARE FOR SIO      21051 50986521
         AIF   (NOT &R2305).OLT020                                21051 50988021
         BAL   LNKRG2,RR00              DETERMINE IF RES/REL NEED 21051 50989521
.OLT020  L     APBSRG,IECOLTSW          IECIOLTS ADDRESS          21051 50991021
         BAL   LNKRG2,OLTZEUS(0,APBSRG) GET AN EXPOSURE           21051 50992521
         B     ZU050                    GO GET SEEK ADDR          21051 50994021
         IECLNK1 ,BC,15,SELBSY,0,LNKRG1,,&TBASE                   21051 50995521
.OLT030  SPACE 2                                                  21051 50997021
ZEUSIO   DS    0H                                                 20201 51060021
         TM    UCBFL1(UCBREG),UCBERR    IS ERP IN CONTROL         20201 51062021
         BC    1,ZU120                  YES, GO PREPARE FOR SIO   20201 51064021
         L     APBSRG,UCBWKADB(UCBREG)  GET PTR TO UCB EXTENSION  20201 51064621
         L     UCBREG,EXPCHN+BASADR(APBSRG) INSURE UCBREG PT BASE 20201 51065221
         N     UAREG,ZBASMSK            JUSTIFY UAREG TO BASE   SA62867 51065621
         AIF   (NOT &R2305).RRZU00                                20201 51066021
         SPACE 1                                                        51068021
*    DETERMINE IF RESERVE OR RELEASE IS REQUIRED.                 20201 51070021
         BAL   LNKRG2,RR00              GO TO SHARED CODE         20201 51072021
.RRZU00  SPACE 1                                                        51074021
*    FIND EXPOSURE CHAIN AND INITIALIZE CHAIN SEARCH CONTROLS     20201 51076021
ZU010    L     APBSRG,UCBWKADB(UCBREG)  GET PTR TO UCB EXTENSION  20201 51078021
         LR    WKREG3,UCBREG            SAVE PTR TO BASE ADR      20201 51080021
         L     WKREG1,EXPCHN+NXTEXP(APBSRG)  SAVE FIRST EXPOSURE P20201 51082021
         L     APBSRG,UCBWKADB(WKREG1)  GET PTR TO EXP EXTENSION  20201 51084021
         SR    UCBREG,UCBREG            INITIALIZE FOR FREE EXPOSU20201 51086021
         LR    WKREG2,UCBREG            INIT EXPOSURE AVAIL REG   20201 51088021
         SPACE 1                                                        51090021
*    DETERMINE IF THIS REQUEST CAN BE STARTED ON A FREE EXPOSURE  20201 51092021
ZU020    LTR   WKREG2,WKREG2            PREVIOUS EXPOSURE SAVED   20201 51094021
         BC    7,ZU030                  YES, BYPASS SAVING THIS ON20201 51096021
         LR    WKREG2,UCBREG            INDICATE A FREE EXPOSURE  20201 51098021
ZU030    CR    UCBREG,WKREG1            ALL EXPOSURES TESTED      20201 51100021
         BC    8,ZU100                  YES, GO CHECK FOR FREE EXP20201 51102021
         L     UCBREG,EXPCHN+NXTEXP(APBSRG)  GET PTR TO NEXT EXP  20201 51104021
         L     APBSRG,UCBWKADB(UCBREG)  GET PTR TO THIS EXTENSION 20201 51106021
         TM    UCBFL1(UCBREG),UCBBSY+UCBERR  THIS EXPOSURE BUSY   20201 51108021
         BC    7,ZU110                  YES, GO TEST FOR RELATED  20201 51110021
         TM    IOBFL1(IOBREG),IOBURL    IS REQUEST RELATED        20201 51112021
         BC    8,ZU020                  YES, GO SET FREE EXP AVAIL20201 51114021
         SPACE 1                                                        51116021
*    UPDATE THE EXPOSURE CHAIN FIELD IN BASE UCB EXTENSION        20201 51118021
ZU040    L     WKREG1,UCBWKADB(WKREG3)  GET BASE EXTENSION        20201 51120021
         ST    UCBREG,EXPCHN+NXTEXP(WKREG1) SAVE PTR TO LAST STRT 20201 51122021
         SPACE 1                                                        51124021
*    INITIALIZE SEEK ADDRESS IN UCB AND GO EXTENT CHECK IT        20201 51126021
ZU050    MVC   UCBSKA(8,UCBREG),IOBDAM(IOBREG) MBBCCHHR TO UCB    20201 51128021
ZU060    BAL   LNKRG2,EXTTST            GO INSURE IT IS WITHIN EXT20201 51130021
ZU070    IC    UAREG,UCBUA(UCBREG)      GET EXPOSURE UNIT ADDRESS 20201 51132021
         SPACE 1                                                        51134021
*    FIND SYSTEM CHANNEL PROGRAM                                  20201 51136021
*    INITIALIZE THE SYSTEM CHANNEL PROGRAM                        20201 51138021
         BAL   LNKRG2,CHPBLD           GO INITIALIZE SYSTEM CCW'S 20201 51140021
         SPACE 1                                                  20201 51142021
*    GO START THE DATA TRANSFER AND HANDLE UNUSUAL CONDITIONS     20201 51144021
ZU080    LR    WKREG1,WKREG3            INITIALIXE CCW PTR REG    20201 51146021
         BAL   LNKRG3,XCP111A           GO TO SIO SUBROUTINE      20201 51148021
         BC    8,ZU090                  CHANNEL WAS STARTED       20201 51150021
         SPACE 1                                                  20201 51152021
         LH    APBSRG,TSTUCB(TSTREG)    GET BASE OR ERR UCB PTR   20201 51154021
         BC    3,ZU085                  BUSY OR NOT OPER         A51608 51154421
         CLI   CSWLOC+4,CSWBSY          DEVICE BUSY STATUS       A51608 51154821
         BC    8,ZU095                  YES, LEAVE ON EXPOSURE  SA71786 51155218
         AIF   (&TWOSW EQ 0).RRX01                                20201 51158621
         MVC   UCBCHA(1,APBSRG),UCBCHA(UCBREG)  SET CHAN ADDR     M0192 51159821
.RRX01   ANOP                                                    A51608 51159921
ZU085    MVC   UCBSKA(8,APBSRG),UCBSKA(UCBREG) MOVE UCB SEEK     A51608 51160221
* .                                     ADDR FROM EXP TO BASE    A51608 51160621
         LR    UCBREG,APBSRG            INIT WITH BASE/ERR UCB   A51608 51161021
         STH   TSTREG,UCBLTS(UCBREG)    INITIALIZE BASE UCB FOR PS20201 51162021
ZU090    STH   UCBREG,TSTUCB(TSTREG)    SAVE EXPOSURE ADR FOR INT 20201 51164021
         BC    15,XCP113                RESET CC AND GO TO PSIO  A51608 51166021
         SPACE 1                                                        51166418
ZU095    NI    UCBFL1(UCBREG),FF-UCBNRY RESET NOT READY         SA71786 51166818
         OI    UCBFL1(UCBREG),UCBBSY    IND DE EXPECTED         SA74193 51166918
         AIF   (&OLTEP EQ 0).OLT040                             SA74193 51167318
*   OLTEP GETS CONTROL OF A 2305 BY ZEROING THE DEVICE TABLE    SA74193 51167418
*   INDEX IN THE UCB.  IF UCBDTI IS ZERO, CONTROL RETURNS TO    SA74193 51167518
*   THE OLTEP ENTRY TO THE 2305 SIO ROUTINE, TO INFORM OLTEP    SA74193 51167618
*   THAT THE EXPOSURE TO BE TESTED IS BUSY.  IF OLTEP DOES      SA74193 51167718
*   NOT CONTROL THE 2305, IOS ATTEMPTS TO START THE REQUEST     SA74193 51168418
*   ON ANOTHER EXPOSURE.  THE DEVICE BUSY STATUS COULD BE       SA74193 51168818
*   THE RESULT OF ATTEMPTING TO START AN EXPOSURE WHICH HAS AN  SA74193 51169218
*   OUTSTANDING 'SET SECTOR' FROM ANOTHER PATH.                 SA74193 51169618
         L     APBSRG,UCBWKADB(UCBREG)  GET PRT TO UCB EXTEN.   SA74193 51169918
         L     APBSRG,EXPCHN+BASADR(APBSRG) GET BASE ADDRESS    SA74193 51170618
         CLI   UCBDTI(APBSRG),ZERO      DOES OLTEP OWN ZEUS     SA74193 51171318
         BE    ZEUSOLT                  YES, TO ZEUS OLTEP ENTRY A74193 51172018
.OLT040  B     ZEUSIO                   TRY ANOTHER EXPOSURE    SA74193 51174618
         SPACE 1                                                  20201 51176018
*    ALL EXPOSURES HAVE BEEN CHECKED.                             20201 51176218
*    SET BASE UCB BUSY AND                                        20201 51178318
*    EXIT IF A FREE ONE WAS NOT FOUND                             20201 51180418
ZU100    LTR   WKREG2,WKREG2            IS A FREE EXPOSURE AVAIL  20201 51182518
         BC    7,ZU105                  YES, GO USE IT FOR SIO    20201 51184618
         OI    UCBFL1(WKREG3),UCBBSY+UCBCUB PREVENT MORE RSTRTS SA74193 51186718
         STH   TSTREG,UCBLTS(WKREG3)    TIE REQUEST TO THE BASE SA74193 51188818
         STH   WKREG3,TSTUCB(TSTREG)                            SA74193 51190918
         IECLNK1  ,BC,15,SELBSY,0,LNKRG1,,&TBASE                  20201 51193018
         SPACE 1                                                  20201 51195118
ZU105    LR    UCBREG,WKREG2            INIT TO USE EXPOSURE ADDR 20201 51197218
         BC    15,ZU040                 GO INITILIAZE FOR SIO     20201 51199318
         SPACE 1                                                  20201 51201418
*    CHECK THIS BUSY EXPOSURE FOR A RELATED REQUEST IF THIS       20201 51203518
*    REQUEST IS RELATED                                           20201 51205618
ZU110    TM    UCBFL1(UCBREG),UCBPST+UCBERR+UCBCUB REQUEST TIED TO UCB  51207718
         BZ    ZU030                    NO, GO GET NEXT EXPOSUR SA74193 51209818
         TM    IOBFL1(IOBREG),IOBURL    IS REQUEST RELATED      SA74193 51211918
         BC    1,ZU030                  NO, GO GET NEXT EXPOSURE  20201 51214018
         LH    DEBREG,UCBLTS(UCBREG)    FIND LAST REQUEST STARTED 20201 51216118
         CLC   TSTDEB(3,TSTREG),TSTDEB(DEBREG) SAME DEB           20201 51218218
         L     DEBREG,TSTPR(TSTREG)    RESTORE DEBREG             20201 51220318
         BC    7,ZU030                  NO, GO GET NEXT EXPOSURE  20201 51222418
         IECLNK1 ,BC,15,SELBSY,0,LNKRG1,,&TBASE                   20201 51224518
         SPACE 1                                                  20201 51226618
*    ERROR ROUTINE IS PROCESSING THIS REQUEST                     20201 51228718
ZU120    DS    0H                                                 20201 51230818
         TM    UCBFL1(UCBREG),UCBBSY    INTERRUPT EXPECTED      SA75351 51231218
         IECLNK1 ,BC,1,SELBSY,0,LNKRG1,,&TBASE                  SA75351 51232818
         AIF   (&M65MP EQ 1).APR005                               M5704 51232918
         AIF   (&APR EQ 0 OR &TWOSW EQ 0).APR111                  M5704 51235018
.APR005  L     WKREG1,UCBWKADB(UCBREG)  GET UCB EXTENSION         20201 51237118
         L     WKREG1,EXPCHN+BASADR(WKREG1) GET BASE UCB ADDRESS  20201 51239218
         SPACE 1                                                  20201 51241318
*    CHECK FOR PREVIOUS INOP PATH                                 20201 51243418
         IC    ICREG,PATHMSK            GET PATH INDICATOR        20201 51245518
         IC    WKREG1,UCBCHM(WKREG1)    GET PATH STATUS INDICATORS20201 51247618
         NR    WKREG1,ICREG             IS THIS PATH DOWN         20201 51249718
         LR    LNKRG2,REG0              SETUP FOR RETURN          20201 51251818
         BCR   4,LNKRG2                 YES, RETURN TO TCH        20201 51253918
.APR111  SPACE 1                                                  20201 51256018
*    DETERMINE WHAT ACTION IS REQUIRED FOR THE ERP                20201 51258118
         L     WKREG3,IOBRST-1(IOBREG)  INITIALIZE FOR RESTART    20201 51260218
         TM    IOBFL2(IOBREG),IOBHAR0   IS THIS RECALIBRATE OPERAT20201 51262318
         BC    1,ZU080                  YES, GO PREPARE FOR SIO   20201 51264418
         TM    IOBFL1(IOBREG),IOBSRS    IS THIS RESTART           20201 51266518
         BC    8,ZU050                  NO, GO SET SEEK ADR       20201 51268618
         BC    15,ZU060                 GO TEST FOR OUT OF EXTENT 20201 51270718
.SKPZU AIF (NOT &R2301 AND NOT &R2303 AND NOT &R2305 AND NOT &RML).RR01 51272818
         TITLE 'SHARED FILE SUPPORT FOR DRUMS AND 3330 - INPUT/OUTPUT SX51274918
               UPERVISOR'                                               51277018
*    INITIALIZE THE CCW IF A DEVICE RESERVE OR RELEASE IS REQUIRED20201 51279121
RR00     TM    UCBTYP+1(UCBREG),UCBRR   THIS DEVICE SHARED        20201 51284021
         BCR   8,LNKRG2                 NO, RETURN                20201 51288921
         CLI   UCBRRCNT(UCBREG),ZERO    RESERVE REQUESTED       SA73317 51293818
         BC    8,ZU160                  NO, CHK FOR RELEASE     SA73317 51298718
         TM    UCBDVRES(UCBREG),RSVD    ALREADY RESERVED        SA73317 51308518
         BCR   1,LNKRG2                 YES, RETURN             SA73317 51313418
         MVI   RRDRMCCW,RESERVE         INITIALIZE RESERVE OP CODE20201 51318321
ZU140    LA    WKREG1,RRDRMCCW          GET PTR TO CCW            20201 51323221
         ST    WKREG1,CAWLOC            INITIALIZE CAW            20201 51328121
         SPACE 1                                                  20201 51333021
*    GO ISSUE SIO FOR RESERVE/RELEASE FUNCTION AND DETERMINE RESULTS    51337921
         ST    WKREG3,EXTSAV            SAVE ADR OF CHAN PGM      20201 51342821
         AIF  (&PROTECT EQ 0).PRO100                             SM4220 51347721
         BAL   LNKRG3,XCP110C           GO DO SIO                 20201 51352621
         AGO    .PRO200                                          SM4220 51357521
.PRO100  ANOP                                                    SM4220 51362421
         BAL   LNKRG3,XCP110B           GO DO SIO                SM4220 51367321
.PRO200  ANOP                                                    SM4220 51372221
         L     WKREG3,EXTSAV            RESTORE ADR OF CHAN PGM   20201 51377121
         BC    7,XCPPIO                 GO SEE WHY IT WASNT STARTE20201 51382021
         L     WKREG1,LPCNT             GET LOOP LIMIT          SA68848 51384021
ZU150    TIO   ZERO(UAREG)              BRING IN CHANNEL END      20201 51386921
         BC    4,ZU150A                 LOOP UNTIL STORED       SA68848 51391821
         BCT   WKREG1,ZU150             DECREMENT LOOP COUNT    SA68848 51393818
ZU150B   OI    UCBFL1(UCBREG),UCBBSY    INDICATE DE IS EXPECTED   20201 51394018
         MVI   UCBDVRES(UCBREG),PND     INDICATE RR PENDING     SA73317 51394418
         IECLNK1 ,BC,15,SELBSY,0,LNKRG1,,&TBASE                   20201 51395418
         SPACE 1                                                        51395818
ZU150A   LH    WKREG1,CSWLOC+4          GET STATUS                20201 51396721
         N     WKREG1,CHEDVE            ANY EXCEPT CE AND DE      20201 51401621
         BC    8,ZU150C                 NO, CONTINUE            SA73317 51403618
         MVI   UCBDVRES(UCBREG),PND     INDICATE RR PENDING     SA73317 51405618
         BC    15,XCPPIO3               YES, GO INVESTIGATE       20201 51406518
         SPACE 1                                                  20201 51411421
*    INDICATE THAT COMMAND WAS ACCEPTED                           20201 51416321
ZU150C   CLI   RRDRMCCW,RELEASE         RELEASE OPERATION       SA73317 51418318
         BC    7,ZU150D                 NO, INDICATE RSVD       SA73317 51421218
         MVI   UCBDVRES(UCBREG),ZERO    INDICATE RELEASED       SA73317 51421618
         BC    15,ZU150E                CONTINUE                SA73317 51422018
ZU150D   MVI   UCBDVRES(UCBREG),RSVD    INDICATE RESERVED       SA73317 51422418
ZU150E   DS    0H                                               SA73317 51422818
         AIF   (NOT &R2305).NOSEPDE                             SA68848 51423221
         TM    CSWLOC+4,CSWDVE          IS OPERATION COMPLETE     20201 51426121
         BCR   1,LNKRG2                 YES, RETURN TO START USER 20201 51431021
         BC    15,ZU150B                ALLOW CPU TO ENABLE     SA68848 51431118
         AGO   .SEPDE                                           SA68848 51431421
.NOSEPDE ANOP                                                   SA68848 51433021
         BCR   15,LNKRG2                RETURN TO START USER    SA68848 51435021
.SEPDE   ANOP                                                   SA68848 51435421
         SPACE 1                                                  20201 51445721
*    SET RELEASE IF REQUIRED                                      20201 51450621
ZU160    TM    UCBDVRES(UCBREG),RSVD+PND  OUTSTANDING RESERVE   SA73317 51455518
         BCR   8,LNKRG2                 NO, NO RELEASE REQUIRED SA73317 51460418
         MVI   RRDRMCCW,RELEASE         INITIALIZE RELEASE OP CODE20201 51465321
         BC    15,ZU140                 GO PREPARE FOR RELEASE FUN20201 51470221
.RR01    TITLE 'DIRECT ACCESS SIO ROUTINE - INPUT/OUTPUT SUPERVISOR'    51475121
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 51480019
*                                                                     * 51540019
*                   DIRECT ACCESS SIO MODULE                          * 51600019
*                                                                     * 51660019
*  FUNCTION    SET UP PRELIMINARY PROCEDURES FOR D/A DEVICES, USES THE* 51720019
*              SEEK ADDRESS IN THE IOB FOR A STAND ALONE SEEK AND     * 51780019
*              RELEASES THE CHANNEL WHILE THE ARM IS SEEKING          * 51840019
*              AFTER THE SEEK IS COMPLETED A START DATA TRANSFER SEEK * 51900019
*              IS PREPARED THEN BRANCH TO THE SIO SUBROUTINE          * 51960019
*                                                                     * 52020019
*   ENTRIES    XIODSK  FROM SELECT SUBROUTINE BY USE OF DEVICE TABLE  * 52080019
*              XCP166  USED AS COMMON DEQUEUE LINKAGE TO GET CORRECT  * 52140019
*                      LOGICAL CHANNEL CONTROL WORD ADDRESS           * 52200019
*     EXITS    XCP111  TO SIO SUBROUTINE FOR STAND ALONE SEEK         * 52260019
*              XCP111A TO SIO SUBROUTINE FOR DRUM                       52320019
*              XCP110  TO SIO SUBROUTINE TO START DATA TRANSFER       * 52380019
*              WKREG1  TO DEQUEUE ROUTINE BY USE OF DEVTAB + UCB INDEX* 52440019
*                                                                     * 52500019
* OPERATION    SET UP THE STAND ALONE SEEK AND CHECK TO MAKE SURE IT  * 52560019
*              IS WITHIN EXTENT THEN GO TO SIO SUBROUTINE, ON RETURN  * 52620019
*              THE CONDITION CODE IS CHECKED FOR ZERO AND COMPLETION  * 52680019
*              OF DATA TRANSFER TO CONTROL UNIT, SET ARM SEEKING FLAG * 52740019
*              AND DEQUEUE STAND ALONE SEEK                           * 52800019
*              AFTER DEVICE END FOR THE STAND ALONE SEEK THE IO INTER-* 52860019
*              RUPT SUPERVISOR PASSES CONTROL BACK TO THIS ROUTINE    * 52920019
*              THE START OR RESTART ADDRESS IS MOVED TO THE TIC CCW IN* 52980019
*              THE START DATA TRANSFER CHAIN DEPENDING ON THE RESTART * 53040019
*              FLAG IN THE IOB, THE FIRST CCW ADDRESS IS PUT INTO THE * 53100019
*              CAW AND THE DATA TRANSFER FLAG IS SET IN THE UCB       * 53160019
*              SET UP POST SIO RETURN IN LNKRG3 AND BRANCH TO SIO     * 53220019
*              SUBROUTINE                                             * 53280019
*                                                                     * 53340019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 53400019
         SPACE 3                                                        53460019
RPSSIO   DS    0H                                                 20201 53490020
XIODSK   DS    0H                                                  SDA2 53520019
         AIF   (&ALTSHR EQ 1).RR109B                             A52475 53529021
         AIF   (&M65MP EQ 0 OR &RESREL EQ 0).RR109              SA60750 53529421
.RR109B  ANOP                                                   SA60750 53529821
         TM    UCBTYP+1(UCBREG),UCBRR   IS THIS DEVICE SHARED    A27707 53534019
         BC    8,XIODSKA                NO, SKIP PATH CHECK      A27707 53541019
         CLI   UCBDVRES(UCBREG),ZERO    IS DEVICE RESERVED       A27707 53548019
         BC    7,XIODSKB                YES, GO INSURE SAME PATH A27707 53555019
         TM    UCBFL1(UCBREG),UCBASK    RESERVE IN EFFECT        A52438 53562021
         BC    8,XIODSKA                NO, SKIP PATH CHECK      A27707 53569019
XIODSKB  DS    0H                                                       53576021
         AIF   (&M65MP EQ 0).RR107                                      53576721
         SPACE                                                          53577421
*              INSURE SIO FOR RESERVED DEVICE IS ISSUED ON        21063 53578121
*              CORRECT PATH IN CORRECT CPU FOR M65MP SHARED DASD  21063 53578821
         LR    WKREG1,UCBREG            TRANSFER UCB ADDR         21063 53579521
         S     WKREG1,NEGDISP           POINT TO UCB MP PREFIX    21063 53580221
         TM    UCBFL3(WKREG1),UCBCPUA   LAST SIO FROM CPU A       21063 53580921
         BO    XIOCPUB                  NO - GO CHK FOR CPU B     21063 53581621
         CLI   CPUID-IEAQFX00,CPUA      YES-ARE WE IN CPU A       21063 53582321
         BE    XIODSKB1                 YES-GO CHK FOR CORR PATH  21063 53582421
         B     XIOREQUE                 NO-GO BACK TO TEST CHANNEL21063 53582521
XIOCPUB  CLI   CPUID-IEAQFX00,CPUA      IS THIS CPU A             21063 53582621
         BE    XIOREQUE                 YES-WRONG CPU-BACK TO TCH 21063 53582721
XIODSKB1 DS    0H                                                 21063 53582821
.RR107   LH    WKREG1,UCBCHA(UCBREG)    GET LAST PATH STARTED    A27707 53582921
         N     WKREG1,ADDRMSK           CLEAR FLAGS              A27707 53583019
         CR    WKREG1,UAREG      PATH SAME AS LAST ONE STARTED   A27707 53590019
         BC    7,XIOREQUE               NO, GO GET ANOTHER PATH         53597021
XIODSKA  DS    0H                                                A27707 53625019
.RR109   AIF   (&DAVV EQ 0).DAVV03                               A27707 53632019
         TM    UCBFL4(UCBREG),UCBVVR    VOL VER RTN IN CONTROL     DAVV 53640019
         BC    1,XCP168                 YES GO TO TEST CONDITION   DAVV 53700019
XCP188   DS    0H                                               SA58676 53750021
.DAVV03  AIF   (&TCBTYP LT 2).MVT015    NOT MVT, SKIP            A24739 53760019
*   DO NOT ALLOW THE EXTENT TEST TO BE BYPASSED UNLESS THE ERROR   IMP3 53820019
*   ROUTINE IS IN CONTROL.                                         IMP3 53880019
         SPACE 1                                                   IMP3 53940019
         TM    UCBFL1(UCBREG),UCBERR                               IMP3 54000019
         BC    7,XIODSK1               BYPASS EXTENT TEST          IMP3 54060019
         NI    IOBFL2(IOBREG),FF-IOBNET-IOBHAR0  RESET FLAGS     BBBBBB 54120019
.MVT015  SPACE 1                                                   IMP5 54180019
XIODSK1  TM    IOBFL2(IOBREG),IOBHAR0  HA OR R0 FROM ERROR RTN     IMP3 54240019
         BC    1,XCP166A                YES NO SEEK NEEDED              54300019
XIODSK1A TM    UCBFL1(UCBREG),UCBASK    SEEK BEEN ISSUED         BBBBBB 54390019
         BC    1,XCP160                 YES, TO START DATA TRANSFERSDA2 54480019
         TM    IOBFL1(IOBREG),IOBSRS    IS RESTART FLAG SET             54660020
         BC    1,XCP161                 YES- SEEK AT UCB ALREADY        54720019
         MVC   UCBSKA(8,UCBREG),IOBDAM(IOBREG) MOVE MBBCCHHR      M2691 54780019
XCP161   TM    IOBFL2(IOBREG),IOBNET    IS EXTENT TEST REQUIRED   20201 54980020
         BC    1,XCP161B                NO, SKIP CHECKS                 55200019
         BAL   LNKRG2,EXTTST            GO SEE IF WITHIN EXTENT   20201 55700020
XCP161B  DS    0C                                                 19025 56340019
         AIF   (NOT &D2301 AND NOT &D2303).DRM000                 20201 56360020
         TM    UCBTYP+3(UCBREG),DRUM    IS THIS A DRUM            20201 56380020
         BC    1,XCPDRM                 YES, GO PREPARE FOR SIO   20201 56400020
.DRM000  AIF   (&RPS EQ 0).RPS01                                  20201 56420020
         TM    UCBTYP+1(UCBREG),UCBRPS  TEST FOR RPS              19025 56460019
         BC    1,XCPRPS                 YES, GO PREPARE FOR SIO   20201 56520020
         SPACE 1                                                  20201 56540020
*    SA SEEK MUST BE STARTED, INITIALIZE THE CCW FOR EXECUTION    20201 56560020
.RPS01   LA    WKREG1,UCBSKA+1(UCBREG)  POINT AT SEEK ADDRESS     20201 56580020
         STH   WKREG1,SEEK1+2           INIT SA SEEK CCW          20201 56600020
         LA    WKREG1,SEEK1             INIT FOR CAW STORE        20201 56620020
         AIF   (&RESREL EQ 0).RR003                                     56640019
         TM    UCBTYP+1(UCBREG),UCBRR   RESERVE/RELEASE CAPABILITY      56700019
         BC    8,XCPRR007               NO-SKIP                         56760019
         LA    WKREG1,SEEKRR            GET RESERVE ADDRESS        SDA2 56820019
XCPRR007 DS    0C                                                       56880019
.RR003   BAL   LNKRG3,XCP111            TO SIO ROUTINE                  56920020
XCP161C  DS    0H                       RETURN FROM SIO          BBBBBB 56960019
         AIF   (&ASR EQ 0).ASR2         CHANNEL CHECK HANDLER       CCH 57000019
         MVI   CATAPP,CATSSK .          SET CCH CODE FOR SIO SEEK   CCH 57060019
.ASR2    SPACE 1                                                   IMP2 57120019
*   CONDITION CODE SET UPON RETURN                                      57180019
         BC    7,XCPPIO1A               RETURN TO PSIO-CK CSW     M2959 57240019
XCP162   DS    0H                                                       57300019
         TIO   0(UAREG)                 TEST FOR DATA TRANS. COMPLETE   57660021
*                                       TO CONTROL UNIT                 57720019
         BC    11,XCP162                BRANCH BACK UNTIL COMPLETE      57780019
         AIF   (&ASR EQ 0).ASR3         CHANNEL CHECK HANDLER       CCH 57840019
         MVI   CATAPP,CATTIOSK .        SET CCH CODE FOR TIO SEEK   CCH 57900019
.ASR3    LH    WKREG1,CSWLOC+4          STATUS                          57960019
         N     WKREG1,CHEDVE            MASK                            58020019
         BC    7,XCPPIO3                CHECK ABNORMAL STATUS    A27025 58080019
         OI    UCBFL1(UCBREG),UCBASK+UCBBSY+UCBPST  SET FLAGS    BBBBBB 58140019
         AIF   (&RESREL EQ 0).RR006                                SDA1 58200019
         MVC   UCBDVRES(1,UCBREG),UCBRRCNT(UCBREG)  IND RES DEV    SDA1 58260019
.RR006   MVC   IOBCSW+1(7,IOBREG),CSWLOC+1  SAVE STATUS IN IOB          58320019
         TM    CSWLOC+4,CSWDVE          SEEK COMPLETE                   58380019
         IECLNK1 ,BC,8,SELBSY,0,LNKRG1,,&TBASE                          58460021
         NI    UCBFL1(UCBREG),FF-UCBBSY-UCBPST RESET FLAGS       BBBBBB 58550021
XCP169A  TM    XCPBTE,XCPCNT+XCPERR     XCP ALONE                BBBBBB 58580019
         IECLNK1 ,BC,8+1,SELBSY,0,LNKRG1,,&TBASE                   TBSE 58620019
         SPACE 1                                                 BBBBBB 58680019
*   START DATA TRANSFER CODE                                            58740019
XCP160   LA    LNKRG2,XCP163            SET RETURN TO FALL THRU   20201 58840020
CHPBLD   L     APBSRG,CCWRTNAD          GET CCW ROUTINE ADDR            58940021
         BALR  WKREG1,APBSRG            GO GET CCW ADDR                 59640021
         AIF   (&SSDA EQ 0 AND &SSTA EQ 0).MPX010                       59690021
         BC    15,XIOREQUE              CCWS BUSY, REQUE RQE            59750021
         AGO   .MPX010                                                  59752021
.MPX010A LR    LNKRG2,REG0              SET RETURN TO TCH               59754021
         BCR   15,LNKRG2                RETURN TO TCH                   59756021
.MPX010  ANOP                                                           59758021
XIODSK8  DS    0H                                                  IMP4 59760019
         MVC   0(16,WKREG3),RRDXCCW     MOVE SKELETON CCWS      SA56509 59882121
CHPBLDA  LA    WKREG1,UCBSKA+1(0,UCBREG)  POINT AT SEEK ADDR      20201 59940020
         STH   WKREG1,SEEK2+2(0,WKREG3)  SET POINTER TO CCHH     BBBBBB 59970019
         SR    WKREG2,WKREG2                                    SA68948 59980021
         IC    WKREG2,UCBSKA(0,UCBREG)  GET M FROM UCB                  60000019
         AIF   (&CEXT EQ 0).CEX000                                20201 60020020
         IC    ICREG,DEBEXT(DEBREG)     GET EXTENT SCALE          20201 60040020
         SLL   WKREG2,ZERO(ICREG)       DETERMINE FM OFFSET       20201 60060020
         AGO   .CEX001                                            20201 60080020
.CEX000  SLL   WKREG2,4                 DETERMINE FM OFFSET       20201 60100020
.CEX001  IC    ICREG,DEBMDM(DEBREG,WKREG2) PICK UP FILE MASK      20201 60120020
         STC   ICREG,SMMSK2(0,WKREG3)   STORE IT IN CCW                 60170021
         LA    WKREG2,SMMSK2(WKREG3)    GET ADDR OF FM IN CCW      1543 60300019
         ST    WKREG2,SFMCCW(0,WKREG3)  SET F.M. ADDRESS IN CCW    SDA1 60360019
         MVI   SFMCCW(WKREG3),SETFMSK  INSERT OP CODE              SDA1 60420019
         MVC   SKTIC+1(3,WKREG3),IOBST(IOBREG)  MOVE IN START ADDR      60660021
         LR    WKREG1,WKREG3            INITIALIZE FOR CAW STORE  20201 60680020
         SPACE 1                                                  20201 60700020
         TM    IOBFL1(IOBREG),IOBSRS    IS RESTART FLAG ON              60720019
         BCR   8,LNKRG2                 NO, USE START ADDRESS     20201 60780020
         MVC   SKTIC+1(3,WKREG3),IOBRST(IOBREG) YES-GET RESTART ADDR.   60840019
         TM    IOBFL2(IOBREG),IOBNET    IS THIS ALTERNATE TRACK PROCE.  60900019
         BCR   8,LNKRG2                 NO, DO NOT CHANGE FILE MAS20201 60960020
         OI    SMMSK2(WKREG3),X'18'     INHIBIT ALL SEEKS               61020019
         BCR   15,LNKRG2                FALL THROUGH OR RETURN    20201 61100020
XCP163   DS    0H                                                 20201 61180020
         AIF   (&RESREL EQ 0).RR004                                     61260019
         SPACE 1                                                 BBBBBB 61267019
*    IF THIS IS A SHARED-FILE DEVICE AND THE RESERVE COUNT IS    BBBBBB 61274019
*    ZERO, THE DATA TRANSFER COMMAND IS PRECEDED BY A RELEASE.   BBBBBB 61281019
         TM    UCBTYP+1(UCBREG),UCBRR   RR CAPABILITY                   61320019
         BC    8,XCP165                 NO, GO PREPARE FOR SIO    20201 61390020
         CLI   UCBRRCNT(UCBREG),ZERO    IS COUNTER ZERO           20201 61460020
         BC    7,XCP165                 NO, DO NOT RELEASE        20201 61530020
         SH    WKREG1,EIGHT             BACK UP CCW CMD.                61620019
         MVI   CCWFLG(WKREG1),CCWCC+CCWSLI+CCWSD  SET FLAGS        SDA1 61680019
         MVI   0(WKREG1),RELEASE        IN CASE RRCNT = 0               61740019
.RR004   SPACE 1                                                  20201 62740020
*    START DATA TRANSFER FOR SEEKABLE DEVICE                     BBBBBB 63786019
XCP165   ST    WKREG1,CAWLOC            CCW ADR IN CAW            20201 63790020
         BAL   LNKRG3,XCP110            GO DO SIO                 20201 63794020
         AIF   (&RESREL EQ 1).RR005AA                            M6152  63796020
         BCR   7,LNKRG3                 RETURN IF NOT O.K.       BBBBBB 63798019
         SPACE 1                                                 A27691 63804019
         AGO   .RR005AB                                          M6152  63804620
.RR005AA BC    8,XCP165AB .             GOOD SIO BYPASS UCBHLT   M6152  63805220
         LTR   WKREG2,WKREG2 .          WAS UCBHLT ON FROM PURGE M6152  63805820
         BC    8+2,XCP165AA .           NO, RE-INSERT SIO CC     M6152  63806420
         OI    UCBCHA(UCBREG),UCBHLT .  SET HIO BIT ON FOR PURGE M6152  63807020
XCP165AA SPM   WKREG1 .                 RE-INSERT SIO CC         M6152  63807620
         BCR   15,LNKRG3 .              RETURN TO POSTSIO        M6152  63808220
         SPACE 3                                                        63808820
.RR005AB ANOP                                                    M6152  63809420
*    SET POST, BUSY, DATA TRANSFER AND ARM SEEKING FLAGS IN UCB  A27691 63810019
XCP165AB OI    UCBFL1(UCBREG),UCBBSY+UCBPST+UCBDTR+UCBASK        M6152  63813020
         AIF   (&RESREL EQ 0).RR36733                            A36733 63817020
         TM    UCBTYP+1(UCBREG),UCBRR . RR CAPABILITY            A36733 63818020
         BC    8,XCPPIO1 .              NO, CONTINUE PROCESSING  A36733 63819020
         MVC   UCBDVRES(1,UCBREG),UCBRRCNT(UCBREG) . IND RES DEV A36733 63820020
.RR36733 BC    15,XCPPIO1 .             CONTINUE PROCESSING      A27691 63824020
         SPACE 1                                                 BBBBBB 63828019
XCP166A  L     WKREG1,IOBRST-1(IOBREG)  GET RESTART ADDR          20201 64728020
         AIF   (&RESREL EQ 0).RR012                                     65640019
         TM    UCBTYP+1(UCBREG),UCBRR   IS REQUEST FOR A RES/REL DEVICE 65700019
         BC    8,XCP165                 NO, GO PREPARE FOR SIO    20201 65760020
         CLI   0(WKREG1),HAOP           BUT IS IT A R-HA         A36342 65820020
         BC    7,XCP165                 NO, GO PREPARE FOR SIO    20201 65880020
         MVC   IOBCSW+1(8,IOBREG),CLEAR SIMULATE CE/DE             SDA1 65940019
         BC    15,INTS02G               GO TO DEQ AND ABE APGE   BBBBBB 66030019
         AGO   .RR013                                                   66120019
.RR012   BC    15,XCP165                GO PREPARE FOR SIO        20201 66180020
.RR013   SPACE 1                                                   IMP4 66240019
         AIF   (&RPS EQ 0).RPS02                                  20201 66242020
XCPRPS   L     WKREG3,UCBWKADB(0,UCBREG) GET PTR TO EXTENSION   SA68948 66246021
         LA    WKREG3,UCBWKDCC(0,WKREG3) POINT TO BLOCK MPX CP    20201 66248020
         LA    LNKRG2,XCPDRM1           SET RETURN REG            20201 66250020
         BC    15,CHPBLDA               GO INITIALIZE SYS CHAN PRO20201 66252020
.RPS02   SPACE 3                                                  20201 66254020
XCPDRM   BAL   LNKRG2,CHPBLD            GO INITIALIZE SYS CHAN PRO20201 66256020
XCPDRM1  DS    0H                                                 20201 66258020
         AIF    (NOT &R2301 AND NOT &R2303 AND NOT &RML).RR002    20201 66260020
         BAL   LNKRG2,RR00              GO CHECK FOR RESERVE/RELEA20201 66262020
         LR    WKREG1,WKREG3            INIT FOR CAW STORE        20201 66264020
.RR002   BC    15,XCPSIO                GO DO SIO                 20201 66266020
         SPACE 2                                                  20201 66268020
         AIF   (&ALTSHR NE 0).REQUE1                                    66278021
         AIF   (&SSDA EQ 0 AND &SSTA EQ 0 AND &RESREL EQ 0).REQUE2      66278821
.REQUE1  ANOP                                                           66279221
XIOREQUE OI    IOBCC(IOBREG),IOBCC1     PREVENT LCH SWITCH              66279621
         OI    UCBFL1(UCBREG),UCBCUB    INSURE NO EXCP START            66279721
         STH   TSTREG,UCBLTS(UCBREG)    SET CORRECT RQE                 66279821
         LR    LNKRG2,REG0              SET RETURN TO TCH               66279921
         BCR   15,LNKRG2                GO FIND REVERVED PATH   SA73137 66293218
         SPACE 2                                                        66303221
.REQUE2  AIF   (&DAVV EQ 0).DAVV04                                      66306721
XCP168   DS    0H                                                 M4482 66320019
         AIF   (&RESREL EQ 0).CKRRDEB                           SA58676 66330021
         CLC   RRDCBDEB+1(3),TSTDEB(TSTREG)  CHECK FOR RRDEB    SA58676 66332021
         BC    8,XCP178                 YES, RE-SCHEDULE DAVV   SA58676 66334021
.CKRRDEB AIF   (&DDR EQ 0).DDRDAV1                              SA58676 66338021
         C     TSTREG,ADDRRQE           IS THIS THE DDR RQE     SA57220 66338421
         BC    8,XCP178                 YES, RE-SCHEDULE DAVV   SA57220 66338821
         AIF   (&DDR LT 2).DDRDAV1                                M4482 66340019
         L     WKREG1,TOADDR            ADDR OF DDRSRTO          BBBBBB 66350020
         CH    UCBREG,0(WKREG1)         IS THIS DDR 'TO' DEVICE  BBBBBB 66360020
         BC    8,XCPVOLVR               YES-TO CANCEL DAVV        M4482 66380019
.DDRDAV1 CH    TSTREG,UCBRQESV(0,UCBREG) DOES XSNT RTN NEED CTL   M4482 66400019
         BC    7,INTERR4A               YES, GO TO SCHEDULE        DAVV 66420019
         TM    UCBFL4(UCBREG),UCBVER    TEST FOR VOLUME VERIFIED   DAVV 66480019
         BC    1,XCPVOLVR               YES-CLEAN UP               DAVV 66540019
         TM    UCBFL1(UCBREG),UCBERR    TEST IF RQE PURGED         DAVV 66600019
         BC    8,INTERR4B               YES-GO TO REST. XSNT FUNC. DAVV 66660019
         TM    IOBFL2(IOBREG),IOBNET    DAVV-TYPE OF SEEK BYPASS  M0161 66680021
         BC    8,XCP166A                YES,NO SEEK NEEDED       A43739 66700021
         BC    15,XIODSK1A              NO-GO SET UP SEEK          DAVV 66720019
         SPACE 1                                                   DAVV 66780019
XCP178   BAL   LNKRG2,INTATN            RE-SCHEDULE DAVV        SA58676 66830021
         BC    15,XCP188                CONTINUE PROCESSING     SA58676 66832021
         SPACE 1                                                SA58676 66834021
XCPVOLVR NI    UCBFL4(UCBREG),FF-UCBDAV RESET DAVV RTN FLAGS       DAVV 66840019
         TM    IOBFL1(IOBREG),IOBEX     IS IOB EXCEPTION ON?   @SA77089 66860018
         BC    1,XIODSK1A               YES, LEAVE IOB ERR ON  @SA77089 66880018
         NI    IOBFL1(IOBREG),FF-IOBERR RESET ERR RTN FLAG         DAVV 66900019
         BC    15,XIODSK1A              GO TO SET UP SEEK          DAVV 66960019
.DAVV04  TITLE 'DIRECT ACCESS EXTENT TEST - INPUT/OUTPUT SUPERVISOR'    66961021
*********************************************************************** 66962020
*                                                                     * 66963020
*                  DIRECT ACCESS EXTENT TEST SUBROUTINE               * 66964020
*                                                                     * 66965020
*    FUNCTION  ENSURE THAT THE SEEK ADDRESS WHICH IS GOING TO BE      * 66966020
*              ACCESSED FOR THIS REQUEST LIES WITHIN THE DATA SET     * 66967020
*              EXTENTS DEFINED IN THE DEB.                            * 66968020
*                                                                     * 66969020
*    ENTRY PT  EXTTST  FROM DIRECT ACCESS SIO MODULES.                * 66970020
*                                                                     * 66971020
*    EXITS     TO CALLING ROUTINE ON LNKRG2 IF NORMAL REQUEST         * 66972020
*              TO DEQUE AND ABNORMAL END APPENDAGE IF EXTENT ERROR.   * 66973020
*              TO DEQUE AND INT024 IF REQUEST IS TO BE IGNORED.       * 66974020
*                                                                     * 66975020
*    OPERATION CHECK THE SEEK ADDRESS IN THE UCB TO ENSURE IT IS      * 66976020
*              VALID.  A VALID SEEK ADDRESS IS NOT LOWER THAN THE     * 66977020
*              START OF THE EXTENT, NOR HIGHER THAN THE END OF IT.    * 66978020
*              FOR A DATA CELL, THE BIN NUMBER IN THE UCB IS EQUAL    * 66979020
*              TO THE BIN NUMBER IN THE DEB.  FOR SPLIT CYCLINDER     * 66980020
*              ALLOCATION, THE TRACK NUMBER IS ALTERED, IF NEEDED, SO * 66981020
*              THAT IT FALLS WITHIN THE TRACK BOUNDARIES OF THE DATA  * 66982020
*              SET. IF THE SEEK ADDRESS IS INVALID, THE END OF EXTENT * 66983020
*              APPENDAGE IS ENTERED, AND IT DETERMINES SUBSEQUENT     * 66984020
*              ACTION. THE REQUEST MAY BE                             * 66985020
*                MARKED WITH THE EXTENT ERROR CODE - X'42' - AND SENT * 66986020
*                TO THE ABNORMAL END APPENDAGE.                       * 66987020
*                POSTED NORMALLY AND DEQUEUED.                        * 66988020
*                VALIDITY CHECKED AGAIN                               * 66989020
*                                                                     * 66990020
*********************************************************************** 66991020
         SPACE 2                                                  20201 66992020
*    FIND THE PROPER DEB EXTENT                                   20201 66993020
EXTTST   SR    WKREG2,WKREG2            INITIALIZE WORK REG       20201 66994020
         IC    WKREG2,UCBSKA(UCBREG)    GET EXTENT M              20201 66995020
.CEX010  SLL   WKREG2,4                 FORM INDEX TO EXTENT      20201 67000020
.CEX020  LA    WKREG1,DEBEXTNT(WKREG2,DEBREG) POINT AT EXTENT     20201 67001020
         SPACE 1                                                  20201 67002020
*    GO TO THE EOE APPENDAGE IF THE SEEK ADDRESS IS NOT BETWEEN   20201 67003020
*    THE EXTENT START AND END ADDRESSES                           20201 67004020
EXTTST1  CLC   UCBSKA+3(4,UCBREG),DEBST(WKREG1)  COMPARE WITH STA 20201 67015020
         BC    4,XCP03E                 BR-LOWER THAN LOW ADDRESS 20201 67016020
         CLC   UCBSKA+3(4,UCBREG),DEBEND(WKREG1)  TEST END LIMIT  20201 67017020
         BC    2,XCP03E                 BR- HIGHER THAN END LIMIT 20201 67018020
         AIF   (&D2321).DCEL001                                   20201 67019020
         CLC   UCBSKA+1(2,UCBREG),DEBBB(WKREG1)  BB EQUAL         20201 67020020
         BC    7,XCP03E                 NO-EXTENT ERROR           20201 67021020
.DCEL001 SPACE 1                                                  20201 67022020
*    RETURN TO CALLER IF NOT SPLIT CYLINDER ALLOCATION            20201 67023020
         TM    DEBOPFL(DEBREG),DEBSCA   TEST FOR SPLIT CYLINDER   20201 67024020
         BCR   8,LNKRG2                 RETURN TO CALLER          20201 67025020
         CLC   UCBSKA+5(2,UCBREG),DEBST+2(WKREG1)  TRACK ADDR L.T 20201 67026020
         BC    4,XCP161A                YES  -RESET TO TOP OF EXT 20201 67027020
         CLC   UCBSKA+5(2,UCBREG),DEBEND+2(WKREG1)   TRK ADDR G.T 20201 67028020
         BCR   8+4,LNKRG2               RETURN TO CALLER          20201 67029020
XCP161A  MVC   UCBSKA+5(2,UCBREG),DEBST+2(WKREG1)  RESET TO TOP O 20201 67030020
         BCR   15,LNKRG2                RETURN TO CALLER          20201 67031020
         SPACE 1                                                  20201 67032020
*    EXIT TO THE EOE APPENDAGE                                    20201 67033020
XCP03E   ST    LNKRG2,EXTSAV            SAVE RETURN ADR ACROSS APG20201 67034020
         ST    LCHREG,LCHWDSV           SAVE LCH REG           @SA78136 67034518
         L     APBSRG,DEBAPG-1(DEBREG)  GET APG VECTOR TABLE      20201 67035020
         L     APBSRG,APGEOE(APBSRG)    GET EOE APPENDAGE VECTOR  20201 67036020
         BALR  LNKRG2,APBSRG            TO END OF EXTENT APPENDAG 20201 67037020
         SPACE 1                                                  20201 67038020
*    DEFINITION OF EOE APPENDAGE - IOS INTERFACE                  20201 67039020
*    INPUT     TSTREG,IOBREG,DEBREG,DCBREG,UCBREG,                20201 67040020
*              LNKRG2(RET ADDR),APBSRG(BASE ADDR)                 20201 67041020
*    REGS CHANGED  WKREG1,WKREG2,WKREG3,LCHREG                    20201 67042020
         SPACE 3                                                  20201 67043020
*    END OF EXTENT APPENDAGE RETURN VECTOR TABLE                  20201 67044020
*                                                                 20201 67045020
         BC    15,XCP167                EXTENT ERROR RETURN       20201 67046020
         BC    15,XCP03F                SKIP RETURN DEQUEUE RQE   20201 67047020
*        BC    15,EXTTST5               TRY AGAIN EXIT            20201 67048020
         SPACE 3                                                  20201 67049020
*    RETRY WITH NEW SEEK ADDRESS                                  20201 67050020
EXTTST5  L     LNKRG2,EXTSAV            REINITIALIZE RETURN REG   20201 67051020
         L     LCHREG,LCHWDSV           RESTORE LCH REG        @SA78136 67051518
         BC    15,EXTTST                RETRY EXTENT TEST         20201 67052020
         SPACE 1                                                  20201 67053020
*    IGNORE THIS REQUEST. DEQUEUE RQE,POST NORMAL AND RETURN RQE  20201 67054020
XCP03F   LA    LNKRG2,INT024            POST RETURN ADDRESS       20201 67055020
         BC    15,XCP167A               TO RESET PENDING FLAGS OR 20201 67056020
         SPACE 1                                                  20201 67057020
*    ILLEGAL REQUEST. DEQUEUE RQE AND GO TO ABNORMAL APPENDAGE    20201 67058020
XCP167   MVI   IOBCOD(IOBREG),EXTERR    EXTENT ERROR CODE         20201 67059020
         LA    LNKRG2,INT058            DEQUE RETURN ADDR.        20201 67060020
XCP167A  NI    UCBFL1(UCBREG),FF-UCBERR CLEAR UCB ERROR FLAG     A27691 67061020
         NI    IOBFL1(IOBREG),FF-IOBERR RESET FLAG                20201 67062020
         BC    15,XCPPDQ                REQ. REQUEST              20201 67063020
    TITLE 'UNIT RECORD AND TP SIO ROUTINE - INPUT/OUTPUT SUPERVISOR'    67064021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 67080019
*                                                                     * 67140019
*        SIO MODULE FOR UNIT RECORD OR TELECOMMUNICATION EQUIPMENT    * 67200019
*                                                                     * 67260019
*  FUNCTION    DETERMINE ENTRY PRINT TO SIO SUBROUTINE, AND CCW ADDRESS 67320019
*                                                                     * 67380019
*     ENTRY    XIOWR   FROM SELECT SUBROUTINE BY DEVICE TABLE ENTRY   * 67410021
*                      FOR PRINTERS WITH EXPANDED SENSE               * 67440021
*              XIOUR   FROM SELECT SUBROUTINE BY DEVICE TABLE ENTRY   * 67470021
*                      FOR UNIT RECORD                                * 67500019
*              XCP121  FROM SELECT SUBROUTINE BY DEVICE TABLE ENTRY   * 67560019
*                      FOR TELEPROCESSING DEVICES                     * 67620019
*                                                                     * 67680019
*     EXITS    XCP130  TO SIO SUBR. FOR IMMEDIATE COMMANDS FROM ERR RTN 67740019
*              XCPSIO  TO SIO SUBR. FOR NORMAL START                  * 67800019
*                                                                     * 67860019
* OPERATION    CHECK IOB MODIFIER 1 FLAG, YES GO TO SIO SUBR. IMMED.  * 67920019
*              COMMAND ENTRY                                          * 67980019
*              LOAD WKREG1 WITH THE IOB RESTART ADDRESS               * 68040019
*              CHECK IF IOB RESTART FLAG IS ON, NO REPLACE RESTART WITH 68100019
*              START ADDRESS IN WKREG1 AND GO TO NORMAL ENTRY OF SIO  * 68160019
*                                                                     * 68220019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 68280019
         SPACE 4                                                        68340019
XIOWR    EQU   *                        NEW UNIT RECORD                 68342021
         AIF   (&P3211 EQ 0).P321100                             A44146 68345021
         TM    UCBFL7(UCBREG),STPPRNT   HAS CANCEL KEY BEEN HIT         68350021
         BC    8,XIOUR                  NO - CONTINUE SIO        A44146 68355021
         TM    UCBFL5(UCBREG),UCBNALOC  DEV OWNED BY OLTEP      SA64237 68355418
         BC    1,XIOUR             YES, SKIP CANCEL             SA64237 68357418
         L     WKREG2,UCBSNADR-1(UCBREG) GET PTR TO SENSE DATA @SA78519 68358418
         MVI   IOBCSW+4(IOBREG),CSWDVE+CSWUCK SET DEVICE END,    A44146 68360021
*                                       UNIT CHECK INTO IOBCSW   A44146 68365021
         STH   TSTREG,UCBLTS(UCBREG)    SET UP RQE IN UCB        A44146 68370021
         BC    15,INTS02H               DEQUE RQST, SEND TO ERP  A44146 68385021
         SPACE 1                                                        68390021
.P321100 ANOP                                                    A44146 68395021
XIOUR    TM    IOBFL1(IOBREG),IOBMD1    IMMEDIATE OPERATION FOR ERROR   68400019
*                                       ROUTINE                         68460019
         BC    1,XCP130                 YES TO START UP  ROUTINE        68520019
XCP121   L     WKREG1,IOBRST-1(IOBREG)  LOAD RESTART ADDRESS            68580019
         TM    IOBFL1(IOBREG),IOBSRS    IS RESTART FLAG ON              68640019
         BC    1,XCP120                 BR- TO SKIP NEXT INSTRUCTION    68700019
         L     WKREG1,IOBST-1(IOBREG)   LOAD START ADDRESS              68760019
XCP120   DS    0C                                                       68820019
         BC    15,XCPSIO                TO START UP DEVICE       BBBBBB 68880019
         TITLE 'COMMON SIO ROUTINE - INPUT/OUTPUT SUPERVISOR'           68940021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 69000019
*                                                                     * 69060019
*              SIO SUBROUTINE                                         * 69120019
*                                                                     * 69180019
*  FUNCTION    ISSUE THE SIO COMMAND FOR ALL I/O REQUESTS             * 69240019
*                                                                     * 69300019
* ENTRY        XCPSIO  COMMON ENTRY FROM DEVICE DEPENDENT SIO MODULES * 69360019
*    POINTS    XCP130  TO PICK UP IMMEDIATE COMMAND OR REPOSITIONING  * 69420019
*                      OP CODES FROM ERROR ROUTINES                   * 69480019
*              XCP110  FROM DIRECT ACCESS SIO ROUTINE TO START        * 69540019
*                      DATA TRANSFER                                  * 69600019
*              XCP111  IS THE STAND ALONE SEEK ENTRY FROM DA SIO MODULE 69660019
*                      SINCE IT EXPECTS CONTROL BACK, IT LOADS LNKRG3 * 69720019
*                      WITH IT'S OWN RETURN ADDRESS                   * 69780019
*                                                                     * 69840019
*     EXITS    VIA LNKRG3 TO POST SIO OR RETURN TO DEV. DEP. SIO MODULE 69900019
*              XCPPDQ  (SIO APP. SKIP RETURN) DEQUES REQUEST AND RETURN 69960019
*                                                                     * 70020019
* OPERATION    1. THE CAW IS SET UP THEN TEST IF ERROR ROUTINE IS IN  * 70080019
*                 CONTROL, IF YES SKIP 2                              * 70140019
*              2. LINK TO THE SIO APPENDAGE (DEB) RETURN VIA LNKRG2 TO* 70200019
*                 SIO APPENDAGE VECTOR TABLE FOR NORMAL OR SKIP RETURN* 70260019
*              3. NORMAL PROCESSING THE SIO IS ISSUED, IF THE RESULT IS 70320019
*                 BUSY (COND. CODE) SET CSW TO REFLECT CONTROL          70380019
*                 UNIT BUSY.                                            70440019
*              4. STORE THE CC, ILC, AND PROG. MASK IN IOB, STORE THE * 70500019
*                 CHANNEL AND UNIT ADDRESS AND THE RQE IN THE UCB.    * 70590019
*              5. SET THE CC TO REFLECT THE SIO CC AND EXIT VIA LNKRG3* 70680019
*                                                                     * 70740019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 70800019
         SPACE 2                                                   IMP2 70860019
*   ERROR RTN WILL USE THIS CODE FOR IMMEDIATE OPERATIONS               70920019
*   IT USES THE MODIFER BITS IN THE IOB FOR THE CCW OP CODE             70980019
XCP130   MVC   SYSIMD(1),IOBMDB(IOBREG) OP CODE TO STAND ALONE CCW      71040019
         LA    WKREG1,SYSIMD            GET ADDRESS OF STAND ALONE CCW  71100019
         SPACE 2                                                        71160019
XCPSIO   LA    LNKRG3,XCPPIO            LOAD RETURN REGISTER            71220019
XCP111A  DS    0C                                                       71280019
XCP111   ST    WKREG1,CAWLOC            PLACE CCW ADDRESS INTO CAW      71340019
XCP111B  TM    IOBFL1(IOBREG),IOBERR    ERP IN CONTROL                  71400019
         AIF   (&TWOSW EQ 0).TWS150                              BBBBBB 71460019
         BC    8,XCP111C                NO-GO TO APPENDAGE       BBBBBB 71520019
         TM    UCBTYP+2(UCBREG),DSKTYP  DA DEVICE               SA71587 71530018
         BC    8,XCP111D                NO, DONT CHECK FOR DAVV SA71587 71532018
         TM    UCBFL4(UCBREG),UCBVVR    IS DAVV IN CONTROL       A42468 71540021
         BC    1,XCP110                 YES, NO TEST FOR ERR KEY A42468 71560021
XCP111D  TM    DCBFL(DCBREG),DCBIEK     TEST FOR IOS ERROR KEY  SA71587 71580018
         BC    8,XCP110                 NO-BYPASS APPENDAGE      BBBBBB 71640019
*    IF THE IOBERR FLAG IS ON AND THE USER IS NOT USING IBM      BBBBBB 71700019
*    ERROR ROUTINES, THIS MUST BE THE RETRY OF A PREVIOUS        BBBBBB 71760019
*    CONDITION CODE 3.  FLAGS IN THE USER'S CONTROL BLOCKS MUST  BBBBBB 71820019
*    BE RE-INITIALIZED SO THAT THE CC3 IS TRANSPARENT TO HIM.    BBBBBB 71880019
         NI    DCBFL(DCBREG),FF-DCBPER  RESET DCB ERROR FLAG     BBBBBB 71940019
         NI    IOBFL1(IOBREG),FF-IOBERR-IOBEX  IOB ERR FLAGS    SA49357 72000021
         AGO   .TWS155                                           BBBBBB 72060019
.TWS150  BC    1,XCP110                 YES-BYPASS APPENDAGE     BBBBBB 72120019
.TWS155  ANOP                                                    BBBBBB 72180019
XCP111C  L     APBSRG,DEBAPG-1(DEBREG)  GET APPENDAGE VECTOR TABLE ADDR 72240019
         L     APBSRG,APGSIO(APBSRG)    GET SIO APPENDAGE ADDRESS       72300019
         ST    LCHREG,LCHWDSV           SAVE LCH ADDR                   72350021
         BALR  LNKRG2,APBSRG            TO SIO APPENDAGE                72360020
         SPACE 1                                                        72420019
*    DEFINITION OF SIO APPENDAGE - IOS INTERFACE                 BBBBBB 72480019
*    INPUT     TSTREG,IOBREG,DEBREG,DCBREG,UCBREG,               BBBBBB 72540019
*              LNKRG2(RET ADDR),APBSRG(BASE ADDR)                BBBBBB 72600019
*    REGS CHANGED  WKREG1,WKREG2,LCHREG                          BBBBBB 72660019
         SPACE 1                                                        72720019
*********************************************************************** 72780019
*                                                                     * 72840019
*        SIO APPENDAGE RETURN VECTOR TABLE                            * 72900019
*                                                                     * 72960019
         BC    15,XCP110A               NORMAL RETURN-TO SIO EXECUTION  73020019
         SPACE 1                                                        73080019
*   SKIP SIO RETURN                                                     73140019
         LA    LNKRG2,INT024B           LOAD RETURN ADDRESS      BBBBBB 73200019
         BC    15,XCPPDQ                TO DEQUEUE                      73320019
*                                                                     * 73380019
*********************************************************************** 73440019
         SPACE 1                                                        73500019
XCP110A  DS    0H                                                BBBBBB 73510019
         L     LCHREG,LCHWDSV           RESTORE LCH ADDR                73520021
XCP110   MVI   CAWLOC,ZERO              CLEAR PROTECTION TAG     BBBBBB 73560019
         AIF   (&PROTECT EQ 0).STIOS3L                                  73620019
*  THE FOLLOWING TEST WILL DETERMINE IF A DISK ERROR ROUTINE IS         73680019
*  PREPARING A READ HA AND READ R0 COMMAND.                             73740019
         TM    UCBFL1(UCBREG),UCBERR    IS ERROR ROUTINE IN CONTROL     73800019
         BC    8,XCP110C                NO.  BYPASS NEXT TEST           73860019
         TM    IOBFL2(IOBREG),IOBHAR0   ERROR RTN READING R0            73920019
         BC    1,XCP110B                YES-SKIP PROT.KEY               73980019
         AIF   (&TCBTYP LT 2).CAWH      NOT MVT, SKIP            A24739 74040019
XCP110C  MVZ   CAWLOC(1),TSTKEY(TSTREG)  SET PROTECTION KEY             74100019
         AGO   .STIOS3L                                                 74160019
.CAWH    ANOP                                                           74220019
XCP110C  MVZ   CAWLOC(1),DEBPRT(DEBREG)  MOVE PROTECT TAG TO CAW        74280019
.STIOS3L ANOP                                                           74340019
XCP110B  DS    0H                                                  IMP4 74400019
         SIO   0(UAREG)                 START UP DEVICE            TEST 74760021
         BALR  WKREG1,0                 GET RIGHT HALF OF PSW    A27691 74860019
         SRL   WKREG1,24                SHIFT CC TO LOW BYTE     BBBBBB 74960019
         STC   WKREG1,IOBCC(IOBREG)     STORE CC,ILC, AND PROG. MASK    75180019
         AIF   (&ASR EQ 0).ASR1         CHANNEL CHECK HANDLER       CCH 75210019
         MVI   CATAPP,CATSIO .          SET CCH CODE FOR SIO MODULE CCH 75240019
.ASR1    AIF   (&TCBTYP EQ 0).GTF1                                M0120 75250021
         SPACE 1                                                  21014 75270721
*   GTF SIO TRACE - IOS INTERFACE                                 21014 75271421
*   INPUT   UAREG,WKREG1(SIO C.C.),CAW,CSW                        21014 75272121
         HOOK  EID=IHLMSIO              TRACE SIO USING GTF       21014 75272821
.GTF1    AIF   (&TRACE EQ 0).STIOS1A                              21014 75273521
         L     ICREG,TRACON             LOAD ADDRESS OF TRACE           75300019
         BALR  WKREG2,ICREG             TO TRACE START I/O              75360019
         SPACE 1                                                   RL19 75420019
*    DEFINITION OF TRACE - IOS INTERFACE                         BBBBBB 75480019
*    INPUT     ICREG(BASE ADDR),UAREG,WKREG1(SIO C.C.),CAW,CSW   BBBBBB 75540019
*              WKREG2(RET ADDR)                                  BBBBBB 75600019
*    REGS CHANGED  WKREG1                                        BBBBBB 75660019
         SPACE 1                                                   RL19 75720019
         SR    ICREG,ICREG              CLEAR THE ICREG                 75780019
.STIOS1A AIF   (&RESREL EQ 0).RR004AA                           SA54451 75800021
         LH    WKREG2,UCBCHA(UCBREG) .  SET REG NEG IF UCBHLT ON M6152  75820020
.RR004AA ANOP                                                    M6152  75840020
         STH   UAREG,UCBCHA(0,UCBREG)   SET UP CURRENT PATH     SA54451 75870021
*                                       RESET HIO & SMD IF ON      IMP5 75960019
         STH   TSTREG,UCBLTS(0,UCBREG)  SAVE RQE ADDRESS           P540 76020019
         AIF   (&M65MP EQ 0).MPB021                                MP1A 76260019
         LR    APBSRG,UCBREG       TRANSFER UCB POINTER            MP1A 76320019
         S     APBSRG,NEGDISP      GET NEG. DISPL. IN UCB          MP1A 76380019
         NI    UCBFL3(APBSRG),X'F7'    CLEAR IOCPUID                    76440019
         OC    UCBFL3(1,APBSRG),IOCPUID+3  PUT IOCPUID IN UCB      MP1A 76500019
.MPB021  ANOP                                                           76560019
XCP113   L     WKREG1,IOBCC(0,IOBREG)   RE-INSERT SIO CC         A27691 76620019
         SPM   WKREG1                   INTO PSW                 A27691 76680019
         BALR  LNKRG3,LNKRG3            TO RETURN TO REQUESTING RTN     76740019
         TITLE 'POST SIO ROUTINE - INPUT/OUTPUT SUPERVISOR'             76800021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 76860019
*                                                                     * 76920019
*              POST SIO ROUTINE                                         76980019
*                                                                     * 77040019
*    FUNCTION  HANDLE CONDITION CODE RESULTING FROM SIO INSTRUCTION.  * 77080019
*                                                                     * 77120019
*    ENTRY POINTS  XCPPIO  FROM SIO SUBROUTINE                        * 77160019
*                  XCPPIO1 FROM DA SIO  MODULE                        * 77200019
*                  XCP056E FROM CCH RETURN VECTOR TABLE               * 77240019
*                                                                     * 77280019
*    OPERATION HANDLE EACH CONDITION CODE AS FOLLOWS -                * 77320019
*                                                                     * 77360019
*        CC=0, SUCCESSFUL SIO -                                       * 77400019
*          SET UCB BUSY AND POST FLAGS, SAVE UCB ADDRESS FOR FAST UCB * 77440019
*          LOOKUP, SAVE CURRENT PATH IN UCBCHM FILED, DEQUEUE RQE,    * 77480019
*          AND RETURN ON LNKRG1 TO SVC EXIT OR CHANNEL RESTART.       * 77520019
*                                                                     * 77560019
*        CC=1,CSW STORED - EXAMINE STATUS -                           * 77600019
*          INCREMENT BY EIGHT THE COMMAND ADDRESS IN THE CSW.         * 77640019
         AIF   (&ASR EQ 0 OR &M65MP EQ 1).ASRCL01                 21111 77650021
*         IF CHANNEL LOGOUT PENDING - EXIT VIA LNKRG2                 * 77660021
.ASRCL01 ANOP                                                     21111 77670021
*          IF CATASTROPHIC ERROR, GO TO SERR01                        * 77680019
*          IF BUSY + CUE, TRY REQUEST AGAIN - RETURN ON LNKRG1+8      * 77720019
*          IF BUSY + SMD, SET UCBCUB FLAG, RETURN TO TCH              * 77760019
*          IF BUSY + DVE + ATT'N, GO TO ATTENTION INTERFACE           * 77800019
*          FOR ANY OTHER BUSY CONDITIONS, RETURN ON LNKRG1+8          * 77840019
*          ALL OTHER STATUS, ENTER INTERRUPT SPVSR. AT INT005         * 77880019
*                                                                     * 77920019
*        CC=2, CHANNEL BUSY -                                         * 77960019
*          SET UCBCUB FLAG, RETURN TO TCH.                            * 78000019
*                                                                     * 78040019
*        CC=3, CHANNEL OR CONTROL UNIT NON-OPERATIONAL -              * 78080019
*          INCREMENT BY EIGHT THE COMMAND ADDRESS IN THE CSW.         * 78120019
*          IF THIS IS THE FIRST TIME THAT CC 3 WAS ENCOUNTERED ON     * 78160019
*          THIS PATH, SET 'UNIT CHECK' AND 'INTERVENTION REQUIRED'    * 78200019
*          BITS IN THE IOB AND EXIT TO INTS02G SO THAT A MESSAGE MAY  * 78240019
*          BE ISSUED.                                                 * 78280019
*          IF THIS IS NOT THE FIRST CC3 ON THIS PATH, SET UCBCUB FLAG * 78320019
*          IN THE UCB AND RETURN TO TCH.                              * 78360019
*                                                                     * 78400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 78720019
         SPACE 2                                                        78780019
XCPPIO   BC    4+2+1,XCPPIO2            BRANCH IF CC=1,2 OR 3    A27691 78880019
         SPACE 1                                                 A26051 79020019
*    CC=0 PRESENTED ON SIO                                       A26051 79080019
         OI    UCBFL1(UCBREG),UCBBSY+UCBPST SET DEV BSY AND STARTED     79110019
XCPPIO1  IC    ICREG,UCBCHA(0,UCBREG) . SAVE THIS UCB            A27691 79140019
         AR    ICREG,ICREG .            ADDRESS FOR              A27691 79170019
         STH   UCBREG,UCBSAVE(ICREG) .  FAST LOOKUP              A27691 79200019
         AIF   (&M65MP EQ 0).TBS100                                     79230019
         OI    CHAN0-IEAQFX00(ICREG),CHBSY SET CHANNEL BUSY      A26051 79260019
.TBS100  AIF   (&TWOSW EQ 0 OR &APR EQ 1).TWOS2                  A27691 79360019
         SPACE 1                                                  19022 79800019
*   RESET PATH IND. IF THERE WAS A PREVIOUS CC 3 ON THAT PATH     19022 79860019
         OC    UCBCHM(1,UCBREG),PATHMSK SET ON CURRENT PATH       19022 79920019
         XC    UCBCHM(1,UCBREG),PATHMSK RESET INDICATOR           19022 79980019
.TWOS2   BAL   LNKRG2,XCPPDQ            GO DEQ REQUEST           A27691 79990019
         SPACE 1                                                 A27691 80000019
*    EXIT FROM SVC OR RETURN TO CHANNEL SEARCH                   A27691 80010019
         IECLNK1 ,BCR,15,LNKRG1,,,,&TBASE                        A27691 80020019
         SPACE 1                                                 A27691 80030019
*    CC=1 (CSW STORED), CC=2 (CH BUSY) OR CC=3 (CH OR CU INOP)   A27691 80040019
XCPPIO1A DS    0H                                                 M2959 80040619
XCPPIO2  BC    2,XCP054D                BRANCH IF BUSY            M2959 80043019
         SPACE 1                                                 A27691 80060019
*    CC=1 (CSW STORED) OR CC=3 (CH OR CU INOP)                   A27691 80070019
*    CARE SHOULD BE TAKEN NOT TO CHANGE THE CC  WITH ANY FIXES    M1647 80070421
*      OR ADDITIONS TO THE FOLLOWING CODE.                        M1647 80070821
         AIF   (&ASR EQ 0 OR &M65MP EQ 1).ASRCL00 LOGOUT PENDING  21111 80072021
         MVC   CAWLOC(1),CSWLOC         SAVE POSS LOG PEND COND   M1647 80074021
.ASRCL00 ANOP                                                     21111 80076021
         L     WKREG1,CAWLOC            GET CCW ADDRESS          A27691 80080019
         LA    WKREG1,CCWLN(WKREG1)     INCREMENT CSW FOR ERP     M1647 80090021
         ST    WKREG1,CSWLOC            SET UP FOR INT. SAVE     A27691 80100019
         AIF   (&ASR EQ 0 OR &M65MP EQ 1).NOLOG00  NO LOGOUT      M1647 80102021
         MVC   CSWLOC(1),CAWLOC         RESTORE POSS LOGOUT PEND  M1647 80104021
.NOLOG00 ANOP                                                     M1647 80106021
         MVC   IOBCSW+1(7,IOBREG),CSWLOC+1                       A27691 80110019
         BC    1,XCP054                 BRANCH IF INOP. CC       A27691 80120019
         SPACE 1                                                 A27691 80130019
*    CC=1 (CSW STORED) DETERMINE CAUSE OF CSW STORED             A27691 80140019
XCPPIO3  LR    LNKRG2,REG0              SET TCH RETURN           A27691 80150019
         AIF   (&ASR EQ 0 OR &M65MP EQ 1).ASRCL02                 21111 80150821
         TM    CSWLOC,CSWCLP            CHANNEL LOGOUT PENDING    21111 80151621
         BCR   7,LNKRG2                 EXIT TO TEST CHANNEL      21111 80152421
.ASRCL02 SPACE 1                                                  21111 80153221
*    SET POST AND BUSY FLAGS FOR INTERRUPT HANDLER AND CCH        M4756 80154019
         OI    UCBFL1(UCBREG),UCBBSY+UCBPST SET POST AND BUSY     M4756 80156019
         TM    CSWLOC+5,CSWCTK+CSWICK+CATCCH  CAT. ERRORS        BBBBBB 80160019
         L     APBSRG,IECPL2            GET TEMP BASE REG      @SA77644 80170018
         BC    7,SERR01-IECCPL02(APBSRG) YES, GO HANDLE THEM   @SA77644 80175018
XCP056E  TM    CSWLOC+4,CSWBSY          STAT CAUSED BY PREV SIO  A27691 80180019
         BC    8,XCP056C                NO, GO INSPECT STATUS    A27691 80190019
         SPACE 1                                                 A27691 80200019
*   BUSY BIT INSPECTION BRANCH CODE                                     80400019
         NI    UCBFL1(UCBREG),FF-UCBBSY RESET UCB BUSY         @SA77621 80460018
         TM    CSWLOC+4,CSWUCK          UNIT CHECK             @SA77621 80470018
         BC    1,XCP056G                YES-DON'T RESET POST   @SA77621 80480018
         NI    UCBFL1(UCBREG),FF-UCBPST RESET UCB POST         @SA77621 80490018
XCP056G  OI    UCBFL1(UCBREG),UCBCUB    SET C.U. BUSY FLAG     @SA77621 80500018
         TM    CSWLOC+4,CSWCUE          TEST FOR CONTROL UNIT END       80520019
         BC    8,XCP056H                NO,CONTINUE            @SA78138 80580018
***************************************************************@SA78138 80590018
* THE FOLLOWING CODE WILL SETUP CHMSK TO RESTART THE CHANNEL  *@SA78138 80590718
* PATH THAT JUST RECEIVED SIO CC=1 WITH STATUS OF BUSY AND    *@SA78138 80591418
* CONTROL UNIT END. BECAUSE CONTROL UNIT ENDING STATUS MAY BE *@SA78138 80592118
* USED TO RESTART A DEVICE ASSIGNED TO A DIFFERENT LOGICAL    *@SA78138 80592818
* CHANNEL ON A CHANNEL PATH NOT IN COMMON WITH THE DEVICE     *@SA78138 80593518
* PRESENTING THE STATUS. THIS WOULD PREVENT CHANNEL RESTART   *@SA78138 80594218
* FOR THE ORIGINAL DEVICE. THIS CODE WILL FORCE CHANNEL       *@SA78138 80594918
* RESTART FOR ALL LOGICAL CHANNEL QUEUES WHICH THE PHYSICAL   *@SA78138 80595618
* CHANNEL IS DEFINED FOR.                                     *@SA78138 80596318
***************************************************************@SA78138 80597018
         IC    ICREG,UCBCHA(UCBREG)     GET PATH ADDRESS       @SA78138 80597718
         L     WKREG1,CHANBIT           GET CHANNEL BIT        @SA78138 80600018
         SRL   WKREG1,ZERO(ICREG)       DERIVE PSW EQUIVALENT  @SA78138 80610018
         O     WKREG1,CHANBIT           ANY CHANNEL TO RESTART @SA78138 80620018
         ST    WKREG1,CHANBIT           SAVE CHANNEL RESTART   @SA78138 80630018
    IECLNK1 ,BC,15,SELTAG,0,LNKRG1,,&TBASE                              80640018
XCP056H  LR    LNKRG2,REG0              SET TCH RETURN         @SA78138 80660018
         TM    CSWLOC+4,CSWSMD          STATUS MODIFIER SET             80700019
         AIF   (&M65MP EQ 1).MPB022A                                    80820019
         BCR   1,LNKRG2                 RETURN TO TEST CHANNEL          80880019
         AGO   .MPB022B                                                 80940019
.MPB022A BC    8,XCPPI04                NO, BRANCH AROUND        BBBBBB 81000019
         LR    WKREG1,UCBREG            COPY UCB ADDRESS          19022 81060019
         S     WKREG1,NEGDISP           POINT AT UCB PREFIX       19022 81120019
         TM    UCBFL3(WKREG1),UCBACU    IS THERE AN ALT C.U.      19022 81180019
         BCR   1,LNKRG2                 YES, RETURN TO TCH        19022 81240019
         IECLNK1 ,BC,15,SELBSY,0,LNKRG1,,&TBASE                   19022 81300019
         SPACE 1                                                  19022 81360019
.MPB022B ANOP                                                           81660019
XCPPI04  TM    CSWLOC+4,CSWDVE+CSWATN  BUSY ALONE                  IMP4 81720019
         BC    7,XCPPI04A               NO DON'T SET BUSY FLAG @SA77621 81810018
         OI    UCBFL1(UCBREG),UCBBSY    SET INTERRUPT EXPECTED   A27707 81860018
         IECLNK1 ,BC,15,SELBSY,0,LNKRG1,,&TBASE                  A27707 81910018
XCPPI04A TM    CSWLOC+4,CSWUCK          UNIT CHECK IN CSW?     @SA77621 81960018
         BO    INTATT2                  YES,LEAVE LNKRG1S AS IS@SA77621 82010018
         IECLNK1 XCPPI05,LA,LNKRG1,SELTAG,0,LNKRG1,,&TBASE       A27707 82080020
.TBS140  BC    15,INTATT2          TO ATTENTION ROUTINE-EXITS      TBSE 82200019
*                                       AFTER INSPECTION AT TRY AGAIN   82260019
         SPACE 1                                                        82320019
*    CC=3 (CH OR CU INOP) ISSUE MESSAGE IF NEEDED                BBBBBB 82350019
         SPACE 1                                                        82352021
*  THE COND CODE 3 MAY BE THE RESULT OF THE RQE BEING ON THE WRONG      82354021
*  LOGICAL CHANNEL.  IF THIS IS THE CASE, THE RQE WILL BE REMOVED       82356021
*  FROM THE WRONG LCH AND THE TASK WILL BE ABENDED.  AN INVALID         82358021
*  CONDITION EXISTS AND IT IS IMPOSSIBLE TO DETERMINE WHY.              82358421
XCP054   TM    XCPBTE,XCPCNT+XCPERR     INT OR ERR ENTRY                82360021
         BC    4,XCP054A                NO,CONTINUE CC3 HANDLING        82370021
         LA    LCHREG,0(LCHREG)         CLEAR HI BYTE           SA71384 82370421
         ST    LCHREG,LCHWDSV           SAVE LCH ADDR                   82372021
         BAL   LNKRG3,XCP064            INIT LCHREG                     82374021
         C     LCHREG,LCHWDSV           IS RQE ON PROPER LCH    SA71384 82376021
         BC    7,XCP054G                NO, GO DEQUEUE AND TERM TASK    82378021
XCP054A  DS    0C                                                  2745 82380021
         AIF   (&TWOSW EQ 0 AND &M65MP EQ 0).TWOS3               A26051 82440021
         AIF   (&APR EQ 1).TWOS2B                                 19022 82500019
         IC    ICREG,PATHMSK            GET PATH INDICATOR        19022 82560019
         IC    WKREG1,UCBCHM(0,UCBREG)  GET PREVIOUS CC 3         19022 82620019
         NR    ICREG,WKREG1             WAS IT ON THIS PATH       19022 82680019
         BC    7,XCP054D                YES, NO MSG REQUIRED     BBBBBB 82740019
.TWOS2B  ANOP                                                    BBBBBB 82800019
         MVN   IOBCC(1,IOBREG),PATHMSK  INDIC PATH FOR ERROR RTN A27691 82860019
         TM    SRTESTAT(UCBREG),SYSCON  SYSRES OR CONSOLE               82920019
         BC    8,XCP054C                NO, ISSUE MESSAGE         M0807 82950020
         TM    UCBTYP+2(UCBREG),DSKTYP  TEST FOR SYSRES ONLY      M0807 82980020
         BC    1,XCP054D                YES, CAN'T ISSUE MSG      M0807 83010020
.TWOS3   ANOP                                                     M0807 83040020
XCP054C  MVI   IOBSNS(IOBREG),X'40'     SIMULATE INT. REQ.              83070020
         MVI   IOBCSW+4(IOBREG),CSWUCK  SET UNIT CHECK                  83100019
         BC    15,INTS02G              DEQUE RQST, SEND TO ERRTN   IMP3 83220019
         SPACE 1                                                        83280019
XCP054D  OI    UCBFL1(UCBREG),UCBCUB    SET C.U. BUSY FLAG       A27691 83360019
         LR    LNKRG2,REG0              SET FOR TCH RETURN       A27691 83440019
         BCR   15,LNKRG2                RETURN TO TCH            A27691 83520019
         SPACE 1                                                 A27691 83600019
XCP054G  L     LCHREG,LCHWDSV           RESTORE WRONG LCH ADDR IN REG   83650021
         L     APBSRG,LCHERRAD          GET LCH ERROR RTN ADDR          83660021
         BCR   15,APBSRG                GO ABEND TASK                   83670021
         SPACE 1                                                        83672021
*    IF ACCEPTED, DEQUEUE, THEN INSPECT STATUS FURTHER           A27691 83680019
XCP056C  BAL   LNKRG2,XCPPDQ            DEQUEUE BEFORE PROCESSING       83760019
         BC    15,INT008                EXAMINE STAT. AS INT.   SA52441 83960021
         TITLE 'COMMON DEQUEUE ROUTINE - INPUT/OUTPUT SUPERVISOR'       84960021
*              COMMON DEQUEUE ROUTINE                                 * 85060021
*                                                                     * 85160020
*   FUNCTION   TO DEQUEUE AN RQE FROM A LOGICAL CHANNEL QUEUE         * 85260020
*                                                                     * 85360020
*   ENTRY PTS  XCPPDQ   FROM DA SIO RTN                               * 85460020
*                       SKIP SIO RETURN FROM SIO APPENDAGE            * 85560020
*                       POST SIO                                      * 85660020
*                       CHANNEL RESTART                               * 85760020
*                       SENSE SUBROUTINE                              * 85860020
*                       INTERRUPT ERROR INTERFACE                     * 85960020
*              XCPDDRDQ FROM XERX02                                   * 86060020
*                       DDRRETRY                                      * 86160020
*                       DDR005                                        * 86260020
*                       DDRCANCL                                      * 86360020
*                                                                     * 86460020
*   EXITS      LNKRG2   TO RETURN TO CALLER                           * 86560020
*                                                                     * 86660020
         SPACE 1                                                 BBBBBB 86760020
XCPPDQ   DS    0C                                                       87360019
         TM    XCPBTE,XCPCNT+XCPERR     EXCP ALONE                      87480019
         BCR   4,LNKRG2                 YES-NO DQ.                      87540019
         BAL   LNKRG3,XCP064            GET LCH WRD.                    87600019
         AIF   (NOT &D2305).NOZUS2                                      87608020
         LR    REG0,UCBREG              SAVE UCB ADDR             20201 87616020
*              GO GET BASE UCB ADDRESS IN CASE 2305               20201 87624020
         L     WKREG2,AZUSRTN           GET SUBRTN ADDR           20201 87632020
         BALR  LNKRG3,WKREG2            GO GET BASE ADDR  IF 2305 20201 87640020
         BC    15,XCP091A               GO DEQUE RQE            SA65046 87642021
XCPDDRDQ LR    REG0,UCBREG              SAVE UCBREG IN REG0     SA65046 87644021
XCP091A  LR    WKREG1,LCHREG            INIT BACK LINK POINTER  SA65046 87646021
         AGO   .ZEUSDQ                                          SA65046 87646421
.NOZUS2  ANOP                                                           87648020
XCPDDRDQ LR    WKREG1,LCHREG            INIT BACK LINK POINTER    19022 87660019
.ZEUSDQ  ANOP                                                   SA65046 87710021
         ST    LCHREG,BLNKPTR          IN CASE NO DQ OCCURS        TPF1 87720019
         LA    LNKRG3,XCP091            SET RECURSING LINK REG     PRER 87780019
XCP091   LR    WKREG2,WKREG1            SAVE BACKLINK POINTER           87840019
         LH    WKREG1,TSTLNK(WKREG2)    GET ENTRY ADDRESS               87900019
         LTR   WKREG1,WKREG1     TEST FOR DUMMY                    CCHA 87960019
         BC    4,XCP092A                IT WASN'T HERE ANYWAY    A26116 88020019
         CR    WKREG1,TSTREG            COMPARE WITH RQE TO BE D.Q.'D   88080019
         BC    8,XCP093                 YES,TO DEQUEUE                  88140019
*   KEEP TRACK OF FIRST REQUEST IN LCH FOR THE UCB IN QUESTION          88200019
         CH    UCBREG,TSTUCB(0,WKREG1)  FOR THIS UCB                    88260019
         BCR   7,LNKRG3                 NO-SKIP                         88320019
*   ERP, PRIORITY, AND ORDERED ENQUEUEING REQUIRE THE QUEUE TO          88380019
*   CONTINUE SEARCH FROM THE TOP REQUEST FOR THE DEVICE.                88440019
XCP092   TM    BLNKPTR,LCHOUT           YES, IS LCH OUT OF ORDER        88500019
         BCR   1,LNKRG3                 BACK-LINK PTR OUT OF ORDER      88560019
         ST    WKREG2,BLNKPTR           SET TO HIGHEST POINT IN Q       88620019
         OI    BLNKPTR,LCHOUT           SET UP DATE INDICATOR           88680019
         BCR   15,LNKRG3                EXIT TO COMPLETE OR INTERM.     88740019
         SPACE 1                                                        88800019
XCP092A  ST    LCHREG,BLNKPTR           SET TO RESTART AT Q TOP  A26116 88860019
         AIF   (NOT &D2305).NOZUS3                                      88890020
         LR    UCBREG,REG0              RESTORE UCB ADDR          20201 88920020
.NOZUS3  BCR   15,LNKRG2                RETURN                   A26116 88950020
         SPACE 1                                                        88980019
XCP093   BAL   LNKRG3,XCP092            SET BACK-LINK PTR IF NEEDED     89040019
         AIF   (NOT &D2305).NOZUS4                                      89070020
         LR    UCBREG,REG0              RESTORE UCB ADDR          20201 89100020
.NOZUS4  MVC   TSTLNK(2,WKREG2),TSTLNK(TSTREG) RELINK ENTRIES           89130020
         TM    TSTLNK+1(TSTREG),DUMADR  TEST FOR LAST ENTRY IN Q        89160019
         BCR   8,LNKRG2                 EXIT- NO FURTHER UPDATE         89220019
         STH   WKREG2,LCHLTS(LCHREG)    UPDATE LAST IN QUEUE POINTER    89280019
         BCR   15,LNKRG2                EXIT                            89340019
         SPACE 1                                                        89400019
*  AN EMPTY QUEUE WILL HAVE ITS LCHWRD ADDRESS IN LTS WHEN EMPTIED      89460019
         SPACE 2                                                        89510021
*        THE IOS PATCH AREA HAS 15 WORDS AVAILABLE FOR ZAPS NEEDED      89560018
*        TO CORRECT OR TRAP PROBLEMS.  THIS AREA HAS ADDRESSABILITY     90560018
*        WITHIN IOS USING THE STANDARD BASE REGS.  THERE IS NO          91560018
*        INTERNAL OR EXTERNAL REFERENCE TO THIS AREA.                   92560018
         SPACE 2                                                        93560018
         DC    C'IOSPATCH-US07653'                             @SA78519 94560018
         BC    15,IOSPATCH                                              95560018
IOSPATCH DC    15F'0'                                                   96560018
         TITLE 'INTERRUPT HANDLER - INPUT/OUTPUT SUPERVISOR'            97560018
         MEND                                                           98560018
