         MACRO                                                          00000010
         ITLPCSIM &TYPE=FULL,&CTRLPGM=                                  00000020
         GBLA  &GTR   MAY BE SET TO NONZERO EXTERNALLY TO TRACE         00000030
         GBLC  &COUNTS   MAY BE SET TO 'Y' EXTERNALLY TO COUNT          00000040
         GBLC  &GCP                                                     00000050
         LCLA  &TRDSPL                                                  00000060
&GCP     SETC  'O'                                                      00000070
         AIF   ('&TYPE' EQ 'NULL').NORELOC                     1/6/76   00000080
         TITLE 'ITEL RELOCATABLE 370 INSTRUCTION SIMULATOR MODULE'      00000090
*********************************************************************** 00000100
* INSTRUCTION SIMULATION MODULE                                       * 00000110
*                                                                     * 00000120
* COPYRIGHT 1974 BY                                                   * 00000130
*        ITEL CORPORATION                                             * 00000140
*        DATA PRODUCTS GROUP                                          * 00000150
*        3460 WEST BAYSHORE ROAD                                      * 00000160
*        PALO ALTO, CALIFORNIA 94303                                  * 00000170
*                                                                     * 00000180
*********************************************************************** 00000190
ITLSIS&GCP CSECT                                                        00000200
         USING *,QR15                                                   00000210
         B     *+24                                                     00000220
         DC    C'COPYRIGHT ITEL 1974 '                                  00000230
         AIF   (&GTR EQ 0).NOTRACE                                      00000240
&TRDSPL  SETA  8*&GTR-8                                                 00000250
         AIF   (&GTR EQ 1).TRACE1                                       00000260
         MVC   TRACETBL(&TRDSPL),TRACETBL+8 * MOVE TRACE TABLE DOWN     00000270
.TRACE1  ANOP                                                           00000280
         MVC   TRACETBL+&TRDSPL.(8),QPRGOLD * TRACE PGM OLD PSW         00000290
.NOTRACE ANOP                                                           00000300
         TM    QSW1,REENTRY *          PGM CHK DURINT SIS               00000310
         BO    SISPC *                 YES, SIS GENERATED PGM CHK       00000320
         OI    QSW1,REENTRY *          SET SIS IN CTL (FOR  REENTRY)    00000330
         L     QR1,IHLCON1           GET POINTER TO IEAPKSAV            00000340
         MVC   QPCSV(64),0(QR1) *       SAVE PFLIH REGS                 00000350
         LM    QR0,QR1,QPRGOLD       GET PRG OLD                        00000360
         STM   QR0,QR1,QPGOPSW       SAVE PSW                           00000370
         TM    QPRGADR+3,X'01'       TEST IF ODD BNDRY BRANCH           00000380
         BO    QPCEX0                YES,EXIT                           00000390
* BACK UP PSW ADDR (QR1) TO START OF INST                               00000400
         TM    QPRGADR,B'11000000'   TEST IF ILC=0                      00000410
         BZ    QPCEX0                YES-IMPRECISE-EXIT                 00000420
         L     QR10,QPRGADR          GET ADDR PART OF PSW               00000430
         L     QR11,Q4N02            GET ILC&LEN FACTOR                 00000440
         SLR   QR10,QR11               SUBTRACT MINIM                   00000450
         CLR   QR10,QR11               TEST IF DONE                     00000460
         BNL   *-4                     LOOP                             00000470
         LA    QR1,0(,QR10)          QR1 POINTS TO FAILING INST         00000480
         ALR   QR10,QR11             AT  LEAST 2                        00000490
         TM    0(QR1),B'11000000'    TEST OP CDE FORMAT                 00000500
         BM    *+10                  LENGTH 4                           00000510
         BZ    *+8                   LENGTH 2                           00000520
         ALR   QR10,QR11             LENGTH 6                           00000530
         ALR   QR10,QR11             ADD LENGTH MINIM                   00000540
         ST    QR10,QPRGADR          SAVE NEXT ADDR                     00000550
         EJECT                                                          00000560
****************************************************************        00000570
*                                                                       00000580
QFMTDCDE DS    0H                    INST FORMAT DECODE                 00000590
* INSTRUCTION DECODE                                                    00000600
* RR TYPE  QR1 POINTS TO INST                                           00000610
*          QR2 POINTS TO SAVED R1                                       00000620
*          QR6 POINTS TO SAVED R2                                       00000630
* RS TYPE  QR1 POINTS TO INST                                           00000640
*          QR2 POINTS TO SAVED R1                                       00000650
*          QR3 CONTAINS M3 OR R3                                        00000660
*          QR5 CONTAINS SUM(B2)+D2                                      00000670
* SI TYPE  QR1 POINTS TO INST                                           00000680
*          QR3 CONTAINS I2 OR EXTENDED OP CODE                          00000690
*          QR4 POINTS TO B1 D1                                          00000700
* RX TYPE QR1 POINTS TO INST                                            00000710
*          QR2 POINTS TO SAVED R1                                       00000720
*         QR7 CONTAINS SUM(X2 NE 0)+(B2 NE 0)+D2                        00000730
* SS TYPE  QR1 POINTS TO INST                                           00000740
*          QR3 CONTAINS L1/I3                                           00000750
*          QR4 CONTAINS SUM(B1)+D1                                      00000760
*          QR5 CONTAINS SUM(B2)+D2                                      00000770
*                                                                       00000780
*********************************************************************** 00000790
         SPACE 2                                                        00000800
         LH    QR11,2(,QR1)          GET B2 D2                          00000810
         BAL   QR14,QB1D1            COMPUTE SUM (B2 NE 0)+D2           00000820
         LR    QR4,QR5               SET QR4=SUM(B1 NE 0)+D1            00000830
         SR    QR3,QR3               CLEAR QR3                          00000840
         IC    QR3,1(,QR1)           R1/R2,R1/R3,R1/M3,R1/X2            00000850
         BAL   QR14,QR1R2              POINT QR2/QR6 TO SAVED R1/R2     00000860
         TM    0(QR1),B'11000000'    TEST IF SS TYPE                    00000870
         BNO   *+12                  NO,SKIP B1D1 CALC                  00000880
         LH    QR11,4(,QR1)          GET B1 D1                          00000890
         BAL   QR14,QB1D1            COMPUTE SUM (B1 NE 0)+D1           00000900
         SR    QR11,QR11             CLEAR QR11                         00000910
         TM    1(QR1),X'0F'          TEST IF X2=0                       00000920
         BZ    *+8                   YES SKIP INDEX COMP                00000930
         L     QR11,0(,QR6)          GET SAVED X2                       00000940
         LA    QR7,0(QR11,QR4)         QR7=SUM(X2NE0)+(B1NE0)+D2        00000950
*                                    END DECODE                         00000960
         EJECT                                                          00000970
****************************************************************        00000980
* TEST FOR AND PROCESS EXECUTE INST                                     00000990
         CLI   0(QR1),X'44'          TEST IF EXECUTE INST               00001000
         BNE   QPCNORM               NO,NORMAL                          00001010
         LH    QR11,0(,QR7)          TEST INST BOUNDARY                 00001020
         CLI   QNTCD2,QEXEX          TEST IF EX EXC                     00001030
         BE    QPCEX0                YES,TERMINATE                      00001040
* MOVE IT TO SPECIAL EXECUTION AREA                                     00001050
         MVC   QTMP0-4(6),0(QR7)     MOVE TARGET TO XEQ AREA            00001060
         TM    1(QR1),X'F0'          TEST IF R1 FIELD 0                 00001070
         BZ    *+10                  YES,SKIP EX MODIFIER               00001080
         OC    QTMP0-3(1),3(QR2)     OR 'EX' MODIFIER(BYTE 3 OF R1)     00001090
         LA    QR1,QTMP0-4           SET INST ADDR TO SP AREA           00001100
         B     QFMTDCDE              DECODE EXECUTE TARGET              00001110
* END EXECUTE PROCESSING                                                00001120
****************************************************************        00001130
QPCNORM  DS    0H                    NORMAL PROCESS                     00001140
         L     QR12,QPRGADR          SET UP USER CC&PRG MASK            00001150
         IC    QR10,QAMWP            GET USER KEY/AMWP                  00001160
         N     QR10,QF0              ISOLATE KEY                        00001170
         BAL   QR14,QSTEXTMD         SET STG&PSW KEY TO USERS           00001180
         EJECT                                                          00001190
*********************************************************************** 00001200
* LOOK UP OP CODE IN TAB - FORMAT OPCDE/DESCRIPTION/PROCESSOR           00001210
QPCOP    DS    0H                    OPERATION EXCEPTION                00001220
         LA    QR9,QINSTB            START OP TBL                       00001230
         LA    QR10,3                BYTES/ENTRY                        00001240
         LA    QR11,QINSTBL-2        END OF OP TBL                      00001250
         IC    QR8,0(,QR1)           GET OP CODE                        00001260
         STC   QR8,QCDS+1            SAVE FOR COMPARE                   00001270
QCDS     CLI   0(QR9),00             OP FILLIN=TABL VAL                 00001280
         BE    QDCDE                 YES GO DECODE INST                 00001290
         BXLE  QR9,QR10,QCDS         LOOP                               00001300
         CLI   QNTCD2,QSPEX          TEST IF SPEC EX                    00001310
         BNE   QPCEX0                NOT HANDLED-ERR EXIT               00001320
         BAL   QR14,QSPCEX           DO SPECIFICATION EXCEPTIONS        00001330
         B     QPCEX1                EXIT                               00001340
QDCDE    DS    0H                    DECODE INSTRUCTION                 00001350
         MVC   QTMP6(2),1(QR9)       ALIGN ADDR                         00001360
         LH    QR11,QTMP6            LOAD IT                            00001370
         LA    QR11,QINSTBE(QR11)    ADDRESS QUASI EXECUTOR             00001380
         SPM   QR12                  SET USER CC&PRG MASK               00001390
         BALR  QR14,QR11             GO TO QUASI                        00001400
         B     QPCEX1                EXIT COMPLETE                      00001410
         EJECT                                                          00001420
QINSTB   DS    0H                    INSTRUCTION TABLE                  00001430
         DC    X'BA'                 COMPARE AND SWAP                   00001440
         DC    AL2(QCS-QINSTBE)                                         00001450
         DC    X'BB'                 COMPARE DOUBLE AND SWAP            00001460
         DC    AL2(QCDSI-QINSTBE)                                       00001470
         AIF   ('&TYPE' EQ 'SHORT').BYPREST                 1/6/76      00001480
         DC    X'AC' *                  STNSM                           00001490
         DC    AL2(QSTNSM-QINSTBE) *    STNSM QUASI RTN                 00001500
         DC    X'AD' *                  STOSM                           00001510
         DC    AL2(QSTOSM-QINSTBE) *    STOSM QUASI RTN                 00001520
         DC    X'B1' *                 LRA                              00001530
         DC    AL2(QLRA-QINSTBE) *     LRA QUASI RTN                    00001540
         DC    X'B2'                 STIDP/STIDC/SCK/STCK               00001550
         DC    AL2(QCSUB-QINSTBE)    CSUB QUASI RTN                     00001560
         DC    X'BD'                 CLM                                00001570
         DC    AL2(QCLM-QINSTBE)     CLM  QUASI RTN                     00001580
         DC    X'BE'                 STCM                               00001590
         DC    AL2(QSTCM-QINSTBE)    STCM QUASI RTN                     00001600
         DC    X'BF'                 ICM                                00001610
         DC    AL2(QICM-QINSTBE)     ICM  QUASI RTN                     00001620
         DC    X'0E'                 MVCL                               00001630
         DC    AL2(QMVCL-QINSTBE)    MVCL QUASI RTN                     00001640
         DC    X'0F'                 CLCL                               00001650
         DC    AL2(QCLCL-QINSTBE)    CLCL QUASI RTN                     00001660
         DC    X'B6'                 STCTL                              00001670
         DC    AL2(QSTCTL-QINSTBE)   STCTLQUASI RTN                     00001680
         DC    X'B7'                 LCTL                               00001690
         DC    AL2(QLCTL-QINSTBE)    LCTL QUASI RTN                     00001700
         DC    X'F0'                 SRP                                00001710
         DC    AL2(QSRP-QINSTBE)     SRP  QUASI RTN                     00001720
.BYPREST ANOP                                             1/6/76        00001730
QINSTBL  EQU   *                     END OF INST TBL                    00001740
QINSTBE  DS    0H                    INSTRUCTION TABLE END              00001750
         EJECT                                                          00001760
*                                                                       00001770
* COMPARE AND SWAP / COMPARE DOUBLE AND SWAP                            00001780
*                                                                       00001790
CS       SUBTAG BA                     COMPARE AND SWAP ENTRY           00001800
         ST    QR4,QTMP1                                                00001810
         TM    QTMP1+3,X'03'                                            00001820
         BNZ   QCSSPEX                  SPECIFICATION EXCEPTION         00001830
         LA    QR8,3                    LENGTH FOR CS                   00001840
         B     QCS01                                                    00001850
CDSI     SUBTAG BB                                                      00001860
         ST    QR4,QTMP1                                                00001870
         TM    QTMP1+3,X'07'                                            00001880
         BNZ   QCSSPEX                  SPECIFICATION EXCEPTION         00001890
         TM    1(QR1),X'11'                                             00001900
         BNZ   QCSSPEX                  SPECIFICATION EXCEPTION         00001910
         LA    QR8,7                    LENGTH FOR CDS                  00001920
QCS01    EX    QR8,QCSCLC                                               00001930
         BNE   QCS02                    FIRST OPERAND NOT EQ SECOND     00001940
         BAL   QR9,QAR4                 TEST STORAGE ADDR               00001950
         EX    QR8,QCSMVCEQ             THIRD OPERAND TO SECOND         00001960
         SR    QR12,QR12                SET CC=0                        00001970
         BR    QR14                     RETURN                          00001980
QCS02    EX    QR8,QCSMVCNE             SECOND OPERAND TO FIRST         00001990
         L     QR12,QCSCC1              SET CC=1                        00002000
         BR    QR14                     RETURN                          00002010
QCSSPEX  MVI   QNTCD2,QSPEX             SET SPECIFICATION EXCEPTION     00002020
         B     QPCEX0                   EXCEPTION RETURN                00002030
QCSCLC   CLC   0(0,QR2),0(QR4)                                          00002040
QCSMVCEQ MVC   0(0,QR4),0(QR6)                                          00002050
QCSMVCNE MVC   0(0,QR2),0(QR4)                                          00002060
QCSCC1   DS    0F                                                       00002070
         DC    X'10000000'              CONDITION CODE 1                00002080
         AIF   ('&TYPE' EQ 'SHORT').B360SM                    1/6/76    00002090
         EJECT                                                          00002100
STNSM    SUBTAG AC                                                      00002110
         BAL   QR10,QSTNOSM *           STNSM/STOSM COMMON RTN          00002120
         NC    QPSWMSK,1(QR1) *         AND SYSTEM MASK                 00002130
         TM    QPSWMSK,X'02' *          IS I/O MASK ONE?                00002140
         BCR   1,QR14 *                 YES, RETURN                     00002150
         NI    QPSWMSK,X'01' *          SET ALL CHANNEL MASKS ZERO      00002160
         BR    QR14 *                   RETURN                          00002170
STOSM    SUBTAG AD                                                      00002180
         BAL   QR10,QSTNOSM *           STNSM/STOSM COMMON RTN          00002190
         OC    QPSWMSK,1(QR1) *         OR SYSTEM MASK                  00002200
         TM    QPSWMSK,X'02' *          IS I/O MASK ONE?                00002210
         BCR   8,QR14 *                 NO, RETURN                      00002220
         OI    QPSWMSK,X'FE' *          SET ALL CHANNEL MASKS ONE       00002230
         BR    QR14 *                   RETURN                          00002240
QSTNOSM  DS    0H                       STNSM/STOSM COMMON RTN          00002250
         MVI   QNTCD2,QPRVEX *          PRESET PRV EXCEPTION            00002260
         TM    QAMWP,QPP *              IS IT PROB PROG?                00002270
         BO    QPCEX0 *                 YES,PRV EXC                     00002280
         IC    QR8,QPSWMSK *            GET MASK                        00002290
         STC   QR8,0(QR4) *             STORE MASK IN 1ST OPERAND LOC   00002300
         NI    0(QR4),X'03' *           TURN CH 1-5 MASKS OFF           00002310
         BR    QR10 *                   RETURN                          00002320
         EJECT                                                          00002330
LRA      SUBTAG B1                                                      00002340
         MVI   QNTCD2,QPRVEX *          PRESET PRV EXC                  00002350
         TM    QAMWP,QPP *              IS IT PROB PROG?                00002360
         BO    QPCEX0 *                 YES,PRV EXC                     00002370
         IC    QR8,0(QR7) *             GEN ADDR EXCP IF OUTSIDE MCH    00002380
         SR    QR8,QR8 *               CLEAR R8                         00002390
         IC    QR8,1(QR1) *            GET R1/X2                        00002400
         SRL   QR8,4 *                 SHIFT X2 TO LOW ORDER            00002410
         SLL   QR8,2 *                 MULTIPLY BY 4                    00002420
         ST    QR7,QR0SV(QR8) *        STORE D2(X2,B2)                  00002430
         SR    QR12,QR12                                                00002440
         BR    QR14 *                  RETURN                           00002450
         EJECT                                                          00002460
****************************************************************        00002470
.COMCP12 ANOP                                                           00002480
SRP      SUBTAG F0                                                      00002490
         BAL   QR9,QAR4                TEST IF VALID STG ARG            00002500
* TEST VALIDITY OF MASK                                                 00002510
         STC   QR3,QSRPLA+3                                             00002520
         NI    QSRPLA+3,X'0F'                                           00002530
         CLI   QSRPLA+3,X'0A'                                           00002540
         BL    QSRPMOK BRANCH IF MASK < 10                              00002550
         ZAP   QTMP1+QW17(1),*      GENERATE DATA EXCEPTION             00002560
QSRPMOK  EQU   * MASK IS OK                                             00002570
* GENERATE SIGN AND TEST FOR VALID DATA                                 00002580
         LR    QR9,QR3 L1/I3 TO QR9                                     00002590
         SRL   QR9,4 LENGTH TO RIGHT NIBBLE                             00002600
         STC   QR9,QSRPLAS+3                                            00002610
         EX    QR9,QSRPZAP1 GENERATE SIGN AND/OR DATA EXCEPTION         00002620
         MVC   QTMP1+QSS(1),QTMP1+QW17+16 SAVE SIGN                     00002630
         NI    QTMP1+QSS,X'0F' CLEAR RIGHT NIBBLE                       00002640
         NI    QTMP1+QW17+16,X'F0' CLEAR SIGN                           00002650
         MVI   QTMP1+QW17,X'00' CLEAR HI ORDER BYTE OF WORK AREA        00002660
* TEST SHIFT ARGUMENT FOR EVEN/ODD, LEFT/RIGHT                          00002670
         LR    QR10,QR5 SHIFT ARGUMENT TO QR10                          00002680
         SRDL QR10,1 EVEN/ODD BIT POS TO QR11                           00002690
         LTR   QR11,QR11 TEST                                           00002700
         BNM   QSRPLRT BRANCH IF EVEN SHIFT                             00002710
         SR    QR9,QR9 CLEAR                                            00002720
         IC    QR9,QTMP1+QW17+1 HIGH ORDER BYTE TO R9                   00002730
         SLL   QR9,4 LEFT NIBBLE TO RIGHT NIBBLE                        00002740
         STC   QR9,QTMP1+QW17 NEW HIGH ORDER BYTE                       00002750
         MVO QTMP1+QW17+1(16),QTMP1+QW17+1(16) SHIFT RIGHT ONE NIBBLE   00002760
QSRPLRT  XC    QTMP1+QW32(32),QTMP1+QW32 CLEAR QW32                     00002770
         SLL   QR10,27 SHIFT ARGUMENT TO BIT POS 0-4                    00002780
         LTR   QR10,QR10                                                00002790
         SRL   QR10,27 SHIFT ARG TO BIT POS 27-31                       00002800
         BNM   QSRPLEFT BRANCH IF LEFT SHIFT                            00002810
* PERFORM RIGHT SHIFT                                                   00002820
         LA    QR8,QTMP1+QW32+31 LOW QRDER BYTE ADDRESS                 00002830
         SR    QR8,QR10 SUBTRACT SHIFT ARG/2                            00002840
         MVC   0(16,QR8),QTMP1+QW17 MOVE AND SHIFT INTO QW32            00002850
         IC    QR9,QTMP1+QW32+15 ROUNDING DIGIT TO QR9                  00002860
         NI    QTMP1+QW32+15,X'F0' CLEAR SIGN POS                       00002870
         OC    QTMP1+QW32+15(1),QTMP1+QSS INSERT SIGN                   00002880
QSRPSLL  SLL   QR9,28 CLEAR LEFT  NIBBLE                                00002890
         SRL   QR9,28                                                   00002900
QSRPLA   LA    QR9,0(QR9) ADD ROUNDING FACTOR TO ROUNDING DIGIT         00002910
         CH    QR9,QSRPH10 TEST FOR ROUND UP                            00002920
         BL    QSRPLFIN BRANCH IF SUM < 10 (DONT ROUND UP)              00002930
         AP    QTMP1+QW32(16),QSRPSLL+3(1) ROUND UP                     00002940
QSRPLFIN EX    QR3,QSRPZAP2 ZAP RESULT TO USER FIELD                    00002950
         BALR  QR12,QR14 COND CODE TO QR12 AND RETURN                   00002960
* PERFORM LEFT SHIFT                                                    00002970
QSRPLEFT LA    QR8,QTMP1+QW32+15  HIGH ORDER BYTE ADDRESS               00002980
         SR    QR8,QR10 SUBTRACT SHIFT ARG/2                            00002990
         MVC   0(17,QR8),QTMP1+QW17 MOVE AND SHIFT INTO QW32            00003000
         OC    QTMP1+QW32+31(1),QTMP1+QSS INSERT SIGN                   00003010
         EX    QR3,QSRPZAP3  ZAP RESULT TO USER FIELD                   00003020
         BALR  QR12,0 COND CODE TO QR12                                 00003030
         OC    QTMP1+QW32(16),QTMP1+QW32 TEST FOR FORCED OVERFLOW       00003040
         BCR   8,QR14 RETURN IF NO OVERFLOW                             00003050
QSRPLAS  LA    QR10,0(QR4) ADDR OF SIGN POS                             00003060
         NI    0(QR10),X'F0' CLEAR SIGN POS                             00003070
         OC    0(1,QR10),QTMP1+QSS ENSURE PROPER SIGN                   00003080
         ZAP   QTMP1+QW17(1),QSRPSLL(4) FORCE OVERFLOW CONDITION        00003090
         BALR  QR12,QR14 COND CODE TO QR14 AND RETURN                   00003100
QSRPZAP1 ZAP   QTMP1+QW17+1(16),0(0,QR4)                                00003110
QSRPZAP2 ZAP   0(0,QR4),QTMP1+QW32(16)                                  00003120
QSRPZAP3 ZAP   0(0,QR4),QTMP1+QW32+16(16)                               00003130
QSRPH10  DC    H'10' CONSTANT TO TEST FOR ROUND UP                      00003140
QW17     EQU   0       17 BYTE WORK AREA FOR INTERMEDIATE RESULT        00003150
QSS      EQU   17      1 BYTE SAVE AREA FOR SIGN                        00003160
QW32     EQU   18      32 BYTE WORK AREA TO DEVELOP RESULT              00003170
         EJECT                                                          00003180
CLM      SUBTAG BD                                                      00003190
         LA    QR11,QCLC                                                00003200
         SR    QR12,QR12             PRESET CC=0                        00003210
         B     QCOMMONM                                                 00003220
ICM      SUBTAG BF                                                      00003230
         LA    QR11,QIC                                                 00003240
         ST    QR14,QICMST14 *       SAVE RETURN ADDRESS                00003250
         LA    QR14,QICMSCC *        LOAD ADDR OF SET CC RTN            00003260
         B     QCOMMONM                                                 00003270
STCM     SUBTAG BE                                                      00003280
         LA    QR11,QSTC                                                00003290
         BAL   QR9,QAR4                                                 00003300
QCOMMONM SLL   QR3,28                   SHIFT MASK TO HI POSITIONS      00003310
         LR    QR9,QR2               COPY LOC OF R1                     00003320
QSTCM1   LTR   QR3,QR3               TEST MASK                          00003330
         BP    QSTCM3                BIT POSITION IS ZERO               00003340
         BM    QSTCM2                BIT POSITION IS ONE                00003350
         BR    QR14                  RETURN,REMAINDER OF MASK = 0       00003360
QSTCM2   SR    QR8,QR8               FORCE CC=0                         00003370
         EX    0,0(,QR11)            EXEC BYE INSERT/ST/CL              00003380
         BE    QCLMA                 SKIP IF CC=0                       00003390
         BALR  QR12,QR14               SET CC&EXIT                      00003400
QCLMA    LA    QR5,1(,QR5)           NEXT STG ADDR                      00003410
QSTCM3   SLL   QR3,1                 NEXT BIT POSITION IN MASK          00003420
         LA    QR9,1(,QR9)           NEXT LOC IN REG                    00003430
         B     QSTCM1                LOOP                               00003440
QICMSCC  SR    QR5,QR4 *             CALCULATE B2D2 LENGTH              00003450
         BZ    QICMEXIT *            EXIT IF LENGTH =0. (CC=0)          00003460
         CLC   QICM7F,0(QR4) *       IS STORAGE OPERAND NEGATIVE?       00003470
         BL    QICMEXIT *            YES, EXIT. (CC=1)                  00003480
         BCTR  QR5,0 *               CALCULATE LENGTH-1                 00003490
         EX    QR5,QICMCLC *         SET CC. (0 IF ALL ZERO, ELSE 2)    00003500
QICMEXIT L     QR14,QICMST14 *       RESTORE RETURN ADDRESS             00003510
         BALR  QR12,QR14 *           SET CC AND RETURN                  00003520
QCLC     CLC   0(1,QR9),0(QR5)       COMPARE PSEUDO REG BYTE TO STG     00003530
QIC      MVC   0(1,QR9),0(QR5)       STG TO PSEUDO REG                  00003540
QSTC     MVC   0(1,QR5),0(QR9)       PSEUDO REG TO STG                  00003550
QICMCLC  CLC   0(0,QR4),QICM0 *      TEST STORAGE OPERAND FOR ZERO      00003560
QICM7F   DC    X'7F' *               CONSTANT TO TEST FOR NEGATIVE      00003570
QICM0    DC    F'0' *                CONSTANT TO TEST FOR ZERO          00003580
QICMST14 DS    F *                   SAVE AREA FOR ICM RETURN           00003590
         EJECT                                                          00003600
MVCL     SUBTAG 0E                                                      00003610
         MVI   QNTCD2,QSPEX            PRESET SPEC EXCEPT               00003620
         TM    1(QR1),X'11'            TEST IF R1,RI EVEN               00003630
         BNZ   QPCEX0                  NO,EXIT                          00003640
         L     QR4,0(QR2)              B1D1 A.                          00003650
         L     QR5,0(QR6)              B2D2 A.                          00003660
         LA    QR4,0(QR4)              CLEAR HI ORDER BYTE              00003670
         LA    QR5,0(QR5)              CLEAR HI ORDER BYTE              00003680
         L     QR7,4(QR2)              L1                               00003690
         L     QR8,4(QR6)              L2                               00003700
         LA    QR7,0(QR7)              CLEAR HI ORDER BYTE              00003710
         LA    QR8,0(QR8)              CLEAR HI ORDER BYTE              00003720
         BAL   QR9,QAR4 *            TEST STG ARG ADDR                  00003730
         EJECT                                                          00003740
*********************************************************************** 00003750
*                                                                       00003760
*              TEST MVCL OPERANDS FOR DESTRUCTIVE OVERLAP               00003770
*                                                                       00003780
*              DEFINITION OF DESTRUCTIVE OVERLAP                        00003790
*                                                                       00003800
*              IF SECOND OPERAND DOES NOT WRAP AROUND STORAGE,          00003810
*              MOVEMENT OCCURS IF EITHER                                00003820
*                                                                       00003830
*                   1:   ADDR1 <= ADDR2                                 00003840
*                                                                       00003850
*              OR   2:   ADDR1 >= ADDR2 + MIN (LENGTH1, LENGTH2)        00003860
*                                                                       00003870
*              IF SECOND OPERAND DOES WRAP AROUND STORAGE,              00003880
*              MOVEMENT OCCURS ONLY IF                                  00003890
*                                                                       00003900
*                   1:   ADDR1 <= ADDR2                                 00003910
*                                                                       00003920
*              AND  2:   ADDR1 >= ADDR2 + MIN (LENGTH1, LENGTH2)        00003930
*                                                                       00003940
*********************************************************************** 00003950
         SPACE                                                          00003960
         LR    QR9,QR8        QR9 <- MIN (LENGTH1, LENGBTH2)            00003970
         CR    QR7,QR8        IS LENGTH 1 < LENGTH2                     00003980
         BNL   QMVCL01             NO, USE LENGTH2                      00003990
         LR    QR9,QR7             YES, USE LENGTH 1                    00004000
QMVCL01  EQU   *                                                        00004010
         LA    QR9,0(QR5,QR9) QR9 <- ADDR2 + MIN (LENGTH1,LENGTH2)      00004020
         CR    QR9,QR5        DOES OPERAND 2 WRAP AROUND STORAGE?       00004030
         BL    QMVCLW0             YES, PERFORM WRAP AROUND TESTS       00004040
         SPACE 2                                                        00004050
*********************************************************************** 00004060
*                                                                       00004070
*              TESTS FOR NON-WRAP AROUND CASE                           00004080
*                                                                       00004090
*********************************************************************** 00004100
         SPACE                                                          00004110
         CR    QR4,QR5        ADDR1 <= ADDR2 ?                          00004120
         BNH   QMVCL30             YES, PERFORM MOVE                    00004130
         CR    QR4,QR9        ADDR1 >= ADDR2 + MIN (LENGTH1, LENGTH2) ? 00004140
         BNL   QMVCL30             YES, PERFORM MOVE                    00004150
         B     QMVCL15             NO, DESTRUCTIVE OVERLAP, SUPPRESS    00004160
         SPACE 2                                                        00004170
*********************************************************************** 00004180
*                                                                       00004190
*              TESTS FOR STORAGE WRAP AROUND CASE                       00004200
*                                                                       00004210
*********************************************************************** 00004220
         SPACE                                                          00004230
QMVCLW0  EQU   *                                                        00004240
         CR    QR4,QR5        ADDR1 <= ADDR2 ?                          00004250
         BH    QMVCL15             NO, DESTRUCTIVE OVERLAP              00004260
         CR    QR4,QR9        ADDR1 >= ADDR2 + MIN (LENGTH1, LENGTH2) ? 00004270
         BNL   QMVCL30             YES, PERFORM MOVE: BOTH TESTS TRUE   00004280
         B     QMVCL15             NO, DESTRUCTIVE OVERLAP              00004290
         EJECT                                                          00004300
*********************************************************************** 00004310
*                                                                       00004320
*              DESTRUCTIVE OVERLAP OF OPERANDS                          00004330
*              SET CONDITION CODE = 3 AND EXIT                          00004340
*                                                                       00004350
*********************************************************************** 00004360
         SPACE                                                          00004370
QMVCL15  TM    0(QR1),X'08'            FORCE CC=3                       00004380
         BALR  QR12,QR0                SAVE CC                          00004390
QMVCL18  ST    QR4,0(QR2)              RESET R1                         00004400
         ST    QR5,0(QR6)              RESET R2                         00004410
         BR    QR14                    RETURN                           00004420
QMVCL30  CR    QR7,QR8                 L1=L2                            00004430
         BALR  QR12,QR0                SAVE CC                          00004440
         LTR   QR7,QR7                 L1=0                             00004450
         BZ    QMVCL18                 YES-EXIT                         00004460
         LTR   QR8,QR8                 L2=0                             00004470
         BZ    QMVCL52                 YES-SET SHORT LOOP               00004480
QMVCL50  XC    QFWQR8,QFWQR8           CLEAR QFWQR8 TO ZERO             00004490
         CR    QR8,QR7                 SENDING LGTH > RECVNG LGTH?      00004500
         BNH   QMVCL51                 NO                               00004510
         SR    QR8,QR7                 YES, BY HOW MUCH ?               00004520
         ST    QR8,QFWQR8              STORE BY HOW MUCH (RESIDUAL)     00004530
         LR    QR8,QR7                 TRUNCATE SENDING TO RECVING      00004540
QMVCL51  C     QR8,QFW256              GREATER THAN 256 ?               00004550
         BH    QMVCL70                 YES                              00004560
         BCTR  QR8,QR0                 NO, RECUDE FOR EXECUTE           00004570
         EX    QR8,QMVCL100            MOVE REMAINING                   00004580
         LA    QR8,1(QR8)              BUMP BACK                        00004590
         AR    QR5,QR8                 UPDATE B2D2                      00004600
         AR    QR4,QR8                 UPDATE B1D1                      00004610
         SR    QR7,QR8                 REDUCE L1                        00004620
         L     QR8,QFWQR8              LOAD UP RESIDUAL                 00004630
QMVCL52  LTR   QR7,QR7                 TEST IF ZERO                     00004640
         BZ    QMVCL65                 IF YES, FINISHED                 00004650
         LA    QR10,4(QR6)             POINT TO PADDING CHARACTER       00004660
QMVCL54  C     QR7,QFW256              GREATER THAN 256?                00004670
         BH    QMVCL75                 YES                              00004680
         BCTR  QR7,QR0                 REDUCE FOR ONE CHAR MOVE         00004690
         MVC   0(1,QR4),0(QR10)        MOVE IN FIRST CHAR               00004700
         LTR   QR7,QR7                 ZERO AFTER FIRST ?               00004710
         BZ    QMVCL56                 YES                              00004720
         BCTR  QR7,QR0                 REDUCE FOR EXECUTE               00004730
         EX    QR7,QMVCL105            MOVE MORE                        00004740
         LA    QR7,1(QR7)              BUMP BACK UP                     00004750
QMVCL56  LA    QR7,1(QR7)              ONCE AGAIN FOR FIRST MOVE        00004760
         AR    QR4,QR7                 UPDATE B1D1                      00004770
         SR    QR7,QR7                 ZERO QR7                         00004780
QMVCL65  IC    QR10,4(QR6)             SAVE PADDING CHARACTER           00004790
         ST    QR8,4(QR6)              SET L2 COUNT                     00004800
         STC   QR10,4(QR6)             RESTORE PADDING CHAR             00004810
         IC    QR10,4(QR2)             BYTE 0 OF R1+1                   00004820
         ST    QR7,4(QR2)              SAVE L1 COUNT                    00004830
         STC   QR10,4(QR2)             RESTORE BYTE 0                   00004840
         B     QMVCL18                 EXIT                             00004850
QMVCL70  MVC   0(256,QR4),0(QR5)       MOVE 256 CHARACTERS              00004860
         LA    QR4,256(QR4)            UPDATE B1D1                      00004870
         LA    QR5,256(QR5)            UPDATE B2D2                      00004880
         S     QR8,QFW256              REDUCE L2                        00004890
         S     QR7,QFW256              REDUCE L1                        00004900
         B     QMVCL51                 GO BACK                          00004910
QMVCL75  MVC   0(1,QR4),0(QR10)        MOVE 256 PADDING CHARACTERS      00004920
         MVC   1(255,QR4),0(QR4)                                        00004930
         LA    QR4,256(QR4)            UPDATE B1D1                      00004940
         S     QR7,QFW256              REDUCE L1                        00004950
         B     QMVCL54                                                  00004960
QFW256   DC    F'256'                  CONSTANT                         00004970
QFWQR8   DC    F'0'                    SAVE RESIDUAL                    00004980
QMVCL100 MVC   0(0,QR4),0(QR5)         MOVE DATA                        00004990
QMVCL105 MVC   1(0,QR4),0(QR4)         MOVE PADDING                     00005000
         EJECT                                                          00005010
CLCL     SUBTAG 0F                                                      00005020
         MVI   QNTCD2,QSPEX          PRESET SPEC EX                     00005030
         TM    1(QR1),X'11'          TEST IF EVEN REGS                  00005040
         BNZ   QPCEX0                NO,EXIT-SPEC EX                    00005050
         L     QR7,0(QR2)              B1D1                             00005060
         L     QR8,4(QR2)              L1                               00005070
         L     QR9,0(QR6)              B2D2                             00005080
         L     QR10,4(QR6)             L2                               00005090
         LA    QR8,0(QR8)              CLEAR HIGH ORDER BYTES           00005100
         LA    QR10,0(QR10)            .COUNT REGISTERS                 00005110
QCLCL30  LR    QR11,QR8                R11=L1                           00005120
         AR    QR11,QR10               R11=L1+L2                        00005130
         BZ    QCLCL60                 L1=L2=0; END                     00005140
         LTR   QR8,QR8                 TEST IF L1=0                     00005150
         BZ    QCLCL80                 L1=0; LOOP PAD:S2                00005160
         LTR   QR10,QR10               TEST IF L2=0                     00005170
         BZ    QCLCL70                 L2=0; LOOP S1:PAD                00005180
         B     QCLCL40                 L1#0;L2#0; LOOP S1:S2            00005190
* LOOP PAD:S2  (L1=0,L2#0)                                              00005200
QCLCL80  CLC   4(1,QR6),0(QR9)         COMPARE PAD:S2                   00005210
         BNE   QCLCL60                 PAD NE S2- END                   00005220
QCLCL85  LA    QR9,1(,QR9)             S2=S2+1                          00005230
         BCT   QR10,QCLCL80            L2=L2-1                          00005240
         B     QCLCL60                 L2=0; END                        00005250
* LOOP S1:PAD  (L1#0,L2=0)                                              00005260
QCLCL70  CLC   0(1,QR7),4(QR6)         COMPARE S1:PAD                   00005270
         BNE   QCLCL60                 S1 NE PAD; END                   00005280
         LA    QR7,1(,QR7)             S1=S1+1                          00005290
         BCT   QR8,QCLCL70             L1=L1-1                          00005300
         B     QCLCL60                 L1=0; END                        00005310
* LOOP S1:S2   (L1#0,L2#0)                                              00005320
QCLCL40  CLC   0(1,QR7),0(QR9)         COMPARE S1:S2                    00005330
         BNE   QCLCL60                 S1 NE S2; END                    00005340
         LA    QR7,1(,QR7)             S1=S1+1                          00005350
         BCT   QR8,QCLCL45             L1=L1-1                          00005360
         B     QCLCL85                 L1=0; LOOP PAD:S2                00005370
QCLCL45  LA    QR9,1(,QR9)             S2=S2+1                          00005380
         BCT   QR10,QCLCL40            L2=L2-1                          00005390
         B     QCLCL70                 L2=0; LOOP S1:PAD                00005400
QCLCL60  BALR  QR12,QR0              SAVE CONDITION CODE                00005410
         IC    QR3,4(QR6)              PICK UP PADDING CHAR             00005420
         ST    QR10,4(QR6)             SAVE L2                          00005430
         STC   QR3,4(QR6)              RESTORE PADDING CHAR             00005440
         IC    QR3,4(QR2)              PICK UP BYTE 0 OF R1+1           00005450
         ST    QR8,4(QR2)              SAVE L1                          00005460
         STC   QR3,4(QR2)              RESTORE BYTE 0                   00005470
         ST    QR7,0(QR2)              STORE UPDATED S1                 00005480
         ST    QR9,0(QR6)              STORE UPDATED S2                 00005490
         BR    QR14                    RETURN                           00005500
         EJECT                                                          00005510
.B360SM  ANOP                                                           00005520
* SUBROUTINE FOR HANDLING SPEC EXCEPTIONS                               00005530
* QR1 POINTS TO ORIGINAL INSTRUCTION                                    00005540
* QR2 POINTS TO SAVED R1                                                00005550
* QR4 POINTS TO OPERAND ADDRESS                                         00005560
* TEST IF PROPER FOR SPEC EXCP                                          00005570
SPCEX    SUBTAG 00                                                      00005580
         AIF  ('&TYPE' NE 'SHORT').B360SMY                              00005590
         B     QPCEX0                FOR 155/165 ALL SPEC BAD           00005600
         AGO   .B360SMX                                                 00005610
.B360SMY ANOP                                                           00005620
         TM    0(QR1),B'11000000'    TEST OP FORMAT                     00005630
         BC    8+1,QPCEX0            FLUSH RR/SS TYPES                  00005640
* PROCESS RX & LM/STM ONLY                                              00005650
         TM    0(QR1),B'01000000'    TEST IF RX TYPE                    00005660
         BO    QPCSRX                YES-GO PROCESS RX                  00005670
         LA    QR2,QR0SV             BURNS' INTERFACE                   00005680
         CLI   0(QR1),X'90'          LM                                 00005690
         BE    QSTM                  YES                                00005700
         CLI   0(QR1),X'98'          STM                                00005710
         BE    QLM                   YES                                00005720
         B     QPCEX0                FLUSH REMAINDER                    00005730
*********************************************************************** 00005740
QPCSRX   DS    0H                    RX INTERFACE                       00005750
         LR    QR10,QR7                TEST STG ARG ADR                 00005760
         CLI   0(QR1),X'4E' *           IS IT CVD                       00005770
         BE    *+12 *                   YES, TEST STG                   00005780
         TM    0(QR1),X'8F' *           IS IT NOT STG MOD INSTRUCTION?  00005790
         BNZ   *+8 *                    NOT STG MOD, DONT TEST STG      00005800
         BAL   QR9,QA                  TEST                             00005810
         MVC   QTMP5(8),0(QR7)       ALIGN INST ARG TO DBLWD            00005820
         MVC   QRXDMI(2),0(QR1)      MOVE OP & R1/X2 TO PROTO           00005830
         NI    QRXDMI+1,X'F0'        CLEAR X2                           00005840
         TM    0(QR1),B'01100000'    TEST IF FLT PNT                    00005850
         BO    QPCSRX1               YES USE ORIG R1                    00005860
* TRANSLATE USER R1 DESIGNATION TO QR10 OR QR11                         00005870
         NI    QRXDMI+1,X'10'        SAVE R1 ODD BIT                    00005880
         OI    QRXDMI+1,X'A0'        OR QR10                            00005890
         MVZ   QILM+1(1),QRXDMI+1    SET UP REG LOAD                    00005900
         MVZ   QRSTM+1(1),QRXDMI+1   SET UP RESTORE REGS                00005910
QPCSRX1  SPM   QR12                  SET USER CC                        00005920
*        PROTO INSTRUCTION                                              00005930
QILM     LM    QR10,QR11,0(QR2)      SET UP PROTO R1&R1+1               00005940
QRXDMI   L     QR10,QTMP5            PROTO OPERATION                    00005950
QRSTM    STM   QR10,QR11,0(QR2)      SAVE PROTO R1 & R1+1               00005960
         BALR  QR12,0                SAVE CC                            00005970
         CLC   0(8,QR7),QTMP5          TEST IF STG MOD GPS 09/20/73     00005980
         BE    *+10                    NO,SKIP RESTORE                  00005990
         MVC   0(8,QR7),QTMP5        RESTORE STG ARG                    00006000
         BR    QR14                  EXIT                               00006010
         EJECT                                                          00006020
LCTL     SUBTAG B7                                                      00006030
         LA    QR2,QCONREG                                              00006040
         EX    0,QLM                 SET TO LOAD                        00006050
         B     QLSTCOM               GO TO COMMON                       00006060
STCTL    SUBTAG B6                                                      00006070
         LA    QR2,QCONREG                                              00006080
         EX    0,QSTM                SET TO STORE                       00006090
QLSTCOM  DS    0H                    CONNECY                            00006100
         MVI   QNTCD2,QPRVEX         PRESET PRV EXC                     00006110
         TM    QAMWP,QPP             TEST IF PROB PRG                   00006120
         BO    QPCEX0                YES,PRV EXC                        00006130
         B     QLSTMCTL              CONTINUE                           00006140
QLM      MVC   QTMP4(6),QPROTOLM     SET UP LOAD PROTO                  00006150
         B     QLSTMCTL              DO IT                              00006160
QSTM     MVC   QTMP4(6),QPROTOSM     SET UP STORE PROTO                 00006170
QLSTMCTL DS    0H                    CONNECT                            00006180
         CLI   0(QR1),X'90' *           IS IT STM?                      00006190
         BE    *+12 *                   YES, TEST STG                   00006200
         CLI   0(QR1),X'B6' *           IS IT STCTL                     00006210
         BNE   *+8 *                    NO, DONT TEST STG               00006220
         BAL   QR9,QAR4                TEST IF VALID STG ARG            00006230
         SR    QR8,QR8                                                  00006240
         SR    QR9,QR9               CLEAR REG 9                        00006250
         IC    QR8,1(QR1)              PICK UP R1R3 FROM INST           00006260
         SRDL  QR8,4                   R1 IN QR8                        00006270
         SRL   QR9,26                  R3 IN QR9 IN WORDS               00006280
         SLL   QR8,2                   R1 IN WORDS- STARTING INDEX      00006290
*                                      .CONTROL REGS                    00006300
         LA    QR4,64                  .AND LENGTH                      00006310
         SR    QR10,QR10               B2D2 INDEX                       00006320
QLCTL20  EQU   *                     LOOP                               00006330
         LA    QR6,0(QR8,QR2)        COMPUTE SOURCE                     00006340
         LA    QR7,0(QR10,QR5)       COMPUTE DESTINATION                00006350
         EX    0,QTMP4               MOVE WORD                          00006360
         CR    QR8,QR9                 DONE?                            00006370
         BE    0(QR14)                 YES-RETURN                       00006380
         LA    QR8,4(QR8)              UP CONTROL REG INDEX             00006390
         LA    QR10,4(QR10)          UP STG REG                         00006400
         CR    QR8,QR4                 OVERLAP?                         00006410
         BL    QLCTL20                 NO-MOVE NEXT REG.                00006420
         SR    QR8,QR8                 YES-CLEAR INDEX                  00006430
         B     QLCTL20                 GET NEXT REG.                    00006440
QPROTOLM MVC   0(4,QR6),0(QR7)       LOAD PROTO INST                    00006450
QPROTOSM MVC   0(4,QR7),0(QR6)       STORE PROTO INST                   00006460
         EJECT                                                          00006470
CSUB     SUBTAG B2                                                      00006480
         CLI   1(QR1),X'05'          TEST IF STCK                       00006490
         BE    QSTCK                 OK,STORE CLOCK                     00006500
         TM    QPOPSWSV+1,X'01'      TEST IF PROBLEM STATE              00006510
         BZ    QSPVRN                NO,OK                              00006520
         MVI   QPOPSWSV+3,QPRVEX     SET PRIVIGED CHK                   00006530
         B     QPCEX0                EXIT 0 TO DOS PC                   00006540
QSPVRN   DS    0H                    NOT SPVR OP                        00006550
         CLI   1(QR1),X'0D' *           IS IT PTLB?                     00006560
         BE    QPTLB *                  PTLB QUASI RTN                  00006570
         CLI   1(QR1),X'13' *           IS IT RRB?                      00006580
         BE    QRRB *                   QRRB QUASI RTN                  00006590
         CLI   1(QR1),X'04' *           IS SUB OP IN LIST               00006600
         BH    QPCEX0 *                 NO, ILLEGAL OP                  00006610
         SLL   QR3,2                 *4                                 00006620
         B     BTBVEC(QR3)           B VECTOR                           00006630
BTBVEC   B     QPCEX0                I2=0 ILLEGAL SUB OP                00006640
         B     QPCEX0                I2=1 ILLEGAL SUB OP                00006650
         B     QSTIDP                I2=2 ST CPU ID                     00006660
         B     QSTIDC                I2=3 ST CHN ID                     00006670
         B     QSCK                  I2=4 SET CLOCK                     00006680
*********************************************************************** 00006690
PTLB     SUBTAG 0D                                                      00006700
         BR    QR14 *                   RETURN                          00006710
*********************************************************************** 00006720
RRB      SUBTAG 13                                                      00006730
         L     QR8,0(QR4) *             GEN ADDR EXCP IF OUTSIDE MCH    00006740
         SR    QR12,QR12 *              SET CC=0                        00006750
         BR    QR14 *                   RETURN                          00006760
*********************************************************************** 00006770
QSTIDC   DS    0H                    STORE CHN ID                       00006780
         SR    QR11,QR11             SET CC=0                           00006790
         BALR  QR12,0                RECORD                             00006800
         ST    QR4,QTMP1             SAVE B2D2                          00006810
         CLI   QTMP1+2,X'00'         TEST IF CHNL 0                     00006820
         MVC   168(4),QSELID         MOVE SELECTOR ID                   00006830
         BCR   7,QR14                EXIT IF NOT MPXR                   00006840
         MVC   168(4),QMPXID         MOVE MULTIPLEXOR ID                00006850
         BR    QR14                  EXIT                               00006860
*********************************************************************** 00006870
QSTIDP   DS    0H                    STORE CPU ID                       00006880
         ST    QR4,QTMP1             SAVE B1D1                          00006890
         TM    QTMP1,X'07'           TEST IF DBL WD BND                 00006900
         BZ    QSTIDPA               YES,SKIP                           00006910
         MVI   QPOPSWSV+3,QSPEX      SET SPECIFICATION EXCEPTION        00006920
         B     QPCEX0                ERROR EXIT                         00006930
QSTIDPA  MVC   0(8,QR4),VCPUID          MOVE CPU ID                     00006940
         BR    QR14                  EXIT                               00006950
*********************************************************************** 00006960
QSCK     DS    0H                    SET CLOCK                          00006970
         TM    *,X'FF'                  SET CC=1 (CLOCK SECURE)         00006980
         BALR  QR12,QR14             SET CC AND EXIT                    00006990
*********************************************************************** 00007000
QSTCK    DS    0H                    STORE CLOCK                        00007010
         BAL   QR9,QAR4                TEST IF STG ARG ADR OK           00007020
         OC    0(8,QR4),0(QR4)          PRETEST STG LOC FOR PROT EXCPT  00007030
         ST    QR14,QVQR14SV            SAVE RETURN REG                 00007040
         SR    QR10,QR10                SET KEY 0                       00007050
         BAL   QR14,QRSTRPSW            SET PSW KEY TO 0                00007060
         BAL   QR14,QSTEXTMD            SET STG KEY TO 0                00007070
         STM   QR0,QR15,QVSTCKSV        SAVE REGS                       00007080
         SR    QR1,QR1                  INDICATE TIMER UNITS            00007090
         L     QR3,QVCVTADR             LOAD CVT ADDRESS                00007100
         L     QR15,QVIGC011            LOAD ADDRESS OF IGC011          00007110
         BALR  QR14,QR15                CALL IGC011                     00007120
QVTMPORG DS    0H                       TEMPORARY ORIGIN                00007130
         STM   QR0,QR1,QVTU-QVTMPORG(QR14) STORE TIME AND DATE          00007140
         LM    QR0,QR15,QVSTCKSV-QVTMPORG(QR14) RESTORE REGS            00007150
         CLC   QVDATE+2(2),QV000F       IS DAY > 0?                     00007160
         BH    QVSTCKOK                 YES, COMPUTE CLOCK VALUE        00007170
         TM    *,X'FF'                  SET CC=1 (NOT-SET STATE)        00007180
         B     QVXIT                    EXIT                            00007190
QVSTCKOK DS    0H                       COMPUTE CLOCK VALUE             00007200
         MVO   QVPACKED,QVDATE+1(1)     GET YR (PACKED)                 00007210
         CVB   QVRWORK,QVPACKED         GET YR (BINARY)                 00007220
         STH   QVRWORK,QVHWYEAR         STORE YR                        00007230
         MVC   QVPACKED+6(2),QVDATE+2    GET DATE (PACKED)              00007240
         CVB   QVRWORK,QVPACKED         GET DAY (BINARY)                00007250
         BCTR  QVRWORK,0                SUBTRACT 1                      00007260
         LH    QR9,QVHWYEAR             GET YR                          00007270
         LTR   QR9,QR9                  IS YR ZERO?                     00007280
         BZ    QVMLTPLY                 YES, USE DATE ONLY              00007290
         SR    QR8,QR8                  CLEAR EVEN REG                  00007300
         D     QR8,QVFOUR               DIVIDE BY FOUR                  00007310
         MH    QR9,QVHW4YR              MULTIPLY QUOTIENT BY 1461       00007320
         MH    QR8,QVHW1YR              MULTIPLY REMAINDER BY 365       00007330
         LTR   QR8,QR8                  IS REMAINDER ZERO?              00007340
         BNZ   QVADDTOT                 NO, ALL GROUPS ARE 1461 DAYS    00007350
         BCTR  QR9,0                    SUBTRACT 1 FOR 1460 DAY GROUP   00007360
QVADDTOT AR    QVRWORK,QR9              ADD 1461 DAY GROUPS TO TOTAL    00007370
         AR    QVRWORK,QR8              ADD 365 DAY GROUPS TO TOTAL     00007380
QVMLTPLY LR    QR9,QVRWORK              TOTAL DAYS TO QR9               00007390
         M     QR8,QVDAYSEC             MULTIPLY BY SECS PER DAY        00007400
         SL    QR9,MAXNEG               SUBTRACT CONSTANT (FOR NEG)     00007410
         M     QR8,QVMEG                COMPUTE MICROSECONDS            00007420
         A     QR8,QVHMEG               ADD CONSTANT (CORRECT FOR SL)   00007430
         STM   QR8,QR9,QVRESULT         STORE TOTAL MICROSECONDS        00007440
         SR    QR8,QR8                  CLEAR EVEN REG                  00007450
         L     QR9,QVTU                 GET TIMER UNITS                 00007460
         D     QR8,QV384                DIVIDE BY 384                   00007470
         LR    QR11,QR8                 SAVE REMAINDER                  00007480
         M     QR8,QV10000              MULTIPLY QUOTIENT BY 10000      00007490
         M     QR10,QV10000             MULTIPLY REMAINDER BY 10000     00007500
         D     QR10,QV384               DIVIDE REMAINDER BY 384         00007510
         ALR   QR9,QR11                 ADD REMAINDER/QUOTIENT TOTALS   00007520
         BC    12,*+8                   BRANCH IF NO CARRY              00007530
         A     QR8,QV1                  ADD 1 FOR CARRY                 00007540
         A     QR8,QVRESULT             ADD TOTAL FROM DATE CALCULATION 00007550
         AL    QR9,QVRESULT+4           ADD TOTAL FROM DATE CALCULATION 00007560
         BC    12,*+8                   BRANCH IF NO CARRY              00007570
         A     QR8,QV1                  ADD 1 FOR CARRY                 00007580
         SLDL  QR8,QVTWELVE             SHIFT TO TOD CLOCK POS          00007590
         STM   QR8,QR9,QVRESULT         STORE CLOCK VALUE               00007600
         CLC   QVRESULT,QVLASTCL        IS CLOCK VALUE SAME AS LAST     00007610
         BNE   QVUNIQUE                 NO, GO TO NEW VALUE SETUP       00007620
         L     QVRWORK,QVLASTAD         LOAD LAST ADJUSTMENT VALUE      00007630
         AH    QVRWORK,QV4096           ADD ADJUSTMENT CONSTANT         00007640
         ST    QVRWORK,QVLASTAD         STORE NEW ADJUSTMENT VALUE      00007650
         ALR   QR9,QVRWORK              ADD TO TOD CLOCK VALUE          00007660
         BC    12,*+8                   BRANCH IF NO CARRY              00007670
         AL    QR8,QV1                  ADD 1 FOR CARRY                 00007680
         STM   QR8,QR9,QVRESULT         STORE ADJUSTED VALUE            00007690
         B     QVENDUP                  RETURN VALUE TO USER            00007700
QVUNIQUE MVC   QVLASTCL,QVRESULT        SAVE THIS CLOCK VALUE           00007710
         XC    QVLASTAD,QVLASTAD        ZERO ADJUSTMENT VALUE           00007720
QVENDUP  MVC   0(8,QR4),QVRESULT        MOVE TO USER AREA               00007730
         SR    QR12,QR12                SET CC=0 (SET STATE)            00007740
QVXIT    L     QR14,QVQR14SV            LOAD RETURN REG                 00007750
         BALR  QR12,QR14                LOAD CC AND EXIT                00007760
QVSTCKSV DS    16F                      REGISTER SAVE AREA              00007770
QVIGC011 DC    V(IGC011)                ADDRESS OG IGC011               00007780
QVCVTADR EQU   X'10'                    DISPLACEMENT OF CVT POINTER     00007790
QVPACKED DS    0D                                                       00007800
         DC    X'000000000000000F'      WORK AREA FOR CVB               00007810
QVRESULT DS    D                        AREA FOR PARTIAL 9ES4           00007820
QVLASTCL DC    D'0'                     LAST TOD CLOCK VALUE            00007830
QVQR14SV DS    F                        QR14 SAVE AREA                  00007840
QVTU     DS    F                        AREA TO HOLD TIMER UNITS        00007850
QVDATE   DS    F                        AREA TO HOLD DATE               00007860
QVFOUR   DC    F'4'                     CONSTANT                        00007870
QVDAYSEC DC    F'86400'                 SECONDS IN A DAY                00007880
MAXNEG   DC    X'80000000'              CORRECTION FACTOR               00007890
QVMEG    DC    F'1000000'               MICROSECONDS IN A SECOND        00007900
QVHMEG   DC    F'500000'                CORRECTION FACTOR               00007910
QV384    DC    F'384'                   CONSTANT TO CONVERT TIMER UNITS 00007920
QV10000  DC    F'10000'                 CONSTANT TO CONVERT TIMER UNITS 00007930
QV1      DC    F'1'                     CONSTANT TO ADD FOR CARRY       00007940
QVLASTAD DS    F                        LAST ADJUSTMENT VALUE           00007950
QVHWYEAR DS    H                        AREA TO HOLD YEAR               00007960
QVHW4YR  DC    H'1461'                  DAYS IN 4 YEARS                 00007970
QVHW1YR  DC    H'365'                   DAYS IN YEAR                    00007980
QV4096   DC    H'4096'                  ADJUSTMENT CONSTANT             00007990
QV000F   DC    X'000F'                  VALUE TO TEST FOR VALID DAY     00008000
QVTWELVE EQU   12                       CONSTANT FOR TOD CLOCK SHIFT    00008010
QVRWORK  EQU   7                                                        00008020
.B360SMX ANOP                                               2/5/76      00008030
*********************************************************************** 00008040
QSTEXTMD DS    0H                    SET RESET EXTERNAL ENVIRON         00008050
         LA    QR11,ITLSIS&GCP            START OF INST SIM          IT 00008060
         N     QR11,QFFF800          SET UP FOR SSK                     00008070
         SSK   QR10,QR11             SET STG KEY                        00008080
         LA    QR11,2048(QR11) *        SET UP FOR NEXT 2K              00008090
         SSK   QR10,QR11 *              SET STG KEY                     00008100
         LA    QR11,SISEND *            END OF INST EMU STG             00008110
         N     QR11,QFFF800 *           SET UP SSK                      00008120
         SSK   QR10,QR11             SET STG KEY                        00008130
QRSTRPSW ST    QR14,QPMRKA           SAVE RETURN IN NEXT PSW            00008140
         STC   QR10,QPMRK+1          SAVE KEY IN NEXT PSW               00008150
         OI    QPMRK+1,X'04'           SET MACH CHK ENABLE              00008160
         LPSW  QPMRK                 LOAD NEXT PSW (RETURN)             00008170
****************************************************************        00008180
QR1R2    DS    0H                      POINT QRI/QR6 TO SAVED R1/R2     00008190
         LR    QR11,QR3              COPY R1/X                          00008200
         SRL   QR11,4                R1 ONLY                            00008210
         SLL   QR11,2                *4                                 00008220
         LA    QR2,QR0SV(QR11)       POINT TO SAVED R1                  00008230
         LR    QR11,QR3              COPY R1/X                          00008240
         N     QR11,QF               R2,X2 ONLY                         00008250
         SLL   QR11,2                *4                                 00008260
         LA    QR6,QR0SV(QR11)       POINT TO SAVED R2/X2               00008270
         BR    QR14                    EXIT                             00008280
****************************************************************        00008290
QB1D1    DS    0H                    COMPUTE SUM (B1 NE 0)+D1           00008300
         LR    QR5,QR11                COPY B1D1                        00008310
         N     QR11,QF000              ISOLATE B1                       00008320
         BCR   8,QR14                  B1=0,EXIT                        00008330
         N     QR5,QFFF                ISOLATE D1                       00008340
         SRL   QR11,10                 SHIFT B1*4                       00008350
         AL    QR5,QR0SV(QR11)         ADD D1 TO REG(B1)                00008360
         LA    QR5,0(,QR5)             CLEAR HI BYTE                    00008370
         BR    QR14                    EXIT                             00008380
*******************************************************************     00008390
QAR4     LR    QR10,QR4                SET UP STG ARG TEST R4           00008400
QA       DS    0H                      TEST FOR SELF DESTRUCTION        00008410
         TM    QAMWP,X'F0' *         PSW PROTECT KEY ZERO?              00008420
         BCR   8,QR9 *               YES,RETURN                         00008430
         N     QR10,QFFF800 *        GET ADDR OF BEGINNING OF BLOCK     00008440
         LA    QR0,SISEND *             END OF PROT KEY ALTERED STG     00008450
         CR    QR10,QR0 *               IS IT KILL ZONE                 00008460
         BCR   2,QR9                 OK,RETURN                          00008470
         MVI   QNTCD2,QPRTEX         SET PROT EXC                       00008480
         B     QPCEX0                  EXIT TO DOS PC RTN               00008490
*********************************************************************** 00008500
SISPC    DS    0H *                     PGM CHK DURINT SIS              00008510
         LH    QR11,QPRGOLD+2 *         GET CURRENT EXCEPTION           00008520
         STH   QR11,QPOPSWSV+2 *        SET SECOND STAT TO 1ST INT      00008530
         L     QR1,IHLCON1 *            GET POINTER TO PFLIH REGS       00008540
         XC    0(64,QR1),QPCSV *        RESTORE ORIGINAL REGS/          00008550
         XC    QPCSV(64),0(QR1) *       AND SAVE 2ND PC RGS FOR DEBUG   00008560
         XC    0(64,QR1),QPCSV *                                        00008570
         B     QPCEX0A                  BRANCH AROUND STM QR0,QR15      00008580
QPCEX0   DS    0H *                     PGM DETERMINED PGM CHK          00008590
         AIF   ('&CTRLPGM' EQ 'MFT').MFT00                          DSX 00008600
         STM   QR0,QR15,QPCSV *         SAVE REGS FOR DEBUG             00008610
         AGO   .NOTMFT0                                             DSX 00008620
.MFT00   ANOP                                                       DSX 00008630
         STM   RA,R9,QPCSV *            SAVE REGS FOR DEBUG         DSX 00008640
.NOTMFT0 ANOP                                                       DSX 00008650
QPCEX0A  DS    0H                       CONNECT                         00008660
         SR    QR10,QR10 *              SET KEY 0                       00008670
         BAL   QR14,QRSTRPSW            SET PSW KEY TO 0                00008680
         BAL   QR14,QSTEXTMD            SET STG KEY TO /                00008690
         NI    QSW1,X'FF'-REENTRY                                       00008700
         USING IPLPSW,0        ITEL FLIH STORAGE ADDRESSABILITY    UNCC 00008710
         NI    PCNPSWCC,X'CF'  RESET REENTRY SWITCH FOR ITEL FLIH  UNCC 00008720
         MVC   QPRGOLD(8),QPGOPSW                                       00008730
         MVC   LASTPRGO(8),QPRGOLD                                      00008740
         AIF   ('&CTRLPGM' EQ 'MFT').MFT01                          DSX 00008750
         LM    QR0,QR14,QPCSV                                           00008760
         AGO   .NOTMFT1                                             DSX 00008770
.MFT01   ANOP                                                       DSX 00008780
         LM    QR10,QR9,QPCSV                                       DSX 00008790
.NOTMFT1 ANOP                                                       DSX 00008800
         L     QR15,VENTRY *            GET OS PFLIH EP                 00008810
         BR    QR15 *                   TRANSFER CTL TO OS PFLIH        00008820
QPCEX1   DS    0H *                     SIMULATED EXIT                  00008830
         MVI   QNTCD2,X'00' *           CLEAR EXCEPTION                 00008840
         N     QR12,Q3000000 *          CLEAR NON CC BITS IN 12         00008850
         NI    QPRGMSK,X'CF' *          CLEAR CC BITS IN PSW            00008860
         AL    QR12,QPRGADR *           ADD RT HALF PSW TO NEW CC       00008870
         ST    QR12,QPRGADR *           RESTORE PSW WITH NEW CC         00008880
         SR    QR10,QR10 *              SET KEY 0                       00008890
         BAL   QR14,QRSTRPSW *          SET PSW KEY TO 0                00008900
         BAL   QR14,QSTEXTMD *          SET STG KEY TO 0                00008910
         NI    QSW1,X'FF'-REENTRY                                       00008920
         MVC   QPRGOLD(8),QPGOPSW                                       00008930
         LM    QR0,QR15,QPCSV *         RESTORE REGS                    00008940
         NI    PCNPSWCC,X'CF'  SET REENTRY SWITCH FOR ITEL FLIH    UNCN 00008950
         LPSW  QPRGOLD *                RETURN TO NEXT INSTR            00008960
         DROP  QR15                                                     00008970
         DS    0D                                                       00008980
VCPUID   DC    X'00010075014500C0'   MOCK CPU ID                        00008990
QMPXID   DC    X'10000060'           MOCK MPX ID                        00009000
QSELID   DC    X'00000060'           MOCK SELCTR ID                     00009010
QFFF800  DC    X'00FFF800'           ISK MASK                           00009020
Q4N02    DC    X'40000002'           INSTRUCTION MINIM                  00009030
Q3000000 DC    X'30000000'           COND CODE MASK                     00009040
QF000    DC    X'0000F000'             BASE REG MASK                    00009050
QFFF     DC    X'00000FFF'           DISPLACEMENT ISOLATION MASK        00009060
QF0      DC    X'000000F0'           HI ORDER HEX DIGIT MASK            00009070
QF       DC    X'0000000F'           LOW ORDER HEX DIGIT MASK           00009080
QPCMSK   DC    X'00'                 PROG CHK MOD STAT MSK              00009090
QPGOPSW  DC    D'0'                  HOLD PRG OLD OVER I/O              00009100
QPOPSWSV EQU   QPGOPSW               POPSWSV=PGOPSW                     00009110
         ORG   *-8                                                      00009120
QPSWMSK  DS    X                     SYSTEM MASK                        00009130
QAMWP    DS    X                     KEY&AMWP                           00009140
QNTCD1   DS    X                     INTERRUPT CODE 1                   00009150
QNTCD2   DS    X                     INTERRUPT CODE 2                   00009160
QPRGMSK  DS    X                     ILC/CC/PRG MASK                    00009170
         ORG   *-1                                                      00009180
QPRGADR  DS    F                     INTRPTD PRG ADDR                   00009190
QPMRK    DS    0D                      PSW INTERNAL                     00009200
         DC    X'00040000' *            PSW USED TO SWITCH STATES       00009210
QPMRKA   DC    A(0)                  PSW ADDR                           00009220
QPCSV    DS    0H                      FLASH RE-ENTRANT FIX             00009230
         AIF   ('&CTRLPGM' EQ 'MFT').MFT03                          DSX 00009240
.MFT02   ANOP                                                       DSX 00009250
QR0SV    DS    F                     SAVED R0                           00009260
QR1SV    DS    F                     SAVED R1                           00009270
QR2SV    DS    F                     SAVED R2                           00009280
QR3SV    DS    F                     SAVED R3                           00009290
QR4SV    DS    F                     SAVED R4                           00009300
QR5SV    DS    F                     SAVED R5                           00009310
QR6SV    DS    F                     SAVED R6                           00009320
QR7SV    DS    F                     SAVED R7                           00009330
QR8SV    DS    F                     SAVED R8                           00009340
QR9SV    DS    F                     SAVED R9                           00009350
         AIF   ('&CTRLPGM' EQ 'MFT').MFT04                          DSX 00009360
.MFT03   ANOP                                                       DSX 00009370
QR10SV   DS    F                     SAVED R10                          00009380
QR11SV   DS    F                     SAVED R11                          00009390
QR12SV   DS    F                     SAVED R12                          00009400
QR13SV   DS    F                     SAVED R13                          00009410
QR14SV   DS    F                     SAVED R14                          00009420
QR15SV   DS    F                     SAVED R15                          00009430
         AIF   ('&CTRLPGM' EQ 'MFT').MFT02                          DSX 00009440
.MFT04   ANOP                                                       DSX 00009450
         DS    F                     QTMP0-4                            00009460
QTMP0    DS    F                     QTMP0                              00009470
QTMP1    DS    F                     TEMP SCRATCH                       00009480
QTMP2    DS    F                     TEMP SCRATCH                       00009490
QTMP3    DS    F                     TEMP SCRATCH                       00009500
QTMP4    DS    F                     TEMP SCRATCH                       00009510
QTMP5    DS    F                     TEMP SCRATCH                       00009520
QTMP6    DS    F                     TEMP SCRATCH                       00009530
QTMP7    DS    F                     TEMP SCRATCH                       00009540
QTMP8    DS    F                     TEMP SCRATCH                       00009550
QTMP9    DS    F                     TESMP SCRATCH                      00009560
QTMP10   DS    F                     TESMP SCRATCH                      00009570
QTMP11   DS    F                     TESMP SCRATCH                      00009580
QTMP12   DS    F                     TESMP SCRATCH                      00009590
QTMP13   DS    F                     TESMP SCRATCH                      00009600
QTMP14   DS    F                     TESMP SCRATCH                      00009610
QCONREG  DC    16F'0'                PSEUDO CONTROL REGS                00009620
QSW1     DC    X'00'                                                    00009630
LASTPRGO DC    D'0'                                                     00009640
         AIF   (&GTR EQ 0).NOTRTBL                                      00009650
TRACETBL DC    &GTR.D'0'                                                00009660
.NOTRTBL ANOP                                                           00009670
         COUNTS                                                         00009680
SISEND   EQU   * *                      END OF PROT KEY ALTERED STG     00009690
         AIF   ('&CTRLPGM' EQ 'MFT').MFT05                          DSX 00009700
IHLCON1  DC    V(IEAPKSAV) *            PI SAVE AREA IN LOW CORE        00009710
         AGO   .NOTMFT2                                             DSX 00009720
.MFT05   ANOP                                                       DSX 00009730
IHLCON1  DC    V(PISAV) *               PI SAVE AREA IN LOW CORE    DSX 00009740
.NOTMFT2 ANOP                                                       DSX 00009750
VENTRY   DC    V(ENTRY2) *            OS PFLIH ENTRY                    00009760
REENTRY  EQU   X'80'                                                    00009770
QPRGOLD  EQU   X'28'                 PRG OLD PSW                        00009780
QMCHOLD  EQU   X'30'                 MACHINE OLD PSW                    00009790
QIOOLD   EQU   X'38'                 I/O OLD PSW                        00009800
QEXTNEW  EQU   X'58'                 EXTERNAL NEW PSW                   00009810
QSVCNEW  EQU   X'60'                 SVC NEW                            00009820
QPRGNEW  EQU   X'68'                 PRG NEW                            00009830
QMCHNEW  EQU   X'70'                 MCH NEW                            00009840
QIONEW   EQU   X'78'                 I/O NEW                            00009850
QCSW     EQU   X'40'                 CSW LOC                            00009860
QCAW     EQU   X'48'                 CHNL ADDR WORD                     00009870
QOPEX    EQU   X'01'                 OPERATION EXCEPTION                00009880
QPRVEX   EQU   X'02'                 PRIVILIGED  EXCEPTION              00009890
QEXEX    EQU   X'03'                 EXECUTE EXCEPTION                  00009900
QPRTEX   EQU   X'04'                 PROTECTION EXCEPTION               00009910
QADREX   EQU   X'05'                   ADDRESS EXCEPTION                00009920
QSPEX    EQU   X'06'                 SPECIFICATION ERROR                00009930
QTMESET  EQU   X'20'                 SET CLCK EXECUTED                  00009940
QPP      EQU   X'01'                 PROBLEM STATE                      00009950
QR0      EQU   0                     R0 NOT USED                        00009960
QR1      EQU   1                     R1 POINTS TO EXCEPTED OP           00009970
QR2      EQU   2                     R2 POINTS TO SAVED R1              00009980
QR3      EQU   3                     R3 CONTAINS IMMEDIATE              00009990
QR4      EQU   4                     R4 CONTAINS SUM(B1)+D1             00010000
QR5      EQU   5                     R5 CONTAINS SUM(B2)+D2             00010010
QR6      EQU   6                     R6 POINTS TO SAVED R2              00010020
QR7      EQU   7                     SUM (X2)+(B2)+D2                   00010030
QR8      EQU   8                     R8  UTILITY                        00010040
QR9      EQU   9                     R9  UTILITY                        00010050
QR10     EQU   10                    R10 UTILITY                        00010060
QR11     EQU   11                    R11 UTILITY                        00010070
QR12     EQU   12                    R12 CONTAIN USER COND CODE         00010080
QR13     EQU   13                    R13 POINTS TO SAVE TABLE           00010090
QR14     EQU   14                    INTERNAL LINKAGE                   00010100
QR15     EQU   15                    BASE REG                           00010110
         AIF   ('&TYPE' EQ 'RELOC').MFT09                               00010120
.NORELOC ANOP                                               1/6/76      00010130
         AIF   ('&CTRLPGM' EQ 'MFT').MFT06                          DSX 00010140
IEAQFX00 CSECT                                                          00010150
         AGO   .NOTMFT3                                             DSX 00010160
.MFT06   ANOP                                                       DSX 00010170
IEAAIH00 CSECT                                                          00010180
.NOTMFT3 ANOP                                                       DSX 00010190
 TITLE 'NON-RELOCATABLE PORTION OF ITEL 370 INSTRUCTION SIMULATOR'      00010200
****************************************************************     TM 00010210
*                                                              *     TM 00010220
*        PROGRAM CHECK RECOVERY ROUTINE                        *     TM 00010230
*                                                              *     TM 00010240
* COPYRIGHT (1975) BY THE ITEL CORPORATION                     *     TM 00010250
*  1 EMBARCADERO CENTER                                        *     TM 00010260
*   SAN FRANCISCO, CALIFORNIA                                  *     TM 00010270
*                                                              *     TM 00010280
* FUNCTION                                                     *     TM 00010290
*   THE FUNCTION OF THE PROGRAM CHECK RECOVERY ROUTINE IS TO   *     TM 00010300
*   RESOLVE PROGRAM CHECKS OCCURRING ON S/360 DUE TO           *     TM 00010310
*   THE USE OF 370 INSTRUCTIONS OR FACILITIES NOT PRESENT      *     TM 00010320
*   ON S/360                                                   *     TM 00010330
*                                                              *     TM 00010340
*   THE RECOVERY PROCEDURES ARE SPLIT INTO TWO PARTS           *     TM 00010350
*     1. ITLPCSIM - SERVICES THE MOST COMMONLY OCCURRING       *     TM 00010360
*                RECOVERABLE PROGRAM CHECKS                    *     TM 00010370
*                  ICM FOR MASK VALUES 1,3,7,8,C,F             *     TM 00010380
*                  STCM     SAME                               *     TM 00010390
*                  CLM      SAME                               *     TM 00010400
*                  RX INSTRUCTION OPERAND MIS-ALIGNMENT        *     TM 00010410
*     2. ITLSISO - SERVICES ALL OTHER RECOVERABLE              *     TM 00010420
*                   PROGRAM CHECKS                             *     TM 00010430
*                                                              *     TM 00010440
*                                                              *     TM 00010450
*   UNRECOVERABLE PROGRAM CHECKS ARE PASSED                             00010460
*      TO ITLSISO FOR FURTHER PROCESSING.                               00010470
*                                                                       00010480
* ENTRY POINTS                                                 *     TM 00010490
*   ITLPCSIM - THE PROGRAM NEW PSW POINTS TO ITLPCSIM                *  00010500
*                                                              *     TM 00010510
* INPUT                                                        *     TM 00010520
*   THE PROGRAM OLD PSW                                        *     TM 00010530
*                                                              *     TM 00010540
* OUTPUT                                                       *     TM 00010550
*   PROGRAM OLD PSW (CONDITION CODE AS APPROPRIATE)            *     TM 00010560
*   REGISTER OR STORAGE MODIFICATION AS APPROPRIATE            *     TM 00010570
*                                                              *     TM 00010580
* SUBROUTINES CALLED                                           *     TM 00010590
*   ITLSISO (THE GENERAL RECOVERY ROUTINE)                     *        00010600
*                                                              *     TM 00010610
* EXTERNAL REFERENCES                                          *     TM 00010620
*   PROGRAM NEW PSW                                            *     TM 00010630
*   PROGRAM OLD PSW                                            *     TM 00010640
*   MAIN STORAGE TO ACCESS OR STORE OPERANDS                   *     TM 00010650
*                                                              *     TM 00010660
* EXITS - NORMAL                                               *     TM 00010670
*   RETURN TO THE INTERRUPTED PROGRAM AT THE INSTRUCTION       *     TM 00010680
*   FOLLOWING THE ONE WHICH FAILED                             *     TM 00010690
*                                                              *     TM 00010700
* EXITS - ABNORMAL                                             *     TM 00010710
*                                                              *     TM 00010720
*   LPSW TO OS PROGRAM CHECK FLIH                                       00010730
* TABLES/WORK AREAS                                            *     TM 00010740
*                                                                       00010750
*   MSK3TB - ICM,STCM AND CLM MASK TABLE                       *     TM 00010760
*   RXAL   - RX INSTRUCTION STORAGE OPERAND LENGTH             *     TM 00010770
*   RXNDX  - RX INSTRUCTION TYPE BY OPCODE                     *     TM 00010780
*   RXTYP  - RX INSTRUCTION TYPE (E.G. LOAD,COMPARE,STORE)     *     TM 00010790
*                                                              *     TM 00010800
* ATTRIBUTES - RE-USABLE,PRIVILIGED,DISABLED, AND ITLPCSIM        *     00010810
*   MUST BE LOCATED BELOW MEMORY LOCATION 4096.                *     TM 00010820
*   ITLPCSIM  & ITLSISO ARE PARTIALY RE-ENTRANT. SECONDARY          *   00010830
*   PROGRAM CHECKS DURING RECOVERY ARE ACCEPTED AND            *     TM 00010840
*   PROCESSED.                                                 *     TM 00010850
*        E.G. A STCM IN A PP ATTEMPTS TO STORE INTO THE        *     TM 00010860
*             SUPERVISOR                                       *     TM 00010870
*             (A RECOVERABLE OPERATION EXCEPTION HAS       )   *     TM 00010880
*             (BECOME AN UNRECOVERABLE PROTECTION EXCEPTION)   *     TM 00010890
*                                                              *     TM 00010900
* NOTES                                                        *     TM 00010910
*   ITLPCSIM EXECUTES WITHOUT A BASE REGISTER.                    *     00010920
*   PROGRAM PARTITION INTEGRITY IS MAINTAINED BY-              *     TM 00010930
*        ENABLING STORAGE PROTECT IN THE USER KEY BEFORE STORE *     TM 00010940
*        ENABLING THE USER PROGRAM MASK                        *     TM 00010950
*   TABLE RXTYP CONTAINS 1 BYTE ADCONS, THEREFORE              *     TM 00010960
*   SUB-PROCESSORS RXLDT, RXMCC, RXSTG AND RXNVAL              *     TM 00010970
*   MUST FOLLOW AND BE WITHIN 250 BYTES OF RXPRC.              *     TM 00010980
*                                                              *     TM 00010990
*   1/29/78 UNIVERSITY OF NEBRASKA MODIFICATION:               *   UNCN 00011000
*        THE ORIGINAL CODE USED THE CONDITION CODE OF THE      *   UNCN 00011010
*        PROGRAM NEW PSW AS A RE-ENTRY GATE IN THE EVENT THAT  *   UNCN 00011020
*        PROGRAM CHECK OCURRED INSIDE THE PROGRAM CHECK        *   UNCN 00011030
*        RECOVERY ROUTINES.  THIS WAS MODIFIED SO THAT ALL     *   UNCN 00011040
*        REFERENCES TO PCNPSW WERE CHANGED TO PCNPSWCC (A BYTE *   UNCN 00011050
*        DEFINED IN THE STORAGE SECTION OF ITLPCSIM) SO THAT   *   UNCN 00011060
*        PROGRAMS THAT MODIFY PROGRAM NEW PSW WILL NOT AFFECT  *   UNCN 00011070
*        THE EXECUTION OF ITEL'S PROGRAM CHECK RECOVERY.       *   UNCN 00011080
*                                                              *   UNCN 00011090
****************************************************************     TM 00011100
*                                                                    TM 00011110
****************************************************************     TM 00011120
* ITLPCSIM IS ENTERED VIA THE PROGRAM NEW PSW. THE CONDITION      *     00011130
* CODE OF THE PROGRAM NEW IS USED AS A RE-ENTRY GATE IN        *     TM 00011140
* CASE SECONDARY PROGRAM CHECKS OCCUR DURING RECOVERY.         *     TM 00011150
*   CC=0 NORMAL ENTRY                                          *     TM 00011160
*   CC=1 RE-ENTRY - A PROGRAM CHECK DURING RECOVERY            *     TM 00011170
*   CC=2 THE PROGRAM CHECK HAS BEEN GIVEN TO THE               *     TM 00011180
*        GENERAL RECOVERY ROUTINE                              *     TM 00011190
*   CC=3 RE-ENTRY - A PROGRAM CHECK DURING RECOVERY            *     TM 00011200
****************************************************************     TM 00011210
*                                                                    TM 00011220
.NRLC2   ANOP                                              1/12/76      00011230
         ENTRY PIXT2                                                    00011240
PIXT2    SVC   3                                                        00011250
         USING IPLPSW,0                                                 00011260
         AIF   ('&TYPE' NE 'NULL').NONULL                   1/6/76      00011270
ITLPCSIM LPSW  PCNPSW2 YOU DUMMY-THIS IS A 370 GO TO PCFLIH 1/6/76      00011280
         AGO   .NULLSM2                                     1/6/76      00011290
.NONULL  ANOP                                               1/6/76      00011300
ITLPCSIM TM    PCNPSWCC,X'30'      TEST RE-ENTRY SWITCH            UNCN 00011310
         BC    1,GPCRENT2                                          UNCN 00011320
         BC    4,PCRENT2                                                00011330
*                                                                       00011340
****************************************************************     TM 00011350
* INITIAL ENTRY-                                               *     TM 00011360
*   SAVE USER'S REGISTERS                                      *     TM 00011370
*   SAVE THE INITIAL ENTRY PROGRAM OLD PSW                     *     TM 00011380
*   GATE THE PROGRAM NEW TO PCRENT2 IN                         *     TM 00011390
*    CASE OF RE-ENTRY                                          *     TM 00011400
****************************************************************     TM 00011410
         STM   R0,R2,SVRG0        SAVE USER REGISTERS 0,1,2          TM 00011420
         LM    R0,R1,PCOLDP       SAVE PROGRAM OLD PSW               TM 00011430
         STM   R0,R1,COPYPSW      IN COPYPSW                         TM 00011440
         AIF   ('&TYPE' NE 'SHORT').NOTSHRT                 1/6/76      00011450
*   SIMULATION TO BE DONE FOR NON-DAT 370                   1/6/76      00011460
         B     GPCRCV             GO TO THE GENERAL ROUTINE 2/25/76     00011470
         AGO   .NOFXSIM                                     1/6/76      00011480
.NOTSHRT ANOP                                               1/6/76      00011490
         OI    PCNPSWCC,X'10'     SET CC=1 IN THE PROGRAM NEW      UNCN 00011500
*   ASSUME THE INTERRUPTED INST. IS 4 BYTES                          TM 00011510
         SL    R1,Q8N04           SUBTRACT ILC 4 AND 4 BYTES         TM 00011520
         LR    R0,R1              COPY RESULT                        TM 00011530
         N     R0,QCN01           TEST ASSUMPTION                    TM 00011540
         BNZ   GPCRCV              NOT TRUE,GO TO THE GENERAL           00011550
*                                 ROUTINE                            TM 00011560
         MVC   COPYI(4),0(R1)     COPY THE INSTRUCTION               TM 00011570
*                                                                    TM 00011580
*   CHECK IF THE INSTRUCTION IS AN RX TYPE                           TM 00011590
*                                                                    TM 00011600
         TM    COPYI,B'01000000'  TEST IF RX                         TM 00011610
         BO    RXRCV              YES,GO TO THE RX ROUTINE           TM 00011620
*                                                                    TM 00011630
*   ASSUME THE INSTRUCTION IS ICM, STCM OR CLM                       TM 00011640
*   GO TO THE ICM,STCM & CLM SET UP ROUTINE                          TM 00011650
*                                                                    TM 00011660
         B     MSK370             GO SET UP ICM, STCM & CLM          TM 00011670
*                                                                    TM 00011680
.NOFXSIM ANOP                                               1/6/76      00011690
****************************************************************     TM 00011700
* PROGRAM CHECK RE-ENTRY                                       *     TM 00011710
*   THE HARDWARE FACILITIES ARE USED TO DETERMINE              *     TM 00011720
*   INSTRUCTION VALIDITY DURING RECOVERY-                      *     TM 00011730
*        STORAGE PROTECT IS ENABLED.                           *     TM 00011740
*        INVALID REGISTER SPECIFICATION ETC IS TRAPPED         *     TM 00011750
*        THE USER'S PROGRAM MASK IS ENABLED                    *     TM 00011760
*   IF A SECONDARY PROGRAM INTERRUPT OCCURS                    *     TM 00011770
*   THE INTERRUPT CODE FROM THE SECOND INTERRUPT               *     TM 00011780
*   IS STORED INTO THE COPY OF THE ORIGINAL INTERRUPT.         *     TM 00011790
*   THE UPDATED COPY IS PUT BACK INTO THE PROGRAM OLD PSW      *     TM 00011800
*   AND THE INTERRUPT IS GIVEN TO THE OS/MVT ROUTINE.          *     TM 00011810
****************************************************************     TM 00011820
PCRENT2  MVC   COPYPSW+2(2),PCOLDP+2 MOVE NEW INT. CODE TO THE       TM 00011830
*                                 COPIED ORIGINAL PRG. OLD           TM 00011840
         MVC   PCOLDP(8),COPYPSW  RESTORE THE UPDATED ORIGINAL       TM 00011850
         LM    R0,R2,SVRG0        RESTORE USER REGISTERS             TM 00011860
*   SET GATE TO NORMAL ENTRY                                         TM 00011870
PCRENT2X NI    PCNPSWCC,X'CF'     SET RE-ENTRY GATE TO NORMAL      UNCN 00011880
         MVC   LSTVPC(8),COPYPSW  SAVE LAST VALID PROGRAM CHECK      TM 00011890
         LPSW  PCNPSW2            EXIT TO OS/MVT ROUTINE             TM 00011900
*                                                                    TM 00011910
****************************************************************     TM 00011920
* GENERAL PROGRAM INTERRUPT ROUTINE CALL                       *     TM 00011930
*   THE PROGRAM CHECK CANNOT BE RECOVERED HERE                 *     TM 00011940
*   THE GENERAL ROUTINE IS CALLED                              *     TM 00011950
****************************************************************     TM 00011960
GPCRCV   LM    R0,R2,SVRG0        RESTORE USER REGISTERS                00011970
         OI    PCNPSWCC,X'20'     SET GATE TO RE-ENTER THE         UNCN 00011980
*                                 GENERAL ROUTINE                    TM 00011990
*                                                                    TM 00012000
****************************************************************     TM 00012010
*   THE GENERAL RECOVERY ROUTINE (ITLSISO)                              00012020
*   LOCATION IS IN AGPCRCV.                                             00012030
****************************************************************     TM 00012040
*   SECONDARY PROGRAM CHECKS WHILE THE GENERAL ROUTINE         *     TM 00012050
*   IS ACTIVE RE-ENTER HERE                                    *     TM 00012060
****************************************************************     TM 00012070
GPCRENT2 DS    0H                                                   DSX 00012080
         AIF  ('&CTRLPGM' EQ 'MFT').MFT07                           DSX 00012090
         STM   R0,RF,IEAPKSAV     SAVE ALL REGISTERS                 TM 00012100
         AGO   .NOTMFT4                                             DSX 00012110
.MFT07   ANOP                                                       DSX 00012120
         STM   RA,R9,PISAV *       SAVE ALL REGISTERS               DSX 00012130
.NOTMFT4 ANOP                                                       DSX 00012140
         L     RF,AGPCRCV         GET ADDRESS OF GEN'L                  00012150
         BALR  RE,RF              CALL IT                            TM 00012160
         AIF   ('&TYPE' EQ 'SHORT').NOSIMFX                 1/6/76      00012170
*                                                                    TM 00012180
****************************************************************     TM 00012190
* ICM,STCM & CLM SIMULATION - SET UP.                          *     TM 00012200
*                                                              *     TM 00012210
*   SET UP INSTRUCTIONS SAVOR1 AND GETADD TO                   *     TM 00012220
*   STORE REGISTER OPERAND 1 AND                               *     TM 00012230
*   OBTAIN THE ADDRESS OF STORAGE OPERAND 2                    *     TM 00012240
****************************************************************     TM 00012250
MSK370   MVZ   SAVOR1+1(1),COPYI+1 COPY REGISTER FIELD               TM 00012260
         L     R0,COPYI           COPY B2 D2 OPERAND                 TM 00012270
         STH   R0,GETADD00+2      INTO GETADD                        TM 00012280
         LM    R0,R1,SVRG0        RESTORE USER'S REGISTERS.          TM 00012290
*                                                                    TM 00012300
*   THE XXX FIELDS OF SVOR1 AND GETADD HAVE BEEN FILLED              TM 00012310
*   IN BY FIELDS FROM THE INTERRUPTED INSTRUCTION                    TM 00012320
*                                                                    TM 00012330
SAVOR1   ST    XXX,REGOP1         STORE REGISTER OPERAND 1           TM 00012340
GETADD00 LA    R1,XXX(0,XXX)      GET STORAGE OPERAND ADDR           TM 00012350
*                                                                    TM 00012360
*   GET OPERAND 3 MASK AND ACCESS THE MASK TABLE                     TM 00012370
*   FOR DEFINITION.                                                  TM 00012380
*                                                                    TM 00012390
         IC    R2,COPYI+1         GET OPERAND3 MASK                  TM 00012400
         N     R2,F               ISOLATE MASK BITS                  TM 00012410
         IC    R2,MSK3TB(R2)      GET EXECUTE TABLE VALUE            TM 00012420
*                                                                    TM 00012430
*   SPLIT UP INSTRUCTIONS FOR SIMULATION                             TM 00012440
*                                                                    TM 00012450
         CLI   COPYI,X'BF'        ICM ?                              TM 00012460
         BE    ICMRCV             YES,GO                             TM 00012470
         CLI   COPYI,X'BE'        STCM ?                             TM 00012480
         BE    STCMRCV            YES,GO                             TM 00012490
         CLI   COPYI,X'BD'        CLM ?                              TM 00012500
         BE    CLMRCV             YES,GO                             TM 00012510
         B     GPCRCV              GO TO GENERAL ROUTINE              T 00012520
*                                                                    TM 00012530
****************************************************************     TM 00012540
*                                                              *     TM 00012550
*ICM SIMULATOR                                                 *     TM 00012560
*                                                              *     TM 00012570
*   THE ICM SIMULATION IS TO-                                  *     TM 00012580
*        PRESET  THE EXIT PSW (PROG. OLD)  COND. CODE =0       *     TM 00012590
*        MOVE THE PROPER NUMBER OF STORAGE BYTES INTO          *     TM 00012600
*              THE PROPER POSITIONS OF THE STORED REGISTER     *     TM 00012610
*        DETERMINE AND SET THE PROPER COND. CODE               *     TM 00012620
*        RESTORE THE REGISTER OPERAND                          *     TM 00012630
*                                                              *     TM 00012640
****************************************************************     TM 00012650
ICMRCV   NI    PCOLDP+4,X'CF'     PRESET USER CC=0                   TM 00012660
         EX    0,ICMV(R2)         MOVE BYTES FROM                    TM 00012670
*                                 OPERAND 2 TO OPERAND 1             TM 00012680
         EX    0,ICMCL(R2)        TEST IF ALL MOVED BYTES            TM 00012690
*                                 ARE ZERO                           TM 00012700
         BC    8,ICMRCVX          CC=0 (PRESET) GO TO EXIT           TM 00012710
         OI    PCOLDP+4,X'20'     SET CC=2 (MOVED BYTES              TM 00012720
*                                 ARE NON ZERO (1ST BIT 0))          TM 00012730
         TM    0(R1),X'80'        TEST IF FIRST BIT=0                TM 00012740
         BZ    ICMRCVX            YES,GO TO ICM EXIT                 TM 00012750
         XI    PCOLDP+4,X'30'     SET CC=1 (BYTES MOVED NON          TM 00012760
*                                 ZERO (1ST BIT =1))                 TM 00012770
*                                                                    TM 00012780
*   REGISTER OPERAND 1 MUST BE RESTORED                              TM 00012790
*   SET UP LOAD INSTRUCTION                                          TM 00012800
*                                                                    TM 00012810
ICMRCVX  LM    R0,R2,SVRG0        RESTORE USER'S REGISTERS           TM 00012820
         MVZ   ICMLD1+1(1),COPYI+1 COPY REG NO.                      TM 00012830
ICMLD1   L     XXX,REGOP1         RESTORE REGISTER                   TM 00012840
         B     RXEXIT             GO TO COMMON EXIT                  TM 00012850
*                                                                    TM 00012860
* ICMV   MVC INSTRUCTION TABLE                                       TM 00012870
*   MOVE BYTES FROM THE STORAGE OPERAND 2 TO MASK                    TM 00012880
*   CORRESPONDING POSITIONS IN REGISTER OPERAND 1                    TM 00012890
ICMV     MVC   REGOP1+3(1),0(R1)  M1                                 TM 00012900
         MVC   REGOP1+2(2),0(R1)  M3                                 TM 00012910
         MVC   REGOP1+1(3),0(R1)  M7                                 TM 00012920
         MVC   REGOP1+0(1),0(R1)  M8                                 TM 00012930
         MVC   REGOP1+0(2),0(R1)  MC                                 TM 00012940
         MVC   REGOP1+0(4),0(R1)  MF                                 TM 00012950
         B     GPCRCV              M0,2,4,5,6,9,A,B,D & E             T 00012960
*                                                                    TM 00012970
* ICMCL  CLC INSTRUCTION TABLE                                       TM 00012980
*   COMPARE ZERO TO THE OPERAND 2 BYTES AS PER THE MASK              TM 00012990
ICMCL    CLC   QZERO(1),0(R1)     M1                                 TM 00013000
         CLC   QZERO(2),0(R1)     M3                                 TM 00013010
         CLC   QZERO(3),0(R1)     M7                                 TM 00013020
         CLC   QZERO(1),0(R1)     M8                                 TM 00013030
         CLC   QZERO(2),0(R1)     MC                                 TM 00013040
         CLC   QZERO(4),0(R1)     MF                                 TM 00013050
*                                                                    TM 00013060
****************************************************************     TM 00013070
*                                                              *     TM 00013080
*STCM SIMULATOR                                                *     TM 00013090
*                                                              *     TM 00013100
*   THE STCM SIMULATION IS TO-                                 *     TM 00013110
*        SET THE CURRENT PSW TO THE USER'S KEY                 *     TM 00013120
*        MOVE THE PROPER BYTES FROM THE REGISTER OPERAND       *     TM 00013130
*              TO THE STORAGE OPERAND                          *     TM 00013140
*                                                              *     TM 00013150
****************************************************************     TM 00013160
STCMRCV  MVZ   STCMPSW+1(1),PCOLDP+1 SET USER KEY INTO               TM 00013170
*                                 THE NEXT USED PSW                  TM 00013180
         LPSW  STCMPSW            ENABLE STORAGE PROTECT             TM 00013190
STCMRCV1 EX    0,STCMV(R2)        STORE PROPER REGISTER              TM 00013200
*                                 BYTES INTO OPERAND 2               TM 00013210
         LM    R0,R2,SVRG0        RESTORE USER'S REGISTERS           TM 00013220
         LPSW  RSMPSW             RESTORE KEY 0 AND GO               TM 00013230
*                                 TO COMMON EXIT (RXEXIT)            TM 00013240
*                                                                    TM 00013250
* STCMV  MVC INSTRUCTION TABLE                                       TM 00013260
*   MOVE OPERAND 1 BYTES (CORRESPONDING TO THE MASK) TO THE          TM 00013270
*   STORAGE OPERAND 2 ADDRESS                                        TM 00013280
STCMV    MVC   0(1,R1),REGOP1+3   M1                                 TM 00013290
         MVC   0(2,R1),REGOP1+2   M3                                 TM 00013300
         MVC   0(3,R1),REGOP1+1   M7                                 TM 00013310
         MVC   0(1,R1),REGOP1+0   M8                                 TM 00013320
         MVC   0(2,R1),REGOP1+0   MC                                 TM 00013330
         MVC   0(4,R1),REGOP1+0   MF                                 TM 00013340
         LPSW  GPCRPSW            M0,2,4,5,6,9,A,B,D & E             TM 00013350
*                                                                    TM 00013360
****************************************************************     TM 00013370
*                                                              *     TM 00013380
*CLM SIMULATOR                                                 *     TM 00013390
*                                                              *     TM 00013400
*   THE CLM SIMULATION IS TO-                                  *     TM 00013410
*        PRESET THE COND CODE TO ZERO                          *     TM 00013420
*        COMPARE THE PROPER BYTES FROM THE REGISTER            *     TM 00013430
*              OPERAND TO THE STORAGE OPERAND                  *     TM 00013440
*        SET THE APPROPRIATE CC                                *     TM 00013450
*                                                              *     TM 00013460
****************************************************************     TM 00013470
CLMRCV   NI    PCOLDP+4,X'CF'     PRESET USER CC=0                   TM 00013480
         EX    0,CLMCL(R2)        COMPARE  THE PROPER                TM 00013490
*                                 BYTES FROM 'REGISTER'              TM 00013500
*                                 OPERAND TO THE STORAGE             TM 00013510
*                                 OPERAND                            TM 00013520
         LM    R0,R2,SVRG0        RESTORE USER'S REGISTERS           TM 00013530
         B     COMCCSET           GO TO COMMON CC SET                TM 00013540
*                                 AND EXIT                           TM 00013550
*                                                                    TM 00013560
* CLMCL CLC INSTRUCTION TABLE                                        TM 00013570
*   COMPARE BYTES FROM OPERAND 1 (CORRESPONDING TO THE               TM 00013580
*   MASK) TO OPERAND 2                                               TM 00013590
CLMCL    CLC   REGOP1+3(1),0(R1)  M1                                 TM 00013600
         CLC   REGOP1+2(2),0(R1)  M3                                 TM 00013610
         CLC   REGOP1+1(3),0(R1)  M7                                 TM 00013620
         CLC   REGOP1+0(1),0(R1)  M8                                 TM 00013630
         CLC   REGOP1+0(2),0(R1)  MC                                 TM 00013640
         CLC   REGOP1+0(4),0(R1)  MF                                 TM 00013650
         B     GPCRCV              M0,2,4,5,6,9,A,B,D & E             T 00013660
*                                                                    TM 00013670
****************************************************************     TM 00013680
*                                                              *     TM 00013690
* SPECIFICATION EXCEPTION RECOVERY                             *     TM 00013700
*                                                              *     TM 00013710
*   RXRCV RESOLVES SPECIFICATION EXCEPTIONS INCURRED           *     TM 00013720
*   BY RX INSTRUCTIONS DUE TO STORAGE OPERAND MISALIGNMENT     *     TM 00013730
*                                                              *     TM 00013740
*   THE RECOVERY IS TO-                                        *     TM 00013750
*        GENERATE THE STORAGE OPERAND ADDRESS                  *     TM 00013760
*        MOVE THE OPERAND TO AN ALIGNED LOCATION               *     TM 00013770
*        RETRY THE OPERATION                                   *     TM 00013780
*        SET THE CONDITION CODE AS REQUIRED                    *     TM 00013790
*        RESTORE THE STORAGE OPERAND AS REQUIRED               *     TM 00013800
*                                                              *     TM 00013810
****************************************************************     TM 00013820
RXRCV    CLI   PCOLDP+3,X'06'     TEST IF A SPECIFICATION            TM 00013830
*                                 EXCEPTION                          TM 00013840
         BNE   GPCRCV              NO,GO TO GENERAL RTN               T 00013850
*   SET UP A LOAD ADDRESS INSTRUCTION TO OBTAIN THE ADDRESS          TM 00013860
*   OF THE STORAGE OPERAND.                                          TM 00013870
         L     R0,COPYI           GET INSTRUCTION                    TM 00013880
         STH   R0,GETADR+2        STORE B2 D2 IN LA                  TM 00013890
         MVN   GETADR+1(1),COPYI+1 MOVE X2 TO LA                     TM 00013900
*   SET UP A RETRY INSTRUCTION                                       TM 00013910
         LH    R0,COPYI           GET OPCDE,R1,X2                    TM 00013920
         STH   R0,RETRYOP         STORE OP,R1,X2 IN RETRY            TM 00013930
         NI    RETRYOP+1,X'F0'    CLEAR THE X2 FIELD                 TM 00013940
*                                                                    TM 00013950
*   GET AND SET THE USER'S PROGRAM MASK                              TM 00013960
*                                                                    TM 00013970
         L     R1,PCOLDP+4        GET USER PRGRAM MASK               TM 00013980
         SPM   R1                 SET IT                             TM 00013990
*                                                                    TM 00014000
*   PRESET CC=0. FOR ACCESS INSTRUCTIONS                             TM 00014010
*   THERE CAN BE NO MORE CC MODIFYING INSTRUCTIONS                   TM 00014020
*   BEFORE EXECUTING RETRYOP                                         TM 00014030
*                                                                    TM 00014040
         SR    R1,R1              CLEAR R1                           TM 00014050
*                                                                    TM 00014060
*   USE THE OP CODE TO GET THE INSTRUCTION DESCRIPTION INDEX         TM 00014070
*                                                                    TM 00014080
         IC    R1,COPYI           GET OP CODE                        TM 00014090
         IC    R1,RXNDX-X'40'(R1) GET ASSOCIATED INDEX               TM 00014100
         IC    R0,RXAL(R1)        GET THE ARGUMENT LENGTH            TM 00014110
         IC    R1,RXTYP(R1)       GET THE INSTRUCTION TYPE           TM 00014120
         B     RXPRC(R1)          GO TO PROPER PROCESSOR             TM 00014130
*                                 E.G. LOAD,COMPARE,STORE            TM 00014140
*                                                                    TM 00014150
RXPRC    EQU   *                  DUMMY WHICH MUST PRECEDE           TM 00014160
*                                 AND BE AT MOST 250 BYTES           TM 00014170
*                                 FROM RXNVAL, RXMCC, RXLDT          TM 00014180
*                                 AND RXSTG                          TM 00014190
*                                                                    TM 00014200
****************************************************************     TM 00014210
*   SPECIFICATION EXCEPTIONS NOT CAUSED BY MISALIGNED          *     TM 00014220
*   STORAGE OPERANDS ARE GIVEN TO THE GENERAL PROGRAM          *     TM 00014230
*   CHECK ROUTINE                                              *     TM 00014240
****************************************************************     TM 00014250
RXNVAL   B     GPCRCV              GO TO GENERAL ROUTINE              T 00014260
*                                                                    TM 00014270
****************************************************************     TM 00014280
*   RX STORAGE MODIFICATION INSTRUCTIONS COME HERE             *     TM 00014290
****************************************************************     TM 00014300
RXSTG    STC   R0,RALIGN+1        STORE ARGUMENT LENGTH IN MVC       TM 00014310
         LM    R0,R1,SVRG0        RESTORE USER'S REGISTERS           TM 00014320
         EX    0,RETRYOP          RETRY THE INSTRUCTION              TM 00014330
         ST    R1,SVRG1           SAVE USER R1                       TM 00014340
         EX    0,GETADR           GET THE STORAGE OPERAND            TM 00014350
*                                 ADDRESS                            TM 00014360
*                                                                    TM 00014370
*   ENABLE STORAGE PROTECT                                           TM 00014380
*                                                                    TM 00014390
         MVZ   PRTPSW+1(1),PCOLDP+1 SET USER KEY IN NEXT PSW         TM 00014400
         LPSW  PRTPSW             CONTINUE IN USER KEY               TM 00014410
RALIGN   MVC   0(XXX,R1),DBLWRD   STORE RESULTANT OPERAND            TM 00014420
         L     R1,SVRG1           RESTORE USER'S R1                  TM 00014430
         LPSW  RSMPSW             RE-INSTATE KEY 0 AND               TM 00014440
*                                 GO TO RXEXIT                       TM 00014450
*                                                                    TM 00014460
****************************************************************     TM 00014470
*   INSTRUCTIONS WHICH MODIFY THE CONDITION CODE COME HERE     *     TM 00014480
****************************************************************     TM 00014490
RXMCC    NI    PCOLDP+4,X'CF'     PRESET USER CC=0                   TM 00014500
*                                                                    TM 00014510
****************************************************************     TM 00014520
*   ACCESS ONLY INSTRUCTIONS ENTER HERE                        *     TM 00014530
****************************************************************     TM 00014540
RXLDT    STC   R0,PALIGN+1        STORE OPERAND 2 LENGTH             TM 00014550
*                                 INTO ALIGNMENT MVC                 TM 00014560
         LM    R0,R1,SVRG0        RESTORE USER'S REGISTERS           TM 00014570
GETADR   LA    R1,XXX(XXX,XXX)    GET THE STORAGE OPERAND            TM 00014580
*                                 ADDRESS                            TM 00014590
PALIGN   MVC   DBLWRD(XXX),0(R1)  ALIGN THE STORAGE OPERAND          TM 00014600
         L     R1,SVRG1           RESTORE USER'S R1                  TM 00014610
RETRYOP  LA    XXX,DBLWRD         RETRY THE INSTRUCTION              TM 00014620
*                                                                    TM 00014630
COMCCSET BC    8,RXEXIT           EXIT IF CC=0 OR IF                 TM 00014640
*                                 CC NOT TO BE SET                   TM 00014650
         BC    4,RXCC1            GO SET CC=1                        TM 00014660
         BC    2,RXCC2            GO SET CC=2                        TM 00014670
         OI    PCOLDP+4,X'30'     SET CC=3                           TM 00014680
         B     RXEXIT             EXIT                               TM 00014690
RXCC1    OI    PCOLDP+4,X'10'     SET CC=1                           TM 00014700
         B     RXEXIT             EXIT                               TM 00014710
RXCC2    OI    PCOLDP+4,X'20'     SET CC=2                           TM 00014720
*                                                                    TM 00014730
****************************************************************     TM 00014740
*   COMMON EXIT                                                *     TM 00014750
*   SET ENTRY GATE IN THE PROGRAM NEW TO NORMAL ENTRY          *     TM 00014760
*   LOAD PSW OF THE PROGRAM OLD RESUMES THE USER PROGRAM       *     TM 00014770
*        AT THE INSTRUCTION FOLLOWING THE PROGRAM CHECK        *     TM 00014780
****************************************************************     TM 00014790
RXEXIT   NI    PCNPSWCC,X'CF'     SET NORMAL ENTRY GATE            UNCN 00014800
         MVC   COPYPSW(8),PCOLDP  COPY EXIT PSW                      TM 00014810
         MVC   PCOLDP(8),LSTVPC   SET LAST VALID PROGRAM CHECK       TM 00014820
         LPSW  COPYPSW            RESUME INTERRUPTED PROGRAM         TM 00014830
*                                                                    TM 00014840
****************************************************************     TM 00014850
*                                                              *     TM 00014860
*              TABLES/BLOCKS                                   *     TM 00014870
*                                                                    TM 00014880
****************************************************************     TM 00014890
*   TABLE RXTYP CONTAINS 1 BYTE ADCONS TO ACCESS THE           *     TM 00014900
*   DIFFERENT SUB-PROCESSORS FOR :                             *     TM 00014910
*        STORAGE ACCESS INSTRUCTIONS                           *     TM 00014920
*        CONDITION CODE MODIFICATION INSTRUCTIONS              *     TM 00014930
*        STORAGE MODIFICATION INSTRUCTIONS                     *     TM 00014940
*   EACH VALID TYPE HAS THREE TABLE ENTRIES FOR                *     TM 00014950
*   2,4 OR 8 BYTE STORAGE OPERAND LENGTHS RESPECTIVELY         *     TM 00014960
****************************************************************     TM 00014970
RXTYP    DC    AL1(RXNVAL-RXPRC)  UNDEFINED, GO TO THE               TM 00014980
*                                 GENERAL ROUTINE                    TM 00014990
         DC    3AL1(RXLDT-RXPRC)  ACCESS ONLY                        TM 00015000
         DC    3AL1(RXMCC-RXPRC)  CONDITION CODE MODIFICATION        TM 00015010
         DC    3AL1(RXSTG-RXPRC)  STORAGE MODIFICATION               TM 00015020
*                                                                    TM 00015030
****************************************************************     TM 00015040
*   TABLE RXAL CONTAINS 1 BYTE STORAGE OPERAND LENGTHS (-1)    *     TM 00015050
*   EACH VALID LENGTH IS IN THE TABLE THREE TIMES              *     TM 00015060
*   FOR LOAD, COMPARE AND STORE INSTRUCTIONS RESPECTIVELY      *     TM 00015070
****************************************************************     TM 00015080
RXAL     DC    X'00'              UNDEFINED                          TM 00015090
         DC    X'010307'          2,4,8 BYTE OPERANDS (ACCESS)       TM 00015100
         DC    X'010307'          2,4,8 BYTE OPERANDS (CC)           TM 00015110
         DC    X'010307'          2,4,8 BYTE OPERANDS (STORE)        TM 00015120
*                                                                    TM 00015130
****************************************************************     TM 00015140
*   TABLE RXNDX CONTAINS 1 BYTE ENTRIES GIVING THE PROPER      *     TM 00015150
*   INDEX INTO RXTYP AND RXAL FOR THE 360 RX SET               *     TM 00015160
****************************************************************     TM 00015170
*                                                                    TM 00015180
RXNDX    DC    X'07000000'        X'40' STH,LA,STC,IC                TM 00015190
         DC    X'00000000'        X'44' EX,BAL,BCT,BC                TM 00015200
         DC    X'01040404'        X'48' LH,CH,AH,SH                  TM 00015210
         DC    X'01000903'        X'4C' MH,U,CVD,CVB                 TM 00015220
         DC    X'08000000'        X'50' ST,U,U,U                     TM 00015230
         DC    X'05050505'        X'54' N,CL,O,X                     TM 00015240
         DC    X'02050505'        X'58' L,C,A,S                      TM 00015250
         DC    X'02020505'        X'5C' M,D,AL,SL                    TM 00015260
         DC    X'09000000'        X'60' STD,U,U,U                    TM 00015270
         DC    X'00000000'        X'64' U,U,U,U                      TM 00015280
         DC    X'03060606'        X'68' LD,CD,AD,SD                  TM 00015290
         DC    X'03030606'        X'6C' MD,DD,AW,SW                  TM 00015300
         DC    X'08000000'        X'70' STE,U,U,U                    TM 00015310
         DC    X'00000000'        X'74' U,U,U,U                      TM 00015320
         DC    X'02050505'        X'78' LE,CE,AE,SE                  TM 00015330
         DC    X'02020505'        X'7C' ME,DE,AU,SU                  TM 00015340
*                                                                    TM 00015350
****************************************************************     TM 00015360
*   TABLE MSK3TB CONTAINS 1 BYTE EQUIVALENTS TO ICM,STCM,CLM   *     TM 00015370
*   MASK VALUES IN THE FORM OF OFFSETS TO MVC OR CLC           *     TM 00015380
*   INSTRUCTIONS.                                              *     TM 00015390
****************************************************************     TM 00015400
MSK3TB   DC    X'24002406'        MASK VALUES 0,1,2,3                TM 00015410
         DC    X'2424240C'                    4,5,6,7                TM 00015420
         DC    X'12242424'                    8,9,A,B                TM 00015430
         DC    X'1824241E'                    C,D,E,F                TM 00015440
.NOSIMFX ANOP                                               1/6/76      00015450
*                                                                    TM 00015460
****************************************************************     TM 00015470
*                                                              *     TM 00015480
*              PSWS                                            *     TM 00015490
*                                                              *     TM 00015500
****************************************************************     TM 00015510
*                                                                    TM 00015520
.NULLSM2 ANOP                                               1/6/76      00015530
         DS    0D                 ALIGN DOUBLE WORD                  TM 00015540
*                                                                    TM 00015550
*   PSW TO ENTER OS/MVT PROGRAM INTERRUPT ROUTINE                    TM 00015560
PCNPSW2  DC    X'00040000'        ENABLE MACHINE ONLY                TM 00015570
         AIF   ('&CTRLPGM' EQ 'MFT').MFT08                          DSX 00015580
         DC    V(IEAQPK00)          OS/MVT INTERRUPT ROUTINE            00015590
         AGO   .NOTMFT5                                             DSX 00015600
.MFT08   ANOP                                                       DSX 00015610
         DC    V(IEAAPK00) *        OS/MFT INTURRUPT ROUTINE        DSX 00015620
.NOTMFT5 ANOP                                                       DSX 00015630
         AIF   ('&TYPE' EQ 'NULL').MFT09                    1/6/76      00015640
*                                                                    TM 00015650
*   PSWS USED TO ENABLE STORAGE PROTECT                              TM 00015660
*        THE PSWS ARE INITIALIZED TO THE USER'S KEY                  TM 00015670
*        PRIOR TO STORAGE MODIFICATION                               TM 00015680
         AIF   ('&TYPE' EQ 'SHORT').GPXRPSW                             00015690
STCMPSW  DC    X'00040000'        ENABLE FOR MACHINE ONLY            TM 00015700
         DC    A(STCMRCV1)        RETURN TO STCMRCV1                 TM 00015710
PRTPSW   DC    X'00040000'        DISABLED                           TM 00015720
         DC    A(RALIGN)          CONTINUE                           TM 00015730
*                                                                    TM 00015740
*   PSWS USED TO RETURN TO KEY 0                                     TM 00015750
RSMPSW   DC    X'00040000'        ENABLE MACHINE ONLY                TM 00015760
         DC    A(RXEXIT)          GO TO COMMON EXIT                  TM 00015770
.GPXRPSW ANOP                                                           00015780
GPCRPSW  DC    X'00040000'        ENABLE FOR MACHINE ONLY            TM 00015790
         DC    A(GPCRCV)          GO TO GPCRCV FOR STCM              TM 00015800
*                                                                    TM 00015810
****************************************************************     TM 00015820
*                                                              *     TM 00015830
*              STORAGE                                         *     TM 00015840
*                                                              *     TM 00015850
****************************************************************     TM 00015860
*                                                                    TM 00015870
COPYPSW  DC    D'0'               COPY OF THE PROGRAM OLD            TM 00015880
LSTVPC   DC    D'0'               LAST VALID PROGRAM CHECK           TM 00015890
DBLWRD   DC    D'0'               DOUBLE WORD WORK AREA              TM 00015900
COPYI    DC    F'0'               COPY INTERRUPTED INST.             TM 00015910
REGOP1   DC    F'0'               REGISTER OPERAND 1 SAVE            TM 00015920
SVRG0    DC    F'0'               SAVE USER REG 0                    TM 00015930
SVRG1    DC    F'0'               SAVE USER REG 1                    TM 00015940
SVRG2    DC    F'0'               SAVE USER REG 2                    TM 00015950
QZERO    DC    F'0'               ZERO                               TM 00015960
Q8N04    DC    X'80000004'        ILC 4 AND ADDRESS 4                TM 00015970
QCN01    DC    X'C0000001'        ILC 6 AND ODD ADDRESS              TM 00015980
F        DC    X'0000000F'        ISOLATE LOW ORDER X DIGIT          TM 00015990
PCNPSWCC DC    X'00'     PROGRAM NEW PSW CONDITION CODE BYTE       UNCN 00016000
*                                                                    TM 00016010
****************************************************************     TM 00016020
*                                                              *     TM 00016030
*              EQUATES                                         *     TM 00016040
*                                                              *     TM 00016050
****************************************************************     TM 00016060
*                                                                    TM 00016070
XXX      EQU   0                  FILLER FOR INSTRUCTION             TM 00016080
*                                 MODIFICATION                       TM 00016090
*                                                                    TM 00016100
PCNPSW   EQU   X'68'              PROGRAM NEW PSW                    TM 00016110
PCOLDP   EQU   X'28'              PROGRAM OLD PSW                    TM 00016120
AGPCRCV  DC    V(ITLSISO)                                               00016130
         AIF   ('&CTRLPGM' EQ 'MFT').MFT09                          DSX 00016140
R0       EQU   0                  R0                                 TM 00016150
R1       EQU   1                  R1                                 TM 00016160
R2       EQU   2                  R2                                 TM 00016170
RE       EQU   14                 RE                                 TM 00016180
RF       EQU   15                 RF                                 TM 00016190
.MFT09   ANOP                                                       DSX 00016200
         MEND                                                        TM 00016210
