         MACRO                                                          00050000
&NAME    STACK &PARM=,&UPT=,&ECT=,&ECB=,&TERM=,&STORAGE=,&DELETE=,     *00100000
               &ENTRY=,&MF=                                             00150000
.********************************************************************** 00200000
.*                                                                    * 00250000
.*                                                                    * 00300000
.*                                                                    * 00350000
.*                                                                    * 00400000
.*STATUS:                                                             * 00450000
.*   CHANGE LEVEL 000.                                                * 00500000
.*                                                                    * 00550000
.*FUNCTION:                                                           * 00600000
.*   THE STACK MACRO EXAMINES PARAMETERS SPECIFIED IN THE STACK MACRO * 00650000
.*   INSTRUCTION AND BUILDS A PARAMETER BLOCK TO BE USED BY THE STACK * 00700000
.*   SERVICE ROUTINE (REFER TO SECTION 3.48.8.1 FOR THE PARAMETER     * 00750000
.*   BLOCK FORMAT).                                                   * 00800000
.*   IN THE LIST FORM, THE STACK MACRO GENERATES THE STACK            * 00850000
.*   PARAMETER BLOCK CONSISTING OF ONE WORD OF CONTROL (OPERATION AND * 00900000
.*   CODE) AND THE ADDRESS OF THE STORAGE LIST SOURCE DESCRIPTOR.     * 00950000
.*   IN THE EXECUTE FORM OF THE STACK MACRO, CODE IS GENERATED        * 01000000
.*   WHICH WILL RESET THE PARAMETER BLOCK IF REQUIRED AND LOAD THE    * 01050000
.*   ADDRESSES OF THE UPT, ECT, ECB, AND PARAMETER BLOCK INTO THE     * 01100000
.*   SERVICE ROUTINE PARAMETER LIST IF SPECIFIED. A LINK MACRO WILL   * 01150000
.*   BE GENERATED TO INVOKE THE STACK SERVICE ROUTINE UNLESS AN       * 01200000
.*   ENTRY POINT IS SPECIFIED. IF AN ENTRY POINT IS SPECIFIED, THE    * 01250000
.*   CODE TO ENABLE A BRANCH AND LINK WILL BE GENERATED.              * 01300000
.*                                                                    * 01350000
.*ENTRY POINTS:                                                       * 01400000
.*   STACK MACRO CALL - ONLY ENTRY POINT.                             * 01450000
.*                                                                    * 01500000
.*INPUT:                                                              * 01550000
.*   PARAMETERS SPECIFIED IN THE STACK MACRO FORMAT (FOR FORMAT       * 01600000
.*   SPECIFICATIONS REFER TO SECTION 3.48.8.1).                       * 01650000
.*                                                                    * 01700000
.*OUTPUT:                                                             * 01750000
.*   IN THE L-FORM, A 2-WORD PARAMETER BLOCK (REFER TO SECTION        * 01800000
.*   3.48.8.1) CONSISTING OF CONTROL WHICH IS SET BY THE MACRO AND    * 01850000
.*   THE ADDRESS OF THE STORAGE LIST SOURCE DESCRIPTOR.               * 01900000
.*   IN THE E-FORM, CODE WHICH RESETS CONTROL IN THE PARAMETER BLOCK, * 01950000
.*   PLACES THE ADDRESSES OF THE SERVICE ROUTINE PARAMETER BLOCK,     * 02000000
.*   UPT, ECT, AND ECB IN THE SERVICE ROUTINE PARAMETER LIST AS       * 02050000
.*   SPECIFIED, AND INVOKES THE SERVICE ROUTINE.                      * 02100000
.*                                                                    * 02150000
.*EXTERNAL REFERENCES:                                                * 02200000
.*   LINK MACRO.                                                      * 02250000
.*                                                                    * 02300000
.*EXITS,NORMAL:                                                       * 02350000
.*   IN THE L-FORM, RETURN TO CALLER.                                 * 02400000
.*   IN THE E-FORM, CODE IS GENERATED TO INVOKE THE STACK SERVICE     * 02450000
.*   ROUTINE ACCORDING TO THE STANDARD LINKAGE CONVENTIONS (REFER TO  * 02500000
.*   SECTION 3.48.1.5).                                               * 02550000
.*                                                                    * 02600000
.*EXITS,ERROR:                                                        * 02650000
.*   INVALID INPUT.                                                   * 02700000
.*                                                                    * 02750000
.*TABLES/WORK AREAS:                                                  * 02800000
.*   SERVICE ROUTINE PARAMETER LIST - A TABLE OF POINTERS TO THE UPT, * 02850000
.*   ECT, ECB, AND SERVICE ROUTINE PARAMETER BLOCK.                   * 02900000
.*   SERVICE ROUTINE PARAMETER BLOCK - A CONTROL TABLE SET ACCORDING  * 02950000
.*   TO THE SPECIFIED MACRO PARAMETERS AND THE ADDRESS OF THE STORAGE * 03000000
.*   LIST SOURCE DESCRIPTOR.                                          * 03050000
.*                                                                    * 03100000
.*ATTRIBUTES:                                                         * 03150000
.*   SERIALLY REUSABLE.                                               * 03200000
.*                                                                    * 03250000
.*NOTES:                                                              * 03300000
.*   DATE OF CURRENT RELEASE :                                        * 03350000
.*      01/22/70                                                      * 03400000
.*   PREVIOUS RELEASE DATES :                                         * 03450000
.*      12/12/69                                                      * 03500000
.*      10/22/69                                                      * 03550000
.*                                                                    * 03600000
.*                                                                    * 03650000
.*                                                                    * 03700000
.*                                                                    * 03750000
.*                                                                    * 03800000
.********************************************************************** 03850000
         LCLA  &A                                                       03900000
         LCLC  &C                                                       03950000
         AIF   (T'&MF EQ 'O').ERR1           NO MF PARAMETER            04000000
         AIF   (N'&SYSLIST EQ 0).MF1   POSITIONAL PARAMETERS INVALID    04050000
         AIF   (T'&SYSLIST(1) NE 'O' OR N'&SYSLIST NE 1).ERR6           04100000
.MF1     AIF   ('&MF' EQ 'L').L1             BRANCH ON LIST FORM        04150000
.********************************************************************** 04200000
.*                                                                    * 04250000
.*                               EXECUTE FORM                         * 04300000
.*                                                                    * 04350000
.********************************************************************** 04400000
         AIF   ('&MF(1)' NE 'E').ERR1                                   04450000
         AIF   (T'&NAME EQ 'O').E1                                      04500000
&NAME    DS    0H                                                       04550000
.E1      AIF   (T'&MF(2) EQ 'O').ERR1                                   04600000
         AIF   ('&MF(2)' EQ '(1)').E2                                   04650000
         AIF   ('&MF(2)'(1,1) EQ '(').WARN3                             04700000
.E1A     LA    1,&MF(2)       LOAD PARM LIST ADDR                       04750000
.E2      AIF   (T'&UPT EQ 'O').E3       UPT OMITTED                     04800000
         AIF   ('&UPT'(1,1) EQ '(').E2A                                 04850000
         LA    14,&UPT        LOAD UPT ADDR                             04900000
         ST    14,0(0,1)     STORE UPT ADDR                             04950000
         AGO   .E3                                                      05000000
.E2A     ANOP                                                           05050000
&A       SETA  K'&UPT-2                                                 05100000
&C       SETC  '&UPT'(2,&A)                                             05150000
         ST    &C,0(0,1)     STORE UPT ADDR IN PARM LIST                05200000
.E3      AIF   (T'&ECT EQ 'O').E4     ECT OMITTED                       05250000
         AIF   ('&ECT'(1,1) EQ '(').E3A                                 05300000
         LA    14,&ECT                  LOAD ECT ADDR                   05350000
         ST    14,4(0,1)               STORE ECT ADDR IN PARM LIST      05400000
         AGO   .E4                                                      05450000
.E3A     ANOP                                                           05500000
&A       SETA  K'&ECT-2                                                 05550000
&C       SETC  '&ECT'(2,&A)                                             05600000
         ST    &C,4(0,1)               STORE ECT ADDR IN PARM LIST      05650000
.E4      AIF   (T'&ECB EQ 'O').E5       ECB OMITTED                     05700000
         AIF   ('&ECB'(1,1) EQ '(').E4A                                 05750000
         LA    14,&ECB        LOAD ECB ADDR                             05800000
         ST    14,8(0,1)     STORE ECB ADDR IN PARM LIST                05850000
         AGO   .E5                                                      05900000
.E4A     ANOP                                                           05950000
&A       SETA  K'&ECB-2                                                 06000000
&C       SETC  '&ECB'(2,&A)                                             06050000
         ST    &C,8(0,1)     STORE ECB ADDR IN PARM LIST                06100000
.E5      AIF   (T'&PARM EQ 'O').E5B     PARM OMITTED                    06150000
         AIF   ('&PARM'(1,1)  EQ '(').E5A                               06200000
         LA    14,&PARM       LOAD PARM ADDR                            06250000
         ST    14,12(0,1)    STORE PARM ADDR IN PARM LIST               06300000
         AGO   .E6                                                      06350000
.E5A     ANOP                                                           06400000
&A       SETA  K'&PARM-2                                                06450000
&C       SETC  '&PARM'(2,&A)                                            06500000
         ST    &C,12(0,1)    STORE PARM ADDR IN PARM LIST               06550000
         AIF   (T'&TERM EQ 'O' AND N'&STORAGE EQ 0 AND                 *06600000
               T'&DELETE EQ 'O').E10                                    06650000
         LR    14,&C          LOAD PARM ADDR                            06700000
         AGO   .E6                                                      06750000
.E5B     AIF   (T'&TERM EQ 'O' AND N'&STORAGE EQ 0   AND T'&DELETE     *06800000
               EQ 'O').E10                                              06850000
         L     14,12(0,1)     LOAD PARM BLOCK ADDR INTO REGISTER        06900000
.E6      AIF   (T'&TERM EQ 'O' AND N'&STORAGE EQ 0   AND T'&DELETE     *06950000
               EQ 'O').E10                                              07000000
.E7      AIF   (T'&TERM EQ 'O').E8      TERM OMITTED                    07050000
         AIF   (N'&STORAGE NE 0   OR T'&DELETE NE 'O').ERR3             07100000
         AIF   ('&TERM' NE '*').ERR4                                    07150000
         MVI   0(14),X'80'         SET OPERATION FIELD                  07200000
         MVI   1(14),X'80'         SET CODE FIELD                       07250000
         AGO   .E10                                                     07300000
.E8      AIF   (N'&STORAGE EQ 0).E9          STORAGE OMITTED            07350000
         AIF   (T'&TERM NE 'O' OR T'&DELETE NE 'O').ERR3                07400000
         MVI   0(14),X'80'         SET OPERATION FIELD                  07450000
         AIF   ('&STORAGE' EQ '()').E8E      ALL OPERANDS OMITTED       07500000
&A       SETA  N'&STORAGE                                               07550000
         AIF   (&A GT 2).ERR2           TOO MANY OPERANDS               07600000
         AIF   (&A EQ 1 OR T'&STORAGE(2) EQ 'O').E8E   LSD ADDR ONLY    07650000
.E8B     AIF   ('&STORAGE(2)' NE 'PROCN').E8C                           07700000
         MVI   1(14),X'42'         SET CODE FIELD                       07750000
         AGO   .E8F                                                     07800000
.E8C     AIF   ('&STORAGE(2)' NE 'PROCL').E8D                           07850000
         MVI   1(14),X'43'         SET CODE FIELD                       07900000
         AGO   .E8F                                                     07950000
.E8D     AIF   ('&STORAGE(2)' NE 'SOURCE').ERR2                         08000000
.E8E     MVI   1(14),X'40'         SET CODE FIELD                       08050000
.E8F     AIF   (T'&STORAGE(1) EQ 'O' OR '&STORAGE' EQ '()').WARN1       08100000
         AIF   ('&STORAGE(1)'(1,1) EQ '(').E8G                          08150000
         LA    0,&STORAGE(1)       LOAD STORAGE SOURCE DESCRIPTOR ADDR  08200000
         ST    0,4(0,14)          STORE STORAGE SOURCE DESCRIPTOR ADDR  08250000
         AGO   .E10                                                     08300000
.E8G     ANOP                                                           08350000
&A       SETA  K'&STORAGE(1)-2                                          08400000
&C       SETC  '&STORAGE(1)'(2,&A)                                      08450000
         ST    &C,4(0,14)         STORE STORAGE SOURCE DESCRIPTOR ADDR  08500000
         AGO   .E10                                                     08550000
.E9      AIF   (T'&DELETE EQ 'O').E10        DELETE OMITTED             08600000
         AIF   (T'&TERM NE 'O' OR N'&STORAGE NE 0).ERR3                 08650000
.E9A     AIF   ('&DELETE' NE 'TOP').E9B                                 08700000
         MVI   0(14),X'40'    SET OPERATION FIELD                       08750000
         AGO   .E10                                                     08800000
.E9B     AIF   ('&DELETE' NE 'PROC').E9C                                08850000
         MVI   0(14),X'20'    SET OPERATION FIELD                       08900000
         AGO   .E10                                                     08950000
.E9C     AIF   ('&DELETE' NE 'ALL').ERR5                                09000000
         MVI   0(14),X'10'    SET OPERATION FIELD                       09050000
.E10     AIF   (T'&ENTRY EQ 'O').E11         ENTRY POINT OMITTED        09100000
         AIF   ('&ENTRY' EQ '(15)').E10B                                09150000
         AIF   ('&ENTRY'(1,1) EQ '(').WARN4                             09200000
.E10A    LA    15,&ENTRY      LOAD EP ADDR                              09250000
.E10B    BALR  14,15     BRANCH TO SERVICE ROUTINE                      09300000
         MEXIT                                                          09350000
.E11     LINK  EP=IKJSTCK          LINK TO SERVICE ROUTINE              09400000
         MEXIT                                                          09450000
.********************************************************************** 09500000
.*                                                                    * 09550000
.*                                 LIST FORM                          * 09600000
.*                                                                    * 09650000
.********************************************************************** 09700000
.L1      DS    0F                                                       09750000
.L2      AIF   (T'&TERM EQ 'O').L3      TERM OMITTED                    09800000
         AIF   ('&TERM' NE '*').ERR4                                    09850000
         AIF   (N'&STORAGE NE 0   OR T'&DELETE NE 'O').ERR3             09900000
&NAME    DC    X'80800000'         SET OPERATION AND CODE FIELDS        09950000
         DC    A(0)      STORAGE SOURCE DESCRIPTOR ADDR                 10000000
         MEXIT                                                          10050000
.L3      AIF   (T'&DELETE EQ 'O').L4    DELETE OMITTED                  10100000
         AIF   (T'&TERM NE 'O' OR N'&STORAGE NE 0).ERR3                 10150000
.L3A     AIF   ('&DELETE' NE 'TOP').L3B                                 10200000
&NAME    DC    X'40000000'         SET OPERATION AND CODE FIELDS        10250000
         AGO   .L3D                                                     10300000
.L3B     AIF   ('&DELETE' NE 'PROC').L3C                                10350000
&NAME    DC    X'20000000'         SET OPERATION AND CODE FIELDS        10400000
         AGO   .L3D                                                     10450000
.L3C     AIF   ('&DELETE' NE 'ALL').ERR5                                10500000
&NAME    DC    X'10000000'         SET OPERATION AND CODE FIELDS        10550000
.L3D     DC    A(0)      STORAGE SOURCE DESCRIPTOR ADDR                 10600000
         MEXIT                                                          10650000
.L4      AIF   (N'&STORAGE EQ 0).L5     NO STORAGE OPERANDS             10700000
         AIF   (T'&TERM NE 'O' OR T'&DELETE NE 'O').ERR3                10750000
         AIF   ('&STORAGE' EQ '()').L4E      ALL OPERANDS OMITTED       10800000
&A       SETA  N'&STORAGE                                               10850000
         AIF   (&A EQ 1 OR T'&STORAGE(2) EQ 'O').L4E   LSD ADDR ONLY    10900000
.L4B     AIF   ('&STORAGE(2)' NE 'PROCN').L4C                           10950000
&NAME    DC    X'80420000'         SET OPERATION AND CODE FIELDS        11000000
         AGO   .L4F                                                     11050000
.L4C     AIF   ('&STORAGE(2)' NE 'PROCL').L4D                           11100000
&NAME    DC    X'80430000'         SET OPERATION AND CODE FIELDS        11150000
         AGO   .L4F                                                     11200000
.L4D     AIF   ('&STORAGE(2)' NE 'SOURCE').ERR2                         11250000
.L4E     ANOP                                                           11300000
&NAME    DC    X'80400000'         SET OPERATION AND CODE FIELDS        11350000
.L4F     AIF   (T'&STORAGE(1) EQ 'O' OR '&STORAGE' EQ '()').WARN2       11400000
         DC    A(&STORAGE(1))      STORAGE SOURCE DESCRIPTOR ADDR       11450000
         MEXIT                                                          11500000
.L5      ANOP                                                           11550000
&NAME    DC    X'00000000'         SET OPERATION AND CODE FIELDS        11600000
         DC    A(0)      STORAGE SOURCE DESCRIPTOR ADDR                 11650000
         MEXIT                                                          11700000
.WARN1   MNOTE 0,'FIRST STORAGE OPERAND IS ASSUMED TO BE IN PARM BLOCK' 11750000
         AGO   .E10                                                     11800000
.WARN2   MNOTE 0,'FIRST STORAGE OPERAND IS OMITTED'                     11850000
         DC    A(0)           STORAGE SOURCE DESCRIPTOR ADDR            11900000
         MEXIT                                                          11950000
.WARN3   MNOTE 0,'PARAMETER LIST ADDR IN MF PARAMETER IS NOT IN REG 1'  12000000
         AGO   .E1A                                                     12050000
.WARN4   MNOTE 0,'ENTRY POINT ADDR IN ENTRY PARAMETER IS NOT IN REG 15' 12100000
         AGO   .E10A                                                    12150000
.ERR1    MNOTE 8,'INVALID OR OMITTED MF PARAMETER'                      12200000
         MEXIT                                                          12250000
.ERR2    MNOTE 8,'INVALID STORAGE PARAMETER OPERAND'                    12300000
         MEXIT                                                          12350000
.ERR3    MNOTE 8,'TERM, STORAGE, AND DELETE ARE MUTUALLY EXCLUSIVE'     12400000
         MEXIT                                                          12450000
.ERR4    MNOTE 8,'INVALID TERM OPERAND'                                 12500000
         MEXIT                                                          12550000
.ERR5    MNOTE 8,'INVALID DELETE OPERAND'                               12600000
         MEXIT                                                          12650000
.ERR6    MNOTE 8,'POSITIONAL PARAMETERS ARE INVALID'                    12700000
         MEXIT                                                          12750000
         MEND                                                           12800000
