         MACRO                                                          00020000
         SGIEE001  &PCUCB,&ACUCB,&CCA1,&CCV1,&CCN1,&CCA2,&CCV2,&CCN2,&V 00040017
         GBLC  &SCHDLR                                                  00060000
         LCLC  &IEEPG,&IEEPP,&IEEAG,&IEEAP                              00080000
.*                                                                      00100000
.*       THIS IS A MASTER SCHEDULER GROUP 0 SYSGEN MACRO WHICH          00120000
.*       GENERATES THE MASTER SCHEDULER CONSOLE INITIALIZATION RT       00140000
.*                                                                      00160000
.*       THE FOLLOWING MACRO PARAMETERS WILL BE EQUATED TO THE          00180000
.*       CORRESPONDING VALUES:                                          00200000
.*       1.  &PCUCB = PRIN CONSOLE INPUT AND OUTPUT UCB'S               00220000
.*       2.  &ACUCB = ALT  CONSOLE INPUT AND OUTPUT UCB'S               00240000
.*       3.  &CCA1 = START READER ADDRESS                               00260000
.*       4.  &CCN1 = DATA SET NAME OF READER                            00280000
.*       5.  &CCV1 = VOLUME SERIAL NR OF READER                         00300000
.*       6.  &CCA2 = START WRITER ADDRESS                               00320000
.*       7.  &CCN2 = DATA SET NAME OF WRITER                            00340000
.*       8.  &CCV2 = VOLUME SERIAL NR OF WRITER                         00360000
.*       9.    &V = VERSION - SSS OR SPS                                00380000
.*                                                                      00400000
&SCHDLR  SETC  '&V'                                                     00420000
&IEEPG   SETC  '&PCUCB'(1,3)                                            00440000
&IEEPP   SETC  '&PCUCB'(4,3)                                            00460000
&IEEAG   SETC  '&ACUCB'(1,3)                                            00480000
&IEEAP   SETC  '&ACUCB'(4,3)                                            00500000
*                                                                       00520000
MSCED    IEEGMSLT DSECT,SMBL=YES                                        00540000
         TITLE 'CONSOLE INITIALIZATION ROUTINE - MODULE IEEICCAN'       00560000
IEEICCAN CSECT                                                          00580000
CCR1     EQU   1                  COUNT REG                             00600000
CCR3     EQU   3                  2 BYTE UCB ADR TBL REG                00620000
CCR4     EQU   4                  CURRENT CONSOLE UCB PTR ADR REG       00640000
CCR5     EQU   5                  UCB PTR ADR REG                       00660000
CCR6     EQU   6                  END OF 2 BYTE UCB ADR TBL REG         00680000
CCRI     EQU   9                  CARD IMAGE ADR/2 BYTE UCB TBL INC REG 00700000
CCR10    EQU   10                 UCB PTR SLOT ADR REG                  00720000
CCR13    EQU   13                 RETURN FOR CONSETUP REG               00740000
CCRREG   EQU   14                 RETURN REG                            00760000
CCRB     EQU   15                 BASE REG                              00780000
SRTESTAT EQU   3        SRTUCB STATUS BITS SLOT      - OFFSET IN UCB    00800000
UCBATI   EQU   11       ATNTAB SLOT                  - OFFSET IN UCB    00820000
UCBNAME  EQU   13       UNIT NAME SLOT               - OFFSET IN UCB    00840000
         USING IEEICCAN,CCRB      CCRB=IEEICCAN BASE REGISTER 15        00860000
         USING IEEMSLT,BASEREG1   BASEREG1=IEEMSLT MODULE BASE REGISTER 00880000
         AIF   ('&SCHDLR' EQ 'SPS').NOINIT                              00900000
FIRSTIME NOP   CANDCOMD           NOP FIRST TIME ONLY                   00920000
         OI    FIRSTIME+1,BIT0+BIT1+BIT2+BIT3    NOP TO BRANCH          00940000
         LA    CCR1,4              UCB LOOP COUNT TO R1                 00960000
         L     CCR3,TVTADR         CVT ADR TO R3                        00980000
         L     CCR4,IEECUCBT(CCR3) 4 WORD UCB TABLE ADDRESS TO R4       01000000
         L     CCR3,IECLSTTV(CCR3) 2 BYTE UCB LOOKUP TABLE ADR TO R3    01020000
         LA    CCR5,CONSOLES       ADR OF SYSGENED UCB NAMES TO R5      01040000
         LH    CCR6,IEEMSFF        ADR OF END OF 2 BYTE UCB LOOKUP TBL  01060000
IEELOOP1 SR    CCRI,CCRI           CLEAR R9                             01080000
IEELOOP2 LH    CCR10,0(CCR3,CCRI)  2 BYTE UCB ADDRESS TO R10            01100000
         CR    CCR6,CCR10          END OF UCB LOOKUP TABLE              01120000
         BE    LOOPAGIN             YES,ERROR                           01140000
         LTR   CCR10,CCR10          NO,HOLE IN UCB LOOKUP TABLE         01160000
         BNE   GETDNAME              NO,PROCEED                         01180000
INCUCBAD LA    CCRI,2(CCRI)          YES,STEP TO NEXT 2 BYTE UCB ADR    01200000
         B     IEELOOP2              AND LOOP                           01220000
GETDNAME N     CCR10,IEEZZ11           ZERO 2 HIGH ORDER BYTES OF R10   01240000
         CLC   0(3,CCR5),UCBNAME(CCR10) SYSGENED NAME=UNIT NAME         01260000
         BNE   INCUCBAD                  NO,CHECK NEXT ENTRY            01280000
         ST    CCR10,0(CCR4)             YES,STORE UCB ADR IN 4 WRD TBL 01300000
LOOPAGIN LA    CCR4,4(CCR4)       INCREMENT 4 WORD TABLE TO NEXT WORD   01320000
         LA    CCR5,3(CCR5)       INCREMENT SYGENED UCB NAMES TO NEXT   01340000
         BCT   CCR1,IEELOOP1       NAME AND LOOP TO COMPARE AGAIN       01360000
         L     CCR3,TVTADR         CVT ADDRESS TO R3                    01380000
         L     CCR4,IEECUCBT(CCR3) 4 WORD UCB TABLE ADDRESS TO R4       01400000
         L     CCR10,0(0,CCR4)     GET UCB ADDRESS OF THE PRIMARY       01420000
*                                  INPUT CONSOLE.                       01440000
         TM    SRTESTAT(CCR10),X'80'    IS IT ONLINE                    01460000
         BZ    PRIMEOFF                 NO                              01480000
         MVI   0(CCR4),BIT0        PRINCIPLE INPUT BIT ON               01500000
         MVI   4(CCR4),BIT0        PRINCIPLE OUTPUT BIT ON              01520000
         L     CCR3,0(CCR4)        PRINCIPLE UCB INPUT ADDRESS TO R3    01540000
         OI    SRTESTAT(CCR3),BIT6     PRIMARY/COMPOSITE(INPUT) BIT ON  01560000
         NI    SRTESTAT(CCR3),F-BIT7   ALTERNATE BIT OFF                01580000
         MVI   UCBATI(CCR3),BIT5  ATTNTAB ENTRY NO FOR CONS INT TO UCB  01600000
         CLC   1(3,CCR4),5(CCR4)   COMPOSITE CONSOLE                    01620000
         BNE   COMPCONS             YES,SET UP COMPOSITE CONSOLE        01640000
         CLC   1(3,CCR4),9(CCR4)    NO,ALTERNATE CONSOLE                01660000
         BE    CANDCOMD              NO,CHECK FOR CANNED COMMANDS       01680000
ALTCONS  L     CCR3,8(CCR4)          YES,ALT UCB INPUT ADR TO R3        01700000
         OI    SRTESTAT(CCR3),BIT7 ALTERNATE BIT ON                     01720000
         NI    SRTESTAT(CCR3),F-BIT6   PRIMARY/COMPOSITE(INPUT) BIT OFF 01740000
         MVI   UCBATI(CCR3),BIT5   ATTNTAB ENTRY NO FOR CONS INT TO UCB 01760000
         B     CANDCOMD            CHECK FOR CANNED COMMANDS            01780000
PRIMEOFF OI    8(CCR4),BIT0        SET ALTERNATE INPUT CONSOLE ACTIVE   01800000
         OI    12(CCR4),BIT0       SET ALTERNATE OUTPUT CONSOLE ACTIVE  01820000
         L     CCR10,0(0,CCR4)     GET UCB ADDRESS OF THE PRIMARY       01840000
*                                  INPUT CONSOLE.                       01860000
         OI    SRTESTAT(CCR10),BIT7     SET ALTERNATE CONSOLE BIT ON    01880000
         NI    SRTESTAT(CCR10),F-BIT6   SET PRIMARY BIT OFF             01900000
         MVI   UCBATI(CCR10),BIT5       ATTENTION TABLE NUMBER FOR      01920000
*                                       CONSOLE                         01940000
PNOTCOMP L     CCR10,8(0,CCR4)     GET UCB ADDRESS FOR ALTERNATE        01960000
*                                  INPUT CONSOLE.                       01980000
         OI    SRTESTAT(CCR10),BIT6     SET PRIMARY CONSOLE BIT ON      02000000
         NI    SRTESTAT(CCR10),F-BIT7   SET ALTERNATE BIT OFF           02020000
         MVI   UCBATI(CCR10),BIT5       ATTENTION TABLE NUMBER FOR      02040000
*                                       CONSOLE                         02060000
         B     CANDCOMD                                                 02080000
COMPCONS L     CCR3,4(CCR4)        PRINCIPLE UCB OUTPUT ADR TO R3       02100000
         OI    SRTESTAT(CCR3),BIT6 PRIMARY/COMPOSITE(OUTPUT) BIT ON     02120000
         NI    SRTESTAT(CCR3),F-BIT7   ALTERNATE BIT OFF                02140000
.NOINIT  ANOP                                                           02160000
CANDCOMD SR    CCRI,CCRI          ZERO IMAGE ADR,MAY BE NO CANNED COMD  02180000
         TM    MSPFG,MSDATE       HAS A SET COMMAND BEEN ISSUED         02200000
         BZ    0(CCRREG)           NO,RETURN TO MCR FOR SET COMMAND     02220000
         L     CCR1,CCURNT         YES,PUT CURRENT COUNT OF BYTES IN R1 02240000
         C     CCR1,CCNBR         IS CURRENT COUNT LT TOTAL NUMBER      02260000
         BNL   CCRTRN               IF NOT, RETURN                      02280000
         LA    CCRI,CCBGN(CCR1)     IF SO, GET NEXT CARD IMAGES ADDR    02300000
         LA    CCR1,80(CCR1)      UPDATE BYTE COUNT                     02320000
         ST    CCR1,CCURNT                                              02340000
CCRTRN   BR    CCRREG             RETURN                                02360000
CCBGN    EQU   *                                                        02380000
         AIF   ('&CCA1' EQ '').B1                                       02390017
RDRCAN   DC    80X'40'                                                  02400017
         ORG   RDRCAN                                                   02410017
         DC    C'START RDR,&CCA1'                                       02420017
         AIF   ('&CCV1' EQ '' AND '&CCN1' EQ '').B1                     02430017
         DC    C','                                                     02440017
         AIF   ('&CCV1' EQ '').A1                                       02450017
         DC    C'&CCV1'                                                 02460017
.A1      AIF   ('&CCN1' EQ '').B1                                       02470017
         DC    C',DSN=&CCN1'                                            02480017
.B1      AIF   ('&CCA2' EQ '').C1                                       02490017
         ORG                                                            02500017
WTRCAN   DC    80X'40'                                                  02510017
         ORG   WTRCAN                                                   02520017
         DC    C'START WTR,&CCA2'                                       02530017
         AIF   ('&CCV2' EQ '' AND '&CCN2' EQ '').C1                     02540017
         DC    C','                                                     02550017
         AIF   ('&CCV2' EQ '').B2                                       02560017
         DC    C'&CCV2'                                                 02570017
.B2      AIF   ('&CCN2' EQ '').C1                                       02580017
         DC    C',DSN=&CCN2'                                            02590017
.C1      ANOP                                                           02740000
         ORG                                                            02760000
CCEND    EQU   *                                                        02780000
CCNBR    DC    A(CCEND-CCBGN)     TOTAL NBR OF BYTES IN CANNED COMMANDS 02800000
CCURNT   DC    F'0'               CURRENT BYTE COUNT                    02820000
IEEZZ11  DC    X'0000'                                                  02840000
IEEMSFF  DC    X'FFFF'                                                  02860000
CONSOLES DC    C'&IEEPG'                                                02880000
         DC    C'&IEEPP'                                                02900000
         DC    C'&IEEAG'                                                02920000
         DC    C'&IEEAP'                                                02940000
         MEND                                                           02960000
