         MACRO                                                          00020000
         SGIEF001 &ACNREQ,&PRGREQ                                       00040000
IEFCC    DSECT                                                          00060000
         IEFACOMM                                                       00080000
         IEFAJCTB                                                       00100000
         IEFASCTB                                                       00120000
         IEFASIOT                                                       00140000
         IEFJFCBN                                                       00160000
         EJECT                                                          00180000
IEFJM    CSECT                                                          00200000
*********************************************************************** 00220000
*                                                                     * 00240000
*                        JOB CARD HEADER ROUTINE                      * 00260000
*                                                                     * 00280000
*********************************************************************** 00300000
* FUNCTION-                                                           * 00320000
*        1. INITIALIZE JOB CONTROL TABLE VALUES.                      * 00340000
*        2. INITIALIZE ACCOUNT CONTROL TABLE.                         * 00360000
*        3. DRIVE SUBROUTINE TO START AND ASSIGN QUEUE ADDRESSES.     * 00380000
*        4. DRIVE SUBROUTINES TO PROCESS JOB CARD POSITIONAL AND      * 00400000
*           KEYWORD PARAMETERS.                                       * 00420000
* ENTRY POINT-                               FROM- CSECT IEFMF        * 00440000
*        CSECT IEFJM- TO PROCESS JOB CONTROL                          * 00460000
*                     STATEMENT                                       * 00480000
* INPUT-                                                              * 00500000
*        REGISTERS-                                                   * 00520000
*              INPR1 - STARTING ADDRESS OF THE JOBNAME ON THE         * 00540000
*                      STATEMENT                                      * 00560000
*              INPR2 - LENGTH IN BYTES OF THE JOBNAME                 * 00580000
*              INPR3 - STARTING ADDRESS OF THE STATEMENT              * 00600000
*                      PARAMETER LIST                                 * 00620000
*              INPR4 - LENGTH IN BYTES OF THE PARAMETER LIST          * 00640000
*                                                                     * 00660000
*        SWITCHES-                                                    * 00680000
*              INJMSWA-                                               * 00700000
*                   INJMANRD  BIT-0/ACCOUNT NUMBER RECEIVED           * 00720000
*                   INJMPNRD  BIT-2/PROGRAMMER NAME RECEIVED          * 00740000
*              INCMSWB-                                               * 00760000
*                   INCMCXP   BIT-3/CONTINUATION EXPECTED             * 00780000
*              INCMSWD-                                               * 00800000
*                   INCMNCON  BIT-7/NO CONTINUATION                   * 00820000
*              INAMSWA-                                               * 00840000
*                   INAMCONT  BIT-1/ACCOUNTING CONTINUATION           * 00860000
*                   INAMERBO  BIT-3/CONTINUATION ERROR IN BREAKOUT    * 00880000
*                   INAMCDCT  BIT-5/COND= FIELD CONTINUATION          * 00900000
*                   INAMCDER  BIT-6/COND= FIELD ERROR                 * 00920000
*                                                                     * 00940000
*                                                                     * 00960000
* OUTPUT-                                                             * 00980000
*        REGISTERS- NONE                                              * 01000000
*                                                                     * 01020000
*        SWITCHES-                                                    * 01040000
*              INJMSWA-                                               * 01060000
*                   INCMLVLR  BIT-5/MESSAGE LEVEL RECEIVED            * 01080000
*                                                                     * 01100000
*              INCMSWA-                                               * 01120000
*                   INCMDFSH  BIT-5/DATA FLUSH                        * 01140000
*                   INCMJFSH  BIT-6/JOB FLUSH                         * 01160000
*                                                                     * 01180000
* EXTERNAL REFERENCES                                                 * 01200000
*        1. V(IEFCOND)  COND= SUBROUTINE                              * 01220000
*        2. V(IEFAM)    ACCOUNTING INFORMATION SUBROUTINE             * 01240000
*        3. V(IEFMI)    Q-MANAGER LINKAGE SUBROUTINE                  * 01260000
*        4. V(IEFMF)    CONTROL ROUTINE VERB ID SUBROUTINE            * 01280000
*        5. V(IEFWMSG)  MESSAGE OUTPUT SUBROUTINE                     * 01300000
*        6. V(IEFBM)    BREAKOUT SUBROUTINE                           * 01320000
*        7. V(IEFN1)  TYPRUN= SUBROUTINE                              * 01340000
*        8. V(IEFNX)  MSGLEVEL= SUBROUTINE                            * 01360000
*        9. V(IEFNY)  PRTY= SUBROUTINE                                * 01380000
*       10. V(IEFNZ)  MSGCLASS= SUBROUTINE                            * 01400000
*                                                                     * 01420000
* EXIT-                                                               * 01440000
*        NORMAL-INJMNEJ4 (STATEMENT LABEL)                            * 01460000
*                                                                     * 01480000
*        ERROR- NONE                                                  * 01500000
*                                                                     * 01520000
* ERROR MESSAGES-                                                     * 01540000
*        1. IEF106I NO JOB NAME, JOB FAILED                           * 01560000
*        2. IEF107I JOB NAME OVER 8 CHARS.                            * 01580000
*        3. IEF110I KEYWORD NOT IN TABLE                              * 01600000
*        4. IEF111I KEYWORD NOT SUPPORTED                             * 01620000
*        5. IEF112I NO ACCOUNT NUMBER, JOB FAILED (SYSTEM OPTION)     * 01640000
*        6. IEF113I PROGRAMMER'S NAME MISSING, JOB FAILED (SYSTEM OPT)* 01660000
*                                                                     * 01680000
* TABLES/WORK AREAS-                                                  * 01700000
*        1. JOB CONTROL TABLE                                         * 01720000
*        2. ACCOUNT CONTROL TABLE                                     * 01740000
*        3. INTERPRETER WORK AREA                                     * 01760000
*                                                                     * 01780000
*********************************************************************** 01800000
         USING IEFJCARD,INBSE                                           01820000
         TM    INJMSWA,X'02'                                            01840000
         BO    INJM9999                                                 01860000
         STM   1,15,INJESAVE            SAVE REGISTERS                  01880000
         BALR  INBSE,0                                                  01900000
         USING *,INBSE                  SET UP BASE REGISTER            01920000
IEFJCARD EQU   *                                                        01940000
         TM    INCMSWB,INCMCXP          IS CONTINUATION EXPECTED        01960000
         BC    INALZERO,INJMNCC1        NO                              01980000
         NI    INCMSWB,INALL-INCMCXP    INDICATE CONT. RECEIVED         02000000
         TM    INAMSWA,INAMCONT         IS ACCOUNTING RTN EXPECT. CONT  02020000
         BC    INALLONE,INJMNCF5       YES                              02040000
         TM    INAMSWA,INAMCDCT         IS COND= RTN EXPECTING CONT.    02060000
         BZ    INJMNCC4                 NO                              02080000
         L     INTRY,IEFCONDV                                           02100000
         LA    INPR5,1                  CONSTANT OF 1                   02120000
         OI    INJMSWA,X'02'            INDICATE FROM JOB               02140000
         B     INJMNEAA                                                 02160000
INJMNCC4 TM    INCMSWD,INCMNCON         IS THIS A CONT. STMNT           02180000
         BO    INJMNEB2                 NO                              02200000
         LA    INPR5,1                                                  02220000
         BC    INALWAYS,INJMNDA1        YES                             02240000
INJMNCC1 MVI   INJMSWA,X'00'            TURN OFF ALL SWITCHES           02260000
         MVI   JCTDSKAD,X'00'           CLEAR OUT JCT                   02280000
         MVC   JCTDSKAD+1(179),JCTDSKAD                                 02300000
         LR    INWK3,INPR3              SAVE REG 3                      02320000
         LA    INPR3,INJMJCT            JCT ADDRESS FOR ASSIGN & START  02340000
         SR    INPR5,INPR5              ZERO INPR5 TO INDICATE START    02360000
         L     INTRY,INJMQULK                                           02380000
         BALR INRTN,INTRY                                               02400000
         L     INWK1,INTTRSCT                                           02420000
         ST    INWK1,JCTSDKAD                                           02440000
         L     INWK1,INTTRSMB                                           02460000
         ST    INWK1,JCTSMBAD                                           02480000
         L     INWK1,INTTRACT                                           02500000
         ST    INWK1,JCTACTAD                                           02520000
         MVC   JCTDSKAD(3),INTTRJCT     DISK ADDRESS TO JC\             02540000
         STC   INPR5,JCTIDENT           JCT ID                          02560000
         MVI   JCTJSRNO,X'01'           FILL IN JOB SERIAL NO           02580000
         LR    INPR3,INWK3              RESTORE REG 3                   02600000
         LA    INPR5,1                                                  02620000
         MVI   ACTDSKAD,X'00'           ZERO                            02640000
         MVC   ACTDSKAD+1(179),ACTDSKAD   ACT                           02660000
         MVI   ACTPRGNM,SSSBLANK        BLANK                           02680000
         MVC   ACTPRGNM+1(19),ACTPRGNM   PROGRAMMERS NAME               02700000
         MVI   JCTJMGLV,X'10'           SET MESSAGE LEVEL TO 1          02720000
         STM   INPR1,INPR2,INAMMGSV     SAVE PARAMETER REGS             02740000
         SR    INPR1,INPR1                                              02760000
         IC    INPR1,DCBLRECL           LENGTH OF STATEMENT             02780000
         L     INPR2,INSTMT             STATEMENT ADDRESS               02800000
         L     INTRY,INJMMRCN                                           02820000
         BALR  INRTN,INTRY                                              02840000
         LM    INPR1,INPR2,INAMMGSV     RESTORE REGISTERS               02860000
         MVI   JCTJNAME,SSSBLANK        BLANK JOB NAME                  02880000
         MVC   JCTJNAME+1(7),JCTJNAME     IN JCT                        02900000
         LA    INPR5,1                  SET UP CONSTANT OF 1            02920000
         LTR   INPR2,INPR2              IS THERE A NAME ON STATEMENT    02940000
         BC    INNOTZRO,INJMNCF1        YES                             02960000
         STM   INPR1,INPR2,INAMMGSV     SAVE REGS                       02980000
         SR    INPR2,INPR2                                              03000000
         LA    INPR1,161                INTERNAL MESSAGE NBR 161        03020000
**  ERROR  **  NO JOB NAME                                              03040000
         L     INTRY,INJMMRCN                                           03060000
         BALR  INRTN,INTRY                                              03080000
         LM    INPR1,INPR2,INAMMGSV     RESTORE REGISTERS               03100000
         MVI   JCTJSTAT,X'04'           INDICATE JOB FAILED             03120000
         OI    INCMSWA,INCMDFSH         TURN ON DATA FLUSH SWITCH       03140000
         BC    INALWAYS,INJMNCJ1                                        03160000
INJMNCF1 CH    INPR2,IT8H               IS NAME OVER 8 CHARS            03180000
         BC    INNOTHI,INJMNCG1         NO                              03200000
         STM   INPR1,INPR2,INAMMGSV     SAVE REGS                       03220000
         SR    INPR2,INPR2              ZERO REG.                       03240000
         LA    INPR1,162                INTERNAL MESSAGE NBR 162        03260000
**  ERROR  **  JOB NAME OVER 8 CHARACTERS                               03280000
         L     INTRY,INJMMRCN                                           03300000
         BALR  INRTN,INTRY                                              03320000
         LM    INPR1,INPR2,INAMMGSV     RESTORE REGISTERS               03340000
         MVC   JCTJNAME(8),0(INPR1)     MOVE FIRST 8 CHARS TO JCT       03360000
         BC    INALWAYS,INJMNCH1                                        03380000
INJMMVNM MVC   JCTJNAME(1),0(INPR1)                                     03400000
INJMNCG1 SR    INPR2,INPR5              ADJUST NAME LENGTH FOR MOVE     03420000
         EX    INPR2,INJMMVNM           MOVE JOB NAME TO JCT            03440000
INJMNCH1 MVI   JCTJSTAT,X'00'           INDICATE IN JCT A GO SETUP JOB  03460000
         MVI   JCTJMGPO,C'A'            SET STANDARD MESSAGE CLASS      03480000
**  MOVE OTHER STANDARD VALUES TO JCT                                   03500000
INJMNCJ1 DS    0C                                                       03520000
**  MOVE TERMINAL NAME TO JCT                                           03540000
         LTR   INPR4,INPR4              IS THERE A LIST                 03560000
         BZ    INJMNEXX                 NO                              03580000
INJMNCF4 LA    INPR5,2                  CONSTANT OF 2                   03600000
         LA    INPR6,INBMLIST           DELIMITER LIST                  03620000
         L     INTRY,INJMBOAD           BREAKOUT ADDRESS                03640000
         BALR  INRTN,INTRY                                              03660000
         LA    INPR5,1                  CONSTANT OF 1                   03680000
         CLI   0(INPR1),SSSEQUAL        DID EQUAL STOP SCAN             03700000
         BE    INJMNDA1                 YES                             03720000
INJMNCF5 EQU   *                                                        03740000
         LA    INWK1,ACTJNFLD           ADDRESS OF NBR OF ACCT FIELDS   03760000
         L     INTRY,INJMADAC                                           03780000
         BALR  INRTN,INTRY                                              03800000
         TM    INAMSWA,INAMCONT         IS CONTINUATION XPECTD IN AC RN 03820000
         BO    INJMNEJ4                 YES                             03840000
         CLI   0(INPR1),SSSEQUAL        DID = CAUSE RETURN              03860000
         BC    INNOTEQU,INJMNEA1        NO                              03880000
         LA    INPR4,1(INPR4,INPR2)     RESTORE PROPER SCAN LENGTH      03900000
         LA    INPR5,1                 NO CHARS TO SCAN                 03920000
INJMNDA1 LA    INPR6,INBMLIST           ADDRESS OF COMMA                03940000
         L     INTRY,INJMBOAD           BREAKOUT ADCON                  03960000
         BALR  INRTN,INTRY                                              03980000
         TM    INCMSWB,INCMCXP          IS CONTINUATION EXPECTED        04000000
         BC    INALLONE,INJMNEJ3        YES                             04020000
         TM    INAMSWA,INAMERBO         WAS THERE A CONT ERR IN BREAK   04040000
         BC    INALLONE,INJMNEB2        YES                         OUT 04060000
         LTR   INPR1,INPR1              DID END STOP SCAN               04080000
         BC    INNOTZRO,INJMNDBA        NO                              04100000
         LA    INPR1,INAMBLNK           GET ADDRESS OF BLANK            04120000
         B     INJMNDBB                                                 04140000
INJMNDBA LR    INPR4,INPR1              GET LENGTH OF FIELD             04160000
         SR    INPR4,INPR3                IN INPR4                      04180000
INJMNDBB SR    INWK1,INWK1              ZERO REG                        04200000
         IC    INWK1,INKEYTBL           NBR ENTRIES IN KEYWORD TABLE    04220000
         LA    INWK2,INKEYTBL+4         ADDRESS OF FIRST TABLE ENTRY    04240000
         SR    INWK3,INWK3              ZERO REG                        04260000
INJMNDC1 IC    INWK3,11(INWK2)          NBR CHARS-1 IN TABLE ENTRY      04280000
         EX    INWK3,INKEYCMP           COMP. KEYWORD TO STATMENT FIELD 04300000
         BC    INEQZERO,INJMNDD3        THIS PATH IF EQUAL              04320000
         LA    INWK2,16(INWK2)          GET NEXT ENTRY                  04340000
         BCT   INWK1,INJMNDC1           TRY AGAIN TIL ENTRIES EXHAUSTED 04360000
         STM   INPR1,INPR2,INAMMGSV     SAVE REGS                       04380000
         SR    INPR2,INPR2              ZERO REG                        04400000
         LA    INPR1,171                INTERNAL MESSAGE NBR            04420000
**  ERROR  **  KEYWORD NOT IN TABLE                                     04440000
         L     INTRY,INJMMRCN                                           04460000
         BALR  INRTN,INTRY                                              04480000
         MVI   JCTJSTAT,X'04'           FAIL JOB                        04500000
         OI    INCMSWA,INCMDFSH         TURN ON DATA FLUSH              04520000
         LM    INPR1,INPR2,INAMMGSV     RESTORE REGISTERS               04540000
         BC    INALWAYS,INJMNEA1                                        04560000
INJMNDD3 TM    12(INWK2),INKEYSUP       IS KEYWORD SUPPORTED ON THIS    04580000
         BC    INALLONE,INJMNDE3        YES                    SYSTEM   04600000
         STM   INPR1,INPR2,INAMMGSV     SAVE REGS                       04620000
         SR    INPR2,INPR2                                              04640000
         LA    INPR1,172                INTERNAL MESSAGE NBR 172        04660000
**  ERROR  **  KEYWORD NOT SUPPORTED ON THIS SYSTEM                     04680000
         L     INTRY,INJMMRCN           MESSAGE ROUTINE ADDRESS         04700000
         BALR  INRTN,INTRY                                              04720000
         LM    INPR1,INPR2,INAMMGSV    RESTORE REGISTERS                04740000
         BC    INALWAYS,INJMNEA1                                        04760000
INKEYCMP CLC   0(1,INWK2),0(INPR3)                                      04780000
INJMNDE3 OI    INJMSWA,X'02'            INDICATE FROM JOB ROUTINE       04800000
         LA    INWK1,JCTJDPCD           FIRST DEPENDENCY                04820000
         L     INTRY,12(INWK2)          ADDRESS FO KEYWORD MODULE       04840000
INJMNEAA BALR  INRTN,INTRY                                              04860000
INJM9999 NI    INJMSWA,255-2                                            04880000
INJMNEA1 TM    INAMSWA,INAMCDCT         WAS CONT. FOUND IN COND= ROUTIN 04900000
         BO    INJMNEJ4                 YES                             04920000
         CLI   0(INPR1),SSSBLANK        DID BLANK STOP SCAN             04940000
         BZ    INJMNEXX                 YES                             04960000
         LR    INPR4,INPR2              SET UP PARAMETERS               04980000
         LA    INPR3,1(INPR1)             TO GET NEXT FIELD             05000000
         BC    INALWAYS,INJMNDA1                                        05020000
INJMNEB2 NI    INAMSWA,INALL-INAMERBO   TURN OFF SWITCH                 05040000
         MVI   JCTJSTAT,X'04'          FAIL JOB                         05060000
         OI    INCMSWA,INCMDFSH        TURN ON DATA FLUSH               05080000
         STM   INPR1,INPR2,INAMMGSV                                     05100000
         LA    INPR1,158                                                05120000
         SR    INPR2,INPR2                                              05140000
         L     INTRY,INJMMRCN                                           05160000
         BALR  INRTN,INTRY                                              05180000
         LM    INPR1,INPR2,INAMMGSV                                     05200000
         NI    INCMSWD,255-INCMNCON     NO                              05220000
INJMNEXX EQU   *                                                        05240000
         TM    INJMSWA,X'04'            WAS MESSAGE LEVEL RECEIVED      05260000
         BC    INALLONE,INJMNED2        YES                             05280000
         NI    JCTJMGLV,X'0F'           SET MESSAGE LEVEL TO ZERO       05300000
         OI    INJMSWA,X'04'            INDICATE MESSAGE LEVEL RECEIVED 05320000
INJMNED2 EQU   *                                                        05340000
         AIF   ('&ACNREQ' EQ 'A').ACCTNO                                05360000
         AGO   .PROGTST                                                 05380000
.ACCTNO  ANOP                                                           05400000
         TM    INJMSWA,INJMANRD      HAS ACCOUNT NBR BEEN  RECEIVED     05420000
         BO    INJMNEE3              YES                                05440000
         SR    INPR2,INPR2           ZERO REG                           05460000
         LA    INPR1,173             INTERNAL MESSAGE NUMBER 173        05480000
** ERROR ** NO ACCOUNT NUMBER RECEIVED                                  05500000
         L     INTRY,INJMMRCN        MESSAGE ROUTINE VCON               05520000
         BALR  INRTN,INTRY                                              05540000
         B     INJMNEG3                                                 05560000
INJMNEE3 EQU   *                                                        05580000
.PROGTST ANOP                                                           05600000
         AIF   ('&PRGREQ' EQ 'P').PROGCOD                               05620000
         AGO   .END                                                     05640000
.PROGCOD ANOP                                                           05660000
         TM    INJMSWA,INJMPNRD      HAS PROGRMRS NAME BEEN RECIEVED    05680000
         BO    INJMNEJ3              YES                                05700000
         SR    INPR2,INPR2           ZERO REG                           05720000
         LA    INPR1,174             INTERNAL MESSAGE NUMBER 174        05740000
**  ERROR  **  PROGRAMMER'S NAME MISSING                                05760000
         L     INTRY,INJMMRCN                                           05780000
         BALR  INRTN,INTRY                                              05800000
         AGO   .FINAL                                                   05820000
.END     ANOP                                                           05840000
         B     INJMNEJ3                                                 05860000
.FINAL   ANOP                                                           05880000
INJMNEG3 MVI   JCTJSTAT,X'04'           INDICATE JOB FAILED             05900000
         OI    INCMSWA,INCMDFSH         TURN ON DATA FLUSH SWITCH       05920000
         BC    INALWAYS,INJMNEJ4                                        05940000
INJMNEJ3 TM    INAMSWA,INAMCDER         WAS THERE AN ERROR IN COND RTN  05960000
         BC    INALZERO,INJMNEJ4        NO                              05980000
         NI    INAMSWA,INALL-INAMCDER   TURN OFF  INDICATOR             06000000
         BC    INALWAYS,INJMNEG3                                        06020000
INJMNEJ4 LM    1,12,INJESAVE            RESTORE REGS                    06040000
         LA    INWK2,20                                                 06060000
         L     INTRY,IEFMFV                                             06080000
         BR    INTRY                                                    06100000
IT8H     DC    XL2'08'                                                  06120000
DCBLRECL DC    X'50'                   LENGTH OF STATEMENT              06140000
INAMBLNK DC    C' '                                                     06160000
IEFCONDV DC    V(IEFCOND)                                               06180000
INJMADAC DC    V(IEFAM)                                                 06200000
INJMQULK DC    V(IEFMI)                                                 06220000
IEFMFV   DC    V(IEFMF)                                                 06240000
INJMMRCN DC    V(IEFWMSG)                                               06260000
INJMBOAD DC    V(IEFBM)                                                 06280000
*********************************************************************** 06300000
**                                                                   ** 06320000
**                            KEYWORD TABLE                          ** 06340000
**                                                                   ** 06360000
*********************************************************************** 06380000
INKEYTBL DS    0C                                                       06400000
         DC    X'05'          HEXIDECIMAL NBR OF ENTRIES IN THE TABLE   06420000
**                                   IN THIS SYSTEM                     06440000
         DC    X'00'                                                    06460000
         DS    2C                                                       06480000
**                  EACH ENTRY WILL HAVE THE FOLLOWING FORMAT --        06500000
**                * BYTES 1-11     THE KEYWORD IN EBCDIC FORM           06520000
**                * BYTE  12       HEX NBR OF CHARS-1 IN KEYWORD        06540000
**                * BYTE  13                                            06560000
**                  BYTES 14-16    ADDRESS OF THE KEYWORD CODE MODULE   06580000
         DC    C'TYPRUN'                                                06600000
         DC    AL1(SSSEQUAL)                                            06620000
         DC    CL4' '                                                   06640000
         DC    X'06'                    NBR OF CHARS-1 IN KEYWORD       06660000
         DC    X'80'               INDICATES SUPPORT BY THIS SYSTEM     06680000
         DC    VL3(IEFN1)                                               06700000
         DC    C'MSGLEVEL'                                              06720000
         DC    AL1(SSSEQUAL)                                            06740000
         DC    CL2' '                                                   06760000
         DC    X'08'                                                    06780000
         DC    X'80'                                                    06800000
         DC    VL3(IEFNX)                                               06820000
         DC    C'PRTY'                                                  06840000
         DC    AL1(SSSEQUAL)                                            06860000
         DC    CL6' '                                                   06880000
         DC    X'04'                                                    06900000
         DC    X'80'                                                    06920000
         DC    VL3(IEFNY)                                               06940000
         DC    C'COND'                                                  06960000
         DC    AL1(SSSEQUAL)                                            06980000
         DC    CL6' '                                                   07000000
         DC    X'04'                                                    07020000
         DC    X'80'                                                    07040000
         DC    VL3(IEFCOND)                                             07060000
         DC    C'MSGCLASS'                                              07080000
         DC    AL1(SSSEQUAL)                                            07100000
         DC    CL2' '                                                   07120000
         DC    X'08'                                                    07140000
         DC    X'80'                                                    07160000
         DC    VL3(IEFNZ)                                               07180000
*    SPECIAL CHARACTER DELIMITER LIST                                   07200000
INBMLIST DC    AL1(SSSCOMMA)            COMMA                           07220000
         DC    AL1(SSSEQUAL)            EQUAL SIGN                      07240000
         DC    AL1(SSSRPREN)            RIGHT PARENTHESIS               07260000
         DC    AL1(SSSLPREN)            LEFT PARENTHESIS                07280000
         DC    AL1(SSSBLANK)            BLANK                           07300000
         DC    AL1(SSSQUOTE)            QUOTE                           07320000
         MEND                                                           07340000
