         MACRO                                                          00900019
&TBLNAME SGIFF0BT &BFRSIZE,&EXPSZE,&NUMDEV,&NUMSEC1,&NUMSEC2,          X01800019
               &NUMSEC3,&NUMSEC4                                        02700019
         LCLA  &TBLNGTH,&TOTAVAL,&NETZONE,&DVCOUNT,&EXPBFR,&TABDISP     03600019
         LCLA  &ZONESZ,&TOTGUAR,&NUMSEC(4),&X1,&SAVE                    04500019
         LCLA  &ZSTBL(4),&GUARTBL(4),&EXTRA,&CTR                        05400019
.*  MACRO REWRITTEN FOR APAR 26262 FOR RELEASE 19                       06300000
&TBLNGTH SETA  &BFRSIZE/256        SET TABLE LENGTH                     07200019
&TOTAVAL SETA  &TBLNGTH            SET TOTAL NO OF BUF SECTIONS AVAIL.  08100019
         AIF   (T'&EXPSZE EQ 'O').BT00       CHECK FOR 2250-1           09000000
&NETZONE SETA  &TOTAVAL/&NUMDEV    SET INITIAL ZONE SIZE                09900019
&DVCOUNT SETA  &NUMDEV             SET NUMBER OF DEVICES                10800019
&EXPBFR  SETA  &EXPSZE             SET AMOUNT OF BUFF FOR EXPRESS       11700019
         AGO   .BT00G              BRANCH TO GENERATE 1ST 2 WORDS       12600019
.BT00    ANOP                                                           13500019
.*    SET FIELDS FOR 2250-1                                             14400019
&DVCOUNT SETA  1                   SET NO OF DEV EQ TO 1                15300019
&EXPBFR  SETA  &BFRSIZE            SET AMT OF BUFF FOR EXPRESS          16200019
&TABDISP SETA  16                  SET DEVICE TABLE DISPLACEMENT        17100019
&ZONESZ  SETA  &TOTAVAL            SET ZONE SIZE EQ FULL BUFFER         18000019
&TOTGUAR SETA  &TOTAVAL            SET TOTAL GUAR EQ FULL BUFFER        18900019
.*    GENERATE 1ST PART OF TABLE                                        19800019
.BT00G   ANOP                                                           20700019
         ENTRY &TBLNAME                                                 21600019
&TBLNAME DC    H'&TBLNGTH'         BUFFER TABLE LENGTH IN SECTIONS      22500019
         DC    H'&DVCOUNT'         NUMBER OF DEVICES                    23400019
         DC    H'&EXPBFR'          AMOUNT OF BUFFER FOR EXPRESS         24300019
         DC    H'&TOTAVAL'         TOTAL AVAIL BUFFER IN SECTIONS       25200019
         AIF   (T'&EXPSZE EQ 'O').BTV22     IF 2250-1 GEN WHOLE TABLE   26100000
&NUMSEC(1) SETA &NUMSEC1           INITIALIZE THE                       27000019
&NUMSEC(2) SETA &NUMSEC2                SUBSCRIPTED VARIABLES FOR       27900019
&NUMSEC(3) SETA &NUMSEC3                     THE NUMBER OF GUAR SECTS   28800019
&NUMSEC(4) SETA &NUMSEC4                          FOR EACH 2250         29700019
.BTP     ANOP                                                           30600019
.* FIND THE LARGEST NUMBER OF GUARANTEED SECTIONS NOT ASSIGNED YET      31500019
&X1      SETA  1                   INITIALIZE COUNTERS                  32400019
&SAVE    SETA  1                   THIS WILL BE THE INDEX OF LARGEST    33300019
.BTR     AIF   (&ZSTBL(&SAVE) EQ 0).BTU  START INDICES WITH VALUES      34200019
&SAVE    SETA  &SAVE+1                            THAT HAVE NOT         35100019
&X1      SETA  &X1+1                              BEEN ASSIGNED         36000019
         AGO   .BTR                               YES.                  36900019
.BTU     AIF   (&X1 GT &NUMDEV).BTRR  ALL ZONES HAVE BEEN ASSIGNED      37800019
.BTQ     AIF   (&X1 EQ &NUMDEV).BTS1  FOUND LARGEST OF REMAINING GUAR.  38700019
&X1      SETA  &X1+1               INCREMENT X1                         39600019
         AIF   (&NUMSEC(&X1) GT &NUMSEC(&SAVE)).BTT                     40500019
         AGO   .BTQ                                                     41400019
.BTT     AIF   (&ZSTBL(&X1) NE 0).BTQ                                   42300019
&SAVE    SETA  &X1            &SAVE WILL CONTAIN THE INDEX OF THE       43200019
.*                                 LARGEST REMAINING NUMSEC REQUEST     44100019
         AGO   .BTQ                                                     45000019
.BTS1    AIF   (&NUMSEC(&SAVE) GT &NETZONE).BTS2 GUAR LARGER THAN ZONE  45900019
.* ALL REMAINING ZONE SIZES ARE SET EQUAL TO NETZONE                    46800019
.* ALL REMAINING GUARANTEED SECTIONS ARE ASSIGNED                       47700019
&X1      SETA  0                        INITIALIZE INDEX                48600019
.BTS11   ANOP                                                           49500019
&X1      SETA  &X1+1                    INCREMENT INDEX                 50400019
         AIF   (&X1 GT &NUMDEV).BTV1    ALL DEVICES HAVE ZONES ASSIGNED 51300019
         AIF   (&ZSTBL(&X1) NE 0).BTS11 BRANCH IF ZONE HAS BEEN ASSIGND 52200019
&ZSTBL(&X1) SETA &NETZONE               SET ZONE SIZE TO NETZONE        53100019
&GUARTBL(&X1) SETA &NUMSEC(&X1)         SET NO. OF GUAR. SEC. TO NUMSEC 54000019
         AGO   .BTS11                   PROCESS NEXT DEVICE             54900019
.BTS2    ANOP                                                           55800019
.*  NUMBER OF GUARANTEED SECTIONS REQUESTED IS GREATER THAN NETZONE     56700019
&CTR     SETA  &CTR+1         KEEPS TRACK OF NO. OF DEVICES PROCESSED   57600019
         AIF   (&CTR EQ &NUMDEV).BTERR  BRANCH SHOULD NEVER BE TAKEN    58500019
&ZSTBL(&SAVE) SETA &NUMSEC(&SAVE)   SET ZONE SIZE TO NO. OF GUAR. SEC.  59400019
&GUARTBL(&SAVE) SETA &NUMSEC(&SAVE) SET NO. OF GUARANTEED SECTIONS      60300019
&NETZONE SETA  (&TOTAVAL-&ZSTBL(1)-&ZSTBL(2)-&ZSTBL(3)-&ZSTBL(4))/(&NUM*61200019
               DEV-&CTR)            RECALCULATE NETZONE                 62100019
         AIF   (&NETZONE LE 0).BTV2 BRANCH TAKEN ONLY IF PARAMETERS     63000019
.*                                      TO SGIFF0BT ARE INCORRECT       63900019
         AGO   .BTP      FIND THE LARGEST REMAINING NUMSEC REQUEST      64800019
.BTERR   ANOP                                                           65700019
.*  THIS WILL ONLY BE EXECUTED IF BAD PARAMETERS ARE PASSED REQUESTING  66600019
.*       MORE BUFFER THAN IS AVAILABLE.                                 67500019
&ZSTBL(&SAVE) SETA &NETZONE        ASSIGN ALL REMAINING BUFFER          68400019
&GUARTBL(&SAVE) SETA &NETZONE           SECTIONS TO THIS DEVICE         69300019
         AGO   .BTV2               GENERATE THE REST OF THE TABLE       70200019
.BTV1    ANOP                                                           71100019
&EXTRA   SETA  &TOTAVAL-&ZSTBL(1)-&ZSTBL(2)-&ZSTBL(3)-&ZSTBL(4)         72000019
         AIF   (&EXTRA LE 0).BTV2       BRANCH IF NO EXTRA SECTIONS     72900019
&ZSTBL(&NUMDEV) SETA &ZSTBL(&NUMDEV)+&EXTRA ASSIGN EXTRA TO LAST DEVICE 73800019
.BTV2    ANOP                                                           74700019
.*  GENERATE THE REST OF THE TABLE                                      75600019
&X1      SETA  1                        INITIALIZE INDEX                76500019
&TABDISP SETA  40                       SET INITIAL TABLE DISPLACEMENT  77400019
.BTV21   ANOP                                                           78300019
&ZONESZ  SETA  &ZSTBL(&X1)              SET ZONE SIZE IN CONSTANT       79200019
&TOTGUAR SETA  &GUARTBL(&X1)            SET GUARANTEED SEC. IN CONSTANT 80100019
.BTV22   ANOP                                                           81000019
         DC    H'0'                     TOTAL SECTIONS ASSIGNED         81900019
         DC    H'&TABDISP'              DEVICE TABLE DISPLACEMENT       82800019
         DC    H'&ZONESZ'               DEVICE ZONE SIZE                83700019
         DC    H'&TOTGUAR'              NUMBER OF GUARANTEED SECTIONS   84600019
         AIF   (T'&EXPSZE EQ 'O').BT10      CHECK FOR 2250-1            85500000
         AIF   (&X1 EQ 4).BT10          CHECK FOR LAST TABLE ENTRY      86400019
&TABDISP SETA  &TABDISP+&ZSTBL(&X1)     INCREMENT TABLE DISPLACEMENT    87300019
&X1      SETA  &X1+1                    INCREMENT INDEX                 88200019
         AIF   (&X1 LE &NUMDEV).BTV21   CONTINUE GENERATING TABLE       89100019
&TABDISP SETA  0              SET DISPL TO 0 FOR UNUSED PORTION OF TABL 90000019
         AGO   .BTV21         CONTINUE GENERATING TABLE                 90900019
.BT10    AIF   (&BFRSIZE EQ 0).BT11     CHECK FOR UNBUFFERED MOD 1      91800019
         DC    XL&TBLNGTH'00'           BUFFER SECTIONS TABLE           92700019
.BT11    ANOP                                                           93600019
         MEND                                                           94500019
