         MACRO                                                          00400019
         SGIEE0VR  &APR,&MCS,&GFX,&TP,&M65MP                     A32191 00700021
         TITLE 'IEE3203D, VARY KEYWORD SCAN ROUTINE'              M4957 01000019
IEE3203D CSECT                                                          01200019
*A 694500,784500-787500                                          A32191 01250021
*C 007000,121400-121996,694500                                   A32191 01300021
* MODULE CLEANUP--A MACRO CALL AND AN END STATEMENT FOLLOWING THE 21774 01350021
* MEND CARD IS INCORRECT AND WAS DELETED                          21774 01400021
*D 882000-932000                                                  21774 01450021
* 008000,113600,125000,127400,748000                              20002 05200020
*********************************************************************** 10400019
* TITLE- IEE3203D   VARY KEYWORD SCAN MODULE                          * 10460019
* FUNCTION- THIS MODULE SCANS THE VARY COMMAND OPERAND FIELD FOR THE  * 10520019
*              KEYWORD AND THEN COMPARES THIS KEYWORD TO EACH ENTRY   * 10580019
*              IN A TABLE OF VALID VARY KEYWORDS. A KEYWORD IS VALID  * 10640019
*              ACCORDING TO THE OPTIONS SPECIFIED AT SYSGEN TIME. FOR * 10700019
*              THIS SYSTEM, THESE KEYWORDS ARE VALID-                 * 10760019
*                  ONLINE    VALID FOR ALL SYSTEMS                    * 10820019
*                  OFFLINE             ''                             * 10880019
.MCS     AIF   ('&MCS' EQ '0').GFX                                      10940019
*                  CONSOLE   VALID FOR MULTIPLE CONSOLE SUPPORT OPT.  * 11000019
*                  HARDCPY             ''                             * 11060019
*                  MSTCONS             ''                             * 11120019
.GFX     AIF   ('&GFX' EQ '0').APR                                      11180019
*                  ONGFX     VALID FOR GRAPHICS OPTION                * 11240019
*                  OFFGFX              ''                             * 11300019
.APR     AIF   ('&APR' EQ '0').TP                                 20002 11360020
*                  PATH      VALID FOR ALTERNATE PATH RETRY OPTION    * 11420019
.TP      AIF   ('&TP' EQ '0').BR                                  20002 11430020
*                  ONTP      VALID FOR TCAM OPTION                20002 11440020
*                  OFFTP               ''                         20002 11450020
.BR      ANOP                                                           11480019
*********************************************************************** 11540019
* ENTRY POINT- IEE3203D FROM COMMAND ROUTER MODULE, IEE0403D          * 11600019
*********************************************************************** 11660019
* ATTRIBUTES- REENTRANT, SVC TRANSIENT, READ-ONLY, SELF RELOCATING    * 11720019
*********************************************************************** 11780019
* APPLICABILITY- MFT,MVT                                              * 11840019
*********************************************************************** 11900019
* EXTERNAL REFERENCES- EXTENDED SAVE AREA (XSA)                       * 11960019
*********************************************************************** 12020019
* EXITS(NORMAL)- IN THIS SYSTEM IEE3203D EXITS TO-                    * 12080019
         AIF   ('&M65MP' EQ '0').NOMP                            A32191 12140021
         AIF   ('&MCS' EQ '0').YESMP                             A32191 12190021
*              IEE3603D FOR KEYWORDS-ONLINE,OFFLINE,CONSOLE      A32191 12192021
*              IEE4703D FOR KEYWORD-HARDCPY                      A32191 12194021
*              IEE4303D FOR KEYWORD-MSTCONS                      A32191 12196021
         AGO   .BR1                                              A32191 12198021
.YESMP   ANOP                                                    A32191 12198421
*              IEE3603D FOR KEYWORDS-ONLINE,OFFLINE              A32191 12198821
         AGO   .BR1                                              A32191 12199221
.NOMP    AIF   ('&MCS' EQ '0').NONMCS                            A32191 12199621
*              IEE3303D FOR KEYWORDS- ONLINE, OFFLINE, CONSOLE        * 12200019
*              IEE4703D FOR KEYWORD- HARDCPY                          * 12260019
*              IEE4303D FOR KEYWORD- MSTCONS                          * 12320019
         AGO   .BR1                                                     12350020
.NONMCS  ANOP                                                           12380019
*              IEE1103D FOR KEYWORDS- ONLINE, OFFLINE                 * 12440019
.BR1     AIF   ('&GFX' EQ '0').NONGFX                                   12500020
*              IEE1703D FOR KEYWORDS- ONGFX, OFFGFX                   * 12560019
.NONGFX  AIF   ('&APR' EQ '0').NONAPR                                   12620019
*              IEE2403D FOR KEYWORD- PATH                             * 12680019
.NONAPR  AIF   ('&TP' EQ '0').NOTP                                20002 12710020
*              IGC1303D FOR KEYWORDS- ONTP, OFFTP                 20002 12740020
.NOTP    ANOP                                                           12770020
*********************************************************************** 12800019
* EXITS(ERROR)- EXIT TO MESSAGE MODULE IEE0503D                       * 12860019
*        MESSAGES-                                                    * 12920019
*              'IEE3111 VARY  PARAMETER MISSING'                      * 12980019
*                WHEN POINTER TO COMMAND PARAM LIST IN XAL IS 0       * 13040019
*              'IEE3071 VARY  DELIMITER ERROR'                        * 13100019
*                WHEN NO COMMA AFTER PARENS, UNBALENCED PARENS, OR NO * 13160019
*                COMMA BEFORE KEYWORD.                                * 13220019
*              'IEE3091 VARY  UNIDENTIFIABLE KEYWORD'                 * 13280019
*                WHEN THE KEYWD DOES NOT MATCH ANY ENTRY IN THE TABLE * 13340019
*********************************************************************** 13400019
* INPUT- REGISTER 2 CONTAINS A POINTER TO THE XSA                     * 13460019
*********************************************************************** 13520019
* OUTPUT- CONTROL IS PASSED TO THE CORRECT COMMAND PROCESSOR, OR THE  * 13580019
*              MESSAGE MODULE, IEE0503D                               * 13640019
*********************************************************************** 13700019
* OPERATION- IEE3203D SCANS THE VARY COMMAND OPERAND FOR THE KEYWORD  * 13760019
*              WHICH IS DEFINED AS THE WORD FOLLOWING THE FIRST COMMA * 13820019
*              NOT EMBEDDED IN PARENS. R9 IS USED TO INDEX THROUGH THE* 13880019
*              OPERAND TO FIND ',KEYWORD'. COMMANDS OF THE FOLLOWING  * 13940019
*              FORMS ARE ACCEPTABLE-                                  * 14000019
*                  V  UNIT,KEYWORD                                    * 14060019
*                  V  UNIT(MULTIPLE UNITS),KEYWORD                    * 14120019
*                  V  (MULTIPLE UNITS),KEYWORD                        * 14180019
*                  V  (MULTIPLE UNITS)UNIT,KEYWORD                    * 14240019
*                  (ANY NUMBER OF BALANCED INNER/OUTER PARENS MAY BE  * 14300019
*                   SPECIFIED)                                        * 14360019
*                  V  ,KEYWORD                                        * 14420019
*              WHEN THE COMMA PRECEDING THE KEYWORD IS FOUND,A POINTER* 14480019
*              TO THE START OF THE KEYWORD IS SAVED AND THE SCAN CON- * 14540019
*              TINUES UNTIL A COMMA, BLANK, OR THE END OF BUFFER IS   * 14600019
*              FOUND. WHEN THE COMPLETE KEYWORD IS FOUND, IT IS COM-  * 14660019
*              PARED TO EACH ENTRY IN THE VALID KEYWORD TABLE UNTIL A * 14720019
*              MATCH OR THE END OF THE TABLE IS FOUND. EACH ENTRY     * 14780019
*              CONSISTS OF A 9 BYTE KEYWORD SLOT FOLLOWED BY ITS 2    * 14840019
*              BYTE MODULE CODE. THE TABLE SCAN IS DONE BY ESTABLISH- * 14900019
*              ING ADDRESSABILITY TO THE TABLE AND THEN INCREMENTING  * 14960019
*              THE BASE REGISTER BY THE LENGTH OF AN ENTRY AS EACH NON* 15020019
*              MATCH IS FOUND. THIS METHOD INSURES FUTURE FLEXIBILITY * 15080019
*              BECAUSE NO MATTER HOW MANY NEW KEYWORDS ARE ADDED TO   * 15140019
*              THE TABLE, THE LABELS 'KEYTAB' AND 'XCTLMOD' WILL AL-  * 15200019
*              WAYS POINT TO THE CURRENT KEYWORD AND ITS MODULE CODE. * 15260019
*              WHEN A MATCH IS FOUND, THE MODULE CODE AT 'XCTLMOD' IS * 15320019
*              INSERTED INTO THE MODULE NAME IN THE XAX AND POINTERS  * 15380019
*              FOR THE XCTL ARE PLACED IN THE XSA. FOR AN ERROR, THE  * 15440019
*              MESSAGE MODULE NAME IS PLACED IN THE XAX, AN ERROR CODE* 15500019
*              IS PLACED IN THE XAE,AND THE XCTL PROCEDURE IS FOLLOWED* 15560019
*********************************************************************** 15620019
* NOTES- THIS SCAN DOES NOT SUPPORT KEYWORDS OF MORE THAN 8 CHARACTERS* 15680019
*********************************************************************** 16400019
* REGISTER ASIGNMENTS                                                   16410019
R1       EQU   1                                                        16420019
R2       EQU   2                   XSA BASE                             16430019
R3       EQU   3                                                        16440019
R4       EQU   4                   COUNTER FOR KEYWORD CHARACTERS       16450019
R5       EQU   5                                                        16460019
R6       EQU   6                   PTR TO FIRST CHAR OF KEYWORD         16470019
R7       EQU   7                   POINTER TO END OF BUFFER             16480019
R8       EQU   8                   WORK REG                             16490019
R9       EQU   9                   PTR TO CURRENT CHAR OF OPERAND FIELD 16500019
R10      EQU   10                                                       16510019
R11      EQU   11                  BASE FOR VALID KEYWORD TABLE         16520019
R12      EQU   12                  PGM BASE                             16530019
R13      EQU   13                                                       16540019
R14      EQU   14                                                       16550019
R15      EQU   15                                                       16560019
*    EQUATES                                                            16570019
C0       EQU   0                                                        16580019
C1       EQU   1                                                        16590019
C2       EQU   2                                                        16600019
C3       EQU   3                                                        16610019
C8       EQU   8                                                        16620019
LENG     EQU   11                  LENGTH OF KEYWORD-MODULE CODE ENTRY  16630019
COMMA    EQU   C','                COMMA CHAR                           16640019
LFTPAREN EQU   C'('                LEFT PAREN CHAR                      16650019
RGTPAREN EQU   C')'                RIGHT PAREN CHAR                     16660019
BLANK    EQU   C' '                BLANK CHAR                           16670019
PARENSW  EQU   3                   SWITCH FOR BALANCED PARENS           16680019
ERR7     EQU   07                  ERR CODE   DELIM ERROR               16690019
ERR9     EQU   9                   ERR CODE   UNIDENT KEYWORD           16700019
ERR11    EQU   11                  ERR CODE   PARAM MISSING             16710019
*********************************************************************** 16720019
         SPACE 10                                                       16730019
*********************************************************************** 16800019
* FUNCTIONS OF THIS ROUTINE-                                          * 17200019
*     1. ESTABLISHES PROGRAM AND XSA ADDRESSABILITY                   * 17600019
*     2. INITIALIZES A BALANCED PAREN SWITCH AND A CHARACTER COUNTER  * 18000019
*     3. CHECKS XAL FOR 0. (IF 0, BRANCHES TO ERROR ROUTINE.)         * 18400019
*     4. COMPUTES THE END OF BUFFER                                   * 18800019
*********************************************************************** 19200019
         BALR  R12,C0              ESTABLISH PGM ADDRESSABILITY         19600019
         USING *,R12                                                    20000019
         B     BRANCH              BRANCH AROUND MODULE ID              20050019
         DC    X'EEEE'             MODULE IDENTIFIER                    20100019
         DC    CL8'IEE3203D'              ..                            20150019
         DC    CL4'9122'                  ..                            20200019
         DC    X'EEEE'                    ..                            20250019
BRANCH   EQU   *                                                        20300019
         USING XSA,R2              BASE FOR EXTENDED SAVE AREA          20400019
         L     R9,XAL              REG 9 POINTS TO OPERAND FIELD OF    *20800019
                                   VARY COMMAND                         21200019
         LA    R9,C0(R9)           ZERO OUT HIGH ORDER BYTE             21600019
         LTR   R9,R9               IS PARAMETER PTR 0 (NO KEYWORD)      22000019
         LA    R5,ERR11            SET ERR CODE FOR MSG 'PARAM MISSING' 22400019
         BZ    ERREXIT             YES,PTR IS 0, GO TO ERROR ROUTINE    22800019
         L     R7,XAR              LOAD POINTER TO THE BUFFER THAT      23200019
         LA    R7,C0(R7)           CONTAINS THE VARY COMMAND            23600019
         AH    R7,C0(R7)           COMPUTE END OF BUFFER                24000019
         SR    PARENSW,PARENSW     INITIALIZE PAREN SWITCH TO 0         24400019
         SR    R4,R4               INITIALIZE CHARACTER COUNTER TO 0    24600019
         SPACE 10                                                       24800019
*********************************************************************** 24850019
* THE COMMAND OPERAND IS SCANNED FOR A LEFT PAREN OR A COMMA. IF A    * 24900019
* LEFT PAREN IS FOUND, THE OPERAND IS SCANNED FOR BALANCED PARENS AND * 24950019
* THEN THE KEYWORD. IF THERE IS NO LEFT PAREN, AND A COMMA IS FOUND,  * 25000019
* THE KEYWORD SHOULD FOLLOW.                                          * 25050019
*********************************************************************** 25100019
PARENSCN EQU   *                                                        25200019
CHECK    CLI   C0(R9),LFTPAREN     IS FIRST CHAR A LEFT PAREN           25600019
         BE    INCSWTCH            YES,GO TO CHECK FOR BAL PARENS       26000019
         CLI   C0(R9),COMMA        IS CURRENT CHAR A COMMA              27000019
         BE    SAVEPTR             YES, GO TO SCAN KEYWORD              28400019
         LA    R9,C1(R9)           INCREMENT PTR TO NEXT CHAR           28800019
         CR    R9,R7               HAS END OF BUFFER BEEN REACHED       29200019
         BE    DELIMERR            YES,GO TO ERR RTN, COMMA MISSING     29600019
         B     CHECK               GO BACK TO CHECK NEXT CHAR           30000019
*********************************************************************** 30400019
* THIS ROUTINE SCANS THE PARAMETER LIST FOR BALANCED PARENS. WHEN A   * 30800019
* LEFT PAREN IS FOUND, PARENSW IS INCREMENTED BY 1, FOR A RIGHT PAREN * 31200019
* IT IS DECREMENTED BY 1. WHEN PARENSW IS 0, BALANCED PARENS HAVE BEEN* 31600019
* FOUND, AND A COMMA AND THE KEYWORD SHOULD FOLLOW.                   * 32000019
*********************************************************************** 32400019
INCSWTCH LA    PARENSW,C1(PARENSW) INCREMENT BY 1 FOR LEFT PAREN        32800019
CHARSCAN LA    R9,C1(R9)           INCREMENT PTR TO NEXT CHAR           33200019
         CLI   C0(R9),LFTPAREN     IS CURRENT CHAR A LEFT PAREN         33600019
         BE    INCSWTCH            YES,CHAR IS'(',SET SWTCH,CHECK AGAIN 34000019
         CLI   C0(R9),RGTPAREN     IS CURRENT CHAR A RIGHT PAREN        34400019
         BNE   CHKSWTCH            NO,CHECK PAREN SWITCH FOR 0          34800019
DECSWTCH BCTR  PARENSW,C0          DECREMENT BY 1 FOR RIGHT PAREN       35200019
CHKSWTCH LTR   PARENSW,PARENSW     IS SWITCH 0 (BALANCED PARENS)        35600019
         BZ    KEYSCAN             YES,GO TO SCAN KEYWORD AFTER PARENS  36000019
         CR    R9,R7               NO, CHECK FOR END OF BUFFER REACHED  36400019
         BNE   CHARSCAN            NO,GO BACK TO CHECK NEXT CHAR        36800019
DELIMERR LA    R5,ERR7             DELIM ERR UNBAL PARENS OR NO COMMA   37200019
         B     ERREXIT             GO TO ERROR RTN TO SET UP XCTL       37600019
         SPACE 10                                                       38000019
*********************************************************************** 38400019
* THIS ROUTINE CHECKS FOR A COMMA PRECEDING A KEYWORD AND IF THE COMMA* 38800019
* IS PRESENT, SCANS THE KEYWORD. A POINTER TO THE FIRST CHAR OF THE   * 39200019
* KEYWORD IS SAVED. (A KEYWORD IS DEFINED AS THE FIRST WORD FOLLOWING * 39600019
* A COMMA NOT EMBEDDED IN PARENS.) THE KEYWORD IS COMPLETE WHEN A     * 40000019
* COMMA, A BLANK, OR END OF BUFFER IS FOUND.                          * 40400019
*********************************************************************** 40800019
KEYSCAN  EQU   *                                                        41200019
         LA    R9,C1(R9)           INCREMENT PTR TO NEXT CHAR           41600019
         CLI   C0(R9),COMMA        IS CURRENT CHAR A COMMA              42000019
         BNE   DELIMERR            NO.COMMA MUST PRECEDE KEYWORD        42400019
SAVEPTR  LA    R6,C1(R9)           SAVE PTR TO 1ST CHAR OF KEYWORD      42800019
SCAN1    LA    R9,C1(R9)           INCREMENT PTR TO CURR CHAR OF KEYWD  43200019
         CLI   C0(R9),COMMA        IS CURRENT CHAR A COMMA              44400019
         BE    TABSCAN             YES,COMMA MEANS END OF KEYWD FOUND   44800019
         CLI   C0(R9),BLANK        NO,CHECK CURRENT CHAR FOR BLANK      45200019
         BE    TABSCAN             YES,BLANK MEANS END OF KEYWD FOUND   45300019
         CR    R9,R7               NO,CHECK FOR END OF BUFFER           45400019
         BE    TABSCAN             GO TO SCAN TABLE                     45500019
         LA    R4,C1(R4)           INCREMENT KEYWORD CHAR COUNTER       45600019
         B     SCAN1               GO BACK TO CHECK NEXT CHAR OF KEYWD  46000019
         SPACE 10                                                       46400019
*********************************************************************** 46800019
* THIS ROUTINE COMPARES THE KEYWORD WITH EACH ENTRY IN A TABLE OF     * 47200019
* VALID VARY KEYWORDS UNTIL A MATCH, OR THE END OF THE TABLE IS FOUND.* 47600019
* WHEN A MATCH IS FOUND,THE CORRECT XCTL MODULE NAME IS PLACED IN THE * 48000019
* XAX, AND PTRS FOR THE XCTL ARE SET UP IN THE XSA.                   * 48400019
*********************************************************************** 48800019
TABSCAN  EQU   *                                                        49200019
         LA    R11,KEYTAB          PUT ADDRESS OF KEYWORD TABLE IN A    49600019
         USING KEYTAB,R11          REG AND ESTABLISH ADDRESSABILITY     50000019
         LA    R8,TABEND           PUT ADDRESS OF END OF TABLE IN A REG 50400019
         BCTR  R4,C0               DECREMENT CHAR COUNTER FOR EX INSTR  50600019
SCAN2    EQU   *                                                        50800019
         CLR   R11,R8              HAS END OF TABLE BEEN REACHED        51200019
         LA    R5,ERR9             PRESET CODE FOR UNIDENT KEYWORD MSG  51600019
         BH    ERREXIT             YES, THE VERB IS INVALID             52000019
         EX    R4,DOCLC            INSERT KEYWORD LENGTH IN CLC INSTR   52400019
         BE    XMOD                IF KEYWDS MATCH,GOTO SET UP XCTL MOD 52800019
INCPTR   LA    R11,LENG(R11)       IF NOT, INCREMENT PTR TO NEXT KEYWD  53200019
         B     SCAN2               GO TO CHECK NEXT ENTRY               53600019
XMOD     LA    R8,C1(R11)          COMPUTE A POINTER TO THE FIRST       53680019
         AR    R4,R8               CHARACTER AFTER THE KEYWORD          53770019
         CLI   C0(R4),BLANK        IS THE CHARACTER BLANK               53840019
         BNE   INCPTR              IF NOT, A FALSE MATCH HAS BEEN FOUND 53920019
*                                  EG. KEYWORD 'ABC' WOULD MATCH TABLE  54000019
*                                  ENTRY 'ABCD' BECAUSE ONLY THE FIRST  54080019
*                                  3 CHARACTERS WERE COMPARED.          54160019
XCTLRTN1 EQU   *                                                        56400019
         MVC   XAX(C8),XCTLNAME    PUT XCTL MOD NAME IN XAX             56800019
         MVC   XAX+C3(C2),XCTLMOD  PUT MOD IDENT CODE IN XCTL MOD NAME  57200019
XCTLRTN2 EQU   *                                                        58000019
         SR    R15,R15             ZERO  OUT A REG                      58400019
         ST    R15,XAD             USE IT TO ZERO OUT DCB PTR IN LIST   58800019
         LA    R15,XAX             GET PTR TO XCTL MOD NAME IN LIST     59200019
         ST    R15,XAP             PUT PTR TO XCTL MOD NAME INTO LIST   59600019
         LR    R15,R2              PUT PTR TO LIST IN REG 15            60000019
         XCTL  SF=(E,(15))         ISSUE XCTL                           60800019
         SPACE 10                                                       61200019
*********************************************************************** 61600019
* EXIT ROUTINE-                                                       * 62000019
* THE CORRECT ERROR CODE AND THE MESSAGE MODULE NAME,IGC0503D, ARE    * 62400019
* PUT IN THE XAE AND THEN THE XCTL PROCEDURE IS FOLLOWED.             * 62800019
*********************************************************************** 63200019
ERREXIT  EQU   *                                                        63600019
         STC   R5,XAE              PUT ERROR CODE IN XAE                64000019
         MVC   XAX(C8),MSGMOD      PUT IGC0503D IN XAX                  64400019
         B     XCTLRTN2            BRANCH TO COMPLETE XCTL              64800019
         SPACE 10                                                       65200019
DOCLC    CLC   C0(C0,R11),C0(R6)   DOES CURRENT TABLE ENTRY EQU KEYWD   65400019
         DS    0F                  ALIGN ON FULL WORD BOUNDARY          65600019
MSGMOD   DC    C'IGC0503D'         ERROR MSG MODULE                     66000019
XCTLNAME DC    CL8'IGC0003D'       XCTL MODULE NAME                     66100019
*********************************************************************** 66200019
KEYTAB   EQU   *                   START OF VALID KEYWORD TABLE         66400019
*                                  ****KEYWORD FOLLOWED BY ITS****      66700019
*                                  ****   XCTL MODULE CODE    ****      67000019
         AIF   ('&M65MP' EQ '0').NONMP                           A32191 67300021
         AIF   ('&MCS' EQ '0').MP                                A32191 67350021
         DC    CL9'ONLINE'             ..                        A32191 67400021
XCTLMOD  EQU   *                                                 A32191 67450021
         DC    CL2'36'                 ..                        A32191 67500021
         DC    CL9'OFFLINE'            ..                        A32191 67550021
         DC    CL2'36'                 ..                        A32191 67560021
         DC    CL9'CONSOLE'            ..                        A32191 67570021
         DC    CL2'36'                 ..                        A32191 67580021
         AGO   .ASITWAS                                          A32191 67590021
.NONMP   AIF   ('&MCS' EQ '0').INIT1                             A32191 67592021
         DC    CL9'ONLINE'                 ..                           67600019
XCTLMOD  EQU   *                                                        67900019
         DC    CL2'33'                     ..                           68200019
         DC    CL9'OFFLINE'                ..                           68500019
         DC    CL2'33'                     ..                           68800019
         DC    CL9'CONSOLE'                ..                           69100019
         DC    CL2'33'                     ..                           69400019
.ASITWAS ANOP                                                    A32191 69450021
         DC    CL9'HARDCPY'                ..                           69700019
         DC    CL2'47'                     ..                           70000019
         DC    CL9'MSTCONS'                ..                           70300019
         DC    CL2'43'                     ..                           70600019
.INIT2   AIF   ('&GFX' EQ '0').INIT3                                    70900019
         DC    CL9'ONGFX'                  ..                           71200019
         DC    CL2'17'                     ..                           71500019
         DC    CL9'OFFGFX'                 ..                           71800019
         DC    CL2'17'                     ..                           72100019
.INIT3   AIF   ('&APR' EQ '0').INIT4                                    72400019
         DC    CL9'PATH'                   ..                           72700019
         DC    CL2'24'                     ..                           73000019
.INIT4   AIF   ('&TP' EQ'0').INIT5                                20002 73300020
         DC    CL9'ONTP'                   ..                     20002 73600020
         DC    CL2'13'                     ..                     20002 73900020
         DC    CL9'OFFTP'                  ..                     20002 74200020
         DC    CL2'13'                     ..                     20002 74500020
.INIT5   ANOP                                                           74800020
TABEND   EQU   *-LENG                                                   75100019
*********************************************************************** 75400019
         AGO   .XX                                                      75600019
.INIT1   ANOP                                                           76000019
         DC    CL9'ONLINE'                 ..                           76400019
XCTLMOD  EQU   *                                                        76800019
         DC    CL2'11'                     ..                           77200019
         DC    CL9'OFFLINE'                ..                           77600019
         DC    CL2'11'                     ..                           78000019
         AGO   .INIT2                                                   78400019
.MP      ANOP                                                    A32191 78450021
         DC    CL9'ONLINE'             ..                        A32191 78500021
XCTLMOD  EQU   *                                                 A32191 78550021
         DC    CL2'36'                 ..                        A32191 78600021
         DC    CL9'OFFLINE'            ..                        A32191 78650021
         DC    CL2'36'                 ..                        A32191 78700021
         AGO   .INIT2                                            A32191 78750021
.XX      ANOP                                                           78800019
SETXSA   DSECT                                                          82400019
         IEEXSA                                                         82800019
         MEND                                                           83200019
