         MACRO                                                          00062000
         IEECAWR &SIZE                                                  00064000
         TITLE 'IEECMAWR   COMMUNICATIONS TASK WAIT AND ROUTER'         00070021
* WAIT AND ROUTER (AWR)                                                 00100021
*                                                                       00150021
* THE FUNCTION OF THIS MODULE IS TO WAIT ON ALL COMMUNICATIONS ECB'S    00200021
* (SINGLE EVENT). IT RUNS AS A SUBTASK OF THE MASTER SCHEDULER TCB      00250021
* AND GIVES CONTROL TO THE ROUTER FUNCTION WHEN ANY OF THE ECB'S        00300021
* ARE POSTED.                                                           00350021
* THE ROUTER CHECKS THE ECB'S IN A PRIORITY SCHEME AS FOLLOWS-          00400021
* RMS,EXTERNAL,ATTENTION,I/O, WTO/R, DOM, AND LOG INITIALIZATION.THESE  00450021
* ECB'S ARE CHECKED IN SUCH A WAY THAT WHENEVER AN ECB IS POSTED AND A  00500021
* SERVICE IS PERFORMED, THE ROUTINE RETURNS TO THE BEGINNING (WREXT),   00550021
* CHECKS THE RMS ECB AND CONTINUES FROM THERE.  WHEN ALL                00600021
* ECB'S HAVE BEEN CHECKED, AND NOTHING IS POSTED, THE ROUTER RETURNS    00650021
* TO THE WAIT MODULE.                                                   00700021
*                                                                       00750021
* MODULE NAME- IEECMAWR                                                 00800021
*                                                                       00850021
* ENTRY POINT - IEECMWRT                                                00900021
*                                                                       00950021
* INPUT- POSTING OF ECB'S                                               01000021
*                                                                       01050021
* OUTPUT- SERVICING POSTED ECB'S BY GIVING CONTROL TO APPROPRIATE       01100021
*         ROUTINES                                                      01150021
*                                                                       01200021
* EXTERNAL ROUTINES -                                                   01250021
*        IGCR107B FOR RMS INTERRUPT                                     01300021
*        IGCXL07B FOR EXTERNAL INTERRUPT                                01350021
*        IEECMDSV FOR ATTENTION,I/O COMPLETE, AND OUTPUT                01400021
*        IEECMWSV FOR WTO/R SERVICE                                     01450021
*        IEECMDOM FOR DOM SERVICE                                       01500021
*        IGC0907B FOR SERVICE AFTER THE LOG HAS BEEN INITIALIZED        01550021
*                                                                       01600021
* EXITS- NONE                                                           01650021
*                                                                       01700021
* ATTRIBUTES- REFRESHABLE, REENTRANT                                    01750021
*                                                                       01800021
         EJECT                                                          01850021
         SPACE 5                                                        01900021
IEECMAWR CSECT                                                          01950021
*APARS                                                           A26818 02000021
*                                                                A26940 02050021
*OWNERSHIP    19372                                                 MCH 02100021
*MODULE CREATED FOR MCS - REL 18                                        02150021
         ENTRY IEECIRFC                                                 02200021
         ENTRY IEECIRUP                                                 02250021
         ENTRY IEECIR45                                                 02300021
         ENTRY WRABXLE                                                  02350021
         EXTRN IEECMDSV                                                 02400021
         EXTRN IEECMWSV                                                 02450021
         EXTRN IEECMDOM                                                 02500021
         USING CVTDSECT,10                                              02550021
R0       EQU   0                   WORKREG                              02600021
R1       EQU   1                   INIT-EIL BASE  ROUTER-PARAMETER REG  02650021
R2       EQU   2                   INIT-BASE DSECT REG  ROUTER-UCM BASE 02700021
R3       EQU   3                   INIT-UCM BASE  RTR-RESV FOR DEVSERV  02750021
R4       EQU   4                   INIT-WORKREG  ROUTER-MCS UCM BASE    02800021
R5       EQU   5                   INIT-WORKREG  ROUTER-INDEX REG       02850021
R6       EQU   6                   WORKREG                              02900021
R7       EQU   7                   WORKREG                              02950021
R8       EQU   8                   INIT-WORKREG  ROUTER-EIL BASE        03000021
R9       EQU   9                   BASE REG                             03050021
R10      EQU   10                  RESERVED FOR WTOSERV                 03100021
R11      EQU   11                  UCM ENTRY                            03150021
R12      EQU   12                     BXLE                              03200021
R13      EQU   13                   REGS                                03250021
R14      EQU   14                  RETURN REG                           03300021
R15      EQU   15                  BRANCH REG                           03350021
ZEROBYTE EQU   X'00'                                                    03400021
HEX40    EQU   X'40'                                                    03450021
EIGHTY   EQU   X'80'                                                    03500021
TWO      EQU   X'02'                                             A26818 03550021
FD       EQU   X'FD'                                             A26818 03600021
SWRTN    EQU   72                                                       03650021
ZERO     EQU   0                                                        03700021
ONE      EQU   1                                                        03750021
FOUR     EQU   4                                                        03800021
EIGHT    EQU   8                                                        03850021
SIXTEEN  EQU   16                                                       03900021
MASK255  EQU   255                 USE TO SWITCH BITS IN A MASK         03950021
TCBDAR   EQU   172                                                  DAR 04000021
DARREC   EQU   X'40'               SECONDARY RECURSION BIT          DAR 04050021
TCBPTR   EQU   8                                                    DAR 04100021
         USING BASE,R2                                                  04150021
         USING UCMXECB,R3                                               04200021
         DS    0D                                                       04250021
IEECIR45 DC    CL8'IEECMAWR'       THIS ROUTINE                         04300021
         DC    AL2(100)                THIS SERIES OF DC'S              04350021
         DC    X'00C0'                 FORM THE COMMUNICATION TASK      04400021
         DC    A(IEECMWRT)             REQUEST BLOCK                    04450021
         DC    XL4'00040000'       FLAG                                 04500021
         DC    A(IEECMWRT)         ENTRY PT TO THIS MODULE              04550021
         DC    A(0)                ZERO                                 04600021
         DC    V(IEACMTCB)         TCB                                  04650021
      EJECT                                                             04700021
*********************************************************************** 04750021
*                                                                     * 04800021
*        IEECMWRT GETS CONTROL DURING SYSTEM INITIALIZATION           * 04850021
*        IT SETS UP ENVIRONMENTAL REGISTERS FOR ALL COMMUNICATIONS    * 04900021
*        TASK RESIDENT ROUTINES, AND ISSUES A WAIT UNTIL              * 04950021
*        INITIALIZATION IS FINISHED.  IT THEN GIVES CONTROL           * 05000021
*        TO CTWSTART                                                  * 05050021
*                                                                     * 05100021
*********************************************************************** 05150021
IEECMWRT EQU   *                                                        05200021
         ENTRY IEECMAA0                                             MCH 05250021
         ENTRY IEECMAA1                                             MCH 05300021
IEECMAA0 EQU   *                                                    MCH 05350021
         BALR  R9,R0               SET UP BASE REGISTERS                05400021
         USING *,9                                                      05450021
         L     R10,CVTPTR              LOAD CVT POINTER                 05500021
         L     R3,CTWCUCM              LOAD UCM POINTER                 05550021
         ST    R3,CVTCUCB              STORE UCM PTR TO CVT             05600021
         L     R2,CVTMSER              GET MSER PTR                     05650021
         L     TCBPTR,ZERO(R10)    OBTAIN ADDRESS OF                DAR 05700021
         L     TCBPTR,FOUR(TCBPTR) CURRENT TCB                      DAR 05750021
         TM    TCBDAR(TCBPTR),DARREC DAR REINITIALIZED THIS TASK    DAR 05800021
         BO    CTWFIX              YES - BRANCH                     DAR 05850021
         LA    R1,BAIPL                SET TO WAIT ON ECB IN MS RES     05900021
*                                      DATA AREA FOR POST BY IEFSD569   05950021
         NI    ZERO(R1),ZEROBYTE   CLEAR WAIT-POST BYTE                 06000021
         WAIT  ECB=(R1)                                                 06050021
CTWFIX   LR    R2,R3                   RESTORE UCM PTR                  06100021
         DROP  R3                                                       06150021
         USING UCMXECB,R2                                               06200021
         NI    ASYN(TCBPTR),X'FE' .TURN OFF PROB. ASYN EXIT   BB A43808 06210021
*                                  BIT SO ROLL-DELETE WILL    BB A43808 06220021
*                                  WORK.                      BB A43808 06230021
ASYN     EQU   X'1D'                                          BB A43808 06240021
         L     R3,UCMVEA           INITIALIZE UCM ENTRY PTR             06250021
         LA    R5,UCMXECB          INITIALIZE                           06300021
         LA    R4,FOUR             UCM                                  06350021
         SR    R5,R4               PREFIX                               06400021
         L     R4,ZERO(R5)         BASE REG                             06450021
         L     R8,UCMLSTP          INITIALIZE EIL PTR                   06500021
         USING EIL,R8                                                   06550021
         USING UCMLIST,R11                                              06600021
         USING UCMMCENT,R4                                              06650021
*********************************************************************** 06700021
*                                                                     * 06750021
*        CTWSTART ISSUES A WAIT ON ALL COMMUNICATIONS ECB'S.          * 06800021
*        THIS BECOMES THE ENTRY POINT OF THE WAIT MODULE AFTER        * 06850021
*        IEECMWRT EXITS.                                              * 06900021
*                                                                     * 06950021
*********************************************************************** 07000021
CTWSTART EQU   *                                                        07050021
         LA    R1,EILSL                 POINT R1 TO ECB LIST            07100021
         LR    R6,R1                                                    07150021
ECBLOOP  EQU   *                                                        07200021
         L     R7,ZERO(R6)        ADDRESS THE ECB                       07250021
         NI    ZERO(R7),WAITOFF   TURN WAIT BIT OFF           BE A44624 07300021
WAITOFF  EQU   X'7F'                                          BE A44624 07310021
         TM    ZERO(R6),EIGHTY    IS THIS THE LAST ECB                  07350021
         BO    LASTECB            YES                                   07400021
         LA    R6,FOUR(R6)        NEXT ECB                              07450021
         B     ECBLOOP            TEST NEXT ECB                         07500021
LASTECB  EQU   *                                                        07550021
CTWAIT   WAIT  ECBLIST=(1)                                              07600021
      EJECT                                                             07650021
*                                                                       07700021
*                   ROUTER   MODULE                                     07750021
*                                                                       07800021
**********************************************************************  07850021
*                                                                     * 07900021
*        SERVICE EXTERNAL INTERRUPTS BY GOING TO IGCXL07B FOR         * 07950021
*        EVERY INTERRUPT                                              * 08000021
*                                                                     * 08050021
**********************************************************************  08100021
         SSM   DISABLE                                                  08150021
WREXT    EQU   *                                                  20061 08200021
RMSCHK   EQU   *                                                  20061 08250021
         TM    UCMRECB,POST        RMS ECB POSTED                 20061 08300021
         BZ    WREXT1              NO-CONTINUE NORMAL PROCESSING  20061 08350021
         LA    R1,ADRMSNAM         GET ADDRESS OF RMS MODULE      20061 08400021
         L     R0,UCMRECB          SAVE ADDRESS IN PARAMETER REG  20061 08450021
         XC    UCMRECB(FOUR),UCMRECB CLEAR ECB                    20061 08500021
         SVC   SWRTN               ISSUE SVC 72 TO ROUTER         20061 08550021
         B     WREXT               CONTINUE SEARCH FOR POSTED ECB 20061 08600021
WREXT1   EQU   *                                                  20061 08650021
         CLI   UCMXCT,ZERO         HAS EXTERNAL ECB BEEN POSTED   20061 08700021
         BE    WRATTN              NO, CHECK ATTENTION ECB              08750021
         SR    R6,R6                                                    08800021
         IC    R6,UCMXCT           GET NUMBER OF TIMES POSTED           08850021
         BCTR  R6,R0               DECREMENT BY ONE                     08900021
         STC   R6,UCMXCT           STORE NEW COUNT OF UNSERVICED POSTS  08950021
         MVC   UCMXSA+EIGHT(R8),WREXTNAM  NAME OF EXT. SWITCH RTN       09000021
         MVI   UCMXSA+SIXTEEN,HEX04     INDICATE EXTERNAL INTERRUPT     09050021
         LA    R1,UCMXSA+EIGHT                                          09100021
         SVC   SWRTN               SVC 72 - GO TO SWITCH RTN            09150021
         B     WREXT               SERVICE ANY UNSERVICED EXTERNAL INT. 09200021
**********************************************************************  09250021
*                                                                     * 09300021
*        GO THROUGH CONSOLE ENTRIES,AND WHENEVER AN ATTENTION IS      * 09350021
*        PENDING, GO TO ROUTINE WRATSERV.                             * 09400021
*                                                                     * 09450021
**********************************************************************  09500021
WRATTN   XC    UCMXECB(FOUR),UCMXECB   CLEAR EXTERNAL ECB               09550021
         TM    UCMAECB,POST        HAS ATTENTION ECB BEEN POSTED        09600021
         BZ    WRIOCOMP            NO,CHECK I/O ECB'S                   09650021
         TM    UCMSFLGS+ONE,TWO   WAS ATTN POSTED BY WTL         A26818 09700021
         BNO   WRALOOP1           NO - REGULAR ATTENTION         A26818 09750021
         LA    R1,EIGHT                                          A26818 09800021
         NI    UCMSFLGS+ONE,FD    TURN OFF FLAG                  A26818 09850021
         B     WRAWTLSV           GO TO DSV                      A26818 09900021
WRALOOP1 LM    R11,R13,UCMVEA     INITIALIZE BXLE UCM ENTRY REGS A26818 09950021
WRALOOP  TM    UCMSTS,UCMAF        IS ATTENTION PENDING FOR THIS ENTRY  10000021
         BNO   WRABXLE            NO,BRANCH TO GET NEXT ENTRY    A33847 10050021
         TM    UCMATR,ACTIVE      IS THIS DEVICE ACTIVE ?        A33847 10100021
         BO    WRATSERV            YES, BRANCH                          10150021
         NI    UCMSTS,MASK255-ATTN NO-TURN OFF ATTENTION FLAG    A33847 10200021
WRABXLE  BXLE  R11,R12,WRALOOP     NO,GET NEXT ENTRY                    10250021
         XC    UCMAECB(FOUR),UCMAECB    CLEAR ATTENTION ECB             10300021
**********************************************************************  10350021
*                                                                     * 10400021
*        GO THROUGH LIST OF I/O ECB'S, AND WHENEVER ONE IS POSTED     * 10450021
*        COMPLETE, GO TO ROUTINE WRIOSERV.                            * 10500021
*                                                                     * 10550021
**********************************************************************  10600021
WRIOCOMP LM    R11,R13,UCMVEA      GET BXLE ENTRY REGS                  10650021
         SR    R6,R6                                                    10700021
WRIOLOOP EQU   *                                                        10750021
         L     R7,EILIOL(R6)       GET ADDRESS OF THIS ENTRY'S ECB      10800021
         TM    ZERO(R7),POST       IS IT POSTED COMPLETE                10850021
         BO    WRIOSERV            YES, BRANCH                          10900021
WRIOBXLE LA    R6,FOUR(R6)         INCREMENT ECB PTR ADDRESS            10950021
         BXLE  R11,R12,WRIOLOOP    AND ENTRY ADDR TO DO NEXT ENTRY      11000021
         EJECT                                                          11050021
**********************************************************************  11100021
*                                                                     * 11150021
*        IF WE ARE STILL PROCESSING CONSOLE OUTPUT QUEUES,            * 11200021
*        CONTINUE PROCESSING BY GOING TO IEECMDSV WITH OUTPUT CODE.   * 11250021
*        (REGISTER 3 POINTS TO NEXT CONSOLE ENTRY TO BE PROCESSED)    * 11300021
*                                                                     * 11350021
**********************************************************************  11400021
WRDVSERV C     R3,UCMVEA           ARE WE IN THE MIDDLE OF 'DEVSERV'    11450021
         BNE   WROUTPUT            YES                        BG A43719 11460021
         TM    UCMSFLGS+ONE,UCMSYSJ NO, IS THERE H.C. TO DO   BG A43179 11470021
         BZ    WRWTO               NO CHECK WTO/R ECB         BG A43719 11480021
         NI    UCMSFLGS+ONE,MASK255-UCMSYSJ TURN OFF H.C.FLAG BG A43719 11490021
WROUTPUT EQU   *                                              BG A43719 11500021
         L     R15,ADDVSV          YES, GO BACK TO 'DEVSERV'            11550021
         SR    R1,R1               CODE = 0 FOR OUTPUT                  11600021
         BALR  R14,R15             GO TO 'DEVSERV'                      11650021
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         11700021
**********************************************************************  11750021
*                                                                     * 11800021
*        IF WE ARE NOT STILL PROCESSING CONSOLE OUTPUT QUEUES,        * 11850021
*        SERVICE A POSTED WTO/R ECB BY GOING TO IEECMWSV.             * 11900021
*        NOTE- WHEN IEECMWSV FINISHES QUEUEING, IT GOES TO IEECMDSV   * 11950021
*        TO START PROCESSING CONSOLE OUTPUT QUEUES. THIS GETS US      * 12000021
*        INTO THE PREVIOUS LOOP, AND THE WTO/R ECB IS NOT CHECKED     * 12050021
*        AGAIN UNTIL ALL CONSOLE QUEUES HAVE BEEN PROCESSED.          * 12100021
*                                                                     * 12150021
**********************************************************************  12200021
WRWTO    TM    UCMOECB,POST        IS WTO/R ECB POSTED                  12250021
         BZ    WRCLNUP             NO,DO NEXT SERVICE                   12300021
         XC    UCMOECB(FOUR),UCMOECB   YES,CLEAR ECB                    12350021
         L     R15,ADWTOSV         GET ADDRESS OF WTO/R SERVICE         12400021
         BALR  R14,R15             GO TO WTO/R SERVICE                  12450021
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         12500021
**********************************************************************  12550021
*                                                                     * 12600021
*        IF THE SYSTEM WQE QUEUE NEEDS TO BE CONSOLIDATED,            * 12650021
*        GO TO IEECMDSV WITH CLEANUP CODE.                            * 12700021
*                                                                     * 12750021
**********************************************************************  12800021
WRCLNUP  TM    UCMSFLGS+ONE,CLEANUP IS CLEANUP SERVICE NEEDED           12850021
         BZ    WRDOM               NO,DO NEXT SERVICE                   12900021
         LA    R1,EIGHT            YES, CODE=4 FOR CLEANUP              12950021
         L     R15,ADDVSV          GET ADDRESS OF DEQ RTN               13000021
         NI    UCMSFLGS+ONE,MASK255-CLEANUP  TURN OFF CLEANUP INDICATOR 13050021
         BALR  R14,R15             GO TO DEQ RTN                        13100021
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         13150021
         EJECT                                                          13200021
**********************************************************************  13250021
*                                                                     * 13300021
*        IF THE DOM ECB HAS BEEN POSTED, GO TO THE DOM SERVICE RTN    * 13350021
*        (IEECMDOM).                                                  * 13400021
*                                                                     * 13450021
*********************************************************************** 13500021
WRDOM    TM    UCMDECB,POST        IS DOM ECB POSTED                    13550021
         BZ    WRLOG               NO, GO TO SYSLOG CHECKER ROUTINE MCS 13600021
         SR    R0,R0              CLEAR INPUT REG 0 FOR DOM      A26940 13650021
         L     R15,ADDOM           YES, GET ADDRESS OF DOM SERVICE      13700021
         BALR  R14,R15             GO TO DOM SERVICE                    13750021
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         13800021
**********************************************************************  13850021
*                                                                     * 13900021
*        IF AN ATTENTION OR I/O COMPLETE IS PENDING, SERVICE BY       * 13950021
*        GOING TO IEECMDSV.                                           * 14000021
*                                                                     * 14050021
*********************************************************************** 14100021
WRIOSERV OI    UCMDEVC,IOCOMP      CODE=4 FOR ATTN OR I/O               14150021
WRATSERV LA    R1,FOUR             CODE=4 FOR ATTN OR I/O               14200021
WRAWTLSV EQU   *                                                 A26818 14250021
         L     R15,ADDVSV          GET ADDR OF DEVSERV                  14300021
         BALR  R14,R15             GO TO DEVSERV                        14350021
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         14400021
*********************************************************************** 14450021
*                                                                     * 14500021
*        IF THE LOG INITIALIZATION ECB HAS BEEN POSTED, GO TO SERVICE * 14550021
*        ROUTINE (IGC0907B) TO CHECK IF HARDCOPY IS SYSLOG            * 14600021
*                                                                     * 14650021
*********************************************************************** 14700021
WRLOG    TM    UCMNPECB,POST       HAS LOG JUST BEEN INITIALIZED    MCS 14750021
         BZ    CTWSTART            NO, GO TO WAIT MODULE            MCS 14800021
         LA    R1,WTL4NIP          YES, GET ADDR OF SYSLOG SERVICE  MCS 14850021
         SVC   SWRTN               SVC72 - IS HARDCOPY SYSLOG       MCS 14900021
         XC    UCMNPECB(FOUR),UCMNPECB  CLEAR LOG ECB IN UCM        MCS 14950021
         B     WREXT               GO TO CHECK EXTERNAL ECB         MCS 15000021
         EJECT                                                          15050021
CLEANUP  EQU   X'80'                                                    15100021
IOCOMP   EQU   X'08'                                                    15150021
POST     EQU   X'40'                                                    15200021
ADRMSNAM DC    CL8'IGCR107B'       NAME OF RMS MODULE             20061 15250021
WREXTNAM DC    CL8'IGCXL07B'       NAME OF CONSOLE SWITCH ROUTINE       15300021
WTL4NIP  DC    CL8'IGC0907B'       NAME OF SYSLOG CHECKER ROUTINE   MCS 15350021
DISABLE  DC    X'00'                                                    15400021
HEX04    EQU   X'04'                                                    15450021
ACTIVE   EQU   X'10'                                             A33847 15500021
ATTN     EQU   X'80'                                             A33847 15550021
ADDVSV   DC    A(IEECMDSV)         DEVICE SUPPORT                       15600021
ADWTOSV  DC    A(IEECMWSV)         WRITE SERVICE                        15650021
ADDOM    DC    A(IEECMDOM)         DOM RTN                              15700021
CTWCUCM  DC    V(IEECVUCM)         UCM                                  15750021
IEECMAA1 EQU   *                                                    MCH 15800021
         SPACE  3                                                       15850021
*                                      BOUNDARY BOX DEFINITION          15900021
         DS    0D                                                       15950021
IEECIRFC DC    A(0)                ZERO                                 16000021
         DC    A(IEECIRUP-IEECIRFC) BOUNDARY BOX SIZE                   16050021
         DC    &SIZE.X'00'        INFORMATION STORAGE                   16110021
         DS    0D                                                       16120021
IEECIRUP EQU   *                                                        16150021
         EJECT                                                          16200021
EIL      DSECT                                                          16250021
         IEECVMUG      EIL                                              16300021
         SPACE 3                                                        16350021
UCM      DSECT                                                          16400021
         IEECUCM                                                        16450021
WQE      DSECT                                                          16500021
         IEECVMUG    WQE                                                16550021
CVTDSECT DSECT                                                          16600021
         CVT                                                            16650021
         IEEBASEB                                                       16700021
         MEND                                                           16750000
