         MACRO                                                          00020021
         SGIKJ0E2 &DST=,&SUBFD=                                         00040021
.* THIS SYSGEN MACRO IS USED TO GENERATED ALL DATA SET TYPES TO  A45714 00060021
.* BE RECOGNIZED BY THE EDIT COMMAND PROCESSOR, AND TO BUILD A   A45714 00080021
.* SUBFIELD FOR ANY DATA SET TYPE REQUIRING ONE.  THIS MACRO     A45714 00100021
.* PERFORMS THIS FUNCTION BY GENERATING THE PROPER IKJPARS       A45714 00120021
.* MACROS FOR ALL THE DATA SET TYPES PASSED BY THE 'DST'         A45714 00140021
.* PARAMETER.                                                    A45714 00160021
         LCLA  &I,&J,&K                                          A45714 00180021
         LCLB  &SW                                               A45714 00200021
.*A013300,321500-321597,352900,394700-394720,467700,470700       A45713 00220021
.*A477900-480713,480792,486500-494784,501500-502392              A45713 00240021
.*A704700-704797,749500-749597,750100,781700                     A45713 00260021
.*A781740-781780,787520-787540                                   A45713 00280021
.*C013000-013200,467200-467600,480772,480829,481800,482400       A45713 00300021
.*C483800,485200,485600,496000,496600                            A45713 00320021
.*D477600-479800,482600-483200,486200-494600,499400-499600       A45713 00340021
.*D500600-501200,501600-502200                                   A45713 00360021
.*A000300-000557,070100,070300,403100-405740,409100-412329       A45714 00380021
.*A421300-421380,503120-503969,578700-585900,587300,592300       A45714 00400021
.*A727300,731300-732376,759500,781724,781784-781926              A45714 00420021
.*C069800,579000-579200,706200,707000,711000,728600,729600       A45714 00440021
.*D402600-405600,408800-411600,502800-503000                     A45714 00460021
.*A412600-412800                                                 A50467 00466021
.*D412600-412800                                                 A50467 00472021
.*A282000-283200,342300,370040-370160,370860-370920             A59609  00473021
.*C292800,328400                                                A59609  00474021
.*D139000-141000,282000-284200                                  A59609  00475021
.*C 511000,511200                                                A59325 00476021
.*C744000                                                       SA61946 00478021
.*A744000-744392                                                 SM5064 00478421
.*D744000                                                        SM5064 00478821
.* C 204800, 205200, 265800, 266200                             SA73470 00479421
.* C 783800                                                     SA73985 00479721
.* C 783800                                                     SA76757 00479821
.* INITIALIZE TO NUMBER OF DATA SET TYPES PASSED.                A45714 00480021
&I       SETA  N'&DST                                            A45714 00500021
.* INITIALIZE LOOP CONTROL INDEX FOR 'DST' PARAMETER.            A45714 00520021
&J       SETA  1                                                 A45714 00540021
.* INITIALIZE INDEX FOR USER DATA SET TYPES.                     A45714 00560021
&K       SETA  1                                                 A45714 00580021
.* INITIALIZE SWITCH TO INDICATED IF SUBFIELD REQUIRED.          A45714 00600021
&SW      SETB  0                                                 A45714 00620021
.* CHECK IF ANY DSTYPES PASSED, IF NOT, ERROR HAS OCCURRED       A45714 00640021
         AIF   (&I GT 0).TAG0                                    A45714 00660021
         MNOTE 8,'DATA SET TYPE PARAMETERS MISSING.'             A45714 00680021
         MEXIT                                                   A45714 00700021
.TAG0    ANOP                                                    A45714 00720021
.* CHECK FOR TOO MANY DATA SET TYPES - INDEX 'I' GT 25.          A45714 00740021
         AIF   (&I LE 25).TAGX1                                  A45714 00760021
.* PROCESS ONLY FIRST 25 - SET INDEX 'I' TO 25.                  A45714 00780021
&I       SETA  25                                                A45714 00800021
.* CHECK IF ANY TRAILING 'DST' ENTRIES ARE NULL.                 A45714 00820021
.TAGX1   AIF   ('&DST(&I)' NE '').OUTX1                          A45714 00840021
.* IF NULL, DECREMENT INDEX 'I' TO NEXT ENTRY.                   A45714 00860021
&I       SETA  &I-1                                              A45714 00880021
         AGO   .TAGX1                                            A45714 00900021
.* INDEX 'I' EQUALS NO. OF NON-NULL 'DST' ENTRIES.               A45714 00920021
.OUTX1   ANOP                                                    A45714 00940021
BEIN     TITLE 'IKJEBEIN - INITIALIZATION MODULE - EDIT CP TSO/360'     00960021
IKJEBEIN CSECT                                                          00980021
*A 327000,327600                                                 A42958 01000021
*C 327400                                                        A42958 01020021
*A 264200-265600                                                 A42947 01040021
*C 399400-400400                                                 A42959 01060021
         ENTRY IKJEBEIN                                                 01080021
         ENTRY IKJEBIN0                                                 01100021
*********************************************************************** 01120021
*                                                                     * 01140021
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 01160021
*                                                                     * 01180021
* FUNCTION -- THIS ROUTINE IS ATTACHED BY THE TERMINAL MONITOR        * 01200021
*    PROGRAM (TMP) WHENEVER THE USER ENTERS THE EDIT COMMAND.         * 01220021
*    IKJEBEIN ISSUES A GETMAIN MACRO INSTRUCTION FOR THE EDIT         * 01240021
*    COMMUNICATION AREA, SCANS THE COMMAND BUFFER USING IKJPARS, AND  * 01260021
*    INITIALIZES THE COMMUNICATION AREA TO CONTAIN VALUES             * 01280021
*    REPRESENTING OPERANDS ON THE EDIT COMMAND.  IF THE USER SPECIFIES* 01300021
*    THAT THE DATA SET IS OLD, IKJEBEIN ALLOCATES IT USING IKJDAIR    * 01320021
*    AND VERIFIES THAT ITS ATTRIBUTES ARE CONSISTENT WITH THE OTHER   * 01340021
*    OPERANDS SPECIFIED ON THE COMMAND.  WHEN IKJEBEIN COMPLETES      * 01360021
*    SUCCESSFULLY, CONTROL IS PASSED TO THE EDIT MAIN CONTROLLER,     * 01380021
*    IKJEBEMA, VIA AN XCTL MACRO INSTRUCTION.                         * 01400021
*                                                                     * 01420021
* ENTRY POINTS --                                                     * 01440021
*         IKJEBEIN - AFTER BEING ATTACHED BY THE TMP WHEN THE EDIT    * 01460021
*                    COMMAND IS ENTERED AT THE TERMINAL.              * 01480021
*                                                                     * 01500021
* INPUT --                                                            * 01520021
*    REGISTER ONE (1) CONTAINS A POINTER TO THE COMMAND PROCESSOR     * 01540021
*    PARAMETER LIST (CPPL).                                           * 01560021
*                                                                     * 01580021
* OUTPUT --                                                           * 01600021
*    REGISTER FIFTEEN (15) CONTAINS A RETURN CODE INDICATING WHETHER  * 01620021
*    EDIT COMPLETED SUCCESSFULLY OR NOT.  RETURN CODES ARE --         * 01640021
*                                                                     * 01660021
*    00 - SUCCESSFUL COMPLETION.                                      * 01680021
*    12 - UNSUCCESSFUL COMPLETION.                                    * 01700021
*                                                                     * 01720021
* EXTERNAL REFERENCES --                                              * 01740021
*         IKJDAIR  - SERVICE ROUTINE USED TO DYNAMICALLY ALLOCATE     * 01760021
*                    THE EDIT DATA SET                                * 01780021
*         IKJEBECO - INITIAL COPY ROUTINE - INVOKED TO COPY AN OLD    * 01800021
*                    DATA SET TO THE UTILITY DATA SET                 * 01820021
*         IKJEBEMS - MESSAGE SELECTION ROUTINE LOADED BY              * 01840021
*                    THIS ROUTINE                                     * 01860021
*         IKJEBEPS - PROCESSOR TABLE SEARCH ROUTINE LOADED BY         * 01880021
*                    THIS ROUTINE                                     * 01900021
*         IKJEBEUI - UTILITY INITIALIZATION ROUTINE - USED TO         * 01920021
*                    INITIALIZE THE EDIT ACCESS METHOD WHEN THE USER  * 01940021
*                    HAS SPECIFIED A NEW DATA SET                     * 01960021
*         IKJEBEUT - UTILITY INTERFACE ROUTINE - LOADED BY THIS       * 01980021
*                    ROUTINE PRIOR TO THE COPY OF THE EDIT DATA SET   * 02000021
*                    AND DELETED WHEN THE COPY IS COMPLETE            * 02020021
*         IKJEBIN1 - EDIT COMMAND PCL (PARAMETER CONTROL LIST)        * 02040021
*         IKJEBIN2 - PCL FOR NEW/OLD PROMPT                           * 02060021
*         IKJEBIN3 - INITIAL MESSAGE PROCESSING ROUTINE               * 02080021
*         IKJEBIN4 - IKJPARS NUMERIC SUBFIELD VALIDITY CHECK EXIT     * 02100021
*         IKJEBIN5 - DATA SET TYPE PROMPTING ROUTINE                  * 02120021
*         IKJEBIN7 - PARTIALLY QUALIFIED DSNAME PROCESSING ROUTINE    * 02140021
*         IKJEBIN8 - OPERAND VALIDITY CHECKING AND CONVERSION         * 02160021
*                    ROUTINE                                          * 02180021
*         IKJPARS  - SERVICE ROUTINE USED TO SYNTAX CHECK THE EDIT    * 02200021
*                    COMMAND AND RESPONSES TO NEW/OLD PROMPT     A45713 02220021
*         IKJPTGT  - SERVICE ROUTINE USED TO PROMPT FOR DATA SET A45713 02240021
*                    TYPE                                        A45713 02260021
*                                                                     * 02280021
*    MACROS USED --                                                   * 02300021
*                                                                     * 02320021
*         BLDL     - BUILD LIST OF DIRECTORY INFORMATION              * 02340021
*         CALL     - PASS CONTROL TO LOADED PROGRAM                   * 02360021
*         CAMLST   - BUILD CONTROL LIST FOR OBTAIN MACRO INSTRUCTION  * 02380021
*         CVT      - DEFINE THE COMMUNICATIONS VECTOR TABLE (CVT)     * 02400021
*         DCBD     - DEFINE THE DATA CONTROL BLOCK (DCB)              * 02420021
*         DELETE   - DELETE COPY OF LOADED PROGRAM FROM MAIN STORAGE  * 02440021
*         DEVTYPE  - OBTAIN DEVICE DEPENDENT INFORMATION              * 02460021
*         FREEMAIN - FREE CORE OBTAINED VIA GETMAIN MACRO INSTRUCTION * 02480021
*         GETMAIN  - GET CORE FOR EDIT COMMUNICATION AREA             * 02500021
*         IECSDSL1 - DEFINE THE DATA SET CONTROL BLOCK (DSCB) FORMAT 1* 02520021
*         IEFUCBOB - DEFINE THE UNIT CONTROL BLOCK (UCB)              * 02540021
*         IEFTIOT1 - DEFINE THE TASK INPUT/OUTPUT TABLE (TIOT)        * 02560021
*         IKJCPPL  - DEFINE THE COMMAND PROCESSOR PARAMETER           * 02580021
*                    LIST (CPPL)                                      * 02600021
*         IKJDFPL  - DEFINE THE DEFAULT SERVICE ROUTINE PARAMETER LIST* 02620021
*         IKJDFPB  - DEFINE THE DEFAULT SERVICE ROUTINE PARAMETER     * 02640021
*                    BLOCK                                            * 02660021
*         IKJEBECA - DEFINE EDIT COMMUNICATION AREA                   * 02680021
*         IKJEBESH - PASS CONTROL TO EDIT SERVICE ROUTINES            * 02700021
*         IKJECT   - DEFINE THE ENVIRONMENT CONTROL TABLE (ECT)       * 02720021
*         IKJENDP  - END IKJPARS PCL                                  * 02740021
*         IKJIDENT - DEFINE POSITIONAL OPERAND TO IKJPARS             * 02760021
*         IKJKEYWD - DEFINE KEYWORD OPERAND TO IKJPARS                * 02780021
*         IKJNAME  - DEFINE VALID KEYWORDS FOR KEYWORD OPERAND        * 02800021
*                    TO IKJPARS                                       * 02820021
*         IKJPARM  - BEGIN IKJPARS PCL                                * 02840021
*         IKJPOSIT - DEFINE POSITIONAL OPERAND TO IKJPARS             * 02860021
*         IKJPPL   - DEFINE THE IKJPARS PARAMETER LIST (PPL)          * 02880021
*         IKJPSCB  - DEFINE THE PROTECTED STEP CONTROL BLOCK (PSCB)   * 02900021
*         IKJRLSA  - RELEASE IKJPARS PDL                              * 02920021
*         IKJSUBF  - DEFINE SUBFIELD OF AN OPERAND TO IKJPARS         * 02940021
*         IKJTCB   - DEFINE THE TASK CONTROL BLOCK (TCB)              * 02960021
*         LINK     - LOAD AND PASS CONTROL TO EXTERNAL PROGRAM        * 02980021
*         LOAD     - LOAD PROGRAM INTO MAIN STORAGE                   * 03000021
*         OBTAIN   - READ DSCB INTO MAIN STORAGE                      * 03020021
*         RETURN   - RESTORE CALLERS REGISTERS BEFORE RETURN          * 03040021
*         SAVE     - SAVE REGISTERS ON INITIAL ENTRY                  * 03060021
*         XCTL     - TRANSFER CONTROL TO MAIN CONTROLLER              * 03080021
*                                                                     * 03100021
* EXITS, NORMAL --                                                    * 03120021
*    WHEN IKJEBEIN COMPLETES SUCCESSFULLY, CONTROL IS PASSED TO THE   * 03140021
*    MAIN CONTROLLER ROUTINE, IKJEBEMA, VIA AN XCTL MACRO INSTRUCTION.* 03160021
*                                                                     * 03180021
* EXITS, ERROR --                                                     * 03200021
*    WHEN IKJEBEIN ENCOUNTERS ANY CONDITION WHICH DOES NOT ALLOW      * 03220021
*    IT TO COMPLETE SUCCESSFULLY, CONTROL IS RETURNED TO THE TMP      * 03240021
*    BY BRANCHING ON REGISTER FOURTEEN (14).                          * 03260021
*                                                                     * 03280021
* TABLES/WORK AREAS --                                                * 03300021
*                                                                     * 03320021
*    THE EDIT COMMUNICATION AREA IS BUILT AND INITIALIZED BY          * 03340021
*    IKJEBEIN.  IKJEBEIN WILL INITIALIZE THE FULLY QUALIFIED DATA SET * 03360021
*    NAME, DATA SET TYPE, DATA SET DEPENDENT INFORMATION, LRECL,      * 03380021
*    BLKSIZE, SEQUENCE NUMBER FIELD DESCRIPTION, SYNTAX CHECKING      * 03400021
*    INFORMATION, AND WILL INDICATE WHETHER DATA IS TO BE MAINTAINED  * 03420021
*    AS ENTERED OR TRANSLATED TO UPPER CASE ALPHABETICS.              * 03440021
*                                                                     * 03460021
*    THE EDIT COMMAND PDL (PARAMETER DESCRIPTOR LIST) IS RETURNED     * 03480021
*    BY IKJPARS AFTER SCANNING THE EDIT COMMAND.  IT ALLOWS IKJEBEIN  * 03500021
*    TO ADDRESS COMMAND OPERANDS FOR PURPOSES OF CONVERSION,          * 03520021
*    INITIALIZATION, AND VALIDATION.  IT IS ALWAYS FREEMAINED BEFORE  * 03540021
*    IKJEBEIN RELINQUISHES CONTROL.                                   * 03560021
*                                                                     * 03580021
* ATTRIBUTES --                                                       * 03600021
*    REFRESHABLE, ENABLED, NON-PRIVILEGED                             * 03620021
*                                                                     * 03640021
* CHARACTER CODE DEPENDENCY --                                        * 03660021
*    THE MAIN CSECT OF THE EDIT INITIALIZATION IS NOT CHARACTER       * 03680021
*    CODE DEPENDENT.                                                  * 03700021
*                                                                     * 03720021
* NOTES -- NONE.                                                      * 03740021
*                                                                     * 03760021
*********************************************************************** 03780021
         EJECT                                                          03800021
*********************************************************************** 03820021
*                                                                     * 03840021
*   GENERAL PURPOSE REGISTER EQUATES FOR THIS ROUTINE.                * 03860021
*                                                                     * 03880021
*********************************************************************** 03900021
ENTCDREG EQU   0              REGISTER USED TO CONTAIN ENTRY CODE       03920021
PARMREG0 EQU   0              PARAMETER REGISTER.                       03940021
PARMREG1 EQU   1              INPUT - ADDRESS OF COMMAND PROCESSOR      03960021
*                                  PARAMETER LIST.                      03980021
*                             OUTPUT - ADDRESS OF THE EDIT              04000021
*                                  COMMUNICATION AREA.                  04020021
*                             GENERAL USAGE IN THIS MODULE -            04040021
*                                  ADDRESS OF A PARAMETER LIST TO       04060021
*                                  BE PASSED TO A ROUTINE INVOKED       04080021
*                                  BY IKJEBEIN.                         04100021
INDEXREG EQU   2              REGISTER USED AS INDEX INTO TABLE         04120021
*                                  OF DATA SET TYPES.                   04140021
LENREG   EQU   2              REGISTER USED TO CONTAIN LENGTH FOR       04160021
*                                  CURRENT OPERATION.                   04180021
UPTREG   EQU   2              ADDRESS OF UPT.                           04200021
COUNTREG EQU   3              LOOP CONTROL COUNTER.                     04220021
ECTREG   EQU   3              ADDRESS OF ECT.                           04240021
FLAGREG  EQU   3              FLAG BYTE USED IN IMMEDIATE               04260021
*                                  INSTRUCTIONS.                        04280021
SIZEREG  EQU   3              SIZE OF AREA BEING INITIALIZED            04300021
*                                  DURING CURRENT OPERATION.            04320021
TABPTREG EQU   3              ADDRESS OF CURRENT LOCATION IN            04340021
*                                  TABLE BEING REFERENCED.              04360021
AREAREG  EQU   4              ADDRESS OF CURRENT POSITION IN AREA       04380021
*                                  BEING INITIALIZED.                   04400021
QUALREG  EQU   4              ADDRESS OF DATA SET QUALIFIER.            04420021
*                                  PROCESSED.                           04440021
DSNAMREG EQU   5              ADDRESS OF DATA SET NAME.                 04460021
ECBREG   EQU   5              ADDRESS OF ATTENTION ECB.                 04480021
ERR1REG  EQU   5              REGISTER USED FOR RELATIVE FIRST          04500021
*                                  LEVEL MESSAGE NUMBER.                04520021
STRTNREG EQU   5              START COLUMN NUMBER FOR NUM CHECK.        04540021
ERR2REG  EQU   6              REGISTER USED FOR RELATIVE SECOND         04560021
*                                  LEVEL MESSAGE NUMBER.                04580021
PCLREG   EQU   6              ADDRESS OF PCL FOR IKJPARSE.              04600021
TMPREG   EQU   6              ADDRESS OF TMP PARAMETER LIST.            04620021
TMPCDREG EQU   6              REGISTER USED TO TEST RETURN CODES        04640021
*                                  FROM INVOKED ROUTINES.               04660021
TYPNOREG EQU   6              REGISTER USED AS COUNTER FOR NUMBER       04680021
*                                  OF ENTRIES REMAINING IN DATA         04700021
*                                  SET TYPE.                            04720021
DATA1REG EQU   7              REGISTER USED TO TRANSMIT DATA TO         04740021
*                                  IKJEBEIA FOR MESSAGE INSERTION.      04760021
PDLREG   EQU   7              ADDRESS OF AREA FOR IKJPARSE TO           04780021
*                                  RETURN PDL ADDRESS.                  04800021
DATA2REG EQU   8              REGISTER USED TO TRANSMIT DATA TO         04820021
*                                  IKJEBEIA FOR MESSAGE INSERTION.      04840021
PASSREG  EQU   8              ADDRESS OF PSCB.                          04860021
SRRTNREG EQU   8              REGISTER USED TO LINK TO INTERNAL         04880021
*                                  SUBROUTINES.                         04900021
COMMREG  EQU   9              BASE REGISTER USED TO ADDRESS THE         04920021
*                                  COMMUNICATION AREA.                  04940021
BASEREG  EQU   11             BASE REGISTER FOR THIS CSECT              04960021
DATAREG  EQU   12             BASE REGISTER USED TO ADDRESS THE         04980021
*                                  INPUT PARAMETER LIST.                05000021
SAVEREG  EQU   13             ADDRESS OF SAVE AREA.                     05020021
RETREG   EQU   14             ADDRESS OF RETURN POINT IN CALLING        05040021
*                                  MODULE.                              05060021
EPLOCREG EQU   15             ENTRY POINT ADDRESS OF MODULE TO BE       05080021
*                                  INVOKED.                             05100021
RETCDREG EQU   15             CONDITION CODE RETURNED TO CALLING        05120021
*                                  ROUTINE.                             05140021
         EJECT                                                          05160021
*********************************************************************** 05180021
*                                                                     * 05200021
*   PROLOG                                                            * 05220021
*                                                                     * 05240021
*********************************************************************** 05260021
         SAVE  (14,12),,*     SAVE ENTRY REGISTERS.                     05280021
         BALR  BASEREG,PARMREG0 ESTABLISH A BASE REGISTER AND           05300021
         USING *,BASEREG           ADDRESSABILITY FOR THIS CSECT.       05320021
         LR    DATAREG,PARMREG1 SAVE ADDRESS OF INPUT PARAMETERS.       05340021
         GETMAIN R,LV=CADLEN,SP=SUBPOOL GET SAVE AND WORK AREA.         05360021
         LR    COMMREG,PARMREG1 ADDRESS OF COMMUNICATION AREA.          05380021
         EJECT                                                          05400021
*********************************************************************** 05480021
*                                                                     * 05500021
*   ESTABLISH ADDRESSABILITY TO COMMUNICATION AREA AND INITIALIZE     * 05520021
*   TO ZERO.  INITIALIZE ADDRESS TO TMP PARAMETER LIST.               * 05540021
*                                                                     * 05560021
*********************************************************************** 05580021
         USING IKJEBECA,COMMREG  ESTABLISH ADDRESSABILITY TO            05600021
*                                  COMMUNICATION AREA.                  05620021
         LA    LENREG,INF255  NUMBER OF BYTES SET TO ZERO EACH          05640021
*                                  TIME THROUGH LOOP BUT LAST.          05660021
         LA    SIZEREG,CADLEN SIZE OF COMMUNICATION AREA.               05680021
         BCTR  SIZEREG,PARMREG0 REDUCE SIZE OF COMMUNICATION AREA       05700021
*                                  BY 1.                                05720021
         LR    AREAREG,COMMREG COPY ADDRESS OF AREA TO BE SET           05740021
*                                  TO ZERO.                             05760021
IN001010 EQU   *                                                        05780021
         CR    SIZEREG,LENREG DETERMINE IF SIZE GREATER THAN 255.       05800021
         BNH   IN001020       IF NOT, BRANCH TO SET REMAINING           05820021
*                                  AREA TO ZERO.                        05840021
         EX    LENREG,INXC001 ZERO 255 BYTES.                           05860021
         AR    AREAREG,LENREG UPDATE POINTER TO NEXT SECTION TO         05880021
*                                  BE SET TO ZERO.                      05900021
         SR    SIZEREG,LENREG DECREMENT NUMBER OF BYTES TO BE           05920021
*                                  ZEROED BY NUMBER JUST SET TO         05940021
*                                  ZERO.                                05960021
         B     IN001010       BRANCH TO CHECK IF DONE.                  05980021
IN001020 EQU   *                                                        06000021
         EX    SIZEREG,INXC001 ZERO NUMBER OF BYTES REMAINING.          06020021
         LA    RETCDREG,CASVAREA ADDRESS OF SAVE AREA IN THE            06040021
*                                  COMMUNICATION AREA.                  06060021
         ST    SAVEREG,D4(,RETCDREG) CROSS CHAIN PREVIOUS AND           06080021
         ST    RETCDREG,D8(,SAVEREG) CURRENT SAVE AREAS AND             06100021
         LR    SAVEREG,RETCDREG    INITIALIZE REG13 TO POINT TO         06120021
*                                  CURRENT SAVE AREA.                   06140021
         LA    RETCDREG,D72(,RETCDREG) COMPUTE ADDRESS OF NEXT          06160021
         ST    RETCDREG,CANXTSVA   LOWER SAVE AREA AND SAVE             06180021
*                                  IN COMMUNICATION AREA.               06200021
         ST    DATAREG,CAPTTMP SAVE ADDRESS TO INPUT PARAMETER          06220021
*                                  LIST FROM TMP.                       06240021
         EJECT                                                          06260021
*********************************************************************** 06280021
*                                                                     * 06300021
*   LOAD IKJEBEMS (MESSAGE SELECTION ROUTINE).  SAVE ENTRY POINT      * 06320021
*   ADDRESS IN THE COMMUNICATION AREA.                                * 06340021
*                                                                     * 06360021
*********************************************************************** 06380021
         SPACE 2                                                        06400021
         LOAD  EP=IKJEBEMS    LOAD IKJEBEMS.                            06420021
         ST    PARMREG0,CAPTMS SAVE ENTRY POINT ADDRESS IN THE          06440021
*                                  COMMUNICATION AREA.                  06460021
         SPACE 2                                                        06480021
         EJECT                                                          06500021
*********************************************************************** 06520021
*                                                                     * 06540021
*   BUILD MODE MESSAGE INSERTION IN THE COMMUNICATION AREA.  THE      * 06560021
*   INSERTION RECORD CONTAINS THE NAME OF THE EDIT COMMAND AS THE     * 06580021
*   USER ENTERED IT.                                                  * 06600021
*                                                                     * 06620021
*********************************************************************** 06640021
         L     AREAREG,CAPTTMP ADDRESS OF CPPL.                         06660021
         L     AREAREG,(CPPLECT-CPPL)(,AREAREG) ADDRESS OF ECT.         06680021
         MVC   CAMODETX+D1(L'ECTPCMD),(ECTPCMD-ECT)(AREAREG)            06700021
*                             MOVE COMMAND NAME TO INSERTION            06720021
*                                  RECORD.                              06740021
         MVI   CAMODETX,CHRBLANK MOVE IN BLANK BEFORE COMMAND           06760021
*                                  NAME.                                06780021
         LA    LENREG,(L'ECTPCMD+D1)(,D0) LOOP CONTROL COUNTER.         06800021
         LA    SIZEREG,CAMODETX+(L'ECTPCMD) ADDRESS OF LAST             06820021
*                                  CHARACTER IN COMMAND NAME.           06840021
IN000010 EQU   *                                                        06860021
         CLI   D0(SIZEREG),CHRBLANK CHECK FOR BLANK.                    06880021
         BNE   IN000020       IF NOT A BLANK, ALL TRAILING BLANKS       06900021
*                                  HAVE BEEN SUPPRESSED.                06920021
         BCTR  SIZEREG,D0     BACK POINTER UP ONE CHARACTER.            06940021
         BCT   LENREG,IN000010 REDUCE COUNTER BY ONE AND BRANCH         06960021
*                                  TO CHECK NEXT BYTE.                  06980021
IN000020 EQU   *                                                        07000021
         LA    LENREG,D4(,LENREG) COMPUTE LENGTH OF INSERTION           07020021
         STH   LENREG,CAMODELN AND SAVE IN CONTROL FIELD.               07040021
         LA    LENREG,D1(,D0) INITIALIZE NUMBER OF SEGMENTS IN          07060021
         ST    LENREG,CAMODEIS     MODE MESSAGE.                        07080021
         LA    AREAREG,CAMODELN INITIALIZE ADDRESS OF MODE              07100021
         ST    AREAREG,CAMODEPT    MESSAGE IN OUTPUT DESCRIPTOR.        07120021
         EJECT                                                          07140021
*********************************************************************** 07160021
*                                                                     * 07180021
*   CALL IKJPARS TO SYNTAX CHECK THE EDIT COMMAND.                    * 07200021
*                                                                     * 07220021
*   INITIALIZE THE FIRST THREE WORDS OF THE SERVICE ROUTINE PARAMETER * 07240021
*   LIST (CAPTUPT, CAPTECT, CAPTECT) TO POINT TO THE UPT, ECT, AND    * 07260021
*   THE EDIT ATTENTION ECB.                                           * 07280021
*                                                                     * 07300021
*   INITIALIZE THE SEVEN WORD PARAMETER LIST FOR IKJPARS.  LINK TO    * 07320021
*   IKJPARS TO SYNTAX CHECK THE EDIT COMMAND AND TO BUILD THE         * 07340021
*   PARAMETER DESCRIPTOR LIST.                                        * 07360021
*                                                                     * 07380021
*********************************************************************** 07400021
         L     DATAREG,CAPTTMP ADDRESS OF PARAMETER LIST PASSED         07420021
*                                  BY TMP.                              07440021
         L     UPTREG,(CPPLUPT-CPPL)(,DATAREG) GET ADDRESS              07460021
*                                  OF UPT.                              07480021
         L     ECTREG,(CPPLECT-CPPL)(,DATAREG) GET ADDRESS              07500021
*                                  OF ECT.                              07520021
         LA    ECBREG,CAATTN  GET ADDRESS OF ATTENTION ECB.             07540021
         L     PCLREG,INPTPCL ADDRESS OF PCL FOR IKJPARSE.              07560021
         L     AREAREG,(CPPLCBUF-CPPL)(,DATAREG) ADDRESS OF             07580021
*                                  EDIT COMMAND.                        07600021
         LA    PDLREG,CATMPLST+(PPLANS-PPL) ADDRESS OF AREA IN          07620021
         LA    PDLREG,CAPTPRSD SPECIFY ADDRESS OF AREA IN               07640021
*                                  WHICH IKJPARS RETURNS THE            07660021
*                                  POINTER TO THE PDL.                  07680021
         XC    CATMPLST+(PPLPCL-PPL)(PPLUWA-PPLPCL+L'PPLUWA),CATMPLST+(X07700021
               PPLPCL-PPL)    ZERO IKJPARS PORTION OF PARAMETER         07720021
*                                  LIST.                                07740021
         LINK  EP=IKJPARS,PARAM=((UPTREG),(ECTREG),(ECBREG),           X07760021
               (PCLREG),(PDLREG),(AREAREG),(COMMREG)),                 X07780021
               MF=(E,CATMPLST) LINK TO IKJPARS TO SCAN COMMAND.         07800021
IN001060 EQU   *                                                        07820021
         B     IN001060+D4(RETCDREG) IKJPARS RETURN CODE BRANCH         07840021
*                                  TABLE.                               07860021
         B     IN001070       00 - SUCCESSFUL COMPLETION.               07880021
         B     INEXIT2        04 - COMMAND NOT COMPLETE, COULD          07900021
*                                  NOT PROMPT, RETURN.                  07920021
         B     INEXIT2        08 - ATTENTION ISSUED, RETURN.            07940021
         B     IN001065       12 - INVALID PARAMETERS.                  07960021
         B     IN001062       16 - NO MAIN STORAGE AVAILABLE --  A45714 07980021
         B     IN001065       20 - ERROR IN VALID. CHK EXIT.     A45714 08000021
*                                  PUT ERROR MESSAGE AND RETURN.        08020021
         SPACE 2                                                        08040021
IN001062 EQU   *                                                 A45714 08060021
*********************************************************************** 08080021
*                                                                     * 08100021
*   ISSUE NO MAIN STORAGE AVAILABLE MESSAGE AND TERMINATE.            * 08120021
*                                                                     * 08140021
*********************************************************************** 08160021
         LA    ERR1REG,INERROR1 RELATIVE ERROR TO BE PROCESSED.         08180021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            08200021
*                                  ERROR MESSAGE AND RETURN.            08220021
         SPACE 2                                                        08240021
*********************************************************************** 08260021
*                                                                     * 08280021
*   ISSUE COMMAND SYSTEM ERROR MESSAGE AND TERMINATE.                 * 08300021
*                                                                     * 08320021
*********************************************************************** 08340021
IN001065 EQU   *                                                        08360021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.         08380021
         LR    DATA2REG,RETCDREG SAVE RETURN CODE FOR MESSAGE.          08400021
         O     DATA2REG,INPARS INDICATE ROUTINE NAME AS IKJPARS.        08420021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            08440021
*                                  ERROR MESSAGE AND RETURN.            08460021
         SPACE 2                                                        08480021
IN001070 EQU   *                                                        08500021
         L     DATAREG,CAPTPRSD ADDRESS OF EDIT PDL.                    08520021
         USING INECMNDD,DATAREG    AND ESTABLISH ADDRESSABILITY         08540021
*                                  TO IT.                               08560021
         EJECT                                                          08580021
*********************************************************************** 08600021
*                                                                     * 08620021
*   DETERMINE IF DATA SET TYPE SPECIFIED ON THE EDIT COMMAND.  IF     * 08640021
*   DATA SET TYPE NOT SPECIFIED, BRANCH TO PROCESS DATA SET NAME.     * 08660021
*                                                                     * 08680021
*   WHEN DATA SET TYPE IS SPECIFIED, INITIALIZE THE DATA SET TYPE     * 08700021
*   FIELD IN THE COMMUNICATION AREA USING A DATA SET TYPE FROM        * 08720021
*   INDSTAB LOCATED BY THE KEYWORD NUMBER RETURNED BY IKJPARS.        * 08740021
*   AFTER THE DATA SET TYPE IS INITIALIZED, LOAD AND CALL IKJEBEPS    * 08760021
*   TO VERIFY THE DATA SET TYPE AND RETURN ALL DATA SET DEPENDENT     * 08780021
*   INFORMATION.                                                      * 08800021
*                                                                     * 08820021
*********************************************************************** 08840021
         CLC   INDSTYPE(L'INNOKEYW),INNOKEYW DETERMINE IF DATA          08860021
*                                  SET TYPE SPECIFIED ON COMMAND.       08880021
         BE    IN001075       IF NOT SPECIFIED, BRANCH TO PROCESS       08900021
*                                  DATA SET NAME.                       08920021
         LH    INDEXREG,INDSTYPE OBTAIN KEYWORD NUMBER RETURNED         08940021
*                                  BY IKJPARS TO BE USED AS             08960021
*                                  INDEX TO DATA SET TYPE TABLE.        08980021
         SLL   INDEXREG,D3(D0) MULTIPLY INDEX BY 8.                     09000021
         LA    AREAREG,IKJEBIN0-D8(INDEXREG) OBTAIN ADDRESS OF          09020021
*                                  DATA SET TYPE.                       09040021
         MVC   CADSTYPE(INDSTELN),D0(AREAREG) MOVE DATA SET TYPE        09060021
*                                  TO COMMUNICATION AREA TO BE          09080021
*                                  USED AS INPUT PARAMETER TO           09100021
*                                  IKJEBEPS.                            09120021
         LOAD  EP=IKJEBEPS    LOAD PROCESSOR TABLE SEARCH ROUTINE       09140021
         LR    EPLOCREG,PARMREG0 COPY ENTRY POINT ADDRESS.              09160021
         CALL  (15),,MF=(E,CADSTYPE) BRANCH TO IKJEBEPS.                09180021
         LTR   RETCDREG,RETCDREG TEST FOR SUCCESSFUL COMPLETION.        09200021
         BNZ   IN001071       IF RETURN CODE = 4, BRANCH TO PUT         09220021
*                                  ERROR MESSAGE AND RETURN.            09240021
         MVC   CADSTYPE(CAPDEND-CAPD),D0(PARMREG1) MOVE DATA SET        09260021
*                                  DEPENDENT INFORMATION TO THE         09280021
*                                  COMMUNICATION AREA.                  09300021
         DELETE EP=IKJEBEPS   DELETE LOAD MODULE FROM CORE.             09320021
         B     IN001075       BRANCH TO PROCESS DATA SET NAME.          09340021
         SPACE 2                                                        09360021
*********************************************************************** 09380021
*                                                                     * 09400021
*   ISSUE COMMAND SYSTEM ERROR MESSAGE.                               * 09420021
*                                                                     * 09440021
*********************************************************************** 09460021
IN001071 EQU   *                                                        09480021
         DELETE EP=IKJEBEPS   DELETE PROCESSOR SEARCH ROUTINE.          09500021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.         09520021
         LA    DATA2REG,ININS004 ADDRESS OF INSERTION LIST FOR          09540021
*                                  SECOND LEVEL MESSAGE.                09560021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            09580021
*                                  ERROR MESSAGE AND TERMINATE.         09600021
         EJECT                                                          09620021
*********************************************************************** 09640021
*                                                                     * 09660021
*   DATA SET NAME PROCESSING.                                         * 09680021
*                                                                     * 09700021
*   UPON RETURN FROM IKJPARS, DETERMINE IF DATA SET NAME WAS ENTERED  * 09720021
*   FULLY QUALIFIED.  IF NOT FULLY QUALIFIED, BRANCH TO FULLY         * 09740021
*   QUALIFY THE DATA SET NAME.  WHEN FULLY QUALIFIED, DETERMINE IF    * 09760021
*   USER SPECIFIED A DATA SET TYPE.  IF A DATA SET TYPE WAS NOT       * 09780021
*   ENTERED, USE PARSE TO PROMPT FOR THE DATA SET TYPE.               * 09800021
*                                                                     * 09820021
*********************************************************************** 09840021
IN001075 EQU   *                                                        09860021
         MVI   CAEDDSN,CHRBLANK INITIALIZE DATA SET NAME, MEMBER        09880021
         MVC   CAEDDSN+D1(CAEDPSWD+L'CAEDPSWD-CAEDDSN-D1),CAEDDSN       09900021
*                                  NAME, DDNAME AND PASSWORD            09920021
*                                  FIELDS TO CHARACTER BLANKS.          09940021
         LH    LENREG,INDSN+INDSNLL GET DATA SET NAME LENGTH.           09960021
         STH   LENREG,CAEDDSNL SAVE LENGTH OF DATA SET NAME.            09980021
         LTR   LENREG,LENREG DETERMINE IF MEMBER NAME ONLY WAS          10000021
*                                  SPECIFIED.                           10020021
         BZ    IN001077       IF SO, BYPASS MOVE OF DSNAME TO           10040021
*                                  COMMUNICATION AREA.                  10060021
         L     AREAREG,INDSN+INDSNPT GET POINTER TO DATA SET NAME       10080021
         BCTR  LENREG,PARMREG0 REDUCE DATA SET NAME BY 1.               10100021
         EX    LENREG,INMV003 MOVE DATA SET NAME TO COMMUNICATION       10120021
*                                  AREA.                                10140021
         TM    INDSN+INMEMFLG,INOPRNDO DETERMINE IF MEMBER NAME         10160021
*                                  SUPPLIED.                            10180021
         BZ    IN001080       IF NOT, BRANCH TO CHECK PASSWORD.         10200021
IN001077 EQU   *                                                        10220021
         LH    LENREG,INDSN+INMEMLL GET LENGTH OF MEMBER NAME.          10240021
         L     AREAREG,INDSN+INMEMPT GET ADDRESS OF MEMBER NAME.        10260021
         BCTR  LENREG,PARMREG0 REDUCE MEMBER NAME LENGTH BY 1.          10280021
         EX    LENREG,INMV004 MOVE MEMBER NAME TO COMMUNICATION         10300021
*                                  AREA.                                10320021
         OI    CAEDFLAG,CAEDDSOR INDICATE DSORG OF PO.                  10340021
IN001080 EQU   *                                                        10360021
         TM    INDSN+INPSWFLG,INOPRNDO DETERMINE IF PASSWORD            10380021
*                                  SPECIFIED.                           10400021
         BZ    IN001090       IF NOT, BRANCH TO CHECK DATA SET          10420021
*                                  TYPE.                                10440021
         LH    LENREG,INDSN+INPSWLL GET LENGTH OF PASSWORD.             10460021
         L     AREAREG,INDSN+INPSWPT GET ADDRESS OF PASSWORD.           10480021
         BCTR  LENREG,PARMREG0 REDUCE LENGTH OF PASSWORD BY 1.          10500021
         EX    LENREG,INMV005 MOVE PASSWORD TO COMMUNICATION            10520021
*                                  AREA.                                10540021
IN001090 EQU   *                                                        10560021
         TM    INDSN+INDSNFLG,INFULLQ DETERMINE IF DATA SET NAME        10580021
*                                  WAS ENTERED FULLY QUALIFIED.         10600021
         BO    IN001095       IF FULLY QUALIFIED, BRANCH TO CHECK       10620021
*                                  IF DATA SET TYPE SPECIFIED.          10640021
*   IF DATA SET NAME IS NOT FULLY QUALIFIED, CALL IKJEBEID TO           10660021
*   FULLY QUALIFY.                                                      10680021
         CALL  IKJEBIN7,((COMMREG),(DATAREG)),MF=(E,INSVCRTN)          X10700021
                                   FULLY QUALIFY DATA SET NAME.         10720021
IN001093 EQU   *                                                        10740021
         B     IN001093+D4(RETCDREG) RETURN CODE BRANCH TABLE.          10760021
         B     IN002000       00 - SUCCESSFUL.                          10780021
         B     INEXIT1        04 - UNSUCCESSFUL. (TERMINATE EDIT.)      10800021
IN001095 EQU   *                                                        10820021
         CLI   CADSCODE,D0    DETERMINE IF DATA SET TYPE WAS            10840021
         BNE   IN002000            ENTERED ON THE EDIT COMMAND.         10860021
*                                  IF SPECIFIED, BRANCH TO LINK         10880021
*                                  TO IKJDAIR.                          10900021
         CALL  IKJEBIN5,((COMMREG)),MF=(E,INSVCRTN) PROMPT FOR         X10920021
                                   DATA SET TYPE.                       10940021
*                                  BRANCH TO PROMPT FOR SAME.           10960021
         LTR   RETCDREG,RETCDREG TEST RETURN CODE FOR SUCCESSFUL        10980021
         BNZ   INEXIT1             COMPLETION.  IF NOT ZERO,            11000021
*                                  BRANCH TO EXIT.                      11020021
         EJECT                                                          11040021
IN002000 EQU   *                                                        11060021
*********************************************************************** 11080021
*                                                                     * 11100021
*   BUILD DATA SET NAME INSERTION RECORD IN COMMUNICATION AREA.  THE  * 11120021
*   INSERTION RECORD WILL BE USED BY ANY ROUTINE WHICH HAS TO ISSUE   * 11140021
*   AN ERROR MESSAGE CONTAINING A DATA SET NAME.  THE INSERTION WILL  * 11160021
*   CONTAIN THE FULLY QUALIFIED DATA SET NAME IN SINGLE QUOTES IF THE * 11180021
*   USER SPECIFIED A FULLY QUALIFIED DATA SET NAME ON THE EDIT        * 11200021
*   COMMAND.  WHEN THE DATA SET NAME IS ENTERED PARTIALLY QUALIFIED,  * 11220021
*   ALL LEVELS OF QUALIFICATION EXCEPT USERID ARE PLACED IN THE       * 11240021
*   COMMUNICATION AREA.                                               * 11260021
*                                                                     * 11280021
*********************************************************************** 11300021
         LA    AREAREG,CADSNREC ADDRESS OF INSERTION RECORD.            11320021
         LH    LENREG,CAEDDSNL LENGTH OF FULLY QUALIFIED DSNAME.        11340021
         LA    DSNAMREG,CAEDDSN ADDRESS OF DATA SET NAME.               11360021
         TM    INDSN+INDSNFLG,INFULLQ DETERMINE IF DATA SET NAME        11380021
*                                  WAS ENTERED FULLY QUALIFIED.         11400021
         BZ    IN002210       IF NOT FULLY QUALIFIED, BRANCH TO         11420021
*                                  BUILD INSERTION RECORD.              11440021
         MVI   D0(AREAREG),INSNGLQT MOVE IN SINGLE QUOTE FOR            11460021
*                                  INSERTION RECORD.                    11480021
         LA    COUNTREG,X1(,D0) INITIALIZE COUNTER TO NUMBER OF         11500021
*                                  CHARACTERS IN NAME.                  11520021
         AR    AREAREG,COUNTREG UPDATE ADDRESS IN INSERTION             11540021
*                                  RECORD.                              11560021
         B     IN002030       BRANCH TO MOVE DATA SET NAME.             11580021
IN002210 EQU   *                                                        11600021
         CLI   D0(DSNAMREG),INPERIOD CHECK FOR FIRST OCCURRENCE         11620021
         BE    IN002220            OF PERIOD IN DSNAME.  BRANCH         11640021
*                                  TO UPDATE COUNTER IF FOUND.          11660021
         LA    DSNAMREG,X1(,DSNAMREG) UPDATE ADDRESS INTO DSNAME        11680021
         BCT   LENREG,IN002210     AND REDUCE LENGTH BY 1.              11700021
*                                  BRANCH TO TEST NEXT CHARACTER        11720021
*                                  IN BUFFER.                           11740021
*                                                                       11760021
*   NOTE -- THE CONTENTS OF LENREG CANNOT GO TO ZERO BASED ON           11780021
*   DEFINITION OF A PARTIALLY QUALIFIED TSO DATA SET NAME.              11800021
*                                                                       11820021
IN002220 EQU   *                                                        11840021
         LA    DSNAMREG,X1(,DSNAMREG) RESET ADDRESS IN DATA SET         11860021
         BCTR  LENREG,D0           NAME AND LENGTH TO BYPASS THE        11880021
*                                  PERIOD.                              11900021
         SR    COUNTREG,COUNTREG ZERO COUNTER OF NUMBER OF BYTES        11920021
*                                  IN DATA SET NAME.                    11940021
IN002030 EQU   *                                                        11960021
         BCTR  LENREG,D0      REDUCE LENGTH TO BE MOVED BY ONE          11980021
*                                  FOR MOVE CHARACTER.                  12000021
         EX    LENREG,INMV001 MOVE DATA SET NAME TO INSERTION           12020021
*                                  RECORD.                              12040021
         LA    COUNTREG,X1(LENREG,COUNTREG) UPDATE COUNTER TO           12060021
*                                  NUMBER OF BYTES IN DSNAME.           12080021
         LA    AREAREG,D1(LENREG,AREAREG) UPDATE ADDRESS IN             12100021
*                                  INSERTION RECORD.                    12120021
         TM    INDSN+INMEMFLG,INOPRNDO DETERMINE IF MEMBER NAME         12140021
*                                  SUPPLIED.                            12160021
         BZ    IN002230       IF NOT SUPPLIED, BRANCH TO COMPLETE       12180021
*                                  INSERTION RECORD.                    12200021
         MVI   D0(AREAREG),INLFTPRN MOVE LEFT PARENTHESIS TO            12220021
*                                  INSERTION RECORD.                    12240021
         LH    LENREG,INDSN+INMEMLL LENGTH OF MEMBER NAME.              12260021
         L     DSNAMREG,INDSN+INMEMPT ADDRESS OF MEMBER NAME.           12280021
         BCTR  LENREG,D0      REDUCE LENGTH BY 1 FOR MVC.               12300021
         EX    LENREG,INMV002 MOVE MEMBER NAME TO INSERTION             12320021
*                                  RECORD.                              12340021
         LA    AREAREG,D2(LENREG,AREAREG) UPDATE ADDRESS IN DATA        12360021
*                                  SET NAME INSERTION.                  12380021
         MVI   D0(AREAREG),INRTPRN MOVE RIGHT PARENTHESIS TO            12400021
*                                  INSERTION RECORD.                    12420021
         LA    AREAREG,D1(,AREAREG) UPDATE ADDRESS IN DATA              12440021
*                                  SET NAME INSERTION.                  12460021
         LA    COUNTREG,D3(LENREG,COUNTREG) UPDATE COUNTER TO           12480021
*                                  REFLECT NUMBER OF CHARACTERS         12500021
*                                  IN DSNAME AND MEMBER NAME.           12520021
IN002230 EQU   *                                                        12540021
         TM    INDSN+INDSNFLG,INFULLQ DETERMINE IF DATA SET NAME        12560021
*                                  WAS ENTERED FULLY QUALIFIED.         12580021
         BZ    IN002240       IF NOT FULLY QUALIFIED, BRANCH TO         12600021
*                                  PLACE LENGTH IN INSERTION            12620021
*                                  RECORD.                              12640021
         MVI   D0(AREAREG),INSNGLQT MOVE CLOSING SINGLE QUOTE IN        12660021
*                                  INSERTION RECORD.                    12680021
         LA    COUNTREG,X1(,COUNTREG) UPDATE COUNTER TO REFLECT         12700021
*                                  NUMBER OF CHARACTERS IN RECORD       12720021
IN002240 EQU   *                                                        12740021
         XC    CADSNPTR(CADSNREC-CADSNPTR),CADSNPTR ZERO CONTROL        12760021
*                                  WORDS FOR INSERTION RECORD.          12780021
         LA    COUNTREG,D4(,COUNTREG) UPDATE COUNTER TO INCLUDE         12800021
*                                  LENGTH OF CONTROL WORD AND           12820021
         STH   COUNTREG,CADSNLEN   SAVE IN INSERTION RECORD.            12840021
         EJECT                                                          12860021
*********************************************************************** 12880021
*                                                                     * 12900021
*   ALLOCATE THE EDIT DATA SET.                                       * 12920021
*                                                                     * 12940021
*   INDICATE THAT THE DATA SET BEING PROCESSED IS THE EDIT DATA SET.  * 12960021
*   BUILD A PARAMETER BLOCK FOR IKJDAIR AND INCLUDE A PASSWORD IF     * 12980021
*   SPECIFIED.  CHECK IF USER SPECIFIED NEW ON THE COMMAND -- IF SO,  * 13000021
*   BRANCH TO VALIDATE OPERANDS SPECIFIED ON THE COMMAND.  OTHERWISE  * 13020021
*   DETERMINE IF A MEMBER NAME WAS SPECIFIED.  WHEN A MEMBER NAME IS  * 13040021
*   ENTERED, CHANGE DISPOSITION FROM OLD TO SHR FOR IKJDAIR.  LINK    * 13060021
*   TO IKJDAIR WITH ENTRY CODE X'08' TO ALLOCATE THE DATA SET.        * 13080021
*                                                                     * 13100021
*********************************************************************** 13120021
         OI    CAEDFLAG,CAEDITDS INDICATE EDIT DATA SET.                13140021
         L     PASSREG,CAPTTMP ADDRESS OF TMP PARAMETER LIST.           13160021
         L     PASSREG,(CPPLPSCB-CPPL)(,PASSREG) ADDRESS OF PSCB.       13180021
         LA    AREAREG,CAEDDSNL ADDRESS OF DATA SET NAME LENGTH         13200021
*                                  AND DATA SET NAME.                   13220021
         MVC   INDREC(INDR8OLL),INDAIR8O INITIALIZE IKJDAIR             13240021
*                                  PARAMETER LIST - ENTRY CODE 8.       13260021
         TM    INDSN+INPSWFLG,INOPRNDO DETERMINE IF PASSWORD            13280021
*                                  SPECIFIED.                           13300021
         BZ    IN002250       IF NOT, BRANCH TO CHECK IF NEW            13320021
*                                  OPERAND SPECIFIED ON COMMAND.        13340021
         MVC   INDREC+(DA08PSWD-DAPB08)(L'CAEDPSWD),CAEDPSWD MOVE       13360021
*                                  PASSWORD TO PARAMETER LIST.          13380021
IN002250 EQU   *                                                        13400021
         CLC   INSTAT(L'INDISPNW),INDISPNW DETERMINE IF NEW WAS         13420021
*                                  SPECIFIED ON COMMAND.                13440021
         BE    IN003100       BRANCH TO VALIDATE OPERANDS ENTERED       13460021
*                                  ON COMMAND IF NEW SPECIFIED.         13480021
         TM    INDSN+INMEMFLG,INOPRNDO DETERMINE IF MEMBER NAME         13500021
*                                  ENTERED ON COMMAND.                  13520021
         BZ    IN002255       IF NOT, BRANCH TO COMPLETE                13540021
*                                  PARAMETER LIST FOR IKJDAIR.          13560021
         OI    INDREC+(DA08DSP1-DAPB08),DA08SHR INDICATE DISP=SHR       13580021
*                                  FOR OLD, PARTITIONED DATA SETS       13600021
IN002255 EQU   *                                                        13620021
         ST    AREAREG,INDREC+(DA08PDSN-DAPB08) PUT ADDRESS OF          13640021
*                                  DSNAME IN PARAMETER LIST.            13660021
         LA    AREAREG,INDREC ADDRESS OF IKJDAIR PARAMETER LIST.        13680021
         LINK  EP=IKJDAIR,PARAM=(,,,(PASSREG),(AREAREG)),              X13700021
               MF=(E,CATMPLST) LINK TO IKJDAIR.                         13720021
         SPACE 5                                                        13740021
*********************************************************************** 13760021
*                                                                     * 13780021
*   UPON RETURN FROM IKJDAIR, TEST RETURN CODE FOR SUCCESSFUL         * 13800021
*   COMPLETION.  WHEN IKJDAIR RETURNS A NON-ZERO RETURN CODE, BRANCH  * 13820021
*   TO APPROPRIATE DIAGNOSTIC AREA.                                   * 13840021
*                                                                     * 13860021
*********************************************************************** 13880021
         SPACE 5                                                        14120021
         LTR   RETCDREG,RETCDREG CHECK FOR NARMAL COMPLETION.   A59609  14121021
         BZ    IN002400       IF SO, BR TO CONTINUE NARMALLY.   A59609  14122021
IN002260 EQU   *                                                A59609  14123021
         CH    RETCDREG,INDAIR08 CHECK FOR CATLG ERROR.         A59609  14124021
         BL    IN002270       INVALID PARAMETERS, SEND MESSAGE. A59609  14125021
         BE    IN002290       CATLG MGMT ERROR, SEND MESSAGE.   A59609  14126021
         CH    RETCDREG,INDAIR16 CHECK IF TIOT FULL.            A59609  14127021
         BL    IN002350       DYN ALLOCATION ERROR, DETERMINE   A59609  14128021
*                                  CAUSE AND SEND MESSAGE.      A59609  14129021
         BE    IN002280       NO TIOT ENTRIES AVAILABLE, SEND   A59609  14130021
*                                  APPROPRIATE MESSAGE.         A59609  14131021
         CH    RETCDREG,INDAIR48 CHECK FOR DAIR STAE ENTERED.   A59609  14132021
         BE    INEXIT12       IF SO, RETURN TO TMP WITH RC=12.  A59609  14133021
*                                                                       14140021
*   OTHERWISE FALL THROUGH TO ISSUE GENERAL ERROR MESSAGE.      A59609  14145021
*                                                                       14150021
*********************************************************************** 14155021
*                                                                     * 14160021
*   IKJDAIR RETURN CODES 04, 20, 24, 28, 32, 36, 40             A59609  14180021
*                                                                     * 14200021
*   ISSUE COMMAND NOT EXECUTABLE MESSAGE WITH SECOND LEVEL LOGIC      * 14220021
*   ERROR MESSAGE.                                                    * 14240021
*                                                                     * 14260021
*********************************************************************** 14280021
IN002270 EQU   *                                                        14300021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.         14320021
         LR    DATA2REG,RETCDREG SAVE RETURN CODE FOR MESSAGE.          14340021
         O     DATA2REG,INDAIR INDICATE ROUTINE NAME AS IKJDAIR.        14360021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            14380021
*                                  ERROR MESSAGE.                       14400021
         EJECT                                                          14420021
*********************************************************************** 14440021
*                                                                     * 14460021
*   IKJDAIR RETURN CODE 16                                            * 14480021
*                                                                     * 14500021
*   ISSUE TOO MANY DATA SETS ALLOCATED MESSAGE.                       * 14520021
*                                                                     * 14540021
*********************************************************************** 14560021
IN002280 EQU   *                                                        14580021
         LA    ERR1REG,INERRORM RELATIVE ERROR TO BE PROCESSED.         14600021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            14620021
*                                  ERROR MESSAGE.                       14640021
         SPACE 5                                                        14660021
*********************************************************************** 14680021
*                                                                     * 14700021
*   IKJDAIR RETURN CODE 08 - CATALOG ERROR.                           * 14720021
*                                                                     * 14740021
*   SINCE IKJDAIR RETURNS THIS RETURN CODE FOR A DYNAMIC ALLOCATION   * 14760021
*   FAILURE OF X'17XX', THIS CODE ASSUMES THAT AN OBTAIN FAILURE HAS  * 14780021
*   OCCURRED WHEN THE DA08DARC FIELD IS ZERO AND THE DA08CTRC FIELD   * 14800021
*   IS NON-ZERO.                                                      * 14820021
*                                                                     * 14840021
*********************************************************************** 14860021
IN002290 EQU   *                                                        14880021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR0000),INDR0000 TEST       14900021
*                                  FOR DARC = ZERO.                     14920021
         BNE   IN002350       IF NOT ZERO, BRANCH TO DETERMINE          14940021
*                                  CAUSE OF DYNAMIC ALLOCATION          14960021
*                                  FAILURE.                             14980021
*                                                                       15000021
*   THE FOLLOWING ASSUMES AN OBTAIN FAILURE, I.E., DARC = ZERO          15020021
*   AND CTRC = NON-ZERO.                                                15040021
*                                                                       15060021
IN002300 EQU   *                                                        15080021
         CLC   INDREC+(DA08CTRC-DAPB08)(L'INDR0004),INDR0004 TEST       15100021
*                                  FOR CATALOG ERROR CODE = 4.          15120021
         BNE   IN002320       IF NOT 4, BRANCH TO CHECK FOR 8.          15140021
         EJECT                                                          15160021
*********************************************************************** 15180021
*                                                                     * 15200021
*   CATALOG ERROR RETURN CODE = 4.                                    * 15220021
*                                                                     * 15240021
*   ISSUE REQUIRED VOLUME NOT MOUNTED MESSAGE.                        * 15260021
*                                                                     * 15280021
*********************************************************************** 15300021
IN002310 EQU   *                                                        15320021
         LA    ERR1REG,INERRORN RELATIVE ERROR TO BE PROCESSED.         15340021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            15360021
*                                  ERROR MESSAGE.                       15380021
         SPACE 2                                                        15400021
IN002320 EQU   *                                                        15420021
         CLC   INDREC+(DA08CTRC-DAPB08)(L'INDR0008),INDR0008 TEST       15440021
*                                  FOR CATALOG ERROR = 8.               15460021
         BNE   IN002340       IF NOT 8, BRANCH TO CHECK FOR 28.         15480021
         EJECT                                                          15500021
         SPACE 5                                                        15520021
IN002325 EQU   *                                                        15540021
*********************************************************************** 15560021
*                                                                     * 15580021
*   CATALOG ERROR RETURN CODE = 8.                                    * 15600021
*                                                                     * 15620021
*   ISSUE DATA SET NOT ON VOLUME MESSAGE.                             * 15640021
*                                                                     * 15660021
*********************************************************************** 15680021
         LA    ERR1REG,INERRORO RELATIVE ERROR TO BE PROCESSED.         15700021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            15720021
*                                  ERROR MESSAGE.                       15740021
IN002340 EQU   *                                                        15760021
         CLC   INDREC+(DA08CTRC-DAPB08)(L'INDR0028),INDR0028 TEST       15780021
*                                  FOR CATALOG ERROR = 28.              15800021
         BNE   IN002346       IF NOT 28, BRANCH TO ISSUE ERROR          15820021
*                                  MESSAGE - ALLOCATION FAILED.         15840021
         EJECT                                                          15860021
*********************************************************************** 15880021
*                                                                       15900021
*   CATALOG ERROR CODE 28.                                              15920021
*                                                                       15940021
*   ISSUE CATALOG I/O ERROR MESSAGE.                                    15960021
*                                                                       15980021
*********************************************************************** 16000021
IN002343 EQU   *                                                        16020021
         LA    ERR2REG,M3043  RELATIVE SECOND-LEVEL MESSAGE.            16040021
         LA    ERR1REG,INERRORP RELATIVE ERROR TO BE PROCESSED.         16060021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            16080021
*                                  ERROR MESSAGE.                       16100021
         SPACE 5                                                        16120021
*********************************************************************** 16140021
*                                                                     * 16160021
*   CATALOG ERROR RETURN CODE OTHER THAN 4,8, OR 28.                  * 16180021
*                                                                     * 16200021
*   ISSUE ALLOCATION FAILED - SYSTEM ERROR MESSAGE.                   * 16220021
*                                                                     * 16240021
*********************************************************************** 16260021
IN002346 EQU   *                                                        16280021
         LA    ERR1REG,INERRORP RELATIVE ERROR TO BE PROCESSED.         16300021
         LA    ERR2REG,M3042  RELATIVE SECOND LEVEL MESSAGE.            16320021
         LH    DATA2REG,INDREC+(DA08CTRC-DAPB08) OBTAIN CATALOG         16340021
*                                  ERROR FOR SECOND LEVEL MESSAGE       16360021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            16380021
*                                  ERROR MESSAGE.                       16400021
         EJECT                                                          16420021
*********************************************************************** 16440021
*                                                                     * 16460021
*   DYNAMIC ALLOCATION FAILURE - DARC IS NON-ZERO.                    * 16480021
*                                                                     * 16500021
*   A TEST IS MADE FOR A DYNAMIC ALLOCATION RETURN CODE IN THE FORM   * 16520021
*   X'17XX' (LOCATE FAILURE).  IF THE CAUSE OF ALLOCATION FAILURE     * 16540021
*   IS ASSOCIATED WITH LOCATE, THE LOW ORDER BYTE OF THE DARC FIELD   * 16560021
*   (THE LOCATE RETURN CODE) IS TESTED.  IF THE RETURN CODE IS 8,     * 16580021
*   12, OR 16 THE DATA SET NAME COULD NOT BE FOUND IN THE CATALOG.    * 16600021
*   IF IT IS 4, THE USER IS INFORMED BY TERMINAL MESSAGE THAT A       * 16620021
*   REQUIRED CVOL IS NOT MOUNTED.  IF THE LOCATE RETURN CODE IS 24,   * 16640021
*   A PERMANENT I/O ERROR EXISTS IN THE CATALOG AND AN APPROPRIATE    * 16660021
*   ERROR MESSAGE IS ISSUED.  ALL OTHER RETURN CODES RESULT IN A      * 16680021
*   GENERAL ALLOCATION ERROR MESSAGE BEING PUT TO THE TERMINAL.       * 16700021
*   TERMINATION OCCURS AFTER ERROR MESSAGES ARE ISSUED FOR THE ABOVE  * 16720021
*   CONDITIONS.                                                       * 16740021
*                                                                     * 16760021
*********************************************************************** 16780021
IN002350 EQU   *                                                        16800021
         CLI   INDREC+(DA08DARC-DAPB08),INDR1700 CHECK IF A             16820021
*                                  LOCATE ERROR OCCURRED.               16840021
         BNE   IN002370       IF NOT A LOCATE ERROR, BRANCH TO          16860021
*                                  DETERMINE CAUSE OF DYNAMIC           16880021
*                                  ALLOCATION FAILURE.                  16900021
         CLI   INDREC+D1+(DA08DARC-DAPB08),D24 CHECK IF I/O ERROR       16920021
*                                  IN CATALOG.                          16940021
         BE    IN002343       IF SO, BRANCH TO SET PARAMETERS FOR       16960021
*                                  ERROR MESSAGE.                       16980021
         CLI   INDREC+D1+(DA08DARC-DAPB08),D12 CHECK FOR LOWEST         17000021
*                                  QUALIFIER OF DSNAME BEING AN         17020021
*                                  INDEX LEVEL OR CVOL POINTER.         17040021
         BE    IN002355       IF SO, BRANCH TO ISSUE ERROR              17060021
*                                  MESSAGE.                             17080021
         CLI   INDREC+D1+(DA08DARC-DAPB08),D16 IS DATA SET NAME         17100021
*                                  INCOMPATIBLE WITH CATALOG            17120021
*                                  STRUCTURE.                           17140021
         BE    IN002355       IF SO, BRANCH TO ISSUE ERROR MESSAGE.     17160021
         CLI   INDREC+D1+(DA08DARC-DAPB08),D8 CHECK LOCATE RETURN       17180021
*                                  CODE.                                17200021
         BL    IN002310       04 - REQUIRED VOLUME NOT AVAILABLE        17220021
         BH    IN002390       20-32 - SYSTEM ERROR IN DYNAMIC           17240021
*                                  ALLOCATION.                          17260021
         SPACE 2                                                        17280021
* FALLING THROUGH THE ABOVE BRANCH IMPLIES THAT DATA SET NAME WAS       17300021
* NOT FOUND IN THE CATALOG.                                             17320021
         SPACE 2                                                        17340021
IN002355 EQU   *                                                        17360021
         CLC   INSTAT(L'INKEYDEF),INKEYDEF DETERMINE IF USER            17380021
*                                  SPECIFIED OLD.                       17400021
         BE   IN002360        IF OLD SPECIFIED, BRANCH TO PUT           17420021
*                                  ERROR MESSAGE AND TERMINATE.         17440021
         BAL   SRRTNREG,INDISPPR BRANCH TO PROMPT FOR NEW OR OLD.       17460021
         LTR   FLAGREG,FLAGREG CHECK USER RESPONSE FOR NEW OR OLD       17480021
         BZ    IN003100       IF ZERO, USER SPECIFIED NEW.              17500021
*                                  BRANCH TO VALIDATE OPERANDS          17520021
*                                  SPECIFIED ON COMMAND.                17540021
         SPACE 5                                                        17560021
*********************************************************************** 17580021
*                                                                     * 17600021
*   USER SPECIFIED OLD AND DATA SET NOT FOUND -- ISSUE ERROR MESSAGE  * 17620021
*   THAT DATA SET NOT FOUND AND TERMINATE EDIT.                       * 17640021
*                                                                     * 17660021
*********************************************************************** 17680021
IN002360 EQU   *                                                        17700021
         LA    ERR1REG,INERROR7 RELATIVE ERROR TO BE PROCESSED.         17720021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            17740021
*                                  ERROR MESSAGE.                       17760021
         EJECT                                                          17780021
*********************************************************************** 17800021
*                                                                     * 17820021
*   DETERMINE CAUSE OF DYNAMIC ALLOCATION FAILURE.                    * 17840021
*                                                                     * 17860021
*********************************************************************** 17880021
IN002370 EQU   *                                                        17900021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR0218),INDR0218 TEST       17920021
*                                  FOR DYNAMIC ALLOCATION RETURN        17940021
*                                  CODE OF X'0218'.                     17960021
         BE    IN002310       BRANCH TO ISSUE REQUIRED VOLUME NOT       17980021
*                                  MOUNTED MESSAGE.                     18000021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR020C),INDR020C TEST       18020021
*                                  FOR DARC = X'020C'.                  18040021
         BE    IN002385       IF SO, BRANCH TO INDICATE ERROR.          18060021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR0210),INDR0210 TEST       18080021
*                                  FOR DARC=X'0210'                     18100021
         BNE   IN002390       IF NOT DATA SET ALREADY IN USE,           18120021
*                                  BRANCH TO CONTINUE TESTS.            18140021
         SPACE 5                                                        18160021
*********************************************************************** 18180021
*                                                                     * 18200021
*   DYNAMIC ALLOCATION ERROR X'020C'                                  * 18220021
*   DYNAMIC ALLOCATION ERROR X'0210'                                  * 18240021
*                                                                     * 18260021
*   ISSUE DATA SET ALREADY IN USE MESSAGE.                            * 18280021
*                                                                     * 18300021
*********************************************************************** 18320021
IN002385 EQU   *                                                        18340021
         LA    ERR1REG,INERRORK RELATIVE ERROR TO BE PROCESSED.         18360021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            18380021
*                                  ERROR MESSAGE.                       18400021
         EJECT                                                          18420021
IN002390 EQU   *                                                        18440021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR0214),INDR0214 TEST       18460021
*                                  FOR DARC=X'0214'.                    18480021
         BE    IN002391       IF DARC=X'0214', BRANCH TO PROCESS.       18500021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR021C),INDR021C TEST       18520021
*                                  FOR DARC=X'021C'.                    18540021
         BNE   IN002393       IF NOT X'021C',BRANCH TO CONTINUE         18560021
*                                  TESTS.                               18580021
         SPACE 5                                                        18600021
*********************************************************************** 18620021
*                                                                       18640021
*   DYNAMIC ALLOCATION ERROR X'021C'.                                   18660021
*   NO UNIT IS AVAILABLE.                                               18680021
*                                                                       18700021
*   DYNAMIC ALLOCATION ERROR X'0214'.                                   18720021
*   INVALID UNIT IN UADS.                                               18740021
*                                                                       18760021
*********************************************************************** 18780021
         LA    ERR2REG,M3182  SPECIFY NO UNIT AVAILABLE MESSAGE.        18800021
         B     IN002392       BRANCH TO SET RELATIVE MESSAGE NO.        18820021
IN002391 EQU   *                                                        18840021
         LA    ERR2REG,M3181  SPECIFY INVALID UNIT MESSAGE.             18860021
IN002392 EQU   *                                                        18880021
         LA    ERR1REG,INERRORW RELATIVE ERROR TO BE PROCESSED.         18900021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            18920021
*                                  MESSAGE.                             18940021
         EJECT                                                          18960021
IN002393 EQU   *                                                        18980021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR0404),INDR0404 TEST       19000021
*                                  FOR DEVICE NOT DIRECT ACCESS.        19020021
         BNE   IN002395       IF NOT X'0404' BRANCH TO CONTINUE         19040021
*                                  TESTS.                               19060021
         SPACE 5                                                        19080021
*********************************************************************** 19100021
*                                                                       19120021
*   DYNAMIC ALLOCATION ERROR X'0404'.                                   19140021
*                                                                       19160021
*   ISSUE MESSAGE FOR DEVICE NOT DIRECT ACCESS.                         19180021
*                                                                       19200021
*********************************************************************** 19220021
         LA    ERR1REG,INERRORQ RELATIVE ERROR TO BE PROCESSED.         19240021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            19260021
*                                  MESSAGE.                             19280021
         SPACE 2                                                        19300021
IN002395 EQU   *                                                        19320021
         CLC   INDREC+(DA08DARC-DAPB08)(L'INDR041C),INDR041C TEST       19340021
*                                  FOR DATA SET ON MULTIPLE             19360021
*                                  VOLUMES.                             19380021
         BNE   IN002399       IF NOT X'041C', BRANCH TO ISSUE           19400021
*                                  SYSTEM ERROR DIAGNOSTIC WITH         19420021
*                                  DARC AS INSERTION.                   19440021
         SPACE 5                                                        19460021
*********************************************************************** 19480021
*                                                                       19500021
*   DYNAMIC ALLOCATION ERROR X'041C'.                                   19520021
*                                                                       19540021
*   ISSUE DIAGNOSTIC FOR MULTIPLE VOLUMES NOT SUPPORTED.                19560021
*                                                                       19580021
*********************************************************************** 19600021
         LA    ERR1REG,INERRORT    RELATIVE ERROR TO BE PROCESSED.      19620021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            19640021
*                                  MESSAGE.                             19660021
         EJECT                                                          19680021
*********************************************************************** 19700021
*                                                                     * 19720021
*   DYNAMIC ALLOCATION ERRORS OTHER THAN THOSE SPECIFICALLY             19740021
*   TESTED FOR.                                                         19760021
*                                                                     * 19780021
*   ISSUE ALLOCATION FAILED - SYSTEM ERROR MESSAGE.                   * 19800021
*                                                                     * 19820021
*********************************************************************** 19840021
IN002399 EQU   *                                                        19860021
         LA    ERR1REG,INERRORP RELATIVE ERROR TO BE PROCESSED.         19880021
         LA    ERR2REG,M3041  RELATIVE SECOND LEVEL MESSAGE.            19900021
         LH    DATA2REG,INDREC+(DA08DARC-DAPB08) OBTAIN DARC FOR        19920021
*                                  SECOND LEVEL MESSAGE.                19940021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            19960021
*                                  ERROR MESSAGE.                       19980021
         EJECT                                                          20000021
*********************************************************************** 20020021
*                                                                     * 20040021
*   DATA SET SUCCESSFULLY ALLOCATED.                                  * 20060021
*                                                                     * 20080021
*   MOVE DDNAME RETURNED BY IKJDAIR TO COMMUNICATION AREA AND         * 20100021
*   INDICATE THAT DATA SET IS ALLOCATED.  DETERMINE IF DATA SET       * 20120021
*   ORGANIZATION IS VALID FOR EDIT -- IF NOT, ISSUE ERROR MESSAGE     * 20140021
*   AND TERMINATE.  IF DATA SET ORGANIZATION IS PARTITIONED, BRANCH   * 20160021
*   TO PROCESS MEMBER NAME.  WHEN DATA SET HAS SEQUENTIAL ORGANIZA-   * 20180021
*   TION, CHECK IF USER SPECIFIED A MEMBER NAME ON COMMAND.  IF       * 20200021
*   A MEMBER NAME WAS ENTERED, REBUILD DATA SET NAME INSERTION AND    * 20220021
*   PUT DIAGNOSTIC MESSAGE TO TERMINAL.  AFTER USER HAS BEEN          * 20240021
*   INFORMED OF ERROR, BRANCH TO PROCESS LOGICAL RECORD SIZE AND      * 20260021
*   BLOCK SIZE FOR OLD DATA SET.                                      * 20280021
*                                                                     * 20300021
*********************************************************************** 20320021
IN002400 EQU   *                                                        20340021
         MVC   CAEDDDN(L'CAEDDDN),INDREC+(DA08DDN-DAPB08) MOVE          20360021
*                                  DDNAME RETURNED BY IKJDAIR           20380021
*                                  INTO THE COMMUNICATION AREA.         20400021
         OI    CAEDFLAG,CAEDDISP+CAEDALOC INDICATE THAT THE EDIT        20420021
*                                  DATA SET HAS BEEN ALLOCATED          20440021
*                                  AND THAT IT HAS DISP = OLD.          20460021
         TM    INDREC+(DA08DSO-DAPB08),DS1ORGPO DETERMINE IF A  SA73470 20480021
*                                  PARTITIONED DATA SET.                20500021
         BO    IN002430       IF SO, BRANCH TO PROCESS MEMBER   SA73470 20520021
*                                  NAME.                                20540021
         CLI   INDREC+(DA08DSO-DAPB08),DS1ORGPS DETERMINE IF A          20560021
*                                  SEQUENTIAL DATA SET.                 20580021
         BE    IN002410       IF SO, BRANCH TO DETERMINE IF A           20600021
*                                  MEMBER NAME WAS ENTERED.             20620021
         CLI   INDREC+(DA08DSO-DAPB08),D0 DETERMINE IF DSORG HAS        20640021
*                                  BEEN ESTABLISHED FOR DATA SET.       20660021
         BE    IN002410       IF NO DSORG, BRANCH TO DO OBTAIN          20680021
*                                  ON DATA SET NAME.                    20700021
         EJECT                                                          20720021
*********************************************************************** 20740021
*                                                                     * 20760021
*   IF NEITHER PARTITIONED OR SEQUENTIAL, ISSUE ERROR MESSAGE THAT    * 20780021
*   DATA SET ORGANIZATION IS INVALID FOR EDIT AND TERMINATE.          * 20800021
*                                                                     * 20820021
*********************************************************************** 20840021
         LA    ERR1REG,INERROR4 RELATIVE ERROR TO BE PROCESSED.         20860021
         LA    DATA1REG,INDREC+(DA08DSO-DAPB08) ADDRESS OF DSORG        20880021
*                                  BYTE FOR IKJEBIN3.                   20900021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            20920021
*                                  ERROR MESSAGE.                       20940021
         SPACE 2                                                        20960021
IN002410 EQU   *                                                        20980021
         TM    INDSN+INMEMFLG,INOPRNDO DETERMINE IF MEMBER NAME         21000021
*                                  SUPPLIED.                            21020021
         BZ    IN002010       IF NOT, BRANCH TO CHECK DATA SET          21040021
*                                  ATTRIBUTES.                          21060021
         LH    SIZEREG,CADSNLEN OBTAIN LENGTH OF INSERTION RECORD       21080021
*                                  WITH MEMBER NAME.                    21100021
         LH    LENREG,INDSN+INMEMLL GET LENGTH OF MEMBER NAME           21120021
*                                  ENTERED ON COMMAND.                  21140021
         LR    DATA1REG,LENREG SAVE MEMBER LENGTH FOR MESSAGE.          21160021
         LA    LENREG,D2(,LENREG) ADD 2 TO LENGTH OF MEMBER NAME        21180021
*                                  FOR PARENTHESES.                     21200021
         SR    SIZEREG,LENREG REDUCE INSERTION LENGTH BY NUMBER         21220021
*                                  OF CHARACTERS IN MEMBER NAME         21240021
         STH   SIZEREG,CADSNLEN    AND SAVE IN INSERTION RECORD.        21260021
         TM    INDSN+INDSNFLG,INFULLQ DETERMINE IF DATA SET NAME        21280021
*                                  WAS ENTERED FULLY QUALIFIED.         21300021
         BZ    IN002420       IF NOT, BRANCH TO REMOVE MEMBER           21320021
*                                  NAME FROM INSERTION RECORD.          21340021
         LA    LENREG,D5(,D0) REDUCE NEW LENGTH BY 5 SO THAT            21360021
         SR    SIZEREG,LENREG      FINAL QUOTE MAY BE ADDED.            21380021
         LA    AREAREG,CADSNREC(SIZEREG) COMPUTE LOCATION OF            21400021
         MVI   D0(AREAREG),INSNGLQT SINGLE QUOTE AND MOVE TO            21420021
*                                  INSERTION RECORD.                    21440021
         EJECT                                                          21460021
*********************************************************************** 21480021
*                                                                     * 21500021
*   WHEN A MEMBER NAME IS ENTERED, ISSUE ERROR MESSAGE THAT DATA      * 21520021
*   SET IS NOT A PARTITIONED DATA SET.  IF A ZERO RETURN CODE IS      * 21540021
*   RETURNED FROM IKJEBIN3, BRANCH TO VALIDATE OLD DATA SET           * 21560021
*   ATTRIBUTES.  WHEN IKJEBIN3 RETURNS A NON-ZERO RETURN CODE,        * 21580021
*   TERMINATE EDIT.                                                   * 21600021
*                                                                     * 21620021
*********************************************************************** 21640021
IN002420 EQU   *                                                        21660021
         LA    ERR1REG,INERROR3 RELATIVE ERROR TO BE PROCESSED.         21680021
         L     EPLOCREG,INMSGRTN ADDRESS OF MESSAGE ROUTINE.            21700021
         CALL  (15),((COMMREG),(ERR1REG),,(DATA1REG),),                X21720021
               MF=(E,INSVCRTN) CALL IKJEBIN3 TO ISSUE MESSAGE.          21740021
         LTR   RETCDREG,RETCDREG CHECK FOR SUCCESSFUL COMPLETION.       21760021
         BNZ   INEXIT1        IF RETURN CODE IS NON-ZERO, BRANCH        21780021
*                                  TO TERMINATE EDIT.                   21800021
         MVI   CAEDMEMB,CHRBLANK REMOVE MEMBER NAME FROM COMMUNI-       21820021
         MVC   CAEDMEMB+D1(L'CAEDMEMB-D1),CAEDMEMB CATION AREA.         21840021
         NI    CAEDFLAG,X'FF'-CAEDDSOR INDICATE DS IS SEQUENTIAL        21860021
         B     IN002010       IF RETURN CODE IS ZERO, BRANCH TO         21880021
*                                  CHECK DATA SET ATTRIBUTES.           21900021
         EJECT                                                          21920021
*********************************************************************** 21940021
*                                                                     * 21960021
*   DATA SET ORGANIZATION IS PARTITIONED.                             * 21980021
*                                                                     * 22000021
*   INDICATE THAT DATA SET ORGANIZATION IS PARTITIONED IN THE         * 22020021
*   COMMUNICATION AREA.  BUILD A DCB AND OPEN FOR BSAM SO THAT        * 22040021
*   BLDL MAY BE USED TO DETERMINE IF MEMBER EXISTS.  IF IT IS NOT     * 22060021
*   POSSIBLE TO OPEN THE DCB, ISSUE ERROR MESSAGE AND RETURN TO       * 22080021
*   THE TMP.  WHEN OPEN IS SUCCESSFUL, DETERMINE IF USER SPECIFIED    * 22100021
*   A MEMBER NAME.  IF A MEMBER NAME WAS NOT SPECIFIED, DEFAULT       * 22120021
*   MEMBER TO TEMPNAME.  ISSUE THE BLDL MACRO INSTRUCTION TO          * 22140021
*   DETERMINE IF THE MEMBER EXISTS.  UPON RETURN FROM BLDL, SAVE      * 22160021
*   BLDL RETURN CODE, CLOSE THE DCB, AND UNALLOCATE THE DATA SET.     * 22180021
*   UPON RETURN FROM UNALLOCATE, TEST RETURN CODE FOR ZERO -- IF      * 22200021
*   NOT ZERO, BRANCH TO DIAGNOSE ERROR.  OTHERWISE, CHECK BLDL        * 22220021
*   RETURN CODE.                                                      * 22240021
*                                                                     * 22260021
*********************************************************************** 22280021
IN002430 EQU   *                                                        22300021
         OI    CAEDFLAG,CAEDDSOR INDICATE THAT DSORG = PO.              22320021
         MVC   INWKDCB(INDCBL),INDCB MOVE DCB TO WORK AREA.             22340021
         MVC   INWKOPEN(INOPENL),INOPEN INITIALIZE OPEN PARAMETER       22360021
*                                  LIST.                                22380021
         LA    AREAREG,INWKDCB ADDRESS OF DCB FOR OPEN.                 22400021
         MVC   INWKDCB+(DCBDDNAM-IHADCB)(L'DCBDDNAM),CAEDDDN MOVE       22420021
*                                  DDNAME INTO DCB.                     22440021
         OPEN  ((AREAREG),(INPUT)),MF=(E,INWKOPEN) OPEN DCB.            22460021
         TM    INWKDCB+(DCBOFLGS-IHADCB),INOPENED CHECK IF DCB          22480021
*                                  WAS OPENED SUCCESSFULLY.             22500021
         BO    IN002440       IF DCB OPENED, BRANCH TO DO BLDL.         22520021
*                                  OTHERWISE, ISSUE OPEN FAILED         22540021
*                                  MESSAGE.                             22560021
         LA    ERR1REG,INERRORL RELATIVE ERROR TO BE PROCESSED.         22580021
         LA    ERR2REG,M3093  RELATIVE SECOND LEVEL MESSAGE.            22600021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            22620021
*                                  ERROR MESSAGE.                       22640021
         SPACE 2                                                        22660021
IN002440 EQU   *                                                        22680021
         TM    INDSN+INMEMFLG,INOPRNDO DETERMINE IF MEMBER NAME         22700021
*                                  SUPPLIED.                            22720021
         BO    IN002450       IF ENTERED, BRANCH TO ISSUE BLDL.         22740021
         MVC   CAEDMEMB(L'CAEDMEMB),INTEMPNM SET MEMBER NAME TO         22760021
*                                  TEMPNAME.                            22780021
         LA    PARMREG1,D8    DUMMY UP LENGTH OF MEMBER NAME FOR        22800021
         STH   PARMREG1,INDSN+INMEMLL MESSAGE INSERTION.                22820021
IN002450 EQU   *                                                        22840021
         MVC   INBLDWD(L'INBLINIT),INBLINIT INITIALIZE LIST WITH        22860021
         MVC   INMEMBER(L'CAEDMEMB),CAEDMEMB MEMBER NAME FOR BLDL       22880021
         LA    PARMREG0,INBLDWD ADDRESS OF LIST FOR BLDL.               22900021
         BLDL  (AREAREG),(0)  DETERMINE IF MEMBER EXISTS.               22920021
         LR    TMPCDREG,RETCDREG SAVE BLDL RETURN CODE.                 22940021
         MVC   INWKOPEN(INCLOSEL),INCLOSE INITIALIZE CLOSE              22960021
*                                  PARAMETER LIST.                      22980021
         CLOSE ((AREAREG),),MF=(E,INWKOPEN) CLOSE DCB.                  23000021
         B     IN002460(TMPCDREG) BLDL RETURN CODE BRANCH TABLE.        23020021
IN002460 EQU   *                                                        23040021
         B     IN002005       00 - VALIDATE DATA SET ATTRIBUTES.        23060021
         B     IN002470       04 - PROMPT FOR NEW OR OLD OPERAND.       23080021
*                             08 - PERMANENT I/O ERROR.                 23100021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.         23120021
         LA    ERR2REG,M3131  RELATIVE SECOND LEVEL MESSAGE.            23140021
         LA    DATA2REG,ININS002 ADDRESS OF INSERTION TEXT FOR          23160021
*                                  SECOND LEVEL MESSAGE.                23180021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            23200021
*                                  ERROR MESSAGE.                       23220021
         EJECT                                                          23240021
*********************************************************************** 23260021
*                                                                       23280021
*   PROMPT FOR NEW/OLD OPERAND IF NOT SPECIFIED ON THE COMMAND.  IF   * 23300021
*   OLD WAS SPECIFIED ORIGINALLY ISSUE ERROR MESSAGE AND RETURN.      * 23320021
*                                                                       23340021
*********************************************************************** 23360021
IN002470 EQU   *                                                        23380021
         CLC   INSTAT(L'INKEYDEF),INKEYDEF DETERMINE IF USER            23400021
*                                  SPECIFIED OLD.                       23420021
         BE    IN002480       IF OLD SPECIFIED, BRANCH TO PUT           23440021
*                                  ERROR MESSAGE AND TERMINATE.         23460021
         BAL   SRRTNREG,INDISPPR BRANCH TO PROMPT FOR NEW OR OLD.       23480021
         LTR   FLAGREG,FLAGREG CHECK USER RESPONSE FOR NEW OR OLD       23500021
         BNZ   IN002480       IF NOT ZERO, USER SPECIFIED OLD,          23520021
*                                 BRANCH TO PUT ERROR MESSAGE.          23540021
         NI    CAEDFLAG,INF255-(CAEDDISP+CAEDMEM) SPECIFY THAT          23560021
*                                  THE MEMBER IS NEW AND THAT           23580021
*                                  THE DATA SET IS TO BE TREATED        23600021
*                                  AS NEW.                              23620021
         B     IN002150       BRANCH TO UNALLOCATE THE DATA SET.        23640021
IN002480 EQU   *                                                        23660021
         LA    ERR1REG,INERRORI RELATIVE ERROR TO BE PROCESSED.         23680021
         LH    DATA1REG,INDSN+INMEMLL LENGTH OF MEMBER NAME.            23700021
         B     IN010010       BRANCH TO CALL IKJEBEIA TO PUT            23720021
*                                  ERROR MESSAGE AND RETURN.            23740021
         EJECT                                                          23760021
*********************************************************************** 23780021
*                                                                     * 23800021
*   LOCATE POINTER TO THIS TASKS TIOT BY WAY OF THE CVT.  SEARCH THE  * 23820021
*   TIOT FOR THE DDNAME.  WHEN THE DDNAME IS FOUND, OBTAIN THE VOLUME * 23840021
*   SERIAL NUMBER FROM THE UCB POINTED TO BY THE TIOT ENTRY.  ISSUE   * 23860021
*   THE OBTAIN SVC TO READ THE DSCB FOR THE DATA SET INTO MAIN        * 23880021
*   STORAGE.                                                          * 23900021
*                                                                     * 23920021
*********************************************************************** 23940021
IN002005 EQU   *                                                        23960021
         OI    CAEDFLAG,CAEDMEM INDICATE THAT MEMBER IS OLD.            23980021
IN002010 EQU   *                                                        24000021
         L     AREAREG,CVTPTR ADDRESS OF CVT.                           24020021
         USING CVT,AREAREG    ADDRESSABILITY IN CVT DSECT.              24040021
         L     AREAREG,CVTTCBP ADDRESS OF NEXT AND CURRENT TCB          24060021
*                                  POINTERS.                            24080021
         DROP  AREAREG                                                  24100021
         L     AREAREG,CURNTTCB(PARMREG0,AREAREG) ADDRESS OF            24120021
*                                  CURRENT TCB.                         24140021
         L     AREAREG,(TCBTIO-TCB)(,AREAREG) ADDRESS OF TIOT.          24160021
         USING IEFTIOT1,AREAREG ADDRESSABILITY IN TIOT DSECT.           24180021
IN002050 EQU   *                                                        24200021
         SR    LENREG,LENREG  ZERO LENGTH REGISTER.                     24220021
         IC    LENREG,TIOELNGH LENGTH OF TIOT ENTRY.                    24240021
         LTR   LENREG,LENREG  CHECK IF END OF TIOT REACHED.             24260021
         BZ    IN002055       IF END OF TIOT, BRANCH TO PUT ERROR       24280021
*                                  MESSAGE AND RETURN TO TMP.           24300021
         CLC   TIOEDDNM(L'CAEDDDN),CAEDDDN CHECK IF THIS ENTRY IS       24320021
*                                  FOR THE EDIT DATA SET.               24340021
         BE    IN002060       IF SO, BRANCH TO GET UCB ADDRESS.         24360021
         LA    AREAREG,D0(LENREG,AREAREG) UPDATE TIOT POINTER TO        24380021
*                                  NEXT ENTRY.                          24400021
         B     IN002050       BRANCH TO CHECK NEXT ENTRY IN TIOT.       24420021
IN002055 EQU   *                                                        24440021
         LA    ERR1REG,INERRORF RELATIVE ERROR TO BE PROCESSED.         24460021
         LA    ERR2REG,M4245  RELATIVE SECOND-LEVEL MESSAGE.            24480021
         B     IN010010            BRANCH TO CALL IKJEBIN3 TO PUT       24500021
*                                  MESSAGE TO THE TERMINAL.             24520021
IN002060 EQU   *                                                        24540021
         L     AREAREG,TIOEFSRT-D1 ADDRESS OF UCB.                      24560021
         DROP  AREAREG                                                  24580021
         CLI   (UCBID-UCBOB)(AREAREG),INF255 DETERMINE IF MAIN          24600021
*                                  UCB OR 2321 SUB-UCB.                 24620021
         BE    IN002070       IF NOT FOR 2321, BRANCH TO GET            24640021
*                                  VOLUME SERIAL NUMBER.                24660021
         USING IEFUCBOB+(DATACELL-UCBOB),AREAREG ADDRESSABILITY         24680021
*                                  FOR SUB-UCB DSECT.                   24700021
         MVC   INCAMVLD(L'INCAMVLD),DCELVOLI MOVE VOLUME SERIAL         24720021
*                                  NUMBER TO WORK AREA FOR OBTAIN       24740021
         B     IN002080       BRANCH TO ISSUE OBTAIN SVC.               24760021
         DROP  AREAREG                                                  24780021
IN002070 EQU   *                                                        24800021
         USING IEFUCBOB,AREAREG ADDRESSABILITY IN UCB DSECT.            24820021
         TM    UCBTBYT3,UCB3DACC CHECK IF DIRECT ACCESS DEVICE.         24840021
         BNZ   IN002075       IF SO, CONTINUE NORMAL PROCESSING.        24860021
         LA    ERR1REG,INERRORQ SPECIFY RELATIVE ERROR.                 24880021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            24900021
*                                  ERROR MESSAGE AND RETURN.            24920021
IN002075 EQU   *                                                        24940021
         MVC   INCAMVLD(L'INCAMVLD),SRTEVOLI MOVE VOLUME SERIAL         24960021
*                                  NUMBER TO WORK AREA FOR OBTAIN       24980021
IN002080 EQU   *                                                        25000021
         MVC   INCAMFLG(INCAMEND),INCAMLST INITIALIZE FLAGS FOR         25020021
*                                  OBTAIN.                              25040021
         LA    RETCDREG,CAEDDSN ADDRESS OF DATA SET NAME.               25060021
         LA    PARMREG0,INCAMVLD ADDRESS OF VOLUME SERIAL NUMBER.       25080021
         LA    PARMREG1,INCAMOBT ADDRESS OF OBTAIN WORKAREA.            25100021
         STM   RETCDREG,PARMREG1,INCAMDSN INITIALIZE POINTERS IN        25120021
*                                  OBTAIN PARAMETER LIST.               25140021
         OBTAIN INCAMFLG      OBTAIN DSCB FOR DATA SET.                 25160021
         B     IN002082(RETCDREG) BRANCH TO TABLE TO DIAGNOSE           25180021
*                                  RETURN CODE FROM OBTAIN.             25200021
*                                                                       25220021
*   THE BRANCH TABLE BELOW IS POSITION DEPENDENT.                       25240021
*                                                                       25260021
IN002082 EQU   *                                                        25280021
         B     IN002085       00 - NORMAL RETURN                        25300021
         B     IN002310       04 - REQUIRED VOLUME NOT MOUNTED          25320021
         B     IN002325       08 - DATA SET NOT ON VOLUME               25340021
         B     IN002084       12 - PERMANENT I/O ERROR                  25360021
         B     IN002084       16 - INVALID PARAMETERS TO OBTAIN         25380021
*                             20 - CCHH NOT WITHIN BOUNDARIES OF        25400021
*                                  VTOC EXTENT                          25420021
         EJECT                                                          25440021
*********************************************************************** 25460021
*                                                                       25480021
*   ISSUE COMMAND SYSTEM ERROR MESSAGE FOR OBTAIN RETURN CODES 12, 16   25500021
*   AND 20.                                                             25520021
*                                                                       25540021
*********************************************************************** 25560021
IN002084 EQU   *                                                        25580021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.         25600021
         LR    DATA2REG,RETCDREG SAVE RETURN CODE FOR MESSAGE.          25620021
         O     DATA2REG,INSVCOBT INDICATE ROUTINE NAME AS OBTAIN.       25640021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            25660021
*                                  ERROR MESSAGE AND RETURN.            25680021
         EJECT                                                          25700021
IN002085 EQU   *                                                        25720021
         DROP  AREAREG                                                  25740021
         LA    AREAREG,INCAMOBT ADDRESS OF DSCB RETURNED BY             25760021
*                             OBTAIN.                                   25780021
         USING IECDSCB1+(DS1FMTID-IECSDSL1),AREAREG                     25800021
*                                  ADDRESSABILITY IN DSCB DSECT.        25820021
         LA    PARMREG0,X1(,D0) SET TAG REGISTER TO 1.                  25840021
         MVC   CAUTILNO+D1(L'DS1LSTAR),DS1LSTAR SAVE LAST BLOCK         25860021
*                                  POINTER FOR CALCULATION OF           25880021
*                                  OLD DATA SET SIZE.                   25900021
         CLC   DS1LSTAR(L'DS1LSTAR),INDSMTY DETERMINE IF DATA SET       25920021
*                                  HAS BEEN WRITTEN INTO.               25940021
         BNE   IN002100       IF NOT ZERO, BRANCH TO CHECK DSORG.       25960021
         SR    PARMREG0,PARMREG0 SET TAG REGISTER TO ZERO.              25980021
         NI    CAEDFLAG,INF255-CAEDDISP INDICATE DATA SET IS            26000021
*                                  EMPTY AND IS TO BE PROCESSED         26020021
*                                  AS NEW.                              26040021
         CLI   DS1DSORG,DS1ORGPS DETERMINE IF SEQUENTIAL.               26060021
         BE    IN002110       IF DSORG=PS, BRANCH TO SET FLAG IN        26080021
*                                  THE COMMUNICATION AREA.              26100021
         CLI   DS1DSORG,D0    DETERMINE IF DSORG HAS BEEN               26120021
*                                  ESTABLISHED FOR THE DATA SET.        26140021
         BE    IN003100       IF DSORG IS NOT SET, BRANCH TO            26160021
*                                  PROCESS AS A NEW DATA SET.           26180021
         SPACE 5                                                        26200021
IN002090 EQU   *                                                        26220021
*********************************************************************** 26240021
*                                                                       26260021
*   AN INVALID DSORG ENCOUNTERED, PUT MESSAGE TO USER AND RETURN        26280021
*   TO THE TMP.                                                         26300021
*                                                                       26320021
*********************************************************************** 26340021
         LA    ERR1REG,INERROR4 RELATIVE ERROR TO BE PROCESSED.         26360021
         LA    DATA1REG,DS1DSORG ADDRESS OF DSORG FIELD.                26380021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            26400021
*                                  ERROR MESSAGE AND RETURN.            26420021
         EJECT                                                          26440021
IN002100 EQU   *                                                        26460021
*                                                                       26480021
*   DATA SET CONTAINS RECORDS (DS1LSTAR NOT ZERO)                       26500021
*                                                                       26520021
         CLI   DS1DSORG,DS1ORGPS DETERMINE IF DSORG IS SEQUENTIAL       26540021
         BE    IN002110       IF PS, BRANCH TO CHECK RECFM.             26560021
         TM    DS1DSORG,DS1ORGPO DETERMINE IF DSORG IS          SA73470 26580021
*                                  PARTITIONED.                         26600021
         BNO   IN002090       IF NEITHER PS OR PO, BRANCH TO PUTSA73470 26620021
*                                  ERROR MESSAGE.                       26640021
         OI    CAEDFLAG,CAEDDSOR INDICATE DATA SET HAS DSORG = PO       26660021
IN002110 EQU   *                                                        26680021
*                                                                       26700021
*   DSORG = PS OR PO.                                                   26720021
*                                                                       26740021
         TM    DS1RECFM,DS1FMSTD+DS1FMOVF+DS1FMA+DS1FMM CHECK FOR       26760021
*                                  STANDARD BLOCKS, TRACK               26780021
*                                  OVERFLOW, ASA CONTROL                26800021
*                                  CHARACTERS OR MACHINE CONTROL        26820021
*                                  CHARACTERS.                          26840021
         BNZ   IN002120       IF ANY OF THE ABOVE ARE REFLECTED         26860021
*                                  IN RECORD FORMAT, BRANCH TO          26880021
*                                  INFORM USER THAT DATA SET IS         26900021
*                                  NOT ACCEPTABLE FOR EDIT.             26920021
         TM    DS1RECFM,DS1FMUDF DETERMINE IF UNDEFINED FORMAT          26940021
*                                  WAS SPECIFIED.                       26960021
         BNO   IN002130       IF NOT UNDEFINED, BRANCH TO               26980021
*                                  DETERMINE FORMAT.                    27000021
         SPACE 5                                                        27020021
IN002120 EQU   *                                                        27040021
*********************************************************************** 27060021
*                                                                       27080021
*   INVALID RECORD FORMAT ENCOUNTERED, PUT MESSAGE TO USER AND          27100021
*   RETURN TO THE TMP.                                                  27120021
*                                                                       27140021
*********************************************************************** 27160021
         LA    ERR1REG,INERROR5 RELATIVE ERROR TO BE PROCESSED.         27180021
         LA    DATA1REG,DS1RECFM ADDRESS OF RECFM FIELD.                27200021
         B     IN010010       BRANCH TO CALL IKJEBEIA TO PUT            27220021
*                                  ERROR MESSAGE AND RETURN.            27240021
         EJECT                                                          27260021
IN002130 EQU   *                                                        27280021
*                                                                       27300021
*   DSORG PS OR PO AND RECFM IS FIXED OR VARIABLE -- DETERMINE          27320021
*   WHICH.                                                              27340021
*                                                                       27360021
         TM    DS1RECFM,DS1FMVAR DETERMINE IF RECFM = V.                27380021
         BO    IN002140       IF RECFM=V, BRANCH TO OBTAIN LRECL.       27400021
         TM    DS1RECFM,DS1FMFX DETERMINE IF RECFM = F.          A42947 27420021
         BO    IN002135       IF RECFM=F, SET RECFM SWITCH.      A42947 27440021
*                                                                A42947 27460021
*   RECFM NOT INITIALIZED FOR DATA SET -- DETERMINE DEFAULT.     A42947 27480021
*                                                                A42947 27500021
         TM    CARECFMD,CARECFMV DETERMINE IF RECFM=V IS DEFLT.  A42947 27520021
         BO    IN002140       IF RECFM DEFLT = V, OBTAIN LRECL.  A42947 27540021
IN002135 EQU   *                                                 A42947 27560021
         OI    CACFLAG2,CARECFM INDICATE THAT DATA SET HAS              27580021
*                                  RECFM = F.                           27600021
IN002140 EQU   *                                                        27620021
         MVC   CALRECL(L'CALRECL),DS1LRECL MOVE LRECL TO THE            27640021
*                                  COMMUNICATION AREA.                  27660021
         LTR   PARMREG0,PARMREG0 CHECK TAG REGISTER AND SET NEW         27680021
         BZ    IN003100            FLAG BASED ON DS1LSTAR CONTENT       27700021
         OI    CAEDFLAG,CAEDDISP INDICATE THAT DATA SET IS OLD.         27720021
         MVC   CABLKS(L'CABLKS),DS1BLKL UPDATE BLOCK SIZE FOR OLD       27740021
*                                  DATA SETS.                           27760021
         TM    CAEDFLAG,CAEDDSOR CHECK IF DSORG = PO.                   27780021
         BZ    IN002940       IF NOT PO, BRANCH TO VALIDATE             27800021
*                                  COMMAND OPERANDS.                    27820021
IN002150 EQU   *                                                        27840021
*                                                                       27860021
*   UNALLOCATE THE DATA SET.                                            27880021
*                                                                       27900021
         L     PASSREG,CAPTTMP ADDRESS OF TMP PARAMETER LIST.           27920021
         L     PASSREG,(CPPLPSCB-CPPL)(,PASSREG) ADDRESS OF PSCB.       27940021
         LA    AREAREG,CAEDDSNL ADDRESS OF DATA SET NAME LENGTH         27960021
*                                  AND DATA SET NAME.                   27980021
         MVC   INDREC(INDR18L),INDR18 INITIALIZE IKJDAIR                28000021
*                                  PARAMETER LIST - ENTRY CODE 18       28020021
         ST    AREAREG,INDREC+(DA18PDSN-DAPB18) PUT ADDRESS OF          28040021
*                                  DSNAME IN PARAMETER LIST.            28060021
         LA    AREAREG,INDREC ADDRESS OF IKJDAIR PARAMETER LIST.        28080021
         LINK  EP=IKJDAIR,PARAM=(,,,(PASSREG),(AREAREG)),              X28100021
               MF=(E,CATMPLST) LINK TO IKJDAIR.                         28120021
         LTR   RETCDREG,RETCDREG TEST FOR RETURN CODE OF ZERO.          28140021
         BZ    IN002190       IF NOT, BRANCH TO CONTINUE NORMAL         28160021
*                                  PROCESSING.                          28180021
         CH    RETCDREG,INDRRC24 CHECK IF DATA SET UNALLOCATED  A59609  28200021
*                                  BELONGS TO CONCATENATED GRP. A59609  28210021
         BE    IN002190       IF SO, BRANCH TO CONTINUE PROCESS A59609  28220021
IN002160 EQU   *                                                A59609  28230021
         CH    RETCDREG,INDAIR08 CHECK FOR CATALOG ERROR.       A59609  28240021
         BL    IN002270       INVALID PARAMETERS, SEND MESSAGE. A59609  28250021
         BE    IN002170       CATLG MGMT ERROR, SEND MESSAGE.   A59609  28260021
         CH    RETCDREG,INDAIR16 CHECK FOR DYN ALLOC. ERROR.    A59609  28270021
         BL    IN002180       IF SO, SEND MESSAGE.              A59609  28280021
         CH    RETCDREG,INDAIR48 CHECK IF DAIR STAE ENTERED.    A59609  28290021
         BE    INEXIT12       IF SO, BR TO RETURN TO TMP,RC=12. A59609  28300021
         B     IN002270       OTHERWISE, BR TO SEND GENERAL     A59609  28310021
*                                  ERROR MESSAGE.               A59609  28320021
IN002170 EQU   *                                                        28440021
         LA    ERR2REG,M4244  SPECIFY CATALOG ERROR.                    28460021
         LH    DATA2REG,INDREC+(DA18CTRC-DAPB18) ACQUIRE CTRC.          28480021
         B     IN002185       BRANCH TO CONTINUE ERROR PROCESSING.      28500021
IN002180 EQU   *                                                        28520021
         LA    ERR2REG,M4242  SPECIFY DYNAMIC ALLOCATION ERROR.         28540021
         LH    DATA2REG,INDREC+(DA18DARC-DAPB18) ACQUIRE DARC.          28560021
IN002185 EQU   *                                                        28580021
         LA    ERR1REG,INERRORF SPECIFY RELATIVE ERROR.                 28600021
         B     IN010010       BRANCH TO CALL IKJEBIN3 TO PUT            28620021
*                                  MESSAGE TO THE TERMINAL.             28640021
IN002190 EQU   *                                                        28660021
         NI    CAEDFLAG,INF255-CAEDALOC INDICATE DATA SET NO            28680021
*                                  LONGER ALLOCATED.                    28700021
         TM    CAEDFLAG,CAEDMEM CHECK IF NEW MEMBER IS TO BE            28720021
*                                  CREATED.                             28740021
         BZ    IN003100       IF SO, BRANCH TO VALIDATE COMMAND         28760021
*                                  OPERANDS.                            28780021
*                                                                       28800021
*   ALLOCATE DATA SET WITH MEMBER NAME SPECIFIED.                       28820021
*                                                                       28840021
         MVC   INDREC(INDR8OLL),INDAIR8O INITIALIZE IKJDAIR             28860021
*                                  PARAMETER LIST.                      28880021
         MVC   INDREC+(DA08MNM-DAPB08)(L'CAEDMEMB),CAEDMEMB MOVE        28900021
*                                  MEMBER NAME TO PARAMETER LIST.       28920021
         TM    INDSN+INPSWFLG,INOPRNDO DETERMINE IF PASSWORD WAS        28940021
*                                  ENTERED.                             28960021
         BZ    IN002930       IF NOT, BRANCH TO CALL IKJDAIR.           28980021
         MVC   INDREC+(DA08PSWD-DAPB08)(L'CAEDPSWD),CAEDPSWD MOVE       29000021
*                                  PASSWORD TO PARAMETER LIST.          29020021
IN002930 EQU   *                                                        29040021
         LA    AREAREG,CAEDDSNL GET ADDRESS OF DSNAME AND PLACE         29060021
         ST    AREAREG,INDREC+(DA08PDSN-DAPB08) IN IKJDAIR              29080021
*                                  PARAMETER LIST.                      29100021
         LA    AREAREG,INDREC ADDRESS OF IKJDAIR PARAMETER BLOCK.       29120021
         L     PASSREG,CAPTTMP ADDRESS OF TMP PARAMETER LIST.           29140021
         L     PASSREG,(CPPLPSCB-CPPL)(,PASSREG) ADDRESS OF PSCB.       29160021
         OI    INDREC+(DA08DSP1-DAPB08),DA08SHR INDICATE DISP=SHR       29180021
*                                  FOR OLD, PARTITIONED DATA SETS       29200021
         LINK  EP=IKJDAIR,PARAM=(,,,(PASSREG),(AREAREG)),              X29220021
               MF=(E,CATMPLST) LINK TO IKJDAIR.                         29240021
         LTR   RETCDREG,RETCDREG CHECK IF DATA SET ALLOCATED.           29260021
         BNZ   IN002260       IF DATA SET NOT ALLOCATED,        A59609  29280021
*                                  BRANCH TO SELECT DIAGNOSTIC          29300021
*                                  AND RETURN TO TMP.                   29320021
         OI    CAEDFLAG,CAEDALOC INDICATE DATA SET ALLOCATED.           29340021
         MVC   CAEDDDN(L'CAEDDDN),INDREC+(DA08DDN-DAPB08) MOVE          29360021
*                                  DDNAME RETURNED BY IKJDAIR TO        29380021
*                                  THE COMMUNICATION AREA.              29400021
IN002940 EQU   *                                                        29420021
*                                                                       29440021
*   AN OLD SEQUENTIAL DATA SET OR AN EXISTING PARTITIONED DATA          29460021
*   SET(MEMBER) HAS BEEN SUCCESSFULLY ALLOCATED, AND ITS DDNAME         29480021
*   AND LRECL ARE IN THE COMMUNICATION AREA.                            29500021
*                                                                       29520021
         SR    PARMREG0,PARMREG0 SET ENTRY CODE TO ZERO FOR             29540021
*                                  IKJEBIN8 (OPERAND VALIDATION)        29560021
*                                  SUBROUTINE.                          29580021
         B     IN003110       BRANCH TO CALL IKJEBIN8.                  29600021
         EJECT                                                          29620021
*********************************************************************** 29640021
*                                                                       29660021
*   CALL OPERAND VALIDITY CHECKING ROUTINE TO VERIFY THAT ALL           29680021
*   OPERANDS SPECIFIED ON THE COMMAND ARE ACCEPTABLE.  UPON             29700021
*   RETURN FROM IKJEBIN8, TEST THE RETURN CODE FOR SUCCESSFUL           29720021
*   COMPLETION.  IF SUCCESSFUL (RETURN CODE = 0), BRANCH TO XCTL        29740021
*   TO IKJEBEMA.  IF UNSUCCESSFUL (RETURN CODE  = 4), BRANCH TO         29760021
*   TERMINATE EDIT.                                                     29780021
*                                                                       29800021
*   NOTE -- AN ENTRY CODE IS SET IN REGISTER ZERO (0) PRIOR TO          29820021
*           CALLING IKJEBIN8 --                                         29840021
*                                                                       29860021
*               00 - OLD DATA SET                                       29880021
*               04 - NEW DATA SET                                       29900021
*                                                                       29920021
*********************************************************************** 29940021
         SPACE 2                                                        29960021
IN003100 EQU   *                                                        29980021
         LA    PARMREG0,D4(,D0) SET ENTRY CODE FOR IKJEBEIE             30000021
*                                        (OPERAND VALIDATION) ROUTINE.  30020021
IN003110 EQU   *                                                        30040021
         CALL  IKJEBIN8,((COMMREG),(DATAREG)),                         X30060021
               MF=(E,INSVCRTN) CALL OPERAND VALIDATION ROUTINE.         30080021
         LTR   RETCDREG,RETCDREG CHECK FOR SUCCESSFUL COMPLETION.       30100021
         BNZ   INEXIT1        IF IKJEBIN8 RETURNED A NON-ZERO           30120021
*                                  RETURN CODE, BRANCH TO RETURN        30140021
*                                  TO THE TMP.                          30160021
         EJECT                                                          30180021
IN008030 EQU   *                                                        30200021
*********************************************************************** 30220021
*                                                                     * 30240021
*   CHECK STATUS OF EDIT DATA SET.                                    * 30260021
*                                                                     * 30280021
*   COMPUTE LOGICAL RECORD SIZE FOR ALL SUBCOMMAND PROCESSORS AND     * 30300021
*   SERVICE ROUTINES. EDIT LRECL IS THE LRECL FOR THE DATA SET + 4    * 30320021
*   (LENGTH OF CONTROL WORD FOR EACH).                                * 30340021
*                                                                     * 30360021
*   DETERMINE WHETHER DATA SET IS OLD OR NEW.  IF DATA SET IS NEW,    * 30380021
*   SET INDICATION THAT INPUT MODE SHOULD BE ENTERED INITIALLY.  IF   * 30400021
*   DATA SET IS OLD, CHECK IF A PARTITIONED DATA SET.  IF NOT A       * 30420021
*   PDS, LOAD IKJEBEUT (THE EDIT UTILITY INTERFACE ROUTINE) INTO      * 30440021
*   MAIN STORAGE AND INITIALIZE 'CAPTUT' IN THE EDIT COMMUNICATION    * 30460021
*   AREA WITH ITS ENTRY POINT ADDRESS.  CALL IKJEBECO TO COPY THE     * 30480021
*   EDIT DATA SET TO THE UTILITY DATA SET.  IF A PDS, PERFORM THE     * 30500021
*   COPY ONLY IF THE MEMBER EXISTS.  UPON RETURN FROM IKJEBECO,       * 30520021
*   DELETE THE UTILITY INTERFACE ROUTINE (IKJEBEUT).                  * 30540021
*                                                                     * 30560021
*********************************************************************** 30580021
         TM    CACFLAG2,CARECFM CHECK IF RECFM IS VARIABLE.             30600021
         BZ    IN008035       IF RECFM = V, LRECL ALREADY IS 4          30620021
*                                  GREATER THAN DATA PORTION OF         30640021
*                                  RECORD, BRANCH AROUND                30660021
*                                  COMPUTATION FOR RECFM = F.           30680021
         LH    LENREG,CALRECL OBTAIN LRECL FOR EDIT DATA SET.           30700021
         LA    LENREG,D4(PARMREG0,LENREG) ADD 4 TO LRECL (FOR           30720021
         STH   LENREG,CALRECL      CONTROL WORD) AND SAVE.              30740021
IN008035 EQU   *                                                        30760021
         TM    CAEDFLAG,CAEDDSOR CHECK IF DSORG = PS.                   30780021
         BZ    IN008040       IF DSORG = PS, BRANCH TO CHECK            30800021
*                                  NEW/OLD STATUS.                      30820021
         TM    CAEDFLAG,CAEDMEM  WHEN DSORG = PO, CHECK IF              30840021
*                                  MEMBER ALREADY EXISTS.               30860021
         BO    IN009010       IF MEMBER EXISTS, BRANCH TO CALL          30880021
*                                  IKJEBECO.                            30900021
         B     IN009030       IF MEMBER IS TO BE CREATED, BRANCH        30920021
*                                  TO CALL IKJEBEUI.                    30940021
IN008040 EQU   *                                                        30960021
         TM    CAEDFLAG,CAEDDISP CHECK IF DISPOSITION IS OLD.           30980021
         BZ    IN009030       IF NEW, BRANCH TO INDICATE INPUT          31000021
*                                  MODE TO BE CALLED.                   31020021
IN009010 EQU   *                                                        31040021
         OI    CAEDFLAG,CAEDINCP INDICATE TO INITIAL COPY THAT          31060021
*                                  EDIT DATA SET IS TO BE COPIED.       31080021
         LOAD  EP=IKJEBEUT    LOAD UTILITY INTERFACE ROUTINE.           31100021
         ST    PARMREG0,CAPTUT SAVE ENTRY POINT ADDRESS IN THE          31120021
*                                  COMMUNICATION AREA.                  31140021
         IKJEBESH (COMMREG),IKJEBECO,PARAM=((COMMREG)),                X31160021
               MF=(E,INSVCRTN) CALL INITIAL COPY ROUTINE.               31180021
         NI    CAEDFLAG,INF255-CAEDINCP TURN OF INITIAL COPY FLAG       31200021
*                                  FOR EDIT DATA SET.                   31220021
IN009020 EQU   *                                                        31240021
         B     IN009020+D4(RETCDREG) IKJEBECO RETURN CODE BRANCH        31260021
*                                  TABLE.                               31280021
         B     IN009025       RETURN CODE 0, BRANCH TO DELETE           31300021
*                                  IKJEBEUT.                            31320021
         B     IN009060       RETURN CODE 4, BRANCH TO INDICATE         31340021
*                                  INPUT MODE TO BE INITIALLY           31360021
*                                  ENTERED.                             31380021
         B     INEXIT1        RETURN CODE = 8, BRANCH TO RETURN         31400021
*                                  TO THE TMP.                          31420021
IN009025 EQU   *                                                        31440021
         DELETE EP=IKJEBEUT   DELETE UTILITY INTERFACE ROUTINE         X31460021
                                   FROM MAIN STORAGE.                   31480021
         B     IN009067       BRANCH TO UNALLOCATE DATA SET (IF A       31500021
*                                  PDS) AND XCTL TO IKJEBEMA.           31520021
         EJECT                                                          31540021
IN009030 EQU   *                                                        31560021
*********************************************************************** 31580021
*                                                                     * 31600021
*   DATA SET IS NEW.                                                  * 31620021
*                                                                     * 31640021
*   WHEN A NEW DATA SET IS TO BE PROCESSED, LINK TO IKJEBEUI TO       * 31660021
*   INITIALIZE THE EDIT ACCESS METHOD.  UPON RETURN FROM IKJEBEUI,    * 31680021
*   DETERMINE IF IKJEBEUI WAS SUCCESSFUL.  IF IKJEBEUI IS NOT         * 31700021
*   SUCCESSFUL, BRANCH TO INFORM USER AND TO RETURN TO TMP.           * 31720021
*                                                                     * 31740021
*   IF IKJEBEUI IS SUCCESSFUL, PLACE ADDRESS OF UTILITY DCB IN THE    * 31760021
*   COMMUNICATION AREA AND XCTL TO IKJEBEMA.                          * 31780021
*                                                                     * 31800021
*********************************************************************** 31820021
         LINK  EP=IKJEBEUI,DCB=0,MF=(E,(COMMREG)),SF=(E,INLINKSF)       31840021
         LTR   RETCDREG,RETCDREG CHECK IF IKJEBEUI SUCCESSFULLY         31860021
*                                  INITIALIZED ACCESS METHOD.           31880021
         BNZ   INEXIT1        IF UNSUCCESSFUL, BRANCH TO RETURN         31900021
*                                  TO TMP.                              31920021
         ST    PARMREG0,CAPTCDCB SAVE ADDRESS OF DCB IN                 31940021
*                                  COMMUNICATION AREA.                  31960021
IN009060 EQU   *                                                        31980021
         TM    CAEDFLAG,CAEDDSOR CHECK IF DSORG = PS.                   32000021
         BZ    IN009065       IF DSORG = PS, BRANCH TO INDICATE         32020021
*                                  INPUT MODE BE ENTERED.               32040021
         NI    CAEDFLAG,INF255-CAEDMEM FOR DSORG = PO, INDICATE         32060021
*                                  THAT MEMBER IS TO BE CREATED.        32080021
         B     IN009070       BRANCH TO XCTL TO IKJEBEMA.               32100021
IN009065 EQU   *                                                        32120021
         NI    CAEDFLAG,INF255-CAEDDISP INDICATE THAT DATA SET IS       32140021
*                                  NEW AND THAT IKJEBEIP TO BE          32160021
*                                  ENTERED INITIALLY.                   32180021
         B     IN009070       BRANCH TO XCTL TO IKJEBEMA.               32200021
         EJECT                                                          32220021
IN009067 EQU   *                                                        32240021
*********************************************************************** 32260021
*                                                                     * 32280021
*   UNALLOCATE DATA SET IF EDIT DATA SET IS AN OLD PARTITIONED DATA   * 32300021
*   SET.                                                              * 32320021
*                                                                     * 32340021
*********************************************************************** 32360021
         TM    CAEDFLAG,CAEDALOC+CAEDMEM+CAEDDSOR CHECK IF EDIT         32380021
*                                  DATA SET IS AN OLD PDS THAT IS       32400021
*                                  CURRENTLY ALLOCATED.                 32420021
         BNO   IN009070       IF NOT OLD AND ALLOCATED, BRANCH TO       32440021
*                                  XCTL TO THE MAIN CONTROLLER.         32460021
         L     PASSREG,CAPTTMP ADDRESS OF TMP PARAMETER LIST.           32480021
         L     PASSREG,(CPPLPSCB-CPPL)(,PASSREG) ADDRESS OF PSCB.       32500021
         LA    AREAREG,CAEDDSNL ADDRESS OF DATA SET NAME LENGTH         32520021
*                                  AND DATA SET NAME.                   32540021
         MVC   INDREC(INDR18L),INDR18 INITIALIZE IKJDAIR                32560021
*                                  PARAMETER LIST - ENTRY CODE 18       32580021
         MVC   INDREC+(DA18MNM-DAPB18)(L'CAEDMEMB),CAEDMEMB MOVE        32600021
*                                  MEMBER NAME TO PARAMETER LIST.       32620021
         ST    AREAREG,INDREC+(DA18PDSN-DAPB18) PUT ADDRESS OF          32640021
*                                  DSNAME IN PARAMETER LIST.            32660021
         LA    AREAREG,INDREC ADDRESS OF IKJDAIR PARAMETER LIST.        32680021
         LINK  EP=IKJDAIR,PARAM=(,,,(PASSREG),(AREAREG)),             XX32700021
               MF=(E,CATMPLST) LINK TO IKJDAIR.                         32720021
         LTR   RETCDREG,RETCDREG TEST FOR RETURN CODE OF ZERO.          32740021
         BZ    IN009068       IF RETURN CODE IS ZERO, BRANCH TO         32760021
*                                  CONTINUE NORMAL PROCESSING.          32780021
         CH    RETCDREG,INDRRC24 CHECK FOR RETURN CODE 24               32800021
*                                  (DECIMAL) FROM IKJDAIR.              32820021
         BNE   IN002160       IF NOT 24, BRANCH TO DIAGNOSE     A59609  32840021
*                                  IKJDAIR ERROR RETURN CODE.           32860021
IN009068 EQU   *                                                        32880021
         NI    CAEDFLAG,INF255-CAEDALOC INDICATE DATA SET NO            32900021
*                                  LONGER ALLOCATED.                    32920021
         EJECT                                                          32940021
IN009070 EQU   *                                                        32960021
*********************************************************************** 32980021
*                                                                     * 33000021
*   TRANSFER CONTROL TO MAIN CONTROLLER.                              * 33020021
*                                                                     * 33040021
*   FREE IKJPARSE PDL USING THE IKJRLSA MACRO INSTRUCTION.  BUILD     * 33060021
*   PARAMETER LIST FOR XCTL.  FREE THIS ROUTINES SAVE AREA AND        * 33080021
*   XCTL TO IKJEBEMA.                                                 * 33100021
*                                                                     * 33120021
*********************************************************************** 33140021
         L     AREAREG,INPDLPTR ADDRESS OF PROMPT PDL.           A45713 33160021
         LTR   AREAREG,AREAREG CHECK IF PROMPT PDL PRESENT.      A45713 33180021
         BNP   IN009075       IF NO, BRANCH TO FREE MAIN PDL.    A45713 33200021
         IKJRLSA INPDLPTR     FREE PROMPT PDL.                   A45713 33220021
         L     AREAREG,INPGLIST+PGPBIBUF-PGPB PROMPT BFR ADDR.   A45713 33240021
         LH    PARMREG0,D0(,AREAREG) LENGTH OF PROMPT BUFFER.    A45713 33260021
         L     PARMREG1,INPGLIST+PGPBIBUF-PGPB PTR TO BFR ADDR.  A45713 33280021
         O     PARMREG0,INSUBPL1 INDICATE SUBPOOL ONE.           A45713 33300021
         FREEMAIN R,LV=(0),A=(1) FREE PUTGET PROMPT BFR.         A45713 33320021
IN009075 EQU   *                                                 A45713 33340021
         IKJRLSA CAPTPRSD     FREE IKJPARS PDL.                         33360021
         OI    CAPRSPDL,CAFREEDL INDICATE THAT NO PDL REMAINS TO        33380021
*                                  BE FREEMAINED.                       33400021
         TM    CACFLAG1,CANONUM TEST IF DATA SET IS LINE NUMBERED       33420021
*                                  SO THAT DEFAULT INCREMENTS MAY       33440021
*                                  BE SET ACCORDINGLY.                  33460021
         BZ    IN009080       IF DATA SET IS NUMBERED, BRANCH TO        33480021
*                                  DEFAULT INCREMENTS TO 10.            33500021
         MVC   CAINCRE(L'CAINCRE),ININC100 SET DATA SET INCREMENT       33520021
         MVC   CAIMLINC(L'CAIMLINC),ININC100 AND LAST INCREMENT         33540021
*                                  USED IN INPUT MODE TO 100 FOR        33560021
*                                  NON-LINE NUMBERED DATA SETS.         33580021
         B     IN009090       BRANCH TO TRANSFER CONTROL TO THE         33600021
*                                  MAIN CONTROLLER (IKJEBEMA).          33620021
IN009080 EQU   *                                                        33640021
         MVC   CAINCRE(L'CAINCRE),ININC010 SET DATA SET INCREMENT       33660021
         MVC   CAIMLINC(L'CAIMLINC),ININC010 AND LAST INCREMENT         33680021
*                                  USED IN INPUT MODE TO 10 FOR         33700021
*                                  LINE NUMBERED DATA SETS.             33720021
         OI    CACFLAG3,CAIMPT INDICATE THAT USER TO BE PROMPTED.       33740021
IN009090 EQU *                                                          33760021
         MVC   INXCTLPL(INXCTLLN),INXCTL INITIALIZE XCTL                33780021
*                                  PARAMETER LIST.                      33800021
         DROP  DATAREG                                                  33820021
         LR    PARMREG1,SAVEREG ADDRESS OF SAVE/WORK AREA.              33840021
         L     SAVEREG,D4(PARMREG0,SAVEREG) ADDRESS OF HIGHER           33860021
*                                  SAVE AREA                            33880021
         L     RETREG,D12(,SAVEREG) ADDRESS OF RETURN POINT.     A42958 33900021
         XC    D0(D72,PARMREG1),D0(PARMREG1) ZERO SAVE AREA.            33920021
         XCTL  (2,12),EP=IKJEBEMA,MF=(E,(COMMREG)),              A42958*33940021
               SF=(E,INXCTLPL)                                   A42958 33960021
*                                  XCTL TO IKJEBEMA.                    33980021
         EJECT                                                          34000021
*********************************************************************** 34020021
*                                                                     * 34040021
*   CALL IKJEBIN3 TO ISSUE ERROR MESSAGE TO USER.  UPON RETURN        * 34060021
*   FROM IKJEBIN3, SET RETURN CODE TO 12 AND RETURN TO THE TMP.       * 34080021
*                                                                     * 34100021
*********************************************************************** 34120021
IN010010 EQU   *                                                        34140021
         L     EPLOCREG,INMSGRTN ADDRESS OF MESSAGE ROUTINE.            34160021
         CALL  (15),((COMMREG),(ERR1REG),(ERR2REG),(DATA1REG),         X34180021
               (DATA2REG)),MF=(E,INSVCRTN) BRANCH TO PUT ERROR         X34200021
                                   MESSAGE.                             34220021
INEXIT12 EQU   *                                                A59609  34230021
         LA    TMPCDREG,D12(,D0) SET RETURN CODE 12 FOR TMP.            34240021
         EJECT                                                          34260021
INEXIT0  EQU   *                                                        34280021
*********************************************************************** 34300021
*                                                                     * 34320021
*   EXIT AREA -- AN ERROR WAS ENCOUNTERED DURING INITIALIZATION OF    * 34340021
*   THE EDIT COMMAND.  ON EXIT, (1) RELEASE THE IKJPARSE PDL USING    * 34360021
*   THE IKJRLSA MACRO INSTRUCTION, (2) CALL IKJEBESR TO DELETE THE    * 34380021
*   PERMANENTLY RESIDENT SERVICE ROUTINES, (3) DELETE IKJEBESR USING  * 34400021
*   THE DELETE MACRO INSTRUCTION, (4) ISSUE A FREEMAIN MACRO          * 34420021
*   INSTRUCTION FOR THE BLDL LIST AND THE COMMUNICATION AREA, AND     * 34440021
*   (5) RETURN TO THE TMP WITH A RETURN CODE OF 12.                   * 34460021
*                                                                     * 34480021
*********************************************************************** 34500021
INEXIT1  EQU   *                                                        34520021
         TM    CAPRSPDL,CAFREEDL CHECK IF PDL EXISTS.                   34540021
         BNZ   INEXIT2        IF NOT, BRANCH TO EXIT.                   34560021
         IKJRLSA CAPTPRSD     FREE IKJPARS PDL.                         34580021
INEXIT2  EQU   *                                                        34600021
         DELETE EP=IKJEBEMS   DELETE MESSAGE SELECTION ROUTINE         X34620021
                                   FROM MAIN STORAGE.                   34640021
         TCLEARQ INPUT        CLEAR INPUT QUEUES.                       34660021
         MVC   CASRPLST+D4(INSTPBLN),INSTKPRM MOVE STACK PARAMETER      34680021
*                                  BLOCK TO DYNAMIC AREA.               34700021
         LA    EPLOCREG,CASRPLST+D4 ADDRESS OF STACK PARAMETER BLOCK.   34720021
         ST    EPLOCREG,CATMPLST+IOPLIOPB-IOPL STORE ADDRESS IN         34740021
*                                  SERVICE ROUTINE PARAMETER LIST.      34760021
         STACK MF=(E,CATMPLST) DELETE ALL ELEMENTS BUT TERMINAL        X34780021
                                   FROM INPUT STACK.                    34800021
         L     SAVEREG,D4(,SAVEREG) ADDRESS OF NEXT HIGHER SAVE         34820021
*                                  AREA.                                34840021
         FREEMAIN R,LV=CADLEN,A=(COMMREG),SP=SUBPOOL FREE THE          X34860021
                                   COMMUNICATION AREA.                  34880021
         RETURN (14,12),,RC=12 RETURN TO THE TMP.                       34900021
         EJECT                                                          34920021
*********************************************************************** 34940021
*                                                                     * 34960021
*   PROMPT USER FOR NEW OR OLD OPERAND.                               * 34980021
*                                                                     * 35000021
*   BUILD A BLANK BUFFER AND LINK TO IKJPARS TO PROMPT USER FOR       * 35020021
*   NEW OR OLD OPERAND.  UPON RETURN FROM IKJPARS, TEST RETURN CODE   * 35040021
*   FOR SUCCESSFUL COMPLETION.  IF A NON-ZERO RETURN CODE IS          * 35060021
*   RETURNED, BRANCH TO DIAGNOSE ERROR.  OTHERWISE, DETERMINE USER    * 35080021
*   RESPONSE, FREE PDL, AND RETURN TO CALLER.                         * 35100021
*                                                                     * 35120021
*********************************************************************** 35140021
INDISPPR EQU   *                                                        35160021
         MVI   INTEMPBF,CHRBLANK INITIALIZE BUFFER TO BLANKS SO         35180021
         MVC   INTEMPBF+D1(L'INTEMPBF-D1),INTEMPBF THAT IKJPARS         35200021
*                                  WILL PROMPT FOR DISPOSITION.         35220021
         MVC   INTEMPBF(L'INBUFRCW),INBUFRCW INITIALIZE BUFFER          35240021
*                                  CONTROL WORD.                        35260021
         L     PCLREG,INDISPDL ADDRESS OF PCL FOR IKJPARS.              35280021
         LA    AREAREG,INTEMPBF ADDRESS OF BUFFER.                      35300021
         LA    PDLREG,INCOREPT ADDRESS OF AREA IN WHICH IKJPARS         35320021
*                                  RETURNS ADDRESS OF PDL.              35340021
         XC    CATMPLST+(PPLPCL-PPL)(PPLUWA-PPLPCL+L'PPLUWA),CATMPLST+(X35360021
               PPLPCL-PPL)    ZERO IKJPARS PORTION OF PARAMETER         35380021
*                                  LIST.                                35400021
         ST    PCLREG,CATMPLST+PPLPCL-PPL INITIALIZE IKJPARS            35420021
         ST    PDLREG,CATMPLST+PPLANS-PPL PARAMETER LIST WITH           35440021
         ST    AREAREG,CATMPLST+PPLCBUF-PPL PCL, BUFFER, ANS. PTRS      35460021
         LINK  EP=IKJPARS,DCB=0,                                       *35480021
               MF=(E,CATMPLST),SF=(E,INLINKSF)                          35500021
         LTR   RETCDREG,RETCDREG TEST FOR SUCCESSFUL COMPLETION.        35520021
         BNZ   IN001060       IF NOT SUCCESSFUL, BRANCH TO              35540021
*                                  DIAGNOSE ERROR.                      35560021
         L     AREAREG,INCOREPT ADDRESS OF PDL BUILT                    35580021
*                                  BY IKJPARS.                          35600021
         USING INDISPD,AREAREG ESTABLISH ADDRESSABILITY TO PDL.         35620021
         L     FLAGREG,INDISPX OBTAIN ADDRESS OF USER RESPONSE.         35640021
         LH    LENREG,INDISPX+D4 LENGTH OF USER RESPONSE.               35660021
         BCTR  LENREG,D0      REDUCE LENGTH BY 1 FOR COMPARE.           35680021
         EX    LENREG,INCL001 DETERMINE IF NEW SPECIFIED.               35700021
         BNE   IN012020       IF NOT NEW, BRANCH TO FREE PDL.           35720021
         SR    FLAGREG,FLAGREG SET NEW INDICATION FOR CALLER.           35740021
IN012020 EQU   *                                                        35760021
         DROP  AREAREG        DISCONTINUE ADDRESSABILITY TO PDL.        35780021
         IKJRLSA INCOREPT     FREE IKJPARS PDL.                         35800021
         BR    SRRTNREG       RETURN TO CALLER.                         35820021
         EJECT                                                          35840021
**********************************************************************  35860021
*                                                                     * 35880021
*   EQUATES, CONSTANTS AND AREAS USED BY INITIALIZATION.              * 35900021
*                                                                     * 35920021
*********************************************************************** 35940021
INMSGRTN DC    V(IKJEBIN3)    ADDRESS OF MESSAGE ROUTINE FOR            35960021
*                                  INITIALIZATION PHASE.                35980021
         SPACE 5                                                        36000021
INCL001  CLC   D0(*-*,FLAGREG),INNEW CHECK IF NEW ENTERED.              36020021
INXC001  XC    D0(*-*,AREAREG),D0(AREAREG) INSTRUCTION EXECUTED         36040021
*                                  OUT OF SEQUENCE TO ZERO CORE.        36060021
INMV001  MVC   D0(*-*,AREAREG),D0(DSNAMREG) MOVE DATA SET NAME          36080021
*                                  TO MESSAGE INSERTION RECORD.         36100021
INMV002  MVC   X1(*-*,AREAREG),D0(DSNAMREG) MOVE MEMBER NAME TO         36120021
*                                  MESSAGE INSERTION RECORD.            36140021
INMV003  MVC   CAEDDSN(*-*),D0(AREAREG) MOVE EDIT DATA SET NAME TO      36160021
*                                  COMMUNICATION AREA.                  36180021
INMV004  MVC   CAEDMEMB(*-*),D0(AREAREG) MOVE MEMBER NAME TO            36200021
*                                  COMMUNICATION AREA.                  36220021
INMV005  MVC   CAEDPSWD(*-*),D0(AREAREG) MOVE PASSWORD TO               36240021
*                                  COMMUNICATION AREA.                  36260021
         SPACE 5                                                        36280021
INXCTL   XCTL  ,SF=L          XCTL PARAMETER LIST.                      36300021
INXCTLLN EQU   *-INXCTL       LENGTH OF XCTL PARAMETER LIST.            36320021
         SPACE 5                                                        36340021
INCAMLST CAMLST SEARCH,1,2,3  CAMLIST FOR OBTAIN DSCB.                  36360021
INCAMEND EQU   *-INCAMLST     LENGTH OF EAMLIST EXPANSION.              36380021
         SPACE 5                                                        36400021
INKEYDEF DC    H'1'           DEFAULT KEYWORD NUMBER FROM IKJPARSE.     36420021
INDISPNW DC    XL2'2'         RELATIVE KEYWORD NUMBER FOR NEW.          36440021
INPARS   DC    XL4'01000000'  INDICATOR FOR IKJPARS SERVICE             36460021
*                                  ROUTINE.                             36480021
INDAIR   DC    XL4'02000000'  INDICATOR FOR IKJDAIR SERVICE             36500021
*                                  ROUTINE.                             36520021
INSVCOBT DC    XL4'04000000'  INDICATOR FOR OBTAIN SVC.                 36540021
INSUBPL1 DC    XL4'01000000'  INDICATOR FOR SUBPOOL ONE.         A45713 36560021
INDSMTY  DC    XL3'0'         CONSTANT USED TO CHECK DS1LSTAR.          36580021
INNOKEYW DC    XL2'0'         CONSTANT USED TO DETERMINE IF A           36600021
*                                  KEYWORD ENTERED ON COMMAND.          36620021
INNEW    DC    CL3'NEW'       NEW DISPOSITION OPERAND KEYWORD.          36640021
INBUFRCW DC    XL4'000C0000'  BUFFER CONTROL WORD FOR DUMMY             36660021
*                                  IKJPARS BUFFER.                      36680021
ININC010 DC    F'10'          DEFAULT INCREMENT FOR LINE                36700021
*                                  NUMBERED DATA SETS.                  36720021
ININC100 DC    F'100'         DEFAULT INCREMENT FOR NON-LINE            36740021
*                                  NUMBERED DATA SETS.                  36760021
INDR0000 DC    XL2'0000'      IKJDAIR DARC = 0 - CATALOG ERROR.         36780021
INDR0004 DC    XL2'4'         IKJDAIR CTRC = 4 - CATALOG ERROR.         36800021
INDR0008 DC    XL2'8'         IKJDAIR CTRC = 8 - CATALOG ERROR.         36820021
INDR0028 DC    XL2'1C'        IKJDAIR CTRC = 28- CATALOG ERROR.         36840021
INDR020C DC    XL2'020C'      IKJDAIR DYNAMIC ALLOCATION ERROR.         36860021
INDR0210 DC    XL2'0210'      IKJDAIR DYNAMIC ALLOCATION ERROR.         36880021
INDR0214 DC    XL2'0214'      IKJDAIR DYNAMIC ALLOCATION ERROR.         36900021
INDR0218 DC    XL2'0218'      IKJDAIR DYNAMIC ALLOCATION ERROR.         36920021
INDR021C DC    XL2'021C'      IKJDAIR DYNAMIC ALLOCATION ERROR.         36940021
INDR0220 DC    XL2'0220'      IKJDAIR DYNAMIC ALLOCATION ERROR.         36960021
INDR0404 DC    XL2'0404'      IKJDAIR DYNAMIC ALLOCATION ERROR.         36980021
INDR041C DC    XL2'041C'      IKJDAIR DYNAMIC ALLOCATION ERROR.         37000021
INDAIR08 DC    H'8'           IKJDAIR RETURN CODE 8 (CATALOG    A59609  37004021
*                                  MANAGEMENT ERROR.)           A59609  37008021
INDAIR16 DC    H'16'          IKJDAIR RETURN CODE 16 (NO ENTRY  A59609  37012021
*                                  AVAILABLE IN TIOT.)          A59609  37016021
INDRRC24 DC    H'24'          IKJDAIR RETURN CODE 24 (DATA SET          37020021
*                                  BELONGS TO A CONCATENATED            37040021
*                                  GROUP).  THIS RETURN CODE IS         37060021
*                                  ACCEPTABLE FOR UNALLOCATION.         37080021
INDAIR48 DC    H'48'          IKJDAIR RETURN CODE 48 (DAIR STAE A59609  37086021
*                                  EXIT ENTERED.)               A59609  37092021
INBLINIT DC    XL4'0001000E'  CONSTANT USED FOR BLDL LIST               37100021
*                                  INITIALIZATION.                      37120021
INTEMPNM DC    CL8'TEMPNAME'  DEFAULT MEMBER NAME WHEN NOT              37140021
*                                  SUPPLIED ON COMMAND.                 37160021
         SPACE 5                                                        37180021
INDCB    DCB   DSORG=PO,MACRF=(E),DDNAME=XXXXXXXX DCB FOR BLDL.         37200021
INDCBL   EQU   *-INDCB        LENGTH OF DCB.                            37220021
INOPEN   OPEN  (,),MF=L       PARAMETER LIST FOR OPEN.                  37240021
INOPENL  EQU   *-INOPEN       LENGTH OF OPEN PARAMETER LIST.            37260021
INCLOSE  CLOSE (,),MF=L       PARAMETER LIST FOR CLOSE.                 37280021
INCLOSEL EQU   *-INCLOSE      LENGTH OF CLOSE PARAMETER LIST.           37300021
         SPACE 2                                                        37320021
INSTKPRM STACK DELETE=ALL,MF=L LIST-FORM STACK MACRO FOR DELETING      X37340021
                                   ALL ELEMENTS BUT TERMINAL FROM      X37360021
                                   THE INPUT STACK.                     37380021
INSTPBLN EQU   *-INSTKPRM     LENGTH OF STACK PARAMETER BLOCK.          37400021
         SPACE 2                                                        37420021
         SPACE 5                                                        37440021
D0       EQU   0              OFFSET ZERO (DECIMAL).                    37460021
D1       EQU   1              OFFSET 1 (DECIMAL).                       37480021
D4       EQU   4              OFFSET 4 (DECIMAL).                       37500021
D5       EQU   5              OFFSET 5 (DECIMAL).                       37520021
D6       EQU   6              OFFSET 6 (DECIMAL).                       37540021
D8       EQU   8              OFFSET 8 (DECIMAL).                       37560021
D9       EQU   9              OFFSET 9 (DECIMAL).                       37580021
D16      EQU   16             OFFSET 16 (DECIMAL).                      37600021
D72      EQU   72             OFFSET 72 (DECIMAL).                      37620021
D12      EQU   12             OFFSET 12 (DECIMAL).                      37640021
D15      EQU   15             OFFSET 15 (DECIMAL).                      37660021
D3       EQU   3              OFFSET 3 (DECIMAL).                       37680021
D2       EQU   2              OFFSET 2 (DECIMAL).                       37700021
D7       EQU   7              OFFSET 7 (DECIMAL).                       37720021
D20      EQU   20             OFFSET 20 (DECIMAL).                      37740021
D24      EQU   24             OFFSET 24 (DECIMAL).                      37760021
D30      EQU   30             OFFSET 30 (DECIMAL).                      37780021
D32      EQU   32             OFFSET 32 (DECIMAL).                      37800021
X1       EQU   1              OFFSET 1.                                 37820021
INSMGPT  EQU   0              OFFSET IN PDE TO POINTER.                 37840021
INSMGLN  EQU   4              OFFSET IN PDE TO LENGTH.                  37860021
INSMGFLG EQU   6              OFFSET IN PDE TO FLAGS.                   37880021
INLSRCMG EQU   2              LEFT SOURCE MARGIN FOR PL/I.              37900021
INRSRCMG EQU   72             RIGHT SOURCE MARGIN FOR PL/I.             37920021
INSNOPT  EQU   0              OFFSET IN PDE TO POINTER.                 37940021
INSNOLN  EQU   4              OFFSET IN PDE TO LENGTH.                  37960021
INSNOFLG EQU   6              OFFSET IN PDE TO FLAGS.                   37980021
INSNOOMT EQU   X'80'          START POSITION/LENGTH ENTERED.            38000021
INBLKPT  EQU   0              OFFSET IN PDE TO ADDRESS OF BLOCK         38020021
*                                  VALUE.                               38040021
INBLKLN  EQU   4              OFFSET IN PDE TO LENGTH OF BLOCK          38060021
*                                  VALUE.                               38080021
INLNEPT  EQU   0              OFFSET IN PDE TO ADDRESS OF LINE          38100021
*                                  VALUE.                               38120021
INLNELN  EQU   4              OFFSET IN PDE TO LENGTH OF LINE           38140021
*                                  VALUE.                               38160021
DS1FMUDF EQU   B'11000000'    DSCB RECFM = UNDEFINED.                   38180021
DS1FMVAR EQU   B'01000000'    DSCB RECFM = VARIABLE.                    38200021
DS1FMSTD EQU   B'00001000'    DSCB RECFM = STANDARD BLOCKS.             38220021
DS1FMOVF EQU   B'00100000'    DSCB RECFM = TRACK OVERFLOW.              38240021
DS1FMA   EQU   B'00000100'    DSCB RECFM = ASA CONTROL CHARACTER.       38260021
DS1FMM   EQU   B'00000010'    DSCB RECFM = MACHINE CONTROL              38280021
*                                  CHARACTER.                           38300021
DS1FMBLK EQU   B'00010000'    DSCB RECFM = BLOCKED.                     38320021
DS1FMFX  EQU   B'10000000'    DSCB RECFM = FIXED.                       38340021
DS1ORGPO EQU   B'00000010'    DSCB DSORG = PARTITIONED.                 38360021
DS1ORGPS EQU   B'01000000'    DSCB DSORG = PHYSICAL SEQUENTIAL.         38380021
INSTATN  EQU   2              RELATIVE KEYWORD NUMBER FOR NEW.          38400021
CURNTTCB EQU   4              OFFSET TO CURRENT TCB.                    38420021
INSTATO  EQU   1              KEYWORD NUMBER FOR OLD (STATUS).          38440021
INOPRNDO EQU   X'80'          IKJPARSE OPERAND OMITTED.                 38460021
INFULLQ  EQU   X'40'          DATA SET NAME FULLY QUALIFIED.            38480021
INDSNPT  EQU   0              OFFSET IN PDE TO DATA SET NAME PT         38500021
INDSNLL  EQU   4              OFFSET IN PDE TO DATA SET NAME LENGTH     38520021
INDSNFLG EQU   6              OFFSET IN PDE TO DATA SET NAME FLAGS.     38540021
INMEMPT  EQU   8              OFFSET IN PDE TO MEMBER PT                38560021
INMEMLL  EQU   12             OFFSET IN PDE TO MEMBER LENGTH.           38580021
INMEMFLG EQU   14             OFFSET IN PDE TO MEMBER FLAGS.            38600021
INPSWPT  EQU   16             OFFSET IN PDE TO PASSWORD PT.             38620021
INPSWLL  EQU   20             OFFSET IN PDE TO PASSWORD LENGTH.         38640021
INPSWFLG EQU   22             OFFSET IN PDE TO PASSWORD FLAGS.          38660021
INTSFSQO EQU   73             GOFORT(FIXED) SEQUENCE NUMBER             38680021
*                                 START COLUMN.                         38700021
RCODE4   EQU   4              RETURN CODE 4 - USED TO TEST RETURN       38720021
*                                  CODES.                               38740021
RCODE12  EQU   12             RETURN CODE 12 - USED IN VALIDITY         38760021
*                                  CHECK EXIT                           38780021
SUBPOOL  EQU   1              SUBPOOL NUMBER FOR MAIN STORAGE           38800021
*                                  REQUESTS                             38820021
INF255   EQU   255            CONSTANT 255 USED FOR LENGTH              38840021
*                                  CHECKS IN CLEARING CORE.             38860021
CHRBLANK EQU   C' '           CHARACTER BLANK.                          38880021
INDCZERO EQU   C'0'           DECIMAL ZERO (UNPACKED AND UNSIGNED).     38900021
INSNGLQT EQU   C''''          SINGLE QUOTE.                             38920021
INPERIOD EQU   C'.'           PERIOD.                                   38940021
INLFTPRN EQU   C'('           LEFT PARENTHESIS.                         38960021
INRTPRN  EQU   C')'           RIGHT PARENTHESIS.                        38980021
INDR1700 EQU   X'17'          IKJDAIR DYNAMIC ALLOCATION ERROR.         39000021
INOPENED EQU   X'10'          MASK USED TO DETERMINE WHETHER THE        39020021
*                                  DCB OPENED SUCCESSFULLY.             39040021
         SPACE 5                                                        39060021
INERROR1 EQU   0              RELATIVE ERROR 1 - TERMINATE EDIT         39080021
*                                  WITH NOT ENOUGH MAIN STORAGE         39100021
*                                  MESSAGE.                             39120021
INERROR2 EQU   4              RELATIVE ERROR 2 - TERMINATE EDIT         39140021
*                                  WITH REQUIRED PROGRAM NOT            39160021
*                                  AVAILABLE MESSAGE.                   39180021
INERROR3 EQU   8              RELATIVE ERROR 3 - TERMINATE EDIT         39200021
*                                  WITH LOGIC ERROR MESSAGE.            39220021
INERROR4 EQU   12             RELATIVE ERROR 4 - TERMINATE EDIT         39240021
*                                  WITH DATA SET ORGANIZATION NOT       39260021
*                                  ACCEPTABLE MESSAGE.                  39280021
INERROR5 EQU   16             RELATIVE ERROR 5 - TERMINATE EDIT         39300021
*                                  WITH RECORD FORMAT = UNDEFINED       39320021
*                                  NOT ACCEPTABLE MESSAGE.              39340021
INERROR6 EQU   20             RELATIVE ERROR 6 - TERMINATE EDIT         39360021
*                                  WITH DATA SET NOT USABLE             39380021
*                                  MESSAGE.                             39400021
INERROR7 EQU   24             RELATIVE ERROR 7 - DATA SET NOT           39420021
*                                  FOUND, OLD SPECIFIED.                39440021
INERROR8 EQU   28             RELATIVE ERROR 8 - LINE VALUE             39460021
*                                  SPECIFIED ON COMMAND INVALID,        39480021
*                                   OR LRECL FIELD IN THE FORMAT        39500021
*                                   1 DSCB IS SET TO ZERO.              39520021
INERROR9 EQU   32             RELATIVE ERROR 9 - BLOCK VALUE            39540021
*                                  SPECIFIED ON COMMAND INVALID.        39560021
INERRORA EQU   36             RELATIVE ERROR 10 - SYNTAX CHECKING       39580021
*                                  SPECIFIED FOR A NON-SCANABLE         39600021
*                                  DATA SET TYPE OR SYNTAX              39620021
*                                  CHECKER NOT IN SYSTEM.               39640021
INERRORB EQU   40             RELATIVE ERROR 11 - NONUM SPECIFIED       39660021
*                                  DATA SET MUST BE NUMBERED.           39680021
INERRORC EQU   44             RELATIVE ERROR 12 - INVALID PL/I          39700021
*                                  SOURCE MARGINS.                      39720021
INERRORD EQU   48             RELATIVE ERROR 13 - NUM OPERAND           39740021
*                                  INCORRECT FOR ASM DATA SET           39760021
*                                  TYPE.                                39780021
INERRORE EQU   52             RELATIVE ERROR 14 - ASIS SPECIFIED,       39800021
*                                  CAPS REQUIRED.                       39820021
INERRORF EQU   56             RELATIVE ERROR 15 - UNALLOCATION          39840021
*                                  ERROR OR DDNAME NOT FOUND.           39860021
INERRORG EQU   60             RELATIVE ERROR 16 - LINE OPERAND          39880021
*                                  SPECIFIED FOR OLD DATA SET.          39900021
INERRORH EQU   64             RELATIVE ERROR 17 - BLOCK OPERAND         39920021
*                                  SPECIFIED FOR OLD DATA SET.          39940021
INERRORI EQU   68             RELATIVE ERROR 18 - DATA SET              39960021
*                                  FOUND, NEW SPECIFIED.                39980021
INERRORJ EQU   72             RELATIVE ERROR 19 - OLD DATA SET          40000021
*                                  HAS LRECL OTHER THAN 80.             40020021
INERRORK EQU   76             RELATIVE ERROR 20 - IKJDAIR RETURN        40040021
*                                  CODE NOT ZERO.                       40060021
INERRORL EQU   80             RELATIVE ERROR 21 - DATA SET NOT          40080021
*                                  USEABLE.                             40100021
INERRORM EQU   84             RELATIVE ERROR 22 - TERMINATE EDIT        40120021
*                                  WITH TOO MANY DATA SETS              40140021
*                                  ALLOCATED MESSAGE.                   40160021
INERRORN EQU   88             RELATIVE ERROR 23 - TERMINATE EDIT        40180021
*                                  WITH REQUIRED VOLUME NOT             40200021
*                                  MOUNTED MESSAGE.                     40220021
INERRORO EQU   92             RELATIVE ERROR 24 - TERMINATE EDIT        40240021
*                                  WITH DATA SET NOT ON VOLUME          40260021
*                                  MESSAGE.                             40280021
INERRORP EQU   96             RELATIVE ERROR 25 - TERMINATE EDIT        40300021
*                                  WITH ALLOCATION FAILED MESSAGE       40320021
INERRORQ EQU   100            RELATIVE ERROR 26 - TERMINATE EDIT        40340021
*                                  WITH DEVICE NOT DIRECT ACCESS        40360021
*                                  MESSAGE.                             40380021
INERRORR EQU   104            RELATIVE ERROR 27 - TERMINATE EDIT        40400021
*                                  WITH INVALID DSNAME MESSAGE.         40420021
INERRORS EQU   108            RELATIVE ERROR 28 - TERMINATE EDIT        40440021
*                                  WITH DATA SET WILL CREATE            40460021
*                                  INVALID CATALOG STRUCTURE            40480021
*                                  MESSAGE.                             40500021
INERRORT EQU   112            RELATIVE ERROR 29 - TERMINATE EDIT        40520021
*                                  WITH DSNAME NOT QUALIFIED            40540021
*                                  MESSAGE.                             40560021
INERRORU EQU   116            RELATIVE ERROR 30 - TERMINATE EDIT        40580021
*                                  WITH DSNAME NOT RESOLVED             40600021
*                                  MESSAGE.                             40620021
INERRORV EQU   120            RELATIVE ERROR 31 - GOFORT(FREE)          40640021
*                                  SPECIFIED BUT RECORD FORMAT IS       40660021
*                                  FIXED.                               40680021
INERRORW EQU   124            RELATIVE ERROR 32 - TERMINATE EDIT        40700021
*                                  WITH INVALID UNIT OR UNIT NOT        40720021
*                                  AVAILABLE MESSAGE.                   40740021
INERRORX EQU   128            RELATIVE ERROR 33 - TERMINATE EDIT A45713 40760021
*                                  WITH MISSING DATA SET TYPE.   A45713 40780021
         SPACE 5                                                        40800021
INDR18   DS    0F             PARAMETER BLOCK FOR ENTRY CODE 18.        40820021
         DC    XL2'18'        IKJDAIR ENTRY CODE X'18'                  40840021
         DC    3XL2'0'        FLAGS, DARC, CTRC.                        40860021
         DC    A(0)           ADDRESS OF DSNAME.                        40880021
         DC    2CL8' '        DDNAME, MEMBER NAME.                      40900021
         DC    XL2'0'         SYSOUT CLASS SPECIFICATION.               40920021
         DC    X'08'          INDICATE DISP = KEEP.                     40940021
         DC    X'0'           CONTROL FLAGS.                            40960021
         DC    CL8' '         JOBNAME.                                  40980021
INDR18L  EQU   *-INDR18       LENGTH OF PARAMETER BLOCK.                41000021
         SPACE 5                                                        41020021
INDAIR8O DS    0F                                                       41040021
         DC    XL2'8'         IKJDAIR ENTRY CODE 8.                     41060021
         DC    10X'0'         INITIALIZE FLAGS, DARC, CTRC AND          41080021
*                                  DSNAME PT FIELDS TO ZEROES.          41100021
         DC    3CL8' '        INITIALIZE DDNAME, UNITNAME AND           41120021
*                                  SERIAL NO. TO BLANKS.                41140021
         DC    4F'0'          INITIALIZE BLKSIZE, PRIMARY,              41160021
*                                  SECONDARY, AND DIRECTORY             41180021
*                                  QUANTITY TO ZEROES.                  41200021
         DC    2CL8' '        INITIALIZE MEMBERNAME AND PASSWORD        41220021
*                                  FIELDS TO BLANKS.                    41240021
         DC    X'0'           INITIALIZE STATUS TO OLD.          A50467 41260021
         DC    AL1(DA08KEEP)  INITIALIZE NORMAL DISPOSITION      A50467 41270021
*                                  TO KEEP.                      A50467 41280021
         DC    AL1(DA08KEP)   INITIALIZE CONDITIONAL DISPOSITION A42959 41300021
*                                  TO KEEP.                      A42959 41320021
         DC    5X'0'          INITIALIZE FLAGS AND DSORG FIELDS  A42959 41340021
*                                  SET BY IKJDAIR TO ZERO.       A42959 41360021
INDR8OLL EQU   *-INDAIR8O     LENGTH OF PARAMETER LIST FOR ENTRY        41380021
*                                  CODE 8.                              41400021
         SPACE 5                                                        41420021
ININS001 EQU   *                                                        41440021
ININS002 IKJEBEMG ININS003,M3131IN1,'BLDL' INSERTION IN COMMAND         41460021
ININS003 IKJEBEMG 0,M3131IN2,'8'   SYSTEM ERROR MESSAGE.                41480021
ININS004 IKJEBEMG ININS005,M3131IN1,'IKJEBEPS' SERVICE ROUTINE         X41500021
                                   NAME FOR INSERTION.                  41520021
ININS005 IKJEBEMG 0,M3131IN2,'4' RETURN CODE FOR INSERTION.             41540021
         SPACE 5                                                        41560021
IKJEBIN0 EQU   *                                                        41580021
.TAG1    ANOP                                                    A45714 41600021
.* CHECK IF LOOP FINISHED - INDEX 'J' GT NO. OF DSTYPES.         A45714 41620021
         AIF   (&J GT &I).OUT1                                   A45714 41640021
         DC    CL8'&DST(&J)' - EDIT DATA SET TYPE.               A45714 41660021
.* INCREMENT INDEX 'J' BY ONE.                                   A45714 41680021
&J       SETA  &J+1                                              A45714 41700021
.* REPEAT LOOP.                                                  A45714 41720021
         AGO   .TAG1                                             A45714 41740021
.OUT1    ANOP                                                    A45714 41760021
INDSTELN EQU   8              LENGTH OF TABLE ENTRY.                    41780021
INNODSTY EQU   (*-IKJEBIN0)/INDSTELN NUMBER OF ENTRIES IN DATA          41800021
*                                  SET TYPE TABLE.                      41820021
         SPACE 5                                                        41840021
         EJECT                                                          41860021
INPTPCL  DC    A(IKJEBIN1)     ADDRESS OF IKJPARSE PCL FOR THE          41880021
*                                  EDIT COMMAND.                        41900021
IKJEBIN1 IKJPARM DSECT=INECMNDD BEGIN EDIT COMMAND PCL.                 41920021
INDSN    IKJPOSIT DSNAME,PROMPT='DATA SET NAME' DATA SET NAME.          41940021
*                             DATA SET STATUS.                          41960021
INSTAT   IKJKEYWD                                                       41980021
         IKJNAME 'OLD'        STATUS = OLD.                             42000021
         IKJNAME 'NEW'        STATUS = NEW.                             42020021
*                             DEFINE DATA SET TYPE.                     42040021
INDSTYPE IKJKEYWD                                                       42060021
.* INITIALIZE INDEX 'J' TO ONE.                                  A45714 42080021
&J       SETA  1                                                 A45714 42100021
.TAG2    ANOP                                                    A45714 42120021
.* CHECK IF LOOP FINISHED - INDEX 'J' GT NO. OF DSTYPES.         A45714 42140021
         AIF   (&J GT &I).OUT2                                   A45714 42160021
.* CHECK IF DSTYPE IS 'PLI' - USE SPECIAL SUBFIELD.              A45714 42180021
         AIF   ('&DST(&J)' EQ 'PLI').TAG3                        A45714 42200021
.* CHECK IF DSTYPE IS 'IPLI' - USE SPECIAL SUBFIELD.             A45714 42220021
         AIF   ('&DST(&J)' EQ 'IPLI').TAG4                       A45714 42240021
.* CHECK IF DSTYPE IS 'GOFORT' - USE SPECIAL SUBFIELD.           A45714 42260021
         AIF   ('&DST(&J)' EQ 'GOFORT').TAG5                     A45714 42280021
.* CHECK IF DSTYPE IS 'PLIF' - USE SPECIAL SUBFIELD.             A45714 42300021
         AIF   ('&DST(&J)' EQ 'PLIF').TAG6                       A45714 42320021
.* CHECK IF USER DSTYPE - FIRST 15 ARE IBM SUPPLIED TYPES.       A45714 42340021
         AIF   (&J GT 15).TAG7                                   A45714 42360021
.TAG2A   ANOP                                                    A45714 42380021
         IKJNAME '&DST(&J)' - EDIT DATA SET TYPE.                A45714 42400021
         AGO   .LOOP1                                            A45714 42420021
.TAG3    ANOP                                                    A45714 42440021
         IKJNAME 'PLI',SUBFLD=INPL1 - EDIT DATA SET TYPE.        A45714 42460021
         AGO   .LOOP1                                            A45714 42480021
.TAG4    ANOP                                                    A45714 42500021
         IKJNAME 'IPLI',SUBFLD=INIPLICS - EDIT DATA SET TYPE.    A45714 42520021
         AGO   .LOOP1                                            A45714 42540021
.TAG5    ANOP                                                    A45714 42560021
         IKJNAME 'GOFORT',SUBFLD=INTSFTN - EDIT DATA SET TYPE.   A45714 42580021
         AGO   .LOOP1                                            A45714 42600021
.TAG6    ANOP                                                    A45714 42620021
         IKJNAME 'PLIF',SUBFLD=INPL1 - EDIT DATA SET TYPE.       A45714 42640021
         AGO   .LOOP1                                            A45714 42660021
.TAG7    ANOP                                                    A45714 42680021
.* SET INDEX 'K' FOR USER EXIT NAME.                             A45714 42700021
&K       SETA  &J-15                                             A45714 42720021
.* CHECK IF USER EXIT SUPPLIED.                                  A45714 42740021
         AIF  ('&SUBFD(&K)' EQ '').TAG2A                         A45714 42760021
         IKJNAME '&DST(&J)',SUBFLD=INUXERTY - EDIT DATA SET TYP. A45714 42780021
.* SET SWITCH 'SW' TO INDICATE EXIT SUPPLIED.                    A45714 42800021
&SW      SETB  1                                                 A45714 42820021
.LOOP1   ANOP                                                    A45714 42840021
.* INCREMENT INDEX 'J' BY ONE                                    A45714 42860021
&J       SETA  &J+1                                              A45714 42880021
.* REPEAT LOOP.                                                  A45714 42900021
         AGO   .TAG2                                             A45714 42920021
.OUT2    ANOP                                                    A45714 42940021
INSCN    IKJKEYWD DEFAULT='NOSCAN' SCAN OPERAND.                        42960021
         IKJNAME 'NOSCAN'     SYNTAX CHECKING NOT DESIRED.              42980021
         IKJNAME 'SCAN'       SYNTAX CHECKING DESIRED.                  43000021
*                             DATA SET FORMAT.                          43020021
INFMT    IKJKEYWD                                                       43040021
         IKJNAME 'CAPS'       DATA MAINTAINED IN UPPER CASE.            43060021
         IKJNAME 'ASIS'       DATA MAINTAINED AS ENTERED.               43080021
INNUM    IKJKEYWD DEFAULT='NUM' LINE NUMBER OPERANDS.                   43100021
         IKJNAME 'NUM',SUBFLD=INNUMS NUMBER DATA SET.                   43120021
         IKJNAME 'NONUM'      DO NOT NUMBER DATA SET.                   43140021
*                             BLOCK OPERAND.                            43160021
INBLK    IKJKEYWD                                                       43180021
         IKJNAME 'BLOCK',SUBFLD=INBLKSZ USER SPECIFIES BLKSIZE.         43200021
*                             LINE OPERAND.                             43220021
INLNE    IKJKEYWD                                                       43240021
         IKJNAME 'LINE',SUBFLD=INLRECL USER SPECIFIES LRECL.            43260021
*                             SUBFIELD DESCRIPTION FOR BLOCK.           43280021
INBLKSZ  IKJSUBF                                                        43300021
INBLKSZE IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC,                X43320021
               PROMPT='BLOCKSIZE',VALIDCK=IKJEBIN4 BLKSIZE TO BE       X43340021
                                   USED.                                43360021
*                             SUBFIELD DESCRIPTION FOR LINE.            43380021
INLRECL  IKJSUBF                                                        43400021
INLNESZ  IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC,                X43420021
               PROMPT='LINESIZE',VALIDCK=IKJEBIN4 LRECL TO BE          X43440021
                                   USED.                                43460021
*                             SUBFIELD DESCRIPTION FOR NUM.             43480021
INNUMS   IKJSUBF                                                        43500021
INNOSTP  IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC START POSITION   43520021
INNOLEN  IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC LENGTH.          43540021
*                             SUBFIELD DESCRIPTION FOR PL1.             43560021
INPL1    IKJSUBF                                                        43580021
INPL1CL1 IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC,                X43600021
               DEFAULT='2',VALIDCK=IKJEBIN4 LEFT SOURCE MARGIN.         43620021
INPL1CL2 IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC,                X43640021
               DEFAULT='72',VALIDCK=IKJEBIN4 RIGHT SOURCE MARGIN.       43660021
INPL1TYP IKJKEYWD DEFAULT='CHAR60' CHARACTER SET USED.                  43680021
         IKJNAME 'CHAR60'     60 CHARACTER SET.                         43700021
         IKJNAME 'CHAR48'     48 CHARACTER SET.                         43720021
INIPLICS IKJSUBF                                                        43740021
INIPLICH IKJKEYWD DEFAULT='CHAR60' CHARACTER SET TO BE USED.            43760021
         IKJNAME 'CHAR60'     60-CHARACTER SET.                         43780021
         IKJNAME 'CHAR48'     48-CHARACTER SET.                         43800021
*                             SUBFIELD DESCRIPTION FOR GOFORT.          43820021
INTSFTN  IKJSUBF                                                        43840021
INTSFTFM IKJKEYWD DEFAULT='FREE' DEFINE STATEMENT FORMAT.               43860021
         IKJNAME 'FREE'       FREE FORMAT STATEMENTS.           1       43880021
         IKJNAME 'FIXED'      FIXED FORMAT STATEMENTS.          2       43900021
.* CHECK IF USER EXIT SUPPLIED.                                  A45714 43920021
         AIF   (&SW EQ 0).TAG8                                   A45714 43940021
*                             SUBFIELD DESCRIPT. FOR USER TYPES. A45714 43960021
INUXERTY IKJSUBF                                                        43980021
INUSERTY IKJIDENT 'DATA SET TYPE PARAMETERS',FIRST=ANY,OTHER=ANY A45714 44000021
.TAG8    ANOP                                                    A45714 44020021
         IKJENDP                                                        44040021
         EJECT                                                          44060021
         TITLE 'IKJEBIN2 - PCL FOR NEW/OLD PROMPT'                      44080021
INDISPDL DC    A(IKJEBIN2)    ADDRESS OF IKJPARS PCL.                   44100021
         SPACE 2                                                        44120021
IKJEBIN2 IKJPARM DSECT=INDISPD PCL FOR DISPOSITION PROMPT.              44140021
INDISPX  IKJIDENT 'NEW OR OLD',MAXLNTH=3,PROMPT='NEW OR OLD'            44160021
         IKJENDP                                                        44180021
         EJECT                                                          44200021
         TITLE 'IKJEBIN3 - MESSAGE PROCESSING'                          44220021
*********************************************************************** 44240021
*                                                                     * 44260021
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 44280021
*                                                                     * 44300021
* FUNCTION -- THIS ROUTINE IS CALLED BY ALL CSECTS OF EDIT            * 44320021
*    INITIALIZATION THAT ISSUE ERROR MESSAGES.  IT SUPPLIES A WORK    * 44340021
*    AREA FOR IKJEBEIA (INITIALIZATION MESSAGE FORMATTING MODULE)     * 44360021
*    AND INVOKES IT VIA LINK MACRO.  UPON RETURN, THE PUTLINE CODE    * 44380021
*    RETURNED IS TESTED, AND THE COMMAND SYSTEM ERROR DIAGNOSTIC      * 44400021
*    MESSAGE ISSUED IF AN ERROR CONDITION HAS OCCURRED.               * 44420021
*                                                                     * 44440021
* ENTRY POINTS --                                                     * 44460021
*         IKJEBIN3 - VIA CALL MACRO FROM ANY EDIT INITIALIZATION      * 44480021
*                    CSECT THAT ISSUES INFORMATIONAL MESSAGES.        * 44500021
*                                                                     * 44520021
* INPUT --                                                            * 44540021
*    REGISTER ONE (1) CONTAINS A POINTER TO AN INCOMPLETE PARAMETER   * 44560021
*    LIST FOR IKJEBEIA.  IKJEBIN3 COMPLETES THE PARAMETER LIST BY     * 44580021
*    INITIALIZING THE SIXTH WORD TO THE ADDRESS OF A WORK AREA FOR THE* 44600021
*    USE OF IKJEBEIA.                                                 * 44620021
*                                                                     * 44640021
* OUTPUT --                                                           * 44660021
*    REGISTER FIFTEEN (15) CONTAINS THE RETURN CODE FROM  THE FINAL   * 44680021
*    INVOCATION OF THE PUTLINE SERVICE ROUTINE.                       * 44700021
*                                                                     * 44720021
* EXTERNAL REFERENCES --                                              * 44740021
*                                                                     * 44760021
*         IKJEBEIA - INVOKED VIA LINK FOR TERMINAL OUTPUT OF EDIT     * 44780021
*                    MESSAGES.                                        * 44800021
*                                                                     * 44820021
*         IKJEBEMS - INVOKED VIA IKJEBESH MACRO FOR TERMINAL OUTPUT   * 44840021
*                    OF THE COMMAND SYSTEM ERROR DIAGNOSTIC FOR       * 44860021
*                    ERROR RETURN CODES RETURNED BY IKJEBEIA.         * 44880021
*                                                                     * 44900021
*    MACROS USED --                                                   * 44920021
*                                                                     * 44940021
*         IKJEBEMG - FOR BUILDING A MESSAGE INSERTION.                * 44960021
*                                                                     * 44980021
*         IKJEBEML - FOR BUILDING AN IKJEBEMS PARAMETER LIST.         * 45000021
*                                                                     * 45020021
*         IKJEBEMI - GENERATES SYMBOLIC EQUATES FOR ALL RELATIVE      * 45040021
*                    MESSAGE NUMBERS AND INSERTION OFFSETS AFFECTING  * 45060021
*                    INITIALIZATION MESSAGES.                         * 45080021
*                                                                     * 45100021
*         IKJEBERT - RETURN LINKAGE WITHIN THE EDIT COMMAND           * 45120021
*                    PROCESSOR.                                       * 45140021
*                                                                     * 45160021
*         IKJEBESH - USED FOR INVOCATION OF EDIT SERVICE ROUTINES.    * 45180021
*                                                                     * 45200021
*         IKJEBESV - ENTRY LINKAGE WITHIN THE EDIT COMMAND PROCESSOR. * 45220021
*                                                                     * 45240021
*         LINK     - ISSUED TO INVOKE IKJEBEIA.                       * 45260021
*                                                                     * 45280021
* EXITS, NORMAL --                                                    * 45300021
*    WHEN IKJEBEIA RETURNS A PUTLINE RETURN CODE OF ZERO, CONTROL     * 45320021
*    IS RETURNED BY BRANCHING ON REGISTER FOURTEEN (14).              * 45340021
*                                                                     * 45360021
* EXITS, ERROR --                                                     * 45380021
*    WHEN AN ERROR CONDITION IS INDICATED BY IKJEBEIA, THE COMMAND    * 45400021
*    SYSTEM ERROR MESSAGE IS ISSUED THROUGH IKJEBEMS.  THE PUTLINE    * 45420021
*    RETURN CODE RETURNED IN REGISTER FIFTEEN (15) BY IKJEBEMS IS     * 45440021
*    RETURNED TO THE CALLING ROUTINE WHEN CONTROL IS RETURNED BY      * 45460021
*    BRANCHING ON REGISTER FOURTEEN (14).                             * 45480021
*                                                                     * 45500021
* TABLES/WORK AREAS --                                                * 45520021
*                                                                     * 45540021
*    THE EDIT COMMUNICATION AREA CONTAINS CONTROL INFORMATION,        * 45560021
*    BUFFERS, AND A WORK AREA FOR THIS ROUTINE.                       * 45580021
*                                                                     * 45600021
* ATTRIBUTES --                                                       * 45620021
*    REFRESHABLE, ENABLED, NON-PRIVILEGED                             * 45640021
*                                                                     * 45660021
* CHARACTER CODE DEPENDENCY --                                        * 45680021
*    THIS ROUTINE MAKES THE ASSUMPTION THAT ALL BITS OF THE HIGH      * 45700021
*    ORDER ZONE OF A CHARACTER DIGIT ARE COMMON TO THOSE OF A SIGNED  * 45720021
*    AND UNPACKED DECIMAL DIGIT.                                      * 45740021
*                                                                     * 45760021
* NOTES -- NONE.                                                      * 45780021
*                                                                     * 45800021
*********************************************************************** 45820021
         EJECT                                                          45840021
IKJEBIN3 CSECT                                                          45860021
         IKJEBESV (14,12),,*,COMMREG=D0(PARMREG1) ENTRY LINKAGE.        45880021
         USING IKJEBECA,COMMREG ADDRESSABILITY TO COMMUNICATION         45900021
*                                  AREA.                                45920021
         LA    PARMREG0,CATEMPBF ADDRESS OF WORK AREA FOR               45940021
*                                  IKJEBEIA.                            45960021
         ST    PARMREG0,D20(,PARMREG1) ADD WORK AREA ADDRESS TO         45980021
*                                  PARAMETER LIST.                      46000021
         LINK  EP=IKJEBEIA,MF=(E,(1)) INVOKE MESSAGE ROUTINE            46020021
*                                  FOR EDIT INITIALIZATION.             46040021
         LTR   RETCDREG,RETCDREG CHECK IF TERMINAL OUTPUT               46060021
*                                  SUCCESSFUL.                          46080021
         BZ    IN300010       IF SO, RETURN TO CALLING ROUTINE.         46100021
         CH    RETCDREG,IN3ATTN CHECK FOR ATTENTION ISSUED.             46120021
         BE    IN300010       IF SO, RETURN TO CALLING ROUTINE.         46140021
         CVD   RETCDREG,IN3INS2 CONVERT RETURN CODE TO DECIMAL.         46160021
         UNPK  IN3INS2-D1(D3),IN3INS2+D6(D2) UNPACK SIGNIFICANT         46180021
*                                  DIGITS.                              46200021
         OI    IN3INS2+D1,INDCZERO INSURE CHARACTER DIGIT IN            46220021
*                                  SECOND POSITION.                     46240021
         LA    LENREG,D6      LENGTH OF SECOND INSERTION.               46260021
         STH   LENREG,IN3LEN2 SET LENGTH IN INSERTION LIST.             46280021
         LA    LENREG,M3131IN2 OFFSET FOR SECOND INSERTION.             46300021
         STH   LENREG,IN3OFF2 STORE OFFSET IN LIST.                     46320021
         SR    LENREG,LENREG  ZERO REGISTER.                            46340021
         ST    LENREG,IN3PT2  INDICATE RETURN CODE AS LAST              46360021
*                                  INSERTION.                           46380021
         MVC   IN3PT1(D15),IN3SRINS MOVE SERVICE ROUTINE                46400021
*                                  INSERTION TO WORK AREA.              46420021
         LA    LENREG,IN3PT2  ADDRESS SECOND INSERTION.                 46440021
         ST    LENREG,IN3PT1  CHAIN INSERTIONS.                         46460021
         MVC   IN3MSLST(D12),IN3MSPRM MOVE PARAMETER LIST               46480021
*                                  TO WORK AREA.                        46500021
         LA    LENREG,IN3PT1  ADDRESS FIRST INSERTION.                  46520021
         ST    LENREG,IN3MSLST+D8 COMPLETE INSERTION CHAIN FOR          46540021
*                                  SECOND LEVEL MESSAGE.                46560021
         IKJEBESH (COMMREG),IKJEBEMS,PARAM=((COMMREG),IN3MSLST),       X46580021
               MF=(E,IN3WKA)  PUT PUTLINE ERROR MESSAGE.                46600021
IN300010 EQU   *                                                        46620021
         IKJEBERT (14,12),,RC=(15) RETURN TO CALLER WITH PUTLINE       X46640021
                                   RETURN CODE.                         46660021
         EJECT                                                          46680021
*********************************************************************** 46700021
*                                                                       46720021
*    CONSTANTS FOR IKJEBIN3                                             46740021
*                                                                       46760021
*********************************************************************** 46780021
         SPACE 2                                                        46800021
IN3MSPRM IKJEBEML M313,M3131,D0,D0,MF=L PARAMETER LIST FOR             X46820021
                                   COMMAND SYSTEM ERROR MESSAGE.        46840021
         SPACE 2                                                        46860021
IN3SRINS IKJEBEMG 0,M3131IN1,'PUTLINE' SERVICE ROUTINE NAME            X46880021
                                   INSERTION.                           46900021
         SPACE 2                                                        46920021
IN3ATTN  DC    H'4'           PUTLINE RETURN CODE 4 IS ATTENTION        46940021
*                                  ISSUED.                              46960021
         EJECT                                                          46980021
*********************************************************************** 47000021
*                                                                       47020021
*    FOLLOWING IS INFORMATION ON ALL MESSAGES USED BY                   47040021
*    EDIT INITIALIZATION.                                               47060021
*                                                                       47080021
*********************************************************************** 47100021
         SPACE 2                                                        47120021
         IKJEBEMI (301,302,303,304,305,306,307,308,309,310,311,312,    X47140021
               313,314,315,316,317,318,330,331,332,333,334,335,336,    X47160021
               342,343,360,361,362,363,364,365,424)                     47180021
         EJECT                                                          47200021
         TITLE 'IKJEBIN4 - VALIDITY CHECK EXIT FOR COMMAND OPERANDS'    47220021
IKJEBIN4 CSECT                                                          47240021
         IKJEBESV (14,12),,*,COMMREG=D4(,PARMREG1)                      47260021
         USING IKJEBECA,COMMREG COMMUNICATION AREA ADDRESSABILITY       47280021
         SR    RETCDREG,RETCDREG SET ZERO RETURN CODE.                  47300021
         L     DATAREG,D0(,PARMREG1) ADDRESS OF PDE FOR NUMERIC         47320021
*                                  SUBFIELD.                            47340021
         L     AREAREG,IBNOADDR(,DATAREG) ADDRESS OF NUMBER             47360021
*                                  ENTERED.                             47380021
         LH    LENREG,IBNOLEN(,DATAREG) LENGTH OF NUMBER ENTERED.       47400021
         BCTR  LENREG,D0      REDUCE LENGTH BY ONE AND TEST FOR         47420021
         EX    LENREG,IBCLC001     ZERO.                                47440021
         BH    IB001010       IF GREATER THAN ZERO, BRANCH TO           47460021
*                                  RETURN.                              47480021
         LA    RETCDREG,D4(,D0) SET ERROR RETURN CODE WHEN LESS         47500021
*                                  THAN ZERO.                           47520021
IB001010 EQU   *                                                        47540021
         IKJEBERT (14,12),,RC=(15) RETURN TO IKJPARS.                   47560021
         SPACE 5                                                        47580021
IBCLC001 CLC   D0(*-*,AREAREG),IBZEROES CHECK FOR ZERO.                 47600021
IBZEROES DC    CL8'00000000'  CONSTANT USED TO CHECK FOR ZEROES.        47620021
IBNOADDR EQU   0              OFFSET IN PDE TO OPERAND ADDRES..         47640021
IBNOLEN  EQU   4              OFFSET IN PDE TO OPERAND LENGTH.          47660021
         EJECT                                                          47680021
         TITLE 'IKJEBIN5 - PROMPT FOR DATA SET TYPE PROCESSING'         47700021
*********************************************************************** 47720021
*                                                                     * 47740021
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 47760021
*                                                                     * 47780021
* FUNCTION -- THIS ROUTINE IS CALLED BY THE IKJEBEIN AND IKJEBIN7     * 47800021
*    CSECTS OF THE EDIT INITIALIZATION PROGRAM TO PROMPT THE TERMINAL * 47820021
*    USER TO ENTER DATA SET TYPE.  THIS IS ACCOMPLISHED BY INVOKING   * 47840021
*    IKJPARS, SPECIFYING A REQUIRED POSITIONAL PARAMETER AND          * 47860021
*    SUPPLYING A BLANK BUFFER TO 'PARSE'.  THE VALIDITY CHECK EXIT    * 47880021
*    INDICATED IN THE PARSE PCL GAINS CONTROL TO CHECK THE TYPE       * 47900021
*    ENTERED IN RESPONSE TO A PROMPT MADE BY IKJPARS.  IT REQUESTS    * 47920021
*    IKJPARS TO RE-PROMPT UNTIL BOTH OF THE FOLLOWING CONDITIONS ARE  * 47940021
*    MET --                                                           * 47960021
*                                                                     * 47980021
*    (1) THE TYPE ENTERED IS FOUND IN A LOCAL TABLE OF EDITABLE DATA  * 48000021
*    SET TYPES.                                                       * 48020021
*                                                                     * 48040021
*    (2) THE TYPE ENTERED IS LOCATED BY THE PROCESSOR SEARCH ROUTINE  * 48060021
*    (IKJEBEPS) IN THE PROCESSOR DESCRIPTOR CSECT (IKJEBEPD).         * 48080021
*                                                                     * 48100021
*    WHEN A VALID TYPE HAS BEEN ENTERED, THE TABLE ENTRY RETURNED     * 48120021
*    BY IKJEBEPS IS MOVED TO THE COMMUNICATION AREA PROCESSOR TABLE   * 48140021
*    FIELD (CAPD) AND CONTROL IS RETURNED TO THE CALLING ROUTINE.     * 48160021
*                                                                     * 48180021
* ENTRY POINTS --                                                     * 48200021
*         IKJEBIN5 - VIA CALL MACRO FROM IKJEBEIN OR IKJEBIN7 WHEN    * 48220021
*                    IT IS NECESSARY TO PROMPT THE TERMINAL USER      * 48240021
*                    FOR DATA SET TYPE.                               * 48260021
*                                                                     * 48280021
* INPUT --                                                            * 48300021
*    REGISTER ONE (1) POINTS TO A WORD CONTAINING THE ADDRESS         * 48320021
*    OF THE EDIT COMMUNICATION AREA.                                  * 48340021
*                                                                     * 48360021
* OUTPUT --                                                           * 48380021
*    REGISTER FIFTEEN (15) CONTAINS --                                * 48400021
*    00 - SUCCESSFUL OPERATION.                                       * 48420021
*    04 - IKJPARS ERROR (TERMINATE EDIT).                             * 48440021
*                                                                     * 48460021
* EXTERNAL REFERENCES --                                              * 48480021
*                                                                     * 48500021
*         IKJEBEPS - THE EDIT PROCESSOR SEARCH ROUTINE, LOADED        * 48520021
*                    AND CALLED TO VALIDATE A DATA SET TYPE AND       * 48540021
*                    RETURN PROCESSOR DEPENDENT INFORMATION FOR       * 48560021
*                    VALID DATA SET TYPES                             * 48580021
*         IKJEBIN3 - CALLED FOR PROCESSING EDIT MESSAGES              * 48600021
*         IKJPARS  - INVOKED VIA LINK MACRO TO SYNTAX CHECK THE  A45713 48620021
*                    RESPONSE FROM IKJPTGT                       A45713 48640021
*         IKJPTGT  - INVOKED VIA PUTGET MACRO TO PROMPT THE USER A45713 48660021
*                    FOR DATA SET TYPE                           A45713 48680021
*                                                                     * 48700021
*    MACROS USED --                                                   * 48720021
*                                                                     * 48740021
*         CALL     - LINKAGE TO IKJEBEPS AND IKJEBIN3.                * 48760021
*         DELETE   - USED TO DELETE IKJEBEPS FROM MAIN STORAGE.       * 48780021
*         IKJEBERT - RETURN LINKAGE WITHIN THE EDIT COMMAND           * 48800021
*                    PROCESSOR.                                       * 48820021
*         IKJEBESV - ENTRY LINKAGE WITHIN THE EDIT COMMAND PROCESSOR. * 48840021
*         IKJENDP  - DEFINES THE END OF THE IKJPARS PCL.              * 48860021
*         IKJIDENT - BUILDS A PCE FOR THE DATA SET TYPE POSITIONAL    * 48880021
*                    PARAMETER.                                       * 48900021
*         IKJPARMD - DEFINES A PCL FOR IKJPARS.                       * 48920021
*         LINK     - LINKAGE TO IKJPARS.                              * 48940021
*         LOAD     - USED TO LOAD THE PROCESSOR SEARCH ROUTINE        * 48960021
*                    (IKJEBEPS) INTO MAIN STORAGE.                    * 48980021
*         PUTGET   - USED TO LINK TO IKJPTGT.                   A45713  49000021
*                                                                     * 49020021
* EXITS, NORMAL --                                                    * 49040021
*    RETURN TO THE CALLING ROUTINE BY BRANCHING ON REGISTER FOURTEEN  * 49060021
*    (14) WITH REGISTER FIFTEEN (15) SET TO ZERO.                     * 49080021
*                                                                     * 49100021
* EXITS, ERROR --                                                     * 49120021
*    RETURN TO THE CALLING ROUTINE BY BRANCHING ON REGISTER           * 49140021
*    FOURTEEN (14) WITH REGISTER FIFTEEN (15) SET TO FOUR (4).        * 49160021
*                                                                     * 49180021
* TABLES/WORK AREAS --                                                * 49200021
*                                                                     * 49220021
*    THE EDIT COMMUNICATION AREA CONTAINS CONTROL INFORMATION AND     * 49240021
*    A WORK AREA FOR THIS ROUTINE --                                  * 49260021
*                                                                     * 49280021
*    CADSTYPE - DATA SET TYPE FIELD.                                  * 49300021
*    CAPD - THIS PROCESSOR TABLE FIELD IS UPDATED BY MOVING THE       * 49320021
*           TABLE ENTRY RETURNED BY IKJEBEPS.                         * 49340021
*                                                                     * 49360021
* ATTRIBUTES --                                                       * 49380021
*    REFRESHABLE, ENABLED, NON-PRIVILEGED                             * 49400021
*                                                                     * 49420021
* CHARACTER CODE DEPENDENCY -- NONE.                                  * 49440021
*                                                                     * 49460021
* NOTES --                                                            * 49480021
*                                                                     * 49500021
*********************************************************************** 49520021
         EJECT                                                          49540021
IKJEBIN5 CSECT                                                          49560021
         IKJEBESV (14,12),,*,COMMREG=D0(,PARMREG1) SAVE REGISTERS       49580021
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY TO THE         49600021
*                                  COMMUNICATION AREA.                  49620021
IC001010 EQU   *                                                 A45713 49640021
**************************************************************** A45713 49660021
*                                                                A45713 49680021
*   BUILD PARMLIST AND LINK TO IKJPTGT TO PROMPT USER FOR DATA   A45713 49700021
*   SET TYPE.                                                    A45713 49720021
*                                                                A45713 49740021
**************************************************************** A45713 49760021
         LA    AREAREG,INPGLIST ADDRESS OF PUTGET PARMBLOCK.     A45713 49780021
         USING PGPB,AREAREG   ESTAB. ADDRESSABILITY TO PARMBLOCK.A45713 49800021
         XC    PGPB(INPGPBLN),PGPB ZERO OUT PARMBLOCK.           A45713 49820021
         ST    AREAREG,CATMPLST+IOPLIOPB-IOPL                    A45713 49840021
         LA    PARMREG1,CATMPLST ADDRESS OF PUTGET PARMLIST.     A45713 49860021
         PUTGET ,OUTPUT=(INPMTOLD,SINGLE,PROMPT),                A45713*49880021
               TERMGET=(EDIT,WAIT),                              A45713*49900021
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),MF=(E,(1))     A45713 49920021
         B     IC001015(RETCDREG) PROCESS RETURN CODE.           A45713 49940021
         SPACE                                                          49960021
IC001015 EQU   *                                                 A45713 49980021
         B     IC001050       RC = 00, SUCCESSFUL RETURN.        A45713 50000021
         B     IC001020       RC = 04, SOURCE OF INPUT IN-CORE.  A45713 50020021
         B     IC001065       RC = 08, ATTENTION ISSUED.         A45713 50040021
         B     IC001040       RC = 12, TRYING TO PROMPT IN PROC. A45713 50060021
         B     IC001020       RC = 16, NOWAIT SPECIFIED FOR TPUT.A45713 50080021
         B     IC001020       RC = 20, NOWAIT SPECIFIED FOR TGET.A45713 50100021
         B     IC001020       RC = 24, INVALID PARAMETERS.       A45713 50120021
         B     IC001030       RC = 28, NOT ENOUGH CORE AVAILABLE.A45713 50140021
         SPACE 2                                                        50160021
IC001020 EQU   *                                                 A45713 50180021
**************************************************************** A45713 50200021
*                                                                A45713 50220021
*   ISSUE COMMAND SYSTEM ERROR MESSAGE AND TERMINATE.            A45713 50240021
*                                                                A45713 50260021
**************************************************************** A45713 50280021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.  A45713 50300021
         LR    DATA2REG,RETCDREG SAVE RETURN CODE FOR MESSAGE.   A45713 50320021
         O     DATA2REG,ICPTGT INDICATE ROUTINE NAME IS IKJPTGT. A45713 50340021
         B     IC001045       BRANCH TO CALL IKJEBIN3 TO PUT     A45713 50360021
*                                  ERROR MESSAGE AND RETURN.     A45713 50380021
         SPACE 2                                                        50400021
IC001030 EQU   *                                                 A45713 50420021
**************************************************************** A45713 50440021
*                                                                A45713 50460021
*   ISSUE NO MAIN STORAGE AVAILABLE MESSAGE AND TERMINATE.       A45713 50480021
*                                                                A45713 50500021
**************************************************************** A45713 50520021
         LA    ERR1REG,INERROR1 RELATIVE ERROR TO BE PROCESSED.  A45713 50540021
         B     IC001045       BRANCH TO CALL IKJEBIN3 TO PUT     A45713 50560021
*                                  ERROR MESSAGE AND TERMINATE.  A45713 50580021
         SPACE 2                                                        50600021
IC001040 EQU   *                                                 A45713 50620021
**************************************************************** A45713 50640021
*                                                                A45713 50660021
*   ISSUE MISSING DATA SET TYPE AND TERMINATE.                   A45713 50680021
*                                                                A45713 50700021
**************************************************************** A45713 50720021
         LA    ERR1REG,INERRORX RELATIVE ERROR TO BE PROCESSED.  A45713 50740021
IC001045 EQU   *                                                        50760021
         L     EPLOCREG,ICMSGRTN ADDRESS OF MESSAGE ROUTINE.     A45713 50780021
         CALL  (15),((COMMREG),(ERR1REG),(ERR2REG),(DATA1REG),         *50800021
               (DATA2REG)),MF=(E,INSVCRTN)                              50820021
         B     IC001065      BRANCH TO RETURN TO CALLER WITH RC=4.      50840021
         SPACE 2                                                        50860021
IC001050 EQU   *                                                 A45713 50880021
         L     PCLREG,ICPTPCL ADDRESS OF PCL FOR IKJPARS.               50900021
         L     AREAREG,PGPBIBUF ADDRESS OF BUFFER.               A45713 50920021
         DROP  AREAREG                                           A45713 50940021
         LA    PDLREG,INPDLPTR SPECIFY ADDRESS OF AREA IN        A45713 50960021
*                                  WHICH IKJPARS RETURNS ADDRESS        50980021
*                                  OF PDL.                              51000021
         XC    CATMPLST+(PPLPCL-PPL)(PPLUWA-PPLPCL+L'PPLUWA),CATMPLST+(X51020021
               PPLPCL-PPL)    ZERO IKJPARS PORTION OF PARAMETER         51040021
*                                  LIST.                                51060021
         LINK  EP=IKJPARS,DCB=0,PARAM=(,,,(PCLREG),(PDLREG),           X51080021
               (AREAREG),(COMMREG)),MF=(E,CATMPLST),             A59325X51100021
               SF=(E,INLINKSF)         LINK TO IKJPARS.          A59325 51120021
         LTR   RETCDREG,RETCDREG TEST FOR SUCCESSFUL COMPLETION.        51140021
         BZ    IC001070       IF SUCCESSFUL, BRANCH TO RETURN    A45713 51160021
         LA    ERR1REG,D8                                               51180021
         CR    ERR1REG,RETCDREG CHECK FOR RETURN CODE 4 OR 8.           51200021
         BNL   IC001065       IF 4 OR 8, RETURN WITH NO          A45713 51220021
*                                  DIAGNOSTIC MESSAGE.                  51240021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.         51260021
         LR    DATA2REG,RETCDREG SAVE RETURN CODE FOR MESSAGE.          51280021
         O     DATA2REG,ICPARS INDICATE ROUTINE NAME AS IKJPARS.        51300021
         CALL  IKJEBIN3,((COMMREG),(ERR1REG),,,(DATA2REG)),            X51320021
               MF=(E,INSVCRTN) PUT ERROR MESSAGE TO USER.               51340021
IC001065 EQU   *                                                 A45713 51360021
         LA    RETCDREG,D4(,D0) SET ERROR RETURN CODE FOR CALLER.       51380021
IC001068 EQU   *                                                 A45713 51400021
         IKJEBERT (14,12),,RC=(15) RESTORE REGISTERS AND RETURN.        51420021
         EJECT                                                          51440021
IC001070 EQU   *                                                 A45713 51460021
*                                                                A45713 51480021
*   DETERMINE IF VALID DATA SET TYPE ENTERED.                    A45713 51500021
*                                                                A45713 51520021
         L     DATAREG,INPDLPTR OBTAIN POINTER TO PROMPT PDL.    A45713 51540021
         USING ICDSTPDL,DATAREG ESTAB. ADDRESSABILITY TO PDL.    A45713 51560021
         LH    INDEXREG,INDSTYP2 OBTAIN KEYWORD NO.              A45713 51580021
         LTR   INDEXREG,INDEXREG CHECK IF DSTYPE ENTERED.        A45713 51600021
         BNZ   IC001080       IF YES, BRANCH TO PROCESS DSTYPE.  A45713 51620021
         IKJRLSA INPDLPTR     RELEASE PDL CORE.                  A45713 51640021
         LH    PARMREG0,D0(,AREAREG) LENGTH OF PUTGET BFR.       A45713 51660021
         L     PARMREG1,INPGLIST+PGPBIBUF-PGPB PTR TO BFR ADDR.  A45713 51680021
         O     PARMREG0,ICSUBPL1 SET SUBPOOL VALUE TO ONE.       A45713 51700021
         FREEMAIN R,LV=(0),A=(1) FREE PUTGET BUFFER.             A45713 51720021
         B     IC001010       BRANCH TO RE-PROMPT USER.          A45713 51740021
         SPACE 2                                                        51760021
IC001080 EQU   *                                                 A45713 51780021
         SLL   INDEXREG,D3(D0) MULTIPLY INDEX BY EIGHT.          A45713 51800021
         L     AREAREG,ICPTTYPE ADDRESS OF DATA SET TYPE TABLE.  A45713 51820021
         SH    AREAREG,ICCONST8 SUBTRACT EIGHT FOR ZERO ORIGIN.  A45713 51840021
         LA    AREAREG,D0(INDEXREG,AREAREG) OBTAIN ADDRESS OF    A45713 51860021
*                                  DATA SET TYPE SPECIFIED.      A45713 51880021
         MVC   CADSTYPE(INDSTELN),D0(AREAREG) MOVE DATA SET TYPE A45713 51900021
*                                  INTO COMMUNICATION AREA.      A45713 51920021
         LOAD  EP=IKJEBEPS    LOAD IKJEBEPS.                            51940021
         LR    EPLOCREG,PARMREG0 COPY ENTRY POINT ADDRESS.              51960021
         CALL  (15),,MF=(E,CADSTYPE) BRANCH TO IKJEBEPS.                51980021
         LTR   RETCDREG,RETCDREG TEST FOR SUCCESSFUL COMPLETION.        52000021
         BZ    IC002070       BRANCH TO MOVE TABLE ENTRY TO THE         52020021
*                                  COMMUNICATION AREA.                  52040021
         LA    RETCDREG,RCODE4 SET RETURN CODE 4 FOR CALLER.     A45713 52060021
IC002060 EQU   *                                                        52080021
         DELETE EP=IKJEBEPS   DELETE IKJEBEPS.                          52100021
         B     IC001068       BRANCH TO RETURN TO CALLER.        A45713 52120021
IC002070 EQU   *                                                        52140021
         MVC   CADSTYPE(CAPDEND-CAPD),D0(PARMREG1) MOVE DATA SET        52160021
*                                  DEPENDENT INFORMATION TO THE         52180021
*                                  COMMUNICATION AREA.                  52200021
         SR    RETCDREG,RETCDREG SET SUCCESSFUL RETURN CODE FOR         52220021
*                                  IKJPARS.                             52240021
         B     IC002060       BRANCH TO DELETE IKJEBEPS.                52260021
         EJECT                                                          52280021
*********************************************************************** 52300021
*                                                                     * 52320021
*   EQUATES, CONSTANTS, AND AREAS USED BY THIS CSECT.                 * 52340021
*                                                                     * 52360021
*********************************************************************** 52380021
ICPTPCL  DC    A(IKJEBIN6)    ADDRESS OF PCL FOR DATA SET TYPE          52400021
*                                  PROMPT.                              52420021
ICMSGRTN DC    V(IKJEBIN3)    ADDRESS OF MESSAGE ROUTINE.               52440021
ICPARS   DC    XL4'01000000'  INDICATOR FOR IKJPARS SERVICE             52460021
*                                  ROUTINE.                             52480021
ICPTGT   DC    XL4'07000000'  INDICATOR FOR IKJPTGT SERV. RTN.          52500021
ICPTTYPE DC    V(IKJEBIN0)    ADDRESS OF DATA SET TYPE TABLE.           52520021
         SPACE                                                          52540021
*   DATA SET TYPE PROMPT MESSAGE.                                A45713 52560021
INPRMTMG DC    AL2(INPRMTLN)  MESSAGE LENGTH.                    A45713 52580021
         DC    H'0'           MESSAGE OFFSET.                    A45713 52600021
         DC    C'IKJ52567A '  MESSAGE IDENTIFIER.                A45713 52620021
         DC    C'ENTER DATA SET TYPE-' MESSAGE TEXT.             A45713 52640021
INPRMTLN EQU   *-INPRMTMG     LENGTH OF PROMPT MESSAGE.          A45713 52660021
* OUTPUT LINE DESCRIPTOR FOR DSTYPE PROMPT MESSAGE.              A45713 52680021
INPMTOLD DC    F'1'           NO. OF MESSAGE SEGMENTS.           A45713 52700021
         DC    A(INPRMTMG)    ADDRESS OF MESSAGE.                A45713 52720021
         SPACE                                                          52740021
ICSUBPL1 DC    XL4'01000000'  INDICATOR FOR SUBPOOL ONE.         A45713 52760021
ICCONST8 DC    H'8'           CONSTANT OF EIGHT.                 A45713 52780021
         TITLE 'IKJEBIN6 - PCL FOR DATA SET TYPE PROMPT'                52800021
IKJEBIN6 IKJPARM DSECT=ICDSTPDL BEGIN PCL FOR DATA SET TYPE.            52820021
INDSTYP2 IKJKEYWD                                                       52840021
.* INITIALIZE INDEX 'J' TO ONE.                                  A45714 52860021
&J       SETA  1                                                 A45714 52880021
.TAG9    ANOP                                                    A45714 52900021
.* CHECK IF LOOP FINISHED - INDEX 'J' GT NO. OF DSTYPES.         A45714 52920021
         AIF   (&J GT &I).OUT3                                   A45714 52940021
.* CHECK FOR DSTYPES WITH SPECIAL SUBFIELDS.                     A45714 52960021
         AIF   ('&DST(&J)' EQ 'PLI').TAG10                       A45714 52980021
         AIF   ('&DST(&J)' EQ 'IPLI').TAG11                      A45714 53000021
         AIF   ('&DST(&J)' EQ 'GOFORT').TAG12                    A45714 53020021
         AIF   ('&DST(&J)' EQ 'PLIF').TAG13                      A45714 53040021
.* CHECK IF DSTYPE IS USER TYPE.                                 A45714 53060021
         AIF   (&J LE 15).TAG9A                                  A45714 53080021
         AIF   (&SW EQ 1).TAG14                                  A45714 53100021
.TAG9A   ANOP                                                    A45714 53120021
         IKJNAME '&DST(&J)' - EDIT DATA SET TYPE.                A45714 53140021
         AGO   .LOOP2                                            A45714 53160021
.TAG10   ANOP                                                    A45714 53180021
         IKJNAME 'PLI',SUBFLD=INPLI2 - EDIT DATA SET TYPE.       A45714 53200021
         AGO   .LOOP2                                            A45714 53220021
.TAG11   ANOP                                                    A45714 53240021
         IKJNAME 'IPLI',SUBFLD=INIPLI2 - EDIT DATA SET TYPE.     A45714 53260021
         AGO   .LOOP2                                            A45714 53280021
.TAG12   ANOP                                                    A45714 53300021
         IKJNAME 'GOFORT',SUBFLD=INTSFTN2 - EDIT DATA SET TYPE.  A45714 53320021
         AGO   .LOOP2                                            A45714 53340021
.TAG13   ANOP                                                    A45714 53360021
         IKJNAME 'PLIF',SUBFLD=INPLI2 - EDIT DATA SET TYPE.      A45714 53380021
         AGO   .LOOP2                                            A45714 53400021
.TAG14   ANOP                                                    A45714 53420021
&K       SETA  &J-15                                             A45714 53440021
.* CHECK IF USER EXIT SUPPLIED FOR DSTYPE.                       A45714 53460021
         AIF   ('&SUBFD(&K)' EQ '').TAG9A                        A45714 53480021
         IKJNAME '&DST(&J)',SUBFLD=INUXRTY2 - USER DSTYPE.       A45714 53500021
.LOOP2   ANOP                                                    A45714 53520021
.* INCREMENT LOOP INDEX 'J' BY ONE.                              A45714 53540021
&J       SETA  &J+1                                              A45714 53560021
         AGO   .TAG9                                             A45714 53580021
.OUT3    ANOP                                                    A45714 53600021
*                             SUBFIELD DESCRIPTION FOR PL1.      A45714 53620021
INPLI2   IKJSUBF                                                        53640021
INPLICL1 IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC,          A45714*53660021
               DEFAULT='2',VALIDCK=IKJEBIN4 LEFT SOURCE MARGIN.  A45714 53680021
INPLICL2 IKJIDENT 'NUMBER',FIRST=NUMERIC,OTHER=NUMERIC,          A45714*53700021
               DEFAULT='72',VALIDCK=IKJEBIN4 RIGHT SOURCE MARGIN.A45714 53720021
INPLITYP IKJKEYWD DEFAULT='CHAR60' CHARACTER SET USED.           A45714 53740021
         IKJNAME 'CHAR60'     60 CHARACTER SET.                  A45714 53760021
         IKJNAME 'CHAR48'     48 CHARACTER SET.                  A45714 53780021
INIPLI2  IKJSUBF                                                        53800021
INIPLIC2 IKJKEYWD DEFAULT='CHAR60' CHARACTER SET TO BE USED.     A45714 53820021
         IKJNAME 'CHAR60'     60-CHARACTER SET.                  A45714 53840021
         IKJNAME 'CHAR48'     48-CHARACTER SET.                  A45714 53860021
*                             SUBFIELD DESCRIPTION FOR GOFORT.   A45714 53880021
INTSFTN2 IKJSUBF                                                        53900021
INTSFTF2 IKJKEYWD DEFAULT='FREE' DEFINE STATEMENT FORMAT.        A45714 53920021
         IKJNAME 'FREE'       FREE FORMAT STATEMENTS.           1A45714 53940021
         IKJNAME 'FIXED'      FIXED FORMAT STATEMENTS.          2A45714 53960021
.* CHECK IF USER EXIT SUPPLIED.                                  A45714 53980021
         AIF   (&SW EQ 0).TAG15                                  A45714 54000021
*                             SUBFIELD DESCRIPT. FOR USER TYPES. A45714 54020021
INUXRTY2 IKJSUBF                                                        54040021
INUSRTY2 IKJIDENT 'DATA SET TYPE PARAMETERS',FIRST=ANY,OTHER=ANY A45714 54060021
.TAG15   ANOP                                                    A45714 54080021
         IKJENDP                                                        54100021
         EJECT                                                          54120021
         TITLE 'IKJEBIN7 - PARTIALLY QUALIFIED DSNAME PROCESSING'       54140021
*********************************************************************** 54160021
*                                                                     * 54180021
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 54200021
*                                                                     * 54220021
* FUNCTION -- THIS ROUTINE IS CALLED BY THE IKJEBEIN CSECT OF THE     * 54240021
*    EDIT INITIALIZATION PROGRAM WHENEVER A PARTIALLY QUALIFIED       * 54260021
*    DSNAME IS ENTERED ON THE EDIT COMMAND.  IT SCANS OFF THE         * 54280021
*    RIGHTMOST QUALIFIER OF THE DSNAME AND DETERMINES IF THE NAME     * 54300021
*    IS (1) SINGLE-LEVEL OR (2) MULTI-LEVEL.  IF SINGLE-LEVEL, IT     * 54320021
*    UNCONDITIONALLY APPENDS A DESCRIPTIVE QUALIFIER FOR THE DATA     * 54340021
*    SET TYPE ENTERED OR PROMPTED FOR.  IT ALSO TAKES THE ABOVE       * 54360021
*    ACTION WHEN THE RIGHTMOST QUALIFIER OF A MULTI-LEVEL NAME IS NOT * 54380021
*    DESCRIPTIVE FOR THE DATA SET TYPE ENTERED ON THE COMMAND.  IF    * 54400021
*    THE NAME IS MULTI-LEVEL AND DATA SET TYPE WAS NOT SPECIFIED,     * 54420021
*    IT DETERMINES WHETHER THE RIGHTMOST QUALIFIER IS DESCRIPTIVE     * 54440021
*    FOR ANY DATA SET TYPE BY LOADING AND CALLING THE EDIT            * 54460021
*    PROCESSOR SEARCH ROUTINE (IKJEBEPS).  IF THE QUALIFIER IS        * 54480021
*    DESCRIPTIVE, DATA SET TYPE DEFAULTS BASED ON THE QUALIFIER.      * 54500021
*    OTHERWISE DATA SET TYPE IS PROMPTED FOR AND THE ASSOCIATED       * 54520021
*    QUALIFIER IS APPENDED TO THE DSNAME ENTERED.  THE PARTIALLY-     * 54540021
*    QUALIFIED NAME IS ALWAYS ADJUSTED SUCH THAT PARAMETERS FOR THE   * 54560021
*    DEFAULT SERVICE ROUTINE (IKJDFLT) DO NOT CONTAIN ANY             * 54580021
*    REDUNDANCY BETWEEN (1) THE RIGHTMOST QUALIFIER OF THE DSNAME AND * 54600021
*    (2) THE QUALIFIER TO BE SUFFIXED TO THE NAME.  THE DEFAULT       * 54620021
*    SERVICE ROUTINE IS INVOKED TO (1) FULLY QUALIFY THE NAME         * 54640021
*    SYNTACTICALLY AND (2) TO PERFORM A CATALOG SEARCH ON THE FULLY   * 54660021
*    QUALIFIED DSNAME.  THE RETURN CODE FROM THE DEFAULT SERVICE      * 54680021
*    ROUTINE IS CHECKED AND ERROR MESSAGES ISSUED IF NECESSARY.       * 54700021
*                                                                     * 54720021
* ENTRY POINTS --                                                     * 54740021
*         IKJEBIN7 - VIA CALL MACRO FROM IKJEBEIN, THE MAIN CSECT     * 54760021
*                    OF THE EDIT INITIALIZATION PROGRAM WHEN A        * 54780021
*                    PARTIALLY QUALIFIED DSNAME IS ENTERED ON THE     * 54800021
*                    EDIT COMMAND.                                    * 54820021
*                                                                     * 54840021
* INPUT --                                                            * 54860021
*    REGISTER ONE (1) CONTAINS A POINTER TO A WORD CONTAINING THE     * 54880021
*    ADDRESS OF THE EDIT COMMUNICATION AREA.                          * 54900021
*                                                                     * 54920021
* OUTPUT --                                                           * 54940021
*    REGISTER FIFTEEN (15) CONTAINS ONE OF THE FOLLOWING              * 54960021
*    RETURN CODES --                                                  * 54980021
*                                                                     * 55000021
*    00 - SUCCESSFUL COMPLETION.                                      * 55020021
*    04 - TERMINATION REQUIRED - ERROR OCCURRED.                      * 55040021
*                                                                     * 55060021
* EXTERNAL REFERENCES --                                              * 55080021
*                                                                     * 55100021
*         IKJDFLT  - DEFAULT SERVICE ROUTINE, INVOKED VIA LINK TO     * 55120021
*                    QUALIFY THE NAME SUPPLIED BY THE USER AND TO     * 55140021
*                    PERFORM A CATALOG SEARCH ON IT.                  * 55160021
*         IKJEBIN3 - CSECT OF EDIT INITIALIZATION CALLED FOR          * 55180021
*                    INITIAL MESSAGE PROCESSING.                      * 55200021
*         IKJEBIN5 - CSECT OF EDIT INITIALIZATION CALLED TO PROMPT    * 55220021
*                    THE USER FOR DATA SET TYPE.                      * 55240021
*                                                                     * 55260021
*    MACROS USED --                                                   * 55280021
*                                                                     * 55300021
*         CALL     - USED FOR LINKAGE TO MODULES CONTAINED IN THE     * 55320021
*                    LOAD MODULE AS WELL AS IKJEBEPS, THE PROCESSOR   * 55340021
*                    SEARCH ROUTINE.                                  * 55360021
*         DELETE   - USED TO DELETE THE IKJEBEPS MODULE FROM MAIN     * 55380021
*                    STORAGE.                                         * 55400021
*         IKJEBERT - RETURN LINKAGE WITHIN THE EDIT COMMAND PROCESSOR.* 55420021
*         IKJEBESV - ENTRY LINKAGE WITHIN THE EDIT COMMAND PROCESSOR. * 55440021
*         LINK     - ISSUED TO INVOKE THE DEFAULT SERVICE ROUTINE.    * 55460021
*         LOAD     - ISSUED TO LOAD IKJEBEPS INTO MAIN STORAGE.       * 55480021
*                                                                     * 55500021
* EXITS, NORMAL --                                                    * 55520021
*    RETURN TO IKJEBEIN BY BRANCHING ON REGISTER FOURTEEN (14)        * 55540021
*    WITH REGISTER FIFTEEN (15) SET TO ZERO (0).                      * 55560021
*                                                                     * 55580021
* EXITS, ERROR --                                                     * 55600021
*    RETURN TO IKJEBEIN BY BRANCHING ON REGISTER FOURTEEN (14)        * 55620021
*    WITH REGISTER FIFTEEN (15) SET TO FOUR (4).                      * 55640021
*                                                                     * 55660021
* TABLES/WORK AREAS --                                                * 55680021
*                                                                     * 55700021
*    THE EDIT COMMUNICATION AREA CONTAINS CONTROL INFORMATION AND     * 55720021
*    A WORK AREA FOR THIS ROUTINE.  THE FOLLOWING FIELDS ANR (1) USED * 55740021
*    AS INPUT AND (2) ARE UPDATED BY THIS ROUTINE --                  * 55760021
*                                                                     * 55780021
*    CADSQUAL - DESCRIPTIVE QUALIFIER FIELD.                          * 55800021
*                                                                     * 55820021
*    CAEDDSN  - DSNAME ENTERED BY THE USER AND QUALIFIED BY THIS      * 55840021
*               ROUTINE.                                              * 55860021
*                                                                     * 55880021
*    THE PROCESSOR TABLE (BEGINNING AT OFFSET 'CAPD') IS INITIALIZED  * 55900021
*    BY THIS ROUTINE OR BY IKJEBIN5 WHENEVER THE DATA SET TYPE IS     * 55920021
*    DEFAULTED OR PROMPTED FOR.                                       * 55940021
*                                                                     * 55960021
* ATTRIBUTES --                                                       * 55980021
*    REFRESHABLE, ENABLED, NON-PRIVILEGED                             * 56000021
*                                                                     * 56020021
* CHARACTER CODE DEPENDENCY -- NONE.                                  * 56040021
*                                                                     * 56060021
* NOTES -- NONE.                                                      * 56080021
*                                                                     * 56100021
*********************************************************************** 56120021
         EJECT                                                          56140021
IKJEBIN7 CSECT                                                          56160021
*********************************************************************** 56180021
*                                                                       56200021
*                             PROLOGUE                                  56220021
*                                                                       56240021
*********************************************************************** 56260021
         IKJEBESV (14,12),,*,COMMREG=D0(,PARMREG1) ENTRY LINKAGE        56280021
         USING IKJEBECA,COMMREG ESTABLISH COMMUNICATION AREA            56300021
*                               ADDRESSABILITY                          56320021
         XC    IN7WORK(IN7WKLEN),IN7WORK ZERO WORK AREA.                56340021
         EJECT                                                          56360021
*********************************************************************** 56380021
*                                                                       56400021
* THIS SECTION SCANS THE USER-SUPPLIED NAME.  IF THE NAME IS NULL OR    56420021
* CONTAINS ONE LEVEL ONLY, A SWITCH IS SET TO INDICATE THAT NO          56440021
* QUALIFIER CHECKING IS TO BE DONE.  OTHERWISE, THE LENGTH AND          56460021
* ADDRESS OF THE RIGHTMOST QUALIFIER ARE ESTABLISHED.                   56480021
*                                                                       56500021
*********************************************************************** 56520021
         SPACE 2                                                        56540021
         LH    LENREG,CAEDDSNL GET LENGTH OF USER SUPPLIED NAME.        56560021
         LA    TMPREG,D2      CONSTANT FOR COMPARES.                    56580021
         SR    LENREG,TMPREG  IF USER NAME IS 2 CHARACTERS OR LESS,     56600021
         BNH   ID000020       BRANCH TO INDICATE SIMPLE NAME.           56620021
         LA    QUALREG,CAEDDSN(LENREG) ADDRESS NEXT-TO-LAST CHAR.       56640021
ID000010 EQU   *                                                        56660021
         CLI   D0(QUALREG),INPERIOD IS CHARACTER A PERIOD -             56680021
         BE    ID000030       IF SO, QUALIFIER CHECK IS REQUIRED.       56700021
         BCTR  QUALREG,D0     ADDRESS NEXT CHARACTER TO LEFT.           56720021
         BCT   LENREG,ID000010 DECREMENT LEN AND REPEAT IF GT 0.        56740021
ID000020 EQU   *                                                        56760021
         OI    IN7FLAGS,IN7NOQLF INDICATE NO QUALIFIER CHECKING.        56780021
         B     ID000040       BRANCH TO CONTINUE PROCESSING.            56800021
ID000030 EQU   *                                                        56820021
         NI    IN7FLAGS,IN7QLFCK INDICATE QUALIFIER CHECKING.           56840021
         SH    LENREG,CAEDDSNL SUBTRACT FULL LENGTH FROM LENGTH.        56860021
         LCR   LENREG,LENREG  COMPLEMENT TO GET QUALIFIER LENGTH.       56880021
         SR    LENREG,TMPREG  ADJUST QUALIFIER LENGTH FOR               56900021
*                             SS OPERATIONS                             56920021
         EJECT                                                          56940021
*********************************************************************** 56960021
*                                                                       56980021
* THIS SECTION MAKES NECESSARY CHECKS ON THE RIGHTMOST QUALIFIER.       57000021
*                                                                       57020021
* IF NO QUALIFIER CHECKS ARE NECESSARY, DATA SET TYPE IS PROMPTED       57040021
* FOR IF NOT ENTERED ON THE COMMAND.  THE DEFAULT SERVICE ROUTINE       57060021
* MAY THEN BE INVOKED TO QUALIFY THE USER-SUPPLIED NAME.                57080021
*                                                                       57100021
* IF QUALIFIER CHECKING IS NECESSARY, IKJEBEPS IS INVOKED TO            57120021
* DETERMINE WHETHER THE RIGHTMOST QUALIFIER IS DESCRIPTIVE FOR          57140021
* EDIT.  IF NOT, PROCESSING IS BASED ON THE QUALIFIER ASSOCIATED        57160021
* WITH THE DATA SET TYPE ENTERED OR PROMPTED FOR.  IF THE QUALIFIER     57180021
* IS DESCRIPTIVE AND DATA SET TYPE WAS NOT ENTERED ON THE COMMAND       57200021
* DATA SET TYPE IS BASED ON THE REGHTMOST QUALIFIER OF THE DSNAME.      57220021
* IF THE QUALIFIER IS DESCRIPTIVE AND DATA SET TYPE WAS ENTERED,        57240021
* STRIPPING OF THE QUALIFIER IS PERFORMED WHEN THE QUALIFIER            57260021
* IS DESCRIPTIVE FOR THE DATA SET TYPE ENTERED.                         57280021
*                                                                       57300021
*********************************************************************** 57320021
         SPACE 2                                                        57340021
ID000040 EQU   *                                                        57360021
         TM    IN7FLAGS,IN7NOQLF IS QUALIFIER CHECKING NECESSARY -      57380021
         BZ    ID000060       IF NECESSARY, BRANCH TO VALIDATE          57400021
         CLI   CADSCODE,CANOTYPE WAS DATA SET TYPE ENTERED -            57420021
         BNE   ID000130       IF SO, BRANCH TO INVOKE DEFAULT.          57440021
ID000050 EQU   *                                                        57460021
         CALL  IKJEBIN5,((COMMREG)),MF=(E,IN7PLIST) CALL IKJEBIN5       57480021
*                                  TO PROMPT FOR DATA SET TYPE.         57500021
         LTR   RETCDREG,RETCDREG WAS PROMPT SUCCESSFUL -                57520021
         BZ    ID000110       IF SO, BRANCH TO INVOKE DEFAULT.          57540021
         BNZ   IDRETCD4       IF NOT, RETURN TO IKJEBEIN WITH RC=4.     57560021
         EJECT                                                          57580021
ID000060 EQU   *                                                        57600021
         LOAD  EP=IKJEBEPS    LOAD PROCESSOR SEARCH ROUTINE.            57620021
         OI    IN7FLAGS,IN7DELPS SPECIFY DELETE NECESSARY FOR           57640021
*                                  ROUTINE.                             57660021
         LR    EPLOCREG,PARMREG0 COPY ENTRY POINT ADDRESS.              57680021
         LA    PARMREG1,D1(,QUALREG) POINT TO QUALIFIER.                57700021
         LCR   PARMREG1,PARMREG1 SPECIFY SEARCH ON QUALIFIER.           57720021
         CALL  (15),MF=(E,(1)) CALL IKJEBEPS.                           57740021
         LTR   RETCDREG,RETCDREG IS QUALIFIER DESCRIPTIVE -             57760021
         BNZ   ID000070       IF NOT, BRANCH TO CHECK DATA SET TYPE.    57780021
         CLI   CADSCODE-CAPD(PARMREG1),CAEDTTYP IS QUALIFIER            57800021
*                                  DESCRIPTIVE FOR EDIT -               57820021
         BNH   ID000080       IF SO, BRANCH TO CHECK DATA SET           57840021
*                             TYPE ENTERED AGAINST QUALIFIER.           57860021
ID000070 EQU   *                                                        57880021
         CLI   CADSCODE,CANOTYPE DATA SET TYPE ENTERED ON COMMAND -     57900021
         BE    ID000050       IF NOT, BRANCH TO CAUSE PROMPT.           57920021
         B     ID000120       IF SO, BRANCH TO INVOKE DEFAULT.          57940021
ID000080 EQU   *                                                        57960021
         CLI   CADSCODE,CANOTYPE WAS TYPE ENTERED ON COMMAND -          57980021
         BNE   ID000100       IF SO, BRANCH TO COMPARE QUALIFIERS.      58000021
         MVC   CAPD(CAPDEND-CAPD),D0(PARMREG1) IF NOT, MOVE             58020021
*                                  PROCESSOR TABLE TO COMM AREA.        58040021
ID000090 EQU   *                                                        58060021
         LH    QUALREG,CAEDDSNL GET DSNAME LENGTH.                      58080021
         LA    LENREG,D2(,LENREG) ADJUST QUALIFIER LENGTH.              58100021
         SR    QUALREG,LENREG SUBTRACT QUALIFIER LENGTH.                58120021
         STH   QUALREG,CAEDDSNL UPDATE DSNAME LENGTH TO LOGICALLY       58140021
*                                  REMOVE RIGHTMOST QUALIFIER.          58160021
         B     ID000120       BRANCH TO INVOKE DEFAULT SERVICE          58180021
*                                  ROUTINE.                             58200021
ID000100 EQU   *                                                        58220021
         EX    LENREG,IDCOMPCL COMPARE TABLE QUALIFIER AND              58240021
*                                  RIGHTMOST QUALIFIER OF NAME.         58260021
         BE    ID000090       IF ALIKE, STRIP NAME QUALIFIER.           58280021
         BNE   ID000120       IF DIFFERENT, BRANCH TO QUALIFY NAME.     58300021
         EJECT                                                          58320021
*********************************************************************** 58340021
*                                                                       58360021
* THIS SECTION INVOKES THE DEFAULT SERVICE ROUTINE TO FULLY QUALIFY     58380021
* THE NAME ENTERED.  IKJEBEPS IS DELETED IF NECESSARY PRIOR TO          58400021
* INITIALIZING PARAMETERS FOR DEFAULT.  PARAMETERS ARE SPECIFIED        58420021
* FOR APPENDING THE USERID AND DESCRIPTIVE QUALIFIER.  IKJDFLT IS       58440021
* INVOKED VIA LINK. RETURN CODES ARE DIAGNOSED AND DIAGNOSTICS          58460021
* ISSUED IF NECESSARY.  RETURN CODES TO IKJEBEIN ARE --                 58480021
*                                                                       58500021
*     0 - SUCCESSFUL.                                                   58520021
*     4 - NOT SUCCESSFUL (TERMINATE EDIT).                              58540021
*                                                                       58560021
*********************************************************************** 58580021
         SPACE 2                                                        58600021
ID000110 EQU   *                                                        58620021
         TM    IN7FLAGS,IN7DELPS MUST IKJEBEPS BE DELETED -             58640021
         BZ    ID000130       IF NOT, BRANCH TO INVOKE IKJDFLT          58660021
ID000120 EQU   *                                                        58680021
         DELETE EP=IKJEBEPS   DELETE PROCESSOR SEARCH ROUTINE.          58700021
         LTR   RETCDREG,RETCDREG WAS DELETE SUCCESSFUL -                58720021
         BZ    ID000130       IF SO, CONTINUE.                          58740021
         B     ID000200       IF NOT, ISSUE DIAGNOSTIC AND              58760021
*                                  TERMINATE.                           58780021
ID000130 EQU   *                                                        58800021
         LA    TMPREG,DFPB00  SPECIFY ENTRY CODE FOR IKJDFLT.           58820021
         STC   TMPREG,IN7PLIST+DFPBCODE-DFPB SET ENTRY CODE BYTE        58840021
*                                  IN PARAMETER BLOCK.                  58860021
         LA    DSNAMREG,CAEDDSNL ADDRESS USER-SUPPLIED DSNAME.          58880021
         ST    DSNAMREG,IN7PLIST+DFPBDSN-DFPB STORE DSNAME IN           58900021
*                                  DEFAULT PARAMETER BLOCK.             58920021
         L     TMPREG,CAPTTMP ADDRESS COMMAND PARAMETER LIST.           58940021
         L     PASSREG,CPPLPSCB-CPPL(,TMPREG) ADDRESS PSCB.             58960021
         ST    PASSREG,IN7PLIST+DFPBPSCB-DFPB STORE PSCB ADDRESS        58980021
*                                  IN DEFAULT PARAMETER BLOCK.          59000021
         LA    QUALREG,CADSQUAL ADDRESS DESCRIPTIVE QUALIFIER.          59020021
         ST    QUALREG,IN7PLIST+DFPBQUAL-DFPB STORE QUALIFIER           59040021
*                                  ADDRESS IN PARAMETER BLOCK.          59060021
         MVI   IN7PLIST+DFPBCNTL-DFPB,DFPBUID SPECIFY PREFIXING         59080021
*                                  OF USERID TO DSNAME.                 59100021
         LA    QUALREG,IN7PLIST ADDRESS DEFAULT PARAMETER BLOCK         59120021
         ST    QUALREG,CATMPLST+DFPLDFPB-DFPL AND CHAIN TO              59140021
*                                  PARAMETER LIST.                      59160021
         LINK  EP=IKJDFLT,MF=(E,CATMPLST) INVOKE DEFAULT SERVICE        59180021
*                                  ROUTINE.                             59200021
         LR    ERR1REG,RETCDREG SAVE RETURN CODE.                       59220021
         SRL   RETCDREG,D2    DIVIDE RETURN CODE BY 4 FOR USE           59240021
*                                  AS INDEX TO TABLE.                   59260021
         IC    RETCDREG,IDRCTAB(RETCDREG) GET ACTION CODE.              59280021
         EJECT                                                          59300021
*********************************************************************** 59320021
*                                                                       59340021
* ACTION CODES ARE BASED ON RETURN CODES FROM THE DEFAULT SERVICE       59360021
* ROUTINE --                                                            59380021
*                                                                       59400021
* ACTION CODE   DEFAULT RC'S  ACTION                                    59420021
*                                                                       59440021
*     00           00,20,36   SUCCESSFUL RETURN                         59460021
*     04           24         RETURN WITH RETURN CODE=04.               59480021
*     08           08         INVALID DSNAME MSG - RC IS 04.            59500021
*     12           16         CATALOG STRUCTURE MSG - RC IS 04.         59520021
*     16           04         NAME NOT RESOLVED MSG - RC IS 04.         59540021
*     20           12         NAME NOT RESOLVED MSG - RC IS 04.         59560021
*     24           28,32      COMMAND SYSTEM ERROR MSG - RC IS 04.      59580021
*                                                                       59600021
* THE ACTION CODE IS USED AS AN INDEX TO THE BRANCH TABLE BELOW.        59620021
*                                                                       59640021
*********************************************************************** 59660021
         SPACE 2                                                        59680021
         B     ID000140(RETCDREG) BRANCH TO BRANCH TABLE.               59700021
ID000140 EQU   *              THIS BRANCH TABLE IS POSITION             59720021
*                                  DEPENDENT.                           59740021
         B     IDRETURN       SUCCESSFUL - RETURN WITH RETURN CODE      59760021
*                                  ZERO.                                59780021
         B     IDRETURN       ATTN ISSUED - RETURN WITH RETURN          59800021
*                                  CODE FOUR.                           59820021
         B     ID000150       ISSUE DIAGNOSTIC - RC IS FOUR.            59840021
         B     ID000160       ISSUE DIAGNOSTIC - RC IS FOUR.            59860021
         B     ID000180       ISSUE DIAGNOSTIC - RC IS FOUR.            59880021
         B     ID000180       ISSUE DIAGNOSTIC - RC IS FOUR.            59900021
         B     ID000190       ISSUE DIAGNOSTIC - RC IS FOUR.            59920021
         EJECT                                                          59940021
*********************************************************************** 59960021
*                                                                       59980021
*                 DIAGNOSTICS AND RETURN LINKAGE.                       60000021
*                                                                       60020021
*********************************************************************** 60040021
         SPACE 2                                                        60060021
ID000150 EQU   *              INVALID DSNAME.                           60080021
         LA    ERR1REG,INERRORR SPECIFY MESSAGE INDEX.                  60100021
         B     ID000220       BRANCH TO CALL IKJEBIN3.                  60120021
         SPACE                                                          60140021
ID000160 EQU   *              LOCATE RC 16 RETURNED TO DEFAULT          60160021
*                                  SERVICE ROUTINE.                     60180021
         LA    ERR1REG,INERRORS SPECIFY MESSAGE INDEX.                  60200021
         SR    DATA1REG,DATA1REG SPECIFY THAT DSNAME INSERTION          60220021
*                                  MUST BE BUILT FOR MESSAGE.           60240021
         B     ID000220       BRANCH TO CALL IKJEBIN3.                  60260021
         SPACE                                                          60280021
ID000180 EQU   *              DEFAULT ERROR CODE 4 OR 12.               60300021
         LR    DATA2REG,ERR1REG COPY DEFAULT RETURN CODE.               60320021
         LA    ERR2REG,M3151  SPECIFY RELATIVE LEVEL-2 MESSAGE.         60340021
         LA    ERR1REG,INERRORU SPECIFY MESSAGE INDEX.                  60360021
         B     ID000220       BRANCH TO CALL IKJEBIN3.                  60380021
         SPACE                                                          60400021
ID000190 EQU   *              COMMAND SYSTEM ERROR IN DEFAULT           60420021
*                                  SERVICE ROUTINE.                     60440021
         LR    DATA2REG,ERR1REG COPY DEFAULT RETURN CODE.               60460021
         O     DATA2REG,IDDFAULT SPECIFY SECOND-LEVEL INSERTION         60480021
*                                  NAME - 'DEFAULT'                     60500021
         B     ID000210       BRANCH TO CONTINUE.                       60520021
         SPACE                                                          60540021
ID000200 EQU   *              DELETE SVC ERROR.                         60560021
         LR    DATA2REG,RETCDREG COPY DELETE RETURN CODE.               60580021
         O     DATA2REG,IDDELSVC SPECIFY SECOND-LEVEL INSERTION         60600021
*                                  NAME - 'DELETE SVC'                  60620021
         SPACE                                                          60640021
ID000210 EQU   *              COMMAND SYSTEM ERROR.                     60660021
         LA    ERR1REG,INERROR2 SPECIFY MESSAGE INDEX.                  60680021
         SPACE                                                          60700021
ID000220 EQU   *              CALL MESSAGE INITIALIZATION ROUTINE.      60720021
         CALL  IKJEBIN3,((COMMREG),(ERR1REG),,,(DATA2REG)),            X60740021
               MF=(E,IN7PLIST) CALL IKJEBIN3.                           60760021
IDRETCD4 EQU   *                                                        60780021
         LA    RETCDREG,D4    RETURN CODE TO IKJEBEIN IS FOUR.          60800021
IDRETURN EQU   *                                                        60820021
         IKJEBERT (14,12),,RC=(15) RETURN TO IKJEBEIN.                  60840021
         EJECT                                                          60860021
*********************************************************************** 60880021
*                                                                       60900021
*                  LOCAL STORAGE CONSTANTS AND EXECUTED INSTRUCTIONS.   60920021
*                                                                       60940021
*********************************************************************** 60960021
         SPACE 2                                                        60980021
         DS    0F             ALIGNMENT.                                61000021
IDDFAULT DC    X'05000000'    INDICATOR FOR DEFAULT INSERTION.          61020021
IDDELSVC DC    X'06000000'    INDICATOR FOR DELETE SVC INSERTION.       61040021
         SPACE 2                                                        61060021
IDCOMPCL CLC   D1(*-*,QUALREG),CADSQUAL COMPARE RIGHTMOST               61080021
*                                  QUALIFIER TO QUALIFIER IN            61100021
*                                  PROCESSOR TABLE.                     61120021
         SPACE 2                                                        61140021
IDRCTAB  DC    X'001008140C0004181800' ACTION CODE TABLE.               61160021
         EJECT                                                          61180021
         TITLE 'IKJEBIN8 - OPERAND PROCESSING'                          61200021
*********************************************************************** 61220021
*                                                                     * 61240021
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 61260021
*                                                                     * 61280021
* FUNCTION -- THIS ROUTINE VALIDATES KEYWORD AND DATA SET TYPE        * 61300021
*    SUBFIELD OPERANDS ENTERED ON THE EDIT COMMAND.  THE LINE         * 61320021
*    OPERAND (OR LRECL IN THE CASE OF AN OLD DATA SET) IS VALIDATED   * 61340021
*    AGAINST TABLE ENTRIES ASSOCIATED WITH THE DATA SET TYPE.         * 61360021
*    THE BLOCK OPERAND (OR BLOCK SIZE) IS CHECKED IN MUCH THE SAME    * 61380021
*    WAY.  THE REMAINING EDIT OPERANDS ARE VALIDITY CHECKED IN THE    * 61400021
*    FOLLOWING ORDER --                                               * 61420021
*                                                                     * 61440021
*    (1) SCAN/NOSCAN                                                  * 61460021
*    (2) NUM/NONUM                                                    * 61480021
*    (3) CAPS/ASIS                                                    * 61500021
*                                                                     * 61520021
*    SPECIAL CASES ARE THOSE DATA SET TYPES FOR WHICH THE USER MAY    * 61540021
*    OPTIONALLY SPECIFY SUBFIELD OPERANDS --                          * 61560021
*                                                                     * 61580021
*    (1) IPLI CHARACTER SET                                           * 61600021
*    (2) PLI OR PLIF CHARACTER SET AND SOURCE MARGINS                 * 61620021
*    (3) GOFORT FORMAT (FIXED OR FREE)                                * 61640021
*    (4) USER DSTYPE SUBFIELD, IF SYSGENED                       A45714 61660021
*                                                                     * 61680021
*    IN CASES 1,2, AND 4, OPERAND CHECKING FOLLOWS VALIDATION    A45714 61700021
*    OF THE OTHER EDIT OPERANDS.  IN CASE 3, SPECIAL             A45714 61720021
*    PROCESSING IS DONE IN PARALLEL WITH LINE OPERAND VALIDATION.     * 61740021
*                                                                     * 61760021
*    MESSAGES ARE ISSUED WHENEVER INVALID, INCONSISTENT, OR           * 61780021
*    SUPERFLUOUS OPERANDS ARE SPECIFIED OR INVALID LRECL'S OR         * 61800021
*    BLKSIZE'S ENCOUNTERED.                                           * 61820021
*                                                                     * 61840021
* ENTRY POINTS --                                                     * 61860021
*         IKJEBIN8 - VIA CALL MACRO FROM IKJEBEIN, THE MAIN CSECT     * 61880021
*                    OF THE EDIT INITIALIZATION PROGRAM WHEN IT       * 61900021
*                    BECOMES NECESSARY TO VALIDATE COMMAND OPERANDS.  * 61920021
*                                                                     * 61940021
* INPUT --                                                            * 61960021
*    REGISTER ONE (1) CONTAINS A POINTER TO A TWO-WORD                * 61980021
*    PARAMETER LIST --                                                * 62000021
*    WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA                  * 62020021
*    WORD 2 - ADDRESS OF THE EDIT COMMAND PDL                         * 62040021
*                                                                     * 62060021
*    REGISTER ZERO (0) CONTAINS AN ENTRY CODE --                      * 62080021
*    00 - OLD DATA SET                                                * 62100021
*    04 - NEW DATA SET                                                * 62120021
*                                                                     * 62140021
* OUTPUT --                                                           * 62160021
*    REGISTER FIFTEEN (15) CONTAINS A RETURN CODE --                  * 62180021
*                                                                     * 62200021
*    00 - SUCCESSFUL OPERATION.                                       * 62220021
*    04 - TERMINATION ERROR.                                          * 62240021
*                                                                     * 62260021
* EXTERNAL REFERENCES --                                              * 62280021
*                                                                     * 62300021
*         IKJEBIN3 - CALLED FOR INITIAL MESSAGE PROCESSING            * 62320021
*                                                                     * 62340021
*    MACROS USED --                                                   * 62360021
*                                                                     * 62380021
*         BLDL     - BUILD LIST OF DIRECTORY INFORMATION         A45714 62400021
*         CALL     - LINKAGE TO IKJEBIN3.                             * 62420021
*         DEVTYPE  - ISSUED FOR OLD DATA SETS IN ORDER TO OBTAIN      * 62440021
*                    TRACK CAPACITY.                                  * 62460021
*         IKJEBEMG - BUILDING MESSAGE INSERTION LISTS.                * 62480021
*         IKJEBERT - RETURN LINKAGE WITHIN THE EDIT COMMAND           * 62500021
*                    PROCESSOR.                                       * 62520021
*         IKJEBESV - ENTRY LINKAGE WITHIN THE EDIT COMMAND PROCESSOR. * 62540021
*         LINK     - PASS CONTROL TO EXTERNAL PROGRAM            A45714 62560021
*                                                                     * 62580021
* EXITS, NORMAL --                                                    * 62600021
*    RETURN TO THE CALLING ROUTINE BY BRANCHING ON REGISTER           * 62620021
*    FOURTEEN (14) WITH REGISTER FIFTEEN (15) SET TO ZERO (0).        * 62640021
*                                                                     * 62660021
* EXITS, ERROR --                                                     * 62680021
*    RETURN TO THE CALLING ROUTINE BY BRANCHING ON REGISTER           * 62700021
*    FOURTEEN (14) WITH REGISTER FIFTEEN (15) SET TO FOUR (4).        * 62720021
*                                                                     * 62740021
* TABLES/WORK AREAS --                                                * 62760021
*                                                                     * 62780021
*    THE EDIT COMMUNICATION AREA CONTAINS CONTROL INFORMATION AND     * 62800021
*    WORK AREAS FOR THIS ROUTINE.  THE FOLLOWING FIELDS ARE UPDATED   * 62820021
*    BY IKJEBIN8 --                                                   * 62840021
*                                                                     * 62860021
*    CABLKS   - BLOCK SIZE                                            * 62880021
*    CACFLAG1 - CONTROL FLAG                                          * 62900021
*    CACFLAG2 - CONTROL FLAG                                          * 62920021
*    CACFLAG6 - CONTROL FLAG                                          * 62940021
*    CADSATTR - DATA SET ATTRIBUTES FLAG                              * 62960021
*    CALINE   - STARTING POSITION FOR SEQUENCE NUMBER                 * 62980021
*    CALENGTH - SEQUENCE NUMBER LENGTH                                * 63000021
*    CALRECL  - LOGICAL RECORD LENGTH                                 * 63020021
*    CAPLIRTM - RIGHT SOURCE MARGIN POSITION                          * 63040021
*    CAPLILFM - LEFT SOURCE MARGIN POSITION                           * 63060021
*    CACHKOPT - LEFT AND RIGHT SOURCE MARGIN IN CHECKER PARMLIST A45714 63080021
*                                                                     * 63100021
*    THE EDIT COMMAND PDL (PARAMETER DESCRIPTOR LIST) IS RETURNED BY  * 63120021
*    IKJPARS AND CONTAINS COMMAND OPERAND INFORMATION.                * 63140021
*                                                                     * 63160021
* ATTRIBUTES --                                                       * 63180021
*    REFRESHABLE, ENABLED, NON-PRIVILEGED                             * 63200021
*                                                                     * 63220021
* CHARACTER CODE DEPENDENCY -- NONE.                                  * 63240021
*                                                                     * 63260021
* NOTES --                                                            * 63280021
*    THIS ROUTINE CONTAINS PROCESSOR DEPENDENT CODE FOR THE FOLLOWING * 63300021
*    DATA SET TYPES --                                                * 63320021
*                                                                     * 63340021
*    GOFORT                                                           * 63360021
*    IPLI                                                             * 63380021
*    PLI                                                              * 63400021
*    PLIF                                                             * 63420021
*********************************************************************** 63440021
         EJECT                                                          63460021
IKJEBIN8 CSECT                                                          63480021
         IKJEBESV (14,12),,*,COMMREG=D0(,PARMREG1) SAVE ENTRY          X63500021
                                   REGISTERS.                           63520021
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY TO THE         63540021
*                                  COMMUNICATION AREA.                  63560021
         L     DATAREG,D4(,PARMREG1) OBTAIN ADDRESS OF EDIT             63580021
*                                  COMMAND PDL.                         63600021
         USING INECMNDD,DATAREG ESTABLISH ADDRESSABILITY TO THE         63620021
*                                  EDIT COMMAND PDL.                    63640021
         MVI   IN8FLAGS,IN8ZEROS ZERO FLAG BYTE FOR THIS ROUTINE.       63660021
         LTR   PARMREG0,PARMREG0 TEST FOR ENTRY CODE ZERO.              63680021
         BNZ   IN003030       IF ENTRY CODE IS NOT ZERO, BRANCH         63700021
*                                  TO PROCESS AS NEW DATA SET.          63720021
         LH    LENREG,CALRECL ACQUIRE LRECL FOR OLD DATA SET.           63740021
         B     IN003065       BRANCH TO VALIDATE LRECL.                 63760021
         EJECT                                                          63780021
*********************************************************************** 63800021
*                                                                     * 63820021
*   VALIDATE LINE OPERAND FOR A NEW DATA SET AND LRECL FOR AN OLD     * 63840021
*   DATA SET.                                                         * 63860021
*                                                                     * 63880021
*   AFTER CONVERTING THE LINE OPERAND TO BINARY, PLACE VALUE IN       * 63900021
*   THE COMMUNICATION AREA.  (IF DATA SET WAS OLD, LRECL HAS          * 63920021
*   PREVIOUSLY BEEN PLACED IN THE COMMUNICATION AREA.  VERIFY THAT    * 63940021
*   LINE(LRECL) IS CORRECT FOR THE DATA SET TYPE BEING EDITED.  IF    * 63960021
*   LINE(LRECL) IS INVALID, PUT MESSAGE TO TERMINAL AND EXIT TO TMP.  * 63980021
*                                                                     * 64000021
*********************************************************************** 64020021
IN003030 EQU   *                                                        64040021
         CLC   INLNE(L'IENOKEYW),IENOKEYW CHECK IF LINE OPERAND         64060021
*                                  SPECIFIED.                           64080021
         BNE   IN003060       IF SPECIFIED, BRANCH TO CONVERT TO        64100021
*                                  BINARY.                              64120021
         BAL   SRRTNREG,IN011010 BRANCH TO CHECK IF DATA SET TYPE       64140021
*                                  IS GOFORT.                           64160021
         TM    IN8FLAGS,IN8TERME DETERMINE IF INVALID OPERANDS OR       64180021
*                                  ATTRIBUTES FOR GOFORT.               64200021
         BO    IEEXIT1        IF SO, BRANCH TO TERMINATE.               64220021
IN003040 EQU   *                                                        64240021
         SR    PARMREG1,PARMREG1 CREATE CONSTANT OF ZERO.               64260021
         CH    PARMREG1,CAFLRLDF CHECK IF DEFAULT RECORD FORMAT         64280021
*                                  IS FIXED.                            64300021
         BNZ   IN003050       IF FIXED, BRANCH TO INITIALIZE LINE       64320021
         MVC   CALRECL(L'CALRECL),CAVLRLDF INITIALIZE LINE SIZE         64340021
*                                  WITH VARIABLE FORMAT LRECL.          64360021
         B     IN004520       BRANCH TO VALIDATE BLOCK OPERAND.         64380021
IN003050 EQU   *                                                        64400021
         MVC   CALRECL(L'CALRECL),CAFLRLDF INITIALIZE LINE SIZE         64420021
*                                  WITH FIXED FORMAT LRECL.             64440021
         OI    CACFLAG2,CARECFM INDICATE THAT DATA SET HAS A            64460021
*                                  FIXED OR FIXED BLOCK FORMAT.         64480021
         B     IN004520       BRANCH TO VALIDATE BLOCK OPERAND.         64500021
IN003060 EQU   *                                                        64520021
         L     AREAREG,INLNESZ+INLNEPT ADDRESS OF LINE VALUE.           64540021
         LH    SIZEREG,INLNESZ+INLNELN LENGTH OF LINE VALUE.            64560021
         BAL   RETREG,INCVBIN BRANCH TO CONVERT TO BINARY.              64580021
         STH   LENREG,CALRECL PLACE LINE VALUE IN COMMUNICATION         64600021
*                                  AREA FOR TESTS.                      64620021
IN003065 EQU   *                                                        64640021
         LTR   LENREG,LENREG  CHECK IF LRECL IS ZERO.                   64660021
         BNZ   IN003067       BYPASS ISSUING WARNING MESSAGE TO USER.   64680021
         LA    ERR1REG,INERROR8 SET RELATIVE ERROR INDICATION FOR       64700021
*                                  WARNING MESSAGE.                     64720021
         LA    ERR2REG,M3353  SET SECOND-LEVEL RELATIVE NUMBER.         64740021
         LH    DATA1REG,CABLKS SPECIFY LRECL TO BE USED.                64760021
         STH   DATA1REG,CALRECL SET LRECL FIELD IN COMMUNICATION        64780021
*                                  AREA.                                64800021
         BAL   AREAREG,IN013010 BRANCH TO ISSUE WARNING MESSAGE.        64820021
         LR    LENREG,DATA1REG  COPY BLOCK SIZE INTO LRECL REGISTER.    64840021
IN003067 EQU   *                                                        64860021
         BAL   SRRTNREG,IN011010 BRANCH TO CHECK IF DATA SET TYPE       64880021
*                                  IS GOFORT.                           64900021
         TM    IN8FLAGS,IN8TERME DETERMINE IF INVALID OPERANDS OR       64920021
*                                  ATTRIBUTES FOR GOFORT.               64940021
         BO    IEEXIT1        IF SO, BRANCH TO TERMINATE.               64960021
         TM    CADSATTR,CALRECLX CHECK IF DEFAULT LRECL IS              64980021
*                                  REQUIRED.                            65000021
         BZ    IN003080       WHEN DEFAULT IS NOT REQUIRED,             65020021
*                                  BRANCH TO CHECK MAXIMUM.             65040021
         LH    SIZEREG,CAFLRLDF DEFAULT LRECL FOR DATA SET TYPE.        65060021
         CR    SIZEREG,LENREG CHECK IF LINE VALUE IS EQUAL TO           65080021
*                                  DEFAULT LRECL.                       65100021
         BE    IN003090       IF EQUAL, BRANCH TO PROCESS BLOCK         65120021
*                                  OPERAND.                             65140021
IN003070 EQU   *                                                        65160021
         TM    CAEDFLAG,CAEDDISP CHECK IF DATA SET IS NEW.              65180021
         BZ    IN003075       IF DATA SET IS NEW, BRANCH TO             65200021
*                                  DEFAULT LRECL.                       65220021
         LH    DATA1REG,CALRECL OBTAIN LRECL FOR MESSAGE.               65240021
         LA    ERR1REG,INERROR6 RELATIVE ERROR TO BE PROCESSED.         65260021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            65280021
         B     IEEXIT1        BRANCH TO EXIT WITH ERROR RETURN          65300021
*                                  CODE.                                65320021
IN003073 EQU   *                                                        65340021
         LH    SIZEREG,CAFLRLDF OBTAIN DEFAULT LINE VALUE FOR FIXED     65360021
*                                  FORMAT RECORDS.                      65380021
         LTR   SIZEREG,SIZEREG DETERMINE IF VARIABLE DEFAULT IS         65400021
*                                  TO BE USED.                          65420021
         BNZ   IN003075       IF NOT, BRANCH TO PUT MESSAGE.            65440021
         LH    SIZEREG,CAVLRLDF IF SO, OBTAIN DEFAULT LINE              65460021
*                                  VALUE FOR VARIABLE FORMAT            65480021
*                                  RECORDS.                             65500021
IN003075 EQU   *                                                        65520021
         LA    ERR1REG,INERROR8 RELATIVE ERROR TO BE PROCESSED.         65540021
         LR    DATA1REG,SIZEREG SAVE VALUE FOR MESSAGE INSERTION.       65560021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            65580021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       65600021
         BNZ   IEEXIT1        IF NOT SUCCESSFUL, BRANCH TO EXIT.        65620021
         B     IN003040       BRANCH TO DEFAULT LRECL.                  65640021
IN003080 EQU   *                                                        65660021
         TM    CAEDFLAG,CAEDDISP CHECK IF DATA SET IS OLD.              65680021
         BO    IN003082       IF OLD, BRANCH TO CHECK IF RECFM=F        65700021
         LH    SIZEREG,CAFLRLMX MAXIMUM LRECL FOR DATA SET TYPE.        65720021
         CR    SIZEREG,LENREG CHECK IF LINE VALUE IS LESS THAN          65740021
*                                  OR EQUAL TO MAXIMUM.                 65760021
         BL    IN003073       IF NOT, BRANCH TO PUT MESSAGE.            65780021
         B     IN003090       OTHERWISE, BRANCH TO PROCESS BLOCK        65800021
*                                  OPERAND.                             65820021
IN003082 EQU   *                                                        65840021
         TM    CACFLAG2,CARECFM CHECK IF RECFM = F.                     65860021
         BO    IN003084       IF FIXED, BRANCH TO CHECK MAXIMUM.        65880021
         LH    SIZEREG,CAVLRLMX MAXIMUM LRECL FOR DATA SET TYPE.        65900021
         CR    SIZEREG,LENREG CHECK IF LINE VALUE IS LESS THAN          65920021
*                                  OR EQUAL TO MAXIMUM.                 65940021
         BL    IN003070       IF NOT, BRANCH TO PUT MESSAGE.            65960021
         B     IN003090       OTHERWISE, BRANCH TO PROCESS BLOCK        65980021
*                                  OPERAND.                             66000021
IN003084 EQU   *                                                        66020021
         LH    SIZEREG,CAFLRLMX MAXIMUM LRECL FOR DATA SET TYPE.        66040021
         CR    SIZEREG,LENREG CHECK IF LINE VALUE IS LESS THAN          66060021
*                                  OR EQUAL TO MAXIMUM.                 66080021
         BL    IN003070       IF NOT, BRANCH TO PUT MESSAGE.            66100021
IN003090 EQU   *                                                        66120021
         TM    CAEDFLAG,CAEDDISP CHECK IF DATA SET IS NEW.              66140021
         BO    INP03010       IF DATA SET IS OLD, BRANCH TO CHECK       66160021
*                                  IF BLOCK OPERAND ENTERED.            66180021
         OI    CACFLAG2,CARECFM INDICATE THAT DATA SET HAS A            66200021
*                                  FIXED OR FIXED BLOCK FORMAT.         66220021
         B     IN004520       BRANCH TO VALIDATE BLOCK OPERAND.         66240021
         EJECT                                                          66260021
IN004020 EQU   *                                                        66280021
*********************************************************************** 66300021
*                                                                     * 66320021
*   VALIDATE BLOCK OPERAND.                                           * 66340021
*                                                                     * 66360021
*   NEW DATA SET, BLOCK NOT SPECIFIED.  BLKSIZE IS DEFAULTED TO       * 66380021
*   VALUE SPECIFIED AT SYSGEN TIME FOR DATA SET TYPE.                 * 66400021
*                                                                     * 66420021
*   NEW DATA SET, BLOCK SPECIFIED.  CONVERT BLOCK OPERAND TO BINARY.  * 66440021
*   IF DATA SET HAS RECFM = V, CHECK THAT BLKSIZE IS GREATER THAN OR  * 66460021
*   EQUAL TO LRECL +4 AND LESS THAN 32760.  IF DATA SET HAS           * 66480021
*   RECFM = F, CHECK THAT BLKSIZE / LRECL IS AN INTEGER.  ISSUE       * 66500021
*   DEVTYPE MACRO INSTRUCTION TO OBTAIN TRACK CAPACITY.  CHECK        * 66520021
*   BLKSIZE TO DETERMINE IF ONE BLOCK WILL FIT ON ONE TRACK OF        * 66540021
*   THE OUTPUT DEVICE.  WHEN ANY OF THESE TESTS FAIL, NOTIFY USER     * 66560021
*   AND USE BLKSIZE SPECIFIED AT SYSGEN TIME.                         * 66580021
*                                                                     * 66600021
*   OLD DATA SET.  DETERMINE IF LINE OR BLOCK OR BOTH OPERANDS WERE   * 66620021
*   SPECIFIED.  IF SO, INFORM USER THAT OPERAND IS IGNORED.           * 66640021
*                                                                     * 66660021
*********************************************************************** 66680021
         LA    AREAREG,INDEVTYP ADDRESS OF DEVTYPE WORK AREA.           66700021
         LA    SIZEREG,CAEDDDN ADDRESS OF DDNAME FOR DEVTYPE.           66720021
         DEVTYPE (SIZEREG),(AREAREG),DEVTAB OBTAIN TRACK SIZE.          66740021
         LTR   RETCDREG,RETCDREG CHECK IF DEVTYPE SUCCESSFUL.           66760021
         BZ    IN004025       IF SUCCESSFUL, BRANCH TO VALIDATE         66780021
*                                  BLOCK OPERAND.                       66800021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.         66820021
         LR    DATA2REG,RETCDREG SAVE RETURN CODE FOR MESSAGE.          66840021
         O     DATA2REG,IEDEVTYP INDICATE ROUTINE NAME AS DEVTYPE       66860021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            66880021
         B     IEEXIT1        BRANCH TO TERMINATE EDIT.                 66900021
IN004025 EQU   *                                                        66920021
         L     LENREG,CAUTILNO LAST BLOCK POINTER FROM DSCB.            66940021
         LTR   LENREG,LENREG  CHECK FOR EMPTY DATA SET.                 66960021
         BZ    IN004420       IF EMPTY, NO COMPUTATION NECESSARY.       66980021
         SRL   LENREG,D8(D0)  ROUND TTR POINTER UP TO NEXT FULL         67000021
         LA    LENREG,D1(,LENREG)  TRACK.                               67020021
         LH    PARMREG1,CABLKS BLKSIZE OF OLD DATA SET.                 67040021
         LH    RETREG,INTRKCAP DEVICE TRACK SIZE (IN BYTES).            67060021
         SR    PARMREG0,PARMREG0 ZERO REGISTER.                         67080021
         IC    PARMREG0,INOVHDKL BLOCK OVERHEAD CONSTANT FOR LAST       67100021
*                                  BLOCK, KEYED RECORDS.                67120021
         SR    RETREG,PARMREG1 COMPUTE NUMBER OF BYTES REMAINING        67140021
         AR    RETREG,PARMREG0     ON A TRACK AFTER LAST BLOCK,         67160021
         IC    PARMREG0,INOVHDNK   INCLUDING ITS OVERHEAD               67180021
         SR    RETREG,PARMREG0     CONSTANT, IS DEDUCTED.               67200021
         TM    INDEVFLG,INTOLFLG CHECK IF TOLERANCE FACTOR MUST         67220021
         BZ    IN004027            BE APPLIED - BRANCH IF NOT.          67240021
         MH    PARMREG1,INTOLFAC COMPUTE BLOCK SIZE INCLUDING           67260021
         SRL   PARMREG1,D9(D0)     TOLERANCE FACTOR.                    67280021
IN004027 EQU   *                                                        67300021
         SR    PARMREG1,PARMREG0 COMPUTE BLOCK SIZE (OTHER THAN         67320021
         IC    PARMREG0,INOVHDK    LAST BLOCK) INCLUDING OVERHEAD       67340021
         AR    PARMREG1,PARMREG0   CONSTANT.                            67360021
         SRDL  RETREG,D32(D0) COMPUTE NUMBER OF BLOCKS REMAINING        67380021
         DR    RETREG,PARMREG1     ON TRACK.                            67400021
         LA    SIZEREG,D1(,RETCDREG) TOTAL NUMBER OF BLOCKS ON          67420021
*                                  ONE TRACK OF THE DEVICE.             67440021
         TM    CACFLAG2,CARECFM CHECK IF RECFM = F.                     67460021
         BZ    IN004120       IF RECFM = V, BRANCH TO OBTAIN            67480021
*                                  LRECL.                               67500021
         LH    AREAREG,CALRECL LRECL FOR RECFM = F.                     67520021
         B     IN004220       BRANCH TO COMPUTE NUMBER OF               67540021
*                                  RECORDS IN RECFM F DATA SET.         67560021
IN004120 EQU   *                                                        67580021
         LA    AREAREG,D30(,D0) DEFAULT LRECL FOR RECFM = V.            67600021
IN004220 EQU   *                                                        67620021
         LH    RETREG,CABLKS  OBTAIN BLKSIZE FOR DATA SET AND           67640021
         SRDL  RETREG,D32(D0)      DIVIDE BY LRECL TO DETERMINE         67660021
         DR    RETREG,AREAREG      NUMBER OF RECORDS PER BLOCK.         67680021
         LTR   RETREG,RETREG  CHECK IF BLKSIZE IS MULTIPLE OF           67700021
         BZ    IN004320            LRECL.  IF SO, BRANCH TO             67720021
*                                  COMPUTE NUMBER OF RECORDS IN         67740021
*                                  DATA SET.                            67760021
         LA    RETCDREG,D1(,RETCDREG) IF BLKSIZE NOT A MULTIPLE         67780021
*                                  OF LRECL, INCREASE BY 1.             67800021
         SR    RETREG,RETREG  ZERO REGISTER FOR MULTIPLICATION.         67820021
IN004320 EQU   *                                                        67840021
         MR    RETREG,SIZEREG COMPUTE TOTAL NUMBER OF RECORDS IN        67860021
         MR    RETREG,LENREG       OLD DATA SET AND SAVE FOR            67880021
         ST    RETCDREG,CAUTILNO   IKJEBEUI.                            67900021
IN004420 EQU   *                                                        67920021
         TM    CAEDFLAG,CAEDDISP CHECK IF DATA SET IS NEW.              67940021
         BO    IN005020       IF DATA SET IS OLD, BRANCH TO CHECK       67960021
*                                  IF SCAN OPERAND ENTERED.             67980021
IN004520 EQU   *                                                        68000021
         CLC   INBLK(L'IENOKEYW),IENOKEYW CHECK IF BLOCK OPERAND        68020021
*                                  SPECIFIED.                           68040021
         BE    IN004070       IF NOT, BRANCH TO MAKE SURE LINE          68060021
*                                  AND BLOCK OPERANDS ARE               68080021
*                                  COMPATIBLE.                          68100021
         L     AREAREG,INBLKSZE+INBLKPT ADDRESS OF BLOCK VALUE.         68120021
         LH    SIZEREG,INBLKSZE+INBLKLN LENGTH OF LINE VALUE.           68140021
         BAL   RETREG,INCVBIN BRANCH TO CONVERT TO BINARY.              68160021
         TM    CACFLAG2,CARECFM CHECK IF RECFM = F.                     68180021
         BO    IN004050       IF FIXED, BRANCH TO CHECK BLOCK           68200021
*                                  OPERAND.                             68220021
         LH    SIZEREG,CALRECL OBTAIN LRECL AND ADD 4 TO COMPUTE        68240021
         LA    SIZEREG,D4(PARMREG0,SIZEREG) REQUIRED BLOCKSIZE          68260021
         CR    SIZEREG,LENREG CHECK IF BLKSIZE IS GREATER THAN OR       68280021
         BNH   IN004060            EQUAL TO LRECL + 4.  IF SO,          68300021
*                                  BRANCH TO CHECK MAXIMUM.             68320021
         LA    ERR2REG,M3334  RELATIVE SECOND LEVEL MESSAGE.            68340021
IN004030 EQU   *                                                        68360021
         LA    ERR1REG,INERROR9 RELATIVE ERROR TO BE PROCESSED.         68380021
         BAL   AREAREG,IN004080 BRANCH TO COMPUTE DEFAULT BLKSIZE       68400021
         LH    DATA1REG,CABLKS DEFAULT BLKSIZE FOR INSERTION.           68420021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            68440021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       68460021
         BNZ   IEEXIT1        IF NOT SUCCESSFUL, BRANCH TO EXIT.        68480021
         B     IN005020       BRANCH TO CHECK SCAN OPERAND.             68500021
IN004050 EQU   *                                                        68520021
         LR    RETREG,LENREG  COPY BLKSIZE AND PLACE IN                 68540021
         SRDL  RETREG,D32(PARMREG0) REGISTER FOR DIVISION.              68560021
         LH    SIZEREG,CALRECL OBTAIN LRECL AND PERFORM THE             68580021
         DR    RETREG,SIZEREG      BLKSIZE / LRECL DIVISION.            68600021
         LTR   RETREG,RETREG  CHECK IF QUOTIENT IS AN INTEGER.          68620021
         BZ    IN004060       IF BLOCK IS AN INTEGER MULTIPLE OF        68640021
*                                  LINE, BRANCH TO CHECK IF LESS        68660021
*                                  THAN MAXIMUM (SYSGEN) VALUE.         68680021
         LA    ERR2REG,M3333  RELATIVE SECOND LEVEL MESSAGE.            68700021
         B     IN004030       BRANCH TO CALL MESSAGE ROUTINE.           68720021
IN004060 EQU   *                                                        68740021
         CH    LENREG,CABLKS  CHECK IF BLKSIZE IS GREATER THAN OR       68760021
         BNH   IN004065            EQUAL TO MAXIMUM.  IF SO,            68780021
*                                  DETERMINE IF LESS THAN OR            68800021
*                                  EQUAL TO TRACK CAPACITY.             68820021
*                             OTHERWISE, INFORM USER OF ERROR.          68840021
         LA    ERR2REG,M3332  RELATIVE SECOND LEVEL MESSAGE.            68860021
         B     IN004030       BRANCH TO CALL MESSAGE ROUTINE.           68880021
IN004065 EQU   *                                                        68900021
         STH   LENREG,CABLKS  INDICATE BLKSIZE IN COMMUNICATION         68920021
*                                  AREA.                                68940021
         B     IN005020       BRANCH TO CHECK SCAN OPERAND.             68960021
IN004070 EQU   *                                                        68980021
         LA    AREAREG,IN005020 ADDRESS OF NEXT CODE SEQUENCE           69000021
*                                  TO BE EXECUTED.                      69020021
IN004080 EQU   *                                                        69040021
         TM    CACFLAG2,CARECFM CHECK IF RECFM = F.                     69060021
         BZ    IN004090       IF RECFM = V, LINE IS COMPATIBLE          69080021
*                                  WITH BLOCK.                          69100021
         LH    RETREG,CABLKS  OBTAIN BLKSIZE AND PLACE IN               69120021
         SRDL  RETREG,D32(PARMREG0) REGISTER FOR DIVISION.              69140021
         LH    SIZEREG,CALRECL OBTAIN LRECL AND PERFORM THE             69160021
         DR    RETREG,SIZEREG      BLKSIZE / LRECL DIVISION.            69180021
         LTR   RETREG,RETREG  CHECK IF QUOTIENT IS AN INTEGER.          69200021
         BZ    IN004090       IF BLKSIZE IS A MULTIPLE OF LRECL,        69220021
*                                  BRANCH TO CHECK SCAN OPERAND.        69240021
         MH    RETCDREG,CALRECL COMPUTE BLKSIZE THAT IS A               69260021
         STH   RETCDREG,CABLKS     MULTIPLE OF LRECL AND SAVE IN        69280021
*                                  THE COMMUNICATION AREA.              69300021
IN004090 EQU   *                                                        69320021
         BR    AREAREG        RETURN TO CALLER.                         69340021
         EJECT                                                          69360021
IN005020 EQU   *                                                        69380021
*********************************************************************** 69400021
*                                                                     * 69420021
*   VALIDATE SCAN OPERAND.                                            * 69440021
*                                                                     * 69460021
*   DETERMINE IF USER ENTERED SCAN OR NOSCAN.  IF SCAN WAS ENTERED,   * 69480021
*   CHECK IF VALID FOR DATA SET TYPE.  IF NOT VALID, INFORM USER      * 69500021
*   AND IGNORE OPERAND.  IF VALID, ISSUE A BLDL MACRO INSTRUCTION     * 69520021
*   FOR THE SYNTAX CHECKER NAME TO DETERMINE IF IN SYSTEM.  IF        * 69540021
*   SYNTAX CHECKER NOT AVAILABLE, ZERO SYNTAX CHECKER NAME AND        * 69560021
*   INFORM USER.                                                      * 69580021
*                                                                     * 69600021
*********************************************************************** 69620021
         TM    CADSATTR,CASCAN CHECK IF SYNTAX CHECKING ALLOWED.        69640021
         BNO   IN005035       IF SYNTAX CHECKING NOT ALLOWED,           69660021
*                                  BRANCH TO CHECK IF SCAN/NOSCAN       69680021
*                                  OPERAND SPECIFIED.                   69700021
         MVC   INBLDWD(L'IELSTDSC),IELSTDSC INITIALIZE LIST             69720021
*                                  DESCRIPTION FIELD FOR BLDL.          69740021
         MVC   INSYNNME(L'CASYNAME),CASYNAME MOVE MODULE NAME TO        69760021
*                                  BLDL LIST.                           69780021
         BLDL  0,INSYNCHK     BLDL ON SYNTAX CHECKER MODULE NAME.       69800021
         LTR   RETCDREG,RETCDREG CHECK IF SYNTAX CHECKER IN             69820021
*                                  SYSTEM.                              69840021
         BZ    IN005035       IF PRESENT, BRANCH TO INDICATE THAT       69860021
*                                  USER REQUESTED SYNTAX CHECKING       69880021
         XC    CASYNAME(L'CASYNAME),CASYNAME ZERO SYNTAX CHECKER        69900021
*                                  NAME FIELD TO INDICATE NOT           69920021
*                                  AVAILABLE.                           69940021
IN005035 EQU   *                                                        69960021
         CLC   INSCN(L'IEKEYDEF),IEKEYDEF CHECK IF SCAN SPECIFIED       69980021
         BE    IN005050       IF NOSCAN SPECIFIED, BRANCH TO            70000021
*                                  CHECK NUM/NONUM OPERAND.             70020021
         TM    CADSATTR,CASCAN CHECK IF SYNTAX CHECKING ALLOWED.        70040021
         BO    IN005040       IF ALLOWED, BRANCH TO CHECK IF            70060021
*                                  SYNTAX CHECKER OR PREPROCESSOR       70080021
*                                  EXISTS IN SYSTEM.                    70100021
IN005037 EQU   *                                                        70120021
         LA    ERR1REG,INERRORA RELATIVE ERROR TO BE PROCESSED.         70140021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            70160021
         B     IEEXIT1        BRANCH TO RETURN WITH ERROR RETURN        70180021
*                                  CODE.                                70200021
IN005040 EQU   *                                                        70220021
         LTR   RETCDREG,RETCDREG CHECK IF CHECKER IN SYSTEM.            70240021
         BZ    IN005045       IF PRESENT, BRANCH TO INDICATE USER       70260021
*                                  REQUESTED SYNTAX CHECKING.           70280021
         B     IN005037       BRANCH TO ISSUE ERROR MESSAGE.            70300021
IN005045 EQU   *                                                        70320021
         OI    CACFLAG2,CASCANON INDICATE THAT USER HAS REQUESTED       70340021
*                                  SYNTAX CHECKING.                     70360021
         EJECT                                                          70380021
IN005050 EQU   *                                                        70400021
*********************************************************************** 70420021
*                                                                     * 70440021
*   VALIDATE NUM/NONUM OPERAND.                                       * 70460021
*                                                                     * 70480021
*   IF USER SPECIFIES NONUM, INDICATE THAT DATA SET IS NOT (DOES NOT) * 70500021
*   TO CONTAIN SEQUENCE NUMBERS.  IF THE USER SPECIFIES NUM, CHECK    * 70520021
*   IF SEQUENCE NUMBER AND START POSITION ARE ALSO SPECIFIED.  WHEN   * 70540021
*   START POSITION AND LENGTH ARE SPECIFIED, CHECK THAT DATA SET TYPE * 70560021
*   IS ASM.  IF DATA SET TYPE IS NOT ASM, PUT DIAGNOSTIC TO TERMINAL. * 70580021
*                                                                     * 70600021
*   IF DATA SET TYPE IS ASM AND START POSITION AND LENGTH ARE         * 70620021
*   SPECIFIED, CHECK THAT START POSITION IS BETWEEN 73 AND 80 AND     * 70640021
*   THAT LENGTH IS LESS THAN OR EQUAL TO (80 - START POSITION + 1).   * 70660021
*                                                                     * 70680021
*********************************************************************** 70700021
         CLC   INNUM(L'IEKEYDEF),IEKEYDEF DETERMINE IF NONUM WAS        70720021
*                                  SPECIFIED.                           70740021
         BE    IN005060       IF NUM SPECIFIED, BRANCH TO PROCESS       70760021
*                                  SUBFIELD OPERANDS.                   70780021
         TM    CADSATTR,CALNNUM CHECK IF DATA SET MUST BE LINE          70800021
*                                  NUMBERED.                            70820021
         BZ    IN005055       IF NOT, BRANCH TO INDICATE DATA SET       70840021
*                                  IS NOT TO (DOES NOT) CONTAIN         70860021
*                                  LINE NUMBERS.                        70880021
         LA    ERR1REG,INERRORB RELATIVE ERROR TO BE PROCESSED.         70900021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            70920021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       70940021
         BNZ   IEEXIT1         IF NOT, BRANCH TO RETURN TO TMP.         70960021
         B     IN006040       BRANCH TO CHECK IF SEQUENCE NUMBER        70980021
*                                  START POSITION AND LENGTH ARE        71000021
*                                  CORRECT FOR LRECL AND RECFM.         71020021
IN005055 EQU   *                                                        71040021
         OI    CACFLAG1,CANONUM INDICATE DATA SET DOES NOT (IS          71060021
*                                  NOT TO) CONTAIN SEQUENCE NOS.        71080021
         B     IN006040       BRANCH TO CHECK SEQUENCE NUMBER           71100021
*                                  START POSITION AND LENGTH.           71120021
IN005060 EQU   *                                                        71140021
         TM    INNOSTP+INSNOFLG,INSNOOMT CHECK IF START POSITION        71160021
*                                  WAS ENTERED.                         71180021
         BZ    IN006040       IF START POSITION NOT ENTERED,            71200021
*                                  BRANCH TO CHECK IF SEQUENCE          71220021
*                                  NUMBER START POSITION AND            71240021
*                                  LENGTH ARE CORRECT.                  71260021
         CLI   CADSCODE,CAASM CHECK IF DATA SET TYPE IS ASM.            71280021
         BE    IN005065       IF ASM, BRANCH TO PROCESS START           71300021
*                                  POSITION AND LENGTH.                 71320021
         LA    ERR2REG,M3603  INDICATE THAT NUM SUBFIELDS WERE          71340021
*                                  SPECIFIED FOR NON-ASM DATA SET       71360021
*                                  TYPE.                                71380021
         B     IN005075       BRANCH TO PUT ERROR MESSAGE.              71400021
IN005065 EQU   *                                                        71420021
         L     AREAREG,INNOSTP+INSNOPT ADDRESS OF START POSITION.       71440021
         LH    SIZEREG,INNOSTP+INSNOLN LENGTH OF OPERAND.               71460021
         BAL   RETREG,INCVBIN BRANCH TO CONVERT TO BINARY.              71480021
         LR    STRTNREG,LENREG SAVE START POSITION.                     71500021
         TM    INNOLEN+INSNOFLG,INSNOOMT CHECK IF SEQUENCE NUMBER       71520021
*                                  LENGTH ALSO ENTERED.                 71540021
         BO    IN005066       IF ENTERED, BRANCH TO CONVERT TO          71560021
*                                  BINARY.                              71580021
         SR    LENREG,LENREG  INDICATE THAT LENGTH NOT ENTERED.         71600021
         B     IN005067       BRANCH TO VALIDATE START POSITION.        71620021
IN005066 EQU   *                                                        71640021
         L     AREAREG,INNOLEN+INSNOPT ADDRESS OF LENGTH.               71660021
         LH    SIZEREG,INNOLEN+INSNOLN LENGTH OF OPERAND SUBFIELD.      71680021
         BAL   RETREG,INCVBIN BRANCH TO CONVERT TO BINARY.              71700021
IN005067 EQU   *                                                        71720021
         CH    STRTNREG,IESTP073 CHECK IF START POSITION GREATER        71740021
         BL    IN005070            THAN OR EQUAL TO COLUMN 73. IF       71760021
*                                  NOT, BRANCH TO PUT DIAGNOSTIC.       71780021
         CH    STRTNREG,IESTP080 CHECK IF START POSITION IS LESS        71800021
         BNH   IN005080            THAN OR EQUAL TO 80.  IF NOT,        71820021
*                                  PUT DIAGNOSTIC TO TERMINAL.          71840021
IN005070 EQU   *                                                        71860021
         LA    ERR2REG,M3601  INDICATE THAT START COLUMN IS IN          71880021
*                                  ERROR.                               71900021
IN005075 EQU   *                                                        71920021
         LA    ERR1REG,INERRORD RELATIVE ERROR TO BE PROCESSED.         71940021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            71960021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       71980021
         BNZ   IEEXIT1        IF NOT, BRANCH TO RETURN TO TMP.          72000021
         B     IN006050       BRANCH TO CHECK CAPS/ASIS KEYWORD.        72020021
IN005080 EQU   *                                                        72040021
         LH    SIZEREG,IESTP080 COMPUTE THE QUANTITY --                 72060021
         LA    SIZEREG,D1(PARMREG0,SIZEREG) 80 - SEQUENCE NUMBER        72080021
         SR    SIZEREG,STRTNREG    START POSITION + 1.                  72100021
         LTR   LENREG,LENREG  CHECK IF SEQUENCE NUMBER LENGTH           72120021
*                                  ALSO ENTERED.                        72140021
         BZ    IN005090       IF NOT ENTERED, BRANCH TO COMPUTE         72160021
*                                  OFFSET JUST COMPUTED.                72180021
         CR    LENREG,SIZEREG CHECK THAT LENGTH IS LESS THAN OR         72200021
         BNH   IN006010            EQUAL TO 80 - START POSITION         72220021
*                                  + 1.  IF SO, BRANCH TO UPDATE        72240021
*                                  COMMUNICATION AREA.                  72260021
         LA    ERR2REG,M3602  INDICATE THAT LENGTH IS IN ERROR.         72280021
         B     IN005075       BRANCH TO PUT ERROR MESSAGE.              72300021
IN005090 EQU   *                                                        72320021
         LR    LENREG,SIZEREG COMPUTED SEQUENCE NUMBER LENGTH.          72340021
IN006010 EQU   *                                                        72360021
         STC   STRTNREG,CALINE SAVE START POSITION IN                   72380021
*                                  COMMUNICATION AREA.                  72400021
         STC   LENREG,CALENGTH SAVE SEQUENCE NUMBER LENGTH IN           72420021
*                                  COMMUNICATION AREA.                  72440021
         OI    CACFLAG2,CASEQCOL INDICATE THAT DEFAULT SEQUENCE         72460021
*                                  FIELD START COLUMN AND LENGTH        72480021
*                                  ARE NOT BEING USED.                  72500021
         B     IN006050       BRANCH TO CHECK CAPS/ASIS KEYWORD.        72520021
IN006040 EQU   *                                                        72540021
         TM    CACFLAG2,CARECFM CHECK IF RECFM = V.  IF SO,             72560021
         BZ    IN006045            BRANCH TO ASSURE THAT SEQUENCE       72580021
*                                  NUMBER START POSITION AND            72600021
*                                  LENGTH ARE CORRECT.                  72620021
         TM    CADSATTR,CALRECLX MUST LRECL = 80.                       72640021
         BO    IN006050       IF SO, BRANCH TO CHECK CAPS/ASIS          72660021
*                                  KEYWORD.                             72680021
         LH    SIZEREG,CALRECL OBTAIN LRECL TO BE USED FOR DATA         72700021
*                                  SET.                                 72720021
         LA    LENREG,D7(PARMREG0,PARMREG0) CONSTANT 7 USED TO          72740021
*                                  FIND STARTING COLUMN NUMBER.         72760021
*   COMPUTE STARTING COLUMN NUMBER                                      72780021
*   START NUMBER = LRECL + 1 - SEQUENCE NUMBER LENGTH WHERE LENGTH      72800021
*   IS ALWAYS 8.                                                        72820021
         SR    SIZEREG,LENREG COMPUTE START COLUMN NUMBER AND           72840021
         LTR   SIZEREG,SIZEREG     CHECK IF RECORD CAN CONTAIN          72860021
*                                  DATA, I.E., LRECL GT LINE            72880021
*                                  NUMBER SIZE.                         72900021
         BP    IN006043       IF LRECL GT LINE NUMBER SIZE,             72920021
*                                  BRANCH TO SAVE START POSITION.       72940021
         TM    CACFLAG1,CANONUM CHECK IF NONUM ENTERED.                 72960021
         BO    IN006050       BRANCH TO CHECK CAPS/ASIS OPERAND         72980021
*                                  IF NONUM.                            73000021
*                                                                       73020021
*   USER SUPPLIED INCOMPATIBLE LINE AND NUM OPERANDS.  ISSUE            73040021
*   MESSAGE AND TERMINATE EDIT.                                         73060021
*                                                                       73080021
         LA    ERR1REG,INERRORH RELATIVE ERROR TO BE PROCESSED.         73100021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            73120021
         B     IEEXIT1        BRANCH TO TERMINATE EDIT.                 73140021
IN006043 EQU   *                                                        73160021
         STC   SIZEREG,CALINE SAVE SEQUENCE NUMBER START POSITION       73180021
         OI    CACFLAG2,CASEQCOL INDICATE THAT DEFAULT SEQUENCE         73200021
*                                  FIELD START COLUMN IS NOT            73220021
*                                  BEING USED.                          73240021
         B     IN006050       BRANCH TO CHECK CAPS/ASIS OPERAND.        73260021
IN006045 EQU   *                                                        73280021
         MVI   CALINE,D1      START COLUMN POSITION, RECFM = V.         73300021
         MVI   CALENGTH,D8    SEQUENCE NUMBER LENGTH, RECFM = V.        73320021
         EJECT                                                          73340021
IN006050 EQU   *                                                        73360021
*********************************************************************** 73380021
*                                                                     * 73400021
*   VALIDATE CAPS/ASIS KEYWORD.                                       * 73420021
*                                                                     * 73440021
*   DETERMINE WHETHER OR NOT CAPS OR AS WAS ENTERED.  IF CAPS WAS     * 73460021
*   ENTERED, INDICATE ALL DATA TO BE CONVERTED TO UPPER CASE.  IF     * 73480021
*   ASIS WAS ENTERED, DETERMINE IF PERMISSABLE FOR DATA SET TYPE.     * 73500021
*   IF NOT PERMISSABLE TO USE ASIS, INFORM USER AND USE DEFAULT.      * 73520021
*                                                                     * 73540021
*********************************************************************** 73560021
         CLC   INFMT(L'IENOKEYW),IENOKEYW CHECK IF CAPS OR ASIS         73580021
*                                  WAS ENTERED.                         73600021
         BE    IN006080       IF NEITHER, BRANCH TO SET CAPS/ASIS       73620021
*                                  FLAG BASED ON DATA SET               73640021
*                                  ATTRIBUTES.                          73660021
         CLC   INFMT(L'IECPSSUP),IECPSSUP CHECK IF CAPS ENTERED.        73680021
         BE    IN006085       IF CAPS SPECIFIED, BRANCH TO SET          73700021
*                                  CAPS FLAG IN COMMUNICATION           73720021
*                                  AREA.                                73740021
         TM    CADSATTR,CACAPSRQ CHECK IF CAPS ARE REQUIRED.            73760021
         BZ    IN006090       IF NOT, BRANCH TO PROCESS PL/I            73780021
*                                  DATA SET TYPE.                       73800021
         LA    ERR1REG,INERRORE RELATIVE ERROR TO BE PROCESSED.         73820021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            73840021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       73860021
         BNZ   IEEXIT1        IF NOT, BRANCH TO RETURN TO TMP.          73880021
         B     IN006085       OTHERWISE, BRANCH TO SET CAPS FLAG        73900021
*                                  IN COMMUNICATION AREA.               73920021
IN006080 EQU   *                                                        73940021
         TM    CADSATTR,CACAPSDF DETERMINE IF ASIS IS THE               73960021
*                                  DEFAULT.                             73980021
         BZ    IN006090       IF ASIS, BRANCH TO CHECK PLI DSTYPE       74000021
IN006085 EQU   *                                                        74020021
         OI    CACFLAG1,CACAPS INDICATE THAT ALL INPUT DATA IS          74040021
*                                  TO BE TRANSLATED TO UPPER CASE       74060021
         EJECT                                                          74080021
IN006090 EQU   *                                                        74100021
*********************************************************************** 74120021
*                                                                       74140021
* IPLI KEYWORD SUBFIELD OPERAND.                                        74160021
*                                                                       74180021
* DETERMINE WHETHER CHAR48 OR CHAR60 WAS ENTERED.  SET THE              74200021
* APPROPRIATE BIT IN CACFLAG6 OF THE COMMUNICATION AREA BASED ON        74220021
* WHAT WAS ENTERED ON THE COMMAND, AND BRANCH TO CHECK THE              74240021
* DISPOSITION OF THE EDIT DATA SET.                                     74260021
*                                                                       74280021
*********************************************************************** 74300021
         SPACE 2                                                        74320021
         L     AREAREG,INPDLPTR ADDRESS OF PROMPT PDL.           A45713 74340021
         LTR   AREAREG,AREAREG CHECK IF PROMPT PDL PRESENT.      A45713 74360021
         BNP   IN006095       IF NO, BRANCH TO PROCESS SUBFLD.   A45713 74380021
         LA    LENREG,INPL1CL1 ADDRESS OF TYPE PDE IN MAIN       SM5064 74400021
*                                  (COMMAND) PDL.                SM5064 74410021
         SR    LENREG,DATAREG COMPUTE OFFSET OF PDE FROM PDL     SM5064 74420021
*                                  ORIGIN.                       SM5064 74430021
         LA    PARMREG0,INPLICL1-ICDSTPDL OBTAIN OFFSET TO       SM5064 74432021
*                                  CORRESPONDING PDE IN PROMPT   SM5064 74434021
*                                  PDL.                          SM5064 74436021
         SR    LENREG,PARMREG0 COMPUTE FACTOR TO BE SUBTRACTED   SM5064 74438021
*                                  FROM PROMPT PDL ORIGIN TO GIVESM5064 74438421
*                                  IT ADDRESSABILITY USING MAIN  SM5064 74438821
*                                  PDL DSECT.                    SM5064 74439221
         SR    AREAREG,LENREG ADJUST BASE FOR PDL REFERENCE.     A45713 74440021
         LR    DATAREG,AREAREG ESTAB. ADDRESSABILITY TO PROMPT   A45713 74460021
*                                  PDL WHILE STILL REFERENCING   A45713 74480021
*                                  LABELS IN MAIN PDL.           A45713 74500021
IN006095 EQU   *                                                 A45713 74520021
         CLI   CADSCODE,CAIPLI CHECK IF DATA SET TYPE IS IPLI.          74540021
         BNE   IN007010       IF NOT, BRANCH TO CONTINUE                74560021
*                                  PROCESSING.                          74580021
         CLC   INIPLICH(L'IEKEYDEF),IEKEYDEF CHECK IF CHAR60            74600021
*                                  SPECIFIED.                           74620021
         BNH   IN007000       IF SO, BRANCH TO SET FLAG.                74640021
         OI    CACFLAG6,CACHAR48 INDICATE 48-CHARACTER SET.             74660021
         B     IN013020       BRANCH TO CHECK DISPOSITION OF     A45714 74680021
*                                  EDIT DATA SET.                       74700021
IN007000 EQU   *                                                        74720021
         OI    CACFLAG6,CACHAR60 INDICATE 60-CHARACTER SET.             74740021
         B     IN013020       BRANCH TO CHECK DISPOSITION OF     A45714 74760021
*                                  EDIT DATA SET.                       74780021
         EJECT                                                          74800021
IN007010 EQU   *                                                        74820021
*********************************************************************** 74840021
*                                                                     * 74860021
*   PLI KEYWORD SUBFIELD OPERAND.                                     * 74880021
*                                                                     * 74900021
*   CONVERT SOURCE MARGIN(S) TO BINARY AND VALIDITY CHECK.  LEFT      * 74920021
*   SOURCE MARGIN MUST BE LESS THAN RIGHT SOURCE MARGIN AND RIGHT     * 74940021
*   SOURCE MARGIN MUST BE LESS THAN SEQUENCE NUMBER START POSITION    * 74960021
*   (IF DATA SET IS SEQUENCE NUMBERED) OR LESS THAN OR EQUAL TO LINE  * 74980021
*   (IF DATA SET DOES NOT CONTAIN SEQUENCE NUMBERS).  IF AN ERROR     * 75000021
*   IS ENCOUNTERED AND THE DATA SET IS NEW, NOTIFY USER AND DEFAULT.  * 75020021
*                                                                     * 75040021
*********************************************************************** 75060021
         CLI   CADSCODE,CAPLI CHECK IF DATA SET TYPE IS PL/I.           75080021
         BE    IN007050       IF PL/I, BRANCH TO CHECK SUBFIELD         75100021
*                                  OPERANDS.                            75120021
         CLI   CADSCODE,CAPLIF CHECK IF DATA SET TYPE IS PL/I (F)       75140021
         BNE   IN013020       IF NO, BRANCH TO CHECK DISPOSITION A45714 75160021
*                                  OF EDIT DATA SET.                    75180021
IN007050 EQU   *                                                        75200021
         TM    INPL1CL1+INSMGFLG,INOPRNDO DETERMINE IF USER             75220021
*                                  SPECIFIED LEFT SOURCE MARGIN.        75240021
         BZ    IN007087       IF NOT, BRANCH TO DEFAULT.                75260021
         LH    EPLOCREG,CALRECL ACQUIRE LOGICAL RECORD LENGTH.          75280021
         TM    CACFLAG1,CANONUM CHECK IF DATA SET NONUM.                75300021
         BO    IN007053       IF SO, BRANCH TO CHECK IF FIXED           75320021
*                                  OR VARIABLE RECORD FORMAT.           75340021
         SR    SIZEREG,SIZEREG                                          75360021
         IC    SIZEREG,CALENGTH ACQUIRE SEQUENCE NUMBER LENGTH.         75380021
         SR    EPLOCREG,SIZEREG SET MAXIMUM SOURCE MARGIN VALUE         75400021
*                                  FOR FIXED, NUM DATA SETS.            75420021
IN007053 EQU   *                                                        75440021
         TM    CACFLAG2,CARECFM CHECK IF FIXED OR VARIABLE              75460021
*                                  RECORD FORMAT.                       75480021
         BO    IN007056       IF FIXED, BRANCH TO VALIDITY CHECK        75500021
*                                  MARGINS SPECIFIED.                   75520021
         LA    SIZEREG,D4     IF VARIABLE,                              75540021
         SR    EPLOCREG,SIZEREG    SUBTRACT 4 TO GIVE MAXIMUM           75560021
*                                  MARGIN VALUE.                        75580021
IN007056 EQU   *                                                        75600021
         L     AREAREG,INPL1CL1+INSMGPT ADDRESS OF LEFT SOURCE          75620021
*                                  MARGIN.                              75640021
         LH    SIZEREG,INPL1CL1+INSMGLN LENGTH OF LEFT SOURCE           75660021
*                                  MARGIN.                              75680021
         BAL   RETREG,INCVBIN BRANCH TO CONVERT TO BINARY.              75700021
         LR    STRTNREG,LENREG SAVE LEFT SOURCE MARGIN.                 75720021
         TM    INPL1CL2+INSMGFLG,INOPRNDO DETERMINE IF USER             75740021
*                                  SPECIFIED RIGHT SOURCE MARGIN.       75760021
         BO    IN007060       IF SPECIFIED, BRANCH TO PROCESS -         75780021
         SR    LENREG,LENREG  OTHERWISE, INDICATE NOT SPECIFIED.        75800021
         B     IN007062       BRANCH TO VALIDATE SOURCE MARGINS.        75820021
IN007060 EQU   *                                                        75840021
         L     AREAREG,INPL1CL2+INSMGPT ADDRESS OF RIGHT SOURCE         75860021
*                                  MARGIN.                              75880021
         LH    SIZEREG,INPL1CL2+INSMGLN LENGTH OF RIGHT SOURCE          75900021
*                                  MARGIN.                              75920021
         BAL   RETREG,INCVBIN BRANCH TO CONVERT TO BINARY.              75940021
IN007062 EQU   *                                                        75960021
         CR    STRTNREG,LENREG CHECK IF LEFT MARGIN IS LESS THAN        75980021
*                                  RIGHT MARGIN.                        76000021
         BL    IN007070       IF LEFT MARGIN IS LESS THAN RIGHT         76020021
*                                  MARGIN, BRANCH TO VALIDATE           76040021
*                                  RIGHT MARGIN.                        76060021
         LTR   LENREG,LENREG  TEST IF RIGHT MARGIN SPECIFIED.           76080021
         BNZ   IN007085       IF SPECIFIED, BRANCH TO PUT ERROR         76100021
*                                  MESSAGE.                             76120021
         LA    PARMREG1,INRSRCMG DEFAULT RIGHT SOURCE MARGIN.           76140021
         CR    STRTNREG,PARMREG1 CHECK IF LEFT MARGIN IS LESS           76160021
         BNL   IN007085            THAN RIGHT MARGIN.  IF NOT,          76180021
*                                  BRANCH TO PUT ERROR MESSAGE.         76200021
         CR    STRTNREG,EPLOCREG CHECK IF LEFT SOURCE MARGIN            76220021
*                                  EXCEEDS MAXIMUM ALLOWABLE.           76240021
         BH    IN007085       IF SO, BRANCH TO PUT ERROR MESSAGE.       76260021
         STC   STRTNREG,CAPLILFM INDICATE LEFT SOURCE MARGIN IN         76280021
*                                  COMMUNICATION AREA.                  76300021
         MVI   CAPLIRTM,INRSRCMG DEFAULT RIGHT MARGIN TO 72.            76320021
         B     IN008010       BRANCH TO CHECK CHARACTER SET.            76340021
IN007070 EQU   *                                                        76360021
         STC   STRTNREG,CAPLILFM INDICATE LEFT SOURCE MARGIN IN         76380021
*                                  COMMUNICATION AREA.                  76400021
         CR    LENREG,EPLOCREG CHECK IF RIGHT SOURCE MARGIN             76420021
*                                  EXCEEDS MAXIMUM ALLOWABLE.           76440021
         BNH   IN007090       IF NOT, BRANCH TO SAVE RIGHT SOURCE       76460021
*                                  MARGIN.                              76480021
IN007085 EQU   *                                                        76500021
         LR    DATA1REG,STRTNREG BUILD PARAMETER VALUE FOR              76520021
         SLL   DATA1REG,D16(D0)    MESSAGE ROUTINE CONTAINING           76540021
         OR    DATA1REG,LENREG     OPERANDS ENTERED.                    76560021
         LA    ERR1REG,INERRORC RELATIVE ERROR TO BE PROCESSED          76580021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            76600021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       76620021
         BNZ   IEEXIT1        IF NOT, BRANCH TO RETURN TO TMP.          76640021
IN007087 EQU   *                                                        76660021
         MVI   CAPLILFM,INLSRCMG DEFAULT LEFT AND RIGHT SOURCE          76680021
         MVI   CAPLIRTM,INRSRCMG   MARGINS TO (2,72).                   76700021
         B     IN008010       BRANCH TO CHECK CHARACTER SET.            76720021
IN007090 EQU   *                                                        76740021
         STC   LENREG,CAPLIRTM SAVE RIGHT SOURCE MARGIN.                76760021
IN008010 EQU   *                                                        76780021
         MVC   CACHKOPT(L'CACHKOPT),CAPLILFM INIT CHKR OPT WORD. A45714 76800021
         CLC   INPL1TYP(L'IEKEYDEF),IEKEYDEF CHECK IF CHAR60            76820021
*                                  SPECIFIED.                           76840021
         BE    IN008020       IF CHAR60, BRANCH TO INDICATE IN          76860021
*                                  COMMUNICATION AREA.                  76880021
         OI    CACFLAG6,CACHAR48 INDICATE CHAR48 IN COMMUNICATION       76900021
*                                  AREA.                                76920021
         B     IN013020       BRANCH TO CHECK DISPOSITION OF     A45714 76940021
*                                  EDIT DATA SET.                       76960021
IN008020 EQU   *                                                        76980021
         OI    CACFLAG6,CACHAR60 INDICATE CHAR60 IN COMMUNICATION       77000021
*                                  AREA.                                77020021
         B     IN013020       BRANCH TO CHECK DISPOSITION OF     A45714 77040021
*                                  EDIT DATA SET.                       77060021
         EJECT                                                          77080021
IN013010 EQU   *                                                        77100021
         L     EPLOCREG,IEMSGRTN ADDRESS OF MESSAGE ROUTINE.            77120021
         CALL  (15),((COMMREG),(ERR1REG),(ERR2REG),(DATA1REG),         X77140021
               (DATA2REG)),MF=(E,INSVCRTN) BRANCH TO PUT ERROR         X77160021
                                   MESSAGE.                             77180021
         BR    AREAREG        RETURN TO CALLER.                         77200021
IN013020 EQU   *                                                 A45714 77220021
.* CHECK IF USER DATA SET TYPE SUBFIELD SPECIFIED.               A45714 77240021
         AIF   (&SW EQ 0).TAG16                                  A45714 77260021
         EJECT                                                   A45714 77280021
**************************************************************** A45714 77300021
*                                                                A45714 77320021
*   USER DATA SET TYPE KEYWORD SUBFIELD OPERAND.                 A45714 77340021
*                                                                A45714 77360021
*   VERIFY PRESENCE AND INVOKE USER EXIT TO ENCODE SUBFIELD      A45714 77380021
*   PARAMETERS INTO A TWO BYTE FIELD 'CACHKOPT' IN THE EDIT      A45714 77400021
*   COMMUNICATION AREA.  THE EXIT ROUTINE IS PASSED A THREE      A45714 77420021
*   WORD PARAMETER LIST IN THE FOLLOWING FORM:                   A45714 77440021
*                                                                A45714 77460021
*                 WORD 1 - ADDRESS OF SUBFIELD PDE.              A45714 77480021
*                 WORD 2 - ADDRESS OF ANSWER AREA.               A45714 77500021
*                 WORD 3 - ADDRESS OF CPPL.                      A45714 77520021
*                                                                A45714 77540021
*   WHERE THE PDE IS OF THE FORM GENERATED BY THE IKJPARS        A45714 77560021
*   IKJIDENT MACRO AND THE ANSWER AREA IS A HALFWORD FIELD.      A45714 77580021
*                                                                A45714 77600021
**************************************************************** A45714 77620021
         CLI   CAEXTNAM,D0    CHECK IF EXIT SUPPLIED.            A45714 77640021
         BE    IN013060       IF NO, BRANCH TO CHECK DISPOSITION A45714 77660021
*                                  OF EDIT DATA SET.             A45714 77680021
         LA    LENREG,D1      NUMBER OF BLDL ENTRIES.            A45714 77700021
         STH   LENREG,INBLDLNO                                   A45714 77720021
         LA    LENREG,INENTRYL LENGTH OF BLDL LIST.              A45714 77740021
         STH   LENREG,INBLDLLN                                   A45714 77760021
         MVC   INBLDLNM(L'INBLDLNM),CAEXTNAM MOVE EXIT NAME      A45714 77780021
*                                  INTO BLDL ENTRY LIST.         A45714 77800021
         BLDL  0,INBLDLST     ISSUE BLDL ON EXIT ROUTINE NAME.   A45714 77820021
         B     IN013030(RETCDREG) CHECK RETURN CODE FROM BLDL.   A45714 77840021
         SPACE                                                          77860021
IN013030 EQU   *                                                 A45714 77880021
         B     IN013050       RC = 00, ROUTINE IN SYSTEM.        A45714 77900021
         B     IN013040       RC = 04, ROUTINE NOT FOUND.        A45714 77920021
*                             RC = 08, I/O ERROR DURING BLDL.    A45714 77940021
         LA    ERR1REG,INERROR2 RELATIVE ERROR TO BE PROCESSED.  A45714 77960021
         LA    ERR2REG,M3131  RELATIVE SECOND LEVEL MESSAGE.     A45714 77980021
         L     DATA2REG,IEINS003 MESSAGE INSERTION ADDRESS.      A45714 78000021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.     A45714 78020021
         B     IEEXIT1        BRANCH TO RETURN TO TMP.           A45714 78040021
         SPACE                                                          78060021
IN013040 EQU   *                                                 A45714 78080021
         LA    ERR1REG,INERRORA RELATIVE ERROR TO BE PROCESSED.  A45714 78100021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.     A45714 78120021
         B     IEEXIT1        BRANCH TO RETURN TO TMP.           A45714 78140021
         SPACE                                                          78160021
IN013050 EQU   *                                                 A45714 78180021
*   BUILD EXIT ROUTINE PARAMETER LIST.                           A45714 78200021
         LA    PDLREG,INUSERTY ADRESS OF SUBFIELD PDE.           A45714 78220021
         ST    PDLREG,INEXTPDE                                   A45714 78240021
         LA    PDLREG,CACHKOPT ADDRESS OF ANSWER AREA.           A45714 78260021
         ST    PDLREG,INEXTANS                                   A45714 78280021
         L     PDLREG,CAPTTMP  ADDRESS OF CP PARMLIST.           A45714 78300021
         ST    PDLREG,INEXTCPL                                   A45714 78320021
         LA    PARMREG1,INEXTPRM ADDRESS OF PARMLIST.            A45714 78340021
         LA    PDLREG,INBLDLNM ADDRESS OF BLDL LIST NAME.        A45714 78360021
         LINK  DE=(PDLREG),DCB=0,SF=(E,INLINKSF) LINK 2 EXIT RTNSA76757 78380021
         SPACE                                                          78400021
IN013060 EQU   *                                                 A45714 78420021
.TAG16   ANOP                                                    A45714 78440021
         B     IEEXIT2        BRANCH TO CHECK DISPOSITION        A45714 78460021
*                                  OF EDIT DATA SET.             A45714 78480021
         EJECT                                                          78500021
*********************************************************************** 78520021
*                                                                     * 78540021
*   EXIT AREA -- RETURN TO INVOKING ROUTINE WITH A RETURN CODE TO     * 78560021
*   INDICATE SUCCESS OR FAILURE.  RETURN CODES ARE -- ZERO (ALL         78580021
*   OPERANDS ENTERED BY USER WERE CORRECT OR WERE DEFAULTED FOR         78600021
*   THE EDIT DATA SET TYPE), 4 (A TERMINAL ERROR WAS ENCOUNTERED,     * 78620021
*   TERMINATE EDIT).                                                  * 78640021
*                                                                     * 78660021
*********************************************************************** 78680021
IEEXIT1  EQU   *                                                        78700021
         LA    RETCDREG,D4(,D0) SET ERROR RETURN CODE.                  78720021
         B     IEEXIT3        BRANCH TO RETURN TO CALLING ROUTINE       78740021
IEEXIT2  EQU   *                                                        78760021
         SR    RETCDREG,RETCDREG SET SUCCESSFUL RETURN CODE.            78780021
IEEXIT3  EQU   *                                                        78800021
         IKJEBERT (14,12),,RC=(15) RETURN TO CALLING ROUTINE.           78820021
         EJECT                                                          78840021
*********************************************************************** 78860021
*                                                                     * 78880021
*   CONVERT TO BINARY SUBROUTINE.                                     * 78900021
*                                                                     * 78920021
*********************************************************************** 78940021
INCVBIN  EQU   *                                                        78960021
         BCTR  SIZEREG,PARMREG0 REDUCE OPERAND LENGTH BY 1.             78980021
         EX    SIZEREG,IEPACK1 CHANGE TO PACKED DECIMAL FORMAT.         79000021
         CVB   LENREG,INDECBIN CHANGE TO FIXED BINARY FORMAT.           79020021
         BR    RETREG         RETURN TO CALLER.                         79040021
         SPACE 5                                                        79060021
INP03010 EQU   *                                                        79080021
*********************************************************************** 79100021
*                                                                     * 79120021
*   SUBROUTINE USED TO DETERMINE IF LINE AND/OR BLOCK KEYWORDS WERE   * 79140021
*   ENTERED ON THE EDIT COMMAND.                                      * 79160021
*                                                                     * 79180021
*   DETERMINE IF LINE OR BLOCK OR BOTH KEYWORDS WERE ENTERED.  IF     * 79200021
*   SO, INFORM USER THAT KEYWORD IS INVALID WITH OLD DATA SET.        * 79220021
*   WHEN COMPLETE, BRANCH TO CHECK SCAN OPERAND.                      * 79240021
*                                                                     * 79260021
*********************************************************************** 79280021
         USING INECMNDD,DATAREG ADDRESSABILITY TO PARSE PDL.            79300021
         TM    CADSATTR,CALRECLX CHECK IF LRECL MUST BE 80.             79320021
         BZ    INP03015       IF NOT, BRANCH TO CHECK IF LINE           79340021
*                                  AND/OR BLOCK OPERAND SPECIFIED       79360021
         TM    CACFLAG2,CARECFM CHECK IF RECFM = V FOR OLD DATA         79380021
         BO    INP03015            SETS.  IF FIXED, BRANCH TO           79400021
*                                  CHECK IF USER SPECIFIED LINE         79420021
*                                  OPERAND.                             79440021
         LA    ERR1REG,INERRORJ RELATIVE ERROR TO BE PROCESSED.         79460021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            79480021
         B     IEEXIT1        BRANCH TO EXIT WITH ERROR RETURN          79500021
*                                  CODE.                                79520021
INP03015 EQU   *                                                        79540021
         CLC   INLNE(L'IENOKEYW),IENOKEYW CHECK IF LINE KEYWORD         79560021
*                                  WAS SPECIFIED.                       79580021
         BE    INP03020       IF NOT, BRANCH TO CHECK IF BLOCK          79600021
*                                  KEYWORD WAS SPECIFIED.               79620021
         LA    ERR1REG,INERRORG RELATIVE ERROR TO BE PROCESSED.         79640021
         LA    DATA1REG,IEINS001 INSERTION RECORD FOR MESSAGE.          79660021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            79680021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       79700021
         BNZ   IEEXIT1        IF NOT, BRANCH TO RETURN TO TMP.          79720021
INP03020 EQU   *                                                        79740021
         CLC   INBLK(L'IENOKEYW),IENOKEYW CHECK IF BLOCK KEYWORD        79760021
*                                  WAS SPECIFIED.                       79780021
         BE    IN004020       IF NOT, BRANCH TO CALCULATE NUMBER        79800021
*                                  OF RECORDS IN OLD DATA SET.          79820021
         LA    ERR1REG,INERRORG RELATIVE ERROR TO BE PROCESSED.         79840021
         LA    DATA1REG,IEINS002 INSERTION RECORD FOR MESSAGE.          79860021
         BAL   AREAREG,IN013010 BRANCH TO PUT ERROR MESSAGE.            79880021
         LTR   RETCDREG,RETCDREG CHECK IF PUTLINE WAS SUCCESSFUL.       79900021
         BNZ   IEEXIT1        IF NOT, BRANCH TO RETURN TO TMP.          79920021
         B     IN004020       BRANCH TO CALCULATE NUMBER OF             79940021
*                                  RECORDS IN OLD DATA SET.             79960021
         SPACE 5                                                        79980021
IN011010 EQU   *                                                        80000021
*********************************************************************** 80020021
*                                                                     * 80040021
*   VALIDATE GOFORT OPERANDS.                                         * 80060021
*                                                                     * 80080021
*   DETERMINE IF DATA SET TYPE IS GOFORT.  IF NOT GOFORT, RETURN.     * 80100021
*   WHEN GOFORT, DETERMINE IF FIXED OR FREE WAS SPECIFIED.  IF FREE   * 80120021
*   SPECIFIED, CAUSE EDIT TO BE TERMINATED UNDER TWO CONDITIONS --    * 80140021
*   (1) RECORD FORMAT F FOR OLD DATA SET, OR (2) LINE OPERAND         * 80160021
*   SPECIFIED FOR A NEW DATA SET.  IF GOFORT(FIXED) HAS BEEN          * 80180021
*   SPECIFIED, INDICATE THAT LRECL IS ALWAYS 80 AND THAT CAPS ARE     * 80200021
*   REQUIRED.  CHANGE SEQUENCE NUMBER START POSITION FROM 1 TO 73.    * 80220021
*                                                                     * 80240021
*********************************************************************** 80260021
         CLI   CADSCODE,CAGOFORT DETERMINE IF DATA SET TYPE IS          80280021
         BNE   IN011020           GOFORT.  IF NOT, RETURN.              80300021
         L     AREAREG,INPDLPTR ADDRESS OF PROMPT PDL.           A45713 80320021
         LTR   AREAREG,AREAREG CHECK IF PDL PRESENT.             A45713 80340021
         BNP   IN011011       IF NO, BRANCH TO PROCESS GOFORT.   A45713 80360021
         USING ICDSTPDL,AREAREG ESTAB. ADDRESSABILITY FOR PDL.   A45713 80380021
         CLC   INTSFTF2(L'IEKEYDEF),IEKEYDEF CHECK IF 'FIXED'    A45713 80400021
*                                  SPECIFIED FOR GOFORT.         A45713 80420021
         BH    IN011014       IF YES, BRANCH TO PROCESS.         A45713 80440021
         B     IN01101A       IF NO, BRANCH TO SET SWITCHES.     A45713 80460021
         DROP  AREAREG                                           A45713 80480021
         SPACE                                                          80500021
IN011011 EQU   *                                                 A45713 80520021
         CLC   INTSFTFM(L'IEKEYDEF),IEKEYDEF DETERMINE IF 'FIXED'       80540021
*                                  SPECIFIED FOR GOFORT.                80560021
         BH    IN011014       IF SO, BRANCH TO PROCESS.                 80580021
IN01101A EQU   *                                                 A45713 80600021
         XI    IN8FLAGS,IN8GOFSW FLIP GOFORT SWITCH.                    80620021
         BZ    IN011020       IF ZERO, VALIDATION HAS BEEN              80640021
*                                  PERFORMED, BRANCH TO RETURN.         80660021
         TM    CAEDFLAG,CAEDDISP DETERMINE IF DATA SET IS NEW.          80680021
         BZ    IN011012       IF SO, BRANCH TO DETERMINE IF LINE        80700021
*                                  OPERAND SPECIFIED.                   80720021
         TM    CACFLAG2,CARECFM IF OLD, DETERMINE IF RECORD FORMAT      80740021
*                                  IS VARIABLE.                         80760021
         BZ    IN011015       IF VARIABLE, BRANCH TO SET 'FREE'         80780021
*                                   SWITCH AND RETURN.                  80800021
         B     IN011013       BRANCH TO SEND ERROR MESSAGE.             80820021
IN011012 EQU   *                                                        80840021
         CLC   INLNE(L'IENOKEYW),IENOKEYW DETERMINE IF LINE             80860021
*                                  OPERAND SPECIFIED.                   80880021
         BE    IN011015       IF SO, BRANCH TO SET 'FREE' SWITCH        80900021
*                                  AND RETURN.                          80920021
IN011013 EQU   *                                                        80940021
         LA    ERR1REG,INERRORV SPECIFY RELATIVE ERROR TO BE            80960021
*                                  PROCESSED.                           80980021
         BAL   AREAREG,IN013010 BRANCH TO SEND ERROR MESSAGE.           81000021
         OI    IN8FLAGS,IN8TERME INDICATE THAT EDIT IS TO BE            81020021
*                                  TERMINATED BY CALLER.                81040021
         BR    SRRTNREG       RETURN TO CALLER.                         81060021
IN011014 EQU   *                                                        81080021
         OI    CADSATTR,CACAPSRQ+CALRECLX INDICATE CAPS REQUIRED        81100021
*                                  AND DEFAULT LRECL TO BE USED.        81120021
         LH    SIZEREG,IELR080 LRECL IS 80 FOR FIXED FORMAT.            81140021
         STH   SIZEREG,CAFLRLDF SET LRECL IN PROCESSOR TABLE.           81160021
         MVI   CALINE,INTSFSQO SET SEQUENCE NUMBER START POSITION       81180021
*                                 TO 73 FOR FIXED.                      81200021
         B     IN011020       BRANCH TO RETURN TO CALLER.               81220021
IN011015 EQU   *                                                        81240021
         OI    CACFLAG6,CAFREE INDICATE THAT GOFORT RECORD FORMAT       81260021
*                                  IS FREE FORM.                        81280021
IN011020 EQU   *                                                        81300021
         BR    SRRTNREG       RETURN TO CALLER.                         81320021
         DROP  DATAREG                                                  81340021
         EJECT                                                          81360021
*********************************************************************** 81380021
*                                                                     * 81400021
*   EQUATES, CONSTANTS AND AREAS USED BY THIS ROUTINE.                * 81420021
*                                                                     * 81440021
*********************************************************************** 81460021
IENOKEYW DC    XL2'0'         CONSTANT USED TO DETERMINE IF A           81480021
*                                  KEYWORD ENTERED ON COMMAND.          81500021
IEMSGRTN DC    V(IKJEBIN3)    ADDRESS OF MESSAGE ROUTINE FOR            81520021
*                                  INITIALIZATION PHASE.                81540021
IEINS003 DC    A(ININS002)    ADDRESS OF MESSAGE INSERTION.      A45714 81560021
IEKEYDEF DC    XL2'1'         DEFAULT KEYWORD NUMBER FROM IKJPARS       81580021
IELR080  DC    H'80'          DEFAULT LRECL = 80.                       81600021
         DS    0F             ALIGN ON WORD BOUNDARY.                   81620021
IEDEVTYP DC    XL4'03000000'  INDICATOR FOR DEVTYPE SVC ROUTINE.        81640021
IELSTDSC DC    X'0001000E'    LIST DESCRIPTION FIELD FOR BLDL.          81660021
IESTP073 DC    H'73'          START POSITION COLUMN 73.                 81680021
IESTP080 EQU   IELR080        START POSITION COLUMN 80.                 81700021
IEPACK1  PACK  INDECBIN(L'INDECBIN),D0(*-*,AREAREG) CONVERT             81720021
IECPSSUP EQU   IEKEYDEF       KEYWORD NUMBER FOR CAPS OPERAND.          81740021
*                                  OPERAND TO PACKED DECIMAL.           81760021
IEINS001 IKJEBEMG 0,M334IN1,'LINE' INVALID OPERAND INSERTION.           81780021
IEINS002 IKJEBEMG 0,M334IN1,'BLOCK' INVALID OPERAND INSERTION.          81800021
         EJECT                                                          81820021
         IKJDAP08                                                       81840021
         EJECT                                                          81860021
         IKJDAP18                                                       81880021
         EJECT                                                          81900021
         IKJEBECA                                                       81920021
         SPACE 2                                                        81940021
*********************************************************************** 81960021
*                                                                     * 81980021
*   DEFINE INITIALIZATION WORK AREA IN THE COMMUNICATION AREA.        * 82000021
*                                                                     * 82020021
*********************************************************************** 82040021
         ORG   CABFRPL        ORIGIN INITIALIZATION WORK AREA.          82060021
INWKAREA DS    0F             INITIALIZATION WORKAREA.                  82080021
INDREC   DS    (((DA08DSO-DAPB08+L'DA08DSO+3)/4)*4)X IKJDAIR            82100021
*                                  PARAMETER BLOCK.                     82120021
         ORG   INWKAREA       OVERLAY INITIALIZATION WORK AREA.         82140021
INCAMFLG DS    F              CAMLIST FLAGS FOR OBTAIN.                 82160021
INCAMDSN DS    F              ADDRESS OF DATA SET NAME FOR OBTAIN.      82180021
INCAMVOL DS    F              ADDRESS OF VOLSER NUMBER FOR OBTAIN.      82200021
INCAMWRK DS    F              ADDRESS OF WORK AREA FOR OBTAIN.          82220021
INCAMOBT DS    350C           OBTAIN WORK AREA.                         82240021
INCAMVLD DS    CL6            VOLUME SERIAL NUMBER.                     82260021
INSYNCHK DS    0F             ALIGN BLDL LIST ON WORD BOUNDARY.         82280021
INBLDWD  DS    F              LIST DESCRIPTION FIELD.                   82300021
INMEMBER DS    0C             MEMBER NAME FOR BLDL.                     82320021
INSYNNME DS    8C             MODULE NAME.                              82340021
         DS    6X             RESERVED FOR BLDL RETURN                  82360021
*                                  INFORMATION.                         82380021
INDECBIN DS    D              DOUBLE WORD USED FOR CONVERT TO           82400021
*                                  BINARY OPERATIONS.                   82420021
INLINKSF DS    2F             SUPERVISOR PARAMETER LIST FOR LINK.       82440021
INSVCRTN DS    6F             WORK AREA FOR SERVICE ROUTINE             82460021
*                                  HANDLER.                             82480021
INXCTLPL DS    2F             XCTL WORK AREA.                           82500021
INDEVTYP DS    2F             DEVTYPE WORK AREA.                        82520021
INCYLNO  DS    H              NUMBER OF CYLINDERS ON DEVICE.            82540021
INTRKNO  DS    H              NUMBER OF TRACKS PER CYLINDER.            82560021
INTRKCAP DS    H              TRACK CAPACITY (IN BYTES).                82580021
INOVHDK  DS    X              OVERHEAD FOR KEYED RECORDS, NOT           82600021
*                                  LAST BLOCK.                          82620021
INOVHDKL DS    X              OVERHEAD FOR KEYED RECORDS, LAST          82640021
*                                  BLOCK.                               82660021
INOVHDNK DS    X              OVERHEAD TO BE SUBTRACTED FOR             82680021
*                                  NON-KEYED RECORDS.                   82700021
INDEVFLG DS    X              TOLERANCE FACTOR FLAGS.                   82720021
INTOLFLG EQU   X'01'          IF 1 (ONE), TOLERANCE FACTOR TO BE        82740021
*                                  APPLIED.                             82760021
INTOLFAC DS    H              TOLERANCE FACTOR.                         82780021
INCOREPT DS    F              ADDRESS OF GOTTEN CORE.                   82800021
         ORG   INWKAREA       OVERLAY INITIALIZATION WORK AREA.         82820021
IN7WORK  DS    0F             WORK AREA FOR IKJEBIN7                    82840021
IN7PLIST DS    6F             PARAMETER LIST AREA FOR ROUTINES          82860021
*                                  CALLED BY IKJEBIN7                   82880021
IN7FLAGS DS    X              CONTROL FLAG FOR IKJEBIN7.                82900021
IN7DELPS EQU   X'80'          BIT 0 = 1 INDICATES DELETE MUST           82920021
*                                  BE ISSUED FOR IKJEBEPS.              82940021
IN7NOQLF EQU   X'40'          BIT 1 = 1 INDICATES NO QUALIFIER          82960021
*                                  CHECKING REQUIRED.                   82980021
IN7QLFCK EQU   X'FF'-IN7NOQLF BIT 1 = 0 INDICATES QUALIFIER             83000021
*                                  CHECKING REQUIRED.                   83020021
IN7WKLEN EQU   *-IN7WORK      LENGTH OF IKJEBIN7 WORK AREA.             83040021
         SPACE 2                                                        83060021
IN8FLAGS DS    X              CONTROL FLAG BYTE FOR IKJEBIN8.           83080021
IN8ZEROS EQU   X'00'          INITIAL VALUE FOR FLAG BYTE.              83100021
*                                                                       83120021
*    NOTE -- BITS 2-7 OF 'IN8FLAGS' ARE RESERVED.                       83140021
*                                                                       83160021
IN8GOFSW EQU   X'80'          AFTER EXCLUSIVE OR OF THIS BIT IN THE     83180021
*                                  GOFORT VALIDATION SUBROUTINE,        83200021
*                                  PROCESSING CONTINUES AS FOLLOWS --   83220021
*                                  BIT 0 ON - CONTINUE VALIDATION       83240021
*                                  BIT 0 OFF - RETURN TO CALLER -       83260021
*                                  OPERANDS AND ATTRIBUTES HAVE BEEN    83280021
*                                  VALIDATED.                           83300021
IN8TERME EQU   X'40'          BIT 1 ON - EDIT IS TO BE TERMINATED       83320021
*                                  WITH ERROR INDICATION.               83340021
*                             BIT 1 OFF - GOFORT OPERAND VALIDATION     83360021
*                                  SUCCESSFUL.                          83380021
         SPACE 2                                                        83400021
INWKDCB  DS    14F            DCB USED FOR BLDL ON EDIT DATA SET.       83420021
INWKOPEN DS    F              REMOTE PARAMETER LIST FOR OPEN AND        83440021
*                                  CLOSE SVCS.                          83460021
         SPACE 2                                                        83480021
IN3WKA   DS    7F             REMOTE PROGRAM PARAMETER LIST.            83500021
IN3MSLST DS    3F             PARAMETER LIST FOR IKJEBEMS.              83520021
IN3MSIN1 DS    0F             INSERTION LIST FOR SERVICE ROUTINE        83540021
*                                  NAME.                                83560021
IN3PT1   DS    F              ADDRESS OF NEXT INSERTION.                83580021
IN3LEN1  DS    H              LENGTH OF INSERTION.                      83600021
IN3OFF1  DS    H              OFFSET OF INSERTION.                      83620021
IN3INS1  DS    CL8            INSERTION TEXT.                           83640021
IN3MSIN2 DS    0F             INSERTION LIST FOR RETURN CODE.           83660021
IN3PT2   DS    F              ADDRESS OF NEXT INSERTION.                83680021
IN3LEN2  DS    H              LENGTH OF INSERTION.                      83700021
IN3OFF2  DS    H              OFFSET OF INSERTION.                      83720021
IN3INS2  DS    CL2            INSERTION TEXT.                           83740021
INTEMPBF DS    CL88           TEMPORARY INPUT BUFFER USED FOR           83760021
*                                  IKJPARS PROMPT RESPONSES.            83780021
         SPACE 2                                                        83800021
         ORG   CASCWKA        DEFINE WORK AREA FOR IKJEBIN5      A45713 83820021
*                                  AND PARTS OF IKJEBIN8.        A45714 83840021
INPGLIST DS    4F             IKJPTGT PARM BLOCK.                A45713 83860021
INPDLPTR DS    A              ADDRESS OF PROMPT PDL.             A45713 83880021
         SPACE                                                          83900021
INBLDLST DS    0H             BLDL LIST FOR USER EXIT RTN.       A45714 83920021
INBLDLNO DS    H              NUMBER OF BLDL ENTRIES.            A45714 83940021
INBLDLLN DS    H              LENGTH OF BLDL ENTRY.              A45714 83960021
INBLDLNM DS    CL8            MODULE NAME OF USER EXIT.          A45714 83980021
         DS    CL50           INFORMATION RETURNED BY BLDL.      A45714 84000021
INENTRYL EQU   *-INBLDLNM     LENGTH OF BLDL ENTRY.              A45714 84020021
         SPACE                                                          84040021
INEXTPRM DS    0F             USER EXIT PARM LIST.               A45714 84060021
INEXTPDE DS    A              ADDRESS OF SUBFIELD PDE.           A45714 84080021
INEXTANS DS    A              ADDRESS OF ANSWER AREA.            A45714 84100021
INEXTCPL DS    A              ADDRESS OF CP PARMLIST.            A45714 84120021
         EJECT                                                          84140021
IEFTIOT1 DSECT                DSECT FOR TASK INPUT/OUTPUT TABLE.        84160021
         IEFTIOT1                                                       84180021
         EJECT                                                          84200021
IEFUCBOB DSECT                DSECT FOR UNIT CONTROL BLOCK.             84220021
         IEFUCBOB                                                       84240021
UCB3DCEL EQU   X'05'          UCB DEVICE TYPE FOR 2321.                 84260021
         EJECT                                                          84280021
CVT      DSECT                DSECT FOR COMMUNICATIONS VECTOR           84300021
         CVT   SYS=VMS             TABLE.                               84320021
         EJECT                                                          84340021
         IKJTCB                                                         84360021
         EJECT                                                          84380021
IECDSCB1 DSECT                FORMAT 1 DSCB DSECT.                      84400021
         IECSDSL1 (1)                                                   84420021
         EJECT                                                          84440021
         IKJCPPL                                                        84460021
         EJECT                                                          84480021
         IKJECT                                                         84500021
         EJECT                                                          84520021
         IKJPPL                                                         84540021
         EJECT                                                          84560021
         DCBD  DSORG=PO,DEVD=DA                                         84580021
         EJECT                                                          84600021
         IKJDFPL                                                        84620021
         EJECT                                                          84640021
         IKJDFPB                                                        84660021
         EJECT                                                          84680021
         IKJIOPL                                                        84700021
         EJECT                                                          84720021
         IKJPGPB                                                 A45713 84740021
INPGPBLN EQU   *-PGPB         LENGTH OF PUTGET PARM BLOCK.       A45713 84760021
         EJECT                                                          84780021
         IKJPSCB                                                        84800021
         MEND                                                           84820021
