         MACRO                                                          01000020
&NAME    IKJEBERT &REG,&PARA,&RC=O                                      02000020
.*                                                                      03000020
.*  THIS MACRO IS USED BY ALL EDIT SUBCOMMANDS AND SERVICE ROUTINES     04000020
.*  TO CONTROL EPILOG CODE GENERATED.  THE BASIC SECTION OF THIS        05000020
.*  MACRO IS THE OS/360 RETURN MACRO INSTRUCTION.  IN ADDITION, THIS    06000020
.*  MACRO WILL DEQUEUE AND ZERO THE CURRENT SAVE AREA AND UPDATE THE    07000020
.*  POINTER TO THE CURRENT SAVE AREA IN THE COMMUNICATION AREA.         08000020
.*                                                                      09000020
.*  MACRO LAST UPDATED 02-04-70                                         10000020
.*                                                                      11000020
         LCLA  &A                                                       12000020
         AIF   ('&NAME' EQ '').GO                                       13000020
&NAME    DS    0H                                                       14000020
.GO      ST    13,(CANXTSVA-IKJEBECA)(COMMREG) UPDATE NEXT              15000020
*                                  AVAILABLE SAVE AREA POINTER.         16000020
         LR    12,13          COPY OVER SAVE AREA ADDRESS.              17000020
         L     13,4(,13)      ADDRESS OF HIGHER SAVE AREA.              18000020
         XC    0(72,12),0(12) ZERO SAVE AREA.                           19000020
         AIF   ('&RC' EQ '(15)').SPECRT                                 20000020
         AIF   ('&REG' EQ '').CONTA                                     21000020
.COMBACK ANOP                                                           22000020
&A       SETA  &REG(1)*4+20                                             23000020
         AIF   (&A LE 75).CONTB                                         24000020
&A       SETA  &A-64                                                    25000020
.CONTB   AIF   (N'&REG NE 2).CONTC                                      26000020
         LM    &REG(1),&REG(2),&A.(13) RESTORE THE REGISTERS.           27000020
         AGO   .CONTA                                                   28000020
.SPECRT  AIF   ('&REG(1)' NE '14' AND '&REG(1)' NE '15').COMBACK        29000020
         AIF   ('&REG(1)' EQ '14' AND N'&REG EQ 1).COMBACK              30000020
         AIF   ('&REG(1)' EQ '15' AND N'&REG EQ 1).CONTA                31000020
         AIF   ('&REG(1)' EQ '14').SKIP                                 32000020
         AIF   ('&REG(2)' EQ '0').ZTWO                                  33000020
.LM      LM    0,&REG(2),20(13) RESTORE THE REGISTERS.                  34000020
         AGO   .CONTA                                                   35000020
.ZTWO    L     0,20(0,13)     RESTORE REGISTER ZERO.                    36000020
         AGO   .CONTA                                                   37000020
.SKIP    L     14,12(0,13)    RESTORE REGISTER 14.                      38000020
         AIF   ('&REG(2)' EQ '15').CONTA                                39000020
         AIF   ('&REG(2)' EQ '0').ZTWO                                  40000020
         AIF   ('&REG(2)' EQ '0').ZTWO                                  41000020
         AGO   .LM                                                      42000020
.CONTC   AIF   (N'&REG NE 1).ERROR1                                     43000020
         L     &REG(1),&A.(0,13) RESTORE REGISTER.                      44000020
.CONTA   AIF   ('&PARA' EQ '').CONTD                                    45000020
         AIF   ('&PARA' NE 'T').ERROR2                                  46000020
         MVI   12(13),X'FF'   SET RETURN INDICATION.                    47000020
.CONTD   AIF   ('&RC' EQ 'O').CONTE                                     48000020
         AIF   ('&RC'(1,1) EQ '(').ISAREG                               49000020
         LA    15,&RC.(0,0)   LOAD RETURN CODE.                         50000020
         AGO   .CONTE                                                   51000020
.ISAREG  AIF   ('&RC(1)' EQ '15').CONTE                                 52000020
         MNOTE 12,'INVALID REGISTER NOTATION IN RC OPERAND.'            53000020
         MEXIT                                                          54000020
.CONTE   BR    14             RETURN.                                   55000020
         AGO   .END                                                     56000020
.ERROR1  MNOTE 12,'INVALID FIRST OPERAND SPECIFIED.'                    57000020
         MEXIT                                                          58000020
.ERROR2  MNOTE 12,'INVALID SECOND OPERAND SPECIFIED.'                   59000020
.END     MEND                                                           60000020
