             MACRO                                                      00050000
&LABEL   IKJRSVWD &TYPNAM,&HELP=,&PROMPT=,&DEFAULT=                     00100000
.*********************************************************************  00150000
.*                                                                      00160000
.* TITLE  -  IKJRSVWD MACRO (SYMBOLIC DEBUG PROJECT)                    00170000
.*                                                                      00180000
.* FUNCTION  -  THE IKJRSVWD MACRO IS USED BY COMMAND PROCESSORS TO     00190000
.*              DEFINE TO PARSE THE EXPECTED FORMAT OF A RESERVE        00192000
.*              WORD PARAMETER.                                         00194000
.*                                                                      00196000
.* INPUT  -  THE PROTOTYPE STATEMENT IS AS DEFINED ABOVE. IT'S          00198000
.*           PARAMETERS REPRESENT THE FOLLOWING:                        00198400
.*                &LABEL   -  A STATEMENT LABEL IS REQUIRED.            00198500
.*                &TYPNAM  -  PARAMETER TYPE                            00198800
.*                &PROMPT= -  PROMPT DATA, IF ENTERED                   00199200
.*                &DEFAULT=  -  DEFAULT, IF ENTERED                     00199300
.*                &HELP=  -  HELP DATA, IF ENTERED                      00199400
.*                                                                      00199600
.* OUTPUT  -  THIS MACRO PRODUCES A PARAMETER CONTROL ENTRY (PCE) TO    00199700
.*            BE PASSED TO THE PARSE SERVICE ROUTINE.                   00199800
.*            IF AN ERROR IS ENCOUNTERED IN PROCESSING THE MACRO        00199900
.*            INSTRUCTION ENTERED BY THE CP, AN APPROPRIATE ERROR       00216600
.*            MESSAGE IS PRINTED AND THE PCE IS NOT GENERATED.          00226600
.*                                                                      00228600
.*********************************************************************  00230600
.*                                                                      00232600
.* THE FOLLOWING CODE DEFINES VARIABLES TO BE USED IN THE MACRO         00233000
.*   EXPANSION:                                                         00233100
.*           GLOBALS:   IKJCSNM - CSECT NAME FROM IKJPARM MACRO LABEL.  00233200
.*                      IKJDSNM - DSECT NAME FOR PDL                    00238800
.*           LOCALS(BINARY):  FENDBIT - INDICATES THE PCE IS NOT TO     00240800
.*                                      BE GENERATED.                   00242800
.*                                                                      00243200
         GBLC  &IKJDSNM,&IKJCSNM                                        00244400
         LCLA  &T,&END                                                  00246400
         LCLB  &FENDBIT,&FIGCON,&SARSVWD,&FPRPT,&FDFLT,&FHELP           00250000
         LCLC  &QUOTE                                                   00260000
&FENDBIT SETB  0                                                        00300000
.*                                                                      00310000
.* DETERMINE THAT THERE IS NO MORE THAN 1 POSITIONAL PARAMETER.         00320000
.*                                                                      00330000
         AIF   (N'&SYSLIST LT 2).GOOD                                   00350000
         MNOTE 8,'NO MORE THAN ONE POSITIONAL PARAMETER ALLOWED'        00400000
&FENDBIT SETB  1                                                        00402000
.*                                                                      00410000
.* DETERMINE IF STATEMENT LABEL WAS ENTERED.                            00420000
.*                                                                      00430000
.GOOD    AIF   ('&LABEL' NE '').GOOD1                                   00450000
.ERROR1  ANOP                                                           00550000
         MNOTE 8,'STATEMENT LABEL MISSING BUT REQUIRED'                 00600000
&FENDBIT SETB  1                                                        00650000
.*                                                                      00660000
.* DETERMINE IF CSECT NAME IS MISSING.                                  00670000
.*                                                                      00680000
.GOOD1   AIF   ('&IKJCSNM' NE '').GOOD2                                 00700000
         MNOTE 8,'CSECT NAME (FROM IKJPARM MACRO LABEL) IS MISSING'     00750000
&FENDBIT SETB  1                                                        00752000
.GOOD2   AIF   (N'&SYSLIST NE 0).TYPE2                                  00760000
&FIGCON  SETB  1                                                        00770000
         AGO   .OKGOBLD                                                 00780000
.TYPE2   ANOP                                                           00790000
&FPRPT   SETB  ('&PROMPT' NE '')                                        00790400
&FDFLT   SETB  ('&DEFAULT' NE '')                                       00790800
&FHELP   SETB  ('&HELP' NE '')                                          00791200
         AIF   (NOT (&FPRPT AND &FDFLT)).PCEBLD                         00791700
         MNOTE 8,'PARAMETER CANNOT BOTH DEFAULT AND REQUIRE PROMPTING'  00794000
&FENDBIT SETB  1                                                        00796000
.PCEBLD  AIF   ('&TYPNAM' NE '').OKGOBLD                                00798000
         MNOTE 8,'POSITIONAL PARAMETER TYPE FIELD MISSING BUT REQUIRED' 00798100
&FENDBIT SETB  1                                                        00798200
.OKGOBLD AIF   (&FENDBIT).END                                           00798300
&IKJCSNM CSECT ,             RESUME PCL CSECT                           00820000
RSVW&SYSNDX EQU  *                                                      00822000
&LABEL   EQU   *                                                        00822400
         DC    BL2'101&FPRPT&FDFLT.0&FHELP.0&FIGCON.0000000'            00824000
         AIF   (N'&SYSLIST NE 0).CONT                                   00826000
         DC    AL2(RSVD&SYSNDX-RSVW&SYSNDX)  LENGTH OF PCE              00828000
         DC    AL2(0)    NO PDE OFFSET - NO PDE BUILT                   00830000
RSVD&SYSNDX  EQU  *                                                     00832000
         AGO   .EXIT2                                                   00834000
.CONT    DC    AL2(RSVR&SYSNDX-RSVW&SYSNDX)  LENGTH OF PCE              00836000
         DC    AL2(LAB&SYSNDX-&IKJDSNM)          OFFSET TO THE PDE      00838000
.*                                                                      00838100
.* THE FOLLOWING CODE SUPPLIES QUOTES TO &TYPNAM IF THEY ARE MISSING    00838200
.*                                                                      00838300
&QUOTE   SETC  '&TYPNAM'(1,1)                                           00840300
         AIF   ('&QUOTE' EQ '''').QUOT                                  00842300
&QUOTE   SETC  ''''                                                     00842700
         DC    AL2(IKK@&SYSNDX-*),AL2(18),C&QUOTE&TYPNAM&QUOTE   PARAME*00842800
               TER TYPE MESSAGE SEGMENT                                 00843700
         AGO   .EQUGEN1                                                 00844100
.QUOT    ANOP                                                           00844500
         DC    AL2(IKK@&SYSNDX-*),AL2(18),C&TYPNAM  PARAMETER TYPE MESS*00844900
               AGE SEGMENT                                              00845300
.EQUGEN1 ANOP                                                           00845400
IKK@&SYSNDX EQU *                                                       00845700
         AIF   (&FPRPT).PRPT           PROMPT                           00846900
         AIF   (NOT &FDFLT).NPRDF      NEITHER                          00848900
         DC    AL1(IKJ@&SYSNDX-*-2),C&DEFAULT DEFAULT DATA              00850900
         AGO   .EQUGEN                                                  00852900
.PRPT    DC    AL1(IKJ@&SYSNDX-*-2),C&PROMPT PROMPT DATA                00854900
.EQUGEN  ANOP                                                           00856900
IKJ@&SYSNDX EQU *                                                       00858900
.NPRDF   ANOP                                                           00860900
         AIF   (NOT &FHELP).NOHELP     IS HELP SPECIFIED                00870900
         DC    AL2(IKJ$&SYSNDX-*)      LENGTH OF HELP DATA              00872900
&T       SETA  1                                                        00873300
.HELPLP  ANOP                                                           00873700
&T       SETA  &T+1                    NEXT HELP                        00873800
         AIF   (&T EQ 256).HELPER                                       00873900
         AIF   (&T LE N'&HELP).HELPLP                                   00878200
         AGO   .HELPCT                                                  00880200
.HELPER  MNOTE 4,'ONLY 255 LEVELS OF HELP AVAILABLE. OTHERS IGNORED'    00882200
.HELPCT  ANOP                                                           00886900
&T       SETA  &T-1                                                     00888900
         DC    AL1(&T)                 NUMBER OF HELP MESSAGES          00890900
&END     SETA  &T                                                       00891300
&T       SETA  1                                                        00903000
.HELPLPA ANOP                                                           00913000
         DC    AL2(IKJ&SYSNDX.&T-*),AL2(00),C&HELP(&T) HELP MSG SEGMENT 00913400
IKJ&SYSNDX.&T EQU *                                                     00913800
&T       SETA  &T+1                                                     00914200
         AIF   (&T LE &END).HELPLPA                                     00914600
IKJ$&SYSNDX EQU *                                                       00914700
.NOHELP  ANOP                                                           00914800
         AIF    (N'&SYSLIST NE 0).GOOD3                                 00921100
         AGO   .EXIT2                                                   00921200
.END     MEXIT                                                          00921300
.GOOD3   ANOP                                                           00921500
RSVR&SYSNDX EQU *                                                       00922100
&IKJDSNM DSECT                                                          00922400
LAB&SYSNDX   DS    2F                  ALLOCATE PDL SPACE               00922700
.EXIT2   ANOP                                                           00972700
&SYSECT  CSECT ,                   RESUME USERS CSECT                   01300000
         MEXIT                                                          01350000
         MEND                                                           01400000
