         MACRO                                                          00500057
&NM     LISTTA &RLN=,&ADDR=,&SCREEN=                                    01000057
.*                                                                      01500057
.*       RELEASE 21 TCAM LEVEL 4, 02/28/72, CHANGE LEVEL=01             02000057
.*                                                                      02500057
.*                                                                      03000057
.*FUNCTION -- THIS MACRO GIVES THE USER THE CAPABILITY TO SPECIFY       03500057
.*   ATTRIBUTES OF HIS CONFIGURATION WHICH VARY AMONG LINES OR          04000057
.*   TERMINALS WITHIN A LINE GROUP.                                     04500057
.*                                                                      05000057
.*ENTRY POINTS -- NOT APPLICABLE                                        05500057
.*                                                                      06000057
.*INPUT -- MACRO CALL PARAMETERS                                        06500057
.*                                                                      07000057
.*OUTPUT -- VALUES IN GLOBAL VARIABLES TO BE USED LATER BY THE          07500057
.*   'TSOMCP' MACRO.  MNOTE MESSAGES IF INVALID PARAMETERS ARE          08000057
.*   DETECTED.                                                          08500057
.*                                                                      09000057
.*EXTERNAL REFERENCES - NOT APPLICABLE                                  09500057
.*                                                                      10000057
.*EXITS,NORMAL -- NORMAL EXIT OCCURS IF NO SERIOUS ERRORS IN THE        10500057
.*   CALLER'S PARAMETERS ARE DETECTED.                                  11000057
.*                                                                      11500057
.*EXITS, ERROR -- UPON DETECTION OF A SERIOUS ERROR, THE 'QUITSW'       12000057
.*   IS SET TO 1 AND FURTHER PROCESSING IS BYPASSED.                    12500057
.*                                                                      13000057
.*TABLES/WORK AREAS -- SEE DESCRIPTIONS ACCOMPANYING VARIABLE           13500057
.*   DECLARATIONS.                                                      14000057
.*                                                                      14500057
.*ATTRIBUTES -- NOT APPLICABLE                                          15000057
.*                                                                      15500057
.*CHARACTER CODE DEPENDENCY - NONE                                      16000057
.*                                                                      16500057
.*NOTES -- NONE                                                         17000057
.*                                                                      17500057
.*                                                                      18000057
.*       GLOBAL VARIABLES                                               18500057
.*                                                                      19000057
         GBLA  &NLG                NUMBER OF LINEGRP MACROS ISSUED      19500057
         GBLA  &LNO(63)            NUMBER OF LINES/LINE GROUP           20000057
         GBLA  &ADRPT              POINTER TO LAST ADDR PARM GROUP      20500057
         GBLA  &SCRPT              POINTER TO LAST SCREEN PARM GROUP    21000057
         GBLA  &SCRH(2500)         CONTAINS SCREEN HEIGHT               21500057
         GBLA  &SCRW(2500)         CONTAINS SCREEN WIDTH                22000057
         GBLA  &TRMNO(2500)        NUMBER OF TERMINALS/LINE             22500057
.*                                                                      23000057
         GBLB  &LGRPSW             INDICATES LINEGRP ISSUED             23500057
         GBLB  &MCPSW              INDICATES TSOMCP ISSUED              24000057
         GBLB  &QUITSW             GENERATION QUIT SWITCH               24500057
         GBLB  &DIALSW(63)         ON MEANS SWITCHED LINE               25000057
.*                                                                      25500057
         GBLC  &T(63)              CONTAINS TERM= PARAMETER VALUES      26000057
         GBLC  &ADCHAR(2500)       CONTAINS ADDR= PARAMETER VALUES      26500057
.*                                                                      27000057
.*       LOCAL VARIABLES                                                27500057
.*                                                                      28000057
         LCLA  &P                  POINTER TO SCREEN/TERMNO ARRAYS      28500057
         LCLA  &I                  WORK VARIABLE                        29000057
         LCLA  &J                  WORK VARIABLE                        29500057
.*                                                                      30000057
.*       TEST FOR MACRO CALL OUT OF ORDER                               30500057
.*                                                                      31000057
         AIF   (&LGRPSW AND NOT &MCPSW).INORDER                         31500057
         MNOTE 16,'IKJ54120I LISTTA MACRO OUT OF ORDER -- IGNORED'      32000057
         AGO   .GIVEUP             GO SET QUIT SW & EXIT                32500057
.INORDER ANOP                                                           33000057
.*                                                                      33500057
.*       TEST IF CALL IS CONSISTANT WITH LAST LINEGRP CALL              34000057
.*                                                                      34500057
         AIF   (N'&RLN EQ 1 AND T'&RLN EQ 'N').RLNOK                    35000057
         MNOTE 16,'IKJ54121I RLN OPERAND MISSING OR INVALID'            35500057
&QUITSW  SETB  1                   PREVENT MCP GENERATION               36000057
         MEXIT                                                          36500057
.RLNOK   ANOP                                                           37000057
         AIF   (&RLN LE &LNO(&NLG) AND &RLN NE 0).REFOK                 37500057
         MNOTE 16,'IKJ54122I RLN OPERAND REFERS TO NON-EXISTENT LINE'   38000057
         AGO   .GIVEUP             GO SET QUIT SWITCH & EXIT            38500057
.*                                                                      39000057
.REFOK   ANOP                                                           39500057
         AIF   ('&T(&NLG)'(1,3) EQ '226').TERMOK                        40000057
         AIF   ('&T(&NLG)'(1,3) EQ '327').TERMOK                        40500057
         AIF   ('&T(&NLG)' EQ '1050').TERMOK                            41000057
         AIF   ('&T(&NLG)' EQ '5041').TERMOK                            41500057
         MNOTE 16,'IKJ54123I LISTTA MACRO NOT ALLOWED WITH TERMINAL TYP-42000057
               E OF PREVIOUS LINEGRP'                                   42500057
         AGO   .GIVEUP             GO SET QUIT SW & EXIT                43000057
.TERMOK  ANOP                                                           43500057
.*                                                                      44000057
.*       SET POINTER TO SCREEN/TERMNO ARRAYS                            44500057
.*                                                                      45000057
&P       SETA  &SCRPT+&RLN-1                                            45500057
.*                                                                      46000057
.*********************************************************************  46500057
.*       ADDR=                                                          47000057
.*********************************************************************  47500057
.*                                                                      48000057
         AIF   (N'&ADDR EQ 0).SCREEN  BR IF OPERAND OMITTED             48500057
         AIF   ('&T(&NLG)' EQ '226L').ADDER1  BR IF 226L                49000057
         AIF   ('&T(&NLG)' NE '327L').NOTLOCL BR IF NOT 327L            49500057
.ADDER1  ANOP                                                           50000057
         MNOTE 4,'IKJ54114I ADDR OPERAND NOT ALLOWED FOR THIS TERMINAL -50500057
                TYPE'                                                   51000057
         AGO   .SCREEN             SKIP ADDR PROCESSING                 51500057
.NOTLOCL ANOP                                                           52000057
         AIF   (N'&ADDR LE &TRMNO(&P)).PUTADDR                          52500057
         MNOTE 4,'IKJ54124I ADDR OPERAND REFERS TO NON-EXISTENT TERMINA-53000057
               L(S)'                                                    53500057
         AGO   .SCREEN                                                  54000057
.*                                                                      54500057
.*       SET POINTER TO ADCHAR ARRAY                                    55000057
.*                                                                      55500057
.PUTADDR ANOP                                                           56000057
&I       SETA  1                   INITIALIZE LOOP CONTROL VARIABLE     56500057
&J       SETA  &ADRPT              INITIALIZE ADCHAR ARRAY POINTER      57000057
.ADDR1   ANOP                      LOOP RLN-1 TIMES                     57500057
         AIF   (&I GE &RLN).MVADDR                                      58000057
&J       SETA  &J+&TRMNO(&SCRPT+&I-1)  INCREMENT POINTER BY NUMBER      58500057
.*                                 OF TERMINALS ON LINE                 59000057
&I       SETA  &I+1                BUMP LOOP CONTROL VARIABLE           59500057
         AGO   .ADDR1              GO TO LOOP TEST                      60000057
.*                                                                      60500057
.*       MOVE ADDRESS CHARACTERS INTO ARRAY                             61000057
.*                                                                      61500057
.MVADDR  ANOP                      LOOP EXECUTED N'&ADDR TIMES          62000057
&I       SETA  0                   SET LOOP CONTROL VARIABLE            62500057
.ADDR2   ANOP                      LOOP EXECUTED FOR EACH SUBOPERAND    63000057
         AIF   ('&ADDR(&I+1)' EQ '').ADDRLT  SKIP NULL SUBOPERANDS      63500057
         AIF   (K'&ADDR(&I+1) EQ 2 AND '&T(&NLG)' EQ '1050').ADSZOK     64000057
         AIF   (K'&ADDR(&I+1) EQ 2 AND '&T(&NLG)' EQ '5041').ADSZOK     64500057
         AIF   (K'&ADDR(&I+1) EQ 4 AND '&T(&NLG)' EQ '226R').ADSZOK     65000057
         AIF   (K'&ADDR(&I+1) EQ 4 AND '&T(&NLG)' EQ '2265').ADSZOK     65500057
         AIF   (K'&ADDR(&I+1) EQ 4 AND '&T(&NLG)' EQ '327R').ADSZOK     66000057
         AIF   (K'&ADDR(&I+1) EQ 4 AND '&T(&NLG)' EQ '327S').ADSZOK     66500057
         MNOTE 4,'IKJ54118I ADDR=&ADDR(&I+1) INCORRECT LENGTH -- IGNORE-67000057
               D'                                                       67500057
         AGO   .ADDRLT                                                  68000057
.ADSZOK  ANOP                                                           68500057
&ADCHAR(&J+&I) SETC '&ADDR(&I+1)'  PUT IN ARRAY                         69000057
.ADDRLT  ANOP                                                           69500057
&I       SETA  &I+1                BUMP LOOP CONTROL VARIABLE           70000057
         AIF   (&I LT N'&ADDR).ADDR2   BR UNTIL ALL OPERANDS HANDLED    70500057
.*                                                                      71000057
.*********************************************************************  71500057
.*       SCREEN                                                         72000057
.*********************************************************************  72500057
.*                                                                      73000057
.SCREEN  ANOP                                                           73500057
         AIF   ('&SCREEN' NE '').CHKDSPY                                74000057
         MEXIT                     EXIT IF OPERAND OMITTED              74500057
.CHKDSPY ANOP                                                           75000057
         AIF   ('&T(&NLG)'(1,3) EQ '226').CHKNO                         75500057
         AIF   ('&T(&NLG)'(1,3) EQ '327').CHKNO                         76000057
         MNOTE 4,'IKJ54114I SCREEN OPERAND NOT ALLOWED FOR THIS TERMINAL76500057
               L TYPE'                                                  77000057
         MEXIT                                                          77500057
.*                                                                      78000057
.CHKNO   ANOP                                                           78500057
         AIF   (N'&SCREEN  EQ 2).CHKSTD                                 79000057
         MNOTE 4,'IKJ54116I SCREEN OPERAND MUST BE A TWO-OPERAND SUBLIST79500057
               T'                                                       80000057
         MEXIT                                                          80500057
.*                                                                      81000057
.*       CHECK FOR STANDARD VALUES                                      81500057
.*                                                                      82000057
.CHKSTD  ANOP                                                           82500057
&I       SETA  &SCREEN(1)                                               83000057
&J       SETA  &SCREEN(2)                                               83500057
         AIF   (&I EQ 12 AND &J EQ 40).PUTSCR                           84000057
         AIF   ('&T(&NLG)'(1,3) EQ '327').ANR                           84500057
         AIF   (&I EQ 12 AND &J EQ 80).PUTSCR                           85000057
         AIF   (&I EQ 6 AND &J EQ 40).PUTSCR                            85500057
         AIF   (&I EQ 15 AND &J EQ 64).PUTSCR                           86000057
         AGO   .SCRER                                                   86500057
.ANR     ANOP                                                           87000057
         AIF   (&I EQ 24 AND &J EQ 80).PUTSCR                           87500057
.SCRER   ANOP                                                           88000057
         MNOTE 4,'IKJ54117I NON-STANDARD SCREEN DIMENSIONS -- ACCEPTED' 88500057
.*                                                                      89000057
.PUTSCR  ANOP                                                           89500057
&SCRH(&P) SETA &SCREEN(1)               MOVE IN HEIGHT                  90000057
&SCRW(&P) SETA &SCREEN(2)               MOVE IN WIDTH                   90500057
         MEXIT                          NORMAL EXIT                     91000057
.*                                                                      91500057
.GIVEUP  ANOP                                                           92000057
&QUITSW  SETB  1                        SERIOUS ERROR - DON'T GENERATE  92500057
         MEXIT                          THE MCP                         93000057
         MEND                                                           93500057
