         MACRO                                                          00100017
         MPFX  &SERMPFX,&GENMPFX                                        00200017
         AIF   ('&GENMPFX' NE 'YES').MPNOREF                            00300017
         TITLE 'MULTIPROCESSOR PRIVATE STORAGE AREA'                    00400017
         SPACE                                                          00500017
         ENTRY MPCVTPTR            .PTR TO MULTIPROCESOR SECONDARY CVT. 00600017
         ENTRY CPUSTAT             .LOCN CONTAIN PROCESSOR STATUS BYTE. 00700017
         ENTRY PREFIX2             .LOCN CONTAIN INDEX TO OTHR CPU PSA. 00800017
         ENTRY IOCPUID             .LOCN CONTAIN CPU BIT FOR I/O IDENT. 00900017
         ENTRY CPUID               .LOCN CONTAIN CPU IDENTIFICATN BYTE. 01000017
         ENTRY IORGSW              .LOCN CONTAIN CPU I/O NESTNG SWITCH. 01100017
         ENTRY IEA0IO01            .ALIAS FOR I/O NESTING SWITCH.       01200017
         ENTRY STMASK              .LOCN CONTAIN REQUESTS FOR OTHR CPU. 01300017
         ENTRY IEATCBP             .LOCN CONTAIN CPU OLD,NEW TASK ADDR. 01400017
         ENTRY PREFTMRA            .LOCN CONTAIN INDEX TO ACTV TMR PSA. 01500017
         ENTRY CONSOLID            .LOCN CONTAIN I/O ADR OF CPU CONSOL. 01600017
         ENTRY FSSEMAP             .LOCN CONTAIN STORAG RECONFIGUR MAP. 01700017
         ENTRY LOCKSTOP            .LOCN CONTAIN PGM TO PUT CPU MANUAL. 01800017
         ENTRY TESTDSP             .LOCN CONTAIN PGM TST DISPACHBILITY. 01900017
         ENTRY INTEXTRN            .LOCN CONTAIN PGM TST OTHR CPU SGNL. 02000017
         ENTRY EXINTPSW            .EXT NEW PSW IN MULTIPROCESSOR.      02100017
         ENTRY EXNEWPSW            .EXT NEW PSW IN PARTITIONED SYSTEM.  02200017
         ENTRY MCWTEPSW            .MCK NEW PSW IN MULTIPROCESSOR.      02300017
         ENTRY MCNEWPSW            .MCK NEW PSW IN PARTITIONED SYSTEM.  02400017
         ENTRY INTCNTDL .LOCN CONTAINS ADJUSTABLE LOOP TIME.       2K   02430018
         ENTRY CHAN0     .LOCN IS ENTRY FOR CHANNELS 0-6  IORMS         02460018
         SPACE                                                          02500017
.MPNOREF ANOP                                                           02600017
         ORG   IEAQFX00+X'298'     .ORGN TO PUT -FSSEMAP- ON 300 BOUND. 02700017
TSTQE    DC    V(IEATSTQE)         .ADDR OF OWN TIME-SLICE TQE.         02800017
MPCVTPTR DC    V(IEAMPCVT)         .ADDR MULTIPROCESSOR CVT WITH LOCK.  02900017
CHRECNUC DS    0CL14               .CHANNEL AVAILABILITY TABLE.         03000017
         AIF   ('&GENMPFX' NE 'YES').MPCHNBY                            03100017
CHRECBSY EQU   B'10000000'           CHANNEL IN -BUSY- STATUS           03200017
CHRECNOP EQU   B'01000000'           CHANNEL IN -NOT OPERATIONL- STATUS 03300017
CHRECNGN EQU   B'00100000'           CHANNEL NOT SYSGENNED IN SYSTEM    03400017
CHRECNAV EQU   B'00010000'           CHANNEL NOT ON CPU IN SYSTEM       03500017
*                                                                       03600017
.MPCHNBY ANOP                                                           03700017
CHAN0    DC    X'1000'                  ENTRY FOR CHANNEL 0             03800017
CHAN1    DC    X'1100'                  ENTRY FOR CHANNEL 1             03900017
CHAN2    DC    X'1200'                  ENTRY FOR CHANNEL 2             04000017
CHAN3    DC    X'1300'                  ENTRY FOR CHANNEL 3             04100017
CHAN4    DC    X'1400'                  ENTRY FOR CHANNEL 4             04200017
CHAN5    DC    X'1500'                  ENTRY FOR CHANNEL 5             04300017
CHAN6    DC    X'1600'                  ENTRY FOR CHANNEL 6             04400017
*                                                                       04500017
PTRIGGER DC    XL1'00'             .PREFIXED CPU INDICATOR.             04600017
         AIF   ('&GENMPFX' NE 'YES').MPPRFBY                            04700017
PTRIGGON EQU   C'P'                  CPU IS PREFIXED (PSA IN HI CORE)   04800017
PTRIGGOF EQU   C' '                  CPU NOT PREFIXD (PSA IN LO CORE)   04900017
*                                                                       05000017
.MPPRFBY ANOP                                                           05100017
CPUSTAT  DC    XL1'01'             .CPU STATUS BYTE.                    05200017
         AIF   ('&GENMPFX' NE 'YES').MPSTABY                            05300017
CPUSTMP2 EQU   B'00000000'           TWO CPU MULTIPROCESSOR SYSTEM      05400017
CPUSTMP1 EQU   B'00000010'           ONE CPU MULTIPROCESSOR SYSTEM      05500017
CPUSTPRT EQU   B'00000001'           ONE CPU PARTITIONED SYSTEM         05600017
CPUSTTWO EQU   CPUSTPRT+CPUSTMP1   .CODES FOR ONE-PROCESSOR SYSTEM.     05700017
*                                                                       05800017
.MPSTABY ANOP                                                           05900017
PREFIX2  DC    XL4'0003F000'       .ADDR OF PREFIX AREA IN HIGH CORE.   06000017
IOCPUID  DC    XL4'00000000'       .CPU IDENTIFICATN BIT FOR I/O OPER.  06100017
CPUID    DC    XL1'00'             .CPU IDENTIFICATION BYTE.            06200017
CPUWAIT  DC    XL1'00'             .FLAG BYTE FOR CPU SYNCHRONIZATION.  06300017
         DC    XL1'00'              RESERVED                            06400017
         SPACE                                                          06500017
         DC    XL1'00'             .I/O FLIH NESTING SWITCH.            06600017
         ORG *-2                   .MAKE BELIEVE IEA0IO01 IS BR/NOP SW. 06700017
IORGSW   DS    0H                  .TAG FOR I/O FLIH NESTING SWITCH.    06800017
IEA0IO01 DS    0H                  .ALIAS FOR I/O FLIH NESTING SWITCH.  06900017
         ORG *+2                   .REORIGIN AFTER ASSIGN NEST SW TAGS. 07000017
         SPACE                                                          07100017
STMASK   DC    F'0'                .SHOULDER TAP MASK.                  07200017
IEATCBP  DC    V(IEAMSTCB)             ADR OF NEW TCB                   07300017
         DC    V(IEAMSTCB)              ADR OF OLD TCB                  07400017
PREFTMRA DC    F'0'                .INDX TO PSA WITH ACTIVE TIMER.      07500017
*                                                                       07600017
ASRFLAGS DC    XL1'00'             .FLAG BYTE FOR RMS SYNCHRONIZATION.  07700017
         AIF ('&GENMPFX' NE 'YES').MPASRBY                              07800017
ASRTOFLG EQU   B'10000000'           TIME-OUT FLG - CPU GOT MALFN SIGNL 07900017
ASRCMFLG EQU   B'00001000'           COMPLETN FLG - RMS RUN ON OTHR CPU 08000017
ASRTORST EQU   X'FF'-ASRTOFLG      .MASK TO TURN OFF MALFN SIGNAL FLAG. 08100017
ASRCMRST EQU   X'FF'-ASRCMFLG      .MASK TO TURN OFF RMS COMPLETE FLAG. 08200017
*                                                                       08300017
.MPASRBY ANOP                                                           08400017
CONSOFF  DC    XL1'00'             .CONSOLE RECONFIGURATION FLAGS.      08500017
         AIF   ('&GENMPFX' NE 'YES').MPCNSBY                            08510017
CONSOFCP EQU   B'10000000'           CONSOLE UNAVAILABLE - CPU OFFLINE  08520017
CONSOFCH EQU   B'01000000'           CONSOLE UNAVAILABLE - CHANL OFFLIN 08530017
*                                                                       08540017
.MPCNSBY ANOP                                                           08570017
CONSOLID DC    XL2'0000'           .CH-CU-DV ADDR OF 1052 ON THIS CPU.  08600017
*                                                                       08700017
UCBSAVE  DC    7Y(DMYUCB)          .TABLE FOR IOS TO REDUCE UCB LOOKUP. 08800017
DMYCHA   DC    X'7FFF'             DUMMY UCB CHANNEL ADDRESS            08900017
DMYUCB   EQU   DMYCHA-4-IPLPSW     ADDR 4 BEFORE INVALID I/O ADDR COMPR 09000017
*                                                                       09100017
         SPACE                                                          09200017
         AIF   ('&SERMPFX' EQ 'SERP').MPNOSER                           09300017
MCNEWPSW DC    A(0)                .DISABLED PSW TO START UP OTHER CPU. 09400017
EDSMCH   DC    V(IGFN0000)         .MCH ENTRY POINT.                    09500017
         AGO   .MPFXPSW                                                 09600017
.MPNOSER ANOP                                                           09700017
MCNEWPSW DC    XL4'00020000'       .COMPLETELY DISABLED WAIT PSW.       09800017
         DC    XL4'000000E2'       .WAIT STATE CODE FOR SYSTEM W/O SER. 09900017
.MPFXPSW ANOP                                                           10000017
MCWTEPSW DC    XL4'00020000'       .COMPLETELY DISABLED WAIT PSW.       10100017
         DC    XL4'00000A21'       .M65MP MACHINE CHECK WAIT CODE.      10200017
EXNEWPSW DC    XL4'00040000'       .RESUME EXTERNAL NEW PSW.            10300017
         DC    V(IEAQEX00)         .EX FLIH ADDR.                       10400017
EXINTPSW DC    XL4'00040000'       .DISABLED ENTRY TO MALF ALERT TEST.  10500017
         DC    V(INTEXTRN)         .MULTISYSTEM EX INTRPT ENTRY POINT.  10600017
         SPACE                                                          10700017
*                                                                       10800017
*   CORE STATUS FOR EACH 2K BLOCK (2 BITS FOR EACH 2K BLOCK)            10900017
*                                                                       11000017
*                   00 - OK (BLOCK IS DESCRIBED BY VALID FBQE OR DQE)   11100017
*                   11 - CONFIGURED OUT (DOES NOT EXIST ON ANY QUEUE)   11200017
*                                                                       11300017
         SPACE                                                          11400017
FSSEMAP  DC    XL256'00'           .STORAGE ELEMENT STATUS MAP (2048K). 11500017
         SPACE                                                          11600017
         AIF   ('&GENMPFX' NE 'YES').MPEJTBY                            11620017
         EJECT                                                          11640017
.MPEJTBY ANOP                                                           11660017
*                                                                       11700017
*   FLRETFLG, RNEXCODE, RNSAVGPR, AND RNSAVPSW FUNCTION TO ALLOW        11800017
*   EXTERNAL INTERRUPTS TO BE TAKEN WHILE SPINNING IN THE PI, IO,       11900017
*   OR EX FLIH'S TEST-SUPERVISOR-LOCK LOOP. (TO TRAP POSS. M.A.)        12000017
*                                                                       12100017
RNSAVCSW DC    D'0'                .I/O FLIH T-S-L LOOP CSW SAVE AREA.  12200017
RNSAVPSW DC    D'0'                .ALL FLIH T-S-L LOOP PSW SAVE AREA.  12300017
RNSAVGPR DC    16F'0'              .ALL FLIH T-S-L LOOP GPR SAVE AREA.  12400017
RNSAVFPR DC    4D'0'               .ALL FLIH T-S-L LOOP FPR SAVE AREA.  12500017
*                                                                       12600017
RNEXCODE DC    X'00'               .EXT FLIH T-S-L LOOP INTR COD STACK. 12700017
INTCNTDL DC    H'0' . MAJOR LOOP CTL, INTCTCNT VALUE ADJUSTED.     2K   12750018
         AIF   ('&GENMPFX' NE 'YES').MPEXTBY                            12800017
EXMAINTR EQU   B'00100000'         .MALFUNCTION ALERT - OTHER CPU MCHK. 12900017
EXSCINTR EQU   B'00010000'         .SYSTEM CALL - OTHER CPU SHOULDRTAP. 13000017
EXMLFRST EQU   X'FF'-EXMAINTR      .MASK TO TURN OFF MALF ALERT EX COD. 13100017
EXCPUATT EQU   EXMAINTR+EXSCINTR   .EX INTRPT CODES FOR OTHR CPU SIGNL. 13200017
EXNMINTR EQU   X'FF'-EXCPUATT      .EX INTRPT CODES NOT FRM MULTISYSTM. 13300017
INTSIZE  EQU   L'RNEXCODE          .SYMBOLIC LENGTH PSW INTERRUPT CODE. 13400017
EXIPLWRD EQU   B'10000000'         .MULTISYST DIR CTL - EXTERNAL START. 13500017
EXCALWRD EQU   B'00010000'         .MULTISYST DIR CTL - SYSTEM CALL.    13600017
*                                                                       13700017
.MPEXTBY ANOP                                                           13800017
FLRETFLG DC    X'00'               .ALL FLIH T-S-L LOOP INTR TYP STACK. 13900017
         AIF   ('&GENMPFX' NE 'YES').MPFLGBY                            14000017
FSSTFLAG EQU   B'00100000'           ST RTNE INDICATOR                  14100017
FSPIFLAG EQU   B'00000100'           PI FLIH INDICATOR                  14200017
FSEXFLAG EQU   B'00000010'           EX FLIH INDICATOR                  14300017
FSIOFLAG EQU   B'00000001'           IO FLIH INDICATOR                  14400017
FSSTNOFL EQU   X'FF'-FSSTFLAG      .MASK TO TURN OFF ST RTNE SPIN FLAG. 14500017
FSALFLAG EQU   FSIOFLAG+FSEXFLAG+FSPIFLAG .ANY STACK INDICATOR.         14600017
*                                                                       14700017
.MPFLGBY ANOP                                                           14800017
         SPACE                                                          14900017
         AIF   ('&GENMPFX' NE 'YES').MPCODBY                            15000017
         TITLE 'E X T E R N A L    I N T E R R U P T    H A N D L E R'  15100017
*                                                                       15200017
INTRGPSA EQU   14                  .INDX REG TO OTHER CPU PSA.          15300017
INTRGWK1 EQU   INTRGPSA            .WORK REG.                           15400017
INTRGPSW EQU   15                  .ADDR REG FOR EXIT PSW.              15500017
INTRGWK2 EQU   INTRGPSW            .WORK REG.                           15600017
         SPACE                                                          15700017
*                                                                       15800017
*   DEFINITION OF FLAGS USED IN FIRST BYTE OF -STMASK-                  15900017
*                                                                       16000017
WRDPEND  EQU   X'80'               .SHOULDER TAP FLAG FOR PENDING REQ.  16100017
WRDWTBEL EQU   X'20'               .SHOULDER TAP MASK FOR BELL RING WT. 16200017
WRDWTCCH EQU   X'10'               .SHOULDER TAP MASK FOR CCH PROCESS.  16300017
WRDWTHIO EQU   X'01'               .SHOULDER TAP MASK FOR IMM HALT I/O. 16400017
WRDNTBEL EQU   X'FF'-WRDWTBEL      .MASK TO TURN OFF BEL STAP BIT.      16500017
WRDNTCCH EQU   X'FF'-WRDWTCCH      .MASK TO TURN OFF CCH STAP BIT.      16600017
WRDNTHIO EQU   X'FF'-WRDWTHIO      .MASK TO TURN OFF HIO STAP BIT.      16700017
WRDWTIMM EQU   WRDWTBEL+WRDWTHIO   .SERVICES PERFORMED W/O SYSTEM LOCK. 16800017
WRDNTIMM EQU   X'FF'-WRDWTIMM      .SERVICES NOT DEFIN W/O SYSTEM LOCK. 16900017
*                                                                       17000017
         SPACE                                                          17100017
*                                                                       17200017
*              S E C O N D    C P U    I N T R P T    A N A L Y S I S   17300017
*                                                                       17400017
         SPACE                                                          17500017
*                                                                       17600017
*   EXTERNAL INTERRUPT ENTRY POINT.  TEST FOR MALFUNCTION ALERT OR      17700017
*   CHANNEL CHECK HANDLER SHOULDER TAP.  IF EITHER, EXECUTE SECOND      17800017
*   CPU RECOVERY MANAGEMENT SYSTEM INTERFACE, WHICH CAUSES THIS CPU     17900017
*   TO SPIN WHILE WAITING FOR THE FIRST CPU TO RECOVER FROM ITS ERROR.  18000017
*                                                                       18100017
*                                                                       18200017
INTEXTRN DS    0H                  .EX INTERRUPT MALF ALERT TEST ENTRY. 18300017
         STM   INTRGPSA,INTRGPSW,INTEXSAV .SAVE CONTENTS OF REGS CHNGD. 18400017
         L     INTRGPSA,PREFIX2    .PICK INDEX TO OTHER CPU PSA.        18500017
         TM    EXOPSW+3,EXMAINTR   .TEST MALFUNCTION ALERT INTERRUPT.   18600017
         BO    INTMLFAL            .YES - COMMENCE MCH SETUP.           18700017
         TM    STMASK-IEAQFX00(INTRGPSA),WRDWTCCH .TEST CHANCHECK STAP. 18800017
         BO    INTCCHST            .YES - COMMENCE CCH SETUP.           18900017
*                                                                       19000017
*   NOW TEST IF THIS CPU SHOULD PERFORM A SERVICE FOR THE OTHER CPU,    19100017
*   WHO RETAINS THE SYSTEM LOCK.  NOTE THAT THIS CPU WILL PERFORM THE   19200017
*   SERVICE BEFORE GOING TO THE EX FLIH, WHERE THE LOCK IS TESTED.      19300017
*                                                                       19400017
         TM    STMASK-IEAQFX00(INTRGPSA),WRDWTIMM .TEST IMMEDIATE STAP. 19500017
         BNZ   INTEXRTN            .YES - GO PERFM THE SERVIC REQUIRED. 19600017
*                                                                       19700017
*   GO ON TO NORMAL EX FLIH IF THIS CPU HAS ANOTHER INTERRUPT BESIDES   19800017
*   THE IMMEDIATE SHOULDRTAP.  ELSE RETURN DIRECTLY TO INTERRUPTED PGM. 19900017
*                                                                       20000017
INTEXTST TM    FLRETFLG,FSSTFLAG   .TEST IF SPIN IN SIGNAL ROUTINE.     20100017
         BO    INTEXBAK            .YES - FORC RETURN BY RELOD OLD PSW. 20200017
         LA    INTRGPSW,EXNEWPSW   .SET UP TO ENTER EX FLIH.            20300017
         TM    FLRETFLG,FSALFLAG   .TEST CPU SPIN ON LOCK IN ANY FLIH.  20400017
         BNZ   INTEXSET            .YES - CPU ALREDY HAS ANOTHR INTRPT. 20500017
         L     INTRGWK1,STMASK-IEAQFX00(,INTRGPSA) .PICK OTHR STAP MSK. 20600017
         N     INTRGWK1,INTEXSTM   .TEST ANY SERVICE BESIDES W/O LOCK.  20700017
         BNZ   INTEXSET            .YES - GO ON TO EX FLIH TO GET LOCK. 20800017
         TM    EXOPSW+3,EXNMINTR   .TEST ANY NON-MULTIPROCES EX INTRPT. 20900017
         BNZ   INTEXSET            .YES - GO ON TO EX FLIH TO SERVICE.  21000017
INTEXBAK LA    INTRGPSW,EXOPSW     .SET UP TO GO BACK TO INTRPT POINT.  21100017
INTEXSET MVC   INTEXPSW,PSWDSPBG(INTRGPSW) .MOVE EXIT PSW TO WORK AREA. 21200017
         LM    INTRGPSA,INTRGPSW,INTEXSAV .RESTORE REGISTERS.           21300017
         LPSW  INTEXPSW            .E X I T.                            21400017
         SPACE                                                          21500017
*                                                                       21600017
*   CONSTANTS AND WORKAREAS USED BY EXTERNAL SIGNAL INTERFACE           21700017
*                                                                       21800017
INTEXSAV DC    D'0'                .INTER-CPU COMMUNICATN REG SAV AREA. 21900017
INTEXPSW DC    D'0'                .INTER-CPU COMMUNICATN PSW LOD AREA. 22000017
INTEXSRG DC    D'0'                .EXTERNAL SIGNAL RECV REG SAVE AREA. 22100017
FLASSAVE DC    D'0'                .EXTERNAL SIGNAL SEND REG SAVE AREA. 22200017
TESTSAVE DC    5F'0'               .DISPATCHABILITY RTN WKREG SAV AREA. 22300017
TESTBACK DC    F'0'                .DISPATCHABILITY RTN RTREG SAV AREA. 22400017
PSWDSPBG EQU   0                   .SYMBOLIC OFFSET TO 1ST BYTE OF PSW. 22500017
PSWDSPWT EQU   1                   .SYMBOLIC OFFSET TO 2ND BYTE OF PSW. 22600017
PSWWAIT  EQU   X'02'               .WAIT BIT IN BYTE ONE OF PSW.        22700017
PSWENAB  EQU   X'FF'               .TEST PSW ENABLED FOR INTERRUPTS.    22800017
PSWSIZE  EQU   L'INTEXPSW          .SYMBOLIC LENGTH OF PSW.             22900017
NTZERO   EQU   7                   .SYMB I2 FIELD FOR COND CODE NOT 0.  23000017
CCZERO   EQU   8                   .SYMB I2 FIELD FOR COND CODE EQL 0.  23100017
MCHKOK   EQU   X'FF'               .SYMB I2 FIELD FOR TEST MCOPSW+2.    23200017
INTEXSTM DC    AL1(WRDNTIMM),X'FFFFFF' .MASK FOR ALL BUT IMMED STAP.    23300017
         TITLE 'R E C O V E R Y    M A N A G M E N T    I N T R F A C'  23400017
*                                                                       23500017
*   SECOND CPU MCH - CCH ROUTINE.  IF HARDWARE ERROR HAS IMPACTED       23600017
*   THIS CPU, LOAD MACHINE CHECK WAIT PSW.                              23700017
*                                                                       23800017
*                                                                       23900017
INTCCHST NI    STMASK-IEAQFX00(INTRGPSA),WRDNTCCH .TURN OFF STAP FLAG.  24000017
INTMLFAL OI    ASRFLAGS,ASRTOFLG   .INDICATE THIS CPU PROCESSING MALF.  24100017
         TM    ASRFLAGS-IEAQFX00(INTRGPSA),ASRTOFLG .TEST MLF BOTH CPU. 24200017
         BNZ   INT2WAIT            .YES - PUT BOTH CPUS INTO WAIT.      24300017
         TM    EXOPSW+3,EXMAINTR   .TEST MALFUNCTION ALERT (MCH).       24400017
         BZ    INTDOCCH            .NOT ON - CCH STAP BYPASSES LOCK.    24500017
         L     INTRGWK2,MPCVTPTR   .ADDR MULTIPROCESSING SECONDARY CVT. 24600017
         TS    MPCVTLK(INTRGWK2)   .TEST SYSTEM LOCK BYTE.              24700017
         BZ    INTDOMCH            .IF OFF, LOCK AND BRANCH.            24800017
         CLC   MPCVTAFF(,INTRGWK2),CPUID .OTHRWISE, CHECK CPU AFFINITY. 24900017
         BNE   INTDOMCH            .OTHER GUY HAD LOCK - LET HIM RMS.   25000017
INT2WAIT LA    INTRGPSW,MCWTEPSW   .SETUP WAIT (MACH CHECK) PSW.        25100017
         B     INTEXSET            .GO LOAD PSW.                        25200017
         SPACE                                                          25300017
*                                                                       25400017
*   MALFUNCTION ALERT INDICATES OTHER CPU EXPERIENCED MACHINE CHECK.    25500017
*   ISSUE ELECTRONIC START TO OTHER CPU TO SET IT TO PROCESSING MCH.    25600017
*                                                                       25700017
INTDOMCH MVC   MPCVTAFF(,INTRGWK2),CPUID-IEAQFX00(INTRGPSA) .LOCK SUPV. 25800017
         MVC   PSWDSPBG(PSWSIZE,INTRGPSA),MCNEWPSW .SETUP RESTART PSW.  25900017
         L     INTRGWK1,INTCTIPL   .SET UP LOOP COUNTER.                26000017
INTWTIPL BCT   INTRGWK1,INTWTIPL   .SPIN FOR 250 MS.                    26200017
         WRD   INTERPSW,EXIPLWRD   .ISSUE ELECTRONIC IPL TO MALF CPU.   26300017
*                                                                       26400017
*   WAIT FOR OTHER CPU TO COMPLETE RMS PROCESSING.  IF OTHER CPU DIED   26500017
*   (DID NOT RESPOND WITHIN REASONABLE TIME), LOAD WAIT STATE PSW.      26600017
*                                                                       26700017
INTDOCCH NI    ASRFLAGS,ASRCMRST   .CLEAR WAIT-FOR-RMS-COMPLETE FLAG.   26800017
         LH    INTRGWK2,INTCTCNT .SET UP LOOP COUNTER.             2K   26870018
INT1SPIN LH    INTRGWK1,INTCTSPN .SET UP SPIN COUNTER.             2K   26940018
         STH   INTRGWK2,INTCNTDL .SAVE MAJOR LOOP CONTROL.         2K   27010018
         CNOP  0,8                 .PUT BCT ON DOUBLE WORD BOUNDARY.    27100017
INTWTCMP BCT   INTRGWK1,INTWTCMP   .SPIN FOR 2 MS.                      27200017
         TM    ASRFLAGS,ASRCMFLG   .TEST IF RMS PROCESSING COMPLETED.   27300017
         BNZ   INTRESUM            .YES - GO TEST IF CAN RESUME.        27400017
         L     INTRGPSA,PREFIX2    .PICK INDEX TO OTHER CPU PSA.        27500017
         TM    STMASK-IEAQFX00(INTRGPSA),WRDWTIMM .TEST IMMEDIATE STAP. 27600017
         BNZ   INTEXRTN            .YES - GO PERFM THE SERVIC REQUIRED. 27700017
INT2SPIN LH    INTRGWK2,INTCNTDL  .SAVE MAJOR LOOP CTL OBTAIN.     2K   27760018
         BCT   INTRGWK2,INT1SPIN .KEEP SPINNING TILL TIME RUNS OUT.2K   27820018
INT1WAIT LA    INTRGPSW,INTERPSW   .ERROR PSW - RMS NEVER COMPLETED.    27900017
         B     INTEXSET            .GO LOAD PSW.                        28000017
         SPACE                                                          28100017
*                                                                       28200017
*   TEST RMS RESULTS.  IF RMS PUT ERROR CPU INTO WAIT, THIS CPU WAITS   28300017
*   ALSO.  IF RMS WAS ABLE TO RECOVER, TRAP STRAY MALFUNCTION ALERTS    28400017
*   AND RE-PROCESS EXTERNAL INTERRUPT.                                  28500017
*                                                                       28600017
INTRESUM L     INTRGPSW,INTRMSAD   .RMS RESUME PSW LOCATION.            28700017
         TM    PSWDSPWT(INTRGPSW),PSWWAIT .TEST IF RMS WENT INTO WAIT.  28800017
         BZ    INTRESOK            .NO WAIT - LET THIS CPU RESUME.      28900017
         TM    PSWDSPBG(INTRGPSW),PSWENAB .TEST COMPLET DISABLED WAIT.  29000017
         BZ    INTEXSET            .YES - LOAD SAME PSW ON THIS CPU.    29100017
INTRESOK MVC   INTEXPSW,EXOPSW     .SAVE EXTERNAL OLD PSW.              29200017
         MVC   EXNPSW(PSWSIZE),INTENABL .ENABLED PSW TRAP MALF ALERT.   29300017
         LPSW  EXNPSW              .ENABLE - OTHR CPU STILL HAS LOCK.   29400017
INTTENAB LPSW  INTDISAB            .DISABLE EXTERNAL.                   29500017
INTTDSAB NI    ASRFLAGS,ASRTORST   .CLEAR HAVE-GOTTEN-MALF-SIGNAL FLAG. 29600017
         OC    INTEXPSW+3(INTSIZE),EXOPSW+3 .SAVE EX INTRPT CODE BITS.  29700017
         MVC   EXOPSW,INTEXPSW     .RESTORE ORIGINAL EX OLD PSW.        29800017
         NI    EXOPSW+3,EXMLFRST   .CLEAR MALFUNCTION ALERT BIT.        29900017
         MVC   EXNPSW(PSWSIZE),EXINTPSW .RESTORE CPU EXTERN NEW PSW.    30000017
         LA    INTRGPSW,EXINTPSW   .SET UP TO RE-ENTER PRE-FLIH.        30100017
         B     INTEXSET            .GO LOAD PSW.                        30200017
         SPACE                                                          30300017
*                                                                       30400017
*   CONSTANTS AND WORKAREAS USED BY RECOVERY MANAGEMENT INTERFACE       30500017
*                                                                       30600017
         DS    0D                   ADDRESSABILITY ON DOUBLE WORD       30700017
INTENABL DC    XL4'01040000'       .PSW TO TRAP MALFUNCTION ALERTS.     30800017
         DC    A(INTTENAB)         .TEMP EX ENTRY PT.                   30900017
INTDISAB DC    XL4'00040000'       .DISABLED PSW FOR RMS INTERFACE.     31000017
         DC    A(INTTDSAB)         .INTF RESUME LOCN.                   31100017
INTERPSW DC    XL4'00020000'       .COMPLETELY DISABLED WAIT PSW.       31200017
         DC    XL4'00000A22'       .M65MP RMS-INCOMPLETE WAIT CODE.     31300017
FLASENAB DC    XL4'01040000'       .PSW TO ALLOW MALFUNCTION ALERT.     31400017
         DC    A(FLASNOMA)         .ADDR VECTOR IF NO EXTERNAL INTERPT. 31500017
FLASDSAB DC    XL4'00040000'       .DISABLED PSW FOR SIGNAL RTNE.       31600017
         DC    A(FLASHOFF)         .RESUME LOCN.                        31700017
         AIF   ('&SERMPFX' NE 'MCH').MPRESLV                            31800017
         EXTRN IGFNUC01            .ADDR OF NUCL DATA IN RMS COMM AREA. 31900017
INTRMSAD DC    A(IGFNUC01+16)      .ADDR OF RESUM PSW IN RMS COMM AREA. 32000017
.MPRESLV ANOP                                                           32100017
FLASTMOT DC    F'0'                .EXTERNAL SIGNAL TIME OUT COUNTER.   32160017
FLASSPIN DC    F'8388608'          .COUNT TO SPIN 80 SEC.               32220017
INTCTIPL DC    F'217391'           .COUNT TO SPIN 250 MS.               32300017
INTCTCNT DC    H'6000' .COUNT TO LOOP TEN SEC(ADJUSTABLE TO 53).   2K   32400018
INTCTSPN DC    H'1739' .COUNT TO SPIN 2 MS.                        2K   32500018
MPCVTAFF EQU   0                   .OFFSET OF CPU AFFINTY BYT IN MPCVT. 32600017
MPCVTLK  EQU   1                   .OFFSET OF SYSTM LOCK BYTE IN MPCVT. 32700017
LOKSIZE  EQU   MPCVTLK+1           .SYMBOLIC LENGTH OF SYSTEM LOCK.     32800017
         TITLE 'E X T E R N A L    S I G N A L    I N T E R F A C E S'  32900017
*                                                                       33000017
*              S E C O N D    C P U    S E R V I C E    R O U T I N E   33100017
*                                                                       33200017
         SPACE                                                          33300017
*                                                                       33400017
*   DECIDE WHICH SERVICE THIS (SECOND) CPU IS REQUESTED TO PERFORM      33500017
*   FOR THE SIGNALLING (FIRST) CPU WHILE THE FIRST RETAINS THE LOCK.    33600017
*                                                                       33700017
INTEXRTN STM   INTRGPSA,INTRGPSW,INTEXSRG .SAVE CONTENTS OF REGS CHNGD. 33800017
         L     INTRGPSA,PREFIX2    .PICK INDEX TO OTHER CPU PSA.        33900017
         TM    STMASK-IEAQFX00(INTRGPSA),WRDWTBEL .TEST SYSTMWAIT STAP. 34000017
         BO    INTBELST            .YES - GO PUT CPU INTO WAIT STATE.   34100017
         TM    FLRETFLG,FSIOFLAG   .TEST THIS CPU SPINNING IN IO FLIH.  34200017
         BZ    INTEXHIO            . NO - BYPAS STACK IO INTERRUPT.     34300017
         MVC   RNSAVCSW(PSWSIZE),CSWLOC .SAVE ORIGINAL IO INTRPT CSW.   34400017
INTEXHIO TM    STMASK-IEAQFX00(INTRGPSA),WRDWTHIO .TEST IMMED HIO STAP. 34500017
         BO    HLTIOUNT            .YES - GO TO IMMEDIATE HALT IO RTNE. 34600017
INTEXSWC TM    FLRETFLG,FSIOFLAG   .TEST THIS CPU SPINNING IN I/O FLIH. 34700017
         BZ    INTEXRTO            . NO - BYPAS UNSTACK I/O INTERRUPT.  34800017
         MVC   CSWLOC(PSWSIZE),RNSAVCSW .RESTOR ORIGINAL IO INTRPT CSW. 34900017
INTEXRTO LM    INTRGPSA,INTRGPSW,INTEXSRG .RESTORE REGISTERS.           35000017
         TM    ASRFLAGS,ASRTOFLG   .TEST IF SERV REQ BY RECOVERY MNGMT. 35100017
         BZ    INTEXTST            . NO - GO LOAD RESUME PSW.           35200017
         B     INT2SPIN            .RETURN TO WAIT FOR RMS COMPLETE.    35300017
         SPACE                                                          35400017
*                                                                       35500017
*              F I R S T    C P U    S I G N A L    R O U T I N E       35600017
*                                                                       35700017
         SPACE                                                          35800017
*                                                                       35900017
*   SIGNAL THE OTHER (SECOND) CPU THAT IT IS TO PERFORM A SERVICE WHICH 36000017
*   HAS CPU AFFINITY AND CAN NOT BE DONE BY THE REQUESTING (FIRST) CPU. 36100017
*                                                                       36200017
FLASH    DS    0H                  .ENTRY TO 1ST CPU COMMUNICATN RTNE.  36300017
         TM    CPUSTAT,CPUSTTWO    .TEST IF TWO PROCESSOR SYSTEM.       36400017
         BCR   NTZERO,INTRGWK1     . NO - DON'T SHOULDER TAP.           36500017
         TM    STMASK,WRDWTIMM+WRDPEND  .TEST USER SERV, TASK SW REQ.   36600017
         BCR   CCZERO,INTRGWK1     . NO - DON'T SHOULDER TAP.           36700017
         STM   INTRGWK1,INTRGWK2,FLASSAVE .STORE REGISTERS.             36800017
         L     INTRGWK2,FLASSPIN   .SET UP SPIN COUNTER.                36900017
FLAS1SPN ST    INTRGWK2,FLASTMOT   .SAVE CURRENT SPIN COUNT.            36960017
         WRD   INTERPSW,EXCALWRD   .ISSUE SYSTEM CALL TO OTHER CPU.     37020017
         TM    STMASK,WRDWTIMM     .TEST IF IMMED SERVICE PROCESSED.    37100017
         BZ    FLASLEVE            .YES - GO OUT.                       37200017
FLASCONT L     INTRGWK2,FLASTMOT   .RESTORE REMAINING SPIN COUNT.       37250017
         L     INTRGPSA,PREFIX2    .PICK INDEX TO OTHER CPU PSA.        37300017
         TM    MCOPSW+2-IEAQFX00(INTRGPSA),MCHKOK .TST OTHR HAD MCHCHK. 37400017
         BO    FLAS2SPN            . NO - KEEP TRYING TO GET THROUGH.   37500017
         OI    FLRETFLG,FSSTFLAG   .INDICATE SPIN IN SIGNAL ROUTINE.    37600017
         LPSW  FLASENAB            .ENABLE - THIS CPU STILL HAS LOCK.   37700017
FLASNOMA LPSW  FLASDSAB            .DISABLE EXTERNAL.                   37800017
FLASHOFF NI    FLRETFLG,FSSTNOFL   .CLEAR SPIN IN SIGNAL ROUTINE FLAG.  37900017
         OC    RNEXCODE,EXOPSW+3   .SAVE EXTRN INTRPT CONDITION.        38000017
         BZ    FLAS2SPN            .BYPASS MARK RETRN IF NO EX STACKED. 38100017
         OI    FLRETFLG,FSEXFLAG   .INDICATE RECURSIVE EXTRN INTERRUPT. 38200017
FLAS2SPN BCT   INTRGWK2,FLAS1SPN   .KEEP SPINNING TILL TIME RUNS OUT.   38300017
         MVC   INTEXSAV,FLASSAVE   .PASS REGISTERS ON.                  38400017
         B     INT1WAIT            .GO INDICATE MACHINE CHECK.          38500017
FLASLEVE LM    INTRGWK1,INTRGWK2,FLASSAVE .RESTORE REGISTERS.           38600017
         BR    INTRGWK1            .RETURN TO CALLER.                   38700017
         SPACE                                                          38800017
*                                                                       38900017
*              T A S K    R E M O V A L    R O U T I N E                39000017
*                                                                       39100017
         SPACE                                                          39200017
*                                                                       39300017
TESTTCB  EQU   4                        TCB TO BE TESTED                39400017
WKRG     EQU   5                        WORK REGISTER                   39500017
PRF2     EQU   6                        ADDRESS OF OTHER CPU PSA        39600017
LKRG     EQU   7                        RETURN REG FOR TCB DISPATCH TST 39700017
VECTR    EQU   8                        BRANCH LOCN IF TCB NON-DISP     39800017
RTRG     EQU   14                       RETURN REG FROM ROUTINE         39900017
*                                                                       40000017
IEATCBPO EQU   IEATCBP+4           .LOCN CONTAIN CPU CURRENT TASK ADDR. 40100017
TCBRBP   EQU   0                        DISPL RB POINTER IN TCB         40200017
RBWCF    EQU   28                       DISPL WAIT COUNT IN RB          40300017
*                                                                       40400017
         SPACE                                                          40500017
*                                                                       40600017
*   BRANCH ENTRY FROM SUPERVISR RUTINES WHICH CHANG THE DISPATCHABILITY 40700017
*   STATUS OF TASKS OTHER THAN THE CURRENT TASK ON THE EXECUTING CPU.   40800017
*   BEGIN BY TESTING IF A CURRENTLY EXECUTING (ON THE OTHER CPU) TASK   40900017
*   HAS BEEN SET NON-DISPATCHABLE.  IF SO, CAUSE AN EXTERNAL INTERRUPT  41000017
*   (SHOULDER TAP) TO THE OTHER CPU, AND WAIT UNTIL THAT CPU HAS STORED 41100017
*   THE STATUS ASSOCIATED WITH THE CURRENT TASK HE WAS WORKING UPON.    41200017
*                                                                       41300017
         SPACE                                                          41400017
TESTDSP  DS    0H                       ENTRY FRM RTN CHNG DSPCHBILITY  41500017
         STM   TESTTCB,VECTR,TESTSAVE   SAVE REGS OVER ROUTINE          41600017
         ST    RTRG,TESTBACK            SAVE RETURN ADDRESS             41700017
         L     PRF2,PREFIX2             PICK ADDRESS OF 2ND CPU PSA     41800017
         LA    LKRG,TESTOWN             BYP STAP IF OLD2 DISPATCHABLE   41900017
         L     TESTTCB,IEATCBPO-IEAQFX00(,PRF2) PICK CURR TASK 2ND CPU  42000017
         BAL   VECTR,READYCHK           GO CHECK - COME BACK IF N-D     42100017
         OI    STMASK,WRDPEND           SET SHOULDER TAP PENDING FLAG   42200017
         BAL   RTRG,FLASH               LINK TO 1ST CPU SIGNAL ROUTINE  42300017
         TM    FLRETFLG-IEAQFX00(PRF2),FSEXFLAG TEST IF HAD EXTRN INTR  42400017
         BZ    FLASCONT                 NO - LOOP TILL GET RESPONSE     42500017
*                                                                       42600017
*   CONTINUE BY TESTING WHETHER ANY OF THE TASKS TO WHICH THE TWO CPUS  42700017
*   WOULD NEXT BE DISPATCHED HAVE BEEN SET NON-DISPATCHABLE.  IF SO,    42800017
*   ZERO THE -NEW- TASK ADDRESSES ON BOTH CPUS TO FORCE THE DISPATCHER  42900017
*   TO SEARCH THE ENTIRE TCB QUEUE FOR READY TASKS.                     43000017
*                                                                       43100017
TESTOWN  LA    VECTR,ZERONEW            FORCE REDYQ SCAN IF REST NONDSP 43200017
         L     TESTTCB,IEATCBPO         PICK CURR TASK OWN CPU          43300017
         BAL   LKRG,READYCHK            GO CHECK                        43400017
         L     TESTTCB,IEATCBP-IEAQFX00(,PRF2) PICK NEXT TASK 2ND CPU   43500017
         BAL   LKRG,READYCHK            GO CHECK                        43600017
         L     TESTTCB,IEATCBP          PICK NEXT TASK OWN CPU          43700017
         BAL   LKRG,READYCHK            GO CHECK                        43800017
TESTRET  LM    TESTTCB,VECTR,TESTSAVE   RESTORE REGISTERS               43900017
         L     RTRG,TESTBACK            PICK RETURN ADDRESS             44000017
         BR    RTRG                     EXIT                            44100017
         SPACE                                                          44200017
*                                                                       44300017
*   SUBROUTINE TO TEST TCB DISPATCHABILITY FLAGS AND RB WAIT COUNT.     44400017
*                                                                       44500017
READYCHK LTR   TESTTCB,TESTTCB          TEST IF HAVE TCB ADDRESS        44600017
         BCR   CCZERO,VECTR              NO - CANNOT BE DISPATCHABLE    44700017
         LH    WKRG,TCBFLGS(,TESTTCB)   PICK TCB NON-DISPATCHABL FLGS   44800017
         LTR   WKRG,WKRG                TEST IF ANY FLAGS SET           44900017
         BCR   NTZERO,VECTR              YES - TCB NOT DISPATCHABLE     45000017
         L     WKRG,TCBRBP(,TESTTCB)    PICK TOP RB ON SELECTED TCB     45100017
         TM    RBWCF(WKRG),PSWENAB      TEST IF RB IN WAIT STATE        45200017
         BCR   NTZERO,VECTR              YES - TCB NOT DISPATCHABLE     45300017
         BR    LKRG                     TCB IS DISPATCHABLE             45400017
*                                                                       45500017
ZERONEW  XC    IEATCBP,IEATCBP          ZERO BOTH NEWS - OWN            45600017
         XC    IEATCBP-IEAQFX00(,PRF2),IEATCBP-IEAQFX00(PRF2) - OTHR    45700017
         B TESTRET                      GO RESTORE REGISTERS, EXIT      45800017
         TITLE 'H A L T    I / O    I N T E R F A C E'                  45900017
*                                                                       46000017
HIORG0   EQU   0                   .SYMB REG.                           46100017
HIORG1   EQU   1                   .UCB MP65.                           46200017
HIORG2   EQU   2                   .WORK REG.                           46300017
HIORGL   EQU   7                   .UCB SRCH.                           46400017
HIORGU   EQU   8                   .UCB ADDR.                           46500017
HIORGE   EQU   14                  .LINK REG.                           46600017
HIORGF   EQU   15                  .RETN REG.                           46700017
*                                                                       46800017
         SPACE                                                          46900017
*                                                                       47000017
*              S E C O N D    C P U    H A L T    I / O    R O U T I N  47100017
*                                                                       47200017
         SPACE                                                          47300017
*                                                                       47400017
*   ENTRY FROM EXTERNAL INTERRUPT.  WHEN HIO SERVICE HAS BEEN PERFORMD, 47500017
*   INDICATE SO BY TURNING OFF REQUEST FLAG IN OTHER CPU STMASK, AND    47600017
*   RETURN TO SECOND CPU SERVICE ROUTINE TO TEST FOR FURTHER REQUESTS.  47700017
*                                                                       47800017
HLTIOUNT DS    0H                  .EX INTERRUPT IMM HIO ENTRY.         47900017
         STM   HIORG0,HIORGF,HIOSAV .SAVE ALL REGS.                     48000017
         TM    CPUSTAT,CPUSTTWO    .TEST IF TWO PROCESSOR SYSTEM.       48100017
         BZ    HIOTST              .YES - CONTINUE.                     48200017
HIOLEV   L     HIORGE,PREFIX2      .OTHER CPU PSA ADDR.                 48300017
         NI    STMASK-IEAQFX00(HIORGE),WRDNTHIO .TURN OFF IMM HIO FLAG. 48400017
         LM    HIORG0,HIORGF,HIOSAV .RELOAD ALL REGS.                   48500017
         B     INTEXSWC            .EXIT.                               48600017
         SPACE                                                          48700017
*                                                                       48800017
*   SCAN ENTIRE UCB TABLE TO FIND EACH DEVICE WHICH HAS BEEN FLAGGED    48900017
*   FOR THIS CPU TO PERFORM HIO OPERATION.                              49000017
*                                                                       49100017
HIOTST   L     HIORGL,HIOILK       .ADDR OF UCB LOOKUP TABLE.           49200017
HIOUCB   LH    HIORGU,HIODSU(,HIORGL) .PICK UCB ADDR.                   49300017
         LA    HIORGL,HIODSL(,HIORGL) .STEP TO NEXT UCB PTR.            49400017
         N     HIORGU,HIOTWM       .CLEAR 2 HI BYTES.                   49500017
         BZ    HIOUCB              .FILLER - STEP UCB.                  49600017
         CL    HIORGU,HIOTWM       .TEST IF END OF UCB LOOKUP TABLE.    49700017
         BE    HIOLEV              .YES - EXIT FROM HIO ROUTINE.        49800017
         L     HIORG1,HIONEG       .PICK NEGATIVE UCB DISPLACEMENT.     49900017
         AR    HIORG1,HIORGU       .DEVELOP EXTENSION BYTE ADDRESS.     50000017
         IC    HIORG2,HIODSB(,HIORG1) .PICK UCB EXTENSION BYTE.         50100017
         SRL   HIORG2,HIOSHF       .POSITION HALT I/O REQUEST BITS.     50200017
         N     HIORG2,HIOCPM       .CLEAR ALL BUT LOW 2 BITS.           50300017
         EX    HIORG2,HIOTMK       .TEST HIO FLAG FOR THIS CPU.         50400017
         BZ    HIOUCB              .NO - STEP UCB.                      50500017
         IC    HIORG2,HIODSB(,HIORG1) .PICK UCB EXTENSION BYTE.         50600017
         N     HIORG2,HIOPUM       .CLEAR ALL BUT I/O CPUID BIT.        50700017
         C     HIORG2,IOCPUID      .WAS I/O STARTED ON THIS CPU.        50800017
         BNE   HIOFLG              .NO - TURN OFF BAD FLAG.             50900017
*                                                                       51000017
*   LINK TO RESIDENT IOS ROUTINE TO HANDLE HIO AND CCH FOR THIS DEVICE. 51100017
*                                                                       51200017
         L     HIOBAS,HIOHIO       .GET I/O RESIDENT HIO RTNE ADDR.     51300017
         USING IECIHIO+2,HIOBAS                                         51400017
         BAL   HRETRG,IECHIORT     .LINK TO HIO ROUTINE.                51500017
         DROP  HIOBAS                                                   51600017
*                                                                       51700017
*   TURN OFF UCB FLAG WHICH REQUESTED HIO BY THIS CPU.                  51800017
*                                                                       51900017
HIOFLG   IC    HIORG2,CPUID        .PICK OWN CPU IDENTIFICATION.        52000017
         N     HIORG2,HIOCPM       .CLEAR ALL BUT LOW 2 BITS.           52100017
         SLL   HIORG2,HIOSHF       .POSITION BITS FOR HALT I/O FLAG.    52200017
         X     HIORG2,HIOTWM       .INVERT FLAG.                        52300017
         EX    HIORG2,HIONMK       .TURN OFF HIO FLAG IN UCB EXTENSION. 52400017
         B     HIOUCB              .GO ON TO NEXT UCB.                  52500017
         SPACE                                                          52600017
*                                                                       52700017
*              F I R S T    C P U    H A L T    I / O    R O U T I N E  52800017
*                                                                       52900017
         SPACE                                                          53000017
*                                                                       53100017
*   BRANCH ENTRY FROM RESIDENT IOS HIO ROUTINE.  GIVEN THAT AN I/O OPER 53200017
*   CAN ONLY BE HALTED BY THE SAME CPU WHICH ISSUED THE SIO, TEST WHICH 53300017
*   CPU STARTED THE I/O OPERATION.  IF I/O STARTED BY THIS CPU, BRANCH  53400017
*   BACK TO IOS HIO ROUTINE TO CONTINUE HIO PROCESSING BY THIS CPU.     53500017
*                                                                       53600017
IECMPHIO DS    0H                  .RESIDENT IOS HIO ROUTINE ENTRY.     53700017
         USING IECIHIO+2,HIOBAS                                         53800017
         TM    CPUSTAT,CPUSTTWO    .TEST IF TWO PROCESSOR SYSTEM.       53900017
         BNZ   IECHIORT            .NO - RETURN TO IOS HIO ROUTINE.     54000017
         STM   HIORGE,HIORG2,HIOPSV .SAVE REGISTERS.                    54100017
         L     HIORG1,HIONEG       .PICK NEGATIVE UCB DISPLACEMENT.     54200017
         AR    HIORG1,HIORGU       .DEVELOP EXTENSION BYTE ADDRESS.     54300017
         IC    HIORG2,HIODSB(,HIORG1) .PICK UCB EXTENSION BYTE.         54400017
         N     HIORG2,HIOPUM       .CLEAR ALL BUT I/O CPUID BIT.        54500017
         C     HIORG2,IOCPUID      .WAS I/O STARTED ON THIS CPU.        54600017
         BNE   HIOTHR              .NO - GO SHOULDERTAP OTHER CPU.      54700017
         LM    HIORG1,HIORG2,HIOPSU .RELOAD USED REGISTERS.             54800017
         B     IECHIORT            .EXIT TO IOS HIO ROUTINE.            54900017
         SPACE                                                          55000017
*                                                                       55100017
*   OTHER CPU STARTED I/O - MUST REQUEST IT TO PERFORM THE ACTUAL HIO.  55200017
*   INDICATE THAT AN IMMEDIATE HIO IS REQUESTD, AND SIGNAL (SHOULDRTAP) 55300017
*   THE OTHER CPU.  WHEN HIO DONE, RETURN TO CALLER OF IOS HIO ROUTINE. 55400017
*                                                                       55500017
HIOTHR   IC    HIORG2,CPUID        .PICK OWN CPU IDENTIFICATION.        55600017
         N     HIORG2,HIOCPM       .CLEAR ALL BUT LOW 2 BITS.           55700017
         X     HIORG2,HIOCPM       .INVERT CPU ID FLAG BITS.            55800017
         SLL   HIORG2,HIOSHF       .POSITION BITS FOR HALT I/O FLAG.    55900017
         EX    HIORG2,HIOIFL       .SETON HIO FLAG IN UCB EXTENSION.    56000017
         OI    STMASK,WRDWTHIO     .SETON HIO FLAG IN SHOULDTAP MASK.   56100017
         BAL HIORGE,FLASH          .LINK TO FIRST CPU EXTRN SIGNAL RTN. 56200017
         LM    HIORGE,HIORG2,HIOPSV .RELOAD REGS.                       56300017
         BR    HRETRG              .EXIT TO CALLER OF IOS HIO ROUTINE.  56400017
         DROP  HIOBAS                                                   56500017
         SPACE                                                          56600017
*                                                                       56700017
*   CONSTANTS AND WORKAREAS USED BY HIO ROUTINE                         56800017
*                                                                       56900017
HIOSAV   DS    16F                 .REG SAVE AREA.                      57000017
HIOPSV   DS    5F                  .REG SAVE AREA.                      57100017
HIOPSU   EQU   HIOPSV+12           .OFFSET TO REG 1 IN REG SAVE AREA.   57200017
HIOILK   DC    A(IECILK2)          .UCB LOOKUP TABLE BEG ADDR.          57300017
HIOHIO   DC    A(IECIHIO+2)        .RESIDENT HIO ROUTINE BASE.          57400017
HIONEG   DC    X'FFFF'             .NEGATIVE PREFIX TO ADDR CONSTANT.   57500017
         DC    Y(0-UCBMPANX)       .M65MP UCB EXTENSION NEG DISPLACMT.  57600017
HIOTWM   DC    X'0000FFFF'         .MASK TO CLEAR HIGH 2 BYTES.         57700017
HIOCPM   DC    X'00000003'         .MASK TO CLEAR ALL BUT LOW 2 BITS.   57800017
HIOPUM   DC    X'00000008'         .MASK TO CLEAR ALL BUT IOCPUID BIT.  57900017
*                                                                       58000017
HIODSU   EQU   0                   .SYMB DISPL UCB ADR IN LOOKUP TABLE. 58100017
HIODSL   EQU   2                   .SYMB LENGTH ENTRY UCB LOOKUP TABLE. 58200017
HIODSB   EQU   0                   .SYMB DISPL MP BYTE IN NEG UCB EXTN. 58300017
HIOSHF   EQU   4                   .SYMB SHIFT TO HIO FLAG IN MP BYTE.  58400017
*                                                                       58500017
HIOZRO   EQU   X'00'               .SYMB I2 FIELD OF ZERO FOR EX INSTR. 58600017
HIOTMK   TM    CPUID,HIOZRO        .EXECUTED INST TEST HIO THIS CPU.    58700017
HIOIFL   OI    HIODSB(HIORG1),HIOZRO .EXECUTED INST TURNS ON HIO FLAG.  58800017
HIONMK   NI    HIODSB(HIORG1),HIOZRO .EXECUTED INST TURN OFF HIO FLAG.  58900017
         TITLE 'P R O C E S S O R    S T O P    R O U T I N E S'        59000017
*                                                                       59100017
*   SECOND CPU BELL RING ROUTINE - PUT CPU INTO SAME WAIT STATE         59200017
*                                                                       59300017
INTBELST NI    STMASK-IEAQFX00(INTRGPSA),WRDNTBEL .TURN OFF STAP FLAG.  59400017
         LA    INTRGPSW,IONPSW-IEAQFX00(,INTRGPSA) .DISPLAY SAME WTCOD. 59500017
         B     INTEXRTO            .EXIT.                               59600017
         SPACE                                                          59700017
*                                                                       59800017
*   SECOND CPU VARY OFFLINE ROUTINE - PUT CPU INTO -MANUAL- STATE       59900017
*                                                                       60000017
LOCKSTOP DS    0H                  .ENTRY TO PUT CPU IN -MANUAL- STATE. 60100017
*        WRD   VARYMCW,X'20'       .ENABLE I/O ON OTHER CPU /SIESTA/.   60200017
         L     INTRGWK2,MPCVTPTR   .PICK ADDR MPCVT WITH SYSTEM LOCK.   60300017
         XC    MPCVTAFF(LOKSIZE,INTRGWK2),MPCVTAFF(INTRGWK2) .CLR LOCK. 60400017
VARYSTOP DC    X'8300'             .DIAGNOSE INSTR - GIVE CPU ROS ADDR. 60500017
         DC    S(VARYMCW)          .ADDR OF MAINTENANCE CONTROL WORD.   60600017
         B     VARYSTOP            .REPEAT STOP IF OPERATR PRESS START. 60700017
         DS    0D                  ADDRESSABILITY ON DOUBLE WORD        60800017
VARYMCW  DC    X'00026000'         ROS TRANSFER ADDRESS FOR STOP LOOP   60900017
         DC    F'0'                RIGHT HALF MAINTENANCE CONTROL WORD  61000017
         TITLE ' '                                                      61800017
.MPCODBY ANOP                                                           61900017
         MEND                                                           62000017
