         MACRO                                                          00020000
&LABEL   IKJIDENT &TYPNAM,&OPTION,&OPTION2,&OPTION3,&OPTION4,&OPTION5, *00030000
               &FIRST=ALPHA,&OTHER=,&PROMPT=,&DEFAULT=,                *00040000
               &MAXLNTH=,&HELP=,&VALIDCK=                               00050000
.* RELEASE 20 SUPPORT CODE -- 20035                                     00051000
         GBLC  &IKJCSNM,&IKJDSNM                                        00060000
         LCLA  &FRSTCHR,&MAXLG,&OTHRCHR,&T,&PDESIZE,&END                00070000
         LCLB  &FLIST,&FRANGE,&FASIS,&FASTRIK,&FPRPT,&FDFLT,&FPTBYPS    00080000
         LCLB  &FHELP,&FVALID,&FMAXLG,&FENDBIT,&FOTHER                  00090000
         LCLC  &BADFRST,&QUOTE                                          00100000
&FENDBIT SETB  0                                                        00110000
         AIF   (N'&SYSLIST LT 7).GOOD                                   00120000
         MNOTE 8,'NO MORE THAN 6 POSITIONAL PARAMETERS ALLOWED'         00130000
.GOOD    AIF   ('&TYPNAM' EQ 'LIST' OR '&TYPNAM' EQ 'RANGE').BAD        00140000
         AIF   ('&TYPNAM' NE 'UPPERCASE' AND '&TYPNAM' NE 'ASIS'       *00150000
               AND '&TYPNAM' NE 'ASTERISK' AND '&TYPNAM' NE 'MAXLNTH'  *00160000
               AND '&TYPNAM' NE '' AND '&TYPNAM' NE 'PTBYPS').GOOD1     00170000
.BAD     MNOTE 8,'PARAMETER TYPE NAME MISSING BUT REQUIRED'             00180000
&FENDBIT SETB  1                                                        00190000
.GOOD1   ANOP                                                           00200000
         AIF   ('&IKJCSNM' NE '').GOOD2                                 00210000
         MNOTE 8,'CSECT NAME (FROM IKJPARM MACRO LABEL) IS MISSING'     00220000
&FENDBIT SETB  1                                                        00230000
.GOOD2   ANOP                                                           00240000
         AIF   ('&LABEL' NE '').GOOD3                                   00250000
         MNOTE 8,'STATEMENT LABEL MISSING BUT REQUIRED'                 00260000
&FENDBIT SETB  1                                                        00270000
.GOOD3   ANOP                                                           00280000
&FLIST   SETB  ('&OPTION' EQ 'LIST' OR '&OPTION2' EQ 'LIST' OR         *00290000
               '&OPTION3' EQ 'LIST' OR '&OPTION4' EQ 'LIST'            *00300000
               OR '&OPTION5' EQ 'LIST')                                 00301000
&FRANGE  SETB  ('&OPTION' EQ 'RANGE' OR '&OPTION2' EQ 'RANGE' OR       *00310000
               '&OPTION3' EQ 'RANGE' OR '&OPTION4' EQ 'RANGE'          *00320000
               OR '&OPTION5' EQ 'RANGE')                                00321000
&FASTRIK SETB  ('&OPTION' EQ 'ASTERISK' OR '&OPTION2' EQ 'ASTERISK' OR *00330000
               '&OPTION3' EQ 'ASTERISK' OR '&OPTION4' EQ 'ASTERISK'    *00340000
               OR '&OPTION5' EQ 'ASTERISK')                             00341000
&FASIS   SETB  ('&OPTION' EQ 'ASIS' OR '&OPTION2' EQ 'ASIS' OR         *00350000
               '&OPTION3' EQ 'ASIS' OR '&OPTION4' EQ 'ASIS'            *00360000
               OR '&OPTION5' EQ 'ASIS')                                 00361000
&FPTBYPS SETB  ('&OPTION' EQ 'PTBYPS' OR '&OPTION2' EQ 'PTBYPS' OR     *00362000
               '&OPTION3' EQ 'PTBYPS' OR '&OPTION4' EQ 'PTBYPS'        *00363000
               OR '&OPTION5' EQ 'PTBYPS')                               00364000
         AIF   ('&OPTION' EQ '' OR '&OPTION' EQ 'LIST' OR '&OPTION'    *00370000
               EQ 'RANGE' OR '&OPTION' EQ 'ASIS' OR '&OPTION'          *00371000
               EQ 'UPPERCASE' OR '&OPTION' EQ 'ASTERISK').OPT1          00372000
         AIF   ('&OPTION' EQ 'PTBYPS').OPT1                             00372100
         MNOTE 8,'''&OPTION'' IS AN INVALID POSITIONAL PARAMETER'       00373000
&FENDBIT SETB  1                                                        00374000
.OPT1    AIF   ('&OPTION2' EQ '' OR '&OPTION2' EQ 'LIST' OR '&OPTION2' *00375000
               EQ 'RANGE' OR '&OPTION2' EQ 'ASIS' OR '&OPTION2' EQ     *00376000
               'UPPERCASE' OR '&OPTION2' EQ 'ASTERISK').OPT2            00378000
         AIF   ('&OPTION2' EQ 'PTBYPS').OPT2                            00378100
         MNOTE 8,'''&OPTION2'' IS AN INVALID POSITIONAL PARAMETER'      00379000
&FENDBIT SETB  1                                                        00379100
.OPT2    AIF   ('&OPTION3' EQ '' OR '&OPTION3' EQ 'LIST' OR '&OPTION3' *00379200
               EQ 'RANGE' OR '&OPTION3' EQ 'ASIS' OR '&OPTION3' EQ     *00379300
               'UPPERCASE' OR '&OPTION3' EQ 'ASTERISK').OPT3            00379500
         AIF   ('&OPTION3' EQ 'PTBYPS').OPT3                            00379600
         MNOTE 8,'''&OPTION3'' IS AN INVALID POSITIONAL PARAMETER'      00379900
&FENDBIT SETB  1                                                        00380000
.OPT3    AIF   ('&OPTION4' EQ '' OR '&OPTION4' EQ 'LIST' OR '&OPTION4' *00380100
               EQ 'RANGE' OR '&OPTION4' EQ 'ASIS' OR '&OPTION4' EQ     *00380400
               'UPPERCASE' OR '&OPTION4' EQ 'ASTERISK').OPT4            00380500
         AIF   ('&OPTION4' EQ 'PTBYPS').OPT4                            00380600
         MNOTE 8,'''&OPTION4'' IS AN INVALID POSITIONAL PARAMETER'      00380900
&FENDBIT SETB  1                                                        00381000
.OPT4    AIF   ('&OPTION5' EQ '' OR '&OPTION5' EQ 'LIST' OR '&OPTION5' *00381100
               EQ 'RANGE' OR '&OPTION5' EQ 'ASIS' OR '&OPTION5' EQ     *00381200
               'UPPERCASE' OR '&OPTION5' EQ 'ASTERISK').OPT5            00381300
         AIF   ('&OPTION5' EQ 'PTBYPS').OPT5                            00381400
         MNOTE 8,'''&OPTION5'' IS AN INVALID POSITIONAL PARAMETER'      00381500
&FENDBIT SETB  1                                                        00381600
.OPT5    AIF   (('&OPTION' EQ 'UPPERCASE' OR '&OPTION2' EQ             *00381700
               'UPPERCASE' OR '&OPTION3' EQ 'UPPERCASE' OR '&OPTION4'  *00381800
               EQ 'UPPERCASE') AND &FASIS).ERROR0                       00381900
         AIF   (('&OPTION5' EQ 'UPPERCASE') AND &FASIS).ERROR0          00382000
         AGO   .A0                                                      00382300
.ERROR0  MNOTE 8,'BOTH ''UPPERCASE'' AND ''ASIS'' CANNOT BE SPECIFIED'  00382400
&FENDBIT SETB  1                                                        00382500
.A0      ANOP                                                           00382600
&FPRPT   SETB  ('&PROMPT' NE '')                                        00382700
&FDFLT   SETB  ('&DEFAULT' NE '')                                       00390000
&FHELP   SETB  ('&HELP' NE '')                                          00400000
&FVALID  SETB  ('&VALIDCK' NE '')                                       00410000
&FOTHER  SETB  ('&OTHER' NE '')                                         00420000
&FMAXLG  SETB  ('&MAXLNTH' NE '')                                       00430000
         AIF   (NOT(&FDFLT AND &FPRPT)).GOOD4                           00440000
         MNOTE 8,'PARAMETER CANNOT BOTH DEFAULT AND REQUIRE PROMPTING'  00450000
&FENDBIT SETB  1                                                        00460000
.GOOD4   ANOP                                                           00470000
         AIF   ('&MAXLNTH' EQ '').NFIRST                                00480000
&MAXLG   SETA  &MAXLNTH                                                 00490000
.NFIRST  ANOP                                                           00500000
.*                                                                      00510000
.*  THE FOLLOWING CODE TESTS RESTRICTION ON FIRST CHARACTER OF STRING.  00520000
.*                                                                      00530000
&FRSTCHR SETA  2                                                        00540000
         AIF   ('&FIRST' EQ 'NUMERIC').NOTHER                           00550000
&FRSTCHR SETA  3                                                        00560000
         AIF   ('&FIRST' EQ 'ALPHANUM').NOTHER                          00570000
&FRSTCHR SETA  0                                                        00580000
         AIF   ('&FIRST' EQ 'ANY').NOTHER                               00590000
&FRSTCHR SETA  1                                                        00600000
         AIF   ('&FIRST' EQ '' OR '&FIRST' EQ 'ALPHA').NOTHER           00610000
         MNOTE 8,'ILLEGAL ''FIRST'' VALUE ''&FIRST'''                   00620000
&FENDBIT SETB  1                                                        00621000
.*                                                                      00630000
.* THE FOLLOWING CODE TESTS RESTRICTION ON CHARACTERS OTHER THAN FIRST. 00640000
.*                                                                      00650000
.NOTHER  ANOP                                                           00660000
         AIF   (&MAXLG EQ 1).MNOT1     IF MAXLNTH = 1, IGNORE 'OTHER'   00670000
&OTHRCHR SETA  2                                                        00680000
         AIF   ('&OTHER' EQ 'NUMERIC').NDEFLT                           00690000
&OTHRCHR SETA  3                                                        00700000
         AIF   ('&OTHER' EQ 'ALPHANUM').NDEFLT                          00710000
&OTHRCHR SETA  0                                                        00720000
         AIF   ('&OTHER' EQ 'ANY').NDEFLT                               00730000
&OTHRCHR SETA  1                                                        00740000
         AIF   ('&OTHER' EQ '' OR '&OTHER' EQ 'ALPHA').NDEFLT           00750000
         MNOTE 8,'ILLEGAL ''OTHER'' VALUE ''&OTHER'''                   00760000
&FENDBIT SETB  1                                                        00761000
         AGO   .NDEFLT                                                  00770000
.MNOT1   AIF   ('&OTHER' EQ '').NDEFLT                                  00771000
         MNOTE 4,'MAXLNTH = 1 SPECIFIED, ''OTHER'' FIELD IGNORED'       00780000
.NDEFLT  ANOP                                                           00790000
         AIF   (&FPTBYPS AND NOT(&FPRPT)).NOTON                         00791000
         AGO   .BITSOK                                                  00792000
.NOTON   MNOTE 4,'''PROMPT'' MUST BE SPECIFIED WHEN ''PTBYPS'' IS CODED*00793000
               '                                                        00793100
&FPTBYPS SETB  0                       TURN OFF PTBYPS BIT              00793200
.BITSOK  ANOP                                                           00794000
         AIF   (NOT(&FENDBIT)).GEN     IF ERRORS DO NOT GENERATE CODE   00800000
         MEXIT                                                          00810000
.GEN     ANOP                                                           00820000
&IKJCSNM CSECT ,                       RESUME PCL CSECT                 00830000
* FLAGS -    BIT3=PROMPT,  BIT4=DEFAULT,  BIT5=NOT USED,  BIT6=HELP,    00840000
*            BIT7=VALIDCK, BIT8=LIST,     BIT9=ASIS,      BIT10=RANGE   00850000
DENT&SYSNDX EQU *                                                       00860000
         DC    BL2'100&FPRPT&FDFLT.0&FHELP&FVALID&FLIST&FASIS&FRANGE.00*00870000
               000'                    FLAGS                            00880000
         DC    AL2(DEND&SYSNDX-DENT&SYSNDX) LENGTH OF PCE               00890000
         DC    AL2(&LABEL-&IKJDSNM)    OFFSET TO PDE                    00900000
* OPTIONS -  BIT0 = ASTERISK,  BIT1 = MAXLNTH,  BIT2 = PTBYPS           00910000
         DC    BL1'&FASTRIK&FMAXLG&FPTBYPS.00000' OPTIONS SPECIFIED     00920000
         DC    AL1(&FRSTCHR)            FIRST CHARACTER RESTRICTION     00930000
         DC    AL1(&OTHRCHR)            RESTRICTION ON CHAR OTHER THAN *00940000
               FIRST                                                    00950000
.*                                                                      00960000
.* THE FOLLOWING CODE SUPPLIES QUOTES TO &TYPNAM IF THEY ARE MISSING.   00970000
.*                                                                      00980000
&QUOTE   SETC  '&TYPNAM'(1,1)                                           00990000
         AIF   ('&QUOTE' EQ '''').QUOT                                  01000000
&QUOTE   SETC  ''''                                                     01010000
         DC    AL2(IKJ@&SYSNDX-*),AL2(18),C&QUOTE&TYPNAM&QUOTE PARAMETE*01020000
               R TYPE MESSAGE SEGMENT                                   01030000
         AGO   .EQUGEN1                                                 01040000
.QUOT    ANOP                                                           01050000
         DC    AL2(IKJ@&SYSNDX-*),AL2(18),C&TYPNAM PARAMETER TYPE MESSA*01060000
               GE SEGMENT                                               01070000
.EQUGEN1 ANOP                                                           01080000
IKJ@&SYSNDX EQU *                                                       01090000
         AIF   (&MAXLG EQ 0).GDEFLT                                     01100000
         DC    AL1(&MAXLG)             MAXIMUM LENGTH OF STRING         01110000
.GDEFLT  ANOP                                                           01120000
         AIF   (&FPRPT).PRPT           PROMPT SPECIFIED                 01130000
         AIF   (NOT &FDFLT).NPRDF                                       01140000
         DC    AL1(IKJ$&SYSNDX-*-2),C&DEFAULT DEFAULT DATA              01150000
         AGO   .EQUGEN                                                  01160000
.PRPT    DC    AL1(IKJ$&SYSNDX-*-2),C&PROMPT PROMPT DATA                01170000
.EQUGEN  ANOP                                                           01180000
IKJ$&SYSNDX EQU *                                                       01190000
.NPRDF   ANOP                                                           01200000
         AIF   (NOT &FHELP).NOHELP     IS HELP SPECIFIED                01210000
         DC    AL2(IKJA&SYSNDX-*)      LENGTH OF HELP DATA              01220000
&T       SETA  1                       SET &T FOR LOOP CONTROL          01230000
.HELPLP  ANOP                                                           01240000
&T       SETA  &T+1                                                     01250000
         AIF   (&T EQ 256).HELPER                                       01260000
         AIF   (&T LE N'&HELP).HELPLP                                   01270000
         AGO   .HELPCT                                                  01280000
.HELPER  MNOTE 4,'ONLY 255 LEVELS OF HELP AVAILABLE. OTHERS IGNORED'    01290000
&T       SETA  &T+1                    PROVIDE FOR DECREMENT            01291000
.HELPCT  ANOP                                                           01300000
&T       SETA  &T-1                                                     01310000
         DC    AL1(&T)                 NUMBER OF HELP MESSAGES          01320000
&END     SETA  &T                                                       01321000
&T       SETA  1                                                        01330000
.HELPLPA ANOP                                                           01340000
         DC    AL2(IKJ&SYSNDX.&T-*),AL2(00),C&HELP(&T) HELP MSG SEGMENT 01350000
IKJ&SYSNDX.&T  EQU *                                                    01360000
&T       SETA  &T+1                                                     01370000
         AIF   (&T LE &END).HELPLPA                                     01380000
IKJA&SYSNDX EQU *                                                       01390000
.NOHELP  AIF   (NOT &FVALID).NOVALID   IS VALIDCK SPECIFIED             01430000
         DC    AL3(&VALIDCK)           VALIDCK ROUTINE ADDRESS          01440000
.NOVALID ANOP                                                           01450000
DEND&SYSNDX EQU *                                                       01460000
&IKJDSNM DSECT                                                          01470000
&PDESIZE SETA  5                                                        01480000
         AIF   (&FLIST AND &FRANGE).DSECT IS LIST AND RANGE SPECIFIED   01490000
&PDESIZE SETA  4                                                        01500000
         AIF   (&FRANGE).DSECT                                          01510000
&PDESIZE SETA  3                                                        01520000
         AIF   (&FLIST).DSECT                                           01530000
&PDESIZE SETA  2                                                        01540000
.DSECT   ANOP                                                           01550000
&LABEL   DS    &PDESIZE.A              ALLOCATE PDE SPACE               01560000
&SYSECT  CSECT ,                       RESUME USERS CSECT               01570000
         MEXIT                                                          01580000
         MEND                                                           01590000
