         MACRO                                                          00050000
&LABEL   IKJTERM &TYPNAM,&OPTION,&OPTION2,&OPTION3,&OPTION4,&PROMPT=,  *00100000
               &RSVWD=,&DEFAULT=,&TYPE=ANY,&SBSCRPT=,&VALIDCK=,&HELP=   00150000
.********************************************************************   00160000
.*                                                                      00170000
.* TITLE  -  IKJTERM MACRO (SYMBOLIC DEBUG PROJECT)                     00172000
.*                                                                      00174000
.* FUNCTION  -  THE IKJTERM MACRO IS USED BY COMMAND PROCESSORS TO      00180000
.*              DEFINE TO PARSE THE EXPECTED FORMAT OF A TERM-TYPE      00190000
.*              PARAMETER.                                              00190100
.*                                                                      00190400
.* INPUT  -  THE PROTOTYPE STATEMENT IS AS DEFINED ABOVE. IT'S          00192000
.*           PARAMETERS REPRESENT THE FOLLOWING:                        00192400
.*               &LABEL   - STATEMENT LABEL IS REQUIRED                 00194000
.*               &TYPNAM  - A PARAMETER TYPE IS REQUIRED                00196000
.*               &OPTION,&OPTION2,OPTION3, AND &OPTION4  -              00198000
.*                          FOUR POSSIBLE POSITIONAL PARAMETERS,        00198400
.*                          LIST,RANGE,SBSCRPT, AND ASIS/UPPERCASE.     00198800
.*               &RSVWD   - SPECIFIES THE PCE-LABEL WHICH WILL          00199200
.*                          DESCRIBE POSSIBLE LITERAL CONSTANTS.        00199600
.*               &TYPE    - INDICATES THE TYPE OF TERM TO BE            00199700
.*                          SCANNED FOR - VARIABLE,CONSTANT,            00199800
.*                          STATEMENT NUMBER, OR ANY(VARIABLE OR        00199900
.*                          CONSTANT). DEFAULT IS ANY.                  00216600
.*               &SBSCRPT - SPECIFIES THE PCE-LABEL WHICH WILL          00226600
.*                          DESCRIBE THE POSSIBLE SUBSCRIPT ON          00228600
.*                          THIS TERM.                                  00230600
.*               &HELP    - SUPPLIES SECOND-LEVEL MESSAGES.             00232600
.*               &VALIDCK - SPECIFIES THE ADDRESS OF A USER-SUPPLIED    00233000
.*                          VALIDITY CHECK EXIT ROUTINE.                00233100
.*               &PROMPT  - SUPPLIES DATA TO BE USED IF PROMPTING FOR   00233200
.*                          A MISSING PARAMETER.                        00238800
.*               &DEFAULT - SUPPLIES VALUE TO BE USED IF THE PARAMETER  00240800
.*                          IS NOT ENTERED.                             00242800
.*                                                                      00243200
.* OUTPUT  -  THIS MACRO PRODUCES A PARAMETER CONTROL ENTRY (PCE) TO BE 00243600
.*            PASSED TO THE PARSE SERVICE ROUTINE.                      00244000
.*            IF AN ERROR IS ENCOUNTERED IN PROCESSING THE MACRO        00244100
.*            INSTRUCTION ENTERED BY THE CP, AN APPROPRIATE ERROR       00244200
.*            MESSAGE IS PRINTED AND THE PCE IS NOT GENERATED.          00244300
.*                                                                      00258200
.********************************************************************   00268200
.*                                                                      00270200
.* THE FOLLOWING CODE DEFINES VARIABLES TO BE USED IN THE MACRO         00270600
.*     EXPANSION.                                                       00271000
.*        GLOBALS   -   IKJCSNM - CSECT NAME FROM IKJPARM MCARO LABEL   00271400
.*                      IKJDSNM - DSECT NAME FOR PDL                    00271800
.*        LOCALS(ARITHMETIC)  -  T - USED AS COUNTER FOR HELP MSG.      00271900
.*                               END - SECOND COUNTER FOR HELP MSG.     00272000
.*                               PDESIZE - AMOUNT OF SPACE FOR PDE      00272100
.*              (BINARY)      -  FLAGS FOR VARIOUS OPTIONS AND TO       00276700
.*                               INDICATE THAT NO PCE IS TO BE          00278700
.*                               GENERATED.                             00280700
.*              (CHARACTER)   -  QUOTE - USED WHEN QUOTES ARE MISSING   00281100
.*                               FROM &TYPNAM                           00281200
.*                                                                      00281300
         GBLC  &IKJCSNM,&IKJDSNM                                        00281500
         LCLA  &T,&PDESIZE,&END                                         00286100
         LCLB  &FLIST,&FRANGE,&FASIS,&FPRPT,&FDFLT,&FHELP,&FVALID       00300000
         LCLB  &FENDBIT,&FSUBSC,&FRSVWD,&FSTMT,&FVAR,&FCNST,&FANY       00350000
         LCLB  &SUBTRM                                                  00360000
         LCLC  &QUOTE                                                   00400000
&FENDBIT SETB  0                                                        00450000
.*                                                                      00460000
.* DETERMINE IF EXTRANEOUS POSITIONAL PARAMETERS HAVE BEEN SPECIFIED.   00470000
.*                                                                      00480000
         AIF   (N'&SYSLIST LT 6).GOOD                                   00500000
         MNOTE 8,'NO MORE THAN 5 POSITIONAL PARAMETERS ALLOWED'         00550000
&FENDBIT SETB  1                                                        00550400
.*                                                                      00552000
.* DETERMINE IF TYPE NAME HAS BEEN ENTERED.                             00560000
.*                                                                      00580000
.GOOD    AIF   ('&TYPNAM' EQ 'LIST' OR '&TYPNAM' EQ 'RANGE' OR         *00600000
               '&TYPNAM' EQ 'ASIS' OR '&TYPNAM' EQ 'UPPERCASE' OR      *00650000
               '&TYPNAM' EQ '').BAD                                     00700000
         AGO   .GOOD1                                                   00750000
.BAD     MNOTE 8,'PARAMETER TYPE MISSING BUT REQUIRED'                  00800000
&FENDBIT SETB  1                                                        00850000
.*                                                                      00852000
.* DETERMINE IF CSECT NAME IS MISSING.                                  00860000
.*                                                                      00870000
.GOOD1   AIF   ('&IKJCSNM' NE '').GOOD2                                 00900000
         MNOTE 8,'CSECT NAME (FROM IKJPARM MACRO LABEL) IS MISSING'     00950000
&FENDBIT SETB  1                                                        01000000
.*                                                                      01010000
.* DETERMINE IF STATEMENT LABEL WAS ENTERED.                            01020000
.*                                                                      01030000
.GOOD2   AIF   ('&LABEL' NE '').GOOD3                                   01050000
         MNOTE 8,'STATEMENT LABEL MISSING BUT REQUIRED'                 01100000
&FENDBIT SETB  1                                                        01150000
.GOOD3   ANOP                                                           01200000
.*                                                                      01210000
.* THE FOLLOWING CODE SETS FLAGS INDICATING THE OPTIONS SPECIFIED       01220000
.*   ON POSITIONAL PARAMETERS.                                          01230000
.*                                                                      01240000
&FLIST   SETB  ('&OPTION' EQ 'LIST' OR '&OPTION2' EQ 'LIST' OR         *01250000
               '&OPTION3' EQ 'LIST' OR '&OPTION4' EQ 'LIST')            01300000
&FRANGE  SETB  ('&OPTION' EQ 'RANGE' OR '&OPTION2' EQ 'RANGE' OR       *01350000
               '&OPTION3' EQ 'RANGE' OR '&OPTION4' EQ 'RANGE')          01400000
&FASIS   SETB  ('&OPTION' EQ 'ASIS' OR '&OPTION2' EQ 'ASIS' OR         *01450000
               '&OPTION3' EQ 'ASIS' OR '&OPTION4' EQ 'ASIS')            01500000
&SUBTRM   SETB  ('&OPTION' EQ 'SBSCRPT' OR '&OPTION2' EQ 'SBSCRPT' OR  *01502000
               '&OPTION3' EQ 'SBSCRPT' OR '&OPTION4' EQ 'SBSCRPT')      01504000
.*                                                                      01510000
.* THE FOLLOWING CODE DETERMINES IF INCORRECT POSITIONAL PARAMETERS     01520000
.*   HAVE BEEN ENTERED.                                                 01530000
.*                                                                      01540000
         AIF   ('&OPTION' EQ 'LIST' OR '&OPTION' EQ 'RANGE' OR         *01550000
               '&OPTION' EQ 'ASIS' OR '&OPTION' EQ 'UPPERCASE' OR      *01600000
               '&OPTION' EQ '' OR '&OPTION' EQ 'SBSCRPT').OPT1          01650000
         MNOTE 8,'''&OPTION'' IS AN INVALID POSITIONAL PARAMETER'       01700000
&FENDBIT SETB  1                                                        01710000
.OPT1    AIF   ('&OPTION2' EQ 'LIST' OR '&OPTION2' EQ 'RANGE' OR       *01750000
               '&OPTION2' EQ 'ASIS' OR '&OPTION2' EQ 'UPPERCASE' OR    *01800000
               '&OPTION2' EQ '' OR '&OPTION2' EQ 'SBSCRPT').OPT2        01850000
         MNOTE 8,'''&OPTION2'' IS AN INVALID POSITIONAL PARAMETER'      01900000
&FENDBIT SETB  1                                                        01950000
.OPT2    AIF   ('&OPTION3' EQ 'LIST' OR '&OPTION3' EQ 'RANGE' OR       *02000000
               '&OPTION3' EQ 'ASIS' OR '&OPTION3' EQ 'UPPERCASE' OR    *02010000
               '&OPTION3' EQ '' OR '&OPTION3' EQ 'SBSCRPT').OPT3        02020000
         MNOTE 8,'''&OPTION3'' IS AN INVALID POSITIONAL PARAMETER'      02030000
&FENDBIT SETB  1                                                        02040000
.OPT3    AIF   ('&OPTION4' EQ 'LIST' OR '&OPTION4' EQ 'RANGE' OR       *02043400
               '&OPTION4' EQ 'ASIS' OR '&OPTION4' EQ 'UPPERCASE' OR    *02045400
               '&OPTION4' EQ '' OR '&OPTION4' EQ 'SBSCRPT').OPT4        02047400
         MNOTE 8,'''&OPTION4'' IS AN INVALID POSITIONAL PARAMETER'      02047800
&FENDBIT SETB  1                                                        02048200
.*                                                                      02048700
.* UPPERCASE AND ASIS CANNOT BOTH BE SPECIFIED.                         02052100
.*                                                                      02055500
.OPT4    AIF   (('&OPTION' EQ 'UPPERCASE' OR '&OPTION2' EQ             *02058900
               'UPPERCASE' OR '&OPTION3' EQ 'UPPERCASE') AND           *02062300
               &FASIS).ERROR3                                           02065700
         AGO   .A1                                                      02069100
.ERROR3  MNOTE 8,'BOTH ''UPPERCASE'' AND ''ASIS'' CANNOT BE SPECIFIED'  02072500
&FENDBIT SETB  1                                                        02075900
.A1      ANOP                                                           02079300
.*                                                                      02082700
.* THE FOLLOWING CODE SETS FLAGS INDICATING KEYWORD OPTIONS.            02086100
.*                                                                      02089500
&FPRPT   SETB  ('&PROMPT' NE '')                                        02092900
&FDFLT   SETB  ('&DEFAULT' NE '')                                       02096300
&FHELP   SETB  ('&HELP' NE '')                                          02099700
&FVALID  SETB  ('&VALIDCK' NE '')                                       02103100
&FSUBSC  SETB  ('&SBSCRPT' NE '')                                       02106500
&FRSVWD  SETB  ('&RSVWD' NE '')                                         02109900
&FSTMT   SETB  ('&TYPE' EQ 'STMT')                                      02111900
&FVAR    SETB  ('&TYPE' EQ 'VAR')                                       02113900
&FCNST   SETB  ('&TYPE' EQ 'CNST')                                      02115900
&FANY    SETB  ('&TYPE' EQ 'ANY')                                       02117900
.*                                                                      02119300
         AIF  (&FRANGE AND &SUBTRM).BAD3                                02121300
         AGO   .GOODI4                                                  02121421
.BAD3    ANOP                                                           02121500
         MNOTE 4,'RANGE OPTION ILLEGAL WITH "SBSCRPT". IGNORED'         02121600
&FRANGE  SETB  0                                                        02122000
.GOODI4  AIF   (&FLIST AND &SUBTRM).BAD4                                02122100
         AGO   .GOODI5                                                  02122221
.BAD4    ANOP                                                           02122300
         MNOTE 4,'LIST OPTION ILLEGAL WITH "SBSCRPT". IGNORED.'         02122700
&FLIST   SETB  0                                                        02123100
.GOODI5  AIF (NOT(&SUBTRM AND &FSUBSC)).GOODI6                          02123200
         MNOTE 8,'"SBSCRPT" OPTION ILLEGAL WITH "SBSCRPT=LABEL" OPTION' 02123300
&FENDBIT SETB  1                                                        02123400
.GOODI6  ANOP                                                           02124500
.*                                                                      02126500
.* THE ONLY VALID 'TYPE' PARAMETERS ARE VAR,STMT,CNST, AND ANY          02127600
.*                                                                      02128700
         AIF   ('&TYPE' NE 'STMT' AND '&TYPE' NE 'VAR' AND '&TYPE' NE  *02129800
               'CNST' AND '&TYPE' NE 'ANY').ERROR                       02130900
         AGO   .GOOD9                                                   02132000
.ERROR   MNOTE 8,'INVALID ''TYPE'' PARAMETER'                           02133100
&FENDBIT SETB  1                                                        02134200
.*                                                                      02135300
.* PROMPT AND DEFAULT CANNOT BOTH BE SPECIFIED.                         02136400
.*                                                                      02137500
.GOOD9   AIF   (NOT(&FDFLT AND &FPRPT)).GOOD4                           02138600
         MNOTE 8,'PARAMETER CANNOT BOTH DEFAULT AND REQUIRE PROMPTING'  02139700
&FENDBIT SETB  1                                                        02140800
.*                                                                      02141900
.* RSVWD IS IGNORED IF TYPE=VAR OR TYPE=STMT.                           02143000
.*                                                                      02144100
.GOOD4   AIF   (('&TYPE' EQ 'VAR' OR '&TYPE' EQ 'STMT') AND            *02145200
               &FRSVWD).ERROR1                                          02146300
         AGO   .GOOD5                                                   02147400
.ERROR1  MNOTE 4,'''RSVWD'' IGNORED WITH ''&TYPE'''                     02148500
&FRSVWD  SETB  0                                                        02149600
.*                                                                      02150700
.* SBSCRPT IS IGNORED IF TYPE=STMT OR TYPE=CNST.                        02151800
.*                                                                      02152900
.GOOD5   AIF   (('&TYPE' EQ 'STMT' OR '&TYPE' EQ 'CNST') AND           *02154000
               &FSUBSC).ERROR2                                          02155100
         AGO   .GOOD6                                                   02156200
.ERROR2  MNOTE 4,'''SBSCRPT'' IGNORED WITH ''&TYPE'''                   02157300
&FSUBSC  SETB  0                                                        02158400
.*                                                                      02159500
.* IF AN ERROR HAS BEEN ENCOUNTERED DO NOT GENERATE PCE.                02169500
.*                                                                      02169600
.GOOD6   AIF   (NOT &FENDBIT).GEN                                       02169800
         MEXIT                                                          02179800
.GEN     ANOP                                                           02189800
&IKJCSNM CSECT ,                                                        02199800
* FLAGS - BIT3=PROMPT,    BIT4=DEFAULT, BIT6=HELP,                      02209800
*         BIT7=VALIDCK,   BIT8=LIST,    BIT9=ASIS,    BIT10=RANGE,      02219800
*         BIT11=SBSCRPT,  BIT12=RSVWD                                   02229800
DENT&SYSNDX EQU *                                                       02239800
&LABEL   EQU   *                                                        02240200
         DC    BL2'110&FPRPT&FDFLT.0&FHELP&FVALID&FLIST&FASIS&FRANGE&FS*02241800
               UBSC&FRSVWD.000'      FLAGS                              02243800
         DC    AL2(DEND&SYSNDX-DENT&SYSNDX)      LENGTH OF PCE          02245800
         AIF   (&SUBTRM).GOODI7                                         02246200
         DC    AL2(LAB&SYSNDX-&IKJDSNM)          OFFSET TO PDE          02247800
         AGO   .GOODI8                                                  02247900
.GOODI7  DC   AL2(0)        NO PDE OFFSET - PREVIOUSLY ALLOCATED        02248000
.GOODI8  ANOP                                                           02248100
* TYPES - BIT0=STMT, BIT1=VAR, BIT2=CNST, BIT3=ANY,BIT4=SBSCRPT         02248200
         DC    BL1'&FSTMT&FVAR&FCNST&FANY&SUBTRM.000'   TYPE SPECIFIED  02248600
.*                                                                      02249000
.* THE FOLLOWING CODE SUPPLIES QUOTES TO &TYPNAM IF THEY ARE MISSING.   02249400
.*                                                                      02249500
&QUOTE   SETC  '&TYPNAM'(1,1)                                           02249600
         AIF   ('&QUOTE' EQ '''').QUOT                                  02249700
&QUOTE   SETC  ''''                                                     02299700
         DC    AL2(IKJ@&SYSNDX-*),AL2(18),C&QUOTE&TYPNAM&QUOTE    PARAM*02309700
               ETER TYPE MESSAGE SEGMENT                                02319700
         AGO   .EQUGEN1                                                 02329700
.QUOT    ANOP                                                           02339700
         DC    AL2(IKJ@&SYSNDX-*),AL2(18),C&TYPNAM    PARAMETER TYPE ME*02341700
               SSAGE SEGMENT                                            02343700
.EQUGEN1 ANOP                                                           02345700
IKJ@&SYSNDX EQU *                                                       02347700
         AIF   (&FPRPT).PRPT      PROMPT SPECIFIED                      02349300
         AIF   (NOT &FDFLT).NPRDF                                       02349400
         DC    AL1(IKJ$&SYSNDX-*-2),C&DEFAULT        DEFAULT DATA       02349500
         AGO   .EQUGEN                                                  02349600
.PRPT    DC     AL1(IKJ$&SYSNDX-*-2),C&PROMPT        PROMPT DATA        02399600
.EQUGEN  ANOP                                                           02409600
IKJ$&SYSNDX EQU *                                                       02419600
.NPRDF   ANOP                                                           02429600
         AIF   (NOT &FSUBSC).NOSUBSC                                    02439600
         DC    AL2(&SBSCRPT-&IKJCSNM)    OFFSET TO SUBSCRIPT PCE        02441600
.NOSUBSC AIF   (NOT &FRSVWD).NORSWD                                     02443600
         DC    AL2(&RSVWD-&IKJCSNM)       OFFSET TO RESERVE WORD PCE    02445600
.NORSWD  ANOP                                                           02447600
IKJA&SYSNDX EQU *                                                       02448000
         AIF   (NOT &FHELP).NOHELP     IS HELP SPECIFIED                02448400
         DC    AL2(IKJB&SYSNDX-*)      LENGTH OF HELP DATA              02448800
&T       SETA  1                                                        02449200
.HELPLP  ANOP                                                           02449300
&T       SETA  &T+1                                                     02449400
         AIF   (&T EQ 256).HELPER                                       02449500
         AIF   (&T LE N'&HELP).HELPLP                                   02499500
         AGO   .HELPCT                                                  02509500
.HELPER  MNOTE 4,'ONLY 255 LEVELS OF HELP AVAILABLE. OTHERS IGNORED'    02519500
&T       SETA  &T+1                                                     02529500
.HELPCT  ANOP                                                           02539500
&T       SETA  &T-1                                                     02541500
         DC    AL1(&T)             NUMBER OF HELP MESSAGES              02543500
&END     SETA  &T                                                       02545500
&T       SETA  1                                                        02547500
.HELPLPA ANOP                                                           02547900
         DC    AL2(IKJ&SYSNDX.&T-*),AL2(00),C&HELP(&T) HELP MSG SEGMENT 02548300
IKJ&SYSNDX.&T EQU *                                                     02548700
&T       SETA  &T+1                                                     02548800
         AIF   (&T LE &END).HELPLPA                                     02548900
IKJB&SYSNDX EQU *                                                       02549000
.NOHELP  AIF   (NOT &FVALID).NOVALID     IS VALIDCK SPECIFIED           02549100
         DC    AL3(&VALIDCK)       VALIDCK ROUTINE ADDRESS              02549200
.NOVALID ANOP                                                           02549300
DEND&SYSNDX EQU *                                                       02582700
         AIF (&SUBTRM).NOALLOC                                          02592700
&IKJDSNM DSECT                                                          02599400
&PDESIZE SETA  41                                                       02601400
         AIF   (&FLIST AND &FRANGE AND &FSUBSC).DSECT                   02603400
&PDESIZE SETA  40                                                       02605400
         AIF   (&FRANGE AND &FSUBSC).DSECT                              02607400
&PDESIZE SETA  21                                                       02607800
         AIF   (&FLIST AND &FSUBSC).DSECT                               02608200
&PDESIZE SETA  20                                                       02608600
         AIF   (&FSUBSC).DSECT                                          02609000
&PDESIZE SETA  11                                                       02609400
         AIF   (&FLIST AND &FRANGE).DSECT  IS LIST AND RANGE SPECIFIED  02619400
&PDESIZE SETA  10                                                       02629400
         AIF   (&FRANGE).DSECT                                          02639400
&PDESIZE SETA  6                                                        02641400
         AIF   (&FLIST).DSECT                                           02643400
&PDESIZE SETA  5                                                        02645400
.DSECT   ANOP                                                           02647400
LAB&SYSNDX   DS    &PDESIZE.F      ALLOCATE PDE SPACE                   02647800
.NOALLOC  ANOP                                                          02647900
&SYSECT  CSECT ,               RESUME USERS CSECT                       02648200
         MEXIT                                                          02648600
         MEND                                                           02649000
