         MACRO                                                          00100057
&LINNME  LINEGRP &TERM=,&DDNAME=,&LINENO=,&UNITNO=1,&TRANTAB=,&TERMNO=,X00200057
               &CODE=,&DIAL=YES,&INTVL=,&FEATURE=,&ADDR=,&SCREEN=,     X00300057
               &PCI=                                            SA59163 00400057
.*                                                                      00500057
.*        POST RELEASE 21.8 CHANGES                                     00600057
.*C596959,596979,596991,596995                                  SA72293 00700057
.*D596997-597498                                                SA72293 00800057
.*        RELEASE 21.8, 01/17/74, CHANGE LEVEL=02               SA68208 00900057
.*                                                                      01000057
.*                                                                      01100057
.*FUNCTION -- AFTER EXAMINING THE CALLER'S PARAMETERS FOR VALIDITY,     01200057
.*   VALUES ARE PLACED IN GLOBAL VARIABLES TO REFLECT THE CALLER'S      01300057
.*   SPECIFICATIONS FOR THIS LINE GROUP.  THE VALUES IN THE GLOBAL      01400057
.*   VARIABLES WILL BE USED LATER BY THE 'TSOMCP' MACRO TO GOVERN       01500057
.*   GENERATION OF THE TCAM MCP MACRO STATEMENTS.                       01600057
.*                                                                      01700057
.*ENTRY POINTS -- NOT APPLICABLE                                        01800057
.*                                                                      01900057
.*INPUT -- MACRO CALL PARAMETERS                                        02000057
.*                                                                      02100057
.*OUTPUT -- VALUES IN GLOBAL VARIABLES TO BE USED LATER BY THE          02200057
.*   'TSOMCP' MACRO.  MNOTE MESSAGES IF INVALID PARAMETERS ARE          02300057
.*   DETECTED.                                                          02400057
.*                                                                      02500057
.*EXTERNAL REFERENCES -- NOT APPLICABLE                                 02600057
.*                                                                      02700057
.*EXITS, NORMAL -- NORMAL EXIT OCCURS IF NO SERIOUS ERRORS IN THE       02800057
.*   CALLER'S PARAMETERS ARE DETECTED.                                  02900057
.*                                                                      03000057
.*EXITS,ERROR -- UPON DETECTION OF A SERIOUS ERROR, THE 'QUITSW'        03100057
.*   IS SET TO 1 AND FURTHER PROCESSING IS BYPASSED.                    03200057
.*                                                                      03300057
.*TABLES/WORK AREAS -- SEE DESCRIPTIONS ACCOMPANYING VARIABLE           03400057
.*   DECLARATIONS.                                                      03500057
.*                                                                      03600057
.*ATTRIBUTES -- NOT APPLICABLE                                          03700057
.*                                                                      03800057
.*CHARACTER CODE DEPENDENCY -- NONE                                     03900057
.*                                                                      04000057
.*NOTES -- NONE                                                         04100057
.*                                                                      04200057
.*                                                                      04300057
.*       GLOBAL VARIABLES                                               04400057
.*                                                                      04500057
         GBLA  &NLG                NUMBER OF LINE GROUP MACROS ISSUED   04600057
         GBLA  &LNO(63)            CONTAINS LINENO= PARAMETER VALUES    04700057
         GBLA  &UNO(63)            CONTAINS UNITNO= PARAMETER VALUES    04800057
         GBLA  &INT(63)            CONTAINS INTVL= PARAMETER VALUES     04900057
         GBLA  &ADRPT              POINTER TO LAST ADDR PARM GROUP      05000057
         GBLA  &SCRPT              POINTER TO LAST SCREEN PARM GROUP    05100057
         GBLA  &SCRH(2500)         CONTAINS SCREEN HEIGHT               05200057
         GBLA  &SCRW(2500)         CONTAINS SCREEN WIDTH                05300057
         GBLA  &TRMNO(2500)        CONTAINS NO. OF TERMINALS/LINE       05400057
         GBLB  &LGRPSW                 LINEGRP ISSUED SWITCH            05500057
         GBLB  &MCPSW                  TSOMCP  ISSUED SWITCH            05600057
         GBLB  &QUITSW                 GENERATION QUIT SWITCH           05700057
         GBLB  &BISYNC                 BISYNCHRONOUS LINE               05800057
         GBLB  &DIALSW(63)             DIAL LINE SWITCHES               05900057
         GBLB  &FETAB(189)             FEATURE= SWITCHES                06000057
.*                                     (3 X 63) = 189                   06100057
         GBLC  &T(63)              CONTAINS TERM= PARAMETER VALUES      06200057
         GBLC  &DDNME(63)          CONTAINS DDNAME= PARAMETER VALUES    06300057
         GBLC  &TTAB(252)          CONTAINS TRANTAB= PARAMETER VALUES   06400057
         GBLC  &CTAB(252)          CONTAINS CODE= PARAMETER VALUES      06500057
.*                                     (4 X 63) = 252                   06600057
         GBLC  &ADCHAR(2500)       CONTAINS ADDR= PARAMETER VALUES      06700057
         GBLC  &PC(63)             CONTAINS PCI SPECIFICATIONS  SA59163 06800057
.*                                                                      06900057
.*       LOCAL VARIABLES                                                07000057
.*                                                                      07100057
         LCLA  &A                                                       07200057
         LCLA  &B                                                       07300057
         LCLA  &C                                                       07400057
         LCLA  &D                                                       07500057
         LCLA  &I                                                       07600057
         LCLB  &BADTERM                TERM= BAD                        07700057
         LCLB  &BADDDNM                DDNAME= BAD                      07800057
         LCLB  &BADLNO                 LINENO= BAD                      07900057
         LCLB  &BADUNO                 UNITNO= BAD                      08000057
         LCLB  &BADTTAB                TRANTAB= BAD                     08100057
         LCLB  &BADCODE                CODE= BAD                        08200057
         LCLB  &BADDIAL                DIAL= BAD                        08300057
         LCLB  &BADINTV                INTVL= BAD                       08400057
         LCLB  &BADFE                  FEATURE= BAD                     08500057
         LCLB  &QTDFTSW                QUOTE DEFAULT SW                 08600057
         LCLB  &SWBC               BC41 TRAN TABLE SPECIFIED            08700057
         LCLB  &SWEB               EB41 TRAN TABLE SPECIFIED            08800057
         LCLB  &SWEBAS             EBCD OR ASCI TABLE SPECIFIED         08900057
         LCLB  &SW2260             INDICATES 2260/65 LINE GROUP         09000057
         LCLB  &SW3270             INDICATES 3270 LINE GROUP            09100057
         LCLC  &F                  HOLDS A FEATURE SUB-LIST MEMBER,     09200057
.*                                 OR A PCI SUB-LIST MEMBER     SA59163 09300057
.*                                                                      09400057
.*       TEST FOR MACRO CALL OUT OF ORDER OR TOO MANY LINEGRP MACRO     09500057
.*       CALLS ISSUED.                                                  09600057
.*                                                                      09700057
&NLG     SETA  &NLG+1                                                   09800057
&I       SETA  &NLG                     SHORT FORM FOR NLG              09900057
         AIF   (NOT &MCPSW).A0         TSOMCP MACRO ISSUED?             10000057
         MNOTE 16,'IKJ54101I LINEGRP MACRO MUST PRECEDE TSOMCP MACRO'   10100057
&QUITSW  SETB  1                       YES, SET QUIT SW.                10200057
.A0      ANOP                                                           10300057
&LGRPSW  SETB  1                       SET LINEGRP ISSUED SW.           10400057
         AIF   (&NLG LE 63).A1         MAX. LINEGRP COUNT EXCEEDED?     10500057
         MNOTE 16,'IKJ54102I MORE THAN 63 LINEGRP MACROS'               10600057
&QUITSW  SETB  1                       YES, SET QUIT SW.                10700057
         MEXIT                                                          10800057
.*                                                                      10900057
.*       ARE REQUIRED OPERANDS SPECIFIED                                11000057
.*                                                                      11100057
.A1      AIF   ('&TERM' NE '' AND '&DDNAME' NE '' AND '&LINENO' NE '').*11200057
               TERM                                                     11300057
         MNOTE 12,'IKJ54103I REQUIRED OPERANDS(S) NOT SPECIFIED'        11400057
&QUITSW  SETB  1                       NO, SET QUIT SW.                 11500057
         MEXIT                                                          11600057
.*  ------------------------------------------------------------------- 11700057
.*  -----      TERM= KEYWORD ANALYSIS       --------------------------- 11800057
.*  ------------------------------------------------------------------- 11900057
.TERM    AIF   (K'&TERM GT 4 OR N'&TERM GT 1).T4    TERM=KEYWORD VALID? 12000057
         AIF   ('&TERM' EQ '1050').T1   BRANCH IF TERM=1050             12100057
         AIF   ('&TERM' EQ '2741').T1   BRANCH IF TERM=2741             12200057
         AIF   ('&TERM' EQ '5041').T1   BRANCH IF TERM=5041             12300057
         AIF   ('&TERM' EQ '3335').T1   BRANCH IF TERM=3335             12400057
         AIF   ('&TERM' EQ '226R').T1   BRANCH IF TERM=226R             12500057
         AIF   ('&TERM' EQ '226L').T1   BRANCH IF TERM=226L             12600057
         AIF   ('&TERM' EQ '2265').T1   BRANCH IF TERM=2265             12700057
         AIF   ('&TERM' EQ '327L').T2   BRANCH IF TERM=327L             12800057
         AIF   ('&TERM' EQ '327R').T2   BRANCH IF TERM=327R             12900057
         AIF   ('&TERM' EQ '327S').T2   BRANCH IF TERM=327S             13000057
.T4      MNOTE 16,'IKJ54104I &TERM INVALID FOR TERM OPERAND'            13100057
&BADTERM SETB  1                       INDICATE BAD TERM= KEYWORD.      13200057
&QUITSW  SETB  1                       SET QUIT SW.                     13300057
         AGO   .DDNME              GO CHECK DD NAME PARAMETER           13400057
.T2      ANOP                                                           13500057
&BISYNC  SETB  1                   BISYNCHRONOUS LINE                   13600057
.T1      ANOP                                                           13700057
&T(&I)   SETC  '&TERM'             PUT VALUE IN ARRAY                   13800057
.*  ------------------------------------------------------------------- 13900057
.*  -----      DDNAME= KEYWORD ANALYSIS     --------------------------- 14000057
.*  ------------------------------------------------------------------- 14100057
.DDNME   AIF   (K'&DDNAME LE 8 AND N'&DDNAME EQ 1).DD1   KEYWORD VALID? 14200057
         MNOTE 16,'IKJ54101I &DDNAME INVALID FOR DDNAME OPERAND'        14300057
&BADDDNM SETB  1                       INDICATE BAD DDNAME= KEYWORD.    14400057
&QUITSW  SETB 1                        NO, SET QUIT SW,                 14500057
         AGO   .LNO                    BR TO TEST LINENO.               14600057
.DD1     ANOP                                                           14700057
&DDNME(&I) SETC '&DDNAME'              SAVE NAME.                       14800057
.*  ------------------------------------------------------------------- 14900057
.*  -----      LINENO= KEYWORD ANALYSIS     --------------------------- 15000057
.*  ------------------------------------------------------------------- 15100057
.LNO     AIF   (K'&LINENO GT 2 OR N'&LINENO GT 1).L1     KEYWORD VALID? 15200057
         AIF   (T'&LINENO NE 'N').L1                                    15300057
         AIF   (&LINENO LE 51 AND &LINENO GT 0).L2                      15400057
.L1      MNOTE 16,'IKJ54104I &LINENO INVALID FOR LINENO OPERAND'        15500057
&BADLNO  SETB  1                       INDICATE BAD LINENO= KEYWORD.    15600057
&QUITSW  SETB  1                       NO, SET QUIT SW,                 15700057
         AGO   .UNO                    BR TO TEST UNITNO.               15800057
.L2      ANOP                                                           15900057
&LNO(&I) SETA  &LINENO                 SAVE LINENO.                     16000057
.*  ------------------------------------------------------------------- 16100057
.*  -----      UNITNO= KEYWORD ANALYSIS     --------------------------- 16200057
.*  ------------------------------------------------------------------- 16300057
.UNO     AIF   (N'&UNITNO GT 1).U1     UNITNO= KEYWORD VALID?           16400057
         AIF   (T'&UNITNO EQ 'N').U2                                    16500057
.U1      MNOTE 16,'IKJ54104I &UNITNO INVALID FOR UNITNO OPERAND'        16600057
&BADUNO  SETB  1                       INDICATE BAD UNITNO= KEYWORD.    16700057
&QUITSW  SETB  1                       NO, SET QUIT SW,                 16800057
         AGO   .TTAB                   BR TO TEST TRANTAB.              16900057
.U2      ANOP                                                           17000057
         AIF   (&UNITNO GT 0 AND &UNITNO LT 256).U3  OPERAND IN RANGE   17100057
         MNOTE 4,'IKJ54110I UNITNO OPERAND OUT OF RANGE, DEFAULT VALUE -17200057
               USED'                                                    17300057
&UNO(&I) SETA  1                        USE DEFAULT VALUE               17400057
         AGO   .TTAB                    BR TO TEST TRANTAB              17500057
.U3      ANOP                                                           17600057
&UNO(&I) SETA  &UNITNO                 SAVE UNITNO.                     17700057
.*  ------------------------------------------------------------------- 17800057
.*  -----      TRANTAB= KEYWORD ANALYSIS    --------------------------- 17900057
.*  ------------------------------------------------------------------- 18000057
.TTAB    ANOP                                                           18100057
         AIF   (&BADTERM).TTQUIT                                        18200057
         AIF   ('&TRANTAB' EQ '').TTABDFT   TEST TRANTAB FOR DEFAULT.   18300057
&C       SETA  N'&TRANTAB               GET NO. OF SUBLIST OPERANDS     18400057
.*                                                                      18500057
.*                                                                      18600057
.*       SET UP FOR LOOP TO CHECK TABLE VALIDITY & STORE IN ARRAY       18700057
.*                                                                      18800057
&A       SETA  (&NLG-1)*4          SET ARRAY POINTER                    18900057
&B       SETA  0                   SET SUBLIST POINTER                  19000057
&D       SETA  1                   SET ARRAY OFFSET POINTER             19100057
.*                                                                      19200057
.TTLOOP1 ANOP                      LOOP EXECUTED ONCE/TRANSLATE TABLE   19300057
&B       SETA  &B+1                INCREMENT LOOP COUNTER               19400057
         AIF   (&B GT &C).CODE     BR IF NO MORE TABLES                 19500057
.*                                                                      19600057
.*       SELECT CHECKING ROUTINE ACCORDING TO TERMINAL TYPE             19700057
.*                                                                      19800057
         AIF   ('&TERM' EQ '5041').TT5041                               19900057
         AIF   ('&TERM' EQ '1050').TT5041                               20000057
         AIF   ('&TERM' EQ '2741').TT2741                               20100057
         AIF   ('&TERM' EQ '3335').TT3335                               20200057
         AIF   ('&TERM' EQ '226L').TT226L                               20300057
         AIF   ('&TERM' EQ '226R').TT226X                               20400057
         AIF   ('&TERM' EQ '2265').TT226X                               20500057
         AIF   ('&TERM' EQ '327L').TT226L                               20600057
         AIF   ('&TERM' EQ '327R').TT327X                               20700057
         AIF   ('&TERM' EQ '327S').TT327X                               20800057
.*                                                                      20900057
.*       5041 & 1050                                                    21000057
.*                                                                      21100057
.TT5041  ANOP                                                           21200057
         AIF   ('&TRANTAB(&B)' EQ '1050').TTEB41                        21300057
         AIF   ('&TERM' EQ '1050').TTBAD                                21400057
.*                                                                      21500057
.*       2741                                                           21600057
.*                                                                      21700057
.TT2741  AIF   ('&TRANTAB(&B)' EQ 'EB41').TTEB41                        21800057
         AIF   ('&TRANTAB(&B)' EQ 'BC41').TTBC41                        21900057
         AIF   ('&TRANTAB(&B)' EQ 'CR41').TTOK                          22000057
         AGO   .TTBAD                                                   22100057
.*                                                                      22200057
.*       3335                                                           22300057
.*                                                                      22400057
.TT3335  ANOP                                                           22500057
         AIF   ('&TRANTAB(&B)' EQ 'TTYB').TTOK                          22600057
         AIF   ('&TRANTAB(&B)' EQ 'TTYC').TTOK                          22700057
         AGO   .TTBAD                                                   22800057
.*                                                                      22900057
.*       226L                                                           23000057
.*                                                                      23100057
.TT226L  ANOP                                                           23200057
         AIF   ('&TRANTAB(&B)' EQ 'EBCD').TTOK                          23300057
         AGO   .TTBAD                                                   23400057
.*                                                                      23500057
.*       226X                                                           23600057
.*                                                                      23700057
.TT226X  ANOP                                                           23800057
         AIF   ('&TRANTAB(&B)' EQ '2260').TTOK                          23900057
         AIF   ('&TRANTAB(&B)' EQ '2265').TTOK                          24000057
.*                                                                      24100057
.*       327R                                                           24200057
.*                                                                      24300057
.TT327X  ANOP                                                           24400057
         AIF   ('&TRANTAB(&B)' EQ 'EBCD').TT1                           24500057
         AIF   ('&TRANTAB(&B)' NE 'ASCI').TTBAD                         24600057
.TT1     ANOP                                                           24700057
         AIF   (NOT &SWEBAS).TT2                                        24800057
         MNOTE 4,'IKJ54113I EBCD OR ASCI (BUT NOT BOTH) ALLOWED FOR THI-24900057
               S TERMINAL TYPE, DEFAULT VALUE USED'                     25000057
         AGO   .TTABDFT                                                 25100057
.TT2     ANOP                                                           25200057
&SWEBAS  SETB  1                                                        25300057
         AGO   .TTOK                                                    25400057
.*                                                                      25500057
.TTBAD   ANOP                                                           25600057
         MNOTE 12,'IKJ54105I TRANTAB=&TRANTAB(&B) INVALID FOR THIS TERM-25700057
               INAL TYPE'                                               25800057
&BADTTAB SETB  1                   INDICATE TRANTAB PARAMETER BAD       25900057
&QUITSW  SETB  1                   INDICATE SERIOUS ERROR               26000057
         AGO   .TTLOOP1            GO CHECK NEXT SUB-OPERAND            26100057
.*                                                                      26200057
.*       PUT TRANSLATE TABLE NAME INTO ARRAY                            26300057
.*                                                                      26400057
.TTOK    ANOP                                                           26500057
&TTAB(&A+&D) SETC '&TRANTAB(&B)'   INSERT TBL NAME IN ARRAY             26600057
&D       SETA  &D+1                BUMP ARRAY OFFSET POINTER            26700057
         AGO   .TTLOOP1            GO PROCESS NEXT SUB-OPERAND          26800057
.*                                                                      26900057
.TTEB41  ANOP                                                           27000057
&SWEB    SETB  1                   INDICATE EB41 TABLE SPECIFIED        27100057
         AGO   .TTOK               GO PUT TABLE INTO ARRAY              27200057
.*                                                                      27300057
.TTBC41  ANOP                                                           27400057
&SWBC    SETB  1                   INDICATE BC41 TABLE SPECIFIED        27500057
         AGO   .TTOK               GO PUT TABLE INTO ARRAY              27600057
.TTQUIT ANOP                                                            27700057
&BADTTAB SETB  1                       INDICATE BAD TRANTAB= KEYWORD.   27800057
&QUITSW  SETB  1                       SET QUIT SW.                     27900057
         AGO   .CODE                                                    28000057
.*                                                                      28100057
.*    PROCESS TRANTAB DEFAULT VALUES.                                   28200057
.*                                                                      28300057
.TTABDFT AIF   ('&TERM' NE '1050').T2741  TERM=1050 SPECIFIED?          28400057
&A       SETA  (&NLG-1)*4              INITILIZE INDEX A.               28500057
&TTAB(&A+1) SETC '1050'                YES, DEFAULT TO TAB 1050.        28600057
         AGO   .CODE                                                    28700057
.T2741   AIF   ('&TERM' NE '2741').T5041  TERM=2741 SPECIFIED?          28800057
&A       SETA  (&NLG-1)*4              INITILIZE INDEX A.               28900057
&TTAB(&A+1) SETC 'CR41'                 YES, DEFAULT TO TAB CR41,       29000057
&TTAB(&A+2) SETC 'EB41'                                 TAB EB41,       29100057
         AGO   .CODE                                                    29200057
.T5041   AIF   ('&TERM' NE '5041').T3335  TERM=5041 SPECIFIED?          29300057
&A       SETA  (&NLG-1)*4              INITILIZE INDEX A.               29400057
&TTAB(&A+1) SETC '1050'                 YES, DEFAULT TO TAB 1050,       29500057
&TTAB(&A+2) SETC 'CR41'                                 TAB CR41.       29600057
&TTAB(&A+3) SETC 'EB41'                                 TAB EB41,       29700057
         AGO   .CODE                                                    29800057
.T3335   AIF   ('&TERM' NE '3335').T2260  TERM=3335 SPECIFIED?          29900057
&A       SETA  (&NLG-1)*4              INITILIZE INDEX A.               30000057
&TTAB(&A+1) SETC 'TTYB'                 YES, DEFAULT TO TAB TTYB,       30100057
         AGO   .CODE                                                    30200057
.T2260   AIF   ('&TERM' NE '226R').T226L  TERM=226R SPECIFIED?          30300057
&TTAB((&NLG-1)*4+1) SETC '2260'         SET 2260 DEFAULT                30400057
         AGO   .CODE                                                    30500057
.T226L   AIF   ('&TERM' NE '226L').T2265  TERM=226L SPECIFIED?          30600057
&TTAB((&NLG-1)*4+1) SETC 'EBCD'         SET 2260 LOCAL DEFAULT          30700057
         AGO   .CODE                                                    30800057
.T2265   AIF   ('&TERM' NE '2265').T3270  TERM=265 SPECIFIED?           30900057
&TTAB((&NLG-1)*4+1) SETC '2265'         SET 2265 DEFAULT                31000057
         AGO   .CODE                                                    31100057
.T3270   ANOP                                                           31200057
         AIF   ('&TERM' EQ '327L').TT3  TERM=327L SPECIFIED?            31300057
         AIF   ('&TERM' EQ '327R').TT3  TERM=327R SPECIFIED             31400057
         AIF   ('&TERM' NE '327S').TTQUIT                               31500057
.TT3     ANOP                                                           31600057
&TTAB((&NLG-1)*4+1) SETC 'EBCD'         SET 3720 DEFAULT                31700057
.CODE    ANOP                                                           31800057
.*  ------------------------------------------------------------------- 31900057
.*  -----      CODE= KEYWORD ANALYSIS    ------------------------------ 32000057
.*  ------------------------------------------------------------------- 32100057
         AIF   (&BADTTAB).CODER1        TRANTAB SPECIFIED CORRECTLY?    32200057
         AIF   ('&CODE' EQ '').CODEDFT TEST CODE FOR DEFAULT.           32300057
.*                                                                      32400057
.*             NOT DEFAULT, TEST FOR VALIDITY.                          32500057
.*                                                                      32600057
         AIF   ('&TTAB((&NLG-1)*4+2)' EQ '').CODER2  BR IF ONLY 1 TBL   32700057
&C       SETA  N'&CODE                 GET NO. OF SUBLIST OPERANDS.     32800057
         AIF   (&C GT 4).CODER3        GT 4 OPERANDS SPECIFIED?         32900057
.*                                                                      33000057
.*   TEST CHARACTER COUNT OF EACH SUBLIST OPERAND.                      33100057
.*                                                                      33200057
&D       SETA  1                                                        33300057
.CLOOP1  AIF   (K'&CODE(&D) GT 8).CODER4  GT 8 CHARACTERS SPECIFIED?    33400057
         AIF   (&D EQ &C).CODEOK       MORE SUB-OPERANDS? NO, BR.       33500057
&D       SETA  &D+1                    INIT. TO TEST NEXT SUB-OPERAND   33600057
         AGO   .CLOOP1                 BR TO TEST AGAIN.                33700057
.CODER1  ANOP                                                           33800057
         AGO   .CQUIT                                                   33900057
.CODER2  MNOTE 4,'IKJ54106I CODE OPERAND SHOULD BE SPECIFIED ONLY IF   X34000057
                MORE THAN ONE TRANSLATE TABLE IS SPECIFIED'             34100057
         AGO   .DIAL                                                    34200057
.CODER3  MNOTE 12,'IKJ54107I CODE OPERAND CONTAINS MORE THAN 4 SUBLIST X34300057
                OPERANDS'                                               34400057
         AGO   .CQUIT                                                   34500057
.CODER4  MNOTE 12,'IKJ54108I CODE SUBOPERAND TOO LONG'                  34600057
.CQUIT   ANOP                                                           34700057
&BADCODE SETB  1                        INDICATE BAD CODE= KEYWORD.     34800057
&QUITSW  SETB  1                       SET QUIT SW.                     34900057
         AGO   .DIAL                    BR TO TEST DIAL.                35000057
.*                                                                      35100057
.*   PROCESS CODE VALUES INTO TABLE.                                    35200057
.*                                                                      35300057
.CODEOK  ANOP                                                           35400057
&A       SETA  (&NLG-1)*4               INITILIZE INDEX A.              35500057
&B       SETA  0                   INITIALIZE INDEX B                   35600057
.CLOOP2  ANOP                                                           35700057
&B       SETA  &B+1                     INCREMENT INDEX B.              35800057
         AIF   ('&CODE(&B)' EQ '').CODNULL  SKIP NULL OPERANDS          35900057
&CTAB(&A+1) SETC '&CODE(&B)'           SAVE CODE SUB-OPERAND IN TABLE.  36000057
&A       SETA  &A+1                    YES, INCREMENT INDEX A.          36100057
.CODNULL ANOP                                                           36200057
         AIF   (N'&CODE LT (&B+1)).DIAL MORE SUB-OPERANDS? NO, BR.      36300057
         AGO   .CLOOP2                                                  36400057
.*                                                                      36500057
.*   PROCESS CODE DEFAULT VALUES.                                       36600057
.*                                                                      36700057
.CODEDFT ANOP                                                           36800057
         AIF   (NOT &SWBC  OR NOT &SWEB).CODESET                        36900057
&QTDFTSW SETB  1                   INDICATE QUOTE IS DEFAULT VALUE      37000057
.CODESET ANOP                                                           37100057
&A       SETA  (&NLG-1)*4               INITILIZE INDEX A.              37200057
         AIF   (&QTDFTSW).C1           DEFAULT OF (") TO BE USED.       37300057
&CTAB(&A+1) SETC 'LOGON'               NO, USE 'LOGON'.                 37400057
         AGO   .DIAL                    BR TO TEST DIAL.                37500057
.C1      ANOP                                                           37600057
&CTAB(&A+1) SETC '"LOGON'          SET DEFAULT FOR BC41/EB41            37700057
.DIAL    ANOP                                                           37800057
.*  ------------------------------------------------------------------- 37900057
.*  -----      DIAL= KEYWORD ANALYSIS.     ---------------------------- 38000057
.*  ------------------------------------------------------------------- 38100057
         AIF   (N'&DIAL GT 1).D1       TEST FOR VALID KEYWORD.          38200057
         AIF   ('&DIAL' EQ 'YES' OR '&DIAL' EQ 'NO').D2                 38300057
.D1      MNOTE 16,'IKJ54104I &DIAL INVALID FOR DIAL OPERAND'            38400057
         AGO   .DQUIT                                                   38500057
.D2      AIF   (NOT &BADTERM).D3       TERM= KEYWORD BAD?               38600057
         AGO   .DQUIT                                                   38700057
.D3      AIF   ('&DIAL' EQ 'YES').D4   DIAL=YES TO BE USED?             38800057
         AIF   ('&TERM' EQ '5041' OR '&TERM' EQ '3335').D5              38900057
         AGO   .INTVL                  BR TO TEST INTVL.                39000057
.D4      ANOP                                                           39100057
         AIF   ('&TERM'(1,3) EQ '226' OR '&TERM'(1,3) EQ '327').D5      39200057
.*                                 2260'S AND 3270'S ARE NON-SWITCHED   39300057
&DIALSW(&I) SETB 1                     INDICATE DIAL=YES SPECIFIED.     39400057
         AGO   .INTVL                  BR TO TEST INTVL.                39500057
.D5      MNOTE 12,'IKJ54109I DIAL OPERAND NOT CONSISTANT WITH TERM     X39600057
                OPERAND'                                                39700057
.DQUIT   ANOP                                                           39800057
&BADDIAL SETB  1                       INDICATE BAD DIAL=KEYWORD.       39900057
&QUITSW SETB  1                        SET QUIT SW.                     40000057
.INTVL ANOP                                                             40100057
.*  ------------------------------------------------------------------- 40200057
.*  ----- INTVL= KEYWORD ANALYSIS     --------------------------------- 40300057
.*  ------------------------------------------------------------------- 40400057
         AIF   (N'&INTVL GT 1).I1      TEST FOR VALID KEYWORD.          40500057
         AIF   ('&INTVL' EQ '').I3  IF OMITTED, GO SET DEFAULT          40600057
         AIF   (&INTVL GE 0 AND &INTVL LE 255).I2                       40700057
.I1      MNOTE 4,'IKJ54110I INTVL OPERAND OUT OF RANGE, DEFAULT VALUE U-40800057
               SED'                                                     40900057
.I3      ANOP                                                           41000057
&INT(&I) SETA  0                   USE DEFAULT VALUE                    41100057
         AIF   ('&TERM' EQ '2741').FEATURE                              41200057
         AIF   ('&TERM' EQ '226L').FEATURE                              41300057
         AIF   ('&TERM' EQ '327L').FEATURE                              41400057
         AIF   ('&TERM' EQ '3335').FEATURE                              41500057
&INT(&I) SETA  2                   SET DEFAULT FOR POLLED TERMINALS     41600057
         AGO   .FEATURE                BR TO TEST FEATURE.              41700057
.I2      ANOP                                                           41800057
&INT(&I) SETA  &INTVL                  SAVE INTVL VALUE.                41900057
.FEATURE ANOP                                                           42000057
.*  ------------------------------------------------------------------- 42100057
.*   -----      FEATURE= KEYWORD ANALYSIS     ------------------------- 42200057
.*  ------------------------------------------------------------------- 42300057
         AIF   (N'&FEATURE GT 3).FEER1 TEST FOR EXCESSIVE OPERANDS.     42400057
         AIF   (&BADTERM).FEER2        TEST FOR BAD TERM= KEYWORD.      42500057
.*                                                                      42600057
.*       ESTABLISH DEFAULT ASSUMPTIONS                                  42700057
.*                                                                      42800057
&A       SETA  (&NLG-1)*3          SET TABLE GROUP POINTER              42900057
         AIF   ('&TERM' EQ '2741' OR '&TERM' EQ '3335').F1              43000057
         AIF   ('&TERM' EQ '226L' OR '&TERM' EQ '226R').F226            43100057
         AIF   ('&TERM' EQ '327L' OR '&TERM' EQ '327R').F327            43200057
         AIF   ('&TERM' EQ '327S').F327                                 43300057
         AIF   ('&TERM' NE '2265').NOBATN                               43400057
.F226    ANOP                                                           43500057
.*  ASSUME (NOBREAK,NOATTN) FOR 2260/65                                 43600057
&SW2260  SETB  1                   INDICATE 2260/65 LINE GROUP          43700057
         AGO   .F2                 GO PROCESS FEATURE SUBLIST           43800057
.F327    ANOP                                                           43900057
.*  ASSUME (NOBREAK,NOATTN) FOR 3270                                    44000057
&SW3270  SETB  1                   INDICATE 3270 LINE GROUP             44100057
         AGO   .F2                                                      44200057
.NOBATN  ANOP                                                           44300057
.* ASSUME (NOBREAK,ATTN) FOR 1050 AND 5041                              44400057
&FETAB(&A+2) SETB 1                                                     44500057
         AGO   .F2                                                      44600057
.* ASSUME (BREAK,ATTN,TOSUPPR) FOR 2741 AND 3335                        44700057
.F1      ANOP                                                           44800057
&FETAB(&A+1) SETB 1                                                     44900057
&FETAB(&A+2) SETB 1                                                     45000057
&FETAB(&A+3) SETB 1                                                     45100057
.*                                                                      45200057
.*       PROCESS FEATURE SUBLIST, SETTING TABLE SWITCHES IF INDICATED   45300057
.*       FEATURES ARE VALID.                                            45400057
.*                                                                      45500057
.F2      ANOP                                                           45600057
         AIF   ('&FEATURE' EQ '').TERMNO  BR IF DEFAULTS WANTED         45700057
&B       SETA  1              SET SUB LIST POINTER                      45800057
.FLOOP   ANOP                                                           45900057
&F       SETC  '&FEATURE(&B)'                                           46000057
         AIF   ('&F' NE 'BREAK').FL1                                    46100057
         AIF   (&SW2260 OR &SW3270).FEER3                               46200057
&FETAB(&A+1) SETB 1                                                     46300057
         AGO   .FTEST                                                   46400057
.FL1     AIF   ('&F' NE 'NOBREAK').FL2                                  46500057
         AIF   ('&TERM' EQ '3335').FEER3                                46600057
&FETAB(&A+1) SETB 0                                                     46700057
         AGO   .FTEST                                                   46800057
.FL2     AIF   ('&F' NE 'ATTN').FL3                                     46900057
         AIF   (&SW2260 OR &SW3270).FEER3                               47000057
&FETAB(&A+2) SETB 1                                                     47100057
         AGO   .FTEST                                                   47200057
.FL3     AIF   ('&F' NE 'NOATTN').FL4                                   47300057
         AIF   ('&TERM' EQ '3335').FEER3                                47400057
&FETAB(&A+2) SETB 0                                                     47500057
         AGO   .FTEST                                                   47600057
.FL4     AIF   ('&F' NE 'TOSUPPR').FEER3                                47700057
         AIF   (&SW2260 OR &SW3270).FEER3                               47800057
&FETAB(&A+3) SETB 1                                                     47900057
.FTEST   ANOP                                                           48000057
&B       SETA  &B+1                                                     48100057
         AIF   (&B LE N'&FEATURE).FLOOP                                 48200057
         AGO   .TERMNO                                                  48300057
.FEER1   MNOTE 12,'IKJ54111I FEATURE OPERAND CONTAINS TOO MANY SUBLIST -48400057
                OPERANDS'                                               48500057
         AGO   .FQUIT                                                   48600057
.FEER2   ANOP                                                           48700057
         AGO   .FQUIT                                                   48800057
.FEER3   MNOTE 4,'IKJ54112I SUBLIST OPERAND &B OF FEATURE OPERAND IS IN-48900057
               VALID'                                                   49000057
         AGO   .FTEST              GO CONTINUE TESTING                  49100057
.FQUIT   ANOP                                                           49200057
&BADFE   SETB  1                       INDICATE BAD FEATURE= KEYWORD.   49300057
&QUITSW  SETB  1                       SET QUIT SW.                     49400057
.********************************************************************** 49500057
.*       TERMNO= KEYWORD ANALYSIS                                       49600057
.********************************************************************** 49700057
.TERMNO  ANOP                                                           49800057
.*                                                                      49900057
.*       CHECK FOR TOO MANY TERMINALS                                   50000057
.*                                                                      50100057
&A       SETA  1                   SET SUBPARAMETER SELECTOR            50200057
&B       SETA  0                   CLEAR TERMINAL COUNT                 50300057
.TCNTLOP ANOP                      LOOP EXECUTED ONCE/LINE IN LINEGRP   50400057
         AIF   ('&TERMNO(&A)' EQ '').COUNT1  TEST FOR DEFAULT           50500057
&B       SETA  &B+&TERMNO(&A)      UPDATE TERMINAL COUNT                50600057
         AGO   .TCNTTST            GO TO LOOP TEST                      50700057
.COUNT1  ANOP                                                           50800057
&B       SETA  &B+1                UPDATE TERMINAL COUNT BY 1           50900057
.TCNTTST ANOP                                                           51000057
&A       SETA  &A+1                INCREMENT SUBPARAMETER SELECTOR      51100057
         AIF   (&A LE &LNO(&NLG)).TCNTLOP                               51200057
.*                                                                      51300057
.*       UPDATE SCREEN AND ADDR CHAR ARRAY POINTERS                     51400057
.*                                                                      51500057
         AIF   (&NLG NE 1).TRM1    BRANCH UNLESS THIS IS FIRST CALL     51600057
&ADRPT   SETA  1                   INITIALIZE ADDR CHARS ARRAY POINTER  51700057
&SCRPT   SETA  1                   INITIALIZE SCREEN ARRAY POINTER      51800057
         AGO   .TRM2               GO TEST PARAMETER VALIDITY           51900057
.TRM1    ANOP                                                           52000057
&B       SETA  0                   SET LOOP VARIABLE                    52100057
.TRMLP1  ANOP                      LOOP ONCE/LINE IN LAST LINEGRP       52200057
&ADRPT   SETA  &ADRPT+&TRMNO(&SCRPT+&B) UPDATE ADDR ARRAY POINTER       52300057
&B       SETA  &B+1                BUMP LOOP CONTROL VARIABLE           52400057
         AIF   (&B LT &LNO(&NLG-1)).TRMLP1  BR IF MORE LINES            52500057
&SCRPT   SETA  &SCRPT+&B           UPDATE SCREEN ARRAY POINTER          52600057
.*                                                                      52700057
.*       CHECK PARAMETER VALIDITY                                       52800057
.*                                                                      52900057
.TRM2    AIF   ('&TERMNO' EQ '').TRMDEF                                 53000057
         AIF   (&SW2260 OR &SW3270).TRM3                                53100057
.*                                 TERMO VALID FOR 2260/2265/3270       53200057
         MNOTE 4,'IKJ54114I TERMNO OPERAND NOT ALLOWED FOR THIS TERMINA-53300057
               L TYPE'                                                  53400057
         AGO   .TRMDEF             GO GENERATE DEFAULT VALUES           53500057
.TRM3    ANOP                                                           53600057
         AIF   (&BADLNO).PCICK                                          53700057
         AIF   (N'&TERMNO LE &LNO(&NLG)).TRM4                           53800057
         MNOTE 8,'IKJ54115I TERMNO OPERAND REFERENCES NON-EXISTENT LINE-53900057
               S'                                                       54000057
.*                                                                      54100057
.*       MOVE PARAMETER VALUES INTO ARRAY                               54200057
.*                                                                      54300057
.TRM4    ANOP                                                           54400057
&A       SETA  N'&TERMNO           SET NUMBER OF OPERANDS TO MOVE       54500057
.TRM5    ANOP                      ENTER HERE IF NOT TO MOVE ALL        54600057
&B       SETA  1                   SET LOOP CONTROL VARIABLE            54700057
.TRMMOV  ANOP                      LOOP ONCE/LINE IN LINE GROUP         54800057
         AIF   (&B GT &A).TRMONE   BR IF DEFAULT NEEDED                 54900057
         AIF   ('&TERMNO(&B)' EQ '').TRMONE  BR IF DEFAULT NEEDED       55000057
&TRMNO(&SCRPT+&B-1) SETA &TERMNO(&B) MOVE OPERAND INTO ARRAY            55100057
         AGO   .TRM6               GO TO LOOP TEST                      55200057
.TRMONE  ANOP                                                           55300057
&TRMNO(&SCRPT+&B-1) SETA 1         PUT DEFAULT VALUE IN ARRAY           55400057
.TRM6    ANOP                                                           55500057
&B       SETA  &B+1                BUMP LOOP CONTROL VARIABLE           55600057
         AIF   (&B LE &LNO(&NLG)).TRMMOV  LOOP BACK IF MORE LINES       55700057
         AGO   .SCREEN             GO PROCESS SCREEN PARAMETER          55800057
.TRMDEF  ANOP                      SET DEFAULT ONE TERMINAL/LINE        55900057
&A       SETA  0                   ASK TO MOVE NO OPERANDS              56000057
         AGO   .TRM5               GO MOVE DEFAULT VALUES INTO ARRAY    56100057
.*                                                                      56200057
.*********************************************************************  56300057
.*       SCREEN=                                                        56400057
.*********************************************************************  56500057
.*                                                                      56600057
.SCREEN  ANOP                                                           56700057
         AIF   ('&SCREEN' EQ '').SCRDEF BR IF DEFAULT VALUES NEEDED     56800057
         AIF   (&SW2260 OR &SW3270).SCR1                                56900057
.*                                      BR IF VALID TERMINAL TYPE       57000057
         MNOTE 4,'IKJ54114I SCREEN OPERAND NOT ALLOWED FOR THIS TERMINA-57100057
               L TYPE'                                                  57200057
         AGO   .ADDR                                                    57300057
.SCR1    ANOP                                                           57400057
         AIF   (N'&SCREEN EQ 2).SCR2    BR IF NO. OF OPERANDS OK        57500057
         MNOTE 4,'IKJ54116I SCREEN OPERAND MUST BE A TWO-OPERAND SUBLIS-57600057
               T'                                                       57700057
         AGO   .SCRDEF                  GO GENERATE DEFAULT VALUES      57800057
.*                                                                      57900057
.*       CHECK FOR STANDARD VALUES                                      58000057
.*                                                                      58100057
.SCR2    ANOP                                                           58200057
&A       SETA  &SCREEN(1)                                               58300057
&B       SETA  &SCREEN(2)                                               58400057
         AIF   (&A EQ 12 AND &B EQ 40).SCRSTD                           58500057
         AIF   (&A EQ 12 AND &B EQ 80).SCR3                             58600057
         AIF   (&A EQ 6 AND &B EQ 40).SCR3                              58700057
         AIF   (&A EQ 15 AND &B EQ 64).SCR3                             58800057
         AIF   (&A EQ 24 AND &B EQ 80).SCR4                             58900057
         AGO   .SCRNSTD                                                 59000057
.SCR3    ANOP                                                           59100057
         AIF   (&SW2260).SCRSTD                                         59200057
         AGO   .SCRNSTD                                                 59300057
.SCR4    ANOP                                                           59400057
         AIF   (&SW3270).SCRSTD                                         59500057
.SCRNSTD ANOP                                                           59600057
         MNOTE 4,'IKJ54117I NON-STANDARD SCREEN DIMENSIONS -- ACCEPTED' 59700057
         AGO   .SCRSTD                                          SA68208 59800057
.*                                                                      59900057
.SCRDEF  ANOP                                                           60000057
         AIF   (NOT &SW2260).SCRDEF1    GENERATE FOR 2260/65            60100057
&A       SETA  12                       SET DEFAULT HEIGHT              60200057
&B       SETA  80                       SET DEFAULT WIDTH               60300057
         AGO   .SCRSTD                                                  60400057
.SCRDEF1 ANOP                                                           60500057
         AIF   (NOT &SW3270).ADDR       GENERATE FOR 3270               60600057
&A       SETA  24                       SET DEFAULT HEIGHT              60700057
&B       SETA  80                       SET DEFAULT WIDTH               60800057
.*                                                                      60900057
.SCRSTD  ANOP                                                           61000057
.*                                                                      61100057
.*       INSERT SCREEN DIMENSIONS IN ARRAYS                             61200057
.*                                                                      61300057
&C       SETA  0                        SET LOOP CONTROL VARIABLE       61400057
.SCRLOOP ANOP                           LOOP ONCE/LINE IN LINE GROUP    61500057
&SCRH(&SCRPT+&C) SETA &A                SET SCREEN HEIGHT               61600057
&SCRW(&SCRPT+&C) SETA &B                SET SCREEN WIDTH                61700057
&C       SETA  &C+1                     BUMP LOOP CONTROL VARIABLE      61800057
         AIF   (&C LT &LNO(&NLG)).SCRLOOP  LOOP IF MORE LINES           61900057
.*                                                                      62000057
.*********************************************************************  62100057
.*       ADDR=                                                          62200057
.*********************************************************************  62300057
.*                                                                      62400057
.ADDR    ANOP                                                           62500057
         AIF   ('&ADDR' EQ '').PCICK                                    62600057
         AIF   (N'&ADDR GT 1).ADER3                                     62700057
         AIF   ('&TERM' NE '1050' AND '&TERM' NE '5041').ADDR226        62800057
         AIF   (K'&ADDR NE 2).ADER2                                     62900057
         AGO   .PUTADDR                                                 63000057
.ADDR226 ANOP                                                           63100057
         AIF   ('&TERM' EQ '226R' OR '&TERM' EQ '2265').ADDR1           63200057
         AIF   ('&TERM' EQ '327R' OR '&TERM' EQ '327S').ADDR1           63300057
         AGO   .ADER1                                                   63400057
.ADDR1   ANOP                                                           63500057
         AIF   (K'&ADDR NE 4).ADER2                                     63600057
.*                                                                      63700057
.*       PUT ADDR CHARS INTO ARRAY                                      63800057
.*                                                                      63900057
.PUTADDR ANOP                                                           64000057
&A       SETA  0                        SET LOOP CONTROL VARIABLE       64100057
&C       SETA  0                   SET TERMINAL COUNTER                 64200057
.ADRLOOP ANOP                           LOOP ONCE/LINE IN LINE GROUP    64300057
&B       SETA  0                        SET INNER LOOP CTRL VARIABLE    64400057
.ADRINLP ANOP                           LOOP ONCE/TERMINAL ON LINE      64500057
&ADCHAR(&ADRPT+&C) SETC '&ADDR'    PUT PARAMETER VALUE IN ARRAY         64600057
&C       SETA  &C+1                BUMP TERMINAL COUNTER                64700057
&B       SETA  &B+1                     BUMP INNER LOOP COUNTER         64800057
         AIF   (&B LT &TRMNO(&SCRPT+&A)).ADRINLP  LOOP IF MORE TERM'S   64900057
&A       SETA  &A+1                     BUMP LOOP CONTROL VARIABLE      65000057
         AIF   (&A LT &LNO(&NLG)).ADRLOOP  LOOP IF MORE LINES           65100057
         AGO   .PCICK                                                   65200057
.*                                                                      65300057
.*       ADDR PARAMETER ERROR MESSAGES                                  65400057
.*                                                                      65500057
.ADER1   MNOTE 4,'IKJ54114I ADDR OPERAND NOT ALLOWED FOR THIS TERMINAL -65600057
                TYPE'                                                   65700057
         AGO   .PCICK                                                   65800057
.ADER2   MNOTE 4,'IKJ54118I ADDR OPERAND INCORRECT LENGTH -- IGNORED'   65900057
         AGO   .PCICK                                                   66000057
.ADER3   MNOTE 8,'IKJ54104I &ADDR INVALID FOR ADDR OPERAND'             66100057
         AGO   .PCICK                                                   66200057
.PCICK ANOP                                                     SA59163 66300057
.*                                                                      66400057
.********************************************************************** 66500057
.*       PCI KEYWORD ANALYSIS                                           66600057
.********************************************************************** 66700057
.*                                                                      66800057
         AIF   ('&PCI' EQ '').DEFPCI                            SA59163 66900057
         AIF   (N'&PCI NE 2).BADPCI                             SA59163 67000057
&F       SETC  '&PCI(1)'                                        SA59163 67100057
.NEXTCK  ANOP                                                   SA59163 67200057
         AIF   ('&F' EQ 'N' OR '&F' EQ 'R' OR '&F' EQ 'X').PCI1 SA59163 67300057
         AIF   ('&F' EQ 'A').PCI1                               SA59163 67400057
.BADPCI  ANOP                           SA59163                 SA59163 67500057
         MNOTE 4,'IKJ54119I PCI OPERAND MUST BE (X,Y), WHERE X AND Y ARX67600057
               E A, X, R, OR N.  PCI DEFAULTED.'                SA59163 67700057
         AGO   .DEFPCI                                          SA59163 67800057
.PCI1    ANOP                                                   SA59163 67900057
         AIF   ('&F' EQ '&PCI(2)').PUTPCI                       SA59163 68000057
&F       SETC  '&PCI(2)'                                        SA59163 68100057
         AGO   .NEXTCK                                          SA59163 68200057
.*                                                                      68300057
.*       DEFAULT PCI SPECIFICATIONS                             SA59163 68400057
.*                                                                      68500057
.DEFPCI  ANOP                                                   SA59163 68600057
         AIF   ('&TERM' EQ '226L').PCINN                        SA72293 68700057
         AIF   ('&TERM' EQ '327L').PCINN                        SA72293 68800057
&PC(&I)  SETC  '(A,A)'                                          SA59163 68900057
         AGO   .ALLDONE                                         SA59163 69000057
.PCINN   ANOP                                                   SA72293 69100057
&PC(&I)  SETC  '(N,N)'        SET PCI FOR LOCAL 3270 AND 2260   SA72293 69200057
         AGO   .ALLDONE                                         SA59163 69300057
.PUTPCI  ANOP                                                   SA59163 69400057
&PC(&I)  SETC  '&PCI'                   USER'S SPECIFICATION    SA59163 69500057
.ALLDONE ANOP                                                   SA59163 69600057
         MEND                                                           69700057
