         MACRO                                                          01000000
&NAME    REDIRECT &MASK,&DEST=ORIGIN,&CONNECT=OR                        02000000
         GBLA  &IEDQZD,&IEDQZE(64),&IEDQZK                              03000000
         GBLB  &IEDQZA(64)                                              04000000
         LCLA  &BIT                                                     05000000
         LCLB  &NOGO,&ALG                                               06000000
         LCLC  &C                                                       07000000
.*             VERSION DATED NOVEMBER 16, 1970                          08000000
         SPACE                                                          09000000
&C       SETC  '&SYSECT'                                                10000000
         AIF   (NOT &IEDQZA(9)).TSOCHK                              TSO 11000000
         MNOTE 12,'***  IHB312  MUST FOLLOW STARTMH MACRO WITH TSOMH=NO*12000000
               '                                                        13000000
         AGO   .MEND                                                TSO 14000000
.TSOCHK  AIF   (&IEDQZA(5)).CHECK                                       15000000
         MNOTE 12,'***  IHB070  SEQUENCE ERROR-MUST FOLLOW INMSG OR OUT*17000000
               MSG MACRO'                                               18000000
&NOGO    SETB  1                                                        19000000
.CHECK   AIF   ('&MASK' EQ '').NXT                                      20000000
         IEDQMASK &MASK,5                                               21000000
         AIF   (&IEDQZA(24)).ERR                                        22000000
         AIF   ('&MASK'(1,1) NE 'X').NXT                                23000000
         AIF   ('&MASK'(2,1) EQ 'L' AND '&MASK'(3,1) NE '5').ERR        24000000
         AIF   ('&MASK'(2,1) NE 'L' AND K'&MASK NE 13).ERR              25000000
         AGO   .NXT                                                     26000000
.ERR     MNOTE 12,'***  IHB300  MASK OPERAND INVALID AS SPECIFIED'      27000000
&NOGO    SETB  1                                                        28000000
.NXT     AIF   ('&DEST' EQ '' OR '&DEST' EQ 'ORIGIN' OR '&DEST' EQ 'DES*29000000
               TIN').AND                                                30000000
         IEDQCHAR 8,&DEST                                               31000000
         AIF   (&IEDQZA(24)).DESTERR                                    32000000
         AIF   (&IEDQZD GT 8).DESTERR                                   32300000
         AIF   ('&DEST'(K'&DEST,1) EQ '''').AND                         32600000
         AIF   (('&DEST'(1,1) GE 'A' AND '&DEST'(1,1) LE 'Z') OR '&DEST*32900000
               '(1,1) EQ '$' OR '&DEST'(1,1) EQ '#' OR '&DEST'(1,1) EQ *33200000
               '@').AND                                                 33500000
.DESTERR MNOTE 12,'***  IHB300  DESTINATION OPERAND INVALID AS SPECIFIE*34000000
               D'                                                       35000000
&NOGO    SETB  1                                                        36000000
.AND     AIF   ('&CONNECT' EQ 'AND' OR '&CONNECT' EQ 'OR').OP           37000000
         MNOTE 12,'***  IHB300  CONNECT OPERAND INVALID AS SPECIFIED'   38000000
&NOGO    SETB  1                                                        39000000
.OP      AIF   (&NOGO).MEND                                             40000000
         AIF   ('&CONNECT' EQ 'OR').ORG                                 41000000
&ALG     SETB  1                                                        42000000
.ORG     AIF   ('&DEST' EQ '' OR '&DEST' EQ 'ORIGIN' OR '&DEST'(K'&DEST*43000000
               ,1) EQ '''').SMV                                         44000000
         IEDQVCON (7,31),(IEDQAZ,IEDQAE)                                45000000
         AGO   .TEST                                                    46000000
.SMV     IEDQVCON 7,IEDQAZ                                              47000000
.TEST    AIF   (NOT &IEDQZA(1)).PARM                                    48000000
&IEDQZA(18) SETB 1                                                      49000000
.PARM    AIF   ('&MASK' NE '0' AND '&MASK' NE 'X''0000000000''' AND '&M*50000000
               ASK' NE 'XL5''0000000000''' AND '&MASK' NE '').SKP       51000000
&BIT     SETA  1                                                        52000000
.SKP     ANOP                                                           53000000
&BIT     SETA  &BIT+2                                                   54000000
         AIF   (&BIT NE 1 AND &BIT NE 3).S                              55000000
&NAME    DC    AL1(&IEDQZE(7)+&BIT),AL1(8+&ALG),H'0'                    56000000
         AGO   .DEST                                                    57000000
.S       ANOP                                                           58000000
&NAME    DC    AL1(&IEDQZE(7)+&BIT),AL1(12+&ALG),AL1(0)                 59000000
         AIF   ('&MASK'(1,1) EQ 'X').XM                                 60000000
         DC    FL5'&MASK' .             ERROR MASK                      61000000
         AGO   .DEST                                                    62000000
.XM      DC    &MASK .                  ERROR MASK                      63000000
.DEST    AIF   ('&DEST' NE 'ORIGIN').OPT                                64000000
         DC    C'S',AL3(0) .            REDIRECT TO ORIGIN              65000000
         AGO   .MEND                                                    66000000
.OPT     AIF   ('&DEST' NE '' AND '&DEST' NE 'DESTIN').OPN              67000000
         DC    C'D',AL3(0) .            REDIRECT TO DESTINATION         68000000
         AGO   .MEND                                                    69000000
.OPN     AIF   ('&DEST'(K'&DEST,1) EQ '''').BUF                         70000000
         DC    C'O',AL1(&IEDQZE(31)),AL1(&DEST),AL1(16)                 71000000
         AGO   .MEND                                                    72000000
.BUF     DC    C'N' .                   REDIRECT PER SPECIFIED DEST     73000000
IEDQMISC CSECT                                                          74000000
         DC    AL1(&IEDQZD),&DEST .     DESTINATION                     75000000
&C       CSECT                                                          76000000
         DC    AL3(IEDQMISC+&IEDQZK)                                    77000000
&IEDQZK  SETA  &IEDQZK+1+&IEDQZD                                        78000000
.MEND    SPACE 2                                                        79000000
         MEND                                                           80000000
