*%         GOTO RLGBBSL;                                                00200020
* /* START OF SPECIFICATIONS ****                                       00400020
********  MODULE PROLOGUE -- A BRIEF DESCRIPTION OF THE MODULE *******/ 00600020
* /*******************************************************************/ 00800020
* /*                                                                 */ 01000020
* /* STATUS --                                                       */ 01200020
* /*    RELEASE 20, MODIFICATION LEVEL 00                            */ 01400020
* /*    A 0-999999                                            S20032 */ 01600020
* /*                                                                 */ 01800020
* /* FUNCTION --                                                     */ 02000020
* /*    DESCRIBE A RE-LOGON BUFFER                                   */ 02200020
* /*                                                                 */ 02400020
* /* ENTRY POINTS --                                                 */ 02600020
* /*         NONE                                                    */ 02800020
* /*                                                                 */ 03000020
* /* INPUT --                                                        */ 03200020
* /*    NONE                                                         */ 03400020
* /*                                                                 */ 03600020
* /* OUTPUT --                                                       */ 03800020
* /*    A BSL OR ASSEMBLER LANGUAGE DEFINITION OF A RE-LOGON BUFFER  */ 04000020
* /*                                                                 */ 04200020
* /* EXTERNAL REFERENCES --                                          */ 04400020
* /*         NONE                                                    */ 04600020
* /*                                                                 */ 04800020
* /* EXITS, NORMAL --                                                */ 05000020
* /*         NONE                                                    */ 05200020
* /*                                                                 */ 05400020
* /* EXITS, ERROR --                                                 */ 05600020
* /*         NONE                                                    */ 05800020
* /*                                                                 */ 06000020
* /* TABLE/WORK AREAS --                                             */ 06200020
* /*         NONE                                                    */ 06400020
* /*                                                                 */ 06600020
* /* ATTRIBUTES --                                                   */ 06800020
* /*         NOT APPLICABLE                                          */ 07000020
* /*                                                                 */ 07200020
* /* NOTES --                                                        */ 07400020
* /*    NONE                                                         */ 07600020
* /*                                                                 */ 07800020
* /*******************************************************************/ 08000020
* /*****  MODULE SPECIFICATIONS -- A MORE DETAILED DESCRIPTION ******** 08200020
*1MODULE-NAME = IKJRLGB                                                 08400020
*  2PROCESSOR = ASSEMBLER                                               08600020
**********************************************************************/ 08800020
* /******************************************************************** 09000020
***** THE RELEASE FOR WHICH THIS MODULE WAS MOST RECENTLY UPDATED ***** 09200020
*1STATUS = 20 MODIFICATION LEVEL 00                                     09400020
**********************************************************************/ 09600020
* /******************************************************************** 09800020
*1DESCRIPTIVE-NAME = RE-LOGON BUFFER                                    10000020
**********************************************************************/ 10200020
* /******************************************************************** 10400020
*1DESCRIPTION = AN UNPROTECTED CONTROL BLOCK SHARED BY TSO LOGON AND -  10600020
*A TERMINAL JOB. THIS CONTROL BLOCK CURRENTLY PROVIDES TWO MAJOR     -  10800020
*FUNCTIONS:                                                          -  11000020
*(A) PROVIDE A COMMAND BUFFER IN WHICH THE LAST STEP OF A TERMINAL   -  11200020
*THIS PERMITS THE USER AT A TERMINAL TO ENTER A SINGLE COMMAND       -  11600020
*REQUESTING RE-LOGON OR LOGOFF PROCESSING RATHER THAN ENTERING ONE   -  11800020
*COMMAND TO REQUEST TERMINATION OF THE COMMAND SYSTEM AND ANOTHER TO -  12000020
*REQUEST A LOGON OR LOGOFF.                                          -  12200020
*(B) PROVIDE A POINTER FIELD FOR USE BY COMMAND SYSTEMS WHICH MAY BE -  12400020
*LOCATED USING A COMBINATION OF SYSTEM SERVICES AND POINTERS         -  12600020
*AVAILABLE TO THE PROBLEM PROGRAM                                       12800020
**********************************************************************/ 13000020
* /******************************************************************** 13200020
*1ASSUMPTIONS = OPERATION UNDER THE TIME-SHARING OPTION OF THE       -  13400020
*OPERATING SYSTEM                                                       13600020
**********************************************************************/ 13800020
* /******************************************************************** 14000020
*1MODULE-TYPE = MACRO                                                   14200020
**********************************************************************/ 14400020
* /******************************************************************** 14600020
*1MACRO-SIZE = 380 CARDS                                                14800020
**********************************************************************/ 15000020
* /******************************************************************** 15200020
*1PARAMETER-RECEIVED = PREFIX                                           15400020
*1HOW-PASSED = KEYWORD                                                  15600020
*1PARAMETER-TYPE = CHARACTER STRING                                     15800020
*1LENGTH+MODE = VARIABLE                                                16000020
*1STRING-VALUE = DEFAULT IS 'RLGB'. TO MAP MULTIPLE COPIES OF THE    -  16200020
*RLGB (EG. ONE IN A DSECT, ONE, INITIALIZED, INLINE) A 1-4 CHARACTER -  16400020
*PREFIX MAY BE SUPPLIED THROUGH THE PREFIX KEYWORD WHICH WILL BE     -  16600020
*SUBSTITUTED FOR 'RLGB' AS THE FIRST CHARACTERS OF THE SYMBOLS       -  16800020
*PRODUCED.                                                              17000020
**********************************************************************/ 17200020
* /******************************************************************** 17400020
*1PARAMETER-RECEIVED = DSECT                                            17600020
*1HOW-PASSED = KEYWORD                                                  17800020
*1PARAMETER-TYPE = CHARACTER STRING                                     18000020
*1LENGTH+MODE = VARIABLE                                                18200020
*1STRING-VALUE = DEFAULT IS 'YES'. IF 'DSECT=NO' IS CODED ON THIS    -  18400020
*MACRO-INSTRUCTION, THE DSECT STATEMENT NORMALLY PRODUCED BY THIS    -  18600020
*MACRO-INSTRUCTION WILL BE OMITTED AND THE SYMBOL NORMALLY PLACED ON -  18800020
*THE DSECT STATEMENT WILL BE PRODUCED ON A DS STATEMENT HAVING ITS   -  19000020
*ORIGIN AT THE ORIGIN OF THE GENERATED DATA AND A LENGTH EQUAL TO    -  19200020
*THE LENGTH OF THE DATA. THE GENERATED DATA WILL BE DOUBLEWORD       -  19400020
*ALIGNED.                                                               19600020
**********************************************************************/ 19800020
* /******************************************************************** 20000020
*1PARAMETER-RECEIVED = COMMAND                                          20200020
*1HOW-PASSED = KEYWORD                                                  20400020
*1PARAMETER-TYPE = CHARACTER STRING                                     20600020
*1LENGTH+MODE = VARIABLE                                                20800020
*1STRING-VALUE = DEFAULT IS ONE BLANK FLANKED BY APOSTROPHES. IF     -  21000020
*THIS KEYWORD IS CODED, IT WILL CAUSE A COMMAND IMAGE TO BE PRODUCED -  21200020
*IN THE RLGB COMMAND IMAGE FIELD MAPPED. THE CHARACTER STRING MUST   -  21400020
*BE ENCLOSED WITHIN APOSTROPHES WHICH CONTAIN THE COMMAND FOR        -  21600020
*WHICH AN IMAGE IS TO BE PRODUCED.                                      21800020
**********************************************************************/ 22000020
* /******************************************************************** 22200020
*1PARAMETER-RECEIVED = CMNDSYS                                          22400020
*1HOW-PASSED = KEYWORD                                                  22600020
*1PARAMETER-TYPE = CHARACTER STRING                                     22800020
*1LENGTH+MODE = VARIABLE                                                23000020
*1STRING-VALUE = DEFAULT IS ZERO. ANY EXPRESSION WHICH MAY APPEAR IN -  23200020
*AN A-TYPE CONSTANT MAY BE CODED FOR THIS KEYWORD                       23400020
**********************************************************************/ 23600020
* /******************************************************************** 23800020
*1SYSTEM-MACROS = NONE                                                  24000020
**********************************************************************/ 24200020
* /******************************************************************** 24400020
*1EXTERNAL-TABLE = RLGB                                                 24600020
*  2REMARKS-ON-USE = OPT: COMMENTS:;                                    24800020
*  2TABLE-SCOPE = EXTERNAL                                              25000020
*  2TABLE-SIZE = 264 BYTES                                              25200020
*  2NOTE = THE IBM-SUPPORTED SIZE OF THIS CONTROL BLOCK MAY VARY     -  25400020
*  FROM RELEASE TO RELEASE AS MAY THE SIZE AND ORDER OF THE FIELDS   -  25600020
*  WITHIN IT. THIS MACRO-INSTRUCTION SHOULD BE USED TO AVOID SUCH    -  25800020
*  CHANGES IMPACTING EXISTING, OPERATIONAL CODE.                        26000020
*  2MAPPING-MACRO = IKJRLGB                                             26200020
*  *******************************************************************/ 26400020
*  /******************************************************************* 26600020
*  2FIELD = RLGBRLB                                                     26800020
*    3FIELD-DISPLACEMENT = 0 BYTES                                      27000020
*    3FIELD-TYPE = TABLE                                                27200020
*    3PURPOSE = PASS A LOGON OR LOGOFF COMMAND FROM THE FINAL STEP   -  27400020
*    OF A TERMINAL JOB TO TSO LOGON                                     27600020
*    3REMARKS-ON-USE = THIS COMMAND WILL NOT BE PROCESSED BY TSO     -  27800020
*    LOGON IF A TERMINAL JOB IS TERMINATED WITH A SYSTEM COMPLETION  -  28000020
*    CODE OR IF THE RLGBCHDR FIELD CONTAINS A DIFFERENT VALUE UPON   -  28200020
*    RETURN FROM THE TERMINAL JOB THAN THAT WHICH IT CONTAINED WHEN  -  28400020
*    THE TERMINAL JOB WAS INITIATED. IN THIS CASE TSO LOGON WILL     -  28600020
*    REFRESH RLGBRLB TO THE VALUE PASSED TO THE TERMINAL JOB AND     -  28800020
*    WILL PROCESS THAT BUFFER.                                          29000020
*    3SCOPE = EXTERNAL                                                  29200020
*    3TABLE-SIZE = 256 BYTES                                            29400020
*    3MAPPING-MACRO = IKJRLGB                                           29600020
*    *****************************************************************/ 29800020
*    /***************************************************************** 30000020
*    3FIELD = RLGBCHDR                                                  30200020
*      4FIELD-DISPLACEMENT = 0 BYTES                                    30400020
*      4FIELD-TYPE = TABLE                                              30600020
*      4SCOPE = EXTERNAL                                                30800020
*      4TABLE-SIZE = 4 BYTES                                            31000020
*      4MAPPING-MACRO = IKJRLGB                                         31200020
*      ***************************************************************/ 31400020
*      /*************************************************************** 31600020
*      4FIELD = RLGBCLEN                                                31800020
*        5FIELD-DISPLACEMENT = 0 BYTES                                  32000020
*        5FIELD-TYPE = ARITHMETIC                                       32200020
*        5MODE = BINARY                                                 32400020
*        5LENGTH = 15 BITS                                              32600020
*        5SIGN = SIGNED                                                 32800020
*        5SCALING = 0                                                   33000020
*        5VALUE = THE LENGTH OF THE RLGBRLB FIELD IN BYTES              33200020
*      ***************************************************************/ 33400020
*      /*************************************************************** 33600020
*      4FIELD = RLGBCOFF                                                33800020
*        5FIELD-DISPLACEMENT = 2 BYTES                                  34000020
*        5FIELD-TYPE = ARITHMETIC                                       34200020
*        5MODE = BINARY                                                 34400020
*        5LENGTH = 15 BITS                                              34600020
*        5SIGN = SIGNED                                                 34800020
*        5SCALING = 0                                                   35000020
*        5VALUE = THE OFFSET OF THE COMMAND WITHIN THE RLGBCTXT      -  35200020
*        FIELD. TSO LOGON REQUIRES THAT THIS BE ZERO.                   35400020
*    *****************************************************************/ 35600020
*    /***************************************************************** 35800020
*    3FIELD = RLGBCTXT                                                  36000020
*      4FIELD-DISPLACEMENT = 4 BYTES                                    36200020
*      4FIELD-TYPE = CHARACTER STRING                                   36400020
*      4LENGTH+MODE = 252 CHARACTERS                                    36600020
*      4STRING-VALUE = COMMAND IMAGE.                                   36800020
*  *******************************************************************/ 37000020
*  /******************************************************************* 37200020
*  2FIELD = RLGBECT                                                     37400020
*    3FIELD-DISPLACEMENT = 256 BYTES                                    37600020
*    3FIELD-TYPE = ADDRESS                                              37800020
*    3ADDRESS-LENGTH = 32 BITS                                          38000020
*    3ADDRESS-OF = ECT                                                  38200020
*      4TYPE-ADDRESSED = TABLE                                          38400020
*      4SCOPE = EXTERNAL                                                38600020
*      4MAPPING-MACRO = IKJECT                                          38800020
*  *******************************************************************/ 39000020
*  /******************************************************************* 39200020
*  2FIELD = *                                                           39400020
*    3FIELD-DISPLACEMENT = 260 BYTES                                    39600020
*    3FIELD-TYPE = RESERVED                                             39800020
*                                                                       40000020
**** END OF SPECIFICATIONS ***/                                         40200020
* /* MAKE BSL COMMENT OF ASSEMBLER MACRO-INSTRUCTION                    40400020
         MACRO                                                          40600020
         IKJRLGB   &DSECT=YES,&PREFIX=RLGB,&COMMAND=' ',&CMNDSYS=0      40800020
         LCLA  &A1                                                      41000020
         LCLB  &B1                                                      41200020
         LCLC  &C1,&C2                                                  41400020
.*       ASSIGN LOCAL VARIABLES INITIAL VALUES                          41600020
&A1      SETA  K'&COMMAND                                               41800020
&C1      SETC  '&PREFIX'(1,4)                                           42000020
&C2      SETC  'L'''                                                    42200020
.*       CHECK FOR ERRORS                                               42400020
         AIF   ('&DSECT' EQ 'YES' OR '&DSECT' EQ 'NO').RLG0100          42600020
         MNOTE 4,'INVALID DSECT OPTION, &DSECT, DSECT=YES ASSUMED'      42800020
.RLG0100 AIF   (K'&PREFIX LE 4).RLG0200                                 43000020
         MNOTE 4,'PREFIX OPERAND TOO LONG, TRUNCATED TO 4 CHARACTERS'   43200020
.RLG0200 AIF   (K'&COMMAND EQ 0).RLG0250                                43400020
         AIF   (&A1 GE 3 AND '&COMMAND'(1,1) EQ '''' AND               *43600020
               '&COMMAND'(&A1,1) EQ '''').RLG0300                       43800020
         MNOTE 4,'INVALID COMMAND OPERAND, &COMMAND, IGNORED'           44000020
.RLG0250 ANOP                                                           44200020
&B1      SETB  1                  FLAG COMMAND KEYWORD ERROR            44400020
.*       GENERATE A DSECT STATEMENT IF REQUESTED                        44600020
.RLG0300 AIF   ('&DSECT' EQ 'NO').RLG0400                               44800020
&C1      DSECT                                                          45000020
         AGO   .RLG0450                                                 45200020
.RLG0400 DS    0D                 ALIGN RLGB DATA                       45400020
&C1      DS    CL264              RE-LOGON BUFFER                       45600020
         ORG   &C1                                                      45800020
.RLG0450 ANOP                                                           46000020
.*       PUT OUT DESCRIPTIVE MATERIAL REGARDING THE RLGB                46200020
*********************************************************************** 46400020
*        THE RE-LOGON BUFFER (RLGB) IS BUILT BY TSO LOGON AND         * 46600020
*        INITIALIZED AS FOLLOWS:                                      * 46800020
*        (A)   RLGBRLB IS INITIALIZED TO AN IMAGE OF A TSO TYPE I     * 47000020
*              COMMAND SYSTEM COMMAND BUFFER, 256 BYTES IN LENGTH     * 47200020
*              AND WITH AN OFFSET FIELD OF ZERO. THE TEXT FIELD OF    * 47400020
*              THE BUFFER IS INITIALIZED TO BLANKS.                   * 47600020
*        (B)   NO OTHER RLGB FIELD IS INITIALIZED.                    * 47800020
*        UPON TERMINATION OF A TERMINAL JOB, THE RLGBRLB FIELD IS     * 48000020
*        PROCESSED AS THOUGH IT HAD BEEN ENTERED AS A COMMAND FROM    * 48200020
*        A TERMINAL PROVIDING:                                        * 48400020
*        (A)   THE TERMINAL JOB WAS NOT TERMINATED WITH A SYSTEM      * 48600020
*              COMPLETION CODE                                        * 48800020
*        (B)   THE RLGBHDR FIELD HAS THE SAME VALUE AS WHEN THE       * 49000020
*              TERMINAL JOB WAS INITIATED.                            * 49200020
*        THE RLGB MAY BE LOCATED DURING A TERMINAL JOB USING THE      * 49400020
*        PSCBRLGB FIELD IN THE PROTECTED STEP CONTROL BLOCK (PSCB)    * 49600020
*        THE RLGB IS PASSED TO THE TERMINAL JOB IN SUBPOOL 0.         * 49800020
*        FREEING THE RLGB WILL PRODUCE UNPREDICTABLE RESULTS WHEN THE * 50000020
*        PROGRAMS DISTRIBUTED WITH THE TYPE I COMMAND SYSTEM ARE      * 50200020
*        EXECUTED, AND MAY RESULT IN ONE OF TWO UNDESIRABLE ACTIONS   * 50400020
*        WHEN A TERMINAL JOB TERMINATES:                              * 50600020
*        (A)   A SECOND-LEVEL MESSAGE WILL BE PRODUCED INDICATING     * 50800020
*              TO THE TERMINAL USER THAT THE RE-LOGON BUFFER HAS      * 51000020
*              BEEN RE-INITIALIZED.                                   * 51200020
*        (B)   A DIAGNOSTIC MESSAGE MAY BE PRODUCED, INDICATING THAT  * 51400020
*              INVALID INPUT HAS BEEN ENTERED DURING TSO LOGON        * 51600020
*              PROCESSING.                                            * 51800020
*        (C)   THE TERMINAL USER MAY BE DISCONNECTED FROM THE TSO     * 52000020
*              SUBSYSTEM WITHOUT ANY INDICATION OF A REASON FOR THE   * 52200020
*              ACTION.                                                * 52400020
*********************************************************************** 52600020
         SPACE                                                          52800020
&C1.RLB  DS    CL256              RE-LOGON COMMAND BUFFER               53000020
         ORG   &C1.RLB                                                  53200020
&C1.HDR  DS    CL4                COMMAND BUFFER HEADER                 53400020
         ORG   &C1.HDR                                                  53600020
&C1.LEN  DC    Y(&C2&C1.RLB)      COMMAND BUFFER LENGTH                 53800020
&C1.OFF  DS    Y(0)               COMMAND BUFFER OFFSET                 54000020
         AIF   (&B1 EQ 1).RLG0500                                       54200020
&C1.TXT  DC    CL(&C2&C1.RLB-&C2&C1.HDR)&COMMAND COMMAND BUFFER TEXT    54400020
         AGO   .RLG0600                                                 54600020
.RLG0500 ANOP                                                           54800020
&C1.TXT  DC    CL(&C2&C1.RLB-&C2&C1.HDR)' '   COMMAND BUFFER TEXT       55000020
.RLG0600 AIF   (T'&CMNDSYS EQ 'O').RLG0700                              55200020
&C1.ECT  DC    A(&CMNDSYS)        COMMAND SYSTEM POINTER                55400020
         AGO   .RLG0800                                                 55600020
.RLG0700 ANOP                                                           55800020
&C1.ECT  DC    A(0)               COMMAND SYSTEM POINTER                56000020
.RLG0800 ANOP                                                           56200020
*        NOTE: PROGRAMS DISTRIBUTED WITH THE TYPE I COMMAND SYSTEM    * 56400020
*              WILL PRODUCE UNPREDICABLE RESULTS IF THIS POINTER DOES * 56600020
*              NOT ADDRESS A CONTROL BLOCK FORMATTED AND INITIALIZED  * 56800020
*              LIKE THE TYPE I ENVIRONMENT CONTROL TABLE (ECT)        * 57000020
*              DESCRIBED BY MACRO-INSTRUCTION IKJECT                  * 57200020
         DC    BL.32'00000000000000000000000000000000' RESERVED         57400020
**/                                                                     57600020
         MEND                                                           57800020
*%RLGBBSL:IF PREFIX = ''                                                58000020
*%        THEN                                                          58200020
*%              PREFIX = 'RLGB';                                        58400020
*%        IF DSECT = ''                                                 58600020
*%        THEN                                                          58800020
*%              DSECT = 'BASED( '  PREFIX  'PTR)';                  59000020
*%        IF COMMAND = ''                                               59200020
*%        THEN                                                          59400020
*%              GOTO RLG00100;                                          59600020
*%        RLGTEM1 = ' INITIAL( 256)';                                   59800020
*%        RLGTEM2 = ' INITIAL(0)';                                      60000020
*%        RLGTEM3 = ' INITIAL( '''  COMMAND  ''')';                 60200020
*%        RLGTEM4 = ' INITIAL(0)';                                      60400020
*%RLG00100:IF CMNDSYS = ''                                              60600020
*%        THEN                                                          60800020
*%              GOTO RLG00200;                                          61000020
*%        RLGTEM1 = ' INITIAL( 256)';                                   61200020
*%        RLGTEM2 = ' INITIAL(0)';                                      61400020
*%        IF COMMAND = ''                                               61600020
*%        THEN                                                          61800020
*%              RLGTEM3 = ' INITIAL( '' '')';                           62000020
*%        RLGTEM4 = ' INITIAL( '  CMNDSYS  ')';                     62200020
*%RLG00200: ;                                                           62400020
* /*******************************************************************/ 62600020
* /*     THE RE-LOGON BUFFER (RLGB) IS BUILT BY TSO LOGON AND        */ 62800020
* /*     INITIALIZED AS FOLLOWS:                                     */ 63000020
* /*     (A)   RLGBRLB IS INITIALIZED TO AN IMAGE OF A TSO TYPE I    */ 63200020
* /*           COMMAND SYSTEM COMMAND BUFFER, 256 BYTES IN LENGTH    */ 63400020
* /*           AND WITH AN OFFSET FIELD OF ZERO. THE TEXT FIELD OF   */ 63600020
* /*           THE BUFFER IS INITIALIZED TO BLANKS.                  */ 63800020
* /*     (B)   NO OTHER RLGB FIELD IS INITIALIZED.                   */ 64000020
* /*     UPON TERMINATION OF A TERMINAL JOB, THE RLGBRLB FIELD IS    */ 64200020
* /*     PROCESSED AS THOUGH IT HAD BEEN ENTERED AS A COMMAND FROM   */ 64400020
* /*     A TERMINAL PROVIDING:                                       */ 64600020
* /*     (A)   THE TERMINAL JOB WAS NOT TERMINATED WITH A SYSTEM     */ 64800020
* /*           COMPLETION CODE                                       */ 65000020
* /*     (B)   THE RLGBHDR FIELD HAS THE SAME VALUE AS WHEN THE      */ 65200020
* /*           TERMINAL JOB WAS INITIATED.                           */ 65400020
* /*     THE RLGB MAY BE LOCATED DURING A TERMINAL JOB USING THE     */ 65600020
* /*     PSCBRLGB FIELD IN THE PROTECTED STEP CONTROL BLOCK (PSCB)   */ 65800020
* /*     THE RLGB IS PASSED TO THE TERMINAL JOB IN SUBPOOL 0.        */ 66000020
* /*     FREEING THE RLGB WILL PRODUCE UNPREDICTABLE RESULTS WHEN THE*/ 66200020
* /*     PROGRAMS DISTRIBUTED WITH THE TYPE I COMMAND SYSTEM ARE     */ 66400020
* /*     EXECUTED, AND MAY RESULT IN ONE OF TWO UNDESIRABLE ACTIONS  */ 66600020
* /*     WHEN A TERMINAL JOB TERMINATES:                             */ 66800020
* /*     (A)   A SECOND-LEVEL MESSAGE WILL BE PRODUCED INDICATING    */ 67000020
* /*           TO THE TERMINAL USER THAT THE RE-LOGON BUFFER HAS     */ 67200020
* /*           BEEN RE-INITIALIZED.                                  */ 67400020
* /*     (B)   A DIAGNOSTIC MESSAGE MAY BE PRODUCED, INDICATING THAT */ 67600020
* /*           INVALID INPUT HAS BEEN ENTERED DURING TSO LOGON       */ 67800020
* /*           PROCESSING.                                           */ 68000020
* /*     (C)   THE TERMINAL USER MAY BE DISCONNECTED FROM THE TSO    */ 68200020
* /*           SUBSYSTEM WITHOUT ANY INDICATION OF A REASON FOR THE  */ 68400020
* /*           ACTION.                                               */ 68600020
* /*******************************************************************/ 68800020
* DECLARE                                                               69000020
* /****** RE-LOGON BUFFER                                    *********/ 69200020
* 1       PREFIX DSECT,                                                 69400020
*%        RLGTEM5 = PREFIX  'RLB';                                    69600020
*         /**** RE-LOGON COMMAND BUFFER                      *********/ 69800020
*         2     RLGTEM5,                                                70000020
*%        RLGTEM5 = PREFIX  'CHDR';                                   70200020
*               /* COMMAND BUFFER HEADER                     *********/ 70400020
*               3  RLGTEM5,                                             70600020
*%        RLGTEM5 = PREFIX  'CLEN'  RLGTEM1;                        70800020
*                  /* COMMAND BUFFER LENGTH                  *********/ 71000020
*                  4  RLGTEM5 POINTER(15),                              71200020
*%        RLGTEM5 = PREFIX  'COFF'  RLGTEM2;                        71400020
*                  /* COMMAND BUFFER OFFSET                  *********/ 71600020
*                  4  RLGTEM5 POINTER(15),                              71800020
*%        RLGTEM5 = PREFIX  'CTXT'  RLGTEM3;                        72000020
*               /* COMMAND BUFFER TEXT                       *********/ 72200020
*               3  RLGTEM5 CHARACTER(252),                              72400020
*%        RLGTEM5 = PREFIX  'ECT'  RLGTEM4;                         72600020
*         /**** COMMAND SYSTEM POINTER                       *********/ 72800020
*         /*    NOTE: PROGRAMS DISTRIBUTED WITH THE TYPE I COMMAND   */ 73000020
*         /*       SYSTEM WILL PRODUCE UNPREDICABLE RESULTS IF       */ 73200020
*         /*       THIS POINTER DOES NOT ADDRESS A CONTROL BLOCK     */ 73400020
*         /*       FORMATTED AND INITIALIZED LIKE THE TYPE I         */ 73600020
*         /*       ENVIRONMENT CONTROL TABLE (ECT) DESCRIBED BY      */ 73800020
*         /*       MACRO-INSTRUCTION IKJECT                          */ 74000020
*         2     RLGTEM5 POINTER(32),                                    74200020
*         /**** RESERVED                                     *********/ 74400020
*         2     * BIT(32);                                              74600020
