         MACRO                                                          00050000
&LABEL   IKJOPER &TYPNAM,&OPERND1=,&OPERND2=,&RSVWD=,&HELP=,           *00100000
               &VALIDCK=,&PROMPT=,&DEFAULT=,&CHAIN=                     00150000
.********************************************************************** 00160000
.* TITLE  -  IKJOPER MACRO (SYMBOLIC DEBUG PROJECT)                     00200000
.*                                                                      00210000
.* FUNCTION  -  THE IKJOPER MACRO IS USED BY COMMAND PROCESSORS TO      00220000
.*              DEFINE TO PARSE THE EXPECTED FORMAT OF AN EXPRESSION    00230000
.*              TYPE PARAMETER.                                         00240000
.*                                                                      00242000
.* INPUT  -  THE PROTOTYPE STATEMENT IS AS DEFINED ABOVE.  IT'S         00244000
.*           PARAMETERS REPRESENT THE FOLLOWING:                        00246000
.*               &LABEL   - STATEMENT LABEL IS REQUIRED                 00248000
.*               &TYPNAM  - A PARAMETER TYPE IS REQUIRED                00248400
.*               &OPERND1 - SPECIFIES THE PCE-LABEL WHICH WILL          00248800
.*                          DESCRIBE THE FIRST OPERAND OF THE           00249200
.*                          EXPRESSION.                                 00249600
.*               &OPERND2 - SPECIFIES THE PCE-LABEL WHICH WILL          00249700
.*                          DESCRIBE THE SECOND OPERAND OF THE          00249800
.*                          EXPRESSION.                                 00249900
.*               &RSVWD   - SPECIFIES THE PCE-LABEL WHICH WILL          00266600
.*                          DESCRIBE POSSIBLE RESERVE WORDS IN          00276600
.*                          THE EXPRESSION.                             00278600
.*               &HELP    - SUPPLIES SECOND-LEVEL MESSAGES.             00280600
.*               &VALIDCK - SPECIFIES THE ADDRESS OF A USER-SUPPLIED    00282600
.*                          VALIDITY CHECK EXIT ROUTINE.                00283000
.*               &PROMPT  - SUPPLIES DATA TO BE USED IF PROMPTING FOR   00283100
.*                          A MISSING PARAMETER.                        00283200
.*               &DEFAULT - SUPPLIES VALUE TO BE USED IF THE PARAMETER  00288800
.*                          IS NOT ENTERED                              00290800
.*               &CHAIN -   ADDRESS OF A TERM ADDRESS-TYPE PCE          00293700
.*                                                                      00294000
.* OUTPUT - THIS MACRO PRODUCES A PARAMETER CONTROL ENTRY (PCE) TO BE   00294100
.*          PASSED TO THE PARSE SERVICE ROUTINE.                        00294200
.*          IF AN ERROR IS ENCOUNTERED IN PROCESSING THE MACRO          00294300
.*          INSTRUCTION ENTERED BY THE CP, AN APPROPRIATE ERROR MESSAGE 00308200
.*          IS PRINTED AND THE PCE IS NOT GENERATED.                    00318200
.*                                                                      00320200
.********************************************************************** 00320600
.*                                                                      00321000
.* THE FOLLOWING CODE DEFINES VARIABLES TO BE USED IN THE MACRO         00321400
.*   EXPANSION.                                                         00321800
.*       GLOBALS   -   IKJCSNM - CSECT NAME FROM IKJPARM MACRO LABEL.   00321900
.*                     IKJDSNM - DSECT NAME FOR PDL                     00322000
.*       LOCALS(ARITHMETIC) -  T - USED AS COUNTER FOR HELP MESSAGES.   00322100
.*                             END - SECOND COUNTER FOR HELP MESSAGES.  00326700
.*                             PDESIZE - AMOUNT OF SPACE FOR PDE        00328700
.*             (BINARY)  -  FLAGS FOR VARIOUS OPTIONS AND TO INDICATE   00330700
.*                          THAT NO PCE IS TO BE GENERATED.             00331100
.*             (CHARACTER)  -  QUOTE- USED WHEN QUOTES ARE MISSING      00331200
.*                                    FROM &TYPNAM.                     00331300
.*                                                                      00331400
         GBLC  &IKJCSNM,&IKJDSNM                                        00331500
         LCLA  &T,&END,&PDESIZE                                         00336100
         LCLB  &FPRPT,&FDFLT,&FHELP,&FVALID,&FENDBIT,&FCHN              00350000
         LCLC  &QUOTE                                                   00400000
&FENDBIT SETB  0                                                        00450000
.*                                                                      00460000
.* DETERMINE IF EXTRANEOUS POSITIONAL PARAMETERS HAVE BEEN SPECIFIED.   00470000
.*                                                                      00480000
         AIF   (N'&SYSLIST LT 2).GOOD                                   00500000
         MNOTE 8,'ONLY ONE POSITIONAL PARAMETER ALLOWED'                00550000
&FENDBIT SETB  1                                                        00552000
.*                                                                      00560000
.* DETERMINE IF TYPE NAME HAS BEEN ENTERED.                             00570000
.*                                                                      00580000
.GOOD    AIF   ('&TYPNAM' EQ '').BAD                                    00600000
         AGO   .GOOD1                                                   00650000
.BAD     MNOTE 8,'PARAMETER TYPE NAME MISSING BUT REQUIRED'             00700000
&FENDBIT SETB  1                                                        00750000
.*                                                                      00760000
.* DETERMINE IF CSECT NAME IS MISSING.                                  00770000
.*                                                                      00780000
.GOOD1   AIF   ('&IKJCSNM' NE '').GOOD2                                 00800000
         MNOTE 8,'CSECT NAME (FROM IKJPARM MACRO LABEL) IS MISSING'     00850000
&FENDBIT SETB  1                                                        00900000
.*                                                                      00910000
.* DETERMINE IF STATEMENT LABEL WAS ENTERED.                            00920000
.*                                                                      00930000
.GOOD2   AIF   ('&LABEL' NE '').GOOD3                                   00950000
         MNOTE 8,'STATEMENT LABEL MISSING BUT REQUIRED'                 01000000
&FENDBIT SETB  1                                                        01050000
.GOOD3   ANOP                                                           01100000
.*                                                                      01150000
.* THE FOLLOWING CODE SETS FLAGS TO INDICATE OPTIONS SPECIFIED ON THE   01200000
.*     MACRO INSTRUCTION.                                               01250000
.*                                                                      01300000
&FPRPT   SETB  ('&PROMPT' NE '')                                        01400000
&FDFLT   SETB  ('&DEFAULT' NE '')                                       01450000
&FHELP   SETB  ('&HELP' NE '')                                          01500000
&FVALID  SETB  ('&VALIDCK' NE '')                                       01550000
&FCHN    SETB  ('&CHAIN' NE '')                                         01560400
.*                                                                      01586000
.* PROMPT AND DEFAULT CANNOT BOTH BE SPECIFIED.                         01596000
.*                                                                      01598000
.OPT6    AIF   (NOT(&FDFLT AND &FPRPT)).OPT2                            01600000
         MNOTE 8,'PARAMETER CANNOT BOTH DEFAULT AND REQUIRE PROMPTING'  01650000
&FENDBIT SETB  1                                                        01700000
.*                                                                      01710000
.* THE FOLLOWING CODE CHECKS THAT OPERND1, OPERND2, AND RSVWD HAVE      01720000
.*     BEEN ENTERED.                                                    01730000
.*                                                                      01740000
.OPT2    AIF   ('&OPERND1' NE '').OPT3                                  01750000
         MNOTE 8,'''OPERND1'' REQUIRED BUT MISSING'                     01800000
&FENDBIT SETB  1                                                        01850000
.OPT3    AIF   ('&OPERND2' NE '').OPT4                                  01900000
         MNOTE 8,'''OPERND2'' REQUIRED BUT MISSING'                     01950000
&FENDBIT SETB  1                                                        02000000
.OPT4    AIF   ('&RSVWD' NE '').OPT5                                    02050000
         MNOTE 8,'''RSVWD'' REQUIRED BUT MISSING'                       02100000
&FENDBIT SETB  1                                                        02150000
.*                                                                      02152000
.* IF AN ERROR HAS BEEN ENCOUNTERED DO NOT GENERATE THE PCE.            02160000
.*                                                                      02170000
.OPT5    AIF   (NOT(&FENDBIT)).GEN                                      02200000
         MEXIT                                                          02250000
.GEN     ANOP                                                           02300000
&IKJCSNM CSECT ,                     RESUME PCL CSECT                   02350000
* FLAGS - BIT3=PROMPT,  BIT4=DEFAULT, BIT6=HELP,                        02400000
*         BIT7=VALIDCK                                                  02450000
DENT&SYSNDX EQU *                                                       02500000
&LABEL   EQU   *                                                        02510000
         DC    BL2'111&FPRPT&FDFLT.0&FHELP&FVALID.00000000' FLAGS       02550000
         DC    AL2(DEND&SYSNDX-DENT&SYSNDX)      LENGTH OF PCE          02600000
         DC    AL2(LAB&SYSNDX-&IKJDSNM)          OFFSET TO PDE          02650000
.*                                                                      02700000
.* THE FOLLOWING CODE SUPPLIES QUOTES TO &TYPNAM IF THEY ARE MISSING    02750000
.*                                                                      02800000
&QUOTE   SETC  '&TYPNAM'(1,1)                                           02850000
         AIF   ('&QUOTE' EQ '''').QUOT                                  02900000
&QUOTE   SETC  ''''                                                     02950000
         DC    AL2(IKJ@&SYSNDX-*),AL2(18),C&QUOTE&TYPNAM&QUOTE   PARAME*03000000
               TER TYPE MESSAGE SEGMENT                                 03050000
         AGO   .EQUGEN1                                                 03100000
.QUOT    ANOP                                                           03150000
         DC    AL2(IKJ@&SYSNDX-*),AL2(18),C&TYPNAM  PARAMETER TYPE MESS*03200000
               AGE SEGMENT                                              03250000
.EQUGEN1 ANOP                                                           03300000
IKJ@&SYSNDX EQU *                                                       03350000
         DC    AL2(&RSVWD-&IKJCSNM)     OFFSET TO RESERVE WORD PCE      03400000
         DC    AL2(&OPERND1-&IKJCSNM)   OFFSET TO FIRST OPERAND PCE     03450000
         DC    AL2(&OPERND2-&IKJCSNM)   OFFSET TO SECOND OPERAND PCE    03500000
         AIF   (&FCHN).DCHERE                                           03510000
         DC    AL2(0)                   NO VAR TERM PCE                 03520000
         AGO   .CONT                                                    03530000
.DCHERE  DC    AL2(&CHAIN-&IKJCSNM)       OFFSET TO VAR TERM PCE        03540000
.CONT    AIF   (&FPRPT).PRPT                                            03550000
         AIF   (NOT &FDFLT).NPRDF                                       03600000
         DC    AL1(IKJ$&SYSNDX-*-2),C&DEFAULT     DEFAULT DATA          03650000
         AGO   .EQUGEN                                                  03700000
.PRPT    DC    AL1(IKJ$&SYSNDX-*-2),C&PROMPT      PROMPT DATA           03750000
.EQUGEN  ANOP                                                           03800000
IKJ$&SYSNDX EQU *                                                       03850000
.NPRDF   ANOP                                                           03860000
         AIF   (NOT &FHELP).NOHELP                                      03900000
         DC    AL2(IKJA&SYSNDX-*)                 LENGTH OF HELP DATA   03950000
&T       SETA  1                                                        04000000
.HELPLP  ANOP                                                           04050000
&T       SETA  &T+1                                                     04100000
         AIF   (&T EQ 256).HELPER                                       04150000
         AIF   (&T LE N'&HELP).HELPLP                                   04200000
         AGO   .HELPCT                                                  04250000
.HELPER  MNOTE 4,'ONLY 255 LEVELS OF HELP AVAILABLE. OTHERS IGNORED'    04300000
.HELPCT  ANOP                                                           04400000
&T       SETA  &T-1                                                     04450000
         DC    AL1(&T)                       NUMBER OF HELP MESSAGES    04500000
&END     SETA  &T                                                       04550000
&T       SETA  1                                                        04600000
.HELPLPA ANOP                                                           04650000
         DC    AL2(IKJ&SYSNDX.&T-*),AL2(00),C&HELP(&T) HELP MSG SEGMENT 04700000
IKJ&SYSNDX.&T EQU *                                                     04750000
&T       SETA  &T+1                                                     04760000
         AIF   (&T LE &END).HELPLPA                                     04770000
IKJA&SYSNDX EQU *                                                       04780000
.NOHELP  AIF   (NOT &FVALID).NOVALID                                    04800000
         DC    AL3(&VALIDCK)         VALIDITY CHECK ROUTINE ADDRESS     04850000
.NOVALID ANOP                                                           04900000
DEND&SYSNDX EQU *                                                       04950000
&IKJDSNM DSECT                                                          05000000
&PDESIZE SETA  2                                                        05150000
LAB&SYSNDX   DS    &PDESIZE.F             ALLOCATE PDE SPACE            05250000
&SYSECT  CSECT ,                      RESUME USERS CSECT                05300000
         MEXIT                                                          05350000
         MEND                                                           05400000
